This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Display the native pwd command.
[perl5.git] / ext / Cwd / t / cwd.t
1 #!./perl
2
3 BEGIN {
4     chdir 't' if -d 't';
5     @INC = '../lib';
6 }
7
8 use Config;
9 use Cwd;
10 use strict;
11 use warnings;
12 use File::Path;
13
14 use Test::More tests => 16;
15
16 my $IsVMS = $^O eq 'VMS';
17
18 # check imports
19 can_ok('main', qw(cwd getcwd fastcwd fastgetcwd));
20 ok( !defined(&chdir),           'chdir() not exported by default' );
21 ok( !defined(&abs_path),        '  nor abs_path()' );
22 ok( !defined(&fast_abs_path),   '  nor fast_abs_path()');
23
24
25 # XXX force Cwd to bootsrap its XSUBs since we have set @INC = "../lib"
26 # XXX and subsequent chdir()s can make them impossible to find
27 eval { fastcwd };
28
29 # Must find an external pwd (or equivalent) command.
30
31 my $pwd_cmd =
32     ($^O eq "MSWin32" || $^O eq "NetWare") ?
33         "cd" :
34         (grep { -x && -f } map { "$_/pwd" }
35                            split m/$Config{path_sep}/, $ENV{PATH})[0];
36
37 $pwd_cmd = 'SHOW DEFAULT' if $IsVMS;
38
39 print "# native pwd = '$pwd_cmd'\n";
40
41 SKIP: {
42     skip "No native pwd command found to test against", 4 unless $pwd_cmd;
43
44     chomp(my $start = `$pwd_cmd`);
45     # Win32's cd returns native C:\ style
46     $start =~ s,\\,/,g if ($^O eq 'MSWin32' || $^O eq "NetWare");
47     # DCL SHOW DEFAULT has leading spaces
48     $start =~ s/^\s+// if $IsVMS;
49     SKIP: {
50         skip "'$pwd_cmd' failed, nothing to test against", 4 if $?;
51
52         my $cwd        = cwd;
53         my $getcwd     = getcwd;
54         my $fastcwd    = fastcwd;
55         my $fastgetcwd = fastgetcwd;
56         is(cwd(),       $start, 'cwd()');
57         is(getcwd(),    $start, 'getcwd()');
58         is(fastcwd(),   $start, 'fastcwd()');
59         is(fastgetcwd(),$start, 'fastgetcwd()');
60     }
61 }
62
63 my $Top_Test_Dir = '_ptrslt_';
64 my $Test_Dir     = "$Top_Test_Dir/_path_/_to_/_a_/_dir_";
65 my $want = "t/$Test_Dir";
66 if( $IsVMS ) {
67     # translate the unixy path to VMSish
68     $want = uc $want;
69     $want =~ s|/|\.|g;
70     $want .= '\]';
71 }
72
73 mkpath(["$Test_Dir"], 0, 0777);
74 Cwd::chdir "$Test_Dir";
75
76 like(cwd(),        qr|$want$|, 'chdir() + cwd()');
77 like(getcwd(),     qr|$want$|, '        + getcwd()');    
78 like(fastcwd(),    qr|$want$|, '        + fastcwd()');
79 like(fastgetcwd(), qr|$want$|, '        + fastgetcwd()');
80
81 # Cwd::chdir should also update $ENV{PWD}
82 like($ENV{PWD}, qr|$want$|,      'Cwd::chdir() updates $ENV{PWD}');
83 Cwd::chdir "..";
84 print "#$ENV{PWD}\n";
85 Cwd::chdir "..";
86 print "#$ENV{PWD}\n";
87 Cwd::chdir "..";
88 print "#$ENV{PWD}\n";
89 Cwd::chdir "..";
90 print "#$ENV{PWD}\n";
91 Cwd::chdir "..";
92 print "#$ENV{PWD}\n";
93
94 rmtree([$Top_Test_Dir], 0, 0);
95
96 if ($IsVMS) {
97     like($ENV{PWD}, qr|\bT\]$|);
98 }
99 else {
100     like($ENV{PWD}, qr|\bt$|);
101 }
102
103 SKIP: {
104     skip "no symlinks on this platform", 2 unless $Config{d_symlink};
105
106     mkpath([$Test_Dir], 0, 0777);
107     symlink $Test_Dir => "linktest";
108
109     my $abs_path      =  Cwd::abs_path("linktest");
110     my $fast_abs_path =  Cwd::fast_abs_path("linktest");
111     my $want          = "t/$Test_Dir";
112
113     like($abs_path,      qr|$want$|);
114     like($fast_abs_path, qr|$want$|);
115
116     rmtree([$Top_Test_Dir], 0, 0);
117     unlink "linktest";
118 }