This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
0323a97405d74606d6fc2d2e6ceadaa28decc1a5
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19 Matching operations can have various modifiers.  Modifiers
20 that relate to the interpretation of the regular expression inside
21 are listed below.  Modifiers that alter the way a regular expression
22 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
23 L<perlop/"Gory details of parsing quoted constructs">.
24
25 =over 4
26
27 =item i
28 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
29 X<regular expression, case-insensitive>
30
31 Do case-insensitive pattern matching.
32
33 If C<use locale> is in effect, the case map is taken from the current
34 locale.  See L<perllocale>.
35
36 =item m
37 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
38
39 Treat string as multiple lines.  That is, change "^" and "$" from matching
40 the start or end of the string to matching the start or end of any
41 line anywhere within the string.
42
43 =item s
44 X</s> X<regex, single-line> X<regexp, single-line>
45 X<regular expression, single-line>
46
47 Treat string as single line.  That is, change "." to match any character
48 whatsoever, even a newline, which normally it would not match.
49
50 Used together, as /ms, they let the "." match any character whatsoever,
51 while still allowing "^" and "$" to match, respectively, just after
52 and just before newlines within the string.
53
54 =item x
55 X</x>
56
57 Extend your pattern's legibility by permitting whitespace and comments.
58
59 =back
60
61 These are usually written as "the C</x> modifier", even though the delimiter
62 in question might not really be a slash.  Any of these
63 modifiers may also be embedded within the regular expression itself using
64 the C<(?...)> construct.  See below.
65
66 The C</x> modifier itself needs a little more explanation.  It tells
67 the regular expression parser to ignore whitespace that is neither
68 backslashed nor within a character class.  You can use this to break up
69 your regular expression into (slightly) more readable parts.  The C<#>
70 character is also treated as a metacharacter introducing a comment,
71 just as in ordinary Perl code.  This also means that if you want real
72 whitespace or C<#> characters in the pattern (outside a character
73 class, where they are unaffected by C</x>), then you'll either have to
74 escape them (using backslashes or C<\Q...\E>) or encode them using octal
75 or hex escapes.  Taken together, these features go a long way towards
76 making Perl's regular expressions more readable.  Note that you have to
77 be careful not to include the pattern delimiter in the comment--perl has
78 no way of knowing you did not intend to close the pattern early.  See
79 the C-comment deletion code in L<perlop>.  Also note that anything inside
80 a C<\Q...\E> stays unaffected by C</x>.
81 X</x>
82
83 =head2 Regular Expressions
84
85 =head3 Metacharacters
86
87 The patterns used in Perl pattern matching derive from supplied in
88 the Version 8 regex routines.  (The routines are derived
89 (distantly) from Henry Spencer's freely redistributable reimplementation
90 of the V8 routines.)  See L<Version 8 Regular Expressions> for
91 details.
92
93 In particular the following metacharacters have their standard I<egrep>-ish
94 meanings:
95 X<metacharacter>
96 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
97
98
99     \   Quote the next metacharacter
100     ^   Match the beginning of the line
101     .   Match any character (except newline)
102     $   Match the end of the line (or before newline at the end)
103     |   Alternation
104     ()  Grouping
105     []  Character class
106
107 By default, the "^" character is guaranteed to match only the
108 beginning of the string, the "$" character only the end (or before the
109 newline at the end), and Perl does certain optimizations with the
110 assumption that the string contains only one line.  Embedded newlines
111 will not be matched by "^" or "$".  You may, however, wish to treat a
112 string as a multi-line buffer, such that the "^" will match after any
113 newline within the string (except if the newline is the last character in
114 the string), and "$" will match before any newline.  At the
115 cost of a little more overhead, you can do this by using the /m modifier
116 on the pattern match operator.  (Older programs did this by setting C<$*>,
117 but this practice has been removed in perl 5.9.)
118 X<^> X<$> X</m>
119
120 To simplify multi-line substitutions, the "." character never matches a
121 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
122 the string is a single line--even if it isn't.
123 X<.> X</s>
124
125 =head3 Quantifiers
126
127 The following standard quantifiers are recognized:
128 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
129
130     *      Match 0 or more times
131     +      Match 1 or more times
132     ?      Match 1 or 0 times
133     {n}    Match exactly n times
134     {n,}   Match at least n times
135     {n,m}  Match at least n but not more than m times
136
137 (If a curly bracket occurs in any other context, it is treated
138 as a regular character.  In particular, the lower bound
139 is not optional.)  The "*" modifier is equivalent to C<{0,}>, the "+"
140 modifier to C<{1,}>, and the "?" modifier to C<{0,1}>.  n and m are limited
141 to integral values less than a preset limit defined when perl is built.
142 This is usually 32766 on the most common platforms.  The actual limit can
143 be seen in the error message generated by code such as this:
144
145     $_ **= $_ , / {$_} / for 2 .. 42;
146
147 By default, a quantified subpattern is "greedy", that is, it will match as
148 many times as possible (given a particular starting location) while still
149 allowing the rest of the pattern to match.  If you want it to match the
150 minimum number of times possible, follow the quantifier with a "?".  Note
151 that the meanings don't change, just the "greediness":
152 X<metacharacter> X<greedy> X<greedyness>
153 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
154
155     *?     Match 0 or more times
156     +?     Match 1 or more times
157     ??     Match 0 or 1 time
158     {n}?   Match exactly n times
159     {n,}?  Match at least n times
160     {n,m}? Match at least n but not more than m times
161
162 By default, when a quantified subpattern does not allow the rest of the
163 overall pattern to match, Perl will backtrack. However, this behaviour is
164 sometimes undesirable. Thus Perl provides the "possesive" quantifier form
165 as well.
166
167     *+     Match 0 or more times and give nothing back
168     ++     Match 1 or more times and give nothing back
169     ?+     Match 0 or 1 time and give nothing back
170     {n}+   Match exactly n times and give nothing back (redundant)
171     {n,}+  Match at least n times and give nothing back
172     {n,m}+ Match at least n but not more than m times and give nothing back
173
174 For instance,
175
176    'aaaa' =~ /a++a/
177
178 will never match, as the C<a++> will gobble up all the C<a>'s in the
179 string and won't leave any for the remaining part of the pattern. This
180 feature can be extremely useful to give perl hints about where it
181 shouldn't backtrack. For instance, the typical "match a double-quoted
182 string" problem can be most efficiently performed when written as:
183
184    /"(?:[^"\\]++|\\.)*+"/
185
186 as we know that if the final quote does not match, bactracking will not
187 help. See the independent subexpression C<< (?>...) >> for more details;
188 possessive quantifiers are just syntactic sugar for that construct. For
189 instance the above example could also be written as follows:
190
191    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
192
193 =head3 Escape sequences
194
195 Because patterns are processed as double quoted strings, the following
196 also work:
197 X<\t> X<\n> X<\r> X<\f> X<\a> X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
198 X<\0> X<\c> X<\N> X<\x>
199
200     \t          tab                   (HT, TAB)
201     \n          newline               (LF, NL)
202     \r          return                (CR)
203     \f          form feed             (FF)
204     \a          alarm (bell)          (BEL)
205     \e          escape (think troff)  (ESC)
206     \033        octal char (think of a PDP-11)
207     \x1B        hex char
208     \x{263a}    wide hex char         (Unicode SMILEY)
209     \c[         control char
210     \N{name}    named char
211     \l          lowercase next char (think vi)
212     \u          uppercase next char (think vi)
213     \L          lowercase till \E (think vi)
214     \U          uppercase till \E (think vi)
215     \E          end case modification (think vi)
216     \Q          quote (disable) pattern metacharacters till \E
217
218 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
219 and C<\U> is taken from the current locale.  See L<perllocale>.  For
220 documentation of C<\N{name}>, see L<charnames>.
221
222 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
223 An unescaped C<$> or C<@> interpolates the corresponding variable,
224 while escaping will cause the literal string C<\$> to be matched.
225 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
226
227 =head3 Character classes
228
229 In addition, Perl defines the following:
230 X<metacharacter>
231 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\X> X<\p> X<\P> X<\C>
232 X<word> X<whitespace>
233
234     \w       Match a "word" character (alphanumeric plus "_")
235     \W       Match a non-"word" character
236     \s       Match a whitespace character
237     \S       Match a non-whitespace character
238     \d       Match a digit character
239     \D       Match a non-digit character
240     \pP      Match P, named property.  Use \p{Prop} for longer names.
241     \PP      Match non-P
242     \X       Match eXtended Unicode "combining character sequence",
243              equivalent to (?:\PM\pM*)
244     \C       Match a single C char (octet) even under Unicode.
245              NOTE: breaks up characters into their UTF-8 bytes,
246              so you may end up with malformed pieces of UTF-8.
247              Unsupported in lookbehind.
248     \1       Backreference to a specific group.
249             '1' may actually be any positive integer.
250     \k<name> Named backreference
251     \N{name} Named unicode character, or unicode escape
252     \x12     Hexadecimal escape sequence
253     \x{1234} Long hexadecimal escape sequence
254
255 A C<\w> matches a single alphanumeric character (an alphabetic
256 character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
257 to match a string of Perl-identifier characters (which isn't the same
258 as matching an English word).  If C<use locale> is in effect, the list
259 of alphabetic characters generated by C<\w> is taken from the current
260 locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
261 C<\d>, and C<\D> within character classes, but if you try to use them
262 as endpoints of a range, that's not a range, the "-" is understood
263 literally.  If Unicode is in effect, C<\s> matches also "\x{85}",
264 "\x{2028}, and "\x{2029}", see L<perlunicode> for more details about
265 C<\pP>, C<\PP>, and C<\X>, and L<perluniintro> about Unicode in general.
266 You can define your own C<\p> and C<\P> properties, see L<perlunicode>.
267 X<\w> X<\W> X<word>
268
269 The POSIX character class syntax
270 X<character class>
271
272     [:class:]
273
274 is also available.  Note that the C<[> and C<]> braces are I<literal>;
275 they must always be used within a character class expression.
276
277     # this is correct:
278     $string =~ /[[:alpha:]]/;
279
280     # this is not, and will generate a warning:
281     $string =~ /[:alpha:]/;
282
283 The available classes and their backslash equivalents (if available) are
284 as follows:
285 X<character class>
286 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
287 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
288
289     alpha
290     alnum
291     ascii
292     blank               [1]
293     cntrl
294     digit       \d
295     graph
296     lower
297     print
298     punct
299     space       \s      [2]
300     upper
301     word        \w      [3]
302     xdigit
303
304 =over
305
306 =item [1]
307
308 A GNU extension equivalent to C<[ \t]>, "all horizontal whitespace".
309
310 =item [2]
311
312 Not exactly equivalent to C<\s> since the C<[[:space:]]> includes
313 also the (very rare) "vertical tabulator", "\ck", chr(11).
314
315 =item [3]
316
317 A Perl extension, see above.
318
319 =back
320
321 For example use C<[:upper:]> to match all the uppercase characters.
322 Note that the C<[]> are part of the C<[::]> construct, not part of the
323 whole character class.  For example:
324
325     [01[:alpha:]%]
326
327 matches zero, one, any alphabetic character, and the percentage sign.
328
329 The following equivalences to Unicode \p{} constructs and equivalent
330 backslash character classes (if available), will hold:
331 X<character class> X<\p> X<\p{}>
332
333     [[:...:]]   \p{...}         backslash
334
335     alpha       IsAlpha
336     alnum       IsAlnum
337     ascii       IsASCII
338     blank       IsSpace
339     cntrl       IsCntrl
340     digit       IsDigit        \d
341     graph       IsGraph
342     lower       IsLower
343     print       IsPrint
344     punct       IsPunct
345     space       IsSpace
346                 IsSpacePerl    \s
347     upper       IsUpper
348     word        IsWord
349     xdigit      IsXDigit
350
351 For example C<[[:lower:]]> and C<\p{IsLower}> are equivalent.
352
353 If the C<utf8> pragma is not used but the C<locale> pragma is, the
354 classes correlate with the usual isalpha(3) interface (except for
355 "word" and "blank").
356
357 The assumedly non-obviously named classes are:
358
359 =over 4
360
361 =item cntrl
362 X<cntrl>
363
364 Any control character.  Usually characters that don't produce output as
365 such but instead control the terminal somehow: for example newline and
366 backspace are control characters.  All characters with ord() less than
367 32 are most often classified as control characters (assuming ASCII,
368 the ISO Latin character sets, and Unicode), as is the character with
369 the ord() value of 127 (C<DEL>).
370
371 =item graph
372 X<graph>
373
374 Any alphanumeric or punctuation (special) character.
375
376 =item print
377 X<print>
378
379 Any alphanumeric or punctuation (special) character or the space character.
380
381 =item punct
382 X<punct>
383
384 Any punctuation (special) character.
385
386 =item xdigit
387 X<xdigit>
388
389 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
390 work just fine) it is included for completeness.
391
392 =back
393
394 You can negate the [::] character classes by prefixing the class name
395 with a '^'. This is a Perl extension.  For example:
396 X<character class, negation>
397
398     POSIX         traditional  Unicode
399
400     [[:^digit:]]    \D         \P{IsDigit}
401     [[:^space:]]    \S         \P{IsSpace}
402     [[:^word:]]     \W         \P{IsWord}
403
404 Perl respects the POSIX standard in that POSIX character classes are
405 only supported within a character class.  The POSIX character classes
406 [.cc.] and [=cc=] are recognized but B<not> supported and trying to
407 use them will cause an error.
408
409 =head3 Assertions
410
411 Perl defines the following zero-width assertions:
412 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
413 X<regexp, zero-width assertion>
414 X<regular expression, zero-width assertion>
415 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
416
417     \b  Match a word boundary
418     \B  Match a non-(word boundary)
419     \A  Match only at beginning of string
420     \Z  Match only at end of string, or before newline at the end
421     \z  Match only at end of string
422     \G  Match only at pos() (e.g. at the end-of-match position
423         of prior m//g)
424
425 A word boundary (C<\b>) is a spot between two characters
426 that has a C<\w> on one side of it and a C<\W> on the other side
427 of it (in either order), counting the imaginary characters off the
428 beginning and end of the string as matching a C<\W>.  (Within
429 character classes C<\b> represents backspace rather than a word
430 boundary, just as it normally does in any double-quoted string.)
431 The C<\A> and C<\Z> are just like "^" and "$", except that they
432 won't match multiple times when the C</m> modifier is used, while
433 "^" and "$" will match at every internal line boundary.  To match
434 the actual end of the string and not ignore an optional trailing
435 newline, use C<\z>.
436 X<\b> X<\A> X<\Z> X<\z> X</m>
437
438 The C<\G> assertion can be used to chain global matches (using
439 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
440 It is also useful when writing C<lex>-like scanners, when you have
441 several patterns that you want to match against consequent substrings
442 of your string, see the previous reference.  The actual location
443 where C<\G> will match can also be influenced by using C<pos()> as
444 an lvalue: see L<perlfunc/pos>. Currently C<\G> is only fully
445 supported when anchored to the start of the pattern; while it
446 is permitted to use it elsewhere, as in C</(?<=\G..)./g>, some
447 such uses (C</.\G/g>, for example) currently cause problems, and
448 it is recommended that you avoid such usage for now.
449 X<\G>
450
451 =head3 Capture buffers
452
453 The bracketing construct C<( ... )> creates capture buffers.  To
454 refer to the digit'th buffer use \<digit> within the
455 match.  Outside the match use "$" instead of "\".  (The
456 \<digit> notation works in certain circumstances outside
457 the match.  See the warning below about \1 vs $1 for details.)
458 Referring back to another part of the match is called a
459 I<backreference>.
460 X<regex, capture buffer> X<regexp, capture buffer>
461 X<regular expression, capture buffer> X<backreference>
462
463 There is no limit to the number of captured substrings that you may
464 use.  However Perl also uses \10, \11, etc. as aliases for \010,
465 \011, etc.  (Recall that 0 means octal, so \011 is the character at
466 number 9 in your coded character set; which would be the 10th character,
467 a horizontal tab under ASCII.)  Perl resolves this
468 ambiguity by interpreting \10 as a backreference only if at least 10
469 left parentheses have opened before it.  Likewise \11 is a
470 backreference only if at least 11 left parentheses have opened
471 before it.  And so on.  \1 through \9 are always interpreted as
472 backreferences.
473
474 Additionally, as of Perl 5.10 you may use named capture buffers and named
475 backreferences. The notation is C<< (?<name>...) >> and C<< \k<name> >>
476 (you may also use single quotes instead of angle brackets to quote the
477 name). The only difference with named capture buffers and unnamed ones is
478 that multiple buffers may have the same name and that the contents of
479 named capture buffers is available via the C<%+> hash. When multiple
480 groups share the same name C<$+{name}> and C<< \k<name> >> refer to the
481 leftmost defined group, thus it's possible to do things with named capture
482 buffers that would otherwise require C<(??{})> code to accomplish. Named
483 capture buffers are numbered just as normal capture buffers are and may be
484 referenced via the magic numeric variables or via numeric backreferences
485 as well as by name.
486
487 Examples:
488
489     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
490
491     /(.)\1/                         # find first doubled char
492          and print "'$1' is the first doubled character\n";
493
494     /(?<char>.)\k<char>/            # ... a different way
495          and print "'$+{char}' is the first doubled character\n";
496
497     /(?<char>.)\1/                  # ... mix and match
498          and print "'$1' is the first doubled character\n";
499
500     if (/Time: (..):(..):(..)/) {   # parse out values
501         $hours = $1;
502         $minutes = $2;
503         $seconds = $3;
504     }
505
506 Several special variables also refer back to portions of the previous
507 match.  C<$+> returns whatever the last bracket match matched.
508 C<$&> returns the entire matched string.  (At one point C<$0> did
509 also, but now it returns the name of the program.)  C<$`> returns
510 everything before the matched string.  C<$'> returns everything
511 after the matched string. And C<$^N> contains whatever was matched by
512 the most-recently closed group (submatch). C<$^N> can be used in
513 extended patterns (see below), for example to assign a submatch to a
514 variable.
515 X<$+> X<$^N> X<$&> X<$`> X<$'>
516
517 The numbered match variables ($1, $2, $3, etc.) and the related punctuation
518 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
519 until the end of the enclosing block or until the next successful
520 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
521 X<$+> X<$^N> X<$&> X<$`> X<$'>
522 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
523
524
525 B<NOTE>: failed matches in Perl do not reset the match variables,
526 which makes it easier to write code that tests for a series of more
527 specific cases and remembers the best match.
528
529 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
530 C<$'> anywhere in the program, it has to provide them for every
531 pattern match.  This may substantially slow your program.  Perl
532 uses the same mechanism to produce $1, $2, etc, so you also pay a
533 price for each pattern that contains capturing parentheses.  (To
534 avoid this cost while retaining the grouping behaviour, use the
535 extended regular expression C<(?: ... )> instead.)  But if you never
536 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
537 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
538 if you can, but if you can't (and some algorithms really appreciate
539 them), once you've used them once, use them at will, because you've
540 already paid the price.  As of 5.005, C<$&> is not so costly as the
541 other two.
542 X<$&> X<$`> X<$'>
543
544 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
545 C<\w>, C<\n>.  Unlike some other regular expression languages, there
546 are no backslashed symbols that aren't alphanumeric.  So anything
547 that looks like \\, \(, \), \<, \>, \{, or \} is always
548 interpreted as a literal character, not a metacharacter.  This was
549 once used in a common idiom to disable or quote the special meanings
550 of regular expression metacharacters in a string that you want to
551 use for a pattern. Simply quote all non-"word" characters:
552
553     $pattern =~ s/(\W)/\\$1/g;
554
555 (If C<use locale> is set, then this depends on the current locale.)
556 Today it is more common to use the quotemeta() function or the C<\Q>
557 metaquoting escape sequence to disable all metacharacters' special
558 meanings like this:
559
560     /$unquoted\Q$quoted\E$unquoted/
561
562 Beware that if you put literal backslashes (those not inside
563 interpolated variables) between C<\Q> and C<\E>, double-quotish
564 backslash interpolation may lead to confusing results.  If you
565 I<need> to use literal backslashes within C<\Q...\E>,
566 consult L<perlop/"Gory details of parsing quoted constructs">.
567
568 =head2 Extended Patterns
569
570 Perl also defines a consistent extension syntax for features not
571 found in standard tools like B<awk> and B<lex>.  The syntax is a
572 pair of parentheses with a question mark as the first thing within
573 the parentheses.  The character after the question mark indicates
574 the extension.
575
576 The stability of these extensions varies widely.  Some have been
577 part of the core language for many years.  Others are experimental
578 and may change without warning or be completely removed.  Check
579 the documentation on an individual feature to verify its current
580 status.
581
582 A question mark was chosen for this and for the minimal-matching
583 construct because 1) question marks are rare in older regular
584 expressions, and 2) whenever you see one, you should stop and
585 "question" exactly what is going on.  That's psychology...
586
587 =over 10
588
589 =item C<(?#text)>
590 X<(?#)>
591
592 A comment.  The text is ignored.  If the C</x> modifier enables
593 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
594 the comment as soon as it sees a C<)>, so there is no way to put a literal
595 C<)> in the comment.
596
597 =item C<(?imsx-imsx)>
598 X<(?)>
599
600 One or more embedded pattern-match modifiers, to be turned on (or
601 turned off, if preceded by C<->) for the remainder of the pattern or
602 the remainder of the enclosing pattern group (if any). This is
603 particularly useful for dynamic patterns, such as those read in from a
604 configuration file, read in as an argument, are specified in a table
605 somewhere, etc.  Consider the case that some of which want to be case
606 sensitive and some do not.  The case insensitive ones need to include
607 merely C<(?i)> at the front of the pattern.  For example:
608
609     $pattern = "foobar";
610     if ( /$pattern/i ) { }
611
612     # more flexible:
613
614     $pattern = "(?i)foobar";
615     if ( /$pattern/ ) { }
616
617 These modifiers are restored at the end of the enclosing group. For example,
618
619     ( (?i) blah ) \s+ \1
620
621 will match a repeated (I<including the case>!) word C<blah> in any
622 case, assuming C<x> modifier, and no C<i> modifier outside this
623 group.
624
625 =item C<(?:pattern)>
626 X<(?:)>
627
628 =item C<(?imsx-imsx:pattern)>
629
630 This is for clustering, not capturing; it groups subexpressions like
631 "()", but doesn't make backreferences as "()" does.  So
632
633     @fields = split(/\b(?:a|b|c)\b/)
634
635 is like
636
637     @fields = split(/\b(a|b|c)\b/)
638
639 but doesn't spit out extra fields.  It's also cheaper not to capture
640 characters if you don't need to.
641
642 Any letters between C<?> and C<:> act as flags modifiers as with
643 C<(?imsx-imsx)>.  For example,
644
645     /(?s-i:more.*than).*million/i
646
647 is equivalent to the more verbose
648
649     /(?:(?s-i)more.*than).*million/i
650
651 =item C<(?=pattern)>
652 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
653
654 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
655 matches a word followed by a tab, without including the tab in C<$&>.
656
657 =item C<(?!pattern)>
658 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
659
660 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
661 matches any occurrence of "foo" that isn't followed by "bar".  Note
662 however that look-ahead and look-behind are NOT the same thing.  You cannot
663 use this for look-behind.
664
665 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
666 will not do what you want.  That's because the C<(?!foo)> is just saying that
667 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
668 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
669 say "like" because there's the case of your "bar" not having three characters
670 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
671 Sometimes it's still easier just to say:
672
673     if (/bar/ && $` !~ /foo$/)
674
675 For look-behind see below.
676
677 =item C<(?<=pattern)>
678 X<(?<=)> X<look-behind, positive> X<lookbehind, positive>
679
680 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
681 matches a word that follows a tab, without including the tab in C<$&>.
682 Works only for fixed-width look-behind.
683
684 =item C<(?<!pattern)>
685 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
686
687 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
688 matches any occurrence of "foo" that does not follow "bar".  Works
689 only for fixed-width look-behind.
690
691 =item C<(?'NAME'pattern)>
692
693 =item C<< (?<NAME>pattern) >>
694 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
695
696 A named capture buffer. Identical in every respect to normal capturing
697 parens C<()> but for the additional fact that C<%+> may be used after
698 a succesful match to refer to a named buffer. See C<perlvar> for more
699 details on the C<%+> hash.
700
701 If multiple distinct capture buffers have the same name then the
702 $+{NAME} will refer to the leftmost defined buffer in the match.
703
704 The forms C<(?'NAME'pattern)> and C<(?<NAME>pattern)> are equivalent.
705
706 B<NOTE:> While the notation of this construct is the same as the similar
707 function in .NET regexes, the behavior is not, in Perl the buffers are
708 numbered sequentially regardless of being named or not. Thus in the
709 pattern
710
711   /(x)(?<foo>y)(z)/
712
713 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
714 the opposite which is what a .NET regex hacker might expect.
715
716 Currently NAME is restricted to word chars only. In other words, it
717 must match C</^\w+$/>.
718
719 =item C<< \k<name> >>
720
721 =item C<< \k'name' >>
722
723 Named backreference. Similar to numeric backreferences, except that
724 the group is designated by name and not number. If multiple groups
725 have the same name then it refers to the leftmost defined group in
726 the current match.
727
728 It is an error to refer to a name not defined by a C<(?<NAME>)>
729 earlier in the pattern.
730
731 Both forms are equivalent.
732
733 =item C<(?{ code })>
734 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
735
736 B<WARNING>: This extended regular expression feature is considered
737 experimental, and may be changed without notice. Code executed that
738 has side effects may not perform identically from version to version
739 due to the effect of future optimisations in the regex engine.
740
741 This zero-width assertion evaluates any embedded Perl code.  It
742 always succeeds, and its C<code> is not interpolated.  Currently,
743 the rules to determine where the C<code> ends are somewhat convoluted.
744
745 This feature can be used together with the special variable C<$^N> to
746 capture the results of submatches in variables without having to keep
747 track of the number of nested parentheses. For example:
748
749   $_ = "The brown fox jumps over the lazy dog";
750   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
751   print "color = $color, animal = $animal\n";
752
753 Inside the C<(?{...})> block, C<$_> refers to the string the regular
754 expression is matching against. You can also use C<pos()> to know what is
755 the current position of matching within this string.
756
757 The C<code> is properly scoped in the following sense: If the assertion
758 is backtracked (compare L<"Backtracking">), all changes introduced after
759 C<local>ization are undone, so that
760
761   $_ = 'a' x 8;
762   m<
763      (?{ $cnt = 0 })                    # Initialize $cnt.
764      (
765        a
766        (?{
767            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
768        })
769      )*
770      aaaa
771      (?{ $res = $cnt })                 # On success copy to non-localized
772                                         # location.
773    >x;
774
775 will set C<$res = 4>.  Note that after the match, $cnt returns to the globally
776 introduced value, because the scopes that restrict C<local> operators
777 are unwound.
778
779 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
780 switch.  If I<not> used in this way, the result of evaluation of
781 C<code> is put into the special variable C<$^R>.  This happens
782 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
783 inside the same regular expression.
784
785 The assignment to C<$^R> above is properly localized, so the old
786 value of C<$^R> is restored if the assertion is backtracked; compare
787 L<"Backtracking">.
788
789 Due to an unfortunate implementation issue, the Perl code contained in these
790 blocks is treated as a compile time closure that can have seemingly bizarre
791 consequences when used with lexically scoped variables inside of subroutines
792 or loops.  There are various workarounds for this, including simply using
793 global variables instead.  If you are using this construct and strange results
794 occur then check for the use of lexically scoped variables.
795
796 For reasons of security, this construct is forbidden if the regular
797 expression involves run-time interpolation of variables, unless the
798 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
799 variables contain results of C<qr//> operator (see
800 L<perlop/"qr/STRING/imosx">).
801
802 This restriction is because of the wide-spread and remarkably convenient
803 custom of using run-time determined strings as patterns.  For example:
804
805     $re = <>;
806     chomp $re;
807     $string =~ /$re/;
808
809 Before Perl knew how to execute interpolated code within a pattern,
810 this operation was completely safe from a security point of view,
811 although it could raise an exception from an illegal pattern.  If
812 you turn on the C<use re 'eval'>, though, it is no longer secure,
813 so you should only do so if you are also using taint checking.
814 Better yet, use the carefully constrained evaluation within a Safe
815 compartment.  See L<perlsec> for details about both these mechanisms.
816
817 Because perl's regex engine is not currently re-entrant, interpolated
818 code may not invoke the regex engine either directly with C<m//> or C<s///>),
819 or indirectly with functions such as C<split>.
820
821 =item C<(??{ code })>
822 X<(??{})>
823 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
824
825 B<WARNING>: This extended regular expression feature is considered
826 experimental, and may be changed without notice. Code executed that
827 has side effects may not perform identically from version to version
828 due to the effect of future optimisations in the regex engine.
829
830 This is a "postponed" regular subexpression.  The C<code> is evaluated
831 at run time, at the moment this subexpression may match.  The result
832 of evaluation is considered as a regular expression and matched as
833 if it were inserted instead of this construct.  Note that this means
834 that the contents of capture buffers defined inside an eval'ed pattern
835 are not available outside of the pattern, and vice versa, there is no
836 way for the inner pattern to refer to a capture buffer defined outside.
837 Thus,
838
839     ('a' x 100)=~/(??{'(.)' x 100})/
840
841 B<will> match, it will B<not> set $1.
842
843 The C<code> is not interpolated.  As before, the rules to determine
844 where the C<code> ends are currently somewhat convoluted.
845
846 The following pattern matches a parenthesized group:
847
848   $re = qr{
849              \(
850              (?:
851                 (?> [^()]+ )    # Non-parens without backtracking
852               |
853                 (??{ $re })     # Group with matching parens
854              )*
855              \)
856           }x;
857
858 See also C<(?PARNO)> for a different, more efficient way to accomplish
859 the same task.
860
861 Because perl's regex engine is not currently re-entrant, delayed
862 code may not invoke the regex engine either directly with C<m//> or C<s///>),
863 or indirectly with functions such as C<split>.
864
865 Recursing deeper than 50 times without consuming any input string will
866 result in a fatal error.  The maximum depth is compiled into perl, so
867 changing it requires a custom build.
868
869 =item C<(?PARNO)> C<(?R)> C<(?0)>
870 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)>
871 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
872
873 Similar to C<(??{ code })> except it does not involve compiling any code,
874 instead it treats the contents of a capture buffer as an independent
875 pattern that must match at the current position.  Capture buffers
876 contained by the pattern will have the value as determined by the
877 outermost recursion.
878
879 PARNO is a sequence of digits (not starting with 0) whose value reflects
880 the paren-number of the capture buffer to recurse to. C<(?R)> recurses to
881 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
882 C<(?R)>.
883
884 The following pattern matches a function foo() which may contain
885 balanced parentheses as the argument.
886
887   $re = qr{ (                    # paren group 1 (full function)
888               foo
889               (                  # paren group 2 (parens)
890                 \(
891                   (              # paren group 3 (contents of parens)
892                   (?:
893                    (?> [^()]+ )  # Non-parens without backtracking
894                   |
895                    (?2)          # Recurse to start of paren group 2
896                   )*
897                   )
898                 \)
899               )
900             )
901           }x;
902
903 If the pattern was used as follows
904
905     'foo(bar(baz)+baz(bop))'=~/$re/
906         and print "\$1 = $1\n",
907                   "\$2 = $2\n",
908                   "\$3 = $3\n";
909
910 the output produced should be the following:
911
912     $1 = foo(bar(baz)+baz(bop))
913     $2 = (bar(baz)+baz(bop))
914     $3 = bar(baz)+baz(bop)
915
916 If there is no corresponding capture buffer defined, then it is a
917 fatal error.  Recursing deeper than 50 times without consuming any input
918 string will also result in a fatal error.  The maximum depth is compiled
919 into perl, so changing it requires a custom build.
920
921 B<Note> that this pattern does not behave the same way as the equivalent
922 PCRE or Python construct of the same form. In perl you can backtrack into
923 a recursed group, in PCRE and Python the recursed into group is treated
924 as atomic. Also, constructs like (?i:(?1)) or (?:(?i)(?1)) do not affect
925 the pattern being recursed into.
926
927 =item C<(?&NAME)>
928 X<(?&NAME)>
929
930 Recurse to a named subpattern. Identical to (?PARNO) except that the
931 parenthesis to recurse to is determined by name. If multiple parens have
932 the same name, then it recurses to the leftmost.
933
934 It is an error to refer to a name that is not declared somewhere in the
935 pattern.
936
937 =item C<(?(condition)yes-pattern|no-pattern)>
938 X<(?()>
939
940 =item C<(?(condition)yes-pattern)>
941
942 Conditional expression.  C<(condition)> should be either an integer in
943 parentheses (which is valid if the corresponding pair of parentheses
944 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
945 name in angle brackets or single quotes (which is valid if a buffer
946 with the given name matched), or the special symbol (R) (true when
947 evaluated inside of recursion or eval). Additionally the R may be
948 followed by a number, (which will be true when evaluated when recursing
949 inside of the appropriate group), or by C<&NAME>, in which case it will
950 be true only when evaluated during recursion in the named group.
951
952 Here's a summary of the possible predicates:
953
954 =over 4
955
956 =item (1) (2) ...
957
958 Checks if the numbered capturing buffer has matched something.
959
960 =item (<NAME>) ('NAME')
961
962 Checks if a buffer with the given name has matched something.
963
964 =item (?{ CODE })
965
966 Treats the code block as the condition.
967
968 =item (R)
969
970 Checks if the expression has been evaluated inside of recursion.
971
972 =item (R1) (R2) ...
973
974 Checks if the expression has been evaluated while executing directly
975 inside of the n-th capture group. This check is the regex equivalent of
976
977   if ((caller(0))[3] eq 'subname') { ... }
978
979 In other words, it does not check the full recursion stack.
980
981 =item (R&NAME)
982
983 Similar to C<(R1)>, this predicate checks to see if we're executing
984 directly inside of the leftmost group with a given name (this is the same
985 logic used by C<(?&NAME)> to disambiguate). It does not check the full
986 stack, but only the name of the innermost active recursion.
987
988 =item (DEFINE)
989
990 In this case, the yes-pattern is never directly executed, and no
991 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
992 See below for details.
993
994 =back
995
996 For example:
997
998     m{ ( \( )?
999        [^()]+
1000        (?(1) \) )
1001      }x
1002
1003 matches a chunk of non-parentheses, possibly included in parentheses
1004 themselves.
1005
1006 A special form is the C<(DEFINE)> predicate, which never executes directly
1007 its yes-pattern, and does not allow a no-pattern. This allows to define
1008 subpatterns which will be executed only by using the recursion mechanism.
1009 This way, you can define a set of regular expression rules that can be
1010 bundled into any pattern you choose.
1011
1012 It is recommended that for this usage you put the DEFINE block at the
1013 end of the pattern, and that you name any subpatterns defined within it.
1014
1015 Also, it's worth noting that patterns defined this way probably will
1016 not be as efficient, as the optimiser is not very clever about
1017 handling them.
1018
1019 An example of how this might be used is as follows:
1020
1021   /(?<NAME>(&NAME_PAT))(?<ADDR>(&ADDRESS_PAT))
1022    (?(DEFINE)
1023      (<NAME_PAT>....)
1024      (<ADRESS_PAT>....)
1025    )/x
1026
1027 Note that capture buffers matched inside of recursion are not accessible
1028 after the recursion returns, so the extra layer of capturing buffers are
1029 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1030 C<$+{NAME}> would be.
1031
1032 =item C<< (?>pattern) >>
1033 X<backtrack> X<backtracking> X<atomic> X<possessive>
1034
1035 An "independent" subexpression, one which matches the substring
1036 that a I<standalone> C<pattern> would match if anchored at the given
1037 position, and it matches I<nothing other than this substring>.  This
1038 construct is useful for optimizations of what would otherwise be
1039 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1040 It may also be useful in places where the "grab all you can, and do not
1041 give anything back" semantic is desirable.
1042
1043 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1044 (anchored at the beginning of string, as above) will match I<all>
1045 characters C<a> at the beginning of string, leaving no C<a> for
1046 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1047 since the match of the subgroup C<a*> is influenced by the following
1048 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1049 C<a*ab> will match fewer characters than a standalone C<a*>, since
1050 this makes the tail match.
1051
1052 An effect similar to C<< (?>pattern) >> may be achieved by writing
1053 C<(?=(pattern))\1>.  This matches the same substring as a standalone
1054 C<a+>, and the following C<\1> eats the matched string; it therefore
1055 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1056 (The difference between these two constructs is that the second one
1057 uses a capturing group, thus shifting ordinals of backreferences
1058 in the rest of a regular expression.)
1059
1060 Consider this pattern:
1061
1062     m{ \(
1063           (
1064             [^()]+              # x+
1065           |
1066             \( [^()]* \)
1067           )+
1068        \)
1069      }x
1070
1071 That will efficiently match a nonempty group with matching parentheses
1072 two levels deep or less.  However, if there is no such group, it
1073 will take virtually forever on a long string.  That's because there
1074 are so many different ways to split a long string into several
1075 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1076 to a subpattern of the above pattern.  Consider how the pattern
1077 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1078 seconds, but that each extra letter doubles this time.  This
1079 exponential performance will make it appear that your program has
1080 hung.  However, a tiny change to this pattern
1081
1082     m{ \(
1083           (
1084             (?> [^()]+ )        # change x+ above to (?> x+ )
1085           |
1086             \( [^()]* \)
1087           )+
1088        \)
1089      }x
1090
1091 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1092 this yourself would be a productive exercise), but finishes in a fourth
1093 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1094 however, that this pattern currently triggers a warning message under
1095 the C<use warnings> pragma or B<-w> switch saying it
1096 C<"matches null string many times in regex">.
1097
1098 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1099 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1100 This was only 4 times slower on a string with 1000000 C<a>s.
1101
1102 The "grab all you can, and do not give anything back" semantic is desirable
1103 in many situations where on the first sight a simple C<()*> looks like
1104 the correct solution.  Suppose we parse text with comments being delimited
1105 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1106 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1107 the comment delimiter, because it may "give up" some whitespace if
1108 the remainder of the pattern can be made to match that way.  The correct
1109 answer is either one of these:
1110
1111     (?>#[ \t]*)
1112     #[ \t]*(?![ \t])
1113
1114 For example, to grab non-empty comments into $1, one should use either
1115 one of these:
1116
1117     / (?> \# [ \t]* ) (        .+ ) /x;
1118     /     \# [ \t]*   ( [^ \t] .* ) /x;
1119
1120 Which one you pick depends on which of these expressions better reflects
1121 the above specification of comments.
1122
1123 In some literature this construct is called "atomic matching" or
1124 "possessive matching".
1125
1126 Possessive quantifiers are equivalent to putting the item they are applied
1127 to inside of one of these constructs. The following equivalences apply:
1128
1129     Quantifier Form     Bracketing Form
1130     ---------------     ---------------
1131     PAT*+               (?>PAT*)
1132     PAT++               (?>PAT+)
1133     PAT?+               (?>PAT?)
1134     PAT{min,max}+       (?>PAT{min,max})
1135
1136 =back
1137
1138 =head2 Special Backtracking Control Verbs
1139
1140 B<WARNING:> These patterns are experimental and subject to change or
1141 removal in a future version of perl. Their usage in production code should
1142 be noted to avoid problems during upgrades.
1143
1144 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1145 otherwise stated the ARG argument is optional; in some cases, it is
1146 forbidden.
1147
1148 Any pattern containing a special backtracking verb that allows an argument
1149 has the special behaviour that when executed it sets the current packages'
1150 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1151 rules apply:
1152
1153 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1154 verb pattern, if the verb was involved in the failure of the match. If the
1155 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1156 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1157 none. Also, the C<$REGMARK> variable will be set to FALSE.
1158
1159 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1160 the C<$REGMARK> variable will be set to the name of the last
1161 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1162 C<(*MARK:NAME)> verb below for more details.
1163
1164 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1165 and most other regex related variables. They are not local to a scope, nor
1166 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1167 Use C<local> to localize changes to them to a specific scope if necessary.
1168
1169 If a pattern does not contain a special backtracking verb that allows an
1170 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1171
1172 =over 4
1173
1174 =item Verbs that take an argument
1175
1176 =over 4
1177
1178 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1179 X<(*PRUNE)> X<(*PRUNE:NAME)>
1180
1181 This zero-width pattern prunes the backtracking tree at the current point
1182 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1183 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1184 A may backtrack as necessary to match. Once it is reached, matching
1185 continues in B, which may also backtrack as necessary; however, should B
1186 not match, then no further backtracking will take place, and the pattern
1187 will fail outright at the current starting position.
1188
1189 The following example counts all the possible matching strings in a
1190 pattern (without actually matching any of them).
1191
1192     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1193     print "Count=$count\n";
1194
1195 which produces:
1196
1197     aaab
1198     aaa
1199     aa
1200     a
1201     aab
1202     aa
1203     a
1204     ab
1205     a
1206     Count=9
1207
1208 If we add a C<(*PRUNE)> before the count like the following
1209
1210     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1211     print "Count=$count\n";
1212
1213 we prevent backtracking and find the count of the longest matching
1214 at each matching startpoint like so:
1215
1216     aaab
1217     aab
1218     ab
1219     Count=3
1220
1221 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1222
1223 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1224 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1225 replaced with a C<< (?>pattern) >> with no functional difference; however,
1226 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1227 C<< (?>pattern) >> alone.
1228
1229
1230 =item C<(*SKIP)> C<(*SKIP:NAME)>
1231 X<(*SKIP)>
1232
1233 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1234 failure it also signifies that whatever text that was matched leading up
1235 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1236 of this pattern. This effectively means that the regex engine "skips" forward
1237 to this position on failure and tries to match again, (assuming that
1238 there is sufficient room to match).
1239
1240 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1241 C<(*MARK:NAME)> was encountered while matching, then it is that position
1242 which is used as the "skip point". If no C<(*MARK)> of that name was
1243 encountered, then the C<(*SKIP)> operator has no effect. When used
1244 without a name the "skip point" is where the match point was when
1245 executing the (*SKIP) pattern.
1246
1247 Compare the following to the examples in C<(*PRUNE)>, note the string
1248 is twice as long:
1249
1250     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1251     print "Count=$count\n";
1252
1253 outputs
1254
1255     aaab
1256     aaab
1257     Count=2
1258
1259 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1260 executed, the next startpoint will be where the cursor was when the
1261 C<(*SKIP)> was executed.
1262
1263 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1264
1265 =item C<(*MARK:NAME)> C<(*:NAME)>
1266 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1267
1268 This zero-width pattern can be used to mark the point reached in a string
1269 when a certain part of the pattern has been successfully matched. This
1270 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1271 forward to that point if backtracked into on failure. Any number of
1272 C<(*MARK)> patterns are allowed, and the NAME portion is optional and may
1273 be duplicated.
1274
1275 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1276 can be used to "label" a pattern branch, so that after matching, the
1277 program can determine which branches of the pattern were involved in the
1278 match.
1279
1280 When a match is successful, the C<$REGMARK> variable will be set to the
1281 name of the most recently executed C<(*MARK:NAME)> that was involved
1282 in the match.
1283
1284 This can be used to determine which branch of a pattern was matched
1285 without using a seperate capture buffer for each branch, which in turn
1286 can result in a performance improvement, as perl cannot optimize
1287 C</(?:(x)|(y)|(z))/> as efficiently as something like
1288 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1289
1290 When a match has failed, and unless another verb has been involved in
1291 failing the match and has provided its own name to use, the C<$REGERROR>
1292 variable will be set to the name of the most recently executed
1293 C<(*MARK:NAME)>.
1294
1295 See C<(*SKIP)> for more details.
1296
1297 =item C<(*THEN)> C<(*THEN:NAME)>
1298
1299 This is similar to the "cut group" operator C<::> from Perl6. Like
1300 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1301 failure, it causes the regex engine to try the next alternation in the
1302 innermost enclosing group (capturing or otherwise).
1303
1304 Its name comes from the observation that this operation combined with the
1305 alternation operator (C<|>) can be used to create what is essentially a
1306 pattern-based if/then/else block:
1307
1308   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1309
1310 Note that if this operator is used and NOT inside of an alternation then
1311 it acts exactly like the C<(*PRUNE)> operator.
1312
1313   / A (*PRUNE) B /
1314
1315 is the same as
1316
1317   / A (*THEN) B /
1318
1319 but
1320
1321   / ( A (*THEN) B | C (*THEN) D ) /
1322
1323 is not the same as
1324
1325   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1326
1327 as after matching the A but failing on the B the C<(*THEN)> verb will
1328 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1329
1330 =item C<(*COMMIT)>
1331 X<(*COMMIT)>
1332
1333 This is the Perl6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1334 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1335 into on failure it causes the match to fail outright. No further attempts
1336 to find a valid match by advancing the start pointer will occur again.
1337 For example,
1338
1339     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1340     print "Count=$count\n";
1341
1342 outputs
1343
1344     aaab
1345     Count=1
1346
1347 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1348 does not match, the regex engine will not try any further matching on the
1349 rest of the string.
1350
1351 =back
1352
1353 =item Verbs without an argument
1354
1355 =over 4
1356
1357 =item C<(*FAIL)> C<(*F)>
1358 X<(*FAIL)> X<(*F)>
1359
1360 This pattern matches nothing and always fails. It can be used to force the
1361 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1362 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1363
1364 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1365
1366 =item C<(*ACCEPT)>
1367 X<(*ACCEPT)>
1368
1369 B<WARNING:> This feature is highly experimental. It is not recommended
1370 for production code.
1371
1372 This pattern matches nothing and causes the end of successful matching at
1373 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1374 whether there is actually more to match in the string. When inside of a
1375 nested pattern, such as recursion or a dynamically generated subbpattern
1376 via C<(??{})>, only the innermost pattern is ended immediately.
1377
1378 If the C<(*ACCEPT)> is inside of capturing buffers then the buffers are
1379 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1380 For instance:
1381
1382   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1383
1384 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1385 be set. If another branch in the inner parens were matched, such as in the
1386 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1387
1388 =back
1389
1390 =back
1391
1392 =head2 Backtracking
1393 X<backtrack> X<backtracking>
1394
1395 NOTE: This section presents an abstract approximation of regular
1396 expression behavior.  For a more rigorous (and complicated) view of
1397 the rules involved in selecting a match among possible alternatives,
1398 see L<Combining pieces together>.
1399
1400 A fundamental feature of regular expression matching involves the
1401 notion called I<backtracking>, which is currently used (when needed)
1402 by all regular expression quantifiers, namely C<*>, C<*?>, C<+>,
1403 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1404 internally, but the general principle outlined here is valid.
1405
1406 For a regular expression to match, the I<entire> regular expression must
1407 match, not just part of it.  So if the beginning of a pattern containing a
1408 quantifier succeeds in a way that causes later parts in the pattern to
1409 fail, the matching engine backs up and recalculates the beginning
1410 part--that's why it's called backtracking.
1411
1412 Here is an example of backtracking:  Let's say you want to find the
1413 word following "foo" in the string "Food is on the foo table.":
1414
1415     $_ = "Food is on the foo table.";
1416     if ( /\b(foo)\s+(\w+)/i ) {
1417         print "$2 follows $1.\n";
1418     }
1419
1420 When the match runs, the first part of the regular expression (C<\b(foo)>)
1421 finds a possible match right at the beginning of the string, and loads up
1422 $1 with "Foo".  However, as soon as the matching engine sees that there's
1423 no whitespace following the "Foo" that it had saved in $1, it realizes its
1424 mistake and starts over again one character after where it had the
1425 tentative match.  This time it goes all the way until the next occurrence
1426 of "foo". The complete regular expression matches this time, and you get
1427 the expected output of "table follows foo."
1428
1429 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1430 everything between "foo" and "bar".  Initially, you write something
1431 like this:
1432
1433     $_ =  "The food is under the bar in the barn.";
1434     if ( /foo(.*)bar/ ) {
1435         print "got <$1>\n";
1436     }
1437
1438 Which perhaps unexpectedly yields:
1439
1440   got <d is under the bar in the >
1441
1442 That's because C<.*> was greedy, so you get everything between the
1443 I<first> "foo" and the I<last> "bar".  Here it's more effective
1444 to use minimal matching to make sure you get the text between a "foo"
1445 and the first "bar" thereafter.
1446
1447     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1448   got <d is under the >
1449
1450 Here's another example: let's say you'd like to match a number at the end
1451 of a string, and you also want to keep the preceding part of the match.
1452 So you write this:
1453
1454     $_ = "I have 2 numbers: 53147";
1455     if ( /(.*)(\d*)/ ) {                                # Wrong!
1456         print "Beginning is <$1>, number is <$2>.\n";
1457     }
1458
1459 That won't work at all, because C<.*> was greedy and gobbled up the
1460 whole string. As C<\d*> can match on an empty string the complete
1461 regular expression matched successfully.
1462
1463     Beginning is <I have 2 numbers: 53147>, number is <>.
1464
1465 Here are some variants, most of which don't work:
1466
1467     $_ = "I have 2 numbers: 53147";
1468     @pats = qw{
1469         (.*)(\d*)
1470         (.*)(\d+)
1471         (.*?)(\d*)
1472         (.*?)(\d+)
1473         (.*)(\d+)$
1474         (.*?)(\d+)$
1475         (.*)\b(\d+)$
1476         (.*\D)(\d+)$
1477     };
1478
1479     for $pat (@pats) {
1480         printf "%-12s ", $pat;
1481         if ( /$pat/ ) {
1482             print "<$1> <$2>\n";
1483         } else {
1484             print "FAIL\n";
1485         }
1486     }
1487
1488 That will print out:
1489
1490     (.*)(\d*)    <I have 2 numbers: 53147> <>
1491     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1492     (.*?)(\d*)   <> <>
1493     (.*?)(\d+)   <I have > <2>
1494     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1495     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1496     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1497     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1498
1499 As you see, this can be a bit tricky.  It's important to realize that a
1500 regular expression is merely a set of assertions that gives a definition
1501 of success.  There may be 0, 1, or several different ways that the
1502 definition might succeed against a particular string.  And if there are
1503 multiple ways it might succeed, you need to understand backtracking to
1504 know which variety of success you will achieve.
1505
1506 When using look-ahead assertions and negations, this can all get even
1507 trickier.  Imagine you'd like to find a sequence of non-digits not
1508 followed by "123".  You might try to write that as
1509
1510     $_ = "ABC123";
1511     if ( /^\D*(?!123)/ ) {              # Wrong!
1512         print "Yup, no 123 in $_\n";
1513     }
1514
1515 But that isn't going to match; at least, not the way you're hoping.  It
1516 claims that there is no 123 in the string.  Here's a clearer picture of
1517 why that pattern matches, contrary to popular expectations:
1518
1519     $x = 'ABC123';
1520     $y = 'ABC445';
1521
1522     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1523     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1524
1525     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1526     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1527
1528 This prints
1529
1530     2: got ABC
1531     3: got AB
1532     4: got ABC
1533
1534 You might have expected test 3 to fail because it seems to a more
1535 general purpose version of test 1.  The important difference between
1536 them is that test 3 contains a quantifier (C<\D*>) and so can use
1537 backtracking, whereas test 1 will not.  What's happening is
1538 that you've asked "Is it true that at the start of $x, following 0 or more
1539 non-digits, you have something that's not 123?"  If the pattern matcher had
1540 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1541 fail.
1542
1543 The search engine will initially match C<\D*> with "ABC".  Then it will
1544 try to match C<(?!123> with "123", which fails.  But because
1545 a quantifier (C<\D*>) has been used in the regular expression, the
1546 search engine can backtrack and retry the match differently
1547 in the hope of matching the complete regular expression.
1548
1549 The pattern really, I<really> wants to succeed, so it uses the
1550 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1551 time.  Now there's indeed something following "AB" that is not
1552 "123".  It's "C123", which suffices.
1553
1554 We can deal with this by using both an assertion and a negation.
1555 We'll say that the first part in $1 must be followed both by a digit
1556 and by something that's not "123".  Remember that the look-aheads
1557 are zero-width expressions--they only look, but don't consume any
1558 of the string in their match.  So rewriting this way produces what
1559 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1560
1561     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1562     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1563
1564     6: got ABC
1565
1566 In other words, the two zero-width assertions next to each other work as though
1567 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1568 matches only if you're at the beginning of the line AND the end of the
1569 line simultaneously.  The deeper underlying truth is that juxtaposition in
1570 regular expressions always means AND, except when you write an explicit OR
1571 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1572 although the attempted matches are made at different positions because "a"
1573 is not a zero-width assertion, but a one-width assertion.
1574
1575 B<WARNING>: particularly complicated regular expressions can take
1576 exponential time to solve because of the immense number of possible
1577 ways they can use backtracking to try match.  For example, without
1578 internal optimizations done by the regular expression engine, this will
1579 take a painfully long time to run:
1580
1581     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1582
1583 And if you used C<*>'s in the internal groups instead of limiting them
1584 to 0 through 5 matches, then it would take forever--or until you ran
1585 out of stack space.  Moreover, these internal optimizations are not
1586 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1587 on the external group, no current optimization is applicable, and the
1588 match takes a long time to finish.
1589
1590 A powerful tool for optimizing such beasts is what is known as an
1591 "independent group",
1592 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1593 zero-length look-ahead/look-behind assertions will not backtrack to make
1594 the tail match, since they are in "logical" context: only
1595 whether they match is considered relevant.  For an example
1596 where side-effects of look-ahead I<might> have influenced the
1597 following match, see L<C<< (?>pattern) >>>.
1598
1599 =head2 Version 8 Regular Expressions
1600 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1601
1602 In case you're not familiar with the "regular" Version 8 regex
1603 routines, here are the pattern-matching rules not described above.
1604
1605 Any single character matches itself, unless it is a I<metacharacter>
1606 with a special meaning described here or above.  You can cause
1607 characters that normally function as metacharacters to be interpreted
1608 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1609 character; "\\" matches a "\").  A series of characters matches that
1610 series of characters in the target string, so the pattern C<blurfl>
1611 would match "blurfl" in the target string.
1612
1613 You can specify a character class, by enclosing a list of characters
1614 in C<[]>, which will match any character from the list.  If the
1615 first character after the "[" is "^", the class matches any character not
1616 in the list.  Within a list, the "-" character specifies a
1617 range, so that C<a-z> represents all characters between "a" and "z",
1618 inclusive.  If you want either "-" or "]" itself to be a member of a
1619 class, put it at the start of the list (possibly after a "^"), or
1620 escape it with a backslash.  "-" is also taken literally when it is
1621 at the end of the list, just before the closing "]".  (The
1622 following all specify the same class of three characters: C<[-az]>,
1623 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1624 specifies a class containing twenty-six characters, even on EBCDIC-based
1625 character sets.)  Also, if you try to use the character
1626 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1627 a range, the "-" is understood literally.
1628
1629 Note also that the whole range idea is rather unportable between
1630 character sets--and even within character sets they may cause results
1631 you probably didn't expect.  A sound principle is to use only ranges
1632 that begin from and end at either alphabets of equal case ([a-e],
1633 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1634 spell out the character sets in full.
1635
1636 Characters may be specified using a metacharacter syntax much like that
1637 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1638 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1639 of octal digits, matches the character whose coded character set value
1640 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1641 matches the character whose numeric value is I<nn>. The expression \cI<x>
1642 matches the character control-I<x>.  Finally, the "." metacharacter
1643 matches any character except "\n" (unless you use C</s>).
1644
1645 You can specify a series of alternatives for a pattern using "|" to
1646 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1647 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1648 first alternative includes everything from the last pattern delimiter
1649 ("(", "[", or the beginning of the pattern) up to the first "|", and
1650 the last alternative contains everything from the last "|" to the next
1651 pattern delimiter.  That's why it's common practice to include
1652 alternatives in parentheses: to minimize confusion about where they
1653 start and end.
1654
1655 Alternatives are tried from left to right, so the first
1656 alternative found for which the entire expression matches, is the one that
1657 is chosen. This means that alternatives are not necessarily greedy. For
1658 example: when matching C<foo|foot> against "barefoot", only the "foo"
1659 part will match, as that is the first alternative tried, and it successfully
1660 matches the target string. (This might not seem important, but it is
1661 important when you are capturing matched text using parentheses.)
1662
1663 Also remember that "|" is interpreted as a literal within square brackets,
1664 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1665
1666 Within a pattern, you may designate subpatterns for later reference
1667 by enclosing them in parentheses, and you may refer back to the
1668 I<n>th subpattern later in the pattern using the metacharacter
1669 \I<n>.  Subpatterns are numbered based on the left to right order
1670 of their opening parenthesis.  A backreference matches whatever
1671 actually matched the subpattern in the string being examined, not
1672 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1673 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1674 1 matched "0x", even though the rule C<0|0x> could potentially match
1675 the leading 0 in the second number.
1676
1677 =head2 Warning on \1 vs $1
1678
1679 Some people get too used to writing things like:
1680
1681     $pattern =~ s/(\W)/\\\1/g;
1682
1683 This is grandfathered for the RHS of a substitute to avoid shocking the
1684 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1685 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1686 the usual double-quoted string means a control-A.  The customary Unix
1687 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1688 of doing that, you get yourself into trouble if you then add an C</e>
1689 modifier.
1690
1691     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1692
1693 Or if you try to do
1694
1695     s/(\d+)/\1000/;
1696
1697 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1698 C<${1}000>.  The operation of interpolation should not be confused
1699 with the operation of matching a backreference.  Certainly they mean two
1700 different things on the I<left> side of the C<s///>.
1701
1702 =head2 Repeated patterns matching zero-length substring
1703
1704 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1705
1706 Regular expressions provide a terse and powerful programming language.  As
1707 with most other power tools, power comes together with the ability
1708 to wreak havoc.
1709
1710 A common abuse of this power stems from the ability to make infinite
1711 loops using regular expressions, with something as innocuous as:
1712
1713     'foo' =~ m{ ( o? )* }x;
1714
1715 The C<o?> can match at the beginning of C<'foo'>, and since the position
1716 in the string is not moved by the match, C<o?> would match again and again
1717 because of the C<*> modifier.  Another common way to create a similar cycle
1718 is with the looping modifier C<//g>:
1719
1720     @matches = ( 'foo' =~ m{ o? }xg );
1721
1722 or
1723
1724     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1725
1726 or the loop implied by split().
1727
1728 However, long experience has shown that many programming tasks may
1729 be significantly simplified by using repeated subexpressions that
1730 may match zero-length substrings.  Here's a simple example being:
1731
1732     @chars = split //, $string;           # // is not magic in split
1733     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1734
1735 Thus Perl allows such constructs, by I<forcefully breaking
1736 the infinite loop>.  The rules for this are different for lower-level
1737 loops given by the greedy modifiers C<*+{}>, and for higher-level
1738 ones like the C</g> modifier or split() operator.
1739
1740 The lower-level loops are I<interrupted> (that is, the loop is
1741 broken) when Perl detects that a repeated expression matched a
1742 zero-length substring.   Thus
1743
1744    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1745
1746 is made equivalent to
1747
1748    m{   (?: NON_ZERO_LENGTH )*
1749       |
1750         (?: ZERO_LENGTH )?
1751     }x;
1752
1753 The higher level-loops preserve an additional state between iterations:
1754 whether the last match was zero-length.  To break the loop, the following
1755 match after a zero-length match is prohibited to have a length of zero.
1756 This prohibition interacts with backtracking (see L<"Backtracking">),
1757 and so the I<second best> match is chosen if the I<best> match is of
1758 zero length.
1759
1760 For example:
1761
1762     $_ = 'bar';
1763     s/\w??/<$&>/g;
1764
1765 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1766 match given by non-greedy C<??> is the zero-length match, and the I<second
1767 best> match is what is matched by C<\w>.  Thus zero-length matches
1768 alternate with one-character-long matches.
1769
1770 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1771 position one notch further in the string.
1772
1773 The additional state of being I<matched with zero-length> is associated with
1774 the matched string, and is reset by each assignment to pos().
1775 Zero-length matches at the end of the previous match are ignored
1776 during C<split>.
1777
1778 =head2 Combining pieces together
1779
1780 Each of the elementary pieces of regular expressions which were described
1781 before (such as C<ab> or C<\Z>) could match at most one substring
1782 at the given position of the input string.  However, in a typical regular
1783 expression these elementary pieces are combined into more complicated
1784 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1785 (in these examples C<S> and C<T> are regular subexpressions).
1786
1787 Such combinations can include alternatives, leading to a problem of choice:
1788 if we match a regular expression C<a|ab> against C<"abc">, will it match
1789 substring C<"a"> or C<"ab">?  One way to describe which substring is
1790 actually matched is the concept of backtracking (see L<"Backtracking">).
1791 However, this description is too low-level and makes you think
1792 in terms of a particular implementation.
1793
1794 Another description starts with notions of "better"/"worse".  All the
1795 substrings which may be matched by the given regular expression can be
1796 sorted from the "best" match to the "worst" match, and it is the "best"
1797 match which is chosen.  This substitutes the question of "what is chosen?"
1798 by the question of "which matches are better, and which are worse?".
1799
1800 Again, for elementary pieces there is no such question, since at most
1801 one match at a given position is possible.  This section describes the
1802 notion of better/worse for combining operators.  In the description
1803 below C<S> and C<T> are regular subexpressions.
1804
1805 =over 4
1806
1807 =item C<ST>
1808
1809 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1810 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1811 which can be matched by C<T>.
1812
1813 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1814 match than C<A'B'>.
1815
1816 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1817 C<B> is better match for C<T> than C<B'>.
1818
1819 =item C<S|T>
1820
1821 When C<S> can match, it is a better match than when only C<T> can match.
1822
1823 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
1824 two matches for C<T>.
1825
1826 =item C<S{REPEAT_COUNT}>
1827
1828 Matches as C<SSS...S> (repeated as many times as necessary).
1829
1830 =item C<S{min,max}>
1831
1832 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
1833
1834 =item C<S{min,max}?>
1835
1836 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
1837
1838 =item C<S?>, C<S*>, C<S+>
1839
1840 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
1841
1842 =item C<S??>, C<S*?>, C<S+?>
1843
1844 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
1845
1846 =item C<< (?>S) >>
1847
1848 Matches the best match for C<S> and only that.
1849
1850 =item C<(?=S)>, C<(?<=S)>
1851
1852 Only the best match for C<S> is considered.  (This is important only if
1853 C<S> has capturing parentheses, and backreferences are used somewhere
1854 else in the whole regular expression.)
1855
1856 =item C<(?!S)>, C<(?<!S)>
1857
1858 For this grouping operator there is no need to describe the ordering, since
1859 only whether or not C<S> can match is important.
1860
1861 =item C<(??{ EXPR })>, C<(?PARNO)>
1862
1863 The ordering is the same as for the regular expression which is
1864 the result of EXPR, or the pattern contained by capture buffer PARNO.
1865
1866 =item C<(?(condition)yes-pattern|no-pattern)>
1867
1868 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
1869 already determined.  The ordering of the matches is the same as for the
1870 chosen subexpression.
1871
1872 =back
1873
1874 The above recipes describe the ordering of matches I<at a given position>.
1875 One more rule is needed to understand how a match is determined for the
1876 whole regular expression: a match at an earlier position is always better
1877 than a match at a later position.
1878
1879 =head2 Creating custom RE engines
1880
1881 Overloaded constants (see L<overload>) provide a simple way to extend
1882 the functionality of the RE engine.
1883
1884 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
1885 matches at boundary between whitespace characters and non-whitespace
1886 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
1887 at these positions, so we want to have each C<\Y|> in the place of the
1888 more complicated version.  We can create a module C<customre> to do
1889 this:
1890
1891     package customre;
1892     use overload;
1893
1894     sub import {
1895       shift;
1896       die "No argument to customre::import allowed" if @_;
1897       overload::constant 'qr' => \&convert;
1898     }
1899
1900     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
1901
1902     # We must also take care of not escaping the legitimate \\Y|
1903     # sequence, hence the presence of '\\' in the conversion rules.
1904     my %rules = ( '\\' => '\\\\',
1905                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
1906     sub convert {
1907       my $re = shift;
1908       $re =~ s{
1909                 \\ ( \\ | Y . )
1910               }
1911               { $rules{$1} or invalid($re,$1) }sgex;
1912       return $re;
1913     }
1914
1915 Now C<use customre> enables the new escape in constant regular
1916 expressions, i.e., those without any runtime variable interpolations.
1917 As documented in L<overload>, this conversion will work only over
1918 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
1919 part of this regular expression needs to be converted explicitly
1920 (but only if the special meaning of C<\Y|> should be enabled inside $re):
1921
1922     use customre;
1923     $re = <>;
1924     chomp $re;
1925     $re = customre::convert $re;
1926     /\Y|$re\Y|/;
1927
1928 =head1 BUGS
1929
1930 This document varies from difficult to understand to completely
1931 and utterly opaque.  The wandering prose riddled with jargon is
1932 hard to fathom in several places.
1933
1934 This document needs a rewrite that separates the tutorial content
1935 from the reference content.
1936
1937 =head1 SEE ALSO
1938
1939 L<perlrequick>.
1940
1941 L<perlretut>.
1942
1943 L<perlop/"Regexp Quote-Like Operators">.
1944
1945 L<perlop/"Gory details of parsing quoted constructs">.
1946
1947 L<perlfaq6>.
1948
1949 L<perlfunc/pos>.
1950
1951 L<perllocale>.
1952
1953 L<perlebcdic>.
1954
1955 I<Mastering Regular Expressions> by Jeffrey Friedl, published
1956 by O'Reilly and Associates.