This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
06388fdc94346ef6bc258ecc5a335d3139097c16
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  Also are new (in 5.14) character set semantics
83 modifiers B<C<<"a">>, B<C<"d">>, B<C<"l">> and B<C<"u">>, which, in 5.14
84 only, must be used embedded in the regular expression, and not after the
85 trailing delimiter.  All this is discussed below in
86 L</Extended Patterns>.
87 X</a> X</d> X</l> X</u>
88
89 The C</x> modifier itself needs a little more explanation.  It tells
90 the regular expression parser to ignore most whitespace that is neither
91 backslashed nor within a character class.  You can use this to break up
92 your regular expression into (slightly) more readable parts.  The C<#>
93 character is also treated as a metacharacter introducing a comment,
94 just as in ordinary Perl code.  This also means that if you want real
95 whitespace or C<#> characters in the pattern (outside a character
96 class, where they are unaffected by C</x>), then you'll either have to
97 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
98 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
99 making Perl's regular expressions more readable.  Note that you have to
100 be careful not to include the pattern delimiter in the comment--perl has
101 no way of knowing you did not intend to close the pattern early.  See
102 the C-comment deletion code in L<perlop>.  Also note that anything inside
103 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
104 whether space interpretation within a single multi-character construct.  For
105 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
106 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
107 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
108 but can between the C<(> and C<?>.  Within any delimiters for such a
109 construct, allowed spaces are not affected by C</x>, and depend on the
110 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
111 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
112 in C<\p{...}>  there can be spaces that follow the Unicode rules, for which see
113 L<perluniprops/Properties accessible through \p{} and \P{}>.
114 X</x>
115
116 =head2 Regular Expressions
117
118 =head3 Metacharacters
119
120 The patterns used in Perl pattern matching evolved from those supplied in
121 the Version 8 regex routines.  (The routines are derived
122 (distantly) from Henry Spencer's freely redistributable reimplementation
123 of the V8 routines.)  See L<Version 8 Regular Expressions> for
124 details.
125
126 In particular the following metacharacters have their standard I<egrep>-ish
127 meanings:
128 X<metacharacter>
129 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
130
131
132     \        Quote the next metacharacter
133     ^        Match the beginning of the line
134     .        Match any character (except newline)
135     $        Match the end of the line (or before newline at the end)
136     |        Alternation
137     ()       Grouping
138     []       Bracketed Character class
139
140 By default, the "^" character is guaranteed to match only the
141 beginning of the string, the "$" character only the end (or before the
142 newline at the end), and Perl does certain optimizations with the
143 assumption that the string contains only one line.  Embedded newlines
144 will not be matched by "^" or "$".  You may, however, wish to treat a
145 string as a multi-line buffer, such that the "^" will match after any
146 newline within the string (except if the newline is the last character in
147 the string), and "$" will match before any newline.  At the
148 cost of a little more overhead, you can do this by using the /m modifier
149 on the pattern match operator.  (Older programs did this by setting C<$*>,
150 but this practice has been removed in perl 5.9.)
151 X<^> X<$> X</m>
152
153 To simplify multi-line substitutions, the "." character never matches a
154 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
155 the string is a single line--even if it isn't.
156 X<.> X</s>
157
158 =head3 Quantifiers
159
160 The following standard quantifiers are recognized:
161 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
162
163     *           Match 0 or more times
164     +           Match 1 or more times
165     ?           Match 1 or 0 times
166     {n}         Match exactly n times
167     {n,}        Match at least n times
168     {n,m}       Match at least n but not more than m times
169
170 (If a curly bracket occurs in any other context, it is treated
171 as a regular character.  In particular, the lower bound
172 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
173 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
174 to non-negative integral values less than a preset limit defined when perl is built.
175 This is usually 32766 on the most common platforms.  The actual limit can
176 be seen in the error message generated by code such as this:
177
178     $_ **= $_ , / {$_} / for 2 .. 42;
179
180 By default, a quantified subpattern is "greedy", that is, it will match as
181 many times as possible (given a particular starting location) while still
182 allowing the rest of the pattern to match.  If you want it to match the
183 minimum number of times possible, follow the quantifier with a "?".  Note
184 that the meanings don't change, just the "greediness":
185 X<metacharacter> X<greedy> X<greediness>
186 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
187
188     *?        Match 0 or more times, not greedily
189     +?        Match 1 or more times, not greedily
190     ??        Match 0 or 1 time, not greedily
191     {n}?      Match exactly n times, not greedily
192     {n,}?     Match at least n times, not greedily
193     {n,m}?    Match at least n but not more than m times, not greedily
194
195 By default, when a quantified subpattern does not allow the rest of the
196 overall pattern to match, Perl will backtrack. However, this behaviour is
197 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
198 as well.
199
200  *+     Match 0 or more times and give nothing back
201  ++     Match 1 or more times and give nothing back
202  ?+     Match 0 or 1 time and give nothing back
203  {n}+   Match exactly n times and give nothing back (redundant)
204  {n,}+  Match at least n times and give nothing back
205  {n,m}+ Match at least n but not more than m times and give nothing back
206
207 For instance,
208
209    'aaaa' =~ /a++a/
210
211 will never match, as the C<a++> will gobble up all the C<a>'s in the
212 string and won't leave any for the remaining part of the pattern. This
213 feature can be extremely useful to give perl hints about where it
214 shouldn't backtrack. For instance, the typical "match a double-quoted
215 string" problem can be most efficiently performed when written as:
216
217    /"(?:[^"\\]++|\\.)*+"/
218
219 as we know that if the final quote does not match, backtracking will not
220 help. See the independent subexpression C<< (?>...) >> for more details;
221 possessive quantifiers are just syntactic sugar for that construct. For
222 instance the above example could also be written as follows:
223
224    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
225
226 =head3 Escape sequences
227
228 Because patterns are processed as double quoted strings, the following
229 also work:
230
231  \t          tab                   (HT, TAB)
232  \n          newline               (LF, NL)
233  \r          return                (CR)
234  \f          form feed             (FF)
235  \a          alarm (bell)          (BEL)
236  \e          escape (think troff)  (ESC)
237  \cK         control char          (example: VT)
238  \x{}, \x00  character whose ordinal is the given hexadecimal number
239  \N{name}    named Unicode character or character sequence
240  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
241  \o{}, \000  character whose ordinal is the given octal number
242  \l          lowercase next char (think vi)
243  \u          uppercase next char (think vi)
244  \L          lowercase till \E (think vi)
245  \U          uppercase till \E (think vi)
246  \Q          quote (disable) pattern metacharacters till \E
247  \E          end either case modification or quoted section, think vi
248
249 Details are in L<perlop/Quote and Quote-like Operators>.
250
251 =head3 Character Classes and other Special Escapes
252
253 In addition, Perl defines the following:
254 X<\g> X<\k> X<\K> X<backreference>
255
256  Sequence   Note    Description
257   [...]     [1]  Match a character according to the rules of the
258                    bracketed character class defined by the "...".
259                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
260   [[:...:]] [2]  Match a character according to the rules of the POSIX
261                    character class "..." within the outer bracketed
262                    character class.  Example: [[:upper:]] matches any
263                    uppercase character.
264   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
265                    other connector punctuation chars plus Unicode
266                    marks
267   \W        [3]  Match a non-"word" character
268   \s        [3]  Match a whitespace character
269   \S        [3]  Match a non-whitespace character
270   \d        [3]  Match a decimal digit character
271   \D        [3]  Match a non-digit character
272   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
273   \PP       [3]  Match non-P
274   \X        [4]  Match Unicode "eXtended grapheme cluster"
275   \C             Match a single C-language char (octet) even if that is
276                    part of a larger UTF-8 character.  Thus it breaks up
277                    characters into their UTF-8 bytes, so you may end up
278                    with malformed pieces of UTF-8.  Unsupported in
279                    lookbehind.
280   \1        [5]  Backreference to a specific capture group or buffer.
281                    '1' may actually be any positive integer.
282   \g1       [5]  Backreference to a specific or previous group,
283   \g{-1}    [5]  The number may be negative indicating a relative
284                    previous group and may optionally be wrapped in
285                    curly brackets for safer parsing.
286   \g{name}  [5]  Named backreference
287   \k<name>  [5]  Named backreference
288   \K        [6]  Keep the stuff left of the \K, don't include it in $&
289   \N        [7]  Any character but \n (experimental).  Not affected by
290                    /s modifier
291   \v        [3]  Vertical whitespace
292   \V        [3]  Not vertical whitespace
293   \h        [3]  Horizontal whitespace
294   \H        [3]  Not horizontal whitespace
295   \R        [4]  Linebreak
296
297 =over 4
298
299 =item [1]
300
301 See L<perlrecharclass/Bracketed Character Classes> for details.
302
303 =item [2]
304
305 See L<perlrecharclass/POSIX Character Classes> for details.
306
307 =item [3]
308
309 See L<perlrecharclass/Backslash sequences> for details.
310
311 =item [4]
312
313 See L<perlrebackslash/Misc> for details.
314
315 =item [5]
316
317 See L</Capture groups> below for details.
318
319 =item [6]
320
321 See L</Extended Patterns> below for details.
322
323 =item [7]
324
325 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
326 character or character sequence whose name is C<NAME>; and similarly
327 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
328 code point is I<hex>.  Otherwise it matches any character but C<\n>.
329
330 =back
331
332 =head3 Assertions
333
334 Perl defines the following zero-width assertions:
335 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
336 X<regexp, zero-width assertion>
337 X<regular expression, zero-width assertion>
338 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
339
340     \b  Match a word boundary
341     \B  Match except at a word boundary
342     \A  Match only at beginning of string
343     \Z  Match only at end of string, or before newline at the end
344     \z  Match only at end of string
345     \G  Match only at pos() (e.g. at the end-of-match position
346         of prior m//g)
347
348 A word boundary (C<\b>) is a spot between two characters
349 that has a C<\w> on one side of it and a C<\W> on the other side
350 of it (in either order), counting the imaginary characters off the
351 beginning and end of the string as matching a C<\W>.  (Within
352 character classes C<\b> represents backspace rather than a word
353 boundary, just as it normally does in any double-quoted string.)
354 The C<\A> and C<\Z> are just like "^" and "$", except that they
355 won't match multiple times when the C</m> modifier is used, while
356 "^" and "$" will match at every internal line boundary.  To match
357 the actual end of the string and not ignore an optional trailing
358 newline, use C<\z>.
359 X<\b> X<\A> X<\Z> X<\z> X</m>
360
361 The C<\G> assertion can be used to chain global matches (using
362 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
363 It is also useful when writing C<lex>-like scanners, when you have
364 several patterns that you want to match against consequent substrings
365 of your string, see the previous reference.  The actual location
366 where C<\G> will match can also be influenced by using C<pos()> as
367 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
368 matches is modified somewhat, in that contents to the left of C<\G> is
369 not counted when determining the length of the match. Thus the following
370 will not match forever:
371 X<\G>
372
373      my $string = 'ABC';
374      pos($string) = 1;
375      while ($string =~ /(.\G)/g) {
376          print $1;
377      }
378
379 It will print 'A' and then terminate, as it considers the match to
380 be zero-width, and thus will not match at the same position twice in a
381 row.
382
383 It is worth noting that C<\G> improperly used can result in an infinite
384 loop. Take care when using patterns that include C<\G> in an alternation.
385
386 =head3 Capture groups
387
388 The bracketing construct C<( ... )> creates capture groups (also referred to as
389 capture buffers). To refer to the current contents of a group later on, within
390 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
391 for the second, and so on.
392 This is called a I<backreference>.
393 X<regex, capture buffer> X<regexp, capture buffer>
394 X<regex, capture group> X<regexp, capture group>
395 X<regular expression, capture buffer> X<backreference>
396 X<regular expression, capture group> X<backreference>
397 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
398 X<named capture buffer> X<regular expression, named capture buffer>
399 X<named capture group> X<regular expression, named capture group>
400 X<%+> X<$+{name}> X<< \k<name> >>
401 There is no limit to the number of captured substrings that you may use.
402 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
403 a group did not match, the associated backreference won't match either. (This
404 can happen if the group is optional, or in a different branch of an
405 alternation.)
406 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
407 this form, described below.
408
409 You can also refer to capture groups relatively, by using a negative number, so
410 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
411 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
412 example:
413
414         /
415          (Y)            # group 1
416          (              # group 2
417             (X)         # group 3
418             \g{-1}      # backref to group 3
419             \g{-3}      # backref to group 1
420          )
421         /x
422
423 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
424 interpolate regexes into larger regexes and not have to worry about the
425 capture groups being renumbered.
426
427 You can dispense with numbers altogether and create named capture groups.
428 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
429 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
430 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
431 I<name> must not begin with a number, nor contain hyphens.
432 When different groups within the same pattern have the same name, any reference
433 to that name assumes the leftmost defined group.  Named groups count in
434 absolute and relative numbering, and so can also be referred to by those
435 numbers.
436 (It's possible to do things with named capture groups that would otherwise
437 require C<(??{})>.)
438
439 Capture group contents are dynamically scoped and available to you outside the
440 pattern until the end of the enclosing block or until the next successful
441 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
442 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
443 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
444
445 Braces are required in referring to named capture groups, but are optional for
446 absolute or relative numbered ones.  Braces are safer when creating a regex by
447 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
448 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
449 is probably not what you intended.
450
451 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
452 there were no named nor relative numbered capture groups.  Absolute numbered
453 groups were referred to using C<\1>, C<\2>, etc, and this notation is still
454 accepted (and likely always will be).  But it leads to some ambiguities if
455 there are more than 9 capture groups, as C<\10> could mean either the tenth
456 capture group, or the character whose ordinal in octal is 010 (a backspace in
457 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
458 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
459 a backreference only if at least 11 left parentheses have opened before it.
460 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
461 There are several examples below that illustrate these perils.  You can avoid
462 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
463 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
464 digits padded with leading zeros, since a leading zero implies an octal
465 constant.
466
467 The C<\I<digit>> notation also works in certain circumstances outside
468 the pattern.  See L</Warning on \1 Instead of $1> below for details.)
469
470 Examples:
471
472     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
473
474     /(.)\g1/                        # find first doubled char
475          and print "'$1' is the first doubled character\n";
476
477     /(?<char>.)\k<char>/            # ... a different way
478          and print "'$+{char}' is the first doubled character\n";
479
480     /(?'char'.)\g1/                 # ... mix and match
481          and print "'$1' is the first doubled character\n";
482
483     if (/Time: (..):(..):(..)/) {   # parse out values
484         $hours = $1;
485         $minutes = $2;
486         $seconds = $3;
487     }
488
489     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
490     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
491     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
492     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
493
494     $a = '(.)\1';        # Creates problems when concatenated.
495     $b = '(.)\g{1}';     # Avoids the problems.
496     "aa" =~ /${a}/;      # True
497     "aa" =~ /${b}/;      # True
498     "aa0" =~ /${a}0/;    # False!
499     "aa0" =~ /${b}0/;    # True
500     "aa\x08" =~ /${a}0/;  # True!
501     "aa\x08" =~ /${b}0/;  # False
502
503 Several special variables also refer back to portions of the previous
504 match.  C<$+> returns whatever the last bracket match matched.
505 C<$&> returns the entire matched string.  (At one point C<$0> did
506 also, but now it returns the name of the program.)  C<$`> returns
507 everything before the matched string.  C<$'> returns everything
508 after the matched string. And C<$^N> contains whatever was matched by
509 the most-recently closed group (submatch). C<$^N> can be used in
510 extended patterns (see below), for example to assign a submatch to a
511 variable.
512 X<$+> X<$^N> X<$&> X<$`> X<$'>
513
514 These special variables, like the C<%+> hash and the numbered match variables
515 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
516 until the end of the enclosing block or until the next successful
517 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
518 X<$+> X<$^N> X<$&> X<$`> X<$'>
519 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
520
521 B<NOTE>: Failed matches in Perl do not reset the match variables,
522 which makes it easier to write code that tests for a series of more
523 specific cases and remembers the best match.
524
525 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
526 C<$'> anywhere in the program, it has to provide them for every
527 pattern match.  This may substantially slow your program.  Perl
528 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
529 price for each pattern that contains capturing parentheses.  (To
530 avoid this cost while retaining the grouping behaviour, use the
531 extended regular expression C<(?: ... )> instead.)  But if you never
532 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
533 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
534 if you can, but if you can't (and some algorithms really appreciate
535 them), once you've used them once, use them at will, because you've
536 already paid the price.  As of 5.005, C<$&> is not so costly as the
537 other two.
538 X<$&> X<$`> X<$'>
539
540 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
541 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
542 and C<$'>, B<except> that they are only guaranteed to be defined after a
543 successful match that was executed with the C</p> (preserve) modifier.
544 The use of these variables incurs no global performance penalty, unlike
545 their punctuation char equivalents, however at the trade-off that you
546 have to tell perl when you want to use them.
547 X</p> X<p modifier>
548
549 =head2 Quoting metacharacters
550
551 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
552 C<\w>, C<\n>.  Unlike some other regular expression languages, there
553 are no backslashed symbols that aren't alphanumeric.  So anything
554 that looks like \\, \(, \), \<, \>, \{, or \} is always
555 interpreted as a literal character, not a metacharacter.  This was
556 once used in a common idiom to disable or quote the special meanings
557 of regular expression metacharacters in a string that you want to
558 use for a pattern. Simply quote all non-"word" characters:
559
560     $pattern =~ s/(\W)/\\$1/g;
561
562 (If C<use locale> is set, then this depends on the current locale.)
563 Today it is more common to use the quotemeta() function or the C<\Q>
564 metaquoting escape sequence to disable all metacharacters' special
565 meanings like this:
566
567     /$unquoted\Q$quoted\E$unquoted/
568
569 Beware that if you put literal backslashes (those not inside
570 interpolated variables) between C<\Q> and C<\E>, double-quotish
571 backslash interpolation may lead to confusing results.  If you
572 I<need> to use literal backslashes within C<\Q...\E>,
573 consult L<perlop/"Gory details of parsing quoted constructs">.
574
575 =head2 Extended Patterns
576
577 Perl also defines a consistent extension syntax for features not
578 found in standard tools like B<awk> and B<lex>.  The syntax is a
579 pair of parentheses with a question mark as the first thing within
580 the parentheses.  The character after the question mark indicates
581 the extension.
582
583 The stability of these extensions varies widely.  Some have been
584 part of the core language for many years.  Others are experimental
585 and may change without warning or be completely removed.  Check
586 the documentation on an individual feature to verify its current
587 status.
588
589 A question mark was chosen for this and for the minimal-matching
590 construct because 1) question marks are rare in older regular
591 expressions, and 2) whenever you see one, you should stop and
592 "question" exactly what is going on.  That's psychology...
593
594 =over 10
595
596 =item C<(?#text)>
597 X<(?#)>
598
599 A comment.  The text is ignored.  If the C</x> modifier enables
600 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
601 the comment as soon as it sees a C<)>, so there is no way to put a literal
602 C<)> in the comment.
603
604 =item C<(?adlupimsx-imsx)>
605
606 =item C<(?^alupimsx)>
607 X<(?)> X<(?^)>
608
609 One or more embedded pattern-match modifiers, to be turned on (or
610 turned off, if preceded by C<->) for the remainder of the pattern or
611 the remainder of the enclosing pattern group (if any).
612
613 This is particularly useful for dynamic patterns, such as those read in from a
614 configuration file, taken from an argument, or specified in a table
615 somewhere.  Consider the case where some patterns want to be case
616 sensitive and some do not:  The case insensitive ones merely need to
617 include C<(?i)> at the front of the pattern.  For example:
618
619     $pattern = "foobar";
620     if ( /$pattern/i ) { }
621
622     # more flexible:
623
624     $pattern = "(?i)foobar";
625     if ( /$pattern/ ) { }
626
627 These modifiers are restored at the end of the enclosing group. For example,
628
629     ( (?i) blah ) \s+ \g1
630
631 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
632 repetition of the previous word, assuming the C</x> modifier, and no C</i>
633 modifier outside this group.
634
635 These modifiers do not carry over into named subpatterns called in the
636 enclosing group. In other words, a pattern such as C<((?i)(&NAME))> does not
637 change the case-sensitivity of the "NAME" pattern.
638
639 Any of these modifiers can be set to apply globally to all regular
640 expressions compiled within the scope of a C<use re>.  See
641 L<re/'/flags' mode>.
642
643 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
644 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
645 C<"d">) may follow the caret to override it.
646 But a minus sign is not legal with it.
647
648 Also, starting in Perl 5.14, are modifiers C<"a">, C<"d">, C<"l">, and
649 C<"u">, which for 5.14 may not be used as suffix modifiers.
650
651 C<"l"> means to use a locale (see L<perllocale>) when pattern matching.
652 The locale used will be the one in effect at the time of execution of
653 the pattern match.  This may not be the same as the compilation-time
654 locale, and can differ from one match to another if there is an
655 intervening call of the
656 L<setlocale() function|perllocale/The setlocale function>.
657 This modifier is automatically set if the regular expression is compiled
658 within the scope of a C<"use locale"> pragma.  Results are not
659 well-defined when using this and matching against a utf8-encoded string.
660
661 C<"u"> means to use Unicode semantics when pattern matching.  It is
662 automatically set if the regular expression is encoded in utf8, or is
663 compiled within the scope of a
664 L<C<"use feature 'unicode_strings">|feature> pragma (and isn't also in
665 the scope of L<C<"use locale">|locale> nor L<C<"use bytes">|bytes>
666 pragmas.  On ASCII platforms, the code points between 128 and 255 take on their
667 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's), whereas
668 in strict ASCII their meanings are undefined.  Thus the platform
669 effectively becomes a Unicode platform.  The ASCII characters remain as
670 ASCII characters (since ASCII is a subset of Latin-1 and Unicode).  For
671 example, when this option is not on, on a non-utf8 string, C<"\w">
672 matches precisely C<[A-Za-z0-9_]>.  When the option is on, it matches
673 not just those, but all the Latin-1 word characters (such as an "n" with
674 a tilde).  On EBCDIC platforms, which already are equivalent to Latin-1,
675 this modifier changes behavior only when the C<"/i"> modifier is also
676 specified, and affects only two characters, giving them full Unicode
677 semantics: the C<MICRO SIGN> will match the Greek capital and
678 small letters C<MU>; otherwise not; and the C<LATIN CAPITAL LETTER SHARP
679 S> will match any of C<SS>, C<Ss>, C<sS>, and C<ss>, otherwise not.
680 (This last case is buggy, however.)
681
682 C<"a"> is the same as C<"u">, except that C<\d>, C<\s>, C<\w>, and the
683 Posix character classes are restricted to matching in the ASCII range
684 only.  That is, with this modifier, C<\d> always means precisely the
685 digits C<"0"> to C<"9">; C<\s> means the five characters C<[ \f\n\r\t]>;
686 C<\w> means the 63 characters C<[A-Za-z0-9_]>; and likewise, all the
687 Posix classes such as C<[[:print:]]> match only the appropriate
688 ASCII-range characters.  As you would expect, this modifier causes, for
689 example, C<\D> to mean the same thing as C<[^0-9]>; in fact, all
690 non-ASCII characters match C<\D>, C<\S>, and C<\W>.  C<\b> still means
691 to match at the boundary between C<\w> and C<\W>, using the C<"a">
692 definitions of them (similarly for C<\B>).  Otherwise, C<"a"> behaves
693 like the C<"u"> modifier, in that case-insensitive matching uses Unicode
694 semantics; for example, "k" will match the Unicode C<\N{KELVIN SIGN}>
695 under C</i> matching, and code points in the Latin1 range, above ASCII
696 will have Unicode semantics when it comes to case-insensitive matching.
697
698 C<"d"> means to use the traditional Perl pattern matching behavior.
699 This is dualistic (hence the name C<"d">, which also could stand for
700 "depends").  When this is in effect, Perl matches utf8-encoded strings
701 using Unicode rules, and matches non-utf8-encoded strings using the
702 platform's native character set rules.  (If the regular expression
703 itself is encoded in utf8, Unicode rules are used regardless of the
704 target string's encoding.)
705 See L<perlunicode/The "Unicode Bug">.  It is automatically selected by
706 default if the regular expression is compiled neither within the scope
707 of a C<"use locale"> pragma nor a <C<"use feature 'unicode_strings">
708 pragma.
709
710 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
711 that they can only be enabled, not disabled, and the C<d>, C<l>, and
712 C<u> modifiers are mutually exclusive: specifying one de-specifies the
713 others, and a maximum of one may appear in the construct.  Thus, for
714 example, C<(?-p)>, C<(?-d:...)>, and C<(?dl:...)> will warn when
715 compiled under C<use warnings>.
716
717 Note also that the C<p> modifier is special in that its presence
718 anywhere in a pattern has a global effect.
719
720 =item C<(?:pattern)>
721 X<(?:)>
722
723 =item C<(?adluimsx-imsx:pattern)>
724
725 =item C<(?^aluimsx:pattern)>
726 X<(?^:)>
727
728 This is for clustering, not capturing; it groups subexpressions like
729 "()", but doesn't make backreferences as "()" does.  So
730
731     @fields = split(/\b(?:a|b|c)\b/)
732
733 is like
734
735     @fields = split(/\b(a|b|c)\b/)
736
737 but doesn't spit out extra fields.  It's also cheaper not to capture
738 characters if you don't need to.
739
740 Any letters between C<?> and C<:> act as flags modifiers as with
741 C<(?adluimsx-imsx)>.  For example,
742
743     /(?s-i:more.*than).*million/i
744
745 is equivalent to the more verbose
746
747     /(?:(?s-i)more.*than).*million/i
748
749 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
750 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
751 flags (except C<"d">) may follow the caret, so
752
753     (?^x:foo)
754
755 is equivalent to
756
757     (?x-ims:foo)
758
759 The caret tells Perl that this cluster doesn't inherit the flags of any
760 surrounding pattern, but to go back to the system defaults (C<d-imsx>),
761 modified by any flags specified.
762
763 The caret allows for simpler stringification of compiled regular
764 expressions.  These look like
765
766     (?^:pattern)
767
768 with any non-default flags appearing between the caret and the colon.
769 A test that looks at such stringification thus doesn't need to have the
770 system default flags hard-coded in it, just the caret.  If new flags are
771 added to Perl, the meaning of the caret's expansion will change to include
772 the default for those flags, so the test will still work, unchanged.
773
774 Specifying a negative flag after the caret is an error, as the flag is
775 redundant.
776
777 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
778 to match at the beginning.
779
780 =item C<(?|pattern)>
781 X<(?|)> X<Branch reset>
782
783 This is the "branch reset" pattern, which has the special property
784 that the capture groups are numbered from the same starting point
785 in each alternation branch. It is available starting from perl 5.10.0.
786
787 Capture groups are numbered from left to right, but inside this
788 construct the numbering is restarted for each branch.
789
790 The numbering within each branch will be as normal, and any groups
791 following this construct will be numbered as though the construct
792 contained only one branch, that being the one with the most capture
793 groups in it.
794
795 This construct will be useful when you want to capture one of a
796 number of alternative matches.
797
798 Consider the following pattern.  The numbers underneath show in
799 which group the captured content will be stored.
800
801
802     # before  ---------------branch-reset----------- after        
803     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
804     # 1            2         2  3        2     3     4  
805
806 Be careful when using the branch reset pattern in combination with 
807 named captures. Named captures are implemented as being aliases to 
808 numbered groups holding the captures, and that interferes with the
809 implementation of the branch reset pattern. If you are using named
810 captures in a branch reset pattern, it's best to use the same names,
811 in the same order, in each of the alternations:
812
813    /(?|  (?<a> x ) (?<b> y )
814       |  (?<a> z ) (?<b> w )) /x
815
816 Not doing so may lead to surprises:
817
818   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
819   say $+ {a};   # Prints '12'
820   say $+ {b};   # *Also* prints '12'.
821
822 The problem here is that both the group named C<< a >> and the group
823 named C<< b >> are aliases for the group belonging to C<< $1 >>.
824
825 =item Look-Around Assertions
826 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
827
828 Look-around assertions are zero width patterns which match a specific
829 pattern without including it in C<$&>. Positive assertions match when
830 their subpattern matches, negative assertions match when their subpattern
831 fails. Look-behind matches text up to the current match position,
832 look-ahead matches text following the current match position.
833
834 =over 4
835
836 =item C<(?=pattern)>
837 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
838
839 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
840 matches a word followed by a tab, without including the tab in C<$&>.
841
842 =item C<(?!pattern)>
843 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
844
845 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
846 matches any occurrence of "foo" that isn't followed by "bar".  Note
847 however that look-ahead and look-behind are NOT the same thing.  You cannot
848 use this for look-behind.
849
850 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
851 will not do what you want.  That's because the C<(?!foo)> is just saying that
852 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
853 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
854 say "like" because there's the case of your "bar" not having three characters
855 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
856 Sometimes it's still easier just to say:
857
858     if (/bar/ && $` !~ /foo$/)
859
860 For look-behind see below.
861
862 =item C<(?<=pattern)> C<\K>
863 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
864
865 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
866 matches a word that follows a tab, without including the tab in C<$&>.
867 Works only for fixed-width look-behind.
868
869 There is a special form of this construct, called C<\K>, which causes the
870 regex engine to "keep" everything it had matched prior to the C<\K> and
871 not include it in C<$&>. This effectively provides variable length
872 look-behind. The use of C<\K> inside of another look-around assertion
873 is allowed, but the behaviour is currently not well defined.
874
875 For various reasons C<\K> may be significantly more efficient than the
876 equivalent C<< (?<=...) >> construct, and it is especially useful in
877 situations where you want to efficiently remove something following
878 something else in a string. For instance
879
880   s/(foo)bar/$1/g;
881
882 can be rewritten as the much more efficient
883
884   s/foo\Kbar//g;
885
886 =item C<(?<!pattern)>
887 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
888
889 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
890 matches any occurrence of "foo" that does not follow "bar".  Works
891 only for fixed-width look-behind.
892
893 =back
894
895 =item C<(?'NAME'pattern)>
896
897 =item C<< (?<NAME>pattern) >>
898 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
899
900 A named capture group. Identical in every respect to normal capturing
901 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
902 used after a successful match to refer to a named group. See C<perlvar>
903 for more details on the C<%+> and C<%-> hashes.
904
905 If multiple distinct capture groups have the same name then the
906 $+{NAME} will refer to the leftmost defined group in the match.
907
908 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
909
910 B<NOTE:> While the notation of this construct is the same as the similar
911 function in .NET regexes, the behavior is not. In Perl the groups are
912 numbered sequentially regardless of being named or not. Thus in the
913 pattern
914
915   /(x)(?<foo>y)(z)/
916
917 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
918 the opposite which is what a .NET regex hacker might expect.
919
920 Currently NAME is restricted to simple identifiers only.
921 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
922 its Unicode extension (see L<utf8>),
923 though it isn't extended by the locale (see L<perllocale>).
924
925 B<NOTE:> In order to make things easier for programmers with experience
926 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
927 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
928 support the use of single quotes as a delimiter for the name.
929
930 =item C<< \k<NAME> >>
931
932 =item C<< \k'NAME' >>
933
934 Named backreference. Similar to numeric backreferences, except that
935 the group is designated by name and not number. If multiple groups
936 have the same name then it refers to the leftmost defined group in
937 the current match.
938
939 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
940 earlier in the pattern.
941
942 Both forms are equivalent.
943
944 B<NOTE:> In order to make things easier for programmers with experience
945 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
946 may be used instead of C<< \k<NAME> >>.
947
948 =item C<(?{ code })>
949 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
950
951 B<WARNING>: This extended regular expression feature is considered
952 experimental, and may be changed without notice. Code executed that
953 has side effects may not perform identically from version to version
954 due to the effect of future optimisations in the regex engine.
955
956 This zero-width assertion evaluates any embedded Perl code.  It
957 always succeeds, and its C<code> is not interpolated.  Currently,
958 the rules to determine where the C<code> ends are somewhat convoluted.
959
960 This feature can be used together with the special variable C<$^N> to
961 capture the results of submatches in variables without having to keep
962 track of the number of nested parentheses. For example:
963
964   $_ = "The brown fox jumps over the lazy dog";
965   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
966   print "color = $color, animal = $animal\n";
967
968 Inside the C<(?{...})> block, C<$_> refers to the string the regular
969 expression is matching against. You can also use C<pos()> to know what is
970 the current position of matching within this string.
971
972 The C<code> is properly scoped in the following sense: If the assertion
973 is backtracked (compare L<"Backtracking">), all changes introduced after
974 C<local>ization are undone, so that
975
976   $_ = 'a' x 8;
977   m<
978      (?{ $cnt = 0 })                   # Initialize $cnt.
979      (
980        a
981        (?{
982            local $cnt = $cnt + 1;      # Update $cnt, backtracking-safe.
983        })
984      )*
985      aaaa
986      (?{ $res = $cnt })                # On success copy to
987                                        # non-localized location.
988    >x;
989
990 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
991 introduced value, because the scopes that restrict C<local> operators
992 are unwound.
993
994 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
995 switch.  If I<not> used in this way, the result of evaluation of
996 C<code> is put into the special variable C<$^R>.  This happens
997 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
998 inside the same regular expression.
999
1000 The assignment to C<$^R> above is properly localized, so the old
1001 value of C<$^R> is restored if the assertion is backtracked; compare
1002 L<"Backtracking">.
1003
1004 For reasons of security, this construct is forbidden if the regular
1005 expression involves run-time interpolation of variables, unless the
1006 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1007 variables contain results of C<qr//> operator (see
1008 L<perlop/"qr/STRINGE<sol>msixpo">).
1009
1010 This restriction is due to the wide-spread and remarkably convenient
1011 custom of using run-time determined strings as patterns.  For example:
1012
1013     $re = <>;
1014     chomp $re;
1015     $string =~ /$re/;
1016
1017 Before Perl knew how to execute interpolated code within a pattern,
1018 this operation was completely safe from a security point of view,
1019 although it could raise an exception from an illegal pattern.  If
1020 you turn on the C<use re 'eval'>, though, it is no longer secure,
1021 so you should only do so if you are also using taint checking.
1022 Better yet, use the carefully constrained evaluation within a Safe
1023 compartment.  See L<perlsec> for details about both these mechanisms.
1024
1025 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
1026 broken. The result is unpredictable and will make perl unstable. The
1027 workaround is to use global (C<our>) variables.
1028
1029 B<WARNING>: In perl 5.12.x and earlier, the regex engine
1030 was not re-entrant, so interpolated code could not
1031 safely invoke the regex engine either directly with
1032 C<m//> or C<s///>), or indirectly with functions such as
1033 C<split>. Invoking the regex engine in these blocks would make perl
1034 unstable.
1035
1036 =item C<(??{ code })>
1037 X<(??{})>
1038 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1039
1040 B<WARNING>: This extended regular expression feature is considered
1041 experimental, and may be changed without notice. Code executed that
1042 has side effects may not perform identically from version to version
1043 due to the effect of future optimisations in the regex engine.
1044
1045 This is a "postponed" regular subexpression.  The C<code> is evaluated
1046 at run time, at the moment this subexpression may match.  The result
1047 of evaluation is considered as a regular expression and matched as
1048 if it were inserted instead of this construct.  Note that this means
1049 that the contents of capture groups defined inside an eval'ed pattern
1050 are not available outside of the pattern, and vice versa, there is no
1051 way for the inner pattern to refer to a capture group defined outside.
1052 Thus,
1053
1054     ('a' x 100)=~/(??{'(.)' x 100})/
1055
1056 B<will> match, it will B<not> set $1.
1057
1058 The C<code> is not interpolated.  As before, the rules to determine
1059 where the C<code> ends are currently somewhat convoluted.
1060
1061 The following pattern matches a parenthesized group:
1062
1063   $re = qr{
1064              \(
1065              (?:
1066                 (?> [^()]+ )       # Non-parens without backtracking
1067               |
1068                 (??{ $re })        # Group with matching parens
1069              )*
1070              \)
1071           }x;
1072
1073 See also C<(?PARNO)> for a different, more efficient way to accomplish
1074 the same task.
1075
1076 For reasons of security, this construct is forbidden if the regular
1077 expression involves run-time interpolation of variables, unless the
1078 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1079 variables contain results of C<qr//> operator (see
1080 L<perlop/"qrE<sol>STRINGE<sol>msixpo">).
1081
1082 In perl 5.12.x and earlier, because the regex engine was not re-entrant,
1083 delayed code could not safely invoke the regex engine either directly with
1084 C<m//> or C<s///>), or indirectly with functions such as C<split>.
1085
1086 Recursing deeper than 50 times without consuming any input string will
1087 result in a fatal error.  The maximum depth is compiled into perl, so
1088 changing it requires a custom build.
1089
1090 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1091 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1092 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1093 X<regex, relative recursion>
1094
1095 Similar to C<(??{ code })> except it does not involve compiling any code,
1096 instead it treats the contents of a capture group as an independent
1097 pattern that must match at the current position.  Capture groups
1098 contained by the pattern will have the value as determined by the
1099 outermost recursion.
1100
1101 PARNO is a sequence of digits (not starting with 0) whose value reflects
1102 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1103 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1104 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1105 to be relative, with negative numbers indicating preceding capture groups
1106 and positive ones following. Thus C<(?-1)> refers to the most recently
1107 declared group, and C<(?+1)> indicates the next group to be declared.
1108 Note that the counting for relative recursion differs from that of
1109 relative backreferences, in that with recursion unclosed groups B<are>
1110 included.
1111
1112 The following pattern matches a function foo() which may contain
1113 balanced parentheses as the argument.
1114
1115   $re = qr{ (                    # paren group 1 (full function)
1116               foo
1117               (                  # paren group 2 (parens)
1118                 \(
1119                   (              # paren group 3 (contents of parens)
1120                   (?:
1121                    (?> [^()]+ )  # Non-parens without backtracking
1122                   |
1123                    (?2)          # Recurse to start of paren group 2
1124                   )*
1125                   )
1126                 \)
1127               )
1128             )
1129           }x;
1130
1131 If the pattern was used as follows
1132
1133     'foo(bar(baz)+baz(bop))'=~/$re/
1134         and print "\$1 = $1\n",
1135                   "\$2 = $2\n",
1136                   "\$3 = $3\n";
1137
1138 the output produced should be the following:
1139
1140     $1 = foo(bar(baz)+baz(bop))
1141     $2 = (bar(baz)+baz(bop))
1142     $3 = bar(baz)+baz(bop)
1143
1144 If there is no corresponding capture group defined, then it is a
1145 fatal error.  Recursing deeper than 50 times without consuming any input
1146 string will also result in a fatal error.  The maximum depth is compiled
1147 into perl, so changing it requires a custom build.
1148
1149 The following shows how using negative indexing can make it
1150 easier to embed recursive patterns inside of a C<qr//> construct
1151 for later use:
1152
1153     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1154     if (/foo $parens \s+ + \s+ bar $parens/x) {
1155        # do something here...
1156     }
1157
1158 B<Note> that this pattern does not behave the same way as the equivalent
1159 PCRE or Python construct of the same form. In Perl you can backtrack into
1160 a recursed group, in PCRE and Python the recursed into group is treated
1161 as atomic. Also, modifiers are resolved at compile time, so constructs
1162 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1163 be processed.
1164
1165 =item C<(?&NAME)>
1166 X<(?&NAME)>
1167
1168 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1169 parenthesis to recurse to is determined by name. If multiple parentheses have
1170 the same name, then it recurses to the leftmost.
1171
1172 It is an error to refer to a name that is not declared somewhere in the
1173 pattern.
1174
1175 B<NOTE:> In order to make things easier for programmers with experience
1176 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1177 may be used instead of C<< (?&NAME) >>.
1178
1179 =item C<(?(condition)yes-pattern|no-pattern)>
1180 X<(?()>
1181
1182 =item C<(?(condition)yes-pattern)>
1183
1184 Conditional expression.  C<(condition)> should be either an integer in
1185 parentheses (which is valid if the corresponding pair of parentheses
1186 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1187 name in angle brackets or single quotes (which is valid if a group
1188 with the given name matched), or the special symbol (R) (true when
1189 evaluated inside of recursion or eval). Additionally the R may be
1190 followed by a number, (which will be true when evaluated when recursing
1191 inside of the appropriate group), or by C<&NAME>, in which case it will
1192 be true only when evaluated during recursion in the named group.
1193
1194 Here's a summary of the possible predicates:
1195
1196 =over 4
1197
1198 =item (1) (2) ...
1199
1200 Checks if the numbered capturing group has matched something.
1201
1202 =item (<NAME>) ('NAME')
1203
1204 Checks if a group with the given name has matched something.
1205
1206 =item (?{ CODE })
1207
1208 Treats the code block as the condition.
1209
1210 =item (R)
1211
1212 Checks if the expression has been evaluated inside of recursion.
1213
1214 =item (R1) (R2) ...
1215
1216 Checks if the expression has been evaluated while executing directly
1217 inside of the n-th capture group. This check is the regex equivalent of
1218
1219   if ((caller(0))[3] eq 'subname') { ... }
1220
1221 In other words, it does not check the full recursion stack.
1222
1223 =item (R&NAME)
1224
1225 Similar to C<(R1)>, this predicate checks to see if we're executing
1226 directly inside of the leftmost group with a given name (this is the same
1227 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1228 stack, but only the name of the innermost active recursion.
1229
1230 =item (DEFINE)
1231
1232 In this case, the yes-pattern is never directly executed, and no
1233 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1234 See below for details.
1235
1236 =back
1237
1238 For example:
1239
1240     m{ ( \( )?
1241        [^()]+
1242        (?(1) \) )
1243      }x
1244
1245 matches a chunk of non-parentheses, possibly included in parentheses
1246 themselves.
1247
1248 A special form is the C<(DEFINE)> predicate, which never executes directly
1249 its yes-pattern, and does not allow a no-pattern. This allows to define
1250 subpatterns which will be executed only by using the recursion mechanism.
1251 This way, you can define a set of regular expression rules that can be
1252 bundled into any pattern you choose.
1253
1254 It is recommended that for this usage you put the DEFINE block at the
1255 end of the pattern, and that you name any subpatterns defined within it.
1256
1257 Also, it's worth noting that patterns defined this way probably will
1258 not be as efficient, as the optimiser is not very clever about
1259 handling them.
1260
1261 An example of how this might be used is as follows:
1262
1263   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1264    (?(DEFINE)
1265      (?<NAME_PAT>....)
1266      (?<ADRESS_PAT>....)
1267    )/x
1268
1269 Note that capture groups matched inside of recursion are not accessible
1270 after the recursion returns, so the extra layer of capturing groups is
1271 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1272 C<$+{NAME}> would be.
1273
1274 =item C<< (?>pattern) >>
1275 X<backtrack> X<backtracking> X<atomic> X<possessive>
1276
1277 An "independent" subexpression, one which matches the substring
1278 that a I<standalone> C<pattern> would match if anchored at the given
1279 position, and it matches I<nothing other than this substring>.  This
1280 construct is useful for optimizations of what would otherwise be
1281 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1282 It may also be useful in places where the "grab all you can, and do not
1283 give anything back" semantic is desirable.
1284
1285 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1286 (anchored at the beginning of string, as above) will match I<all>
1287 characters C<a> at the beginning of string, leaving no C<a> for
1288 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1289 since the match of the subgroup C<a*> is influenced by the following
1290 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1291 C<a*ab> will match fewer characters than a standalone C<a*>, since
1292 this makes the tail match.
1293
1294 An effect similar to C<< (?>pattern) >> may be achieved by writing
1295 C<(?=(pattern))\g1>.  This matches the same substring as a standalone
1296 C<a+>, and the following C<\g1> eats the matched string; it therefore
1297 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1298 (The difference between these two constructs is that the second one
1299 uses a capturing group, thus shifting ordinals of backreferences
1300 in the rest of a regular expression.)
1301
1302 Consider this pattern:
1303
1304     m{ \(
1305           (
1306             [^()]+           # x+
1307           |
1308             \( [^()]* \)
1309           )+
1310        \)
1311      }x
1312
1313 That will efficiently match a nonempty group with matching parentheses
1314 two levels deep or less.  However, if there is no such group, it
1315 will take virtually forever on a long string.  That's because there
1316 are so many different ways to split a long string into several
1317 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1318 to a subpattern of the above pattern.  Consider how the pattern
1319 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1320 seconds, but that each extra letter doubles this time.  This
1321 exponential performance will make it appear that your program has
1322 hung.  However, a tiny change to this pattern
1323
1324     m{ \(
1325           (
1326             (?> [^()]+ )        # change x+ above to (?> x+ )
1327           |
1328             \( [^()]* \)
1329           )+
1330        \)
1331      }x
1332
1333 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1334 this yourself would be a productive exercise), but finishes in a fourth
1335 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1336 however, that this pattern currently triggers a warning message under
1337 the C<use warnings> pragma or B<-w> switch saying it
1338 C<"matches null string many times in regex">.
1339
1340 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1341 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1342 This was only 4 times slower on a string with 1000000 C<a>s.
1343
1344 The "grab all you can, and do not give anything back" semantic is desirable
1345 in many situations where on the first sight a simple C<()*> looks like
1346 the correct solution.  Suppose we parse text with comments being delimited
1347 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1348 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1349 the comment delimiter, because it may "give up" some whitespace if
1350 the remainder of the pattern can be made to match that way.  The correct
1351 answer is either one of these:
1352
1353     (?>#[ \t]*)
1354     #[ \t]*(?![ \t])
1355
1356 For example, to grab non-empty comments into $1, one should use either
1357 one of these:
1358
1359     / (?> \# [ \t]* ) (        .+ ) /x;
1360     /     \# [ \t]*   ( [^ \t] .* ) /x;
1361
1362 Which one you pick depends on which of these expressions better reflects
1363 the above specification of comments.
1364
1365 In some literature this construct is called "atomic matching" or
1366 "possessive matching".
1367
1368 Possessive quantifiers are equivalent to putting the item they are applied
1369 to inside of one of these constructs. The following equivalences apply:
1370
1371     Quantifier Form     Bracketing Form
1372     ---------------     ---------------
1373     PAT*+               (?>PAT*)
1374     PAT++               (?>PAT+)
1375     PAT?+               (?>PAT?)
1376     PAT{min,max}+       (?>PAT{min,max})
1377
1378 =back
1379
1380 =head2 Special Backtracking Control Verbs
1381
1382 B<WARNING:> These patterns are experimental and subject to change or
1383 removal in a future version of Perl. Their usage in production code should
1384 be noted to avoid problems during upgrades.
1385
1386 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1387 otherwise stated the ARG argument is optional; in some cases, it is
1388 forbidden.
1389
1390 Any pattern containing a special backtracking verb that allows an argument
1391 has the special behaviour that when executed it sets the current package's
1392 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1393 rules apply:
1394
1395 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1396 verb pattern, if the verb was involved in the failure of the match. If the
1397 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1398 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1399 none. Also, the C<$REGMARK> variable will be set to FALSE.
1400
1401 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1402 the C<$REGMARK> variable will be set to the name of the last
1403 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1404 C<(*MARK:NAME)> verb below for more details.
1405
1406 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1407 and most other regex related variables. They are not local to a scope, nor
1408 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1409 Use C<local> to localize changes to them to a specific scope if necessary.
1410
1411 If a pattern does not contain a special backtracking verb that allows an
1412 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1413
1414 =over 4
1415
1416 =item Verbs that take an argument
1417
1418 =over 4
1419
1420 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1421 X<(*PRUNE)> X<(*PRUNE:NAME)>
1422
1423 This zero-width pattern prunes the backtracking tree at the current point
1424 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1425 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1426 A may backtrack as necessary to match. Once it is reached, matching
1427 continues in B, which may also backtrack as necessary; however, should B
1428 not match, then no further backtracking will take place, and the pattern
1429 will fail outright at the current starting position.
1430
1431 The following example counts all the possible matching strings in a
1432 pattern (without actually matching any of them).
1433
1434     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1435     print "Count=$count\n";
1436
1437 which produces:
1438
1439     aaab
1440     aaa
1441     aa
1442     a
1443     aab
1444     aa
1445     a
1446     ab
1447     a
1448     Count=9
1449
1450 If we add a C<(*PRUNE)> before the count like the following
1451
1452     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1453     print "Count=$count\n";
1454
1455 we prevent backtracking and find the count of the longest matching
1456 at each matching starting point like so:
1457
1458     aaab
1459     aab
1460     ab
1461     Count=3
1462
1463 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1464
1465 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1466 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1467 replaced with a C<< (?>pattern) >> with no functional difference; however,
1468 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1469 C<< (?>pattern) >> alone.
1470
1471
1472 =item C<(*SKIP)> C<(*SKIP:NAME)>
1473 X<(*SKIP)>
1474
1475 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1476 failure it also signifies that whatever text that was matched leading up
1477 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1478 of this pattern. This effectively means that the regex engine "skips" forward
1479 to this position on failure and tries to match again, (assuming that
1480 there is sufficient room to match).
1481
1482 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1483 C<(*MARK:NAME)> was encountered while matching, then it is that position
1484 which is used as the "skip point". If no C<(*MARK)> of that name was
1485 encountered, then the C<(*SKIP)> operator has no effect. When used
1486 without a name the "skip point" is where the match point was when
1487 executing the (*SKIP) pattern.
1488
1489 Compare the following to the examples in C<(*PRUNE)>, note the string
1490 is twice as long:
1491
1492     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1493     print "Count=$count\n";
1494
1495 outputs
1496
1497     aaab
1498     aaab
1499     Count=2
1500
1501 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1502 executed, the next starting point will be where the cursor was when the
1503 C<(*SKIP)> was executed.
1504
1505 =item C<(*MARK:NAME)> C<(*:NAME)>
1506 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1507
1508 This zero-width pattern can be used to mark the point reached in a string
1509 when a certain part of the pattern has been successfully matched. This
1510 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1511 forward to that point if backtracked into on failure. Any number of
1512 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1513
1514 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1515 can be used to "label" a pattern branch, so that after matching, the
1516 program can determine which branches of the pattern were involved in the
1517 match.
1518
1519 When a match is successful, the C<$REGMARK> variable will be set to the
1520 name of the most recently executed C<(*MARK:NAME)> that was involved
1521 in the match.
1522
1523 This can be used to determine which branch of a pattern was matched
1524 without using a separate capture group for each branch, which in turn
1525 can result in a performance improvement, as perl cannot optimize
1526 C</(?:(x)|(y)|(z))/> as efficiently as something like
1527 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1528
1529 When a match has failed, and unless another verb has been involved in
1530 failing the match and has provided its own name to use, the C<$REGERROR>
1531 variable will be set to the name of the most recently executed
1532 C<(*MARK:NAME)>.
1533
1534 See C<(*SKIP)> for more details.
1535
1536 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1537
1538 =item C<(*THEN)> C<(*THEN:NAME)>
1539
1540 This is similar to the "cut group" operator C<::> from Perl 6. Like
1541 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1542 failure, it causes the regex engine to try the next alternation in the
1543 innermost enclosing group (capturing or otherwise).
1544
1545 Its name comes from the observation that this operation combined with the
1546 alternation operator (C<|>) can be used to create what is essentially a
1547 pattern-based if/then/else block:
1548
1549   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1550
1551 Note that if this operator is used and NOT inside of an alternation then
1552 it acts exactly like the C<(*PRUNE)> operator.
1553
1554   / A (*PRUNE) B /
1555
1556 is the same as
1557
1558   / A (*THEN) B /
1559
1560 but
1561
1562   / ( A (*THEN) B | C (*THEN) D ) /
1563
1564 is not the same as
1565
1566   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1567
1568 as after matching the A but failing on the B the C<(*THEN)> verb will
1569 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1570
1571 =item C<(*COMMIT)>
1572 X<(*COMMIT)>
1573
1574 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1575 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1576 into on failure it causes the match to fail outright. No further attempts
1577 to find a valid match by advancing the start pointer will occur again.
1578 For example,
1579
1580     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1581     print "Count=$count\n";
1582
1583 outputs
1584
1585     aaab
1586     Count=1
1587
1588 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1589 does not match, the regex engine will not try any further matching on the
1590 rest of the string.
1591
1592 =back
1593
1594 =item Verbs without an argument
1595
1596 =over 4
1597
1598 =item C<(*FAIL)> C<(*F)>
1599 X<(*FAIL)> X<(*F)>
1600
1601 This pattern matches nothing and always fails. It can be used to force the
1602 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1603 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1604
1605 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1606
1607 =item C<(*ACCEPT)>
1608 X<(*ACCEPT)>
1609
1610 B<WARNING:> This feature is highly experimental. It is not recommended
1611 for production code.
1612
1613 This pattern matches nothing and causes the end of successful matching at
1614 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1615 whether there is actually more to match in the string. When inside of a
1616 nested pattern, such as recursion, or in a subpattern dynamically generated
1617 via C<(??{})>, only the innermost pattern is ended immediately.
1618
1619 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1620 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1621 For instance:
1622
1623   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1624
1625 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1626 be set. If another branch in the inner parentheses were matched, such as in the
1627 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1628
1629 =back
1630
1631 =back
1632
1633 =head2 Backtracking
1634 X<backtrack> X<backtracking>
1635
1636 NOTE: This section presents an abstract approximation of regular
1637 expression behavior.  For a more rigorous (and complicated) view of
1638 the rules involved in selecting a match among possible alternatives,
1639 see L<Combining RE Pieces>.
1640
1641 A fundamental feature of regular expression matching involves the
1642 notion called I<backtracking>, which is currently used (when needed)
1643 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1644 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1645 internally, but the general principle outlined here is valid.
1646
1647 For a regular expression to match, the I<entire> regular expression must
1648 match, not just part of it.  So if the beginning of a pattern containing a
1649 quantifier succeeds in a way that causes later parts in the pattern to
1650 fail, the matching engine backs up and recalculates the beginning
1651 part--that's why it's called backtracking.
1652
1653 Here is an example of backtracking:  Let's say you want to find the
1654 word following "foo" in the string "Food is on the foo table.":
1655
1656     $_ = "Food is on the foo table.";
1657     if ( /\b(foo)\s+(\w+)/i ) {
1658         print "$2 follows $1.\n";
1659     }
1660
1661 When the match runs, the first part of the regular expression (C<\b(foo)>)
1662 finds a possible match right at the beginning of the string, and loads up
1663 $1 with "Foo".  However, as soon as the matching engine sees that there's
1664 no whitespace following the "Foo" that it had saved in $1, it realizes its
1665 mistake and starts over again one character after where it had the
1666 tentative match.  This time it goes all the way until the next occurrence
1667 of "foo". The complete regular expression matches this time, and you get
1668 the expected output of "table follows foo."
1669
1670 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1671 everything between "foo" and "bar".  Initially, you write something
1672 like this:
1673
1674     $_ =  "The food is under the bar in the barn.";
1675     if ( /foo(.*)bar/ ) {
1676         print "got <$1>\n";
1677     }
1678
1679 Which perhaps unexpectedly yields:
1680
1681   got <d is under the bar in the >
1682
1683 That's because C<.*> was greedy, so you get everything between the
1684 I<first> "foo" and the I<last> "bar".  Here it's more effective
1685 to use minimal matching to make sure you get the text between a "foo"
1686 and the first "bar" thereafter.
1687
1688     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1689   got <d is under the >
1690
1691 Here's another example. Let's say you'd like to match a number at the end
1692 of a string, and you also want to keep the preceding part of the match.
1693 So you write this:
1694
1695     $_ = "I have 2 numbers: 53147";
1696     if ( /(.*)(\d*)/ ) {                                # Wrong!
1697         print "Beginning is <$1>, number is <$2>.\n";
1698     }
1699
1700 That won't work at all, because C<.*> was greedy and gobbled up the
1701 whole string. As C<\d*> can match on an empty string the complete
1702 regular expression matched successfully.
1703
1704     Beginning is <I have 2 numbers: 53147>, number is <>.
1705
1706 Here are some variants, most of which don't work:
1707
1708     $_ = "I have 2 numbers: 53147";
1709     @pats = qw{
1710         (.*)(\d*)
1711         (.*)(\d+)
1712         (.*?)(\d*)
1713         (.*?)(\d+)
1714         (.*)(\d+)$
1715         (.*?)(\d+)$
1716         (.*)\b(\d+)$
1717         (.*\D)(\d+)$
1718     };
1719
1720     for $pat (@pats) {
1721         printf "%-12s ", $pat;
1722         if ( /$pat/ ) {
1723             print "<$1> <$2>\n";
1724         } else {
1725             print "FAIL\n";
1726         }
1727     }
1728
1729 That will print out:
1730
1731     (.*)(\d*)    <I have 2 numbers: 53147> <>
1732     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1733     (.*?)(\d*)   <> <>
1734     (.*?)(\d+)   <I have > <2>
1735     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1736     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1737     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1738     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1739
1740 As you see, this can be a bit tricky.  It's important to realize that a
1741 regular expression is merely a set of assertions that gives a definition
1742 of success.  There may be 0, 1, or several different ways that the
1743 definition might succeed against a particular string.  And if there are
1744 multiple ways it might succeed, you need to understand backtracking to
1745 know which variety of success you will achieve.
1746
1747 When using look-ahead assertions and negations, this can all get even
1748 trickier.  Imagine you'd like to find a sequence of non-digits not
1749 followed by "123".  You might try to write that as
1750
1751     $_ = "ABC123";
1752     if ( /^\D*(?!123)/ ) {                # Wrong!
1753         print "Yup, no 123 in $_\n";
1754     }
1755
1756 But that isn't going to match; at least, not the way you're hoping.  It
1757 claims that there is no 123 in the string.  Here's a clearer picture of
1758 why that pattern matches, contrary to popular expectations:
1759
1760     $x = 'ABC123';
1761     $y = 'ABC445';
1762
1763     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1764     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1765
1766     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1767     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1768
1769 This prints
1770
1771     2: got ABC
1772     3: got AB
1773     4: got ABC
1774
1775 You might have expected test 3 to fail because it seems to a more
1776 general purpose version of test 1.  The important difference between
1777 them is that test 3 contains a quantifier (C<\D*>) and so can use
1778 backtracking, whereas test 1 will not.  What's happening is
1779 that you've asked "Is it true that at the start of $x, following 0 or more
1780 non-digits, you have something that's not 123?"  If the pattern matcher had
1781 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1782 fail.
1783
1784 The search engine will initially match C<\D*> with "ABC".  Then it will
1785 try to match C<(?!123> with "123", which fails.  But because
1786 a quantifier (C<\D*>) has been used in the regular expression, the
1787 search engine can backtrack and retry the match differently
1788 in the hope of matching the complete regular expression.
1789
1790 The pattern really, I<really> wants to succeed, so it uses the
1791 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1792 time.  Now there's indeed something following "AB" that is not
1793 "123".  It's "C123", which suffices.
1794
1795 We can deal with this by using both an assertion and a negation.
1796 We'll say that the first part in $1 must be followed both by a digit
1797 and by something that's not "123".  Remember that the look-aheads
1798 are zero-width expressions--they only look, but don't consume any
1799 of the string in their match.  So rewriting this way produces what
1800 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1801
1802     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1803     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1804
1805     6: got ABC
1806
1807 In other words, the two zero-width assertions next to each other work as though
1808 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1809 matches only if you're at the beginning of the line AND the end of the
1810 line simultaneously.  The deeper underlying truth is that juxtaposition in
1811 regular expressions always means AND, except when you write an explicit OR
1812 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1813 although the attempted matches are made at different positions because "a"
1814 is not a zero-width assertion, but a one-width assertion.
1815
1816 B<WARNING>: Particularly complicated regular expressions can take
1817 exponential time to solve because of the immense number of possible
1818 ways they can use backtracking to try for a match.  For example, without
1819 internal optimizations done by the regular expression engine, this will
1820 take a painfully long time to run:
1821
1822     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1823
1824 And if you used C<*>'s in the internal groups instead of limiting them
1825 to 0 through 5 matches, then it would take forever--or until you ran
1826 out of stack space.  Moreover, these internal optimizations are not
1827 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1828 on the external group, no current optimization is applicable, and the
1829 match takes a long time to finish.
1830
1831 A powerful tool for optimizing such beasts is what is known as an
1832 "independent group",
1833 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1834 zero-length look-ahead/look-behind assertions will not backtrack to make
1835 the tail match, since they are in "logical" context: only
1836 whether they match is considered relevant.  For an example
1837 where side-effects of look-ahead I<might> have influenced the
1838 following match, see L<C<< (?>pattern) >>>.
1839
1840 =head2 Version 8 Regular Expressions
1841 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1842
1843 In case you're not familiar with the "regular" Version 8 regex
1844 routines, here are the pattern-matching rules not described above.
1845
1846 Any single character matches itself, unless it is a I<metacharacter>
1847 with a special meaning described here or above.  You can cause
1848 characters that normally function as metacharacters to be interpreted
1849 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1850 character; "\\" matches a "\"). This escape mechanism is also required
1851 for the character used as the pattern delimiter.
1852
1853 A series of characters matches that series of characters in the target
1854 string, so the pattern  C<blurfl> would match "blurfl" in the target
1855 string.
1856
1857 You can specify a character class, by enclosing a list of characters
1858 in C<[]>, which will match any character from the list.  If the
1859 first character after the "[" is "^", the class matches any character not
1860 in the list.  Within a list, the "-" character specifies a
1861 range, so that C<a-z> represents all characters between "a" and "z",
1862 inclusive.  If you want either "-" or "]" itself to be a member of a
1863 class, put it at the start of the list (possibly after a "^"), or
1864 escape it with a backslash.  "-" is also taken literally when it is
1865 at the end of the list, just before the closing "]".  (The
1866 following all specify the same class of three characters: C<[-az]>,
1867 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1868 specifies a class containing twenty-six characters, even on EBCDIC-based
1869 character sets.)  Also, if you try to use the character
1870 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1871 a range, the "-" is understood literally.
1872
1873 Note also that the whole range idea is rather unportable between
1874 character sets--and even within character sets they may cause results
1875 you probably didn't expect.  A sound principle is to use only ranges
1876 that begin from and end at either alphabetics of equal case ([a-e],
1877 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1878 spell out the character sets in full.
1879
1880 Characters may be specified using a metacharacter syntax much like that
1881 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1882 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1883 of three octal digits, matches the character whose coded character set value
1884 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1885 matches the character whose ordinal is I<nn>. The expression \cI<x>
1886 matches the character control-I<x>.  Finally, the "." metacharacter
1887 matches any character except "\n" (unless you use C</s>).
1888
1889 You can specify a series of alternatives for a pattern using "|" to
1890 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1891 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1892 first alternative includes everything from the last pattern delimiter
1893 ("(", "[", or the beginning of the pattern) up to the first "|", and
1894 the last alternative contains everything from the last "|" to the next
1895 pattern delimiter.  That's why it's common practice to include
1896 alternatives in parentheses: to minimize confusion about where they
1897 start and end.
1898
1899 Alternatives are tried from left to right, so the first
1900 alternative found for which the entire expression matches, is the one that
1901 is chosen. This means that alternatives are not necessarily greedy. For
1902 example: when matching C<foo|foot> against "barefoot", only the "foo"
1903 part will match, as that is the first alternative tried, and it successfully
1904 matches the target string. (This might not seem important, but it is
1905 important when you are capturing matched text using parentheses.)
1906
1907 Also remember that "|" is interpreted as a literal within square brackets,
1908 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1909
1910 Within a pattern, you may designate subpatterns for later reference
1911 by enclosing them in parentheses, and you may refer back to the
1912 I<n>th subpattern later in the pattern using the metacharacter
1913 \I<n>.  Subpatterns are numbered based on the left to right order
1914 of their opening parenthesis.  A backreference matches whatever
1915 actually matched the subpattern in the string being examined, not
1916 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
1917 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1918 1 matched "0x", even though the rule C<0|0x> could potentially match
1919 the leading 0 in the second number.
1920
1921 =head2 Warning on \1 Instead of $1
1922
1923 Some people get too used to writing things like:
1924
1925     $pattern =~ s/(\W)/\\\1/g;
1926
1927 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
1928 shocking the
1929 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1930 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1931 the usual double-quoted string means a control-A.  The customary Unix
1932 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1933 of doing that, you get yourself into trouble if you then add an C</e>
1934 modifier.
1935
1936     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
1937
1938 Or if you try to do
1939
1940     s/(\d+)/\1000/;
1941
1942 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1943 C<${1}000>.  The operation of interpolation should not be confused
1944 with the operation of matching a backreference.  Certainly they mean two
1945 different things on the I<left> side of the C<s///>.
1946
1947 =head2 Repeated Patterns Matching a Zero-length Substring
1948
1949 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1950
1951 Regular expressions provide a terse and powerful programming language.  As
1952 with most other power tools, power comes together with the ability
1953 to wreak havoc.
1954
1955 A common abuse of this power stems from the ability to make infinite
1956 loops using regular expressions, with something as innocuous as:
1957
1958     'foo' =~ m{ ( o? )* }x;
1959
1960 The C<o?> matches at the beginning of C<'foo'>, and since the position
1961 in the string is not moved by the match, C<o?> would match again and again
1962 because of the C<*> quantifier.  Another common way to create a similar cycle
1963 is with the looping modifier C<//g>:
1964
1965     @matches = ( 'foo' =~ m{ o? }xg );
1966
1967 or
1968
1969     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1970
1971 or the loop implied by split().
1972
1973 However, long experience has shown that many programming tasks may
1974 be significantly simplified by using repeated subexpressions that
1975 may match zero-length substrings.  Here's a simple example being:
1976
1977     @chars = split //, $string;                  # // is not magic in split
1978     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1979
1980 Thus Perl allows such constructs, by I<forcefully breaking
1981 the infinite loop>.  The rules for this are different for lower-level
1982 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1983 ones like the C</g> modifier or split() operator.
1984
1985 The lower-level loops are I<interrupted> (that is, the loop is
1986 broken) when Perl detects that a repeated expression matched a
1987 zero-length substring.   Thus
1988
1989    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1990
1991 is made equivalent to
1992
1993    m{   (?: NON_ZERO_LENGTH )*
1994       |
1995         (?: ZERO_LENGTH )?
1996     }x;
1997
1998 The higher level-loops preserve an additional state between iterations:
1999 whether the last match was zero-length.  To break the loop, the following
2000 match after a zero-length match is prohibited to have a length of zero.
2001 This prohibition interacts with backtracking (see L<"Backtracking">),
2002 and so the I<second best> match is chosen if the I<best> match is of
2003 zero length.
2004
2005 For example:
2006
2007     $_ = 'bar';
2008     s/\w??/<$&>/g;
2009
2010 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2011 match given by non-greedy C<??> is the zero-length match, and the I<second
2012 best> match is what is matched by C<\w>.  Thus zero-length matches
2013 alternate with one-character-long matches.
2014
2015 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2016 position one notch further in the string.
2017
2018 The additional state of being I<matched with zero-length> is associated with
2019 the matched string, and is reset by each assignment to pos().
2020 Zero-length matches at the end of the previous match are ignored
2021 during C<split>.
2022
2023 =head2 Combining RE Pieces
2024
2025 Each of the elementary pieces of regular expressions which were described
2026 before (such as C<ab> or C<\Z>) could match at most one substring
2027 at the given position of the input string.  However, in a typical regular
2028 expression these elementary pieces are combined into more complicated
2029 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
2030 (in these examples C<S> and C<T> are regular subexpressions).
2031
2032 Such combinations can include alternatives, leading to a problem of choice:
2033 if we match a regular expression C<a|ab> against C<"abc">, will it match
2034 substring C<"a"> or C<"ab">?  One way to describe which substring is
2035 actually matched is the concept of backtracking (see L<"Backtracking">).
2036 However, this description is too low-level and makes you think
2037 in terms of a particular implementation.
2038
2039 Another description starts with notions of "better"/"worse".  All the
2040 substrings which may be matched by the given regular expression can be
2041 sorted from the "best" match to the "worst" match, and it is the "best"
2042 match which is chosen.  This substitutes the question of "what is chosen?"
2043 by the question of "which matches are better, and which are worse?".
2044
2045 Again, for elementary pieces there is no such question, since at most
2046 one match at a given position is possible.  This section describes the
2047 notion of better/worse for combining operators.  In the description
2048 below C<S> and C<T> are regular subexpressions.
2049
2050 =over 4
2051
2052 =item C<ST>
2053
2054 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2055 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2056 which can be matched by C<T>.
2057
2058 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
2059 match than C<A'B'>.
2060
2061 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2062 C<B> is better match for C<T> than C<B'>.
2063
2064 =item C<S|T>
2065
2066 When C<S> can match, it is a better match than when only C<T> can match.
2067
2068 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2069 two matches for C<T>.
2070
2071 =item C<S{REPEAT_COUNT}>
2072
2073 Matches as C<SSS...S> (repeated as many times as necessary).
2074
2075 =item C<S{min,max}>
2076
2077 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2078
2079 =item C<S{min,max}?>
2080
2081 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2082
2083 =item C<S?>, C<S*>, C<S+>
2084
2085 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2086
2087 =item C<S??>, C<S*?>, C<S+?>
2088
2089 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2090
2091 =item C<< (?>S) >>
2092
2093 Matches the best match for C<S> and only that.
2094
2095 =item C<(?=S)>, C<(?<=S)>
2096
2097 Only the best match for C<S> is considered.  (This is important only if
2098 C<S> has capturing parentheses, and backreferences are used somewhere
2099 else in the whole regular expression.)
2100
2101 =item C<(?!S)>, C<(?<!S)>
2102
2103 For this grouping operator there is no need to describe the ordering, since
2104 only whether or not C<S> can match is important.
2105
2106 =item C<(??{ EXPR })>, C<(?PARNO)>
2107
2108 The ordering is the same as for the regular expression which is
2109 the result of EXPR, or the pattern contained by capture group PARNO.
2110
2111 =item C<(?(condition)yes-pattern|no-pattern)>
2112
2113 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2114 already determined.  The ordering of the matches is the same as for the
2115 chosen subexpression.
2116
2117 =back
2118
2119 The above recipes describe the ordering of matches I<at a given position>.
2120 One more rule is needed to understand how a match is determined for the
2121 whole regular expression: a match at an earlier position is always better
2122 than a match at a later position.
2123
2124 =head2 Creating Custom RE Engines
2125
2126 Overloaded constants (see L<overload>) provide a simple way to extend
2127 the functionality of the RE engine.
2128
2129 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2130 matches at a boundary between whitespace characters and non-whitespace
2131 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2132 at these positions, so we want to have each C<\Y|> in the place of the
2133 more complicated version.  We can create a module C<customre> to do
2134 this:
2135
2136     package customre;
2137     use overload;
2138
2139     sub import {
2140       shift;
2141       die "No argument to customre::import allowed" if @_;
2142       overload::constant 'qr' => \&convert;
2143     }
2144
2145     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2146
2147     # We must also take care of not escaping the legitimate \\Y|
2148     # sequence, hence the presence of '\\' in the conversion rules.
2149     my %rules = ( '\\' => '\\\\',
2150                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2151     sub convert {
2152       my $re = shift;
2153       $re =~ s{
2154                 \\ ( \\ | Y . )
2155               }
2156               { $rules{$1} or invalid($re,$1) }sgex;
2157       return $re;
2158     }
2159
2160 Now C<use customre> enables the new escape in constant regular
2161 expressions, i.e., those without any runtime variable interpolations.
2162 As documented in L<overload>, this conversion will work only over
2163 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2164 part of this regular expression needs to be converted explicitly
2165 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2166
2167     use customre;
2168     $re = <>;
2169     chomp $re;
2170     $re = customre::convert $re;
2171     /\Y|$re\Y|/;
2172
2173 =head1 PCRE/Python Support
2174
2175 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2176 to the regex syntax. While Perl programmers are encouraged to use the
2177 Perl specific syntax, the following are also accepted:
2178
2179 =over 4
2180
2181 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2182
2183 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2184
2185 =item C<< (?P=NAME) >>
2186
2187 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2188
2189 =item C<< (?P>NAME) >>
2190
2191 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2192
2193 =back
2194
2195 =head1 BUGS
2196
2197 There are numerous problems with case insensitive matching of characters
2198 outside the ASCII range, especially with those whose folds are multiple
2199 characters, such as ligatures like C<LATIN SMALL LIGATURE FF>.
2200
2201 In a bracketed character class with case insensitive matching, ranges only work
2202 for ASCII characters.  For example,
2203 C<m/[\N{CYRILLIC CAPITAL LETTER A}-\N{CYRILLIC CAPITAL LETTER YA}]/i>
2204 doesn't match all the Russian upper and lower case letters.
2205
2206 Many regular expression constructs don't work on EBCDIC platforms.
2207
2208 This document varies from difficult to understand to completely
2209 and utterly opaque.  The wandering prose riddled with jargon is
2210 hard to fathom in several places.
2211
2212 This document needs a rewrite that separates the tutorial content
2213 from the reference content.
2214
2215 =head1 SEE ALSO
2216
2217 L<perlrequick>.
2218
2219 L<perlretut>.
2220
2221 L<perlop/"Regexp Quote-Like Operators">.
2222
2223 L<perlop/"Gory details of parsing quoted constructs">.
2224
2225 L<perlfaq6>.
2226
2227 L<perlfunc/pos>.
2228
2229 L<perllocale>.
2230
2231 L<perlebcdic>.
2232
2233 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2234 by O'Reilly and Associates.