| 1 | =head1 NAME |
| 2 | |
| 3 | perlfunc - Perl builtin functions |
| 4 | |
| 5 | =head1 DESCRIPTION |
| 6 | |
| 7 | The functions in this section can serve as terms in an expression. |
| 8 | They fall into two major categories: list operators and named unary |
| 9 | operators. These differ in their precedence relationship with a |
| 10 | following comma. (See the precedence table in L<perlop>.) List |
| 11 | operators take more than one argument, while unary operators can never |
| 12 | take more than one argument. Thus, a comma terminates the argument of |
| 13 | a unary operator, but merely separates the arguments of a list |
| 14 | operator. A unary operator generally provides a scalar context to its |
| 15 | argument, while a list operator may provide either scalar or list |
| 16 | contexts for its arguments. If it does both, the scalar arguments will |
| 17 | be first, and the list argument will follow. (Note that there can ever |
| 18 | be only one such list argument.) For instance, splice() has three scalar |
| 19 | arguments followed by a list, whereas gethostbyname() has four scalar |
| 20 | arguments. |
| 21 | |
| 22 | In the syntax descriptions that follow, list operators that expect a |
| 23 | list (and provide list context for the elements of the list) are shown |
| 24 | with LIST as an argument. Such a list may consist of any combination |
| 25 | of scalar arguments or list values; the list values will be included |
| 26 | in the list as if each individual element were interpolated at that |
| 27 | point in the list, forming a longer single-dimensional list value. |
| 28 | Elements of the LIST should be separated by commas. |
| 29 | |
| 30 | Any function in the list below may be used either with or without |
| 31 | parentheses around its arguments. (The syntax descriptions omit the |
| 32 | parentheses.) If you use the parentheses, the simple (but occasionally |
| 33 | surprising) rule is this: It I<looks> like a function, therefore it I<is> a |
| 34 | function, and precedence doesn't matter. Otherwise it's a list |
| 35 | operator or unary operator, and precedence does matter. And whitespace |
| 36 | between the function and left parenthesis doesn't count--so you need to |
| 37 | be careful sometimes: |
| 38 | |
| 39 | print 1+2+4; # Prints 7. |
| 40 | print(1+2) + 4; # Prints 3. |
| 41 | print (1+2)+4; # Also prints 3! |
| 42 | print +(1+2)+4; # Prints 7. |
| 43 | print ((1+2)+4); # Prints 7. |
| 44 | |
| 45 | If you run Perl with the B<-w> switch it can warn you about this. For |
| 46 | example, the third line above produces: |
| 47 | |
| 48 | print (...) interpreted as function at - line 1. |
| 49 | Useless use of integer addition in void context at - line 1. |
| 50 | |
| 51 | A few functions take no arguments at all, and therefore work as neither |
| 52 | unary nor list operators. These include such functions as C<time> |
| 53 | and C<endpwent>. For example, C<time+86_400> always means |
| 54 | C<time() + 86_400>. |
| 55 | |
| 56 | For functions that can be used in either a scalar or list context, |
| 57 | nonabortive failure is generally indicated in a scalar context by |
| 58 | returning the undefined value, and in a list context by returning the |
| 59 | null list. |
| 60 | |
| 61 | Remember the following important rule: There is B<no rule> that relates |
| 62 | the behavior of an expression in list context to its behavior in scalar |
| 63 | context, or vice versa. It might do two totally different things. |
| 64 | Each operator and function decides which sort of value it would be most |
| 65 | appropriate to return in scalar context. Some operators return the |
| 66 | length of the list that would have been returned in list context. Some |
| 67 | operators return the first value in the list. Some operators return the |
| 68 | last value in the list. Some operators return a count of successful |
| 69 | operations. In general, they do what you want, unless you want |
| 70 | consistency. |
| 71 | |
| 72 | An named array in scalar context is quite different from what would at |
| 73 | first glance appear to be a list in scalar context. You can't get a list |
| 74 | like C<(1,2,3)> into being in scalar context, because the compiler knows |
| 75 | the context at compile time. It would generate the scalar comma operator |
| 76 | there, not the list construction version of the comma. That means it |
| 77 | was never a list to start with. |
| 78 | |
| 79 | In general, functions in Perl that serve as wrappers for system calls |
| 80 | of the same name (like chown(2), fork(2), closedir(2), etc.) all return |
| 81 | true when they succeed and C<undef> otherwise, as is usually mentioned |
| 82 | in the descriptions below. This is different from the C interfaces, |
| 83 | which return C<-1> on failure. Exceptions to this rule are C<wait>, |
| 84 | C<waitpid>, and C<syscall>. System calls also set the special C<$!> |
| 85 | variable on failure. Other functions do not, except accidentally. |
| 86 | |
| 87 | =head2 Perl Functions by Category |
| 88 | |
| 89 | Here are Perl's functions (including things that look like |
| 90 | functions, like some keywords and named operators) |
| 91 | arranged by category. Some functions appear in more |
| 92 | than one place. |
| 93 | |
| 94 | =over |
| 95 | |
| 96 | =item Functions for SCALARs or strings |
| 97 | |
| 98 | C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>, |
| 99 | C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>, |
| 100 | C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///> |
| 101 | |
| 102 | =item Regular expressions and pattern matching |
| 103 | |
| 104 | C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//> |
| 105 | |
| 106 | =item Numeric functions |
| 107 | |
| 108 | C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>, |
| 109 | C<sin>, C<sqrt>, C<srand> |
| 110 | |
| 111 | =item Functions for real @ARRAYs |
| 112 | |
| 113 | C<pop>, C<push>, C<shift>, C<splice>, C<unshift> |
| 114 | |
| 115 | =item Functions for list data |
| 116 | |
| 117 | C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack> |
| 118 | |
| 119 | =item Functions for real %HASHes |
| 120 | |
| 121 | C<delete>, C<each>, C<exists>, C<keys>, C<values> |
| 122 | |
| 123 | =item Input and output functions |
| 124 | |
| 125 | C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>, |
| 126 | C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>, |
| 127 | C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>, |
| 128 | C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>, |
| 129 | C<warn>, C<write> |
| 130 | |
| 131 | =item Functions for fixed length data or records |
| 132 | |
| 133 | C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec> |
| 134 | |
| 135 | =item Functions for filehandles, files, or directories |
| 136 | |
| 137 | C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>, |
| 138 | C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>, |
| 139 | C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>, |
| 140 | C<unlink>, C<utime> |
| 141 | |
| 142 | =item Keywords related to the control flow of your perl program |
| 143 | |
| 144 | C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>, |
| 145 | C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray> |
| 146 | |
| 147 | =item Keywords related to scoping |
| 148 | |
| 149 | C<caller>, C<import>, C<local>, C<my>, C<package>, C<use> |
| 150 | |
| 151 | =item Miscellaneous functions |
| 152 | |
| 153 | C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<reset>, |
| 154 | C<scalar>, C<undef>, C<wantarray> |
| 155 | |
| 156 | =item Functions for processes and process groups |
| 157 | |
| 158 | C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>, |
| 159 | C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>, |
| 160 | C<times>, C<wait>, C<waitpid> |
| 161 | |
| 162 | =item Keywords related to perl modules |
| 163 | |
| 164 | C<do>, C<import>, C<no>, C<package>, C<require>, C<use> |
| 165 | |
| 166 | =item Keywords related to classes and object-orientedness |
| 167 | |
| 168 | C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>, |
| 169 | C<untie>, C<use> |
| 170 | |
| 171 | =item Low-level socket functions |
| 172 | |
| 173 | C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>, |
| 174 | C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>, |
| 175 | C<socket>, C<socketpair> |
| 176 | |
| 177 | =item System V interprocess communication functions |
| 178 | |
| 179 | C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>, |
| 180 | C<shmctl>, C<shmget>, C<shmread>, C<shmwrite> |
| 181 | |
| 182 | =item Fetching user and group info |
| 183 | |
| 184 | C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>, |
| 185 | C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>, |
| 186 | C<getpwuid>, C<setgrent>, C<setpwent> |
| 187 | |
| 188 | =item Fetching network info |
| 189 | |
| 190 | C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>, |
| 191 | C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>, |
| 192 | C<getprotobyname>, C<getprotobynumber>, C<getprotoent>, |
| 193 | C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>, |
| 194 | C<setnetent>, C<setprotoent>, C<setservent> |
| 195 | |
| 196 | =item Time-related functions |
| 197 | |
| 198 | C<gmtime>, C<localtime>, C<time>, C<times> |
| 199 | |
| 200 | =item Functions new in perl5 |
| 201 | |
| 202 | C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>, |
| 203 | C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<prototype>, C<qx>, |
| 204 | C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>, |
| 205 | C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use> |
| 206 | |
| 207 | * - C<sub> was a keyword in perl4, but in perl5 it is an |
| 208 | operator, which can be used in expressions. |
| 209 | |
| 210 | =item Functions obsoleted in perl5 |
| 211 | |
| 212 | C<dbmclose>, C<dbmopen> |
| 213 | |
| 214 | =back |
| 215 | |
| 216 | =head2 Portability |
| 217 | |
| 218 | Perl was born in Unix and can therefore access all common Unix |
| 219 | system calls. In non-Unix environments, the functionality of some |
| 220 | Unix system calls may not be available, or details of the available |
| 221 | functionality may differ slightly. The Perl functions affected |
| 222 | by this are: |
| 223 | |
| 224 | C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>, |
| 225 | C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>, |
| 226 | C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>, |
| 227 | C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>, |
| 228 | C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>, |
| 229 | C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>, |
| 230 | C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>, |
| 231 | C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>, |
| 232 | C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>, |
| 233 | C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>, |
| 234 | C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>, |
| 235 | C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>, |
| 236 | C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>, |
| 237 | C<shmwrite>, C<socket>, C<socketpair>, C<stat>, C<symlink>, C<syscall>, |
| 238 | C<sysopen>, C<system>, C<times>, C<truncate>, C<umask>, C<unlink>, |
| 239 | C<utime>, C<wait>, C<waitpid> |
| 240 | |
| 241 | For more information about the portability of these functions, see |
| 242 | L<perlport> and other available platform-specific documentation. |
| 243 | |
| 244 | =head2 Alphabetical Listing of Perl Functions |
| 245 | |
| 246 | =over 8 |
| 247 | |
| 248 | =item I<-X> FILEHANDLE |
| 249 | |
| 250 | =item I<-X> EXPR |
| 251 | |
| 252 | =item I<-X> |
| 253 | |
| 254 | A file test, where X is one of the letters listed below. This unary |
| 255 | operator takes one argument, either a filename or a filehandle, and |
| 256 | tests the associated file to see if something is true about it. If the |
| 257 | argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN. |
| 258 | Unless otherwise documented, it returns C<1> for true and C<''> for false, or |
| 259 | the undefined value if the file doesn't exist. Despite the funny |
| 260 | names, precedence is the same as any other named unary operator, and |
| 261 | the argument may be parenthesized like any other unary operator. The |
| 262 | operator may be any of: |
| 263 | X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p> |
| 264 | X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C> |
| 265 | |
| 266 | -r File is readable by effective uid/gid. |
| 267 | -w File is writable by effective uid/gid. |
| 268 | -x File is executable by effective uid/gid. |
| 269 | -o File is owned by effective uid. |
| 270 | |
| 271 | -R File is readable by real uid/gid. |
| 272 | -W File is writable by real uid/gid. |
| 273 | -X File is executable by real uid/gid. |
| 274 | -O File is owned by real uid. |
| 275 | |
| 276 | -e File exists. |
| 277 | -z File has zero size. |
| 278 | -s File has nonzero size (returns size). |
| 279 | |
| 280 | -f File is a plain file. |
| 281 | -d File is a directory. |
| 282 | -l File is a symbolic link. |
| 283 | -p File is a named pipe (FIFO), or Filehandle is a pipe. |
| 284 | -S File is a socket. |
| 285 | -b File is a block special file. |
| 286 | -c File is a character special file. |
| 287 | -t Filehandle is opened to a tty. |
| 288 | |
| 289 | -u File has setuid bit set. |
| 290 | -g File has setgid bit set. |
| 291 | -k File has sticky bit set. |
| 292 | |
| 293 | -T File is an ASCII text file. |
| 294 | -B File is a "binary" file (opposite of -T). |
| 295 | |
| 296 | -M Age of file in days when script started. |
| 297 | -A Same for access time. |
| 298 | -C Same for inode change time. |
| 299 | |
| 300 | Example: |
| 301 | |
| 302 | while (<>) { |
| 303 | chop; |
| 304 | next unless -f $_; # ignore specials |
| 305 | #... |
| 306 | } |
| 307 | |
| 308 | The interpretation of the file permission operators C<-r>, C<-R>, |
| 309 | C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode |
| 310 | of the file and the uids and gids of the user. There may be other |
| 311 | reasons you can't actually read, write, or execute the file. Such |
| 312 | reasons may be for example network filesystem access controls, ACLs |
| 313 | (access control lists), read-only filesystems, and unrecognized |
| 314 | executable formats. |
| 315 | |
| 316 | Also note that, for the superuser on the local filesystems, the C<-r>, |
| 317 | C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1 |
| 318 | if any execute bit is set in the mode. Scripts run by the superuser |
| 319 | may thus need to do a stat() to determine the actual mode of the file, |
| 320 | or temporarily set their effective uid to something else. |
| 321 | |
| 322 | If you are using ACLs, there is a pragma called C<filetest> that may |
| 323 | produce more accurate results than the bare stat() mode bits. |
| 324 | When under the C<use filetest 'access'> the above-mentioned filetests |
| 325 | will test whether the permission can (not) be granted using the |
| 326 | access() family of system calls. Also note that the C<-x> and C<-X> may |
| 327 | under this pragma return true even if there are no execute permission |
| 328 | bits set (nor any extra execute permission ACLs). This strangeness is |
| 329 | due to the underlying system calls' definitions. Read the |
| 330 | documentation for the C<filetest> pragma for more information. |
| 331 | |
| 332 | Note that C<-s/a/b/> does not do a negated substitution. Saying |
| 333 | C<-exp($foo)> still works as expected, however--only single letters |
| 334 | following a minus are interpreted as file tests. |
| 335 | |
| 336 | The C<-T> and C<-B> switches work as follows. The first block or so of the |
| 337 | file is examined for odd characters such as strange control codes or |
| 338 | characters with the high bit set. If too many strange characters (>30%) |
| 339 | are found, it's a C<-B> file, otherwise it's a C<-T> file. Also, any file |
| 340 | containing null in the first block is considered a binary file. If C<-T> |
| 341 | or C<-B> is used on a filehandle, the current stdio buffer is examined |
| 342 | rather than the first block. Both C<-T> and C<-B> return true on a null |
| 343 | file, or a file at EOF when testing a filehandle. Because you have to |
| 344 | read a file to do the C<-T> test, on most occasions you want to use a C<-f> |
| 345 | against the file first, as in C<next unless -f $file && -T $file>. |
| 346 | |
| 347 | If any of the file tests (or either the C<stat> or C<lstat> operators) are given |
| 348 | the special filehandle consisting of a solitary underline, then the stat |
| 349 | structure of the previous file test (or stat operator) is used, saving |
| 350 | a system call. (This doesn't work with C<-t>, and you need to remember |
| 351 | that lstat() and C<-l> will leave values in the stat structure for the |
| 352 | symbolic link, not the real file.) Example: |
| 353 | |
| 354 | print "Can do.\n" if -r $a || -w _ || -x _; |
| 355 | |
| 356 | stat($filename); |
| 357 | print "Readable\n" if -r _; |
| 358 | print "Writable\n" if -w _; |
| 359 | print "Executable\n" if -x _; |
| 360 | print "Setuid\n" if -u _; |
| 361 | print "Setgid\n" if -g _; |
| 362 | print "Sticky\n" if -k _; |
| 363 | print "Text\n" if -T _; |
| 364 | print "Binary\n" if -B _; |
| 365 | |
| 366 | =item abs VALUE |
| 367 | |
| 368 | =item abs |
| 369 | |
| 370 | Returns the absolute value of its argument. |
| 371 | If VALUE is omitted, uses C<$_>. |
| 372 | |
| 373 | =item accept NEWSOCKET,GENERICSOCKET |
| 374 | |
| 375 | Accepts an incoming socket connect, just as the accept(2) system call |
| 376 | does. Returns the packed address if it succeeded, false otherwise. |
| 377 | See the example in L<perlipc/"Sockets: Client/Server Communication">. |
| 378 | |
| 379 | On systems that support a close-on-exec flag on files, the flag will |
| 380 | be set for the newly opened file descriptor, as determined by the |
| 381 | value of $^F. See L<perlvar/$^F>. |
| 382 | |
| 383 | =item alarm SECONDS |
| 384 | |
| 385 | =item alarm |
| 386 | |
| 387 | Arranges to have a SIGALRM delivered to this process after the |
| 388 | specified number of seconds have elapsed. If SECONDS is not specified, |
| 389 | the value stored in C<$_> is used. (On some machines, |
| 390 | unfortunately, the elapsed time may be up to one second less than you |
| 391 | specified because of how seconds are counted.) Only one timer may be |
| 392 | counting at once. Each call disables the previous timer, and an |
| 393 | argument of C<0> may be supplied to cancel the previous timer without |
| 394 | starting a new one. The returned value is the amount of time remaining |
| 395 | on the previous timer. |
| 396 | |
| 397 | For delays of finer granularity than one second, you may use Perl's |
| 398 | four-argument version of select() leaving the first three arguments |
| 399 | undefined, or you might be able to use the C<syscall> interface to |
| 400 | access setitimer(2) if your system supports it. The Time::HiRes module |
| 401 | from CPAN may also prove useful. |
| 402 | |
| 403 | It is usually a mistake to intermix C<alarm> and C<sleep> calls. |
| 404 | (C<sleep> may be internally implemented in your system with C<alarm>) |
| 405 | |
| 406 | If you want to use C<alarm> to time out a system call you need to use an |
| 407 | C<eval>/C<die> pair. You can't rely on the alarm causing the system call to |
| 408 | fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to |
| 409 | restart system calls on some systems. Using C<eval>/C<die> always works, |
| 410 | modulo the caveats given in L<perlipc/"Signals">. |
| 411 | |
| 412 | eval { |
| 413 | local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required |
| 414 | alarm $timeout; |
| 415 | $nread = sysread SOCKET, $buffer, $size; |
| 416 | alarm 0; |
| 417 | }; |
| 418 | if ($@) { |
| 419 | die unless $@ eq "alarm\n"; # propagate unexpected errors |
| 420 | # timed out |
| 421 | } |
| 422 | else { |
| 423 | # didn't |
| 424 | } |
| 425 | |
| 426 | =item atan2 Y,X |
| 427 | |
| 428 | Returns the arctangent of Y/X in the range -PI to PI. |
| 429 | |
| 430 | For the tangent operation, you may use the C<Math::Trig::tan> |
| 431 | function, or use the familiar relation: |
| 432 | |
| 433 | sub tan { sin($_[0]) / cos($_[0]) } |
| 434 | |
| 435 | =item bind SOCKET,NAME |
| 436 | |
| 437 | Binds a network address to a socket, just as the bind system call |
| 438 | does. Returns true if it succeeded, false otherwise. NAME should be a |
| 439 | packed address of the appropriate type for the socket. See the examples in |
| 440 | L<perlipc/"Sockets: Client/Server Communication">. |
| 441 | |
| 442 | =item binmode FILEHANDLE, DISCIPLINE |
| 443 | |
| 444 | =item binmode FILEHANDLE |
| 445 | |
| 446 | Arranges for FILEHANDLE to be read or written in "binary" or "text" mode |
| 447 | on systems where the run-time libraries distinguish between binary and |
| 448 | text files. If FILEHANDLE is an expression, the value is taken as the |
| 449 | name of the filehandle. DISCIPLINE can be either of C<":raw"> for |
| 450 | binary mode or C<":crlf"> for "text" mode. If the DISCIPLINE is |
| 451 | omitted, it defaults to C<":raw">. |
| 452 | |
| 453 | binmode() should be called after open() but before any I/O is done on |
| 454 | the filehandle. |
| 455 | |
| 456 | On many systems binmode() currently has no effect, but in future, it |
| 457 | will be extended to support user-defined input and output disciplines. |
| 458 | On some systems binmode() is necessary when you're not working with a |
| 459 | text file. For the sake of portability it is a good idea to always use |
| 460 | it when appropriate, and to never use it when it isn't appropriate. |
| 461 | |
| 462 | In other words: Regardless of platform, use binmode() on binary |
| 463 | files, and do not use binmode() on text files. |
| 464 | |
| 465 | The C<open> pragma can be used to establish default disciplines. |
| 466 | See L<open>. |
| 467 | |
| 468 | The operating system, device drivers, C libraries, and Perl run-time |
| 469 | system all work together to let the programmer treat a single |
| 470 | character (C<\n>) as the line terminator, irrespective of the external |
| 471 | representation. On many operating systems, the native text file |
| 472 | representation matches the internal representation, but on some |
| 473 | platforms the external representation of C<\n> is made up of more than |
| 474 | one character. |
| 475 | |
| 476 | Mac OS and all variants of Unix use a single character to end each line |
| 477 | in the external representation of text (even though that single |
| 478 | character is not necessarily the same across these platforms). |
| 479 | Consequently binmode() has no effect on these operating systems. In |
| 480 | other systems like VMS, MS-DOS and the various flavors of MS-Windows |
| 481 | your program sees a C<\n> as a simple C<\cJ>, but what's stored in text |
| 482 | files are the two characters C<\cM\cJ>. That means that, if you don't |
| 483 | use binmode() on these systems, C<\cM\cJ> sequences on disk will be |
| 484 | converted to C<\n> on input, and any C<\n> in your program will be |
| 485 | converted back to C<\cM\cJ> on output. This is what you want for text |
| 486 | files, but it can be disastrous for binary files. |
| 487 | |
| 488 | Another consequence of using binmode() (on some systems) is that |
| 489 | special end-of-file markers will be seen as part of the data stream. |
| 490 | For systems from the Microsoft family this means that if your binary |
| 491 | data contains C<\cZ>, the I/O subsystem will ragard it as the end of |
| 492 | the file, unless you use binmode(). |
| 493 | |
| 494 | binmode() is not only important for readline() and print() operations, |
| 495 | but also when using read(), seek(), sysread(), syswrite() and tell() |
| 496 | (see L<perlport> for more details). See the C<$/> and C<$\> variables |
| 497 | in L<perlvar> for how to manually set your input and output |
| 498 | line-termination sequences. |
| 499 | |
| 500 | =item bless REF,CLASSNAME |
| 501 | |
| 502 | =item bless REF |
| 503 | |
| 504 | This function tells the thingy referenced by REF that it is now an object |
| 505 | in the CLASSNAME package. If CLASSNAME is omitted, the current package |
| 506 | is used. Because a C<bless> is often the last thing in a constructor, |
| 507 | it returns the reference for convenience. Always use the two-argument |
| 508 | version if the function doing the blessing might be inherited by a |
| 509 | derived class. See L<perltoot> and L<perlobj> for more about the blessing |
| 510 | (and blessings) of objects. |
| 511 | |
| 512 | Consider always blessing objects in CLASSNAMEs that are mixed case. |
| 513 | Namespaces with all lowercase names are considered reserved for |
| 514 | Perl pragmata. Builtin types have all uppercase names, so to prevent |
| 515 | confusion, you may wish to avoid such package names as well. Make sure |
| 516 | that CLASSNAME is a true value. |
| 517 | |
| 518 | See L<perlmod/"Perl Modules">. |
| 519 | |
| 520 | =item caller EXPR |
| 521 | |
| 522 | =item caller |
| 523 | |
| 524 | Returns the context of the current subroutine call. In scalar context, |
| 525 | returns the caller's package name if there is a caller, that is, if |
| 526 | we're in a subroutine or C<eval> or C<require>, and the undefined value |
| 527 | otherwise. In list context, returns |
| 528 | |
| 529 | ($package, $filename, $line) = caller; |
| 530 | |
| 531 | With EXPR, it returns some extra information that the debugger uses to |
| 532 | print a stack trace. The value of EXPR indicates how many call frames |
| 533 | to go back before the current one. |
| 534 | |
| 535 | ($package, $filename, $line, $subroutine, $hasargs, |
| 536 | $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i); |
| 537 | |
| 538 | Here $subroutine may be C<(eval)> if the frame is not a subroutine |
| 539 | call, but an C<eval>. In such a case additional elements $evaltext and |
| 540 | C<$is_require> are set: C<$is_require> is true if the frame is created by a |
| 541 | C<require> or C<use> statement, $evaltext contains the text of the |
| 542 | C<eval EXPR> statement. In particular, for a C<eval BLOCK> statement, |
| 543 | $filename is C<(eval)>, but $evaltext is undefined. (Note also that |
| 544 | each C<use> statement creates a C<require> frame inside an C<eval EXPR>) |
| 545 | frame. C<$hints> and C<$bitmask> contain pragmatic hints that the caller |
| 546 | was compiled with. The C<$hints> and C<$bitmask> values are subject to |
| 547 | change between versions of Perl, and are not meant for external use. |
| 548 | |
| 549 | Furthermore, when called from within the DB package, caller returns more |
| 550 | detailed information: it sets the list variable C<@DB::args> to be the |
| 551 | arguments with which the subroutine was invoked. |
| 552 | |
| 553 | Be aware that the optimizer might have optimized call frames away before |
| 554 | C<caller> had a chance to get the information. That means that C<caller(N)> |
| 555 | might not return information about the call frame you expect it do, for |
| 556 | C<< N > 1 >>. In particular, C<@DB::args> might have information from the |
| 557 | previous time C<caller> was called. |
| 558 | |
| 559 | =item chdir EXPR |
| 560 | |
| 561 | Changes the working directory to EXPR, if possible. If EXPR is omitted, |
| 562 | changes to the directory specified by C<$ENV{HOME}>, if set; if not, |
| 563 | changes to the directory specified by C<$ENV{LOGDIR}>. If neither is |
| 564 | set, C<chdir> does nothing. It returns true upon success, false |
| 565 | otherwise. See the example under C<die>. |
| 566 | |
| 567 | =item chmod LIST |
| 568 | |
| 569 | Changes the permissions of a list of files. The first element of the |
| 570 | list must be the numerical mode, which should probably be an octal |
| 571 | number, and which definitely should I<not> a string of octal digits: |
| 572 | C<0644> is okay, C<'0644'> is not. Returns the number of files |
| 573 | successfully changed. See also L</oct>, if all you have is a string. |
| 574 | |
| 575 | $cnt = chmod 0755, 'foo', 'bar'; |
| 576 | chmod 0755, @executables; |
| 577 | $mode = '0644'; chmod $mode, 'foo'; # !!! sets mode to |
| 578 | # --w----r-T |
| 579 | $mode = '0644'; chmod oct($mode), 'foo'; # this is better |
| 580 | $mode = 0644; chmod $mode, 'foo'; # this is best |
| 581 | |
| 582 | You can also import the symbolic C<S_I*> constants from the Fcntl |
| 583 | module: |
| 584 | |
| 585 | use Fcntl ':mode'; |
| 586 | |
| 587 | chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables; |
| 588 | # This is identical to the chmod 0755 of the above example. |
| 589 | |
| 590 | =item chomp VARIABLE |
| 591 | |
| 592 | =item chomp LIST |
| 593 | |
| 594 | =item chomp |
| 595 | |
| 596 | This safer version of L</chop> removes any trailing string |
| 597 | that corresponds to the current value of C<$/> (also known as |
| 598 | $INPUT_RECORD_SEPARATOR in the C<English> module). It returns the total |
| 599 | number of characters removed from all its arguments. It's often used to |
| 600 | remove the newline from the end of an input record when you're worried |
| 601 | that the final record may be missing its newline. When in paragraph |
| 602 | mode (C<$/ = "">), it removes all trailing newlines from the string. |
| 603 | When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is |
| 604 | a reference to an integer or the like, see L<perlvar>) chomp() won't |
| 605 | remove anything. |
| 606 | If VARIABLE is omitted, it chomps C<$_>. Example: |
| 607 | |
| 608 | while (<>) { |
| 609 | chomp; # avoid \n on last field |
| 610 | @array = split(/:/); |
| 611 | # ... |
| 612 | } |
| 613 | |
| 614 | You can actually chomp anything that's an lvalue, including an assignment: |
| 615 | |
| 616 | chomp($cwd = `pwd`); |
| 617 | chomp($answer = <STDIN>); |
| 618 | |
| 619 | If you chomp a list, each element is chomped, and the total number of |
| 620 | characters removed is returned. |
| 621 | |
| 622 | =item chop VARIABLE |
| 623 | |
| 624 | =item chop LIST |
| 625 | |
| 626 | =item chop |
| 627 | |
| 628 | Chops off the last character of a string and returns the character |
| 629 | chopped. It's used primarily to remove the newline from the end of an |
| 630 | input record, but is much more efficient than C<s/\n//> because it neither |
| 631 | scans nor copies the string. If VARIABLE is omitted, chops C<$_>. |
| 632 | Example: |
| 633 | |
| 634 | while (<>) { |
| 635 | chop; # avoid \n on last field |
| 636 | @array = split(/:/); |
| 637 | #... |
| 638 | } |
| 639 | |
| 640 | You can actually chop anything that's an lvalue, including an assignment: |
| 641 | |
| 642 | chop($cwd = `pwd`); |
| 643 | chop($answer = <STDIN>); |
| 644 | |
| 645 | If you chop a list, each element is chopped. Only the value of the |
| 646 | last C<chop> is returned. |
| 647 | |
| 648 | Note that C<chop> returns the last character. To return all but the last |
| 649 | character, use C<substr($string, 0, -1)>. |
| 650 | |
| 651 | =item chown LIST |
| 652 | |
| 653 | Changes the owner (and group) of a list of files. The first two |
| 654 | elements of the list must be the I<numeric> uid and gid, in that |
| 655 | order. A value of -1 in either position is interpreted by most |
| 656 | systems to leave that value unchanged. Returns the number of files |
| 657 | successfully changed. |
| 658 | |
| 659 | $cnt = chown $uid, $gid, 'foo', 'bar'; |
| 660 | chown $uid, $gid, @filenames; |
| 661 | |
| 662 | Here's an example that looks up nonnumeric uids in the passwd file: |
| 663 | |
| 664 | print "User: "; |
| 665 | chomp($user = <STDIN>); |
| 666 | print "Files: "; |
| 667 | chomp($pattern = <STDIN>); |
| 668 | |
| 669 | ($login,$pass,$uid,$gid) = getpwnam($user) |
| 670 | or die "$user not in passwd file"; |
| 671 | |
| 672 | @ary = glob($pattern); # expand filenames |
| 673 | chown $uid, $gid, @ary; |
| 674 | |
| 675 | On most systems, you are not allowed to change the ownership of the |
| 676 | file unless you're the superuser, although you should be able to change |
| 677 | the group to any of your secondary groups. On insecure systems, these |
| 678 | restrictions may be relaxed, but this is not a portable assumption. |
| 679 | On POSIX systems, you can detect this condition this way: |
| 680 | |
| 681 | use POSIX qw(sysconf _PC_CHOWN_RESTRICTED); |
| 682 | $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED); |
| 683 | |
| 684 | =item chr NUMBER |
| 685 | |
| 686 | =item chr |
| 687 | |
| 688 | Returns the character represented by that NUMBER in the character set. |
| 689 | For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and |
| 690 | chr(0x263a) is a Unicode smiley face (but only within the scope of |
| 691 | a C<use utf8>). For the reverse, use L</ord>. |
| 692 | See L<utf8> for more about Unicode. |
| 693 | |
| 694 | If NUMBER is omitted, uses C<$_>. |
| 695 | |
| 696 | =item chroot FILENAME |
| 697 | |
| 698 | =item chroot |
| 699 | |
| 700 | This function works like the system call by the same name: it makes the |
| 701 | named directory the new root directory for all further pathnames that |
| 702 | begin with a C</> by your process and all its children. (It doesn't |
| 703 | change your current working directory, which is unaffected.) For security |
| 704 | reasons, this call is restricted to the superuser. If FILENAME is |
| 705 | omitted, does a C<chroot> to C<$_>. |
| 706 | |
| 707 | =item close FILEHANDLE |
| 708 | |
| 709 | =item close |
| 710 | |
| 711 | Closes the file or pipe associated with the file handle, returning true |
| 712 | only if stdio successfully flushes buffers and closes the system file |
| 713 | descriptor. Closes the currently selected filehandle if the argument |
| 714 | is omitted. |
| 715 | |
| 716 | You don't have to close FILEHANDLE if you are immediately going to do |
| 717 | another C<open> on it, because C<open> will close it for you. (See |
| 718 | C<open>.) However, an explicit C<close> on an input file resets the line |
| 719 | counter (C<$.>), while the implicit close done by C<open> does not. |
| 720 | |
| 721 | If the file handle came from a piped open C<close> will additionally |
| 722 | return false if one of the other system calls involved fails or if the |
| 723 | program exits with non-zero status. (If the only problem was that the |
| 724 | program exited non-zero C<$!> will be set to C<0>.) Closing a pipe |
| 725 | also waits for the process executing on the pipe to complete, in case you |
| 726 | want to look at the output of the pipe afterwards, and |
| 727 | implicitly puts the exit status value of that command into C<$?>. |
| 728 | |
| 729 | Prematurely closing the read end of a pipe (i.e. before the process |
| 730 | writing to it at the other end has closed it) will result in a |
| 731 | SIGPIPE being delivered to the writer. If the other end can't |
| 732 | handle that, be sure to read all the data before closing the pipe. |
| 733 | |
| 734 | Example: |
| 735 | |
| 736 | open(OUTPUT, '|sort >foo') # pipe to sort |
| 737 | or die "Can't start sort: $!"; |
| 738 | #... # print stuff to output |
| 739 | close OUTPUT # wait for sort to finish |
| 740 | or warn $! ? "Error closing sort pipe: $!" |
| 741 | : "Exit status $? from sort"; |
| 742 | open(INPUT, 'foo') # get sort's results |
| 743 | or die "Can't open 'foo' for input: $!"; |
| 744 | |
| 745 | FILEHANDLE may be an expression whose value can be used as an indirect |
| 746 | filehandle, usually the real filehandle name. |
| 747 | |
| 748 | =item closedir DIRHANDLE |
| 749 | |
| 750 | Closes a directory opened by C<opendir> and returns the success of that |
| 751 | system call. |
| 752 | |
| 753 | DIRHANDLE may be an expression whose value can be used as an indirect |
| 754 | dirhandle, usually the real dirhandle name. |
| 755 | |
| 756 | =item connect SOCKET,NAME |
| 757 | |
| 758 | Attempts to connect to a remote socket, just as the connect system call |
| 759 | does. Returns true if it succeeded, false otherwise. NAME should be a |
| 760 | packed address of the appropriate type for the socket. See the examples in |
| 761 | L<perlipc/"Sockets: Client/Server Communication">. |
| 762 | |
| 763 | =item continue BLOCK |
| 764 | |
| 765 | Actually a flow control statement rather than a function. If there is a |
| 766 | C<continue> BLOCK attached to a BLOCK (typically in a C<while> or |
| 767 | C<foreach>), it is always executed just before the conditional is about to |
| 768 | be evaluated again, just like the third part of a C<for> loop in C. Thus |
| 769 | it can be used to increment a loop variable, even when the loop has been |
| 770 | continued via the C<next> statement (which is similar to the C C<continue> |
| 771 | statement). |
| 772 | |
| 773 | C<last>, C<next>, or C<redo> may appear within a C<continue> |
| 774 | block. C<last> and C<redo> will behave as if they had been executed within |
| 775 | the main block. So will C<next>, but since it will execute a C<continue> |
| 776 | block, it may be more entertaining. |
| 777 | |
| 778 | while (EXPR) { |
| 779 | ### redo always comes here |
| 780 | do_something; |
| 781 | } continue { |
| 782 | ### next always comes here |
| 783 | do_something_else; |
| 784 | # then back the top to re-check EXPR |
| 785 | } |
| 786 | ### last always comes here |
| 787 | |
| 788 | Omitting the C<continue> section is semantically equivalent to using an |
| 789 | empty one, logically enough. In that case, C<next> goes directly back |
| 790 | to check the condition at the top of the loop. |
| 791 | |
| 792 | =item cos EXPR |
| 793 | |
| 794 | Returns the cosine of EXPR (expressed in radians). If EXPR is omitted, |
| 795 | takes cosine of C<$_>. |
| 796 | |
| 797 | For the inverse cosine operation, you may use the C<Math::Trig::acos()> |
| 798 | function, or use this relation: |
| 799 | |
| 800 | sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) } |
| 801 | |
| 802 | =item crypt PLAINTEXT,SALT |
| 803 | |
| 804 | Encrypts a string exactly like the crypt(3) function in the C library |
| 805 | (assuming that you actually have a version there that has not been |
| 806 | extirpated as a potential munition). This can prove useful for checking |
| 807 | the password file for lousy passwords, amongst other things. Only the |
| 808 | guys wearing white hats should do this. |
| 809 | |
| 810 | Note that C<crypt> is intended to be a one-way function, much like breaking |
| 811 | eggs to make an omelette. There is no (known) corresponding decrypt |
| 812 | function. As a result, this function isn't all that useful for |
| 813 | cryptography. (For that, see your nearby CPAN mirror.) |
| 814 | |
| 815 | When verifying an existing encrypted string you should use the encrypted |
| 816 | text as the salt (like C<crypt($plain, $crypted) eq $crypted>). This |
| 817 | allows your code to work with the standard C<crypt> and with more |
| 818 | exotic implementations. When choosing a new salt create a random two |
| 819 | character string whose characters come from the set C<[./0-9A-Za-z]> |
| 820 | (like C<join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>). |
| 821 | |
| 822 | Here's an example that makes sure that whoever runs this program knows |
| 823 | their own password: |
| 824 | |
| 825 | $pwd = (getpwuid($<))[1]; |
| 826 | |
| 827 | system "stty -echo"; |
| 828 | print "Password: "; |
| 829 | chomp($word = <STDIN>); |
| 830 | print "\n"; |
| 831 | system "stty echo"; |
| 832 | |
| 833 | if (crypt($word, $pwd) ne $pwd) { |
| 834 | die "Sorry...\n"; |
| 835 | } else { |
| 836 | print "ok\n"; |
| 837 | } |
| 838 | |
| 839 | Of course, typing in your own password to whoever asks you |
| 840 | for it is unwise. |
| 841 | |
| 842 | The L<crypt> function is unsuitable for encrypting large quantities |
| 843 | of data, not least of all because you can't get the information |
| 844 | back. Look at the F<by-module/Crypt> and F<by-module/PGP> directories |
| 845 | on your favorite CPAN mirror for a slew of potentially useful |
| 846 | modules. |
| 847 | |
| 848 | =item dbmclose HASH |
| 849 | |
| 850 | [This function has been largely superseded by the C<untie> function.] |
| 851 | |
| 852 | Breaks the binding between a DBM file and a hash. |
| 853 | |
| 854 | =item dbmopen HASH,DBNAME,MASK |
| 855 | |
| 856 | [This function has been largely superseded by the C<tie> function.] |
| 857 | |
| 858 | This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a |
| 859 | hash. HASH is the name of the hash. (Unlike normal C<open>, the first |
| 860 | argument is I<not> a filehandle, even though it looks like one). DBNAME |
| 861 | is the name of the database (without the F<.dir> or F<.pag> extension if |
| 862 | any). If the database does not exist, it is created with protection |
| 863 | specified by MASK (as modified by the C<umask>). If your system supports |
| 864 | only the older DBM functions, you may perform only one C<dbmopen> in your |
| 865 | program. In older versions of Perl, if your system had neither DBM nor |
| 866 | ndbm, calling C<dbmopen> produced a fatal error; it now falls back to |
| 867 | sdbm(3). |
| 868 | |
| 869 | If you don't have write access to the DBM file, you can only read hash |
| 870 | variables, not set them. If you want to test whether you can write, |
| 871 | either use file tests or try setting a dummy hash entry inside an C<eval>, |
| 872 | which will trap the error. |
| 873 | |
| 874 | Note that functions such as C<keys> and C<values> may return huge lists |
| 875 | when used on large DBM files. You may prefer to use the C<each> |
| 876 | function to iterate over large DBM files. Example: |
| 877 | |
| 878 | # print out history file offsets |
| 879 | dbmopen(%HIST,'/usr/lib/news/history',0666); |
| 880 | while (($key,$val) = each %HIST) { |
| 881 | print $key, ' = ', unpack('L',$val), "\n"; |
| 882 | } |
| 883 | dbmclose(%HIST); |
| 884 | |
| 885 | See also L<AnyDBM_File> for a more general description of the pros and |
| 886 | cons of the various dbm approaches, as well as L<DB_File> for a particularly |
| 887 | rich implementation. |
| 888 | |
| 889 | You can control which DBM library you use by loading that library |
| 890 | before you call dbmopen(): |
| 891 | |
| 892 | use DB_File; |
| 893 | dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db") |
| 894 | or die "Can't open netscape history file: $!"; |
| 895 | |
| 896 | =item defined EXPR |
| 897 | |
| 898 | =item defined |
| 899 | |
| 900 | Returns a Boolean value telling whether EXPR has a value other than |
| 901 | the undefined value C<undef>. If EXPR is not present, C<$_> will be |
| 902 | checked. |
| 903 | |
| 904 | Many operations return C<undef> to indicate failure, end of file, |
| 905 | system error, uninitialized variable, and other exceptional |
| 906 | conditions. This function allows you to distinguish C<undef> from |
| 907 | other values. (A simple Boolean test will not distinguish among |
| 908 | C<undef>, zero, the empty string, and C<"0">, which are all equally |
| 909 | false.) Note that since C<undef> is a valid scalar, its presence |
| 910 | doesn't I<necessarily> indicate an exceptional condition: C<pop> |
| 911 | returns C<undef> when its argument is an empty array, I<or> when the |
| 912 | element to return happens to be C<undef>. |
| 913 | |
| 914 | You may also use C<defined(&func)> to check whether subroutine C<&func> |
| 915 | has ever been defined. The return value is unaffected by any forward |
| 916 | declarations of C<&foo>. |
| 917 | |
| 918 | Use of C<defined> on aggregates (hashes and arrays) is deprecated. It |
| 919 | used to report whether memory for that aggregate has ever been |
| 920 | allocated. This behavior may disappear in future versions of Perl. |
| 921 | You should instead use a simple test for size: |
| 922 | |
| 923 | if (@an_array) { print "has array elements\n" } |
| 924 | if (%a_hash) { print "has hash members\n" } |
| 925 | |
| 926 | When used on a hash element, it tells you whether the value is defined, |
| 927 | not whether the key exists in the hash. Use L</exists> for the latter |
| 928 | purpose. |
| 929 | |
| 930 | Examples: |
| 931 | |
| 932 | print if defined $switch{'D'}; |
| 933 | print "$val\n" while defined($val = pop(@ary)); |
| 934 | die "Can't readlink $sym: $!" |
| 935 | unless defined($value = readlink $sym); |
| 936 | sub foo { defined &$bar ? &$bar(@_) : die "No bar"; } |
| 937 | $debugging = 0 unless defined $debugging; |
| 938 | |
| 939 | Note: Many folks tend to overuse C<defined>, and then are surprised to |
| 940 | discover that the number C<0> and C<""> (the zero-length string) are, in fact, |
| 941 | defined values. For example, if you say |
| 942 | |
| 943 | "ab" =~ /a(.*)b/; |
| 944 | |
| 945 | The pattern match succeeds, and C<$1> is defined, despite the fact that it |
| 946 | matched "nothing". But it didn't really match nothing--rather, it |
| 947 | matched something that happened to be zero characters long. This is all |
| 948 | very above-board and honest. When a function returns an undefined value, |
| 949 | it's an admission that it couldn't give you an honest answer. So you |
| 950 | should use C<defined> only when you're questioning the integrity of what |
| 951 | you're trying to do. At other times, a simple comparison to C<0> or C<""> is |
| 952 | what you want. |
| 953 | |
| 954 | See also L</undef>, L</exists>, L</ref>. |
| 955 | |
| 956 | =item delete EXPR |
| 957 | |
| 958 | Given an expression that specifies a hash element, array element, hash slice, |
| 959 | or array slice, deletes the specified element(s) from the hash or array. |
| 960 | In the case of an array, if the array elements happen to be at the end, |
| 961 | the size of the array will shrink to the highest element that tests |
| 962 | true for exists() (or 0 if no such element exists). |
| 963 | |
| 964 | Returns each element so deleted or the undefined value if there was no such |
| 965 | element. Deleting from C<$ENV{}> modifies the environment. Deleting from |
| 966 | a hash tied to a DBM file deletes the entry from the DBM file. Deleting |
| 967 | from a C<tie>d hash or array may not necessarily return anything. |
| 968 | |
| 969 | Deleting an array element effectively returns that position of the array |
| 970 | to its initial, uninitialized state. Subsequently testing for the same |
| 971 | element with exists() will return false. Note that deleting array |
| 972 | elements in the middle of an array will not shift the index of the ones |
| 973 | after them down--use splice() for that. See L</exists>. |
| 974 | |
| 975 | The following (inefficiently) deletes all the values of %HASH and @ARRAY: |
| 976 | |
| 977 | foreach $key (keys %HASH) { |
| 978 | delete $HASH{$key}; |
| 979 | } |
| 980 | |
| 981 | foreach $index (0 .. $#ARRAY) { |
| 982 | delete $ARRAY[$index]; |
| 983 | } |
| 984 | |
| 985 | And so do these: |
| 986 | |
| 987 | delete @HASH{keys %HASH}; |
| 988 | |
| 989 | delete @ARRAY[0 .. $#ARRAY]; |
| 990 | |
| 991 | But both of these are slower than just assigning the empty list |
| 992 | or undefining %HASH or @ARRAY: |
| 993 | |
| 994 | %HASH = (); # completely empty %HASH |
| 995 | undef %HASH; # forget %HASH ever existed |
| 996 | |
| 997 | @ARRAY = (); # completely empty @ARRAY |
| 998 | undef @ARRAY; # forget @ARRAY ever existed |
| 999 | |
| 1000 | Note that the EXPR can be arbitrarily complicated as long as the final |
| 1001 | operation is a hash element, array element, hash slice, or array slice |
| 1002 | lookup: |
| 1003 | |
| 1004 | delete $ref->[$x][$y]{$key}; |
| 1005 | delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys}; |
| 1006 | |
| 1007 | delete $ref->[$x][$y][$index]; |
| 1008 | delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices]; |
| 1009 | |
| 1010 | =item die LIST |
| 1011 | |
| 1012 | Outside an C<eval>, prints the value of LIST to C<STDERR> and |
| 1013 | exits with the current value of C<$!> (errno). If C<$!> is C<0>, |
| 1014 | exits with the value of C<<< ($? >> 8) >>> (backtick `command` |
| 1015 | status). If C<<< ($? >> 8) >>> is C<0>, exits with C<255>. Inside |
| 1016 | an C<eval(),> the error message is stuffed into C<$@> and the |
| 1017 | C<eval> is terminated with the undefined value. This makes |
| 1018 | C<die> the way to raise an exception. |
| 1019 | |
| 1020 | Equivalent examples: |
| 1021 | |
| 1022 | die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news'; |
| 1023 | chdir '/usr/spool/news' or die "Can't cd to spool: $!\n" |
| 1024 | |
| 1025 | If the value of EXPR does not end in a newline, the current script line |
| 1026 | number and input line number (if any) are also printed, and a newline |
| 1027 | is supplied. Note that the "input line number" (also known as "chunk") |
| 1028 | is subject to whatever notion of "line" happens to be currently in |
| 1029 | effect, and is also available as the special variable C<$.>. |
| 1030 | See L<perlvar/"$/"> and L<perlvar/"$.">. |
| 1031 | |
| 1032 | Hint: sometimes appending C<", stopped"> to your message |
| 1033 | will cause it to make better sense when the string C<"at foo line 123"> is |
| 1034 | appended. Suppose you are running script "canasta". |
| 1035 | |
| 1036 | die "/etc/games is no good"; |
| 1037 | die "/etc/games is no good, stopped"; |
| 1038 | |
| 1039 | produce, respectively |
| 1040 | |
| 1041 | /etc/games is no good at canasta line 123. |
| 1042 | /etc/games is no good, stopped at canasta line 123. |
| 1043 | |
| 1044 | See also exit(), warn(), and the Carp module. |
| 1045 | |
| 1046 | If LIST is empty and C<$@> already contains a value (typically from a |
| 1047 | previous eval) that value is reused after appending C<"\t...propagated">. |
| 1048 | This is useful for propagating exceptions: |
| 1049 | |
| 1050 | eval { ... }; |
| 1051 | die unless $@ =~ /Expected exception/; |
| 1052 | |
| 1053 | If C<$@> is empty then the string C<"Died"> is used. |
| 1054 | |
| 1055 | die() can also be called with a reference argument. If this happens to be |
| 1056 | trapped within an eval(), $@ contains the reference. This behavior permits |
| 1057 | a more elaborate exception handling implementation using objects that |
| 1058 | maintain arbitary state about the nature of the exception. Such a scheme |
| 1059 | is sometimes preferable to matching particular string values of $@ using |
| 1060 | regular expressions. Here's an example: |
| 1061 | |
| 1062 | eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) }; |
| 1063 | if ($@) { |
| 1064 | if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) { |
| 1065 | # handle Some::Module::Exception |
| 1066 | } |
| 1067 | else { |
| 1068 | # handle all other possible exceptions |
| 1069 | } |
| 1070 | } |
| 1071 | |
| 1072 | Because perl will stringify uncaught exception messages before displaying |
| 1073 | them, you may want to overload stringification operations on such custom |
| 1074 | exception objects. See L<overload> for details about that. |
| 1075 | |
| 1076 | You can arrange for a callback to be run just before the C<die> |
| 1077 | does its deed, by setting the C<$SIG{__DIE__}> hook. The associated |
| 1078 | handler will be called with the error text and can change the error |
| 1079 | message, if it sees fit, by calling C<die> again. See |
| 1080 | L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and |
| 1081 | L<"eval BLOCK"> for some examples. Although this feature was meant |
| 1082 | to be run only right before your program was to exit, this is not |
| 1083 | currently the case--the C<$SIG{__DIE__}> hook is currently called |
| 1084 | even inside eval()ed blocks/strings! If one wants the hook to do |
| 1085 | nothing in such situations, put |
| 1086 | |
| 1087 | die @_ if $^S; |
| 1088 | |
| 1089 | as the first line of the handler (see L<perlvar/$^S>). Because |
| 1090 | this promotes strange action at a distance, this counterintuitive |
| 1091 | behavior may be fixed in a future release. |
| 1092 | |
| 1093 | =item do BLOCK |
| 1094 | |
| 1095 | Not really a function. Returns the value of the last command in the |
| 1096 | sequence of commands indicated by BLOCK. When modified by a loop |
| 1097 | modifier, executes the BLOCK once before testing the loop condition. |
| 1098 | (On other statements the loop modifiers test the conditional first.) |
| 1099 | |
| 1100 | C<do BLOCK> does I<not> count as a loop, so the loop control statements |
| 1101 | C<next>, C<last>, or C<redo> cannot be used to leave or restart the block. |
| 1102 | See L<perlsyn> for alternative strategies. |
| 1103 | |
| 1104 | =item do SUBROUTINE(LIST) |
| 1105 | |
| 1106 | A deprecated form of subroutine call. See L<perlsub>. |
| 1107 | |
| 1108 | =item do EXPR |
| 1109 | |
| 1110 | Uses the value of EXPR as a filename and executes the contents of the |
| 1111 | file as a Perl script. Its primary use is to include subroutines |
| 1112 | from a Perl subroutine library. |
| 1113 | |
| 1114 | do 'stat.pl'; |
| 1115 | |
| 1116 | is just like |
| 1117 | |
| 1118 | scalar eval `cat stat.pl`; |
| 1119 | |
| 1120 | except that it's more efficient and concise, keeps track of the current |
| 1121 | filename for error messages, searches the @INC libraries, and updates |
| 1122 | C<%INC> if the file is found. See L<perlvar/Predefined Names> for these |
| 1123 | variables. It also differs in that code evaluated with C<do FILENAME> |
| 1124 | cannot see lexicals in the enclosing scope; C<eval STRING> does. It's the |
| 1125 | same, however, in that it does reparse the file every time you call it, |
| 1126 | so you probably don't want to do this inside a loop. |
| 1127 | |
| 1128 | If C<do> cannot read the file, it returns undef and sets C<$!> to the |
| 1129 | error. If C<do> can read the file but cannot compile it, it |
| 1130 | returns undef and sets an error message in C<$@>. If the file is |
| 1131 | successfully compiled, C<do> returns the value of the last expression |
| 1132 | evaluated. |
| 1133 | |
| 1134 | Note that inclusion of library modules is better done with the |
| 1135 | C<use> and C<require> operators, which also do automatic error checking |
| 1136 | and raise an exception if there's a problem. |
| 1137 | |
| 1138 | You might like to use C<do> to read in a program configuration |
| 1139 | file. Manual error checking can be done this way: |
| 1140 | |
| 1141 | # read in config files: system first, then user |
| 1142 | for $file ("/share/prog/defaults.rc", |
| 1143 | "$ENV{HOME}/.someprogrc") |
| 1144 | { |
| 1145 | unless ($return = do $file) { |
| 1146 | warn "couldn't parse $file: $@" if $@; |
| 1147 | warn "couldn't do $file: $!" unless defined $return; |
| 1148 | warn "couldn't run $file" unless $return; |
| 1149 | } |
| 1150 | } |
| 1151 | |
| 1152 | =item dump LABEL |
| 1153 | |
| 1154 | =item dump |
| 1155 | |
| 1156 | This function causes an immediate core dump. See also the B<-u> |
| 1157 | command-line switch in L<perlrun>, which does the same thing. |
| 1158 | Primarily this is so that you can use the B<undump> program (not |
| 1159 | supplied) to turn your core dump into an executable binary after |
| 1160 | having initialized all your variables at the beginning of the |
| 1161 | program. When the new binary is executed it will begin by executing |
| 1162 | a C<goto LABEL> (with all the restrictions that C<goto> suffers). |
| 1163 | Think of it as a goto with an intervening core dump and reincarnation. |
| 1164 | If C<LABEL> is omitted, restarts the program from the top. |
| 1165 | |
| 1166 | B<WARNING>: Any files opened at the time of the dump will I<not> |
| 1167 | be open any more when the program is reincarnated, with possible |
| 1168 | resulting confusion on the part of Perl. |
| 1169 | |
| 1170 | This function is now largely obsolete, partly because it's very |
| 1171 | hard to convert a core file into an executable, and because the |
| 1172 | real compiler backends for generating portable bytecode and compilable |
| 1173 | C code have superseded it. |
| 1174 | |
| 1175 | If you're looking to use L<dump> to speed up your program, consider |
| 1176 | generating bytecode or native C code as described in L<perlcc>. If |
| 1177 | you're just trying to accelerate a CGI script, consider using the |
| 1178 | C<mod_perl> extension to B<Apache>, or the CPAN module, Fast::CGI. |
| 1179 | You might also consider autoloading or selfloading, which at least |
| 1180 | make your program I<appear> to run faster. |
| 1181 | |
| 1182 | =item each HASH |
| 1183 | |
| 1184 | When called in list context, returns a 2-element list consisting of the |
| 1185 | key and value for the next element of a hash, so that you can iterate over |
| 1186 | it. When called in scalar context, returns the key for only the "next" |
| 1187 | element in the hash. |
| 1188 | |
| 1189 | Entries are returned in an apparently random order. The actual random |
| 1190 | order is subject to change in future versions of perl, but it is guaranteed |
| 1191 | to be in the same order as either the C<keys> or C<values> function |
| 1192 | would produce on the same (unmodified) hash. |
| 1193 | |
| 1194 | When the hash is entirely read, a null array is returned in list context |
| 1195 | (which when assigned produces a false (C<0>) value), and C<undef> in |
| 1196 | scalar context. The next call to C<each> after that will start iterating |
| 1197 | again. There is a single iterator for each hash, shared by all C<each>, |
| 1198 | C<keys>, and C<values> function calls in the program; it can be reset by |
| 1199 | reading all the elements from the hash, or by evaluating C<keys HASH> or |
| 1200 | C<values HASH>. If you add or delete elements of a hash while you're |
| 1201 | iterating over it, you may get entries skipped or duplicated, so don't. |
| 1202 | |
| 1203 | The following prints out your environment like the printenv(1) program, |
| 1204 | only in a different order: |
| 1205 | |
| 1206 | while (($key,$value) = each %ENV) { |
| 1207 | print "$key=$value\n"; |
| 1208 | } |
| 1209 | |
| 1210 | See also C<keys>, C<values> and C<sort>. |
| 1211 | |
| 1212 | =item eof FILEHANDLE |
| 1213 | |
| 1214 | =item eof () |
| 1215 | |
| 1216 | =item eof |
| 1217 | |
| 1218 | Returns 1 if the next read on FILEHANDLE will return end of file, or if |
| 1219 | FILEHANDLE is not open. FILEHANDLE may be an expression whose value |
| 1220 | gives the real filehandle. (Note that this function actually |
| 1221 | reads a character and then C<ungetc>s it, so isn't very useful in an |
| 1222 | interactive context.) Do not read from a terminal file (or call |
| 1223 | C<eof(FILEHANDLE)> on it) after end-of-file is reached. File types such |
| 1224 | as terminals may lose the end-of-file condition if you do. |
| 1225 | |
| 1226 | An C<eof> without an argument uses the last file read. Using C<eof()> |
| 1227 | with empty parentheses is very different. It refers to the pseudo file |
| 1228 | formed from the files listed on the command line and accessed via the |
| 1229 | C<< <> >> operator. Since C<< <> >> isn't explicitly opened, |
| 1230 | as a normal filehandle is, an C<eof()> before C<< <> >> has been |
| 1231 | used will cause C<@ARGV> to be examined to determine if input is |
| 1232 | available. |
| 1233 | |
| 1234 | In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to |
| 1235 | detect the end of each file, C<eof()> will only detect the end of the |
| 1236 | last file. Examples: |
| 1237 | |
| 1238 | # reset line numbering on each input file |
| 1239 | while (<>) { |
| 1240 | next if /^\s*#/; # skip comments |
| 1241 | print "$.\t$_"; |
| 1242 | } continue { |
| 1243 | close ARGV if eof; # Not eof()! |
| 1244 | } |
| 1245 | |
| 1246 | # insert dashes just before last line of last file |
| 1247 | while (<>) { |
| 1248 | if (eof()) { # check for end of current file |
| 1249 | print "--------------\n"; |
| 1250 | close(ARGV); # close or last; is needed if we |
| 1251 | # are reading from the terminal |
| 1252 | } |
| 1253 | print; |
| 1254 | } |
| 1255 | |
| 1256 | Practical hint: you almost never need to use C<eof> in Perl, because the |
| 1257 | input operators typically return C<undef> when they run out of data, or if |
| 1258 | there was an error. |
| 1259 | |
| 1260 | =item eval EXPR |
| 1261 | |
| 1262 | =item eval BLOCK |
| 1263 | |
| 1264 | In the first form, the return value of EXPR is parsed and executed as if it |
| 1265 | were a little Perl program. The value of the expression (which is itself |
| 1266 | determined within scalar context) is first parsed, and if there weren't any |
| 1267 | errors, executed in the context of the current Perl program, so that any |
| 1268 | variable settings or subroutine and format definitions remain afterwards. |
| 1269 | Note that the value is parsed every time the eval executes. If EXPR is |
| 1270 | omitted, evaluates C<$_>. This form is typically used to delay parsing |
| 1271 | and subsequent execution of the text of EXPR until run time. |
| 1272 | |
| 1273 | In the second form, the code within the BLOCK is parsed only once--at the |
| 1274 | same time the code surrounding the eval itself was parsed--and executed |
| 1275 | within the context of the current Perl program. This form is typically |
| 1276 | used to trap exceptions more efficiently than the first (see below), while |
| 1277 | also providing the benefit of checking the code within BLOCK at compile |
| 1278 | time. |
| 1279 | |
| 1280 | The final semicolon, if any, may be omitted from the value of EXPR or within |
| 1281 | the BLOCK. |
| 1282 | |
| 1283 | In both forms, the value returned is the value of the last expression |
| 1284 | evaluated inside the mini-program; a return statement may be also used, just |
| 1285 | as with subroutines. The expression providing the return value is evaluated |
| 1286 | in void, scalar, or list context, depending on the context of the eval itself. |
| 1287 | See L</wantarray> for more on how the evaluation context can be determined. |
| 1288 | |
| 1289 | If there is a syntax error or runtime error, or a C<die> statement is |
| 1290 | executed, an undefined value is returned by C<eval>, and C<$@> is set to the |
| 1291 | error message. If there was no error, C<$@> is guaranteed to be a null |
| 1292 | string. Beware that using C<eval> neither silences perl from printing |
| 1293 | warnings to STDERR, nor does it stuff the text of warning messages into C<$@>. |
| 1294 | To do either of those, you have to use the C<$SIG{__WARN__}> facility. See |
| 1295 | L</warn> and L<perlvar>. |
| 1296 | |
| 1297 | Note that, because C<eval> traps otherwise-fatal errors, it is useful for |
| 1298 | determining whether a particular feature (such as C<socket> or C<symlink>) |
| 1299 | is implemented. It is also Perl's exception trapping mechanism, where |
| 1300 | the die operator is used to raise exceptions. |
| 1301 | |
| 1302 | If the code to be executed doesn't vary, you may use the eval-BLOCK |
| 1303 | form to trap run-time errors without incurring the penalty of |
| 1304 | recompiling each time. The error, if any, is still returned in C<$@>. |
| 1305 | Examples: |
| 1306 | |
| 1307 | # make divide-by-zero nonfatal |
| 1308 | eval { $answer = $a / $b; }; warn $@ if $@; |
| 1309 | |
| 1310 | # same thing, but less efficient |
| 1311 | eval '$answer = $a / $b'; warn $@ if $@; |
| 1312 | |
| 1313 | # a compile-time error |
| 1314 | eval { $answer = }; # WRONG |
| 1315 | |
| 1316 | # a run-time error |
| 1317 | eval '$answer ='; # sets $@ |
| 1318 | |
| 1319 | Due to the current arguably broken state of C<__DIE__> hooks, when using |
| 1320 | the C<eval{}> form as an exception trap in libraries, you may wish not |
| 1321 | to trigger any C<__DIE__> hooks that user code may have installed. |
| 1322 | You can use the C<local $SIG{__DIE__}> construct for this purpose, |
| 1323 | as shown in this example: |
| 1324 | |
| 1325 | # a very private exception trap for divide-by-zero |
| 1326 | eval { local $SIG{'__DIE__'}; $answer = $a / $b; }; |
| 1327 | warn $@ if $@; |
| 1328 | |
| 1329 | This is especially significant, given that C<__DIE__> hooks can call |
| 1330 | C<die> again, which has the effect of changing their error messages: |
| 1331 | |
| 1332 | # __DIE__ hooks may modify error messages |
| 1333 | { |
| 1334 | local $SIG{'__DIE__'} = |
| 1335 | sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x }; |
| 1336 | eval { die "foo lives here" }; |
| 1337 | print $@ if $@; # prints "bar lives here" |
| 1338 | } |
| 1339 | |
| 1340 | Because this promotes action at a distance, this counterintuitive behavior |
| 1341 | may be fixed in a future release. |
| 1342 | |
| 1343 | With an C<eval>, you should be especially careful to remember what's |
| 1344 | being looked at when: |
| 1345 | |
| 1346 | eval $x; # CASE 1 |
| 1347 | eval "$x"; # CASE 2 |
| 1348 | |
| 1349 | eval '$x'; # CASE 3 |
| 1350 | eval { $x }; # CASE 4 |
| 1351 | |
| 1352 | eval "\$$x++"; # CASE 5 |
| 1353 | $$x++; # CASE 6 |
| 1354 | |
| 1355 | Cases 1 and 2 above behave identically: they run the code contained in |
| 1356 | the variable $x. (Although case 2 has misleading double quotes making |
| 1357 | the reader wonder what else might be happening (nothing is).) Cases 3 |
| 1358 | and 4 likewise behave in the same way: they run the code C<'$x'>, which |
| 1359 | does nothing but return the value of $x. (Case 4 is preferred for |
| 1360 | purely visual reasons, but it also has the advantage of compiling at |
| 1361 | compile-time instead of at run-time.) Case 5 is a place where |
| 1362 | normally you I<would> like to use double quotes, except that in this |
| 1363 | particular situation, you can just use symbolic references instead, as |
| 1364 | in case 6. |
| 1365 | |
| 1366 | C<eval BLOCK> does I<not> count as a loop, so the loop control statements |
| 1367 | C<next>, C<last>, or C<redo> cannot be used to leave or restart the block. |
| 1368 | |
| 1369 | =item exec LIST |
| 1370 | |
| 1371 | =item exec PROGRAM LIST |
| 1372 | |
| 1373 | The C<exec> function executes a system command I<and never returns>-- |
| 1374 | use C<system> instead of C<exec> if you want it to return. It fails and |
| 1375 | returns false only if the command does not exist I<and> it is executed |
| 1376 | directly instead of via your system's command shell (see below). |
| 1377 | |
| 1378 | Since it's a common mistake to use C<exec> instead of C<system>, Perl |
| 1379 | warns you if there is a following statement which isn't C<die>, C<warn>, |
| 1380 | or C<exit> (if C<-w> is set - but you always do that). If you |
| 1381 | I<really> want to follow an C<exec> with some other statement, you |
| 1382 | can use one of these styles to avoid the warning: |
| 1383 | |
| 1384 | exec ('foo') or print STDERR "couldn't exec foo: $!"; |
| 1385 | { exec ('foo') }; print STDERR "couldn't exec foo: $!"; |
| 1386 | |
| 1387 | If there is more than one argument in LIST, or if LIST is an array |
| 1388 | with more than one value, calls execvp(3) with the arguments in LIST. |
| 1389 | If there is only one scalar argument or an array with one element in it, |
| 1390 | the argument is checked for shell metacharacters, and if there are any, |
| 1391 | the entire argument is passed to the system's command shell for parsing |
| 1392 | (this is C</bin/sh -c> on Unix platforms, but varies on other platforms). |
| 1393 | If there are no shell metacharacters in the argument, it is split into |
| 1394 | words and passed directly to C<execvp>, which is more efficient. |
| 1395 | Examples: |
| 1396 | |
| 1397 | exec '/bin/echo', 'Your arguments are: ', @ARGV; |
| 1398 | exec "sort $outfile | uniq"; |
| 1399 | |
| 1400 | If you don't really want to execute the first argument, but want to lie |
| 1401 | to the program you are executing about its own name, you can specify |
| 1402 | the program you actually want to run as an "indirect object" (without a |
| 1403 | comma) in front of the LIST. (This always forces interpretation of the |
| 1404 | LIST as a multivalued list, even if there is only a single scalar in |
| 1405 | the list.) Example: |
| 1406 | |
| 1407 | $shell = '/bin/csh'; |
| 1408 | exec $shell '-sh'; # pretend it's a login shell |
| 1409 | |
| 1410 | or, more directly, |
| 1411 | |
| 1412 | exec {'/bin/csh'} '-sh'; # pretend it's a login shell |
| 1413 | |
| 1414 | When the arguments get executed via the system shell, results will |
| 1415 | be subject to its quirks and capabilities. See L<perlop/"`STRING`"> |
| 1416 | for details. |
| 1417 | |
| 1418 | Using an indirect object with C<exec> or C<system> is also more |
| 1419 | secure. This usage (which also works fine with system()) forces |
| 1420 | interpretation of the arguments as a multivalued list, even if the |
| 1421 | list had just one argument. That way you're safe from the shell |
| 1422 | expanding wildcards or splitting up words with whitespace in them. |
| 1423 | |
| 1424 | @args = ( "echo surprise" ); |
| 1425 | |
| 1426 | exec @args; # subject to shell escapes |
| 1427 | # if @args == 1 |
| 1428 | exec { $args[0] } @args; # safe even with one-arg list |
| 1429 | |
| 1430 | The first version, the one without the indirect object, ran the I<echo> |
| 1431 | program, passing it C<"surprise"> an argument. The second version |
| 1432 | didn't--it tried to run a program literally called I<"echo surprise">, |
| 1433 | didn't find it, and set C<$?> to a non-zero value indicating failure. |
| 1434 | |
| 1435 | Note that C<exec> will not call your C<END> blocks, nor will it call |
| 1436 | any C<DESTROY> methods in your objects. |
| 1437 | |
| 1438 | =item exists EXPR |
| 1439 | |
| 1440 | Given an expression that specifies a hash element or array element, |
| 1441 | returns true if the specified element in the hash or array has ever |
| 1442 | been initialized, even if the corresponding value is undefined. The |
| 1443 | element is not autovivified if it doesn't exist. |
| 1444 | |
| 1445 | print "Exists\n" if exists $hash{$key}; |
| 1446 | print "Defined\n" if defined $hash{$key}; |
| 1447 | print "True\n" if $hash{$key}; |
| 1448 | |
| 1449 | print "Exists\n" if exists $array[$index]; |
| 1450 | print "Defined\n" if defined $array[$index]; |
| 1451 | print "True\n" if $array[$index]; |
| 1452 | |
| 1453 | A hash or array element can be true only if it's defined, and defined if |
| 1454 | it exists, but the reverse doesn't necessarily hold true. |
| 1455 | |
| 1456 | Given an expression that specifies the name of a subroutine, |
| 1457 | returns true if the specified subroutine has ever been declared, even |
| 1458 | if it is undefined. Mentioning a subroutine name for exists or defined |
| 1459 | does not count as declaring it. |
| 1460 | |
| 1461 | print "Exists\n" if exists &subroutine; |
| 1462 | print "Defined\n" if defined &subroutine; |
| 1463 | |
| 1464 | Note that the EXPR can be arbitrarily complicated as long as the final |
| 1465 | operation is a hash or array key lookup or subroutine name: |
| 1466 | |
| 1467 | if (exists $ref->{A}->{B}->{$key}) { } |
| 1468 | if (exists $hash{A}{B}{$key}) { } |
| 1469 | |
| 1470 | if (exists $ref->{A}->{B}->[$ix]) { } |
| 1471 | if (exists $hash{A}{B}[$ix]) { } |
| 1472 | |
| 1473 | if (exists &{$ref->{A}{B}{$key}}) { } |
| 1474 | |
| 1475 | Although the deepest nested array or hash will not spring into existence |
| 1476 | just because its existence was tested, any intervening ones will. |
| 1477 | Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring |
| 1478 | into existence due to the existence test for the $key element above. |
| 1479 | This happens anywhere the arrow operator is used, including even: |
| 1480 | |
| 1481 | undef $ref; |
| 1482 | if (exists $ref->{"Some key"}) { } |
| 1483 | print $ref; # prints HASH(0x80d3d5c) |
| 1484 | |
| 1485 | This surprising autovivification in what does not at first--or even |
| 1486 | second--glance appear to be an lvalue context may be fixed in a future |
| 1487 | release. |
| 1488 | |
| 1489 | See L<perlref/"Pseudo-hashes: Using an array as a hash"> for specifics |
| 1490 | on how exists() acts when used on a pseudo-hash. |
| 1491 | |
| 1492 | Use of a subroutine call, rather than a subroutine name, as an argument |
| 1493 | to exists() is an error. |
| 1494 | |
| 1495 | exists ⊂ # OK |
| 1496 | exists &sub(); # Error |
| 1497 | |
| 1498 | =item exit EXPR |
| 1499 | |
| 1500 | Evaluates EXPR and exits immediately with that value. Example: |
| 1501 | |
| 1502 | $ans = <STDIN>; |
| 1503 | exit 0 if $ans =~ /^[Xx]/; |
| 1504 | |
| 1505 | See also C<die>. If EXPR is omitted, exits with C<0> status. The only |
| 1506 | universally recognized values for EXPR are C<0> for success and C<1> |
| 1507 | for error; other values are subject to interpretation depending on the |
| 1508 | environment in which the Perl program is running. For example, exiting |
| 1509 | 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause |
| 1510 | the mailer to return the item undelivered, but that's not true everywhere. |
| 1511 | |
| 1512 | Don't use C<exit> to abort a subroutine if there's any chance that |
| 1513 | someone might want to trap whatever error happened. Use C<die> instead, |
| 1514 | which can be trapped by an C<eval>. |
| 1515 | |
| 1516 | The exit() function does not always exit immediately. It calls any |
| 1517 | defined C<END> routines first, but these C<END> routines may not |
| 1518 | themselves abort the exit. Likewise any object destructors that need to |
| 1519 | be called are called before the real exit. If this is a problem, you |
| 1520 | can call C<POSIX:_exit($status)> to avoid END and destructor processing. |
| 1521 | See L<perlmod> for details. |
| 1522 | |
| 1523 | =item exp EXPR |
| 1524 | |
| 1525 | =item exp |
| 1526 | |
| 1527 | Returns I<e> (the natural logarithm base) to the power of EXPR. |
| 1528 | If EXPR is omitted, gives C<exp($_)>. |
| 1529 | |
| 1530 | =item fcntl FILEHANDLE,FUNCTION,SCALAR |
| 1531 | |
| 1532 | Implements the fcntl(2) function. You'll probably have to say |
| 1533 | |
| 1534 | use Fcntl; |
| 1535 | |
| 1536 | first to get the correct constant definitions. Argument processing and |
| 1537 | value return works just like C<ioctl> below. |
| 1538 | For example: |
| 1539 | |
| 1540 | use Fcntl; |
| 1541 | fcntl($filehandle, F_GETFL, $packed_return_buffer) |
| 1542 | or die "can't fcntl F_GETFL: $!"; |
| 1543 | |
| 1544 | You don't have to check for C<defined> on the return from C<fnctl>. |
| 1545 | Like C<ioctl>, it maps a C<0> return from the system call into |
| 1546 | C<"0 but true"> in Perl. This string is true in boolean context and C<0> |
| 1547 | in numeric context. It is also exempt from the normal B<-w> warnings |
| 1548 | on improper numeric conversions. |
| 1549 | |
| 1550 | Note that C<fcntl> will produce a fatal error if used on a machine that |
| 1551 | doesn't implement fcntl(2). See the Fcntl module or your fcntl(2) |
| 1552 | manpage to learn what functions are available on your system. |
| 1553 | |
| 1554 | =item fileno FILEHANDLE |
| 1555 | |
| 1556 | Returns the file descriptor for a filehandle, or undefined if the |
| 1557 | filehandle is not open. This is mainly useful for constructing |
| 1558 | bitmaps for C<select> and low-level POSIX tty-handling operations. |
| 1559 | If FILEHANDLE is an expression, the value is taken as an indirect |
| 1560 | filehandle, generally its name. |
| 1561 | |
| 1562 | You can use this to find out whether two handles refer to the |
| 1563 | same underlying descriptor: |
| 1564 | |
| 1565 | if (fileno(THIS) == fileno(THAT)) { |
| 1566 | print "THIS and THAT are dups\n"; |
| 1567 | } |
| 1568 | |
| 1569 | =item flock FILEHANDLE,OPERATION |
| 1570 | |
| 1571 | Calls flock(2), or an emulation of it, on FILEHANDLE. Returns true |
| 1572 | for success, false on failure. Produces a fatal error if used on a |
| 1573 | machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3). |
| 1574 | C<flock> is Perl's portable file locking interface, although it locks |
| 1575 | only entire files, not records. |
| 1576 | |
| 1577 | Two potentially non-obvious but traditional C<flock> semantics are |
| 1578 | that it waits indefinitely until the lock is granted, and that its locks |
| 1579 | B<merely advisory>. Such discretionary locks are more flexible, but offer |
| 1580 | fewer guarantees. This means that files locked with C<flock> may be |
| 1581 | modified by programs that do not also use C<flock>. See L<perlport>, |
| 1582 | your port's specific documentation, or your system-specific local manpages |
| 1583 | for details. It's best to assume traditional behavior if you're writing |
| 1584 | portable programs. (But if you're not, you should as always feel perfectly |
| 1585 | free to write for your own system's idiosyncrasies (sometimes called |
| 1586 | "features"). Slavish adherence to portability concerns shouldn't get |
| 1587 | in the way of your getting your job done.) |
| 1588 | |
| 1589 | OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with |
| 1590 | LOCK_NB. These constants are traditionally valued 1, 2, 8 and 4, but |
| 1591 | you can use the symbolic names if you import them from the Fcntl module, |
| 1592 | either individually, or as a group using the ':flock' tag. LOCK_SH |
| 1593 | requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN |
| 1594 | releases a previously requested lock. If LOCK_NB is bitwise-or'ed with |
| 1595 | LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking |
| 1596 | waiting for the lock (check the return status to see if you got it). |
| 1597 | |
| 1598 | To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE |
| 1599 | before locking or unlocking it. |
| 1600 | |
| 1601 | Note that the emulation built with lockf(3) doesn't provide shared |
| 1602 | locks, and it requires that FILEHANDLE be open with write intent. These |
| 1603 | are the semantics that lockf(3) implements. Most if not all systems |
| 1604 | implement lockf(3) in terms of fcntl(2) locking, though, so the |
| 1605 | differing semantics shouldn't bite too many people. |
| 1606 | |
| 1607 | Note also that some versions of C<flock> cannot lock things over the |
| 1608 | network; you would need to use the more system-specific C<fcntl> for |
| 1609 | that. If you like you can force Perl to ignore your system's flock(2) |
| 1610 | function, and so provide its own fcntl(2)-based emulation, by passing |
| 1611 | the switch C<-Ud_flock> to the F<Configure> program when you configure |
| 1612 | perl. |
| 1613 | |
| 1614 | Here's a mailbox appender for BSD systems. |
| 1615 | |
| 1616 | use Fcntl ':flock'; # import LOCK_* constants |
| 1617 | |
| 1618 | sub lock { |
| 1619 | flock(MBOX,LOCK_EX); |
| 1620 | # and, in case someone appended |
| 1621 | # while we were waiting... |
| 1622 | seek(MBOX, 0, 2); |
| 1623 | } |
| 1624 | |
| 1625 | sub unlock { |
| 1626 | flock(MBOX,LOCK_UN); |
| 1627 | } |
| 1628 | |
| 1629 | open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}") |
| 1630 | or die "Can't open mailbox: $!"; |
| 1631 | |
| 1632 | lock(); |
| 1633 | print MBOX $msg,"\n\n"; |
| 1634 | unlock(); |
| 1635 | |
| 1636 | On systems that support a real flock(), locks are inherited across fork() |
| 1637 | calls, whereas those that must resort to the more capricious fcntl() |
| 1638 | function lose the locks, making it harder to write servers. |
| 1639 | |
| 1640 | See also L<DB_File> for other flock() examples. |
| 1641 | |
| 1642 | =item fork |
| 1643 | |
| 1644 | Does a fork(2) system call to create a new process running the |
| 1645 | same program at the same point. It returns the child pid to the |
| 1646 | parent process, C<0> to the child process, or C<undef> if the fork is |
| 1647 | unsuccessful. File descriptors (and sometimes locks on those descriptors) |
| 1648 | are shared, while everything else is copied. On most systems supporting |
| 1649 | fork(), great care has gone into making it extremely efficient (for |
| 1650 | example, using copy-on-write technology on data pages), making it the |
| 1651 | dominant paradigm for multitasking over the last few decades. |
| 1652 | |
| 1653 | All files opened for output are flushed before forking the child process. |
| 1654 | |
| 1655 | If you C<fork> without ever waiting on your children, you will |
| 1656 | accumulate zombies. On some systems, you can avoid this by setting |
| 1657 | C<$SIG{CHLD}> to C<"IGNORE">. See also L<perlipc> for more examples of |
| 1658 | forking and reaping moribund children. |
| 1659 | |
| 1660 | Note that if your forked child inherits system file descriptors like |
| 1661 | STDIN and STDOUT that are actually connected by a pipe or socket, even |
| 1662 | if you exit, then the remote server (such as, say, a CGI script or a |
| 1663 | backgrounded job launched from a remote shell) won't think you're done. |
| 1664 | You should reopen those to F</dev/null> if it's any issue. |
| 1665 | |
| 1666 | =item format |
| 1667 | |
| 1668 | Declare a picture format for use by the C<write> function. For |
| 1669 | example: |
| 1670 | |
| 1671 | format Something = |
| 1672 | Test: @<<<<<<<< @||||| @>>>>> |
| 1673 | $str, $%, '$' . int($num) |
| 1674 | . |
| 1675 | |
| 1676 | $str = "widget"; |
| 1677 | $num = $cost/$quantity; |
| 1678 | $~ = 'Something'; |
| 1679 | write; |
| 1680 | |
| 1681 | See L<perlform> for many details and examples. |
| 1682 | |
| 1683 | =item formline PICTURE,LIST |
| 1684 | |
| 1685 | This is an internal function used by C<format>s, though you may call it, |
| 1686 | too. It formats (see L<perlform>) a list of values according to the |
| 1687 | contents of PICTURE, placing the output into the format output |
| 1688 | accumulator, C<$^A> (or C<$ACCUMULATOR> in English). |
| 1689 | Eventually, when a C<write> is done, the contents of |
| 1690 | C<$^A> are written to some filehandle, but you could also read C<$^A> |
| 1691 | yourself and then set C<$^A> back to C<"">. Note that a format typically |
| 1692 | does one C<formline> per line of form, but the C<formline> function itself |
| 1693 | doesn't care how many newlines are embedded in the PICTURE. This means |
| 1694 | that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line. |
| 1695 | You may therefore need to use multiple formlines to implement a single |
| 1696 | record format, just like the format compiler. |
| 1697 | |
| 1698 | Be careful if you put double quotes around the picture, because an C<@> |
| 1699 | character may be taken to mean the beginning of an array name. |
| 1700 | C<formline> always returns true. See L<perlform> for other examples. |
| 1701 | |
| 1702 | =item getc FILEHANDLE |
| 1703 | |
| 1704 | =item getc |
| 1705 | |
| 1706 | Returns the next character from the input file attached to FILEHANDLE, |
| 1707 | or the undefined value at end of file, or if there was an error. |
| 1708 | If FILEHANDLE is omitted, reads from STDIN. This is not particularly |
| 1709 | efficient. However, it cannot be used by itself to fetch single |
| 1710 | characters without waiting for the user to hit enter. For that, try |
| 1711 | something more like: |
| 1712 | |
| 1713 | if ($BSD_STYLE) { |
| 1714 | system "stty cbreak </dev/tty >/dev/tty 2>&1"; |
| 1715 | } |
| 1716 | else { |
| 1717 | system "stty", '-icanon', 'eol', "\001"; |
| 1718 | } |
| 1719 | |
| 1720 | $key = getc(STDIN); |
| 1721 | |
| 1722 | if ($BSD_STYLE) { |
| 1723 | system "stty -cbreak </dev/tty >/dev/tty 2>&1"; |
| 1724 | } |
| 1725 | else { |
| 1726 | system "stty", 'icanon', 'eol', '^@'; # ASCII null |
| 1727 | } |
| 1728 | print "\n"; |
| 1729 | |
| 1730 | Determination of whether $BSD_STYLE should be set |
| 1731 | is left as an exercise to the reader. |
| 1732 | |
| 1733 | The C<POSIX::getattr> function can do this more portably on |
| 1734 | systems purporting POSIX compliance. See also the C<Term::ReadKey> |
| 1735 | module from your nearest CPAN site; details on CPAN can be found on |
| 1736 | L<perlmodlib/CPAN>. |
| 1737 | |
| 1738 | =item getlogin |
| 1739 | |
| 1740 | Implements the C library function of the same name, which on most |
| 1741 | systems returns the current login from F</etc/utmp>, if any. If null, |
| 1742 | use C<getpwuid>. |
| 1743 | |
| 1744 | $login = getlogin || getpwuid($<) || "Kilroy"; |
| 1745 | |
| 1746 | Do not consider C<getlogin> for authentication: it is not as |
| 1747 | secure as C<getpwuid>. |
| 1748 | |
| 1749 | =item getpeername SOCKET |
| 1750 | |
| 1751 | Returns the packed sockaddr address of other end of the SOCKET connection. |
| 1752 | |
| 1753 | use Socket; |
| 1754 | $hersockaddr = getpeername(SOCK); |
| 1755 | ($port, $iaddr) = sockaddr_in($hersockaddr); |
| 1756 | $herhostname = gethostbyaddr($iaddr, AF_INET); |
| 1757 | $herstraddr = inet_ntoa($iaddr); |
| 1758 | |
| 1759 | =item getpgrp PID |
| 1760 | |
| 1761 | Returns the current process group for the specified PID. Use |
| 1762 | a PID of C<0> to get the current process group for the |
| 1763 | current process. Will raise an exception if used on a machine that |
| 1764 | doesn't implement getpgrp(2). If PID is omitted, returns process |
| 1765 | group of current process. Note that the POSIX version of C<getpgrp> |
| 1766 | does not accept a PID argument, so only C<PID==0> is truly portable. |
| 1767 | |
| 1768 | =item getppid |
| 1769 | |
| 1770 | Returns the process id of the parent process. |
| 1771 | |
| 1772 | =item getpriority WHICH,WHO |
| 1773 | |
| 1774 | Returns the current priority for a process, a process group, or a user. |
| 1775 | (See L<getpriority(2)>.) Will raise a fatal exception if used on a |
| 1776 | machine that doesn't implement getpriority(2). |
| 1777 | |
| 1778 | =item getpwnam NAME |
| 1779 | |
| 1780 | =item getgrnam NAME |
| 1781 | |
| 1782 | =item gethostbyname NAME |
| 1783 | |
| 1784 | =item getnetbyname NAME |
| 1785 | |
| 1786 | =item getprotobyname NAME |
| 1787 | |
| 1788 | =item getpwuid UID |
| 1789 | |
| 1790 | =item getgrgid GID |
| 1791 | |
| 1792 | =item getservbyname NAME,PROTO |
| 1793 | |
| 1794 | =item gethostbyaddr ADDR,ADDRTYPE |
| 1795 | |
| 1796 | =item getnetbyaddr ADDR,ADDRTYPE |
| 1797 | |
| 1798 | =item getprotobynumber NUMBER |
| 1799 | |
| 1800 | =item getservbyport PORT,PROTO |
| 1801 | |
| 1802 | =item getpwent |
| 1803 | |
| 1804 | =item getgrent |
| 1805 | |
| 1806 | =item gethostent |
| 1807 | |
| 1808 | =item getnetent |
| 1809 | |
| 1810 | =item getprotoent |
| 1811 | |
| 1812 | =item getservent |
| 1813 | |
| 1814 | =item setpwent |
| 1815 | |
| 1816 | =item setgrent |
| 1817 | |
| 1818 | =item sethostent STAYOPEN |
| 1819 | |
| 1820 | =item setnetent STAYOPEN |
| 1821 | |
| 1822 | =item setprotoent STAYOPEN |
| 1823 | |
| 1824 | =item setservent STAYOPEN |
| 1825 | |
| 1826 | =item endpwent |
| 1827 | |
| 1828 | =item endgrent |
| 1829 | |
| 1830 | =item endhostent |
| 1831 | |
| 1832 | =item endnetent |
| 1833 | |
| 1834 | =item endprotoent |
| 1835 | |
| 1836 | =item endservent |
| 1837 | |
| 1838 | These routines perform the same functions as their counterparts in the |
| 1839 | system library. In list context, the return values from the |
| 1840 | various get routines are as follows: |
| 1841 | |
| 1842 | ($name,$passwd,$uid,$gid, |
| 1843 | $quota,$comment,$gcos,$dir,$shell,$expire) = getpw* |
| 1844 | ($name,$passwd,$gid,$members) = getgr* |
| 1845 | ($name,$aliases,$addrtype,$length,@addrs) = gethost* |
| 1846 | ($name,$aliases,$addrtype,$net) = getnet* |
| 1847 | ($name,$aliases,$proto) = getproto* |
| 1848 | ($name,$aliases,$port,$proto) = getserv* |
| 1849 | |
| 1850 | (If the entry doesn't exist you get a null list.) |
| 1851 | |
| 1852 | In scalar context, you get the name, unless the function was a |
| 1853 | lookup by name, in which case you get the other thing, whatever it is. |
| 1854 | (If the entry doesn't exist you get the undefined value.) For example: |
| 1855 | |
| 1856 | $uid = getpwnam($name); |
| 1857 | $name = getpwuid($num); |
| 1858 | $name = getpwent(); |
| 1859 | $gid = getgrnam($name); |
| 1860 | $name = getgrgid($num; |
| 1861 | $name = getgrent(); |
| 1862 | #etc. |
| 1863 | |
| 1864 | In I<getpw*()> the fields $quota, $comment, and $expire are |
| 1865 | special cases in the sense that in many systems they are unsupported. |
| 1866 | If the $quota is unsupported, it is an empty scalar. If it is |
| 1867 | supported, it usually encodes the disk quota. If the $comment |
| 1868 | field is unsupported, it is an empty scalar. If it is supported it |
| 1869 | usually encodes some administrative comment about the user. In some |
| 1870 | systems the $quota field may be $change or $age, fields that have |
| 1871 | to do with password aging. In some systems the $comment field may |
| 1872 | be $class. The $expire field, if present, encodes the expiration |
| 1873 | period of the account or the password. For the availability and the |
| 1874 | exact meaning of these fields in your system, please consult your |
| 1875 | getpwnam(3) documentation and your F<pwd.h> file. You can also find |
| 1876 | out from within Perl what your $quota and $comment fields mean |
| 1877 | and whether you have the $expire field by using the C<Config> module |
| 1878 | and the values C<d_pwquota>, C<d_pwage>, C<d_pwchange>, C<d_pwcomment>, |
| 1879 | and C<d_pwexpire>. Shadow password files are only supported if your |
| 1880 | vendor has implemented them in the intuitive fashion that calling the |
| 1881 | regular C library routines gets the shadow versions if you're running |
| 1882 | under privilege. Those that incorrectly implement a separate library |
| 1883 | call are not supported. |
| 1884 | |
| 1885 | The $members value returned by I<getgr*()> is a space separated list of |
| 1886 | the login names of the members of the group. |
| 1887 | |
| 1888 | For the I<gethost*()> functions, if the C<h_errno> variable is supported in |
| 1889 | C, it will be returned to you via C<$?> if the function call fails. The |
| 1890 | C<@addrs> value returned by a successful call is a list of the raw |
| 1891 | addresses returned by the corresponding system library call. In the |
| 1892 | Internet domain, each address is four bytes long and you can unpack it |
| 1893 | by saying something like: |
| 1894 | |
| 1895 | ($a,$b,$c,$d) = unpack('C4',$addr[0]); |
| 1896 | |
| 1897 | The Socket library makes this slightly easier: |
| 1898 | |
| 1899 | use Socket; |
| 1900 | $iaddr = inet_aton("127.1"); # or whatever address |
| 1901 | $name = gethostbyaddr($iaddr, AF_INET); |
| 1902 | |
| 1903 | # or going the other way |
| 1904 | $straddr = inet_ntoa($iaddr); |
| 1905 | |
| 1906 | If you get tired of remembering which element of the return list |
| 1907 | contains which return value, by-name interfaces are provided |
| 1908 | in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>, |
| 1909 | C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>, |
| 1910 | and C<User::grent>. These override the normal built-ins, supplying |
| 1911 | versions that return objects with the appropriate names |
| 1912 | for each field. For example: |
| 1913 | |
| 1914 | use File::stat; |
| 1915 | use User::pwent; |
| 1916 | $is_his = (stat($filename)->uid == pwent($whoever)->uid); |
| 1917 | |
| 1918 | Even though it looks like they're the same method calls (uid), |
| 1919 | they aren't, because a C<File::stat> object is different from |
| 1920 | a C<User::pwent> object. |
| 1921 | |
| 1922 | =item getsockname SOCKET |
| 1923 | |
| 1924 | Returns the packed sockaddr address of this end of the SOCKET connection, |
| 1925 | in case you don't know the address because you have several different |
| 1926 | IPs that the connection might have come in on. |
| 1927 | |
| 1928 | use Socket; |
| 1929 | $mysockaddr = getsockname(SOCK); |
| 1930 | ($port, $myaddr) = sockaddr_in($mysockaddr); |
| 1931 | printf "Connect to %s [%s]\n", |
| 1932 | scalar gethostbyaddr($myaddr, AF_INET), |
| 1933 | inet_ntoa($myaddr); |
| 1934 | |
| 1935 | =item getsockopt SOCKET,LEVEL,OPTNAME |
| 1936 | |
| 1937 | Returns the socket option requested, or undef if there is an error. |
| 1938 | |
| 1939 | =item glob EXPR |
| 1940 | |
| 1941 | =item glob |
| 1942 | |
| 1943 | Returns the value of EXPR with filename expansions such as the |
| 1944 | standard Unix shell F</bin/csh> would do. This is the internal function |
| 1945 | implementing the C<< <*.c> >> operator, but you can use it directly. |
| 1946 | If EXPR is omitted, C<$_> is used. The C<< <*.c> >> operator is |
| 1947 | discussed in more detail in L<perlop/"I/O Operators">. |
| 1948 | |
| 1949 | Beginning with v5.6.0, this operator is implemented using the standard |
| 1950 | C<File::Glob> extension. See L<File::Glob> for details. |
| 1951 | |
| 1952 | =item gmtime EXPR |
| 1953 | |
| 1954 | Converts a time as returned by the time function to a 8-element list |
| 1955 | with the time localized for the standard Greenwich time zone. |
| 1956 | Typically used as follows: |
| 1957 | |
| 1958 | # 0 1 2 3 4 5 6 7 |
| 1959 | ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) = |
| 1960 | gmtime(time); |
| 1961 | |
| 1962 | All list elements are numeric, and come straight out of the C `struct |
| 1963 | tm'. $sec, $min, and $hour are the seconds, minutes, and hours of the |
| 1964 | specified time. $mday is the day of the month, and $mon is the month |
| 1965 | itself, in the range C<0..11> with 0 indicating January and 11 |
| 1966 | indicating December. $year is the number of years since 1900. That |
| 1967 | is, $year is C<123> in year 2023. $wday is the day of the week, with |
| 1968 | 0 indicating Sunday and 3 indicating Wednesday. $yday is the day of |
| 1969 | the year, in the range C<1..365> (or C<1..366> in leap years.) |
| 1970 | |
| 1971 | Note that the $year element is I<not> simply the last two digits of |
| 1972 | the year. If you assume it is, then you create non-Y2K-compliant |
| 1973 | programs--and you wouldn't want to do that, would you? |
| 1974 | |
| 1975 | The proper way to get a complete 4-digit year is simply: |
| 1976 | |
| 1977 | $year += 1900; |
| 1978 | |
| 1979 | And to get the last two digits of the year (e.g., '01' in 2001) do: |
| 1980 | |
| 1981 | $year = sprintf("%02d", $year % 100); |
| 1982 | |
| 1983 | If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>). |
| 1984 | |
| 1985 | In scalar context, C<gmtime()> returns the ctime(3) value: |
| 1986 | |
| 1987 | $now_string = gmtime; # e.g., "Thu Oct 13 04:54:34 1994" |
| 1988 | |
| 1989 | Also see the C<timegm> function provided by the C<Time::Local> module, |
| 1990 | and the strftime(3) function available via the POSIX module. |
| 1991 | |
| 1992 | This scalar value is B<not> locale dependent (see L<perllocale>), but |
| 1993 | is instead a Perl builtin. Also see the C<Time::Local> module, and the |
| 1994 | strftime(3) and mktime(3) functions available via the POSIX module. To |
| 1995 | get somewhat similar but locale dependent date strings, set up your |
| 1996 | locale environment variables appropriately (please see L<perllocale>) |
| 1997 | and try for example: |
| 1998 | |
| 1999 | use POSIX qw(strftime); |
| 2000 | $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime; |
| 2001 | |
| 2002 | Note that the C<%a> and C<%b> escapes, which represent the short forms |
| 2003 | of the day of the week and the month of the year, may not necessarily |
| 2004 | be three characters wide in all locales. |
| 2005 | |
| 2006 | =item goto LABEL |
| 2007 | |
| 2008 | =item goto EXPR |
| 2009 | |
| 2010 | =item goto &NAME |
| 2011 | |
| 2012 | The C<goto-LABEL> form finds the statement labeled with LABEL and resumes |
| 2013 | execution there. It may not be used to go into any construct that |
| 2014 | requires initialization, such as a subroutine or a C<foreach> loop. It |
| 2015 | also can't be used to go into a construct that is optimized away, |
| 2016 | or to get out of a block or subroutine given to C<sort>. |
| 2017 | It can be used to go almost anywhere else within the dynamic scope, |
| 2018 | including out of subroutines, but it's usually better to use some other |
| 2019 | construct such as C<last> or C<die>. The author of Perl has never felt the |
| 2020 | need to use this form of C<goto> (in Perl, that is--C is another matter). |
| 2021 | |
| 2022 | The C<goto-EXPR> form expects a label name, whose scope will be resolved |
| 2023 | dynamically. This allows for computed C<goto>s per FORTRAN, but isn't |
| 2024 | necessarily recommended if you're optimizing for maintainability: |
| 2025 | |
| 2026 | goto ("FOO", "BAR", "GLARCH")[$i]; |
| 2027 | |
| 2028 | The C<goto-&NAME> form is quite different from the other forms of C<goto>. |
| 2029 | In fact, it isn't a goto in the normal sense at all, and doesn't have |
| 2030 | the stigma associated with other gotos. Instead, it |
| 2031 | substitutes a call to the named subroutine for the currently running |
| 2032 | subroutine. This is used by C<AUTOLOAD> subroutines that wish to load |
| 2033 | another subroutine and then pretend that the other subroutine had been |
| 2034 | called in the first place (except that any modifications to C<@_> |
| 2035 | in the current subroutine are propagated to the other subroutine.) |
| 2036 | After the C<goto>, not even C<caller> will be able to tell that this |
| 2037 | routine was called first. |
| 2038 | |
| 2039 | NAME needn't be the name of a subroutine; it can be a scalar variable |
| 2040 | containing a code reference, or a block which evaluates to a code |
| 2041 | reference. |
| 2042 | |
| 2043 | =item grep BLOCK LIST |
| 2044 | |
| 2045 | =item grep EXPR,LIST |
| 2046 | |
| 2047 | This is similar in spirit to, but not the same as, grep(1) and its |
| 2048 | relatives. In particular, it is not limited to using regular expressions. |
| 2049 | |
| 2050 | Evaluates the BLOCK or EXPR for each element of LIST (locally setting |
| 2051 | C<$_> to each element) and returns the list value consisting of those |
| 2052 | elements for which the expression evaluated to true. In scalar |
| 2053 | context, returns the number of times the expression was true. |
| 2054 | |
| 2055 | @foo = grep(!/^#/, @bar); # weed out comments |
| 2056 | |
| 2057 | or equivalently, |
| 2058 | |
| 2059 | @foo = grep {!/^#/} @bar; # weed out comments |
| 2060 | |
| 2061 | Note that, because C<$_> is a reference into the list value, it can |
| 2062 | be used to modify the elements of the array. While this is useful and |
| 2063 | supported, it can cause bizarre results if the LIST is not a named array. |
| 2064 | Similarly, grep returns aliases into the original list, much as a for |
| 2065 | loop's index variable aliases the list elements. That is, modifying an |
| 2066 | element of a list returned by grep (for example, in a C<foreach>, C<map> |
| 2067 | or another C<grep>) actually modifies the element in the original list. |
| 2068 | This is usually something to be avoided when writing clear code. |
| 2069 | |
| 2070 | See also L</map> for a list composed of the results of the BLOCK or EXPR. |
| 2071 | |
| 2072 | =item hex EXPR |
| 2073 | |
| 2074 | =item hex |
| 2075 | |
| 2076 | Interprets EXPR as a hex string and returns the corresponding value. |
| 2077 | (To convert strings that might start with either 0, 0x, or 0b, see |
| 2078 | L</oct>.) If EXPR is omitted, uses C<$_>. |
| 2079 | |
| 2080 | print hex '0xAf'; # prints '175' |
| 2081 | print hex 'aF'; # same |
| 2082 | |
| 2083 | Hex strings may only represent integers. Strings that would cause |
| 2084 | integer overflow trigger a warning. |
| 2085 | |
| 2086 | =item import |
| 2087 | |
| 2088 | There is no builtin C<import> function. It is just an ordinary |
| 2089 | method (subroutine) defined (or inherited) by modules that wish to export |
| 2090 | names to another module. The C<use> function calls the C<import> method |
| 2091 | for the package used. See also L</use()>, L<perlmod>, and L<Exporter>. |
| 2092 | |
| 2093 | =item index STR,SUBSTR,POSITION |
| 2094 | |
| 2095 | =item index STR,SUBSTR |
| 2096 | |
| 2097 | The index function searches for one string within another, but without |
| 2098 | the wildcard-like behavior of a full regular-expression pattern match. |
| 2099 | It returns the position of the first occurrence of SUBSTR in STR at |
| 2100 | or after POSITION. If POSITION is omitted, starts searching from the |
| 2101 | beginning of the string. The return value is based at C<0> (or whatever |
| 2102 | you've set the C<$[> variable to--but don't do that). If the substring |
| 2103 | is not found, returns one less than the base, ordinarily C<-1>. |
| 2104 | |
| 2105 | =item int EXPR |
| 2106 | |
| 2107 | =item int |
| 2108 | |
| 2109 | Returns the integer portion of EXPR. If EXPR is omitted, uses C<$_>. |
| 2110 | You should not use this function for rounding: one because it truncates |
| 2111 | towards C<0>, and two because machine representations of floating point |
| 2112 | numbers can sometimes produce counterintuitive results. For example, |
| 2113 | C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's |
| 2114 | because it's really more like -268.99999999999994315658 instead. Usually, |
| 2115 | the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil> |
| 2116 | functions will serve you better than will int(). |
| 2117 | |
| 2118 | =item ioctl FILEHANDLE,FUNCTION,SCALAR |
| 2119 | |
| 2120 | Implements the ioctl(2) function. You'll probably first have to say |
| 2121 | |
| 2122 | require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph |
| 2123 | |
| 2124 | to get the correct function definitions. If F<ioctl.ph> doesn't |
| 2125 | exist or doesn't have the correct definitions you'll have to roll your |
| 2126 | own, based on your C header files such as F<< <sys/ioctl.h> >>. |
| 2127 | (There is a Perl script called B<h2ph> that comes with the Perl kit that |
| 2128 | may help you in this, but it's nontrivial.) SCALAR will be read and/or |
| 2129 | written depending on the FUNCTION--a pointer to the string value of SCALAR |
| 2130 | will be passed as the third argument of the actual C<ioctl> call. (If SCALAR |
| 2131 | has no string value but does have a numeric value, that value will be |
| 2132 | passed rather than a pointer to the string value. To guarantee this to be |
| 2133 | true, add a C<0> to the scalar before using it.) The C<pack> and C<unpack> |
| 2134 | functions may be needed to manipulate the values of structures used by |
| 2135 | C<ioctl>. |
| 2136 | |
| 2137 | The return value of C<ioctl> (and C<fcntl>) is as follows: |
| 2138 | |
| 2139 | if OS returns: then Perl returns: |
| 2140 | -1 undefined value |
| 2141 | 0 string "0 but true" |
| 2142 | anything else that number |
| 2143 | |
| 2144 | Thus Perl returns true on success and false on failure, yet you can |
| 2145 | still easily determine the actual value returned by the operating |
| 2146 | system: |
| 2147 | |
| 2148 | $retval = ioctl(...) || -1; |
| 2149 | printf "System returned %d\n", $retval; |
| 2150 | |
| 2151 | The special string "C<0> but true" is exempt from B<-w> complaints |
| 2152 | about improper numeric conversions. |
| 2153 | |
| 2154 | Here's an example of setting a filehandle named C<REMOTE> to be |
| 2155 | non-blocking at the system level. You'll have to negotiate C<$|> |
| 2156 | on your own, though. |
| 2157 | |
| 2158 | use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK); |
| 2159 | |
| 2160 | $flags = fcntl(REMOTE, F_GETFL, 0) |
| 2161 | or die "Can't get flags for the socket: $!\n"; |
| 2162 | |
| 2163 | $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK) |
| 2164 | or die "Can't set flags for the socket: $!\n"; |
| 2165 | |
| 2166 | =item join EXPR,LIST |
| 2167 | |
| 2168 | Joins the separate strings of LIST into a single string with fields |
| 2169 | separated by the value of EXPR, and returns that new string. Example: |
| 2170 | |
| 2171 | $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell); |
| 2172 | |
| 2173 | Beware that unlike C<split>, C<join> doesn't take a pattern as its |
| 2174 | first argument. Compare L</split>. |
| 2175 | |
| 2176 | =item keys HASH |
| 2177 | |
| 2178 | Returns a list consisting of all the keys of the named hash. (In |
| 2179 | scalar context, returns the number of keys.) The keys are returned in |
| 2180 | an apparently random order. The actual random order is subject to |
| 2181 | change in future versions of perl, but it is guaranteed to be the same |
| 2182 | order as either the C<values> or C<each> function produces (given |
| 2183 | that the hash has not been modified). As a side effect, it resets |
| 2184 | HASH's iterator. |
| 2185 | |
| 2186 | Here is yet another way to print your environment: |
| 2187 | |
| 2188 | @keys = keys %ENV; |
| 2189 | @values = values %ENV; |
| 2190 | while (@keys) { |
| 2191 | print pop(@keys), '=', pop(@values), "\n"; |
| 2192 | } |
| 2193 | |
| 2194 | or how about sorted by key: |
| 2195 | |
| 2196 | foreach $key (sort(keys %ENV)) { |
| 2197 | print $key, '=', $ENV{$key}, "\n"; |
| 2198 | } |
| 2199 | |
| 2200 | To sort a hash by value, you'll need to use a C<sort> function. |
| 2201 | Here's a descending numeric sort of a hash by its values: |
| 2202 | |
| 2203 | foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) { |
| 2204 | printf "%4d %s\n", $hash{$key}, $key; |
| 2205 | } |
| 2206 | |
| 2207 | As an lvalue C<keys> allows you to increase the number of hash buckets |
| 2208 | allocated for the given hash. This can gain you a measure of efficiency if |
| 2209 | you know the hash is going to get big. (This is similar to pre-extending |
| 2210 | an array by assigning a larger number to $#array.) If you say |
| 2211 | |
| 2212 | keys %hash = 200; |
| 2213 | |
| 2214 | then C<%hash> will have at least 200 buckets allocated for it--256 of them, |
| 2215 | in fact, since it rounds up to the next power of two. These |
| 2216 | buckets will be retained even if you do C<%hash = ()>, use C<undef |
| 2217 | %hash> if you want to free the storage while C<%hash> is still in scope. |
| 2218 | You can't shrink the number of buckets allocated for the hash using |
| 2219 | C<keys> in this way (but you needn't worry about doing this by accident, |
| 2220 | as trying has no effect). |
| 2221 | |
| 2222 | See also C<each>, C<values> and C<sort>. |
| 2223 | |
| 2224 | =item kill SIGNAL, LIST |
| 2225 | |
| 2226 | Sends a signal to a list of processes. Returns the number of |
| 2227 | processes successfully signaled (which is not necessarily the |
| 2228 | same as the number actually killed). |
| 2229 | |
| 2230 | $cnt = kill 1, $child1, $child2; |
| 2231 | kill 9, @goners; |
| 2232 | |
| 2233 | If SIGNAL is zero, no signal is sent to the process. This is a |
| 2234 | useful way to check that the process is alive and hasn't changed |
| 2235 | its UID. See L<perlport> for notes on the portability of this |
| 2236 | construct. |
| 2237 | |
| 2238 | Unlike in the shell, if SIGNAL is negative, it kills |
| 2239 | process groups instead of processes. (On System V, a negative I<PROCESS> |
| 2240 | number will also kill process groups, but that's not portable.) That |
| 2241 | means you usually want to use positive not negative signals. You may also |
| 2242 | use a signal name in quotes. See L<perlipc/"Signals"> for details. |
| 2243 | |
| 2244 | =item last LABEL |
| 2245 | |
| 2246 | =item last |
| 2247 | |
| 2248 | The C<last> command is like the C<break> statement in C (as used in |
| 2249 | loops); it immediately exits the loop in question. If the LABEL is |
| 2250 | omitted, the command refers to the innermost enclosing loop. The |
| 2251 | C<continue> block, if any, is not executed: |
| 2252 | |
| 2253 | LINE: while (<STDIN>) { |
| 2254 | last LINE if /^$/; # exit when done with header |
| 2255 | #... |
| 2256 | } |
| 2257 | |
| 2258 | C<last> cannot be used to exit a block which returns a value such as |
| 2259 | C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit |
| 2260 | a grep() or map() operation. |
| 2261 | |
| 2262 | Note that a block by itself is semantically identical to a loop |
| 2263 | that executes once. Thus C<last> can be used to effect an early |
| 2264 | exit out of such a block. |
| 2265 | |
| 2266 | See also L</continue> for an illustration of how C<last>, C<next>, and |
| 2267 | C<redo> work. |
| 2268 | |
| 2269 | =item lc EXPR |
| 2270 | |
| 2271 | =item lc |
| 2272 | |
| 2273 | Returns an lowercased version of EXPR. This is the internal function |
| 2274 | implementing the C<\L> escape in double-quoted strings. |
| 2275 | Respects current LC_CTYPE locale if C<use locale> in force. See L<perllocale> |
| 2276 | and L<utf8>. |
| 2277 | |
| 2278 | If EXPR is omitted, uses C<$_>. |
| 2279 | |
| 2280 | =item lcfirst EXPR |
| 2281 | |
| 2282 | =item lcfirst |
| 2283 | |
| 2284 | Returns the value of EXPR with the first character lowercased. This is |
| 2285 | the internal function implementing the C<\l> escape in double-quoted strings. |
| 2286 | Respects current LC_CTYPE locale if C<use locale> in force. See L<perllocale>. |
| 2287 | |
| 2288 | If EXPR is omitted, uses C<$_>. |
| 2289 | |
| 2290 | =item length EXPR |
| 2291 | |
| 2292 | =item length |
| 2293 | |
| 2294 | Returns the length in characters of the value of EXPR. If EXPR is |
| 2295 | omitted, returns length of C<$_>. Note that this cannot be used on |
| 2296 | an entire array or hash to find out how many elements these have. |
| 2297 | For that, use C<scalar @array> and C<scalar keys %hash> respectively. |
| 2298 | |
| 2299 | =item link OLDFILE,NEWFILE |
| 2300 | |
| 2301 | Creates a new filename linked to the old filename. Returns true for |
| 2302 | success, false otherwise. |
| 2303 | |
| 2304 | =item listen SOCKET,QUEUESIZE |
| 2305 | |
| 2306 | Does the same thing that the listen system call does. Returns true if |
| 2307 | it succeeded, false otherwise. See the example in L<perlipc/"Sockets: Client/Server Communication">. |
| 2308 | |
| 2309 | =item local EXPR |
| 2310 | |
| 2311 | You really probably want to be using C<my> instead, because C<local> isn't |
| 2312 | what most people think of as "local". See L<perlsub/"Private Variables |
| 2313 | via my()"> for details. |
| 2314 | |
| 2315 | A local modifies the listed variables to be local to the enclosing |
| 2316 | block, file, or eval. If more than one value is listed, the list must |
| 2317 | be placed in parentheses. See L<perlsub/"Temporary Values via local()"> |
| 2318 | for details, including issues with tied arrays and hashes. |
| 2319 | |
| 2320 | =item localtime EXPR |
| 2321 | |
| 2322 | Converts a time as returned by the time function to a 9-element list |
| 2323 | with the time analyzed for the local time zone. Typically used as |
| 2324 | follows: |
| 2325 | |
| 2326 | # 0 1 2 3 4 5 6 7 8 |
| 2327 | ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = |
| 2328 | localtime(time); |
| 2329 | |
| 2330 | All list elements are numeric, and come straight out of the C `struct |
| 2331 | tm'. $sec, $min, and $hour are the seconds, minutes, and hours of the |
| 2332 | specified time. $mday is the day of the month, and $mon is the month |
| 2333 | itself, in the range C<0..11> with 0 indicating January and 11 |
| 2334 | indicating December. $year is the number of years since 1900. That |
| 2335 | is, $year is C<123> in year 2023. $wday is the day of the week, with |
| 2336 | 0 indicating Sunday and 3 indicating Wednesday. $yday is the day of |
| 2337 | the year, in the range C<1..365> (or C<1..366> in leap years.) $isdst |
| 2338 | is true if the specified time occurs during daylight savings time, |
| 2339 | false otherwise. |
| 2340 | |
| 2341 | Note that the $year element is I<not> simply the last two digits of |
| 2342 | the year. If you assume it is, then you create non-Y2K-compliant |
| 2343 | programs--and you wouldn't want to do that, would you? |
| 2344 | |
| 2345 | The proper way to get a complete 4-digit year is simply: |
| 2346 | |
| 2347 | $year += 1900; |
| 2348 | |
| 2349 | And to get the last two digits of the year (e.g., '01' in 2001) do: |
| 2350 | |
| 2351 | $year = sprintf("%02d", $year % 100); |
| 2352 | |
| 2353 | If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>). |
| 2354 | |
| 2355 | In scalar context, C<localtime()> returns the ctime(3) value: |
| 2356 | |
| 2357 | $now_string = localtime; # e.g., "Thu Oct 13 04:54:34 1994" |
| 2358 | |
| 2359 | This scalar value is B<not> locale dependent, see L<perllocale>, but |
| 2360 | instead a Perl builtin. Also see the C<Time::Local> module |
| 2361 | (to convert the second, minutes, hours, ... back to seconds since the |
| 2362 | stroke of midnight the 1st of January 1970, the value returned by |
| 2363 | time()), and the strftime(3) and mktime(3) functions available via the |
| 2364 | POSIX module. To get somewhat similar but locale dependent date |
| 2365 | strings, set up your locale environment variables appropriately |
| 2366 | (please see L<perllocale>) and try for example: |
| 2367 | |
| 2368 | use POSIX qw(strftime); |
| 2369 | $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime; |
| 2370 | |
| 2371 | Note that the C<%a> and C<%b>, the short forms of the day of the week |
| 2372 | and the month of the year, may not necessarily be three characters wide. |
| 2373 | |
| 2374 | =item lock |
| 2375 | |
| 2376 | lock I<THING> |
| 2377 | |
| 2378 | This function places an advisory lock on a variable, subroutine, |
| 2379 | or referenced object contained in I<THING> until the lock goes out |
| 2380 | of scope. This is a built-in function only if your version of Perl |
| 2381 | was built with threading enabled, and if you've said C<use Threads>. |
| 2382 | Otherwise a user-defined function by this name will be called. See |
| 2383 | L<Thread>. |
| 2384 | |
| 2385 | =item log EXPR |
| 2386 | |
| 2387 | =item log |
| 2388 | |
| 2389 | Returns the natural logarithm (base I<e>) of EXPR. If EXPR is omitted, |
| 2390 | returns log of C<$_>. To get the log of another base, use basic algebra: |
| 2391 | The base-N log of a number is equal to the natural log of that number |
| 2392 | divided by the natural log of N. For example: |
| 2393 | |
| 2394 | sub log10 { |
| 2395 | my $n = shift; |
| 2396 | return log($n)/log(10); |
| 2397 | } |
| 2398 | |
| 2399 | See also L</exp> for the inverse operation. |
| 2400 | |
| 2401 | =item lstat FILEHANDLE |
| 2402 | |
| 2403 | =item lstat EXPR |
| 2404 | |
| 2405 | =item lstat |
| 2406 | |
| 2407 | Does the same thing as the C<stat> function (including setting the |
| 2408 | special C<_> filehandle) but stats a symbolic link instead of the file |
| 2409 | the symbolic link points to. If symbolic links are unimplemented on |
| 2410 | your system, a normal C<stat> is done. |
| 2411 | |
| 2412 | If EXPR is omitted, stats C<$_>. |
| 2413 | |
| 2414 | =item m// |
| 2415 | |
| 2416 | The match operator. See L<perlop>. |
| 2417 | |
| 2418 | =item map BLOCK LIST |
| 2419 | |
| 2420 | =item map EXPR,LIST |
| 2421 | |
| 2422 | Evaluates the BLOCK or EXPR for each element of LIST (locally setting |
| 2423 | C<$_> to each element) and returns the list value composed of the |
| 2424 | results of each such evaluation. In scalar context, returns the |
| 2425 | total number of elements so generated. Evaluates BLOCK or EXPR in |
| 2426 | list context, so each element of LIST may produce zero, one, or |
| 2427 | more elements in the returned value. |
| 2428 | |
| 2429 | @chars = map(chr, @nums); |
| 2430 | |
| 2431 | translates a list of numbers to the corresponding characters. And |
| 2432 | |
| 2433 | %hash = map { getkey($_) => $_ } @array; |
| 2434 | |
| 2435 | is just a funny way to write |
| 2436 | |
| 2437 | %hash = (); |
| 2438 | foreach $_ (@array) { |
| 2439 | $hash{getkey($_)} = $_; |
| 2440 | } |
| 2441 | |
| 2442 | Note that, because C<$_> is a reference into the list value, it can |
| 2443 | be used to modify the elements of the array. While this is useful and |
| 2444 | supported, it can cause bizarre results if the LIST is not a named array. |
| 2445 | Using a regular C<foreach> loop for this purpose would be clearer in |
| 2446 | most cases. See also L</grep> for an array composed of those items of |
| 2447 | the original list for which the BLOCK or EXPR evaluates to true. |
| 2448 | |
| 2449 | =item mkdir FILENAME,MASK |
| 2450 | |
| 2451 | =item mkdir FILENAME |
| 2452 | |
| 2453 | Creates the directory specified by FILENAME, with permissions |
| 2454 | specified by MASK (as modified by C<umask>). If it succeeds it |
| 2455 | returns true, otherwise it returns false and sets C<$!> (errno). |
| 2456 | If omitted, MASK defaults to 0777. |
| 2457 | |
| 2458 | In general, it is better to create directories with permissive MASK, |
| 2459 | and let the user modify that with their C<umask>, than it is to supply |
| 2460 | a restrictive MASK and give the user no way to be more permissive. |
| 2461 | The exceptions to this rule are when the file or directory should be |
| 2462 | kept private (mail files, for instance). The perlfunc(1) entry on |
| 2463 | C<umask> discusses the choice of MASK in more detail. |
| 2464 | |
| 2465 | =item msgctl ID,CMD,ARG |
| 2466 | |
| 2467 | Calls the System V IPC function msgctl(2). You'll probably have to say |
| 2468 | |
| 2469 | use IPC::SysV; |
| 2470 | |
| 2471 | first to get the correct constant definitions. If CMD is C<IPC_STAT>, |
| 2472 | then ARG must be a variable which will hold the returned C<msqid_ds> |
| 2473 | structure. Returns like C<ioctl>: the undefined value for error, |
| 2474 | C<"0 but true"> for zero, or the actual return value otherwise. See also |
| 2475 | C<IPC::SysV> and C<IPC::Semaphore> documentation. |
| 2476 | |
| 2477 | =item msgget KEY,FLAGS |
| 2478 | |
| 2479 | Calls the System V IPC function msgget(2). Returns the message queue |
| 2480 | id, or the undefined value if there is an error. See also C<IPC::SysV> |
| 2481 | and C<IPC::Msg> documentation. |
| 2482 | |
| 2483 | =item msgsnd ID,MSG,FLAGS |
| 2484 | |
| 2485 | Calls the System V IPC function msgsnd to send the message MSG to the |
| 2486 | message queue ID. MSG must begin with the native long integer message |
| 2487 | type, which may be created with C<pack("l!", $type)>. Returns true if |
| 2488 | successful, or false if there is an error. See also C<IPC::SysV> and |
| 2489 | C<IPC::SysV::Msg> documentation. |
| 2490 | |
| 2491 | =item msgrcv ID,VAR,SIZE,TYPE,FLAGS |
| 2492 | |
| 2493 | Calls the System V IPC function msgrcv to receive a message from |
| 2494 | message queue ID into variable VAR with a maximum message size of |
| 2495 | SIZE. Note that if a message is received, the message type will be |
| 2496 | the first thing in VAR, and the maximum length of VAR is SIZE plus the |
| 2497 | size of the message type. Returns true if successful, or false if |
| 2498 | there is an error. See also C<IPC::SysV> and C<IPC::SysV::Msg> documentation. |
| 2499 | |
| 2500 | =item my EXPR |
| 2501 | |
| 2502 | =item my EXPR : ATTRIBUTES |
| 2503 | |
| 2504 | A C<my> declares the listed variables to be local (lexically) to the |
| 2505 | enclosing block, file, or C<eval>. If |
| 2506 | more than one value is listed, the list must be placed in parentheses. See |
| 2507 | L<perlsub/"Private Variables via my()"> for details. |
| 2508 | |
| 2509 | =item next LABEL |
| 2510 | |
| 2511 | =item next |
| 2512 | |
| 2513 | The C<next> command is like the C<continue> statement in C; it starts |
| 2514 | the next iteration of the loop: |
| 2515 | |
| 2516 | LINE: while (<STDIN>) { |
| 2517 | next LINE if /^#/; # discard comments |
| 2518 | #... |
| 2519 | } |
| 2520 | |
| 2521 | Note that if there were a C<continue> block on the above, it would get |
| 2522 | executed even on discarded lines. If the LABEL is omitted, the command |
| 2523 | refers to the innermost enclosing loop. |
| 2524 | |
| 2525 | C<next> cannot be used to exit a block which returns a value such as |
| 2526 | C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit |
| 2527 | a grep() or map() operation. |
| 2528 | |
| 2529 | Note that a block by itself is semantically identical to a loop |
| 2530 | that executes once. Thus C<next> will exit such a block early. |
| 2531 | |
| 2532 | See also L</continue> for an illustration of how C<last>, C<next>, and |
| 2533 | C<redo> work. |
| 2534 | |
| 2535 | =item no Module LIST |
| 2536 | |
| 2537 | See the L</use> function, which C<no> is the opposite of. |
| 2538 | |
| 2539 | =item oct EXPR |
| 2540 | |
| 2541 | =item oct |
| 2542 | |
| 2543 | Interprets EXPR as an octal string and returns the corresponding |
| 2544 | value. (If EXPR happens to start off with C<0x>, interprets it as a |
| 2545 | hex string. If EXPR starts off with C<0b>, it is interpreted as a |
| 2546 | binary string.) The following will handle decimal, binary, octal, and |
| 2547 | hex in the standard Perl or C notation: |
| 2548 | |
| 2549 | $val = oct($val) if $val =~ /^0/; |
| 2550 | |
| 2551 | If EXPR is omitted, uses C<$_>. To go the other way (produce a number |
| 2552 | in octal), use sprintf() or printf(): |
| 2553 | |
| 2554 | $perms = (stat("filename"))[2] & 07777; |
| 2555 | $oct_perms = sprintf "%lo", $perms; |
| 2556 | |
| 2557 | The oct() function is commonly used when a string such as C<644> needs |
| 2558 | to be converted into a file mode, for example. (Although perl will |
| 2559 | automatically convert strings into numbers as needed, this automatic |
| 2560 | conversion assumes base 10.) |
| 2561 | |
| 2562 | =item open FILEHANDLE,MODE,LIST |
| 2563 | |
| 2564 | =item open FILEHANDLE,EXPR |
| 2565 | |
| 2566 | =item open FILEHANDLE |
| 2567 | |
| 2568 | Opens the file whose filename is given by EXPR, and associates it with |
| 2569 | FILEHANDLE. If FILEHANDLE is an expression, its value is used as the |
| 2570 | name of the real filehandle wanted. If EXPR is omitted, the scalar |
| 2571 | variable of the same name as the FILEHANDLE contains the filename. |
| 2572 | (Note that lexical variables--those declared with C<my>--will not work |
| 2573 | for this purpose; so if you're using C<my>, specify EXPR in your call |
| 2574 | to open.) See L<perlopentut> for a kinder, gentler explanation of opening |
| 2575 | files. |
| 2576 | |
| 2577 | If MODE is C<< '<' >> or nothing, the file is opened for input. |
| 2578 | If MODE is C<< '>' >>, the file is truncated and opened for |
| 2579 | output, being created if necessary. If MODE is C<<< '>>' >>>, |
| 2580 | the file is opened for appending, again being created if necessary. |
| 2581 | You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to indicate that |
| 2582 | you want both read and write access to the file; thus C<< '+<' >> is almost |
| 2583 | always preferred for read/write updates--the C<< '+>' >> mode would clobber the |
| 2584 | file first. You can't usually use either read-write mode for updating |
| 2585 | textfiles, since they have variable length records. See the B<-i> |
| 2586 | switch in L<perlrun> for a better approach. The file is created with |
| 2587 | permissions of C<0666> modified by the process' C<umask> value. |
| 2588 | |
| 2589 | These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>, |
| 2590 | C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>. |
| 2591 | |
| 2592 | In the 2-arguments (and 1-argument) form of the call the mode and |
| 2593 | filename should be concatenated (in this order), possibly separated by |
| 2594 | spaces. It is possible to omit the mode if the mode is C<< '<' >>. |
| 2595 | |
| 2596 | If the filename begins with C<'|'>, the filename is interpreted as a |
| 2597 | command to which output is to be piped, and if the filename ends with a |
| 2598 | C<'|'>, the filename is interpreted as a command which pipes output to |
| 2599 | us. See L<perlipc/"Using open() for IPC"> |
| 2600 | for more examples of this. (You are not allowed to C<open> to a command |
| 2601 | that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>, |
| 2602 | and L<perlipc/"Bidirectional Communication"> for alternatives.) |
| 2603 | |
| 2604 | If MODE is C<'|-'>, the filename is interpreted as a |
| 2605 | command to which output is to be piped, and if MODE is |
| 2606 | C<'-|'>, the filename is interpreted as a command which pipes output to |
| 2607 | us. In the 2-arguments (and 1-argument) form one should replace dash |
| 2608 | (C<'-'>) with the command. See L<perlipc/"Using open() for IPC"> |
| 2609 | for more examples of this. (You are not allowed to C<open> to a command |
| 2610 | that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>, |
| 2611 | and L<perlipc/"Bidirectional Communication"> for alternatives.) |
| 2612 | |
| 2613 | In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN |
| 2614 | and opening C<< '>-' >> opens STDOUT. |
| 2615 | |
| 2616 | Open returns |
| 2617 | nonzero upon success, the undefined value otherwise. If the C<open> |
| 2618 | involved a pipe, the return value happens to be the pid of the |
| 2619 | subprocess. |
| 2620 | |
| 2621 | If you're unfortunate enough to be running Perl on a system that |
| 2622 | distinguishes between text files and binary files (modern operating |
| 2623 | systems don't care), then you should check out L</binmode> for tips for |
| 2624 | dealing with this. The key distinction between systems that need C<binmode> |
| 2625 | and those that don't is their text file formats. Systems like Unix, MacOS, and |
| 2626 | Plan9, which delimit lines with a single character, and which encode that |
| 2627 | character in C as C<"\n">, do not need C<binmode>. The rest need it. |
| 2628 | |
| 2629 | When opening a file, it's usually a bad idea to continue normal execution |
| 2630 | if the request failed, so C<open> is frequently used in connection with |
| 2631 | C<die>. Even if C<die> won't do what you want (say, in a CGI script, |
| 2632 | where you want to make a nicely formatted error message (but there are |
| 2633 | modules that can help with that problem)) you should always check |
| 2634 | the return value from opening a file. The infrequent exception is when |
| 2635 | working with an unopened filehandle is actually what you want to do. |
| 2636 | |
| 2637 | Examples: |
| 2638 | |
| 2639 | $ARTICLE = 100; |
| 2640 | open ARTICLE or die "Can't find article $ARTICLE: $!\n"; |
| 2641 | while (<ARTICLE>) {... |
| 2642 | |
| 2643 | open(LOG, '>>/usr/spool/news/twitlog'); # (log is reserved) |
| 2644 | # if the open fails, output is discarded |
| 2645 | |
| 2646 | open(DBASE, '+<', 'dbase.mine') # open for update |
| 2647 | or die "Can't open 'dbase.mine' for update: $!"; |
| 2648 | |
| 2649 | open(DBASE, '+<dbase.mine') # ditto |
| 2650 | or die "Can't open 'dbase.mine' for update: $!"; |
| 2651 | |
| 2652 | open(ARTICLE, '-|', "caesar <$article") # decrypt article |
| 2653 | or die "Can't start caesar: $!"; |
| 2654 | |
| 2655 | open(ARTICLE, "caesar <$article |") # ditto |
| 2656 | or die "Can't start caesar: $!"; |
| 2657 | |
| 2658 | open(EXTRACT, "|sort >/tmp/Tmp$$") # $$ is our process id |
| 2659 | or die "Can't start sort: $!"; |
| 2660 | |
| 2661 | # process argument list of files along with any includes |
| 2662 | |
| 2663 | foreach $file (@ARGV) { |
| 2664 | process($file, 'fh00'); |
| 2665 | } |
| 2666 | |
| 2667 | sub process { |
| 2668 | my($filename, $input) = @_; |
| 2669 | $input++; # this is a string increment |
| 2670 | unless (open($input, $filename)) { |
| 2671 | print STDERR "Can't open $filename: $!\n"; |
| 2672 | return; |
| 2673 | } |
| 2674 | |
| 2675 | local $_; |
| 2676 | while (<$input>) { # note use of indirection |
| 2677 | if (/^#include "(.*)"/) { |
| 2678 | process($1, $input); |
| 2679 | next; |
| 2680 | } |
| 2681 | #... # whatever |
| 2682 | } |
| 2683 | } |
| 2684 | |
| 2685 | You may also, in the Bourne shell tradition, specify an EXPR beginning |
| 2686 | with C<< '>&' >>, in which case the rest of the string is interpreted as the |
| 2687 | name of a filehandle (or file descriptor, if numeric) to be |
| 2688 | duped and opened. You may use C<&> after C<< > >>, C<<< >> >>>, |
| 2689 | C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>. The |
| 2690 | mode you specify should match the mode of the original filehandle. |
| 2691 | (Duping a filehandle does not take into account any existing contents of |
| 2692 | stdio buffers.) Duping file handles is not yet supported for 3-argument |
| 2693 | open(). |
| 2694 | |
| 2695 | Here is a script that saves, redirects, and restores STDOUT and |
| 2696 | STDERR: |
| 2697 | |
| 2698 | #!/usr/bin/perl |
| 2699 | open(OLDOUT, ">&STDOUT"); |
| 2700 | open(OLDERR, ">&STDERR"); |
| 2701 | |
| 2702 | open(STDOUT, '>', "foo.out") || die "Can't redirect stdout"; |
| 2703 | open(STDERR, ">&STDOUT") || die "Can't dup stdout"; |
| 2704 | |
| 2705 | select(STDERR); $| = 1; # make unbuffered |
| 2706 | select(STDOUT); $| = 1; # make unbuffered |
| 2707 | |
| 2708 | print STDOUT "stdout 1\n"; # this works for |
| 2709 | print STDERR "stderr 1\n"; # subprocesses too |
| 2710 | |
| 2711 | close(STDOUT); |
| 2712 | close(STDERR); |
| 2713 | |
| 2714 | open(STDOUT, ">&OLDOUT"); |
| 2715 | open(STDERR, ">&OLDERR"); |
| 2716 | |
| 2717 | print STDOUT "stdout 2\n"; |
| 2718 | print STDERR "stderr 2\n"; |
| 2719 | |
| 2720 | If you specify C<< '<&=N' >>, where C<N> is a number, then Perl will do an |
| 2721 | equivalent of C's C<fdopen> of that file descriptor; this is more |
| 2722 | parsimonious of file descriptors. For example: |
| 2723 | |
| 2724 | open(FILEHANDLE, "<&=$fd") |
| 2725 | |
| 2726 | Note that this feature depends on the fdopen() C library function. |
| 2727 | On many UNIX systems, fdopen() is known to fail when file descriptors |
| 2728 | exceed a certain value, typically 255. If you need more file |
| 2729 | descriptors than that, consider rebuilding Perl to use the C<sfio> |
| 2730 | library. |
| 2731 | |
| 2732 | If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'> |
| 2733 | with 2-arguments (or 1-argument) form of open(), then |
| 2734 | there is an implicit fork done, and the return value of open is the pid |
| 2735 | of the child within the parent process, and C<0> within the child |
| 2736 | process. (Use C<defined($pid)> to determine whether the open was successful.) |
| 2737 | The filehandle behaves normally for the parent, but i/o to that |
| 2738 | filehandle is piped from/to the STDOUT/STDIN of the child process. |
| 2739 | In the child process the filehandle isn't opened--i/o happens from/to |
| 2740 | the new STDOUT or STDIN. Typically this is used like the normal |
| 2741 | piped open when you want to exercise more control over just how the |
| 2742 | pipe command gets executed, such as when you are running setuid, and |
| 2743 | don't want to have to scan shell commands for metacharacters. |
| 2744 | The following triples are more or less equivalent: |
| 2745 | |
| 2746 | open(FOO, "|tr '[a-z]' '[A-Z]'"); |
| 2747 | open(FOO, '|-', "tr '[a-z]' '[A-Z]'"); |
| 2748 | open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]'; |
| 2749 | |
| 2750 | open(FOO, "cat -n '$file'|"); |
| 2751 | open(FOO, '-|', "cat -n '$file'"); |
| 2752 | open(FOO, '-|') || exec 'cat', '-n', $file; |
| 2753 | |
| 2754 | See L<perlipc/"Safe Pipe Opens"> for more examples of this. |
| 2755 | |
| 2756 | NOTE: On any operation that may do a fork, all files opened for output |
| 2757 | are flushed before the fork is attempted. On systems that support a |
| 2758 | close-on-exec flag on files, the flag will be set for the newly opened |
| 2759 | file descriptor as determined by the value of $^F. See L<perlvar/$^F>. |
| 2760 | |
| 2761 | Closing any piped filehandle causes the parent process to wait for the |
| 2762 | child to finish, and returns the status value in C<$?>. |
| 2763 | |
| 2764 | The filename passed to 2-argument (or 1-argument) form of open() |
| 2765 | will have leading and trailing |
| 2766 | whitespace deleted, and the normal redirection characters |
| 2767 | honored. This property, known as "magic open", |
| 2768 | can often be used to good effect. A user could specify a filename of |
| 2769 | F<"rsh cat file |">, or you could change certain filenames as needed: |
| 2770 | |
| 2771 | $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/; |
| 2772 | open(FH, $filename) or die "Can't open $filename: $!"; |
| 2773 | |
| 2774 | Use 3-argument form to open a file with arbitrary weird characters in it, |
| 2775 | |
| 2776 | open(FOO, '<', $file); |
| 2777 | |
| 2778 | otherwise it's necessary to protect any leading and trailing whitespace: |
| 2779 | |
| 2780 | $file =~ s#^(\s)#./$1#; |
| 2781 | open(FOO, "< $file\0"); |
| 2782 | |
| 2783 | (this may not work on some bizzare filesystems). One should |
| 2784 | conscientiously choose between the the I<magic> and 3-arguments form |
| 2785 | of open(): |
| 2786 | |
| 2787 | open IN, $ARGV[0]; |
| 2788 | |
| 2789 | will allow the user to specify an argument of the form C<"rsh cat file |">, |
| 2790 | but will not work on a filename which happens to have a trailing space, while |
| 2791 | |
| 2792 | open IN, '<', $ARGV[0]; |
| 2793 | |
| 2794 | will have exactly the opposite restrictions. |
| 2795 | |
| 2796 | If you want a "real" C C<open> (see L<open(2)> on your system), then you |
| 2797 | should use the C<sysopen> function, which involves no such magic (but |
| 2798 | may use subtly different filemodes than Perl open(), which is mapped |
| 2799 | to C fopen()). This is |
| 2800 | another way to protect your filenames from interpretation. For example: |
| 2801 | |
| 2802 | use IO::Handle; |
| 2803 | sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL) |
| 2804 | or die "sysopen $path: $!"; |
| 2805 | $oldfh = select(HANDLE); $| = 1; select($oldfh); |
| 2806 | print HANDLE "stuff $$\n"); |
| 2807 | seek(HANDLE, 0, 0); |
| 2808 | print "File contains: ", <HANDLE>; |
| 2809 | |
| 2810 | Using the constructor from the C<IO::Handle> package (or one of its |
| 2811 | subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous |
| 2812 | filehandles that have the scope of whatever variables hold references to |
| 2813 | them, and automatically close whenever and however you leave that scope: |
| 2814 | |
| 2815 | use IO::File; |
| 2816 | #... |
| 2817 | sub read_myfile_munged { |
| 2818 | my $ALL = shift; |
| 2819 | my $handle = new IO::File; |
| 2820 | open($handle, "myfile") or die "myfile: $!"; |
| 2821 | $first = <$handle> |
| 2822 | or return (); # Automatically closed here. |
| 2823 | mung $first or die "mung failed"; # Or here. |
| 2824 | return $first, <$handle> if $ALL; # Or here. |
| 2825 | $first; # Or here. |
| 2826 | } |
| 2827 | |
| 2828 | See L</seek> for some details about mixing reading and writing. |
| 2829 | |
| 2830 | =item opendir DIRHANDLE,EXPR |
| 2831 | |
| 2832 | Opens a directory named EXPR for processing by C<readdir>, C<telldir>, |
| 2833 | C<seekdir>, C<rewinddir>, and C<closedir>. Returns true if successful. |
| 2834 | DIRHANDLEs have their own namespace separate from FILEHANDLEs. |
| 2835 | |
| 2836 | =item ord EXPR |
| 2837 | |
| 2838 | =item ord |
| 2839 | |
| 2840 | Returns the numeric (ASCII or Unicode) value of the first character of EXPR. If |
| 2841 | EXPR is omitted, uses C<$_>. For the reverse, see L</chr>. |
| 2842 | See L<utf8> for more about Unicode. |
| 2843 | |
| 2844 | =item our EXPR |
| 2845 | |
| 2846 | An C<our> declares the listed variables to be valid globals within |
| 2847 | the enclosing block, file, or C<eval>. That is, it has the same |
| 2848 | scoping rules as a "my" declaration, but does not create a local |
| 2849 | variable. If more than one value is listed, the list must be placed |
| 2850 | in parentheses. The C<our> declaration has no semantic effect unless |
| 2851 | "use strict vars" is in effect, in which case it lets you use the |
| 2852 | declared global variable without qualifying it with a package name. |
| 2853 | (But only within the lexical scope of the C<our> declaration. In this |
| 2854 | it differs from "use vars", which is package scoped.) |
| 2855 | |
| 2856 | An C<our> declaration declares a global variable that will be visible |
| 2857 | across its entire lexical scope, even across package boundaries. The |
| 2858 | package in which the variable is entered is determined at the point |
| 2859 | of the declaration, not at the point of use. This means the following |
| 2860 | behavior holds: |
| 2861 | |
| 2862 | package Foo; |
| 2863 | our $bar; # declares $Foo::bar for rest of lexical scope |
| 2864 | $bar = 20; |
| 2865 | |
| 2866 | package Bar; |
| 2867 | print $bar; # prints 20 |
| 2868 | |
| 2869 | Multiple C<our> declarations in the same lexical scope are allowed |
| 2870 | if they are in different packages. If they happened to be in the same |
| 2871 | package, Perl will emit warnings if you have asked for them. |
| 2872 | |
| 2873 | use warnings; |
| 2874 | package Foo; |
| 2875 | our $bar; # declares $Foo::bar for rest of lexical scope |
| 2876 | $bar = 20; |
| 2877 | |
| 2878 | package Bar; |
| 2879 | our $bar = 30; # declares $Bar::bar for rest of lexical scope |
| 2880 | print $bar; # prints 30 |
| 2881 | |
| 2882 | our $bar; # emits warning |
| 2883 | |
| 2884 | =item pack TEMPLATE,LIST |
| 2885 | |
| 2886 | Takes a LIST of values and converts it into a string using the rules |
| 2887 | given by the TEMPLATE. The resulting string is the concatenation of |
| 2888 | the converted values. Typically, each converted value looks |
| 2889 | like its machine-level representation. For example, on 32-bit machines |
| 2890 | a converted integer may be represented by a sequence of 4 bytes. |
| 2891 | |
| 2892 | The TEMPLATE is a |
| 2893 | sequence of characters that give the order and type of values, as |
| 2894 | follows: |
| 2895 | |
| 2896 | a A string with arbitrary binary data, will be null padded. |
| 2897 | A An ascii string, will be space padded. |
| 2898 | Z A null terminated (asciz) string, will be null padded. |
| 2899 | |
| 2900 | b A bit string (ascending bit order inside each byte, like vec()). |
| 2901 | B A bit string (descending bit order inside each byte). |
| 2902 | h A hex string (low nybble first). |
| 2903 | H A hex string (high nybble first). |
| 2904 | |
| 2905 | c A signed char value. |
| 2906 | C An unsigned char value. Only does bytes. See U for Unicode. |
| 2907 | |
| 2908 | s A signed short value. |
| 2909 | S An unsigned short value. |
| 2910 | (This 'short' is _exactly_ 16 bits, which may differ from |
| 2911 | what a local C compiler calls 'short'. If you want |
| 2912 | native-length shorts, use the '!' suffix.) |
| 2913 | |
| 2914 | i A signed integer value. |
| 2915 | I An unsigned integer value. |
| 2916 | (This 'integer' is _at_least_ 32 bits wide. Its exact |
| 2917 | size depends on what a local C compiler calls 'int', |
| 2918 | and may even be larger than the 'long' described in |
| 2919 | the next item.) |
| 2920 | |
| 2921 | l A signed long value. |
| 2922 | L An unsigned long value. |
| 2923 | (This 'long' is _exactly_ 32 bits, which may differ from |
| 2924 | what a local C compiler calls 'long'. If you want |
| 2925 | native-length longs, use the '!' suffix.) |
| 2926 | |
| 2927 | n An unsigned short in "network" (big-endian) order. |
| 2928 | N An unsigned long in "network" (big-endian) order. |
| 2929 | v An unsigned short in "VAX" (little-endian) order. |
| 2930 | V An unsigned long in "VAX" (little-endian) order. |
| 2931 | (These 'shorts' and 'longs' are _exactly_ 16 bits and |
| 2932 | _exactly_ 32 bits, respectively.) |
| 2933 | |
| 2934 | q A signed quad (64-bit) value. |
| 2935 | Q An unsigned quad value. |
| 2936 | (Quads are available only if your system supports 64-bit |
| 2937 | integer values _and_ if Perl has been compiled to support those. |
| 2938 | Causes a fatal error otherwise.) |
| 2939 | |
| 2940 | f A single-precision float in the native format. |
| 2941 | d A double-precision float in the native format. |
| 2942 | |
| 2943 | p A pointer to a null-terminated string. |
| 2944 | P A pointer to a structure (fixed-length string). |
| 2945 | |
| 2946 | u A uuencoded string. |
| 2947 | U A Unicode character number. Encodes to UTF-8 internally. |
| 2948 | Works even if C<use utf8> is not in effect. |
| 2949 | |
| 2950 | w A BER compressed integer. Its bytes represent an unsigned |
| 2951 | integer in base 128, most significant digit first, with as |
| 2952 | few digits as possible. Bit eight (the high bit) is set |
| 2953 | on each byte except the last. |
| 2954 | |
| 2955 | x A null byte. |
| 2956 | X Back up a byte. |
| 2957 | @ Null fill to absolute position. |
| 2958 | |
| 2959 | The following rules apply: |
| 2960 | |
| 2961 | =over 8 |
| 2962 | |
| 2963 | =item * |
| 2964 | |
| 2965 | Each letter may optionally be followed by a number giving a repeat |
| 2966 | count. With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>, |
| 2967 | C<H>, and C<P> the pack function will gobble up that many values from |
| 2968 | the LIST. A C<*> for the repeat count means to use however many items are |
| 2969 | left, except for C<@>, C<x>, C<X>, where it is equivalent |
| 2970 | to C<0>, and C<u>, where it is equivalent to 1 (or 45, what is the |
| 2971 | same). |
| 2972 | |
| 2973 | When used with C<Z>, C<*> results in the addition of a trailing null |
| 2974 | byte (so the packed result will be one longer than the byte C<length> |
| 2975 | of the item). |
| 2976 | |
| 2977 | The repeat count for C<u> is interpreted as the maximal number of bytes |
| 2978 | to encode per line of output, with 0 and 1 replaced by 45. |
| 2979 | |
| 2980 | =item * |
| 2981 | |
| 2982 | The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a |
| 2983 | string of length count, padding with nulls or spaces as necessary. When |
| 2984 | unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything |
| 2985 | after the first null, and C<a> returns data verbatim. When packing, |
| 2986 | C<a>, and C<Z> are equivalent. |
| 2987 | |
| 2988 | If the value-to-pack is too long, it is truncated. If too long and an |
| 2989 | explicit count is provided, C<Z> packs only C<$count-1> bytes, followed |
| 2990 | by a null byte. Thus C<Z> always packs a trailing null byte under |
| 2991 | all circumstances. |
| 2992 | |
| 2993 | =item * |
| 2994 | |
| 2995 | Likewise, the C<b> and C<B> fields pack a string that many bits long. |
| 2996 | Each byte of the input field of pack() generates 1 bit of the result. |
| 2997 | Each result bit is based on the least-significant bit of the corresponding |
| 2998 | input byte, i.e., on C<ord($byte)%2>. In particular, bytes C<"0"> and |
| 2999 | C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">. |
| 3000 | |
| 3001 | Starting from the beginning of the input string of pack(), each 8-tuple |
| 3002 | of bytes is converted to 1 byte of output. With format C<b> |
| 3003 | the first byte of the 8-tuple determines the least-significant bit of a |
| 3004 | byte, and with format C<B> it determines the most-significant bit of |
| 3005 | a byte. |
| 3006 | |
| 3007 | If the length of the input string is not exactly divisible by 8, the |
| 3008 | remainder is packed as if the input string were padded by null bytes |
| 3009 | at the end. Similarly, during unpack()ing the "extra" bits are ignored. |
| 3010 | |
| 3011 | If the input string of pack() is longer than needed, extra bytes are ignored. |
| 3012 | A C<*> for the repeat count of pack() means to use all the bytes of |
| 3013 | the input field. On unpack()ing the bits are converted to a string |
| 3014 | of C<"0">s and C<"1">s. |
| 3015 | |
| 3016 | =item * |
| 3017 | |
| 3018 | The C<h> and C<H> fields pack a string that many nybbles (4-bit groups, |
| 3019 | representable as hexadecimal digits, 0-9a-f) long. |
| 3020 | |
| 3021 | Each byte of the input field of pack() generates 4 bits of the result. |
| 3022 | For non-alphabetical bytes the result is based on the 4 least-significant |
| 3023 | bits of the input byte, i.e., on C<ord($byte)%16>. In particular, |
| 3024 | bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes |
| 3025 | C<"\0"> and C<"\1">. For bytes C<"a".."f"> and C<"A".."F"> the result |
| 3026 | is compatible with the usual hexadecimal digits, so that C<"a"> and |
| 3027 | C<"A"> both generate the nybble C<0xa==10>. The result for bytes |
| 3028 | C<"g".."z"> and C<"G".."Z"> is not well-defined. |
| 3029 | |
| 3030 | Starting from the beginning of the input string of pack(), each pair |
| 3031 | of bytes is converted to 1 byte of output. With format C<h> the |
| 3032 | first byte of the pair determines the least-significant nybble of the |
| 3033 | output byte, and with format C<H> it determines the most-significant |
| 3034 | nybble. |
| 3035 | |
| 3036 | If the length of the input string is not even, it behaves as if padded |
| 3037 | by a null byte at the end. Similarly, during unpack()ing the "extra" |
| 3038 | nybbles are ignored. |
| 3039 | |
| 3040 | If the input string of pack() is longer than needed, extra bytes are ignored. |
| 3041 | A C<*> for the repeat count of pack() means to use all the bytes of |
| 3042 | the input field. On unpack()ing the bits are converted to a string |
| 3043 | of hexadecimal digits. |
| 3044 | |
| 3045 | =item * |
| 3046 | |
| 3047 | The C<p> type packs a pointer to a null-terminated string. You are |
| 3048 | responsible for ensuring the string is not a temporary value (which can |
| 3049 | potentially get deallocated before you get around to using the packed result). |
| 3050 | The C<P> type packs a pointer to a structure of the size indicated by the |
| 3051 | length. A NULL pointer is created if the corresponding value for C<p> or |
| 3052 | C<P> is C<undef>, similarly for unpack(). |
| 3053 | |
| 3054 | =item * |
| 3055 | |
| 3056 | The C</> template character allows packing and unpacking of strings where |
| 3057 | the packed structure contains a byte count followed by the string itself. |
| 3058 | You write I<length-item>C</>I<string-item>. |
| 3059 | |
| 3060 | The I<length-item> can be any C<pack> template letter, |
| 3061 | and describes how the length value is packed. |
| 3062 | The ones likely to be of most use are integer-packing ones like |
| 3063 | C<n> (for Java strings), C<w> (for ASN.1 or SNMP) |
| 3064 | and C<N> (for Sun XDR). |
| 3065 | |
| 3066 | The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">. |
| 3067 | For C<unpack> the length of the string is obtained from the I<length-item>, |
| 3068 | but if you put in the '*' it will be ignored. |
| 3069 | |
| 3070 | unpack 'C/a', "\04Gurusamy"; gives 'Guru' |
| 3071 | unpack 'a3/A* A*', '007 Bond J '; gives (' Bond','J') |
| 3072 | pack 'n/a* w/a*','hello,','world'; gives "\000\006hello,\005world" |
| 3073 | |
| 3074 | The I<length-item> is not returned explicitly from C<unpack>. |
| 3075 | |
| 3076 | Adding a count to the I<length-item> letter is unlikely to do anything |
| 3077 | useful, unless that letter is C<A>, C<a> or C<Z>. Packing with a |
| 3078 | I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters, |
| 3079 | which Perl does not regard as legal in numeric strings. |
| 3080 | |
| 3081 | =item * |
| 3082 | |
| 3083 | The integer types C<s>, C<S>, C<l>, and C<L> may be |
| 3084 | immediately followed by a C<!> suffix to signify native shorts or |
| 3085 | longs--as you can see from above for example a bare C<l> does mean |
| 3086 | exactly 32 bits, the native C<long> (as seen by the local C compiler) |
| 3087 | may be larger. This is an issue mainly in 64-bit platforms. You can |
| 3088 | see whether using C<!> makes any difference by |
| 3089 | |
| 3090 | print length(pack("s")), " ", length(pack("s!")), "\n"; |
| 3091 | print length(pack("l")), " ", length(pack("l!")), "\n"; |
| 3092 | |
| 3093 | C<i!> and C<I!> also work but only because of completeness; |
| 3094 | they are identical to C<i> and C<I>. |
| 3095 | |
| 3096 | The actual sizes (in bytes) of native shorts, ints, longs, and long |
| 3097 | longs on the platform where Perl was built are also available via |
| 3098 | L<Config>: |
| 3099 | |
| 3100 | use Config; |
| 3101 | print $Config{shortsize}, "\n"; |
| 3102 | print $Config{intsize}, "\n"; |
| 3103 | print $Config{longsize}, "\n"; |
| 3104 | print $Config{longlongsize}, "\n"; |
| 3105 | |
| 3106 | (The C<$Config{longlongsize}> will be undefine if your system does |
| 3107 | not support long longs.) |
| 3108 | |
| 3109 | =item * |
| 3110 | |
| 3111 | The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, and C<L> |
| 3112 | are inherently non-portable between processors and operating systems |
| 3113 | because they obey the native byteorder and endianness. For example a |
| 3114 | 4-byte integer 0x12345678 (305419896 decimal) be ordered natively |
| 3115 | (arranged in and handled by the CPU registers) into bytes as |
| 3116 | |
| 3117 | 0x12 0x34 0x56 0x78 # little-endian |
| 3118 | 0x78 0x56 0x34 0x12 # big-endian |
| 3119 | |
| 3120 | Basically, the Intel, Alpha, and VAX CPUs are little-endian, while |
| 3121 | everybody else, for example Motorola m68k/88k, PPC, Sparc, HP PA, |
| 3122 | Power, and Cray are big-endian. MIPS can be either: Digital used it |
| 3123 | in little-endian mode; SGI uses it in big-endian mode. |
| 3124 | |
| 3125 | The names `big-endian' and `little-endian' are comic references to |
| 3126 | the classic "Gulliver's Travels" (via the paper "On Holy Wars and a |
| 3127 | Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and |
| 3128 | the egg-eating habits of the Lilliputians. |
| 3129 | |
| 3130 | Some systems may have even weirder byte orders such as |
| 3131 | |
| 3132 | 0x56 0x78 0x12 0x34 |
| 3133 | 0x34 0x12 0x78 0x56 |
| 3134 | |
| 3135 | You can see your system's preference with |
| 3136 | |
| 3137 | print join(" ", map { sprintf "%#02x", $_ } |
| 3138 | unpack("C*",pack("L",0x12345678))), "\n"; |
| 3139 | |
| 3140 | The byteorder on the platform where Perl was built is also available |
| 3141 | via L<Config>: |
| 3142 | |
| 3143 | use Config; |
| 3144 | print $Config{byteorder}, "\n"; |
| 3145 | |
| 3146 | Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'> |
| 3147 | and C<'87654321'> are big-endian. |
| 3148 | |
| 3149 | If you want portable packed integers use the formats C<n>, C<N>, |
| 3150 | C<v>, and C<V>, their byte endianness and size is known. |
| 3151 | See also L<perlport>. |
| 3152 | |
| 3153 | =item * |
| 3154 | |
| 3155 | Real numbers (floats and doubles) are in the native machine format only; |
| 3156 | due to the multiplicity of floating formats around, and the lack of a |
| 3157 | standard "network" representation, no facility for interchange has been |
| 3158 | made. This means that packed floating point data written on one machine |
| 3159 | may not be readable on another - even if both use IEEE floating point |
| 3160 | arithmetic (as the endian-ness of the memory representation is not part |
| 3161 | of the IEEE spec). See also L<perlport>. |
| 3162 | |
| 3163 | Note that Perl uses doubles internally for all numeric calculation, and |
| 3164 | converting from double into float and thence back to double again will |
| 3165 | lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general |
| 3166 | equal $foo). |
| 3167 | |
| 3168 | =item * |
| 3169 | |
| 3170 | You must yourself do any alignment or padding by inserting for example |
| 3171 | enough C<'x'>es while packing. There is no way to pack() and unpack() |
| 3172 | could know where the bytes are going to or coming from. Therefore |
| 3173 | C<pack> (and C<unpack>) handle their output and input as flat |
| 3174 | sequences of bytes. |
| 3175 | |
| 3176 | =item * |
| 3177 | |
| 3178 | A comment in a TEMPLATE starts with C<#> and goes to the end of line. |
| 3179 | |
| 3180 | =item * |
| 3181 | |
| 3182 | If TEMPLATE requires more arguments to pack() than actually given, pack() |
| 3183 | assumes additional C<""> arguments. If TEMPLATE requires less arguments |
| 3184 | to pack() than actually given, extra arguments are ignored. |
| 3185 | |
| 3186 | =back |
| 3187 | |
| 3188 | Examples: |
| 3189 | |
| 3190 | $foo = pack("CCCC",65,66,67,68); |
| 3191 | # foo eq "ABCD" |
| 3192 | $foo = pack("C4",65,66,67,68); |
| 3193 | # same thing |
| 3194 | $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9); |
| 3195 | # same thing with Unicode circled letters |
| 3196 | |
| 3197 | $foo = pack("ccxxcc",65,66,67,68); |
| 3198 | # foo eq "AB\0\0CD" |
| 3199 | |
| 3200 | # note: the above examples featuring "C" and "c" are true |
| 3201 | # only on ASCII and ASCII-derived systems such as ISO Latin 1 |
| 3202 | # and UTF-8. In EBCDIC the first example would be |
| 3203 | # $foo = pack("CCCC",193,194,195,196); |
| 3204 | |
| 3205 | $foo = pack("s2",1,2); |
| 3206 | # "\1\0\2\0" on little-endian |
| 3207 | # "\0\1\0\2" on big-endian |
| 3208 | |
| 3209 | $foo = pack("a4","abcd","x","y","z"); |
| 3210 | # "abcd" |
| 3211 | |
| 3212 | $foo = pack("aaaa","abcd","x","y","z"); |
| 3213 | # "axyz" |
| 3214 | |
| 3215 | $foo = pack("a14","abcdefg"); |
| 3216 | # "abcdefg\0\0\0\0\0\0\0" |
| 3217 | |
| 3218 | $foo = pack("i9pl", gmtime); |
| 3219 | # a real struct tm (on my system anyway) |
| 3220 | |
| 3221 | $utmp_template = "Z8 Z8 Z16 L"; |
| 3222 | $utmp = pack($utmp_template, @utmp1); |
| 3223 | # a struct utmp (BSDish) |
| 3224 | |
| 3225 | @utmp2 = unpack($utmp_template, $utmp); |
| 3226 | # "@utmp1" eq "@utmp2" |
| 3227 | |
| 3228 | sub bintodec { |
| 3229 | unpack("N", pack("B32", substr("0" x 32 . shift, -32))); |
| 3230 | } |
| 3231 | |
| 3232 | $foo = pack('sx2l', 12, 34); |
| 3233 | # short 12, two zero bytes padding, long 34 |
| 3234 | $bar = pack('s@4l', 12, 34); |
| 3235 | # short 12, zero fill to position 4, long 34 |
| 3236 | # $foo eq $bar |
| 3237 | |
| 3238 | The same template may generally also be used in unpack(). |
| 3239 | |
| 3240 | =item package |
| 3241 | |
| 3242 | =item package NAMESPACE |
| 3243 | |
| 3244 | Declares the compilation unit as being in the given namespace. The scope |
| 3245 | of the package declaration is from the declaration itself through the end |
| 3246 | of the enclosing block, file, or eval (the same as the C<my> operator). |
| 3247 | All further unqualified dynamic identifiers will be in this namespace. |
| 3248 | A package statement affects only dynamic variables--including those |
| 3249 | you've used C<local> on--but I<not> lexical variables, which are created |
| 3250 | with C<my>. Typically it would be the first declaration in a file to |
| 3251 | be included by the C<require> or C<use> operator. You can switch into a |
| 3252 | package in more than one place; it merely influences which symbol table |
| 3253 | is used by the compiler for the rest of that block. You can refer to |
| 3254 | variables and filehandles in other packages by prefixing the identifier |
| 3255 | with the package name and a double colon: C<$Package::Variable>. |
| 3256 | If the package name is null, the C<main> package as assumed. That is, |
| 3257 | C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>, |
| 3258 | still seen in older code). |
| 3259 | |
| 3260 | If NAMESPACE is omitted, then there is no current package, and all |
| 3261 | identifiers must be fully qualified or lexicals. This is stricter |
| 3262 | than C<use strict>, since it also extends to function names. |
| 3263 | |
| 3264 | See L<perlmod/"Packages"> for more information about packages, modules, |
| 3265 | and classes. See L<perlsub> for other scoping issues. |
| 3266 | |
| 3267 | =item pipe READHANDLE,WRITEHANDLE |
| 3268 | |
| 3269 | Opens a pair of connected pipes like the corresponding system call. |
| 3270 | Note that if you set up a loop of piped processes, deadlock can occur |
| 3271 | unless you are very careful. In addition, note that Perl's pipes use |
| 3272 | stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE |
| 3273 | after each command, depending on the application. |
| 3274 | |
| 3275 | See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication"> |
| 3276 | for examples of such things. |
| 3277 | |
| 3278 | On systems that support a close-on-exec flag on files, the flag will be set |
| 3279 | for the newly opened file descriptors as determined by the value of $^F. |
| 3280 | See L<perlvar/$^F>. |
| 3281 | |
| 3282 | =item pop ARRAY |
| 3283 | |
| 3284 | =item pop |
| 3285 | |
| 3286 | Pops and returns the last value of the array, shortening the array by |
| 3287 | one element. Has an effect similar to |
| 3288 | |
| 3289 | $ARRAY[$#ARRAY--] |
| 3290 | |
| 3291 | If there are no elements in the array, returns the undefined value |
| 3292 | (although this may happen at other times as well). If ARRAY is |
| 3293 | omitted, pops the C<@ARGV> array in the main program, and the C<@_> |
| 3294 | array in subroutines, just like C<shift>. |
| 3295 | |
| 3296 | =item pos SCALAR |
| 3297 | |
| 3298 | =item pos |
| 3299 | |
| 3300 | Returns the offset of where the last C<m//g> search left off for the variable |
| 3301 | is in question (C<$_> is used when the variable is not specified). May be |
| 3302 | modified to change that offset. Such modification will also influence |
| 3303 | the C<\G> zero-width assertion in regular expressions. See L<perlre> and |
| 3304 | L<perlop>. |
| 3305 | |
| 3306 | =item print FILEHANDLE LIST |
| 3307 | |
| 3308 | =item print LIST |
| 3309 | |
| 3310 | =item print |
| 3311 | |
| 3312 | Prints a string or a list of strings. Returns true if successful. |
| 3313 | FILEHANDLE may be a scalar variable name, in which case the variable |
| 3314 | contains the name of or a reference to the filehandle, thus introducing |
| 3315 | one level of indirection. (NOTE: If FILEHANDLE is a variable and |
| 3316 | the next token is a term, it may be misinterpreted as an operator |
| 3317 | unless you interpose a C<+> or put parentheses around the arguments.) |
| 3318 | If FILEHANDLE is omitted, prints by default to standard output (or |
| 3319 | to the last selected output channel--see L</select>). If LIST is |
| 3320 | also omitted, prints C<$_> to the currently selected output channel. |
| 3321 | To set the default output channel to something other than STDOUT |
| 3322 | use the select operation. The current value of C<$,> (if any) is |
| 3323 | printed between each LIST item. The current value of C<$\> (if |
| 3324 | any) is printed after the entire LIST has been printed. Because |
| 3325 | print takes a LIST, anything in the LIST is evaluated in list |
| 3326 | context, and any subroutine that you call will have one or more of |
| 3327 | its expressions evaluated in list context. Also be careful not to |
| 3328 | follow the print keyword with a left parenthesis unless you want |
| 3329 | the corresponding right parenthesis to terminate the arguments to |
| 3330 | the print--interpose a C<+> or put parentheses around all the |
| 3331 | arguments. |
| 3332 | |
| 3333 | Note that if you're storing FILEHANDLES in an array or other expression, |
| 3334 | you will have to use a block returning its value instead: |
| 3335 | |
| 3336 | print { $files[$i] } "stuff\n"; |
| 3337 | print { $OK ? STDOUT : STDERR } "stuff\n"; |
| 3338 | |
| 3339 | =item printf FILEHANDLE FORMAT, LIST |
| 3340 | |
| 3341 | =item printf FORMAT, LIST |
| 3342 | |
| 3343 | Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\> |
| 3344 | (the output record separator) is not appended. The first argument |
| 3345 | of the list will be interpreted as the C<printf> format. If C<use locale> is |
| 3346 | in effect, the character used for the decimal point in formatted real numbers |
| 3347 | is affected by the LC_NUMERIC locale. See L<perllocale>. |
| 3348 | |
| 3349 | Don't fall into the trap of using a C<printf> when a simple |
| 3350 | C<print> would do. The C<print> is more efficient and less |
| 3351 | error prone. |
| 3352 | |
| 3353 | =item prototype FUNCTION |
| 3354 | |
| 3355 | Returns the prototype of a function as a string (or C<undef> if the |
| 3356 | function has no prototype). FUNCTION is a reference to, or the name of, |
| 3357 | the function whose prototype you want to retrieve. |
| 3358 | |
| 3359 | If FUNCTION is a string starting with C<CORE::>, the rest is taken as a |
| 3360 | name for Perl builtin. If the builtin is not I<overridable> (such as |
| 3361 | C<qw//>) or its arguments cannot be expressed by a prototype (such as |
| 3362 | C<system>) returns C<undef> because the builtin does not really behave |
| 3363 | like a Perl function. Otherwise, the string describing the equivalent |
| 3364 | prototype is returned. |
| 3365 | |
| 3366 | =item push ARRAY,LIST |
| 3367 | |
| 3368 | Treats ARRAY as a stack, and pushes the values of LIST |
| 3369 | onto the end of ARRAY. The length of ARRAY increases by the length of |
| 3370 | LIST. Has the same effect as |
| 3371 | |
| 3372 | for $value (LIST) { |
| 3373 | $ARRAY[++$#ARRAY] = $value; |
| 3374 | } |
| 3375 | |
| 3376 | but is more efficient. Returns the new number of elements in the array. |
| 3377 | |
| 3378 | =item q/STRING/ |
| 3379 | |
| 3380 | =item qq/STRING/ |
| 3381 | |
| 3382 | =item qr/STRING/ |
| 3383 | |
| 3384 | =item qx/STRING/ |
| 3385 | |
| 3386 | =item qw/STRING/ |
| 3387 | |
| 3388 | Generalized quotes. See L<perlop/"Regexp Quote-Like Operators">. |
| 3389 | |
| 3390 | =item quotemeta EXPR |
| 3391 | |
| 3392 | =item quotemeta |
| 3393 | |
| 3394 | Returns the value of EXPR with all non-alphanumeric |
| 3395 | characters backslashed. (That is, all characters not matching |
| 3396 | C</[A-Za-z_0-9]/> will be preceded by a backslash in the |
| 3397 | returned string, regardless of any locale settings.) |
| 3398 | This is the internal function implementing |
| 3399 | the C<\Q> escape in double-quoted strings. |
| 3400 | |
| 3401 | If EXPR is omitted, uses C<$_>. |
| 3402 | |
| 3403 | =item rand EXPR |
| 3404 | |
| 3405 | =item rand |
| 3406 | |
| 3407 | Returns a random fractional number greater than or equal to C<0> and less |
| 3408 | than the value of EXPR. (EXPR should be positive.) If EXPR is |
| 3409 | omitted, the value C<1> is used. Automatically calls C<srand> unless |
| 3410 | C<srand> has already been called. See also C<srand>. |
| 3411 | |
| 3412 | (Note: If your rand function consistently returns numbers that are too |
| 3413 | large or too small, then your version of Perl was probably compiled |
| 3414 | with the wrong number of RANDBITS.) |
| 3415 | |
| 3416 | =item read FILEHANDLE,SCALAR,LENGTH,OFFSET |
| 3417 | |
| 3418 | =item read FILEHANDLE,SCALAR,LENGTH |
| 3419 | |
| 3420 | Attempts to read LENGTH bytes of data into variable SCALAR from the |
| 3421 | specified FILEHANDLE. Returns the number of bytes actually read, |
| 3422 | C<0> at end of file, or undef if there was an error. SCALAR will be grown |
| 3423 | or shrunk to the length actually read. An OFFSET may be specified to |
| 3424 | place the read data at some other place than the beginning of the |
| 3425 | string. This call is actually implemented in terms of stdio's fread(3) |
| 3426 | call. To get a true read(2) system call, see C<sysread>. |
| 3427 | |
| 3428 | =item readdir DIRHANDLE |
| 3429 | |
| 3430 | Returns the next directory entry for a directory opened by C<opendir>. |
| 3431 | If used in list context, returns all the rest of the entries in the |
| 3432 | directory. If there are no more entries, returns an undefined value in |
| 3433 | scalar context or a null list in list context. |
| 3434 | |
| 3435 | If you're planning to filetest the return values out of a C<readdir>, you'd |
| 3436 | better prepend the directory in question. Otherwise, because we didn't |
| 3437 | C<chdir> there, it would have been testing the wrong file. |
| 3438 | |
| 3439 | opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!"; |
| 3440 | @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR); |
| 3441 | closedir DIR; |
| 3442 | |
| 3443 | =item readline EXPR |
| 3444 | |
| 3445 | Reads from the filehandle whose typeglob is contained in EXPR. In scalar |
| 3446 | context, each call reads and returns the next line, until end-of-file is |
| 3447 | reached, whereupon the subsequent call returns undef. In list context, |
| 3448 | reads until end-of-file is reached and returns a list of lines. Note that |
| 3449 | the notion of "line" used here is however you may have defined it |
| 3450 | with C<$/> or C<$INPUT_RECORD_SEPARATOR>). See L<perlvar/"$/">. |
| 3451 | |
| 3452 | When C<$/> is set to C<undef>, when readline() is in scalar |
| 3453 | context (i.e. file slurp mode), and when an empty file is read, it |
| 3454 | returns C<''> the first time, followed by C<undef> subsequently. |
| 3455 | |
| 3456 | This is the internal function implementing the C<< <EXPR> >> |
| 3457 | operator, but you can use it directly. The C<< <EXPR> >> |
| 3458 | operator is discussed in more detail in L<perlop/"I/O Operators">. |
| 3459 | |
| 3460 | $line = <STDIN>; |
| 3461 | $line = readline(*STDIN); # same thing |
| 3462 | |
| 3463 | =item readlink EXPR |
| 3464 | |
| 3465 | =item readlink |
| 3466 | |
| 3467 | Returns the value of a symbolic link, if symbolic links are |
| 3468 | implemented. If not, gives a fatal error. If there is some system |
| 3469 | error, returns the undefined value and sets C<$!> (errno). If EXPR is |
| 3470 | omitted, uses C<$_>. |
| 3471 | |
| 3472 | =item readpipe EXPR |
| 3473 | |
| 3474 | EXPR is executed as a system command. |
| 3475 | The collected standard output of the command is returned. |
| 3476 | In scalar context, it comes back as a single (potentially |
| 3477 | multi-line) string. In list context, returns a list of lines |
| 3478 | (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>). |
| 3479 | This is the internal function implementing the C<qx/EXPR/> |
| 3480 | operator, but you can use it directly. The C<qx/EXPR/> |
| 3481 | operator is discussed in more detail in L<perlop/"I/O Operators">. |
| 3482 | |
| 3483 | =item recv SOCKET,SCALAR,LENGTH,FLAGS |
| 3484 | |
| 3485 | Receives a message on a socket. Attempts to receive LENGTH bytes of |
| 3486 | data into variable SCALAR from the specified SOCKET filehandle. SCALAR |
| 3487 | will be grown or shrunk to the length actually read. Takes the same |
| 3488 | flags as the system call of the same name. Returns the address of the |
| 3489 | sender if SOCKET's protocol supports this; returns an empty string |
| 3490 | otherwise. If there's an error, returns the undefined value. This call |
| 3491 | is actually implemented in terms of recvfrom(2) system call. See |
| 3492 | L<perlipc/"UDP: Message Passing"> for examples. |
| 3493 | |
| 3494 | =item redo LABEL |
| 3495 | |
| 3496 | =item redo |
| 3497 | |
| 3498 | The C<redo> command restarts the loop block without evaluating the |
| 3499 | conditional again. The C<continue> block, if any, is not executed. If |
| 3500 | the LABEL is omitted, the command refers to the innermost enclosing |
| 3501 | loop. This command is normally used by programs that want to lie to |
| 3502 | themselves about what was just input: |
| 3503 | |
| 3504 | # a simpleminded Pascal comment stripper |
| 3505 | # (warning: assumes no { or } in strings) |
| 3506 | LINE: while (<STDIN>) { |
| 3507 | while (s|({.*}.*){.*}|$1 |) {} |
| 3508 | s|{.*}| |; |
| 3509 | if (s|{.*| |) { |
| 3510 | $front = $_; |
| 3511 | while (<STDIN>) { |
| 3512 | if (/}/) { # end of comment? |
| 3513 | s|^|$front\{|; |
| 3514 | redo LINE; |
| 3515 | } |
| 3516 | } |
| 3517 | } |
| 3518 | print; |
| 3519 | } |
| 3520 | |
| 3521 | C<redo> cannot be used to retry a block which returns a value such as |
| 3522 | C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit |
| 3523 | a grep() or map() operation. |
| 3524 | |
| 3525 | Note that a block by itself is semantically identical to a loop |
| 3526 | that executes once. Thus C<redo> inside such a block will effectively |
| 3527 | turn it into a looping construct. |
| 3528 | |
| 3529 | See also L</continue> for an illustration of how C<last>, C<next>, and |
| 3530 | C<redo> work. |
| 3531 | |
| 3532 | =item ref EXPR |
| 3533 | |
| 3534 | =item ref |
| 3535 | |
| 3536 | Returns a true value if EXPR is a reference, false otherwise. If EXPR |
| 3537 | is not specified, C<$_> will be used. The value returned depends on the |
| 3538 | type of thing the reference is a reference to. |
| 3539 | Builtin types include: |
| 3540 | |
| 3541 | SCALAR |
| 3542 | ARRAY |
| 3543 | HASH |
| 3544 | CODE |
| 3545 | REF |
| 3546 | GLOB |
| 3547 | LVALUE |
| 3548 | |
| 3549 | If the referenced object has been blessed into a package, then that package |
| 3550 | name is returned instead. You can think of C<ref> as a C<typeof> operator. |
| 3551 | |
| 3552 | if (ref($r) eq "HASH") { |
| 3553 | print "r is a reference to a hash.\n"; |
| 3554 | } |
| 3555 | unless (ref($r)) { |
| 3556 | print "r is not a reference at all.\n"; |
| 3557 | } |
| 3558 | if (UNIVERSAL::isa($r, "HASH")) { # for subclassing |
| 3559 | print "r is a reference to something that isa hash.\n"; |
| 3560 | } |
| 3561 | |
| 3562 | See also L<perlref>. |
| 3563 | |
| 3564 | =item rename OLDNAME,NEWNAME |
| 3565 | |
| 3566 | Changes the name of a file; an existing file NEWNAME will be |
| 3567 | clobbered. Returns true for success, false otherwise. |
| 3568 | |
| 3569 | Behavior of this function varies wildly depending on your system |
| 3570 | implementation. For example, it will usually not work across file system |
| 3571 | boundaries, even though the system I<mv> command sometimes compensates |
| 3572 | for this. Other restrictions include whether it works on directories, |
| 3573 | open files, or pre-existing files. Check L<perlport> and either the |
| 3574 | rename(2) manpage or equivalent system documentation for details. |
| 3575 | |
| 3576 | =item require VERSION |
| 3577 | |
| 3578 | =item require EXPR |
| 3579 | |
| 3580 | =item require |
| 3581 | |
| 3582 | Demands some semantics specified by EXPR, or by C<$_> if EXPR is not |
| 3583 | supplied. |
| 3584 | |
| 3585 | If a VERSION is specified as a literal of the form v5.6.1, |
| 3586 | demands that the current version of Perl (C<$^V> or $PERL_VERSION) be |
| 3587 | at least as recent as that version, at run time. (For compatibility |
| 3588 | with older versions of Perl, a numeric argument will also be interpreted |
| 3589 | as VERSION.) Compare with L</use>, which can do a similar check at |
| 3590 | compile time. |
| 3591 | |
| 3592 | require v5.6.1; # run time version check |
| 3593 | require 5.6.1; # ditto |
| 3594 | require 5.005_03; # float version allowed for compatibility |
| 3595 | |
| 3596 | Otherwise, demands that a library file be included if it hasn't already |
| 3597 | been included. The file is included via the do-FILE mechanism, which is |
| 3598 | essentially just a variety of C<eval>. Has semantics similar to the following |
| 3599 | subroutine: |
| 3600 | |
| 3601 | sub require { |
| 3602 | my($filename) = @_; |
| 3603 | return 1 if $INC{$filename}; |
| 3604 | my($realfilename,$result); |
| 3605 | ITER: { |
| 3606 | foreach $prefix (@INC) { |
| 3607 | $realfilename = "$prefix/$filename"; |
| 3608 | if (-f $realfilename) { |
| 3609 | $INC{$filename} = $realfilename; |
| 3610 | $result = do $realfilename; |
| 3611 | last ITER; |
| 3612 | } |
| 3613 | } |
| 3614 | die "Can't find $filename in \@INC"; |
| 3615 | } |
| 3616 | delete $INC{$filename} if $@ || !$result; |
| 3617 | die $@ if $@; |
| 3618 | die "$filename did not return true value" unless $result; |
| 3619 | return $result; |
| 3620 | } |
| 3621 | |
| 3622 | Note that the file will not be included twice under the same specified |
| 3623 | name. The file must return true as the last statement to indicate |
| 3624 | successful execution of any initialization code, so it's customary to |
| 3625 | end such a file with C<1;> unless you're sure it'll return true |
| 3626 | otherwise. But it's better just to put the C<1;>, in case you add more |
| 3627 | statements. |
| 3628 | |
| 3629 | If EXPR is a bareword, the require assumes a "F<.pm>" extension and |
| 3630 | replaces "F<::>" with "F</>" in the filename for you, |
| 3631 | to make it easy to load standard modules. This form of loading of |
| 3632 | modules does not risk altering your namespace. |
| 3633 | |
| 3634 | In other words, if you try this: |
| 3635 | |
| 3636 | require Foo::Bar; # a splendid bareword |
| 3637 | |
| 3638 | The require function will actually look for the "F<Foo/Bar.pm>" file in the |
| 3639 | directories specified in the C<@INC> array. |
| 3640 | |
| 3641 | But if you try this: |
| 3642 | |
| 3643 | $class = 'Foo::Bar'; |
| 3644 | require $class; # $class is not a bareword |
| 3645 | #or |
| 3646 | require "Foo::Bar"; # not a bareword because of the "" |
| 3647 | |
| 3648 | The require function will look for the "F<Foo::Bar>" file in the @INC array and |
| 3649 | will complain about not finding "F<Foo::Bar>" there. In this case you can do: |
| 3650 | |
| 3651 | eval "require $class"; |
| 3652 | |
| 3653 | For a yet-more-powerful import facility, see L</use> and L<perlmod>. |
| 3654 | |
| 3655 | =item reset EXPR |
| 3656 | |
| 3657 | =item reset |
| 3658 | |
| 3659 | Generally used in a C<continue> block at the end of a loop to clear |
| 3660 | variables and reset C<??> searches so that they work again. The |
| 3661 | expression is interpreted as a list of single characters (hyphens |
| 3662 | allowed for ranges). All variables and arrays beginning with one of |
| 3663 | those letters are reset to their pristine state. If the expression is |
| 3664 | omitted, one-match searches (C<?pattern?>) are reset to match again. Resets |
| 3665 | only variables or searches in the current package. Always returns |
| 3666 | 1. Examples: |
| 3667 | |
| 3668 | reset 'X'; # reset all X variables |
| 3669 | reset 'a-z'; # reset lower case variables |
| 3670 | reset; # just reset ?one-time? searches |
| 3671 | |
| 3672 | Resetting C<"A-Z"> is not recommended because you'll wipe out your |
| 3673 | C<@ARGV> and C<@INC> arrays and your C<%ENV> hash. Resets only package |
| 3674 | variables--lexical variables are unaffected, but they clean themselves |
| 3675 | up on scope exit anyway, so you'll probably want to use them instead. |
| 3676 | See L</my>. |
| 3677 | |
| 3678 | =item return EXPR |
| 3679 | |
| 3680 | =item return |
| 3681 | |
| 3682 | Returns from a subroutine, C<eval>, or C<do FILE> with the value |
| 3683 | given in EXPR. Evaluation of EXPR may be in list, scalar, or void |
| 3684 | context, depending on how the return value will be used, and the context |
| 3685 | may vary from one execution to the next (see C<wantarray>). If no EXPR |
| 3686 | is given, returns an empty list in list context, the undefined value in |
| 3687 | scalar context, and (of course) nothing at all in a void context. |
| 3688 | |
| 3689 | (Note that in the absence of a explicit C<return>, a subroutine, eval, |
| 3690 | or do FILE will automatically return the value of the last expression |
| 3691 | evaluated.) |
| 3692 | |
| 3693 | =item reverse LIST |
| 3694 | |
| 3695 | In list context, returns a list value consisting of the elements |
| 3696 | of LIST in the opposite order. In scalar context, concatenates the |
| 3697 | elements of LIST and returns a string value with all characters |
| 3698 | in the opposite order. |
| 3699 | |
| 3700 | print reverse <>; # line tac, last line first |
| 3701 | |
| 3702 | undef $/; # for efficiency of <> |
| 3703 | print scalar reverse <>; # character tac, last line tsrif |
| 3704 | |
| 3705 | This operator is also handy for inverting a hash, although there are some |
| 3706 | caveats. If a value is duplicated in the original hash, only one of those |
| 3707 | can be represented as a key in the inverted hash. Also, this has to |
| 3708 | unwind one hash and build a whole new one, which may take some time |
| 3709 | on a large hash, such as from a DBM file. |
| 3710 | |
| 3711 | %by_name = reverse %by_address; # Invert the hash |
| 3712 | |
| 3713 | =item rewinddir DIRHANDLE |
| 3714 | |
| 3715 | Sets the current position to the beginning of the directory for the |
| 3716 | C<readdir> routine on DIRHANDLE. |
| 3717 | |
| 3718 | =item rindex STR,SUBSTR,POSITION |
| 3719 | |
| 3720 | =item rindex STR,SUBSTR |
| 3721 | |
| 3722 | Works just like index() except that it returns the position of the LAST |
| 3723 | occurrence of SUBSTR in STR. If POSITION is specified, returns the |
| 3724 | last occurrence at or before that position. |
| 3725 | |
| 3726 | =item rmdir FILENAME |
| 3727 | |
| 3728 | =item rmdir |
| 3729 | |
| 3730 | Deletes the directory specified by FILENAME if that directory is empty. If it |
| 3731 | succeeds it returns true, otherwise it returns false and sets C<$!> (errno). If |
| 3732 | FILENAME is omitted, uses C<$_>. |
| 3733 | |
| 3734 | =item s/// |
| 3735 | |
| 3736 | The substitution operator. See L<perlop>. |
| 3737 | |
| 3738 | =item scalar EXPR |
| 3739 | |
| 3740 | Forces EXPR to be interpreted in scalar context and returns the value |
| 3741 | of EXPR. |
| 3742 | |
| 3743 | @counts = ( scalar @a, scalar @b, scalar @c ); |
| 3744 | |
| 3745 | There is no equivalent operator to force an expression to |
| 3746 | be interpolated in list context because in practice, this is never |
| 3747 | needed. If you really wanted to do so, however, you could use |
| 3748 | the construction C<@{[ (some expression) ]}>, but usually a simple |
| 3749 | C<(some expression)> suffices. |
| 3750 | |
| 3751 | Because C<scalar> is unary operator, if you accidentally use for EXPR a |
| 3752 | parenthesized list, this behaves as a scalar comma expression, evaluating |
| 3753 | all but the last element in void context and returning the final element |
| 3754 | evaluated in scalar context. This is seldom what you want. |
| 3755 | |
| 3756 | The following single statement: |
| 3757 | |
| 3758 | print uc(scalar(&foo,$bar)),$baz; |
| 3759 | |
| 3760 | is the moral equivalent of these two: |
| 3761 | |
| 3762 | &foo; |
| 3763 | print(uc($bar),$baz); |
| 3764 | |
| 3765 | See L<perlop> for more details on unary operators and the comma operator. |
| 3766 | |
| 3767 | =item seek FILEHANDLE,POSITION,WHENCE |
| 3768 | |
| 3769 | Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>. |
| 3770 | FILEHANDLE may be an expression whose value gives the name of the |
| 3771 | filehandle. The values for WHENCE are C<0> to set the new position to |
| 3772 | POSITION, C<1> to set it to the current position plus POSITION, and |
| 3773 | C<2> to set it to EOF plus POSITION (typically negative). For WHENCE |
| 3774 | you may use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END> |
| 3775 | (start of the file, current position, end of the file) from the Fcntl |
| 3776 | module. Returns C<1> upon success, C<0> otherwise. |
| 3777 | |
| 3778 | If you want to position file for C<sysread> or C<syswrite>, don't use |
| 3779 | C<seek>--buffering makes its effect on the file's system position |
| 3780 | unpredictable and non-portable. Use C<sysseek> instead. |
| 3781 | |
| 3782 | Due to the rules and rigors of ANSI C, on some systems you have to do a |
| 3783 | seek whenever you switch between reading and writing. Amongst other |
| 3784 | things, this may have the effect of calling stdio's clearerr(3). |
| 3785 | A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position: |
| 3786 | |
| 3787 | seek(TEST,0,1); |
| 3788 | |
| 3789 | This is also useful for applications emulating C<tail -f>. Once you hit |
| 3790 | EOF on your read, and then sleep for a while, you might have to stick in a |
| 3791 | seek() to reset things. The C<seek> doesn't change the current position, |
| 3792 | but it I<does> clear the end-of-file condition on the handle, so that the |
| 3793 | next C<< <FILE> >> makes Perl try again to read something. We hope. |
| 3794 | |
| 3795 | If that doesn't work (some stdios are particularly cantankerous), then |
| 3796 | you may need something more like this: |
| 3797 | |
| 3798 | for (;;) { |
| 3799 | for ($curpos = tell(FILE); $_ = <FILE>; |
| 3800 | $curpos = tell(FILE)) { |
| 3801 | # search for some stuff and put it into files |
| 3802 | } |
| 3803 | sleep($for_a_while); |
| 3804 | seek(FILE, $curpos, 0); |
| 3805 | } |
| 3806 | |
| 3807 | =item seekdir DIRHANDLE,POS |
| 3808 | |
| 3809 | Sets the current position for the C<readdir> routine on DIRHANDLE. POS |
| 3810 | must be a value returned by C<telldir>. Has the same caveats about |
| 3811 | possible directory compaction as the corresponding system library |
| 3812 | routine. |
| 3813 | |
| 3814 | =item select FILEHANDLE |
| 3815 | |
| 3816 | =item select |
| 3817 | |
| 3818 | Returns the currently selected filehandle. Sets the current default |
| 3819 | filehandle for output, if FILEHANDLE is supplied. This has two |
| 3820 | effects: first, a C<write> or a C<print> without a filehandle will |
| 3821 | default to this FILEHANDLE. Second, references to variables related to |
| 3822 | output will refer to this output channel. For example, if you have to |
| 3823 | set the top of form format for more than one output channel, you might |
| 3824 | do the following: |
| 3825 | |
| 3826 | select(REPORT1); |
| 3827 | $^ = 'report1_top'; |
| 3828 | select(REPORT2); |
| 3829 | $^ = 'report2_top'; |
| 3830 | |
| 3831 | FILEHANDLE may be an expression whose value gives the name of the |
| 3832 | actual filehandle. Thus: |
| 3833 | |
| 3834 | $oldfh = select(STDERR); $| = 1; select($oldfh); |
| 3835 | |
| 3836 | Some programmers may prefer to think of filehandles as objects with |
| 3837 | methods, preferring to write the last example as: |
| 3838 | |
| 3839 | use IO::Handle; |
| 3840 | STDERR->autoflush(1); |
| 3841 | |
| 3842 | =item select RBITS,WBITS,EBITS,TIMEOUT |
| 3843 | |
| 3844 | This calls the select(2) system call with the bit masks specified, which |
| 3845 | can be constructed using C<fileno> and C<vec>, along these lines: |
| 3846 | |
| 3847 | $rin = $win = $ein = ''; |
| 3848 | vec($rin,fileno(STDIN),1) = 1; |
| 3849 | vec($win,fileno(STDOUT),1) = 1; |
| 3850 | $ein = $rin | $win; |
| 3851 | |
| 3852 | If you want to select on many filehandles you might wish to write a |
| 3853 | subroutine: |
| 3854 | |
| 3855 | sub fhbits { |
| 3856 | my(@fhlist) = split(' ',$_[0]); |
| 3857 | my($bits); |
| 3858 | for (@fhlist) { |
| 3859 | vec($bits,fileno($_),1) = 1; |
| 3860 | } |
| 3861 | $bits; |
| 3862 | } |
| 3863 | $rin = fhbits('STDIN TTY SOCK'); |
| 3864 | |
| 3865 | The usual idiom is: |
| 3866 | |
| 3867 | ($nfound,$timeleft) = |
| 3868 | select($rout=$rin, $wout=$win, $eout=$ein, $timeout); |
| 3869 | |
| 3870 | or to block until something becomes ready just do this |
| 3871 | |
| 3872 | $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef); |
| 3873 | |
| 3874 | Most systems do not bother to return anything useful in $timeleft, so |
| 3875 | calling select() in scalar context just returns $nfound. |
| 3876 | |
| 3877 | Any of the bit masks can also be undef. The timeout, if specified, is |
| 3878 | in seconds, which may be fractional. Note: not all implementations are |
| 3879 | capable of returning the$timeleft. If not, they always return |
| 3880 | $timeleft equal to the supplied $timeout. |
| 3881 | |
| 3882 | You can effect a sleep of 250 milliseconds this way: |
| 3883 | |
| 3884 | select(undef, undef, undef, 0.25); |
| 3885 | |
| 3886 | B<WARNING>: One should not attempt to mix buffered I/O (like C<read> |
| 3887 | or <FH>) with C<select>, except as permitted by POSIX, and even |
| 3888 | then only on POSIX systems. You have to use C<sysread> instead. |
| 3889 | |
| 3890 | =item semctl ID,SEMNUM,CMD,ARG |
| 3891 | |
| 3892 | Calls the System V IPC function C<semctl>. You'll probably have to say |
| 3893 | |
| 3894 | use IPC::SysV; |
| 3895 | |
| 3896 | first to get the correct constant definitions. If CMD is IPC_STAT or |
| 3897 | GETALL, then ARG must be a variable which will hold the returned |
| 3898 | semid_ds structure or semaphore value array. Returns like C<ioctl>: |
| 3899 | the undefined value for error, "C<0 but true>" for zero, or the actual |
| 3900 | return value otherwise. The ARG must consist of a vector of native |
| 3901 | short integers, which may may be created with C<pack("s!",(0)x$nsem)>. |
| 3902 | See also C<IPC::SysV> and C<IPC::Semaphore> documentation. |
| 3903 | |
| 3904 | =item semget KEY,NSEMS,FLAGS |
| 3905 | |
| 3906 | Calls the System V IPC function semget. Returns the semaphore id, or |
| 3907 | the undefined value if there is an error. See also C<IPC::SysV> and |
| 3908 | C<IPC::SysV::Semaphore> documentation. |
| 3909 | |
| 3910 | =item semop KEY,OPSTRING |
| 3911 | |
| 3912 | Calls the System V IPC function semop to perform semaphore operations |
| 3913 | such as signaling and waiting. OPSTRING must be a packed array of |
| 3914 | semop structures. Each semop structure can be generated with |
| 3915 | C<pack("sss", $semnum, $semop, $semflag)>. The number of semaphore |
| 3916 | operations is implied by the length of OPSTRING. Returns true if |
| 3917 | successful, or false if there is an error. As an example, the |
| 3918 | following code waits on semaphore $semnum of semaphore id $semid: |
| 3919 | |
| 3920 | $semop = pack("sss", $semnum, -1, 0); |
| 3921 | die "Semaphore trouble: $!\n" unless semop($semid, $semop); |
| 3922 | |
| 3923 | To signal the semaphore, replace C<-1> with C<1>. See also C<IPC::SysV> |
| 3924 | and C<IPC::SysV::Semaphore> documentation. |
| 3925 | |
| 3926 | =item send SOCKET,MSG,FLAGS,TO |
| 3927 | |
| 3928 | =item send SOCKET,MSG,FLAGS |
| 3929 | |
| 3930 | Sends a message on a socket. Takes the same flags as the system call |
| 3931 | of the same name. On unconnected sockets you must specify a |
| 3932 | destination to send TO, in which case it does a C C<sendto>. Returns |
| 3933 | the number of characters sent, or the undefined value if there is an |
| 3934 | error. The C system call sendmsg(2) is currently unimplemented. |
| 3935 | See L<perlipc/"UDP: Message Passing"> for examples. |
| 3936 | |
| 3937 | =item setpgrp PID,PGRP |
| 3938 | |
| 3939 | Sets the current process group for the specified PID, C<0> for the current |
| 3940 | process. Will produce a fatal error if used on a machine that doesn't |
| 3941 | implement POSIX setpgid(2) or BSD setpgrp(2). If the arguments are omitted, |
| 3942 | it defaults to C<0,0>. Note that the BSD 4.2 version of C<setpgrp> does not |
| 3943 | accept any arguments, so only C<setpgrp(0,0)> is portable. See also |
| 3944 | C<POSIX::setsid()>. |
| 3945 | |
| 3946 | =item setpriority WHICH,WHO,PRIORITY |
| 3947 | |
| 3948 | Sets the current priority for a process, a process group, or a user. |
| 3949 | (See setpriority(2).) Will produce a fatal error if used on a machine |
| 3950 | that doesn't implement setpriority(2). |
| 3951 | |
| 3952 | =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL |
| 3953 | |
| 3954 | Sets the socket option requested. Returns undefined if there is an |
| 3955 | error. OPTVAL may be specified as C<undef> if you don't want to pass an |
| 3956 | argument. |
| 3957 | |
| 3958 | =item shift ARRAY |
| 3959 | |
| 3960 | =item shift |
| 3961 | |
| 3962 | Shifts the first value of the array off and returns it, shortening the |
| 3963 | array by 1 and moving everything down. If there are no elements in the |
| 3964 | array, returns the undefined value. If ARRAY is omitted, shifts the |
| 3965 | C<@_> array within the lexical scope of subroutines and formats, and the |
| 3966 | C<@ARGV> array at file scopes or within the lexical scopes established by |
| 3967 | the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}> |
| 3968 | constructs. |
| 3969 | |
| 3970 | See also C<unshift>, C<push>, and C<pop>. C<Shift()> and C<unshift> do the |
| 3971 | same thing to the left end of an array that C<pop> and C<push> do to the |
| 3972 | right end. |
| 3973 | |
| 3974 | =item shmctl ID,CMD,ARG |
| 3975 | |
| 3976 | Calls the System V IPC function shmctl. You'll probably have to say |
| 3977 | |
| 3978 | use IPC::SysV; |
| 3979 | |
| 3980 | first to get the correct constant definitions. If CMD is C<IPC_STAT>, |
| 3981 | then ARG must be a variable which will hold the returned C<shmid_ds> |
| 3982 | structure. Returns like ioctl: the undefined value for error, "C<0> but |
| 3983 | true" for zero, or the actual return value otherwise. |
| 3984 | See also C<IPC::SysV> documentation. |
| 3985 | |
| 3986 | =item shmget KEY,SIZE,FLAGS |
| 3987 | |
| 3988 | Calls the System V IPC function shmget. Returns the shared memory |
| 3989 | segment id, or the undefined value if there is an error. |
| 3990 | See also C<IPC::SysV> documentation. |
| 3991 | |
| 3992 | =item shmread ID,VAR,POS,SIZE |
| 3993 | |
| 3994 | =item shmwrite ID,STRING,POS,SIZE |
| 3995 | |
| 3996 | Reads or writes the System V shared memory segment ID starting at |
| 3997 | position POS for size SIZE by attaching to it, copying in/out, and |
| 3998 | detaching from it. When reading, VAR must be a variable that will |
| 3999 | hold the data read. When writing, if STRING is too long, only SIZE |
| 4000 | bytes are used; if STRING is too short, nulls are written to fill out |
| 4001 | SIZE bytes. Return true if successful, or false if there is an error. |
| 4002 | See also C<IPC::SysV> documentation and the C<IPC::Shareable> module |
| 4003 | from CPAN. |
| 4004 | |
| 4005 | =item shutdown SOCKET,HOW |
| 4006 | |
| 4007 | Shuts down a socket connection in the manner indicated by HOW, which |
| 4008 | has the same interpretation as in the system call of the same name. |
| 4009 | |
| 4010 | shutdown(SOCKET, 0); # I/we have stopped reading data |
| 4011 | shutdown(SOCKET, 1); # I/we have stopped writing data |
| 4012 | shutdown(SOCKET, 2); # I/we have stopped using this socket |
| 4013 | |
| 4014 | This is useful with sockets when you want to tell the other |
| 4015 | side you're done writing but not done reading, or vice versa. |
| 4016 | It's also a more insistent form of close because it also |
| 4017 | disables the file descriptor in any forked copies in other |
| 4018 | processes. |
| 4019 | |
| 4020 | =item sin EXPR |
| 4021 | |
| 4022 | =item sin |
| 4023 | |
| 4024 | Returns the sine of EXPR (expressed in radians). If EXPR is omitted, |
| 4025 | returns sine of C<$_>. |
| 4026 | |
| 4027 | For the inverse sine operation, you may use the C<Math::Trig::asin> |
| 4028 | function, or use this relation: |
| 4029 | |
| 4030 | sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) } |
| 4031 | |
| 4032 | =item sleep EXPR |
| 4033 | |
| 4034 | =item sleep |
| 4035 | |
| 4036 | Causes the script to sleep for EXPR seconds, or forever if no EXPR. |
| 4037 | May be interrupted if the process receives a signal such as C<SIGALRM>. |
| 4038 | Returns the number of seconds actually slept. You probably cannot |
| 4039 | mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented |
| 4040 | using C<alarm>. |
| 4041 | |
| 4042 | On some older systems, it may sleep up to a full second less than what |
| 4043 | you requested, depending on how it counts seconds. Most modern systems |
| 4044 | always sleep the full amount. They may appear to sleep longer than that, |
| 4045 | however, because your process might not be scheduled right away in a |
| 4046 | busy multitasking system. |
| 4047 | |
| 4048 | For delays of finer granularity than one second, you may use Perl's |
| 4049 | C<syscall> interface to access setitimer(2) if your system supports |
| 4050 | it, or else see L</select> above. The Time::HiRes module from CPAN |
| 4051 | may also help. |
| 4052 | |
| 4053 | See also the POSIX module's C<sigpause> function. |
| 4054 | |
| 4055 | =item socket SOCKET,DOMAIN,TYPE,PROTOCOL |
| 4056 | |
| 4057 | Opens a socket of the specified kind and attaches it to filehandle |
| 4058 | SOCKET. DOMAIN, TYPE, and PROTOCOL are specified the same as for |
| 4059 | the system call of the same name. You should C<use Socket> first |
| 4060 | to get the proper definitions imported. See the examples in |
| 4061 | L<perlipc/"Sockets: Client/Server Communication">. |
| 4062 | |
| 4063 | On systems that support a close-on-exec flag on files, the flag will |
| 4064 | be set for the newly opened file descriptor, as determined by the |
| 4065 | value of $^F. See L<perlvar/$^F>. |
| 4066 | |
| 4067 | =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL |
| 4068 | |
| 4069 | Creates an unnamed pair of sockets in the specified domain, of the |
| 4070 | specified type. DOMAIN, TYPE, and PROTOCOL are specified the same as |
| 4071 | for the system call of the same name. If unimplemented, yields a fatal |
| 4072 | error. Returns true if successful. |
| 4073 | |
| 4074 | On systems that support a close-on-exec flag on files, the flag will |
| 4075 | be set for the newly opened file descriptors, as determined by the value |
| 4076 | of $^F. See L<perlvar/$^F>. |
| 4077 | |
| 4078 | Some systems defined C<pipe> in terms of C<socketpair>, in which a call |
| 4079 | to C<pipe(Rdr, Wtr)> is essentially: |
| 4080 | |
| 4081 | use Socket; |
| 4082 | socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC); |
| 4083 | shutdown(Rdr, 1); # no more writing for reader |
| 4084 | shutdown(Wtr, 0); # no more reading for writer |
| 4085 | |
| 4086 | See L<perlipc> for an example of socketpair use. |
| 4087 | |
| 4088 | =item sort SUBNAME LIST |
| 4089 | |
| 4090 | =item sort BLOCK LIST |
| 4091 | |
| 4092 | =item sort LIST |
| 4093 | |
| 4094 | Sorts the LIST and returns the sorted list value. If SUBNAME or BLOCK |
| 4095 | is omitted, C<sort>s in standard string comparison order. If SUBNAME is |
| 4096 | specified, it gives the name of a subroutine that returns an integer |
| 4097 | less than, equal to, or greater than C<0>, depending on how the elements |
| 4098 | of the list are to be ordered. (The C<< <=> >> and C<cmp> |
| 4099 | operators are extremely useful in such routines.) SUBNAME may be a |
| 4100 | scalar variable name (unsubscripted), in which case the value provides |
| 4101 | the name of (or a reference to) the actual subroutine to use. In place |
| 4102 | of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort |
| 4103 | subroutine. |
| 4104 | |
| 4105 | If the subroutine's prototype is C<($$)>, the elements to be compared |
| 4106 | are passed by reference in C<@_>, as for a normal subroutine. If not, |
| 4107 | the normal calling code for subroutines is bypassed in the interests of |
| 4108 | efficiency, and the elements to be compared are passed into the subroutine |
| 4109 | as the package global variables $a and $b (see example below). Note that |
| 4110 | in the latter case, it is usually counter-productive to declare $a and |
| 4111 | $b as lexicals. |
| 4112 | |
| 4113 | In either case, the subroutine may not be recursive. The values to be |
| 4114 | compared are always passed by reference, so don't modify them. |
| 4115 | |
| 4116 | You also cannot exit out of the sort block or subroutine using any of the |
| 4117 | loop control operators described in L<perlsyn> or with C<goto>. |
| 4118 | |
| 4119 | When C<use locale> is in effect, C<sort LIST> sorts LIST according to the |
| 4120 | current collation locale. See L<perllocale>. |
| 4121 | |
| 4122 | Examples: |
| 4123 | |
| 4124 | # sort lexically |
| 4125 | @articles = sort @files; |
| 4126 | |
| 4127 | # same thing, but with explicit sort routine |
| 4128 | @articles = sort {$a cmp $b} @files; |
| 4129 | |
| 4130 | # now case-insensitively |
| 4131 | @articles = sort {uc($a) cmp uc($b)} @files; |
| 4132 | |
| 4133 | # same thing in reversed order |
| 4134 | @articles = sort {$b cmp $a} @files; |
| 4135 | |
| 4136 | # sort numerically ascending |
| 4137 | @articles = sort {$a <=> $b} @files; |
| 4138 | |
| 4139 | # sort numerically descending |
| 4140 | @articles = sort {$b <=> $a} @files; |
| 4141 | |
| 4142 | # this sorts the %age hash by value instead of key |
| 4143 | # using an in-line function |
| 4144 | @eldest = sort { $age{$b} <=> $age{$a} } keys %age; |
| 4145 | |
| 4146 | # sort using explicit subroutine name |
| 4147 | sub byage { |
| 4148 | $age{$a} <=> $age{$b}; # presuming numeric |
| 4149 | } |
| 4150 | @sortedclass = sort byage @class; |
| 4151 | |
| 4152 | sub backwards { $b cmp $a } |
| 4153 | @harry = qw(dog cat x Cain Abel); |
| 4154 | @george = qw(gone chased yz Punished Axed); |
| 4155 | print sort @harry; |
| 4156 | # prints AbelCaincatdogx |
| 4157 | print sort backwards @harry; |
| 4158 | # prints xdogcatCainAbel |
| 4159 | print sort @george, 'to', @harry; |
| 4160 | # prints AbelAxedCainPunishedcatchaseddoggonetoxyz |
| 4161 | |
| 4162 | # inefficiently sort by descending numeric compare using |
| 4163 | # the first integer after the first = sign, or the |
| 4164 | # whole record case-insensitively otherwise |
| 4165 | |
| 4166 | @new = sort { |
| 4167 | ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0] |
| 4168 | || |
| 4169 | uc($a) cmp uc($b) |
| 4170 | } @old; |
| 4171 | |
| 4172 | # same thing, but much more efficiently; |
| 4173 | # we'll build auxiliary indices instead |
| 4174 | # for speed |
| 4175 | @nums = @caps = (); |
| 4176 | for (@old) { |
| 4177 | push @nums, /=(\d+)/; |
| 4178 | push @caps, uc($_); |
| 4179 | } |
| 4180 | |
| 4181 | @new = @old[ sort { |
| 4182 | $nums[$b] <=> $nums[$a] |
| 4183 | || |
| 4184 | $caps[$a] cmp $caps[$b] |
| 4185 | } 0..$#old |
| 4186 | ]; |
| 4187 | |
| 4188 | # same thing, but without any temps |
| 4189 | @new = map { $_->[0] } |
| 4190 | sort { $b->[1] <=> $a->[1] |
| 4191 | || |
| 4192 | $a->[2] cmp $b->[2] |
| 4193 | } map { [$_, /=(\d+)/, uc($_)] } @old; |
| 4194 | |
| 4195 | # using a prototype allows you to use any comparison subroutine |
| 4196 | # as a sort subroutine (including other package's subroutines) |
| 4197 | package other; |
| 4198 | sub backwards ($$) { $_[1] cmp $_[0]; } # $a and $b are not set here |
| 4199 | |
| 4200 | package main; |
| 4201 | @new = sort other::backwards @old; |
| 4202 | |
| 4203 | If you're using strict, you I<must not> declare $a |
| 4204 | and $b as lexicals. They are package globals. That means |
| 4205 | if you're in the C<main> package, it's |
| 4206 | |
| 4207 | @articles = sort {$main::b <=> $main::a} @files; |
| 4208 | |
| 4209 | or just |
| 4210 | |
| 4211 | @articles = sort {$::b <=> $::a} @files; |
| 4212 | |
| 4213 | but if you're in the C<FooPack> package, it's |
| 4214 | |
| 4215 | @articles = sort {$FooPack::b <=> $FooPack::a} @files; |
| 4216 | |
| 4217 | The comparison function is required to behave. If it returns |
| 4218 | inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and |
| 4219 | sometimes saying the opposite, for example) the results are not |
| 4220 | well-defined. |
| 4221 | |
| 4222 | =item splice ARRAY,OFFSET,LENGTH,LIST |
| 4223 | |
| 4224 | =item splice ARRAY,OFFSET,LENGTH |
| 4225 | |
| 4226 | =item splice ARRAY,OFFSET |
| 4227 | |
| 4228 | =item splice ARRAY |
| 4229 | |
| 4230 | Removes the elements designated by OFFSET and LENGTH from an array, and |
| 4231 | replaces them with the elements of LIST, if any. In list context, |
| 4232 | returns the elements removed from the array. In scalar context, |
| 4233 | returns the last element removed, or C<undef> if no elements are |
| 4234 | removed. The array grows or shrinks as necessary. |
| 4235 | If OFFSET is negative then it starts that far from the end of the array. |
| 4236 | If LENGTH is omitted, removes everything from OFFSET onward. |
| 4237 | If LENGTH is negative, leaves that many elements off the end of the array. |
| 4238 | If both OFFSET and LENGTH are omitted, removes everything. |
| 4239 | |
| 4240 | The following equivalences hold (assuming C<$[ == 0>): |
| 4241 | |
| 4242 | push(@a,$x,$y) splice(@a,@a,0,$x,$y) |
| 4243 | pop(@a) splice(@a,-1) |
| 4244 | shift(@a) splice(@a,0,1) |
| 4245 | unshift(@a,$x,$y) splice(@a,0,0,$x,$y) |
| 4246 | $a[$x] = $y splice(@a,$x,1,$y) |
| 4247 | |
| 4248 | Example, assuming array lengths are passed before arrays: |
| 4249 | |
| 4250 | sub aeq { # compare two list values |
| 4251 | my(@a) = splice(@_,0,shift); |
| 4252 | my(@b) = splice(@_,0,shift); |
| 4253 | return 0 unless @a == @b; # same len? |
| 4254 | while (@a) { |
| 4255 | return 0 if pop(@a) ne pop(@b); |
| 4256 | } |
| 4257 | return 1; |
| 4258 | } |
| 4259 | if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... } |
| 4260 | |
| 4261 | =item split /PATTERN/,EXPR,LIMIT |
| 4262 | |
| 4263 | =item split /PATTERN/,EXPR |
| 4264 | |
| 4265 | =item split /PATTERN/ |
| 4266 | |
| 4267 | =item split |
| 4268 | |
| 4269 | Splits a string into a list of strings and returns that list. By default, |
| 4270 | empty leading fields are preserved, and empty trailing ones are deleted. |
| 4271 | |
| 4272 | If not in list context, returns the number of fields found and splits into |
| 4273 | the C<@_> array. (In list context, you can force the split into C<@_> by |
| 4274 | using C<??> as the pattern delimiters, but it still returns the list |
| 4275 | value.) The use of implicit split to C<@_> is deprecated, however, because |
| 4276 | it clobbers your subroutine arguments. |
| 4277 | |
| 4278 | If EXPR is omitted, splits the C<$_> string. If PATTERN is also omitted, |
| 4279 | splits on whitespace (after skipping any leading whitespace). Anything |
| 4280 | matching PATTERN is taken to be a delimiter separating the fields. (Note |
| 4281 | that the delimiter may be longer than one character.) |
| 4282 | |
| 4283 | If LIMIT is specified and positive, splits into no more than that |
| 4284 | many fields (though it may split into fewer). If LIMIT is unspecified |
| 4285 | or zero, trailing null fields are stripped (which potential users |
| 4286 | of C<pop> would do well to remember). If LIMIT is negative, it is |
| 4287 | treated as if an arbitrarily large LIMIT had been specified. |
| 4288 | |
| 4289 | A pattern matching the null string (not to be confused with |
| 4290 | a null pattern C<//>, which is just one member of the set of patterns |
| 4291 | matching a null string) will split the value of EXPR into separate |
| 4292 | characters at each point it matches that way. For example: |
| 4293 | |
| 4294 | print join(':', split(/ */, 'hi there')); |
| 4295 | |
| 4296 | produces the output 'h:i:t:h:e:r:e'. |
| 4297 | |
| 4298 | The LIMIT parameter can be used to split a line partially |
| 4299 | |
| 4300 | ($login, $passwd, $remainder) = split(/:/, $_, 3); |
| 4301 | |
| 4302 | When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT |
| 4303 | one larger than the number of variables in the list, to avoid |
| 4304 | unnecessary work. For the list above LIMIT would have been 4 by |
| 4305 | default. In time critical applications it behooves you not to split |
| 4306 | into more fields than you really need. |
| 4307 | |
| 4308 | If the PATTERN contains parentheses, additional list elements are |
| 4309 | created from each matching substring in the delimiter. |
| 4310 | |
| 4311 | split(/([,-])/, "1-10,20", 3); |
| 4312 | |
| 4313 | produces the list value |
| 4314 | |
| 4315 | (1, '-', 10, ',', 20) |
| 4316 | |
| 4317 | If you had the entire header of a normal Unix email message in $header, |
| 4318 | you could split it up into fields and their values this way: |
| 4319 | |
| 4320 | $header =~ s/\n\s+/ /g; # fix continuation lines |
| 4321 | %hdrs = (UNIX_FROM => split /^(\S*?):\s*/m, $header); |
| 4322 | |
| 4323 | The pattern C</PATTERN/> may be replaced with an expression to specify |
| 4324 | patterns that vary at runtime. (To do runtime compilation only once, |
| 4325 | use C</$variable/o>.) |
| 4326 | |
| 4327 | As a special case, specifying a PATTERN of space (C<' '>) will split on |
| 4328 | white space just as C<split> with no arguments does. Thus, C<split(' ')> can |
| 4329 | be used to emulate B<awk>'s default behavior, whereas C<split(/ /)> |
| 4330 | will give you as many null initial fields as there are leading spaces. |
| 4331 | A C<split> on C</\s+/> is like a C<split(' ')> except that any leading |
| 4332 | whitespace produces a null first field. A C<split> with no arguments |
| 4333 | really does a C<split(' ', $_)> internally. |
| 4334 | |
| 4335 | Example: |
| 4336 | |
| 4337 | open(PASSWD, '/etc/passwd'); |
| 4338 | while (<PASSWD>) { |
| 4339 | ($login, $passwd, $uid, $gid, |
| 4340 | $gcos, $home, $shell) = split(/:/); |
| 4341 | #... |
| 4342 | } |
| 4343 | |
| 4344 | (Note that $shell above will still have a newline on it. See L</chop>, |
| 4345 | L</chomp>, and L</join>.) |
| 4346 | |
| 4347 | =item sprintf FORMAT, LIST |
| 4348 | |
| 4349 | Returns a string formatted by the usual C<printf> conventions of the |
| 4350 | C library function C<sprintf>. See L<sprintf(3)> or L<printf(3)> |
| 4351 | on your system for an explanation of the general principles. |
| 4352 | |
| 4353 | Perl does its own C<sprintf> formatting--it emulates the C |
| 4354 | function C<sprintf>, but it doesn't use it (except for floating-point |
| 4355 | numbers, and even then only the standard modifiers are allowed). As a |
| 4356 | result, any non-standard extensions in your local C<sprintf> are not |
| 4357 | available from Perl. |
| 4358 | |
| 4359 | Perl's C<sprintf> permits the following universally-known conversions: |
| 4360 | |
| 4361 | %% a percent sign |
| 4362 | %c a character with the given number |
| 4363 | %s a string |
| 4364 | %d a signed integer, in decimal |
| 4365 | %u an unsigned integer, in decimal |
| 4366 | %o an unsigned integer, in octal |
| 4367 | %x an unsigned integer, in hexadecimal |
| 4368 | %e a floating-point number, in scientific notation |
| 4369 | %f a floating-point number, in fixed decimal notation |
| 4370 | %g a floating-point number, in %e or %f notation |
| 4371 | |
| 4372 | In addition, Perl permits the following widely-supported conversions: |
| 4373 | |
| 4374 | %X like %x, but using upper-case letters |
| 4375 | %E like %e, but using an upper-case "E" |
| 4376 | %G like %g, but with an upper-case "E" (if applicable) |
| 4377 | %b an unsigned integer, in binary |
| 4378 | %p a pointer (outputs the Perl value's address in hexadecimal) |
| 4379 | %n special: *stores* the number of characters output so far |
| 4380 | into the next variable in the parameter list |
| 4381 | |
| 4382 | Finally, for backward (and we do mean "backward") compatibility, Perl |
| 4383 | permits these unnecessary but widely-supported conversions: |
| 4384 | |
| 4385 | %i a synonym for %d |
| 4386 | %D a synonym for %ld |
| 4387 | %U a synonym for %lu |
| 4388 | %O a synonym for %lo |
| 4389 | %F a synonym for %f |
| 4390 | |
| 4391 | Perl permits the following universally-known flags between the C<%> |
| 4392 | and the conversion letter: |
| 4393 | |
| 4394 | space prefix positive number with a space |
| 4395 | + prefix positive number with a plus sign |
| 4396 | - left-justify within the field |
| 4397 | 0 use zeros, not spaces, to right-justify |
| 4398 | # prefix non-zero octal with "0", non-zero hex with "0x" |
| 4399 | number minimum field width |
| 4400 | .number "precision": digits after decimal point for |
| 4401 | floating-point, max length for string, minimum length |
| 4402 | for integer |
| 4403 | l interpret integer as C type "long" or "unsigned long" |
| 4404 | h interpret integer as C type "short" or "unsigned short" |
| 4405 | If no flags, interpret integer as C type "int" or "unsigned" |
| 4406 | |
| 4407 | There are also two Perl-specific flags: |
| 4408 | |
| 4409 | V interpret integer as Perl's standard integer type |
| 4410 | v interpret string as a vector of integers, output as |
| 4411 | numbers separated either by dots, or by an arbitrary |
| 4412 | string received from the argument list when the flag |
| 4413 | is preceded by C<*> |
| 4414 | |
| 4415 | Where a number would appear in the flags, an asterisk (C<*>) may be |
| 4416 | used instead, in which case Perl uses the next item in the parameter |
| 4417 | list as the given number (that is, as the field width or precision). |
| 4418 | If a field width obtained through C<*> is negative, it has the same |
| 4419 | effect as the C<-> flag: left-justification. |
| 4420 | |
| 4421 | The C<v> flag is useful for displaying ordinal values of characters |
| 4422 | in arbitrary strings: |
| 4423 | |
| 4424 | printf "version is v%vd\n", $^V; # Perl's version |
| 4425 | printf "address is %*vX\n", ":", $addr; # IPv6 address |
| 4426 | printf "bits are %*vb\n", " ", $bits; # random bitstring |
| 4427 | |
| 4428 | If C<use locale> is in effect, the character used for the decimal |
| 4429 | point in formatted real numbers is affected by the LC_NUMERIC locale. |
| 4430 | See L<perllocale>. |
| 4431 | |
| 4432 | If Perl understands "quads" (64-bit integers) (this requires |
| 4433 | either that the platform natively support quads or that Perl |
| 4434 | be specifically compiled to support quads), the characters |
| 4435 | |
| 4436 | d u o x X b i D U O |
| 4437 | |
| 4438 | print quads, and they may optionally be preceded by |
| 4439 | |
| 4440 | ll L q |
| 4441 | |
| 4442 | For example |
| 4443 | |
| 4444 | %lld %16LX %qo |
| 4445 | |
| 4446 | You can find out whether your Perl supports quads via L<Config>: |
| 4447 | |
| 4448 | use Config; |
| 4449 | ($Config{use64bitint} eq 'define' || $Config{longsize} == 8) && |
| 4450 | print "quads\n"; |
| 4451 | |
| 4452 | If Perl understands "long doubles" (this requires that the platform |
| 4453 | support long doubles), the flags |
| 4454 | |
| 4455 | e f g E F G |
| 4456 | |
| 4457 | may optionally be preceded by |
| 4458 | |
| 4459 | ll L |
| 4460 | |
| 4461 | For example |
| 4462 | |
| 4463 | %llf %Lg |
| 4464 | |
| 4465 | You can find out whether your Perl supports long doubles via L<Config>: |
| 4466 | |
| 4467 | use Config; |
| 4468 | $Config{d_longdbl} eq 'define' && print "long doubles\n"; |
| 4469 | |
| 4470 | =item sqrt EXPR |
| 4471 | |
| 4472 | =item sqrt |
| 4473 | |
| 4474 | Return the square root of EXPR. If EXPR is omitted, returns square |
| 4475 | root of C<$_>. Only works on non-negative operands, unless you've |
| 4476 | loaded the standard Math::Complex module. |
| 4477 | |
| 4478 | use Math::Complex; |
| 4479 | print sqrt(-2); # prints 1.4142135623731i |
| 4480 | |
| 4481 | =item srand EXPR |
| 4482 | |
| 4483 | =item srand |
| 4484 | |
| 4485 | Sets the random number seed for the C<rand> operator. If EXPR is |
| 4486 | omitted, uses a semi-random value supplied by the kernel (if it supports |
| 4487 | the F</dev/urandom> device) or based on the current time and process |
| 4488 | ID, among other things. In versions of Perl prior to 5.004 the default |
| 4489 | seed was just the current C<time>. This isn't a particularly good seed, |
| 4490 | so many old programs supply their own seed value (often C<time ^ $$> or |
| 4491 | C<time ^ ($$ + ($$ << 15))>), but that isn't necessary any more. |
| 4492 | |
| 4493 | In fact, it's usually not necessary to call C<srand> at all, because if |
| 4494 | it is not called explicitly, it is called implicitly at the first use of |
| 4495 | the C<rand> operator. However, this was not the case in version of Perl |
| 4496 | before 5.004, so if your script will run under older Perl versions, it |
| 4497 | should call C<srand>. |
| 4498 | |
| 4499 | Note that you need something much more random than the default seed for |
| 4500 | cryptographic purposes. Checksumming the compressed output of one or more |
| 4501 | rapidly changing operating system status programs is the usual method. For |
| 4502 | example: |
| 4503 | |
| 4504 | srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`); |
| 4505 | |
| 4506 | If you're particularly concerned with this, see the C<Math::TrulyRandom> |
| 4507 | module in CPAN. |
| 4508 | |
| 4509 | Do I<not> call C<srand> multiple times in your program unless you know |
| 4510 | exactly what you're doing and why you're doing it. The point of the |
| 4511 | function is to "seed" the C<rand> function so that C<rand> can produce |
| 4512 | a different sequence each time you run your program. Just do it once at the |
| 4513 | top of your program, or you I<won't> get random numbers out of C<rand>! |
| 4514 | |
| 4515 | Frequently called programs (like CGI scripts) that simply use |
| 4516 | |
| 4517 | time ^ $$ |
| 4518 | |
| 4519 | for a seed can fall prey to the mathematical property that |
| 4520 | |
| 4521 | a^b == (a+1)^(b+1) |
| 4522 | |
| 4523 | one-third of the time. So don't do that. |
| 4524 | |
| 4525 | =item stat FILEHANDLE |
| 4526 | |
| 4527 | =item stat EXPR |
| 4528 | |
| 4529 | =item stat |
| 4530 | |
| 4531 | Returns a 13-element list giving the status info for a file, either |
| 4532 | the file opened via FILEHANDLE, or named by EXPR. If EXPR is omitted, |
| 4533 | it stats C<$_>. Returns a null list if the stat fails. Typically used |
| 4534 | as follows: |
| 4535 | |
| 4536 | ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size, |
| 4537 | $atime,$mtime,$ctime,$blksize,$blocks) |
| 4538 | = stat($filename); |
| 4539 | |
| 4540 | Not all fields are supported on all filesystem types. Here are the |
| 4541 | meaning of the fields: |
| 4542 | |
| 4543 | 0 dev device number of filesystem |
| 4544 | 1 ino inode number |
| 4545 | 2 mode file mode (type and permissions) |
| 4546 | 3 nlink number of (hard) links to the file |
| 4547 | 4 uid numeric user ID of file's owner |
| 4548 | 5 gid numeric group ID of file's owner |
| 4549 | 6 rdev the device identifier (special files only) |
| 4550 | 7 size total size of file, in bytes |
| 4551 | 8 atime last access time in seconds since the epoch |
| 4552 | 9 mtime last modify time in seconds since the epoch |
| 4553 | 10 ctime inode change time (NOT creation time!) in seconds since the epoch |
| 4554 | 11 blksize preferred block size for file system I/O |
| 4555 | 12 blocks actual number of blocks allocated |
| 4556 | |
| 4557 | (The epoch was at 00:00 January 1, 1970 GMT.) |
| 4558 | |
| 4559 | If stat is passed the special filehandle consisting of an underline, no |
| 4560 | stat is done, but the current contents of the stat structure from the |
| 4561 | last stat or filetest are returned. Example: |
| 4562 | |
| 4563 | if (-x $file && (($d) = stat(_)) && $d < 0) { |
| 4564 | print "$file is executable NFS file\n"; |
| 4565 | } |
| 4566 | |
| 4567 | (This works on machines only for which the device number is negative |
| 4568 | under NFS.) |
| 4569 | |
| 4570 | Because the mode contains both the file type and its permissions, you |
| 4571 | should mask off the file type portion and (s)printf using a C<"%o"> |
| 4572 | if you want to see the real permissions. |
| 4573 | |
| 4574 | $mode = (stat($filename))[2]; |
| 4575 | printf "Permissions are %04o\n", $mode & 07777; |
| 4576 | |
| 4577 | In scalar context, C<stat> returns a boolean value indicating success |
| 4578 | or failure, and, if successful, sets the information associated with |
| 4579 | the special filehandle C<_>. |
| 4580 | |
| 4581 | The File::stat module provides a convenient, by-name access mechanism: |
| 4582 | |
| 4583 | use File::stat; |
| 4584 | $sb = stat($filename); |
| 4585 | printf "File is %s, size is %s, perm %04o, mtime %s\n", |
| 4586 | $filename, $sb->size, $sb->mode & 07777, |
| 4587 | scalar localtime $sb->mtime; |
| 4588 | |
| 4589 | You can import symbolic mode constants (C<S_IF*>) and functions |
| 4590 | (C<S_IS*>) from the Fcntl module: |
| 4591 | |
| 4592 | use Fcntl ':mode'; |
| 4593 | |
| 4594 | $mode = (stat($filename))[2]; |
| 4595 | |
| 4596 | $user_rwx = ($mode & S_IRWXU) >> 6; |
| 4597 | $group_read = ($mode & S_IRGRP) >> 3; |
| 4598 | $other_execute = $mode & S_IXOTH; |
| 4599 | |
| 4600 | printf "Permissions are %04o\n", S_ISMODE($mode), "\n"; |
| 4601 | |
| 4602 | $is_setuid = $mode & S_ISUID; |
| 4603 | $is_setgid = S_ISDIR($mode); |
| 4604 | |
| 4605 | You could write the last two using the C<-u> and C<-d> operators. |
| 4606 | The commonly available S_IF* constants are |
| 4607 | |
| 4608 | # Permissions: read, write, execute, for user, group, others. |
| 4609 | |
| 4610 | S_IRWXU S_IRUSR S_IWUSR S_IXUSR |
| 4611 | S_IRWXG S_IRGRP S_IWGRP S_IXGRP |
| 4612 | S_IRWXO S_IROTH S_IWOTH S_IXOTH |
| 4613 | |
| 4614 | # Setuid/Setgid/Stickiness. |
| 4615 | |
| 4616 | S_ISUID S_ISGID S_ISVTX S_ISTXT |
| 4617 | |
| 4618 | # File types. Not necessarily all are available on your system. |
| 4619 | |
| 4620 | S_IFREG S_IFDIR S_IFLNK S_IFBLK S_ISCHR S_IFIFO S_IFSOCK S_IFWHT S_ENFMT |
| 4621 | |
| 4622 | # The following are compatibility aliases for S_IRUSR, S_IWUSR, S_IXUSR. |
| 4623 | |
| 4624 | S_IREAD S_IWRITE S_IEXEC |
| 4625 | |
| 4626 | and the S_IF* functions are |
| 4627 | |
| 4628 | S_IFMODE($mode) the part of $mode containg the permission bits |
| 4629 | and the setuid/setgid/sticky bits |
| 4630 | |
| 4631 | S_IFMT($mode) the part of $mode containing the file type |
| 4632 | which can be bit-anded with e.g. S_IFREG |
| 4633 | or with the following functions |
| 4634 | |
| 4635 | # The operators -f, -d, -l, -b, -c, -p, and -s. |
| 4636 | |
| 4637 | S_ISREG($mode) S_ISDIR($mode) S_ISLNK($mode) |
| 4638 | S_ISBLK($mode) S_ISCHR($mode) S_ISFIFO($mode) S_ISSOCK($mode) |
| 4639 | |
| 4640 | # No direct -X operator counterpart, but for the first one |
| 4641 | # the -g operator is often equivalent. The ENFMT stands for |
| 4642 | # record flocking enforcement, a platform-dependent feature. |
| 4643 | |
| 4644 | S_ISENFMT($mode) S_ISWHT($mode) |
| 4645 | |
| 4646 | See your native chmod(2) and stat(2) documentation for more details |
| 4647 | about the S_* constants. |
| 4648 | |
| 4649 | =item study SCALAR |
| 4650 | |
| 4651 | =item study |
| 4652 | |
| 4653 | Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of |
| 4654 | doing many pattern matches on the string before it is next modified. |
| 4655 | This may or may not save time, depending on the nature and number of |
| 4656 | patterns you are searching on, and on the distribution of character |
| 4657 | frequencies in the string to be searched--you probably want to compare |
| 4658 | run times with and without it to see which runs faster. Those loops |
| 4659 | which scan for many short constant strings (including the constant |
| 4660 | parts of more complex patterns) will benefit most. You may have only |
| 4661 | one C<study> active at a time--if you study a different scalar the first |
| 4662 | is "unstudied". (The way C<study> works is this: a linked list of every |
| 4663 | character in the string to be searched is made, so we know, for |
| 4664 | example, where all the C<'k'> characters are. From each search string, |
| 4665 | the rarest character is selected, based on some static frequency tables |
| 4666 | constructed from some C programs and English text. Only those places |
| 4667 | that contain this "rarest" character are examined.) |
| 4668 | |
| 4669 | For example, here is a loop that inserts index producing entries |
| 4670 | before any line containing a certain pattern: |
| 4671 | |
| 4672 | while (<>) { |
| 4673 | study; |
| 4674 | print ".IX foo\n" if /\bfoo\b/; |
| 4675 | print ".IX bar\n" if /\bbar\b/; |
| 4676 | print ".IX blurfl\n" if /\bblurfl\b/; |
| 4677 | # ... |
| 4678 | print; |
| 4679 | } |
| 4680 | |
| 4681 | In searching for C</\bfoo\b/>, only those locations in C<$_> that contain C<f> |
| 4682 | will be looked at, because C<f> is rarer than C<o>. In general, this is |
| 4683 | a big win except in pathological cases. The only question is whether |
| 4684 | it saves you more time than it took to build the linked list in the |
| 4685 | first place. |
| 4686 | |
| 4687 | Note that if you have to look for strings that you don't know till |
| 4688 | runtime, you can build an entire loop as a string and C<eval> that to |
| 4689 | avoid recompiling all your patterns all the time. Together with |
| 4690 | undefining C<$/> to input entire files as one record, this can be very |
| 4691 | fast, often faster than specialized programs like fgrep(1). The following |
| 4692 | scans a list of files (C<@files>) for a list of words (C<@words>), and prints |
| 4693 | out the names of those files that contain a match: |
| 4694 | |
| 4695 | $search = 'while (<>) { study;'; |
| 4696 | foreach $word (@words) { |
| 4697 | $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n"; |
| 4698 | } |
| 4699 | $search .= "}"; |
| 4700 | @ARGV = @files; |
| 4701 | undef $/; |
| 4702 | eval $search; # this screams |
| 4703 | $/ = "\n"; # put back to normal input delimiter |
| 4704 | foreach $file (sort keys(%seen)) { |
| 4705 | print $file, "\n"; |
| 4706 | } |
| 4707 | |
| 4708 | =item sub BLOCK |
| 4709 | |
| 4710 | =item sub NAME |
| 4711 | |
| 4712 | =item sub NAME BLOCK |
| 4713 | |
| 4714 | This is subroutine definition, not a real function I<per se>. With just a |
| 4715 | NAME (and possibly prototypes or attributes), it's just a forward declaration. |
| 4716 | Without a NAME, it's an anonymous function declaration, and does actually |
| 4717 | return a value: the CODE ref of the closure you just created. See L<perlsub> |
| 4718 | and L<perlref> for details. |
| 4719 | |
| 4720 | =item substr EXPR,OFFSET,LENGTH,REPLACEMENT |
| 4721 | |
| 4722 | =item substr EXPR,OFFSET,LENGTH |
| 4723 | |
| 4724 | =item substr EXPR,OFFSET |
| 4725 | |
| 4726 | Extracts a substring out of EXPR and returns it. First character is at |
| 4727 | offset C<0>, or whatever you've set C<$[> to (but don't do that). |
| 4728 | If OFFSET is negative (or more precisely, less than C<$[>), starts |
| 4729 | that far from the end of the string. If LENGTH is omitted, returns |
| 4730 | everything to the end of the string. If LENGTH is negative, leaves that |
| 4731 | many characters off the end of the string. |
| 4732 | |
| 4733 | You can use the substr() function as an lvalue, in which case EXPR |
| 4734 | must itself be an lvalue. If you assign something shorter than LENGTH, |
| 4735 | the string will shrink, and if you assign something longer than LENGTH, |
| 4736 | the string will grow to accommodate it. To keep the string the same |
| 4737 | length you may need to pad or chop your value using C<sprintf>. |
| 4738 | |
| 4739 | If OFFSET and LENGTH specify a substring that is partly outside the |
| 4740 | string, only the part within the string is returned. If the substring |
| 4741 | is beyond either end of the string, substr() returns the undefined |
| 4742 | value and produces a warning. When used as an lvalue, specifying a |
| 4743 | substring that is entirely outside the string is a fatal error. |
| 4744 | Here's an example showing the behavior for boundary cases: |
| 4745 | |
| 4746 | my $name = 'fred'; |
| 4747 | substr($name, 4) = 'dy'; # $name is now 'freddy' |
| 4748 | my $null = substr $name, 6, 2; # returns '' (no warning) |
| 4749 | my $oops = substr $name, 7; # returns undef, with warning |
| 4750 | substr($name, 7) = 'gap'; # fatal error |
| 4751 | |
| 4752 | An alternative to using substr() as an lvalue is to specify the |
| 4753 | replacement string as the 4th argument. This allows you to replace |
| 4754 | parts of the EXPR and return what was there before in one operation, |
| 4755 | just as you can with splice(). |
| 4756 | |
| 4757 | =item symlink OLDFILE,NEWFILE |
| 4758 | |
| 4759 | Creates a new filename symbolically linked to the old filename. |
| 4760 | Returns C<1> for success, C<0> otherwise. On systems that don't support |
| 4761 | symbolic links, produces a fatal error at run time. To check for that, |
| 4762 | use eval: |
| 4763 | |
| 4764 | $symlink_exists = eval { symlink("",""); 1 }; |
| 4765 | |
| 4766 | =item syscall LIST |
| 4767 | |
| 4768 | Calls the system call specified as the first element of the list, |
| 4769 | passing the remaining elements as arguments to the system call. If |
| 4770 | unimplemented, produces a fatal error. The arguments are interpreted |
| 4771 | as follows: if a given argument is numeric, the argument is passed as |
| 4772 | an int. If not, the pointer to the string value is passed. You are |
| 4773 | responsible to make sure a string is pre-extended long enough to |
| 4774 | receive any result that might be written into a string. You can't use a |
| 4775 | string literal (or other read-only string) as an argument to C<syscall> |
| 4776 | because Perl has to assume that any string pointer might be written |
| 4777 | through. If your |
| 4778 | integer arguments are not literals and have never been interpreted in a |
| 4779 | numeric context, you may need to add C<0> to them to force them to look |
| 4780 | like numbers. This emulates the C<syswrite> function (or vice versa): |
| 4781 | |
| 4782 | require 'syscall.ph'; # may need to run h2ph |
| 4783 | $s = "hi there\n"; |
| 4784 | syscall(&SYS_write, fileno(STDOUT), $s, length $s); |
| 4785 | |
| 4786 | Note that Perl supports passing of up to only 14 arguments to your system call, |
| 4787 | which in practice should usually suffice. |
| 4788 | |
| 4789 | Syscall returns whatever value returned by the system call it calls. |
| 4790 | If the system call fails, C<syscall> returns C<-1> and sets C<$!> (errno). |
| 4791 | Note that some system calls can legitimately return C<-1>. The proper |
| 4792 | way to handle such calls is to assign C<$!=0;> before the call and |
| 4793 | check the value of C<$!> if syscall returns C<-1>. |
| 4794 | |
| 4795 | There's a problem with C<syscall(&SYS_pipe)>: it returns the file |
| 4796 | number of the read end of the pipe it creates. There is no way |
| 4797 | to retrieve the file number of the other end. You can avoid this |
| 4798 | problem by using C<pipe> instead. |
| 4799 | |
| 4800 | =item sysopen FILEHANDLE,FILENAME,MODE |
| 4801 | |
| 4802 | =item sysopen FILEHANDLE,FILENAME,MODE,PERMS |
| 4803 | |
| 4804 | Opens the file whose filename is given by FILENAME, and associates it |
| 4805 | with FILEHANDLE. If FILEHANDLE is an expression, its value is used as |
| 4806 | the name of the real filehandle wanted. This function calls the |
| 4807 | underlying operating system's C<open> function with the parameters |
| 4808 | FILENAME, MODE, PERMS. |
| 4809 | |
| 4810 | The possible values and flag bits of the MODE parameter are |
| 4811 | system-dependent; they are available via the standard module C<Fcntl>. |
| 4812 | See the documentation of your operating system's C<open> to see which |
| 4813 | values and flag bits are available. You may combine several flags |
| 4814 | using the C<|>-operator. |
| 4815 | |
| 4816 | Some of the most common values are C<O_RDONLY> for opening the file in |
| 4817 | read-only mode, C<O_WRONLY> for opening the file in write-only mode, |
| 4818 | and C<O_RDWR> for opening the file in read-write mode, and. |
| 4819 | |
| 4820 | For historical reasons, some values work on almost every system |
| 4821 | supported by perl: zero means read-only, one means write-only, and two |
| 4822 | means read/write. We know that these values do I<not> work under |
| 4823 | OS/390 & VM/ESA Unix and on the Macintosh; you probably don't want to |
| 4824 | use them in new code. |
| 4825 | |
| 4826 | If the file named by FILENAME does not exist and the C<open> call creates |
| 4827 | it (typically because MODE includes the C<O_CREAT> flag), then the value of |
| 4828 | PERMS specifies the permissions of the newly created file. If you omit |
| 4829 | the PERMS argument to C<sysopen>, Perl uses the octal value C<0666>. |
| 4830 | These permission values need to be in octal, and are modified by your |
| 4831 | process's current C<umask>. |
| 4832 | |
| 4833 | In many systems the C<O_EXCL> flag is available for opening files in |
| 4834 | exclusive mode. This is B<not> locking: exclusiveness means here that |
| 4835 | if the file already exists, sysopen() fails. The C<O_EXCL> wins |
| 4836 | C<O_TRUNC>. |
| 4837 | |
| 4838 | Sometimes you may want to truncate an already-existing file: C<O_TRUNC>. |
| 4839 | |
| 4840 | You should seldom if ever use C<0644> as argument to C<sysopen>, because |
| 4841 | that takes away the user's option to have a more permissive umask. |
| 4842 | Better to omit it. See the perlfunc(1) entry on C<umask> for more |
| 4843 | on this. |
| 4844 | |
| 4845 | Note that C<sysopen> depends on the fdopen() C library function. |
| 4846 | On many UNIX systems, fdopen() is known to fail when file descriptors |
| 4847 | exceed a certain value, typically 255. If you need more file |
| 4848 | descriptors than that, consider rebuilding Perl to use the C<sfio> |
| 4849 | library, or perhaps using the POSIX::open() function. |
| 4850 | |
| 4851 | See L<perlopentut> for a kinder, gentler explanation of opening files. |
| 4852 | |
| 4853 | =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET |
| 4854 | |
| 4855 | =item sysread FILEHANDLE,SCALAR,LENGTH |
| 4856 | |
| 4857 | Attempts to read LENGTH bytes of data into variable SCALAR from the |
| 4858 | specified FILEHANDLE, using the system call read(2). It bypasses stdio, |
| 4859 | so mixing this with other kinds of reads, C<print>, C<write>, |
| 4860 | C<seek>, C<tell>, or C<eof> can cause confusion because stdio |
| 4861 | usually buffers data. Returns the number of bytes actually read, C<0> |
| 4862 | at end of file, or undef if there was an error. SCALAR will be grown or |
| 4863 | shrunk so that the last byte actually read is the last byte of the |
| 4864 | scalar after the read. |
| 4865 | |
| 4866 | An OFFSET may be specified to place the read data at some place in the |
| 4867 | string other than the beginning. A negative OFFSET specifies |
| 4868 | placement at that many bytes counting backwards from the end of the |
| 4869 | string. A positive OFFSET greater than the length of SCALAR results |
| 4870 | in the string being padded to the required size with C<"\0"> bytes before |
| 4871 | the result of the read is appended. |
| 4872 | |
| 4873 | There is no syseof() function, which is ok, since eof() doesn't work |
| 4874 | very well on device files (like ttys) anyway. Use sysread() and check |
| 4875 | for a return value for 0 to decide whether you're done. |
| 4876 | |
| 4877 | =item sysseek FILEHANDLE,POSITION,WHENCE |
| 4878 | |
| 4879 | Sets FILEHANDLE's system position using the system call lseek(2). It |
| 4880 | bypasses stdio, so mixing this with reads (other than C<sysread>), |
| 4881 | C<print>, C<write>, C<seek>, C<tell>, or C<eof> may cause confusion. |
| 4882 | FILEHANDLE may be an expression whose value gives the name of the |
| 4883 | filehandle. The values for WHENCE are C<0> to set the new position to |
| 4884 | POSITION, C<1> to set the it to the current position plus POSITION, |
| 4885 | and C<2> to set it to EOF plus POSITION (typically negative). For |
| 4886 | WHENCE, you may also use the constants C<SEEK_SET>, C<SEEK_CUR>, and |
| 4887 | C<SEEK_END> (start of the file, current position, end of the file) |
| 4888 | from the Fcntl module. |
| 4889 | |
| 4890 | Returns the new position, or the undefined value on failure. A position |
| 4891 | of zero is returned as the string C<"0 but true">; thus C<sysseek> returns |
| 4892 | true on success and false on failure, yet you can still easily determine |
| 4893 | the new position. |
| 4894 | |
| 4895 | =item system LIST |
| 4896 | |
| 4897 | =item system PROGRAM LIST |
| 4898 | |
| 4899 | Does exactly the same thing as C<exec LIST>, except that a fork is |
| 4900 | done first, and the parent process waits for the child process to |
| 4901 | complete. Note that argument processing varies depending on the |
| 4902 | number of arguments. If there is more than one argument in LIST, |
| 4903 | or if LIST is an array with more than one value, starts the program |
| 4904 | given by the first element of the list with arguments given by the |
| 4905 | rest of the list. If there is only one scalar argument, the argument |
| 4906 | is checked for shell metacharacters, and if there are any, the |
| 4907 | entire argument is passed to the system's command shell for parsing |
| 4908 | (this is C</bin/sh -c> on Unix platforms, but varies on other |
| 4909 | platforms). If there are no shell metacharacters in the argument, |
| 4910 | it is split into words and passed directly to C<execvp>, which is |
| 4911 | more efficient. |
| 4912 | |
| 4913 | All files opened for output are flushed before attempting the exec(). |
| 4914 | |
| 4915 | The return value is the exit status of the program as |
| 4916 | returned by the C<wait> call. To get the actual exit value divide by |
| 4917 | 256. See also L</exec>. This is I<not> what you want to use to capture |
| 4918 | the output from a command, for that you should use merely backticks or |
| 4919 | C<qx//>, as described in L<perlop/"`STRING`">. Return value of -1 |
| 4920 | indicates a failure to start the program (inspect $! for the reason). |
| 4921 | |
| 4922 | Like C<exec>, C<system> allows you to lie to a program about its name if |
| 4923 | you use the C<system PROGRAM LIST> syntax. Again, see L</exec>. |
| 4924 | |
| 4925 | Because C<system> and backticks block C<SIGINT> and C<SIGQUIT>, killing the |
| 4926 | program they're running doesn't actually interrupt your program. |
| 4927 | |
| 4928 | @args = ("command", "arg1", "arg2"); |
| 4929 | system(@args) == 0 |
| 4930 | or die "system @args failed: $?" |
| 4931 | |
| 4932 | You can check all the failure possibilities by inspecting |
| 4933 | C<$?> like this: |
| 4934 | |
| 4935 | $exit_value = $? >> 8; |
| 4936 | $signal_num = $? & 127; |
| 4937 | $dumped_core = $? & 128; |
| 4938 | |
| 4939 | When the arguments get executed via the system shell, results |
| 4940 | and return codes will be subject to its quirks and capabilities. |
| 4941 | See L<perlop/"`STRING`"> and L</exec> for details. |
| 4942 | |
| 4943 | =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET |
| 4944 | |
| 4945 | =item syswrite FILEHANDLE,SCALAR,LENGTH |
| 4946 | |
| 4947 | =item syswrite FILEHANDLE,SCALAR |
| 4948 | |
| 4949 | Attempts to write LENGTH bytes of data from variable SCALAR to the |
| 4950 | specified FILEHANDLE, using the system call write(2). If LENGTH |
| 4951 | is not specified, writes whole SCALAR. It bypasses stdio, so mixing |
| 4952 | this with reads (other than C<sysread())>, C<print>, C<write>, |
| 4953 | C<seek>, C<tell>, or C<eof> may cause confusion because stdio |
| 4954 | usually buffers data. Returns the number of bytes actually written, |
| 4955 | or C<undef> if there was an error. If the LENGTH is greater than |
| 4956 | the available data in the SCALAR after the OFFSET, only as much |
| 4957 | data as is available will be written. |
| 4958 | |
| 4959 | An OFFSET may be specified to write the data from some part of the |
| 4960 | string other than the beginning. A negative OFFSET specifies writing |
| 4961 | that many bytes counting backwards from the end of the string. In the |
| 4962 | case the SCALAR is empty you can use OFFSET but only zero offset. |
| 4963 | |
| 4964 | =item tell FILEHANDLE |
| 4965 | |
| 4966 | =item tell |
| 4967 | |
| 4968 | Returns the current position for FILEHANDLE. FILEHANDLE may be an |
| 4969 | expression whose value gives the name of the actual filehandle. If |
| 4970 | FILEHANDLE is omitted, assumes the file last read. |
| 4971 | |
| 4972 | There is no C<systell> function. Use C<sysseek(FH, 0, 1)> for that. |
| 4973 | |
| 4974 | =item telldir DIRHANDLE |
| 4975 | |
| 4976 | Returns the current position of the C<readdir> routines on DIRHANDLE. |
| 4977 | Value may be given to C<seekdir> to access a particular location in a |
| 4978 | directory. Has the same caveats about possible directory compaction as |
| 4979 | the corresponding system library routine. |
| 4980 | |
| 4981 | =item tie VARIABLE,CLASSNAME,LIST |
| 4982 | |
| 4983 | This function binds a variable to a package class that will provide the |
| 4984 | implementation for the variable. VARIABLE is the name of the variable |
| 4985 | to be enchanted. CLASSNAME is the name of a class implementing objects |
| 4986 | of correct type. Any additional arguments are passed to the C<new> |
| 4987 | method of the class (meaning C<TIESCALAR>, C<TIEHANDLE>, C<TIEARRAY>, |
| 4988 | or C<TIEHASH>). Typically these are arguments such as might be passed |
| 4989 | to the C<dbm_open()> function of C. The object returned by the C<new> |
| 4990 | method is also returned by the C<tie> function, which would be useful |
| 4991 | if you want to access other methods in CLASSNAME. |
| 4992 | |
| 4993 | Note that functions such as C<keys> and C<values> may return huge lists |
| 4994 | when used on large objects, like DBM files. You may prefer to use the |
| 4995 | C<each> function to iterate over such. Example: |
| 4996 | |
| 4997 | # print out history file offsets |
| 4998 | use NDBM_File; |
| 4999 | tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0); |
| 5000 | while (($key,$val) = each %HIST) { |
| 5001 | print $key, ' = ', unpack('L',$val), "\n"; |
| 5002 | } |
| 5003 | untie(%HIST); |
| 5004 | |
| 5005 | A class implementing a hash should have the following methods: |
| 5006 | |
| 5007 | TIEHASH classname, LIST |
| 5008 | FETCH this, key |
| 5009 | STORE this, key, value |
| 5010 | DELETE this, key |
| 5011 | CLEAR this |
| 5012 | EXISTS this, key |
| 5013 | FIRSTKEY this |
| 5014 | NEXTKEY this, lastkey |
| 5015 | DESTROY this |
| 5016 | |
| 5017 | A class implementing an ordinary array should have the following methods: |
| 5018 | |
| 5019 | TIEARRAY classname, LIST |
| 5020 | FETCH this, key |
| 5021 | STORE this, key, value |
| 5022 | FETCHSIZE this |
| 5023 | STORESIZE this, count |
| 5024 | CLEAR this |
| 5025 | PUSH this, LIST |
| 5026 | POP this |
| 5027 | SHIFT this |
| 5028 | UNSHIFT this, LIST |
| 5029 | SPLICE this, offset, length, LIST |
| 5030 | EXTEND this, count |
| 5031 | DESTROY this |
| 5032 | |
| 5033 | A class implementing a file handle should have the following methods: |
| 5034 | |
| 5035 | TIEHANDLE classname, LIST |
| 5036 | READ this, scalar, length, offset |
| 5037 | READLINE this |
| 5038 | GETC this |
| 5039 | WRITE this, scalar, length, offset |
| 5040 | PRINT this, LIST |
| 5041 | PRINTF this, format, LIST |
| 5042 | CLOSE this |
| 5043 | DESTROY this |
| 5044 | |
| 5045 | A class implementing a scalar should have the following methods: |
| 5046 | |
| 5047 | TIESCALAR classname, LIST |
| 5048 | FETCH this, |
| 5049 | STORE this, value |
| 5050 | DESTROY this |
| 5051 | |
| 5052 | Not all methods indicated above need be implemented. See L<perltie>, |
| 5053 | L<Tie::Hash>, L<Tie::Array>, L<Tie::Scalar>, and L<Tie::Handle>. |
| 5054 | |
| 5055 | Unlike C<dbmopen>, the C<tie> function will not use or require a module |
| 5056 | for you--you need to do that explicitly yourself. See L<DB_File> |
| 5057 | or the F<Config> module for interesting C<tie> implementations. |
| 5058 | |
| 5059 | For further details see L<perltie>, L<"tied VARIABLE">. |
| 5060 | |
| 5061 | =item tied VARIABLE |
| 5062 | |
| 5063 | Returns a reference to the object underlying VARIABLE (the same value |
| 5064 | that was originally returned by the C<tie> call that bound the variable |
| 5065 | to a package.) Returns the undefined value if VARIABLE isn't tied to a |
| 5066 | package. |
| 5067 | |
| 5068 | =item time |
| 5069 | |
| 5070 | Returns the number of non-leap seconds since whatever time the system |
| 5071 | considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS, |
| 5072 | and 00:00:00 UTC, January 1, 1970 for most other systems). |
| 5073 | Suitable for feeding to C<gmtime> and C<localtime>. |
| 5074 | |
| 5075 | For measuring time in better granularity than one second, |
| 5076 | you may use either the Time::HiRes module from CPAN, or |
| 5077 | if you have gettimeofday(2), you may be able to use the |
| 5078 | C<syscall> interface of Perl, see L<perlfaq8> for details. |
| 5079 | |
| 5080 | =item times |
| 5081 | |
| 5082 | Returns a four-element list giving the user and system times, in |
| 5083 | seconds, for this process and the children of this process. |
| 5084 | |
| 5085 | ($user,$system,$cuser,$csystem) = times; |
| 5086 | |
| 5087 | =item tr/// |
| 5088 | |
| 5089 | The transliteration operator. Same as C<y///>. See L<perlop>. |
| 5090 | |
| 5091 | =item truncate FILEHANDLE,LENGTH |
| 5092 | |
| 5093 | =item truncate EXPR,LENGTH |
| 5094 | |
| 5095 | Truncates the file opened on FILEHANDLE, or named by EXPR, to the |
| 5096 | specified length. Produces a fatal error if truncate isn't implemented |
| 5097 | on your system. Returns true if successful, the undefined value |
| 5098 | otherwise. |
| 5099 | |
| 5100 | =item uc EXPR |
| 5101 | |
| 5102 | =item uc |
| 5103 | |
| 5104 | Returns an uppercased version of EXPR. This is the internal function |
| 5105 | implementing the C<\U> escape in double-quoted strings. |
| 5106 | Respects current LC_CTYPE locale if C<use locale> in force. See L<perllocale>. |
| 5107 | Under Unicode (C<use utf8>) it uses the standard Unicode uppercase mappings. (It |
| 5108 | does not attempt to do titlecase mapping on initial letters. See C<ucfirst> for that.) |
| 5109 | |
| 5110 | If EXPR is omitted, uses C<$_>. |
| 5111 | |
| 5112 | =item ucfirst EXPR |
| 5113 | |
| 5114 | =item ucfirst |
| 5115 | |
| 5116 | Returns the value of EXPR with the first character |
| 5117 | in uppercase (titlecase in Unicode). This is |
| 5118 | the internal function implementing the C<\u> escape in double-quoted strings. |
| 5119 | Respects current LC_CTYPE locale if C<use locale> in force. See L<perllocale> |
| 5120 | and L<utf8>. |
| 5121 | |
| 5122 | If EXPR is omitted, uses C<$_>. |
| 5123 | |
| 5124 | =item umask EXPR |
| 5125 | |
| 5126 | =item umask |
| 5127 | |
| 5128 | Sets the umask for the process to EXPR and returns the previous value. |
| 5129 | If EXPR is omitted, merely returns the current umask. |
| 5130 | |
| 5131 | The Unix permission C<rwxr-x---> is represented as three sets of three |
| 5132 | bits, or three octal digits: C<0750> (the leading 0 indicates octal |
| 5133 | and isn't one of the digits). The C<umask> value is such a number |
| 5134 | representing disabled permissions bits. The permission (or "mode") |
| 5135 | values you pass C<mkdir> or C<sysopen> are modified by your umask, so |
| 5136 | even if you tell C<sysopen> to create a file with permissions C<0777>, |
| 5137 | if your umask is C<0022> then the file will actually be created with |
| 5138 | permissions C<0755>. If your C<umask> were C<0027> (group can't |
| 5139 | write; others can't read, write, or execute), then passing |
| 5140 | C<sysopen> C<0666> would create a file with mode C<0640> (C<0666 &~ |
| 5141 | 027> is C<0640>). |
| 5142 | |
| 5143 | Here's some advice: supply a creation mode of C<0666> for regular |
| 5144 | files (in C<sysopen>) and one of C<0777> for directories (in |
| 5145 | C<mkdir>) and executable files. This gives users the freedom of |
| 5146 | choice: if they want protected files, they might choose process umasks |
| 5147 | of C<022>, C<027>, or even the particularly antisocial mask of C<077>. |
| 5148 | Programs should rarely if ever make policy decisions better left to |
| 5149 | the user. The exception to this is when writing files that should be |
| 5150 | kept private: mail files, web browser cookies, I<.rhosts> files, and |
| 5151 | so on. |
| 5152 | |
| 5153 | If umask(2) is not implemented on your system and you are trying to |
| 5154 | restrict access for I<yourself> (i.e., (EXPR & 0700) > 0), produces a |
| 5155 | fatal error at run time. If umask(2) is not implemented and you are |
| 5156 | not trying to restrict access for yourself, returns C<undef>. |
| 5157 | |
| 5158 | Remember that a umask is a number, usually given in octal; it is I<not> a |
| 5159 | string of octal digits. See also L</oct>, if all you have is a string. |
| 5160 | |
| 5161 | =item undef EXPR |
| 5162 | |
| 5163 | =item undef |
| 5164 | |
| 5165 | Undefines the value of EXPR, which must be an lvalue. Use only on a |
| 5166 | scalar value, an array (using C<@>), a hash (using C<%>), a subroutine |
| 5167 | (using C<&>), or a typeglob (using <*>). (Saying C<undef $hash{$key}> |
| 5168 | will probably not do what you expect on most predefined variables or |
| 5169 | DBM list values, so don't do that; see L<delete>.) Always returns the |
| 5170 | undefined value. You can omit the EXPR, in which case nothing is |
| 5171 | undefined, but you still get an undefined value that you could, for |
| 5172 | instance, return from a subroutine, assign to a variable or pass as a |
| 5173 | parameter. Examples: |
| 5174 | |
| 5175 | undef $foo; |
| 5176 | undef $bar{'blurfl'}; # Compare to: delete $bar{'blurfl'}; |
| 5177 | undef @ary; |
| 5178 | undef %hash; |
| 5179 | undef &mysub; |
| 5180 | undef *xyz; # destroys $xyz, @xyz, %xyz, &xyz, etc. |
| 5181 | return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it; |
| 5182 | select undef, undef, undef, 0.25; |
| 5183 | ($a, $b, undef, $c) = &foo; # Ignore third value returned |
| 5184 | |
| 5185 | Note that this is a unary operator, not a list operator. |
| 5186 | |
| 5187 | =item unlink LIST |
| 5188 | |
| 5189 | =item unlink |
| 5190 | |
| 5191 | Deletes a list of files. Returns the number of files successfully |
| 5192 | deleted. |
| 5193 | |
| 5194 | $cnt = unlink 'a', 'b', 'c'; |
| 5195 | unlink @goners; |
| 5196 | unlink <*.bak>; |
| 5197 | |
| 5198 | Note: C<unlink> will not delete directories unless you are superuser and |
| 5199 | the B<-U> flag is supplied to Perl. Even if these conditions are |
| 5200 | met, be warned that unlinking a directory can inflict damage on your |
| 5201 | filesystem. Use C<rmdir> instead. |
| 5202 | |
| 5203 | If LIST is omitted, uses C<$_>. |
| 5204 | |
| 5205 | =item unpack TEMPLATE,EXPR |
| 5206 | |
| 5207 | C<unpack> does the reverse of C<pack>: it takes a string |
| 5208 | and expands it out into a list of values. |
| 5209 | (In scalar context, it returns merely the first value produced.) |
| 5210 | |
| 5211 | The string is broken into chunks described by the TEMPLATE. Each chunk |
| 5212 | is converted separately to a value. Typically, either the string is a result |
| 5213 | of C<pack>, or the bytes of the string represent a C structure of some |
| 5214 | kind. |
| 5215 | |
| 5216 | The TEMPLATE has the same format as in the C<pack> function. |
| 5217 | Here's a subroutine that does substring: |
| 5218 | |
| 5219 | sub substr { |
| 5220 | my($what,$where,$howmuch) = @_; |
| 5221 | unpack("x$where a$howmuch", $what); |
| 5222 | } |
| 5223 | |
| 5224 | and then there's |
| 5225 | |
| 5226 | sub ordinal { unpack("c",$_[0]); } # same as ord() |
| 5227 | |
| 5228 | In addition to fields allowed in pack(), you may prefix a field with |
| 5229 | a %<number> to indicate that |
| 5230 | you want a <number>-bit checksum of the items instead of the items |
| 5231 | themselves. Default is a 16-bit checksum. Checksum is calculated by |
| 5232 | summing numeric values of expanded values (for string fields the sum of |
| 5233 | C<ord($char)> is taken, for bit fields the sum of zeroes and ones). |
| 5234 | |
| 5235 | For example, the following |
| 5236 | computes the same number as the System V sum program: |
| 5237 | |
| 5238 | $checksum = do { |
| 5239 | local $/; # slurp! |
| 5240 | unpack("%32C*",<>) % 65535; |
| 5241 | }; |
| 5242 | |
| 5243 | The following efficiently counts the number of set bits in a bit vector: |
| 5244 | |
| 5245 | $setbits = unpack("%32b*", $selectmask); |
| 5246 | |
| 5247 | The C<p> and C<P> formats should be used with care. Since Perl |
| 5248 | has no way of checking whether the value passed to C<unpack()> |
| 5249 | corresponds to a valid memory location, passing a pointer value that's |
| 5250 | not known to be valid is likely to have disastrous consequences. |
| 5251 | |
| 5252 | If the repeat count of a field is larger than what the remainder of |
| 5253 | the input string allows, repeat count is decreased. If the input string |
| 5254 | is longer than one described by the TEMPLATE, the rest is ignored. |
| 5255 | |
| 5256 | See L</pack> for more examples and notes. |
| 5257 | |
| 5258 | =item untie VARIABLE |
| 5259 | |
| 5260 | Breaks the binding between a variable and a package. (See C<tie>.) |
| 5261 | |
| 5262 | =item unshift ARRAY,LIST |
| 5263 | |
| 5264 | Does the opposite of a C<shift>. Or the opposite of a C<push>, |
| 5265 | depending on how you look at it. Prepends list to the front of the |
| 5266 | array, and returns the new number of elements in the array. |
| 5267 | |
| 5268 | unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/; |
| 5269 | |
| 5270 | Note the LIST is prepended whole, not one element at a time, so the |
| 5271 | prepended elements stay in the same order. Use C<reverse> to do the |
| 5272 | reverse. |
| 5273 | |
| 5274 | =item use Module VERSION LIST |
| 5275 | |
| 5276 | =item use Module VERSION |
| 5277 | |
| 5278 | =item use Module LIST |
| 5279 | |
| 5280 | =item use Module |
| 5281 | |
| 5282 | =item use VERSION |
| 5283 | |
| 5284 | Imports some semantics into the current package from the named module, |
| 5285 | generally by aliasing certain subroutine or variable names into your |
| 5286 | package. It is exactly equivalent to |
| 5287 | |
| 5288 | BEGIN { require Module; import Module LIST; } |
| 5289 | |
| 5290 | except that Module I<must> be a bareword. |
| 5291 | |
| 5292 | VERSION, which can be specified as a literal of the form v5.6.1, demands |
| 5293 | that the current version of Perl (C<$^V> or $PERL_VERSION) be at least |
| 5294 | as recent as that version. (For compatibility with older versions of Perl, |
| 5295 | a numeric literal will also be interpreted as VERSION.) If the version |
| 5296 | of the running Perl interpreter is less than VERSION, then an error |
| 5297 | message is printed and Perl exits immediately without attempting to |
| 5298 | parse the rest of the file. Compare with L</require>, which can do a |
| 5299 | similar check at run time. |
| 5300 | |
| 5301 | use v5.6.1; # compile time version check |
| 5302 | use 5.6.1; # ditto |
| 5303 | use 5.005_03; # float version allowed for compatibility |
| 5304 | |
| 5305 | This is often useful if you need to check the current Perl version before |
| 5306 | C<use>ing library modules that have changed in incompatible ways from |
| 5307 | older versions of Perl. (We try not to do this more than we have to.) |
| 5308 | |
| 5309 | The C<BEGIN> forces the C<require> and C<import> to happen at compile time. The |
| 5310 | C<require> makes sure the module is loaded into memory if it hasn't been |
| 5311 | yet. The C<import> is not a builtin--it's just an ordinary static method |
| 5312 | call into the C<Module> package to tell the module to import the list of |
| 5313 | features back into the current package. The module can implement its |
| 5314 | C<import> method any way it likes, though most modules just choose to |
| 5315 | derive their C<import> method via inheritance from the C<Exporter> class that |
| 5316 | is defined in the C<Exporter> module. See L<Exporter>. If no C<import> |
| 5317 | method can be found then the call is skipped. |
| 5318 | |
| 5319 | If you don't want your namespace altered, explicitly supply an empty list: |
| 5320 | |
| 5321 | use Module (); |
| 5322 | |
| 5323 | That is exactly equivalent to |
| 5324 | |
| 5325 | BEGIN { require Module } |
| 5326 | |
| 5327 | If the VERSION argument is present between Module and LIST, then the |
| 5328 | C<use> will call the VERSION method in class Module with the given |
| 5329 | version as an argument. The default VERSION method, inherited from |
| 5330 | the UNIVERSAL class, croaks if the given version is larger than the |
| 5331 | value of the variable C<$Module::VERSION>. |
| 5332 | |
| 5333 | Again, there is a distinction between omitting LIST (C<import> called |
| 5334 | with no arguments) and an explicit empty LIST C<()> (C<import> not |
| 5335 | called). Note that there is no comma after VERSION! |
| 5336 | |
| 5337 | Because this is a wide-open interface, pragmas (compiler directives) |
| 5338 | are also implemented this way. Currently implemented pragmas are: |
| 5339 | |
| 5340 | use integer; |
| 5341 | use diagnostics; |
| 5342 | use sigtrap qw(SEGV BUS); |
| 5343 | use strict qw(subs vars refs); |
| 5344 | use subs qw(afunc blurfl); |
| 5345 | use warnings qw(all); |
| 5346 | |
| 5347 | Some of these pseudo-modules import semantics into the current |
| 5348 | block scope (like C<strict> or C<integer>, unlike ordinary modules, |
| 5349 | which import symbols into the current package (which are effective |
| 5350 | through the end of the file). |
| 5351 | |
| 5352 | There's a corresponding C<no> command that unimports meanings imported |
| 5353 | by C<use>, i.e., it calls C<unimport Module LIST> instead of C<import>. |
| 5354 | |
| 5355 | no integer; |
| 5356 | no strict 'refs'; |
| 5357 | no warnings; |
| 5358 | |
| 5359 | If no C<unimport> method can be found the call fails with a fatal error. |
| 5360 | |
| 5361 | See L<perlmod> for a list of standard modules and pragmas. |
| 5362 | |
| 5363 | =item utime LIST |
| 5364 | |
| 5365 | Changes the access and modification times on each file of a list of |
| 5366 | files. The first two elements of the list must be the NUMERICAL access |
| 5367 | and modification times, in that order. Returns the number of files |
| 5368 | successfully changed. The inode change time of each file is set |
| 5369 | to the current time. This code has the same effect as the C<touch> |
| 5370 | command if the files already exist: |
| 5371 | |
| 5372 | #!/usr/bin/perl |
| 5373 | $now = time; |
| 5374 | utime $now, $now, @ARGV; |
| 5375 | |
| 5376 | =item values HASH |
| 5377 | |
| 5378 | Returns a list consisting of all the values of the named hash. (In a |
| 5379 | scalar context, returns the number of values.) The values are |
| 5380 | returned in an apparently random order. The actual random order is |
| 5381 | subject to change in future versions of perl, but it is guaranteed to |
| 5382 | be the same order as either the C<keys> or C<each> function would |
| 5383 | produce on the same (unmodified) hash. |
| 5384 | |
| 5385 | Note that you cannot modify the values of a hash this way, because the |
| 5386 | returned list is just a copy. You need to use a hash slice for that, |
| 5387 | since it's lvaluable in a way that values() is not. |
| 5388 | |
| 5389 | for (values %hash) { s/foo/bar/g } # FAILS! |
| 5390 | for (@hash{keys %hash}) { s/foo/bar/g } # ok |
| 5391 | |
| 5392 | As a side effect, calling values() resets the HASH's internal iterator. |
| 5393 | See also C<keys>, C<each>, and C<sort>. |
| 5394 | |
| 5395 | =item vec EXPR,OFFSET,BITS |
| 5396 | |
| 5397 | Treats the string in EXPR as a bit vector made up of elements of |
| 5398 | width BITS, and returns the value of the element specified by OFFSET |
| 5399 | as an unsigned integer. BITS therefore specifies the number of bits |
| 5400 | that are reserved for each element in the bit vector. This must |
| 5401 | be a power of two from 1 to 32 (or 64, if your platform supports |
| 5402 | that). |
| 5403 | |
| 5404 | If BITS is 8, "elements" coincide with bytes of the input string. |
| 5405 | |
| 5406 | If BITS is 16 or more, bytes of the input string are grouped into chunks |
| 5407 | of size BITS/8, and each group is converted to a number as with |
| 5408 | pack()/unpack() with big-endian formats C<n>/C<N> (and analoguously |
| 5409 | for BITS==64). See L<"pack"> for details. |
| 5410 | |
| 5411 | If bits is 4 or less, the string is broken into bytes, then the bits |
| 5412 | of each byte are broken into 8/BITS groups. Bits of a byte are |
| 5413 | numbered in a little-endian-ish way, as in C<0x01>, C<0x02>, |
| 5414 | C<0x04>, C<0x08>, C<0x10>, C<0x20>, C<0x40>, C<0x80>. For example, |
| 5415 | breaking the single input byte C<chr(0x36)> into two groups gives a list |
| 5416 | C<(0x6, 0x3)>; breaking it into 4 groups gives C<(0x2, 0x1, 0x3, 0x0)>. |
| 5417 | |
| 5418 | C<vec> may also be assigned to, in which case parentheses are needed |
| 5419 | to give the expression the correct precedence as in |
| 5420 | |
| 5421 | vec($image, $max_x * $x + $y, 8) = 3; |
| 5422 | |
| 5423 | If the selected element is off the end of the string, the value 0 is |
| 5424 | returned. If an element off the end of the string is written to, |
| 5425 | Perl will first extend the string with sufficiently many zero bytes. |
| 5426 | |
| 5427 | Strings created with C<vec> can also be manipulated with the logical |
| 5428 | operators C<|>, C<&>, C<^>, and C<~>. These operators will assume a bit |
| 5429 | vector operation is desired when both operands are strings. |
| 5430 | See L<perlop/"Bitwise String Operators">. |
| 5431 | |
| 5432 | The following code will build up an ASCII string saying C<'PerlPerlPerl'>. |
| 5433 | The comments show the string after each step. Note that this code works |
| 5434 | in the same way on big-endian or little-endian machines. |
| 5435 | |
| 5436 | my $foo = ''; |
| 5437 | vec($foo, 0, 32) = 0x5065726C; # 'Perl' |
| 5438 | |
| 5439 | # $foo eq "Perl" eq "\x50\x65\x72\x6C", 32 bits |
| 5440 | print vec($foo, 0, 8); # prints 80 == 0x50 == ord('P') |
| 5441 | |
| 5442 | vec($foo, 2, 16) = 0x5065; # 'PerlPe' |
| 5443 | vec($foo, 3, 16) = 0x726C; # 'PerlPerl' |
| 5444 | vec($foo, 8, 8) = 0x50; # 'PerlPerlP' |
| 5445 | vec($foo, 9, 8) = 0x65; # 'PerlPerlPe' |
| 5446 | vec($foo, 20, 4) = 2; # 'PerlPerlPe' . "\x02" |
| 5447 | vec($foo, 21, 4) = 7; # 'PerlPerlPer' |
| 5448 | # 'r' is "\x72" |
| 5449 | vec($foo, 45, 2) = 3; # 'PerlPerlPer' . "\x0c" |
| 5450 | vec($foo, 93, 1) = 1; # 'PerlPerlPer' . "\x2c" |
| 5451 | vec($foo, 94, 1) = 1; # 'PerlPerlPerl' |
| 5452 | # 'l' is "\x6c" |
| 5453 | |
| 5454 | To transform a bit vector into a string or list of 0's and 1's, use these: |
| 5455 | |
| 5456 | $bits = unpack("b*", $vector); |
| 5457 | @bits = split(//, unpack("b*", $vector)); |
| 5458 | |
| 5459 | If you know the exact length in bits, it can be used in place of the C<*>. |
| 5460 | |
| 5461 | Here is an example to illustrate how the bits actually fall in place: |
| 5462 | |
| 5463 | #!/usr/bin/perl -wl |
| 5464 | |
| 5465 | print <<'EOT'; |
| 5466 | 0 1 2 3 |
| 5467 | unpack("V",$_) 01234567890123456789012345678901 |
| 5468 | ------------------------------------------------------------------ |
| 5469 | EOT |
| 5470 | |
| 5471 | for $w (0..3) { |
| 5472 | $width = 2**$w; |
| 5473 | for ($shift=0; $shift < $width; ++$shift) { |
| 5474 | for ($off=0; $off < 32/$width; ++$off) { |
| 5475 | $str = pack("B*", "0"x32); |
| 5476 | $bits = (1<<$shift); |
| 5477 | vec($str, $off, $width) = $bits; |
| 5478 | $res = unpack("b*",$str); |
| 5479 | $val = unpack("V", $str); |
| 5480 | write; |
| 5481 | } |
| 5482 | } |
| 5483 | } |
| 5484 | |
| 5485 | format STDOUT = |
| 5486 | vec($_,@#,@#) = @<< == @######### @>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
| 5487 | $off, $width, $bits, $val, $res |
| 5488 | . |
| 5489 | __END__ |
| 5490 | |
| 5491 | Regardless of the machine architecture on which it is run, the above |
| 5492 | example should print the following table: |
| 5493 | |
| 5494 | 0 1 2 3 |
| 5495 | unpack("V",$_) 01234567890123456789012345678901 |
| 5496 | ------------------------------------------------------------------ |
| 5497 | vec($_, 0, 1) = 1 == 1 10000000000000000000000000000000 |
| 5498 | vec($_, 1, 1) = 1 == 2 01000000000000000000000000000000 |
| 5499 | vec($_, 2, 1) = 1 == 4 00100000000000000000000000000000 |
| 5500 | vec($_, 3, 1) = 1 == 8 00010000000000000000000000000000 |
| 5501 | vec($_, 4, 1) = 1 == 16 00001000000000000000000000000000 |
| 5502 | vec($_, 5, 1) = 1 == 32 00000100000000000000000000000000 |
| 5503 | vec($_, 6, 1) = 1 == 64 00000010000000000000000000000000 |
| 5504 | vec($_, 7, 1) = 1 == 128 00000001000000000000000000000000 |
| 5505 | vec($_, 8, 1) = 1 == 256 00000000100000000000000000000000 |
| 5506 | vec($_, 9, 1) = 1 == 512 00000000010000000000000000000000 |
| 5507 | vec($_,10, 1) = 1 == 1024 00000000001000000000000000000000 |
| 5508 | vec($_,11, 1) = 1 == 2048 00000000000100000000000000000000 |
| 5509 | vec($_,12, 1) = 1 == 4096 00000000000010000000000000000000 |
| 5510 | vec($_,13, 1) = 1 == 8192 00000000000001000000000000000000 |
| 5511 | vec($_,14, 1) = 1 == 16384 00000000000000100000000000000000 |
| 5512 | vec($_,15, 1) = 1 == 32768 00000000000000010000000000000000 |
| 5513 | vec($_,16, 1) = 1 == 65536 00000000000000001000000000000000 |
| 5514 | vec($_,17, 1) = 1 == 131072 00000000000000000100000000000000 |
| 5515 | vec($_,18, 1) = 1 == 262144 00000000000000000010000000000000 |
| 5516 | vec($_,19, 1) = 1 == 524288 00000000000000000001000000000000 |
| 5517 | vec($_,20, 1) = 1 == 1048576 00000000000000000000100000000000 |
| 5518 | vec($_,21, 1) = 1 == 2097152 00000000000000000000010000000000 |
| 5519 | vec($_,22, 1) = 1 == 4194304 00000000000000000000001000000000 |
| 5520 | vec($_,23, 1) = 1 == 8388608 00000000000000000000000100000000 |
| 5521 | vec($_,24, 1) = 1 == 16777216 00000000000000000000000010000000 |
| 5522 | vec($_,25, 1) = 1 == 33554432 00000000000000000000000001000000 |
| 5523 | vec($_,26, 1) = 1 == 67108864 00000000000000000000000000100000 |
| 5524 | vec($_,27, 1) = 1 == 134217728 00000000000000000000000000010000 |
| 5525 | vec($_,28, 1) = 1 == 268435456 00000000000000000000000000001000 |
| 5526 | vec($_,29, 1) = 1 == 536870912 00000000000000000000000000000100 |
| 5527 | vec($_,30, 1) = 1 == 1073741824 00000000000000000000000000000010 |
| 5528 | vec($_,31, 1) = 1 == 2147483648 00000000000000000000000000000001 |
| 5529 | vec($_, 0, 2) = 1 == 1 10000000000000000000000000000000 |
| 5530 | vec($_, 1, 2) = 1 == 4 00100000000000000000000000000000 |
| 5531 | vec($_, 2, 2) = 1 == 16 00001000000000000000000000000000 |
| 5532 | vec($_, 3, 2) = 1 == 64 00000010000000000000000000000000 |
| 5533 | vec($_, 4, 2) = 1 == 256 00000000100000000000000000000000 |
| 5534 | vec($_, 5, 2) = 1 == 1024 00000000001000000000000000000000 |
| 5535 | vec($_, 6, 2) = 1 == 4096 00000000000010000000000000000000 |
| 5536 | vec($_, 7, 2) = 1 == 16384 00000000000000100000000000000000 |
| 5537 | vec($_, 8, 2) = 1 == 65536 00000000000000001000000000000000 |
| 5538 | vec($_, 9, 2) = 1 == 262144 00000000000000000010000000000000 |
| 5539 | vec($_,10, 2) = 1 == 1048576 00000000000000000000100000000000 |
| 5540 | vec($_,11, 2) = 1 == 4194304 00000000000000000000001000000000 |
| 5541 | vec($_,12, 2) = 1 == 16777216 00000000000000000000000010000000 |
| 5542 | vec($_,13, 2) = 1 == 67108864 00000000000000000000000000100000 |
| 5543 | vec($_,14, 2) = 1 == 268435456 00000000000000000000000000001000 |
| 5544 | vec($_,15, 2) = 1 == 1073741824 00000000000000000000000000000010 |
| 5545 | vec($_, 0, 2) = 2 == 2 01000000000000000000000000000000 |
| 5546 | vec($_, 1, 2) = 2 == 8 00010000000000000000000000000000 |
| 5547 | vec($_, 2, 2) = 2 == 32 00000100000000000000000000000000 |
| 5548 | vec($_, 3, 2) = 2 == 128 00000001000000000000000000000000 |
| 5549 | vec($_, 4, 2) = 2 == 512 00000000010000000000000000000000 |
| 5550 | vec($_, 5, 2) = 2 == 2048 00000000000100000000000000000000 |
| 5551 | vec($_, 6, 2) = 2 == 8192 00000000000001000000000000000000 |
| 5552 | vec($_, 7, 2) = 2 == 32768 00000000000000010000000000000000 |
| 5553 | vec($_, 8, 2) = 2 == 131072 00000000000000000100000000000000 |
| 5554 | vec($_, 9, 2) = 2 == 524288 00000000000000000001000000000000 |
| 5555 | vec($_,10, 2) = 2 == 2097152 00000000000000000000010000000000 |
| 5556 | vec($_,11, 2) = 2 == 8388608 00000000000000000000000100000000 |
| 5557 | vec($_,12, 2) = 2 == 33554432 00000000000000000000000001000000 |
| 5558 | vec($_,13, 2) = 2 == 134217728 00000000000000000000000000010000 |
| 5559 | vec($_,14, 2) = 2 == 536870912 00000000000000000000000000000100 |
| 5560 | vec($_,15, 2) = 2 == 2147483648 00000000000000000000000000000001 |
| 5561 | vec($_, 0, 4) = 1 == 1 10000000000000000000000000000000 |
| 5562 | vec($_, 1, 4) = 1 == 16 00001000000000000000000000000000 |
| 5563 | vec($_, 2, 4) = 1 == 256 00000000100000000000000000000000 |
| 5564 | vec($_, 3, 4) = 1 == 4096 00000000000010000000000000000000 |
| 5565 | vec($_, 4, 4) = 1 == 65536 00000000000000001000000000000000 |
| 5566 | vec($_, 5, 4) = 1 == 1048576 00000000000000000000100000000000 |
| 5567 | vec($_, 6, 4) = 1 == 16777216 00000000000000000000000010000000 |
| 5568 | vec($_, 7, 4) = 1 == 268435456 00000000000000000000000000001000 |
| 5569 | vec($_, 0, 4) = 2 == 2 01000000000000000000000000000000 |
| 5570 | vec($_, 1, 4) = 2 == 32 00000100000000000000000000000000 |
| 5571 | vec($_, 2, 4) = 2 == 512 00000000010000000000000000000000 |
| 5572 | vec($_, 3, 4) = 2 == 8192 00000000000001000000000000000000 |
| 5573 | vec($_, 4, 4) = 2 == 131072 00000000000000000100000000000000 |
| 5574 | vec($_, 5, 4) = 2 == 2097152 00000000000000000000010000000000 |
| 5575 | vec($_, 6, 4) = 2 == 33554432 00000000000000000000000001000000 |
| 5576 | vec($_, 7, 4) = 2 == 536870912 00000000000000000000000000000100 |
| 5577 | vec($_, 0, 4) = 4 == 4 00100000000000000000000000000000 |
| 5578 | vec($_, 1, 4) = 4 == 64 00000010000000000000000000000000 |
| 5579 | vec($_, 2, 4) = 4 == 1024 00000000001000000000000000000000 |
| 5580 | vec($_, 3, 4) = 4 == 16384 00000000000000100000000000000000 |
| 5581 | vec($_, 4, 4) = 4 == 262144 00000000000000000010000000000000 |
| 5582 | vec($_, 5, 4) = 4 == 4194304 00000000000000000000001000000000 |
| 5583 | vec($_, 6, 4) = 4 == 67108864 00000000000000000000000000100000 |
| 5584 | vec($_, 7, 4) = 4 == 1073741824 00000000000000000000000000000010 |
| 5585 | vec($_, 0, 4) = 8 == 8 00010000000000000000000000000000 |
| 5586 | vec($_, 1, 4) = 8 == 128 00000001000000000000000000000000 |
| 5587 | vec($_, 2, 4) = 8 == 2048 00000000000100000000000000000000 |
| 5588 | vec($_, 3, 4) = 8 == 32768 00000000000000010000000000000000 |
| 5589 | vec($_, 4, 4) = 8 == 524288 00000000000000000001000000000000 |
| 5590 | vec($_, 5, 4) = 8 == 8388608 00000000000000000000000100000000 |
| 5591 | vec($_, 6, 4) = 8 == 134217728 00000000000000000000000000010000 |
| 5592 | vec($_, 7, 4) = 8 == 2147483648 00000000000000000000000000000001 |
| 5593 | vec($_, 0, 8) = 1 == 1 10000000000000000000000000000000 |
| 5594 | vec($_, 1, 8) = 1 == 256 00000000100000000000000000000000 |
| 5595 | vec($_, 2, 8) = 1 == 65536 00000000000000001000000000000000 |
| 5596 | vec($_, 3, 8) = 1 == 16777216 00000000000000000000000010000000 |
| 5597 | vec($_, 0, 8) = 2 == 2 01000000000000000000000000000000 |
| 5598 | vec($_, 1, 8) = 2 == 512 00000000010000000000000000000000 |
| 5599 | vec($_, 2, 8) = 2 == 131072 00000000000000000100000000000000 |
| 5600 | vec($_, 3, 8) = 2 == 33554432 00000000000000000000000001000000 |
| 5601 | vec($_, 0, 8) = 4 == 4 00100000000000000000000000000000 |
| 5602 | vec($_, 1, 8) = 4 == 1024 00000000001000000000000000000000 |
| 5603 | vec($_, 2, 8) = 4 == 262144 00000000000000000010000000000000 |
| 5604 | vec($_, 3, 8) = 4 == 67108864 00000000000000000000000000100000 |
| 5605 | vec($_, 0, 8) = 8 == 8 00010000000000000000000000000000 |
| 5606 | vec($_, 1, 8) = 8 == 2048 00000000000100000000000000000000 |
| 5607 | vec($_, 2, 8) = 8 == 524288 00000000000000000001000000000000 |
| 5608 | vec($_, 3, 8) = 8 == 134217728 00000000000000000000000000010000 |
| 5609 | vec($_, 0, 8) = 16 == 16 00001000000000000000000000000000 |
| 5610 | vec($_, 1, 8) = 16 == 4096 00000000000010000000000000000000 |
| 5611 | vec($_, 2, 8) = 16 == 1048576 00000000000000000000100000000000 |
| 5612 | vec($_, 3, 8) = 16 == 268435456 00000000000000000000000000001000 |
| 5613 | vec($_, 0, 8) = 32 == 32 00000100000000000000000000000000 |
| 5614 | vec($_, 1, 8) = 32 == 8192 00000000000001000000000000000000 |
| 5615 | vec($_, 2, 8) = 32 == 2097152 00000000000000000000010000000000 |
| 5616 | vec($_, 3, 8) = 32 == 536870912 00000000000000000000000000000100 |
| 5617 | vec($_, 0, 8) = 64 == 64 00000010000000000000000000000000 |
| 5618 | vec($_, 1, 8) = 64 == 16384 00000000000000100000000000000000 |
| 5619 | vec($_, 2, 8) = 64 == 4194304 00000000000000000000001000000000 |
| 5620 | vec($_, 3, 8) = 64 == 1073741824 00000000000000000000000000000010 |
| 5621 | vec($_, 0, 8) = 128 == 128 00000001000000000000000000000000 |
| 5622 | vec($_, 1, 8) = 128 == 32768 00000000000000010000000000000000 |
| 5623 | vec($_, 2, 8) = 128 == 8388608 00000000000000000000000100000000 |
| 5624 | vec($_, 3, 8) = 128 == 2147483648 00000000000000000000000000000001 |
| 5625 | |
| 5626 | =item wait |
| 5627 | |
| 5628 | Behaves like the wait(2) system call on your system: it waits for a child |
| 5629 | process to terminate and returns the pid of the deceased process, or |
| 5630 | C<-1> if there are no child processes. The status is returned in C<$?>. |
| 5631 | Note that a return value of C<-1> could mean that child processes are |
| 5632 | being automatically reaped, as described in L<perlipc>. |
| 5633 | |
| 5634 | =item waitpid PID,FLAGS |
| 5635 | |
| 5636 | Waits for a particular child process to terminate and returns the pid of |
| 5637 | the deceased process, or C<-1> if there is no such child process. On some |
| 5638 | systems, a value of 0 indicates that there are processes still running. |
| 5639 | The status is returned in C<$?>. If you say |
| 5640 | |
| 5641 | use POSIX ":sys_wait_h"; |
| 5642 | #... |
| 5643 | do { |
| 5644 | $kid = waitpid(-1,&WNOHANG); |
| 5645 | } until $kid == -1; |
| 5646 | |
| 5647 | then you can do a non-blocking wait for all pending zombie processes. |
| 5648 | Non-blocking wait is available on machines supporting either the |
| 5649 | waitpid(2) or wait4(2) system calls. However, waiting for a particular |
| 5650 | pid with FLAGS of C<0> is implemented everywhere. (Perl emulates the |
| 5651 | system call by remembering the status values of processes that have |
| 5652 | exited but have not been harvested by the Perl script yet.) |
| 5653 | |
| 5654 | Note that on some systems, a return value of C<-1> could mean that child |
| 5655 | processes are being automatically reaped. See L<perlipc> for details, |
| 5656 | and for other examples. |
| 5657 | |
| 5658 | =item wantarray |
| 5659 | |
| 5660 | Returns true if the context of the currently executing subroutine is |
| 5661 | looking for a list value. Returns false if the context is looking |
| 5662 | for a scalar. Returns the undefined value if the context is looking |
| 5663 | for no value (void context). |
| 5664 | |
| 5665 | return unless defined wantarray; # don't bother doing more |
| 5666 | my @a = complex_calculation(); |
| 5667 | return wantarray ? @a : "@a"; |
| 5668 | |
| 5669 | This function should have been named wantlist() instead. |
| 5670 | |
| 5671 | =item warn LIST |
| 5672 | |
| 5673 | Produces a message on STDERR just like C<die>, but doesn't exit or throw |
| 5674 | an exception. |
| 5675 | |
| 5676 | If LIST is empty and C<$@> already contains a value (typically from a |
| 5677 | previous eval) that value is used after appending C<"\t...caught"> |
| 5678 | to C<$@>. This is useful for staying almost, but not entirely similar to |
| 5679 | C<die>. |
| 5680 | |
| 5681 | If C<$@> is empty then the string C<"Warning: Something's wrong"> is used. |
| 5682 | |
| 5683 | No message is printed if there is a C<$SIG{__WARN__}> handler |
| 5684 | installed. It is the handler's responsibility to deal with the message |
| 5685 | as it sees fit (like, for instance, converting it into a C<die>). Most |
| 5686 | handlers must therefore make arrangements to actually display the |
| 5687 | warnings that they are not prepared to deal with, by calling C<warn> |
| 5688 | again in the handler. Note that this is quite safe and will not |
| 5689 | produce an endless loop, since C<__WARN__> hooks are not called from |
| 5690 | inside one. |
| 5691 | |
| 5692 | You will find this behavior is slightly different from that of |
| 5693 | C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can |
| 5694 | instead call C<die> again to change it). |
| 5695 | |
| 5696 | Using a C<__WARN__> handler provides a powerful way to silence all |
| 5697 | warnings (even the so-called mandatory ones). An example: |
| 5698 | |
| 5699 | # wipe out *all* compile-time warnings |
| 5700 | BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } } |
| 5701 | my $foo = 10; |
| 5702 | my $foo = 20; # no warning about duplicate my $foo, |
| 5703 | # but hey, you asked for it! |
| 5704 | # no compile-time or run-time warnings before here |
| 5705 | $DOWARN = 1; |
| 5706 | |
| 5707 | # run-time warnings enabled after here |
| 5708 | warn "\$foo is alive and $foo!"; # does show up |
| 5709 | |
| 5710 | See L<perlvar> for details on setting C<%SIG> entries, and for more |
| 5711 | examples. See the Carp module for other kinds of warnings using its |
| 5712 | carp() and cluck() functions. |
| 5713 | |
| 5714 | =item write FILEHANDLE |
| 5715 | |
| 5716 | =item write EXPR |
| 5717 | |
| 5718 | =item write |
| 5719 | |
| 5720 | Writes a formatted record (possibly multi-line) to the specified FILEHANDLE, |
| 5721 | using the format associated with that file. By default the format for |
| 5722 | a file is the one having the same name as the filehandle, but the |
| 5723 | format for the current output channel (see the C<select> function) may be set |
| 5724 | explicitly by assigning the name of the format to the C<$~> variable. |
| 5725 | |
| 5726 | Top of form processing is handled automatically: if there is |
| 5727 | insufficient room on the current page for the formatted record, the |
| 5728 | page is advanced by writing a form feed, a special top-of-page format |
| 5729 | is used to format the new page header, and then the record is written. |
| 5730 | By default the top-of-page format is the name of the filehandle with |
| 5731 | "_TOP" appended, but it may be dynamically set to the format of your |
| 5732 | choice by assigning the name to the C<$^> variable while the filehandle is |
| 5733 | selected. The number of lines remaining on the current page is in |
| 5734 | variable C<$->, which can be set to C<0> to force a new page. |
| 5735 | |
| 5736 | If FILEHANDLE is unspecified, output goes to the current default output |
| 5737 | channel, which starts out as STDOUT but may be changed by the |
| 5738 | C<select> operator. If the FILEHANDLE is an EXPR, then the expression |
| 5739 | is evaluated and the resulting string is used to look up the name of |
| 5740 | the FILEHANDLE at run time. For more on formats, see L<perlform>. |
| 5741 | |
| 5742 | Note that write is I<not> the opposite of C<read>. Unfortunately. |
| 5743 | |
| 5744 | =item y/// |
| 5745 | |
| 5746 | The transliteration operator. Same as C<tr///>. See L<perlop>. |
| 5747 | |
| 5748 | =back |