This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
031ffa8f2bb5b9121061ba0b9609943d15a05c63
[perl5.git] / dist / Devel-PPPort / Makefile.PL
1 ################################################################################
2 #
3 #  Makefile.PL -- generate Makefile
4 #
5 ################################################################################
6 #
7 #  Version 3.x, Copyright (C) 2004-2013, Marcus Holland-Moritz.
8 #  Version 2.x, Copyright (C) 2001, Paul Marquess.
9 #  Version 1.x, Copyright (C) 1999, Kenneth Albanowski.
10 #
11 #  This program is free software; you can redistribute it and/or
12 #  modify it under the same terms as Perl itself.
13 #
14 ################################################################################
15
16 require 5.003;
17
18 use strict;
19 BEGIN { $^W = 1; }
20
21 use ExtUtils::MakeMaker;
22 use Config;
23
24 use vars '%opt';  # needs to be global, and we can't use 'our'
25
26 unless ($ENV{'PERL_CORE'}) {
27   $ENV{'PERL_CORE'} = 1 if grep { $_ eq 'PERL_CORE=1' } @ARGV;
28 }
29
30 @ARGV = map { /^--with-(apicheck)$/ && ++$opt{$1} ? () : $_ } @ARGV;
31
32 my %mf = (
33   NAME          => 'Devel::PPPort',
34   VERSION_FROM  => 'PPPort_pm.PL',
35   PM            => { 'PPPort.pm' => '$(INST_LIBDIR)/PPPort.pm' },
36   H             => [ qw(ppport.h) ],
37   OBJECT        => 'RealPPPort$(OBJ_EXT) $(O_FILES)',
38   XSPROTOARG    => '-noprototypes',
39   CONFIGURE     => \&configure,
40 );
41 delete $mf{META_MERGE} unless eval { ExtUtils::MakeMaker->VERSION (6.46) };
42 WriteMakefile(%mf);
43
44 sub configure
45 {
46   my @clean    = qw{ $(H_FILES) RealPPPort.xs RealPPPort.c PPPort.pm };
47   my %depend   = ('$(OBJECT)' => '$(H_FILES)');
48   my @C_FILES  = qw{ module2.c module3.c },
49   my %PL_FILES = (
50     'ppport_h.PL'  => 'ppport.h',
51     'PPPort_pm.PL' => 'PPPort.pm',
52     'RealPPPort_xs.PL' => 'RealPPPort.xs',
53     'mktests.PL' => 't/01_test.t',
54   );
55   my @moreopts;
56
57   if (eval $ExtUtils::MakeMaker::VERSION >= 6) {
58     push @moreopts, AUTHOR => 'Marcus Holland-Moritz <mhx@cpan.org>';
59     push @moreopts, ABSTRACT_FROM => 'PPPort_pm.PL';
60   }
61
62   if (eval $ExtUtils::MakeMaker::VERSION >= 6.30_01) {
63     print "Setting license tag...\n";
64     push @moreopts, LICENSE => 'perl';
65   }
66
67   if (not $ENV{'PERL_CORE'}) {
68     # Devel::PPPort is in the core since 5.7.3
69     # 5.11.0+ has site before perl
70     push @moreopts, INSTALLDIRS => (
71       ("$]" >= 5.007003 and "$]" < 5.011)
72         ? 'perl'
73         : 'site'
74     );
75   }
76
77   if ($opt{'apicheck'}) {
78     $PL_FILES{'apicheck_c.PL'} = 'apicheck.c';
79     push @C_FILES, qw{ apicheck.c };
80     push @clean,   qw{ apicheck.c apicheck.i };
81     $depend{'apicheck.i'} = 'ppport.h';
82   }
83
84   open FH, '<PPPort_pm.PL' or die "cannot open PPPort_pm.PL for reading: $!";
85   my $version;
86   while (my $line = <FH>) {
87     ($version) = $line =~ /^\$VERSION = '([\d.]+)';$/ and last;
88   };
89   die 'failed to extract $VERSION from PPPort_pm.PL' if not $version;
90   close FH;
91
92   if ($Config{gccversion}) {
93     my $define = '-W -Wall';
94     $define .= ' -Wdeclaration-after-statement' if $Config{gccversion} =~ /^(\d+\.\d+)\./ && $1 >= 3.4;
95     push @moreopts, DEFINE => $define;
96   }
97
98   return {
99     C        => \@C_FILES,
100     XS       => { 'RealPPPort.xs' => 'RealPPPort.c' },
101     PL_FILES => \%PL_FILES,
102     depend   => \%depend,
103     clean    => { FILES => "@clean" },
104     META_MERGE    => {
105       'meta-spec' => { version => 2 },
106       provides => {
107         'Devel::PPPort' => {
108           file    => 'PPPort_pm.PL',
109           version => $version,
110         },
111       },
112       resources => {
113         bugtracker => {
114           web => 'https://rt.perl.org/rt3/',
115         },
116         repository => {
117           type => 'git',
118           url  => 'git://perl5.git.perl.org/perl.git',
119           web  => 'https://perl5.git.perl.org/perl.git',
120         },
121       },
122     },
123     @moreopts,
124   };
125 }
126
127 sub MY::postamble
128 {
129   package MY;
130   my $post = shift->SUPER::postamble(@_);
131   $post .= <<'POSTAMBLE';
132
133 purge_all: realclean
134         @$(RM_F) PPPort.pm t/*.t
135
136 regen_pm:
137         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) PPPort_pm.PL
138
139 regen_xs:
140         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) RealPPPort_xs.PL
141
142 regen_tests:
143         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) mktests.PL
144
145 regen_h:
146         $(PERL) -I$(INST_ARCHLIB) -I$(INST_LIB) -I$(PERL_ARCHLIB) -I$(PERL_LIB) ppport_h.PL
147
148 regen: regen_pm regen_xs regen_tests regen_h
149
150 POSTAMBLE
151   return $post;
152 }
153
154 sub MY::processPL
155 {
156   package MY;
157   my $original = shift->SUPER::processPL(@_);
158
159   require "./parts/ppptools.pl";
160   my $includes = join ' ', all_files_in_dir('parts/inc');
161
162   my $updated = '';
163   my @rules = split( m{^\s*$}m, $original );
164   foreach my $rule ( @rules ) {
165     if ( $rule =~ m{^\s*^PPPort\.pm\s+:}m ) {
166       $rule =~ s{^(\s*^PPPort\.pm\s+:.*)}{$1 $includes}m; # PPPort.pm depends on all files from parts/inc
167       $rule =~ s{pm_to_blib}{}m; # PPPort.pm must not depend on built PPPort.pm in blib/
168     } elsif ( $rule =~ m{^\s*^ppport\.h\s+:}m ) {
169       $rule =~ s{^(\s*^ppport\.h\s+:.*)}{$1 PPPort.pm}m; # ppport.h depends on PPPort.pm
170       $rule =~ s{pm_to_blib}{}m; # ppport.h is used to build RealPPPort.xs so cannot depend on built PPPort in blib/
171     } elsif ( $rule =~ m{^\s*^RealPPPort\.xs\s+:}m ) {
172       $rule =~ s{^(\s*^RealPPPort\.xs\s+:.*)}{$1 ppport.h}m; # RealPPPort.xs depends on ppport.h
173       $rule =~ s{pm_to_blib}{}m; # RealPPPort.xs is used to build PPPort binary, so it cannot depend on it
174     } elsif ( $rule =~ m{^\s*\S+\b01_test\.t\s+:}m ) {
175       $rule =~ s{^(\s*^\S+\b01_test\.t\s+:.*)}{$1 $includes}m; # all tests in t/ depends on all files from parts/inc
176       $rule =~ s{pm_to_blib}{}m; # Generating test files does not depend on built PPPort in blib/
177     }
178     $updated .= $rule;
179   }
180
181   return $updated;
182 }
183
184 sub MY::dist_core
185 {
186   package MY;
187   my $dist = shift->SUPER::dist_core(@_);
188
189   my $updated = '';
190   my @rules = split( m{^\s*$}m, $dist );
191   foreach my $rule ( @rules ) {
192     if ( $rule =~ m{^\s*^dist\s+:}m ) {
193         $rule =~ s{:}{: manifest}; # make sure we regenerate the manifest
194         $rule .= qq[\t].q[$(NOECHO) $(ECHO) "Warning: Please check '__MAX_PERL__' value in PPPort_pm.PL"].qq[\n];
195     }
196     $updated .= $rule;
197   }
198
199   return $updated;
200 }
201
202
203 sub MY::c_o
204 {
205   package MY;
206   my $co = shift->SUPER::c_o(@_);
207
208   if ($::opt{'apicheck'} && $co !~ /^\.c\.i:/m) {
209     print "Adding custom rule for preprocessed apicheck file...\n";
210
211     $co .= <<'CO'
212
213 .SUFFIXES: .i
214
215 .c.i:
216         $(CCCMD) -E -I$(PERL_INC) $(DEFINE) $*.c > $*.i
217 CO
218   }
219
220   return $co;
221 }