This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Add --gold option to bisect.pl for the revision to use for "recent" files.
[perl5.git] / Porting / bisect.pl
1 #!/usr/bin/perl -w
2 use strict;
3
4 =for comment
5
6 Documentation for this is in bisect-runner.pl
7
8 =cut
9
10 # The default, auto_abbrev will treat -e as an abbreviation of --end
11 # Which isn't what we want.
12 use Getopt::Long qw(:config pass_through no_auto_abbrev);
13
14 my ($start, $end, $validate, $usage, $bad, $jobs, $make, $gold);
15 $bad = !GetOptions('start=s' => \$start, 'end=s' => \$end,
16                    'jobs|j=i' => \$jobs, 'make=s' => \$make, 'gold=s' => \$gold,
17                    validate => \$validate, 'usage|help|?' => \$usage);
18 unshift @ARGV, '--help' if $bad || $usage;
19 unshift @ARGV, '--validate' if $validate;
20
21 my $runner = $0;
22 $runner =~ s/bisect\.pl/bisect-runner.pl/;
23
24 die "Can't find bisect runner $runner" unless -f $runner;
25
26 system $^X, $runner, '--check-args', '--check-shebang', @ARGV and exit 255;
27 exit 255 if $bad;
28 exit 0 if $usage;
29
30 {
31     my ($dev0, $ino0) = stat $0;
32     die "Can't stat $0: $!" unless defined $ino0;
33     my ($dev1, $ino1) = stat 'Porting/bisect.pl';
34     die "Can't run a bisect using the directory containing $runner"
35       if defined $dev1 && $dev0 == $dev1 && $ino0 == $ino1;
36 }
37
38 my $start_time = time;
39
40 if (!defined $jobs &&
41     !($^O eq 'hpux' && system((defined $make ? $make : 'make')
42                               . ' --version >/dev/null 2>&1'))) {
43     # Try to default to (ab)use all the CPUs:
44     my $cpus;
45     if (open my $fh, '<', '/proc/cpuinfo') {
46         while (<$fh>) {
47             ++$cpus if /^processor\s+:\s+\d+$/;
48         }
49     } elsif (-x '/sbin/sysctl') {
50         $cpus =  $1 if `/sbin/sysctl hw.ncpu` =~ /^hw\.ncpu: (\d+)$/;
51     } elsif (-x '/usr/bin/getconf') {
52         $cpus = $1 if `/usr/bin/getconf _NPROCESSORS_ONLN` =~ /^(\d+)$/;
53     }
54     $jobs = defined $cpus ? $cpus + 1 : 2;
55 }
56
57 unshift @ARGV, '--jobs', $jobs if defined $jobs;
58 unshift @ARGV, '--make', $make if defined $make;
59
60 # We try these in this order for the start revision if none is specified.
61 my @stable = map {chomp $_; $_} grep {/v5\.[0-9]+[02468]\.0$/} `git tag -l`;
62 die "git tag -l didn't seem to return any tags for stable releases"
63     unless @stable;
64 unshift @stable, qw(perl-5.005 perl-5.6.0 perl-5.8.0);
65
66 {
67     my ($dev_C, $ino_C) = stat 'Configure';
68     my ($dev_c, $ino_c) = stat 'configure';
69     if (defined $dev_C && defined $dev_c
70         && $dev_C == $dev_c && $ino_C == $ino_c) {
71         print "You seem to be on a case-insensitive file system.\n\n";
72     } else {
73         unshift @stable, qw(perl-5.002 perl-5.003 perl-5.004)
74     }
75 }
76
77 unshift @ARGV, '--gold', defined $gold ? $gold : $stable[-1];
78
79 $end = 'blead' unless defined $end;
80
81 # Canonicalising branches to revisions before moving the checkout permits one
82 # to use revisions such as 'HEAD' for --start or --end
83 foreach ($start, $end) {
84     next unless $_;
85     $_ = `git rev-parse $_`;
86     die unless defined $_;
87     chomp;
88 }
89
90 my $modified = my @modified = `git ls-files --modified --deleted --others`;
91
92 die "This checkout is not clean, found file(s):\n",
93     join("\t","",@modified),
94     "$modified modified, untracked, or other file(s)\n",
95     "These files may not show in git status as they may be ignored.\n",
96     "You can use 'git clean -Xdf' to cleanup the ignored files.\n"
97     if $modified;
98
99 sub validate {
100     my $commit = shift;
101     if (defined $start && `git rev-list -n1 $commit ^$start^` eq "") {
102         print "Skipping $commit, as it is earlier than $start\n";
103         return;
104     }
105     if (defined $end && `git rev-list -n1 $end ^$commit^` eq "") {
106         print "Skipping $commit, as it is more recent than $end\n";
107         return;
108     }
109     print "Testing $commit...\n";
110     system "git checkout $commit </dev/null" and die;
111     my $ret = system $^X, $runner, '--no-clean', @ARGV;
112     die "Runner returned $ret, not 0 for revision $commit" if $ret;
113     system 'git clean -dxf </dev/null' and die;
114     system 'git reset --hard HEAD </dev/null' and die;
115     return $commit;
116 }
117
118 if ($validate) {
119     require Text::Wrap;
120     my @built = map {validate $_} 'blead', reverse @stable;
121     if (@built) {
122         print Text::Wrap::wrap("", "", "Successfully validated @built\n");
123         exit 0;
124     }
125     print "Did not validate anything\n";
126     exit 1;
127 }
128
129 my $git_version = `git --version`;
130 if (defined $git_version
131     && $git_version =~ /\Agit version (\d+\.\d+\.\d+)(.*)/) {
132     $git_version = eval "v$1";
133 } else {
134     $git_version = v0.0.0;
135 }
136
137 if ($git_version ge v1.6.6) {
138     system "git bisect reset HEAD" and die;
139 } else {
140     system "git bisect reset" and die;
141 }
142
143 # Sanity check the first and last revisions:
144 system "git checkout $end" and die;
145 my $ret = system $^X, $runner, @ARGV;
146 die "Runner returned $ret for end revision" unless $ret;
147 die "Runner returned $ret for end revision, which is a skip"
148     if $ret == 125 * 256;
149
150 if (defined $start) {
151     system "git checkout $start" and die;
152     my $ret = system $^X, $runner, @ARGV;
153     die "Runner returned $ret, not 0 for start revision" if $ret;
154 } else {
155     # Try to find the earliest version for which the test works
156     my @tried;
157     foreach my $try (@stable) {
158         if (`git rev-list -n1 $end ^$try^` eq "") {
159             print "Skipping $try, as it is more recent than end commit "
160                 . (substr $end, 0, 16) . "\n";
161             # As @stable is supposed to be in age order, arguably we should
162             # last; here.
163             next;
164         }
165         system "git checkout $try" and die;
166         my $ret = system $^X, $runner, @ARGV;
167         if (!$ret) {
168             $start = $try;
169             last;
170         }
171         push @tried, $try;
172     }
173     die "Can't find a suitable start revision to default to.\nTried @tried"
174         unless defined $start;
175 }
176
177 system "git bisect start" and die;
178 system "git bisect good $start" and die;
179 system "git bisect bad $end" and die;
180
181 # And now get git bisect to do the hard work:
182 system 'git', 'bisect', 'run', $^X, $runner, @ARGV and die;
183
184 END {
185     my $end_time = time;
186
187     printf "That took %d seconds\n", $end_time - $start_time
188         if defined $start_time;
189 }
190
191 =for comment
192
193 Documentation for this is in bisect-runner.pl
194
195 =cut
196
197 # Local variables:
198 # cperl-indent-level: 4
199 # indent-tabs-mode: nil
200 # End:
201 #
202 # ex: set ts=8 sts=4 sw=4 et: