This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
0423fd31257da7e96844acbff4798f4b7a1ce166
[perl5.git] / Porting / bisect.pl
1 #!/usr/bin/perl -w
2 use strict;
3
4 =for comment
5
6 Documentation for this is in bisect-runner.pl
7
8 =cut
9
10 # The default, auto_abbrev will treat -e as an abbreviation of --end
11 # Which isn't what we want.
12 use Getopt::Long qw(:config pass_through no_auto_abbrev);
13
14 my ($start, $end, $validate, $usage, $bad, $jobs, $make);
15 $bad = !GetOptions('start=s' => \$start, 'end=s' => \$end,
16                    'jobs|j=i' => \$jobs, 'make=s' => \$make,
17                    validate => \$validate, 'usage|help|?' => \$usage);
18 unshift @ARGV, '--help' if $bad || $usage;
19 unshift @ARGV, '--validate' if $validate;
20
21 my $runner = $0;
22 $runner =~ s/bisect\.pl/bisect-runner.pl/;
23
24 die "Can't find bisect runner $runner" unless -f $runner;
25
26 system $^X, $runner, '--check-args', '--check-shebang', @ARGV and exit 255;
27 exit 255 if $bad;
28 exit 0 if $usage;
29
30 {
31     my ($dev0, $ino0) = stat $0;
32     die "Can't stat $0: $!" unless defined $ino0;
33     my ($dev1, $ino1) = stat 'Porting/bisect.pl';
34     die "Can't run a bisect using the directory containing $runner"
35       if defined $dev1 && $dev0 == $dev1 && $ino0 == $ino1;
36 }
37
38 my $start_time = time;
39
40 if (!defined $jobs &&
41     !($^O eq 'hpux' && system((defined $make ? $make : 'make')
42                               . ' --version >/dev/null 2>&1'))) {
43     # Try to default to (ab)use all the CPUs:
44     my $cpus;
45     if (open my $fh, '<', '/proc/cpuinfo') {
46         while (<$fh>) {
47             ++$cpus if /^processor\s+:\s+\d+$/;
48         }
49     } elsif (-x '/sbin/sysctl') {
50         $cpus =  $1 if `/sbin/sysctl hw.ncpu` =~ /^hw\.ncpu: (\d+)$/;
51     } elsif (-x '/usr/bin/getconf') {
52         $cpus = $1 if `/usr/bin/getconf _NPROCESSORS_ONLN` =~ /^(\d+)$/;
53     }
54     $jobs = defined $cpus ? $cpus + 1 : 2;
55 }
56
57 unshift @ARGV, '--jobs', $jobs if defined $jobs;
58 unshift @ARGV, '--make', $make if defined $make;
59
60 # We try these in this order for the start revision if none is specified.
61 my @stable = map {chomp $_; $_} grep {/v5\.[0-9]+[02468]\.0$/} `git tag -l`;
62 die "git tag -l didn't seem to return any tags for stable releases"
63     unless @stable;
64 unshift @stable, qw(perl-5.005 perl-5.6.0 perl-5.8.0);
65
66 {
67     my ($dev_C, $ino_C) = stat 'Configure';
68     my ($dev_c, $ino_c) = stat 'configure';
69     if (defined $dev_C && defined $dev_c
70         && $dev_C == $dev_c && $ino_C == $ino_c) {
71         print "You seem to be on a case-insensitive file system.\n\n";
72     } else {
73         unshift @stable, qw(perl-5.002 perl-5.003 perl-5.004)
74     }
75 }
76
77 $end = 'blead' unless defined $end;
78
79 # Canonicalising branches to revisions before moving the checkout permits one
80 # to use revisions such as 'HEAD' for --start or --end
81 foreach ($start, $end) {
82     next unless $_;
83     $_ = `git rev-parse $_`;
84     die unless defined $_;
85     chomp;
86 }
87
88 my $modified = my @modified = `git ls-files --modified --deleted --others`;
89
90 die "This checkout is not clean, found file(s):\n",
91     join("\t","",@modified),
92     "$modified modified, untracked, or other file(s)\n",
93     "These files may not show in git status as they may be ignored.\n",
94     "You can use 'git clean -Xdf' to cleanup the ignored files.\n"
95     if $modified;
96
97 sub validate {
98     my $commit = shift;
99     if (defined $start && `git rev-list -n1 $commit ^$start^` eq "") {
100         print "Skipping $commit, as it is earlier than $start\n";
101         return;
102     }
103     if (defined $end && `git rev-list -n1 $end ^$commit^` eq "") {
104         print "Skipping $commit, as it is more recent than $end\n";
105         return;
106     }
107     print "Testing $commit...\n";
108     system "git checkout $commit </dev/null" and die;
109     my $ret = system $^X, $runner, '--no-clean', @ARGV;
110     die "Runner returned $ret, not 0 for revision $commit" if $ret;
111     system 'git clean -dxf </dev/null' and die;
112     system 'git reset --hard HEAD </dev/null' and die;
113     return $commit;
114 }
115
116 if ($validate) {
117     require Text::Wrap;
118     my @built = map {validate $_} 'blead', reverse @stable;
119     if (@built) {
120         print Text::Wrap::wrap("", "", "Successfully validated @built\n");
121         exit 0;
122     }
123     print "Did not validate anything\n";
124     exit 1;
125 }
126
127 my $git_version = `git --version`;
128 if (defined $git_version
129     && $git_version =~ /\Agit version (\d+\.\d+\.\d+)(.*)/) {
130     $git_version = eval "v$1";
131 } else {
132     $git_version = v0.0.0;
133 }
134
135 if ($git_version ge v1.6.6) {
136     system "git bisect reset HEAD" and die;
137 } else {
138     system "git bisect reset" and die;
139 }
140
141 # Sanity check the first and last revisions:
142 system "git checkout $end" and die;
143 my $ret = system $^X, $runner, @ARGV;
144 die "Runner returned $ret for end revision" unless $ret;
145 die "Runner returned $ret for end revision, which is a skip"
146     if $ret == 125 * 256;
147
148 if (defined $start) {
149     system "git checkout $start" and die;
150     my $ret = system $^X, $runner, @ARGV;
151     die "Runner returned $ret, not 0 for start revision" if $ret;
152 } else {
153     # Try to find the earliest version for which the test works
154     my @tried;
155     foreach my $try (@stable) {
156         if (`git rev-list -n1 $end ^$try^` eq "") {
157             print "Skipping $try, as it is more recent than end commit "
158                 . (substr $end, 0, 16) . "\n";
159             # As @stable is supposed to be in age order, arguably we should
160             # last; here.
161             next;
162         }
163         system "git checkout $try" and die;
164         my $ret = system $^X, $runner, @ARGV;
165         if (!$ret) {
166             $start = $try;
167             last;
168         }
169         push @tried, $try;
170     }
171     die "Can't find a suitable start revision to default to.\nTried @tried"
172         unless defined $start;
173 }
174
175 system "git bisect start" and die;
176 system "git bisect good $start" and die;
177 system "git bisect bad $end" and die;
178
179 # And now get git bisect to do the hard work:
180 system 'git', 'bisect', 'run', $^X, $runner, @ARGV and die;
181
182 END {
183     my $end_time = time;
184
185     printf "That took %d seconds\n", $end_time - $start_time
186         if defined $start_time;
187 }
188
189 =for comment
190
191 Documentation for this is in bisect-runner.pl
192
193 =cut
194
195 # Local variables:
196 # cperl-indent-level: 4
197 # indent-tabs-mode: nil
198 # End:
199 #
200 # ex: set ts=8 sts=4 sw=4 et: