This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
01426c88e897d8ae50e798300cb837e366c20380
[perl5.git] / t / loc_tools.pl
1 # Common tools for test files files to find the locales which exist on the
2 # system.  Caller should have verified that this isn't miniperl before calling
3 # the functions.
4
5 # Note that it's okay that some languages have their native names
6 # capitalized here even though that's not "right".  They are lowercased
7 # anyway later during the scanning process (and besides, some clueless
8 # vendor might have them capitalized erroneously anyway).
9
10 # Functions whose names begin with underscore are internal helper functions
11 # for this file, and are not to be used by outside callers.
12
13 use Config;
14 use strict;
15
16 eval { require POSIX; import POSIX 'locale_h'; };
17 my $has_locale_h = ! $@;
18
19 my @known_categories = ( qw(LC_ALL LC_COLLATE LC_CTYPE LC_MESSAGES LC_MONETARY
20                             LC_NUMERIC LC_TIME LC_ADDRESS LC_IDENTIFICATION
21                             LC_MEASUREMENT LC_PAPER LC_TELEPHONE));
22 my @platform_categories;
23
24 # LC_ALL can be -1 on some platforms.  And, in fact the implementors could
25 # legally use any integer to represent any category.  But it makes the most
26 # sense for them to have used small integers.  Below, we create new locale
27 # numbers for ones missing from this machine.  We make them very negative,
28 # hopefully more negative than anything likely to be a valid category on the
29 # platform, but also below is a check to be sure that our guess is valid.
30 my $max_bad_category_number = -1000000;
31
32 # Initialize this hash so that it looks like e.g.,
33 #   6 => 'CTYPE',
34 # where 6 is the value of &POSIX::LC_CTYPE
35 my %category_name;
36 my %category_number;
37 if ($has_locale_h) {
38     my $number_for_missing_category = $max_bad_category_number;
39     foreach my $name (@known_categories) {
40         my $number = eval "&POSIX::$name";
41         if ($@) {
42             # Use a negative number (smaller than any legitimate category
43             # number) if the platform doesn't support this category, so we
44             # have an entry for all the ones that might be specified in calls
45             # to us.
46             $number = $number_for_missing_category-- if $@;
47         }
48         elsif (   $number !~ / ^ -? \d+ $ /x
49                || $number <=  $max_bad_category_number)
50         {
51             # We think this should be an int.  And it has to be larger than
52             # any of our synthetic numbers.
53             die "Unexpected locale category number '$number' for $name"
54         }
55         else {
56             push @platform_categories, $name;
57         }
58
59         $name =~ s/LC_//;
60         $category_name{$number} = "$name";
61         $category_number{$name} = $number;
62     }
63 }
64
65 sub _my_diag($) {
66     my $message = shift;
67     if (defined &main::diag) {
68         diag($message);
69     }
70     else {
71         local($\, $", $,) = (undef, ' ', '');
72         print STDERR $message, "\n";
73     }
74 }
75
76 sub _my_fail($) {
77     my $message = shift;
78     if (defined &main::fail) {
79         fail($message);
80     }
81     else {
82         local($\, $", $,) = (undef, ' ', '');
83         print "not ok 0 $message\n";
84     }
85 }
86
87 sub _trylocale ($$$$) { # For use only by other functions in this file!
88
89     # Adds the locale given by the first parameter to the list given by the
90     # 3rd iff the platform supports the locale in each of the category numbers
91     # given by the 2nd parameter, which is either a single category or a
92     # reference to a list of categories.  The list MUST be sorted so that
93     # CTYPE is first, COLLATE is last unless ALL is present, in which case
94     # that comes after COLLATE.  This is because locale.c detects bad locales
95     # only with CTYPE, and COLLATE on some platforms can core dump if it is a
96     # bad locale.
97     #
98     # The 4th parameter is true if to accept locales that aren't apparently
99     # fully compatible with Perl.
100
101     my $locale = shift;
102     my $categories = shift;
103     my $list = shift;
104     my $allow_incompatible = shift;
105
106     return if ! $locale || grep { $locale eq $_ } @$list;
107
108     # This is a toy (pig latin) locale that is not fully implemented on some
109     # systems
110     return if $locale =~ / ^ pig $ /ix;
111
112     # Certain platforms have a crippled locale system in which setlocale
113     # returns success for just about any possible locale name, but if anything
114     # actually happens as a result of the call, it is that the underlying
115     # locale is set to a system default, likely C or C.UTF-8.  We can't test
116     # such systems fully, but we shouldn't disable the user from using
117     # locales, as it may work out for them (or not).
118     return if    defined $Config{d_setlocale_accepts_any_locale_name}
119               && $locale !~ / ^ (?: C | POSIX | C\.UTF-8 ) $/ix;
120
121     $categories = [ $categories ] unless ref $categories;
122
123     my $badutf8 = 0;
124     my $plays_well = 1;
125
126     use warnings 'locale';
127
128     local $SIG{__WARN__} = sub {
129         $badutf8 = 1 if grep { /Malformed UTF-8/ } @_;
130         $plays_well = 0 if grep {
131                     /Locale .* may not work well(?#
132                    )|The Perl program will use the expected meanings/i
133             } @_;
134     };
135
136     # Incompatible locales aren't warned about unless using locales.
137     use locale;
138
139     foreach my $category (@$categories) {
140         die "category '$category' must instead be a number"
141                                             unless $category =~ / ^ -? \d+ $ /x;
142
143         return unless setlocale($category, $locale);
144         last if $badutf8 || ! $plays_well;
145     }
146
147     if ($badutf8) {
148         _my_fail("Verify locale name doesn't contain malformed utf8");
149         return;
150     }
151     push @$list, $locale if $plays_well || $allow_incompatible;
152 }
153
154 sub _decode_encodings { # For use only by other functions in this file!
155     my @enc;
156
157     foreach (split(/ /, shift)) {
158         if (/^(\d+)$/) {
159             push @enc, "ISO8859-$1";
160             push @enc, "iso8859$1";     # HP
161             if ($1 eq '1') {
162                  push @enc, "roman8";   # HP
163             }
164             push @enc, $_;
165             push @enc, "$_.UTF-8";
166             push @enc, "$_.65001"; # Windows UTF-8
167             push @enc, "$_.ACP"; # Windows ANSI code page
168             push @enc, "$_.OCP"; # Windows OEM code page
169             push @enc, "$_.1252"; # Windows
170         }
171     }
172     if ($^O eq 'os390') {
173         push @enc, qw(IBM-037 IBM-819 IBM-1047);
174     }
175     push @enc, "UTF-8";
176     push @enc, "65001"; # Windows UTF-8
177
178     return @enc;
179 }
180
181 sub valid_locale_categories() {
182     # Returns a list of the locale categories (expressed as strings, like
183     # "LC_ALL) known to this program that are available on this platform.
184
185     return @platform_categories;
186 }
187
188 sub locales_enabled(;$) {
189     # Returns 0 if no locale handling is available on this platform; otherwise
190     # 1.
191     #
192     # The optional parameter is a reference to a list of individual POSIX
193     # locale categories.  If any of the individual categories specified by the
194     # optional parameter is all digits (and an optional leading minus), it is
195     # taken to be the C enum for the category (e.g., &POSIX::LC_CTYPE).
196     # Otherwise it should be a string name of the category, like 'LC_TIME'.
197     # The initial 'LC_' is optional.  It is a fatal error to call this with
198     # something that isn't a known category to this file.
199     #
200     # This optional parameter denotes which POSIX locale categories must be
201     # available on the platform.  If any aren't available, this function
202     # returns 0; otherwise it returns 1 and changes the list for the caller so
203     # that any category names are converted into their equivalent numbers, and
204     # sorts it to match the expectations of _trylocale.
205     #
206     # It is acceptable for the second parameter to be just a simple scalar
207     # denoting a single category (either name or number).  No conversion into
208     # a number is done in this case.
209
210     # khw cargo-culted the '?' in the pattern on the next line.
211     return 0 if $Config{ccflags} =~ /\bD?NO_LOCALE\b/;
212
213     if (! $Config{d_setlocale}) {
214         return 0 if $Config{ccflags} =~ /\bD?NO_POSIX_2008_LOCALE\b/;
215         return 0 unless $Config{d_newlocale};
216         return 0 unless $Config{d_uselocale};
217         return 0 unless $Config{d_duplocale};
218         return 0 unless $Config{d_freelocale};
219     }
220
221     # Done with the global possibilities.  Now check if any passed in category
222     # is disabled.
223
224     my $categories_ref = shift;
225     my $return_categories_numbers = 0;
226     my @categories_numbers;
227     my $has_LC_ALL = 0;
228     my $has_LC_COLLATE = 0;
229
230     if (defined $categories_ref) {
231         my @local_categories_copy;
232
233         if (ref $categories_ref) {
234             @local_categories_copy = @$$categories_ref;
235             $return_categories_numbers = 1;
236         }
237         else {  # Single category passed in
238             @local_categories_copy = $categories_ref;
239         }
240
241         for my $category_name_or_number (@local_categories_copy) {
242             my $name;
243             my $number;
244             if ($category_name_or_number =~ / ^ -? \d+ $ /x) {
245                 $number = $category_name_or_number;
246                 die "Invalid locale category number '$number'"
247                     unless grep { $number == $_ } keys %category_name;
248                 $name = $category_name{$number};
249             }
250             else {
251                 $name = $category_name_or_number;
252                 $name =~ s/ ^ LC_ //x;
253                 foreach my $trial (keys %category_name) {
254                     if ($category_name{$trial} eq $name) {
255                         $number = $trial;
256                         last;
257                     }
258                 }
259                 die "Invalid locale category name '$name'"
260                     unless defined $number;
261             }
262
263             return 0 if    $number <= $max_bad_category_number
264                         || $Config{ccflags} =~ /\bD?NO_LOCALE_$name\b/;
265
266             eval "defined &POSIX::LC_$name";
267             return 0 if $@;
268
269             if ($return_categories_numbers) {
270                 if ($name eq 'CTYPE') {
271                     unshift @categories_numbers, $number;   # Always first
272                 }
273                 elsif ($name eq 'ALL') {
274                     $has_LC_ALL = 1;
275                 }
276                 elsif ($name eq 'COLLATE') {
277                     $has_LC_COLLATE = 1;
278                 }
279                 else {
280                     push @categories_numbers, $number;
281                 }
282             }
283         }
284     }
285
286     if ($return_categories_numbers) {
287
288         # COLLATE comes after all other locales except ALL, which comes last
289         if ($has_LC_COLLATE) {
290             push @categories_numbers, $category_number{'COLLATE'};
291         }
292         if ($has_LC_ALL) {
293             push @categories_numbers, $category_number{'ALL'};
294         }
295         $$categories_ref = \@categories_numbers;
296     }
297
298     return 1;
299 }
300
301
302 sub find_locales ($;$) {
303
304     # Returns an array of all the locales we found on the system.  If the
305     # optional 2nd parameter is non-zero, the list includes all found locales;
306     # otherwise it is restricted to those locales that play well with Perl, as
307     # far as we can easily determine.
308     #
309     # The first parameter is either a single locale category or a reference to
310     # a list of categories to find valid locales for it (or in the case of
311     # multiple) for all of them.  Each category can be a name (like 'LC_ALL'
312     # or simply 'ALL') or the C enum value for the category.
313
314     my $categories = shift;
315     my $allow_incompatible = shift // 0;
316
317     $categories = [ $categories ] unless ref $categories;
318     return unless locales_enabled(\$categories);
319
320     # Note, the subroutine call above converts the $categories into a form
321     # suitable for _trylocale().
322
323     # Visual C's CRT goes silly on strings of the form "en_US.ISO8859-1"
324     # and mingw32 uses said silly CRT
325     # This doesn't seem to be an issue any more, at least on Windows XP,
326     # so re-enable the tests for Windows XP onwards.
327     my $winxp = ($^O eq 'MSWin32' && defined &Win32::GetOSVersion &&
328                     join('.', (Win32::GetOSVersion())[1..2]) >= 5.1);
329     return if ((($^O eq 'MSWin32' && !$winxp) || $^O eq 'NetWare')
330                 && $Config{cc} =~ /^(cl|gcc|g\+\+|ici)/i);
331
332     # UWIN seems to loop after taint tests, just skip for now
333     return if ($^O =~ /^uwin/);
334
335     my @Locale;
336     _trylocale("C", $categories, \@Locale, $allow_incompatible);
337     _trylocale("POSIX", $categories, \@Locale, $allow_incompatible);
338
339     if ($Config{d_has_C_UTF8} eq 'true') {
340         _trylocale("C.UTF-8", $categories, \@Locale, $allow_incompatible);
341     }
342
343     # There's no point in looking at anything more if we know that setlocale
344     # will return success on any garbage or non-garbage name.
345     return sort @Locale if defined $Config{d_setlocale_accepts_any_locale_name};
346
347     foreach (1..16) {
348         _trylocale("ISO8859-$_", $categories, \@Locale, $allow_incompatible);
349         _trylocale("iso8859$_", $categories, \@Locale, $allow_incompatible);
350         _trylocale("iso8859-$_", $categories, \@Locale, $allow_incompatible);
351         _trylocale("iso_8859_$_", $categories, \@Locale, $allow_incompatible);
352         _trylocale("isolatin$_", $categories, \@Locale, $allow_incompatible);
353         _trylocale("isolatin-$_", $categories, \@Locale, $allow_incompatible);
354         _trylocale("iso_latin_$_", $categories, \@Locale, $allow_incompatible);
355     }
356
357     # Sanitize the environment so that we can run the external 'locale'
358     # program without the taint mode getting grumpy.
359
360     # $ENV{PATH} is special in VMS.
361     delete local $ENV{PATH} if $^O ne 'VMS' or $Config{d_setenv};
362
363     # Other subversive stuff.
364     delete local @ENV{qw(IFS CDPATH ENV BASH_ENV)};
365
366     if (-x "/usr/bin/locale"
367         && open(LOCALES, '-|', "/usr/bin/locale -a 2>/dev/null"))
368     {
369         while (<LOCALES>) {
370             # It seems that /usr/bin/locale steadfastly outputs 8 bit data, which
371             # ain't great when we're running this testPERL_UNICODE= so that utf8
372             # locales will cause all IO hadles to default to (assume) utf8
373             next unless utf8::valid($_);
374             chomp;
375             _trylocale($_, $categories, \@Locale, $allow_incompatible);
376         }
377         close(LOCALES);
378     } elsif ($^O eq 'VMS'
379              && defined($ENV{'SYS$I18N_LOCALE'})
380              && -d 'SYS$I18N_LOCALE')
381     {
382     # The SYS$I18N_LOCALE logical name search list was not present on
383     # VAX VMS V5.5-12, but was on AXP && VAX VMS V6.2 as well as later versions.
384         opendir(LOCALES, "SYS\$I18N_LOCALE:");
385         while ($_ = readdir(LOCALES)) {
386             chomp;
387             _trylocale($_, $categories, \@Locale, $allow_incompatible);
388         }
389         close(LOCALES);
390     } elsif (($^O eq 'openbsd' || $^O eq 'bitrig' ) && -e '/usr/share/locale') {
391
392         # OpenBSD doesn't have a locale executable, so reading
393         # /usr/share/locale is much easier and faster than the last resort
394         # method.
395
396         opendir(LOCALES, '/usr/share/locale');
397         while ($_ = readdir(LOCALES)) {
398             chomp;
399             _trylocale($_, $categories, \@Locale, $allow_incompatible);
400         }
401         close(LOCALES);
402     } else { # Final fallback.  Try our list of locales hard-coded here
403
404         # This is going to be slow.
405         my @Data;
406
407         # Locales whose name differs if the utf8 bit is on are stored in these
408         # two files with appropriate encodings.
409         my $data_file = ($^H & 0x08 || (${^OPEN} || "") =~ /:utf8/)
410                         ? _source_location() . "/lib/locale/utf8"
411                         : _source_location() . "/lib/locale/latin1";
412         if (-e $data_file) {
413             @Data = do $data_file;
414         }
415         else {
416             _my_diag(__FILE__ . ":" . __LINE__ . ": '$data_file' doesn't exist");
417         }
418
419         # The rest of the locales are in this file.
420         push @Data, <DATA>;
421
422         foreach my $line (@Data) {
423             my ($locale_name, $language_codes, $country_codes, $encodings) =
424                 split /:/, $line;
425             _my_diag(__FILE__ . ":" . __LINE__ . ": Unexpected syntax in '$line'")
426                                                      unless defined $locale_name;
427             my @enc = _decode_encodings($encodings);
428             foreach my $loc (split(/ /, $locale_name)) {
429                 _trylocale($loc, $categories, \@Locale, $allow_incompatible);
430                 foreach my $enc (@enc) {
431                     _trylocale("$loc.$enc", $categories, \@Locale,
432                                                             $allow_incompatible);
433                 }
434                 $loc = lc $loc;
435                 foreach my $enc (@enc) {
436                     _trylocale("$loc.$enc", $categories, \@Locale,
437                                                             $allow_incompatible);
438                 }
439             }
440             foreach my $lang (split(/ /, $language_codes)) {
441                 _trylocale($lang, $categories, \@Locale, $allow_incompatible);
442                 foreach my $country (split(/ /, $country_codes)) {
443                     my $lc = "${lang}_${country}";
444                     _trylocale($lc, $categories, \@Locale, $allow_incompatible);
445                     foreach my $enc (@enc) {
446                         _trylocale("$lc.$enc", $categories, \@Locale,
447                                                             $allow_incompatible);
448                     }
449                     my $lC = "${lang}_\U${country}";
450                     _trylocale($lC, $categories, \@Locale, $allow_incompatible);
451                     foreach my $enc (@enc) {
452                         _trylocale("$lC.$enc", $categories, \@Locale,
453                                                             $allow_incompatible);
454                     }
455                 }
456             }
457         }
458     }
459
460     @Locale = sort @Locale;
461
462     return @Locale;
463 }
464
465 sub is_locale_utf8 ($) { # Return a boolean as to if core Perl thinks the input
466                          # is a UTF-8 locale
467
468     # On z/OS, even locales marked as UTF-8 aren't.
469     return 0 if ord "A" != 65;
470
471     return 0 unless locales_enabled('LC_CTYPE');
472
473     my $locale = shift;
474
475     use locale;
476     no warnings 'locale'; # We may be trying out a weird locale
477
478     my $save_locale = setlocale(&POSIX::LC_CTYPE());
479     if (! $save_locale) {
480         ok(0, "Verify could save previous locale");
481         return 0;
482     }
483
484     if (! setlocale(&POSIX::LC_CTYPE(), $locale)) {
485         ok(0, "Verify could setlocale to $locale");
486         return 0;
487     }
488
489     my $ret = 0;
490
491     # Use an op that gives different results for UTF-8 than any other locale.
492     # If a platform has UTF-8 locales, there should be at least one locale on
493     # most platforms with UTF-8 in its name, so if there is a bug in the op
494     # giving a false negative, we should get a failure for those locales as we
495     # go through testing all the locales on the platform.
496     if (CORE::fc(chr utf8::unicode_to_native(0xdf)) ne "ss") {
497         if ($locale =~ /UTF-?8/i) {
498             ok (0, "Verify $locale with UTF-8 in name is a UTF-8 locale");
499         }
500     }
501     else {
502         $ret = 1;
503     }
504
505     die "Couldn't restore locale '$save_locale'"
506         unless setlocale(&POSIX::LC_CTYPE(), $save_locale);
507
508     return $ret;
509 }
510
511 sub find_utf8_ctype_locales (;$) { # Return the names of the locales that core
512                                   # Perl thinks are UTF-8 LC_CTYPE locales.
513                                   # Optional parameter is a reference to a
514                                   # list of locales to try; if omitted, this
515                                   # tries all locales it can find on the
516                                   # platform
517     return unless locales_enabled('LC_CTYPE');
518
519     my $locales_ref = shift;
520     my @return;
521
522     if (! defined $locales_ref) {
523
524         my @locales = find_locales(&POSIX::LC_CTYPE());
525         $locales_ref = \@locales;
526     }
527
528     foreach my $locale (@$locales_ref) {
529         push @return, $locale if is_locale_utf8($locale);
530     }
531
532     return @return;
533 }
534
535
536 sub find_utf8_ctype_locale (;$) { # Return the name of a locale that core Perl
537                                   # thinks is a UTF-8 LC_CTYPE non-turkic
538                                   # locale.
539                                   # Optional parameter is a reference to a
540                                   # list of locales to try; if omitted, this
541                                   # tries all locales it can find on the
542                                   # platform
543     my $try_locales_ref = shift;
544
545     my @utf8_locales = find_utf8_ctype_locales($try_locales_ref);
546     my @turkic_locales = find_utf8_turkic_locales($try_locales_ref);
547
548     my %seen_turkic;
549
550     # Create undef elements in the hash for turkic locales
551     @seen_turkic{@turkic_locales} = ();
552
553     foreach my $locale (@utf8_locales) {
554         return $locale unless exists $seen_turkic{$locale};
555     }
556
557     return;
558 }
559
560 sub find_utf8_turkic_locales (;$) {
561
562     # Return the name of all the locales that core Perl thinks are UTF-8
563     # Turkic LC_CTYPE.  Optional parameter is a reference to a list of locales
564     # to try; if omitted, this tries all locales it can find on the platform
565
566     my @return;
567
568     my $save_locale = setlocale(&POSIX::LC_CTYPE());
569     foreach my $locale (find_utf8_ctype_locales(shift)) {
570         use locale;
571         setlocale(&POSIX::LC_CTYPE(), $locale);
572         push @return, $locale if uc('i') eq "\x{130}";
573     }
574     setlocale(&POSIX::LC_CTYPE(), $save_locale);
575
576     return @return;
577 }
578
579 sub find_utf8_turkic_locale (;$) {
580     my @turkics = find_utf8_turkic_locales(shift);
581
582     return unless @turkics;
583     return $turkics[0]
584 }
585
586
587 # returns full path to the directory containing the current source
588 # file, inspired by mauke's Dir::Self
589 sub _source_location {
590     require File::Spec;
591
592     my $caller_filename = (caller)[1];
593
594     my $loc = File::Spec->rel2abs(
595         File::Spec->catpath(
596             (File::Spec->splitpath($caller_filename))[0, 1], ''
597         )
598     );
599
600     return ($loc =~ /^(.*)$/)[0]; # untaint
601 }
602
603 1
604
605 # Format of data is: locale_name, language_codes, country_codes, encodings
606 __DATA__
607 Afrikaans:af:za:1 15
608 Arabic:ar:dz eg sa:6 arabic8
609 Brezhoneg Breton:br:fr:1 15
610 Bulgarski Bulgarian:bg:bg:5
611 Chinese:zh:cn tw:cn.EUC eucCN eucTW euc.CN euc.TW Big5 GB2312 tw.EUC
612 Hrvatski Croatian:hr:hr:2
613 Cymraeg Welsh:cy:cy:1 14 15
614 Czech:cs:cz:2
615 Dansk Danish:da:dk:1 15
616 Nederlands Dutch:nl:be nl:1 15
617 English American British:en:au ca gb ie nz us uk zw:1 15 cp850
618 Esperanto:eo:eo:3
619 Eesti Estonian:et:ee:4 6 13
620 Suomi Finnish:fi:fi:1 15
621 Flamish::fl:1 15
622 Deutsch German:de:at be ch de lu:1 15
623 Euskaraz Basque:eu:es fr:1 15
624 Galego Galician:gl:es:1 15
625 Ellada Greek:el:gr:7 g8
626 Frysk:fy:nl:1 15
627 Greenlandic:kl:gl:4 6
628 Hebrew:iw:il:8 hebrew8
629 Hungarian:hu:hu:2
630 Indonesian:id:id:1 15
631 Gaeilge Irish:ga:IE:1 14 15
632 Italiano Italian:it:ch it:1 15
633 Nihongo Japanese:ja:jp:euc eucJP jp.EUC sjis
634 Korean:ko:kr:
635 Latine Latin:la:va:1 15
636 Latvian:lv:lv:4 6 13
637 Lithuanian:lt:lt:4 6 13
638 Macedonian:mk:mk:1 15
639 Maltese:mt:mt:3
640 Moldovan:mo:mo:2
641 Norsk Norwegian:no no\@nynorsk nb nn:no:1 15
642 Occitan:oc:es:1 15
643 Polski Polish:pl:pl:2
644 Rumanian:ro:ro:2
645 Russki Russian:ru:ru su ua:5 koi8 koi8r KOI8-R koi8u cp1251 cp866
646 Serbski Serbian:sr:yu:5
647 Slovak:sk:sk:2
648 Slovene Slovenian:sl:si:2
649 Sqhip Albanian:sq:sq:1 15
650 Svenska Swedish:sv:fi se:1 15
651 Thai:th:th:11 tis620
652 Turkish:tr:tr:9 turkish8
653 Yiddish:yi::1 15