This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Reorganize the srand entry.
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 An named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
140 C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<sockatmark>, C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<sockatmark>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item I<-X> FILEHANDLE
250
251 =item I<-X> EXPR
252
253 =item I<-X>
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file.
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Age of file in days when script started.
298     -A  Same for access time.
299     -C  Same for inode change time.
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current stdio buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  Example:
354
355     print "Can do.\n" if -r $a || -w _ || -x _;
356
357     stat($filename);
358     print "Readable\n" if -r _;
359     print "Writable\n" if -w _;
360     print "Executable\n" if -x _;
361     print "Setuid\n" if -u _;
362     print "Setgid\n" if -g _;
363     print "Sticky\n" if -k _;
364     print "Text\n" if -T _;
365     print "Binary\n" if -B _;
366
367 =item abs VALUE
368
369 =item abs
370
371 Returns the absolute value of its argument.
372 If VALUE is omitted, uses C<$_>.
373
374 =item accept NEWSOCKET,GENERICSOCKET
375
376 Accepts an incoming socket connect, just as the accept(2) system call
377 does.  Returns the packed address if it succeeded, false otherwise.
378 See the example in L<perlipc/"Sockets: Client/Server Communication">.
379
380 On systems that support a close-on-exec flag on files, the flag will
381 be set for the newly opened file descriptor, as determined by the
382 value of $^F.  See L<perlvar/$^F>.
383
384 =item alarm SECONDS
385
386 =item alarm
387
388 Arranges to have a SIGALRM delivered to this process after the
389 specified number of seconds have elapsed.  If SECONDS is not specified,
390 the value stored in C<$_> is used. (On some machines,
391 unfortunately, the elapsed time may be up to one second less than you
392 specified because of how seconds are counted.)  Only one timer may be
393 counting at once.  Each call disables the previous timer, and an
394 argument of C<0> may be supplied to cancel the previous timer without
395 starting a new one.  The returned value is the amount of time remaining
396 on the previous timer.
397
398 For delays of finer granularity than one second, you may use Perl's
399 four-argument version of select() leaving the first three arguments
400 undefined, or you might be able to use the C<syscall> interface to
401 access setitimer(2) if your system supports it.  The Time::HiRes
402 module (from CPAN, and starting from Perl 5.8 part of the standard
403 distribution) may also prove useful.
404
405 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
406 (C<sleep> may be internally implemented in your system with C<alarm>)
407
408 If you want to use C<alarm> to time out a system call you need to use an
409 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
410 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
411 restart system calls on some systems.  Using C<eval>/C<die> always works,
412 modulo the caveats given in L<perlipc/"Signals">.
413
414     eval {
415         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
416         alarm $timeout;
417         $nread = sysread SOCKET, $buffer, $size;
418         alarm 0;
419     };
420     if ($@) {
421         die unless $@ eq "alarm\n";   # propagate unexpected errors
422         # timed out
423     }
424     else {
425         # didn't
426     }
427
428 =item atan2 Y,X
429
430 Returns the arctangent of Y/X in the range -PI to PI.
431
432 For the tangent operation, you may use the C<Math::Trig::tan>
433 function, or use the familiar relation:
434
435     sub tan { sin($_[0]) / cos($_[0])  }
436
437 =item bind SOCKET,NAME
438
439 Binds a network address to a socket, just as the bind system call
440 does.  Returns true if it succeeded, false otherwise.  NAME should be a
441 packed address of the appropriate type for the socket.  See the examples in
442 L<perlipc/"Sockets: Client/Server Communication">.
443
444 =item binmode FILEHANDLE, DISCIPLINE
445
446 =item binmode FILEHANDLE
447
448 Arranges for FILEHANDLE to be read or written in "binary" or "text" mode
449 on systems where the run-time libraries distinguish between binary and
450 text files.  If FILEHANDLE is an expression, the value is taken as the
451 name of the filehandle.  DISCIPLINE can be either of C<":raw"> for
452 binary mode or C<":crlf"> for "text" mode.  If the DISCIPLINE is
453 omitted, it defaults to C<":raw">.  Returns true on success, C<undef> on
454 failure.
455
456 binmode() should be called after open() but before any I/O is done on
457 the filehandle.
458
459 On some systems binmode() is necessary when you're not working with a
460 text file.  For the sake of portability it is a good idea to always use
461 it when appropriate, and to never use it when it isn't appropriate.
462
463 In other words:  Regardless of platform, use binmode() on binary
464 files, and do not use binmode() on text files.
465
466 The C<open> pragma can be used to establish default disciplines.
467 See L<open>.
468
469 The operating system, device drivers, C libraries, and Perl run-time
470 system all work together to let the programmer treat a single
471 character (C<\n>) as the line terminator, irrespective of the external
472 representation.  On many operating systems, the native text file
473 representation matches the internal representation, but on some
474 platforms the external representation of C<\n> is made up of more than
475 one character.
476
477 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
478 character to end each line in the external representation of text (even
479 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
480 on Unix and most VMS files).  Consequently binmode() has no effect on
481 these operating systems.  In other systems like OS/2, DOS and the various
482 flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>, but
483 what's stored in text files are the two characters C<\cM\cJ>.  That means
484 that, if you don't use binmode() on these systems, C<\cM\cJ> sequences on
485 disk will be converted to C<\n> on input, and any C<\n> in your program
486 will be converted back to C<\cM\cJ> on output.  This is what you want for
487 text files, but it can be disastrous for binary files.
488
489 Another consequence of using binmode() (on some systems) is that
490 special end-of-file markers will be seen as part of the data stream.
491 For systems from the Microsoft family this means that if your binary
492 data contains C<\cZ>, the I/O subsystem will regard it as the end of
493 the file, unless you use binmode().
494
495 binmode() is not only important for readline() and print() operations,
496 but also when using read(), seek(), sysread(), syswrite() and tell()
497 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
498 in L<perlvar> for how to manually set your input and output
499 line-termination sequences.
500
501 =item bless REF,CLASSNAME
502
503 =item bless REF
504
505 This function tells the thingy referenced by REF that it is now an object
506 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
507 is used.  Because a C<bless> is often the last thing in a constructor,
508 it returns the reference for convenience.  Always use the two-argument
509 version if the function doing the blessing might be inherited by a
510 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
511 (and blessings) of objects.
512
513 Consider always blessing objects in CLASSNAMEs that are mixed case.
514 Namespaces with all lowercase names are considered reserved for
515 Perl pragmata.  Builtin types have all uppercase names, so to prevent
516 confusion, you may wish to avoid such package names as well.  Make sure
517 that CLASSNAME is a true value.
518
519 See L<perlmod/"Perl Modules">.
520
521 =item caller EXPR
522
523 =item caller
524
525 Returns the context of the current subroutine call.  In scalar context,
526 returns the caller's package name if there is a caller, that is, if
527 we're in a subroutine or C<eval> or C<require>, and the undefined value
528 otherwise.  In list context, returns
529
530     ($package, $filename, $line) = caller;
531
532 With EXPR, it returns some extra information that the debugger uses to
533 print a stack trace.  The value of EXPR indicates how many call frames
534 to go back before the current one.
535
536     ($package, $filename, $line, $subroutine, $hasargs,
537     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
538
539 Here $subroutine may be C<(eval)> if the frame is not a subroutine
540 call, but an C<eval>.  In such a case additional elements $evaltext and
541 C<$is_require> are set: C<$is_require> is true if the frame is created by a
542 C<require> or C<use> statement, $evaltext contains the text of the
543 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
544 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
545 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
546 frame.  C<$hasargs> is true if a new instance of C<@_> was set up for the
547 frame.  C<$hints> and C<$bitmask> contain pragmatic hints that the caller
548 was compiled with.  The C<$hints> and C<$bitmask> values are subject to
549 change between versions of Perl, and are not meant for external use.
550
551 Furthermore, when called from within the DB package, caller returns more
552 detailed information: it sets the list variable C<@DB::args> to be the
553 arguments with which the subroutine was invoked.
554
555 Be aware that the optimizer might have optimized call frames away before
556 C<caller> had a chance to get the information.  That means that C<caller(N)>
557 might not return information about the call frame you expect it do, for
558 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
559 previous time C<caller> was called.
560
561 =item chdir EXPR
562
563 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
564 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
565 changes to the directory specified by C<$ENV{LOGDIR}>.  If neither is
566 set, C<chdir> does nothing.  It returns true upon success, false
567 otherwise.  See the example under C<die>.
568
569 =item chmod LIST
570
571 Changes the permissions of a list of files.  The first element of the
572 list must be the numerical mode, which should probably be an octal
573 number, and which definitely should I<not> a string of octal digits:
574 C<0644> is okay, C<'0644'> is not.  Returns the number of files
575 successfully changed.  See also L</oct>, if all you have is a string.
576
577     $cnt = chmod 0755, 'foo', 'bar';
578     chmod 0755, @executables;
579     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
580                                              # --w----r-T
581     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
582     $mode = 0644;   chmod $mode, 'foo';      # this is best
583
584 You can also import the symbolic C<S_I*> constants from the Fcntl
585 module:
586
587     use Fcntl ':mode';
588
589     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
590     # This is identical to the chmod 0755 of the above example.
591
592 =item chomp VARIABLE
593
594 =item chomp LIST
595
596 =item chomp
597
598 This safer version of L</chop> removes any trailing string
599 that corresponds to the current value of C<$/> (also known as
600 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
601 number of characters removed from all its arguments.  It's often used to
602 remove the newline from the end of an input record when you're worried
603 that the final record may be missing its newline.  When in paragraph
604 mode (C<$/ = "">), it removes all trailing newlines from the string.
605 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
606 a reference to an integer or the like, see L<perlvar>) chomp() won't
607 remove anything.
608 If VARIABLE is omitted, it chomps C<$_>.  Example:
609
610     while (<>) {
611         chomp;  # avoid \n on last field
612         @array = split(/:/);
613         # ...
614     }
615
616 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
617
618 You can actually chomp anything that's an lvalue, including an assignment:
619
620     chomp($cwd = `pwd`);
621     chomp($answer = <STDIN>);
622
623 If you chomp a list, each element is chomped, and the total number of
624 characters removed is returned.
625
626 =item chop VARIABLE
627
628 =item chop LIST
629
630 =item chop
631
632 Chops off the last character of a string and returns the character
633 chopped.  It is much more efficient than C<s/.$//s> because it neither
634 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
635 If VARIABLE is a hash, it chops the hash's values, but not its keys.
636
637 You can actually chop anything that's an lvalue, including an assignment.
638
639 If you chop a list, each element is chopped.  Only the value of the
640 last C<chop> is returned.
641
642 Note that C<chop> returns the last character.  To return all but the last
643 character, use C<substr($string, 0, -1)>.
644
645 =item chown LIST
646
647 Changes the owner (and group) of a list of files.  The first two
648 elements of the list must be the I<numeric> uid and gid, in that
649 order.  A value of -1 in either position is interpreted by most
650 systems to leave that value unchanged.  Returns the number of files
651 successfully changed.
652
653     $cnt = chown $uid, $gid, 'foo', 'bar';
654     chown $uid, $gid, @filenames;
655
656 Here's an example that looks up nonnumeric uids in the passwd file:
657
658     print "User: ";
659     chomp($user = <STDIN>);
660     print "Files: ";
661     chomp($pattern = <STDIN>);
662
663     ($login,$pass,$uid,$gid) = getpwnam($user)
664         or die "$user not in passwd file";
665
666     @ary = glob($pattern);      # expand filenames
667     chown $uid, $gid, @ary;
668
669 On most systems, you are not allowed to change the ownership of the
670 file unless you're the superuser, although you should be able to change
671 the group to any of your secondary groups.  On insecure systems, these
672 restrictions may be relaxed, but this is not a portable assumption.
673 On POSIX systems, you can detect this condition this way:
674
675     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
676     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
677
678 =item chr NUMBER
679
680 =item chr
681
682 Returns the character represented by that NUMBER in the character set.
683 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
684 chr(0x263a) is a Unicode smiley face.  Note that characters from
685 127 to 255 (inclusive) are not encoded in Unicode for backward
686 compatibility reasons.
687
688 For the reverse, use L</ord>.
689 See L<utf8> for more about Unicode.
690
691 If NUMBER is omitted, uses C<$_>.
692
693 =item chroot FILENAME
694
695 =item chroot
696
697 This function works like the system call by the same name: it makes the
698 named directory the new root directory for all further pathnames that
699 begin with a C</> by your process and all its children.  (It doesn't
700 change your current working directory, which is unaffected.)  For security
701 reasons, this call is restricted to the superuser.  If FILENAME is
702 omitted, does a C<chroot> to C<$_>.
703
704 =item close FILEHANDLE
705
706 =item close
707
708 Closes the file or pipe associated with the file handle, returning true
709 only if stdio successfully flushes buffers and closes the system file
710 descriptor.  Closes the currently selected filehandle if the argument
711 is omitted.
712
713 You don't have to close FILEHANDLE if you are immediately going to do
714 another C<open> on it, because C<open> will close it for you.  (See
715 C<open>.)  However, an explicit C<close> on an input file resets the line
716 counter (C<$.>), while the implicit close done by C<open> does not.
717
718 If the file handle came from a piped open C<close> will additionally
719 return false if one of the other system calls involved fails or if the
720 program exits with non-zero status.  (If the only problem was that the
721 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe
722 also waits for the process executing on the pipe to complete, in case you
723 want to look at the output of the pipe afterwards, and
724 implicitly puts the exit status value of that command into C<$?>.
725
726 Prematurely closing the read end of a pipe (i.e. before the process
727 writing to it at the other end has closed it) will result in a
728 SIGPIPE being delivered to the writer.  If the other end can't
729 handle that, be sure to read all the data before closing the pipe.
730
731 Example:
732
733     open(OUTPUT, '|sort >foo')  # pipe to sort
734         or die "Can't start sort: $!";
735     #...                        # print stuff to output
736     close OUTPUT                # wait for sort to finish
737         or warn $! ? "Error closing sort pipe: $!"
738                    : "Exit status $? from sort";
739     open(INPUT, 'foo')          # get sort's results
740         or die "Can't open 'foo' for input: $!";
741
742 FILEHANDLE may be an expression whose value can be used as an indirect
743 filehandle, usually the real filehandle name.
744
745 =item closedir DIRHANDLE
746
747 Closes a directory opened by C<opendir> and returns the success of that
748 system call.
749
750 DIRHANDLE may be an expression whose value can be used as an indirect
751 dirhandle, usually the real dirhandle name.
752
753 =item connect SOCKET,NAME
754
755 Attempts to connect to a remote socket, just as the connect system call
756 does.  Returns true if it succeeded, false otherwise.  NAME should be a
757 packed address of the appropriate type for the socket.  See the examples in
758 L<perlipc/"Sockets: Client/Server Communication">.
759
760 =item continue BLOCK
761
762 Actually a flow control statement rather than a function.  If there is a
763 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
764 C<foreach>), it is always executed just before the conditional is about to
765 be evaluated again, just like the third part of a C<for> loop in C.  Thus
766 it can be used to increment a loop variable, even when the loop has been
767 continued via the C<next> statement (which is similar to the C C<continue>
768 statement).
769
770 C<last>, C<next>, or C<redo> may appear within a C<continue>
771 block.  C<last> and C<redo> will behave as if they had been executed within
772 the main block.  So will C<next>, but since it will execute a C<continue>
773 block, it may be more entertaining.
774
775     while (EXPR) {
776         ### redo always comes here
777         do_something;
778     } continue {
779         ### next always comes here
780         do_something_else;
781         # then back the top to re-check EXPR
782     }
783     ### last always comes here
784
785 Omitting the C<continue> section is semantically equivalent to using an
786 empty one, logically enough.  In that case, C<next> goes directly back
787 to check the condition at the top of the loop.
788
789 =item cos EXPR
790
791 =item cos
792
793 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
794 takes cosine of C<$_>.
795
796 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
797 function, or use this relation:
798
799     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
800
801 =item crypt PLAINTEXT,SALT
802
803 Encrypts a string exactly like the crypt(3) function in the C library
804 (assuming that you actually have a version there that has not been
805 extirpated as a potential munition).  This can prove useful for checking
806 the password file for lousy passwords, amongst other things.  Only the
807 guys wearing white hats should do this.
808
809 Note that C<crypt> is intended to be a one-way function, much like breaking
810 eggs to make an omelette.  There is no (known) corresponding decrypt
811 function.  As a result, this function isn't all that useful for
812 cryptography.  (For that, see your nearby CPAN mirror.)
813
814 When verifying an existing encrypted string you should use the encrypted
815 text as the salt (like C<crypt($plain, $crypted) eq $crypted>).  This
816 allows your code to work with the standard C<crypt> and with more
817 exotic implementations.  When choosing a new salt create a random two
818 character string whose characters come from the set C<[./0-9A-Za-z]>
819 (like C<join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
820
821 Here's an example that makes sure that whoever runs this program knows
822 their own password:
823
824     $pwd = (getpwuid($<))[1];
825
826     system "stty -echo";
827     print "Password: ";
828     chomp($word = <STDIN>);
829     print "\n";
830     system "stty echo";
831
832     if (crypt($word, $pwd) ne $pwd) {
833         die "Sorry...\n";
834     } else {
835         print "ok\n";
836     }
837
838 Of course, typing in your own password to whoever asks you
839 for it is unwise.
840
841 The L<crypt> function is unsuitable for encrypting large quantities
842 of data, not least of all because you can't get the information
843 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
844 on your favorite CPAN mirror for a slew of potentially useful
845 modules.
846
847 =item dbmclose HASH
848
849 [This function has been largely superseded by the C<untie> function.]
850
851 Breaks the binding between a DBM file and a hash.
852
853 =item dbmopen HASH,DBNAME,MASK
854
855 [This function has been largely superseded by the C<tie> function.]
856
857 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
858 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
859 argument is I<not> a filehandle, even though it looks like one).  DBNAME
860 is the name of the database (without the F<.dir> or F<.pag> extension if
861 any).  If the database does not exist, it is created with protection
862 specified by MASK (as modified by the C<umask>).  If your system supports
863 only the older DBM functions, you may perform only one C<dbmopen> in your
864 program.  In older versions of Perl, if your system had neither DBM nor
865 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
866 sdbm(3).
867
868 If you don't have write access to the DBM file, you can only read hash
869 variables, not set them.  If you want to test whether you can write,
870 either use file tests or try setting a dummy hash entry inside an C<eval>,
871 which will trap the error.
872
873 Note that functions such as C<keys> and C<values> may return huge lists
874 when used on large DBM files.  You may prefer to use the C<each>
875 function to iterate over large DBM files.  Example:
876
877     # print out history file offsets
878     dbmopen(%HIST,'/usr/lib/news/history',0666);
879     while (($key,$val) = each %HIST) {
880         print $key, ' = ', unpack('L',$val), "\n";
881     }
882     dbmclose(%HIST);
883
884 See also L<AnyDBM_File> for a more general description of the pros and
885 cons of the various dbm approaches, as well as L<DB_File> for a particularly
886 rich implementation.
887
888 You can control which DBM library you use by loading that library
889 before you call dbmopen():
890
891     use DB_File;
892     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
893         or die "Can't open netscape history file: $!";
894
895 =item defined EXPR
896
897 =item defined
898
899 Returns a Boolean value telling whether EXPR has a value other than
900 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
901 checked.
902
903 Many operations return C<undef> to indicate failure, end of file,
904 system error, uninitialized variable, and other exceptional
905 conditions.  This function allows you to distinguish C<undef> from
906 other values.  (A simple Boolean test will not distinguish among
907 C<undef>, zero, the empty string, and C<"0">, which are all equally
908 false.)  Note that since C<undef> is a valid scalar, its presence
909 doesn't I<necessarily> indicate an exceptional condition: C<pop>
910 returns C<undef> when its argument is an empty array, I<or> when the
911 element to return happens to be C<undef>.
912
913 You may also use C<defined(&func)> to check whether subroutine C<&func>
914 has ever been defined.  The return value is unaffected by any forward
915 declarations of C<&foo>.  Note that a subroutine which is not defined
916 may still be callable: its package may have an C<AUTOLOAD> method that
917 makes it spring into existence the first time that it is called -- see
918 L<perlsub>.
919
920 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
921 used to report whether memory for that aggregate has ever been
922 allocated.  This behavior may disappear in future versions of Perl.
923 You should instead use a simple test for size:
924
925     if (@an_array) { print "has array elements\n" }
926     if (%a_hash)   { print "has hash members\n"   }
927
928 When used on a hash element, it tells you whether the value is defined,
929 not whether the key exists in the hash.  Use L</exists> for the latter
930 purpose.
931
932 Examples:
933
934     print if defined $switch{'D'};
935     print "$val\n" while defined($val = pop(@ary));
936     die "Can't readlink $sym: $!"
937         unless defined($value = readlink $sym);
938     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
939     $debugging = 0 unless defined $debugging;
940
941 Note:  Many folks tend to overuse C<defined>, and then are surprised to
942 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
943 defined values.  For example, if you say
944
945     "ab" =~ /a(.*)b/;
946
947 The pattern match succeeds, and C<$1> is defined, despite the fact that it
948 matched "nothing".  But it didn't really match nothing--rather, it
949 matched something that happened to be zero characters long.  This is all
950 very above-board and honest.  When a function returns an undefined value,
951 it's an admission that it couldn't give you an honest answer.  So you
952 should use C<defined> only when you're questioning the integrity of what
953 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
954 what you want.
955
956 See also L</undef>, L</exists>, L</ref>.
957
958 =item delete EXPR
959
960 Given an expression that specifies a hash element, array element, hash slice,
961 or array slice, deletes the specified element(s) from the hash or array.
962 In the case of an array, if the array elements happen to be at the end,
963 the size of the array will shrink to the highest element that tests
964 true for exists() (or 0 if no such element exists).
965
966 Returns each element so deleted or the undefined value if there was no such
967 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
968 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
969 from a C<tie>d hash or array may not necessarily return anything.
970
971 Deleting an array element effectively returns that position of the array
972 to its initial, uninitialized state.  Subsequently testing for the same
973 element with exists() will return false.  Note that deleting array
974 elements in the middle of an array will not shift the index of the ones
975 after them down--use splice() for that.  See L</exists>.
976
977 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
978
979     foreach $key (keys %HASH) {
980         delete $HASH{$key};
981     }
982
983     foreach $index (0 .. $#ARRAY) {
984         delete $ARRAY[$index];
985     }
986
987 And so do these:
988
989     delete @HASH{keys %HASH};
990
991     delete @ARRAY[0 .. $#ARRAY];
992
993 But both of these are slower than just assigning the empty list
994 or undefining %HASH or @ARRAY:
995
996     %HASH = ();         # completely empty %HASH
997     undef %HASH;        # forget %HASH ever existed
998
999     @ARRAY = ();        # completely empty @ARRAY
1000     undef @ARRAY;       # forget @ARRAY ever existed
1001
1002 Note that the EXPR can be arbitrarily complicated as long as the final
1003 operation is a hash element, array element,  hash slice, or array slice
1004 lookup:
1005
1006     delete $ref->[$x][$y]{$key};
1007     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1008
1009     delete $ref->[$x][$y][$index];
1010     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1011
1012 =item die LIST
1013
1014 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1015 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1016 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1017 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1018 an C<eval(),> the error message is stuffed into C<$@> and the
1019 C<eval> is terminated with the undefined value.  This makes
1020 C<die> the way to raise an exception.
1021
1022 Equivalent examples:
1023
1024     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1025     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1026
1027 If the value of EXPR does not end in a newline, the current script line
1028 number and input line number (if any) are also printed, and a newline
1029 is supplied.  Note that the "input line number" (also known as "chunk")
1030 is subject to whatever notion of "line" happens to be currently in
1031 effect, and is also available as the special variable C<$.>.
1032 See L<perlvar/"$/"> and L<perlvar/"$.">.
1033
1034 Hint: sometimes appending C<", stopped"> to your message
1035 will cause it to make better sense when the string C<"at foo line 123"> is
1036 appended.  Suppose you are running script "canasta".
1037
1038     die "/etc/games is no good";
1039     die "/etc/games is no good, stopped";
1040
1041 produce, respectively
1042
1043     /etc/games is no good at canasta line 123.
1044     /etc/games is no good, stopped at canasta line 123.
1045
1046 See also exit(), warn(), and the Carp module.
1047
1048 If LIST is empty and C<$@> already contains a value (typically from a
1049 previous eval) that value is reused after appending C<"\t...propagated">.
1050 This is useful for propagating exceptions:
1051
1052     eval { ... };
1053     die unless $@ =~ /Expected exception/;
1054
1055 If C<$@> is empty then the string C<"Died"> is used.
1056
1057 die() can also be called with a reference argument.  If this happens to be
1058 trapped within an eval(), $@ contains the reference.  This behavior permits
1059 a more elaborate exception handling implementation using objects that
1060 maintain arbitrary state about the nature of the exception.  Such a scheme
1061 is sometimes preferable to matching particular string values of $@ using
1062 regular expressions.  Here's an example:
1063
1064     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1065     if ($@) {
1066         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1067             # handle Some::Module::Exception
1068         }
1069         else {
1070             # handle all other possible exceptions
1071         }
1072     }
1073
1074 Because perl will stringify uncaught exception messages before displaying
1075 them, you may want to overload stringification operations on such custom
1076 exception objects.  See L<overload> for details about that.
1077
1078 You can arrange for a callback to be run just before the C<die>
1079 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1080 handler will be called with the error text and can change the error
1081 message, if it sees fit, by calling C<die> again.  See
1082 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1083 L<"eval BLOCK"> for some examples.  Although this feature was meant
1084 to be run only right before your program was to exit, this is not
1085 currently the case--the C<$SIG{__DIE__}> hook is currently called
1086 even inside eval()ed blocks/strings!  If one wants the hook to do
1087 nothing in such situations, put
1088
1089         die @_ if $^S;
1090
1091 as the first line of the handler (see L<perlvar/$^S>).  Because
1092 this promotes strange action at a distance, this counterintuitive
1093 behavior may be fixed in a future release.
1094
1095 =item do BLOCK
1096
1097 Not really a function.  Returns the value of the last command in the
1098 sequence of commands indicated by BLOCK.  When modified by a loop
1099 modifier, executes the BLOCK once before testing the loop condition.
1100 (On other statements the loop modifiers test the conditional first.)
1101
1102 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1103 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1104 See L<perlsyn> for alternative strategies.
1105
1106 =item do SUBROUTINE(LIST)
1107
1108 A deprecated form of subroutine call.  See L<perlsub>.
1109
1110 =item do EXPR
1111
1112 Uses the value of EXPR as a filename and executes the contents of the
1113 file as a Perl script.  Its primary use is to include subroutines
1114 from a Perl subroutine library.
1115
1116     do 'stat.pl';
1117
1118 is just like
1119
1120     eval `cat stat.pl`;
1121
1122 except that it's more efficient and concise, keeps track of the current
1123 filename for error messages, searches the @INC libraries, and updates
1124 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1125 variables.  It also differs in that code evaluated with C<do FILENAME>
1126 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1127 same, however, in that it does reparse the file every time you call it,
1128 so you probably don't want to do this inside a loop.
1129
1130 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1131 error.  If C<do> can read the file but cannot compile it, it
1132 returns undef and sets an error message in C<$@>.   If the file is
1133 successfully compiled, C<do> returns the value of the last expression
1134 evaluated.
1135
1136 Note that inclusion of library modules is better done with the
1137 C<use> and C<require> operators, which also do automatic error checking
1138 and raise an exception if there's a problem.
1139
1140 You might like to use C<do> to read in a program configuration
1141 file.  Manual error checking can be done this way:
1142
1143     # read in config files: system first, then user
1144     for $file ("/share/prog/defaults.rc",
1145                "$ENV{HOME}/.someprogrc")
1146    {
1147         unless ($return = do $file) {
1148             warn "couldn't parse $file: $@" if $@;
1149             warn "couldn't do $file: $!"    unless defined $return;
1150             warn "couldn't run $file"       unless $return;
1151         }
1152     }
1153
1154 =item dump LABEL
1155
1156 =item dump
1157
1158 This function causes an immediate core dump.  See also the B<-u>
1159 command-line switch in L<perlrun>, which does the same thing.
1160 Primarily this is so that you can use the B<undump> program (not
1161 supplied) to turn your core dump into an executable binary after
1162 having initialized all your variables at the beginning of the
1163 program.  When the new binary is executed it will begin by executing
1164 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1165 Think of it as a goto with an intervening core dump and reincarnation.
1166 If C<LABEL> is omitted, restarts the program from the top.
1167
1168 B<WARNING>: Any files opened at the time of the dump will I<not>
1169 be open any more when the program is reincarnated, with possible
1170 resulting confusion on the part of Perl.
1171
1172 This function is now largely obsolete, partly because it's very
1173 hard to convert a core file into an executable, and because the
1174 real compiler backends for generating portable bytecode and compilable
1175 C code have superseded it.
1176
1177 If you're looking to use L<dump> to speed up your program, consider
1178 generating bytecode or native C code as described in L<perlcc>.  If
1179 you're just trying to accelerate a CGI script, consider using the
1180 C<mod_perl> extension to B<Apache>, or the CPAN module, Fast::CGI.
1181 You might also consider autoloading or selfloading, which at least
1182 make your program I<appear> to run faster.
1183
1184 =item each HASH
1185
1186 When called in list context, returns a 2-element list consisting of the
1187 key and value for the next element of a hash, so that you can iterate over
1188 it.  When called in scalar context, returns only the key for the next
1189 element in the hash.
1190
1191 Entries are returned in an apparently random order.  The actual random
1192 order is subject to change in future versions of perl, but it is guaranteed
1193 to be in the same order as either the C<keys> or C<values> function
1194 would produce on the same (unmodified) hash.
1195
1196 When the hash is entirely read, a null array is returned in list context
1197 (which when assigned produces a false (C<0>) value), and C<undef> in
1198 scalar context.  The next call to C<each> after that will start iterating
1199 again.  There is a single iterator for each hash, shared by all C<each>,
1200 C<keys>, and C<values> function calls in the program; it can be reset by
1201 reading all the elements from the hash, or by evaluating C<keys HASH> or
1202 C<values HASH>.  If you add or delete elements of a hash while you're
1203 iterating over it, you may get entries skipped or duplicated, so
1204 don't.  Exception: It is always safe to delete the item most recently
1205 returned by C<each()>, which means that the following code will work:
1206
1207         while (($key, $value) = each %hash) {
1208           print $key, "\n";
1209           delete $hash{$key};   # This is safe
1210         }
1211
1212 The following prints out your environment like the printenv(1) program,
1213 only in a different order:
1214
1215     while (($key,$value) = each %ENV) {
1216         print "$key=$value\n";
1217     }
1218
1219 See also C<keys>, C<values> and C<sort>.
1220
1221 =item eof FILEHANDLE
1222
1223 =item eof ()
1224
1225 =item eof
1226
1227 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1228 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1229 gives the real filehandle.  (Note that this function actually
1230 reads a character and then C<ungetc>s it, so isn't very useful in an
1231 interactive context.)  Do not read from a terminal file (or call
1232 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1233 as terminals may lose the end-of-file condition if you do.
1234
1235 An C<eof> without an argument uses the last file read.  Using C<eof()>
1236 with empty parentheses is very different.  It refers to the pseudo file
1237 formed from the files listed on the command line and accessed via the
1238 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1239 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1240 used will cause C<@ARGV> to be examined to determine if input is
1241 available.
1242
1243 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1244 detect the end of each file, C<eof()> will only detect the end of the
1245 last file.  Examples:
1246
1247     # reset line numbering on each input file
1248     while (<>) {
1249         next if /^\s*#/;        # skip comments
1250         print "$.\t$_";
1251     } continue {
1252         close ARGV  if eof;     # Not eof()!
1253     }
1254
1255     # insert dashes just before last line of last file
1256     while (<>) {
1257         if (eof()) {            # check for end of current file
1258             print "--------------\n";
1259             close(ARGV);        # close or last; is needed if we
1260                                 # are reading from the terminal
1261         }
1262         print;
1263     }
1264
1265 Practical hint: you almost never need to use C<eof> in Perl, because the
1266 input operators typically return C<undef> when they run out of data, or if
1267 there was an error.
1268
1269 =item eval EXPR
1270
1271 =item eval BLOCK
1272
1273 In the first form, the return value of EXPR is parsed and executed as if it
1274 were a little Perl program.  The value of the expression (which is itself
1275 determined within scalar context) is first parsed, and if there weren't any
1276 errors, executed in the lexical context of the current Perl program, so
1277 that any variable settings or subroutine and format definitions remain
1278 afterwards.  Note that the value is parsed every time the eval executes.
1279 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1280 delay parsing and subsequent execution of the text of EXPR until run time.
1281
1282 In the second form, the code within the BLOCK is parsed only once--at the
1283 same time the code surrounding the eval itself was parsed--and executed
1284 within the context of the current Perl program.  This form is typically
1285 used to trap exceptions more efficiently than the first (see below), while
1286 also providing the benefit of checking the code within BLOCK at compile
1287 time.
1288
1289 The final semicolon, if any, may be omitted from the value of EXPR or within
1290 the BLOCK.
1291
1292 In both forms, the value returned is the value of the last expression
1293 evaluated inside the mini-program; a return statement may be also used, just
1294 as with subroutines.  The expression providing the return value is evaluated
1295 in void, scalar, or list context, depending on the context of the eval itself.
1296 See L</wantarray> for more on how the evaluation context can be determined.
1297
1298 If there is a syntax error or runtime error, or a C<die> statement is
1299 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1300 error message.  If there was no error, C<$@> is guaranteed to be a null
1301 string.  Beware that using C<eval> neither silences perl from printing
1302 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1303 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1304 L</warn> and L<perlvar>.
1305
1306 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1307 determining whether a particular feature (such as C<socket> or C<symlink>)
1308 is implemented.  It is also Perl's exception trapping mechanism, where
1309 the die operator is used to raise exceptions.
1310
1311 If the code to be executed doesn't vary, you may use the eval-BLOCK
1312 form to trap run-time errors without incurring the penalty of
1313 recompiling each time.  The error, if any, is still returned in C<$@>.
1314 Examples:
1315
1316     # make divide-by-zero nonfatal
1317     eval { $answer = $a / $b; }; warn $@ if $@;
1318
1319     # same thing, but less efficient
1320     eval '$answer = $a / $b'; warn $@ if $@;
1321
1322     # a compile-time error
1323     eval { $answer = };                 # WRONG
1324
1325     # a run-time error
1326     eval '$answer =';   # sets $@
1327
1328 Due to the current arguably broken state of C<__DIE__> hooks, when using
1329 the C<eval{}> form as an exception trap in libraries, you may wish not
1330 to trigger any C<__DIE__> hooks that user code may have installed.
1331 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1332 as shown in this example:
1333
1334     # a very private exception trap for divide-by-zero
1335     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1336     warn $@ if $@;
1337
1338 This is especially significant, given that C<__DIE__> hooks can call
1339 C<die> again, which has the effect of changing their error messages:
1340
1341     # __DIE__ hooks may modify error messages
1342     {
1343        local $SIG{'__DIE__'} =
1344               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1345        eval { die "foo lives here" };
1346        print $@ if $@;                # prints "bar lives here"
1347     }
1348
1349 Because this promotes action at a distance, this counterintuitive behavior
1350 may be fixed in a future release.
1351
1352 With an C<eval>, you should be especially careful to remember what's
1353 being looked at when:
1354
1355     eval $x;            # CASE 1
1356     eval "$x";          # CASE 2
1357
1358     eval '$x';          # CASE 3
1359     eval { $x };        # CASE 4
1360
1361     eval "\$$x++";      # CASE 5
1362     $$x++;              # CASE 6
1363
1364 Cases 1 and 2 above behave identically: they run the code contained in
1365 the variable $x.  (Although case 2 has misleading double quotes making
1366 the reader wonder what else might be happening (nothing is).)  Cases 3
1367 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1368 does nothing but return the value of $x.  (Case 4 is preferred for
1369 purely visual reasons, but it also has the advantage of compiling at
1370 compile-time instead of at run-time.)  Case 5 is a place where
1371 normally you I<would> like to use double quotes, except that in this
1372 particular situation, you can just use symbolic references instead, as
1373 in case 6.
1374
1375 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1376 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1377
1378 =item exec LIST
1379
1380 =item exec PROGRAM LIST
1381
1382 The C<exec> function executes a system command I<and never returns>--
1383 use C<system> instead of C<exec> if you want it to return.  It fails and
1384 returns false only if the command does not exist I<and> it is executed
1385 directly instead of via your system's command shell (see below).
1386
1387 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1388 warns you if there is a following statement which isn't C<die>, C<warn>,
1389 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1390 I<really> want to follow an C<exec> with some other statement, you
1391 can use one of these styles to avoid the warning:
1392
1393     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1394     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1395
1396 If there is more than one argument in LIST, or if LIST is an array
1397 with more than one value, calls execvp(3) with the arguments in LIST.
1398 If there is only one scalar argument or an array with one element in it,
1399 the argument is checked for shell metacharacters, and if there are any,
1400 the entire argument is passed to the system's command shell for parsing
1401 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1402 If there are no shell metacharacters in the argument, it is split into
1403 words and passed directly to C<execvp>, which is more efficient.
1404 Examples:
1405
1406     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1407     exec "sort $outfile | uniq";
1408
1409 If you don't really want to execute the first argument, but want to lie
1410 to the program you are executing about its own name, you can specify
1411 the program you actually want to run as an "indirect object" (without a
1412 comma) in front of the LIST.  (This always forces interpretation of the
1413 LIST as a multivalued list, even if there is only a single scalar in
1414 the list.)  Example:
1415
1416     $shell = '/bin/csh';
1417     exec $shell '-sh';          # pretend it's a login shell
1418
1419 or, more directly,
1420
1421     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1422
1423 When the arguments get executed via the system shell, results will
1424 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1425 for details.
1426
1427 Using an indirect object with C<exec> or C<system> is also more
1428 secure.  This usage (which also works fine with system()) forces
1429 interpretation of the arguments as a multivalued list, even if the
1430 list had just one argument.  That way you're safe from the shell
1431 expanding wildcards or splitting up words with whitespace in them.
1432
1433     @args = ( "echo surprise" );
1434
1435     exec @args;               # subject to shell escapes
1436                                 # if @args == 1
1437     exec { $args[0] } @args;  # safe even with one-arg list
1438
1439 The first version, the one without the indirect object, ran the I<echo>
1440 program, passing it C<"surprise"> an argument.  The second version
1441 didn't--it tried to run a program literally called I<"echo surprise">,
1442 didn't find it, and set C<$?> to a non-zero value indicating failure.
1443
1444 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1445 output before the exec, but this may not be supported on some platforms
1446 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1447 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1448 open handles in order to avoid lost output.
1449
1450 Note that C<exec> will not call your C<END> blocks, nor will it call
1451 any C<DESTROY> methods in your objects.
1452
1453 =item exists EXPR
1454
1455 Given an expression that specifies a hash element or array element,
1456 returns true if the specified element in the hash or array has ever
1457 been initialized, even if the corresponding value is undefined.  The
1458 element is not autovivified if it doesn't exist.
1459
1460     print "Exists\n"    if exists $hash{$key};
1461     print "Defined\n"   if defined $hash{$key};
1462     print "True\n"      if $hash{$key};
1463
1464     print "Exists\n"    if exists $array[$index];
1465     print "Defined\n"   if defined $array[$index];
1466     print "True\n"      if $array[$index];
1467
1468 A hash or array element can be true only if it's defined, and defined if
1469 it exists, but the reverse doesn't necessarily hold true.
1470
1471 Given an expression that specifies the name of a subroutine,
1472 returns true if the specified subroutine has ever been declared, even
1473 if it is undefined.  Mentioning a subroutine name for exists or defined
1474 does not count as declaring it.  Note that a subroutine which does not
1475 exist may still be callable: its package may have an C<AUTOLOAD>
1476 method that makes it spring into existence the first time that it is
1477 called -- see L<perlsub>.
1478
1479     print "Exists\n"    if exists &subroutine;
1480     print "Defined\n"   if defined &subroutine;
1481
1482 Note that the EXPR can be arbitrarily complicated as long as the final
1483 operation is a hash or array key lookup or subroutine name:
1484
1485     if (exists $ref->{A}->{B}->{$key})  { }
1486     if (exists $hash{A}{B}{$key})       { }
1487
1488     if (exists $ref->{A}->{B}->[$ix])   { }
1489     if (exists $hash{A}{B}[$ix])        { }
1490
1491     if (exists &{$ref->{A}{B}{$key}})   { }
1492
1493 Although the deepest nested array or hash will not spring into existence
1494 just because its existence was tested, any intervening ones will.
1495 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1496 into existence due to the existence test for the $key element above.
1497 This happens anywhere the arrow operator is used, including even:
1498
1499     undef $ref;
1500     if (exists $ref->{"Some key"})      { }
1501     print $ref;             # prints HASH(0x80d3d5c)
1502
1503 This surprising autovivification in what does not at first--or even
1504 second--glance appear to be an lvalue context may be fixed in a future
1505 release.
1506
1507 See L<perlref/"Pseudo-hashes: Using an array as a hash"> for specifics
1508 on how exists() acts when used on a pseudo-hash.
1509
1510 Use of a subroutine call, rather than a subroutine name, as an argument
1511 to exists() is an error.
1512
1513     exists &sub;        # OK
1514     exists &sub();      # Error
1515
1516 =item exit EXPR
1517
1518 Evaluates EXPR and exits immediately with that value.    Example:
1519
1520     $ans = <STDIN>;
1521     exit 0 if $ans =~ /^[Xx]/;
1522
1523 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1524 universally recognized values for EXPR are C<0> for success and C<1>
1525 for error; other values are subject to interpretation depending on the
1526 environment in which the Perl program is running.  For example, exiting
1527 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1528 the mailer to return the item undelivered, but that's not true everywhere.
1529
1530 Don't use C<exit> to abort a subroutine if there's any chance that
1531 someone might want to trap whatever error happened.  Use C<die> instead,
1532 which can be trapped by an C<eval>.
1533
1534 The exit() function does not always exit immediately.  It calls any
1535 defined C<END> routines first, but these C<END> routines may not
1536 themselves abort the exit.  Likewise any object destructors that need to
1537 be called are called before the real exit.  If this is a problem, you
1538 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1539 See L<perlmod> for details.
1540
1541 =item exp EXPR
1542
1543 =item exp
1544
1545 Returns I<e> (the natural logarithm base) to the power of EXPR.
1546 If EXPR is omitted, gives C<exp($_)>.
1547
1548 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1549
1550 Implements the fcntl(2) function.  You'll probably have to say
1551
1552     use Fcntl;
1553
1554 first to get the correct constant definitions.  Argument processing and
1555 value return works just like C<ioctl> below.
1556 For example:
1557
1558     use Fcntl;
1559     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1560         or die "can't fcntl F_GETFL: $!";
1561
1562 You don't have to check for C<defined> on the return from C<fnctl>.
1563 Like C<ioctl>, it maps a C<0> return from the system call into
1564 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1565 in numeric context.  It is also exempt from the normal B<-w> warnings
1566 on improper numeric conversions.
1567
1568 Note that C<fcntl> will produce a fatal error if used on a machine that
1569 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1570 manpage to learn what functions are available on your system.
1571
1572 =item fileno FILEHANDLE
1573
1574 Returns the file descriptor for a filehandle, or undefined if the
1575 filehandle is not open.  This is mainly useful for constructing
1576 bitmaps for C<select> and low-level POSIX tty-handling operations.
1577 If FILEHANDLE is an expression, the value is taken as an indirect
1578 filehandle, generally its name.
1579
1580 You can use this to find out whether two handles refer to the
1581 same underlying descriptor:
1582
1583     if (fileno(THIS) == fileno(THAT)) {
1584         print "THIS and THAT are dups\n";
1585     }
1586
1587 (Filehandles connected to memory objects via new features of C<open> may
1588 return undefined even though they are open.)
1589
1590
1591 =item flock FILEHANDLE,OPERATION
1592
1593 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1594 for success, false on failure.  Produces a fatal error if used on a
1595 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1596 C<flock> is Perl's portable file locking interface, although it locks
1597 only entire files, not records.
1598
1599 Two potentially non-obvious but traditional C<flock> semantics are
1600 that it waits indefinitely until the lock is granted, and that its locks
1601 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1602 fewer guarantees.  This means that files locked with C<flock> may be
1603 modified by programs that do not also use C<flock>.  See L<perlport>,
1604 your port's specific documentation, or your system-specific local manpages
1605 for details.  It's best to assume traditional behavior if you're writing
1606 portable programs.  (But if you're not, you should as always feel perfectly
1607 free to write for your own system's idiosyncrasies (sometimes called
1608 "features").  Slavish adherence to portability concerns shouldn't get
1609 in the way of your getting your job done.)
1610
1611 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1612 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1613 you can use the symbolic names if you import them from the Fcntl module,
1614 either individually, or as a group using the ':flock' tag.  LOCK_SH
1615 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1616 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1617 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1618 waiting for the lock (check the return status to see if you got it).
1619
1620 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1621 before locking or unlocking it.
1622
1623 Note that the emulation built with lockf(3) doesn't provide shared
1624 locks, and it requires that FILEHANDLE be open with write intent.  These
1625 are the semantics that lockf(3) implements.  Most if not all systems
1626 implement lockf(3) in terms of fcntl(2) locking, though, so the
1627 differing semantics shouldn't bite too many people.
1628
1629 Note also that some versions of C<flock> cannot lock things over the
1630 network; you would need to use the more system-specific C<fcntl> for
1631 that.  If you like you can force Perl to ignore your system's flock(2)
1632 function, and so provide its own fcntl(2)-based emulation, by passing
1633 the switch C<-Ud_flock> to the F<Configure> program when you configure
1634 perl.
1635
1636 Here's a mailbox appender for BSD systems.
1637
1638     use Fcntl ':flock'; # import LOCK_* constants
1639
1640     sub lock {
1641         flock(MBOX,LOCK_EX);
1642         # and, in case someone appended
1643         # while we were waiting...
1644         seek(MBOX, 0, 2);
1645     }
1646
1647     sub unlock {
1648         flock(MBOX,LOCK_UN);
1649     }
1650
1651     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1652             or die "Can't open mailbox: $!";
1653
1654     lock();
1655     print MBOX $msg,"\n\n";
1656     unlock();
1657
1658 On systems that support a real flock(), locks are inherited across fork()
1659 calls, whereas those that must resort to the more capricious fcntl()
1660 function lose the locks, making it harder to write servers.
1661
1662 See also L<DB_File> for other flock() examples.
1663
1664 =item fork
1665
1666 Does a fork(2) system call to create a new process running the
1667 same program at the same point.  It returns the child pid to the
1668 parent process, C<0> to the child process, or C<undef> if the fork is
1669 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1670 are shared, while everything else is copied.  On most systems supporting
1671 fork(), great care has gone into making it extremely efficient (for
1672 example, using copy-on-write technology on data pages), making it the
1673 dominant paradigm for multitasking over the last few decades.
1674
1675 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1676 output before forking the child process, but this may not be supported
1677 on some platforms (see L<perlport>).  To be safe, you may need to set
1678 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1679 C<IO::Handle> on any open handles in order to avoid duplicate output.
1680
1681 If you C<fork> without ever waiting on your children, you will
1682 accumulate zombies.  On some systems, you can avoid this by setting
1683 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1684 forking and reaping moribund children.
1685
1686 Note that if your forked child inherits system file descriptors like
1687 STDIN and STDOUT that are actually connected by a pipe or socket, even
1688 if you exit, then the remote server (such as, say, a CGI script or a
1689 backgrounded job launched from a remote shell) won't think you're done.
1690 You should reopen those to F</dev/null> if it's any issue.
1691
1692 =item format
1693
1694 Declare a picture format for use by the C<write> function.  For
1695 example:
1696
1697     format Something =
1698         Test: @<<<<<<<< @||||| @>>>>>
1699               $str,     $%,    '$' . int($num)
1700     .
1701
1702     $str = "widget";
1703     $num = $cost/$quantity;
1704     $~ = 'Something';
1705     write;
1706
1707 See L<perlform> for many details and examples.
1708
1709 =item formline PICTURE,LIST
1710
1711 This is an internal function used by C<format>s, though you may call it,
1712 too.  It formats (see L<perlform>) a list of values according to the
1713 contents of PICTURE, placing the output into the format output
1714 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1715 Eventually, when a C<write> is done, the contents of
1716 C<$^A> are written to some filehandle, but you could also read C<$^A>
1717 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1718 does one C<formline> per line of form, but the C<formline> function itself
1719 doesn't care how many newlines are embedded in the PICTURE.  This means
1720 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1721 You may therefore need to use multiple formlines to implement a single
1722 record format, just like the format compiler.
1723
1724 Be careful if you put double quotes around the picture, because an C<@>
1725 character may be taken to mean the beginning of an array name.
1726 C<formline> always returns true.  See L<perlform> for other examples.
1727
1728 =item getc FILEHANDLE
1729
1730 =item getc
1731
1732 Returns the next character from the input file attached to FILEHANDLE,
1733 or the undefined value at end of file, or if there was an error.
1734 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1735 efficient.  However, it cannot be used by itself to fetch single
1736 characters without waiting for the user to hit enter.  For that, try
1737 something more like:
1738
1739     if ($BSD_STYLE) {
1740         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1741     }
1742     else {
1743         system "stty", '-icanon', 'eol', "\001";
1744     }
1745
1746     $key = getc(STDIN);
1747
1748     if ($BSD_STYLE) {
1749         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1750     }
1751     else {
1752         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1753     }
1754     print "\n";
1755
1756 Determination of whether $BSD_STYLE should be set
1757 is left as an exercise to the reader.
1758
1759 The C<POSIX::getattr> function can do this more portably on
1760 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1761 module from your nearest CPAN site; details on CPAN can be found on
1762 L<perlmodlib/CPAN>.
1763
1764 =item getlogin
1765
1766 Implements the C library function of the same name, which on most
1767 systems returns the current login from F</etc/utmp>, if any.  If null,
1768 use C<getpwuid>.
1769
1770     $login = getlogin || getpwuid($<) || "Kilroy";
1771
1772 Do not consider C<getlogin> for authentication: it is not as
1773 secure as C<getpwuid>.
1774
1775 =item getpeername SOCKET
1776
1777 Returns the packed sockaddr address of other end of the SOCKET connection.
1778
1779     use Socket;
1780     $hersockaddr    = getpeername(SOCK);
1781     ($port, $iaddr) = sockaddr_in($hersockaddr);
1782     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1783     $herstraddr     = inet_ntoa($iaddr);
1784
1785 =item getpgrp PID
1786
1787 Returns the current process group for the specified PID.  Use
1788 a PID of C<0> to get the current process group for the
1789 current process.  Will raise an exception if used on a machine that
1790 doesn't implement getpgrp(2).  If PID is omitted, returns process
1791 group of current process.  Note that the POSIX version of C<getpgrp>
1792 does not accept a PID argument, so only C<PID==0> is truly portable.
1793
1794 =item getppid
1795
1796 Returns the process id of the parent process.
1797
1798 =item getpriority WHICH,WHO
1799
1800 Returns the current priority for a process, a process group, or a user.
1801 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1802 machine that doesn't implement getpriority(2).
1803
1804 =item getpwnam NAME
1805
1806 =item getgrnam NAME
1807
1808 =item gethostbyname NAME
1809
1810 =item getnetbyname NAME
1811
1812 =item getprotobyname NAME
1813
1814 =item getpwuid UID
1815
1816 =item getgrgid GID
1817
1818 =item getservbyname NAME,PROTO
1819
1820 =item gethostbyaddr ADDR,ADDRTYPE
1821
1822 =item getnetbyaddr ADDR,ADDRTYPE
1823
1824 =item getprotobynumber NUMBER
1825
1826 =item getservbyport PORT,PROTO
1827
1828 =item getpwent
1829
1830 =item getgrent
1831
1832 =item gethostent
1833
1834 =item getnetent
1835
1836 =item getprotoent
1837
1838 =item getservent
1839
1840 =item setpwent
1841
1842 =item setgrent
1843
1844 =item sethostent STAYOPEN
1845
1846 =item setnetent STAYOPEN
1847
1848 =item setprotoent STAYOPEN
1849
1850 =item setservent STAYOPEN
1851
1852 =item endpwent
1853
1854 =item endgrent
1855
1856 =item endhostent
1857
1858 =item endnetent
1859
1860 =item endprotoent
1861
1862 =item endservent
1863
1864 These routines perform the same functions as their counterparts in the
1865 system library.  In list context, the return values from the
1866 various get routines are as follows:
1867
1868     ($name,$passwd,$uid,$gid,
1869        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1870     ($name,$passwd,$gid,$members) = getgr*
1871     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1872     ($name,$aliases,$addrtype,$net) = getnet*
1873     ($name,$aliases,$proto) = getproto*
1874     ($name,$aliases,$port,$proto) = getserv*
1875
1876 (If the entry doesn't exist you get a null list.)
1877
1878 The exact meaning of the $gcos field varies but it usually contains
1879 the real name of the user (as opposed to the login name) and other
1880 information pertaining to the user.  Beware, however, that in many
1881 system users are able to change this information and therefore it
1882 cannot be trusted and therefore the $gcos is tainted (see
1883 L<perlsec>).  The $passwd and $shell, user's encrypted password and
1884 login shell, are also tainted, because of the same reason.
1885
1886 In scalar context, you get the name, unless the function was a
1887 lookup by name, in which case you get the other thing, whatever it is.
1888 (If the entry doesn't exist you get the undefined value.)  For example:
1889
1890     $uid   = getpwnam($name);
1891     $name  = getpwuid($num);
1892     $name  = getpwent();
1893     $gid   = getgrnam($name);
1894     $name  = getgrgid($num;
1895     $name  = getgrent();
1896     #etc.
1897
1898 In I<getpw*()> the fields $quota, $comment, and $expire are special
1899 cases in the sense that in many systems they are unsupported.  If the
1900 $quota is unsupported, it is an empty scalar.  If it is supported, it
1901 usually encodes the disk quota.  If the $comment field is unsupported,
1902 it is an empty scalar.  If it is supported it usually encodes some
1903 administrative comment about the user.  In some systems the $quota
1904 field may be $change or $age, fields that have to do with password
1905 aging.  In some systems the $comment field may be $class.  The $expire
1906 field, if present, encodes the expiration period of the account or the
1907 password.  For the availability and the exact meaning of these fields
1908 in your system, please consult your getpwnam(3) documentation and your
1909 F<pwd.h> file.  You can also find out from within Perl what your
1910 $quota and $comment fields mean and whether you have the $expire field
1911 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1912 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
1913 files are only supported if your vendor has implemented them in the
1914 intuitive fashion that calling the regular C library routines gets the
1915 shadow versions if you're running under privilege or if there exists
1916 the shadow(3) functions as found in System V ( this includes Solaris
1917 and Linux.)  Those systems which implement a proprietary shadow password
1918 facility are unlikely to be supported.
1919
1920 The $members value returned by I<getgr*()> is a space separated list of
1921 the login names of the members of the group.
1922
1923 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1924 C, it will be returned to you via C<$?> if the function call fails.  The
1925 C<@addrs> value returned by a successful call is a list of the raw
1926 addresses returned by the corresponding system library call.  In the
1927 Internet domain, each address is four bytes long and you can unpack it
1928 by saying something like:
1929
1930     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1931
1932 The Socket library makes this slightly easier:
1933
1934     use Socket;
1935     $iaddr = inet_aton("127.1"); # or whatever address
1936     $name  = gethostbyaddr($iaddr, AF_INET);
1937
1938     # or going the other way
1939     $straddr = inet_ntoa($iaddr);
1940
1941 If you get tired of remembering which element of the return list
1942 contains which return value, by-name interfaces are provided
1943 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1944 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1945 and C<User::grent>.  These override the normal built-ins, supplying
1946 versions that return objects with the appropriate names
1947 for each field.  For example:
1948
1949    use File::stat;
1950    use User::pwent;
1951    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1952
1953 Even though it looks like they're the same method calls (uid),
1954 they aren't, because a C<File::stat> object is different from
1955 a C<User::pwent> object.
1956
1957 =item getsockname SOCKET
1958
1959 Returns the packed sockaddr address of this end of the SOCKET connection,
1960 in case you don't know the address because you have several different
1961 IPs that the connection might have come in on.
1962
1963     use Socket;
1964     $mysockaddr = getsockname(SOCK);
1965     ($port, $myaddr) = sockaddr_in($mysockaddr);
1966     printf "Connect to %s [%s]\n",
1967        scalar gethostbyaddr($myaddr, AF_INET),
1968        inet_ntoa($myaddr);
1969
1970 =item getsockopt SOCKET,LEVEL,OPTNAME
1971
1972 Returns the socket option requested, or undef if there is an error.
1973
1974 =item glob EXPR
1975
1976 =item glob
1977
1978 Returns the value of EXPR with filename expansions such as the
1979 standard Unix shell F</bin/csh> would do.  This is the internal function
1980 implementing the C<< <*.c> >> operator, but you can use it directly.
1981 If EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is
1982 discussed in more detail in L<perlop/"I/O Operators">.
1983
1984 Beginning with v5.6.0, this operator is implemented using the standard
1985 C<File::Glob> extension.  See L<File::Glob> for details.
1986
1987 =item gmtime EXPR
1988
1989 Converts a time as returned by the time function to a 8-element list
1990 with the time localized for the standard Greenwich time zone.
1991 Typically used as follows:
1992
1993     #  0    1    2     3     4    5     6     7
1994     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
1995                                             gmtime(time);
1996
1997 All list elements are numeric, and come straight out of the C `struct
1998 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
1999 specified time.  $mday is the day of the month, and $mon is the month
2000 itself, in the range C<0..11> with 0 indicating January and 11
2001 indicating December.  $year is the number of years since 1900.  That
2002 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2003 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2004 the year, in the range C<0..364> (or C<0..365> in leap years.)
2005
2006 Note that the $year element is I<not> simply the last two digits of
2007 the year.  If you assume it is, then you create non-Y2K-compliant
2008 programs--and you wouldn't want to do that, would you?
2009
2010 The proper way to get a complete 4-digit year is simply:
2011
2012         $year += 1900;
2013
2014 And to get the last two digits of the year (e.g., '01' in 2001) do:
2015
2016         $year = sprintf("%02d", $year % 100);
2017
2018 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2019
2020 In scalar context, C<gmtime()> returns the ctime(3) value:
2021
2022     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2023
2024 Also see the C<timegm> function provided by the C<Time::Local> module,
2025 and the strftime(3) function available via the POSIX module.
2026
2027 This scalar value is B<not> locale dependent (see L<perllocale>), but
2028 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2029 strftime(3) and mktime(3) functions available via the POSIX module.  To
2030 get somewhat similar but locale dependent date strings, set up your
2031 locale environment variables appropriately (please see L<perllocale>)
2032 and try for example:
2033
2034     use POSIX qw(strftime);
2035     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2036
2037 Note that the C<%a> and C<%b> escapes, which represent the short forms
2038 of the day of the week and the month of the year, may not necessarily
2039 be three characters wide in all locales.
2040
2041 =item goto LABEL
2042
2043 =item goto EXPR
2044
2045 =item goto &NAME
2046
2047 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2048 execution there.  It may not be used to go into any construct that
2049 requires initialization, such as a subroutine or a C<foreach> loop.  It
2050 also can't be used to go into a construct that is optimized away,
2051 or to get out of a block or subroutine given to C<sort>.
2052 It can be used to go almost anywhere else within the dynamic scope,
2053 including out of subroutines, but it's usually better to use some other
2054 construct such as C<last> or C<die>.  The author of Perl has never felt the
2055 need to use this form of C<goto> (in Perl, that is--C is another matter).
2056
2057 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2058 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2059 necessarily recommended if you're optimizing for maintainability:
2060
2061     goto ("FOO", "BAR", "GLARCH")[$i];
2062
2063 The C<goto-&NAME> form is quite different from the other forms of C<goto>.
2064 In fact, it isn't a goto in the normal sense at all, and doesn't have
2065 the stigma associated with other gotos.  Instead, it
2066 substitutes a call to the named subroutine for the currently running
2067 subroutine.  This is used by C<AUTOLOAD> subroutines that wish to load
2068 another subroutine and then pretend that the other subroutine had been
2069 called in the first place (except that any modifications to C<@_>
2070 in the current subroutine are propagated to the other subroutine.)
2071 After the C<goto>, not even C<caller> will be able to tell that this
2072 routine was called first.
2073
2074 NAME needn't be the name of a subroutine; it can be a scalar variable
2075 containing a code reference, or a block which evaluates to a code
2076 reference.
2077
2078 =item grep BLOCK LIST
2079
2080 =item grep EXPR,LIST
2081
2082 This is similar in spirit to, but not the same as, grep(1) and its
2083 relatives.  In particular, it is not limited to using regular expressions.
2084
2085 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2086 C<$_> to each element) and returns the list value consisting of those
2087 elements for which the expression evaluated to true.  In scalar
2088 context, returns the number of times the expression was true.
2089
2090     @foo = grep(!/^#/, @bar);    # weed out comments
2091
2092 or equivalently,
2093
2094     @foo = grep {!/^#/} @bar;    # weed out comments
2095
2096 Note that C<$_> is an alias to the list value, so it can be used to
2097 modify the elements of the LIST.  While this is useful and supported,
2098 it can cause bizarre results if the elements of LIST are not variables.
2099 Similarly, grep returns aliases into the original list, much as a for
2100 loop's index variable aliases the list elements.  That is, modifying an
2101 element of a list returned by grep (for example, in a C<foreach>, C<map>
2102 or another C<grep>) actually modifies the element in the original list.
2103 This is usually something to be avoided when writing clear code.
2104
2105 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2106
2107 =item hex EXPR
2108
2109 =item hex
2110
2111 Interprets EXPR as a hex string and returns the corresponding value.
2112 (To convert strings that might start with either 0, 0x, or 0b, see
2113 L</oct>.)  If EXPR is omitted, uses C<$_>.
2114
2115     print hex '0xAf'; # prints '175'
2116     print hex 'aF';   # same
2117
2118 Hex strings may only represent integers.  Strings that would cause
2119 integer overflow trigger a warning.
2120
2121 =item import
2122
2123 There is no builtin C<import> function.  It is just an ordinary
2124 method (subroutine) defined (or inherited) by modules that wish to export
2125 names to another module.  The C<use> function calls the C<import> method
2126 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2127
2128 =item index STR,SUBSTR,POSITION
2129
2130 =item index STR,SUBSTR
2131
2132 The index function searches for one string within another, but without
2133 the wildcard-like behavior of a full regular-expression pattern match.
2134 It returns the position of the first occurrence of SUBSTR in STR at
2135 or after POSITION.  If POSITION is omitted, starts searching from the
2136 beginning of the string.  The return value is based at C<0> (or whatever
2137 you've set the C<$[> variable to--but don't do that).  If the substring
2138 is not found, returns one less than the base, ordinarily C<-1>.
2139
2140 =item int EXPR
2141
2142 =item int
2143
2144 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2145 You should not use this function for rounding: one because it truncates
2146 towards C<0>, and two because machine representations of floating point
2147 numbers can sometimes produce counterintuitive results.  For example,
2148 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2149 because it's really more like -268.99999999999994315658 instead.  Usually,
2150 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2151 functions will serve you better than will int().
2152
2153 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2154
2155 Implements the ioctl(2) function.  You'll probably first have to say
2156
2157     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2158
2159 to get the correct function definitions.  If F<ioctl.ph> doesn't
2160 exist or doesn't have the correct definitions you'll have to roll your
2161 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2162 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2163 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2164 written depending on the FUNCTION--a pointer to the string value of SCALAR
2165 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2166 has no string value but does have a numeric value, that value will be
2167 passed rather than a pointer to the string value.  To guarantee this to be
2168 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2169 functions may be needed to manipulate the values of structures used by
2170 C<ioctl>.
2171
2172 The return value of C<ioctl> (and C<fcntl>) is as follows:
2173
2174         if OS returns:          then Perl returns:
2175             -1                    undefined value
2176              0                  string "0 but true"
2177         anything else               that number
2178
2179 Thus Perl returns true on success and false on failure, yet you can
2180 still easily determine the actual value returned by the operating
2181 system:
2182
2183     $retval = ioctl(...) || -1;
2184     printf "System returned %d\n", $retval;
2185
2186 The special string "C<0> but true" is exempt from B<-w> complaints
2187 about improper numeric conversions.
2188
2189 Here's an example of setting a filehandle named C<REMOTE> to be
2190 non-blocking at the system level.  You'll have to negotiate C<$|>
2191 on your own, though.
2192
2193     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2194
2195     $flags = fcntl(REMOTE, F_GETFL, 0)
2196                 or die "Can't get flags for the socket: $!\n";
2197
2198     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2199                 or die "Can't set flags for the socket: $!\n";
2200
2201 =item join EXPR,LIST
2202
2203 Joins the separate strings of LIST into a single string with fields
2204 separated by the value of EXPR, and returns that new string.  Example:
2205
2206     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2207
2208 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2209 first argument.  Compare L</split>.
2210
2211 =item keys HASH
2212
2213 Returns a list consisting of all the keys of the named hash.  (In
2214 scalar context, returns the number of keys.)  The keys are returned in
2215 an apparently random order.  The actual random order is subject to
2216 change in future versions of perl, but it is guaranteed to be the same
2217 order as either the C<values> or C<each> function produces (given
2218 that the hash has not been modified).  As a side effect, it resets
2219 HASH's iterator.
2220
2221 Here is yet another way to print your environment:
2222
2223     @keys = keys %ENV;
2224     @values = values %ENV;
2225     while (@keys) {
2226         print pop(@keys), '=', pop(@values), "\n";
2227     }
2228
2229 or how about sorted by key:
2230
2231     foreach $key (sort(keys %ENV)) {
2232         print $key, '=', $ENV{$key}, "\n";
2233     }
2234
2235 The returned values are copies of the original keys in the hash, so
2236 modifying them will not affect the original hash.  Compare L</values>.
2237
2238 To sort a hash by value, you'll need to use a C<sort> function.
2239 Here's a descending numeric sort of a hash by its values:
2240
2241     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2242         printf "%4d %s\n", $hash{$key}, $key;
2243     }
2244
2245 As an lvalue C<keys> allows you to increase the number of hash buckets
2246 allocated for the given hash.  This can gain you a measure of efficiency if
2247 you know the hash is going to get big.  (This is similar to pre-extending
2248 an array by assigning a larger number to $#array.)  If you say
2249
2250     keys %hash = 200;
2251
2252 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2253 in fact, since it rounds up to the next power of two.  These
2254 buckets will be retained even if you do C<%hash = ()>, use C<undef
2255 %hash> if you want to free the storage while C<%hash> is still in scope.
2256 You can't shrink the number of buckets allocated for the hash using
2257 C<keys> in this way (but you needn't worry about doing this by accident,
2258 as trying has no effect).
2259
2260 See also C<each>, C<values> and C<sort>.
2261
2262 =item kill SIGNAL, LIST
2263
2264 Sends a signal to a list of processes.  Returns the number of
2265 processes successfully signaled (which is not necessarily the
2266 same as the number actually killed).
2267
2268     $cnt = kill 1, $child1, $child2;
2269     kill 9, @goners;
2270
2271 If SIGNAL is zero, no signal is sent to the process.  This is a
2272 useful way to check that the process is alive and hasn't changed
2273 its UID.  See L<perlport> for notes on the portability of this
2274 construct.
2275
2276 Unlike in the shell, if SIGNAL is negative, it kills
2277 process groups instead of processes.  (On System V, a negative I<PROCESS>
2278 number will also kill process groups, but that's not portable.)  That
2279 means you usually want to use positive not negative signals.  You may also
2280 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2281
2282 =item last LABEL
2283
2284 =item last
2285
2286 The C<last> command is like the C<break> statement in C (as used in
2287 loops); it immediately exits the loop in question.  If the LABEL is
2288 omitted, the command refers to the innermost enclosing loop.  The
2289 C<continue> block, if any, is not executed:
2290
2291     LINE: while (<STDIN>) {
2292         last LINE if /^$/;      # exit when done with header
2293         #...
2294     }
2295
2296 C<last> cannot be used to exit a block which returns a value such as
2297 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2298 a grep() or map() operation.
2299
2300 Note that a block by itself is semantically identical to a loop
2301 that executes once.  Thus C<last> can be used to effect an early
2302 exit out of such a block.
2303
2304 See also L</continue> for an illustration of how C<last>, C<next>, and
2305 C<redo> work.
2306
2307 =item lc EXPR
2308
2309 =item lc
2310
2311 Returns an lowercased version of EXPR.  This is the internal function
2312 implementing the C<\L> escape in double-quoted strings.  Respects
2313 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2314 and L<perlunicode>.
2315
2316 If EXPR is omitted, uses C<$_>.
2317
2318 =item lcfirst EXPR
2319
2320 =item lcfirst
2321
2322 Returns the value of EXPR with the first character lowercased.  This
2323 is the internal function implementing the C<\l> escape in
2324 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2325 locale> in force.  See L<perllocale> and L<perlunicode>.
2326
2327 If EXPR is omitted, uses C<$_>.
2328
2329 =item length EXPR
2330
2331 =item length
2332
2333 Returns the length in characters of the value of EXPR.  If EXPR is
2334 omitted, returns length of C<$_>.  Note that this cannot be used on
2335 an entire array or hash to find out how many elements these have.
2336 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2337
2338 =item link OLDFILE,NEWFILE
2339
2340 Creates a new filename linked to the old filename.  Returns true for
2341 success, false otherwise.
2342
2343 =item listen SOCKET,QUEUESIZE
2344
2345 Does the same thing that the listen system call does.  Returns true if
2346 it succeeded, false otherwise.  See the example in
2347 L<perlipc/"Sockets: Client/Server Communication">.
2348
2349 =item local EXPR
2350
2351 You really probably want to be using C<my> instead, because C<local> isn't
2352 what most people think of as "local".  See
2353 L<perlsub/"Private Variables via my()"> for details.
2354
2355 A local modifies the listed variables to be local to the enclosing
2356 block, file, or eval.  If more than one value is listed, the list must
2357 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2358 for details, including issues with tied arrays and hashes.
2359
2360 =item localtime EXPR
2361
2362 Converts a time as returned by the time function to a 9-element list
2363 with the time analyzed for the local time zone.  Typically used as
2364 follows:
2365
2366     #  0    1    2     3     4    5     6     7     8
2367     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2368                                                 localtime(time);
2369
2370 All list elements are numeric, and come straight out of the C `struct
2371 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2372 specified time.  $mday is the day of the month, and $mon is the month
2373 itself, in the range C<0..11> with 0 indicating January and 11
2374 indicating December.  $year is the number of years since 1900.  That
2375 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2376 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2377 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2378 is true if the specified time occurs during daylight savings time,
2379 false otherwise.
2380
2381 Note that the $year element is I<not> simply the last two digits of
2382 the year.  If you assume it is, then you create non-Y2K-compliant
2383 programs--and you wouldn't want to do that, would you?
2384
2385 The proper way to get a complete 4-digit year is simply:
2386
2387         $year += 1900;
2388
2389 And to get the last two digits of the year (e.g., '01' in 2001) do:
2390
2391         $year = sprintf("%02d", $year % 100);
2392
2393 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2394
2395 In scalar context, C<localtime()> returns the ctime(3) value:
2396
2397     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2398
2399 This scalar value is B<not> locale dependent, see L<perllocale>, but
2400 instead a Perl builtin.  Also see the C<Time::Local> module
2401 (to convert the second, minutes, hours, ... back to seconds since the
2402 stroke of midnight the 1st of January 1970, the value returned by
2403 time()), and the strftime(3) and mktime(3) functions available via the
2404 POSIX module.  To get somewhat similar but locale dependent date
2405 strings, set up your locale environment variables appropriately
2406 (please see L<perllocale>) and try for example:
2407
2408     use POSIX qw(strftime);
2409     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2410
2411 Note that the C<%a> and C<%b>, the short forms of the day of the week
2412 and the month of the year, may not necessarily be three characters wide.
2413
2414 =item lock
2415
2416     lock I<THING>
2417
2418 This function places an advisory lock on a variable, subroutine,
2419 or referenced object contained in I<THING> until the lock goes out
2420 of scope.  This is a built-in function only if your version of Perl
2421 was built with threading enabled, and if you've said C<use Threads>.
2422 Otherwise a user-defined function by this name will be called.  See
2423 L<Thread>.
2424
2425 =item log EXPR
2426
2427 =item log
2428
2429 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2430 returns log of C<$_>.  To get the log of another base, use basic algebra:
2431 The base-N log of a number is equal to the natural log of that number
2432 divided by the natural log of N.  For example:
2433
2434     sub log10 {
2435         my $n = shift;
2436         return log($n)/log(10);
2437     }
2438
2439 See also L</exp> for the inverse operation.
2440
2441 =item lstat EXPR
2442
2443 =item lstat
2444
2445 Does the same thing as the C<stat> function (including setting the
2446 special C<_> filehandle) but stats a symbolic link instead of the file
2447 the symbolic link points to.  If symbolic links are unimplemented on
2448 your system, a normal C<stat> is done.
2449
2450 If EXPR is omitted, stats C<$_>.
2451
2452 =item m//
2453
2454 The match operator.  See L<perlop>.
2455
2456 =item map BLOCK LIST
2457
2458 =item map EXPR,LIST
2459
2460 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2461 C<$_> to each element) and returns the list value composed of the
2462 results of each such evaluation.  In scalar context, returns the
2463 total number of elements so generated.  Evaluates BLOCK or EXPR in
2464 list context, so each element of LIST may produce zero, one, or
2465 more elements in the returned value.
2466
2467     @chars = map(chr, @nums);
2468
2469 translates a list of numbers to the corresponding characters.  And
2470
2471     %hash = map { getkey($_) => $_ } @array;
2472
2473 is just a funny way to write
2474
2475     %hash = ();
2476     foreach $_ (@array) {
2477         $hash{getkey($_)} = $_;
2478     }
2479
2480 Note that C<$_> is an alias to the list value, so it can be used to
2481 modify the elements of the LIST.  While this is useful and supported,
2482 it can cause bizarre results if the elements of LIST are not variables.
2483 Using a regular C<foreach> loop for this purpose would be clearer in
2484 most cases.  See also L</grep> for an array composed of those items of
2485 the original list for which the BLOCK or EXPR evaluates to true.
2486
2487 C<{> starts both hash references and blocks, so C<map { ...> could be either
2488 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2489 ahead for the closing C<}> it has to take a guess at which its dealing with
2490 based what it finds just after the C<{>. Usually it gets it right, but if it
2491 doesn't it won't realize something is wrong until it gets to the C<}> and
2492 encounters the missing (or unexpected) comma. The syntax error will be
2493 reported close to the C<}> but you'll need to change something near the C<{>
2494 such as using a unary C<+> to give perl some help:
2495
2496     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2497     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2498     %hash = map { ("\L$_", 1) } @array  # this also works
2499     %hash = map {  lc($_), 1  } @array  # as does this.
2500     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2501
2502     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2503
2504 or to force an anon hash constructor use C<+{>
2505
2506    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2507
2508 and you get list of anonymous hashes each with only 1 entry.
2509
2510 =item mkdir FILENAME,MASK
2511
2512 =item mkdir FILENAME
2513
2514 Creates the directory specified by FILENAME, with permissions
2515 specified by MASK (as modified by C<umask>).  If it succeeds it
2516 returns true, otherwise it returns false and sets C<$!> (errno).
2517 If omitted, MASK defaults to 0777.
2518
2519 In general, it is better to create directories with permissive MASK,
2520 and let the user modify that with their C<umask>, than it is to supply
2521 a restrictive MASK and give the user no way to be more permissive.
2522 The exceptions to this rule are when the file or directory should be
2523 kept private (mail files, for instance).  The perlfunc(1) entry on
2524 C<umask> discusses the choice of MASK in more detail.
2525
2526 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2527 number of trailing slashes.  Some operating and filesystems do not get
2528 this right, so Perl automatically removes all trailing slashes to keep
2529 everyone happy.
2530
2531 =item msgctl ID,CMD,ARG
2532
2533 Calls the System V IPC function msgctl(2).  You'll probably have to say
2534
2535     use IPC::SysV;
2536
2537 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2538 then ARG must be a variable which will hold the returned C<msqid_ds>
2539 structure.  Returns like C<ioctl>: the undefined value for error,
2540 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2541 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2542
2543 =item msgget KEY,FLAGS
2544
2545 Calls the System V IPC function msgget(2).  Returns the message queue
2546 id, or the undefined value if there is an error.  See also
2547 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2548
2549 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2550
2551 Calls the System V IPC function msgrcv to receive a message from
2552 message queue ID into variable VAR with a maximum message size of
2553 SIZE.  Note that when a message is received, the message type as a
2554 native long integer will be the first thing in VAR, followed by the
2555 actual message.  This packing may be opened with C<unpack("l! a*")>.
2556 Taints the variable.  Returns true if successful, or false if there is
2557 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2558 C<IPC::SysV::Msg> documentation.
2559
2560 =item msgsnd ID,MSG,FLAGS
2561
2562 Calls the System V IPC function msgsnd to send the message MSG to the
2563 message queue ID.  MSG must begin with the native long integer message
2564 type, and be followed by the length of the actual message, and finally
2565 the message itself.  This kind of packing can be achieved with
2566 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2567 or false if there is an error.  See also C<IPC::SysV>
2568 and C<IPC::SysV::Msg> documentation.
2569
2570 =item my EXPR
2571
2572 =item my EXPR : ATTRIBUTES
2573
2574 A C<my> declares the listed variables to be local (lexically) to the
2575 enclosing block, file, or C<eval>.  If
2576 more than one value is listed, the list must be placed in parentheses.  See
2577 L<perlsub/"Private Variables via my()"> for details.
2578
2579 =item next LABEL
2580
2581 =item next
2582
2583 The C<next> command is like the C<continue> statement in C; it starts
2584 the next iteration of the loop:
2585
2586     LINE: while (<STDIN>) {
2587         next LINE if /^#/;      # discard comments
2588         #...
2589     }
2590
2591 Note that if there were a C<continue> block on the above, it would get
2592 executed even on discarded lines.  If the LABEL is omitted, the command
2593 refers to the innermost enclosing loop.
2594
2595 C<next> cannot be used to exit a block which returns a value such as
2596 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2597 a grep() or map() operation.
2598
2599 Note that a block by itself is semantically identical to a loop
2600 that executes once.  Thus C<next> will exit such a block early.
2601
2602 See also L</continue> for an illustration of how C<last>, C<next>, and
2603 C<redo> work.
2604
2605 =item no Module LIST
2606
2607 See the L</use> function, which C<no> is the opposite of.
2608
2609 =item oct EXPR
2610
2611 =item oct
2612
2613 Interprets EXPR as an octal string and returns the corresponding
2614 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2615 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2616 binary string.)  The following will handle decimal, binary, octal, and
2617 hex in the standard Perl or C notation:
2618
2619     $val = oct($val) if $val =~ /^0/;
2620
2621 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2622 in octal), use sprintf() or printf():
2623
2624     $perms = (stat("filename"))[2] & 07777;
2625     $oct_perms = sprintf "%lo", $perms;
2626
2627 The oct() function is commonly used when a string such as C<644> needs
2628 to be converted into a file mode, for example. (Although perl will
2629 automatically convert strings into numbers as needed, this automatic
2630 conversion assumes base 10.)
2631
2632 =item open FILEHANDLE,EXPR
2633
2634 =item open FILEHANDLE,MODE,EXPR
2635
2636 =item open FILEHANDLE,MODE,EXPR,LIST
2637
2638 =item open FILEHANDLE
2639
2640 Opens the file whose filename is given by EXPR, and associates it with
2641 FILEHANDLE.  If FILEHANDLE is an undefined lexical (C<my>) variable the variable is
2642 assigned a reference to a new anonymous filehandle, otherwise if FILEHANDLE is an expression,
2643 its value is used as the name of the real filehandle wanted.  (This is considered a symbolic
2644 reference, so C<use strict 'refs'> should I<not> be in effect.)
2645
2646 If EXPR is omitted, the scalar
2647 variable of the same name as the FILEHANDLE contains the filename.
2648 (Note that lexical variables--those declared with C<my>--will not work
2649 for this purpose; so if you're using C<my>, specify EXPR in your call
2650 to open.)  See L<perlopentut> for a kinder, gentler explanation of opening
2651 files.
2652
2653 If three or more arguments are specified then the mode of opening and the file name
2654 are separate. If MODE is C<< '<' >> or nothing, the file is opened for input.
2655 If MODE is C<< '>' >>, the file is truncated and opened for
2656 output, being created if necessary.  If MODE is C<<< '>>' >>>,
2657 the file is opened for appending, again being created if necessary.
2658 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to indicate that
2659 you want both read and write access to the file; thus C<< '+<' >> is almost
2660 always preferred for read/write updates--the C<< '+>' >> mode would clobber the
2661 file first.  You can't usually use either read-write mode for updating
2662 textfiles, since they have variable length records.  See the B<-i>
2663 switch in L<perlrun> for a better approach.  The file is created with
2664 permissions of C<0666> modified by the process' C<umask> value.
2665
2666 These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>,
2667 C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2668
2669 In the 2-arguments (and 1-argument) form of the call the mode and
2670 filename should be concatenated (in this order), possibly separated by
2671 spaces.  It is possible to omit the mode in these forms if the mode is
2672 C<< '<' >>.
2673
2674 If the filename begins with C<'|'>, the filename is interpreted as a
2675 command to which output is to be piped, and if the filename ends with a
2676 C<'|'>, the filename is interpreted as a command which pipes output to
2677 us.  See L<perlipc/"Using open() for IPC">
2678 for more examples of this.  (You are not allowed to C<open> to a command
2679 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2680 and L<perlipc/"Bidirectional Communication with Another Process">
2681 for alternatives.)
2682
2683 For three or more arguments if MODE is C<'|-'>, the filename is interpreted as a
2684 command to which output is to be piped, and if MODE is
2685 C<'-|'>, the filename is interpreted as a command which pipes output to
2686 us.  In the 2-arguments (and 1-argument) form one should replace dash
2687 (C<'-'>) with the command.  See L<perlipc/"Using open() for IPC">
2688 for more examples of this.  (You are not allowed to C<open> to a command
2689 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2690 and L<perlipc/"Bidirectional Communication"> for alternatives.) In 3+ arg form of
2691 pipe opens then if LIST is specified (extra arguments after the command name) then
2692 LIST becomes arguments to the command invoked if the platform supports it.
2693 The meaning of C<open> with more than three arguments for non-pipe modes
2694 is not yet specified. Experimental "layers" may give extra LIST arguments meaning.
2695
2696 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2697 and opening C<< '>-' >> opens STDOUT.
2698
2699 Open returns
2700 nonzero upon success, the undefined value otherwise.  If the C<open>
2701 involved a pipe, the return value happens to be the pid of the
2702 subprocess.
2703
2704 If you're unfortunate enough to be running Perl on a system that
2705 distinguishes between text files and binary files (modern operating
2706 systems don't care), then you should check out L</binmode> for tips for
2707 dealing with this.  The key distinction between systems that need C<binmode>
2708 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2709 Plan9, which delimit lines with a single character, and which encode that
2710 character in C as C<"\n">, do not need C<binmode>.  The rest need it.
2711
2712 In the three argument form MODE may also contain a list of IO "layers" (see L<open> and
2713 L<PerlIO> for more details) to be applied to the handle. This can be used to achieve the
2714 effect of C<binmode> as well as more complex behaviours.
2715
2716 When opening a file, it's usually a bad idea to continue normal execution
2717 if the request failed, so C<open> is frequently used in connection with
2718 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2719 where you want to make a nicely formatted error message (but there are
2720 modules that can help with that problem)) you should always check
2721 the return value from opening a file.  The infrequent exception is when
2722 working with an unopened filehandle is actually what you want to do.
2723
2724 As a special case the 3 arg form with a read/write mode and the third argument
2725 being C<undef>:
2726
2727     open(TMP, "+>", undef) or die ...
2728
2729 opens a filehandle to an anonymous temporary file.
2730
2731
2732 Examples:
2733
2734     $ARTICLE = 100;
2735     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2736     while (<ARTICLE>) {...
2737
2738     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2739     # if the open fails, output is discarded
2740
2741     open(DBASE, '+<', 'dbase.mine')             # open for update
2742         or die "Can't open 'dbase.mine' for update: $!";
2743
2744     open(DBASE, '+<dbase.mine')                 # ditto
2745         or die "Can't open 'dbase.mine' for update: $!";
2746
2747     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2748         or die "Can't start caesar: $!";
2749
2750     open(ARTICLE, "caesar <$article |")         # ditto
2751         or die "Can't start caesar: $!";
2752
2753     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2754         or die "Can't start sort: $!";
2755
2756     # process argument list of files along with any includes
2757
2758     foreach $file (@ARGV) {
2759         process($file, 'fh00');
2760     }
2761
2762     sub process {
2763         my($filename, $input) = @_;
2764         $input++;               # this is a string increment
2765         unless (open($input, $filename)) {
2766             print STDERR "Can't open $filename: $!\n";
2767             return;
2768         }
2769
2770         local $_;
2771         while (<$input>) {              # note use of indirection
2772             if (/^#include "(.*)"/) {
2773                 process($1, $input);
2774                 next;
2775             }
2776             #...                # whatever
2777         }
2778     }
2779
2780 You may also, in the Bourne shell tradition, specify an EXPR beginning
2781 with C<< '>&' >>, in which case the rest of the string is interpreted as the
2782 name of a filehandle (or file descriptor, if numeric) to be
2783 duped and opened.  You may use C<&> after C<< > >>, C<<< >> >>>,
2784 C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.  The
2785 mode you specify should match the mode of the original filehandle.
2786 (Duping a filehandle does not take into account any existing contents of
2787 stdio buffers.) If you use the 3 arg form then you can pass either a number,
2788 the name of a filehandle or the normal "reference to a glob".
2789
2790 Here is a script that saves, redirects, and restores STDOUT and
2791 STDERR:
2792
2793     #!/usr/bin/perl
2794     open(my $oldout, ">&", \*STDOUT);
2795     open(OLDERR, ">&STDERR");
2796
2797     open(STDOUT, '>', "foo.out") || die "Can't redirect stdout";
2798     open(STDERR, ">&STDOUT")     || die "Can't dup stdout";
2799
2800     select(STDERR); $| = 1;     # make unbuffered
2801     select(STDOUT); $| = 1;     # make unbuffered
2802
2803     print STDOUT "stdout 1\n";  # this works for
2804     print STDERR "stderr 1\n";  # subprocesses too
2805
2806     close(STDOUT);
2807     close(STDERR);
2808
2809     open(STDOUT, ">&OLDOUT");
2810     open(STDERR, ">&OLDERR");
2811
2812     print STDOUT "stdout 2\n";
2813     print STDERR "stderr 2\n";
2814
2815 If you specify C<< '<&=N' >>, where C<N> is a number, then Perl will
2816 do an equivalent of C's C<fdopen> of that file descriptor; this is
2817 more parsimonious of file descriptors.  For example:
2818
2819     open(FILEHANDLE, "<&=$fd")
2820
2821 or
2822
2823     open(FILEHANDLE, "<&=", $fd)
2824
2825 Note that if Perl is using the standard C libraries' fdopen() then on
2826 many UNIX systems, fdopen() is known to fail when file descriptors
2827 exceed a certain value, typically 255. If you need more file
2828 descriptors than that, consider rebuilding Perl to use the C<PerlIO>.
2829
2830 You can see whether Perl has been compiled with PerlIO or not by
2831 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
2832 is C<define>, you have PerlIO, otherwise you don't.
2833
2834 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2835 with 2-arguments (or 1-argument) form of open(), then
2836 there is an implicit fork done, and the return value of open is the pid
2837 of the child within the parent process, and C<0> within the child
2838 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2839 The filehandle behaves normally for the parent, but i/o to that
2840 filehandle is piped from/to the STDOUT/STDIN of the child process.
2841 In the child process the filehandle isn't opened--i/o happens from/to
2842 the new STDOUT or STDIN.  Typically this is used like the normal
2843 piped open when you want to exercise more control over just how the
2844 pipe command gets executed, such as when you are running setuid, and
2845 don't want to have to scan shell commands for metacharacters.
2846 The following triples are more or less equivalent:
2847
2848     open(FOO, "|tr '[a-z]' '[A-Z]'");
2849     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2850     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2851     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
2852
2853     open(FOO, "cat -n '$file'|");
2854     open(FOO, '-|', "cat -n '$file'");
2855     open(FOO, '-|') || exec 'cat', '-n', $file;
2856     open(FOO, '-|', "cat", '-n', $file);
2857
2858 The last example in each block shows the pipe as "list form", which is
2859 not yet supported on all platforms.
2860
2861 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2862
2863 Beginning with v5.6.0, Perl will attempt to flush all files opened for
2864 output before any operation that may do a fork, but this may not be
2865 supported on some platforms (see L<perlport>).  To be safe, you may need
2866 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
2867 of C<IO::Handle> on any open handles.
2868
2869 On systems that support a
2870 close-on-exec flag on files, the flag will be set for the newly opened
2871 file descriptor as determined by the value of $^F.  See L<perlvar/$^F>.
2872
2873 Closing any piped filehandle causes the parent process to wait for the
2874 child to finish, and returns the status value in C<$?>.
2875
2876 The filename passed to 2-argument (or 1-argument) form of open()
2877 will have leading and trailing
2878 whitespace deleted, and the normal redirection characters
2879 honored.  This property, known as "magic open",
2880 can often be used to good effect.  A user could specify a filename of
2881 F<"rsh cat file |">, or you could change certain filenames as needed:
2882
2883     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2884     open(FH, $filename) or die "Can't open $filename: $!";
2885
2886 Use 3-argument form to open a file with arbitrary weird characters in it,
2887
2888     open(FOO, '<', $file);
2889
2890 otherwise it's necessary to protect any leading and trailing whitespace:
2891
2892     $file =~ s#^(\s)#./$1#;
2893     open(FOO, "< $file\0");
2894
2895 (this may not work on some bizarre filesystems).  One should
2896 conscientiously choose between the I<magic> and 3-arguments form
2897 of open():
2898
2899     open IN, $ARGV[0];
2900
2901 will allow the user to specify an argument of the form C<"rsh cat file |">,
2902 but will not work on a filename which happens to have a trailing space, while
2903
2904     open IN, '<', $ARGV[0];
2905
2906 will have exactly the opposite restrictions.
2907
2908 If you want a "real" C C<open> (see L<open(2)> on your system), then you
2909 should use the C<sysopen> function, which involves no such magic (but
2910 may use subtly different filemodes than Perl open(), which is mapped
2911 to C fopen()).  This is
2912 another way to protect your filenames from interpretation.  For example:
2913
2914     use IO::Handle;
2915     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2916         or die "sysopen $path: $!";
2917     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2918     print HANDLE "stuff $$\n";
2919     seek(HANDLE, 0, 0);
2920     print "File contains: ", <HANDLE>;
2921
2922 Using the constructor from the C<IO::Handle> package (or one of its
2923 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2924 filehandles that have the scope of whatever variables hold references to
2925 them, and automatically close whenever and however you leave that scope:
2926
2927     use IO::File;
2928     #...
2929     sub read_myfile_munged {
2930         my $ALL = shift;
2931         my $handle = new IO::File;
2932         open($handle, "myfile") or die "myfile: $!";
2933         $first = <$handle>
2934             or return ();     # Automatically closed here.
2935         mung $first or die "mung failed";       # Or here.
2936         return $first, <$handle> if $ALL;       # Or here.
2937         $first;                                 # Or here.
2938     }
2939
2940 See L</seek> for some details about mixing reading and writing.
2941
2942 =item opendir DIRHANDLE,EXPR
2943
2944 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
2945 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
2946 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2947
2948 =item ord EXPR
2949
2950 =item ord
2951
2952 Returns the numeric (ASCII or Unicode) value of the first character of EXPR.  If
2953 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2954 See L<utf8> for more about Unicode.
2955
2956 =item our EXPR
2957
2958 =item our EXPR : ATTRIBUTES
2959
2960 An C<our> declares the listed variables to be valid globals within
2961 the enclosing block, file, or C<eval>.  That is, it has the same
2962 scoping rules as a "my" declaration, but does not create a local
2963 variable.  If more than one value is listed, the list must be placed
2964 in parentheses.  The C<our> declaration has no semantic effect unless
2965 "use strict vars" is in effect, in which case it lets you use the
2966 declared global variable without qualifying it with a package name.
2967 (But only within the lexical scope of the C<our> declaration.  In this
2968 it differs from "use vars", which is package scoped.)
2969
2970 An C<our> declaration declares a global variable that will be visible
2971 across its entire lexical scope, even across package boundaries.  The
2972 package in which the variable is entered is determined at the point
2973 of the declaration, not at the point of use.  This means the following
2974 behavior holds:
2975
2976     package Foo;
2977     our $bar;           # declares $Foo::bar for rest of lexical scope
2978     $bar = 20;
2979
2980     package Bar;
2981     print $bar;         # prints 20
2982
2983 Multiple C<our> declarations in the same lexical scope are allowed
2984 if they are in different packages.  If they happened to be in the same
2985 package, Perl will emit warnings if you have asked for them.
2986
2987     use warnings;
2988     package Foo;
2989     our $bar;           # declares $Foo::bar for rest of lexical scope
2990     $bar = 20;
2991
2992     package Bar;
2993     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
2994     print $bar;         # prints 30
2995
2996     our $bar;           # emits warning
2997
2998 An C<our> declaration may also have a list of attributes associated
2999 with it.  B<WARNING>: This is an experimental feature that may be
3000 changed or removed in future releases of Perl.  It should not be
3001 relied upon.
3002
3003 The only currently recognized attribute is C<unique> which indicates
3004 that a single copy of the global is to be used by all interpreters
3005 should the program happen to be running in a multi-interpreter
3006 environment. (The default behaviour would be for each interpreter to
3007 have its own copy of the global.)  In such an environment, this
3008 attribute also has the effect of making the global readonly.
3009 Examples:
3010
3011     our @EXPORT : unique = qw(foo);
3012     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3013     our $VERSION : unique = "1.00";
3014
3015 Multi-interpreter environments can come to being either through the
3016 fork() emulation on Windows platforms, or by embedding perl in a
3017 multi-threaded application.  The C<unique> attribute does nothing in
3018 all other environments.
3019
3020 =item pack TEMPLATE,LIST
3021
3022 Takes a LIST of values and converts it into a string using the rules
3023 given by the TEMPLATE.  The resulting string is the concatenation of
3024 the converted values.  Typically, each converted value looks
3025 like its machine-level representation.  For example, on 32-bit machines
3026 a converted integer may be represented by a sequence of 4 bytes.
3027
3028 The TEMPLATE is a
3029 sequence of characters that give the order and type of values, as
3030 follows:
3031
3032     a   A string with arbitrary binary data, will be null padded.
3033     A   An ASCII string, will be space padded.
3034     Z   A null terminated (asciz) string, will be null padded.
3035
3036     b   A bit string (ascending bit order inside each byte, like vec()).
3037     B   A bit string (descending bit order inside each byte).
3038     h   A hex string (low nybble first).
3039     H   A hex string (high nybble first).
3040
3041     c   A signed char value.
3042     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3043
3044     s   A signed short value.
3045     S   An unsigned short value.
3046           (This 'short' is _exactly_ 16 bits, which may differ from
3047            what a local C compiler calls 'short'.  If you want
3048            native-length shorts, use the '!' suffix.)
3049
3050     i   A signed integer value.
3051     I   An unsigned integer value.
3052           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3053            size depends on what a local C compiler calls 'int',
3054            and may even be larger than the 'long' described in
3055            the next item.)
3056
3057     l   A signed long value.
3058     L   An unsigned long value.
3059           (This 'long' is _exactly_ 32 bits, which may differ from
3060            what a local C compiler calls 'long'.  If you want
3061            native-length longs, use the '!' suffix.)
3062
3063     n   An unsigned short in "network" (big-endian) order.
3064     N   An unsigned long in "network" (big-endian) order.
3065     v   An unsigned short in "VAX" (little-endian) order.
3066     V   An unsigned long in "VAX" (little-endian) order.
3067           (These 'shorts' and 'longs' are _exactly_ 16 bits and
3068            _exactly_ 32 bits, respectively.)
3069
3070     q   A signed quad (64-bit) value.
3071     Q   An unsigned quad value.
3072           (Quads are available only if your system supports 64-bit
3073            integer values _and_ if Perl has been compiled to support those.
3074            Causes a fatal error otherwise.)
3075
3076     f   A single-precision float in the native format.
3077     d   A double-precision float in the native format.
3078
3079     p   A pointer to a null-terminated string.
3080     P   A pointer to a structure (fixed-length string).
3081
3082     u   A uuencoded string.
3083     U   A Unicode character number.  Encodes to UTF-8 internally
3084         (or UTF-EBCDIC in EBCDIC platforms).
3085
3086     w   A BER compressed integer.  Its bytes represent an unsigned
3087         integer in base 128, most significant digit first, with as
3088         few digits as possible.  Bit eight (the high bit) is set
3089         on each byte except the last.
3090
3091     x   A null byte.
3092     X   Back up a byte.
3093     @   Null fill to absolute position.
3094
3095 The following rules apply:
3096
3097 =over 8
3098
3099 =item *
3100
3101 Each letter may optionally be followed by a number giving a repeat
3102 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3103 C<H>, and C<P> the pack function will gobble up that many values from
3104 the LIST.  A C<*> for the repeat count means to use however many items are
3105 left, except for C<@>, C<x>, C<X>, where it is equivalent
3106 to C<0>, and C<u>, where it is equivalent to 1 (or 45, what is the
3107 same).
3108
3109 When used with C<Z>, C<*> results in the addition of a trailing null
3110 byte (so the packed result will be one longer than the byte C<length>
3111 of the item).
3112
3113 The repeat count for C<u> is interpreted as the maximal number of bytes
3114 to encode per line of output, with 0 and 1 replaced by 45.
3115
3116 =item *
3117
3118 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3119 string of length count, padding with nulls or spaces as necessary.  When
3120 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3121 after the first null, and C<a> returns data verbatim.  When packing,
3122 C<a>, and C<Z> are equivalent.
3123
3124 If the value-to-pack is too long, it is truncated.  If too long and an
3125 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3126 by a null byte.  Thus C<Z> always packs a trailing null byte under
3127 all circumstances.
3128
3129 =item *
3130
3131 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3132 Each byte of the input field of pack() generates 1 bit of the result.
3133 Each result bit is based on the least-significant bit of the corresponding
3134 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3135 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3136
3137 Starting from the beginning of the input string of pack(), each 8-tuple
3138 of bytes is converted to 1 byte of output.  With format C<b>
3139 the first byte of the 8-tuple determines the least-significant bit of a
3140 byte, and with format C<B> it determines the most-significant bit of
3141 a byte.
3142
3143 If the length of the input string is not exactly divisible by 8, the
3144 remainder is packed as if the input string were padded by null bytes
3145 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3146
3147 If the input string of pack() is longer than needed, extra bytes are ignored.
3148 A C<*> for the repeat count of pack() means to use all the bytes of
3149 the input field.  On unpack()ing the bits are converted to a string
3150 of C<"0">s and C<"1">s.
3151
3152 =item *
3153
3154 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3155 representable as hexadecimal digits, 0-9a-f) long.
3156
3157 Each byte of the input field of pack() generates 4 bits of the result.
3158 For non-alphabetical bytes the result is based on the 4 least-significant
3159 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3160 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3161 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3162 is compatible with the usual hexadecimal digits, so that C<"a"> and
3163 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3164 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3165
3166 Starting from the beginning of the input string of pack(), each pair
3167 of bytes is converted to 1 byte of output.  With format C<h> the
3168 first byte of the pair determines the least-significant nybble of the
3169 output byte, and with format C<H> it determines the most-significant
3170 nybble.
3171
3172 If the length of the input string is not even, it behaves as if padded
3173 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3174 nybbles are ignored.
3175
3176 If the input string of pack() is longer than needed, extra bytes are ignored.
3177 A C<*> for the repeat count of pack() means to use all the bytes of
3178 the input field.  On unpack()ing the bits are converted to a string
3179 of hexadecimal digits.
3180
3181 =item *
3182
3183 The C<p> type packs a pointer to a null-terminated string.  You are
3184 responsible for ensuring the string is not a temporary value (which can
3185 potentially get deallocated before you get around to using the packed result).
3186 The C<P> type packs a pointer to a structure of the size indicated by the
3187 length.  A NULL pointer is created if the corresponding value for C<p> or
3188 C<P> is C<undef>, similarly for unpack().
3189
3190 =item *
3191
3192 The C</> template character allows packing and unpacking of strings where
3193 the packed structure contains a byte count followed by the string itself.
3194 You write I<length-item>C</>I<string-item>.
3195
3196 The I<length-item> can be any C<pack> template letter,
3197 and describes how the length value is packed.
3198 The ones likely to be of most use are integer-packing ones like
3199 C<n> (for Java strings), C<w> (for ASN.1 or SNMP)
3200 and C<N> (for Sun XDR).
3201
3202 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
3203 For C<unpack> the length of the string is obtained from the I<length-item>,
3204 but if you put in the '*' it will be ignored.
3205
3206     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3207     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3208     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3209
3210 The I<length-item> is not returned explicitly from C<unpack>.
3211
3212 Adding a count to the I<length-item> letter is unlikely to do anything
3213 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3214 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3215 which Perl does not regard as legal in numeric strings.
3216
3217 =item *
3218
3219 The integer types C<s>, C<S>, C<l>, and C<L> may be
3220 immediately followed by a C<!> suffix to signify native shorts or
3221 longs--as you can see from above for example a bare C<l> does mean
3222 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3223 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3224 see whether using C<!> makes any difference by
3225
3226         print length(pack("s")), " ", length(pack("s!")), "\n";
3227         print length(pack("l")), " ", length(pack("l!")), "\n";
3228
3229 C<i!> and C<I!> also work but only because of completeness;
3230 they are identical to C<i> and C<I>.
3231
3232 The actual sizes (in bytes) of native shorts, ints, longs, and long
3233 longs on the platform where Perl was built are also available via
3234 L<Config>:
3235
3236        use Config;
3237        print $Config{shortsize},    "\n";
3238        print $Config{intsize},      "\n";
3239        print $Config{longsize},     "\n";
3240        print $Config{longlongsize}, "\n";
3241
3242 (The C<$Config{longlongsize}> will be undefine if your system does
3243 not support long longs.)
3244
3245 =item *
3246
3247 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, and C<L>
3248 are inherently non-portable between processors and operating systems
3249 because they obey the native byteorder and endianness.  For example a
3250 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3251 (arranged in and handled by the CPU registers) into bytes as
3252
3253         0x12 0x34 0x56 0x78     # big-endian
3254         0x78 0x56 0x34 0x12     # little-endian
3255
3256 Basically, the Intel and VAX CPUs are little-endian, while everybody
3257 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3258 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3259 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3260 mode.
3261
3262 The names `big-endian' and `little-endian' are comic references to
3263 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3264 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3265 the egg-eating habits of the Lilliputians.
3266
3267 Some systems may have even weirder byte orders such as
3268
3269         0x56 0x78 0x12 0x34
3270         0x34 0x12 0x78 0x56
3271
3272 You can see your system's preference with
3273
3274         print join(" ", map { sprintf "%#02x", $_ }
3275                             unpack("C*",pack("L",0x12345678))), "\n";
3276
3277 The byteorder on the platform where Perl was built is also available
3278 via L<Config>:
3279
3280         use Config;
3281         print $Config{byteorder}, "\n";
3282
3283 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3284 and C<'87654321'> are big-endian.
3285
3286 If you want portable packed integers use the formats C<n>, C<N>,
3287 C<v>, and C<V>, their byte endianness and size are known.
3288 See also L<perlport>.
3289
3290 =item *
3291
3292 Real numbers (floats and doubles) are in the native machine format only;
3293 due to the multiplicity of floating formats around, and the lack of a
3294 standard "network" representation, no facility for interchange has been
3295 made.  This means that packed floating point data written on one machine
3296 may not be readable on another - even if both use IEEE floating point
3297 arithmetic (as the endian-ness of the memory representation is not part
3298 of the IEEE spec).  See also L<perlport>.
3299
3300 Note that Perl uses doubles internally for all numeric calculation, and
3301 converting from double into float and thence back to double again will
3302 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3303 equal $foo).
3304
3305 =item *
3306
3307 If the pattern begins with a C<U>, the resulting string will be treated
3308 as Unicode-encoded. You can force UTF8 encoding on in a string with an
3309 initial C<U0>, and the bytes that follow will be interpreted as Unicode
3310 characters. If you don't want this to happen, you can begin your pattern
3311 with C<C0> (or anything else) to force Perl not to UTF8 encode your
3312 string, and then follow this with a C<U*> somewhere in your pattern.
3313
3314 =item *
3315
3316 You must yourself do any alignment or padding by inserting for example
3317 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3318 could know where the bytes are going to or coming from.  Therefore
3319 C<pack> (and C<unpack>) handle their output and input as flat
3320 sequences of bytes.
3321
3322 =item *
3323
3324 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3325
3326 =item *
3327
3328 If TEMPLATE requires more arguments to pack() than actually given, pack()
3329 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3330 to pack() than actually given, extra arguments are ignored.
3331
3332 =back
3333
3334 Examples:
3335
3336     $foo = pack("CCCC",65,66,67,68);
3337     # foo eq "ABCD"
3338     $foo = pack("C4",65,66,67,68);
3339     # same thing
3340     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3341     # same thing with Unicode circled letters
3342
3343     $foo = pack("ccxxcc",65,66,67,68);
3344     # foo eq "AB\0\0CD"
3345
3346     # note: the above examples featuring "C" and "c" are true
3347     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3348     # and UTF-8.  In EBCDIC the first example would be
3349     # $foo = pack("CCCC",193,194,195,196);
3350
3351     $foo = pack("s2",1,2);
3352     # "\1\0\2\0" on little-endian
3353     # "\0\1\0\2" on big-endian
3354
3355     $foo = pack("a4","abcd","x","y","z");
3356     # "abcd"
3357
3358     $foo = pack("aaaa","abcd","x","y","z");
3359     # "axyz"
3360
3361     $foo = pack("a14","abcdefg");
3362     # "abcdefg\0\0\0\0\0\0\0"
3363
3364     $foo = pack("i9pl", gmtime);
3365     # a real struct tm (on my system anyway)
3366
3367     $utmp_template = "Z8 Z8 Z16 L";
3368     $utmp = pack($utmp_template, @utmp1);
3369     # a struct utmp (BSDish)
3370
3371     @utmp2 = unpack($utmp_template, $utmp);
3372     # "@utmp1" eq "@utmp2"
3373
3374     sub bintodec {
3375         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3376     }
3377
3378     $foo = pack('sx2l', 12, 34);
3379     # short 12, two zero bytes padding, long 34
3380     $bar = pack('s@4l', 12, 34);
3381     # short 12, zero fill to position 4, long 34
3382     # $foo eq $bar
3383
3384 The same template may generally also be used in unpack().
3385
3386 =item package NAMESPACE
3387
3388 =item package
3389
3390 Declares the compilation unit as being in the given namespace.  The scope
3391 of the package declaration is from the declaration itself through the end
3392 of the enclosing block, file, or eval (the same as the C<my> operator).
3393 All further unqualified dynamic identifiers will be in this namespace.
3394 A package statement affects only dynamic variables--including those
3395 you've used C<local> on--but I<not> lexical variables, which are created
3396 with C<my>.  Typically it would be the first declaration in a file to
3397 be included by the C<require> or C<use> operator.  You can switch into a
3398 package in more than one place; it merely influences which symbol table
3399 is used by the compiler for the rest of that block.  You can refer to
3400 variables and filehandles in other packages by prefixing the identifier
3401 with the package name and a double colon:  C<$Package::Variable>.
3402 If the package name is null, the C<main> package as assumed.  That is,
3403 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3404 still seen in older code).
3405
3406 If NAMESPACE is omitted, then there is no current package, and all
3407 identifiers must be fully qualified or lexicals.  However, you are
3408 strongly advised not to make use of this feature. Its use can cause
3409 unexpected behaviour, even crashing some versions of Perl. It is
3410 deprecated, and will be removed from a future release.
3411
3412 See L<perlmod/"Packages"> for more information about packages, modules,
3413 and classes.  See L<perlsub> for other scoping issues.
3414
3415 =item pipe READHANDLE,WRITEHANDLE
3416
3417 Opens a pair of connected pipes like the corresponding system call.
3418 Note that if you set up a loop of piped processes, deadlock can occur
3419 unless you are very careful.  In addition, note that Perl's pipes use
3420 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3421 after each command, depending on the application.
3422
3423 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3424 for examples of such things.
3425
3426 On systems that support a close-on-exec flag on files, the flag will be set
3427 for the newly opened file descriptors as determined by the value of $^F.
3428 See L<perlvar/$^F>.
3429
3430 =item pop ARRAY
3431
3432 =item pop
3433
3434 Pops and returns the last value of the array, shortening the array by
3435 one element.  Has an effect similar to
3436
3437     $ARRAY[$#ARRAY--]
3438
3439 If there are no elements in the array, returns the undefined value
3440 (although this may happen at other times as well).  If ARRAY is
3441 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3442 array in subroutines, just like C<shift>.
3443
3444 =item pos SCALAR
3445
3446 =item pos
3447
3448 Returns the offset of where the last C<m//g> search left off for the variable
3449 in question (C<$_> is used when the variable is not specified).  May be
3450 modified to change that offset.  Such modification will also influence
3451 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3452 L<perlop>.
3453
3454 =item print FILEHANDLE LIST
3455
3456 =item print LIST
3457
3458 =item print
3459
3460 Prints a string or a list of strings.  Returns true if successful.
3461 FILEHANDLE may be a scalar variable name, in which case the variable
3462 contains the name of or a reference to the filehandle, thus introducing
3463 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3464 the next token is a term, it may be misinterpreted as an operator
3465 unless you interpose a C<+> or put parentheses around the arguments.)
3466 If FILEHANDLE is omitted, prints by default to standard output (or
3467 to the last selected output channel--see L</select>).  If LIST is
3468 also omitted, prints C<$_> to the currently selected output channel.
3469 To set the default output channel to something other than STDOUT
3470 use the select operation.  The current value of C<$,> (if any) is
3471 printed between each LIST item.  The current value of C<$\> (if
3472 any) is printed after the entire LIST has been printed.  Because
3473 print takes a LIST, anything in the LIST is evaluated in list
3474 context, and any subroutine that you call will have one or more of
3475 its expressions evaluated in list context.  Also be careful not to
3476 follow the print keyword with a left parenthesis unless you want
3477 the corresponding right parenthesis to terminate the arguments to
3478 the print--interpose a C<+> or put parentheses around all the
3479 arguments.
3480
3481 Note that if you're storing FILEHANDLES in an array or other expression,
3482 you will have to use a block returning its value instead:
3483
3484     print { $files[$i] } "stuff\n";
3485     print { $OK ? STDOUT : STDERR } "stuff\n";
3486
3487 =item printf FILEHANDLE FORMAT, LIST
3488
3489 =item printf FORMAT, LIST
3490
3491 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3492 (the output record separator) is not appended.  The first argument
3493 of the list will be interpreted as the C<printf> format. See C<sprintf>
3494 for an explanation of the format argument. If C<use locale> is in effect,
3495 the character used for the decimal point in formatted real numbers is
3496 affected by the LC_NUMERIC locale.  See L<perllocale>.
3497
3498 Don't fall into the trap of using a C<printf> when a simple
3499 C<print> would do.  The C<print> is more efficient and less
3500 error prone.
3501
3502 =item prototype FUNCTION
3503
3504 Returns the prototype of a function as a string (or C<undef> if the
3505 function has no prototype).  FUNCTION is a reference to, or the name of,
3506 the function whose prototype you want to retrieve.
3507
3508 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3509 name for Perl builtin.  If the builtin is not I<overridable> (such as
3510 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3511 C<system>) returns C<undef> because the builtin does not really behave
3512 like a Perl function.  Otherwise, the string describing the equivalent
3513 prototype is returned.
3514
3515 =item push ARRAY,LIST
3516
3517 Treats ARRAY as a stack, and pushes the values of LIST
3518 onto the end of ARRAY.  The length of ARRAY increases by the length of
3519 LIST.  Has the same effect as
3520
3521     for $value (LIST) {
3522         $ARRAY[++$#ARRAY] = $value;
3523     }
3524
3525 but is more efficient.  Returns the new number of elements in the array.
3526
3527 =item q/STRING/
3528
3529 =item qq/STRING/
3530
3531 =item qr/STRING/
3532
3533 =item qx/STRING/
3534
3535 =item qw/STRING/
3536
3537 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3538
3539 =item quotemeta EXPR
3540
3541 =item quotemeta
3542
3543 Returns the value of EXPR with all non-"word"
3544 characters backslashed.  (That is, all characters not matching
3545 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3546 returned string, regardless of any locale settings.)
3547 This is the internal function implementing
3548 the C<\Q> escape in double-quoted strings.
3549
3550 If EXPR is omitted, uses C<$_>.
3551
3552 =item rand EXPR
3553
3554 =item rand
3555
3556 Returns a random fractional number greater than or equal to C<0> and less
3557 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3558 omitted, or a C<0>, the value C<1> is used.  Automatically calls C<srand>
3559 unless C<srand> has already been called.  See also C<srand>.
3560
3561 Apply C<int()> to the value returned by C<rand()> if you want random
3562 integers instead of random fractional numbers.  For example,
3563
3564     int(rand(10))
3565
3566 returns a random integer between C<0> and C<9>, inclusive.
3567
3568 (Note: If your rand function consistently returns numbers that are too
3569 large or too small, then your version of Perl was probably compiled
3570 with the wrong number of RANDBITS.)
3571
3572 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3573
3574 =item read FILEHANDLE,SCALAR,LENGTH
3575
3576 Attempts to read LENGTH bytes of data into variable SCALAR from the
3577 specified FILEHANDLE.  Returns the number of bytes actually read, C<0>
3578 at end of file, or undef if there was an error.  SCALAR will be grown
3579 or shrunk to the length actually read.  If SCALAR needs growing, the
3580 new bytes will be zero bytes.  An OFFSET may be specified to place
3581 the read data into some other place in SCALAR than the beginning.
3582 The call is actually implemented in terms of stdio's fread(3) call.
3583 To get a true read(2) system call, see C<sysread>.
3584
3585 =item readdir DIRHANDLE
3586
3587 Returns the next directory entry for a directory opened by C<opendir>.
3588 If used in list context, returns all the rest of the entries in the
3589 directory.  If there are no more entries, returns an undefined value in
3590 scalar context or a null list in list context.
3591
3592 If you're planning to filetest the return values out of a C<readdir>, you'd
3593 better prepend the directory in question.  Otherwise, because we didn't
3594 C<chdir> there, it would have been testing the wrong file.
3595
3596     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3597     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3598     closedir DIR;
3599
3600 =item readline EXPR
3601
3602 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3603 context, each call reads and returns the next line, until end-of-file is
3604 reached, whereupon the subsequent call returns undef.  In list context,
3605 reads until end-of-file is reached and returns a list of lines.  Note that
3606 the notion of "line" used here is however you may have defined it
3607 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3608
3609 When C<$/> is set to C<undef>, when readline() is in scalar
3610 context (i.e. file slurp mode), and when an empty file is read, it
3611 returns C<''> the first time, followed by C<undef> subsequently.
3612
3613 This is the internal function implementing the C<< <EXPR> >>
3614 operator, but you can use it directly.  The C<< <EXPR> >>
3615 operator is discussed in more detail in L<perlop/"I/O Operators">.
3616
3617     $line = <STDIN>;
3618     $line = readline(*STDIN);           # same thing
3619
3620 =item readlink EXPR
3621
3622 =item readlink
3623
3624 Returns the value of a symbolic link, if symbolic links are
3625 implemented.  If not, gives a fatal error.  If there is some system
3626 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3627 omitted, uses C<$_>.
3628
3629 =item readpipe EXPR
3630
3631 EXPR is executed as a system command.
3632 The collected standard output of the command is returned.
3633 In scalar context, it comes back as a single (potentially
3634 multi-line) string.  In list context, returns a list of lines
3635 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3636 This is the internal function implementing the C<qx/EXPR/>
3637 operator, but you can use it directly.  The C<qx/EXPR/>
3638 operator is discussed in more detail in L<perlop/"I/O Operators">.
3639
3640 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3641
3642 Receives a message on a socket.  Attempts to receive LENGTH bytes of
3643 data into variable SCALAR from the specified SOCKET filehandle.  SCALAR
3644 will be grown or shrunk to the length actually read.  Takes the same
3645 flags as the system call of the same name.  Returns the address of the
3646 sender if SOCKET's protocol supports this; returns an empty string
3647 otherwise.  If there's an error, returns the undefined value.  This call
3648 is actually implemented in terms of recvfrom(2) system call.  See
3649 L<perlipc/"UDP: Message Passing"> for examples.
3650
3651 =item redo LABEL
3652
3653 =item redo
3654
3655 The C<redo> command restarts the loop block without evaluating the
3656 conditional again.  The C<continue> block, if any, is not executed.  If
3657 the LABEL is omitted, the command refers to the innermost enclosing
3658 loop.  This command is normally used by programs that want to lie to
3659 themselves about what was just input:
3660
3661     # a simpleminded Pascal comment stripper
3662     # (warning: assumes no { or } in strings)
3663     LINE: while (<STDIN>) {
3664         while (s|({.*}.*){.*}|$1 |) {}
3665         s|{.*}| |;
3666         if (s|{.*| |) {
3667             $front = $_;
3668             while (<STDIN>) {
3669                 if (/}/) {      # end of comment?
3670                     s|^|$front\{|;
3671                     redo LINE;
3672                 }
3673             }
3674         }
3675         print;
3676     }
3677
3678 C<redo> cannot be used to retry a block which returns a value such as
3679 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3680 a grep() or map() operation.
3681
3682 Note that a block by itself is semantically identical to a loop
3683 that executes once.  Thus C<redo> inside such a block will effectively
3684 turn it into a looping construct.
3685
3686 See also L</continue> for an illustration of how C<last>, C<next>, and
3687 C<redo> work.
3688
3689 =item ref EXPR
3690
3691 =item ref
3692
3693 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3694 is not specified, C<$_> will be used.  The value returned depends on the
3695 type of thing the reference is a reference to.
3696 Builtin types include:
3697
3698     SCALAR
3699     ARRAY
3700     HASH
3701     CODE
3702     REF
3703     GLOB
3704     LVALUE
3705
3706 If the referenced object has been blessed into a package, then that package
3707 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3708
3709     if (ref($r) eq "HASH") {
3710         print "r is a reference to a hash.\n";
3711     }
3712     unless (ref($r)) {
3713         print "r is not a reference at all.\n";
3714     }
3715     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3716         print "r is a reference to something that isa hash.\n";
3717     }
3718
3719 See also L<perlref>.
3720
3721 =item rename OLDNAME,NEWNAME
3722
3723 Changes the name of a file; an existing file NEWNAME will be
3724 clobbered.  Returns true for success, false otherwise.
3725
3726 Behavior of this function varies wildly depending on your system
3727 implementation.  For example, it will usually not work across file system
3728 boundaries, even though the system I<mv> command sometimes compensates
3729 for this.  Other restrictions include whether it works on directories,
3730 open files, or pre-existing files.  Check L<perlport> and either the
3731 rename(2) manpage or equivalent system documentation for details.
3732
3733 =item require VERSION
3734
3735 =item require EXPR
3736
3737 =item require
3738
3739 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
3740 supplied.
3741
3742 If a VERSION is specified as a literal of the form v5.6.1,
3743 demands that the current version of Perl (C<$^V> or $PERL_VERSION) be
3744 at least as recent as that version, at run time.  (For compatibility
3745 with older versions of Perl, a numeric argument will also be interpreted
3746 as VERSION.)  Compare with L</use>, which can do a similar check at
3747 compile time.
3748
3749     require v5.6.1;     # run time version check
3750     require 5.6.1;      # ditto
3751     require 5.005_03;   # float version allowed for compatibility
3752
3753 Otherwise, demands that a library file be included if it hasn't already
3754 been included.  The file is included via the do-FILE mechanism, which is
3755 essentially just a variety of C<eval>.  Has semantics similar to the following
3756 subroutine:
3757
3758     sub require {
3759         my($filename) = @_;
3760         return 1 if $INC{$filename};
3761         my($realfilename,$result);
3762         ITER: {
3763             foreach $prefix (@INC) {
3764                 $realfilename = "$prefix/$filename";
3765                 if (-f $realfilename) {
3766                     $INC{$filename} = $realfilename;
3767                     $result = do $realfilename;
3768                     last ITER;
3769                 }
3770             }
3771             die "Can't find $filename in \@INC";
3772         }
3773         delete $INC{$filename} if $@ || !$result;
3774         die $@ if $@;
3775         die "$filename did not return true value" unless $result;
3776         return $result;
3777     }
3778
3779 Note that the file will not be included twice under the same specified
3780 name.  The file must return true as the last statement to indicate
3781 successful execution of any initialization code, so it's customary to
3782 end such a file with C<1;> unless you're sure it'll return true
3783 otherwise.  But it's better just to put the C<1;>, in case you add more
3784 statements.
3785
3786 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3787 replaces "F<::>" with "F</>" in the filename for you,
3788 to make it easy to load standard modules.  This form of loading of
3789 modules does not risk altering your namespace.
3790
3791 In other words, if you try this:
3792
3793         require Foo::Bar;    # a splendid bareword
3794
3795 The require function will actually look for the "F<Foo/Bar.pm>" file in the
3796 directories specified in the C<@INC> array.
3797
3798 But if you try this:
3799
3800         $class = 'Foo::Bar';
3801         require $class;      # $class is not a bareword
3802     #or
3803         require "Foo::Bar";  # not a bareword because of the ""
3804
3805 The require function will look for the "F<Foo::Bar>" file in the @INC array and
3806 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3807
3808         eval "require $class";
3809
3810 You can also insert hooks into the import facility, by putting directly
3811 Perl code into the @INC array.  There are three forms of hooks: subroutine
3812 references, array references and blessed objects.
3813
3814 Subroutine references are the simplest case.  When the inclusion system
3815 walks through @INC and encounters a subroutine, this subroutine gets
3816 called with two parameters, the first being a reference to itself, and the
3817 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
3818 subroutine should return C<undef> or a filehandle, from which the file to
3819 include will be read.  If C<undef> is returned, C<require> will look at
3820 the remaining elements of @INC.
3821
3822 If the hook is an array reference, its first element must be a subroutine
3823 reference.  This subroutine is called as above, but the first parameter is
3824 the array reference.  This enables to pass indirectly some arguments to
3825 the subroutine.
3826
3827 In other words, you can write:
3828
3829     push @INC, \&my_sub;
3830     sub my_sub {
3831         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
3832         ...
3833     }
3834
3835 or:
3836
3837     push @INC, [ \&my_sub, $x, $y, ... ];
3838     sub my_sub {
3839         my ($arrayref, $filename) = @_;
3840         # Retrieve $x, $y, ...
3841         my @parameters = @$arrayref[1..$#$arrayref];
3842         ...
3843     }
3844
3845 If the hook is an object, it must provide an INC method, that will be
3846 called as above, the first parameter being the object itself.  (Note that
3847 you must fully qualify the sub's name, as it is always forced into package
3848 C<main>.)  Here is a typical code layout:
3849
3850     # In Foo.pm
3851     package Foo;
3852     sub new { ... }
3853     sub Foo::INC {
3854         my ($self, $filename) = @_;
3855         ...
3856     }
3857
3858     # In the main program
3859     push @INC, new Foo(...);
3860
3861 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3862
3863 =item reset EXPR
3864
3865 =item reset
3866
3867 Generally used in a C<continue> block at the end of a loop to clear
3868 variables and reset C<??> searches so that they work again.  The
3869 expression is interpreted as a list of single characters (hyphens
3870 allowed for ranges).  All variables and arrays beginning with one of
3871 those letters are reset to their pristine state.  If the expression is
3872 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3873 only variables or searches in the current package.  Always returns
3874 1.  Examples:
3875
3876     reset 'X';          # reset all X variables
3877     reset 'a-z';        # reset lower case variables
3878     reset;              # just reset ?one-time? searches
3879
3880 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3881 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
3882 variables--lexical variables are unaffected, but they clean themselves
3883 up on scope exit anyway, so you'll probably want to use them instead.
3884 See L</my>.
3885
3886 =item return EXPR
3887
3888 =item return
3889
3890 Returns from a subroutine, C<eval>, or C<do FILE> with the value
3891 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3892 context, depending on how the return value will be used, and the context
3893 may vary from one execution to the next (see C<wantarray>).  If no EXPR
3894 is given, returns an empty list in list context, the undefined value in
3895 scalar context, and (of course) nothing at all in a void context.
3896
3897 (Note that in the absence of a explicit C<return>, a subroutine, eval,
3898 or do FILE will automatically return the value of the last expression
3899 evaluated.)
3900
3901 =item reverse LIST
3902
3903 In list context, returns a list value consisting of the elements
3904 of LIST in the opposite order.  In scalar context, concatenates the
3905 elements of LIST and returns a string value with all characters
3906 in the opposite order.
3907
3908     print reverse <>;           # line tac, last line first
3909
3910     undef $/;                   # for efficiency of <>
3911     print scalar reverse <>;    # character tac, last line tsrif
3912
3913 This operator is also handy for inverting a hash, although there are some
3914 caveats.  If a value is duplicated in the original hash, only one of those
3915 can be represented as a key in the inverted hash.  Also, this has to
3916 unwind one hash and build a whole new one, which may take some time
3917 on a large hash, such as from a DBM file.
3918
3919     %by_name = reverse %by_address;     # Invert the hash
3920
3921 =item rewinddir DIRHANDLE
3922
3923 Sets the current position to the beginning of the directory for the
3924 C<readdir> routine on DIRHANDLE.
3925
3926 =item rindex STR,SUBSTR,POSITION
3927
3928 =item rindex STR,SUBSTR
3929
3930 Works just like index() except that it returns the position of the LAST
3931 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
3932 last occurrence at or before that position.
3933
3934 =item rmdir FILENAME
3935
3936 =item rmdir
3937
3938 Deletes the directory specified by FILENAME if that directory is empty.  If it
3939 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
3940 FILENAME is omitted, uses C<$_>.
3941
3942 =item s///
3943
3944 The substitution operator.  See L<perlop>.
3945
3946 =item scalar EXPR
3947
3948 Forces EXPR to be interpreted in scalar context and returns the value
3949 of EXPR.
3950
3951     @counts = ( scalar @a, scalar @b, scalar @c );
3952
3953 There is no equivalent operator to force an expression to
3954 be interpolated in list context because in practice, this is never
3955 needed.  If you really wanted to do so, however, you could use
3956 the construction C<@{[ (some expression) ]}>, but usually a simple
3957 C<(some expression)> suffices.
3958
3959 Because C<scalar> is unary operator, if you accidentally use for EXPR a
3960 parenthesized list, this behaves as a scalar comma expression, evaluating
3961 all but the last element in void context and returning the final element
3962 evaluated in scalar context.  This is seldom what you want.
3963
3964 The following single statement:
3965
3966         print uc(scalar(&foo,$bar)),$baz;
3967
3968 is the moral equivalent of these two:
3969
3970         &foo;
3971         print(uc($bar),$baz);
3972
3973 See L<perlop> for more details on unary operators and the comma operator.
3974
3975 =item seek FILEHANDLE,POSITION,WHENCE
3976
3977 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
3978 FILEHANDLE may be an expression whose value gives the name of the
3979 filehandle.  The values for WHENCE are C<0> to set the new position to
3980 POSITION, C<1> to set it to the current position plus POSITION, and
3981 C<2> to set it to EOF plus POSITION (typically negative).  For WHENCE
3982 you may use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END>
3983 (start of the file, current position, end of the file) from the Fcntl
3984 module.  Returns C<1> upon success, C<0> otherwise.
3985
3986 If you want to position file for C<sysread> or C<syswrite>, don't use
3987 C<seek>--buffering makes its effect on the file's system position
3988 unpredictable and non-portable.  Use C<sysseek> instead.
3989
3990 Due to the rules and rigors of ANSI C, on some systems you have to do a
3991 seek whenever you switch between reading and writing.  Amongst other
3992 things, this may have the effect of calling stdio's clearerr(3).
3993 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
3994
3995     seek(TEST,0,1);
3996
3997 This is also useful for applications emulating C<tail -f>.  Once you hit
3998 EOF on your read, and then sleep for a while, you might have to stick in a
3999 seek() to reset things.  The C<seek> doesn't change the current position,
4000 but it I<does> clear the end-of-file condition on the handle, so that the
4001 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4002
4003 If that doesn't work (some stdios are particularly cantankerous), then
4004 you may need something more like this:
4005
4006     for (;;) {
4007         for ($curpos = tell(FILE); $_ = <FILE>;
4008              $curpos = tell(FILE)) {
4009             # search for some stuff and put it into files
4010         }
4011         sleep($for_a_while);
4012         seek(FILE, $curpos, 0);
4013     }
4014
4015 =item seekdir DIRHANDLE,POS
4016
4017 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4018 must be a value returned by C<telldir>.  Has the same caveats about
4019 possible directory compaction as the corresponding system library
4020 routine.
4021
4022 =item select FILEHANDLE
4023
4024 =item select
4025
4026 Returns the currently selected filehandle.  Sets the current default
4027 filehandle for output, if FILEHANDLE is supplied.  This has two
4028 effects: first, a C<write> or a C<print> without a filehandle will
4029 default to this FILEHANDLE.  Second, references to variables related to
4030 output will refer to this output channel.  For example, if you have to
4031 set the top of form format for more than one output channel, you might
4032 do the following:
4033
4034     select(REPORT1);
4035     $^ = 'report1_top';
4036     select(REPORT2);
4037     $^ = 'report2_top';
4038
4039 FILEHANDLE may be an expression whose value gives the name of the
4040 actual filehandle.  Thus:
4041
4042     $oldfh = select(STDERR); $| = 1; select($oldfh);
4043
4044 Some programmers may prefer to think of filehandles as objects with
4045 methods, preferring to write the last example as:
4046
4047     use IO::Handle;
4048     STDERR->autoflush(1);
4049
4050 =item select RBITS,WBITS,EBITS,TIMEOUT
4051
4052 This calls the select(2) system call with the bit masks specified, which
4053 can be constructed using C<fileno> and C<vec>, along these lines:
4054
4055     $rin = $win = $ein = '';
4056     vec($rin,fileno(STDIN),1) = 1;
4057     vec($win,fileno(STDOUT),1) = 1;
4058     $ein = $rin | $win;
4059
4060 If you want to select on many filehandles you might wish to write a
4061 subroutine:
4062
4063     sub fhbits {
4064         my(@fhlist) = split(' ',$_[0]);
4065         my($bits);
4066         for (@fhlist) {
4067             vec($bits,fileno($_),1) = 1;
4068         }
4069         $bits;
4070     }
4071     $rin = fhbits('STDIN TTY SOCK');
4072
4073 The usual idiom is:
4074
4075     ($nfound,$timeleft) =
4076       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4077
4078 or to block until something becomes ready just do this
4079
4080     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4081
4082 Most systems do not bother to return anything useful in $timeleft, so
4083 calling select() in scalar context just returns $nfound.
4084
4085 Any of the bit masks can also be undef.  The timeout, if specified, is
4086 in seconds, which may be fractional.  Note: not all implementations are
4087 capable of returning the$timeleft.  If not, they always return
4088 $timeleft equal to the supplied $timeout.
4089
4090 You can effect a sleep of 250 milliseconds this way:
4091
4092     select(undef, undef, undef, 0.25);
4093
4094 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4095 or <FH>) with C<select>, except as permitted by POSIX, and even
4096 then only on POSIX systems.  You have to use C<sysread> instead.
4097
4098 =item semctl ID,SEMNUM,CMD,ARG
4099
4100 Calls the System V IPC function C<semctl>.  You'll probably have to say
4101
4102     use IPC::SysV;
4103
4104 first to get the correct constant definitions.  If CMD is IPC_STAT or
4105 GETALL, then ARG must be a variable which will hold the returned
4106 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4107 the undefined value for error, "C<0 but true>" for zero, or the actual
4108 return value otherwise.  The ARG must consist of a vector of native
4109 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4110 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4111 documentation.
4112
4113 =item semget KEY,NSEMS,FLAGS
4114
4115 Calls the System V IPC function semget.  Returns the semaphore id, or
4116 the undefined value if there is an error.  See also
4117 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4118 documentation.
4119
4120 =item semop KEY,OPSTRING
4121
4122 Calls the System V IPC function semop to perform semaphore operations
4123 such as signalling and waiting.  OPSTRING must be a packed array of
4124 semop structures.  Each semop structure can be generated with
4125 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4126 operations is implied by the length of OPSTRING.  Returns true if
4127 successful, or false if there is an error.  As an example, the
4128 following code waits on semaphore $semnum of semaphore id $semid:
4129
4130     $semop = pack("s!3", $semnum, -1, 0);
4131     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4132
4133 To signal the semaphore, replace C<-1> with C<1>.  See also
4134 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4135 documentation.
4136
4137 =item send SOCKET,MSG,FLAGS,TO
4138
4139 =item send SOCKET,MSG,FLAGS
4140
4141 Sends a message on a socket.  Takes the same flags as the system call
4142 of the same name.  On unconnected sockets you must specify a
4143 destination to send TO, in which case it does a C C<sendto>.  Returns
4144 the number of characters sent, or the undefined value if there is an
4145 error.  The C system call sendmsg(2) is currently unimplemented.
4146 See L<perlipc/"UDP: Message Passing"> for examples.
4147
4148 =item setpgrp PID,PGRP
4149
4150 Sets the current process group for the specified PID, C<0> for the current
4151 process.  Will produce a fatal error if used on a machine that doesn't
4152 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4153 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4154 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4155 C<POSIX::setsid()>.
4156
4157 =item setpriority WHICH,WHO,PRIORITY
4158
4159 Sets the current priority for a process, a process group, or a user.
4160 (See setpriority(2).)  Will produce a fatal error if used on a machine
4161 that doesn't implement setpriority(2).
4162
4163 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4164
4165 Sets the socket option requested.  Returns undefined if there is an
4166 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4167 argument.
4168
4169 =item shift ARRAY
4170
4171 =item shift
4172
4173 Shifts the first value of the array off and returns it, shortening the
4174 array by 1 and moving everything down.  If there are no elements in the
4175 array, returns the undefined value.  If ARRAY is omitted, shifts the
4176 C<@_> array within the lexical scope of subroutines and formats, and the
4177 C<@ARGV> array at file scopes or within the lexical scopes established by
4178 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4179 constructs.
4180
4181 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4182 same thing to the left end of an array that C<pop> and C<push> do to the
4183 right end.
4184
4185 =item shmctl ID,CMD,ARG
4186
4187 Calls the System V IPC function shmctl.  You'll probably have to say
4188
4189     use IPC::SysV;
4190
4191 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4192 then ARG must be a variable which will hold the returned C<shmid_ds>
4193 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4194 true" for zero, or the actual return value otherwise.
4195 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4196
4197 =item shmget KEY,SIZE,FLAGS
4198
4199 Calls the System V IPC function shmget.  Returns the shared memory
4200 segment id, or the undefined value if there is an error.
4201 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4202
4203 =item shmread ID,VAR,POS,SIZE
4204
4205 =item shmwrite ID,STRING,POS,SIZE
4206
4207 Reads or writes the System V shared memory segment ID starting at
4208 position POS for size SIZE by attaching to it, copying in/out, and
4209 detaching from it.  When reading, VAR must be a variable that will
4210 hold the data read.  When writing, if STRING is too long, only SIZE
4211 bytes are used; if STRING is too short, nulls are written to fill out
4212 SIZE bytes.  Return true if successful, or false if there is an error.
4213 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4214 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4215
4216 =item shutdown SOCKET,HOW
4217
4218 Shuts down a socket connection in the manner indicated by HOW, which
4219 has the same interpretation as in the system call of the same name.
4220
4221     shutdown(SOCKET, 0);    # I/we have stopped reading data
4222     shutdown(SOCKET, 1);    # I/we have stopped writing data
4223     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4224
4225 This is useful with sockets when you want to tell the other
4226 side you're done writing but not done reading, or vice versa.
4227 It's also a more insistent form of close because it also
4228 disables the file descriptor in any forked copies in other
4229 processes.
4230
4231 =item sin EXPR
4232
4233 =item sin
4234
4235 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4236 returns sine of C<$_>.
4237
4238 For the inverse sine operation, you may use the C<Math::Trig::asin>
4239 function, or use this relation:
4240
4241     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4242
4243 =item sleep EXPR
4244
4245 =item sleep
4246
4247 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4248 May be interrupted if the process receives a signal such as C<SIGALRM>.
4249 Returns the number of seconds actually slept.  You probably cannot
4250 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4251 using C<alarm>.
4252
4253 On some older systems, it may sleep up to a full second less than what
4254 you requested, depending on how it counts seconds.  Most modern systems
4255 always sleep the full amount.  They may appear to sleep longer than that,
4256 however, because your process might not be scheduled right away in a
4257 busy multitasking system.
4258
4259 For delays of finer granularity than one second, you may use Perl's
4260 C<syscall> interface to access setitimer(2) if your system supports
4261 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
4262 and starting from Perl 5.8 part of the standard distribution) may also
4263 help.
4264
4265 See also the POSIX module's C<pause> function.
4266
4267 =item sockatmark SOCKET
4268
4269 Returns true if the socket is positioned at the out-of-band mark
4270 (also known as the urgent data mark), false otherwise.  Use right
4271 after reading from the socket.
4272
4273 Not available directly, one has to import the function from
4274 the IO::Socket extension
4275
4276     use IO::Socket 'sockatmark';
4277
4278 Even this doesn't guarantee that sockatmark() really is available,
4279 though, because sockatmark() is a relatively recent addition to
4280 the family of socket functions.  If it is unavailable, attempt to
4281 use it will fail
4282
4283         IO::Socket::atmark not implemented on this architecture ...
4284
4285 See also L<IO::Socket>.
4286
4287 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4288
4289 Opens a socket of the specified kind and attaches it to filehandle
4290 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4291 the system call of the same name.  You should C<use Socket> first
4292 to get the proper definitions imported.  See the examples in
4293 L<perlipc/"Sockets: Client/Server Communication">.
4294
4295 On systems that support a close-on-exec flag on files, the flag will
4296 be set for the newly opened file descriptor, as determined by the
4297 value of $^F.  See L<perlvar/$^F>.
4298
4299 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4300
4301 Creates an unnamed pair of sockets in the specified domain, of the
4302 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4303 for the system call of the same name.  If unimplemented, yields a fatal
4304 error.  Returns true if successful.
4305
4306 On systems that support a close-on-exec flag on files, the flag will
4307 be set for the newly opened file descriptors, as determined by the value
4308 of $^F.  See L<perlvar/$^F>.
4309
4310 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4311 to C<pipe(Rdr, Wtr)> is essentially:
4312
4313     use Socket;
4314     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4315     shutdown(Rdr, 1);        # no more writing for reader
4316     shutdown(Wtr, 0);        # no more reading for writer
4317
4318 See L<perlipc> for an example of socketpair use.
4319
4320 =item sort SUBNAME LIST
4321
4322 =item sort BLOCK LIST
4323
4324 =item sort LIST
4325
4326 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
4327 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
4328 specified, it gives the name of a subroutine that returns an integer
4329 less than, equal to, or greater than C<0>, depending on how the elements
4330 of the list are to be ordered.  (The C<< <=> >> and C<cmp>
4331 operators are extremely useful in such routines.)  SUBNAME may be a
4332 scalar variable name (unsubscripted), in which case the value provides
4333 the name of (or a reference to) the actual subroutine to use.  In place
4334 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
4335 subroutine.
4336
4337 If the subroutine's prototype is C<($$)>, the elements to be compared
4338 are passed by reference in C<@_>, as for a normal subroutine.  This is
4339 slower than unprototyped subroutines, where the elements to be
4340 compared are passed into the subroutine
4341 as the package global variables $a and $b (see example below).  Note that
4342 in the latter case, it is usually counter-productive to declare $a and
4343 $b as lexicals.
4344
4345 In either case, the subroutine may not be recursive.  The values to be
4346 compared are always passed by reference, so don't modify them.
4347
4348 You also cannot exit out of the sort block or subroutine using any of the
4349 loop control operators described in L<perlsyn> or with C<goto>.
4350
4351 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4352 current collation locale.  See L<perllocale>.
4353
4354 Perl does B<not> guarantee that sort is stable.  (A I<stable> sort
4355 preserves the input order of elements that compare equal.)  5.7 and
4356 5.8 happen to use a stable mergesort, but 5.6 and earlier used quicksort,
4357 which is not stable.  Do not assume that future perls will continue to
4358 use a stable sort.
4359
4360 Examples:
4361
4362     # sort lexically
4363     @articles = sort @files;
4364
4365     # same thing, but with explicit sort routine
4366     @articles = sort {$a cmp $b} @files;
4367
4368     # now case-insensitively
4369     @articles = sort {uc($a) cmp uc($b)} @files;
4370
4371     # same thing in reversed order
4372     @articles = sort {$b cmp $a} @files;
4373
4374     # sort numerically ascending
4375     @articles = sort {$a <=> $b} @files;
4376
4377     # sort numerically descending
4378     @articles = sort {$b <=> $a} @files;
4379
4380     # this sorts the %age hash by value instead of key
4381     # using an in-line function
4382     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4383
4384     # sort using explicit subroutine name
4385     sub byage {
4386         $age{$a} <=> $age{$b};  # presuming numeric
4387     }
4388     @sortedclass = sort byage @class;
4389
4390     sub backwards { $b cmp $a }
4391     @harry  = qw(dog cat x Cain Abel);
4392     @george = qw(gone chased yz Punished Axed);
4393     print sort @harry;
4394             # prints AbelCaincatdogx
4395     print sort backwards @harry;
4396             # prints xdogcatCainAbel
4397     print sort @george, 'to', @harry;
4398             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4399
4400     # inefficiently sort by descending numeric compare using
4401     # the first integer after the first = sign, or the
4402     # whole record case-insensitively otherwise
4403
4404     @new = sort {
4405         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4406                             ||
4407                     uc($a)  cmp  uc($b)
4408     } @old;
4409
4410     # same thing, but much more efficiently;
4411     # we'll build auxiliary indices instead
4412     # for speed
4413     @nums = @caps = ();
4414     for (@old) {
4415         push @nums, /=(\d+)/;
4416         push @caps, uc($_);
4417     }
4418
4419     @new = @old[ sort {
4420                         $nums[$b] <=> $nums[$a]
4421                                  ||
4422                         $caps[$a] cmp $caps[$b]
4423                        } 0..$#old
4424                ];
4425
4426     # same thing, but without any temps
4427     @new = map { $_->[0] }
4428            sort { $b->[1] <=> $a->[1]
4429                            ||
4430                   $a->[2] cmp $b->[2]
4431            } map { [$_, /=(\d+)/, uc($_)] } @old;
4432
4433     # using a prototype allows you to use any comparison subroutine
4434     # as a sort subroutine (including other package's subroutines)
4435     package other;
4436     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4437
4438     package main;
4439     @new = sort other::backwards @old;
4440
4441 If you're using strict, you I<must not> declare $a
4442 and $b as lexicals.  They are package globals.  That means
4443 if you're in the C<main> package and type
4444
4445     @articles = sort {$b <=> $a} @files;
4446
4447 then C<$a> and C<$b> are C<$main::a> and C<$main::b> (or C<$::a> and C<$::b>),
4448 but if you're in the C<FooPack> package, it's the same as typing
4449
4450     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
4451
4452 The comparison function is required to behave.  If it returns
4453 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4454 sometimes saying the opposite, for example) the results are not
4455 well-defined.
4456
4457 =item splice ARRAY,OFFSET,LENGTH,LIST
4458
4459 =item splice ARRAY,OFFSET,LENGTH
4460
4461 =item splice ARRAY,OFFSET
4462
4463 =item splice ARRAY
4464
4465 Removes the elements designated by OFFSET and LENGTH from an array, and
4466 replaces them with the elements of LIST, if any.  In list context,
4467 returns the elements removed from the array.  In scalar context,
4468 returns the last element removed, or C<undef> if no elements are
4469 removed.  The array grows or shrinks as necessary.
4470 If OFFSET is negative then it starts that far from the end of the array.
4471 If LENGTH is omitted, removes everything from OFFSET onward.
4472 If LENGTH is negative, leaves that many elements off the end of the array.
4473 If both OFFSET and LENGTH are omitted, removes everything.
4474
4475 The following equivalences hold (assuming C<$[ == 0>):
4476
4477     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
4478     pop(@a)             splice(@a,-1)
4479     shift(@a)           splice(@a,0,1)
4480     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
4481     $a[$x] = $y         splice(@a,$x,1,$y)
4482
4483 Example, assuming array lengths are passed before arrays:
4484
4485     sub aeq {   # compare two list values
4486         my(@a) = splice(@_,0,shift);
4487         my(@b) = splice(@_,0,shift);
4488         return 0 unless @a == @b;       # same len?
4489         while (@a) {
4490             return 0 if pop(@a) ne pop(@b);
4491         }
4492         return 1;
4493     }
4494     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
4495
4496 =item split /PATTERN/,EXPR,LIMIT
4497
4498 =item split /PATTERN/,EXPR
4499
4500 =item split /PATTERN/
4501
4502 =item split
4503
4504 Splits a string into a list of strings and returns that list.  By default,
4505 empty leading fields are preserved, and empty trailing ones are deleted.
4506
4507 In scalar context, returns the number of fields found and splits into
4508 the C<@_> array.  Use of split in scalar context is deprecated, however,
4509 because it clobbers your subroutine arguments.
4510
4511 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
4512 splits on whitespace (after skipping any leading whitespace).  Anything
4513 matching PATTERN is taken to be a delimiter separating the fields.  (Note
4514 that the delimiter may be longer than one character.)
4515
4516 If LIMIT is specified and positive, it represents the maximum number
4517 of fields the EXPR will be split into, though the actual number of
4518 fields returned depends on the number of times PATTERN matches within
4519 EXPR.  If LIMIT is unspecified or zero, trailing null fields are
4520 stripped (which potential users of C<pop> would do well to remember).
4521 If LIMIT is negative, it is treated as if an arbitrarily large LIMIT
4522 had been specified.  Note that splitting an EXPR that evaluates to the
4523 empty string always returns the empty list, regardless of the LIMIT
4524 specified.
4525
4526 A pattern matching the null string (not to be confused with
4527 a null pattern C<//>, which is just one member of the set of patterns
4528 matching a null string) will split the value of EXPR into separate
4529 characters at each point it matches that way.  For example:
4530
4531     print join(':', split(/ */, 'hi there'));
4532
4533 produces the output 'h:i:t:h:e:r:e'.
4534
4535 Using the empty pattern C<//> specifically matches the null string, and is
4536 not be confused with the use of C<//> to mean "the last successful pattern
4537 match".
4538
4539 Empty leading (or trailing) fields are produced when there positive width
4540 matches at the beginning (or end) of the string; a zero-width match at the
4541 beginning (or end) of the string does not produce an empty field.  For
4542 example:
4543
4544    print join(':', split(/(?=\w)/, 'hi there!'));
4545
4546 produces the output 'h:i :t:h:e:r:e!'.
4547
4548 The LIMIT parameter can be used to split a line partially
4549
4550     ($login, $passwd, $remainder) = split(/:/, $_, 3);
4551
4552 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
4553 one larger than the number of variables in the list, to avoid
4554 unnecessary work.  For the list above LIMIT would have been 4 by
4555 default.  In time critical applications it behooves you not to split
4556 into more fields than you really need.
4557
4558 If the PATTERN contains parentheses, additional list elements are
4559 created from each matching substring in the delimiter.
4560
4561     split(/([,-])/, "1-10,20", 3);
4562
4563 produces the list value
4564
4565     (1, '-', 10, ',', 20)
4566
4567 If you had the entire header of a normal Unix email message in $header,
4568 you could split it up into fields and their values this way:
4569
4570     $header =~ s/\n\s+/ /g;  # fix continuation lines
4571     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
4572
4573 The pattern C</PATTERN/> may be replaced with an expression to specify
4574 patterns that vary at runtime.  (To do runtime compilation only once,
4575 use C</$variable/o>.)
4576
4577 As a special case, specifying a PATTERN of space (C<' '>) will split on
4578 white space just as C<split> with no arguments does.  Thus, C<split(' ')> can
4579 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
4580 will give you as many null initial fields as there are leading spaces.
4581 A C<split> on C</\s+/> is like a C<split(' ')> except that any leading
4582 whitespace produces a null first field.  A C<split> with no arguments
4583 really does a C<split(' ', $_)> internally.
4584
4585 A PATTERN of C</^/> is treated as if it were C</^/m>, since it isn't
4586 much use otherwise.
4587
4588 Example:
4589
4590     open(PASSWD, '/etc/passwd');
4591     while (<PASSWD>) {
4592         chomp;
4593         ($login, $passwd, $uid, $gid,
4594          $gcos, $home, $shell) = split(/:/);
4595         #...
4596     }
4597
4598 As with regular pattern matching, any capturing parentheses that are not
4599 matched in a C<split()> will be set to C<undef> when returned:
4600
4601     @fields = split /(A)|B/, "1A2B3";
4602     # @fields is (1, 'A', 2, undef, 3)
4603
4604 =item sprintf FORMAT, LIST
4605
4606 Returns a string formatted by the usual C<printf> conventions of the C
4607 library function C<sprintf>.  See below for more details
4608 and see L<sprintf(3)> or L<printf(3)> on your system for an explanation of
4609 the general principles.
4610
4611 For example:
4612
4613         # Format number with up to 8 leading zeroes
4614         $result = sprintf("%08d", $number);
4615
4616         # Round number to 3 digits after decimal point
4617         $rounded = sprintf("%.3f", $number);
4618
4619 Perl does its own C<sprintf> formatting--it emulates the C
4620 function C<sprintf>, but it doesn't use it (except for floating-point
4621 numbers, and even then only the standard modifiers are allowed).  As a
4622 result, any non-standard extensions in your local C<sprintf> are not
4623 available from Perl.
4624
4625 Unlike C<printf>, C<sprintf> does not do what you probably mean when you
4626 pass it an array as your first argument. The array is given scalar context,
4627 and instead of using the 0th element of the array as the format, Perl will
4628 use the count of elements in the array as the format, which is almost never
4629 useful.
4630
4631 Perl's C<sprintf> permits the following universally-known conversions:
4632
4633    %%   a percent sign
4634    %c   a character with the given number
4635    %s   a string
4636    %d   a signed integer, in decimal
4637    %u   an unsigned integer, in decimal
4638    %o   an unsigned integer, in octal
4639    %x   an unsigned integer, in hexadecimal
4640    %e   a floating-point number, in scientific notation
4641    %f   a floating-point number, in fixed decimal notation
4642    %g   a floating-point number, in %e or %f notation
4643
4644 In addition, Perl permits the following widely-supported conversions:
4645
4646    %X   like %x, but using upper-case letters
4647    %E   like %e, but using an upper-case "E"
4648    %G   like %g, but with an upper-case "E" (if applicable)
4649    %b   an unsigned integer, in binary
4650    %p   a pointer (outputs the Perl value's address in hexadecimal)
4651    %n   special: *stores* the number of characters output so far
4652         into the next variable in the parameter list
4653
4654 Finally, for backward (and we do mean "backward") compatibility, Perl
4655 permits these unnecessary but widely-supported conversions:
4656