This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Update ExtUtils-CBuilder to CPAN version 0.2800
[perl5.git] / cpan / ExtUtils-CBuilder / lib / ExtUtils / CBuilder / Base.pm
1 package ExtUtils::CBuilder::Base;
2
3 use strict;
4 use File::Spec;
5 use File::Basename;
6 use Cwd ();
7 use Config;
8 use Text::ParseWords;
9 use IO::File;
10 use Data::Dumper;$Data::Dumper::Indent=1;
11 use IPC::Cmd qw(can_run);
12 use File::Temp qw(tempfile);
13
14 use vars qw($VERSION);
15 $VERSION = '0.2800';
16
17 # More details about C/C++ compilers:
18 # http://developers.sun.com/sunstudio/documentation/product/compiler.jsp
19 # http://gcc.gnu.org/
20 # http://publib.boulder.ibm.com/infocenter/comphelp/v101v121/index.jsp
21 # http://msdn.microsoft.com/en-us/vstudio/default.aspx
22
23 my %cc2cxx = (
24     # first line order is important to support wrappers like in pkgsrc
25     cc => [ 'c++', 'CC', 'aCC', 'cxx', ], # Sun Studio, HP ANSI C/C++ Compilers
26     gcc => [ 'g++' ], # GNU Compiler Collection
27     xlc => [ 'xlC' ], # IBM C/C++ Set, xlc without thread-safety
28     xlc_r => [ 'xlC_r' ], # IBM C/C++ Set, xlc with thread-safety
29     cl    => [ 'cl' ], # Microsoft Visual Studio
30 );
31
32 sub new {
33   my $class = shift;
34   my $self = bless {@_}, $class;
35
36   $self->{properties}{perl} = $class->find_perl_interpreter
37     or warn "Warning: Can't locate your perl binary";
38
39   while (my ($k,$v) = each %Config) {
40     $self->{config}{$k} = $v unless exists $self->{config}{$k};
41   }
42   $self->{config}{cc} = $ENV{CC} if defined $ENV{CC};
43   $self->{config}{ccflags} = $ENV{CFLAGS} if defined $ENV{CFLAGS};
44   $self->{config}{cxx} = $ENV{CXX} if defined $ENV{CXX};
45   $self->{config}{cxxflags} = $ENV{CXXFLAGS} if defined $ENV{CXXFLAGS};
46   $self->{config}{ld} = $ENV{LD} if defined $ENV{LD};
47   $self->{config}{ldflags} = $ENV{LDFLAGS} if defined $ENV{LDFLAGS};
48
49   unless ( exists $self->{config}{cxx} ) {
50     my ($ccpath, $ccbase, $ccsfx ) = fileparse($self->{config}{cc}, qr/\.[^.]*/);
51     foreach my $cxx (@{$cc2cxx{$ccbase}}) {
52       if( can_run( File::Spec->catfile( $ccpath, $cxx, $ccsfx ) ) ) {
53         $self->{config}{cxx} = File::Spec->catfile( $ccpath, $cxx, $ccsfx );
54         last;
55       }
56       if( can_run( File::Spec->catfile( $cxx, $ccsfx ) ) ) {
57         $self->{config}{cxx} = File::Spec->catfile( $cxx, $ccsfx );
58         last;
59       }
60       if( can_run( $cxx ) ) {
61         $self->{config}{cxx} = $cxx;
62         last;
63       }
64     }
65     unless ( exists $self->{config}{cxx} ) {
66       $self->{config}{cxx} = $self->{config}{cc};
67       my $cflags = $self->{config}{cflags};
68       $self->{config}{cxxflags} = '-x c++';
69       $self->{config}{cxxflags} .= " $cflags" if defined $cflags;
70     }
71   }
72
73   return $self;
74 }
75
76 sub find_perl_interpreter {
77   my $perl;
78   File::Spec->file_name_is_absolute($perl = $^X)
79     or -f ($perl = $Config::Config{perlpath})
80     or ($perl = $^X); # XXX how about using IPC::Cmd::can_run here?
81   return $perl;
82 }
83
84 sub add_to_cleanup {
85   my $self = shift;
86   foreach (@_) {
87     $self->{files_to_clean}{$_} = 1;
88   }
89 }
90
91 sub cleanup {
92   my $self = shift;
93   foreach my $file (keys %{$self->{files_to_clean}}) {
94     unlink $file;
95   }
96 }
97
98 sub get_config {
99     return %{ $_[0]->{config} };
100 }
101
102 sub object_file {
103   my ($self, $filename) = @_;
104
105   # File name, minus the suffix
106   (my $file_base = $filename) =~ s/\.[^.]+$//;
107   return "$file_base$self->{config}{obj_ext}";
108 }
109
110 sub arg_include_dirs {
111   my $self = shift;
112   return map {"-I$_"} @_;
113 }
114
115 sub arg_nolink { '-c' }
116
117 sub arg_object_file {
118   my ($self, $file) = @_;
119   return ('-o', $file);
120 }
121
122 sub arg_share_object_file {
123   my ($self, $file) = @_;
124   return ($self->split_like_shell($self->{config}{lddlflags}), '-o', $file);
125 }
126
127 sub arg_exec_file {
128   my ($self, $file) = @_;
129   return ('-o', $file);
130 }
131
132 sub arg_defines {
133   my ($self, %args) = @_;
134   return map "-D$_=$args{$_}", keys %args;
135 }
136
137 sub compile {
138   my ($self, %args) = @_;
139   die "Missing 'source' argument to compile()" unless defined $args{source};
140   
141   my $cf = $self->{config}; # For convenience
142   
143   my $object_file = $args{object_file}
144     ? $args{object_file}
145     : $self->object_file($args{source});
146
147   my $include_dirs_ref = 
148     (exists($args{include_dirs}) && ref($args{include_dirs}) ne "ARRAY")
149       ? [ $args{include_dirs} ]
150       : $args{include_dirs};
151   my @include_dirs = $self->arg_include_dirs(
152     @{ $include_dirs_ref || [] },
153     $self->perl_inc(),
154   );
155   
156   my @defines = $self->arg_defines( %{$args{defines} || {}} );
157   
158   my @extra_compiler_flags =
159     $self->split_like_shell($args{extra_compiler_flags});
160   my @cccdlflags = $self->split_like_shell($cf->{cccdlflags});
161   my @ccflags = $self->split_like_shell($args{'C++'} ? $cf->{cxxflags} : $cf->{ccflags});
162   my @optimize = $self->split_like_shell($cf->{optimize});
163   my @flags = (
164     @include_dirs,
165     @defines,
166     @cccdlflags,
167     @extra_compiler_flags,
168     $self->arg_nolink,
169     @ccflags,
170     @optimize,
171     $self->arg_object_file($object_file),
172   );
173   my @cc = $self->split_like_shell($args{'C++'} ? $cf->{cxx} : $cf->{cc});
174   
175   $self->do_system(@cc, @flags, $args{source})
176     or die "error building $object_file from '$args{source}'";
177
178   return $object_file;
179 }
180
181 sub have_compiler {
182   my ($self, $is_cplusplus) = @_;
183   my $have_compiler_flag = $is_cplusplus ? "have_cxx" : "have_cc";
184   my $suffix = $is_cplusplus ? ".cc" : ".c";
185   return $self->{$have_compiler_flag} if defined $self->{$have_compiler_flag};
186
187   my $result;
188   my $attempts = 3;
189   # tmpdir has issues for some people so fall back to current dir
190
191   # don't clobber existing files (rare, but possible)
192   my ( $FH, $tmpfile ) = tempfile( "compilet-XXXXX", SUFFIX => $suffix );
193   binmode $FH;
194
195   if ( $is_cplusplus ) {
196     print $FH "class Bogus { public: int boot_compilet() { return 1; } };\n";
197   }
198   else {
199     print $FH "int boot_compilet() { return 1; }\n";
200   }
201
202   my ($obj_file, @lib_files);
203   eval {
204     local $^W = 0;
205     local $self->{quiet} = 1;
206     $obj_file = $self->compile('C++' => $is_cplusplus, source => $tmpfile);
207     @lib_files = $self->link(objects => $obj_file, module_name => 'compilet');
208   };
209   $result = $@ ? 0 : 1;
210
211   foreach (grep defined, $tmpfile, $obj_file, @lib_files) {
212     1 while unlink;
213   }
214
215   return $self->{$have_compiler_flag} = $result;
216 }
217
218 sub have_cplusplus {
219   push @_, 1;
220   goto &have_compiler;
221 }
222
223 sub lib_file {
224   my ($self, $dl_file) = @_;
225   $dl_file =~ s/\.[^.]+$//;
226   $dl_file =~ tr/"//d;
227   return "$dl_file.$self->{config}{dlext}";
228 }
229
230
231 sub exe_file {
232   my ($self, $dl_file) = @_;
233   $dl_file =~ s/\.[^.]+$//;
234   $dl_file =~ tr/"//d;
235   return "$dl_file$self->{config}{_exe}";
236 }
237
238 sub need_prelink { 0 }
239
240 sub extra_link_args_after_prelink { return }
241
242 sub prelink {
243   my ($self, %args) = @_;
244
245   my ($dl_file_out, $mksymlists_args) = _prepare_mksymlists_args(\%args);
246
247   require ExtUtils::Mksymlists;
248   # dl. abbrev for dynamic library
249   ExtUtils::Mksymlists::Mksymlists( %{ $mksymlists_args } );
250
251   # Mksymlists will create one of these files
252   return grep -e, map "$dl_file_out.$_", qw(ext def opt);
253 }
254
255 sub _prepare_mksymlists_args {
256   my $args = shift;
257   ($args->{dl_file} = $args->{dl_name}) =~ s/.*::// unless $args->{dl_file};
258   
259   my %mksymlists_args = (
260     DL_VARS  => $args->{dl_vars}      || [],
261     DL_FUNCS => $args->{dl_funcs}     || {},
262     FUNCLIST => $args->{dl_func_list} || [],
263     IMPORTS  => $args->{dl_imports}   || {},
264     NAME     => $args->{dl_name},    # Name of the Perl module
265     DLBASE   => $args->{dl_base},    # Basename of DLL file
266     FILE     => $args->{dl_file},    # Dir + Basename of symlist file
267     VERSION  => (defined $args->{dl_version} ? $args->{dl_version} : '0.0'),
268   );
269   return ($args->{dl_file}, \%mksymlists_args);
270 }
271
272 sub link {
273   my ($self, %args) = @_;
274   return $self->_do_link('lib_file', lddl => 1, %args);
275 }
276
277 sub link_executable {
278   my ($self, %args) = @_;
279   return $self->_do_link('exe_file', lddl => 0, %args);
280 }
281
282 sub _do_link {
283   my ($self, $type, %args) = @_;
284
285   my $cf = $self->{config}; # For convenience
286   
287   my $objects = delete $args{objects};
288   $objects = [$objects] unless ref $objects;
289   my $out = $args{$type} || $self->$type($objects->[0]);
290   
291   my @temp_files;
292   @temp_files =
293     $self->prelink(%args, dl_name => $args{module_name})
294       if $args{lddl} && $self->need_prelink;
295   
296   my @linker_flags = (
297     $self->split_like_shell($args{extra_linker_flags}),
298     $self->extra_link_args_after_prelink(
299        %args, dl_name => $args{module_name}, prelink_res => \@temp_files
300     )
301   );
302
303   my @output = $args{lddl}
304     ? $self->arg_share_object_file($out)
305     : $self->arg_exec_file($out);
306   my @shrp = $self->split_like_shell($cf->{shrpenv});
307   my @ld = $self->split_like_shell($cf->{ld});
308   
309   $self->do_system(@shrp, @ld, @output, @$objects, @linker_flags)
310     or die "error building $out from @$objects";
311   
312   return wantarray ? ($out, @temp_files) : $out;
313 }
314
315
316 sub do_system {
317   my ($self, @cmd) = @_;
318   print "@cmd\n" if !$self->{quiet};
319   return !system(@cmd);
320 }
321
322 sub split_like_shell {
323   my ($self, $string) = @_;
324   
325   return () unless defined($string);
326   return @$string if UNIVERSAL::isa($string, 'ARRAY');
327   $string =~ s/^\s+|\s+$//g;
328   return () unless length($string);
329   
330   # Text::ParseWords replaces all 'escaped' characters with themselves, which completely
331   # breaks paths under windows. As such, we forcibly replace backwards slashes with forward
332   # slashes on windows.
333   $string =~ s@\\@/@g if $^O eq 'MSWin32';
334   
335   return Text::ParseWords::shellwords($string);
336 }
337
338 # if building perl, perl's main source directory
339 sub perl_src {
340   # N.B. makemaker actually searches regardless of PERL_CORE, but
341   # only squawks at not finding it if PERL_CORE is set
342
343   return unless $ENV{PERL_CORE};
344
345   my $Updir = File::Spec->updir;
346   my $dir   = File::Spec->curdir;
347
348   # Try up to 5 levels upwards
349   for (0..10) {
350     if (
351       -f File::Spec->catfile($dir,"config_h.SH")
352       &&
353       -f File::Spec->catfile($dir,"perl.h")
354       &&
355       -f File::Spec->catfile($dir,"lib","Exporter.pm")
356     ) {
357       return Cwd::realpath( $dir );
358     }
359
360     $dir = File::Spec->catdir($dir, $Updir);
361   }
362
363   warn "PERL_CORE is set but I can't find your perl source!\n";
364   return ''; # return empty string if $ENV{PERL_CORE} but can't find dir ???
365 }
366
367 # directory of perl's include files
368 sub perl_inc {
369   my $self = shift;
370
371   $self->perl_src() || File::Spec->catdir($self->{config}{archlibexp},"CORE");
372 }
373
374 sub DESTROY {
375   my $self = shift;
376   local($., $@, $!, $^E, $?);
377   $self->cleanup();
378 }
379
380 1;
381
382 # vim: ts=2 sw=2 et: