This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
05005cb4acadddb934184d505ab8c516ebc7deb9
[perl5.git] / pod / perlfaq4.pod
1 =head1 NAME
2
3 perlfaq4 - Data Manipulation ($Revision: 1.60 $, $Date: 2005/02/14 18:24:01 $)
4
5 =head1 DESCRIPTION
6
7 This section of the FAQ answers questions related to manipulating
8 numbers, dates, strings, arrays, hashes, and miscellaneous data issues.
9
10 =head1 Data: Numbers
11
12 =head2 Why am I getting long decimals (eg, 19.9499999999999) instead of the numbers I should be getting (eg, 19.95)?
13
14 Internally, your computer represents floating-point numbers
15 in binary. Digital (as in powers of two) computers cannot
16 store all numbers exactly.  Some real numbers lose precision
17 in the process.  This is a problem with how computers store
18 numbers and affects all computer languages, not just Perl.
19
20 L<perlnumber> show the gory details of number
21 representations and conversions.
22
23 To limit the number of decimal places in your numbers, you
24 can use the printf or sprintf function.  See the
25 L<"Floating Point Arithmetic"|perlop> for more details.
26
27         printf "%.2f", 10/3;
28
29         my $number = sprintf "%.2f", 10/3;
30
31 =head2 Why is int() broken?
32
33 Your int() is most probably working just fine.  It's the numbers that
34 aren't quite what you think.
35
36 First, see the above item "Why am I getting long decimals
37 (eg, 19.9499999999999) instead of the numbers I should be getting
38 (eg, 19.95)?".
39
40 For example, this
41
42     print int(0.6/0.2-2), "\n";
43
44 will in most computers print 0, not 1, because even such simple
45 numbers as 0.6 and 0.2 cannot be presented exactly by floating-point
46 numbers.  What you think in the above as 'three' is really more like
47 2.9999999999999995559.
48
49 =head2 Why isn't my octal data interpreted correctly?
50
51 Perl only understands octal and hex numbers as such when they occur as
52 literals in your program.  Octal literals in perl must start with a
53 leading "0" and hexadecimal literals must start with a leading "0x".
54 If they are read in from somewhere and assigned, no automatic
55 conversion takes place.  You must explicitly use oct() or hex() if you
56 want the values converted to decimal.  oct() interprets hex ("0x350"),
57 octal ("0350" or even without the leading "0", like "377") and binary
58 ("0b1010") numbers, while hex() only converts hexadecimal ones, with
59 or without a leading "0x", like "0x255", "3A", "ff", or "deadbeef".
60 The inverse mapping from decimal to octal can be done with either the
61 "%o" or "%O" sprintf() formats.
62
63 This problem shows up most often when people try using chmod(), mkdir(),
64 umask(), or sysopen(), which by widespread tradition typically take
65 permissions in octal.
66
67     chmod(644,  $file); # WRONG
68     chmod(0644, $file); # right
69
70 Note the mistake in the first line was specifying the decimal literal
71 644, rather than the intended octal literal 0644.  The problem can
72 be seen with:
73
74     printf("%#o",644); # prints 01204
75
76 Surely you had not intended C<chmod(01204, $file);> - did you?  If you
77 want to use numeric literals as arguments to chmod() et al. then please
78 try to express them as octal constants, that is with a leading zero and
79 with the following digits restricted to the set 0..7.
80
81 =head2 Does Perl have a round() function?  What about ceil() and floor()?  Trig functions?
82
83 Remember that int() merely truncates toward 0.  For rounding to a
84 certain number of digits, sprintf() or printf() is usually the easiest
85 route.
86
87     printf("%.3f", 3.1415926535);       # prints 3.142
88
89 The POSIX module (part of the standard Perl distribution) implements
90 ceil(), floor(), and a number of other mathematical and trigonometric
91 functions.
92
93     use POSIX;
94     $ceil   = ceil(3.5);                        # 4
95     $floor  = floor(3.5);                       # 3
96
97 In 5.000 to 5.003 perls, trigonometry was done in the Math::Complex
98 module.  With 5.004, the Math::Trig module (part of the standard Perl
99 distribution) implements the trigonometric functions. Internally it
100 uses the Math::Complex module and some functions can break out from
101 the real axis into the complex plane, for example the inverse sine of
102 2.
103
104 Rounding in financial applications can have serious implications, and
105 the rounding method used should be specified precisely.  In these
106 cases, it probably pays not to trust whichever system rounding is
107 being used by Perl, but to instead implement the rounding function you
108 need yourself.
109
110 To see why, notice how you'll still have an issue on half-way-point
111 alternation:
112
113     for ($i = 0; $i < 1.01; $i += 0.05) { printf "%.1f ",$i}
114
115     0.0 0.1 0.1 0.2 0.2 0.2 0.3 0.3 0.4 0.4 0.5 0.5 0.6 0.7 0.7
116     0.8 0.8 0.9 0.9 1.0 1.0
117
118 Don't blame Perl.  It's the same as in C.  IEEE says we have to do this.
119 Perl numbers whose absolute values are integers under 2**31 (on 32 bit
120 machines) will work pretty much like mathematical integers.  Other numbers
121 are not guaranteed.
122
123 =head2 How do I convert between numeric representations/bases/radixes?
124
125 As always with Perl there is more than one way to do it.  Below
126 are a few examples of approaches to making common conversions
127 between number representations.  This is intended to be representational
128 rather than exhaustive.
129
130 Some of the examples below use the Bit::Vector module from CPAN.
131 The reason you might choose Bit::Vector over the perl built in
132 functions is that it works with numbers of ANY size, that it is
133 optimized for speed on some operations, and for at least some
134 programmers the notation might be familiar.
135
136 =over 4
137
138 =item How do I convert hexadecimal into decimal
139
140 Using perl's built in conversion of 0x notation:
141
142     $dec = 0xDEADBEEF;
143
144 Using the hex function:
145
146     $dec = hex("DEADBEEF");
147
148 Using pack:
149
150     $dec = unpack("N", pack("H8", substr("0" x 8 . "DEADBEEF", -8)));
151
152 Using the CPAN module Bit::Vector:
153
154     use Bit::Vector;
155     $vec = Bit::Vector->new_Hex(32, "DEADBEEF");
156     $dec = $vec->to_Dec();
157
158 =item How do I convert from decimal to hexadecimal
159
160 Using sprintf:
161
162     $hex = sprintf("%X", 3735928559); # upper case A-F
163     $hex = sprintf("%x", 3735928559); # lower case a-f
164
165 Using unpack:
166
167     $hex = unpack("H*", pack("N", 3735928559));
168
169 Using Bit::Vector:
170
171     use Bit::Vector;
172     $vec = Bit::Vector->new_Dec(32, -559038737);
173     $hex = $vec->to_Hex();
174
175 And Bit::Vector supports odd bit counts:
176
177     use Bit::Vector;
178     $vec = Bit::Vector->new_Dec(33, 3735928559);
179     $vec->Resize(32); # suppress leading 0 if unwanted
180     $hex = $vec->to_Hex();
181
182 =item How do I convert from octal to decimal
183
184 Using Perl's built in conversion of numbers with leading zeros:
185
186     $dec = 033653337357; # note the leading 0!
187
188 Using the oct function:
189
190     $dec = oct("33653337357");
191
192 Using Bit::Vector:
193
194     use Bit::Vector;
195     $vec = Bit::Vector->new(32);
196     $vec->Chunk_List_Store(3, split(//, reverse "33653337357"));
197     $dec = $vec->to_Dec();
198
199 =item How do I convert from decimal to octal
200
201 Using sprintf:
202
203     $oct = sprintf("%o", 3735928559);
204
205 Using Bit::Vector:
206
207     use Bit::Vector;
208     $vec = Bit::Vector->new_Dec(32, -559038737);
209     $oct = reverse join('', $vec->Chunk_List_Read(3));
210
211 =item How do I convert from binary to decimal
212
213 Perl 5.6 lets you write binary numbers directly with
214 the 0b notation:
215
216     $number = 0b10110110;
217
218 Using oct:
219
220     my $input = "10110110";
221     $decimal = oct( "0b$input" );
222
223 Using pack and ord:
224
225     $decimal = ord(pack('B8', '10110110'));
226
227 Using pack and unpack for larger strings:
228
229     $int = unpack("N", pack("B32",
230         substr("0" x 32 . "11110101011011011111011101111", -32)));
231     $dec = sprintf("%d", $int);
232
233     # substr() is used to left pad a 32 character string with zeros.
234
235 Using Bit::Vector:
236
237     $vec = Bit::Vector->new_Bin(32, "11011110101011011011111011101111");
238     $dec = $vec->to_Dec();
239
240 =item How do I convert from decimal to binary
241
242 Using sprintf (perl 5.6+):
243
244     $bin = sprintf("%b", 3735928559);
245
246 Using unpack:
247
248     $bin = unpack("B*", pack("N", 3735928559));
249
250 Using Bit::Vector:
251
252     use Bit::Vector;
253     $vec = Bit::Vector->new_Dec(32, -559038737);
254     $bin = $vec->to_Bin();
255
256 The remaining transformations (e.g. hex -> oct, bin -> hex, etc.)
257 are left as an exercise to the inclined reader.
258
259 =back
260
261 =head2 Why doesn't & work the way I want it to?
262
263 The behavior of binary arithmetic operators depends on whether they're
264 used on numbers or strings.  The operators treat a string as a series
265 of bits and work with that (the string C<"3"> is the bit pattern
266 C<00110011>).  The operators work with the binary form of a number
267 (the number C<3> is treated as the bit pattern C<00000011>).
268
269 So, saying C<11 & 3> performs the "and" operation on numbers (yielding
270 C<3>).  Saying C<"11" & "3"> performs the "and" operation on strings
271 (yielding C<"1">).
272
273 Most problems with C<&> and C<|> arise because the programmer thinks
274 they have a number but really it's a string.  The rest arise because
275 the programmer says:
276
277     if ("\020\020" & "\101\101") {
278         # ...
279     }
280
281 but a string consisting of two null bytes (the result of C<"\020\020"
282 & "\101\101">) is not a false value in Perl.  You need:
283
284     if ( ("\020\020" & "\101\101") !~ /[^\000]/) {
285         # ...
286     }
287
288 =head2 How do I multiply matrices?
289
290 Use the Math::Matrix or Math::MatrixReal modules (available from CPAN)
291 or the PDL extension (also available from CPAN).
292
293 =head2 How do I perform an operation on a series of integers?
294
295 To call a function on each element in an array, and collect the
296 results, use:
297
298     @results = map { my_func($_) } @array;
299
300 For example:
301
302     @triple = map { 3 * $_ } @single;
303
304 To call a function on each element of an array, but ignore the
305 results:
306
307     foreach $iterator (@array) {
308         some_func($iterator);
309     }
310
311 To call a function on each integer in a (small) range, you B<can> use:
312
313     @results = map { some_func($_) } (5 .. 25);
314
315 but you should be aware that the C<..> operator creates an array of
316 all integers in the range.  This can take a lot of memory for large
317 ranges.  Instead use:
318
319     @results = ();
320     for ($i=5; $i < 500_005; $i++) {
321         push(@results, some_func($i));
322     }
323
324 This situation has been fixed in Perl5.005. Use of C<..> in a C<for>
325 loop will iterate over the range, without creating the entire range.
326
327     for my $i (5 .. 500_005) {
328         push(@results, some_func($i));
329     }
330
331 will not create a list of 500,000 integers.
332
333 =head2 How can I output Roman numerals?
334
335 Get the http://www.cpan.org/modules/by-module/Roman module.
336
337 =head2 Why aren't my random numbers random?
338
339 If you're using a version of Perl before 5.004, you must call C<srand>
340 once at the start of your program to seed the random number generator.
341
342          BEGIN { srand() if $] < 5.004 }
343
344 5.004 and later automatically call C<srand> at the beginning.  Don't
345 call C<srand> more than once---you make your numbers less random, rather
346 than more.
347
348 Computers are good at being predictable and bad at being random
349 (despite appearances caused by bugs in your programs :-).  see the
350 F<random> article in the "Far More Than You Ever Wanted To Know"
351 collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz , courtesy of
352 Tom Phoenix, talks more about this.  John von Neumann said, ``Anyone
353 who attempts to generate random numbers by deterministic means is, of
354 course, living in a state of sin.''
355
356 If you want numbers that are more random than C<rand> with C<srand>
357 provides, you should also check out the Math::TrulyRandom module from
358 CPAN.  It uses the imperfections in your system's timer to generate
359 random numbers, but this takes quite a while.  If you want a better
360 pseudorandom generator than comes with your operating system, look at
361 ``Numerical Recipes in C'' at http://www.nr.com/ .
362
363 =head2 How do I get a random number between X and Y?
364
365 C<rand($x)> returns a number such that
366 C<< 0 <= rand($x) < $x >>. Thus what you want to have perl
367 figure out is a random number in the range from 0 to the
368 difference between your I<X> and I<Y>.
369
370 That is, to get a number between 10 and 15, inclusive, you
371 want a random number between 0 and 5 that you can then add
372 to 10.
373
374     my $number = 10 + int rand( 15-10+1 );
375
376 Hence you derive the following simple function to abstract
377 that. It selects a random integer between the two given
378 integers (inclusive), For example: C<random_int_in(50,120)>.
379
380    sub random_int_in ($$) {
381      my($min, $max) = @_;
382       # Assumes that the two arguments are integers themselves!
383      return $min if $min == $max;
384      ($min, $max) = ($max, $min)  if  $min > $max;
385      return $min + int rand(1 + $max - $min);
386    }
387
388 =head1 Data: Dates
389
390 =head2 How do I find the day or week of the year?
391
392 The localtime function returns the day of the week.  Without an
393 argument localtime uses the current time.
394
395     $day_of_year = (localtime)[7];
396
397 The POSIX module can also format a date as the day of the year or
398 week of the year.
399
400         use POSIX qw/strftime/;
401         my $day_of_year  = strftime "%j", localtime;
402         my $week_of_year = strftime "%W", localtime;
403
404 To get the day of year for any date, use the Time::Local module to get
405 a time in epoch seconds for the argument to localtime.
406
407         use POSIX qw/strftime/;
408         use Time::Local;
409         my $week_of_year = strftime "%W", 
410                 localtime( timelocal( 0, 0, 0, 18, 11, 1987 ) );
411
412 The Date::Calc module provides two functions for to calculate these.
413
414         use Date::Calc;
415         my $day_of_year  = Day_of_Year(  1987, 12, 18 );
416         my $week_of_year = Week_of_Year( 1987, 12, 18 );
417
418 =head2 How do I find the current century or millennium?
419
420 Use the following simple functions:
421
422     sub get_century    {
423         return int((((localtime(shift || time))[5] + 1999))/100);
424     }
425     sub get_millennium {
426         return 1+int((((localtime(shift || time))[5] + 1899))/1000);
427     }
428
429 On some systems, the POSIX module's strftime() function has
430 been extended in a non-standard way to use a C<%C> format,
431 which they sometimes claim is the "century".  It isn't,
432 because on most such systems, this is only the first two
433 digits of the four-digit year, and thus cannot be used to
434 reliably determine the current century or millennium.
435
436 =head2 How can I compare two dates and find the difference?
437
438 If you're storing your dates as epoch seconds then simply subtract one
439 from the other.  If you've got a structured date (distinct year, day,
440 month, hour, minute, seconds values), then for reasons of accessibility,
441 simplicity, and efficiency, merely use either timelocal or timegm (from
442 the Time::Local module in the standard distribution) to reduce structured
443 dates to epoch seconds.  However, if you don't know the precise format of
444 your dates, then you should probably use either of the Date::Manip and
445 Date::Calc modules from CPAN before you go hacking up your own parsing
446 routine to handle arbitrary date formats.
447
448 =head2 How can I take a string and turn it into epoch seconds?
449
450 If it's a regular enough string that it always has the same format,
451 you can split it up and pass the parts to C<timelocal> in the standard
452 Time::Local module.  Otherwise, you should look into the Date::Calc
453 and Date::Manip modules from CPAN.
454
455 =head2 How can I find the Julian Day?
456
457 (contributed by brian d foy and Dave Cross)
458
459 You can use the Time::JulianDay module available on CPAN.  Ensure that
460 you really want to find a Julian day, though, as many people have
461 different ideas about Julian days.  See
462 http://www.hermetic.ch/cal_stud/jdn.htm for instance.
463
464 You can also try the DateTime module, which can convert a date/time
465 to a Julian Day.
466
467   $ perl -MDateTime -le'print DateTime->today->jd'
468   2453401.5
469
470 Or the modified Julian Day
471
472   $ perl -MDateTime -le'print DateTime->today->mjd'
473   53401
474
475 Or even the day of the year (which is what some people think of as a
476 Julian day)
477
478   $ perl -MDateTime -le'print DateTime->today->doy'
479   31
480
481 =head2 How do I find yesterday's date?
482
483 If you only need to find the date (and not the same time), you
484 can use the Date::Calc module.
485
486         use Date::Calc qw(Today Add_Delta_Days);
487
488         my @date = Add_Delta_Days( Today(), -1 );
489
490         print "@date\n";
491
492 Most people try to use the time rather than the calendar to
493 figure out dates, but that assumes that your days are
494 twenty-four hours each.  For most people, there are two days
495 a year when they aren't: the switch to and from summer time
496 throws this off. Russ Allbery offers this solution.
497
498     sub yesterday {
499                 my $now  = defined $_[0] ? $_[0] : time;
500                 my $then = $now - 60 * 60 * 24;
501                 my $ndst = (localtime $now)[8] > 0;
502                 my $tdst = (localtime $then)[8] > 0;
503                 $then - ($tdst - $ndst) * 60 * 60;
504                 }
505
506 Should give you "this time yesterday" in seconds since epoch relative to
507 the first argument or the current time if no argument is given and
508 suitable for passing to localtime or whatever else you need to do with
509 it.  $ndst is whether we're currently in daylight savings time; $tdst is
510 whether the point 24 hours ago was in daylight savings time.  If $tdst
511 and $ndst are the same, a boundary wasn't crossed, and the correction
512 will subtract 0.  If $tdst is 1 and $ndst is 0, subtract an hour more
513 from yesterday's time since we gained an extra hour while going off
514 daylight savings time.  If $tdst is 0 and $ndst is 1, subtract a
515 negative hour (add an hour) to yesterday's time since we lost an hour.
516
517 All of this is because during those days when one switches off or onto
518 DST, a "day" isn't 24 hours long; it's either 23 or 25.
519
520 The explicit settings of $ndst and $tdst are necessary because localtime
521 only says it returns the system tm struct, and the system tm struct at
522 least on Solaris doesn't guarantee any particular positive value (like,
523 say, 1) for isdst, just a positive value.  And that value can
524 potentially be negative, if DST information isn't available (this sub
525 just treats those cases like no DST).
526
527 Note that between 2am and 3am on the day after the time zone switches
528 off daylight savings time, the exact hour of "yesterday" corresponding
529 to the current hour is not clearly defined.  Note also that if used
530 between 2am and 3am the day after the change to daylight savings time,
531 the result will be between 3am and 4am of the previous day; it's
532 arguable whether this is correct.
533
534 This sub does not attempt to deal with leap seconds (most things don't).
535
536
537
538 =head2 Does Perl have a Year 2000 problem?  Is Perl Y2K compliant?
539
540 Short answer: No, Perl does not have a Year 2000 problem.  Yes, Perl is
541 Y2K compliant (whatever that means).  The programmers you've hired to
542 use it, however, probably are not.
543
544 Long answer: The question belies a true understanding of the issue.
545 Perl is just as Y2K compliant as your pencil--no more, and no less.
546 Can you use your pencil to write a non-Y2K-compliant memo?  Of course
547 you can.  Is that the pencil's fault?  Of course it isn't.
548
549 The date and time functions supplied with Perl (gmtime and localtime)
550 supply adequate information to determine the year well beyond 2000
551 (2038 is when trouble strikes for 32-bit machines).  The year returned
552 by these functions when used in a list context is the year minus 1900.
553 For years between 1910 and 1999 this I<happens> to be a 2-digit decimal
554 number. To avoid the year 2000 problem simply do not treat the year as
555 a 2-digit number.  It isn't.
556
557 When gmtime() and localtime() are used in scalar context they return
558 a timestamp string that contains a fully-expanded year.  For example,
559 C<$timestamp = gmtime(1005613200)> sets $timestamp to "Tue Nov 13 01:00:00
560 2001".  There's no year 2000 problem here.
561
562 That doesn't mean that Perl can't be used to create non-Y2K compliant
563 programs.  It can.  But so can your pencil.  It's the fault of the user,
564 not the language.  At the risk of inflaming the NRA: ``Perl doesn't
565 break Y2K, people do.''  See http://www.perl.org/about/y2k.html for
566 a longer exposition.
567
568 =head1 Data: Strings
569
570 =head2 How do I validate input?
571
572 The answer to this question is usually a regular expression, perhaps
573 with auxiliary logic.  See the more specific questions (numbers, mail
574 addresses, etc.) for details.
575
576 =head2 How do I unescape a string?
577
578 It depends just what you mean by ``escape''.  URL escapes are dealt
579 with in L<perlfaq9>.  Shell escapes with the backslash (C<\>)
580 character are removed with
581
582     s/\\(.)/$1/g;
583
584 This won't expand C<"\n"> or C<"\t"> or any other special escapes.
585
586 =head2 How do I remove consecutive pairs of characters?
587
588 To turn C<"abbcccd"> into C<"abccd">:
589
590     s/(.)\1/$1/g;       # add /s to include newlines
591
592 Here's a solution that turns "abbcccd" to "abcd":
593
594     y///cs;     # y == tr, but shorter :-)
595
596 =head2 How do I expand function calls in a string?
597
598 This is documented in L<perlref>.  In general, this is fraught with
599 quoting and readability problems, but it is possible.  To interpolate
600 a subroutine call (in list context) into a string:
601
602     print "My sub returned @{[mysub(1,2,3)]} that time.\n";
603
604 =head2 How do I find matching/nesting anything?
605
606 This isn't something that can be done in one regular expression, no
607 matter how complicated.  To find something between two single
608 characters, a pattern like C</x([^x]*)x/> will get the intervening
609 bits in $1. For multiple ones, then something more like
610 C</alpha(.*?)omega/> would be needed.  But none of these deals with
611 nested patterns.  For balanced expressions using C<(>, C<{>, C<[>
612 or C<< < >> as delimiters, use the CPAN module Regexp::Common, or see
613 L<perlre/(??{ code })>.  For other cases, you'll have to write a parser.
614
615 If you are serious about writing a parser, there are a number of
616 modules or oddities that will make your life a lot easier.  There are
617 the CPAN modules Parse::RecDescent, Parse::Yapp, and Text::Balanced;
618 and the byacc program.   Starting from perl 5.8 the Text::Balanced
619 is part of the standard distribution.
620
621 One simple destructive, inside-out approach that you might try is to
622 pull out the smallest nesting parts one at a time:
623
624     while (s/BEGIN((?:(?!BEGIN)(?!END).)*)END//gs) {
625         # do something with $1
626     }
627
628 A more complicated and sneaky approach is to make Perl's regular
629 expression engine do it for you.  This is courtesy Dean Inada, and
630 rather has the nature of an Obfuscated Perl Contest entry, but it
631 really does work:
632
633     # $_ contains the string to parse
634     # BEGIN and END are the opening and closing markers for the
635     # nested text.
636
637     @( = ('(','');
638     @) = (')','');
639     ($re=$_)=~s/((BEGIN)|(END)|.)/$)[!$3]\Q$1\E$([!$2]/gs;
640     @$ = (eval{/$re/},$@!~/unmatched/i);
641     print join("\n",@$[0..$#$]) if( $$[-1] );
642
643 =head2 How do I reverse a string?
644
645 Use reverse() in scalar context, as documented in
646 L<perlfunc/reverse>.
647
648     $reversed = reverse $string;
649
650 =head2 How do I expand tabs in a string?
651
652 You can do it yourself:
653
654     1 while $string =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e;
655
656 Or you can just use the Text::Tabs module (part of the standard Perl
657 distribution).
658
659     use Text::Tabs;
660     @expanded_lines = expand(@lines_with_tabs);
661
662 =head2 How do I reformat a paragraph?
663
664 Use Text::Wrap (part of the standard Perl distribution):
665
666     use Text::Wrap;
667     print wrap("\t", '  ', @paragraphs);
668
669 The paragraphs you give to Text::Wrap should not contain embedded
670 newlines.  Text::Wrap doesn't justify the lines (flush-right).
671
672 Or use the CPAN module Text::Autoformat.  Formatting files can be easily
673 done by making a shell alias, like so:
674
675     alias fmt="perl -i -MText::Autoformat -n0777 \
676         -e 'print autoformat $_, {all=>1}' $*"
677
678 See the documentation for Text::Autoformat to appreciate its many
679 capabilities.
680
681 =head2 How can I access or change N characters of a string?
682
683 You can access the first characters of a string with substr().
684 To get the first character, for example, start at position 0
685 and grab the string of length 1.
686
687
688         $string = "Just another Perl Hacker";
689     $first_char = substr( $string, 0, 1 );  #  'J'
690
691 To change part of a string, you can use the optional fourth
692 argument which is the replacement string.
693
694     substr( $string, 13, 4, "Perl 5.8.0" );
695
696 You can also use substr() as an lvalue.
697
698     substr( $string, 13, 4 ) =  "Perl 5.8.0";
699
700 =head2 How do I change the Nth occurrence of something?
701
702 You have to keep track of N yourself.  For example, let's say you want
703 to change the fifth occurrence of C<"whoever"> or C<"whomever"> into
704 C<"whosoever"> or C<"whomsoever">, case insensitively.  These
705 all assume that $_ contains the string to be altered.
706
707     $count = 0;
708     s{((whom?)ever)}{
709         ++$count == 5           # is it the 5th?
710             ? "${2}soever"      # yes, swap
711             : $1                # renege and leave it there
712     }ige;
713
714 In the more general case, you can use the C</g> modifier in a C<while>
715 loop, keeping count of matches.
716
717     $WANT = 3;
718     $count = 0;
719     $_ = "One fish two fish red fish blue fish";
720     while (/(\w+)\s+fish\b/gi) {
721         if (++$count == $WANT) {
722             print "The third fish is a $1 one.\n";
723         }
724     }
725
726 That prints out: C<"The third fish is a red one.">  You can also use a
727 repetition count and repeated pattern like this:
728
729     /(?:\w+\s+fish\s+){2}(\w+)\s+fish/i;
730
731 =head2 How can I count the number of occurrences of a substring within a string?
732
733 There are a number of ways, with varying efficiency.  If you want a
734 count of a certain single character (X) within a string, you can use the
735 C<tr///> function like so:
736
737     $string = "ThisXlineXhasXsomeXx'sXinXit";
738     $count = ($string =~ tr/X//);
739     print "There are $count X characters in the string";
740
741 This is fine if you are just looking for a single character.  However,
742 if you are trying to count multiple character substrings within a
743 larger string, C<tr///> won't work.  What you can do is wrap a while()
744 loop around a global pattern match.  For example, let's count negative
745 integers:
746
747     $string = "-9 55 48 -2 23 -76 4 14 -44";
748     while ($string =~ /-\d+/g) { $count++ }
749     print "There are $count negative numbers in the string";
750
751 Another version uses a global match in list context, then assigns the
752 result to a scalar, producing a count of the number of matches.
753
754         $count = () = $string =~ /-\d+/g;
755
756 =head2 How do I capitalize all the words on one line?
757
758 To make the first letter of each word upper case:
759
760         $line =~ s/\b(\w)/\U$1/g;
761
762 This has the strange effect of turning "C<don't do it>" into "C<Don'T
763 Do It>".  Sometimes you might want this.  Other times you might need a
764 more thorough solution (Suggested by brian d foy):
765
766     $string =~ s/ (
767                  (^\w)    #at the beginning of the line
768                    |      # or
769                  (\s\w)   #preceded by whitespace
770                    )
771                 /\U$1/xg;
772     $string =~ /([\w']+)/\u\L$1/g;
773
774 To make the whole line upper case:
775
776         $line = uc($line);
777
778 To force each word to be lower case, with the first letter upper case:
779
780         $line =~ s/(\w+)/\u\L$1/g;
781
782 You can (and probably should) enable locale awareness of those
783 characters by placing a C<use locale> pragma in your program.
784 See L<perllocale> for endless details on locales.
785
786 This is sometimes referred to as putting something into "title
787 case", but that's not quite accurate.  Consider the proper
788 capitalization of the movie I<Dr. Strangelove or: How I Learned to
789 Stop Worrying and Love the Bomb>, for example.
790
791 Damian Conway's L<Text::Autoformat> module provides some smart
792 case transformations:
793
794     use Text::Autoformat;
795     my $x = "Dr. Strangelove or: How I Learned to Stop ".
796       "Worrying and Love the Bomb";
797
798     print $x, "\n";
799     for my $style (qw( sentence title highlight ))
800     {
801         print autoformat($x, { case => $style }), "\n";
802     }
803
804 =head2 How can I split a [character] delimited string except when inside [character]?
805
806 Several modules can handle this sort of pasing---Text::Balanced,
807 Text::CSV, Text::CSV_XS, and Text::ParseWords, among others.
808
809 Take the example case of trying to split a string that is
810 comma-separated into its different fields. You can't use C<split(/,/)>
811 because you shouldn't split if the comma is inside quotes.  For
812 example, take a data line like this:
813
814     SAR001,"","Cimetrix, Inc","Bob Smith","CAM",N,8,1,0,7,"Error, Core Dumped"
815
816 Due to the restriction of the quotes, this is a fairly complex
817 problem.  Thankfully, we have Jeffrey Friedl, author of
818 I<Mastering Regular Expressions>, to handle these for us.  He
819 suggests (assuming your string is contained in $text):
820
821      @new = ();
822      push(@new, $+) while $text =~ m{
823          "([^\"\\]*(?:\\.[^\"\\]*)*)",?  # groups the phrase inside the quotes
824        | ([^,]+),?
825        | ,
826      }gx;
827      push(@new, undef) if substr($text,-1,1) eq ',';
828
829 If you want to represent quotation marks inside a
830 quotation-mark-delimited field, escape them with backslashes (eg,
831 C<"like \"this\"">.
832
833 Alternatively, the Text::ParseWords module (part of the standard Perl
834 distribution) lets you say:
835
836     use Text::ParseWords;
837     @new = quotewords(",", 0, $text);
838
839 There's also a Text::CSV (Comma-Separated Values) module on CPAN.
840
841 =head2 How do I strip blank space from the beginning/end of a string?
842
843 Although the simplest approach would seem to be
844
845     $string =~ s/^\s*(.*?)\s*$/$1/;
846
847 not only is this unnecessarily slow and destructive, it also fails with
848 embedded newlines.  It is much faster to do this operation in two steps:
849
850     $string =~ s/^\s+//;
851     $string =~ s/\s+$//;
852
853 Or more nicely written as:
854
855     for ($string) {
856         s/^\s+//;
857         s/\s+$//;
858     }
859
860 This idiom takes advantage of the C<foreach> loop's aliasing
861 behavior to factor out common code.  You can do this
862 on several strings at once, or arrays, or even the
863 values of a hash if you use a slice:
864
865     # trim whitespace in the scalar, the array,
866     # and all the values in the hash
867     foreach ($scalar, @array, @hash{keys %hash}) {
868         s/^\s+//;
869         s/\s+$//;
870     }
871
872 =head2 How do I pad a string with blanks or pad a number with zeroes?
873
874 In the following examples, C<$pad_len> is the length to which you wish
875 to pad the string, C<$text> or C<$num> contains the string to be padded,
876 and C<$pad_char> contains the padding character. You can use a single
877 character string constant instead of the C<$pad_char> variable if you
878 know what it is in advance. And in the same way you can use an integer in
879 place of C<$pad_len> if you know the pad length in advance.
880
881 The simplest method uses the C<sprintf> function. It can pad on the left
882 or right with blanks and on the left with zeroes and it will not
883 truncate the result. The C<pack> function can only pad strings on the
884 right with blanks and it will truncate the result to a maximum length of
885 C<$pad_len>.
886
887     # Left padding a string with blanks (no truncation):
888         $padded = sprintf("%${pad_len}s", $text);
889         $padded = sprintf("%*s", $pad_len, $text);  # same thing
890
891     # Right padding a string with blanks (no truncation):
892         $padded = sprintf("%-${pad_len}s", $text);
893         $padded = sprintf("%-*s", $pad_len, $text); # same thing
894
895     # Left padding a number with 0 (no truncation):
896         $padded = sprintf("%0${pad_len}d", $num);
897         $padded = sprintf("%0*d", $pad_len, $num); # same thing
898
899     # Right padding a string with blanks using pack (will truncate):
900     $padded = pack("A$pad_len",$text);
901
902 If you need to pad with a character other than blank or zero you can use
903 one of the following methods.  They all generate a pad string with the
904 C<x> operator and combine that with C<$text>. These methods do
905 not truncate C<$text>.
906
907 Left and right padding with any character, creating a new string:
908
909     $padded = $pad_char x ( $pad_len - length( $text ) ) . $text;
910     $padded = $text . $pad_char x ( $pad_len - length( $text ) );
911
912 Left and right padding with any character, modifying C<$text> directly:
913
914     substr( $text, 0, 0 ) = $pad_char x ( $pad_len - length( $text ) );
915     $text .= $pad_char x ( $pad_len - length( $text ) );
916
917 =head2 How do I extract selected columns from a string?
918
919 Use substr() or unpack(), both documented in L<perlfunc>.
920 If you prefer thinking in terms of columns instead of widths,
921 you can use this kind of thing:
922
923     # determine the unpack format needed to split Linux ps output
924     # arguments are cut columns
925     my $fmt = cut2fmt(8, 14, 20, 26, 30, 34, 41, 47, 59, 63, 67, 72);
926
927     sub cut2fmt {
928         my(@positions) = @_;
929         my $template  = '';
930         my $lastpos   = 1;
931         for my $place (@positions) {
932             $template .= "A" . ($place - $lastpos) . " ";
933             $lastpos   = $place;
934         }
935         $template .= "A*";
936         return $template;
937     }
938
939 =head2 How do I find the soundex value of a string?
940
941 (contributed by brian d foy)
942
943 You can use the Text::Soundex module. If you want to do fuzzy or close
944 matching, you might also try the String::Approx, and Text::Metaphone,
945 and Text::DoubleMetaphone modules.
946
947 =head2 How can I expand variables in text strings?
948
949 Let's assume that you have a string that contains placeholder
950 variables.
951
952     $text = 'this has a $foo in it and a $bar';
953
954 You can use a substitution with a double evaluation.  The
955 first /e turns C<$1> into C<$foo>, and the second /e turns
956 C<$foo> into its value.  You may want to wrap this in an
957 C<eval>: if you try to get the value of an undeclared variable
958 while running under C<use strict>, you get a fatal error.
959
960     eval { $text =~ s/(\$\w+)/$1/eeg };
961     die if $@;
962
963 It's probably better in the general case to treat those
964 variables as entries in some special hash.  For example:
965
966     %user_defs = (
967         foo  => 23,
968         bar  => 19,
969     );
970     $text =~ s/\$(\w+)/$user_defs{$1}/g;
971
972 =head2 What's wrong with always quoting "$vars"?
973
974 The problem is that those double-quotes force stringification--
975 coercing numbers and references into strings--even when you
976 don't want them to be strings.  Think of it this way: double-quote
977 expansion is used to produce new strings.  If you already
978 have a string, why do you need more?
979
980 If you get used to writing odd things like these:
981
982     print "$var";       # BAD
983     $new = "$old";      # BAD
984     somefunc("$var");   # BAD
985
986 You'll be in trouble.  Those should (in 99.8% of the cases) be
987 the simpler and more direct:
988
989     print $var;
990     $new = $old;
991     somefunc($var);
992
993 Otherwise, besides slowing you down, you're going to break code when
994 the thing in the scalar is actually neither a string nor a number, but
995 a reference:
996
997     func(\@array);
998     sub func {
999         my $aref = shift;
1000         my $oref = "$aref";  # WRONG
1001     }
1002
1003 You can also get into subtle problems on those few operations in Perl
1004 that actually do care about the difference between a string and a
1005 number, such as the magical C<++> autoincrement operator or the
1006 syscall() function.
1007
1008 Stringification also destroys arrays.
1009
1010     @lines = `command`;
1011     print "@lines";             # WRONG - extra blanks
1012     print @lines;               # right
1013
1014 =head2 Why don't my E<lt>E<lt>HERE documents work?
1015
1016 Check for these three things:
1017
1018 =over 4
1019
1020 =item There must be no space after the E<lt>E<lt> part.
1021
1022 =item There (probably) should be a semicolon at the end.
1023
1024 =item You can't (easily) have any space in front of the tag.
1025
1026 =back
1027
1028 If you want to indent the text in the here document, you
1029 can do this:
1030
1031     # all in one
1032     ($VAR = <<HERE_TARGET) =~ s/^\s+//gm;
1033         your text
1034         goes here
1035     HERE_TARGET
1036
1037 But the HERE_TARGET must still be flush against the margin.
1038 If you want that indented also, you'll have to quote
1039 in the indentation.
1040
1041     ($quote = <<'    FINIS') =~ s/^\s+//gm;
1042             ...we will have peace, when you and all your works have
1043             perished--and the works of your dark master to whom you
1044             would deliver us. You are a liar, Saruman, and a corrupter
1045             of men's hearts.  --Theoden in /usr/src/perl/taint.c
1046         FINIS
1047     $quote =~ s/\s+--/\n--/;
1048
1049 A nice general-purpose fixer-upper function for indented here documents
1050 follows.  It expects to be called with a here document as its argument.
1051 It looks to see whether each line begins with a common substring, and
1052 if so, strips that substring off.  Otherwise, it takes the amount of leading
1053 whitespace found on the first line and removes that much off each
1054 subsequent line.
1055
1056     sub fix {
1057         local $_ = shift;
1058         my ($white, $leader);  # common whitespace and common leading string
1059         if (/^\s*(?:([^\w\s]+)(\s*).*\n)(?:\s*\1\2?.*\n)+$/) {
1060             ($white, $leader) = ($2, quotemeta($1));
1061         } else {
1062             ($white, $leader) = (/^(\s+)/, '');
1063         }
1064         s/^\s*?$leader(?:$white)?//gm;
1065         return $_;
1066     }
1067
1068 This works with leading special strings, dynamically determined:
1069
1070     $remember_the_main = fix<<'    MAIN_INTERPRETER_LOOP';
1071         @@@ int
1072         @@@ runops() {
1073         @@@     SAVEI32(runlevel);
1074         @@@     runlevel++;
1075         @@@     while ( op = (*op->op_ppaddr)() );
1076         @@@     TAINT_NOT;
1077         @@@     return 0;
1078         @@@ }
1079     MAIN_INTERPRETER_LOOP
1080
1081 Or with a fixed amount of leading whitespace, with remaining
1082 indentation correctly preserved:
1083
1084     $poem = fix<<EVER_ON_AND_ON;
1085        Now far ahead the Road has gone,
1086           And I must follow, if I can,
1087        Pursuing it with eager feet,
1088           Until it joins some larger way
1089        Where many paths and errands meet.
1090           And whither then? I cannot say.
1091                 --Bilbo in /usr/src/perl/pp_ctl.c
1092     EVER_ON_AND_ON
1093
1094 =head1 Data: Arrays
1095
1096 =head2 What is the difference between a list and an array?
1097
1098 An array has a changeable length.  A list does not.  An array is something
1099 you can push or pop, while a list is a set of values.  Some people make
1100 the distinction that a list is a value while an array is a variable.
1101 Subroutines are passed and return lists, you put things into list
1102 context, you initialize arrays with lists, and you foreach() across
1103 a list.  C<@> variables are arrays, anonymous arrays are arrays, arrays
1104 in scalar context behave like the number of elements in them, subroutines
1105 access their arguments through the array C<@_>, and push/pop/shift only work
1106 on arrays.
1107
1108 As a side note, there's no such thing as a list in scalar context.
1109 When you say
1110
1111     $scalar = (2, 5, 7, 9);
1112
1113 you're using the comma operator in scalar context, so it uses the scalar
1114 comma operator.  There never was a list there at all!  This causes the
1115 last value to be returned: 9.
1116
1117 =head2 What is the difference between $array[1] and @array[1]?
1118
1119 The former is a scalar value; the latter an array slice, making
1120 it a list with one (scalar) value.  You should use $ when you want a
1121 scalar value (most of the time) and @ when you want a list with one
1122 scalar value in it (very, very rarely; nearly never, in fact).
1123
1124 Sometimes it doesn't make a difference, but sometimes it does.
1125 For example, compare:
1126
1127     $good[0] = `some program that outputs several lines`;
1128
1129 with
1130
1131     @bad[0]  = `same program that outputs several lines`;
1132
1133 The C<use warnings> pragma and the B<-w> flag will warn you about these
1134 matters.
1135
1136 =head2 How can I remove duplicate elements from a list or array?
1137
1138 There are several possible ways, depending on whether the array is
1139 ordered and whether you wish to preserve the ordering.
1140
1141 =over 4
1142
1143 =item a)
1144
1145 If @in is sorted, and you want @out to be sorted:
1146 (this assumes all true values in the array)
1147
1148     $prev = "not equal to $in[0]";
1149     @out = grep($_ ne $prev && ($prev = $_, 1), @in);
1150
1151 This is nice in that it doesn't use much extra memory, simulating
1152 uniq(1)'s behavior of removing only adjacent duplicates.  The ", 1"
1153 guarantees that the expression is true (so that grep picks it up)
1154 even if the $_ is 0, "", or undef.
1155
1156 =item b)
1157
1158 If you don't know whether @in is sorted:
1159
1160     undef %saw;
1161     @out = grep(!$saw{$_}++, @in);
1162
1163 =item c)
1164
1165 Like (b), but @in contains only small integers:
1166
1167     @out = grep(!$saw[$_]++, @in);
1168
1169 =item d)
1170
1171 A way to do (b) without any loops or greps:
1172
1173     undef %saw;
1174     @saw{@in} = ();
1175     @out = sort keys %saw;  # remove sort if undesired
1176
1177 =item e)
1178
1179 Like (d), but @in contains only small positive integers:
1180
1181     undef @ary;
1182     @ary[@in] = @in;
1183     @out = grep {defined} @ary;
1184
1185 =back
1186
1187 But perhaps you should have been using a hash all along, eh?
1188
1189 =head2 How can I tell whether a certain element is contained in a list or array?
1190
1191 Hearing the word "in" is an I<in>dication that you probably should have
1192 used a hash, not a list or array, to store your data.  Hashes are
1193 designed to answer this question quickly and efficiently.  Arrays aren't.
1194
1195 That being said, there are several ways to approach this.  If you
1196 are going to make this query many times over arbitrary string values,
1197 the fastest way is probably to invert the original array and maintain a
1198 hash whose keys are the first array's values.
1199
1200     @blues = qw/azure cerulean teal turquoise lapis-lazuli/;
1201     %is_blue = ();
1202     for (@blues) { $is_blue{$_} = 1 }
1203
1204 Now you can check whether $is_blue{$some_color}.  It might have been a
1205 good idea to keep the blues all in a hash in the first place.
1206
1207 If the values are all small integers, you could use a simple indexed
1208 array.  This kind of an array will take up less space:
1209
1210     @primes = (2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31);
1211     @is_tiny_prime = ();
1212     for (@primes) { $is_tiny_prime[$_] = 1 }
1213     # or simply  @istiny_prime[@primes] = (1) x @primes;
1214
1215 Now you check whether $is_tiny_prime[$some_number].
1216
1217 If the values in question are integers instead of strings, you can save
1218 quite a lot of space by using bit strings instead:
1219
1220     @articles = ( 1..10, 150..2000, 2017 );
1221     undef $read;
1222     for (@articles) { vec($read,$_,1) = 1 }
1223
1224 Now check whether C<vec($read,$n,1)> is true for some C<$n>.
1225
1226 Please do not use
1227
1228     ($is_there) = grep $_ eq $whatever, @array;
1229
1230 or worse yet
1231
1232     ($is_there) = grep /$whatever/, @array;
1233
1234 These are slow (checks every element even if the first matches),
1235 inefficient (same reason), and potentially buggy (what if there are
1236 regex characters in $whatever?).  If you're only testing once, then
1237 use:
1238
1239     $is_there = 0;
1240     foreach $elt (@array) {
1241         if ($elt eq $elt_to_find) {
1242             $is_there = 1;
1243             last;
1244         }
1245     }
1246     if ($is_there) { ... }
1247
1248 =head2 How do I compute the difference of two arrays?  How do I compute the intersection of two arrays?
1249
1250 Use a hash.  Here's code to do both and more.  It assumes that
1251 each element is unique in a given array:
1252
1253     @union = @intersection = @difference = ();
1254     %count = ();
1255     foreach $element (@array1, @array2) { $count{$element}++ }
1256     foreach $element (keys %count) {
1257         push @union, $element;
1258         push @{ $count{$element} > 1 ? \@intersection : \@difference }, $element;
1259     }
1260
1261 Note that this is the I<symmetric difference>, that is, all elements in
1262 either A or in B but not in both.  Think of it as an xor operation.
1263
1264 =head2 How do I test whether two arrays or hashes are equal?
1265
1266 The following code works for single-level arrays.  It uses a stringwise
1267 comparison, and does not distinguish defined versus undefined empty
1268 strings.  Modify if you have other needs.
1269
1270     $are_equal = compare_arrays(\@frogs, \@toads);
1271
1272     sub compare_arrays {
1273         my ($first, $second) = @_;
1274         no warnings;  # silence spurious -w undef complaints
1275         return 0 unless @$first == @$second;
1276         for (my $i = 0; $i < @$first; $i++) {
1277             return 0 if $first->[$i] ne $second->[$i];
1278         }
1279         return 1;
1280     }
1281
1282 For multilevel structures, you may wish to use an approach more
1283 like this one.  It uses the CPAN module FreezeThaw:
1284
1285     use FreezeThaw qw(cmpStr);
1286     @a = @b = ( "this", "that", [ "more", "stuff" ] );
1287
1288     printf "a and b contain %s arrays\n",
1289         cmpStr(\@a, \@b) == 0
1290             ? "the same"
1291             : "different";
1292
1293 This approach also works for comparing hashes.  Here
1294 we'll demonstrate two different answers:
1295
1296     use FreezeThaw qw(cmpStr cmpStrHard);
1297
1298     %a = %b = ( "this" => "that", "extra" => [ "more", "stuff" ] );
1299     $a{EXTRA} = \%b;
1300     $b{EXTRA} = \%a;
1301
1302     printf "a and b contain %s hashes\n",
1303         cmpStr(\%a, \%b) == 0 ? "the same" : "different";
1304
1305     printf "a and b contain %s hashes\n",
1306         cmpStrHard(\%a, \%b) == 0 ? "the same" : "different";
1307
1308
1309 The first reports that both those the hashes contain the same data,
1310 while the second reports that they do not.  Which you prefer is left as
1311 an exercise to the reader.
1312
1313 =head2 How do I find the first array element for which a condition is true?
1314
1315 To find the first array element which satisfies a condition, you can
1316 use the first() function in the List::Util module, which comes with
1317 Perl 5.8.  This example finds the first element that contains "Perl".
1318
1319         use List::Util qw(first);
1320
1321         my $element = first { /Perl/ } @array;
1322
1323 If you cannot use List::Util, you can make your own loop to do the
1324 same thing.  Once you find the element, you stop the loop with last.
1325
1326         my $found;
1327         foreach my $element ( @array )
1328                 {
1329                 if( /Perl/ ) { $found = $element; last }
1330                 }
1331
1332 If you want the array index, you can iterate through the indices
1333 and check the array element at each index until you find one
1334 that satisfies the condition.
1335
1336         my( $found, $index ) = ( undef, -1 );
1337     for( $i = 0; $i < @array; $i++ )
1338         {
1339         if( $array[$i] =~ /Perl/ )
1340                 {
1341                 $found = $array[$i];
1342                 $index = $i;
1343                 last;
1344                 }
1345         }
1346
1347 =head2 How do I handle linked lists?
1348
1349 In general, you usually don't need a linked list in Perl, since with
1350 regular arrays, you can push and pop or shift and unshift at either end,
1351 or you can use splice to add and/or remove arbitrary number of elements at
1352 arbitrary points.  Both pop and shift are both O(1) operations on Perl's
1353 dynamic arrays.  In the absence of shifts and pops, push in general
1354 needs to reallocate on the order every log(N) times, and unshift will
1355 need to copy pointers each time.
1356
1357 If you really, really wanted, you could use structures as described in
1358 L<perldsc> or L<perltoot> and do just what the algorithm book tells you
1359 to do.  For example, imagine a list node like this:
1360
1361     $node = {
1362         VALUE => 42,
1363         LINK  => undef,
1364     };
1365
1366 You could walk the list this way:
1367
1368     print "List: ";
1369     for ($node = $head;  $node; $node = $node->{LINK}) {
1370         print $node->{VALUE}, " ";
1371     }
1372     print "\n";
1373
1374 You could add to the list this way:
1375
1376     my ($head, $tail);
1377     $tail = append($head, 1);       # grow a new head
1378     for $value ( 2 .. 10 ) {
1379         $tail = append($tail, $value);
1380     }
1381
1382     sub append {
1383         my($list, $value) = @_;
1384         my $node = { VALUE => $value };
1385         if ($list) {
1386             $node->{LINK} = $list->{LINK};
1387             $list->{LINK} = $node;
1388         } else {
1389             $_[0] = $node;      # replace caller's version
1390         }
1391         return $node;
1392     }
1393
1394 But again, Perl's built-in are virtually always good enough.
1395
1396 =head2 How do I handle circular lists?
1397
1398 Circular lists could be handled in the traditional fashion with linked
1399 lists, or you could just do something like this with an array:
1400
1401     unshift(@array, pop(@array));  # the last shall be first
1402     push(@array, shift(@array));   # and vice versa
1403
1404 =head2 How do I shuffle an array randomly?
1405
1406 If you either have Perl 5.8.0 or later installed, or if you have
1407 Scalar-List-Utils 1.03 or later installed, you can say:
1408
1409     use List::Util 'shuffle';
1410
1411         @shuffled = shuffle(@list);
1412
1413 If not, you can use a Fisher-Yates shuffle.
1414
1415     sub fisher_yates_shuffle {
1416         my $deck = shift;  # $deck is a reference to an array
1417         my $i = @$deck;
1418         while ($i--) {
1419             my $j = int rand ($i+1);
1420             @$deck[$i,$j] = @$deck[$j,$i];
1421         }
1422     }
1423
1424     # shuffle my mpeg collection
1425     #
1426     my @mpeg = <audio/*/*.mp3>;
1427     fisher_yates_shuffle( \@mpeg );    # randomize @mpeg in place
1428     print @mpeg;
1429
1430 Note that the above implementation shuffles an array in place,
1431 unlike the List::Util::shuffle() which takes a list and returns
1432 a new shuffled list.
1433
1434 You've probably seen shuffling algorithms that work using splice,
1435 randomly picking another element to swap the current element with
1436
1437     srand;
1438     @new = ();
1439     @old = 1 .. 10;  # just a demo
1440     while (@old) {
1441         push(@new, splice(@old, rand @old, 1));
1442     }
1443
1444 This is bad because splice is already O(N), and since you do it N times,
1445 you just invented a quadratic algorithm; that is, O(N**2).  This does
1446 not scale, although Perl is so efficient that you probably won't notice
1447 this until you have rather largish arrays.
1448
1449 =head2 How do I process/modify each element of an array?
1450
1451 Use C<for>/C<foreach>:
1452
1453     for (@lines) {
1454         s/foo/bar/;     # change that word
1455         y/XZ/ZX/;       # swap those letters
1456     }
1457
1458 Here's another; let's compute spherical volumes:
1459
1460     for (@volumes = @radii) {   # @volumes has changed parts
1461         $_ **= 3;
1462         $_ *= (4/3) * 3.14159;  # this will be constant folded
1463     }
1464
1465 which can also be done with map() which is made to transform
1466 one list into another:
1467
1468         @volumes = map {$_ ** 3 * (4/3) * 3.14159} @radii;
1469
1470 If you want to do the same thing to modify the values of the
1471 hash, you can use the C<values> function.  As of Perl 5.6
1472 the values are not copied, so if you modify $orbit (in this
1473 case), you modify the value.
1474
1475     for $orbit ( values %orbits ) {
1476         ($orbit **= 3) *= (4/3) * 3.14159;
1477     }
1478
1479 Prior to perl 5.6 C<values> returned copies of the values,
1480 so older perl code often contains constructions such as
1481 C<@orbits{keys %orbits}> instead of C<values %orbits> where
1482 the hash is to be modified.
1483
1484 =head2 How do I select a random element from an array?
1485
1486 Use the rand() function (see L<perlfunc/rand>):
1487
1488     $index   = rand @array;
1489     $element = $array[$index];
1490
1491 Or, simply:
1492     my $element = $array[ rand @array ];
1493
1494 =head2 How do I permute N elements of a list?
1495
1496 Use the List::Permutor module on CPAN.  If the list is
1497 actually an array, try the Algorithm::Permute module (also
1498 on CPAN).  It's written in XS code and is very efficient.
1499
1500         use Algorithm::Permute;
1501         my @array = 'a'..'d';
1502         my $p_iterator = Algorithm::Permute->new ( \@array );
1503         while (my @perm = $p_iterator->next) {
1504            print "next permutation: (@perm)\n";
1505         }
1506
1507 For even faster execution, you could do:
1508
1509    use Algorithm::Permute;
1510    my @array = 'a'..'d';
1511    Algorithm::Permute::permute {
1512       print "next permutation: (@array)\n";
1513    } @array;
1514
1515 Here's a little program that generates all permutations of
1516 all the words on each line of input. The algorithm embodied
1517 in the permute() function is discussed in Volume 4 (still
1518 unpublished) of Knuth's I<The Art of Computer Programming>
1519 and will work on any list:
1520
1521         #!/usr/bin/perl -n
1522         # Fischer-Kause ordered permutation generator
1523
1524         sub permute (&@) {
1525                 my $code = shift;
1526                 my @idx = 0..$#_;
1527                 while ( $code->(@_[@idx]) ) {
1528                         my $p = $#idx;
1529                         --$p while $idx[$p-1] > $idx[$p];
1530                         my $q = $p or return;
1531                         push @idx, reverse splice @idx, $p;
1532                         ++$q while $idx[$p-1] > $idx[$q];
1533                         @idx[$p-1,$q]=@idx[$q,$p-1];
1534                 }
1535         }
1536
1537         permute {print"@_\n"} split;
1538
1539 =head2 How do I sort an array by (anything)?
1540
1541 Supply a comparison function to sort() (described in L<perlfunc/sort>):
1542
1543     @list = sort { $a <=> $b } @list;
1544
1545 The default sort function is cmp, string comparison, which would
1546 sort C<(1, 2, 10)> into C<(1, 10, 2)>.  C<< <=> >>, used above, is
1547 the numerical comparison operator.
1548
1549 If you have a complicated function needed to pull out the part you
1550 want to sort on, then don't do it inside the sort function.  Pull it
1551 out first, because the sort BLOCK can be called many times for the
1552 same element.  Here's an example of how to pull out the first word
1553 after the first number on each item, and then sort those words
1554 case-insensitively.
1555
1556     @idx = ();
1557     for (@data) {
1558         ($item) = /\d+\s*(\S+)/;
1559         push @idx, uc($item);
1560     }
1561     @sorted = @data[ sort { $idx[$a] cmp $idx[$b] } 0 .. $#idx ];
1562
1563 which could also be written this way, using a trick
1564 that's come to be known as the Schwartzian Transform:
1565
1566     @sorted = map  { $_->[0] }
1567               sort { $a->[1] cmp $b->[1] }
1568               map  { [ $_, uc( (/\d+\s*(\S+)/)[0]) ] } @data;
1569
1570 If you need to sort on several fields, the following paradigm is useful.
1571
1572     @sorted = sort { field1($a) <=> field1($b) ||
1573                      field2($a) cmp field2($b) ||
1574                      field3($a) cmp field3($b)
1575                    }     @data;
1576
1577 This can be conveniently combined with precalculation of keys as given
1578 above.
1579
1580 See the F<sort> article in the "Far More Than You Ever Wanted
1581 To Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz for
1582 more about this approach.
1583
1584 See also the question below on sorting hashes.
1585
1586 =head2 How do I manipulate arrays of bits?
1587
1588 Use pack() and unpack(), or else vec() and the bitwise operations.
1589
1590 For example, this sets $vec to have bit N set if $ints[N] was set:
1591
1592     $vec = '';
1593     foreach(@ints) { vec($vec,$_,1) = 1 }
1594
1595 Here's how, given a vector in $vec, you can
1596 get those bits into your @ints array:
1597
1598     sub bitvec_to_list {
1599         my $vec = shift;
1600         my @ints;
1601         # Find null-byte density then select best algorithm
1602         if ($vec =~ tr/\0// / length $vec > 0.95) {
1603             use integer;
1604             my $i;
1605             # This method is faster with mostly null-bytes
1606             while($vec =~ /[^\0]/g ) {
1607                 $i = -9 + 8 * pos $vec;
1608                 push @ints, $i if vec($vec, ++$i, 1);
1609                 push @ints, $i if vec($vec, ++$i, 1);
1610                 push @ints, $i if vec($vec, ++$i, 1);
1611                 push @ints, $i if vec($vec, ++$i, 1);
1612                 push @ints, $i if vec($vec, ++$i, 1);
1613                 push @ints, $i if vec($vec, ++$i, 1);
1614                 push @ints, $i if vec($vec, ++$i, 1);
1615                 push @ints, $i if vec($vec, ++$i, 1);
1616             }
1617         } else {
1618             # This method is a fast general algorithm
1619             use integer;
1620             my $bits = unpack "b*", $vec;
1621             push @ints, 0 if $bits =~ s/^(\d)// && $1;
1622             push @ints, pos $bits while($bits =~ /1/g);
1623         }
1624         return \@ints;
1625     }
1626
1627 This method gets faster the more sparse the bit vector is.
1628 (Courtesy of Tim Bunce and Winfried Koenig.)
1629
1630 You can make the while loop a lot shorter with this suggestion
1631 from Benjamin Goldberg:
1632
1633         while($vec =~ /[^\0]+/g ) {
1634            push @ints, grep vec($vec, $_, 1), $-[0] * 8 .. $+[0] * 8;
1635         }
1636
1637 Or use the CPAN module Bit::Vector:
1638
1639     $vector = Bit::Vector->new($num_of_bits);
1640     $vector->Index_List_Store(@ints);
1641     @ints = $vector->Index_List_Read();
1642
1643 Bit::Vector provides efficient methods for bit vector, sets of small integers
1644 and "big int" math.
1645
1646 Here's a more extensive illustration using vec():
1647
1648     # vec demo
1649     $vector = "\xff\x0f\xef\xfe";
1650     print "Ilya's string \\xff\\x0f\\xef\\xfe represents the number ",
1651         unpack("N", $vector), "\n";
1652     $is_set = vec($vector, 23, 1);
1653     print "Its 23rd bit is ", $is_set ? "set" : "clear", ".\n";
1654     pvec($vector);
1655
1656     set_vec(1,1,1);
1657     set_vec(3,1,1);
1658     set_vec(23,1,1);
1659
1660     set_vec(3,1,3);
1661     set_vec(3,2,3);
1662     set_vec(3,4,3);
1663     set_vec(3,4,7);
1664     set_vec(3,8,3);
1665     set_vec(3,8,7);
1666
1667     set_vec(0,32,17);
1668     set_vec(1,32,17);
1669
1670     sub set_vec {
1671         my ($offset, $width, $value) = @_;
1672         my $vector = '';
1673         vec($vector, $offset, $width) = $value;
1674         print "offset=$offset width=$width value=$value\n";
1675         pvec($vector);
1676     }
1677
1678     sub pvec {
1679         my $vector = shift;
1680         my $bits = unpack("b*", $vector);
1681         my $i = 0;
1682         my $BASE = 8;
1683
1684         print "vector length in bytes: ", length($vector), "\n";
1685         @bytes = unpack("A8" x length($vector), $bits);
1686         print "bits are: @bytes\n\n";
1687     }
1688
1689 =head2 Why does defined() return true on empty arrays and hashes?
1690
1691 The short story is that you should probably only use defined on scalars or
1692 functions, not on aggregates (arrays and hashes).  See L<perlfunc/defined>
1693 in the 5.004 release or later of Perl for more detail.
1694
1695 =head1 Data: Hashes (Associative Arrays)
1696
1697 =head2 How do I process an entire hash?
1698
1699 Use the each() function (see L<perlfunc/each>) if you don't care
1700 whether it's sorted:
1701
1702     while ( ($key, $value) = each %hash) {
1703         print "$key = $value\n";
1704     }
1705
1706 If you want it sorted, you'll have to use foreach() on the result of
1707 sorting the keys as shown in an earlier question.
1708
1709 =head2 What happens if I add or remove keys from a hash while iterating over it?
1710
1711 (contributed by brian d foy)
1712
1713 The easy answer is "Don't do that!"
1714
1715 If you iterate through the hash with each(), you can delete the key
1716 most recently returned without worrying about it.  If you delete or add
1717 other keys, the iterator may skip or double up on them since perl
1718 may rearrange the hash table.  See the
1719 entry for C<each()> in L<perlfunc>.
1720
1721 =head2 How do I look up a hash element by value?
1722
1723 Create a reverse hash:
1724
1725     %by_value = reverse %by_key;
1726     $key = $by_value{$value};
1727
1728 That's not particularly efficient.  It would be more space-efficient
1729 to use:
1730
1731     while (($key, $value) = each %by_key) {
1732         $by_value{$value} = $key;
1733     }
1734
1735 If your hash could have repeated values, the methods above will only find
1736 one of the associated keys.   This may or may not worry you.  If it does
1737 worry you, you can always reverse the hash into a hash of arrays instead:
1738
1739      while (($key, $value) = each %by_key) {
1740          push @{$key_list_by_value{$value}}, $key;
1741      }
1742
1743 =head2 How can I know how many entries are in a hash?
1744
1745 If you mean how many keys, then all you have to do is
1746 use the keys() function in a scalar context:
1747
1748     $num_keys = keys %hash;
1749
1750 The keys() function also resets the iterator, which means that you may
1751 see strange results if you use this between uses of other hash operators
1752 such as each().
1753
1754 =head2 How do I sort a hash (optionally by value instead of key)?
1755
1756 Internally, hashes are stored in a way that prevents you from imposing
1757 an order on key-value pairs.  Instead, you have to sort a list of the
1758 keys or values:
1759
1760     @keys = sort keys %hash;    # sorted by key
1761     @keys = sort {
1762                     $hash{$a} cmp $hash{$b}
1763             } keys %hash;       # and by value
1764
1765 Here we'll do a reverse numeric sort by value, and if two keys are
1766 identical, sort by length of key, or if that fails, by straight ASCII
1767 comparison of the keys (well, possibly modified by your locale--see
1768 L<perllocale>).
1769
1770     @keys = sort {
1771                 $hash{$b} <=> $hash{$a}
1772                           ||
1773                 length($b) <=> length($a)
1774                           ||
1775                       $a cmp $b
1776     } keys %hash;
1777
1778 =head2 How can I always keep my hash sorted?
1779
1780 You can look into using the DB_File module and tie() using the
1781 $DB_BTREE hash bindings as documented in L<DB_File/"In Memory Databases">.
1782 The Tie::IxHash module from CPAN might also be instructive.
1783
1784 =head2 What's the difference between "delete" and "undef" with hashes?
1785
1786 Hashes contain pairs of scalars: the first is the key, the
1787 second is the value.  The key will be coerced to a string,
1788 although the value can be any kind of scalar: string,
1789 number, or reference.  If a key $key is present in
1790 %hash, C<exists($hash{$key})> will return true.  The value
1791 for a given key can be C<undef>, in which case
1792 C<$hash{$key}> will be C<undef> while C<exists $hash{$key}>
1793 will return true.  This corresponds to (C<$key>, C<undef>)
1794 being in the hash.
1795
1796 Pictures help...  here's the %hash table:
1797
1798           keys  values
1799         +------+------+
1800         |  a   |  3   |
1801         |  x   |  7   |
1802         |  d   |  0   |
1803         |  e   |  2   |
1804         +------+------+
1805
1806 And these conditions hold
1807
1808         $hash{'a'}                       is true
1809         $hash{'d'}                       is false
1810         defined $hash{'d'}               is true
1811         defined $hash{'a'}               is true
1812         exists $hash{'a'}                is true (Perl5 only)
1813         grep ($_ eq 'a', keys %hash)     is true
1814
1815 If you now say
1816
1817         undef $hash{'a'}
1818
1819 your table now reads:
1820
1821
1822           keys  values
1823         +------+------+
1824         |  a   | undef|
1825         |  x   |  7   |
1826         |  d   |  0   |
1827         |  e   |  2   |
1828         +------+------+
1829
1830 and these conditions now hold; changes in caps:
1831
1832         $hash{'a'}                       is FALSE
1833         $hash{'d'}                       is false
1834         defined $hash{'d'}               is true
1835         defined $hash{'a'}               is FALSE
1836         exists $hash{'a'}                is true (Perl5 only)
1837         grep ($_ eq 'a', keys %hash)     is true
1838
1839 Notice the last two: you have an undef value, but a defined key!
1840
1841 Now, consider this:
1842
1843         delete $hash{'a'}
1844
1845 your table now reads:
1846
1847           keys  values
1848         +------+------+
1849         |  x   |  7   |
1850         |  d   |  0   |
1851         |  e   |  2   |
1852         +------+------+
1853
1854 and these conditions now hold; changes in caps:
1855
1856         $hash{'a'}                       is false
1857         $hash{'d'}                       is false
1858         defined $hash{'d'}               is true
1859         defined $hash{'a'}               is false
1860         exists $hash{'a'}                is FALSE (Perl5 only)
1861         grep ($_ eq 'a', keys %hash)     is FALSE
1862
1863 See, the whole entry is gone!
1864
1865 =head2 Why don't my tied hashes make the defined/exists distinction?
1866
1867 This depends on the tied hash's implementation of EXISTS().
1868 For example, there isn't the concept of undef with hashes
1869 that are tied to DBM* files. It also means that exists() and
1870 defined() do the same thing with a DBM* file, and what they
1871 end up doing is not what they do with ordinary hashes.
1872
1873 =head2 How do I reset an each() operation part-way through?
1874
1875 Using C<keys %hash> in scalar context returns the number of keys in
1876 the hash I<and> resets the iterator associated with the hash.  You may
1877 need to do this if you use C<last> to exit a loop early so that when you
1878 re-enter it, the hash iterator has been reset.
1879
1880 =head2 How can I get the unique keys from two hashes?
1881
1882 First you extract the keys from the hashes into lists, then solve
1883 the "removing duplicates" problem described above.  For example:
1884
1885     %seen = ();
1886     for $element (keys(%foo), keys(%bar)) {
1887         $seen{$element}++;
1888     }
1889     @uniq = keys %seen;
1890
1891 Or more succinctly:
1892
1893     @uniq = keys %{{%foo,%bar}};
1894
1895 Or if you really want to save space:
1896
1897     %seen = ();
1898     while (defined ($key = each %foo)) {
1899         $seen{$key}++;
1900     }
1901     while (defined ($key = each %bar)) {
1902         $seen{$key}++;
1903     }
1904     @uniq = keys %seen;
1905
1906 =head2 How can I store a multidimensional array in a DBM file?
1907
1908 Either stringify the structure yourself (no fun), or else
1909 get the MLDBM (which uses Data::Dumper) module from CPAN and layer
1910 it on top of either DB_File or GDBM_File.
1911
1912 =head2 How can I make my hash remember the order I put elements into it?
1913
1914 Use the Tie::IxHash from CPAN.
1915
1916     use Tie::IxHash;
1917     tie my %myhash, 'Tie::IxHash';
1918     for (my $i=0; $i<20; $i++) {
1919         $myhash{$i} = 2*$i;
1920     }
1921     my @keys = keys %myhash;
1922     # @keys = (0,1,2,3,...)
1923
1924 =head2 Why does passing a subroutine an undefined element in a hash create it?
1925
1926 If you say something like:
1927
1928     somefunc($hash{"nonesuch key here"});
1929
1930 Then that element "autovivifies"; that is, it springs into existence
1931 whether you store something there or not.  That's because functions
1932 get scalars passed in by reference.  If somefunc() modifies C<$_[0]>,
1933 it has to be ready to write it back into the caller's version.
1934
1935 This has been fixed as of Perl5.004.
1936
1937 Normally, merely accessing a key's value for a nonexistent key does
1938 I<not> cause that key to be forever there.  This is different than
1939 awk's behavior.
1940
1941 =head2 How can I make the Perl equivalent of a C structure/C++ class/hash or array of hashes or arrays?
1942
1943 Usually a hash ref, perhaps like this:
1944
1945     $record = {
1946         NAME   => "Jason",
1947         EMPNO  => 132,
1948         TITLE  => "deputy peon",
1949         AGE    => 23,
1950         SALARY => 37_000,
1951         PALS   => [ "Norbert", "Rhys", "Phineas"],
1952     };
1953
1954 References are documented in L<perlref> and the upcoming L<perlreftut>.
1955 Examples of complex data structures are given in L<perldsc> and
1956 L<perllol>.  Examples of structures and object-oriented classes are
1957 in L<perltoot>.
1958
1959 =head2 How can I use a reference as a hash key?
1960
1961 You can't do this directly, but you could use the standard Tie::RefHash
1962 module distributed with Perl.
1963
1964 =head1 Data: Misc
1965
1966 =head2 How do I handle binary data correctly?
1967
1968 Perl is binary clean, so this shouldn't be a problem.  For example,
1969 this works fine (assuming the files are found):
1970
1971     if (`cat /vmunix` =~ /gzip/) {
1972         print "Your kernel is GNU-zip enabled!\n";
1973     }
1974
1975 On less elegant (read: Byzantine) systems, however, you have
1976 to play tedious games with "text" versus "binary" files.  See
1977 L<perlfunc/"binmode"> or L<perlopentut>.
1978
1979 If you're concerned about 8-bit ASCII data, then see L<perllocale>.
1980
1981 If you want to deal with multibyte characters, however, there are
1982 some gotchas.  See the section on Regular Expressions.
1983
1984 =head2 How do I determine whether a scalar is a number/whole/integer/float?
1985
1986 Assuming that you don't care about IEEE notations like "NaN" or
1987 "Infinity", you probably just want to use a regular expression.
1988
1989    if (/\D/)            { print "has nondigits\n" }
1990    if (/^\d+$/)         { print "is a whole number\n" }
1991    if (/^-?\d+$/)       { print "is an integer\n" }
1992    if (/^[+-]?\d+$/)    { print "is a +/- integer\n" }
1993    if (/^-?\d+\.?\d*$/) { print "is a real number\n" }
1994    if (/^-?(?:\d+(?:\.\d*)?|\.\d+)$/) { print "is a decimal number\n" }
1995    if (/^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/)
1996                         { print "a C float\n" }
1997
1998 There are also some commonly used modules for the task.
1999 L<Scalar::Util> (distributed with 5.8) provides access to perl's
2000 internal function C<looks_like_number> for determining
2001 whether a variable looks like a number.  L<Data::Types>
2002 exports functions that validate data types using both the
2003 above and other regular expressions. Thirdly, there is
2004 C<Regexp::Common> which has regular expressions to match
2005 various types of numbers. Those three modules are available
2006 from the CPAN.
2007
2008 If you're on a POSIX system, Perl supports the C<POSIX::strtod>
2009 function.  Its semantics are somewhat cumbersome, so here's a C<getnum>
2010 wrapper function for more convenient access.  This function takes
2011 a string and returns the number it found, or C<undef> for input that
2012 isn't a C float.  The C<is_numeric> function is a front end to C<getnum>
2013 if you just want to say, ``Is this a float?''
2014
2015     sub getnum {
2016         use POSIX qw(strtod);
2017         my $str = shift;
2018         $str =~ s/^\s+//;
2019         $str =~ s/\s+$//;
2020         $! = 0;
2021         my($num, $unparsed) = strtod($str);
2022         if (($str eq '') || ($unparsed != 0) || $!) {
2023             return undef;
2024         } else {
2025             return $num;
2026         }
2027     }
2028
2029     sub is_numeric { defined getnum($_[0]) }
2030
2031 Or you could check out the L<String::Scanf> module on the CPAN
2032 instead. The POSIX module (part of the standard Perl distribution) provides
2033 the C<strtod> and C<strtol> for converting strings to double and longs,
2034 respectively.
2035
2036 =head2 How do I keep persistent data across program calls?
2037
2038 For some specific applications, you can use one of the DBM modules.
2039 See L<AnyDBM_File>.  More generically, you should consult the FreezeThaw
2040 or Storable modules from CPAN.  Starting from Perl 5.8 Storable is part
2041 of the standard distribution.  Here's one example using Storable's C<store>
2042 and C<retrieve> functions:
2043
2044     use Storable;
2045     store(\%hash, "filename");
2046
2047     # later on...
2048     $href = retrieve("filename");        # by ref
2049     %hash = %{ retrieve("filename") };   # direct to hash
2050
2051 =head2 How do I print out or copy a recursive data structure?
2052
2053 The Data::Dumper module on CPAN (or the 5.005 release of Perl) is great
2054 for printing out data structures.  The Storable module on CPAN (or the
2055 5.8 release of Perl), provides a function called C<dclone> that recursively
2056 copies its argument.
2057
2058     use Storable qw(dclone);
2059     $r2 = dclone($r1);
2060
2061 Where $r1 can be a reference to any kind of data structure you'd like.
2062 It will be deeply copied.  Because C<dclone> takes and returns references,
2063 you'd have to add extra punctuation if you had a hash of arrays that
2064 you wanted to copy.
2065
2066     %newhash = %{ dclone(\%oldhash) };
2067
2068 =head2 How do I define methods for every class/object?
2069
2070 Use the UNIVERSAL class (see L<UNIVERSAL>).
2071
2072 =head2 How do I verify a credit card checksum?
2073
2074 Get the Business::CreditCard module from CPAN.
2075
2076 =head2 How do I pack arrays of doubles or floats for XS code?
2077
2078 The kgbpack.c code in the PGPLOT module on CPAN does just this.
2079 If you're doing a lot of float or double processing, consider using
2080 the PDL module from CPAN instead--it makes number-crunching easy.
2081
2082 =head1 AUTHOR AND COPYRIGHT
2083
2084 Copyright (c) 1997-2005 Tom Christiansen, Nathan Torkington, and
2085 other authors as noted. All rights reserved.
2086
2087 This documentation is free; you can redistribute it and/or modify it
2088 under the same terms as Perl itself.
2089
2090 Irrespective of its distribution, all code examples in this file
2091 are hereby placed into the public domain.  You are permitted and
2092 encouraged to use this code in your own programs for fun
2093 or for profit as you see fit.  A simple comment in the code giving
2094 credit would be courteous but is not required.