This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
05ea482d9ca3f28b0debfdcadf6aa328e874b492
[perl5.git] / autodoc.pl
1 #!/usr/bin/perl -w
2
3 # Unconditionally regenerate:
4 #
5 #    pod/perlintern.pod
6 #    pod/perlapi.pod
7 #
8 # from information stored in
9 #
10 #    embed.fnc
11 #    plus all the .c and .h files listed in MANIFEST
12 #
13 # Has an optional arg, which is the directory to chdir to before reading
14 # MANIFEST and *.[ch].
15 #
16 # This script is invoked as part of 'make all'
17 #
18 # '=head1' are the only headings looked for.  If the first non-blank line after
19 # the heading begins with a word character, it is considered to be the first 
20 # line of documentation that applies to the heading itself.  That is, it is 
21 # output immediately after the heading, before the first function, and not 
22 # indented. The next input line that is a pod directive terminates this 
23 # heading-level documentation.
24
25 use strict;
26
27 if (@ARGV) {
28     my $workdir = shift;
29     chdir $workdir
30         or die "Couldn't chdir to '$workdir': $!";
31 }
32 require './regen/regen_lib.pl';
33 require './regen/embed_lib.pl';
34
35 #
36 # See database of global and static function prototypes in embed.fnc
37 # This is used to generate prototype headers under various configurations,
38 # export symbols lists for different platforms, and macros to provide an
39 # implicit interpreter context argument.
40 #
41
42 my %docs;
43 my %funcflags;
44 my %macro = (
45              ax => 1,
46              items => 1,
47              ix => 1,
48              svtype => 1,
49             );
50 my %missing;
51
52 my $curheader = "Unknown section";
53
54 sub autodoc ($$) { # parse a file and extract documentation info
55     my($fh,$file) = @_;
56     my($in, $doc, $line, $header_doc);
57
58     # Count lines easier
59     my $get_next_line = sub { $line++; return <$fh> };
60
61 FUNC:
62     while (defined($in = $get_next_line->())) {
63         if ($in =~ /^#\s*define\s+([A-Za-z_][A-Za-z_0-9]+)\(/ &&
64             ($file ne 'embed.h' || $file ne 'proto.h')) {
65             $macro{$1} = $file;
66             next FUNC;
67         }
68         if ($in=~ /^=head1 (.*)/) {
69             $curheader = $1;
70
71             # If the next non-space line begins with a word char, then it is
72             # the start of heading-ldevel documentation.
73             if (defined($doc = $get_next_line->())) {
74                 # Skip over empty lines
75                 while ($doc =~ /^\s+$/) {
76                     if (! defined($doc = $get_next_line->())) {
77                         next FUNC;
78                     }
79                 }
80
81                 if ($doc !~ /^\w/) {
82                     $in = $doc;
83                     redo FUNC;
84                 }
85                 $header_doc = $doc;
86
87                 # Continue getting the heading-level documentation until read
88                 # in any pod directive (or as a fail-safe, find a closing
89                 # comment to this pod in a C language file
90 HDR_DOC:
91                 while (defined($doc = $get_next_line->())) {
92                     if ($doc =~ /^=\w/) {
93                         $in = $doc;
94                         redo FUNC;
95                     }
96
97                     if ($doc =~ m:^\s*\*/$:) {
98                         warn "=cut missing? $file:$line:$doc";;
99                         last HDR_DOC;
100                     }
101                     $header_doc .= $doc;
102                 }
103             }
104             next FUNC;
105         }
106         if ($in =~ /^=for\s+apidoc\s+(.*?)\s*\n/) {
107             my $proto = $1;
108             $proto = "||$proto" unless $proto =~ /\|/;
109             my($flags, $ret, $name, @args) = split /\s*\|\s*/, $proto;
110             my $docs = "";
111 DOC:
112             while (defined($doc = $get_next_line->())) {
113
114                 # Other pod commands are considered part of the current
115                 # function's docs, so can have lists, etc.
116                 last DOC if $doc =~ /^=(cut|for\s+apidoc|head)/;
117                 if ($doc =~ m:^\*/$:) {
118                     warn "=cut missing? $file:$line:$doc";;
119                     last DOC;
120                 }
121                 $docs .= $doc;
122             }
123             $docs = "\n$docs" if $docs and $docs !~ /^\n/;
124
125             # Check the consistency of the flags
126             my ($embed_where, $inline_where);
127             my ($embed_may_change, $inline_may_change);
128
129             my $embed_docref = delete $funcflags{$name};
130             if ($embed_docref and %$embed_docref) {
131                 $embed_where = $embed_docref->{flags} =~ /A/ ? 'api' : 'guts';
132                 $embed_may_change = $embed_docref->{flags} =~ /M/;
133                 $flags .= 'D' if $embed_docref->{flags} =~ /D/;
134             } else {
135                 $missing{$name} = $file;
136             }
137             if ($flags =~ /m/) {
138                 $inline_where = $flags =~ /A/ ? 'api' : 'guts';
139                 $inline_may_change = $flags =~ /x/;
140
141                 if (defined $embed_where && $inline_where ne $embed_where) {
142                     warn "Function '$name' inconsistency: embed.fnc says $embed_where, Pod says $inline_where";
143                 }
144
145                 if (defined $embed_may_change
146                     && $inline_may_change ne $embed_may_change) {
147                     my $message = "Function '$name' inconsistency: ";
148                     if ($embed_may_change) {
149                         $message .= "embed.fnc says 'may change', Pod does not";
150                     } else {
151                         $message .= "Pod says 'may change', embed.fnc does not";
152                     }
153                     warn $message;
154                 }
155             } elsif (!defined $embed_where) {
156                 warn "Unable to place $name!\n";
157                 next;
158             } else {
159                 $inline_where = $embed_where;
160                 $flags .= 'x' if $embed_may_change;
161                 @args = @{$embed_docref->{args}};
162                 $ret = $embed_docref->{retval};
163             }
164
165             if (exists $docs{$inline_where}{$curheader}{$name}) {
166                 warn "$0: duplicate API entry for '$name' in $inline_where/$curheader\n";
167                 next;
168             }
169             $docs{$inline_where}{$curheader}{$name}
170                 = [$flags, $docs, $ret, $file, @args];
171
172             # Create a special entry with an empty-string name for the
173             # heading-level documentation.
174             if (defined $header_doc) {
175                 $docs{$inline_where}{$curheader}{""} = $header_doc;
176                 undef $header_doc;
177             }
178
179             if (defined $doc) {
180                 if ($doc =~ /^=(?:for|head)/) {
181                     $in = $doc;
182                     redo FUNC;
183                 }
184             } else {
185                 warn "$file:$line:$in";
186             }
187         }
188     }
189 }
190
191 sub docout ($$$) { # output the docs for one function
192     my($fh, $name, $docref) = @_;
193     my($flags, $docs, $ret, $file, @args) = @$docref;
194     $name =~ s/\s*$//;
195
196     if ($flags =~ /D/) {
197         $docs = "\n\nDEPRECATED!  It is planned to remove this function from a
198 future release of Perl.  Do not use it for new code; remove it from
199 existing code.\n\n$docs";
200     }
201     else {
202         $docs = "\n\nNOTE: this function is experimental and may change or be
203 removed without notice.\n\n$docs" if $flags =~ /x/;
204     }
205     $docs .= "NOTE: the perl_ form of this function is deprecated.\n\n"
206         if $flags =~ /p/;
207     $docs .= "NOTE: this function must be explicitly called as Perl_$name with an aTHX_ parameter.\n\n"
208         if $flags =~ /o/;
209
210     print $fh "=item $name\nX<$name>\n$docs";
211
212     if ($flags =~ /U/) { # no usage
213         # nothing
214     } else {
215         if ($flags =~ /s/) { # semicolon ("dTHR;")
216             print $fh "\t\t$name;";
217         } elsif ($flags =~ /n/) { # no args
218             print $fh "\t$ret\t$name";
219         } else { # full usage
220             my $p            = $flags =~ /o/; # no #define foo Perl_foo
221             my $n            = "Perl_"x$p . $name;
222             my $large_ret    = length $ret > 7;
223             my $indent_size  = 7+8 # nroff: 7 under =head + 8 under =item
224                             +8+($large_ret ? 1 + length $ret : 8)
225                             +length($n) + 1;
226             my $indent;
227             print $fh "\t$ret" . ($large_ret ? ' ' : "\t") . "$n(";
228             my $long_args;
229             for (@args) {
230                 if ($indent_size + 2 + length > 79) {
231                     $long_args=1;
232                     $indent_size -= length($n) - 3;
233                     last;
234                 }
235             }
236             my $args = '';
237             if ($p) {
238                 $args = @args ? "pTHX_ " : "pTHX";
239                 if ($long_args) { print $fh $args; $args = '' }
240             }
241             $long_args and print $fh "\n";
242             my $first = !$long_args;
243             while () {
244                 if (!@args or
245                     length $args
246                     && $indent_size + 3 + length($args[0]) + length $args > 79
247                 ) {
248                     print $fh
249                     $first ? '' : (
250                         $indent //=
251                         "\t".($large_ret ? " " x (1+length $ret) : "\t")
252                         ." "x($long_args ? 4 : 1 + length $n)
253                     ),
254                     $args, (","x($args ne 'pTHX_ ') . "\n")x!!@args;
255                     $args = $first = '';
256                 }
257                 @args or last;
258                 $args .= ", "x!!(length $args && $args ne 'pTHX_ ')
259                     . shift @args;
260             }
261             if ($long_args) { print $fh "\n", substr $indent, 0, -4 }
262             print $fh ")";
263         }
264         print $fh "\n\n";
265     }
266     print $fh "=for hackers\nFound in file $file\n\n";
267 }
268
269 sub sort_helper {
270     # Do a case-insensitive dictionary sort, with only alphabetics
271     # significant, falling back to using everything for determinancy
272     return (uc($a =~ s/[[:^alpha:]]//r) cmp uc($b =~ s/[[:^alpha:]]//r))
273            || uc($a) cmp uc($b)
274            || $a cmp $b;
275 }
276
277 sub output {
278     my ($podname, $header, $dochash, $missing, $footer) = @_;
279     #
280     # strip leading '|' from each line which had been used to hide
281     # pod from pod checkers.
282     s/^\|//gm for $header, $footer;
283
284     my $fh = open_new("pod/$podname.pod", undef,
285                       {by => "$0 extracting documentation",
286                        from => 'the C source files'}, 1);
287
288     print $fh $header;
289
290     my $key;
291     for $key (sort sort_helper keys %$dochash) {
292         my $section = $dochash->{$key}; 
293         print $fh "\n=head1 $key\n\n";
294
295         # Output any heading-level documentation and delete so won't get in
296         # the way later
297         if (exists $section->{""}) {
298             print $fh $section->{""} . "\n";
299             delete $section->{""};
300         }
301         print $fh "=over 8\n\n";
302
303         for my $key (sort sort_helper keys %$section) {
304             docout($fh, $key, $section->{$key});
305         }
306         print $fh "\n=back\n";
307     }
308
309     if (@$missing) {
310         print $fh "\n=head1 Undocumented functions\n\n";
311     print $fh $podname eq 'perlapi' ? <<'_EOB_' : <<'_EOB_';
312 The following functions have been flagged as part of the public API,
313 but are currently undocumented.  Use them at your own risk, as the
314 interfaces are subject to change.  Functions that are not listed in this
315 document are not intended for public use, and should NOT be used under any
316 circumstances.
317
318 If you feel you need to use one of these functions, first send email to
319 L<perl5-porters@perl.org|mailto:perl5-porters@perl.org>.  It may be
320 that there is a good reason for the function not being documented, and it
321 should be removed from this list; or it may just be that no one has gotten
322 around to documenting it.  In the latter case, you will be asked to submit a
323 patch to document the function.  Once your patch is accepted, it will indicate
324 that the interface is stable (unless it is explicitly marked otherwise) and
325 usable by you.
326 _EOB_
327 The following functions are currently undocumented.  If you use one of
328 them, you may wish to consider creating and submitting documentation for
329 it.
330 _EOB_
331     print $fh "\n=over\n\n";
332
333     for my $missing (sort @$missing) {
334         print $fh "=item $missing\nX<$missing>\n\n";
335     }
336     print $fh "=back\n\n";
337 }
338     print $fh $footer, "=cut\n";
339
340     read_only_bottom_close_and_rename($fh);
341 }
342
343 foreach (@{(setup_embed())[0]}) {
344     next if @$_ < 2;
345     my ($flags, $retval, $func, @args) = @$_;
346     s/\b(?:NN|NULLOK)\b\s+//g for @args;
347
348     $funcflags{$func} = {
349                          flags => $flags,
350                          retval => $retval,
351                          args => \@args,
352                         };
353 }
354
355 # glob() picks up docs from extra .c or .h files that may be in unclean
356 # development trees.
357 open my $fh, '<', 'MANIFEST'
358     or die "Can't open MANIFEST: $!";
359 while (my $line = <$fh>) {
360     next unless my ($file) = $line =~ /^(\S+\.[ch])\t/;
361
362     open F, '<', $file or die "Cannot open $file for docs: $!\n";
363     $curheader = "Functions in file $file\n";
364     autodoc(\*F,$file);
365     close F or die "Error closing $file: $!\n";
366 }
367 close $fh or die "Error whilst reading MANIFEST: $!";
368
369 for (sort keys %funcflags) {
370     next unless $funcflags{$_}{flags} =~ /d/;
371     warn "no docs for $_\n"
372 }
373
374 foreach (sort keys %missing) {
375     next if $macro{$_};
376     # Heuristics for known not-a-function macros:
377     next if /^[A-Z]/;
378     next if /^dj?[A-Z]/;
379
380     warn "Function '$_', documented in $missing{$_}, not listed in embed.fnc";
381 }
382
383 # walk table providing an array of components in each line to
384 # subroutine, printing the result
385
386 # List of funcs in the public API that aren't also marked as experimental nor
387 # deprecated.
388 my @missing_api = grep $funcflags{$_}{flags} =~ /A/ && $funcflags{$_}{flags} !~ /[MD]/ && !$docs{api}{$_}, keys %funcflags;
389 output('perlapi', <<'_EOB_', $docs{api}, \@missing_api, <<'_EOE_');
390 |=encoding UTF-8
391 |
392 |=head1 NAME
393 |
394 |perlapi - autogenerated documentation for the perl public API
395 |
396 |=head1 DESCRIPTION
397 |X<Perl API> X<API> X<api>
398 |
399 |This file contains the documentation of the perl public API generated by
400 |F<embed.pl>, specifically a listing of functions, macros, flags, and variables
401 |that may be used by extension writers.  L<At the end|/Undocumented functions>
402 |is a list of functions which have yet to be documented.  The interfaces of
403 |those are subject to change without notice.  Anything not listed here is
404 |not part of the public API, and should not be used by extension writers at
405 |all.  For these reasons, blindly using functions listed in proto.h is to be
406 |avoided when writing extensions.
407 |
408 |In Perl, unlike C, a string of characters may generally contain embedded
409 |C<NUL> characters.  Sometimes in the documentation a Perl string is referred
410 |to as a "buffer" to distinguish it from a C string, but sometimes they are
411 |both just referred to as strings.
412 |
413 |Note that all Perl API global variables must be referenced with the C<PL_>
414 |prefix.  Again, those not listed here are not to be used by extension writers,
415 |and can be changed or removed without notice; same with macros.
416 |Some macros are provided for compatibility with the older,
417 |unadorned names, but this support may be disabled in a future release.
418 |
419 |Perl was originally written to handle US-ASCII only (that is characters
420 |whose ordinal numbers are in the range 0 - 127).
421 |And documentation and comments may still use the term ASCII, when
422 |sometimes in fact the entire range from 0 - 255 is meant.
423 |
424 |The non-ASCII characters below 256 can have various meanings, depending on
425 |various things.  (See, most notably, L<perllocale>.)  But usually the whole
426 |range can be referred to as ISO-8859-1.  Often, the term "Latin-1" (or
427 |"Latin1") is used as an equivalent for ISO-8859-1.  But some people treat
428 |"Latin1" as referring just to the characters in the range 128 through 255, or
429 |somethimes from 160 through 255.
430 |This documentation uses "Latin1" and "Latin-1" to refer to all 256 characters.
431 |
432 |Note that Perl can be compiled and run under either ASCII or EBCDIC (See
433 |L<perlebcdic>).  Most of the documentation (and even comments in the code)
434 |ignore the EBCDIC possibility.
435 |For almost all purposes the differences are transparent.
436 |As an example, under EBCDIC,
437 |instead of UTF-8, UTF-EBCDIC is used to encode Unicode strings, and so
438 |whenever this documentation refers to C<utf8>
439 |(and variants of that name, including in function names),
440 |it also (essentially transparently) means C<UTF-EBCDIC>.
441 |But the ordinals of characters differ between ASCII, EBCDIC, and
442 |the UTF- encodings, and a string encoded in UTF-EBCDIC may occupy a different
443 |number of bytes than in UTF-8.
444 |
445 |The listing below is alphabetical, case insensitive.
446 |
447 _EOB_
448 |
449 |=head1 AUTHORS
450 |
451 |Until May 1997, this document was maintained by Jeff Okamoto
452 |<okamoto@corp.hp.com>.  It is now maintained as part of Perl itself.
453 |
454 |With lots of help and suggestions from Dean Roehrich, Malcolm Beattie,
455 |Andreas Koenig, Paul Hudson, Ilya Zakharevich, Paul Marquess, Neil
456 |Bowers, Matthew Green, Tim Bunce, Spider Boardman, Ulrich Pfeifer,
457 |Stephen McCamant, and Gurusamy Sarathy.
458 |
459 |API Listing originally by Dean Roehrich <roehrich@cray.com>.
460 |
461 |Updated to be autogenerated from comments in the source by Benjamin Stuhl.
462 |
463 |=head1 SEE ALSO
464 |
465 |L<perlguts>, L<perlxs>, L<perlxstut>, L<perlintern>
466 |
467 _EOE_
468
469 # List of non-static internal functions
470 my @missing_guts =
471  grep $funcflags{$_}{flags} !~ /[AS]/ && !$docs{guts}{$_}, keys %funcflags;
472
473 output('perlintern', <<'END', $docs{guts}, \@missing_guts, <<'END');
474 |=head1 NAME
475 |
476 |perlintern - autogenerated documentation of purely B<internal>
477 |                Perl functions
478 |
479 |=head1 DESCRIPTION
480 |X<internal Perl functions> X<interpreter functions>
481 |
482 |This file is the autogenerated documentation of functions in the
483 |Perl interpreter that are documented using Perl's internal documentation
484 |format but are not marked as part of the Perl API.  In other words,
485 |B<they are not for use in extensions>!
486 |
487 END
488 |
489 |=head1 AUTHORS
490 |
491 |The autodocumentation system was originally added to the Perl core by
492 |Benjamin Stuhl.  Documentation is by whoever was kind enough to
493 |document their functions.
494 |
495 |=head1 SEE ALSO
496 |
497 |L<perlguts>, L<perlapi>
498 |
499 END