This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: [perl #32949] FileCache only works in "main" package
[perl5.git] / lib / FileCache.pm
1 package FileCache;
2
3 our $VERSION = '1.04_01';
4
5 =head1 NAME
6
7 FileCache - keep more files open than the system permits
8
9 =head1 SYNOPSIS
10
11     use FileCache;
12     # or
13     use FileCache maxopen => 16;
14
15     cacheout $mode, $path;
16     # or
17     cacheout $path;
18     print $path @data;
19
20     $fh = cacheout $mode, $path;
21     # or
22     $fh = cacheout $path;
23     print $fh @data;
24
25 =head1 DESCRIPTION
26
27 The C<cacheout> function will make sure that there's a filehandle open
28 for reading or writing available as the pathname you give it. It
29 automatically closes and re-opens files if you exceed your system's
30 maximum number of file descriptors, or the suggested maximum I<maxopen>.
31
32 =over
33
34 =item cacheout EXPR
35
36 The 1-argument form of cacheout will open a file for writing (C<< '>' >>)
37 on it's first use, and appending (C<<< '>>' >>>) thereafter.
38
39 Returns EXPR on success for convenience. You may neglect the
40 return value and manipulate EXPR as the filehandle directly if you prefer.
41
42 =item cacheout MODE, EXPR
43
44 The 2-argument form of cacheout will use the supplied mode for the initial
45 and subsequent openings. Most valid modes for 3-argument C<open> are supported
46 namely; C<< '>' >>, C<< '+>' >>, C<< '<' >>, C<< '<+' >>, C<<< '>>' >>>,
47 C< '|-' > and C< '-|' >
48
49 To pass supplemental arguments to a program opened with C< '|-' > or C< '-|' >
50 append them to the command string as you would system EXPR.
51
52 Returns EXPR on success for convenience. You may neglect the
53 return value and manipulate EXPR as the filehandle directly if you prefer.
54
55 =head1 CAVEATS
56
57 While it is permissible to C<close> a FileCache managed file,
58 do not do so if you are calling C<FileCache::cacheout> from a package other
59 than which it was imported, or with another module which overrides C<close>.
60 If you must, use C<FileCache::cacheout_close>.
61
62 Although FileCache can be used with piped opens ('-|' or '|-') doing so is
63 strongly discouraged.  If FileCache finds it necessary to close and then reopen
64 a pipe, the command at the far end of the pipe will be reexecuted - the results
65 of performing IO on FileCache'd pipes is unlikely to be what you expect.  The
66 ability to use FileCache on pipes may be removed in a future release.
67
68 FileCache does not store the current file offset if it finds it necessary to
69 close a file.  When the file is reopened, the offset will be as specified by the
70 original C<open> file mode.  This could be construed to be a bug.
71
72 =head1 BUGS
73
74 F<sys/param.h> lies with its C<NOFILE> define on some systems,
75 so you may have to set I<maxopen> yourself.
76
77 =cut
78
79 require 5.006;
80 use Carp;
81 use Config;
82 use strict;
83 no strict 'refs';
84 # These are not C<my> for legacy reasons.
85 # Previous versions requested the user set $cacheout_maxopen by hand.
86 # Some authors fiddled with %saw to overcome the clobber on initial open.
87 use vars qw(%saw $cacheout_maxopen @EXPORT);
88 my %isopen;
89 my $cacheout_seq = 0;
90
91 sub import {
92     my ($pkg,%args) = @_;
93
94     # Not using Exporter is naughty.
95     # Also, using caller(1) is just wrong.
96     #$pkg = caller(1);
97     #*{$pkg.'::cacheout'} = \&cacheout;
98     #*{$pkg.'::close'}    = \&cacheout_close;
99
100     # Use Exporter. %args are for us, not Exporter.
101     # Make sure to up export_to_level, or we will import into ourselves,
102     # rather than our calling package;
103     use base 'Exporter';
104     @EXPORT = qw[cacheout cacheout_close];
105
106     __PACKAGE__->export_to_level(1);
107     Exporter::import( $pkg );
108
109     # Truth is okay here because setting maxopen to 0 would be bad
110     return $cacheout_maxopen = $args{maxopen} if $args{maxopen};
111     foreach my $param ( '/usr/include/sys/param.h' ){
112       if (open($param, '<', $param)) {
113         local ($_, $.);
114         while (<$param>) {
115           if( /^\s*#\s*define\s+NOFILE\s+(\d+)/ ){
116             $cacheout_maxopen = $1 - 4;
117             close($param);
118             last;
119           }
120         }
121         close $param;
122       }
123     }
124     $cacheout_maxopen ||= 16;
125 }
126
127 # Open in their package.
128 sub cacheout_open {
129   return open(*{caller(1) . '::' . $_[1]}, $_[0], $_[1]) && $_[1];
130 }
131
132 # Close in their package.
133 sub cacheout_close {
134   # Short-circuit in case the filehandle disappeared
135   my $pkg = caller($_[1]||0);
136   fileno(*{$pkg . '::' . $_[0]}) &&
137     CORE::close(*{$pkg . '::' . $_[0]});
138   delete $isopen{$_[0]};
139 }
140
141 # But only this sub name is visible to them.
142 sub cacheout {
143     my($mode, $file, $class, $ret, $ref, $narg);
144     croak "Not enough arguments for cacheout"  unless $narg = scalar @_;
145     croak "Too many arguments for cacheout"    if $narg > 2;
146
147     ($mode, $file) = @_;
148     ($file, $mode) = ($mode, $file) if $narg == 1;
149     croak "Invalid mode for cacheout" if $mode &&
150       ( $mode !~ /^\s*(?:>>|\+?>|\+?<|\|\-|)|\-\|\s*$/ );
151
152     # Mode changed?
153     if( $isopen{$file} && ($mode||'>') ne $isopen{$file}->[1] ){
154       &cacheout_close($file, 1);
155     }
156     
157     if( $isopen{$file}) {
158       $ret = $file;
159       $isopen{$file}->[0]++;
160     }
161     else{
162       if( scalar keys(%isopen) > $cacheout_maxopen -1 ) {
163         my @lru = sort{ $isopen{$a}->[0] <=> $isopen{$b}->[0] } keys(%isopen);
164         $cacheout_seq = 0;
165         $isopen{$_}->[0] = $cacheout_seq++ for
166           splice(@lru, int($cacheout_maxopen / 3)||$cacheout_maxopen);
167         &cacheout_close($_, 1) for @lru;
168       }
169
170       unless( $ref ){
171         $mode ||= $saw{$file} ? '>>' : ($saw{$file}=1, '>');
172       }
173       #XXX should we just return the value from cacheout_open, no croak?
174       $ret = cacheout_open($mode, $file) or croak("Can't create $file: $!");
175       
176       $isopen{$file} = [++$cacheout_seq, $mode];
177     }
178     return $ret;
179 }
180 1;