This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Indexing and POD fixes
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 =head2 Operator Precedence and Associativity
9 X<operator, precedence> X<precedence> X<associativity>
10
11 Operator precedence and associativity work in Perl more or less like
12 they do in mathematics.
13
14 I<Operator precedence> means some operators are evaluated before
15 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
16 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
17 22> and not C<6 * 5 == 30>.
18
19 I<Operator associativity> defines what happens if a sequence of the
20 same operators is used one after another: whether the evaluator will
21 evaluate the left operations first or the right.  For example, in C<8
22 - 4 - 2>, subtraction is left associative so Perl evaluates the
23 expression left to right.  C<8 - 4> is evaluated first making the
24 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
25
26 Perl operators have the following associativity and precedence,
27 listed from highest precedence to lowest.  Operators borrowed from
28 C keep the same precedence relationship with each other, even where
29 C's precedence is slightly screwy.  (This makes learning Perl easier
30 for C folks.)  With very few exceptions, these all operate on scalar
31 values only, not array values.
32
33     left        terms and list operators (leftward)
34     left        ->
35     nonassoc    ++ --
36     right       **
37     right       ! ~ \ and unary + and -
38     left        =~ !~
39     left        * / % x
40     left        + - .
41     left        << >>
42     nonassoc    named unary operators
43     nonassoc    < > <= >= lt gt le ge
44     nonassoc    == != <=> eq ne cmp ~~
45     left        &
46     left        | ^
47     left        &&
48     left        || //
49     nonassoc    ..  ...
50     right       ?:
51     right       = += -= *= etc.
52     left        , =>
53     nonassoc    list operators (rightward)
54     right       not
55     left        and
56     left        or xor err
57
58 In the following sections, these operators are covered in precedence order.
59
60 Many operators can be overloaded for objects.  See L<overload>.
61
62 =head2 Terms and List Operators (Leftward)
63 X<list operator> X<operator, list> X<term>
64
65 A TERM has the highest precedence in Perl.  They include variables,
66 quote and quote-like operators, any expression in parentheses,
67 and any function whose arguments are parenthesized.  Actually, there
68 aren't really functions in this sense, just list operators and unary
69 operators behaving as functions because you put parentheses around
70 the arguments.  These are all documented in L<perlfunc>.
71
72 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
73 is followed by a left parenthesis as the next token, the operator and
74 arguments within parentheses are taken to be of highest precedence,
75 just like a normal function call.
76
77 In the absence of parentheses, the precedence of list operators such as
78 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
79 whether you are looking at the left side or the right side of the operator.
80 For example, in
81
82     @ary = (1, 3, sort 4, 2);
83     print @ary;         # prints 1324
84
85 the commas on the right of the sort are evaluated before the sort,
86 but the commas on the left are evaluated after.  In other words,
87 list operators tend to gobble up all arguments that follow, and
88 then act like a simple TERM with regard to the preceding expression.
89 Be careful with parentheses:
90
91     # These evaluate exit before doing the print:
92     print($foo, exit);  # Obviously not what you want.
93     print $foo, exit;   # Nor is this.
94
95     # These do the print before evaluating exit:
96     (print $foo), exit; # This is what you want.
97     print($foo), exit;  # Or this.
98     print ($foo), exit; # Or even this.
99
100 Also note that
101
102     print ($foo & 255) + 1, "\n";
103
104 probably doesn't do what you expect at first glance.  The parentheses
105 enclose the argument list for C<print> which is evaluated (printing
106 the result of C<$foo & 255>).  Then one is added to the return value
107 of C<print> (usually 1).  The result is something like this:
108
109     1 + 1, "\n";    # Obviously not what you meant.
110
111 To do what you meant properly, you must write:
112
113     print(($foo & 255) + 1, "\n");
114
115 See L<Named Unary Operators> for more discussion of this.
116
117 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
118 well as subroutine and method calls, and the anonymous
119 constructors C<[]> and C<{}>.
120
121 See also L<Quote and Quote-like Operators> toward the end of this section,
122 as well as L</"I/O Operators">.
123
124 =head2 The Arrow Operator
125 X<arrow> X<dereference> X<< -> >>
126
127 "C<< -> >>" is an infix dereference operator, just as it is in C
128 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
129 C<(...)> subscript, then the left side must be either a hard or
130 symbolic reference to an array, a hash, or a subroutine respectively.
131 (Or technically speaking, a location capable of holding a hard
132 reference, if it's an array or hash reference being used for
133 assignment.)  See L<perlreftut> and L<perlref>.
134
135 Otherwise, the right side is a method name or a simple scalar
136 variable containing either the method name or a subroutine reference,
137 and the left side must be either an object (a blessed reference)
138 or a class name (that is, a package name).  See L<perlobj>.
139
140 =head2 Auto-increment and Auto-decrement
141 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
142
143 "++" and "--" work as in C.  That is, if placed before a variable,
144 they increment or decrement the variable by one before returning the
145 value, and if placed after, increment or decrement after returning the
146 value.
147
148     $i = 0;  $j = 0;
149     print $i++;  # prints 0
150     print ++$j;  # prints 1
151
152 Note that just as in C, Perl doesn't define B<when> the variable is
153 incremented or decremented. You just know it will be done sometime
154 before or after the value is returned. This also means that modifying
155 a variable twice in the same statement will lead to undefined behaviour.
156 Avoid statements like:
157
158     $i = $i ++;
159     print ++ $i + $i ++;
160
161 Perl will not guarantee what the result of the above statements is.
162
163 The auto-increment operator has a little extra builtin magic to it.  If
164 you increment a variable that is numeric, or that has ever been used in
165 a numeric context, you get a normal increment.  If, however, the
166 variable has been used in only string contexts since it was set, and
167 has a value that is not the empty string and matches the pattern
168 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
169 character within its range, with carry:
170
171     print ++($foo = '99');      # prints '100'
172     print ++($foo = 'a0');      # prints 'a1'
173     print ++($foo = 'Az');      # prints 'Ba'
174     print ++($foo = 'zz');      # prints 'aaa'
175
176 C<undef> is always treated as numeric, and in particular is changed
177 to C<0> before incrementing (so that a post-increment of an undef value
178 will return C<0> rather than C<undef>).
179
180 The auto-decrement operator is not magical.
181
182 =head2 Exponentiation
183 X<**> X<exponentiation> X<power>
184
185 Binary "**" is the exponentiation operator.  It binds even more
186 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
187 implemented using C's pow(3) function, which actually works on doubles
188 internally.)
189
190 =head2 Symbolic Unary Operators
191 X<unary operator> X<operator, unary>
192
193 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
194 precedence version of this.
195 X<!>
196
197 Unary "-" performs arithmetic negation if the operand is numeric.  If
198 the operand is an identifier, a string consisting of a minus sign
199 concatenated with the identifier is returned.  Otherwise, if the string
200 starts with a plus or minus, a string starting with the opposite sign
201 is returned.  One effect of these rules is that -bareword is equivalent
202 to the string "-bareword".  If, however, the string begins with a
203 non-alphabetic character (exluding "+" or "-"), Perl will attempt to convert
204 the string to a numeric and the arithmetic negation is performed. If the
205 string cannot be cleanly converted to a numeric, Perl will give the warning
206 B<Argument "the string" isn't numeric in negation (-) at ...>.
207 X<-> X<negation, arithmetic>
208
209 Unary "~" performs bitwise negation, i.e., 1's complement.  For
210 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
211 L<Bitwise String Operators>.)  Note that the width of the result is
212 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
213 bits wide on a 64-bit platform, so if you are expecting a certain bit
214 width, remember to use the & operator to mask off the excess bits.
215 X<~> X<negation, binary>
216
217 Unary "+" has no effect whatsoever, even on strings.  It is useful
218 syntactically for separating a function name from a parenthesized expression
219 that would otherwise be interpreted as the complete list of function
220 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
221 X<+>
222
223 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
224 and L<perlref>.  Do not confuse this behavior with the behavior of
225 backslash within a string, although both forms do convey the notion
226 of protecting the next thing from interpolation.
227 X<\> X<reference> X<backslash>
228
229 =head2 Binding Operators
230 X<binding> X<operator, binding> X<=~> X<!~>
231
232 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
233 search or modify the string $_ by default.  This operator makes that kind
234 of operation work on some other string.  The right argument is a search
235 pattern, substitution, or transliteration.  The left argument is what is
236 supposed to be searched, substituted, or transliterated instead of the default
237 $_.  When used in scalar context, the return value generally indicates the
238 success of the operation.  Behavior in list context depends on the particular
239 operator.  See L</"Regexp Quote-Like Operators"> for details and
240 L<perlretut> for examples using these operators.
241
242 If the right argument is an expression rather than a search pattern,
243 substitution, or transliteration, it is interpreted as a search pattern at run
244 time. Note that this means that its contents will be interpolated twice, so
245
246   '\\' =~ q'\\';
247
248 is not ok, as the regex engine will end up trying to compile the
249 pattern C<\>, which it will consider a syntax error.
250
251 Binary "!~" is just like "=~" except the return value is negated in
252 the logical sense.
253
254 =head2 Multiplicative Operators
255 X<operator, multiplicative>
256
257 Binary "*" multiplies two numbers.
258 X<*>
259
260 Binary "/" divides two numbers.
261 X</> X<slash>
262
263 Binary "%" computes the modulus of two numbers.  Given integer
264 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
265 C<$a> minus the largest multiple of C<$b> that is not greater than
266 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
267 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
268 result will be less than or equal to zero).  If the operands
269 C<$a> and C<$b> are floating point values and the absolute value of
270 C<$b> (that is C<abs($b)>) is less than C<(UV_MAX + 1)>, only
271 the integer portion of C<$a> and C<$b> will be used in the operation
272 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
273 If the absolute value of the right operand (C<abs($b)>) is greater than
274 or equal to C<(UV_MAX + 1)>, "%" computes the floating-point remainder
275 C<$r> in the equation C<($r = $a - $i*$b)> where C<$i> is a certain
276 integer that makes C<$r> should have the same sign as the right operand
277 C<$b> (B<not> as the left operand C<$a> like C function C<fmod()>)
278 and the absolute value less than that of C<$b>.
279 Note that when C<use integer> is in scope, "%" gives you direct access
280 to the modulus operator as implemented by your C compiler.  This
281 operator is not as well defined for negative operands, but it will
282 execute faster.
283 X<%> X<remainder> X<modulus> X<mod>
284
285 Binary "x" is the repetition operator.  In scalar context or if the left
286 operand is not enclosed in parentheses, it returns a string consisting
287 of the left operand repeated the number of times specified by the right
288 operand.  In list context, if the left operand is enclosed in
289 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
290 If the right operand is zero or negative, it returns an empty string
291 or an empty list, depending on the context.
292 X<x>
293
294     print '-' x 80;             # print row of dashes
295
296     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
297
298     @ones = (1) x 80;           # a list of 80 1's
299     @ones = (5) x @ones;        # set all elements to 5
300
301
302 =head2 Additive Operators
303 X<operator, additive>
304
305 Binary "+" returns the sum of two numbers.
306 X<+>
307
308 Binary "-" returns the difference of two numbers.
309 X<->
310
311 Binary "." concatenates two strings.
312 X<string, concatenation> X<concatenation>
313 X<cat> X<concat> X<concatenate> X<.>
314
315 =head2 Shift Operators
316 X<shift operator> X<operator, shift> X<<< << >>>
317 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
318 X<shl> X<shr> X<shift, right> X<shift, left>
319
320 Binary "<<" returns the value of its left argument shifted left by the
321 number of bits specified by the right argument.  Arguments should be
322 integers.  (See also L<Integer Arithmetic>.)
323
324 Binary ">>" returns the value of its left argument shifted right by
325 the number of bits specified by the right argument.  Arguments should
326 be integers.  (See also L<Integer Arithmetic>.)
327
328 Note that both "<<" and ">>" in Perl are implemented directly using
329 "<<" and ">>" in C.  If C<use integer> (see L<Integer Arithmetic>) is
330 in force then signed C integers are used, else unsigned C integers are
331 used.  Either way, the implementation isn't going to generate results
332 larger than the size of the integer type Perl was built with (32 bits
333 or 64 bits).
334
335 The result of overflowing the range of the integers is undefined
336 because it is undefined also in C.  In other words, using 32-bit
337 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
338 of bits is also undefined.
339
340 =head2 Named Unary Operators
341 X<operator, named unary>
342
343 The various named unary operators are treated as functions with one
344 argument, with optional parentheses.
345
346 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
347 is followed by a left parenthesis as the next token, the operator and
348 arguments within parentheses are taken to be of highest precedence,
349 just like a normal function call.  For example,
350 because named unary operators are higher precedence than ||:
351
352     chdir $foo    || die;       # (chdir $foo) || die
353     chdir($foo)   || die;       # (chdir $foo) || die
354     chdir ($foo)  || die;       # (chdir $foo) || die
355     chdir +($foo) || die;       # (chdir $foo) || die
356
357 but, because * is higher precedence than named operators:
358
359     chdir $foo * 20;    # chdir ($foo * 20)
360     chdir($foo) * 20;   # (chdir $foo) * 20
361     chdir ($foo) * 20;  # (chdir $foo) * 20
362     chdir +($foo) * 20; # chdir ($foo * 20)
363
364     rand 10 * 20;       # rand (10 * 20)
365     rand(10) * 20;      # (rand 10) * 20
366     rand (10) * 20;     # (rand 10) * 20
367     rand +(10) * 20;    # rand (10 * 20)
368
369 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
370 treated like named unary operators, but they don't follow this functional
371 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
372 equivalent to C<-f "$file.bak">.
373 X<-X> X<filetest> X<operator, filetest>
374
375 See also L<"Terms and List Operators (Leftward)">.
376
377 =head2 Relational Operators
378 X<relational operator> X<operator, relational>
379
380 Binary "<" returns true if the left argument is numerically less than
381 the right argument.
382 X<< < >>
383
384 Binary ">" returns true if the left argument is numerically greater
385 than the right argument.
386 X<< > >>
387
388 Binary "<=" returns true if the left argument is numerically less than
389 or equal to the right argument.
390 X<< <= >>
391
392 Binary ">=" returns true if the left argument is numerically greater
393 than or equal to the right argument.
394 X<< >= >>
395
396 Binary "lt" returns true if the left argument is stringwise less than
397 the right argument.
398 X<< lt >>
399
400 Binary "gt" returns true if the left argument is stringwise greater
401 than the right argument.
402 X<< gt >>
403
404 Binary "le" returns true if the left argument is stringwise less than
405 or equal to the right argument.
406 X<< le >>
407
408 Binary "ge" returns true if the left argument is stringwise greater
409 than or equal to the right argument.
410 X<< ge >>
411
412 =head2 Equality Operators
413 X<equality> X<equal> X<equals> X<operator, equality>
414
415 Binary "==" returns true if the left argument is numerically equal to
416 the right argument.
417 X<==>
418
419 Binary "!=" returns true if the left argument is numerically not equal
420 to the right argument.
421 X<!=>
422
423 Binary "<=>" returns -1, 0, or 1 depending on whether the left
424 argument is numerically less than, equal to, or greater than the right
425 argument.  If your platform supports NaNs (not-a-numbers) as numeric
426 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
427 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
428 returns true, as does NaN != anything else. If your platform doesn't
429 support NaNs then NaN is just a string with numeric value 0.
430 X<< <=> >> X<spaceship>
431
432     perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
433     perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
434
435 Binary "eq" returns true if the left argument is stringwise equal to
436 the right argument.
437 X<eq>
438
439 Binary "ne" returns true if the left argument is stringwise not equal
440 to the right argument.
441 X<ne>
442
443 Binary "cmp" returns -1, 0, or 1 depending on whether the left
444 argument is stringwise less than, equal to, or greater than the right
445 argument.
446 X<cmp>
447
448 Binary "~~" does a smart match between its arguments. Smart matching
449 is described in L<perlsyn/"Smart matching in detail">.
450 This operator is only available if you enable the "~~" feature:
451 see L<feature> for more information.
452 X<~~>
453
454 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
455 by the current locale if C<use locale> is in effect.  See L<perllocale>.
456
457 =head2 Bitwise And
458 X<operator, bitwise, and> X<bitwise and> X<&>
459
460 Binary "&" returns its operands ANDed together bit by bit.
461 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
462
463 Note that "&" has lower priority than relational operators, so for example
464 the brackets are essential in a test like
465
466         print "Even\n" if ($x & 1) == 0;
467
468 =head2 Bitwise Or and Exclusive Or
469 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
470 X<bitwise xor> X<^>
471
472 Binary "|" returns its operands ORed together bit by bit.
473 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
474
475 Binary "^" returns its operands XORed together bit by bit.
476 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
477
478 Note that "|" and "^" have lower priority than relational operators, so
479 for example the brackets are essential in a test like
480
481         print "false\n" if (8 | 2) != 10;
482
483 =head2 C-style Logical And
484 X<&&> X<logical and> X<operator, logical, and>
485
486 Binary "&&" performs a short-circuit logical AND operation.  That is,
487 if the left operand is false, the right operand is not even evaluated.
488 Scalar or list context propagates down to the right operand if it
489 is evaluated.
490
491 =head2 C-style Logical Or
492 X<||> X<operator, logical, or>
493
494 Binary "||" performs a short-circuit logical OR operation.  That is,
495 if the left operand is true, the right operand is not even evaluated.
496 Scalar or list context propagates down to the right operand if it
497 is evaluated.
498
499 =head2 C-style Logical Defined-Or
500 X<//> X<operator, logical, defined-or>
501
502 Although it has no direct equivalent in C, Perl's C<//> operator is related
503 to its C-style or.  In fact, it's exactly the same as C<||>, except that it
504 tests the left hand side's definedness instead of its truth.  Thus, C<$a // $b>
505 is similar to C<defined($a) || $b> (except that it returns the value of C<$a>
506 rather than the value of C<defined($a)>) and is exactly equivalent to
507 C<defined($a) ? $a : $b>.  This is very useful for providing default values
508 for variables.  If you actually want to test if at least one of C<$a> and
509 C<$b> is defined, use C<defined($a // $b)>.
510
511 The C<||>, C<//> and C<&&> operators return the last value evaluated
512 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
513 portable way to find out the home directory might be:
514
515     $home = $ENV{'HOME'} // $ENV{'LOGDIR'} //
516         (getpwuid($<))[7] // die "You're homeless!\n";
517
518 In particular, this means that you shouldn't use this
519 for selecting between two aggregates for assignment:
520
521     @a = @b || @c;              # this is wrong
522     @a = scalar(@b) || @c;      # really meant this
523     @a = @b ? @b : @c;          # this works fine, though
524
525 As more readable alternatives to C<&&>, C<//> and C<||> when used for
526 control flow, Perl provides C<and>, C<err> and C<or> operators (see below).
527 The short-circuit behavior is identical.  The precedence of "and", "err"
528 and "or" is much lower, however, so that you can safely use them after a
529 list operator without the need for parentheses:
530
531     unlink "alpha", "beta", "gamma"
532             or gripe(), next LINE;
533
534 With the C-style operators that would have been written like this:
535
536     unlink("alpha", "beta", "gamma")
537             || (gripe(), next LINE);
538
539 Using "or" for assignment is unlikely to do what you want; see below.
540
541 =head2 Range Operators
542 X<operator, range> X<range> X<..> X<...>
543
544 Binary ".." is the range operator, which is really two different
545 operators depending on the context.  In list context, it returns a
546 list of values counting (up by ones) from the left value to the right
547 value.  If the left value is greater than the right value then it
548 returns the empty list.  The range operator is useful for writing
549 C<foreach (1..10)> loops and for doing slice operations on arrays. In
550 the current implementation, no temporary array is created when the
551 range operator is used as the expression in C<foreach> loops, but older
552 versions of Perl might burn a lot of memory when you write something
553 like this:
554
555     for (1 .. 1_000_000) {
556         # code
557     }
558
559 The range operator also works on strings, using the magical auto-increment,
560 see below.
561
562 In scalar context, ".." returns a boolean value.  The operator is
563 bistable, like a flip-flop, and emulates the line-range (comma) operator
564 of B<sed>, B<awk>, and various editors.  Each ".." operator maintains its
565 own boolean state.  It is false as long as its left operand is false.
566 Once the left operand is true, the range operator stays true until the
567 right operand is true, I<AFTER> which the range operator becomes false
568 again.  It doesn't become false till the next time the range operator is
569 evaluated.  It can test the right operand and become false on the same
570 evaluation it became true (as in B<awk>), but it still returns true once.
571 If you don't want it to test the right operand till the next
572 evaluation, as in B<sed>, just use three dots ("...") instead of
573 two.  In all other regards, "..." behaves just like ".." does.
574
575 The right operand is not evaluated while the operator is in the
576 "false" state, and the left operand is not evaluated while the
577 operator is in the "true" state.  The precedence is a little lower
578 than || and &&.  The value returned is either the empty string for
579 false, or a sequence number (beginning with 1) for true.  The
580 sequence number is reset for each range encountered.  The final
581 sequence number in a range has the string "E0" appended to it, which
582 doesn't affect its numeric value, but gives you something to search
583 for if you want to exclude the endpoint.  You can exclude the
584 beginning point by waiting for the sequence number to be greater
585 than 1.
586
587 If either operand of scalar ".." is a constant expression,
588 that operand is considered true if it is equal (C<==>) to the current
589 input line number (the C<$.> variable).
590
591 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
592 but that is only an issue if you use a floating point expression; when
593 implicitly using C<$.> as described in the previous paragraph, the
594 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
595 is set to a floating point value and you are not reading from a file.
596 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
597 you want in scalar context because each of the operands are evaluated
598 using their integer representation.
599
600 Examples:
601
602 As a scalar operator:
603
604     if (101 .. 200) { print; } # print 2nd hundred lines, short for
605                                #   if ($. == 101 .. $. == 200) ...
606
607     next LINE if (1 .. /^$/);  # skip header lines, short for
608                                #   ... if ($. == 1 .. /^$/);
609                                # (typically in a loop labeled LINE)
610
611     s/^/> / if (/^$/ .. eof());  # quote body
612
613     # parse mail messages
614     while (<>) {
615         $in_header =   1  .. /^$/;
616         $in_body   = /^$/ .. eof;
617         if ($in_header) {
618             # ...
619         } else { # in body
620             # ...
621         }
622     } continue {
623         close ARGV if eof;             # reset $. each file
624     }
625
626 Here's a simple example to illustrate the difference between
627 the two range operators:
628
629     @lines = ("   - Foo",
630               "01 - Bar",
631               "1  - Baz",
632               "   - Quux");
633
634     foreach (@lines) {
635         if (/0/ .. /1/) {
636             print "$_\n";
637         }
638     }
639
640 This program will print only the line containing "Bar". If
641 the range operator is changed to C<...>, it will also print the
642 "Baz" line.
643
644 And now some examples as a list operator:
645
646     for (101 .. 200) { print; } # print $_ 100 times
647     @foo = @foo[0 .. $#foo];    # an expensive no-op
648     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
649
650 The range operator (in list context) makes use of the magical
651 auto-increment algorithm if the operands are strings.  You
652 can say
653
654     @alphabet = ('A' .. 'Z');
655
656 to get all normal letters of the English alphabet, or
657
658     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
659
660 to get a hexadecimal digit, or
661
662     @z2 = ('01' .. '31');  print $z2[$mday];
663
664 to get dates with leading zeros.
665
666 If the final value specified is not in the sequence that the magical
667 increment would produce, the sequence goes until the next value would
668 be longer than the final value specified.
669
670 If the initial value specified isn't part of a magical increment
671 sequence (that is, a non-empty string matching "/^[a-zA-Z]*[0-9]*\z/"),
672 only the initial value will be returned.  So the following will only
673 return an alpha:
674
675     use charnames 'greek';
676     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
677
678 To get lower-case greek letters, use this instead:
679
680     my @greek_small =  map { chr } ( ord("\N{alpha}") .. ord("\N{omega}") );
681
682 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
683 return two elements in list context.
684
685     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
686
687 =head2 Conditional Operator
688 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
689
690 Ternary "?:" is the conditional operator, just as in C.  It works much
691 like an if-then-else.  If the argument before the ? is true, the
692 argument before the : is returned, otherwise the argument after the :
693 is returned.  For example:
694
695     printf "I have %d dog%s.\n", $n,
696             ($n == 1) ? '' : "s";
697
698 Scalar or list context propagates downward into the 2nd
699 or 3rd argument, whichever is selected.
700
701     $a = $ok ? $b : $c;  # get a scalar
702     @a = $ok ? @b : @c;  # get an array
703     $a = $ok ? @b : @c;  # oops, that's just a count!
704
705 The operator may be assigned to if both the 2nd and 3rd arguments are
706 legal lvalues (meaning that you can assign to them):
707
708     ($a_or_b ? $a : $b) = $c;
709
710 Because this operator produces an assignable result, using assignments
711 without parentheses will get you in trouble.  For example, this:
712
713     $a % 2 ? $a += 10 : $a += 2
714
715 Really means this:
716
717     (($a % 2) ? ($a += 10) : $a) += 2
718
719 Rather than this:
720
721     ($a % 2) ? ($a += 10) : ($a += 2)
722
723 That should probably be written more simply as:
724
725     $a += ($a % 2) ? 10 : 2;
726
727 =head2 Assignment Operators
728 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
729 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
730 X<%=> X<^=> X<x=>
731
732 "=" is the ordinary assignment operator.
733
734 Assignment operators work as in C.  That is,
735
736     $a += 2;
737
738 is equivalent to
739
740     $a = $a + 2;
741
742 although without duplicating any side effects that dereferencing the lvalue
743 might trigger, such as from tie().  Other assignment operators work similarly.
744 The following are recognized:
745
746     **=    +=    *=    &=    <<=    &&=
747            -=    /=    |=    >>=    ||=
748            .=    %=    ^=           //=
749                  x=
750
751 Although these are grouped by family, they all have the precedence
752 of assignment.
753
754 Unlike in C, the scalar assignment operator produces a valid lvalue.
755 Modifying an assignment is equivalent to doing the assignment and
756 then modifying the variable that was assigned to.  This is useful
757 for modifying a copy of something, like this:
758
759     ($tmp = $global) =~ tr [A-Z] [a-z];
760
761 Likewise,
762
763     ($a += 2) *= 3;
764
765 is equivalent to
766
767     $a += 2;
768     $a *= 3;
769
770 Similarly, a list assignment in list context produces the list of
771 lvalues assigned to, and a list assignment in scalar context returns
772 the number of elements produced by the expression on the right hand
773 side of the assignment.
774
775 =head2 Comma Operator
776 X<comma> X<operator, comma> X<,>
777
778 Binary "," is the comma operator.  In scalar context it evaluates
779 its left argument, throws that value away, then evaluates its right
780 argument and returns that value.  This is just like C's comma operator.
781
782 In list context, it's just the list argument separator, and inserts
783 both its arguments into the list.  These arguments are also evaluated
784 from left to right.
785
786 The C<< => >> operator is a synonym for the comma, but forces any word
787 (consisting entirely of word characters) to its left to be interpreted
788 as a string (as of 5.001).  This includes words that might otherwise be
789 considered a constant or function call.
790
791     use constant FOO => "something";
792
793     my %h = ( FOO => 23 );
794
795 is equivalent to:
796
797     my %h = ("FOO", 23);
798
799 It is I<NOT>:
800
801     my %h = ("something", 23);
802
803 If the argument on the left is not a word, it is first interpreted as
804 an expression, and then the string value of that is used.
805
806 The C<< => >> operator is helpful in documenting the correspondence
807 between keys and values in hashes, and other paired elements in lists.
808
809         %hash = ( $key => $value );
810         login( $username => $password );
811
812 =head2 List Operators (Rightward)
813 X<operator, list, rightward> X<list operator>
814
815 On the right side of a list operator, it has very low precedence,
816 such that it controls all comma-separated expressions found there.
817 The only operators with lower precedence are the logical operators
818 "and", "or", and "not", which may be used to evaluate calls to list
819 operators without the need for extra parentheses:
820
821     open HANDLE, "filename"
822         or die "Can't open: $!\n";
823
824 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
825
826 =head2 Logical Not
827 X<operator, logical, not> X<not>
828
829 Unary "not" returns the logical negation of the expression to its right.
830 It's the equivalent of "!" except for the very low precedence.
831
832 =head2 Logical And
833 X<operator, logical, and> X<and>
834
835 Binary "and" returns the logical conjunction of the two surrounding
836 expressions.  It's equivalent to && except for the very low
837 precedence.  This means that it short-circuits: i.e., the right
838 expression is evaluated only if the left expression is true.
839
840 =head2 Logical or, Defined or, and Exclusive Or
841 X<operator, logical, or> X<operator, logical, xor> X<operator, logical, err>
842 X<operator, logical, defined or> X<operator, logical, exclusive or>
843 X<or> X<xor> X<err>
844
845 Binary "or" returns the logical disjunction of the two surrounding
846 expressions.  It's equivalent to || except for the very low precedence.
847 This makes it useful for control flow
848
849     print FH $data              or die "Can't write to FH: $!";
850
851 This means that it short-circuits: i.e., the right expression is evaluated
852 only if the left expression is false.  Due to its precedence, you should
853 probably avoid using this for assignment, only for control flow.
854
855     $a = $b or $c;              # bug: this is wrong
856     ($a = $b) or $c;            # really means this
857     $a = $b || $c;              # better written this way
858
859 However, when it's a list-context assignment and you're trying to use
860 "||" for control flow, you probably need "or" so that the assignment
861 takes higher precedence.
862
863     @info = stat($file) || die;     # oops, scalar sense of stat!
864     @info = stat($file) or die;     # better, now @info gets its due
865
866 Then again, you could always use parentheses.
867
868 Binary "err" is equivalent to C<//>--it's just like binary "or", except it
869 tests its left argument's definedness instead of its truth.  There are two
870 ways to remember "err":  either because many functions return C<undef> on
871 an B<err>or, or as a sort of correction:  C<$a = ($b err 'default')>. This
872 keyword is only available when the 'err' feature is enabled: see
873 L<feature> for more information.
874
875 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
876 It cannot short circuit, of course.
877
878 =head2 C Operators Missing From Perl
879 X<operator, missing from perl> X<&> X<*>
880 X<typecasting> X<(TYPE)>
881
882 Here is what C has that Perl doesn't:
883
884 =over 8
885
886 =item unary &
887
888 Address-of operator.  (But see the "\" operator for taking a reference.)
889
890 =item unary *
891
892 Dereference-address operator. (Perl's prefix dereferencing
893 operators are typed: $, @, %, and &.)
894
895 =item (TYPE)
896
897 Type-casting operator.
898
899 =back
900
901 =head2 Quote and Quote-like Operators
902 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
903 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
904 X<escape sequence> X<escape>
905
906
907 While we usually think of quotes as literal values, in Perl they
908 function as operators, providing various kinds of interpolating and
909 pattern matching capabilities.  Perl provides customary quote characters
910 for these behaviors, but also provides a way for you to choose your
911 quote character for any of them.  In the following table, a C<{}> represents
912 any pair of delimiters you choose.
913
914     Customary  Generic        Meaning        Interpolates
915         ''       q{}          Literal             no
916         ""      qq{}          Literal             yes
917         ``      qx{}          Command             yes*
918                 qw{}         Word list            no
919         //       m{}       Pattern match          yes*
920                 qr{}          Pattern             yes*
921                  s{}{}      Substitution          yes*
922                 tr{}{}    Transliteration         no (but see below)
923         <<EOF                 here-doc            yes*
924
925         * unless the delimiter is ''.
926
927 Non-bracketing delimiters use the same character fore and aft, but the four
928 sorts of brackets (round, angle, square, curly) will all nest, which means
929 that
930
931         q{foo{bar}baz}
932
933 is the same as
934
935         'foo{bar}baz'
936
937 Note, however, that this does not always work for quoting Perl code:
938
939         $s = q{ if($a eq "}") ... }; # WRONG
940
941 is a syntax error. The C<Text::Balanced> module (from CPAN, and
942 starting from Perl 5.8 part of the standard distribution) is able
943 to do this properly.
944
945 There can be whitespace between the operator and the quoting
946 characters, except when C<#> is being used as the quoting character.
947 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
948 operator C<q> followed by a comment.  Its argument will be taken
949 from the next line.  This allows you to write:
950
951     s {foo}  # Replace foo
952       {bar}  # with bar.
953
954 The following escape sequences are available in constructs that interpolate
955 and in transliterations.
956 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N>
957
958     \t          tab             (HT, TAB)
959     \n          newline         (NL)
960     \r          return          (CR)
961     \f          form feed       (FF)
962     \b          backspace       (BS)
963     \a          alarm (bell)    (BEL)
964     \e          escape          (ESC)
965     \033        octal char      (example: ESC)
966     \x1b        hex char        (example: ESC)
967     \x{263a}    wide hex char   (example: SMILEY)
968     \c[         control char    (example: ESC)
969     \N{name}    named Unicode character
970
971 The character following C<\c> is mapped to some other character by
972 converting letters to upper case and then (on ASCII systems) by inverting
973 the 7th bit (0x40). The most interesting range is from '@' to '_'
974 (0x40 through 0x5F), resulting in a control character from 0x00
975 through 0x1F. A '?' maps to the DEL character. On EBCDIC systems only
976 '@', the letters, '[', '\', ']', '^', '_' and '?' will work, resulting
977 in 0x00 through 0x1F and 0x7F.
978
979 B<NOTE>: Unlike C and other languages, Perl has no \v escape sequence for
980 the vertical tab (VT - ASCII 11), but you may use C<\ck> or C<\x0b>.
981
982 The following escape sequences are available in constructs that interpolate
983 but not in transliterations.
984 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
985
986     \l          lowercase next char
987     \u          uppercase next char
988     \L          lowercase till \E
989     \U          uppercase till \E
990     \E          end case modification
991     \Q          quote non-word characters till \E
992
993 If C<use locale> is in effect, the case map used by C<\l>, C<\L>,
994 C<\u> and C<\U> is taken from the current locale.  See L<perllocale>.
995 If Unicode (for example, C<\N{}> or wide hex characters of 0x100 or
996 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u> and
997 C<\U> is as defined by Unicode.  For documentation of C<\N{name}>,
998 see L<charnames>.
999
1000 All systems use the virtual C<"\n"> to represent a line terminator,
1001 called a "newline".  There is no such thing as an unvarying, physical
1002 newline character.  It is only an illusion that the operating system,
1003 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1004 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1005 on a Mac, these are reversed, and on systems without line terminator,
1006 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
1007 you mean a "newline" for your system, but use the literal ASCII when you
1008 need an exact character.  For example, most networking protocols expect
1009 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1010 and although they often accept just C<"\012">, they seldom tolerate just
1011 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1012 you may be burned some day.
1013 X<newline> X<line terminator> X<eol> X<end of line>
1014 X<\n> X<\r> X<\r\n>
1015
1016 For constructs that do interpolate, variables beginning with "C<$>"
1017 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1018 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1019 But method calls such as C<< $obj->meth >> are not.
1020
1021 Interpolating an array or slice interpolates the elements in order,
1022 separated by the value of C<$">, so is equivalent to interpolating
1023 C<join $", @array>.    "Punctuation" arrays such as C<@*> are only
1024 interpolated if the name is enclosed in braces C<@{*}>, but special
1025 arrays C<@_>, C<@+>, and C<@-> are interpolated, even without braces.
1026
1027 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
1028 An unescaped C<$> or C<@> interpolates the corresponding variable,
1029 while escaping will cause the literal string C<\$> to be inserted.
1030 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
1031
1032 Patterns are subject to an additional level of interpretation as a
1033 regular expression.  This is done as a second pass, after variables are
1034 interpolated, so that regular expressions may be incorporated into the
1035 pattern from the variables.  If this is not what you want, use C<\Q> to
1036 interpolate a variable literally.
1037
1038 Apart from the behavior described above, Perl does not expand
1039 multiple levels of interpolation.  In particular, contrary to the
1040 expectations of shell programmers, back-quotes do I<NOT> interpolate
1041 within double quotes, nor do single quotes impede evaluation of
1042 variables when used within double quotes.
1043
1044 =head2 Regexp Quote-Like Operators
1045 X<operator, regexp>
1046
1047 Here are the quote-like operators that apply to pattern
1048 matching and related activities.
1049
1050 =over 8
1051
1052 =item qr/STRING/msixpo
1053 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1054
1055 This operator quotes (and possibly compiles) its I<STRING> as a regular
1056 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1057 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1058 is done.  Returns a Perl value which may be used instead of the
1059 corresponding C</STRING/imosx> expression.
1060
1061 For example,
1062
1063     $rex = qr/my.STRING/is;
1064     s/$rex/foo/;
1065
1066 is equivalent to
1067
1068     s/my.STRING/foo/is;
1069
1070 The result may be used as a subpattern in a match:
1071
1072     $re = qr/$pattern/;
1073     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
1074     $string =~ $re;             # or used standalone
1075     $string =~ /$re/;           # or this way
1076
1077 Since Perl may compile the pattern at the moment of execution of qr()
1078 operator, using qr() may have speed advantages in some situations,
1079 notably if the result of qr() is used standalone:
1080
1081     sub match {
1082         my $patterns = shift;
1083         my @compiled = map qr/$_/i, @$patterns;
1084         grep {
1085             my $success = 0;
1086             foreach my $pat (@compiled) {
1087                 $success = 1, last if /$pat/;
1088             }
1089             $success;
1090         } @_;
1091     }
1092
1093 Precompilation of the pattern into an internal representation at
1094 the moment of qr() avoids a need to recompile the pattern every
1095 time a match C</$pat/> is attempted.  (Perl has many other internal
1096 optimizations, but none would be triggered in the above example if
1097 we did not use qr() operator.)
1098
1099 Options are:
1100
1101     m   Treat string as multiple lines.
1102     s   Treat string as single line. (Make . match a newline)
1103     i   Do case-insensitive pattern matching.
1104     x   Use extended regular expressions.
1105     p   When matching preserve a copy of the matched string so
1106         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be defined.
1107     o   Compile pattern only once.
1108
1109 If a precompiled pattern is embedded in a larger pattern then the effect
1110 of 'msixp' will be propagated appropriately.  The effect of the 'o'
1111 modifier has is not propagated, being restricted to those patterns
1112 explicitly using it.
1113
1114 See L<perlre> for additional information on valid syntax for STRING, and
1115 for a detailed look at the semantics of regular expressions.
1116
1117 =item m/PATTERN/msixpogc
1118 X<m> X<operator, match>
1119 X<regexp, options> X<regexp> X<regex, options> X<regex>
1120 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1121
1122 =item /PATTERN/msixpogc
1123
1124 Searches a string for a pattern match, and in scalar context returns
1125 true if it succeeds, false if it fails.  If no string is specified
1126 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1127 string specified with C<=~> need not be an lvalue--it may be the
1128 result of an expression evaluation, but remember the C<=~> binds
1129 rather tightly.)  See also L<perlre>.  See L<perllocale> for
1130 discussion of additional considerations that apply when C<use locale>
1131 is in effect.
1132
1133 Options are as described in C<qr//>; in addition, the following match
1134 process modifiers are available:
1135
1136     g   Match globally, i.e., find all occurrences.
1137     c   Do not reset search position on a failed match when /g is in effect.
1138
1139 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1140 you can use any pair of non-alphanumeric, non-whitespace characters
1141 as delimiters.  This is particularly useful for matching path names
1142 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1143 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
1144 If "'" is the delimiter, no interpolation is performed on the PATTERN.
1145
1146 PATTERN may contain variables, which will be interpolated (and the
1147 pattern recompiled) every time the pattern search is evaluated, except
1148 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1149 C<$|> are not interpolated because they look like end-of-string tests.)
1150 If you want such a pattern to be compiled only once, add a C</o> after
1151 the trailing delimiter.  This avoids expensive run-time recompilations,
1152 and is useful when the value you are interpolating won't change over
1153 the life of the script.  However, mentioning C</o> constitutes a promise
1154 that you won't change the variables in the pattern.  If you change them,
1155 Perl won't even notice.  See also L<"qr/STRING/msixpo">.
1156
1157 If the PATTERN evaluates to the empty string, the last
1158 I<successfully> matched regular expression is used instead. In this
1159 case, only the C<g> and C<c> flags on the empty pattern is honoured -
1160 the other flags are taken from the original pattern. If no match has
1161 previously succeeded, this will (silently) act instead as a genuine
1162 empty pattern (which will always match).
1163
1164 Note that it's possible to confuse Perl into thinking C<//> (the empty
1165 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1166 good about this, but some pathological cases might trigger this, such as
1167 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //>
1168 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl
1169 will assume you meant defined-or.  If you meant the empty regex, just
1170 use parentheses or spaces to disambiguate, or even prefix the empty
1171 regex with an C<m> (so C<//> becomes C<m//>).
1172
1173 If the C</g> option is not used, C<m//> in list context returns a
1174 list consisting of the subexpressions matched by the parentheses in the
1175 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
1176 also set, and that this differs from Perl 4's behavior.)  When there are
1177 no parentheses in the pattern, the return value is the list C<(1)> for
1178 success.  With or without parentheses, an empty list is returned upon
1179 failure.
1180
1181 Examples:
1182
1183     open(TTY, '/dev/tty');
1184     <TTY> =~ /^y/i && foo();    # do foo if desired
1185
1186     if (/Version: *([0-9.]*)/) { $version = $1; }
1187
1188     next if m#^/usr/spool/uucp#;
1189
1190     # poor man's grep
1191     $arg = shift;
1192     while (<>) {
1193         print if /$arg/o;       # compile only once
1194     }
1195
1196     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1197
1198 This last example splits $foo into the first two words and the
1199 remainder of the line, and assigns those three fields to $F1, $F2, and
1200 $Etc.  The conditional is true if any variables were assigned, i.e., if
1201 the pattern matched.
1202
1203 The C</g> modifier specifies global pattern matching--that is,
1204 matching as many times as possible within the string.  How it behaves
1205 depends on the context.  In list context, it returns a list of the
1206 substrings matched by any capturing parentheses in the regular
1207 expression.  If there are no parentheses, it returns a list of all
1208 the matched strings, as if there were parentheses around the whole
1209 pattern.
1210
1211 In scalar context, each execution of C<m//g> finds the next match,
1212 returning true if it matches, and false if there is no further match.
1213 The position after the last match can be read or set using the pos()
1214 function; see L<perlfunc/pos>.   A failed match normally resets the
1215 search position to the beginning of the string, but you can avoid that
1216 by adding the C</c> modifier (e.g. C<m//gc>).  Modifying the target
1217 string also resets the search position.
1218
1219 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1220 zero-width assertion that matches the exact position where the previous
1221 C<m//g>, if any, left off.  Without the C</g> modifier, the C<\G> assertion
1222 still anchors at pos(), but the match is of course only attempted once.
1223 Using C<\G> without C</g> on a target string that has not previously had a
1224 C</g> match applied to it is the same as using the C<\A> assertion to match
1225 the beginning of the string.  Note also that, currently, C<\G> is only
1226 properly supported when anchored at the very beginning of the pattern.
1227
1228 Examples:
1229
1230     # list context
1231     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1232
1233     # scalar context
1234     $/ = "";
1235     while (defined($paragraph = <>)) {
1236         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
1237             $sentences++;
1238         }
1239     }
1240     print "$sentences\n";
1241
1242     # using m//gc with \G
1243     $_ = "ppooqppqq";
1244     while ($i++ < 2) {
1245         print "1: '";
1246         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1247         print "2: '";
1248         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1249         print "3: '";
1250         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1251     }
1252     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1253
1254 The last example should print:
1255
1256     1: 'oo', pos=4
1257     2: 'q', pos=5
1258     3: 'pp', pos=7
1259     1: '', pos=7
1260     2: 'q', pos=8
1261     3: '', pos=8
1262     Final: 'q', pos=8
1263
1264 Notice that the final match matched C<q> instead of C<p>, which a match
1265 without the C<\G> anchor would have done. Also note that the final match
1266 did not update C<pos> -- C<pos> is only updated on a C</g> match. If the
1267 final match did indeed match C<p>, it's a good bet that you're running an
1268 older (pre-5.6.0) Perl.
1269
1270 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1271 combine several regexps like this to process a string part-by-part,
1272 doing different actions depending on which regexp matched.  Each
1273 regexp tries to match where the previous one leaves off.
1274
1275  $_ = <<'EOL';
1276       $url = URI::URL->new( "http://www/" );   die if $url eq "xXx";
1277  EOL
1278  LOOP:
1279     {
1280       print(" digits"),         redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1281       print(" lowercase"),      redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
1282       print(" UPPERCASE"),      redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
1283       print(" Capitalized"),    redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
1284       print(" MiXeD"),          redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
1285       print(" alphanumeric"),   redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
1286       print(" line-noise"),     redo LOOP if /\G[^A-Za-z0-9]+/gc;
1287       print ". That's all!\n";
1288     }
1289
1290 Here is the output (split into several lines):
1291
1292  line-noise lowercase line-noise lowercase UPPERCASE line-noise
1293  UPPERCASE line-noise lowercase line-noise lowercase line-noise
1294  lowercase lowercase line-noise lowercase lowercase line-noise
1295  MiXeD line-noise. That's all!
1296
1297 =item ?PATTERN?
1298 X<?>
1299
1300 This is just like the C</pattern/> search, except that it matches only
1301 once between calls to the reset() operator.  This is a useful
1302 optimization when you want to see only the first occurrence of
1303 something in each file of a set of files, for instance.  Only C<??>
1304 patterns local to the current package are reset.
1305
1306     while (<>) {
1307         if (?^$?) {
1308                             # blank line between header and body
1309         }
1310     } continue {
1311         reset if eof;       # clear ?? status for next file
1312     }
1313
1314 This usage is vaguely deprecated, which means it just might possibly
1315 be removed in some distant future version of Perl, perhaps somewhere
1316 around the year 2168.
1317
1318 =item s/PATTERN/REPLACEMENT/msixpogce
1319 X<substitute> X<substitution> X<replace> X<regexp, replace>
1320 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e>
1321
1322 Searches a string for a pattern, and if found, replaces that pattern
1323 with the replacement text and returns the number of substitutions
1324 made.  Otherwise it returns false (specifically, the empty string).
1325
1326 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1327 variable is searched and modified.  (The string specified with C<=~> must
1328 be scalar variable, an array element, a hash element, or an assignment
1329 to one of those, i.e., an lvalue.)
1330
1331 If the delimiter chosen is a single quote, no interpolation is
1332 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1333 PATTERN contains a $ that looks like a variable rather than an
1334 end-of-string test, the variable will be interpolated into the pattern
1335 at run-time.  If you want the pattern compiled only once the first time
1336 the variable is interpolated, use the C</o> option.  If the pattern
1337 evaluates to the empty string, the last successfully executed regular
1338 expression is used instead.  See L<perlre> for further explanation on these.
1339 See L<perllocale> for discussion of additional considerations that apply
1340 when C<use locale> is in effect.
1341
1342 Options are as with m// with the addition of the following replacement
1343 specific options:
1344
1345     e   Evaluate the right side as an expression.
1346     ee  Evaluate the right side as a string then eval the result
1347
1348 Any non-alphanumeric, non-whitespace delimiter may replace the
1349 slashes.  If single quotes are used, no interpretation is done on the
1350 replacement string (the C</e> modifier overrides this, however).  Unlike
1351 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
1352 text is not evaluated as a command.  If the
1353 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
1354 pair of quotes, which may or may not be bracketing quotes, e.g.,
1355 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
1356 replacement portion to be treated as a full-fledged Perl expression
1357 and evaluated right then and there.  It is, however, syntax checked at
1358 compile-time. A second C<e> modifier will cause the replacement portion
1359 to be C<eval>ed before being run as a Perl expression.
1360
1361 Examples:
1362
1363     s/\bgreen\b/mauve/g;                # don't change wintergreen
1364
1365     $path =~ s|/usr/bin|/usr/local/bin|;
1366
1367     s/Login: $foo/Login: $bar/; # run-time pattern
1368
1369     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1370
1371     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1372
1373     $_ = 'abc123xyz';
1374     s/\d+/$&*2/e;               # yields 'abc246xyz'
1375     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1376     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1377
1378     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1379     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1380     s/^=(\w+)/pod($1)/ge;       # use function call
1381
1382     # expand variables in $_, but dynamics only, using
1383     # symbolic dereferencing
1384     s/\$(\w+)/${$1}/g;
1385
1386     # Add one to the value of any numbers in the string
1387     s/(\d+)/1 + $1/eg;
1388
1389     # This will expand any embedded scalar variable
1390     # (including lexicals) in $_ : First $1 is interpolated
1391     # to the variable name, and then evaluated
1392     s/(\$\w+)/$1/eeg;
1393
1394     # Delete (most) C comments.
1395     $program =~ s {
1396         /\*     # Match the opening delimiter.
1397         .*?     # Match a minimal number of characters.
1398         \*/     # Match the closing delimiter.
1399     } []gsx;
1400
1401     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_, expensively
1402
1403     for ($variable) {           # trim whitespace in $variable, cheap
1404         s/^\s+//;
1405         s/\s+$//;
1406     }
1407
1408     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1409
1410 Note the use of $ instead of \ in the last example.  Unlike
1411 B<sed>, we use the \<I<digit>> form in only the left hand side.
1412 Anywhere else it's $<I<digit>>.
1413
1414 Occasionally, you can't use just a C</g> to get all the changes
1415 to occur that you might want.  Here are two common cases:
1416
1417     # put commas in the right places in an integer
1418     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
1419
1420     # expand tabs to 8-column spacing
1421     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1422
1423 =back
1424
1425 =head2 Quote-Like Operators
1426 X<operator, quote-like>
1427
1428 =over 4
1429
1430 =item q/STRING/
1431 X<q> X<quote, single> X<'> X<''>
1432
1433 =item 'STRING'
1434
1435 A single-quoted, literal string.  A backslash represents a backslash
1436 unless followed by the delimiter or another backslash, in which case
1437 the delimiter or backslash is interpolated.
1438
1439     $foo = q!I said, "You said, 'She said it.'"!;
1440     $bar = q('This is it.');
1441     $baz = '\n';                # a two-character string
1442
1443 =item qq/STRING/
1444 X<qq> X<quote, double> X<"> X<"">
1445
1446 =item "STRING"
1447
1448 A double-quoted, interpolated string.
1449
1450     $_ .= qq
1451      (*** The previous line contains the naughty word "$1".\n)
1452                 if /\b(tcl|java|python)\b/i;      # :-)
1453     $baz = "\n";                # a one-character string
1454
1455 =item qx/STRING/
1456 X<qx> X<`> X<``> X<backtick>
1457
1458 =item `STRING`
1459
1460 A string which is (possibly) interpolated and then executed as a
1461 system command with C</bin/sh> or its equivalent.  Shell wildcards,
1462 pipes, and redirections will be honored.  The collected standard
1463 output of the command is returned; standard error is unaffected.  In
1464 scalar context, it comes back as a single (potentially multi-line)
1465 string, or undef if the command failed.  In list context, returns a
1466 list of lines (however you've defined lines with $/ or
1467 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
1468
1469 Because backticks do not affect standard error, use shell file descriptor
1470 syntax (assuming the shell supports this) if you care to address this.
1471 To capture a command's STDERR and STDOUT together:
1472
1473     $output = `cmd 2>&1`;
1474
1475 To capture a command's STDOUT but discard its STDERR:
1476
1477     $output = `cmd 2>/dev/null`;
1478
1479 To capture a command's STDERR but discard its STDOUT (ordering is
1480 important here):
1481
1482     $output = `cmd 2>&1 1>/dev/null`;
1483
1484 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1485 but leave its STDOUT to come out the old STDERR:
1486
1487     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1488
1489 To read both a command's STDOUT and its STDERR separately, it's easiest
1490 to redirect them separately to files, and then read from those files
1491 when the program is done:
1492
1493     system("program args 1>program.stdout 2>program.stderr");
1494
1495 The STDIN filehandle used by the command is inherited from Perl's STDIN.
1496 For example:
1497
1498     open BLAM, "blam" || die "Can't open: $!";
1499     open STDIN, "<&BLAM";
1500     print `sort`;
1501
1502 will print the sorted contents of the file "blam".
1503
1504 Using single-quote as a delimiter protects the command from Perl's
1505 double-quote interpolation, passing it on to the shell instead:
1506
1507     $perl_info  = qx(ps $$);            # that's Perl's $$
1508     $shell_info = qx'ps $$';            # that's the new shell's $$
1509
1510 How that string gets evaluated is entirely subject to the command
1511 interpreter on your system.  On most platforms, you will have to protect
1512 shell metacharacters if you want them treated literally.  This is in
1513 practice difficult to do, as it's unclear how to escape which characters.
1514 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1515 to emulate backticks safely.
1516
1517 On some platforms (notably DOS-like ones), the shell may not be
1518 capable of dealing with multiline commands, so putting newlines in
1519 the string may not get you what you want.  You may be able to evaluate
1520 multiple commands in a single line by separating them with the command
1521 separator character, if your shell supports that (e.g. C<;> on many Unix
1522 shells; C<&> on the Windows NT C<cmd> shell).
1523
1524 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1525 output before starting the child process, but this may not be supported
1526 on some platforms (see L<perlport>).  To be safe, you may need to set
1527 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1528 C<IO::Handle> on any open handles.
1529
1530 Beware that some command shells may place restrictions on the length
1531 of the command line.  You must ensure your strings don't exceed this
1532 limit after any necessary interpolations.  See the platform-specific
1533 release notes for more details about your particular environment.
1534
1535 Using this operator can lead to programs that are difficult to port,
1536 because the shell commands called vary between systems, and may in
1537 fact not be present at all.  As one example, the C<type> command under
1538 the POSIX shell is very different from the C<type> command under DOS.
1539 That doesn't mean you should go out of your way to avoid backticks
1540 when they're the right way to get something done.  Perl was made to be
1541 a glue language, and one of the things it glues together is commands.
1542 Just understand what you're getting yourself into.
1543
1544 See L</"I/O Operators"> for more discussion.
1545
1546 =item qw/STRING/
1547 X<qw> X<quote, list> X<quote, words>
1548
1549 Evaluates to a list of the words extracted out of STRING, using embedded
1550 whitespace as the word delimiters.  It can be understood as being roughly
1551 equivalent to:
1552
1553     split(' ', q/STRING/);
1554
1555 the differences being that it generates a real list at compile time, and
1556 in scalar context it returns the last element in the list.  So
1557 this expression:
1558
1559     qw(foo bar baz)
1560
1561 is semantically equivalent to the list:
1562
1563     'foo', 'bar', 'baz'
1564
1565 Some frequently seen examples:
1566
1567     use POSIX qw( setlocale localeconv )
1568     @EXPORT = qw( foo bar baz );
1569
1570 A common mistake is to try to separate the words with comma or to
1571 put comments into a multi-line C<qw>-string.  For this reason, the
1572 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
1573 produces warnings if the STRING contains the "," or the "#" character.
1574
1575
1576 =item tr/SEARCHLIST/REPLACEMENTLIST/cds
1577 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
1578
1579 =item y/SEARCHLIST/REPLACEMENTLIST/cds
1580
1581 Transliterates all occurrences of the characters found in the search list
1582 with the corresponding character in the replacement list.  It returns
1583 the number of characters replaced or deleted.  If no string is
1584 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1585 string specified with =~ must be a scalar variable, an array element, a
1586 hash element, or an assignment to one of those, i.e., an lvalue.)
1587
1588 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
1589 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1590 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1591 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1592 its own pair of quotes, which may or may not be bracketing quotes,
1593 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1594
1595 Note that C<tr> does B<not> do regular expression character classes
1596 such as C<\d> or C<[:lower:]>.  The C<tr> operator is not equivalent to
1597 the tr(1) utility.  If you want to map strings between lower/upper
1598 cases, see L<perlfunc/lc> and L<perlfunc/uc>, and in general consider
1599 using the C<s> operator if you need regular expressions.
1600
1601 Note also that the whole range idea is rather unportable between
1602 character sets--and even within character sets they may cause results
1603 you probably didn't expect.  A sound principle is to use only ranges
1604 that begin from and end at either alphabets of equal case (a-e, A-E),
1605 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1606 character sets in full.
1607
1608 Options:
1609
1610     c   Complement the SEARCHLIST.
1611     d   Delete found but unreplaced characters.
1612     s   Squash duplicate replaced characters.
1613
1614 If the C</c> modifier is specified, the SEARCHLIST character set
1615 is complemented.  If the C</d> modifier is specified, any characters
1616 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1617 (Note that this is slightly more flexible than the behavior of some
1618 B<tr> programs, which delete anything they find in the SEARCHLIST,
1619 period.) If the C</s> modifier is specified, sequences of characters
1620 that were transliterated to the same character are squashed down
1621 to a single instance of the character.
1622
1623 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1624 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1625 than the SEARCHLIST, the final character is replicated till it is long
1626 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1627 This latter is useful for counting characters in a class or for
1628 squashing character sequences in a class.
1629
1630 Examples:
1631
1632     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1633
1634     $cnt = tr/*/*/;             # count the stars in $_
1635
1636     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1637
1638     $cnt = tr/0-9//;            # count the digits in $_
1639
1640     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1641
1642     ($HOST = $host) =~ tr/a-z/A-Z/;
1643
1644     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1645
1646     tr [\200-\377]
1647        [\000-\177];             # delete 8th bit
1648
1649 If multiple transliterations are given for a character, only the
1650 first one is used:
1651
1652     tr/AAA/XYZ/
1653
1654 will transliterate any A to X.
1655
1656 Because the transliteration table is built at compile time, neither
1657 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1658 interpolation.  That means that if you want to use variables, you
1659 must use an eval():
1660
1661     eval "tr/$oldlist/$newlist/";
1662     die $@ if $@;
1663
1664     eval "tr/$oldlist/$newlist/, 1" or die $@;
1665
1666 =item <<EOF
1667 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
1668
1669 A line-oriented form of quoting is based on the shell "here-document"
1670 syntax.  Following a C<< << >> you specify a string to terminate
1671 the quoted material, and all lines following the current line down to
1672 the terminating string are the value of the item.
1673
1674 The terminating string may be either an identifier (a word), or some
1675 quoted text.  An unquoted identifier works like double quotes.
1676 There may not be a space between the C<< << >> and the identifier,
1677 unless the identifier is explicitly quoted.  (If you put a space it
1678 will be treated as a null identifier, which is valid, and matches the
1679 first empty line.)  The terminating string must appear by itself
1680 (unquoted and with no surrounding whitespace) on the terminating line.
1681
1682 If the terminating string is quoted, the type of quotes used determine
1683 the treatment of the text.
1684
1685 =over 4
1686
1687 =item Double Quotes
1688
1689 Double quotes indicate that the text will be interpolated using exactly
1690 the same rules as normal double quoted strings.
1691
1692        print <<EOF;
1693     The price is $Price.
1694     EOF
1695
1696        print << "EOF"; # same as above
1697     The price is $Price.
1698     EOF
1699
1700
1701 =item Single Quotes
1702
1703 Single quotes indicate the text is to be treated literally with no
1704 interpolation of its content. This is similar to single quoted
1705 strings except that backslashes have no special meaning, with C<\\>
1706 being treated as two backslashes and not one as they would in every
1707 other quoting construct.
1708
1709 This is the only form of quoting in perl where there is no need
1710 to worry about escaping content, something that code generators
1711 can and do make good use of.
1712
1713 =item Backticks
1714
1715 The content of the here doc is treated just as it would be if the
1716 string were embedded in backticks. Thus the content is interpolated
1717 as though it were double quoted and then executed via the shell, with
1718 the results of the execution returned.
1719
1720        print << `EOC`; # execute command and get results
1721     echo hi there
1722     EOC
1723
1724 =back
1725
1726 It is possible to stack multiple here-docs in a row:
1727
1728        print <<"foo", <<"bar"; # you can stack them
1729     I said foo.
1730     foo
1731     I said bar.
1732     bar
1733
1734        myfunc(<< "THIS", 23, <<'THAT');
1735     Here's a line
1736     or two.
1737     THIS
1738     and here's another.
1739     THAT
1740
1741 Just don't forget that you have to put a semicolon on the end
1742 to finish the statement, as Perl doesn't know you're not going to
1743 try to do this:
1744
1745        print <<ABC
1746     179231
1747     ABC
1748        + 20;
1749
1750 If you want to remove the line terminator from your here-docs,
1751 use C<chomp()>.
1752
1753     chomp($string = <<'END');
1754     This is a string.
1755     END
1756
1757 If you want your here-docs to be indented with the rest of the code,
1758 you'll need to remove leading whitespace from each line manually:
1759
1760     ($quote = <<'FINIS') =~ s/^\s+//gm;
1761        The Road goes ever on and on,
1762        down from the door where it began.
1763     FINIS
1764
1765 If you use a here-doc within a delimited construct, such as in C<s///eg>,
1766 the quoted material must come on the lines following the final delimiter.
1767 So instead of
1768
1769     s/this/<<E . 'that'
1770     the other
1771     E
1772      . 'more '/eg;
1773
1774 you have to write
1775
1776     s/this/<<E . 'that'
1777      . 'more '/eg;
1778     the other
1779     E
1780
1781 If the terminating identifier is on the last line of the program, you
1782 must be sure there is a newline after it; otherwise, Perl will give the
1783 warning B<Can't find string terminator "END" anywhere before EOF...>.
1784
1785 Additionally, the quoting rules for the end of string identifier are not
1786 related to Perl's quoting rules -- C<q()>, C<qq()>, and the like are not
1787 supported in place of C<''> and C<"">, and the only interpolation is for
1788 backslashing the quoting character:
1789
1790     print << "abc\"def";
1791     testing...
1792     abc"def
1793
1794 Finally, quoted strings cannot span multiple lines.  The general rule is
1795 that the identifier must be a string literal.  Stick with that, and you
1796 should be safe.
1797
1798 =back
1799
1800 =head2 Gory details of parsing quoted constructs
1801 X<quote, gory details>
1802
1803 When presented with something that might have several different
1804 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
1805 principle to pick the most probable interpretation.  This strategy
1806 is so successful that Perl programmers often do not suspect the
1807 ambivalence of what they write.  But from time to time, Perl's
1808 notions differ substantially from what the author honestly meant.
1809
1810 This section hopes to clarify how Perl handles quoted constructs.
1811 Although the most common reason to learn this is to unravel labyrinthine
1812 regular expressions, because the initial steps of parsing are the
1813 same for all quoting operators, they are all discussed together.
1814
1815 The most important Perl parsing rule is the first one discussed
1816 below: when processing a quoted construct, Perl first finds the end
1817 of that construct, then interprets its contents.  If you understand
1818 this rule, you may skip the rest of this section on the first
1819 reading.  The other rules are likely to contradict the user's
1820 expectations much less frequently than this first one.
1821
1822 Some passes discussed below are performed concurrently, but because
1823 their results are the same, we consider them individually.  For different
1824 quoting constructs, Perl performs different numbers of passes, from
1825 one to four, but these passes are always performed in the same order.
1826
1827 =over 4
1828
1829 =item Finding the end
1830
1831 The first pass is finding the end of the quoted construct, where
1832 the information about the delimiters is used in parsing.
1833 During this search, text between the starting and ending delimiters
1834 is copied to a safe location. The text copied gets delimiter-independent.
1835
1836 If the construct is a here-doc, the ending delimiter is a line
1837 that has a terminating string as the content. Therefore C<<<EOF> is
1838 terminated by C<EOF> immediately followed by C<"\n"> and starting
1839 from the first column of the terminating line.
1840 When searching for the terminating line of a here-doc, nothing
1841 is skipped. In other words, lines after the here-doc syntax
1842 are compared with the terminating string line by line.
1843
1844 For the constructs except here-docs, single characters are used as starting
1845 and ending delimiters. If the starting delimiter is an opening punctuation
1846 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
1847 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
1848 If the starting delimiter is an unpaired character like C</> or a closing
1849 punctuation, the ending delimiter is same as the starting delimiter.
1850 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
1851 C<qq[]> and C<qq]]> constructs.
1852
1853 When searching for single-character delimiters, escaped delimiters
1854 and C<\\> are skipped. For example, while searching for terminating C</>,
1855 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
1856 bracketing, nested pairs are also skipped.  For example, while searching
1857 for closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
1858 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
1859 However, when backslashes are used as the delimiters (like C<qq\\> and
1860 C<tr\\\>), nothing is skipped.
1861 During the search for the end, backslashes that escape delimiters
1862 are removed (exactly speaking, they are not copied to the safe location).
1863
1864 For constructs with three-part delimiters (C<s///>, C<y///>, and
1865 C<tr///>), the search is repeated once more.
1866 If the first delimiter is not an opening punctuation, three delimiters must
1867 be same such as C<s!!!> and C<tr)))>, in which case the second delimiter
1868 terminates the left part and starts the right part at once.
1869 If the left part is delimited by bracketing punctuations (that is C<()>,
1870 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
1871 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespaces
1872 and comments are allowed between both parts, though the comment must follow
1873 at least one whitespace; otherwise a character expected as the start of
1874 the comment may be regarded as the starting delimiter of the right part.
1875
1876 During this search no attention is paid to the semantics of the construct.
1877 Thus:
1878
1879     "$hash{"$foo/$bar"}"
1880
1881 or:
1882
1883     m/
1884       bar       # NOT a comment, this slash / terminated m//!
1885      /x
1886
1887 do not form legal quoted expressions.   The quoted part ends on the
1888 first C<"> and C</>, and the rest happens to be a syntax error.
1889 Because the slash that terminated C<m//> was followed by a C<SPACE>,
1890 the example above is not C<m//x>, but rather C<m//> with no C</x>
1891 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
1892
1893 Also no attention is paid to C<\c\> (multichar control char syntax) during
1894 this search. Thus the second C<\> in C<qq/\c\/> is interpreted as a part
1895 of C<\/>, and the following C</> is not recognized as a delimiter.
1896 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
1897
1898 =item Interpolation
1899 X<interpolation>
1900
1901 The next step is interpolation in the text obtained, which is now
1902 delimiter-independent.  There are multiple cases.
1903
1904 =over 4
1905
1906 =item C<<<'EOF'>
1907
1908 No interpolation is performed.
1909 Note that the combination C<\\> is left intact, since escaped delimiters
1910 are not available for here-docs.
1911
1912 =item  C<m''>, the pattern of C<s'''>
1913
1914 No interpolation is performed at this stage.
1915 Any backslashed sequences including C<\\> are treated at the stage
1916 to L</"parsing regular expressions">.
1917
1918 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
1919
1920 The only interpolation is removal of C<\> from pairs of C<\\>.
1921 Therefore C<-> in C<tr'''> and C<y'''> is treated literally
1922 as a hyphen and no character range is available.
1923 C<\1> in the replacement of C<s'''> does not work as C<$1>.
1924
1925 =item C<tr///>, C<y///>
1926
1927 No variable interpolation occurs.  String modifying combinations for
1928 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
1929 The other escape sequences such as C<\200> and C<\t> and backslashed
1930 characters such as C<\\> and C<\-> are converted to appropriate literals.
1931 The character C<-> is treated specially and therefore C<\-> is treated
1932 as a literal C<->.
1933
1934 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
1935
1936 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
1937 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
1938 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
1939 The other escape sequences such as C<\200> and C<\t> and backslashed
1940 characters such as C<\\> and C<\-> are replaced with appropriate
1941 expansions.
1942
1943 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
1944 is interpolated in the usual way.  Something like C<"\Q\\E"> has
1945 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
1946 result is the same as for C<"\\\\E">.  As a general rule, backslashes
1947 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
1948 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
1949 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
1950
1951   $str = '\t';
1952   return "\Q$str";
1953
1954 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
1955
1956 Interpolated scalars and arrays are converted internally to the C<join> and
1957 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
1958
1959   $foo . " XXX '" . (join $", @arr) . "'";
1960
1961 All operations above are performed simultaneously, left to right.
1962
1963 Because the result of C<"\Q STRING \E"> has all metacharacters
1964 quoted, there is no way to insert a literal C<$> or C<@> inside a
1965 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
1966 C<"\\\$">; if not, it is interpreted as the start of an interpolated
1967 scalar.
1968
1969 Note also that the interpolation code needs to make a decision on
1970 where the interpolated scalar ends.  For instance, whether
1971 C<< "a $b -> {c}" >> really means:
1972
1973   "a " . $b . " -> {c}";
1974
1975 or:
1976
1977   "a " . $b -> {c};
1978
1979 Most of the time, the longest possible text that does not include
1980 spaces between components and which contains matching braces or
1981 brackets.  because the outcome may be determined by voting based
1982 on heuristic estimators, the result is not strictly predictable.
1983 Fortunately, it's usually correct for ambiguous cases.
1984
1985 =item the replacement of C<s///>
1986
1987 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
1988 happens as with C<qq//> constructs.
1989
1990 It is at this step that C<\1> is begrudgingly converted to C<$1> in
1991 the replacement text of C<s///>, in order to correct the incorrigible
1992 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
1993 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
1994 (that is, the C<$^W> variable) was set.
1995
1996 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
1997
1998 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\E>,
1999 and interpolation happens (almost) as with C<qq//> constructs.
2000
2001 However any other combinations of C<\> followed by a character
2002 are not substituted but only skipped, in order to parse them
2003 as regular expressions at the following step.
2004 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2005 treated as an array symbol (for example C<@foo>),
2006 even though the same text in C<qq//> gives interpolation of C<\c@>.
2007
2008 Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
2009 a C<#>-comment in a C<//x>-regular expression, no processing is
2010 performed whatsoever.  This is the first step at which the presence
2011 of the C<//x> modifier is relevant.
2012
2013 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2014 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2015 voted (by several different estimators) to be either an array element
2016 or C<$var> followed by an RE alternative.  This is where the notation
2017 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2018 array element C<-9>, not as a regular expression from the variable
2019 C<$arr> followed by a digit, which would be the interpretation of
2020 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2021 the result is not predictable.
2022
2023 The lack of processing of C<\\> creates specific restrictions on
2024 the post-processed text.  If the delimiter is C</>, one cannot get
2025 the combination C<\/> into the result of this step.  C</> will
2026 finish the regular expression, C<\/> will be stripped to C</> on
2027 the previous step, and C<\\/> will be left as is.  Because C</> is
2028 equivalent to C<\/> inside a regular expression, this does not
2029 matter unless the delimiter happens to be character special to the
2030 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2031 alphanumeric char, as in:
2032
2033   m m ^ a \s* b mmx;
2034
2035 In the RE above, which is intentionally obfuscated for illustration, the
2036 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2037 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one
2038 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2039 non-whitespace choices.
2040
2041 =back
2042
2043 This step is the last one for all constructs except regular expressions,
2044 which are processed further.
2045
2046 =item parsing regular expressions
2047 X<regexp, parse>
2048
2049 Previous steps were performed during the compilation of Perl code,
2050 but this one happens at run time--although it may be optimized to
2051 be calculated at compile time if appropriate.  After preprocessing
2052 described above, and possibly after evaluation if concatenation,
2053 joining, casing translation, or metaquoting are involved, the
2054 resulting I<string> is passed to the RE engine for compilation.
2055
2056 Whatever happens in the RE engine might be better discussed in L<perlre>,
2057 but for the sake of continuity, we shall do so here.
2058
2059 This is another step where the presence of the C<//x> modifier is
2060 relevant.  The RE engine scans the string from left to right and
2061 converts it to a finite automaton.
2062
2063 Backslashed characters are either replaced with corresponding
2064 literal strings (as with C<\{>), or else they generate special nodes
2065 in the finite automaton (as with C<\b>).  Characters special to the
2066 RE engine (such as C<|>) generate corresponding nodes or groups of
2067 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2068 converted to literal strings to match, or else is ignored (as is
2069 whitespace and C<#>-style comments if C<//x> is present).
2070
2071 Parsing of the bracketed character class construct, C<[...]>, is
2072 rather different than the rule used for the rest of the pattern.
2073 The terminator of this construct is found using the same rules as
2074 for finding the terminator of a C<{}>-delimited construct, the only
2075 exception being that C<]> immediately following C<[> is treated as
2076 though preceded by a backslash.  Similarly, the terminator of
2077 C<(?{...})> is found using the same rules as for finding the
2078 terminator of a C<{}>-delimited construct.
2079
2080 It is possible to inspect both the string given to RE engine and the
2081 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2082 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
2083 switch documented in L<perlrun/"Command Switches">.
2084
2085 =item Optimization of regular expressions
2086 X<regexp, optimization>
2087
2088 This step is listed for completeness only.  Since it does not change
2089 semantics, details of this step are not documented and are subject
2090 to change without notice.  This step is performed over the finite
2091 automaton that was generated during the previous pass.
2092
2093 It is at this stage that C<split()> silently optimizes C</^/> to
2094 mean C</^/m>.
2095
2096 =back
2097
2098 =head2 I/O Operators
2099 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2100 X<< <> >> X<@ARGV>
2101
2102 There are several I/O operators you should know about.
2103
2104 A string enclosed by backticks (grave accents) first undergoes
2105 double-quote interpolation.  It is then interpreted as an external
2106 command, and the output of that command is the value of the
2107 backtick string, like in a shell.  In scalar context, a single string
2108 consisting of all output is returned.  In list context, a list of
2109 values is returned, one per line of output.  (You can set C<$/> to use
2110 a different line terminator.)  The command is executed each time the
2111 pseudo-literal is evaluated.  The status value of the command is
2112 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2113 Unlike in B<csh>, no translation is done on the return data--newlines
2114 remain newlines.  Unlike in any of the shells, single quotes do not
2115 hide variable names in the command from interpretation.  To pass a
2116 literal dollar-sign through to the shell you need to hide it with a
2117 backslash.  The generalized form of backticks is C<qx//>.  (Because
2118 backticks always undergo shell expansion as well, see L<perlsec> for
2119 security concerns.)
2120 X<qx> X<`> X<``> X<backtick> X<glob>
2121
2122 In scalar context, evaluating a filehandle in angle brackets yields
2123 the next line from that file (the newline, if any, included), or
2124 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2125 (sometimes known as file-slurp mode) and the file is empty, it
2126 returns C<''> the first time, followed by C<undef> subsequently.
2127
2128 Ordinarily you must assign the returned value to a variable, but
2129 there is one situation where an automatic assignment happens.  If
2130 and only if the input symbol is the only thing inside the conditional
2131 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2132 the value is automatically assigned to the global variable $_,
2133 destroying whatever was there previously.  (This may seem like an
2134 odd thing to you, but you'll use the construct in almost every Perl
2135 script you write.)  The $_ variable is not implicitly localized.
2136 You'll have to put a C<local $_;> before the loop if you want that
2137 to happen.
2138
2139 The following lines are equivalent:
2140
2141     while (defined($_ = <STDIN>)) { print; }
2142     while ($_ = <STDIN>) { print; }
2143     while (<STDIN>) { print; }
2144     for (;<STDIN>;) { print; }
2145     print while defined($_ = <STDIN>);
2146     print while ($_ = <STDIN>);
2147     print while <STDIN>;
2148
2149 This also behaves similarly, but avoids $_ :
2150
2151     while (my $line = <STDIN>) { print $line }
2152
2153 In these loop constructs, the assigned value (whether assignment
2154 is automatic or explicit) is then tested to see whether it is
2155 defined.  The defined test avoids problems where line has a string
2156 value that would be treated as false by Perl, for example a "" or
2157 a "0" with no trailing newline.  If you really mean for such values
2158 to terminate the loop, they should be tested for explicitly:
2159
2160     while (($_ = <STDIN>) ne '0') { ... }
2161     while (<STDIN>) { last unless $_; ... }
2162
2163 In other boolean contexts, C<< <I<filehandle>> >> without an
2164 explicit C<defined> test or comparison elicit a warning if the
2165 C<use warnings> pragma or the B<-w>
2166 command-line switch (the C<$^W> variable) is in effect.
2167
2168 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2169 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2170 in packages, where they would be interpreted as local identifiers
2171 rather than global.)  Additional filehandles may be created with
2172 the open() function, amongst others.  See L<perlopentut> and
2173 L<perlfunc/open> for details on this.
2174 X<stdin> X<stdout> X<sterr>
2175
2176 If a <FILEHANDLE> is used in a context that is looking for
2177 a list, a list comprising all input lines is returned, one line per
2178 list element.  It's easy to grow to a rather large data space this
2179 way, so use with care.
2180
2181 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2182 See L<perlfunc/readline>.
2183
2184 The null filehandle <> is special: it can be used to emulate the
2185 behavior of B<sed> and B<awk>.  Input from <> comes either from
2186 standard input, or from each file listed on the command line.  Here's
2187 how it works: the first time <> is evaluated, the @ARGV array is
2188 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2189 gives you standard input.  The @ARGV array is then processed as a list
2190 of filenames.  The loop
2191
2192     while (<>) {
2193         ...                     # code for each line
2194     }
2195
2196 is equivalent to the following Perl-like pseudo code:
2197
2198     unshift(@ARGV, '-') unless @ARGV;
2199     while ($ARGV = shift) {
2200         open(ARGV, $ARGV);
2201         while (<ARGV>) {
2202             ...         # code for each line
2203         }
2204     }
2205
2206 except that it isn't so cumbersome to say, and will actually work.
2207 It really does shift the @ARGV array and put the current filename
2208 into the $ARGV variable.  It also uses filehandle I<ARGV>
2209 internally--<> is just a synonym for <ARGV>, which
2210 is magical.  (The pseudo code above doesn't work because it treats
2211 <ARGV> as non-magical.)
2212
2213 You can modify @ARGV before the first <> as long as the array ends up
2214 containing the list of filenames you really want.  Line numbers (C<$.>)
2215 continue as though the input were one big happy file.  See the example
2216 in L<perlfunc/eof> for how to reset line numbers on each file.
2217
2218 If you want to set @ARGV to your own list of files, go right ahead.
2219 This sets @ARGV to all plain text files if no @ARGV was given:
2220
2221     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2222
2223 You can even set them to pipe commands.  For example, this automatically
2224 filters compressed arguments through B<gzip>:
2225
2226     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2227
2228 If you want to pass switches into your script, you can use one of the
2229 Getopts modules or put a loop on the front like this:
2230
2231     while ($_ = $ARGV[0], /^-/) {
2232         shift;
2233         last if /^--$/;
2234         if (/^-D(.*)/) { $debug = $1 }
2235         if (/^-v/)     { $verbose++  }
2236         # ...           # other switches
2237     }
2238
2239     while (<>) {
2240         # ...           # code for each line
2241     }
2242
2243 The <> symbol will return C<undef> for end-of-file only once.
2244 If you call it again after this, it will assume you are processing another
2245 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
2246
2247 If what the angle brackets contain is a simple scalar variable (e.g.,
2248 <$foo>), then that variable contains the name of the
2249 filehandle to input from, or its typeglob, or a reference to the
2250 same.  For example:
2251
2252     $fh = \*STDIN;
2253     $line = <$fh>;
2254
2255 If what's within the angle brackets is neither a filehandle nor a simple
2256 scalar variable containing a filehandle name, typeglob, or typeglob
2257 reference, it is interpreted as a filename pattern to be globbed, and
2258 either a list of filenames or the next filename in the list is returned,
2259 depending on context.  This distinction is determined on syntactic
2260 grounds alone.  That means C<< <$x> >> is always a readline() from
2261 an indirect handle, but C<< <$hash{key}> >> is always a glob().
2262 That's because $x is a simple scalar variable, but C<$hash{key}> is
2263 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
2264 is treated as C<glob("$x ")>, not C<readline($x)>.
2265
2266 One level of double-quote interpretation is done first, but you can't
2267 say C<< <$foo> >> because that's an indirect filehandle as explained
2268 in the previous paragraph.  (In older versions of Perl, programmers
2269 would insert curly brackets to force interpretation as a filename glob:
2270 C<< <${foo}> >>.  These days, it's considered cleaner to call the
2271 internal function directly as C<glob($foo)>, which is probably the right
2272 way to have done it in the first place.)  For example:
2273
2274     while (<*.c>) {
2275         chmod 0644, $_;
2276     }
2277
2278 is roughly equivalent to:
2279
2280     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
2281     while (<FOO>) {
2282         chomp;
2283         chmod 0644, $_;
2284     }
2285
2286 except that the globbing is actually done internally using the standard
2287 C<File::Glob> extension.  Of course, the shortest way to do the above is:
2288
2289     chmod 0644, <*.c>;
2290
2291 A (file)glob evaluates its (embedded) argument only when it is
2292 starting a new list.  All values must be read before it will start
2293 over.  In list context, this isn't important because you automatically
2294 get them all anyway.  However, in scalar context the operator returns
2295 the next value each time it's called, or C<undef> when the list has
2296 run out.  As with filehandle reads, an automatic C<defined> is
2297 generated when the glob occurs in the test part of a C<while>,
2298 because legal glob returns (e.g. a file called F<0>) would otherwise
2299 terminate the loop.  Again, C<undef> is returned only once.  So if
2300 you're expecting a single value from a glob, it is much better to
2301 say
2302
2303     ($file) = <blurch*>;
2304
2305 than
2306
2307     $file = <blurch*>;
2308
2309 because the latter will alternate between returning a filename and
2310 returning false.
2311
2312 If you're trying to do variable interpolation, it's definitely better
2313 to use the glob() function, because the older notation can cause people
2314 to become confused with the indirect filehandle notation.
2315
2316     @files = glob("$dir/*.[ch]");
2317     @files = glob($files[$i]);
2318
2319 =head2 Constant Folding
2320 X<constant folding> X<folding>
2321
2322 Like C, Perl does a certain amount of expression evaluation at
2323 compile time whenever it determines that all arguments to an
2324 operator are static and have no side effects.  In particular, string
2325 concatenation happens at compile time between literals that don't do
2326 variable substitution.  Backslash interpolation also happens at
2327 compile time.  You can say
2328
2329     'Now is the time for all' . "\n" .
2330         'good men to come to.'
2331
2332 and this all reduces to one string internally.  Likewise, if
2333 you say
2334
2335     foreach $file (@filenames) {
2336         if (-s $file > 5 + 100 * 2**16) {  }
2337     }
2338
2339 the compiler will precompute the number which that expression
2340 represents so that the interpreter won't have to.
2341
2342 =head2 No-ops
2343 X<no-op> X<nop>
2344
2345 Perl doesn't officially have a no-op operator, but the bare constants
2346 C<0> and C<1> are special-cased to not produce a warning in a void
2347 context, so you can for example safely do
2348
2349     1 while foo();
2350
2351 =head2 Bitwise String Operators
2352 X<operator, bitwise, string>
2353
2354 Bitstrings of any size may be manipulated by the bitwise operators
2355 (C<~ | & ^>).
2356
2357 If the operands to a binary bitwise op are strings of different
2358 sizes, B<|> and B<^> ops act as though the shorter operand had
2359 additional zero bits on the right, while the B<&> op acts as though
2360 the longer operand were truncated to the length of the shorter.
2361 The granularity for such extension or truncation is one or more
2362 bytes.
2363
2364     # ASCII-based examples
2365     print "j p \n" ^ " a h";            # prints "JAPH\n"
2366     print "JA" | "  ph\n";              # prints "japh\n"
2367     print "japh\nJunk" & '_____';       # prints "JAPH\n";
2368     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
2369
2370 If you are intending to manipulate bitstrings, be certain that
2371 you're supplying bitstrings: If an operand is a number, that will imply
2372 a B<numeric> bitwise operation.  You may explicitly show which type of
2373 operation you intend by using C<""> or C<0+>, as in the examples below.
2374
2375     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
2376     $foo = '150' |  105;        # yields 255
2377     $foo =  150  | '105';       # yields 255
2378     $foo = '150' | '105';       # yields string '155' (under ASCII)
2379
2380     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
2381     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
2382
2383 See L<perlfunc/vec> for information on how to manipulate individual bits
2384 in a bit vector.
2385
2386 =head2 Integer Arithmetic
2387 X<integer>
2388
2389 By default, Perl assumes that it must do most of its arithmetic in
2390 floating point.  But by saying
2391
2392     use integer;
2393
2394 you may tell the compiler that it's okay to use integer operations
2395 (if it feels like it) from here to the end of the enclosing BLOCK.
2396 An inner BLOCK may countermand this by saying
2397
2398     no integer;
2399
2400 which lasts until the end of that BLOCK.  Note that this doesn't
2401 mean everything is only an integer, merely that Perl may use integer
2402 operations if it is so inclined.  For example, even under C<use
2403 integer>, if you take the C<sqrt(2)>, you'll still get C<1.4142135623731>
2404 or so.
2405
2406 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
2407 and ">>") always produce integral results.  (But see also
2408 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
2409 them.  By default, their results are interpreted as unsigned integers, but
2410 if C<use integer> is in effect, their results are interpreted
2411 as signed integers.  For example, C<~0> usually evaluates to a large
2412 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
2413 machines.
2414
2415 =head2 Floating-point Arithmetic
2416 X<floating-point> X<floating point> X<float> X<real>
2417
2418 While C<use integer> provides integer-only arithmetic, there is no
2419 analogous mechanism to provide automatic rounding or truncation to a
2420 certain number of decimal places.  For rounding to a certain number
2421 of digits, sprintf() or printf() is usually the easiest route.
2422 See L<perlfaq4>.
2423
2424 Floating-point numbers are only approximations to what a mathematician
2425 would call real numbers.  There are infinitely more reals than floats,
2426 so some corners must be cut.  For example:
2427
2428     printf "%.20g\n", 123456789123456789;
2429     #        produces 123456789123456784
2430
2431 Testing for exact equality of floating-point equality or inequality is
2432 not a good idea.  Here's a (relatively expensive) work-around to compare
2433 whether two floating-point numbers are equal to a particular number of
2434 decimal places.  See Knuth, volume II, for a more robust treatment of
2435 this topic.
2436
2437     sub fp_equal {
2438         my ($X, $Y, $POINTS) = @_;
2439         my ($tX, $tY);
2440         $tX = sprintf("%.${POINTS}g", $X);
2441         $tY = sprintf("%.${POINTS}g", $Y);
2442         return $tX eq $tY;
2443     }
2444
2445 The POSIX module (part of the standard perl distribution) implements
2446 ceil(), floor(), and other mathematical and trigonometric functions.
2447 The Math::Complex module (part of the standard perl distribution)
2448 defines mathematical functions that work on both the reals and the
2449 imaginary numbers.  Math::Complex not as efficient as POSIX, but
2450 POSIX can't work with complex numbers.
2451
2452 Rounding in financial applications can have serious implications, and
2453 the rounding method used should be specified precisely.  In these
2454 cases, it probably pays not to trust whichever system rounding is
2455 being used by Perl, but to instead implement the rounding function you
2456 need yourself.
2457
2458 =head2 Bigger Numbers
2459 X<number, arbitrary precision>
2460
2461 The standard Math::BigInt and Math::BigFloat modules provide
2462 variable-precision arithmetic and overloaded operators, although
2463 they're currently pretty slow. At the cost of some space and
2464 considerable speed, they avoid the normal pitfalls associated with
2465 limited-precision representations.
2466
2467     use Math::BigInt;
2468     $x = Math::BigInt->new('123456789123456789');
2469     print $x * $x;
2470
2471     # prints +15241578780673678515622620750190521
2472
2473 There are several modules that let you calculate with (bound only by
2474 memory and cpu-time) unlimited or fixed precision. There are also
2475 some non-standard modules that provide faster implementations via
2476 external C libraries.
2477
2478 Here is a short, but incomplete summary:
2479
2480         Math::Fraction          big, unlimited fractions like 9973 / 12967
2481         Math::String            treat string sequences like numbers
2482         Math::FixedPrecision    calculate with a fixed precision
2483         Math::Currency          for currency calculations
2484         Bit::Vector             manipulate bit vectors fast (uses C)
2485         Math::BigIntFast        Bit::Vector wrapper for big numbers
2486         Math::Pari              provides access to the Pari C library
2487         Math::BigInteger        uses an external C library
2488         Math::Cephes            uses external Cephes C library (no big numbers)
2489         Math::Cephes::Fraction  fractions via the Cephes library
2490         Math::GMP               another one using an external C library
2491
2492 Choose wisely.
2493
2494 =cut