dist/B-Deparse/Deparse.pm

   1 # B::Deparse.pm
   2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
   3 # All rights reserved.
   4 # This module is free software; you can redistribute and/or modify
   5 # it under the same terms as Perl itself.
   6
   7 # This is based on the module of the same name by Malcolm Beattie,
   8 # but essentially none of his code remains.
   9
  10 package B::Deparse;
  11 use Carp;
  12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
  13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
  14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
  15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
  16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
  17          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
  18          OPpSORT_REVERSE
  19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
  20          CVf_METHOD CVf_LVALUE
  21          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
  22          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED);
  23 $VERSION = "1.10";
  24 use strict;
  25 use vars qw/$AUTOLOAD/;
  26 use warnings ();
  27
  28 BEGIN {
  29     # List version-specific constants here.
  30     # Easiest way to keep this code portable between version looks to
  31     # be to fake up a dummy constant that will never actually be true.
  32     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
  33                 OPpPAD_STATE PMf_SKIPWHITE RXf_SKIPWHITE
  34                 CVf_LOCKED OPpREVERSE_INPLACE OPpSUBSTR_REPL_FIRST
  35                 PMf_NONDESTRUCT OPpCONST_ARYBASE OPpEVAL_BYTES)) {
  36         eval { import B $_ };
  37         no strict 'refs';
  38         *{$_} = sub () {0} unless *{$_}{CODE};
  39     }
  40 }
  41
  42 # Changes between 0.50 and 0.51:
  43 # - fixed nulled leave with live enter in sort { }
  44 # - fixed reference constants (\"str")
  45 # - handle empty programs gracefully
  46 # - handle infinite loops (for (;;) {}, while (1) {})
  47 # - differentiate between 'for my $x ...' and 'my $x; for $x ...'
  48 # - various minor cleanups
  49 # - moved globals into an object
  50 # - added '-u', like B::C
  51 # - package declarations using cop_stash
  52 # - subs, formats and code sorted by cop_seq
  53 # Changes between 0.51 and 0.52:
  54 # - added pp_threadsv (special variables under USE_5005THREADS)
  55 # - added documentation
  56 # Changes between 0.52 and 0.53:
  57 # - many changes adding precedence contexts and associativity
  58 # - added '-p' and '-s' output style options
  59 # - various other minor fixes
  60 # Changes between 0.53 and 0.54:
  61 # - added support for new 'for (1..100)' optimization,
  62 #   thanks to Gisle Aas
  63 # Changes between 0.54 and 0.55:
  64 # - added support for new qr// construct
  65 # - added support for new pp_regcreset OP
  66 # Changes between 0.55 and 0.56:
  67 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
  68 # - fixed $# on non-lexicals broken in last big rewrite
  69 # - added temporary fix for change in opcode of OP_STRINGIFY
  70 # - fixed problem in 0.54's for() patch in 'for (@ary)'
  71 # - fixed precedence in conditional of ?:
  72 # - tweaked list paren elimination in 'my($x) = @_'
  73 # - made continue-block detection trickier wrt. null ops
  74 # - fixed various prototype problems in pp_entersub
  75 # - added support for sub prototypes that never get GVs
  76 # - added unquoting for special filehandle first arg in truncate
  77 # - print doubled rv2gv (a bug) as '*{*GV}' instead of illegal '**GV'
  78 # - added semicolons at the ends of blocks
  79 # - added -l '#line' declaration option -- fixes cmd/subval.t 27,28
  80 # Changes between 0.56 and 0.561:
  81 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
  82 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
  83 # Changes between 0.561 and 0.57:
  84 # - stylistic changes to symbolic constant stuff
  85 # - handled scope in s///e replacement code
  86 # - added unquote option for expanding "" into concats, etc.
  87 # - split method and proto parts of pp_entersub into separate functions
  88 # - various minor cleanups
  89 # Changes after 0.57:
  90 # - added parens in \&foo (patch by Albert Dvornik)
  91 # Changes between 0.57 and 0.58:
  92 # - fixed '0' statements that weren't being printed
  93 # - added methods for use from other programs
  94 #   (based on patches from James Duncan and Hugo van der Sanden)
  95 # - added -si and -sT to control indenting (also based on a patch from Hugo)
  96 # - added -sv to print something else instead of '???'
  97 # - preliminary version of utf8 tr/// handling
  98 # Changes after 0.58:
  99 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
 100 # - added support for Hugo's new OP_SETSTATE (like nextstate)
 101 # Changes between 0.58 and 0.59
 102 # - added support for Chip's OP_METHOD_NAMED
 103 # - added support for Ilya's OPpTARGET_MY optimization
 104 # - elided arrows before '()' subscripts when possible
 105 # Changes between 0.59 and 0.60
 106 # - support for method attributes was added
 107 # - some warnings fixed
 108 # - separate recognition of constant subs
 109 # - rewrote continue block handling, now recognizing for loops
 110 # - added more control of expanding control structures
 111 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
 112 # - many bug-fixes
 113 # - support for pragmas and 'use'
 114 # - support for the little-used $[ variable
 115 # - support for __DATA__ sections
 116 # - UTF8 support
 117 # - BEGIN, CHECK, INIT and END blocks
 118 # - scoping of subroutine declarations fixed
 119 # - compile-time output from the input program can be suppressed, so that the
 120 #   output is just the deparsed code. (a change to O.pm in fact)
 121 # - our() declarations
 122 # - *all* the known bugs are now listed in the BUGS section
 123 # - comprehensive test mechanism (TEST -deparse)
 124 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
 125 # - bug-fixes
 126 # - new switch -P
 127 # - support for command-line switches (-l, -0, etc.)
 128 # Changes between 0.63 and 0.64
 129 # - support for //, CHECK blocks, and assertions
 130 # - improved handling of foreach loops and lexicals
 131 # - option to use Data::Dumper for constants
 132 # - more bug fixes
 133 # - discovered lots more bugs not yet fixed
 134 #
 135 # ...
 136 #
 137 # Changes between 0.72 and 0.73
 138 # - support new switch constructs
 139
 140 # Todo:
 141 #  (See also BUGS section at the end of this file)
 142 #
 143 # - finish tr/// changes
 144 # - add option for even more parens (generalize \&foo change)
 145 # - left/right context
 146 # - copy comments (look at real text with $^P?)
 147 # - avoid semis in one-statement blocks
 148 # - associativity of &&=, ||=, ?:
 149 # - ',' => '=>' (auto-unquote?)
 150 # - break long lines ("\r" as discretionary break?)
 151 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
 152 # - more style options: brace style, hex vs. octal, quotes, ...
 153 # - print big ints as hex/octal instead of decimal (heuristic?)
 154 # - handle 'my $x if 0'?
 155 # - version using op_next instead of op_first/sibling?
 156 # - avoid string copies (pass arrays, one big join?)
 157 # - here-docs?
 158
 159 # Current test.deparse failures
 160 # comp/hints 6 - location of BEGIN blocks wrt. block openings
 161 # run/switchI 1 - missing -I switches entirely
 162 #    perl -Ifoo -e 'print @INC'
 163 # op/caller 2 - warning mask propagates backwards before warnings::register
 164 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
 165 # op/getpid 2 - can't assign to shared my() declaration (threads only)
 166 #    'my $x : shared = 5'
 167 # op/override 7 - parens on overridden require change v-string interpretation
 168 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
 169 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
 170 # op/pat 774 - losing Unicode-ness of Latin1-only strings
 171 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
 172 # op/recurse 12 - missing parens on recursive call makes it look like method
 173 #    'sub f { f($x) }'
 174 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
 175 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
 176 # op/tiehandle compile - "use strict" deparsed in the wrong place
 177 # uni/tr_ several
 178 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
 179 # ext/Data/Dumper/t/dumper compile
 180 # ext/DB_file/several
 181 # ext/Encode/several
 182 # ext/Ernno/Errno warnings
 183 # ext/IO/lib/IO/t/io_sel 23
 184 # ext/PerlIO/t/encoding compile
 185 # ext/POSIX/t/posix 6
 186 # ext/Socket/Socket 8
 187 # ext/Storable/t/croak compile
 188 # lib/Attribute/Handlers/t/multi compile
 189 # lib/bignum/ several
 190 # lib/charnames 35
 191 # lib/constant 32
 192 # lib/English 40
 193 # lib/ExtUtils/t/bytes 4
 194 # lib/File/DosGlob compile
 195 # lib/Filter/Simple/t/data 1
 196 # lib/Math/BigInt/t/constant 1
 197 # lib/Net/t/config Deparse-warning
 198 # lib/overload compile
 199 # lib/Switch/ several
 200 # lib/Symbol 4
 201 # lib/Test/Simple several
 202 # lib/Term/Complete
 203 # lib/Tie/File/t/29_downcopy 5
 204 # lib/vars 22
 205
 206 # Object fields (were globals):
 207 #
 208 # avoid_local:
 209 # (local($a), local($b)) and local($a, $b) have the same internal
 210 # representation but the short form looks better. We notice we can
 211 # use a large-scale local when checking the list, but need to prevent
 212 # individual locals too. This hash holds the addresses of OPs that
 213 # have already had their local-ness accounted for. The same thing
 214 # is done with my().
 215 #
 216 # curcv:
 217 # CV for current sub (or main program) being deparsed
 218 #
 219 # curcvlex:
 220 # Cached hash of lexical variables for curcv: keys are names,
 221 # each value is an array of pairs, indicating the cop_seq of scopes
 222 # in which a var of that name is valid.
 223 #
 224 # curcop:
 225 # COP for statement being deparsed
 226 #
 227 # curstash:
 228 # name of the current package for deparsed code
 229 #
 230 # subs_todo:
 231 # array of [cop_seq, CV, is_format?] for subs and formats we still
 232 # want to deparse
 233 #
 234 # protos_todo:
 235 # as above, but [name, prototype] for subs that never got a GV
 236 #
 237 # subs_done, forms_done:
 238 # keys are addresses of GVs for subs and formats we've already
 239 # deparsed (or at least put into subs_todo)
 240 #
 241 # subs_declared
 242 # keys are names of subs for which we've printed declarations.
 243 # That means we can omit parentheses from the arguments. It also means we
 244 # need to put CORE:: on core functions of the same name.
 245 #
 246 # subs_deparsed
 247 # Keeps track of fully qualified names of all deparsed subs.
 248 #
 249 # parens: -p
 250 # linenums: -l
 251 # unquote: -q
 252 # cuddle: ' ' or '\n', depending on -sC
 253 # indent_size: -si
 254 # use_tabs: -sT
 255 # ex_const: -sv
 256
 257 # A little explanation of how precedence contexts and associativity
 258 # work:
 259 #
 260 # deparse() calls each per-op subroutine with an argument $cx (short
 261 # for context, but not the same as the cx* in the perl core), which is
 262 # a number describing the op's parents in terms of precedence, whether
 263 # they're inside an expression or at statement level, etc.  (see
 264 # chart below). When ops with children call deparse on them, they pass
 265 # along their precedence. Fractional values are used to implement
 266 # associativity ('($x + $y) + $z' => '$x + $y + $y') and related
 267 # parentheses hacks. The major disadvantage of this scheme is that
 268 # it doesn't know about right sides and left sides, so say if you
 269 # assign a listop to a variable, it can't tell it's allowed to leave
 270 # the parens off the listop.
 271
 272 # Precedences:
 273 # 26             [TODO] inside interpolation context ("")
 274 # 25 left        terms and list operators (leftward)
 275 # 24 left        ->
 276 # 23 nonassoc    ++ --
 277 # 22 right       **
 278 # 21 right       ! ~ \ and unary + and -
 279 # 20 left        =~ !~
 280 # 19 left        * / % x
 281 # 18 left        + - .
 282 # 17 left        << >>
 283 # 16 nonassoc    named unary operators
 284 # 15 nonassoc    < > <= >= lt gt le ge
 285 # 14 nonassoc    == != <=> eq ne cmp
 286 # 13 left        &
 287 # 12 left        | ^
 288 # 11 left        &&
 289 # 10 left        ||
 290 #  9 nonassoc    ..  ...
 291 #  8 right       ?:
 292 #  7 right       = += -= *= etc.
 293 #  6 left        , =>
 294 #  5 nonassoc    list operators (rightward)
 295 #  4 right       not
 296 #  3 left        and
 297 #  2 left        or xor
 298 #  1             statement modifiers
 299 #  0.5           statements, but still print scopes as do { ... }
 300 #  0             statement level
 301
 302 # Nonprinting characters with special meaning:
 303 # \cS - steal parens (see maybe_parens_unop)
 304 # \n - newline and indent
 305 # \t - increase indent
 306 # \b - decrease indent ('outdent')
 307 # \f - flush left (no indent)
 308 # \cK - kill following semicolon, if any
 309
 310 sub null {
 311     my $op = shift;
 312     return class($op) eq "NULL";
 313 }
 314
 315 sub todo {
 316     my $self = shift;
 317     my($cv, $is_form) = @_;
 318     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
 319     my $seq;
 320     if ($cv->OUTSIDE_SEQ) {
 321         $seq = $cv->OUTSIDE_SEQ;
 322     } elsif (!null($cv->START) and is_state($cv->START)) {
 323         $seq = $cv->START->cop_seq;
 324     } else {
 325         $seq = 0;
 326     }
 327     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
 328     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
 329         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
 330     }
 331 }
 332
 333 sub next_todo {
 334     my $self = shift;
 335     my $ent = shift @{$self->{'subs_todo'}};
 336     my $cv = $ent->[1];
 337     my $gv = $cv->GV;
 338     my $name = $self->gv_name($gv);
 339     if ($ent->[2]) {
 340         return "format $name =\n"
 341             . $self->deparse_format($ent->[1]). "\n";
 342     } else {
 343         $self->{'subs_declared'}{$name} = 1;
 344         if ($name eq "BEGIN") {
 345             my $use_dec = $self->begin_is_use($cv);
 346             if (defined ($use_dec) and $self->{'expand'} < 5) {
 347                 return () if 0 == length($use_dec);
 348                 return $use_dec;
 349             }
 350         }
 351         my $l = '';
 352         if ($self->{'linenums'}) {
 353             my $line = $gv->LINE;
 354             my $file = $gv->FILE;
 355             $l = "\n\f#line $line \"$file\"\n";
 356         }
 357         my $p = '';
 358         if (class($cv->STASH) ne "SPECIAL") {
 359             my $stash = $cv->STASH->NAME;
 360             if ($stash ne $self->{'curstash'}) {
 361                 $p = "package $stash;\n";
 362                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
 363                 $self->{'curstash'} = $stash;
 364             }
 365             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
 366         }
 367         return "${p}${l}sub $name " . $self->deparse_sub($cv);
 368     }
 369 }
 370
 371 # Return a "use" declaration for this BEGIN block, if appropriate
 372 sub begin_is_use {
 373     my ($self, $cv) = @_;
 374     my $root = $cv->ROOT;
 375     local @$self{qw'curcv curcvlex'} = ($cv);
 376 #require B::Debug;
 377 #B::walkoptree($cv->ROOT, "debug");
 378     my $lineseq = $root->first;
 379     return if $lineseq->name ne "lineseq";
 380
 381     my $req_op = $lineseq->first->sibling;
 382     return if $req_op->name ne "require";
 383
 384     my $module;
 385     if ($req_op->first->private & OPpCONST_BARE) {
 386         # Actually it should always be a bareword
 387         $module = $self->const_sv($req_op->first)->PV;
 388         $module =~ s[/][::]g;
 389         $module =~ s/.pm$//;
 390     }
 391     else {
 392         $module = $self->const($self->const_sv($req_op->first), 6);
 393     }
 394
 395     my $version;
 396     my $version_op = $req_op->sibling;
 397     return if class($version_op) eq "NULL";
 398     if ($version_op->name eq "lineseq") {
 399         # We have a version parameter; skip nextstate & pushmark
 400         my $constop = $version_op->first->next->next;
 401
 402         return unless $self->const_sv($constop)->PV eq $module;
 403         $constop = $constop->sibling;
 404         $version = $self->const_sv($constop);
 405         if (class($version) eq "IV") {
 406             $version = $version->int_value;
 407         } elsif (class($version) eq "NV") {
 408             $version = $version->NV;
 409         } elsif (class($version) ne "PVMG") {
 410             # Includes PVIV and PVNV
 411             $version = $version->PV;
 412         } else {
 413             # version specified as a v-string
 414             $version = 'v'.join '.', map ord, split //, $version->PV;
 415         }
 416         $constop = $constop->sibling;
 417         return if $constop->name ne "method_named";
 418         return if $self->const_sv($constop)->PV ne "VERSION";
 419     }
 420
 421     $lineseq = $version_op->sibling;
 422     return if $lineseq->name ne "lineseq";
 423     my $entersub = $lineseq->first->sibling;
 424     if ($entersub->name eq "stub") {
 425         return "use $module $version ();\n" if defined $version;
 426         return "use $module ();\n";
 427     }
 428     return if $entersub->name ne "entersub";
 429
 430     # See if there are import arguments
 431     my $args = '';
 432
 433     my $svop = $entersub->first->sibling; # Skip over pushmark
 434     return unless $self->const_sv($svop)->PV eq $module;
 435
 436     # Pull out the arguments
 437     for ($svop=$svop->sibling; $svop->name ne "method_named";
 438                 $svop = $svop->sibling) {
 439         $args .= ", " if length($args);
 440         $args .= $self->deparse($svop, 6);
 441     }
 442
 443     my $use = 'use';
 444     my $method_named = $svop;
 445     return if $method_named->name ne "method_named";
 446     my $method_name = $self->const_sv($method_named)->PV;
 447
 448     if ($method_name eq "unimport") {
 449         $use = 'no';
 450     }
 451
 452     # Certain pragmas are dealt with using hint bits,
 453     # so we ignore them here
 454     if ($module eq 'strict' || $module eq 'integer'
 455         || $module eq 'bytes' || $module eq 'warnings'
 456         || $module eq 'feature') {
 457         return "";
 458     }
 459
 460     if (defined $version && length $args) {
 461         return "$use $module $version ($args);\n";
 462     } elsif (defined $version) {
 463         return "$use $module $version;\n";
 464     } elsif (length $args) {
 465         return "$use $module ($args);\n";
 466     } else {
 467         return "$use $module;\n";
 468     }
 469 }
 470
 471 sub stash_subs {
 472     my ($self, $pack) = @_;
 473     my (@ret, $stash);
 474     if (!defined $pack) {
 475         $pack = '';
 476         $stash = \%::;
 477     }
 478     else {
 479         $pack =~ s/(::)?$/::/;
 480         no strict 'refs';
 481         $stash = \%{"main::$pack"};
 482     }
 483     my %stash = svref_2object($stash)->ARRAY;
 484     while (my ($key, $val) = each %stash) {
 485         my $class = class($val);
 486         if ($class eq "PV") {
 487             # Just a prototype. As an ugly but fairly effective way
 488             # to find out if it belongs here is to see if the AUTOLOAD
 489             # (if any) for the stash was defined in one of our files.
 490             my $A = $stash{"AUTOLOAD"};
 491             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 492                 && class($A->CV) eq "CV") {
 493                 my $AF = $A->FILE;
 494                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 495             }
 496             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
 497         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
 498             # Just a name. As above.
 499             # But skip proxy constant subroutines, as some form of perl-space
 500             # visible code must have created them, be it a use statement, or
 501             # some direct symbol-table manipulation code that we will Deparse
 502             my $A = $stash{"AUTOLOAD"};
 503             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
 504                 && class($A->CV) eq "CV") {
 505                 my $AF = $A->FILE;
 506                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
 507             }
 508             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
 509         } elsif ($class eq "GV") {
 510             if (class(my $cv = $val->CV) ne "SPECIAL") {
 511                 next if $self->{'subs_done'}{$$val}++;
 512                 next if $$val != ${$cv->GV};   # Ignore imposters
 513                 $self->todo($cv, 0);
 514             }
 515             if (class(my $cv = $val->FORM) ne "SPECIAL") {
 516                 next if $self->{'forms_done'}{$$val}++;
 517                 next if $$val != ${$cv->GV};   # Ignore imposters
 518                 $self->todo($cv, 1);
 519             }
 520             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
 521                 $self->stash_subs($pack . $key)
 522                     unless $pack eq '' && $key eq 'main::';
 523                     # avoid infinite recursion
 524             }
 525         }
 526     }
 527 }
 528
 529 sub print_protos {
 530     my $self = shift;
 531     my $ar;
 532     my @ret;
 533     foreach $ar (@{$self->{'protos_todo'}}) {
 534         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
 535         push @ret, "sub " . $ar->[0] .  "$proto;\n";
 536     }
 537     delete $self->{'protos_todo'};
 538     return @ret;
 539 }
 540
 541 sub style_opts {
 542     my $self = shift;
 543     my $opts = shift;
 544     my $opt;
 545     while (length($opt = substr($opts, 0, 1))) {
 546         if ($opt eq "C") {
 547             $self->{'cuddle'} = " ";
 548             $opts = substr($opts, 1);
 549         } elsif ($opt eq "i") {
 550             $opts =~ s/^i(\d+)//;
 551             $self->{'indent_size'} = $1;
 552         } elsif ($opt eq "T") {
 553             $self->{'use_tabs'} = 1;
 554             $opts = substr($opts, 1);
 555         } elsif ($opt eq "v") {
 556             $opts =~ s/^v([^.]*)(.|$)//;
 557             $self->{'ex_const'} = $1;
 558         }
 559     }
 560 }
 561
 562 sub new {
 563     my $class = shift;
 564     my $self = bless {}, $class;
 565     $self->{'cuddle'} = "\n";
 566     $self->{'curcop'} = undef;
 567     $self->{'curstash'} = "main";
 568     $self->{'ex_const'} = "'???'";
 569     $self->{'expand'} = 0;
 570     $self->{'files'} = {};
 571     $self->{'indent_size'} = 4;
 572     $self->{'linenums'} = 0;
 573     $self->{'parens'} = 0;
 574     $self->{'subs_todo'} = [];
 575     $self->{'unquote'} = 0;
 576     $self->{'use_dumper'} = 0;
 577     $self->{'use_tabs'} = 0;
 578
 579     $self->{'ambient_arybase'} = 0;
 580     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
 581     $self->{'ambient_hints'} = 0;
 582     $self->{'ambient_hinthash'} = undef;
 583     $self->init();
 584
 585     while (my $arg = shift @_) {
 586         if ($arg eq "-d") {
 587             $self->{'use_dumper'} = 1;
 588             require Data::Dumper;
 589         } elsif ($arg =~ /^-f(.*)/) {
 590             $self->{'files'}{$1} = 1;
 591         } elsif ($arg eq "-l") {
 592             $self->{'linenums'} = 1;
 593         } elsif ($arg eq "-p") {
 594             $self->{'parens'} = 1;
 595         } elsif ($arg eq "-P") {
 596             $self->{'noproto'} = 1;
 597         } elsif ($arg eq "-q") {
 598             $self->{'unquote'} = 1;
 599         } elsif (substr($arg, 0, 2) eq "-s") {
 600             $self->style_opts(substr $arg, 2);
 601         } elsif ($arg =~ /^-x(\d)$/) {
 602             $self->{'expand'} = $1;
 603         }
 604     }
 605     return $self;
 606 }
 607
 608 {
 609     # Mask out the bits that L<warnings::register> uses
 610     my $WARN_MASK;
 611     BEGIN {
 612         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
 613     }
 614     sub WARN_MASK () {
 615         return $WARN_MASK;
 616     }
 617 }
 618
 619 # Initialise the contextual information, either from
 620 # defaults provided with the ambient_pragmas method,
 621 # or from perl's own defaults otherwise.
 622 sub init {
 623     my $self = shift;
 624
 625     $self->{'arybase'}  = $self->{'ambient_arybase'};
 626     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
 627                                 ? $self->{'ambient_warnings'} & WARN_MASK
 628                                 : undef;
 629     $self->{'hints'}    = $self->{'ambient_hints'};
 630     $self->{'hints'} &= 0xFF if $] < 5.009;
 631     $self->{'hinthash'} = $self->{'ambient_hinthash'};
 632
 633     # also a convenient place to clear out subs_declared
 634     delete $self->{'subs_declared'};
 635 }
 636
 637 sub compile {
 638     my(@args) = @_;
 639     return sub {
 640         my $self = B::Deparse->new(@args);
 641         # First deparse command-line args
 642         if (defined $^I) { # deparse -i
 643             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
 644         }
 645         if ($^W) { # deparse -w
 646             print qq(BEGIN { \$^W = $^W; }\n);
 647         }
 648         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
 649             my $fs = perlstring($/) || 'undef';
 650             my $bs = perlstring($O::savebackslash) || 'undef';
 651             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
 652         }
 653         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
 654         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
 655             ? B::unitcheck_av->ARRAY
 656             : ();
 657         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
 658         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
 659         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
 660         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
 661             $self->todo($block, 0);
 662         }
 663         $self->stash_subs();
 664         local($SIG{"__DIE__"}) =
 665           sub {
 666               if ($self->{'curcop'}) {
 667                   my $cop = $self->{'curcop'};
 668                   my($line, $file) = ($cop->line, $cop->file);
 669                   print STDERR "While deparsing $file near line $line,\n";
 670               }
 671             };
 672         $self->{'curcv'} = main_cv;
 673         $self->{'curcvlex'} = undef;
 674         print $self->print_protos;
 675         @{$self->{'subs_todo'}} =
 676           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
 677         print $self->indent($self->deparse_root(main_root)), "\n"
 678           unless null main_root;
 679         my @text;
 680         while (scalar(@{$self->{'subs_todo'}})) {
 681             push @text, $self->next_todo;
 682         }
 683         print $self->indent(join("", @text)), "\n" if @text;
 684
 685         # Print __DATA__ section, if necessary
 686         no strict 'refs';
 687         my $laststash = defined $self->{'curcop'}
 688             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
 689         if (defined *{$laststash."::DATA"}{IO}) {
 690             print "package $laststash;\n"
 691                 unless $laststash eq $self->{'curstash'};
 692             print "__DATA__\n";
 693             print readline(*{$laststash."::DATA"});
 694         }
 695     }
 696 }
 697
 698 sub coderef2text {
 699     my $self = shift;
 700     my $sub = shift;
 701     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
 702
 703     $self->init();
 704     return $self->indent($self->deparse_sub(svref_2object($sub)));
 705 }
 706
 707 sub ambient_pragmas {
 708     my $self = shift;
 709     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
 710
 711     while (@_ > 1) {
 712         my $name = shift();
 713         my $val  = shift();
 714
 715         if ($name eq 'strict') {
 716             require strict;
 717
 718             if ($val eq 'none') {
 719                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
 720                 next();
 721             }
 722
 723             my @names;
 724             if ($val eq "all") {
 725                 @names = qw/refs subs vars/;
 726             }
 727             elsif (ref $val) {
 728                 @names = @$val;
 729             }
 730             else {
 731                 @names = split' ', $val;
 732             }
 733             $hint_bits |= strict::bits(@names);
 734         }
 735
 736         elsif ($name eq '$[') {
 737             if (OPpCONST_ARYBASE) {
 738                 $arybase = $val;
 739             } else {
 740                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
 741             }
 742         }
 743
 744         elsif ($name eq 'integer'
 745             || $name eq 'bytes'
 746             || $name eq 'utf8') {
 747             require "$name.pm";
 748             if ($val) {
 749                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
 750             }
 751             else {
 752                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
 753             }
 754         }
 755
 756         elsif ($name eq 're') {
 757             require re;
 758             if ($val eq 'none') {
 759                 $hint_bits &= ~re::bits(qw/taint eval/);
 760                 next();
 761             }
 762
 763             my @names;
 764             if ($val eq 'all') {
 765                 @names = qw/taint eval/;
 766             }
 767             elsif (ref $val) {
 768                 @names = @$val;
 769             }
 770             else {
 771                 @names = split' ',$val;
 772             }
 773             $hint_bits |= re::bits(@names);
 774         }
 775
 776         elsif ($name eq 'warnings') {
 777             if ($val eq 'none') {
 778                 $warning_bits = $warnings::NONE;
 779                 next();
 780             }
 781
 782             my @names;
 783             if (ref $val) {
 784                 @names = @$val;
 785             }
 786             else {
 787                 @names = split/\s+/, $val;
 788             }
 789
 790             $warning_bits = $warnings::NONE if !defined ($warning_bits);
 791             $warning_bits |= warnings::bits(@names);
 792         }
 793
 794         elsif ($name eq 'warning_bits') {
 795             $warning_bits = $val;
 796         }
 797
 798         elsif ($name eq 'hint_bits') {
 799             $hint_bits = $val;
 800         }
 801
 802         elsif ($name eq '%^H') {
 803             $hinthash = $val;
 804         }
 805
 806         else {
 807             croak "Unknown pragma type: $name";
 808         }
 809     }
 810     if (@_) {
 811         croak "The ambient_pragmas method expects an even number of args";
 812     }
 813
 814     $self->{'ambient_arybase'} = $arybase;
 815     $self->{'ambient_warnings'} = $warning_bits;
 816     $self->{'ambient_hints'} = $hint_bits;
 817     $self->{'ambient_hinthash'} = $hinthash;
 818 }
 819
 820 # This method is the inner loop, so try to keep it simple
 821 sub deparse {
 822     my $self = shift;
 823     my($op, $cx) = @_;
 824
 825     Carp::confess("Null op in deparse") if !defined($op)
 826                                         || class($op) eq "NULL";
 827     my $meth = "pp_" . $op->name;
 828     return $self->$meth($op, $cx);
 829 }
 830
 831 sub indent {
 832     my $self = shift;
 833     my $txt = shift;
 834     my @lines = split(/\n/, $txt);
 835     my $leader = "";
 836     my $level = 0;
 837     my $line;
 838     for $line (@lines) {
 839         my $cmd = substr($line, 0, 1);
 840         if ($cmd eq "\t" or $cmd eq "\b") {
 841             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
 842             if ($self->{'use_tabs'}) {
 843                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
 844             } else {
 845                 $leader = " " x $level;
 846             }
 847             $line = substr($line, 1);
 848         }
 849         if (substr($line, 0, 1) eq "\f") {
 850             $line = substr($line, 1); # no indent
 851         } else {
 852             $line = $leader . $line;
 853         }
 854         $line =~ s/\cK;?//g;
 855     }
 856     return join("\n", @lines);
 857 }
 858
 859 sub deparse_sub {
 860     my $self = shift;
 861     my $cv = shift;
 862     my $proto = "";
 863 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
 864 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
 865     local $self->{'curcop'} = $self->{'curcop'};
 866     if ($cv->FLAGS & SVf_POK) {
 867         $proto = "(". $cv->PV . ") ";
 868     }
 869     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
 870         $proto .= ": ";
 871         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
 872         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
 873         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
 874     }
 875
 876     local($self->{'curcv'}) = $cv;
 877     local($self->{'curcvlex'});
 878     local(@$self{qw'curstash warnings hints hinthash'})
 879                 = @$self{qw'curstash warnings hints hinthash'};
 880     my $body;
 881     if (not null $cv->ROOT) {
 882         my $lineseq = $cv->ROOT->first;
 883         if ($lineseq->name eq "lineseq") {
 884             my @ops;
 885             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
 886                 push @ops, $o;
 887             }
 888             $body = $self->lineseq(undef, @ops).";";
 889             my $scope_en = $self->find_scope_en($lineseq);
 890             if (defined $scope_en) {
 891                 my $subs = join"", $self->seq_subs($scope_en);
 892                 $body .= ";\n$subs" if length($subs);
 893             }
 894         }
 895         else {
 896             $body = $self->deparse($cv->ROOT->first, 0);
 897         }
 898     }
 899     else {
 900         my $sv = $cv->const_sv;
 901         if ($$sv) {
 902             # uh-oh. inlinable sub... format it differently
 903             return $proto . "{ " . $self->const($sv, 0) . " }\n";
 904         } else { # XSUB? (or just a declaration)
 905             return "$proto;\n";
 906         }
 907     }
 908     return $proto ."{\n\t$body\n\b}" ."\n";
 909 }
 910
 911 sub deparse_format {
 912     my $self = shift;
 913     my $form = shift;
 914     my @text;
 915     local($self->{'curcv'}) = $form;
 916     local($self->{'curcvlex'});
 917     local($self->{'in_format'}) = 1;
 918     local(@$self{qw'curstash warnings hints hinthash'})
 919                 = @$self{qw'curstash warnings hints hinthash'};
 920     my $op = $form->ROOT;
 921     my $kid;
 922     return "\f." if $op->first->name eq 'stub'
 923                 || $op->first->name eq 'nextstate';
 924     $op = $op->first->first; # skip leavewrite, lineseq
 925     while (not null $op) {
 926         $op = $op->sibling; # skip nextstate
 927         my @exprs;
 928         $kid = $op->first->sibling; # skip pushmark
 929         push @text, "\f".$self->const_sv($kid)->PV;
 930         $kid = $kid->sibling;
 931         for (; not null $kid; $kid = $kid->sibling) {
 932             push @exprs, $self->deparse($kid, 0);
 933         }
 934         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
 935         $op = $op->sibling;
 936     }
 937     return join("", @text) . "\f.";
 938 }
 939
 940 sub is_scope {
 941     my $op = shift;
 942     return $op->name eq "leave" || $op->name eq "scope"
 943       || $op->name eq "lineseq"
 944         || ($op->name eq "null" && class($op) eq "UNOP"
 945             && (is_scope($op->first) || $op->first->name eq "enter"));
 946 }
 947
 948 sub is_state {
 949     my $name = $_[0]->name;
 950     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
 951 }
 952
 953 sub is_miniwhile { # check for one-line loop ('foo() while $y--')
 954     my $op = shift;
 955     return (!null($op) and null($op->sibling)
 956             and $op->name eq "null" and class($op) eq "UNOP"
 957             and (($op->first->name =~ /^(and|or)$/
 958                   and $op->first->first->sibling->name eq "lineseq")
 959                  or ($op->first->name eq "lineseq"
 960                      and not null $op->first->first->sibling
 961                      and $op->first->first->sibling->name eq "unstack")
 962                  ));
 963 }
 964
 965 # Check if the op and its sibling are the initialization and the rest of a
 966 # for (..;..;..) { ... } loop
 967 sub is_for_loop {
 968     my $op = shift;
 969     # This OP might be almost anything, though it won't be a
 970     # nextstate. (It's the initialization, so in the canonical case it
 971     # will be an sassign.) The sibling is (old style) a lineseq whose
 972     # first child is a nextstate and whose second is a leaveloop, or
 973     # (new style) an unstack whose sibling is a leaveloop.
 974     my $lseq = $op->sibling;
 975     return 0 unless !is_state($op) and !null($lseq);
 976     if ($lseq->name eq "lineseq") {
 977         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
 978             && (my $sib = $lseq->first->sibling)) {
 979             return (!null($sib) && $sib->name eq "leaveloop");
 980         }
 981     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
 982         my $sib = $lseq->sibling;
 983         return $sib && !null($sib) && $sib->name eq "leaveloop";
 984     }
 985     return 0;
 986 }
 987
 988 sub is_scalar {
 989     my $op = shift;
 990     return ($op->name eq "rv2sv" or
 991             $op->name eq "padsv" or
 992             $op->name eq "gv" or # only in array/hash constructs
 993             $op->flags & OPf_KIDS && !null($op->first)
 994               && $op->first->name eq "gvsv");
 995 }
 996
 997 sub maybe_parens {
 998     my $self = shift;
 999     my($text, $cx, $prec) = @_;
1000     if ($prec < $cx              # unary ops nest just fine
1001         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1002         or $self->{'parens'})
1003     {
1004         $text = "($text)";
1005         # In a unop, let parent reuse our parens; see maybe_parens_unop
1006         $text = "\cS" . $text if $cx == 16;
1007         return $text;
1008     } else {
1009         return $text;
1010     }
1011 }
1012
1013 # same as above, but get around the 'if it looks like a function' rule
1014 sub maybe_parens_unop {
1015     my $self = shift;
1016     my($name, $kid, $cx) = @_;
1017     if ($cx > 16 or $self->{'parens'}) {
1018         $kid =  $self->deparse($kid, 1);
1019         if ($name eq "umask" && $kid =~ /^\d+$/) {
1020             $kid = sprintf("%#o", $kid);
1021         }
1022         return $self->keyword($name) . "($kid)";
1023     } else {
1024         $kid = $self->deparse($kid, 16);
1025         if ($name eq "umask" && $kid =~ /^\d+$/) {
1026             $kid = sprintf("%#o", $kid);
1027         }
1028         $name = $self->keyword($name);
1029         if (substr($kid, 0, 1) eq "\cS") {
1030             # use kid's parens
1031             return $name . substr($kid, 1);
1032         } elsif (substr($kid, 0, 1) eq "(") {
1033             # avoid looks-like-a-function trap with extra parens
1034             # ('+' can lead to ambiguities)
1035             return "$name(" . $kid  . ")";
1036         } else {
1037             return "$name $kid";
1038         }
1039     }
1040 }
1041
1042 sub maybe_parens_func {
1043     my $self = shift;
1044     my($func, $text, $cx, $prec) = @_;
1045     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1046         return "$func($text)";
1047     } else {
1048         return "$func $text";
1049     }
1050 }
1051
1052 sub maybe_local {
1053     my $self = shift;
1054     my($op, $cx, $text) = @_;
1055     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1056     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1057         and not $self->{'avoid_local'}{$$op}) {
1058         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1059         if( $our_local eq 'our' ) {
1060             if ( $text !~ /^\W(\w+::)*\w+\z/
1061              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1062             ) {
1063                 die "Unexpected our($text)\n";
1064             }
1065             $text =~ s/(\w+::)+//;
1066         }
1067         if (want_scalar($op)) {
1068             return "$our_local $text";
1069         } else {
1070             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1071         }
1072     } else {
1073         return $text;
1074     }
1075 }
1076
1077 sub maybe_targmy {
1078     my $self = shift;
1079     my($op, $cx, $func, @args) = @_;
1080     if ($op->private & OPpTARGET_MY) {
1081         my $var = $self->padname($op->targ);
1082         my $val = $func->($self, $op, 7, @args);
1083         return $self->maybe_parens("$var = $val", $cx, 7);
1084     } else {
1085         return $func->($self, $op, $cx, @args);
1086     }
1087 }
1088
1089 sub padname_sv {
1090     my $self = shift;
1091     my $targ = shift;
1092     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1093 }
1094
1095 sub maybe_my {
1096     my $self = shift;
1097     my($op, $cx, $text) = @_;
1098     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1099         my $my = $op->private & OPpPAD_STATE
1100             ? $self->keyword("state")
1101             : "my";
1102         if (want_scalar($op)) {
1103             return "$my $text";
1104         } else {
1105             return $self->maybe_parens_func($my, $text, $cx, 16);
1106         }
1107     } else {
1108         return $text;
1109     }
1110 }
1111
1112 # The following OPs don't have functions:
1113
1114 # pp_padany -- does not exist after parsing
1115
1116 sub AUTOLOAD {
1117     if ($AUTOLOAD =~ s/^.*::pp_//) {
1118         warn "unexpected OP_".uc $AUTOLOAD;
1119         return "XXX";
1120     } else {
1121         die "Undefined subroutine $AUTOLOAD called";
1122     }
1123 }
1124
1125 sub DESTROY {}  #       Do not AUTOLOAD
1126
1127 # $root should be the op which represents the root of whatever
1128 # we're sequencing here. If it's undefined, then we don't append
1129 # any subroutine declarations to the deparsed ops, otherwise we
1130 # append appropriate declarations.
1131 sub lineseq {
1132     my($self, $root, @ops) = @_;
1133     my($expr, @exprs);
1134
1135     my $out_cop = $self->{'curcop'};
1136     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1137     my $limit_seq;
1138     if (defined $root) {
1139         $limit_seq = $out_seq;
1140         my $nseq;
1141         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1142         $limit_seq = $nseq if !defined($limit_seq)
1143                            or defined($nseq) && $nseq < $limit_seq;
1144     }
1145     $limit_seq = $self->{'limit_seq'}
1146         if defined($self->{'limit_seq'})
1147         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1148     local $self->{'limit_seq'} = $limit_seq;
1149
1150     $self->walk_lineseq($root, \@ops,
1151                        sub { push @exprs, $_[0]} );
1152
1153     my $body = join(";\n", grep {length} @exprs);
1154     my $subs = "";
1155     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1156         $subs = join "\n", $self->seq_subs($limit_seq);
1157     }
1158     return join(";\n", grep {length} $body, $subs);
1159 }
1160
1161 sub scopeop {
1162     my($real_block, $self, $op, $cx) = @_;
1163     my $kid;
1164     my @kids;
1165
1166     local(@$self{qw'curstash warnings hints hinthash'})
1167                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1168     if ($real_block) {
1169         $kid = $op->first->sibling; # skip enter
1170         if (is_miniwhile($kid)) {
1171             my $top = $kid->first;
1172             my $name = $top->name;
1173             if ($name eq "and") {
1174                 $name = "while";
1175             } elsif ($name eq "or") {
1176                 $name = "until";
1177             } else { # no conditional -> while 1 or until 0
1178                 return $self->deparse($top->first, 1) . " while 1";
1179             }
1180             my $cond = $top->first;
1181             my $body = $cond->sibling->first; # skip lineseq
1182             $cond = $self->deparse($cond, 1);
1183             $body = $self->deparse($body, 1);
1184             return "$body $name $cond";
1185         }
1186     } else {
1187         $kid = $op->first;
1188     }
1189     for (; !null($kid); $kid = $kid->sibling) {
1190         push @kids, $kid;
1191     }
1192     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1193         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1194     } else {
1195         my $lineseq = $self->lineseq($op, @kids);
1196         return (length ($lineseq) ? "$lineseq;" : "");
1197     }
1198 }
1199
1200 sub pp_scope { scopeop(0, @_); }
1201 sub pp_lineseq { scopeop(0, @_); }
1202 sub pp_leave { scopeop(1, @_); }
1203
1204 # This is a special case of scopeop and lineseq, for the case of the
1205 # main_root. The difference is that we print the output statements as
1206 # soon as we get them, for the sake of impatient users.
1207 sub deparse_root {
1208     my $self = shift;
1209     my($op) = @_;
1210     local(@$self{qw'curstash warnings hints hinthash'})
1211       = @$self{qw'curstash warnings hints hinthash'};
1212     my @kids;
1213     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1214     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1215         push @kids, $kid;
1216     }
1217     $self->walk_lineseq($op, \@kids,
1218                         sub { print $self->indent($_[0].';');
1219                               print "\n" unless $_[1] == $#kids;
1220                           });
1221 }
1222
1223 sub walk_lineseq {
1224     my ($self, $op, $kids, $callback) = @_;
1225     my @kids = @$kids;
1226     for (my $i = 0; $i < @kids; $i++) {
1227         my $expr = "";
1228         if (is_state $kids[$i]) {
1229             $expr = $self->deparse($kids[$i++], 0);
1230             if ($i > $#kids) {
1231                 $callback->($expr, $i);
1232                 last;
1233             }
1234         }
1235         if (is_for_loop($kids[$i])) {
1236             $callback->($expr . $self->for_loop($kids[$i], 0),
1237                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1238             next;
1239         }
1240         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1241         $expr =~ s/;\n?\z//;
1242         $callback->($expr, $i);
1243     }
1244 }
1245
1246 # The BEGIN {} is used here because otherwise this code isn't executed
1247 # when you run B::Deparse on itself.
1248 my %globalnames;
1249 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1250             "ENV", "ARGV", "ARGVOUT", "_"); }
1251
1252 sub gv_name {
1253     my $self = shift;
1254     my $gv = shift;
1255 Carp::confess() unless ref($gv) eq "B::GV";
1256     my $stash = $gv->STASH->NAME;
1257     my $name = $gv->SAFENAME;
1258     if ($stash eq 'main' && $name =~ /^::/) {
1259         $stash = '::';
1260     }
1261     elsif (($stash eq 'main' && $globalnames{$name})
1262         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1263             && ($stash eq 'main' || $name !~ /::/))
1264         or $name =~ /^[^A-Za-z_:]/)
1265     {
1266         $stash = "";
1267     } else {
1268         $stash = $stash . "::";
1269     }
1270     if ($name =~ /^(\^..|{)/) {
1271         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1272     }
1273     return $stash . $name;
1274 }
1275
1276 # Return the name to use for a stash variable.
1277 # If a lexical with the same name is in scope, it may need to be
1278 # fully-qualified.
1279 sub stash_variable {
1280     my ($self, $prefix, $name, $cx) = @_;
1281
1282     return "$prefix$name" if $name =~ /::/;
1283
1284     unless ($prefix eq '$' || $prefix eq '@' || #'
1285             $prefix eq '%' || $prefix eq '$#') {
1286         return "$prefix$name";
1287     }
1288
1289     if ($name =~ /^[^\w+-]$/) {
1290       if (defined $cx && $cx == 26) {
1291         if ($prefix eq '@') {
1292             return "$prefix\{$name}";
1293         }
1294         elsif ($name eq '#') { return '${#}' } #  "${#}a" vs "$#a"
1295       }
1296       if ($prefix eq '$#') {
1297         return "\$#{$name}";
1298       }
1299     }
1300
1301     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1302     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1303     return "$prefix$name";
1304 }
1305
1306 sub lex_in_scope {
1307     my ($self, $name) = @_;
1308     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1309
1310     return 0 if !defined($self->{'curcop'});
1311     my $seq = $self->{'curcop'}->cop_seq;
1312     return 0 if !exists $self->{'curcvlex'}{$name};
1313     for my $a (@{$self->{'curcvlex'}{$name}}) {
1314         my ($st, $en) = @$a;
1315         return 1 if $seq > $st && $seq <= $en;
1316     }
1317     return 0;
1318 }
1319
1320 sub populate_curcvlex {
1321     my $self = shift;
1322     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1323         my $padlist = $cv->PADLIST;
1324         # an undef CV still in lexical chain
1325         next if class($padlist) eq "SPECIAL";
1326         my @padlist = $padlist->ARRAY;
1327         my @ns = $padlist[0]->ARRAY;
1328
1329         for (my $i=0; $i<@ns; ++$i) {
1330             next if class($ns[$i]) eq "SPECIAL";
1331             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1332             if (class($ns[$i]) eq "PV") {
1333                 # Probably that pesky lexical @_
1334                 next;
1335             }
1336             my $name = $ns[$i]->PVX;
1337             my ($seq_st, $seq_en) =
1338                 ($ns[$i]->FLAGS & SVf_FAKE)
1339                     ? (0, 999999)
1340                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1341
1342             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1343         }
1344     }
1345 }
1346
1347 sub find_scope_st { ((find_scope(@_))[0]); }
1348 sub find_scope_en { ((find_scope(@_))[1]); }
1349
1350 # Recurses down the tree, looking for pad variable introductions and COPs
1351 sub find_scope {
1352     my ($self, $op, $scope_st, $scope_en) = @_;
1353     carp("Undefined op in find_scope") if !defined $op;
1354     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1355
1356     my @queue = ($op);
1357     while(my $op = shift @queue ) {
1358         for (my $o=$op->first; $$o; $o=$o->sibling) {
1359             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1360                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1361                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1362                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1363                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1364                 return ($scope_st, $scope_en);
1365             }
1366             elsif (is_state($o)) {
1367                 my $c = $o->cop_seq;
1368                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1369                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1370                 return ($scope_st, $scope_en);
1371             }
1372             elsif ($o->flags & OPf_KIDS) {
1373                 unshift (@queue, $o);
1374             }
1375         }
1376     }
1377
1378     return ($scope_st, $scope_en);
1379 }
1380
1381 # Returns a list of subs which should be inserted before the COP
1382 sub cop_subs {
1383     my ($self, $op, $out_seq) = @_;
1384     my $seq = $op->cop_seq;
1385     # If we have nephews, then our sequence number indicates
1386     # the cop_seq of the end of some sort of scope.
1387     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1388         and my $nseq = $self->find_scope_st($op->sibling) ) {
1389         $seq = $nseq;
1390     }
1391     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1392     return $self->seq_subs($seq);
1393 }
1394
1395 sub seq_subs {
1396     my ($self, $seq) = @_;
1397     my @text;
1398 #push @text, "# ($seq)\n";
1399
1400     return "" if !defined $seq;
1401     while (scalar(@{$self->{'subs_todo'}})
1402            and $seq > $self->{'subs_todo'}[0][0]) {
1403         push @text, $self->next_todo;
1404     }
1405     return @text;
1406 }
1407
1408 # Notice how subs and formats are inserted between statements here;
1409 # also $[ assignments and pragmas.
1410 sub pp_nextstate {
1411     my $self = shift;
1412     my($op, $cx) = @_;
1413     $self->{'curcop'} = $op;
1414     my @text;
1415     push @text, $self->cop_subs($op);
1416     my $stash = $op->stashpv;
1417     if ($stash ne $self->{'curstash'}) {
1418         push @text, "package $stash;\n";
1419         $self->{'curstash'} = $stash;
1420     }
1421
1422     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
1423         push @text, '$[ = '. $op->arybase .";\n";
1424         $self->{'arybase'} = $op->arybase;
1425     }
1426
1427     my $warnings = $op->warnings;
1428     my $warning_bits;
1429     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1430         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1431     }
1432     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1433         $warning_bits = $warnings::NONE;
1434     }
1435     elsif ($warnings->isa("B::SPECIAL")) {
1436         $warning_bits = undef;
1437     }
1438     else {
1439         $warning_bits = $warnings->PV & WARN_MASK;
1440     }
1441
1442     if (defined ($warning_bits) and
1443        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1444         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1445         $self->{'warnings'} = $warning_bits;
1446     }
1447
1448     my $hints = $] < 5.008009 ? $op->private : $op->hints;
1449     if ($self->{'hints'} != $hints) {
1450         push @text, declare_hints($self->{'hints'}, $hints);
1451         $self->{'hints'} = $hints;
1452     }
1453
1454     # hack to check that the hint hash hasn't changed
1455     if ($] > 5.009 &&
1456         "@{[sort %{$self->{'hinthash'} || {}}]}"
1457         ne "@{[sort %{$op->hints_hash->HASH || {}}]}") {
1458         push @text, declare_hinthash($self->{'hinthash'}, $op->hints_hash->HASH, $self->{indent_size});
1459         $self->{'hinthash'} = $op->hints_hash->HASH;
1460     }
1461
1462     # This should go after of any branches that add statements, to
1463     # increase the chances that it refers to the same line it did in
1464     # the original program.
1465     if ($self->{'linenums'}) {
1466         push @text, "\f#line " . $op->line .
1467           ' "' . $op->file, qq'"\n';
1468     }
1469
1470     push @text, $op->label . ": " if $op->label;
1471
1472     return join("", @text);
1473 }
1474
1475 sub declare_warnings {
1476     my ($from, $to) = @_;
1477     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1478         return "use warnings;\n";
1479     }
1480     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1481         return "no warnings;\n";
1482     }
1483     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1484 }
1485
1486 sub declare_hints {
1487     my ($from, $to) = @_;
1488     my $use = $to   & ~$from;
1489     my $no  = $from & ~$to;
1490     my $decls = "";
1491     for my $pragma (hint_pragmas($use)) {
1492         $decls .= "use $pragma;\n";
1493     }
1494     for my $pragma (hint_pragmas($no)) {
1495         $decls .= "no $pragma;\n";
1496     }
1497     return $decls;
1498 }
1499
1500 # Internal implementation hints that the core sets automatically, so don't need
1501 # (or want) to be passed back to the user
1502 my %ignored_hints = (
1503     'open<' => 1,
1504     'open>' => 1,
1505     ':'     => 1,
1506 );
1507
1508 sub declare_hinthash {
1509     my ($from, $to, $indent) = @_;
1510     my @decls;
1511     for my $key (keys %$to) {
1512         next if $ignored_hints{$key};
1513         if (!exists $from->{$key} or $from->{$key} ne $to->{$key}) {
1514             push @decls, qq(\$^H{'$key'} = )
1515               . (defined $to->{$key} ? qq(q($to->{$key})) : 'undef')
1516               . qq(;);
1517         }
1518     }
1519     for my $key (keys %$from) {
1520         next if $ignored_hints{$key};
1521         if (!exists $to->{$key}) {
1522             push @decls, qq(delete \$^H{'$key'};);
1523         }
1524     }
1525     @decls or return '';
1526     return join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1527 }
1528
1529 sub hint_pragmas {
1530     my ($bits) = @_;
1531     my @pragmas;
1532     push @pragmas, "integer" if $bits & 0x1;
1533     push @pragmas, "strict 'refs'" if $bits & 0x2;
1534     push @pragmas, "bytes" if $bits & 0x8;
1535     return @pragmas;
1536 }
1537
1538 sub pp_dbstate { pp_nextstate(@_) }
1539 sub pp_setstate { pp_nextstate(@_) }
1540
1541 sub pp_unstack { return "" } # see also leaveloop
1542
1543 my %feature_keywords = (
1544   # keyword => 'feature',
1545     state   => 'state',
1546     say     => 'say',
1547     given   => 'switch',
1548     when    => 'switch',
1549     default => 'switch',
1550     break   => 'switch',
1551     evalbytes=>'evalbytes',
1552     __SUB__ => '__SUB__',
1553 );
1554
1555 sub keyword {
1556     my $self = shift;
1557     my $name = shift;
1558     return $name if $name =~ /^CORE::/; # just in case
1559     if (exists $feature_keywords{$name}) {
1560         return "CORE::$name"
1561          if !$self->{'hinthash'}
1562          || !$self->{'hinthash'}{"feature_$feature_keywords{$name}"}
1563     }
1564     if (
1565       $name !~ /^(?:chom?p|do|exec|glob|s(?:elect|ystem))\z/
1566        && !defined eval{prototype "CORE::$name"}
1567     ) { return $name }
1568     if (
1569         exists $self->{subs_declared}{$name}
1570          or
1571         exists &{"$self->{curstash}::$name"}
1572     ) {
1573         return "CORE::$name"
1574     }
1575     return $name;
1576 }
1577
1578 sub baseop {
1579     my $self = shift;
1580     my($op, $cx, $name) = @_;
1581     return $self->keyword($name);
1582 }
1583
1584 sub pp_stub {
1585     my $self = shift;
1586     my($op, $cx, $name) = @_;
1587     if ($cx >= 1) {
1588         return "()";
1589     }
1590     else {
1591         return "();";
1592     }
1593 }
1594 sub pp_wantarray { baseop(@_, "wantarray") }
1595 sub pp_fork { baseop(@_, "fork") }
1596 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1597 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1598 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1599 sub pp_tms { baseop(@_, "times") }
1600 sub pp_ghostent { baseop(@_, "gethostent") }
1601 sub pp_gnetent { baseop(@_, "getnetent") }
1602 sub pp_gprotoent { baseop(@_, "getprotoent") }
1603 sub pp_gservent { baseop(@_, "getservent") }
1604 sub pp_ehostent { baseop(@_, "endhostent") }
1605 sub pp_enetent { baseop(@_, "endnetent") }
1606 sub pp_eprotoent { baseop(@_, "endprotoent") }
1607 sub pp_eservent { baseop(@_, "endservent") }
1608 sub pp_gpwent { baseop(@_, "getpwent") }
1609 sub pp_spwent { baseop(@_, "setpwent") }
1610 sub pp_epwent { baseop(@_, "endpwent") }
1611 sub pp_ggrent { baseop(@_, "getgrent") }
1612 sub pp_sgrent { baseop(@_, "setgrent") }
1613 sub pp_egrent { baseop(@_, "endgrent") }
1614 sub pp_getlogin { baseop(@_, "getlogin") }
1615
1616 sub POSTFIX () { 1 }
1617
1618 # I couldn't think of a good short name, but this is the category of
1619 # symbolic unary operators with interesting precedence
1620
1621 sub pfixop {
1622     my $self = shift;
1623     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1624     my $kid = $op->first;
1625     $kid = $self->deparse($kid, $prec);
1626     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1627                                $cx, $prec);
1628 }
1629
1630 sub pp_preinc { pfixop(@_, "++", 23) }
1631 sub pp_predec { pfixop(@_, "--", 23) }
1632 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1633 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1634 sub pp_i_preinc { pfixop(@_, "++", 23) }
1635 sub pp_i_predec { pfixop(@_, "--", 23) }
1636 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1637 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1638 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1639
1640 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1641 sub real_negate {
1642     my $self = shift;
1643     my($op, $cx) = @_;
1644     if ($op->first->name =~ /^(i_)?negate$/) {
1645         # avoid --$x
1646         $self->pfixop($op, $cx, "-", 21.5);
1647     } else {
1648         $self->pfixop($op, $cx, "-", 21);
1649     }
1650 }
1651 sub pp_i_negate { pp_negate(@_) }
1652
1653 sub pp_not {
1654     my $self = shift;
1655     my($op, $cx) = @_;
1656     if ($cx <= 4) {
1657         $self->pfixop($op, $cx, $self->keyword("not")." ", 4);
1658     } else {
1659         $self->pfixop($op, $cx, "!", 21);
1660     }
1661 }
1662
1663 sub unop {
1664     my $self = shift;
1665     my($op, $cx, $name) = @_;
1666     my $kid;
1667     if ($op->flags & OPf_KIDS) {
1668         $kid = $op->first;
1669         if (not $name) {
1670             # this deals with 'boolkeys' right now
1671             return $self->deparse($kid,$cx);
1672         }
1673         my $builtinname = $name;
1674         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
1675         if (defined prototype($builtinname)
1676            && prototype($builtinname) =~ /^;?\*/
1677            && $kid->name eq "rv2gv") {
1678             $kid = $kid->first;
1679         }
1680
1681         return $self->maybe_parens_unop($name, $kid, $cx);
1682     } else {
1683         return $self->keyword($name)
1684           . ($op->flags & OPf_SPECIAL ? "()" : "");
1685     }
1686 }
1687
1688 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1689 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1690 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1691 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1692 sub pp_defined { unop(@_, "defined") }
1693 sub pp_undef { unop(@_, "undef") }
1694 sub pp_study { unop(@_, "study") }
1695 sub pp_ref { unop(@_, "ref") }
1696 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1697
1698 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1699 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1700 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1701 sub pp_srand { unop(@_, "srand") }
1702 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1703 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1704 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1705 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1706 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1707 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1708 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1709
1710 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1711 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1712 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1713
1714 sub pp_each { unop(@_, "each") }
1715 sub pp_values { unop(@_, "values") }
1716 sub pp_keys { unop(@_, "keys") }
1717 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
1718 sub pp_boolkeys {
1719     # no name because its an optimisation op that has no keyword
1720     unop(@_,"");
1721 }
1722 sub pp_aeach { unop(@_, "each") }
1723 sub pp_avalues { unop(@_, "values") }
1724 sub pp_akeys { unop(@_, "keys") }
1725 sub pp_pop { unop(@_, "pop") }
1726 sub pp_shift { unop(@_, "shift") }
1727
1728 sub pp_caller { unop(@_, "caller") }
1729 sub pp_reset { unop(@_, "reset") }
1730 sub pp_exit { unop(@_, "exit") }
1731 sub pp_prototype { unop(@_, "prototype") }
1732
1733 sub pp_close { unop(@_, "close") }
1734 sub pp_fileno { unop(@_, "fileno") }
1735 sub pp_umask { unop(@_, "umask") }
1736 sub pp_untie { unop(@_, "untie") }
1737 sub pp_tied { unop(@_, "tied") }
1738 sub pp_dbmclose { unop(@_, "dbmclose") }
1739 sub pp_getc { unop(@_, "getc") }
1740 sub pp_eof { unop(@_, "eof") }
1741 sub pp_tell { unop(@_, "tell") }
1742 sub pp_getsockname { unop(@_, "getsockname") }
1743 sub pp_getpeername { unop(@_, "getpeername") }
1744
1745 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1746 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1747 sub pp_readlink { unop(@_, "readlink") }
1748 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1749 sub pp_readdir { unop(@_, "readdir") }
1750 sub pp_telldir { unop(@_, "telldir") }
1751 sub pp_rewinddir { unop(@_, "rewinddir") }
1752 sub pp_closedir { unop(@_, "closedir") }
1753 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1754 sub pp_localtime { unop(@_, "localtime") }
1755 sub pp_gmtime { unop(@_, "gmtime") }
1756 sub pp_alarm { unop(@_, "alarm") }
1757 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1758
1759 sub pp_dofile { unop(@_, "do") }
1760 sub pp_entereval {
1761     unop(
1762       @_,
1763       $_[1]->private & OPpEVAL_BYTES ? $_[0]->keyword('evalbytes') : "eval"
1764     )
1765 }
1766
1767 sub pp_ghbyname { unop(@_, "gethostbyname") }
1768 sub pp_gnbyname { unop(@_, "getnetbyname") }
1769 sub pp_gpbyname { unop(@_, "getprotobyname") }
1770 sub pp_shostent { unop(@_, "sethostent") }
1771 sub pp_snetent { unop(@_, "setnetent") }
1772 sub pp_sprotoent { unop(@_, "setprotoent") }
1773 sub pp_sservent { unop(@_, "setservent") }
1774 sub pp_gpwnam { unop(@_, "getpwnam") }
1775 sub pp_gpwuid { unop(@_, "getpwuid") }
1776 sub pp_ggrnam { unop(@_, "getgrnam") }
1777 sub pp_ggrgid { unop(@_, "getgrgid") }
1778
1779 sub pp_lock { unop(@_, "lock") }
1780
1781 sub pp_continue { unop(@_, "continue"); }
1782 sub pp_break { unop(@_, "break"); }
1783
1784 sub givwhen {
1785     my $self = shift;
1786     my($op, $cx, $givwhen) = @_;
1787
1788     my $enterop = $op->first;
1789     my ($head, $block);
1790     if ($enterop->flags & OPf_SPECIAL) {
1791         $head = $self->keyword("default");
1792         $block = $self->deparse($enterop->first, 0);
1793     }
1794     else {
1795         my $cond = $enterop->first;
1796         my $cond_str = $self->deparse($cond, 1);
1797         $head = "$givwhen ($cond_str)";
1798         $block = $self->deparse($cond->sibling, 0);
1799     }
1800
1801     return "$head {\n".
1802         "\t$block\n".
1803         "\b}\cK";
1804 }
1805
1806 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
1807 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
1808
1809 sub pp_exists {
1810     my $self = shift;
1811     my($op, $cx) = @_;
1812     my $arg;
1813     if ($op->private & OPpEXISTS_SUB) {
1814         # Checking for the existence of a subroutine
1815         return $self->maybe_parens_func("exists",
1816                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1817     }
1818     if ($op->flags & OPf_SPECIAL) {
1819         # Array element, not hash element
1820         return $self->maybe_parens_func("exists",
1821                                 $self->pp_aelem($op->first, 16), $cx, 16);
1822     }
1823     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1824                                     $cx, 16);
1825 }
1826
1827 sub pp_delete {
1828     my $self = shift;
1829     my($op, $cx) = @_;
1830     my $arg;
1831     if ($op->private & OPpSLICE) {
1832         if ($op->flags & OPf_SPECIAL) {
1833             # Deleting from an array, not a hash
1834             return $self->maybe_parens_func("delete",
1835                                         $self->pp_aslice($op->first, 16),
1836                                         $cx, 16);
1837         }
1838         return $self->maybe_parens_func("delete",
1839                                         $self->pp_hslice($op->first, 16),
1840                                         $cx, 16);
1841     } else {
1842         if ($op->flags & OPf_SPECIAL) {
1843             # Deleting from an array, not a hash
1844             return $self->maybe_parens_func("delete",
1845                                         $self->pp_aelem($op->first, 16),
1846                                         $cx, 16);
1847         }
1848         return $self->maybe_parens_func("delete",
1849                                         $self->pp_helem($op->first, 16),
1850                                         $cx, 16);
1851     }
1852 }
1853
1854 sub pp_require {
1855     my $self = shift;
1856     my($op, $cx) = @_;
1857     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
1858     if (class($op) eq "UNOP" and $op->first->name eq "const"
1859         and $op->first->private & OPpCONST_BARE)
1860     {
1861         my $name = $self->const_sv($op->first)->PV;
1862         $name =~ s[/][::]g;
1863         $name =~ s/\.pm//g;
1864         return "$opname $name";
1865     } else {
1866         $self->unop($op, $cx, $op->first->private & OPpCONST_NOVER ? "no" : $opname);
1867     }
1868 }
1869
1870 sub pp_scalar {
1871     my $self = shift;
1872     my($op, $cx) = @_;
1873     my $kid = $op->first;
1874     if (not null $kid->sibling) {
1875         # XXX Was a here-doc
1876         return $self->dquote($op);
1877     }
1878     $self->unop(@_, "scalar");
1879 }
1880
1881
1882 sub padval {
1883     my $self = shift;
1884     my $targ = shift;
1885     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
1886 }
1887
1888 sub anon_hash_or_list {
1889     my $self = shift;
1890     my($op, $cx) = @_;
1891
1892     my($pre, $post) = @{{"anonlist" => ["[","]"],
1893                          "anonhash" => ["{","}"]}->{$op->name}};
1894     my($expr, @exprs);
1895     $op = $op->first->sibling; # skip pushmark
1896     for (; !null($op); $op = $op->sibling) {
1897         $expr = $self->deparse($op, 6);
1898         push @exprs, $expr;
1899     }
1900     if ($pre eq "{" and $cx < 1) {
1901         # Disambiguate that it's not a block
1902         $pre = "+{";
1903     }
1904     return $pre . join(", ", @exprs) . $post;
1905 }
1906
1907 sub pp_anonlist {
1908     my $self = shift;
1909     my ($op, $cx) = @_;
1910     if ($op->flags & OPf_SPECIAL) {
1911         return $self->anon_hash_or_list($op, $cx);
1912     }
1913     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
1914     return 'XXX';
1915 }
1916
1917 *pp_anonhash = \&pp_anonlist;
1918
1919 sub pp_refgen {
1920     my $self = shift;
1921     my($op, $cx) = @_;
1922     my $kid = $op->first;
1923     if ($kid->name eq "null") {
1924         $kid = $kid->first;
1925         if (!null($kid->sibling) and
1926                  $kid->sibling->name eq "anoncode") {
1927             return $self->e_anoncode({ code => $self->padval($kid->sibling->targ) });
1928         } elsif ($kid->name eq "pushmark") {
1929             my $sib_name = $kid->sibling->name;
1930             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1931                 and not $kid->sibling->flags & OPf_REF)
1932             {
1933                 # The @a in \(@a) isn't in ref context, but only when the
1934                 # parens are there.
1935                 return "\\(" . $self->pp_list($op->first) . ")";
1936             } elsif ($sib_name eq 'entersub') {
1937                 my $text = $self->deparse($kid->sibling, 1);
1938                 # Always show parens for \(&func()), but only with -p otherwise
1939                 $text = "($text)" if $self->{'parens'}
1940                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1941                 return "\\$text";
1942             }
1943         }
1944     }
1945     $self->pfixop($op, $cx, "\\", 20);
1946 }
1947
1948 sub e_anoncode {
1949     my ($self, $info) = @_;
1950     my $text = $self->deparse_sub($info->{code});
1951     return "sub " . $text;
1952 }
1953
1954 sub pp_srefgen { pp_refgen(@_) }
1955
1956 sub pp_readline {
1957     my $self = shift;
1958     my($op, $cx) = @_;
1959     my $kid = $op->first;
1960     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1961     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1962     return $self->unop($op, $cx, "readline");
1963 }
1964
1965 sub pp_rcatline {
1966     my $self = shift;
1967     my($op) = @_;
1968     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
1969 }
1970
1971 # Unary operators that can occur as pseudo-listops inside double quotes
1972 sub dq_unop {
1973     my $self = shift;
1974     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1975     my $kid;
1976     if ($op->flags & OPf_KIDS) {
1977        $kid = $op->first;
1978        # If there's more than one kid, the first is an ex-pushmark.
1979        $kid = $kid->sibling if not null $kid->sibling;
1980        return $self->maybe_parens_unop($name, $kid, $cx);
1981     } else {
1982        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1983     }
1984 }
1985
1986 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1987 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1988 sub pp_uc { dq_unop(@_, "uc") }
1989 sub pp_lc { dq_unop(@_, "lc") }
1990 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1991
1992 sub loopex {
1993     my $self = shift;
1994     my ($op, $cx, $name) = @_;
1995     if (class($op) eq "PVOP") {
1996         return "$name " . $op->pv;
1997     } elsif (class($op) eq "OP") {
1998         return $name;
1999     } elsif (class($op) eq "UNOP") {
2000         # Note -- loop exits are actually exempt from the
2001         # looks-like-a-func rule, but a few extra parens won't hurt
2002         return $self->maybe_parens_unop($name, $op->first, $cx);
2003     }
2004 }
2005
2006 sub pp_last { loopex(@_, "last") }
2007 sub pp_next { loopex(@_, "next") }
2008 sub pp_redo { loopex(@_, "redo") }
2009 sub pp_goto { loopex(@_, "goto") }
2010 sub pp_dump { loopex(@_, $_[0]->keyword("dump")) }
2011
2012 sub ftst {
2013     my $self = shift;
2014     my($op, $cx, $name) = @_;
2015     if (class($op) eq "UNOP") {
2016         # Genuine '-X' filetests are exempt from the LLAFR, but not
2017         # l?stat(); for the sake of clarity, give'em all parens
2018         return $self->maybe_parens_unop($name, $op->first, $cx);
2019     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2020         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2021     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2022         return $name;
2023     }
2024 }
2025
2026 sub pp_lstat    { ftst(@_, "lstat") }
2027 sub pp_stat     { ftst(@_, "stat") }
2028 sub pp_ftrread  { ftst(@_, "-R") }
2029 sub pp_ftrwrite { ftst(@_, "-W") }
2030 sub pp_ftrexec  { ftst(@_, "-X") }
2031 sub pp_fteread  { ftst(@_, "-r") }
2032 sub pp_ftewrite { ftst(@_, "-w") }
2033 sub pp_fteexec  { ftst(@_, "-x") }
2034 sub pp_ftis     { ftst(@_, "-e") }
2035 sub pp_fteowned { ftst(@_, "-O") }
2036 sub pp_ftrowned { ftst(@_, "-o") }
2037 sub pp_ftzero   { ftst(@_, "-z") }
2038 sub pp_ftsize   { ftst(@_, "-s") }
2039 sub pp_ftmtime  { ftst(@_, "-M") }
2040 sub pp_ftatime  { ftst(@_, "-A") }
2041 sub pp_ftctime  { ftst(@_, "-C") }
2042 sub pp_ftsock   { ftst(@_, "-S") }
2043 sub pp_ftchr    { ftst(@_, "-c") }
2044 sub pp_ftblk    { ftst(@_, "-b") }
2045 sub pp_ftfile   { ftst(@_, "-f") }
2046 sub pp_ftdir    { ftst(@_, "-d") }
2047 sub pp_ftpipe   { ftst(@_, "-p") }
2048 sub pp_ftlink   { ftst(@_, "-l") }
2049 sub pp_ftsuid   { ftst(@_, "-u") }
2050 sub pp_ftsgid   { ftst(@_, "-g") }
2051 sub pp_ftsvtx   { ftst(@_, "-k") }
2052 sub pp_fttty    { ftst(@_, "-t") }
2053 sub pp_fttext   { ftst(@_, "-T") }
2054 sub pp_ftbinary { ftst(@_, "-B") }
2055
2056 sub SWAP_CHILDREN () { 1 }
2057 sub ASSIGN () { 2 } # has OP= variant
2058 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2059
2060 my(%left, %right);
2061
2062 sub assoc_class {
2063     my $op = shift;
2064     my $name = $op->name;
2065     if ($name eq "concat" and $op->first->name eq "concat") {
2066         # avoid spurious '=' -- see comment in pp_concat
2067         return "concat";
2068     }
2069     if ($name eq "null" and class($op) eq "UNOP"
2070         and $op->first->name =~ /^(and|x?or)$/
2071         and null $op->first->sibling)
2072     {
2073         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2074         # with a null that's used as the common end point of the two
2075         # flows of control. For precedence purposes, ignore it.
2076         # (COND_EXPRs have these too, but we don't bother with
2077         # their associativity).
2078         return assoc_class($op->first);
2079     }
2080     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2081 }
2082
2083 # Left associative operators, like '+', for which
2084 # $a + $b + $c is equivalent to ($a + $b) + $c
2085
2086 BEGIN {
2087     %left = ('multiply' => 19, 'i_multiply' => 19,
2088              'divide' => 19, 'i_divide' => 19,
2089              'modulo' => 19, 'i_modulo' => 19,
2090              'repeat' => 19,
2091              'add' => 18, 'i_add' => 18,
2092              'subtract' => 18, 'i_subtract' => 18,
2093              'concat' => 18,
2094              'left_shift' => 17, 'right_shift' => 17,
2095              'bit_and' => 13,
2096              'bit_or' => 12, 'bit_xor' => 12,
2097              'and' => 3,
2098              'or' => 2, 'xor' => 2,
2099             );
2100 }
2101
2102 sub deparse_binop_left {
2103     my $self = shift;
2104     my($op, $left, $prec) = @_;
2105     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2106         and $left{assoc_class($op)} == $left{assoc_class($left)})
2107     {
2108         return $self->deparse($left, $prec - .00001);
2109     } else {
2110         return $self->deparse($left, $prec);
2111     }
2112 }
2113
2114 # Right associative operators, like '=', for which
2115 # $a = $b = $c is equivalent to $a = ($b = $c)
2116
2117 BEGIN {
2118     %right = ('pow' => 22,
2119               'sassign=' => 7, 'aassign=' => 7,
2120               'multiply=' => 7, 'i_multiply=' => 7,
2121               'divide=' => 7, 'i_divide=' => 7,
2122               'modulo=' => 7, 'i_modulo=' => 7,
2123               'repeat=' => 7,
2124               'add=' => 7, 'i_add=' => 7,
2125               'subtract=' => 7, 'i_subtract=' => 7,
2126               'concat=' => 7,
2127               'left_shift=' => 7, 'right_shift=' => 7,
2128               'bit_and=' => 7,
2129               'bit_or=' => 7, 'bit_xor=' => 7,
2130               'andassign' => 7,
2131               'orassign' => 7,
2132              );
2133 }
2134
2135 sub deparse_binop_right {
2136     my $self = shift;
2137     my($op, $right, $prec) = @_;
2138     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2139         and $right{assoc_class($op)} == $right{assoc_class($right)})
2140     {
2141         return $self->deparse($right, $prec - .00001);
2142     } else {
2143         return $self->deparse($right, $prec);
2144     }
2145 }
2146
2147 sub binop {
2148     my $self = shift;
2149     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2150     my $left = $op->first;
2151     my $right = $op->last;
2152     my $eq = "";
2153     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2154         $eq = "=";
2155         $prec = 7;
2156     }
2157     if ($flags & SWAP_CHILDREN) {
2158         ($left, $right) = ($right, $left);
2159     }
2160     $left = $self->deparse_binop_left($op, $left, $prec);
2161     $left = "($left)" if $flags & LIST_CONTEXT
2162                 && $left !~ /^(my|our|local|)[\@\(]/;
2163     $right = $self->deparse_binop_right($op, $right, $prec);
2164     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2165 }
2166
2167 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2168 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2169 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2170 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2171 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2172 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2173 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2174 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2175 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2176 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2177 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2178
2179 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2180 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2181 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2182 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2183 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2184
2185 sub pp_eq { binop(@_, "==", 14) }
2186 sub pp_ne { binop(@_, "!=", 14) }
2187 sub pp_lt { binop(@_, "<", 15) }
2188 sub pp_gt { binop(@_, ">", 15) }
2189 sub pp_ge { binop(@_, ">=", 15) }
2190 sub pp_le { binop(@_, "<=", 15) }
2191 sub pp_ncmp { binop(@_, "<=>", 14) }
2192 sub pp_i_eq { binop(@_, "==", 14) }
2193 sub pp_i_ne { binop(@_, "!=", 14) }
2194 sub pp_i_lt { binop(@_, "<", 15) }
2195 sub pp_i_gt { binop(@_, ">", 15) }
2196 sub pp_i_ge { binop(@_, ">=", 15) }
2197 sub pp_i_le { binop(@_, "<=", 15) }
2198 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2199
2200 sub pp_seq { binop(@_, "eq", 14) }
2201 sub pp_sne { binop(@_, "ne", 14) }
2202 sub pp_slt { binop(@_, "lt", 15) }
2203 sub pp_sgt { binop(@_, "gt", 15) }
2204 sub pp_sge { binop(@_, "ge", 15) }
2205 sub pp_sle { binop(@_, "le", 15) }
2206 sub pp_scmp { binop(@_, "cmp", 14) }
2207
2208 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2209 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2210
2211 sub pp_smartmatch {
2212     my ($self, $op, $cx) = @_;
2213     if ($op->flags & OPf_SPECIAL) {
2214         return $self->deparse($op->last, $cx);
2215     }
2216     else {
2217         binop(@_, "~~", 14);
2218     }
2219 }
2220
2221 # '.' is special because concats-of-concats are optimized to save copying
2222 # by making all but the first concat stacked. The effect is as if the
2223 # programmer had written '($a . $b) .= $c', except legal.
2224 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2225 sub real_concat {
2226     my $self = shift;
2227     my($op, $cx) = @_;
2228     my $left = $op->first;
2229     my $right = $op->last;
2230     my $eq = "";
2231     my $prec = 18;
2232     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2233         $eq = "=";
2234         $prec = 7;
2235     }
2236     $left = $self->deparse_binop_left($op, $left, $prec);
2237     $right = $self->deparse_binop_right($op, $right, $prec);
2238     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2239 }
2240
2241 # 'x' is weird when the left arg is a list
2242 sub pp_repeat {
2243     my $self = shift;
2244     my($op, $cx) = @_;
2245     my $left = $op->first;
2246     my $right = $op->last;
2247     my $eq = "";
2248     my $prec = 19;
2249     if ($op->flags & OPf_STACKED) {
2250         $eq = "=";
2251         $prec = 7;
2252     }
2253     if (null($right)) { # list repeat; count is inside left-side ex-list
2254         my $kid = $left->first->sibling; # skip pushmark
2255         my @exprs;
2256         for (; !null($kid->sibling); $kid = $kid->sibling) {
2257             push @exprs, $self->deparse($kid, 6);
2258         }
2259         $right = $kid;
2260         $left = "(" . join(", ", @exprs). ")";
2261     } else {
2262         $left = $self->deparse_binop_left($op, $left, $prec);
2263     }
2264     $right = $self->deparse_binop_right($op, $right, $prec);
2265     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2266 }
2267
2268 sub range {
2269     my $self = shift;
2270     my ($op, $cx, $type) = @_;
2271     my $left = $op->first;
2272     my $right = $left->sibling;
2273     $left = $self->deparse($left, 9);
2274     $right = $self->deparse($right, 9);
2275     return $self->maybe_parens("$left $type $right", $cx, 9);
2276 }
2277
2278 sub pp_flop {
2279     my $self = shift;
2280     my($op, $cx) = @_;
2281     my $flip = $op->first;
2282     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2283     return $self->range($flip->first, $cx, $type);
2284 }
2285
2286 # one-line while/until is handled in pp_leave
2287
2288 sub logop {
2289     my $self = shift;
2290     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2291     my $left = $op->first;
2292     my $right = $op->first->sibling;
2293     if ($cx < 1 and is_scope($right) and $blockname
2294         and $self->{'expand'} < 7)
2295     { # if ($a) {$b}
2296         $left = $self->deparse($left, 1);
2297         $right = $self->deparse($right, 0);
2298         return "$blockname ($left) {\n\t$right\n\b}\cK";
2299     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2300              and $self->{'expand'} < 7) { # $b if $a
2301         $right = $self->deparse($right, 1);
2302         $left = $self->deparse($left, 1);
2303         return "$right $blockname $left";
2304     } elsif ($cx > $lowprec and $highop) { # $a && $b
2305         $left = $self->deparse_binop_left($op, $left, $highprec);
2306         $right = $self->deparse_binop_right($op, $right, $highprec);
2307         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2308     } else { # $a and $b
2309         $left = $self->deparse_binop_left($op, $left, $lowprec);
2310         $right = $self->deparse_binop_right($op, $right, $lowprec);
2311         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2312     }
2313 }
2314
2315 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2316 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2317 sub pp_dor { logop(@_, "//", 10) }
2318
2319 # xor is syntactically a logop, but it's really a binop (contrary to
2320 # old versions of opcode.pl). Syntax is what matters here.
2321 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2322
2323 sub logassignop {
2324     my $self = shift;
2325     my ($op, $cx, $opname) = @_;
2326     my $left = $op->first;
2327     my $right = $op->first->sibling->first; # skip sassign
2328     $left = $self->deparse($left, 7);
2329     $right = $self->deparse($right, 7);
2330     return $self->maybe_parens("$left $opname $right", $cx, 7);
2331 }
2332
2333 sub pp_andassign { logassignop(@_, "&&=") }
2334 sub pp_orassign  { logassignop(@_, "||=") }
2335 sub pp_dorassign { logassignop(@_, "//=") }
2336
2337 sub listop {
2338     my $self = shift;
2339     my($op, $cx, $name, $kid) = @_;
2340     my(@exprs);
2341     my $parens = ($cx >= 5) || $self->{'parens'};
2342     $kid ||= $op->first->sibling;
2343     return $self->keyword($name) if null $kid;
2344     my $first;
2345     $name = "socketpair" if $name eq "sockpair";
2346     my $fullname = $self->keyword($name);
2347     my $proto = prototype("CORE::$name");
2348     if (defined $proto
2349         && $proto =~ /^;?\*/
2350         && $kid->name eq "rv2gv") {
2351         $first = $self->deparse($kid->first, 6);
2352     }
2353     else {
2354         $first = $self->deparse($kid, 6);
2355     }
2356     if ($name eq "chmod" && $first =~ /^\d+$/) {
2357         $first = sprintf("%#o", $first);
2358     }
2359     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
2360     push @exprs, $first;
2361     $kid = $kid->sibling;
2362     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv") {
2363         push @exprs, $self->deparse($kid->first, 6);
2364         $kid = $kid->sibling;
2365     }
2366     for (; !null($kid); $kid = $kid->sibling) {
2367         push @exprs, $self->deparse($kid, 6);
2368     }
2369     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
2370         return "$exprs[0] = $fullname"
2371                  . ($parens ? "($exprs[0])" : " $exprs[0]");
2372     }
2373     if ($parens) {
2374         return "$fullname(" . join(", ", @exprs) . ")";
2375     } else {
2376         return "$fullname " . join(", ", @exprs);
2377     }
2378 }
2379
2380 sub pp_bless { listop(@_, "bless") }
2381 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2382 sub pp_substr {
2383     my ($self,$op,$cx) = @_;
2384     if ($op->private & OPpSUBSTR_REPL_FIRST) {
2385         return
2386            listop($self, $op, 7, "substr", $op->first->sibling->sibling)
2387          . " = "
2388          . $self->deparse($op->first->sibling, 7);
2389     }
2390     maybe_local(@_, listop(@_, "substr"))
2391 }
2392 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2393 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2394 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2395 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2396 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2397 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2398 sub pp_unpack { listop(@_, "unpack") }
2399 sub pp_pack { listop(@_, "pack") }
2400 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2401 sub pp_splice { listop(@_, "splice") }
2402 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2403 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2404 sub pp_reverse { listop(@_, "reverse") }
2405 sub pp_warn { listop(@_, "warn") }
2406 sub pp_die { listop(@_, "die") }
2407 # Actually, return is exempt from the LLAFR (see examples in this very
2408 # module!), but for consistency's sake, ignore that fact
2409 sub pp_return { listop(@_, "return") }
2410 sub pp_open { listop(@_, "open") }
2411 sub pp_pipe_op { listop(@_, "pipe") }
2412 sub pp_tie { listop(@_, "tie") }
2413 sub pp_binmode { listop(@_, "binmode") }
2414 sub pp_dbmopen { listop(@_, "dbmopen") }
2415 sub pp_sselect { listop(@_, "select") }
2416 sub pp_select { listop(@_, "select") }
2417 sub pp_read { listop(@_, "read") }
2418 sub pp_sysopen { listop(@_, "sysopen") }
2419 sub pp_sysseek { listop(@_, "sysseek") }
2420 sub pp_sysread { listop(@_, "sysread") }
2421 sub pp_syswrite { listop(@_, "syswrite") }
2422 sub pp_send { listop(@_, "send") }
2423 sub pp_recv { listop(@_, "recv") }
2424 sub pp_seek { listop(@_, "seek") }
2425 sub pp_fcntl { listop(@_, "fcntl") }
2426 sub pp_ioctl { listop(@_, "ioctl") }
2427 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2428 sub pp_socket { listop(@_, "socket") }
2429 sub pp_sockpair { listop(@_, "sockpair") }
2430 sub pp_bind { listop(@_, "bind") }
2431 sub pp_connect { listop(@_, "connect") }
2432 sub pp_listen { listop(@_, "listen") }
2433 sub pp_accept { listop(@_, "accept") }
2434 sub pp_shutdown { listop(@_, "shutdown") }
2435 sub pp_gsockopt { listop(@_, "getsockopt") }
2436 sub pp_ssockopt { listop(@_, "setsockopt") }
2437 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2438 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2439 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2440 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2441 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2442 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2443 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2444 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2445 sub pp_open_dir { listop(@_, "opendir") }
2446 sub pp_seekdir { listop(@_, "seekdir") }
2447 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2448 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2449 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2450 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2451 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2452 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2453 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2454 sub pp_shmget { listop(@_, "shmget") }
2455 sub pp_shmctl { listop(@_, "shmctl") }
2456 sub pp_shmread { listop(@_, "shmread") }
2457 sub pp_shmwrite { listop(@_, "shmwrite") }
2458 sub pp_msgget { listop(@_, "msgget") }
2459 sub pp_msgctl { listop(@_, "msgctl") }
2460 sub pp_msgsnd { listop(@_, "msgsnd") }
2461 sub pp_msgrcv { listop(@_, "msgrcv") }
2462 sub pp_semget { listop(@_, "semget") }
2463 sub pp_semctl { listop(@_, "semctl") }
2464 sub pp_semop { listop(@_, "semop") }
2465 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2466 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2467 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2468 sub pp_gsbyname { listop(@_, "getservbyname") }
2469 sub pp_gsbyport { listop(@_, "getservbyport") }
2470 sub pp_syscall { listop(@_, "syscall") }
2471
2472 sub pp_glob {
2473     my $self = shift;
2474     my($op, $cx) = @_;
2475     my $text = $self->dq($op->first->sibling);  # skip pushmark
2476     my $keyword =
2477         $op->flags & OPf_SPECIAL ? 'glob' : $self->keyword('glob');
2478     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2479         or $keyword =~ /^CORE::/
2480         or $text =~ /[<>]/) {
2481         return "$keyword(" . single_delim('qq', '"', $text) . ')';
2482     } else {
2483         return '<' . $text . '>';
2484     }
2485 }
2486
2487 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2488 # be a filehandle. This could probably be better fixed in the core
2489 # by moving the GV lookup into ck_truc.
2490
2491 sub pp_truncate {
2492     my $self = shift;
2493     my($op, $cx) = @_;
2494     my(@exprs);
2495     my $parens = ($cx >= 5) || $self->{'parens'};
2496     my $kid = $op->first->sibling;
2497     my $fh;
2498     if ($op->flags & OPf_SPECIAL) {
2499         # $kid is an OP_CONST
2500         $fh = $self->const_sv($kid)->PV;
2501     } else {
2502         $fh = $self->deparse($kid, 6);
2503         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2504     }
2505     my $len = $self->deparse($kid->sibling, 6);
2506     my $name = $self->keyword('truncate');
2507     if ($parens) {
2508         return "$name($fh, $len)";
2509     } else {
2510         return "$name $fh, $len";
2511     }
2512 }
2513
2514 sub indirop {
2515     my $self = shift;
2516     my($op, $cx, $name) = @_;
2517     my($expr, @exprs);
2518     my $firstkid = my $kid = $op->first->sibling;
2519     my $indir = "";
2520     if ($op->flags & OPf_STACKED) {
2521         $indir = $kid;
2522         $indir = $indir->first; # skip rv2gv
2523         if (is_scope($indir)) {
2524             $indir = "{" . $self->deparse($indir, 0) . "}";
2525             $indir = "{;}" if $indir eq "{}";
2526         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2527             $indir = $self->const_sv($indir)->PV;
2528         } else {
2529             $indir = $self->deparse($indir, 24);
2530         }
2531         $indir = $indir . " ";
2532         $kid = $kid->sibling;
2533     }
2534     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2535         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2536                                                   : '{$a <=> $b} ';
2537     }
2538     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2539         $indir = '{$b cmp $a} ';
2540     }
2541     for (; !null($kid); $kid = $kid->sibling) {
2542         $expr = $self->deparse($kid, !$indir && $kid == $firstkid && $name eq "sort" && $firstkid->name eq "entersub" ? 16 : 6);
2543         push @exprs, $expr;
2544     }
2545     my $name2;
2546     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2547         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
2548     }
2549     else { $name2 = $self->keyword($name) }
2550     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2551         return "$exprs[0] = $name2 $indir $exprs[0]";
2552     }
2553
2554     my $args = $indir . join(", ", @exprs);
2555     if ($indir ne "" && $name eq "sort") {
2556         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2557         # give bareword warnings in that case. Therefore if context
2558         # requires, we'll put parens around the outside "(sort f 1, 2,
2559         # 3)". Unfortunately, we'll currently think the parens are
2560         # necessary more often that they really are, because we don't
2561         # distinguish which side of an assignment we're on.
2562         if ($cx >= 5) {
2563             return "($name2 $args)";
2564         } else {
2565             return "$name2 $args";
2566         }
2567     } elsif (
2568         !$indir && $name eq "sort"
2569       && $op->first->sibling->name eq 'entersub'
2570     ) {
2571         # We cannot say sort foo(bar), as foo will be interpreted as a
2572         # comparison routine.  We have to say sort(...) in that case.
2573         return "$name2($args)";
2574     } else {
2575         return $self->maybe_parens_func($name2, $args, $cx, 5);
2576     }
2577
2578 }
2579
2580 sub pp_prtf { indirop(@_, "printf") }
2581 sub pp_print { indirop(@_, "print") }
2582 sub pp_say  { indirop(@_, "say") }
2583 sub pp_sort { indirop(@_, "sort") }
2584
2585 sub mapop {
2586     my $self = shift;
2587     my($op, $cx, $name) = @_;
2588     my($expr, @exprs);
2589     my $kid = $op->first; # this is the (map|grep)start
2590     $kid = $kid->first->sibling; # skip a pushmark
2591     my $code = $kid->first; # skip a null
2592     if (is_scope $code) {
2593         $code = "{" . $self->deparse($code, 0) . "} ";
2594     } else {
2595         $code = $self->deparse($code, 24) . ", ";
2596     }
2597     $kid = $kid->sibling;
2598     for (; !null($kid); $kid = $kid->sibling) {
2599         $expr = $self->deparse($kid, 6);
2600         push @exprs, $expr if defined $expr;
2601     }
2602     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2603 }
2604
2605 sub pp_mapwhile { mapop(@_, "map") }
2606 sub pp_grepwhile { mapop(@_, "grep") }
2607 sub pp_mapstart { baseop(@_, "map") }
2608 sub pp_grepstart { baseop(@_, "grep") }
2609
2610 sub pp_list {
2611     my $self = shift;
2612     my($op, $cx) = @_;
2613     my($expr, @exprs);
2614     my $kid = $op->first->sibling; # skip pushmark
2615     return '' if class($kid) eq 'NULL';
2616     my $lop;
2617     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
2618     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2619         # This assumes that no other private flags equal 128, and that
2620         # OPs that store things other than flags in their op_private,
2621         # like OP_AELEMFAST, won't be immediate children of a list.
2622         #
2623         # OP_ENTERSUB can break this logic, so check for it.
2624         # I suspect that open and exit can too.
2625
2626         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2627                 or $lop->name eq "undef")
2628             or $lop->name eq "entersub"
2629             or $lop->name eq "exit"
2630             or $lop->name eq "open")
2631         {
2632             $local = ""; # or not
2633             last;
2634         }
2635         if ($lop->name =~ /^pad[ash]v$/) {
2636             if ($lop->private & OPpPAD_STATE) { # state()
2637                 ($local = "", last) if $local =~ /^(?:local|our|my)$/;
2638                 $local = "state";
2639             } else { # my()
2640                 ($local = "", last) if $local =~ /^(?:local|our|state)$/;
2641                 $local = "my";
2642             }
2643         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2644                         && $lop->private & OPpOUR_INTRO
2645                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2646                         && $lop->first->private & OPpOUR_INTRO) { # our()
2647             ($local = "", last) if $local =~ /^(?:my|local|state)$/;
2648             $local = "our";
2649         } elsif ($lop->name ne "undef"
2650                 # specifically avoid the "reverse sort" optimisation,
2651                 # where "reverse" is nullified
2652                 && !($lop->name eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
2653         {
2654             # local()
2655             ($local = "", last) if $local =~ /^(?:my|our|state)$/;
2656             $local = "local";
2657         }
2658     }
2659     $local = "" if $local eq "either"; # no point if it's all undefs
2660     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2661     for (; !null($kid); $kid = $kid->sibling) {
2662         if ($local) {
2663             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2664                 $lop = $kid->first;
2665             } else {
2666                 $lop = $kid;
2667             }
2668             $self->{'avoid_local'}{$$lop}++;
2669             $expr = $self->deparse($kid, 6);
2670             delete $self->{'avoid_local'}{$$lop};
2671         } else {
2672             $expr = $self->deparse($kid, 6);
2673         }
2674         push @exprs, $expr;
2675     }
2676     if ($local) {
2677         return "$local(" . join(", ", @exprs) . ")";
2678     } else {
2679         return $self->maybe_parens( join(", ", @exprs), $cx, 6);
2680     }
2681 }
2682
2683 sub is_ifelse_cont {
2684     my $op = shift;
2685     return ($op->name eq "null" and class($op) eq "UNOP"
2686             and $op->first->name =~ /^(and|cond_expr)$/
2687             and is_scope($op->first->first->sibling));
2688 }
2689
2690 sub pp_cond_expr {
2691     my $self = shift;
2692     my($op, $cx) = @_;
2693     my $cond = $op->first;
2694     my $true = $cond->sibling;
2695     my $false = $true->sibling;
2696     my $cuddle = $self->{'cuddle'};
2697     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
2698             (is_scope($false) || is_ifelse_cont($false))
2699             and $self->{'expand'} < 7) {
2700         $cond = $self->deparse($cond, 8);
2701         $true = $self->deparse($true, 6);
2702         $false = $self->deparse($false, 8);
2703         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2704     }
2705
2706     $cond = $self->deparse($cond, 1);
2707     $true = $self->deparse($true, 0);
2708     my $head = "if ($cond) {\n\t$true\n\b}";
2709     my @elsifs;
2710     while (!null($false) and is_ifelse_cont($false)) {
2711         my $newop = $false->first;
2712         my $newcond = $newop->first;
2713         my $newtrue = $newcond->sibling;
2714         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2715         if ($newcond->name eq "lineseq")
2716         {
2717             # lineseq to ensure correct line numbers in elsif()
2718             # Bug #37302 fixed by change #33710.
2719             $newcond = $newcond->first->sibling;
2720         }
2721         $newcond = $self->deparse($newcond, 1);
2722         $newtrue = $self->deparse($newtrue, 0);
2723         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2724     }
2725     if (!null($false)) {
2726         $false = $cuddle . "else {\n\t" .
2727           $self->deparse($false, 0) . "\n\b}\cK";
2728     } else {
2729         $false = "\cK";
2730     }
2731     return $head . join($cuddle, "", @elsifs) . $false;
2732 }
2733
2734 sub pp_once {
2735     my ($self, $op, $cx) = @_;
2736     my $cond = $op->first;
2737     my $true = $cond->sibling;
2738
2739     return $self->deparse($true, $cx);
2740 }
2741
2742 sub loop_common {
2743     my $self = shift;
2744     my($op, $cx, $init) = @_;
2745     my $enter = $op->first;
2746     my $kid = $enter->sibling;
2747     local(@$self{qw'curstash warnings hints hinthash'})
2748                 = @$self{qw'curstash warnings hints hinthash'};
2749     my $head = "";
2750     my $bare = 0;
2751     my $body;
2752     my $cond = undef;
2753     if ($kid->name eq "lineseq") { # bare or infinite loop
2754         if ($kid->last->name eq "unstack") { # infinite
2755             $head = "while (1) "; # Can't use for(;;) if there's a continue
2756             $cond = "";
2757         } else {
2758             $bare = 1;
2759         }
2760         $body = $kid;
2761     } elsif ($enter->name eq "enteriter") { # foreach
2762         my $ary = $enter->first->sibling; # first was pushmark
2763         my $var = $ary->sibling;
2764         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
2765             # "reverse" was optimised away
2766             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
2767         } elsif ($enter->flags & OPf_STACKED
2768             and not null $ary->first->sibling->sibling)
2769         {
2770             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2771               $self->deparse($ary->first->sibling->sibling, 9);
2772         } else {
2773             $ary = $self->deparse($ary, 1);
2774         }
2775         if (null $var) {
2776             if (($enter->flags & OPf_SPECIAL) && ($] < 5.009)) {
2777                 # thread special var, under 5005threads
2778                 $var = $self->pp_threadsv($enter, 1);
2779             } else { # regular my() variable
2780                 $var = $self->pp_padsv($enter, 1);
2781             }
2782         } elsif ($var->name eq "rv2gv") {
2783             $var = $self->pp_rv2sv($var, 1);
2784             if ($enter->private & OPpOUR_INTRO) {
2785                 # our declarations don't have package names
2786                 $var =~ s/^(.).*::/$1/;
2787                 $var = "our $var";
2788             }
2789         } elsif ($var->name eq "gv") {
2790             $var = "\$" . $self->deparse($var, 1);
2791         }
2792         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2793         if (!is_state $body->first and $body->first->name ne "stub") {
2794             confess unless $var eq '$_';
2795             $body = $body->first;
2796             return $self->deparse($body, 2) . " foreach ($ary)";
2797         }
2798         $head = "foreach $var ($ary) ";
2799     } elsif ($kid->name eq "null") { # while/until
2800         $kid = $kid->first;
2801         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2802         $cond = $self->deparse($kid->first, 1);
2803         $head = "$name ($cond) ";
2804         $body = $kid->first->sibling;
2805     } elsif ($kid->name eq "stub") { # bare and empty
2806         return "{;}"; # {} could be a hashref
2807     }
2808     # If there isn't a continue block, then the next pointer for the loop
2809     # will point to the unstack, which is kid's last child, except
2810     # in a bare loop, when it will point to the leaveloop. When neither of
2811     # these conditions hold, then the second-to-last child is the continue
2812     # block (or the last in a bare loop).
2813     my $cont_start = $enter->nextop;
2814     my $cont;
2815     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
2816         if ($bare) {
2817             $cont = $body->last;
2818         } else {
2819             $cont = $body->first;
2820             while (!null($cont->sibling->sibling)) {
2821                 $cont = $cont->sibling;
2822             }
2823         }
2824         my $state = $body->first;
2825         my $cuddle = $self->{'cuddle'};
2826         my @states;
2827         for (; $$state != $$cont; $state = $state->sibling) {
2828             push @states, $state;
2829         }
2830         $body = $self->lineseq(undef, @states);
2831         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2832             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2833             $cont = "\cK";
2834         } else {
2835             $cont = $cuddle . "continue {\n\t" .
2836               $self->deparse($cont, 0) . "\n\b}\cK";
2837         }
2838     } else {
2839         return "" if !defined $body;
2840         if (length $init) {
2841             $head = "for ($init; $cond;) ";
2842         }
2843         $cont = "\cK";
2844         $body = $self->deparse($body, 0);
2845     }
2846     $body =~ s/;?$/;\n/;
2847
2848     return $head . "{\n\t" . $body . "\b}" . $cont;
2849 }
2850
2851 sub pp_leaveloop { shift->loop_common(@_, "") }
2852
2853 sub for_loop {
2854     my $self = shift;
2855     my($op, $cx) = @_;
2856     my $init = $self->deparse($op, 1);
2857     my $s = $op->sibling;
2858     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
2859     return $self->loop_common($ll, $cx, $init);
2860 }
2861
2862 sub pp_leavetry {
2863     my $self = shift;
2864     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2865 }
2866
2867 BEGIN { for (qw[ const stringify rv2sv list glob ]) {
2868     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
2869 }}
2870
2871 sub pp_null {
2872     my $self = shift;
2873     my($op, $cx) = @_;
2874     if (class($op) eq "OP") {
2875         # old value is lost
2876         return $self->{'ex_const'} if $op->targ == OP_CONST;
2877     } elsif ($op->first->name eq "pushmark") {
2878         return $self->pp_list($op, $cx);
2879     } elsif ($op->first->name eq "enter") {
2880         return $self->pp_leave($op, $cx);
2881     } elsif ($op->first->name eq "leave") {
2882         return $self->pp_leave($op->first, $cx);
2883     } elsif ($op->first->name eq "scope") {
2884         return $self->pp_scope($op->first, $cx);
2885     } elsif ($op->targ == OP_STRINGIFY) {
2886         return $self->dquote($op, $cx);
2887     } elsif ($op->targ == OP_GLOB) {
2888         return $self->pp_glob(
2889                  $op->first    # entersub
2890                     ->first    # ex-list
2891                     ->first    # pushmark
2892                     ->sibling, # glob
2893                  $cx
2894                );
2895     } elsif (!null($op->first->sibling) and
2896              $op->first->sibling->name eq "readline" and
2897              $op->first->sibling->flags & OPf_STACKED) {
2898         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2899                                    . $self->deparse($op->first->sibling, 7),
2900                                    $cx, 7);
2901     } elsif (!null($op->first->sibling) and
2902              $op->first->sibling->name eq "trans" and
2903              $op->first->sibling->flags & OPf_STACKED) {
2904         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2905                                    . $self->deparse($op->first->sibling, 20),
2906                                    $cx, 20);
2907     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
2908         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2909     } elsif (!null($op->first->sibling) and
2910              $op->first->sibling->name eq "null" and
2911              class($op->first->sibling) eq "UNOP" and
2912              $op->first->sibling->first->flags & OPf_STACKED and
2913              $op->first->sibling->first->name eq "rcatline") {
2914         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2915                                    . $self->deparse($op->first->sibling, 18),
2916                                    $cx, 18);
2917     } else {
2918         return $self->deparse($op->first, $cx);
2919     }
2920 }
2921
2922 sub padname {
2923     my $self = shift;
2924     my $targ = shift;
2925     return $self->padname_sv($targ)->PVX;
2926 }
2927
2928 sub padany {
2929     my $self = shift;
2930     my $op = shift;
2931     return substr($self->padname($op->targ), 1); # skip $/@/%
2932 }
2933
2934 sub pp_padsv {
2935     my $self = shift;
2936     my($op, $cx) = @_;
2937     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2938 }
2939
2940 sub pp_padav { pp_padsv(@_) }
2941 sub pp_padhv { pp_padsv(@_) }
2942
2943 my @threadsv_names = B::threadsv_names;
2944 sub pp_threadsv {
2945     my $self = shift;
2946     my($op, $cx) = @_;
2947     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2948 }
2949
2950 sub gv_or_padgv {
2951     my $self = shift;
2952     my $op = shift;
2953     if (class($op) eq "PADOP") {
2954         return $self->padval($op->padix);
2955     } else { # class($op) eq "SVOP"
2956         return $op->gv;
2957     }
2958 }
2959
2960 sub pp_gvsv {
2961     my $self = shift;
2962     my($op, $cx) = @_;
2963     my $gv = $self->gv_or_padgv($op);
2964     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2965                                  $self->gv_name($gv), $cx));
2966 }
2967
2968 sub pp_gv {
2969     my $self = shift;
2970     my($op, $cx) = @_;
2971     my $gv = $self->gv_or_padgv($op);
2972     return $self->gv_name($gv);
2973 }
2974
2975 sub pp_aelemfast_lex {
2976     my $self = shift;
2977     my($op, $cx) = @_;
2978     my $name = $self->padname($op->targ);
2979     $name =~ s/^@/\$/;
2980     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
2981 }
2982
2983 sub pp_aelemfast {
2984     my $self = shift;
2985     my($op, $cx) = @_;
2986     # optimised PADAV, pre 5.15
2987     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
2988
2989     my $gv = $self->gv_or_padgv($op);
2990     my $name = $self->gv_name($gv);
2991     $name = $self->{'curstash'}."::$name"
2992         if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2993     $name = '$' . $name;
2994     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
2995 }
2996
2997 sub rv2x {
2998     my $self = shift;
2999     my($op, $cx, $type) = @_;
3000
3001     if (class($op) eq 'NULL' || !$op->can("first")) {
3002         carp("Unexpected op in pp_rv2x");
3003         return 'XXX';
3004     }
3005     my $kid = $op->first;
3006     if ($kid->name eq "gv") {
3007         return $self->stash_variable($type, $self->deparse($kid, 0), $cx);
3008     } elsif (is_scalar $kid) {
3009         my $str = $self->deparse($kid, 0);
3010         if ($str =~ /^\$([^\w\d])\z/) {
3011             # "$$+" isn't a legal way to write the scalar dereference
3012             # of $+, since the lexer can't tell you aren't trying to
3013             # do something like "$$ + 1" to get one more than your
3014             # PID. Either "${$+}" or "$${+}" are workable
3015             # disambiguations, but if the programmer did the former,
3016             # they'd be in the "else" clause below rather than here.
3017             # It's not clear if this should somehow be unified with
3018             # the code in dq and re_dq that also adds lexer
3019             # disambiguation braces.
3020             $str = '$' . "{$1}"; #'
3021         }
3022         return $type . $str;
3023     } else {
3024         return $type . "{" . $self->deparse($kid, 0) . "}";
3025     }
3026 }
3027
3028 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
3029 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
3030 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
3031
3032 # skip rv2av
3033 sub pp_av2arylen {
3034     my $self = shift;
3035     my($op, $cx) = @_;
3036     if ($op->first->name eq "padav") {
3037         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
3038     } else {
3039         return $self->maybe_local($op, $cx,
3040                                   $self->rv2x($op->first, $cx, '$#'));
3041     }
3042 }
3043
3044 # skip down to the old, ex-rv2cv
3045 sub pp_rv2cv {
3046     my ($self, $op, $cx) = @_;
3047     if (!null($op->first) && $op->first->name eq 'null' &&
3048         $op->first->targ eq OP_LIST)
3049     {
3050         return $self->rv2x($op->first->first->sibling, $cx, "&")
3051     }
3052     else {
3053         return $self->rv2x($op, $cx, "")
3054     }
3055 }
3056
3057 sub list_const {
3058     my $self = shift;
3059     my($cx, @list) = @_;
3060     my @a = map $self->const($_, 6), @list;
3061     if (@a == 0) {
3062         return "()";
3063     } elsif (@a == 1) {
3064         return $a[0];
3065     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
3066         # collapse (-1,0,1,2) into (-1..2)
3067         my ($s, $e) = @a[0,-1];
3068         my $i = $s;
3069         return $self->maybe_parens("$s..$e", $cx, 9)
3070           unless grep $i++ != $_, @a;
3071     }
3072     return $self->maybe_parens(join(", ", @a), $cx, 6);
3073 }
3074
3075 sub pp_rv2av {
3076     my $self = shift;
3077     my($op, $cx) = @_;
3078     my $kid = $op->first;
3079     if ($kid->name eq "const") { # constant list
3080         my $av = $self->const_sv($kid);
3081         return $self->list_const($cx, $av->ARRAY);
3082     } else {
3083         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
3084     }
3085  }
3086
3087 sub is_subscriptable {
3088     my $op = shift;
3089     if ($op->name =~ /^[ahg]elem/) {
3090         return 1;
3091     } elsif ($op->name eq "entersub") {
3092         my $kid = $op->first;
3093         return 0 unless null $kid->sibling;
3094         $kid = $kid->first;
3095         $kid = $kid->sibling until null $kid->sibling;
3096         return 0 if is_scope($kid);
3097         $kid = $kid->first;
3098         return 0 if $kid->name eq "gv";
3099         return 0 if is_scalar($kid);
3100         return is_subscriptable($kid);
3101     } else {
3102         return 0;
3103     }
3104 }
3105
3106 sub elem_or_slice_array_name
3107 {
3108     my $self = shift;
3109     my ($array, $left, $padname, $allow_arrow) = @_;
3110
3111     if ($array->name eq $padname) {
3112         return $self->padany($array);
3113     } elsif (is_scope($array)) { # ${expr}[0]
3114         return "{" . $self->deparse($array, 0) . "}";
3115     } elsif ($array->name eq "gv") {
3116         $array = $self->gv_name($self->gv_or_padgv($array));
3117         if ($array !~ /::/) {
3118             my $prefix = ($left eq '[' ? '@' : '%');
3119             $array = $self->{curstash}.'::'.$array
3120                 if $self->lex_in_scope($prefix . $array);
3121         }
3122         return $array;
3123     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3124         return $self->deparse($array, 24);
3125     } else {
3126         return undef;
3127     }
3128 }
3129
3130 sub elem_or_slice_single_index
3131 {
3132     my $self = shift;
3133     my ($idx) = @_;
3134
3135     $idx = $self->deparse($idx, 1);
3136
3137     # Outer parens in an array index will confuse perl
3138     # if we're interpolating in a regular expression, i.e.
3139     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3140     #
3141     # If $self->{parens}, then an initial '(' will
3142     # definitely be paired with a final ')'. If
3143     # !$self->{parens}, the misleading parens won't
3144     # have been added in the first place.
3145     #
3146     # [You might think that we could get "(...)...(...)"
3147     # where the initial and final parens do not match
3148     # each other. But we can't, because the above would
3149     # only happen if there's an infix binop between the
3150     # two pairs of parens, and *that* means that the whole
3151     # expression would be parenthesized as well.]
3152     #
3153     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3154
3155     # Hash-element braces will autoquote a bareword inside themselves.
3156     # We need to make sure that C<$hash{warn()}> doesn't come out as
3157     # C<$hash{warn}>, which has a quite different meaning. Currently
3158     # B::Deparse will always quote strings, even if the string was a
3159     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3160     # for constant strings.) So we can cheat slightly here - if we see
3161     # a bareword, we know that it is supposed to be a function call.
3162     #
3163     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3164
3165     return $idx;
3166 }
3167
3168 sub elem {
3169     my $self = shift;
3170     my ($op, $cx, $left, $right, $padname) = @_;
3171     my($array, $idx) = ($op->first, $op->first->sibling);
3172
3173     $idx = $self->elem_or_slice_single_index($idx);
3174
3175     unless ($array->name eq $padname) { # Maybe this has been fixed
3176         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3177     }
3178     if (my $array_name=$self->elem_or_slice_array_name
3179             ($array, $left, $padname, 1)) {
3180         return "\$" . $array_name . $left . $idx . $right;
3181     } else {
3182         # $x[20][3]{hi} or expr->[20]
3183         my $arrow = is_subscriptable($array) ? "" : "->";
3184         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3185     }
3186
3187 }
3188
3189 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3190 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3191
3192 sub pp_gelem {
3193     my $self = shift;
3194     my($op, $cx) = @_;
3195     my($glob, $part) = ($op->first, $op->last);
3196     $glob = $glob->first; # skip rv2gv
3197     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3198     my $scope = is_scope($glob);
3199     $glob = $self->deparse($glob, 0);
3200     $part = $self->deparse($part, 1);
3201     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3202 }
3203
3204 sub slice {
3205     my $self = shift;
3206     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3207     my $last;
3208     my(@elems, $kid, $array, $list);
3209     if (class($op) eq "LISTOP") {
3210         $last = $op->last;
3211     } else { # ex-hslice inside delete()
3212         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3213         $last = $kid;
3214     }
3215     $array = $last;
3216     $array = $array->first
3217         if $array->name eq $regname or $array->name eq "null";
3218     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3219     $kid = $op->first->sibling; # skip pushmark
3220     if ($kid->name eq "list") {
3221         $kid = $kid->first->sibling; # skip list, pushmark
3222         for (; !null $kid; $kid = $kid->sibling) {
3223             push @elems, $self->deparse($kid, 6);
3224         }
3225         $list = join(", ", @elems);
3226     } else {
3227         $list = $self->elem_or_slice_single_index($kid);
3228     }
3229     return "\@" . $array . $left . $list . $right;
3230 }
3231
3232 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3233 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3234
3235 sub pp_lslice {
3236     my $self = shift;
3237     my($op, $cx) = @_;
3238     my $idx = $op->first;
3239     my $list = $op->last;
3240     my(@elems, $kid);
3241     $list = $self->deparse($list, 1);
3242     $idx = $self->deparse($idx, 1);
3243     return "($list)" . "[$idx]";
3244 }
3245
3246 sub want_scalar {
3247     my $op = shift;
3248     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3249 }
3250
3251 sub want_list {
3252     my $op = shift;
3253     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3254 }
3255
3256 sub _method {
3257     my $self = shift;
3258     my($op, $cx) = @_;
3259     my $kid = $op->first->sibling; # skip pushmark
3260     my($meth, $obj, @exprs);
3261     if ($kid->name eq "list" and want_list $kid) {
3262         # When an indirect object isn't a bareword but the args are in
3263         # parens, the parens aren't part of the method syntax (the LLAFR
3264         # doesn't apply), but they make a list with OPf_PARENS set that
3265         # doesn't get flattened by the append_elem that adds the method,
3266         # making a (object, arg1, arg2, ...) list where the object
3267         # usually is. This can be distinguished from
3268         # '($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3269         # object) because in the later the list is in scalar context
3270         # as the left side of -> always is, while in the former
3271         # the list is in list context as method arguments always are.
3272         # (Good thing there aren't method prototypes!)
3273         $meth = $kid->sibling;
3274         $kid = $kid->first->sibling; # skip pushmark
3275         $obj = $kid;
3276         $kid = $kid->sibling;
3277         for (; not null $kid; $kid = $kid->sibling) {
3278             push @exprs, $kid;
3279         }
3280     } else {
3281         $obj = $kid;
3282         $kid = $kid->sibling;
3283         for (; !null ($kid->sibling) && $kid->name!~/^method(?:_named)?\z/;
3284               $kid = $kid->sibling) {
3285             push @exprs, $kid
3286         }
3287         $meth = $kid;
3288     }
3289
3290     if ($meth->name eq "method_named") {
3291         $meth = $self->const_sv($meth)->PV;
3292     } else {
3293         $meth = $meth->first;
3294         if ($meth->name eq "const") {
3295             # As of 5.005_58, this case is probably obsoleted by the
3296             # method_named case above
3297             $meth = $self->const_sv($meth)->PV; # needs to be bare
3298         }
3299     }
3300
3301     return { method => $meth, variable_method => ref($meth),
3302              object => $obj, args => \@exprs  };
3303 }
3304
3305 # compat function only
3306 sub method {
3307     my $self = shift;
3308     my $info = $self->_method(@_);
3309     return $self->e_method( $self->_method(@_) );
3310 }
3311
3312 sub e_method {
3313     my ($self, $info) = @_;
3314     my $obj = $self->deparse($info->{object}, 24);
3315
3316     my $meth = $info->{method};
3317     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3318     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3319     my $kid = $obj . "->" . $meth;
3320     if (length $args) {
3321         return $kid . "(" . $args . ")"; # parens mandatory
3322     } else {
3323         return $kid;
3324     }
3325 }
3326
3327 # returns "&" if the prototype doesn't match the args,
3328 # or ("", $args_after_prototype_demunging) if it does.
3329 sub check_proto {
3330     my $self = shift;
3331     return "&" if $self->{'noproto'};
3332     my($proto, @args) = @_;
3333     my($arg, $real);
3334     my $doneok = 0;
3335     my @reals;
3336     # An unbackslashed @ or % gobbles up the rest of the args
3337     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3338     while ($proto) {
3339         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)//;
3340         my $chr = $1;
3341         if ($chr eq "") {
3342             return "&" if @args;
3343         } elsif ($chr eq ";") {
3344             $doneok = 1;
3345         } elsif ($chr eq "@" or $chr eq "%") {
3346             push @reals, map($self->deparse($_, 6), @args);
3347             @args = ();
3348         } else {
3349             $arg = shift @args;
3350             last unless $arg;
3351             if ($chr eq "\$" || $chr eq "_") {
3352                 if (want_scalar $arg) {
3353                     push @reals, $self->deparse($arg, 6);
3354                 } else {
3355                     return "&";
3356                 }
3357             } elsif ($chr eq "&") {
3358                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3359                     push @reals, $self->deparse($arg, 6);
3360                 } else {
3361                     return "&";
3362                 }
3363             } elsif ($chr eq "*") {
3364                 if ($arg->name =~ /^s?refgen$/
3365                     and $arg->first->first->name eq "rv2gv")
3366                   {
3367                       $real = $arg->first->first; # skip refgen, null
3368                       if ($real->first->name eq "gv") {
3369                           push @reals, $self->deparse($real, 6);
3370                       } else {
3371                           push @reals, $self->deparse($real->first, 6);
3372                       }
3373                   } else {
3374                       return "&";
3375                   }
3376             } elsif (substr($chr, 0, 1) eq "\\") {
3377                 $chr =~ tr/\\[]//d;
3378                 if ($arg->name =~ /^s?refgen$/ and
3379                     !null($real = $arg->first) and
3380                     ($chr =~ /\$/ && is_scalar($real->first)
3381                      or ($chr =~ /@/
3382                          && class($real->first->sibling) ne 'NULL'
3383                          && $real->first->sibling->name
3384                          =~ /^(rv2|pad)av$/)
3385                      or ($chr =~ /%/
3386                          && class($real->first->sibling) ne 'NULL'
3387                          && $real->first->sibling->name
3388                          =~ /^(rv2|pad)hv$/)
3389                      #or ($chr =~ /&/ # This doesn't work
3390                      #   && $real->first->name eq "rv2cv")
3391                      or ($chr =~ /\*/
3392                          && $real->first->name eq "rv2gv")))
3393                   {
3394                       push @reals, $self->deparse($real, 6);
3395                   } else {
3396                       return "&";
3397                   }
3398             }
3399        }
3400     }
3401     return "&" if $proto and !$doneok; # too few args and no ';'
3402     return "&" if @args;               # too many args
3403     return ("", join ", ", @reals);
3404 }
3405
3406 sub pp_entersub {
3407     my $self = shift;
3408     my($op, $cx) = @_;
3409     return $self->e_method($self->_method($op, $cx))
3410         unless null $op->first->sibling;
3411     my $prefix = "";
3412     my $amper = "";
3413     my($kid, @exprs);
3414     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3415         $prefix = "do ";
3416     } elsif ($op->private & OPpENTERSUB_AMPER) {
3417         $amper = "&";
3418     }
3419     $kid = $op->first;
3420     $kid = $kid->first->sibling; # skip ex-list, pushmark
3421     for (; not null $kid->sibling; $kid = $kid->sibling) {
3422         push @exprs, $kid;
3423     }
3424     my $simple = 0;
3425     my $proto = undef;
3426     if (is_scope($kid)) {
3427         $amper = "&";
3428         $kid = "{" . $self->deparse($kid, 0) . "}";
3429     } elsif ($kid->first->name eq "gv") {
3430         my $gv = $self->gv_or_padgv($kid->first);
3431         if (class($gv->CV) ne "SPECIAL") {
3432             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3433         }
3434         $simple = 1; # only calls of named functions can be prototyped
3435         $kid = $self->deparse($kid, 24);
3436         if (!$amper) {
3437             if ($kid eq 'main::') {
3438                 $kid = '::';
3439             } elsif ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3440                 $kid = single_delim("q", "'", $kid) . '->';
3441             }
3442         }
3443     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3444         $amper = "&";
3445         $kid = $self->deparse($kid, 24);
3446     } else {
3447         $prefix = "";
3448         my $arrow = is_subscriptable($kid->first) ? "" : "->";
3449         $kid = $self->deparse($kid, 24) . $arrow;
3450     }
3451
3452     # Doesn't matter how many prototypes there are, if
3453     # they haven't happened yet!
3454     my $declared;
3455     {
3456         no strict 'refs';
3457         no warnings 'uninitialized';
3458         $declared = exists $self->{'subs_declared'}{$kid}
3459             || (
3460                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3461                  && !exists
3462                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3463                  && defined prototype $self->{'curstash'}."::".$kid
3464                );
3465         if (!$declared && defined($proto)) {
3466             # Avoid "too early to check prototype" warning
3467             ($amper, $proto) = ('&');
3468         }
3469     }
3470
3471     my $args;
3472     if ($declared and defined $proto and not $amper) {
3473         ($amper, $args) = $self->check_proto($proto, @exprs);
3474         if ($amper eq "&") {
3475             $args = join(", ", map($self->deparse($_, 6), @exprs));
3476         }
3477     } else {
3478         $args = join(", ", map($self->deparse($_, 6), @exprs));
3479     }
3480     if ($prefix or $amper) {
3481         if ($op->flags & OPf_STACKED) {
3482             return $prefix . $amper . $kid . "(" . $args . ")";
3483         } else {
3484             return $prefix . $amper. $kid;
3485         }
3486     } else {
3487         # It's a syntax error to call CORE::GLOBAL::foo with a prefix,
3488         # so it must have been translated from a keyword call. Translate
3489         # it back.
3490         $kid =~ s/^CORE::GLOBAL:://;
3491
3492         my $dproto = defined($proto) ? $proto : "undefined";
3493         if (!$declared) {
3494             return "$kid(" . $args . ")";
3495         } elsif ($dproto eq "") {
3496             return $kid;
3497         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3498             # is_scalar is an excessively conservative test here:
3499             # really, we should be comparing to the precedence of the
3500             # top operator of $exprs[0] (ala unop()), but that would
3501             # take some major code restructuring to do right.
3502             return $self->maybe_parens_func($kid, $args, $cx, 16);
3503         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3504             return $self->maybe_parens_func($kid, $args, $cx, 5);
3505         } else {
3506             return "$kid(" . $args . ")";
3507         }
3508     }
3509 }
3510
3511 sub pp_enterwrite { unop(@_, "write") }
3512
3513 # escape things that cause interpolation in double quotes,
3514 # but not character escapes
3515 sub uninterp {
3516     my($str) = @_;
3517     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3518     return $str;
3519 }
3520
3521 {
3522 my $bal;
3523 BEGIN {
3524     use re "eval";
3525     # Matches any string which is balanced with respect to {braces}
3526     $bal = qr(
3527       (?:
3528         [^\\{}]
3529       | \\\\
3530       | \\[{}]
3531       | \{(??{$bal})\}
3532       )*
3533     )x;
3534 }
3535
3536 # the same, but treat $|, $), $( and $ at the end of the string differently
3537 sub re_uninterp {
3538     my($str) = @_;
3539
3540     $str =~ s/
3541           ( ^|\G                  # $1
3542           | [^\\]
3543           )
3544
3545           (                       # $2
3546             (?:\\\\)*
3547           )
3548
3549           (                       # $3
3550             (\(\?\??\{$bal\}\))   # $4
3551           | [\$\@]
3552             (?!\||\)|\(|$)
3553           | \\[uUlLQE]
3554           )
3555
3556         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3557
3558     return $str;
3559 }
3560
3561 # This is for regular expressions with the /x modifier
3562 # We have to leave comments unmangled.
3563 sub re_uninterp_extended {
3564     my($str) = @_;
3565
3566     $str =~ s/
3567           ( ^|\G                  # $1
3568           | [^\\]
3569           )
3570
3571           (                       # $2
3572             (?:\\\\)*
3573           )
3574
3575           (                       # $3
3576             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3577             | \#[^\n]*            #     (skip over comments)
3578             )
3579           | [\$\@]
3580             (?!\||\)|\(|$|\s)
3581           | \\[uUlLQE]
3582           )
3583
3584         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3585
3586     return $str;
3587 }
3588 }
3589
3590 my %unctrl = # portable to to EBCDIC
3591     (
3592      "\c@" => '\c@',    # unused
3593      "\cA" => '\cA',
3594      "\cB" => '\cB',
3595      "\cC" => '\cC',
3596      "\cD" => '\cD',
3597      "\cE" => '\cE',
3598      "\cF" => '\cF',
3599      "\cG" => '\cG',
3600      "\cH" => '\cH',
3601      "\cI" => '\cI',
3602      "\cJ" => '\cJ',
3603      "\cK" => '\cK',
3604      "\cL" => '\cL',
3605      "\cM" => '\cM',
3606      "\cN" => '\cN',
3607      "\cO" => '\cO',
3608      "\cP" => '\cP',
3609      "\cQ" => '\cQ',
3610      "\cR" => '\cR',
3611      "\cS" => '\cS',
3612      "\cT" => '\cT',
3613      "\cU" => '\cU',
3614      "\cV" => '\cV',
3615      "\cW" => '\cW',
3616      "\cX" => '\cX',
3617      "\cY" => '\cY',
3618      "\cZ" => '\cZ',
3619      "\c[" => '\c[',    # unused
3620      "\c\\" => '\c\\',  # unused
3621      "\c]" => '\c]',    # unused
3622      "\c_" => '\c_',    # unused
3623     );
3624
3625 # character escapes, but not delimiters that might need to be escaped
3626 sub escape_str { # ASCII, UTF8
3627     my($str) = @_;
3628     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3629     $str =~ s/\a/\\a/g;
3630 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3631     $str =~ s/\t/\\t/g;
3632     $str =~ s/\n/\\n/g;
3633     $str =~ s/\e/\\e/g;
3634     $str =~ s/\f/\\f/g;
3635     $str =~ s/\r/\\r/g;
3636     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3637     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3638     return $str;
3639 }
3640
3641 # For regexes with the /x modifier.
3642 # Leave whitespace unmangled.
3643 sub escape_extended_re {
3644     my($str) = @_;
3645     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3646     $str =~ s/([[:^print:]])/
3647         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3648     $str =~ s/\n/\n\f/g;
3649     return $str;
3650 }
3651
3652 # Don't do this for regexen
3653 sub unback {
3654     my($str) = @_;
3655     $str =~ s/\\/\\\\/g;
3656     return $str;
3657 }
3658
3659 # Remove backslashes which precede literal control characters,
3660 # to avoid creating ambiguity when we escape the latter.
3661 sub re_unback {
3662     my($str) = @_;
3663
3664     # the insane complexity here is due to the behaviour of "\c\"
3665     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3666     return $str;
3667 }
3668
3669 sub balanced_delim {
3670     my($str) = @_;
3671     my @str = split //, $str;
3672     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
3673     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3674         ($open, $close) = @$ar;
3675         $fail = 0; $cnt = 0; $last_bs = 0;
3676         for $c (@str) {
3677             if ($c eq $open) {
3678                 $fail = 1 if $last_bs;
3679                 $cnt++;
3680             } elsif ($c eq $close) {
3681                 $fail = 1 if $last_bs;
3682                 $cnt--;
3683                 if ($cnt < 0) {
3684                     # qq()() isn't ")("
3685                     $fail = 1;
3686                     last;
3687                 }
3688             }
3689             $last_bs = $c eq '\\';
3690         }
3691         $fail = 1 if $cnt != 0;
3692         return ($open, "$open$str$close") if not $fail;
3693     }
3694     return ("", $str);
3695 }
3696
3697 sub single_delim {
3698     my($q, $default, $str) = @_;
3699     return "$default$str$default" if $default and index($str, $default) == -1;
3700     if ($q ne 'qr') {
3701         (my $succeed, $str) = balanced_delim($str);
3702         return "$q$str" if $succeed;
3703     }
3704     for my $delim ('/', '"', '#') {
3705         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3706     }
3707     if ($default) {
3708         $str =~ s/$default/\\$default/g;
3709         return "$default$str$default";
3710     } else {
3711         $str =~ s[/][\\/]g;
3712         return "$q/$str/";
3713     }
3714 }
3715
3716 my $max_prec;
3717 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
3718
3719 # Split a floating point number into an integer mantissa and a binary
3720 # exponent. Assumes you've already made sure the number isn't zero or
3721 # some weird infinity or NaN.
3722 sub split_float {
3723     my($f) = @_;
3724     my $exponent = 0;
3725     if ($f == int($f)) {
3726         while ($f % 2 == 0) {
3727             $f /= 2;
3728             $exponent++;
3729         }
3730     } else {
3731         while ($f != int($f)) {
3732             $f *= 2;
3733             $exponent--;
3734         }
3735     }
3736     my $mantissa = sprintf("%.0f", $f);
3737     return ($mantissa, $exponent);
3738 }
3739
3740 sub const {
3741     my $self = shift;
3742     my($sv, $cx) = @_;
3743     if ($self->{'use_dumper'}) {
3744         return $self->const_dumper($sv, $cx);
3745     }
3746     if (class($sv) eq "SPECIAL") {
3747         # sv_undef, sv_yes, sv_no
3748         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
3749     }
3750     if (class($sv) eq "NULL") {
3751        return 'undef';
3752     }
3753     # convert a version object into the "v1.2.3" string in its V magic
3754     if ($sv->FLAGS & SVs_RMG) {
3755         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3756             return $mg->PTR if $mg->TYPE eq 'V';
3757         }
3758     }
3759
3760     if ($sv->FLAGS & SVf_IOK) {
3761         my $str = $sv->int_value;
3762         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
3763         return $str;
3764     } elsif ($sv->FLAGS & SVf_NOK) {
3765         my $nv = $sv->NV;
3766         if ($nv == 0) {
3767             if (pack("F", $nv) eq pack("F", 0)) {
3768                 # positive zero
3769                 return "0";
3770             } else {
3771                 # negative zero
3772                 return $self->maybe_parens("-.0", $cx, 21);
3773             }
3774         } elsif (1/$nv == 0) {
3775             if ($nv > 0) {
3776                 # positive infinity
3777                 return $self->maybe_parens("9**9**9", $cx, 22);
3778             } else {
3779                 # negative infinity
3780                 return $self->maybe_parens("-9**9**9", $cx, 21);
3781             }
3782         } elsif ($nv != $nv) {
3783             # NaN
3784             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
3785                 # the normal kind
3786                 return "sin(9**9**9)";
3787             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
3788                 # the inverted kind
3789                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
3790             } else {
3791                 # some other kind
3792                 my $hex = unpack("h*", pack("F", $nv));
3793                 return qq'unpack("F", pack("h*", "$hex"))';
3794             }
3795         }
3796         # first, try the default stringification
3797         my $str = "$nv";
3798         if ($str != $nv) {
3799             # failing that, try using more precision
3800             $str = sprintf("%.${max_prec}g", $nv);
3801 #           if (pack("F", $str) ne pack("F", $nv)) {
3802             if ($str != $nv) {
3803                 # not representable in decimal with whatever sprintf()
3804                 # and atof() Perl is using here.
3805                 my($mant, $exp) = split_float($nv);
3806                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
3807             }
3808         }
3809         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
3810         return $str;
3811     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3812         my $ref = $sv->RV;
3813         if (class($ref) eq "AV") {
3814             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
3815         } elsif (class($ref) eq "HV") {
3816             my %hash = $ref->ARRAY;
3817             my @elts;
3818             for my $k (sort keys %hash) {
3819                 push @elts, "$k => " . $self->const($hash{$k}, 6);
3820             }
3821             return "{" . join(", ", @elts) . "}";
3822         } elsif (class($ref) eq "CV") {
3823             BEGIN {
3824 # Commented out until after 5.15.6
3825 #               if ($] > 5.0150051) {
3826                     require overloading;
3827                     unimport overloading;
3828 #               }
3829             }
3830             # Remove the 1|| after 5.15.6
3831             if ((1||$] > 5.0150051) && $self->{curcv} &&
3832                  $self->{curcv}->object_2svref == $ref->object_2svref) {
3833                 return $self->keyword("__SUB__");
3834             }
3835             return "sub " . $self->deparse_sub($ref);
3836         }
3837         if ($ref->FLAGS & SVs_SMG) {
3838             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3839                 if ($mg->TYPE eq 'r') {
3840                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
3841                     return single_delim("qr", "", $re);
3842                 }
3843             }
3844         }
3845
3846         return $self->maybe_parens("\\" . $self->const($ref, 20), $cx, 20);
3847     } elsif ($sv->FLAGS & SVf_POK) {
3848         my $str = $sv->PV;
3849         if ($str =~ /[[:^print:]]/) {
3850             return single_delim("qq", '"', uninterp escape_str unback $str);
3851         } else {
3852             return single_delim("q", "'", unback $str);
3853         }
3854     } else {
3855         return "undef";
3856     }
3857 }
3858
3859 sub const_dumper {
3860     my $self = shift;
3861     my($sv, $cx) = @_;
3862     my $ref = $sv->object_2svref();
3863     my $dumper = Data::Dumper->new([$$ref], ['$v']);
3864     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
3865     my $str = $dumper->Dump();
3866     if ($str =~ /^\$v/) {
3867         return '${my ' . $str . ' \$v}';
3868     } else {
3869         return $str;
3870     }
3871 }
3872
3873 sub const_sv {
3874     my $self = shift;
3875     my $op = shift;
3876     my $sv = $op->sv;
3877     # the constant could be in the pad (under useithreads)
3878     $sv = $self->padval($op->targ) unless $$sv;
3879     return $sv;
3880 }
3881
3882 sub pp_const {
3883     my $self = shift;
3884     my($op, $cx) = @_;
3885     if ($op->private & OPpCONST_ARYBASE) {
3886         return '$[';
3887     }
3888 #    if ($op->private & OPpCONST_BARE) { # trouble with '=>' autoquoting
3889 #       return $self->const_sv($op)->PV;
3890 #    }
3891     my $sv = $self->const_sv($op);
3892     return $self->const($sv, $cx);
3893 }
3894
3895 sub dq {
3896     my $self = shift;
3897     my $op = shift;
3898     my $type = $op->name;
3899     if ($type eq "const") {
3900         return '$[' if $op->private & OPpCONST_ARYBASE;
3901         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3902     } elsif ($type eq "concat") {
3903         my $first = $self->dq($op->first);
3904         my $last  = $self->dq($op->last);
3905
3906         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
3907         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3908             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3909             || ($last =~ /^[:'{\[\w_]/ && #'
3910                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3911
3912         return $first . $last;
3913     } elsif ($type eq "uc") {
3914         return '\U' . $self->dq($op->first->sibling) . '\E';
3915     } elsif ($type eq "lc") {
3916         return '\L' . $self->dq($op->first->sibling) . '\E';
3917     } elsif ($type eq "ucfirst") {
3918         return '\u' . $self->dq($op->first->sibling);
3919     } elsif ($type eq "lcfirst") {
3920         return '\l' . $self->dq($op->first->sibling);
3921     } elsif ($type eq "quotemeta") {
3922         return '\Q' . $self->dq($op->first->sibling) . '\E';
3923     } elsif ($type eq "join") {
3924         return $self->deparse($op->last, 26); # was join($", @ary)
3925     } else {
3926         return $self->deparse($op, 26);
3927     }
3928 }
3929
3930 sub pp_backtick {
3931     my $self = shift;
3932     my($op, $cx) = @_;
3933     # skip pushmark if it exists (readpipe() vs ``)
3934     my $child = $op->first->sibling->isa('B::NULL')
3935         ? $op->first : $op->first->sibling;
3936     if ($self->pure_string($child)) {
3937         return single_delim("qx", '`', $self->dq($child, 1));
3938     }
3939     unop($self, @_, "readpipe");
3940 }
3941
3942 sub dquote {
3943     my $self = shift;
3944     my($op, $cx) = @_;
3945     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3946     return $self->deparse($kid, $cx) if $self->{'unquote'};
3947     $self->maybe_targmy($kid, $cx,
3948                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3949 }
3950
3951 # OP_STRINGIFY is a listop, but it only ever has one arg
3952 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3953
3954 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3955 # note that tr(from)/to/ is OK, but not tr/from/(to)
3956 sub double_delim {
3957     my($from, $to) = @_;
3958     my($succeed, $delim);
3959     if ($from !~ m[/] and $to !~ m[/]) {
3960         return "/$from/$to/";
3961     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3962         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3963             return "$from$to";
3964         } else {
3965             for $delim ('/', '"', '#') { # note no "'" -- s''' is special
3966                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3967             }
3968             $to =~ s[/][\\/]g;
3969             return "$from/$to/";
3970         }
3971     } else {
3972         for $delim ('/', '"', '#') { # note no '
3973             return "$delim$from$delim$to$delim"
3974                 if index($to . $from, $delim) == -1;
3975         }
3976         $from =~ s[/][\\/]g;
3977         $to =~ s[/][\\/]g;
3978         return "/$from/$to/";
3979     }
3980 }
3981
3982 # Only used by tr///, so backslashes hyphens
3983 sub pchr { # ASCII
3984     my($n) = @_;
3985     if ($n == ord '\\') {
3986         return '\\\\';
3987     } elsif ($n == ord "-") {
3988         return "\\-";
3989     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3990         return chr($n);
3991     } elsif ($n == ord "\a") {
3992         return '\\a';
3993     } elsif ($n == ord "\b") {
3994         return '\\b';
3995     } elsif ($n == ord "\t") {
3996         return '\\t';
3997     } elsif ($n == ord "\n") {
3998         return '\\n';
3999     } elsif ($n == ord "\e") {
4000         return '\\e';
4001     } elsif ($n == ord "\f") {
4002         return '\\f';
4003     } elsif ($n == ord "\r") {
4004         return '\\r';
4005     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
4006         return '\\c' . chr(ord("@") + $n);
4007     } else {
4008 #       return '\x' . sprintf("%02x", $n);
4009         return '\\' . sprintf("%03o", $n);
4010     }
4011 }
4012
4013 sub collapse {
4014     my(@chars) = @_;
4015     my($str, $c, $tr) = ("");
4016     for ($c = 0; $c < @chars; $c++) {
4017         $tr = $chars[$c];
4018         $str .= pchr($tr);
4019         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
4020             $chars[$c + 2] == $tr + 2)
4021         {
4022             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
4023               {}
4024             $str .= "-";
4025             $str .= pchr($chars[$c]);
4026         }
4027     }
4028     return $str;
4029 }
4030
4031 sub tr_decode_byte {
4032     my($table, $flags) = @_;
4033     my(@table) = unpack("s*", $table);
4034     splice @table, 0x100, 1;   # Number of subsequent elements
4035     my($c, $tr, @from, @to, @delfrom, $delhyphen);
4036     if ($table[ord "-"] != -1 and
4037         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
4038     {
4039         $tr = $table[ord "-"];
4040         $table[ord "-"] = -1;
4041         if ($tr >= 0) {
4042             @from = ord("-");
4043             @to = $tr;
4044         } else { # -2 ==> delete
4045             $delhyphen = 1;
4046         }
4047     }
4048     for ($c = 0; $c < @table; $c++) {
4049         $tr = $table[$c];
4050         if ($tr >= 0) {
4051             push @from, $c; push @to, $tr;
4052         } elsif ($tr == -2) {
4053             push @delfrom, $c;
4054         }
4055     }
4056     @from = (@from, @delfrom);
4057     if ($flags & OPpTRANS_COMPLEMENT) {
4058         my @newfrom = ();
4059         my %from;
4060         @from{@from} = (1) x @from;
4061         for ($c = 0; $c < 256; $c++) {
4062             push @newfrom, $c unless $from{$c};
4063         }
4064         @from = @newfrom;
4065     }
4066     unless ($flags & OPpTRANS_DELETE || !@to) {
4067         pop @to while $#to and $to[$#to] == $to[$#to -1];
4068     }
4069     my($from, $to);
4070     $from = collapse(@from);
4071     $to = collapse(@to);
4072     $from .= "-" if $delhyphen;
4073     return ($from, $to);
4074 }
4075
4076 sub tr_chr {
4077     my $x = shift;
4078     if ($x == ord "-") {
4079         return "\\-";
4080     } elsif ($x == ord "\\") {
4081         return "\\\\";
4082     } else {
4083         return chr $x;
4084     }
4085 }
4086
4087 # XXX This doesn't yet handle all cases correctly either
4088
4089 sub tr_decode_utf8 {
4090     my($swash_hv, $flags) = @_;
4091     my %swash = $swash_hv->ARRAY;
4092     my $final = undef;
4093     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
4094     my $none = $swash{"NONE"}->IV;
4095     my $extra = $none + 1;
4096     my(@from, @delfrom, @to);
4097     my $line;
4098     foreach $line (split /\n/, $swash{'LIST'}->PV) {
4099         my($min, $max, $result) = split(/\t/, $line);
4100         $min = hex $min;
4101         if (length $max) {
4102             $max = hex $max;
4103         } else {
4104             $max = $min;
4105         }
4106         $result = hex $result;
4107         if ($result == $extra) {
4108             push @delfrom, [$min, $max];
4109         } else {
4110             push @from, [$min, $max];
4111             push @to, [$result, $result + $max - $min];
4112         }
4113     }
4114     for my $i (0 .. $#from) {
4115         if ($from[$i][0] == ord '-') {
4116             unshift @from, splice(@from, $i, 1);
4117             unshift @to, splice(@to, $i, 1);
4118             last;
4119         } elsif ($from[$i][1] == ord '-') {
4120             $from[$i][1]--;
4121             $to[$i][1]--;
4122             unshift @from, ord '-';
4123             unshift @to, ord '-';
4124             last;
4125         }
4126     }
4127     for my $i (0 .. $#delfrom) {
4128         if ($delfrom[$i][0] == ord '-') {
4129             push @delfrom, splice(@delfrom, $i, 1);
4130             last;
4131         } elsif ($delfrom[$i][1] == ord '-') {
4132             $delfrom[$i][1]--;
4133             push @delfrom, ord '-';
4134             last;
4135         }
4136     }
4137     if (defined $final and $to[$#to][1] != $final) {
4138         push @to, [$final, $final];
4139     }
4140     push @from, @delfrom;
4141     if ($flags & OPpTRANS_COMPLEMENT) {
4142         my @newfrom;
4143         my $next = 0;
4144         for my $i (0 .. $#from) {
4145             push @newfrom, [$next, $from[$i][0] - 1];
4146             $next = $from[$i][1] + 1;
4147         }
4148         @from = ();
4149         for my $range (@newfrom) {
4150             if ($range->[0] <= $range->[1]) {
4151                 push @from, $range;
4152             }
4153         }
4154     }
4155     my($from, $to, $diff);
4156     for my $chunk (@from) {
4157         $diff = $chunk->[1] - $chunk->[0];
4158         if ($diff > 1) {
4159             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4160         } elsif ($diff == 1) {
4161             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4162         } else {
4163             $from .= tr_chr($chunk->[0]);
4164         }
4165     }
4166     for my $chunk (@to) {
4167         $diff = $chunk->[1] - $chunk->[0];
4168         if ($diff > 1) {
4169             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4170         } elsif ($diff == 1) {
4171             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4172         } else {
4173             $to .= tr_chr($chunk->[0]);
4174         }
4175     }
4176     #$final = sprintf("%04x", $final) if defined $final;
4177     #$none = sprintf("%04x", $none) if defined $none;
4178     #$extra = sprintf("%04x", $extra) if defined $extra;
4179     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
4180     #print STDERR $swash{'LIST'}->PV;
4181     return (escape_str($from), escape_str($to));
4182 }
4183
4184 sub pp_trans {
4185     my $self = shift;
4186     my($op, $cx) = @_;
4187     my($from, $to);
4188     my $class = class($op);
4189     my $priv_flags = $op->private;
4190     if ($class eq "PVOP") {
4191         ($from, $to) = tr_decode_byte($op->pv, $priv_flags);
4192     } elsif ($class eq "PADOP") {
4193         ($from, $to)
4194           = tr_decode_utf8($self->padval($op->padix)->RV, $priv_flags);
4195     } else { # class($op) eq "SVOP"
4196         ($from, $to) = tr_decode_utf8($op->sv->RV, $priv_flags);
4197     }
4198     my $flags = "";
4199     $flags .= "c" if $priv_flags & OPpTRANS_COMPLEMENT;
4200     $flags .= "d" if $priv_flags & OPpTRANS_DELETE;
4201     $to = "" if $from eq $to and $flags eq "";
4202     $flags .= "s" if $priv_flags & OPpTRANS_SQUASH;
4203     return "tr" . double_delim($from, $to) . $flags;
4204 }
4205
4206 sub pp_transr { &pp_trans . 'r' }
4207
4208 sub re_dq_disambiguate {
4209     my ($first, $last) = @_;
4210     # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
4211     ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4212         $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4213         || ($last =~ /^[{\[\w_]/ &&
4214             $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4215     return $first . $last;
4216 }
4217
4218 # Like dq(), but different
4219 sub re_dq {
4220     my $self = shift;
4221     my ($op, $extended) = @_;
4222
4223     my $type = $op->name;
4224     if ($type eq "const") {
4225         return '$[' if $op->private & OPpCONST_ARYBASE;
4226         my $unbacked = re_unback($self->const_sv($op)->as_string);
4227         return re_uninterp_extended(escape_extended_re($unbacked))
4228             if $extended;
4229         return re_uninterp(escape_str($unbacked));
4230     } elsif ($type eq "concat") {
4231         my $first = $self->re_dq($op->first, $extended);
4232         my $last  = $self->re_dq($op->last,  $extended);
4233         return re_dq_disambiguate($first, $last);
4234     } elsif ($type eq "uc") {
4235         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
4236     } elsif ($type eq "lc") {
4237         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
4238     } elsif ($type eq "ucfirst") {
4239         return '\u' . $self->re_dq($op->first->sibling, $extended);
4240     } elsif ($type eq "lcfirst") {
4241         return '\l' . $self->re_dq($op->first->sibling, $extended);
4242     } elsif ($type eq "quotemeta") {
4243         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
4244     } elsif ($type eq "join") {
4245         return $self->deparse($op->last, 26); # was join($", @ary)
4246     } else {
4247         return $self->deparse($op, 26);
4248     }
4249 }
4250
4251 sub pure_string {
4252     my ($self, $op) = @_;
4253     return 0 if null $op;
4254     my $type = $op->name;
4255
4256     if ($type eq 'const') {
4257         return 1;
4258     }
4259     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
4260         return $self->pure_string($op->first->sibling);
4261     }
4262     elsif ($type eq 'join') {
4263         my $join_op = $op->first->sibling;  # Skip pushmark
4264         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
4265
4266         my $gvop = $join_op->first;
4267         return 0 unless $gvop->name eq 'gvsv';
4268         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
4269
4270         return 0 unless ${$join_op->sibling} eq ${$op->last};
4271         return 0 unless $op->last->name =~ /^(?:[ah]slice|(?:rv2|pad)av)$/;
4272     }
4273     elsif ($type eq 'concat') {
4274         return $self->pure_string($op->first)
4275             && $self->pure_string($op->last);
4276     }
4277     elsif (is_scalar($op) || $type =~ /^[ah]elem$/) {
4278         return 1;
4279     }
4280     elsif ($type eq "null" and $op->can('first') and not null $op->first and
4281            $op->first->name eq "null" and $op->first->can('first')
4282            and not null $op->first->first and
4283            $op->first->first->name eq "aelemfast") {
4284         return 1;
4285     }
4286     else {
4287         return 0;
4288     }
4289
4290     return 1;
4291 }
4292
4293 sub regcomp {
4294     my $self = shift;
4295     my($op, $cx, $extended) = @_;
4296     my $kid = $op->first;
4297     $kid = $kid->first if $kid->name eq "regcmaybe";
4298     $kid = $kid->first if $kid->name eq "regcreset";
4299     if ($kid->name eq "null" and !null($kid->first)
4300         and $kid->first->name eq 'pushmark')
4301     {
4302         my $str = '';
4303         $kid = $kid->first->sibling;
4304         while (!null($kid)) {
4305             my $first = $str;
4306             my $last = $self->re_dq($kid, $extended);
4307             $str = re_dq_disambiguate($first, $last);
4308             $kid = $kid->sibling;
4309         }
4310         return $str, 1;
4311     }
4312
4313     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
4314     return ($self->deparse($kid, $cx), 0);
4315 }
4316
4317 sub pp_regcomp {
4318     my ($self, $op, $cx) = @_;
4319     return (($self->regcomp($op, $cx, 0))[0]);
4320 }
4321
4322 # osmic acid -- see osmium tetroxide
4323
4324 my %matchwords;
4325 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
4326     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic',
4327     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi');
4328
4329 sub matchop {
4330     my $self = shift;
4331     my($op, $cx, $name, $delim) = @_;
4332     my $kid = $op->first;
4333     my ($binop, $var, $re) = ("", "", "");
4334     if ($op->flags & OPf_STACKED) {
4335         $binop = 1;
4336         $var = $self->deparse($kid, 20);
4337         $kid = $kid->sibling;
4338     }
4339     my $quote = 1;
4340     my $extended = ($op->pmflags & PMf_EXTENDED);
4341     my $rhs_bound_to_defsv;
4342     if (null $kid) {
4343         my $unbacked = re_unback($op->precomp);
4344         if ($extended) {
4345             $re = re_uninterp_extended(escape_extended_re($unbacked));
4346         } else {
4347             $re = re_uninterp(escape_str(re_unback($op->precomp)));
4348         }
4349     } elsif ($kid->name ne 'regcomp') {
4350         carp("found ".$kid->name." where regcomp expected");
4351     } else {
4352         ($re, $quote) = $self->regcomp($kid, 21, $extended);
4353         $rhs_bound_to_defsv = 1 if $kid->first->first->flags & OPf_SPECIAL;
4354     }
4355     my $flags = "";
4356     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
4357     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4358     $flags .= "i" if $op->pmflags & PMf_FOLD;
4359     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4360     $flags .= "o" if $op->pmflags & PMf_KEEP;
4361     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4362     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
4363     $flags = $matchwords{$flags} if $matchwords{$flags};
4364     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
4365         $re =~ s/\?/\\?/g;
4366         $re = "?$re?";
4367     } elsif ($quote) {
4368         $re = single_delim($name, $delim, $re);
4369     }
4370     $re = $re . $flags if $quote;
4371     if ($binop) {