| 1 | =head1 NAME |
| 2 | X<regular expression> X<regex> X<regexp> |
| 3 | |
| 4 | perlre - Perl regular expressions |
| 5 | |
| 6 | =head1 DESCRIPTION |
| 7 | |
| 8 | This page describes the syntax of regular expressions in Perl. |
| 9 | |
| 10 | If you haven't used regular expressions before, a tutorial introduction |
| 11 | is available in L<perlretut>. If you know just a little about them, |
| 12 | a quick-start introduction is available in L<perlrequick>. |
| 13 | |
| 14 | Except for L</The Basics> section, this page assumes you are familiar |
| 15 | with regular expression basics, like what is a "pattern", what does it |
| 16 | look like, and how it is basically used. For a reference on how they |
| 17 | are used, plus various examples of the same, see discussions of C<m//>, |
| 18 | C<s///>, C<qr//> and C<"??"> in L<perlop/"Regexp Quote-Like Operators">. |
| 19 | |
| 20 | New in v5.22, L<C<use re 'strict'>|re/'strict' mode> applies stricter |
| 21 | rules than otherwise when compiling regular expression patterns. It can |
| 22 | find things that, while legal, may not be what you intended. |
| 23 | |
| 24 | =head2 The Basics |
| 25 | X<regular expression, version 8> X<regex, version 8> X<regexp, version 8> |
| 26 | |
| 27 | Regular expressions are strings with the very particular syntax and |
| 28 | meaning described in this document and auxiliary documents referred to |
| 29 | by this one. The strings are called "patterns". Patterns are used to |
| 30 | determine if some other string, called the "target", has (or doesn't |
| 31 | have) the characteristics specified by the pattern. We call this |
| 32 | "matching" the target string against the pattern. Usually the match is |
| 33 | done by having the target be the first operand, and the pattern be the |
| 34 | second operand, of one of the two binary operators C<=~> and C<!~>, |
| 35 | listed in L<perlop/Binding Operators>; and the pattern will have been |
| 36 | converted from an ordinary string by one of the operators in |
| 37 | L<perlop/"Regexp Quote-Like Operators">, like so: |
| 38 | |
| 39 | $foo =~ m/abc/ |
| 40 | |
| 41 | This evaluates to true if and only if the string in the variable C<$foo> |
| 42 | contains somewhere in it, the sequence of characters "a", "b", then "c". |
| 43 | (The C<=~ m>, or match operator, is described in |
| 44 | L<perlop/m/PATTERN/msixpodualngc>.) |
| 45 | |
| 46 | Patterns that aren't already stored in some variable must be delimitted, |
| 47 | at both ends, by delimitter characters. These are often, as in the |
| 48 | example above, forward slashes, and the typical way a pattern is written |
| 49 | in documentation is with those slashes. In most cases, the delimitter |
| 50 | is the same character, fore and aft, but there are a few cases where a |
| 51 | character looks like it has a mirror-image mate, where the opening |
| 52 | version is the beginning delimiter, and the closing one is the ending |
| 53 | delimiter, like |
| 54 | |
| 55 | $foo =~ m<abc> |
| 56 | |
| 57 | Most times, the pattern is evaluated in double-quotish context, but it |
| 58 | is possible to choose delimiters to force single-quotish, like |
| 59 | |
| 60 | $foo =~ m'abc' |
| 61 | |
| 62 | If the pattern contains its delimiter within it, that delimiter must be |
| 63 | escaped. Prefixing it with a backslash (I<e.g.>, C<"/foo\/bar/">) |
| 64 | serves this purpose. |
| 65 | |
| 66 | Any single character in a pattern matches that same character in the |
| 67 | target string, unless the character is a I<metacharacter> with a special |
| 68 | meaning described in this document. A sequence of non-metacharacters |
| 69 | matches the same sequence in the target string, as we saw above with |
| 70 | C<m/abc/>. |
| 71 | |
| 72 | Only a few characters (all of them being ASCII punctuation characters) |
| 73 | are metacharacters. The most commonly used one is a dot C<".">, which |
| 74 | normally matches almost any character (including a dot itself). |
| 75 | |
| 76 | You can cause characters that normally function as metacharacters to be |
| 77 | interpreted literally by prefixing them with a C<"\">, just like the |
| 78 | pattern's delimiter must be escaped if it also occurs within the |
| 79 | pattern. Thus, C<"\."> matches just a literal dot, C<"."> instead of |
| 80 | its normal meaning. This means that the backslash is also a |
| 81 | metacharacter, so C<"\\"> matches a single C<"\">. And a sequence that |
| 82 | contains an escaped metacharacter matches the same sequence (but without |
| 83 | the escape) in the target string. So, the pattern C</blur\\fl/> would |
| 84 | match any target string that contains the sequence C<"blur\fl">. |
| 85 | |
| 86 | The metacharacter C<"|"> is used to match one thing or another. Thus |
| 87 | |
| 88 | $foo =~ m/this|that/ |
| 89 | |
| 90 | is TRUE if and only if C<$foo> contains either the sequence C<"this"> or |
| 91 | the sequence C<"that">. Like all metacharacters, prefixing the C<"|"> |
| 92 | with a backslash makes it match the plain punctuation character; in its |
| 93 | case, the VERTICAL LINE. |
| 94 | |
| 95 | $foo =~ m/this\|that/ |
| 96 | |
| 97 | is TRUE if and only if C<$foo> contains the sequence C<"this|that">. |
| 98 | |
| 99 | You aren't limited to just a single C<"|">. |
| 100 | |
| 101 | $foo =~ m/fee|fie|foe|fum/ |
| 102 | |
| 103 | is TRUE if and only if C<$foo> contains any of those 4 sequences from |
| 104 | the children's story "Jack and the Beanstalk". |
| 105 | |
| 106 | As you can see, the C<"|"> binds less tightly than a sequence of |
| 107 | ordinary characters. We can override this by using the grouping |
| 108 | metacharacters, the parentheses C<"("> and C<")">. |
| 109 | |
| 110 | $foo =~ m/th(is|at) thing/ |
| 111 | |
| 112 | is TRUE if and only if C<$foo> contains either the sequence S<C<"this |
| 113 | thing">> or the sequence S<C<"that thing">>. The portions of the string |
| 114 | that match the portions of the pattern enclosed in parentheses are |
| 115 | normally made available separately for use later in the pattern, |
| 116 | substitution, or program. This is called "capturing", and it can get |
| 117 | complicated. See L</Capture groups>. |
| 118 | |
| 119 | The first alternative includes everything from the last pattern |
| 120 | delimiter (C<"(">, C<"(?:"> (described later), I<etc>. or the beginning |
| 121 | of the pattern) up to the first C<"|">, and the last alternative |
| 122 | contains everything from the last C<"|"> to the next closing pattern |
| 123 | delimiter. That's why it's common practice to include alternatives in |
| 124 | parentheses: to minimize confusion about where they start and end. |
| 125 | |
| 126 | Alternatives are tried from left to right, so the first |
| 127 | alternative found for which the entire expression matches, is the one that |
| 128 | is chosen. This means that alternatives are not necessarily greedy. For |
| 129 | example: when matching C<foo|foot> against C<"barefoot">, only the C<"foo"> |
| 130 | part will match, as that is the first alternative tried, and it successfully |
| 131 | matches the target string. (This might not seem important, but it is |
| 132 | important when you are capturing matched text using parentheses.) |
| 133 | |
| 134 | Besides taking away the special meaning of a metacharacter, a prefixed |
| 135 | backslash changes some letter and digit characters away from matching |
| 136 | just themselves to instead have special meaning. These are called |
| 137 | "escape sequences", and all such are described in L<perlrebackslash>. A |
| 138 | backslash sequence (of a letter or digit) that doesn't currently have |
| 139 | special meaning to Perl will raise a warning if warnings are enabled, |
| 140 | as those are reserved for potential future use. |
| 141 | |
| 142 | One such sequence is C<\b>, which matches a boundary of some sort. |
| 143 | C<\b{wb}> and a few others give specialized types of boundaries. |
| 144 | (They are all described in detail starting at |
| 145 | L<perlrebackslash/\b{}, \b, \B{}, \B>.) Note that these don't match |
| 146 | characters, but the zero-width spaces between characters. They are an |
| 147 | example of a L<zero-width assertion|/Assertions>. Consider again, |
| 148 | |
| 149 | $foo =~ m/fee|fie|foe|fum/ |
| 150 | |
| 151 | It evaluates to TRUE if, besides those 4 words, any of the sequences |
| 152 | "feed", "field", "Defoe", "fume", and many others are in C<$foo>. By |
| 153 | judicious use of C<\b> (or better (because it is designed to handle |
| 154 | natural language) C<\b{wb}>), we can make sure that only the Giant's |
| 155 | words are matched: |
| 156 | |
| 157 | $foo =~ m/\b(fee|fie|foe|fum)\b/ |
| 158 | $foo =~ m/\b{wb}(fee|fie|foe|fum)\b{wb}/ |
| 159 | |
| 160 | The final example shows that the characters C<"{"> and C<"}"> are |
| 161 | metacharacters. |
| 162 | |
| 163 | Another use for escape sequences is to specify characters that cannot |
| 164 | (or which you prefer not to) be written literally. These are described |
| 165 | in detail in L<perlrebackslash/Character Escapes>, but the next three |
| 166 | paragraphs briefly describe some of them. |
| 167 | |
| 168 | Various control characters can be written in C language style: C<"\n"> |
| 169 | matches a newline, C<"\t"> a tab, C<"\r"> a carriage return, C<"\f"> a |
| 170 | form feed, I<etc>. |
| 171 | |
| 172 | More generally, C<\I<nnn>>, where I<nnn> is a string of three octal |
| 173 | digits, matches the character whose native code point is I<nnn>. You |
| 174 | can easily run into trouble if you don't have exactly three digits. So |
| 175 | always use three, or since Perl 5.14, you can use C<\o{...}> to specify |
| 176 | any number of octal digits. |
| 177 | |
| 178 | Similarly, C<\xI<nn>>, where I<nn> are hexadecimal digits, matches the |
| 179 | character whose native ordinal is I<nn>. Again, not using exactly two |
| 180 | digits is a recipe for disaster, but you can use C<\x{...}> to specify |
| 181 | any number of hex digits. |
| 182 | |
| 183 | Besides being a metacharacter, the C<"."> is an example of a "character |
| 184 | class", something that can match any single character of a given set of |
| 185 | them. In its case, the set is just about all possible characters. Perl |
| 186 | predefines several character classes besides the C<".">; there is a |
| 187 | separate reference page about just these, L<perlrecharclass>. |
| 188 | |
| 189 | You can define your own custom character classes, by putting into your |
| 190 | pattern in the appropriate place(s), a list of all the characters you |
| 191 | want in the set. You do this by enclosing the list within C<[]> bracket |
| 192 | characters. These are called "bracketed character classes" when we are |
| 193 | being precise, but often the word "bracketed" is dropped. (Dropping it |
| 194 | usually doesn't cause confusion.) This means that the C<"["> character |
| 195 | is another metacharacter. It doesn't match anything just by itelf; it |
| 196 | is used only to tell Perl that what follows it is a bracketed character |
| 197 | class. If you want to match a literal left square bracket, you must |
| 198 | escape it, like C<"\[">. The matching C<"]"> is also a metacharacter; |
| 199 | again it doesn't match anything by itself, but just marks the end of |
| 200 | your custom class to Perl. It is an example of a "sometimes |
| 201 | metacharacter". It isn't a metacharacter if there is no corresponding |
| 202 | C<"[">, and matches its literal self: |
| 203 | |
| 204 | print "]" =~ /]/; # prints 1 |
| 205 | |
| 206 | The list of characters within the character class gives the set of |
| 207 | characters matched by the class. C<"[abc]"> matches a single "a" or "b" |
| 208 | or "c". But if the first character after the C<"["> is C<"^">, the |
| 209 | class matches any character not in the list. Within a list, the C<"-"> |
| 210 | character specifies a range of characters, so that C<a-z> represents all |
| 211 | characters between "a" and "z", inclusive. If you want either C<"-"> or |
| 212 | C<"]"> itself to be a member of a class, put it at the start of the list |
| 213 | (possibly after a C<"^">), or escape it with a backslash. C<"-"> is |
| 214 | also taken literally when it is at the end of the list, just before the |
| 215 | closing C<"]">. (The following all specify the same class of three |
| 216 | characters: C<[-az]>, C<[az-]>, and C<[a\-z]>. All are different from |
| 217 | C<[a-z]>, which specifies a class containing twenty-six characters, even |
| 218 | on EBCDIC-based character sets.) |
| 219 | |
| 220 | There is lots more to bracketed character classes; full details are in |
| 221 | L<perlrecharclass/Bracketed Character Classes>. |
| 222 | |
| 223 | =head3 Metacharacters |
| 224 | X<metacharacter> |
| 225 | X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]> |
| 226 | |
| 227 | L</The Basics> introduced some of the metacharacters. This section |
| 228 | gives them all. Most of them have the same meaning as in the I<egrep> |
| 229 | command. |
| 230 | |
| 231 | Only the C<"\"> is always a metacharacter. The others are metacharacters |
| 232 | just sometimes. The following tables lists all of them, summarizes |
| 233 | their use, and gives the contexts where they are metacharacters. |
| 234 | Outside those contexts or if prefixed by a C<"\">, they match their |
| 235 | corresponding punctuation character. In some cases, their meaning |
| 236 | varies depending on various pattern modifiers that alter the default |
| 237 | behaviors. See L</Modifiers>. |
| 238 | |
| 239 | |
| 240 | PURPOSE WHERE |
| 241 | \ Escape the next character Always, except when |
| 242 | escaped by another \ |
| 243 | ^ Match the beginning of the string Not in [] |
| 244 | (or line, if /m is used) |
| 245 | ^ Complement the [] class At the beginning of [] |
| 246 | . Match any single character except newline Not in [] |
| 247 | (under /s, includes newline) |
| 248 | $ Match the end of the string Not in [], but can |
| 249 | (or before newline at the end of the mean interpolate a |
| 250 | string; or before any newline if /m is scalar |
| 251 | used) |
| 252 | | Alternation Not in [] |
| 253 | () Grouping Not in [] |
| 254 | [ Start Bracketed Character class Not in [] |
| 255 | ] End Bracketed Character class Only in [], and |
| 256 | not first |
| 257 | * Matches the preceding element 0 or more Not in [] |
| 258 | times |
| 259 | + Matches the preceding element 1 or more Not in [] |
| 260 | times |
| 261 | ? Matches the preceding element 0 or 1 Not in [] |
| 262 | times |
| 263 | { Starts a sequence that gives number(s) Not in [] |
| 264 | of times the preceding element can be |
| 265 | matched |
| 266 | { when following certain escape sequences |
| 267 | starts a modifier to the meaning of the |
| 268 | sequence |
| 269 | } End sequence started by { |
| 270 | - Indicates a range Only in [] interior |
| 271 | |
| 272 | Notice that most of the metacharacters lose their special meaning when |
| 273 | they occur in a bracketed character class, except C<"^"> has a different |
| 274 | meaning when it is at the beginning of such a class. And C<"-"> and C<"]"> |
| 275 | are metacharacters only at restricted positions within bracketed |
| 276 | character classes; while C<"}"> is a metacharacter only when closing a |
| 277 | special construct started by C<"{">. |
| 278 | |
| 279 | In double-quotish context, as is usually the case, you need to be |
| 280 | careful about C<"$"> and the non-metacharacter C<"@">. Those could |
| 281 | interpolate variables, which may or may not be what you intended. |
| 282 | |
| 283 | These rules were designed for compactness of expression, rather than |
| 284 | legibility and maintainability. The L</E<sol>x and E<sol>xx> pattern |
| 285 | modifiers allow you to insert white space to improve readability. And |
| 286 | use of S<C<L<re 'strict'|re/'strict' mode>>> adds extra checking to |
| 287 | catch some typos that might silently compile into something unintended. |
| 288 | |
| 289 | By default, the C<"^"> character is guaranteed to match only the |
| 290 | beginning of the string, the C<"$"> character only the end (or before the |
| 291 | newline at the end), and Perl does certain optimizations with the |
| 292 | assumption that the string contains only one line. Embedded newlines |
| 293 | will not be matched by C<"^"> or C<"$">. You may, however, wish to treat a |
| 294 | string as a multi-line buffer, such that the C<"^"> will match after any |
| 295 | newline within the string (except if the newline is the last character in |
| 296 | the string), and C<"$"> will match before any newline. At the |
| 297 | cost of a little more overhead, you can do this by using the |
| 298 | L</C<E<sol>m>> modifier on the pattern match operator. (Older programs |
| 299 | did this by setting C<$*>, but this option was removed in perl 5.10.) |
| 300 | X<^> X<$> X</m> |
| 301 | |
| 302 | To simplify multi-line substitutions, the C<"."> character never matches a |
| 303 | newline unless you use the L<C<E<sol>s>|/s> modifier, which in effect tells |
| 304 | Perl to pretend the string is a single line--even if it isn't. |
| 305 | X<.> X</s> |
| 306 | |
| 307 | =head2 Modifiers |
| 308 | |
| 309 | =head3 Overview |
| 310 | |
| 311 | The default behavior for matching can be changed, using various |
| 312 | modifiers. Modifiers that relate to the interpretation of the pattern |
| 313 | are listed just below. Modifiers that alter the way a pattern is used |
| 314 | by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and |
| 315 | L<perlop/"Gory details of parsing quoted constructs">. |
| 316 | |
| 317 | =over 4 |
| 318 | |
| 319 | =item B<C<m>> |
| 320 | X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline> |
| 321 | |
| 322 | Treat the string being matched against as multiple lines. That is, change C<"^"> and C<"$"> from matching |
| 323 | the start of the string's first line and the end of its last line to |
| 324 | matching the start and end of each line within the string. |
| 325 | |
| 326 | =item B<C<s>> |
| 327 | X</s> X<regex, single-line> X<regexp, single-line> |
| 328 | X<regular expression, single-line> |
| 329 | |
| 330 | Treat the string as single line. That is, change C<"."> to match any character |
| 331 | whatsoever, even a newline, which normally it would not match. |
| 332 | |
| 333 | Used together, as C</ms>, they let the C<"."> match any character whatsoever, |
| 334 | while still allowing C<"^"> and C<"$"> to match, respectively, just after |
| 335 | and just before newlines within the string. |
| 336 | |
| 337 | =item B<C<i>> |
| 338 | X</i> X<regex, case-insensitive> X<regexp, case-insensitive> |
| 339 | X<regular expression, case-insensitive> |
| 340 | |
| 341 | Do case-insensitive pattern matching. For example, "A" will match "a" |
| 342 | under C</i>. |
| 343 | |
| 344 | If locale matching rules are in effect, the case map is taken from the |
| 345 | current |
| 346 | locale for code points less than 255, and from Unicode rules for larger |
| 347 | code points. However, matches that would cross the Unicode |
| 348 | rules/non-Unicode rules boundary (ords 255/256) will not succeed, unless |
| 349 | the locale is a UTF-8 one. See L<perllocale>. |
| 350 | |
| 351 | There are a number of Unicode characters that match a sequence of |
| 352 | multiple characters under C</i>. For example, |
| 353 | C<LATIN SMALL LIGATURE FI> should match the sequence C<fi>. Perl is not |
| 354 | currently able to do this when the multiple characters are in the pattern and |
| 355 | are split between groupings, or when one or more are quantified. Thus |
| 356 | |
| 357 | "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i; # Matches |
| 358 | "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i; # Doesn't match! |
| 359 | "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i; # Doesn't match! |
| 360 | |
| 361 | # The below doesn't match, and it isn't clear what $1 and $2 would |
| 362 | # be even if it did!! |
| 363 | "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i; # Doesn't match! |
| 364 | |
| 365 | Perl doesn't match multiple characters in a bracketed |
| 366 | character class unless the character that maps to them is explicitly |
| 367 | mentioned, and it doesn't match them at all if the character class is |
| 368 | inverted, which otherwise could be highly confusing. See |
| 369 | L<perlrecharclass/Bracketed Character Classes>, and |
| 370 | L<perlrecharclass/Negation>. |
| 371 | |
| 372 | =item B<C<x>> and B<C<xx>> |
| 373 | X</x> |
| 374 | |
| 375 | Extend your pattern's legibility by permitting whitespace and comments. |
| 376 | Details in L</E<sol>x and E<sol>xx> |
| 377 | |
| 378 | =item B<C<p>> |
| 379 | X</p> X<regex, preserve> X<regexp, preserve> |
| 380 | |
| 381 | Preserve the string matched such that C<${^PREMATCH}>, C<${^MATCH}>, and |
| 382 | C<${^POSTMATCH}> are available for use after matching. |
| 383 | |
| 384 | In Perl 5.20 and higher this is ignored. Due to a new copy-on-write |
| 385 | mechanism, C<${^PREMATCH}>, C<${^MATCH}>, and C<${^POSTMATCH}> will be available |
| 386 | after the match regardless of the modifier. |
| 387 | |
| 388 | =item B<C<a>>, B<C<d>>, B<C<l>>, and B<C<u>> |
| 389 | X</a> X</d> X</l> X</u> |
| 390 | |
| 391 | These modifiers, all new in 5.14, affect which character-set rules |
| 392 | (Unicode, I<etc>.) are used, as described below in |
| 393 | L</Character set modifiers>. |
| 394 | |
| 395 | =item B<C<n>> |
| 396 | X</n> X<regex, non-capture> X<regexp, non-capture> |
| 397 | X<regular expression, non-capture> |
| 398 | |
| 399 | Prevent the grouping metacharacters C<()> from capturing. This modifier, |
| 400 | new in 5.22, will stop C<$1>, C<$2>, I<etc>... from being filled in. |
| 401 | |
| 402 | "hello" =~ /(hi|hello)/; # $1 is "hello" |
| 403 | "hello" =~ /(hi|hello)/n; # $1 is undef |
| 404 | |
| 405 | This is equivalent to putting C<?:> at the beginning of every capturing group: |
| 406 | |
| 407 | "hello" =~ /(?:hi|hello)/; # $1 is undef |
| 408 | |
| 409 | C</n> can be negated on a per-group basis. Alternatively, named captures |
| 410 | may still be used. |
| 411 | |
| 412 | "hello" =~ /(?-n:(hi|hello))/n; # $1 is "hello" |
| 413 | "hello" =~ /(?<greet>hi|hello)/n; # $1 is "hello", $+{greet} is |
| 414 | # "hello" |
| 415 | |
| 416 | =item Other Modifiers |
| 417 | |
| 418 | There are a number of flags that can be found at the end of regular |
| 419 | expression constructs that are I<not> generic regular expression flags, but |
| 420 | apply to the operation being performed, like matching or substitution (C<m//> |
| 421 | or C<s///> respectively). |
| 422 | |
| 423 | Flags described further in |
| 424 | L<perlretut/"Using regular expressions in Perl"> are: |
| 425 | |
| 426 | c - keep the current position during repeated matching |
| 427 | g - globally match the pattern repeatedly in the string |
| 428 | |
| 429 | Substitution-specific modifiers described in |
| 430 | L<perlop/"s/PATTERN/REPLACEMENT/msixpodualngcer"> are: |
| 431 | |
| 432 | e - evaluate the right-hand side as an expression |
| 433 | ee - evaluate the right side as a string then eval the result |
| 434 | o - pretend to optimize your code, but actually introduce bugs |
| 435 | r - perform non-destructive substitution and return the new value |
| 436 | |
| 437 | =back |
| 438 | |
| 439 | Regular expression modifiers are usually written in documentation |
| 440 | as I<e.g.>, "the C</x> modifier", even though the delimiter |
| 441 | in question might not really be a slash. The modifiers C</imnsxadlup> |
| 442 | may also be embedded within the regular expression itself using |
| 443 | the C<(?...)> construct, see L</Extended Patterns> below. |
| 444 | |
| 445 | =head3 Details on some modifiers |
| 446 | |
| 447 | Some of the modifiers require more explanation than given in the |
| 448 | L</Overview> above. |
| 449 | |
| 450 | =head4 C</x> and C</xx> |
| 451 | |
| 452 | A single C</x> tells |
| 453 | the regular expression parser to ignore most whitespace that is neither |
| 454 | backslashed nor within a bracketed character class. You can use this to |
| 455 | break up your regular expression into more readable parts. |
| 456 | Also, the C<"#"> character is treated as a metacharacter introducing a |
| 457 | comment that runs up to the pattern's closing delimiter, or to the end |
| 458 | of the current line if the pattern extends onto the next line. Hence, |
| 459 | this is very much like an ordinary Perl code comment. (You can include |
| 460 | the closing delimiter within the comment only if you precede it with a |
| 461 | backslash, so be careful!) |
| 462 | |
| 463 | Use of C</x> means that if you want real |
| 464 | whitespace or C<"#"> characters in the pattern (outside a bracketed character |
| 465 | class, which is unaffected by C</x>), then you'll either have to |
| 466 | escape them (using backslashes or C<\Q...\E>) or encode them using octal, |
| 467 | hex, or C<\N{}> escapes. |
| 468 | It is ineffective to try to continue a comment onto the next line by |
| 469 | escaping the C<\n> with a backslash or C<\Q>. |
| 470 | |
| 471 | You can use L</(?#text)> to create a comment that ends earlier than the |
| 472 | end of the current line, but C<text> also can't contain the closing |
| 473 | delimiter unless escaped with a backslash. |
| 474 | |
| 475 | A common pitfall is to forget that C<"#"> characters begin a comment under |
| 476 | C</x> and are not matched literally. Just keep that in mind when trying |
| 477 | to puzzle out why a particular C</x> pattern isn't working as expected. |
| 478 | |
| 479 | Starting in Perl v5.26, if the modifier has a second C<"x"> within it, |
| 480 | it does everything that a single C</x> does, but additionally |
| 481 | non-backslashed SPACE and TAB characters within bracketed character |
| 482 | classes are also generally ignored, and hence can be added to make the |
| 483 | classes more readable. |
| 484 | |
| 485 | / [d-e g-i 3-7]/xx |
| 486 | /[ ! @ " # $ % ^ & * () = ? <> ' ]/xx |
| 487 | |
| 488 | may be easier to grasp than the squashed equivalents |
| 489 | |
| 490 | /[d-eg-i3-7]/ |
| 491 | /[!@"#$%^&*()=?<>']/ |
| 492 | |
| 493 | Taken together, these features go a long way towards |
| 494 | making Perl's regular expressions more readable. Here's an example: |
| 495 | |
| 496 | # Delete (most) C comments. |
| 497 | $program =~ s { |
| 498 | /\* # Match the opening delimiter. |
| 499 | .*? # Match a minimal number of characters. |
| 500 | \*/ # Match the closing delimiter. |
| 501 | } []gsx; |
| 502 | |
| 503 | Note that anything inside |
| 504 | a C<\Q...\E> stays unaffected by C</x>. And note that C</x> doesn't affect |
| 505 | space interpretation within a single multi-character construct. For |
| 506 | example in C<\x{...}>, regardless of the C</x> modifier, there can be no |
| 507 | spaces. Same for a L<quantifier|/Quantifiers> such as C<{3}> or |
| 508 | C<{5,}>. Similarly, C<(?:...)> can't have a space between the C<"(">, |
| 509 | C<"?">, and C<":">. Within any delimiters for such a |
| 510 | construct, allowed spaces are not affected by C</x>, and depend on the |
| 511 | construct. For example, C<\x{...}> can't have spaces because hexadecimal |
| 512 | numbers don't have spaces in them. But, Unicode properties can have spaces, so |
| 513 | in C<\p{...}> there can be spaces that follow the Unicode rules, for which see |
| 514 | L<perluniprops/Properties accessible through \p{} and \P{}>. |
| 515 | X</x> |
| 516 | |
| 517 | The set of characters that are deemed whitespace are those that Unicode |
| 518 | calls "Pattern White Space", namely: |
| 519 | |
| 520 | U+0009 CHARACTER TABULATION |
| 521 | U+000A LINE FEED |
| 522 | U+000B LINE TABULATION |
| 523 | U+000C FORM FEED |
| 524 | U+000D CARRIAGE RETURN |
| 525 | U+0020 SPACE |
| 526 | U+0085 NEXT LINE |
| 527 | U+200E LEFT-TO-RIGHT MARK |
| 528 | U+200F RIGHT-TO-LEFT MARK |
| 529 | U+2028 LINE SEPARATOR |
| 530 | U+2029 PARAGRAPH SEPARATOR |
| 531 | |
| 532 | =head4 Character set modifiers |
| 533 | |
| 534 | C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called |
| 535 | the character set modifiers; they affect the character set rules |
| 536 | used for the regular expression. |
| 537 | |
| 538 | The C</d>, C</u>, and C</l> modifiers are not likely to be of much use |
| 539 | to you, and so you need not worry about them very much. They exist for |
| 540 | Perl's internal use, so that complex regular expression data structures |
| 541 | can be automatically serialized and later exactly reconstituted, |
| 542 | including all their nuances. But, since Perl can't keep a secret, and |
| 543 | there may be rare instances where they are useful, they are documented |
| 544 | here. |
| 545 | |
| 546 | The C</a> modifier, on the other hand, may be useful. Its purpose is to |
| 547 | allow code that is to work mostly on ASCII data to not have to concern |
| 548 | itself with Unicode. |
| 549 | |
| 550 | Briefly, C</l> sets the character set to that of whatever B<L>ocale is in |
| 551 | effect at the time of the execution of the pattern match. |
| 552 | |
| 553 | C</u> sets the character set to B<U>nicode. |
| 554 | |
| 555 | C</a> also sets the character set to Unicode, BUT adds several |
| 556 | restrictions for B<A>SCII-safe matching. |
| 557 | |
| 558 | C</d> is the old, problematic, pre-5.14 B<D>efault character set |
| 559 | behavior. Its only use is to force that old behavior. |
| 560 | |
| 561 | At any given time, exactly one of these modifiers is in effect. Their |
| 562 | existence allows Perl to keep the originally compiled behavior of a |
| 563 | regular expression, regardless of what rules are in effect when it is |
| 564 | actually executed. And if it is interpolated into a larger regex, the |
| 565 | original's rules continue to apply to it, and only it. |
| 566 | |
| 567 | The C</l> and C</u> modifiers are automatically selected for |
| 568 | regular expressions compiled within the scope of various pragmas, |
| 569 | and we recommend that in general, you use those pragmas instead of |
| 570 | specifying these modifiers explicitly. For one thing, the modifiers |
| 571 | affect only pattern matching, and do not extend to even any replacement |
| 572 | done, whereas using the pragmas gives consistent results for all |
| 573 | appropriate operations within their scopes. For example, |
| 574 | |
| 575 | s/foo/\Ubar/il |
| 576 | |
| 577 | will match "foo" using the locale's rules for case-insensitive matching, |
| 578 | but the C</l> does not affect how the C<\U> operates. Most likely you |
| 579 | want both of them to use locale rules. To do this, instead compile the |
| 580 | regular expression within the scope of C<use locale>. This both |
| 581 | implicitly adds the C</l>, and applies locale rules to the C<\U>. The |
| 582 | lesson is to C<use locale>, and not C</l> explicitly. |
| 583 | |
| 584 | Similarly, it would be better to use C<use feature 'unicode_strings'> |
| 585 | instead of, |
| 586 | |
| 587 | s/foo/\Lbar/iu |
| 588 | |
| 589 | to get Unicode rules, as the C<\L> in the former (but not necessarily |
| 590 | the latter) would also use Unicode rules. |
| 591 | |
| 592 | More detail on each of the modifiers follows. Most likely you don't |
| 593 | need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead |
| 594 | to L<E<sol>a|/E<sol>a (and E<sol>aa)>. |
| 595 | |
| 596 | =head4 /l |
| 597 | |
| 598 | means to use the current locale's rules (see L<perllocale>) when pattern |
| 599 | matching. For example, C<\w> will match the "word" characters of that |
| 600 | locale, and C<"/i"> case-insensitive matching will match according to |
| 601 | the locale's case folding rules. The locale used will be the one in |
| 602 | effect at the time of execution of the pattern match. This may not be |
| 603 | the same as the compilation-time locale, and can differ from one match |
| 604 | to another if there is an intervening call of the |
| 605 | L<setlocale() function|perllocale/The setlocale function>. |
| 606 | |
| 607 | Prior to v5.20, Perl did not support multi-byte locales. Starting then, |
| 608 | UTF-8 locales are supported. No other multi byte locales are ever |
| 609 | likely to be supported. However, in all locales, one can have code |
| 610 | points above 255 and these will always be treated as Unicode no matter |
| 611 | what locale is in effect. |
| 612 | |
| 613 | Under Unicode rules, there are a few case-insensitive matches that cross |
| 614 | the 255/256 boundary. Except for UTF-8 locales in Perls v5.20 and |
| 615 | later, these are disallowed under C</l>. For example, 0xFF (on ASCII |
| 616 | platforms) does not caselessly match the character at 0x178, C<LATIN |
| 617 | CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be C<LATIN SMALL |
| 618 | LETTER Y WITH DIAERESIS> in the current locale, and Perl has no way of |
| 619 | knowing if that character even exists in the locale, much less what code |
| 620 | point it is. |
| 621 | |
| 622 | In a UTF-8 locale in v5.20 and later, the only visible difference |
| 623 | between locale and non-locale in regular expressions should be tainting |
| 624 | (see L<perlsec>). |
| 625 | |
| 626 | This modifier may be specified to be the default by C<use locale>, but |
| 627 | see L</Which character set modifier is in effect?>. |
| 628 | X</l> |
| 629 | |
| 630 | =head4 /u |
| 631 | |
| 632 | means to use Unicode rules when pattern matching. On ASCII platforms, |
| 633 | this means that the code points between 128 and 255 take on their |
| 634 | Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's). |
| 635 | (Otherwise Perl considers their meanings to be undefined.) Thus, |
| 636 | under this modifier, the ASCII platform effectively becomes a Unicode |
| 637 | platform; and hence, for example, C<\w> will match any of the more than |
| 638 | 100_000 word characters in Unicode. |
| 639 | |
| 640 | Unlike most locales, which are specific to a language and country pair, |
| 641 | Unicode classifies all the characters that are letters I<somewhere> in |
| 642 | the world as |
| 643 | C<\w>. For example, your locale might not think that C<LATIN SMALL |
| 644 | LETTER ETH> is a letter (unless you happen to speak Icelandic), but |
| 645 | Unicode does. Similarly, all the characters that are decimal digits |
| 646 | somewhere in the world will match C<\d>; this is hundreds, not 10, |
| 647 | possible matches. And some of those digits look like some of the 10 |
| 648 | ASCII digits, but mean a different number, so a human could easily think |
| 649 | a number is a different quantity than it really is. For example, |
| 650 | C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an |
| 651 | C<ASCII DIGIT EIGHT> (U+0038). And, C<\d+>, may match strings of digits |
| 652 | that are a mixture from different writing systems, creating a security |
| 653 | issue. L<Unicode::UCD/num()> can be used to sort |
| 654 | this out. Or the C</a> modifier can be used to force C<\d> to match |
| 655 | just the ASCII 0 through 9. |
| 656 | |
| 657 | Also, under this modifier, case-insensitive matching works on the full |
| 658 | set of Unicode |
| 659 | characters. The C<KELVIN SIGN>, for example matches the letters "k" and |
| 660 | "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which, |
| 661 | if you're not prepared, might make it look like a hexadecimal constant, |
| 662 | presenting another potential security issue. See |
| 663 | L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode |
| 664 | security issues. |
| 665 | |
| 666 | This modifier may be specified to be the default by C<use feature |
| 667 | 'unicode_strings>, C<use locale ':not_characters'>, or |
| 668 | C<L<use 5.012|perlfunc/use VERSION>> (or higher), |
| 669 | but see L</Which character set modifier is in effect?>. |
| 670 | X</u> |
| 671 | |
| 672 | =head4 /d |
| 673 | |
| 674 | This modifier means to use the "Default" native rules of the platform |
| 675 | except when there is cause to use Unicode rules instead, as follows: |
| 676 | |
| 677 | =over 4 |
| 678 | |
| 679 | =item 1 |
| 680 | |
| 681 | the target string is encoded in UTF-8; or |
| 682 | |
| 683 | =item 2 |
| 684 | |
| 685 | the pattern is encoded in UTF-8; or |
| 686 | |
| 687 | =item 3 |
| 688 | |
| 689 | the pattern explicitly mentions a code point that is above 255 (say by |
| 690 | C<\x{100}>); or |
| 691 | |
| 692 | =item 4 |
| 693 | |
| 694 | the pattern uses a Unicode name (C<\N{...}>); or |
| 695 | |
| 696 | =item 5 |
| 697 | |
| 698 | the pattern uses a Unicode property (C<\p{...}> or C<\P{...}>); or |
| 699 | |
| 700 | =item 6 |
| 701 | |
| 702 | the pattern uses a Unicode break (C<\b{...}> or C<\B{...}>); or |
| 703 | |
| 704 | =item 7 |
| 705 | |
| 706 | the pattern uses L</C<(?[ ])>> |
| 707 | |
| 708 | =back |
| 709 | |
| 710 | Another mnemonic for this modifier is "Depends", as the rules actually |
| 711 | used depend on various things, and as a result you can get unexpected |
| 712 | results. See L<perlunicode/The "Unicode Bug">. The Unicode Bug has |
| 713 | become rather infamous, leading to yet another (printable) name for this |
| 714 | modifier, "Dodgy". |
| 715 | |
| 716 | Unless the pattern or string are encoded in UTF-8, only ASCII characters |
| 717 | can match positively. |
| 718 | |
| 719 | Here are some examples of how that works on an ASCII platform: |
| 720 | |
| 721 | $str = "\xDF"; # $str is not in UTF-8 format. |
| 722 | $str =~ /^\w/; # No match, as $str isn't in UTF-8 format. |
| 723 | $str .= "\x{0e0b}"; # Now $str is in UTF-8 format. |
| 724 | $str =~ /^\w/; # Match! $str is now in UTF-8 format. |
| 725 | chop $str; |
| 726 | $str =~ /^\w/; # Still a match! $str remains in UTF-8 format. |
| 727 | |
| 728 | This modifier is automatically selected by default when none of the |
| 729 | others are, so yet another name for it is "Default". |
| 730 | |
| 731 | Because of the unexpected behaviors associated with this modifier, you |
| 732 | probably should only explicitly use it to maintain weird backward |
| 733 | compatibilities. |
| 734 | |
| 735 | =head4 /a (and /aa) |
| 736 | |
| 737 | This modifier stands for ASCII-restrict (or ASCII-safe). This modifier |
| 738 | may be doubled-up to increase its effect. |
| 739 | |
| 740 | When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and |
| 741 | the Posix character classes to match only in the ASCII range. They thus |
| 742 | revert to their pre-5.6, pre-Unicode meanings. Under C</a>, C<\d> |
| 743 | always means precisely the digits C<"0"> to C<"9">; C<\s> means the five |
| 744 | characters C<[ \f\n\r\t]>, and starting in Perl v5.18, the vertical tab; |
| 745 | C<\w> means the 63 characters |
| 746 | C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as |
| 747 | C<[[:print:]]> match only the appropriate ASCII-range characters. |
| 748 | |
| 749 | This modifier is useful for people who only incidentally use Unicode, |
| 750 | and who do not wish to be burdened with its complexities and security |
| 751 | concerns. |
| 752 | |
| 753 | With C</a>, one can write C<\d> with confidence that it will only match |
| 754 | ASCII characters, and should the need arise to match beyond ASCII, you |
| 755 | can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>). There are |
| 756 | similar C<\p{...}> constructs that can match beyond ASCII both white |
| 757 | space (see L<perlrecharclass/Whitespace>), and Posix classes (see |
| 758 | L<perlrecharclass/POSIX Character Classes>). Thus, this modifier |
| 759 | doesn't mean you can't use Unicode, it means that to get Unicode |
| 760 | matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that |
| 761 | signals Unicode. |
| 762 | |
| 763 | As you would expect, this modifier causes, for example, C<\D> to mean |
| 764 | the same thing as C<[^0-9]>; in fact, all non-ASCII characters match |
| 765 | C<\D>, C<\S>, and C<\W>. C<\b> still means to match at the boundary |
| 766 | between C<\w> and C<\W>, using the C</a> definitions of them (similarly |
| 767 | for C<\B>). |
| 768 | |
| 769 | Otherwise, C</a> behaves like the C</u> modifier, in that |
| 770 | case-insensitive matching uses Unicode rules; for example, "k" will |
| 771 | match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code |
| 772 | points in the Latin1 range, above ASCII will have Unicode rules when it |
| 773 | comes to case-insensitive matching. |
| 774 | |
| 775 | To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>), |
| 776 | specify the C<"a"> twice, for example C</aai> or C</aia>. (The first |
| 777 | occurrence of C<"a"> restricts the C<\d>, I<etc>., and the second occurrence |
| 778 | adds the C</i> restrictions.) But, note that code points outside the |
| 779 | ASCII range will use Unicode rules for C</i> matching, so the modifier |
| 780 | doesn't really restrict things to just ASCII; it just forbids the |
| 781 | intermixing of ASCII and non-ASCII. |
| 782 | |
| 783 | To summarize, this modifier provides protection for applications that |
| 784 | don't wish to be exposed to all of Unicode. Specifying it twice |
| 785 | gives added protection. |
| 786 | |
| 787 | This modifier may be specified to be the default by C<use re '/a'> |
| 788 | or C<use re '/aa'>. If you do so, you may actually have occasion to use |
| 789 | the C</u> modifier explicitly if there are a few regular expressions |
| 790 | where you do want full Unicode rules (but even here, it's best if |
| 791 | everything were under feature C<"unicode_strings">, along with the |
| 792 | C<use re '/aa'>). Also see L</Which character set modifier is in |
| 793 | effect?>. |
| 794 | X</a> |
| 795 | X</aa> |
| 796 | |
| 797 | =head4 Which character set modifier is in effect? |
| 798 | |
| 799 | Which of these modifiers is in effect at any given point in a regular |
| 800 | expression depends on a fairly complex set of interactions. These have |
| 801 | been designed so that in general you don't have to worry about it, but |
| 802 | this section gives the gory details. As |
| 803 | explained below in L</Extended Patterns> it is possible to explicitly |
| 804 | specify modifiers that apply only to portions of a regular expression. |
| 805 | The innermost always has priority over any outer ones, and one applying |
| 806 | to the whole expression has priority over any of the default settings that are |
| 807 | described in the remainder of this section. |
| 808 | |
| 809 | The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set |
| 810 | default modifiers (including these) for regular expressions compiled |
| 811 | within its scope. This pragma has precedence over the other pragmas |
| 812 | listed below that also change the defaults. |
| 813 | |
| 814 | Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>; |
| 815 | and C<L<use feature 'unicode_strings|feature>>, or |
| 816 | C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to |
| 817 | C</u> when not in the same scope as either C<L<use locale|perllocale>> |
| 818 | or C<L<use bytes|bytes>>. |
| 819 | (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also |
| 820 | sets the default to C</u>, overriding any plain C<use locale>.) |
| 821 | Unlike the mechanisms mentioned above, these |
| 822 | affect operations besides regular expressions pattern matching, and so |
| 823 | give more consistent results with other operators, including using |
| 824 | C<\U>, C<\l>, I<etc>. in substitution replacements. |
| 825 | |
| 826 | If none of the above apply, for backwards compatibility reasons, the |
| 827 | C</d> modifier is the one in effect by default. As this can lead to |
| 828 | unexpected results, it is best to specify which other rule set should be |
| 829 | used. |
| 830 | |
| 831 | =head4 Character set modifier behavior prior to Perl 5.14 |
| 832 | |
| 833 | Prior to 5.14, there were no explicit modifiers, but C</l> was implied |
| 834 | for regexes compiled within the scope of C<use locale>, and C</d> was |
| 835 | implied otherwise. However, interpolating a regex into a larger regex |
| 836 | would ignore the original compilation in favor of whatever was in effect |
| 837 | at the time of the second compilation. There were a number of |
| 838 | inconsistencies (bugs) with the C</d> modifier, where Unicode rules |
| 839 | would be used when inappropriate, and vice versa. C<\p{}> did not imply |
| 840 | Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12. |
| 841 | |
| 842 | =head2 Regular Expressions |
| 843 | |
| 844 | =head3 Quantifiers |
| 845 | |
| 846 | Quantifiers are used when a particular portion of a pattern needs to |
| 847 | match a certain number (or numbers) of times. If there isn't a |
| 848 | quantifier the number of times to match is exactly one. The following |
| 849 | standard quantifiers are recognized: |
| 850 | X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}> |
| 851 | |
| 852 | * Match 0 or more times |
| 853 | + Match 1 or more times |
| 854 | ? Match 1 or 0 times |
| 855 | {n} Match exactly n times |
| 856 | {n,} Match at least n times |
| 857 | {n,m} Match at least n but not more than m times |
| 858 | |
| 859 | (If a non-escaped curly bracket occurs in a context other than one of |
| 860 | the quantifiers listed above, where it does not form part of a |
| 861 | backslashed sequence like C<\x{...}>, it is either a fatal syntax error, |
| 862 | or treated as a regular character, generally with a deprecation warning |
| 863 | raised. To escape it, you can precede it with a backslash (C<"\{">) or |
| 864 | enclose it within square brackets (C<"[{]">). |
| 865 | This change will allow for future syntax extensions (like making the |
| 866 | lower bound of a quantifier optional), and better error checking of |
| 867 | quantifiers). |
| 868 | |
| 869 | The C<"*"> quantifier is equivalent to C<{0,}>, the C<"+"> |
| 870 | quantifier to C<{1,}>, and the C<"?"> quantifier to C<{0,1}>. I<n> and I<m> are limited |
| 871 | to non-negative integral values less than a preset limit defined when perl is built. |
| 872 | This is usually 32766 on the most common platforms. The actual limit can |
| 873 | be seen in the error message generated by code such as this: |
| 874 | |
| 875 | $_ **= $_ , / {$_} / for 2 .. 42; |
| 876 | |
| 877 | By default, a quantified subpattern is "greedy", that is, it will match as |
| 878 | many times as possible (given a particular starting location) while still |
| 879 | allowing the rest of the pattern to match. If you want it to match the |
| 880 | minimum number of times possible, follow the quantifier with a C<"?">. Note |
| 881 | that the meanings don't change, just the "greediness": |
| 882 | X<metacharacter> X<greedy> X<greediness> |
| 883 | X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?> |
| 884 | |
| 885 | *? Match 0 or more times, not greedily |
| 886 | +? Match 1 or more times, not greedily |
| 887 | ?? Match 0 or 1 time, not greedily |
| 888 | {n}? Match exactly n times, not greedily (redundant) |
| 889 | {n,}? Match at least n times, not greedily |
| 890 | {n,m}? Match at least n but not more than m times, not greedily |
| 891 | |
| 892 | Normally when a quantified subpattern does not allow the rest of the |
| 893 | overall pattern to match, Perl will backtrack. However, this behaviour is |
| 894 | sometimes undesirable. Thus Perl provides the "possessive" quantifier form |
| 895 | as well. |
| 896 | |
| 897 | *+ Match 0 or more times and give nothing back |
| 898 | ++ Match 1 or more times and give nothing back |
| 899 | ?+ Match 0 or 1 time and give nothing back |
| 900 | {n}+ Match exactly n times and give nothing back (redundant) |
| 901 | {n,}+ Match at least n times and give nothing back |
| 902 | {n,m}+ Match at least n but not more than m times and give nothing back |
| 903 | |
| 904 | For instance, |
| 905 | |
| 906 | 'aaaa' =~ /a++a/ |
| 907 | |
| 908 | will never match, as the C<a++> will gobble up all the C<"a">'s in the |
| 909 | string and won't leave any for the remaining part of the pattern. This |
| 910 | feature can be extremely useful to give perl hints about where it |
| 911 | shouldn't backtrack. For instance, the typical "match a double-quoted |
| 912 | string" problem can be most efficiently performed when written as: |
| 913 | |
| 914 | /"(?:[^"\\]++|\\.)*+"/ |
| 915 | |
| 916 | as we know that if the final quote does not match, backtracking will not |
| 917 | help. See the independent subexpression |
| 918 | L</C<< (?>pattern) >>> for more details; |
| 919 | possessive quantifiers are just syntactic sugar for that construct. For |
| 920 | instance the above example could also be written as follows: |
| 921 | |
| 922 | /"(?>(?:(?>[^"\\]+)|\\.)*)"/ |
| 923 | |
| 924 | Note that the possessive quantifier modifier can not be be combined |
| 925 | with the non-greedy modifier. This is because it would make no sense. |
| 926 | Consider the follow equivalency table: |
| 927 | |
| 928 | Illegal Legal |
| 929 | ------------ ------ |
| 930 | X??+ X{0} |
| 931 | X+?+ X{1} |
| 932 | X{min,max}?+ X{min} |
| 933 | |
| 934 | =head3 Escape sequences |
| 935 | |
| 936 | Because patterns are processed as double-quoted strings, the following |
| 937 | also work: |
| 938 | |
| 939 | \t tab (HT, TAB) |
| 940 | \n newline (LF, NL) |
| 941 | \r return (CR) |
| 942 | \f form feed (FF) |
| 943 | \a alarm (bell) (BEL) |
| 944 | \e escape (think troff) (ESC) |
| 945 | \cK control char (example: VT) |
| 946 | \x{}, \x00 character whose ordinal is the given hexadecimal number |
| 947 | \N{name} named Unicode character or character sequence |
| 948 | \N{U+263D} Unicode character (example: FIRST QUARTER MOON) |
| 949 | \o{}, \000 character whose ordinal is the given octal number |
| 950 | \l lowercase next char (think vi) |
| 951 | \u uppercase next char (think vi) |
| 952 | \L lowercase until \E (think vi) |
| 953 | \U uppercase until \E (think vi) |
| 954 | \Q quote (disable) pattern metacharacters until \E |
| 955 | \E end either case modification or quoted section, think vi |
| 956 | |
| 957 | Details are in L<perlop/Quote and Quote-like Operators>. |
| 958 | |
| 959 | =head3 Character Classes and other Special Escapes |
| 960 | |
| 961 | In addition, Perl defines the following: |
| 962 | X<\g> X<\k> X<\K> X<backreference> |
| 963 | |
| 964 | Sequence Note Description |
| 965 | [...] [1] Match a character according to the rules of the |
| 966 | bracketed character class defined by the "...". |
| 967 | Example: [a-z] matches "a" or "b" or "c" ... or "z" |
| 968 | [[:...:]] [2] Match a character according to the rules of the POSIX |
| 969 | character class "..." within the outer bracketed |
| 970 | character class. Example: [[:upper:]] matches any |
| 971 | uppercase character. |
| 972 | (?[...]) [8] Extended bracketed character class |
| 973 | \w [3] Match a "word" character (alphanumeric plus "_", plus |
| 974 | other connector punctuation chars plus Unicode |
| 975 | marks) |
| 976 | \W [3] Match a non-"word" character |
| 977 | \s [3] Match a whitespace character |
| 978 | \S [3] Match a non-whitespace character |
| 979 | \d [3] Match a decimal digit character |
| 980 | \D [3] Match a non-digit character |
| 981 | \pP [3] Match P, named property. Use \p{Prop} for longer names |
| 982 | \PP [3] Match non-P |
| 983 | \X [4] Match Unicode "eXtended grapheme cluster" |
| 984 | \1 [5] Backreference to a specific capture group or buffer. |
| 985 | '1' may actually be any positive integer. |
| 986 | \g1 [5] Backreference to a specific or previous group, |
| 987 | \g{-1} [5] The number may be negative indicating a relative |
| 988 | previous group and may optionally be wrapped in |
| 989 | curly brackets for safer parsing. |
| 990 | \g{name} [5] Named backreference |
| 991 | \k<name> [5] Named backreference |
| 992 | \K [6] Keep the stuff left of the \K, don't include it in $& |
| 993 | \N [7] Any character but \n. Not affected by /s modifier |
| 994 | \v [3] Vertical whitespace |
| 995 | \V [3] Not vertical whitespace |
| 996 | \h [3] Horizontal whitespace |
| 997 | \H [3] Not horizontal whitespace |
| 998 | \R [4] Linebreak |
| 999 | |
| 1000 | =over 4 |
| 1001 | |
| 1002 | =item [1] |
| 1003 | |
| 1004 | See L<perlrecharclass/Bracketed Character Classes> for details. |
| 1005 | |
| 1006 | =item [2] |
| 1007 | |
| 1008 | See L<perlrecharclass/POSIX Character Classes> for details. |
| 1009 | |
| 1010 | =item [3] |
| 1011 | |
| 1012 | See L<perlrecharclass/Backslash sequences> for details. |
| 1013 | |
| 1014 | =item [4] |
| 1015 | |
| 1016 | See L<perlrebackslash/Misc> for details. |
| 1017 | |
| 1018 | =item [5] |
| 1019 | |
| 1020 | See L</Capture groups> below for details. |
| 1021 | |
| 1022 | =item [6] |
| 1023 | |
| 1024 | See L</Extended Patterns> below for details. |
| 1025 | |
| 1026 | =item [7] |
| 1027 | |
| 1028 | Note that C<\N> has two meanings. When of the form C<\N{NAME}>, it matches the |
| 1029 | character or character sequence whose name is C<NAME>; and similarly |
| 1030 | when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode |
| 1031 | code point is I<hex>. Otherwise it matches any character but C<\n>. |
| 1032 | |
| 1033 | =item [8] |
| 1034 | |
| 1035 | See L<perlrecharclass/Extended Bracketed Character Classes> for details. |
| 1036 | |
| 1037 | =back |
| 1038 | |
| 1039 | =head3 Assertions |
| 1040 | |
| 1041 | Besides L<C<"^"> and C<"$">|/Metacharacters>, Perl defines the following |
| 1042 | zero-width assertions: |
| 1043 | X<zero-width assertion> X<assertion> X<regex, zero-width assertion> |
| 1044 | X<regexp, zero-width assertion> |
| 1045 | X<regular expression, zero-width assertion> |
| 1046 | X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G> |
| 1047 | |
| 1048 | \b{} Match at Unicode boundary of specified type |
| 1049 | \B{} Match where corresponding \b{} doesn't match |
| 1050 | \b Match a \w\W or \W\w boundary |
| 1051 | \B Match except at a \w\W or \W\w boundary |
| 1052 | \A Match only at beginning of string |
| 1053 | \Z Match only at end of string, or before newline at the end |
| 1054 | \z Match only at end of string |
| 1055 | \G Match only at pos() (e.g. at the end-of-match position |
| 1056 | of prior m//g) |
| 1057 | |
| 1058 | A Unicode boundary (C<\b{}>), available starting in v5.22, is a spot |
| 1059 | between two characters, or before the first character in the string, or |
| 1060 | after the final character in the string where certain criteria defined |
| 1061 | by Unicode are met. See L<perlrebackslash/\b{}, \b, \B{}, \B> for |
| 1062 | details. |
| 1063 | |
| 1064 | A word boundary (C<\b>) is a spot between two characters |
| 1065 | that has a C<\w> on one side of it and a C<\W> on the other side |
| 1066 | of it (in either order), counting the imaginary characters off the |
| 1067 | beginning and end of the string as matching a C<\W>. (Within |
| 1068 | character classes C<\b> represents backspace rather than a word |
| 1069 | boundary, just as it normally does in any double-quoted string.) |
| 1070 | The C<\A> and C<\Z> are just like C<"^"> and C<"$">, except that they |
| 1071 | won't match multiple times when the C</m> modifier is used, while |
| 1072 | C<"^"> and C<"$"> will match at every internal line boundary. To match |
| 1073 | the actual end of the string and not ignore an optional trailing |
| 1074 | newline, use C<\z>. |
| 1075 | X<\b> X<\A> X<\Z> X<\z> X</m> |
| 1076 | |
| 1077 | The C<\G> assertion can be used to chain global matches (using |
| 1078 | C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">. |
| 1079 | It is also useful when writing C<lex>-like scanners, when you have |
| 1080 | several patterns that you want to match against consequent substrings |
| 1081 | of your string; see the previous reference. The actual location |
| 1082 | where C<\G> will match can also be influenced by using C<pos()> as |
| 1083 | an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length |
| 1084 | matches (see L</"Repeated Patterns Matching a Zero-length Substring">) |
| 1085 | is modified somewhat, in that contents to the left of C<\G> are |
| 1086 | not counted when determining the length of the match. Thus the following |
| 1087 | will not match forever: |
| 1088 | X<\G> |
| 1089 | |
| 1090 | my $string = 'ABC'; |
| 1091 | pos($string) = 1; |
| 1092 | while ($string =~ /(.\G)/g) { |
| 1093 | print $1; |
| 1094 | } |
| 1095 | |
| 1096 | It will print 'A' and then terminate, as it considers the match to |
| 1097 | be zero-width, and thus will not match at the same position twice in a |
| 1098 | row. |
| 1099 | |
| 1100 | It is worth noting that C<\G> improperly used can result in an infinite |
| 1101 | loop. Take care when using patterns that include C<\G> in an alternation. |
| 1102 | |
| 1103 | Note also that C<s///> will refuse to overwrite part of a substitution |
| 1104 | that has already been replaced; so for example this will stop after the |
| 1105 | first iteration, rather than iterating its way backwards through the |
| 1106 | string: |
| 1107 | |
| 1108 | $_ = "123456789"; |
| 1109 | pos = 6; |
| 1110 | s/.(?=.\G)/X/g; |
| 1111 | print; # prints 1234X6789, not XXXXX6789 |
| 1112 | |
| 1113 | |
| 1114 | =head3 Capture groups |
| 1115 | |
| 1116 | The grouping construct C<( ... )> creates capture groups (also referred to as |
| 1117 | capture buffers). To refer to the current contents of a group later on, within |
| 1118 | the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>) |
| 1119 | for the second, and so on. |
| 1120 | This is called a I<backreference>. |
| 1121 | X<regex, capture buffer> X<regexp, capture buffer> |
| 1122 | X<regex, capture group> X<regexp, capture group> |
| 1123 | X<regular expression, capture buffer> X<backreference> |
| 1124 | X<regular expression, capture group> X<backreference> |
| 1125 | X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference> |
| 1126 | X<named capture buffer> X<regular expression, named capture buffer> |
| 1127 | X<named capture group> X<regular expression, named capture group> |
| 1128 | X<%+> X<$+{name}> X<< \k<name> >> |
| 1129 | There is no limit to the number of captured substrings that you may use. |
| 1130 | Groups are numbered with the leftmost open parenthesis being number 1, I<etc>. If |
| 1131 | a group did not match, the associated backreference won't match either. (This |
| 1132 | can happen if the group is optional, or in a different branch of an |
| 1133 | alternation.) |
| 1134 | You can omit the C<"g">, and write C<"\1">, I<etc>, but there are some issues with |
| 1135 | this form, described below. |
| 1136 | |
| 1137 | You can also refer to capture groups relatively, by using a negative number, so |
| 1138 | that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture |
| 1139 | group, and C<\g-2> and C<\g{-2}> both refer to the group before it. For |
| 1140 | example: |
| 1141 | |
| 1142 | / |
| 1143 | (Y) # group 1 |
| 1144 | ( # group 2 |
| 1145 | (X) # group 3 |
| 1146 | \g{-1} # backref to group 3 |
| 1147 | \g{-3} # backref to group 1 |
| 1148 | ) |
| 1149 | /x |
| 1150 | |
| 1151 | would match the same as C</(Y) ( (X) \g3 \g1 )/x>. This allows you to |
| 1152 | interpolate regexes into larger regexes and not have to worry about the |
| 1153 | capture groups being renumbered. |
| 1154 | |
| 1155 | You can dispense with numbers altogether and create named capture groups. |
| 1156 | The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to |
| 1157 | reference. (To be compatible with .Net regular expressions, C<\g{I<name>}> may |
| 1158 | also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.) |
| 1159 | I<name> must not begin with a number, nor contain hyphens. |
| 1160 | When different groups within the same pattern have the same name, any reference |
| 1161 | to that name assumes the leftmost defined group. Named groups count in |
| 1162 | absolute and relative numbering, and so can also be referred to by those |
| 1163 | numbers. |
| 1164 | (It's possible to do things with named capture groups that would otherwise |
| 1165 | require C<(??{})>.) |
| 1166 | |
| 1167 | Capture group contents are dynamically scoped and available to you outside the |
| 1168 | pattern until the end of the enclosing block or until the next successful |
| 1169 | match, whichever comes first. (See L<perlsyn/"Compound Statements">.) |
| 1170 | You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">, |
| 1171 | I<etc>); or by name via the C<%+> hash, using C<"$+{I<name>}">. |
| 1172 | |
| 1173 | Braces are required in referring to named capture groups, but are optional for |
| 1174 | absolute or relative numbered ones. Braces are safer when creating a regex by |
| 1175 | concatenating smaller strings. For example if you have C<qr/$a$b/>, and C<$a> |
| 1176 | contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which |
| 1177 | is probably not what you intended. |
| 1178 | |
| 1179 | The C<\g> and C<\k> notations were introduced in Perl 5.10.0. Prior to that |
| 1180 | there were no named nor relative numbered capture groups. Absolute numbered |
| 1181 | groups were referred to using C<\1>, |
| 1182 | C<\2>, I<etc>., and this notation is still |
| 1183 | accepted (and likely always will be). But it leads to some ambiguities if |
| 1184 | there are more than 9 capture groups, as C<\10> could mean either the tenth |
| 1185 | capture group, or the character whose ordinal in octal is 010 (a backspace in |
| 1186 | ASCII). Perl resolves this ambiguity by interpreting C<\10> as a backreference |
| 1187 | only if at least 10 left parentheses have opened before it. Likewise C<\11> is |
| 1188 | a backreference only if at least 11 left parentheses have opened before it. |
| 1189 | And so on. C<\1> through C<\9> are always interpreted as backreferences. |
| 1190 | There are several examples below that illustrate these perils. You can avoid |
| 1191 | the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups; |
| 1192 | and for octal constants always using C<\o{}>, or for C<\077> and below, using 3 |
| 1193 | digits padded with leading zeros, since a leading zero implies an octal |
| 1194 | constant. |
| 1195 | |
| 1196 | The C<\I<digit>> notation also works in certain circumstances outside |
| 1197 | the pattern. See L</Warning on \1 Instead of $1> below for details. |
| 1198 | |
| 1199 | Examples: |
| 1200 | |
| 1201 | s/^([^ ]*) *([^ ]*)/$2 $1/; # swap first two words |
| 1202 | |
| 1203 | /(.)\g1/ # find first doubled char |
| 1204 | and print "'$1' is the first doubled character\n"; |
| 1205 | |
| 1206 | /(?<char>.)\k<char>/ # ... a different way |
| 1207 | and print "'$+{char}' is the first doubled character\n"; |
| 1208 | |
| 1209 | /(?'char'.)\g1/ # ... mix and match |
| 1210 | and print "'$1' is the first doubled character\n"; |
| 1211 | |
| 1212 | if (/Time: (..):(..):(..)/) { # parse out values |
| 1213 | $hours = $1; |
| 1214 | $minutes = $2; |
| 1215 | $seconds = $3; |
| 1216 | } |
| 1217 | |
| 1218 | /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/ # \g10 is a backreference |
| 1219 | /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/ # \10 is octal |
| 1220 | /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/ # \10 is a backreference |
| 1221 | /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal |
| 1222 | |
| 1223 | $a = '(.)\1'; # Creates problems when concatenated. |
| 1224 | $b = '(.)\g{1}'; # Avoids the problems. |
| 1225 | "aa" =~ /${a}/; # True |
| 1226 | "aa" =~ /${b}/; # True |
| 1227 | "aa0" =~ /${a}0/; # False! |
| 1228 | "aa0" =~ /${b}0/; # True |
| 1229 | "aa\x08" =~ /${a}0/; # True! |
| 1230 | "aa\x08" =~ /${b}0/; # False |
| 1231 | |
| 1232 | Several special variables also refer back to portions of the previous |
| 1233 | match. C<$+> returns whatever the last bracket match matched. |
| 1234 | C<$&> returns the entire matched string. (At one point C<$0> did |
| 1235 | also, but now it returns the name of the program.) C<$`> returns |
| 1236 | everything before the matched string. C<$'> returns everything |
| 1237 | after the matched string. And C<$^N> contains whatever was matched by |
| 1238 | the most-recently closed group (submatch). C<$^N> can be used in |
| 1239 | extended patterns (see below), for example to assign a submatch to a |
| 1240 | variable. |
| 1241 | X<$+> X<$^N> X<$&> X<$`> X<$'> |
| 1242 | |
| 1243 | These special variables, like the C<%+> hash and the numbered match variables |
| 1244 | (C<$1>, C<$2>, C<$3>, I<etc>.) are dynamically scoped |
| 1245 | until the end of the enclosing block or until the next successful |
| 1246 | match, whichever comes first. (See L<perlsyn/"Compound Statements">.) |
| 1247 | X<$+> X<$^N> X<$&> X<$`> X<$'> |
| 1248 | X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9> |
| 1249 | |
| 1250 | B<NOTE>: Failed matches in Perl do not reset the match variables, |
| 1251 | which makes it easier to write code that tests for a series of more |
| 1252 | specific cases and remembers the best match. |
| 1253 | |
| 1254 | B<WARNING>: If your code is to run on Perl 5.16 or earlier, |
| 1255 | beware that once Perl sees that you need one of C<$&>, C<$`>, or |
| 1256 | C<$'> anywhere in the program, it has to provide them for every |
| 1257 | pattern match. This may substantially slow your program. |
| 1258 | |
| 1259 | Perl uses the same mechanism to produce C<$1>, C<$2>, I<etc>, so you also |
| 1260 | pay a price for each pattern that contains capturing parentheses. |
| 1261 | (To avoid this cost while retaining the grouping behaviour, use the |
| 1262 | extended regular expression C<(?: ... )> instead.) But if you never |
| 1263 | use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing |
| 1264 | parentheses will not be penalized. So avoid C<$&>, C<$'>, and C<$`> |
| 1265 | if you can, but if you can't (and some algorithms really appreciate |
| 1266 | them), once you've used them once, use them at will, because you've |
| 1267 | already paid the price. |
| 1268 | X<$&> X<$`> X<$'> |
| 1269 | |
| 1270 | Perl 5.16 introduced a slightly more efficient mechanism that notes |
| 1271 | separately whether each of C<$`>, C<$&>, and C<$'> have been seen, and |
| 1272 | thus may only need to copy part of the string. Perl 5.20 introduced a |
| 1273 | much more efficient copy-on-write mechanism which eliminates any slowdown. |
| 1274 | |
| 1275 | As another workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>, |
| 1276 | C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&> |
| 1277 | and C<$'>, B<except> that they are only guaranteed to be defined after a |
| 1278 | successful match that was executed with the C</p> (preserve) modifier. |
| 1279 | The use of these variables incurs no global performance penalty, unlike |
| 1280 | their punctuation character equivalents, however at the trade-off that you |
| 1281 | have to tell perl when you want to use them. As of Perl 5.20, these three |
| 1282 | variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored. |
| 1283 | X</p> X<p modifier> |
| 1284 | |
| 1285 | =head2 Quoting metacharacters |
| 1286 | |
| 1287 | Backslashed metacharacters in Perl are alphanumeric, such as C<\b>, |
| 1288 | C<\w>, C<\n>. Unlike some other regular expression languages, there |
| 1289 | are no backslashed symbols that aren't alphanumeric. So anything |
| 1290 | that looks like C<\\>, C<\(>, C<\)>, C<\[>, C<\]>, C<\{>, or C<\}> is |
| 1291 | always |
| 1292 | interpreted as a literal character, not a metacharacter. This was |
| 1293 | once used in a common idiom to disable or quote the special meanings |
| 1294 | of regular expression metacharacters in a string that you want to |
| 1295 | use for a pattern. Simply quote all non-"word" characters: |
| 1296 | |
| 1297 | $pattern =~ s/(\W)/\\$1/g; |
| 1298 | |
| 1299 | (If C<use locale> is set, then this depends on the current locale.) |
| 1300 | Today it is more common to use the C<L<quotemeta()|perlfunc/quotemeta>> |
| 1301 | function or the C<\Q> metaquoting escape sequence to disable all |
| 1302 | metacharacters' special meanings like this: |
| 1303 | |
| 1304 | /$unquoted\Q$quoted\E$unquoted/ |
| 1305 | |
| 1306 | Beware that if you put literal backslashes (those not inside |
| 1307 | interpolated variables) between C<\Q> and C<\E>, double-quotish |
| 1308 | backslash interpolation may lead to confusing results. If you |
| 1309 | I<need> to use literal backslashes within C<\Q...\E>, |
| 1310 | consult L<perlop/"Gory details of parsing quoted constructs">. |
| 1311 | |
| 1312 | C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>. |
| 1313 | |
| 1314 | =head2 Extended Patterns |
| 1315 | |
| 1316 | Perl also defines a consistent extension syntax for features not |
| 1317 | found in standard tools like B<awk> and |
| 1318 | B<lex>. The syntax for most of these is a |
| 1319 | pair of parentheses with a question mark as the first thing within |
| 1320 | the parentheses. The character after the question mark indicates |
| 1321 | the extension. |
| 1322 | |
| 1323 | A question mark was chosen for this and for the minimal-matching |
| 1324 | construct because 1) question marks are rare in older regular |
| 1325 | expressions, and 2) whenever you see one, you should stop and |
| 1326 | "question" exactly what is going on. That's psychology.... |
| 1327 | |
| 1328 | =over 4 |
| 1329 | |
| 1330 | =item C<(?#text)> |
| 1331 | X<(?#)> |
| 1332 | |
| 1333 | A comment. The text is ignored. |
| 1334 | Note that Perl closes |
| 1335 | the comment as soon as it sees a C<")">, so there is no way to put a literal |
| 1336 | C<")"> in the comment. The pattern's closing delimiter must be escaped by |
| 1337 | a backslash if it appears in the comment. |
| 1338 | |
| 1339 | See L</E<sol>x> for another way to have comments in patterns. |
| 1340 | |
| 1341 | Note that a comment can go just about anywhere, except in the middle of |
| 1342 | an escape sequence. Examples: |
| 1343 | |
| 1344 | qr/foo(?#comment)bar/' # Matches 'foobar' |
| 1345 | |
| 1346 | # The pattern below matches 'abcd', 'abccd', or 'abcccd' |
| 1347 | qr/abc(?#comment between literal and its quantifier){1,3}d/ |
| 1348 | |
| 1349 | # The pattern below generates a syntax error, because the '\p' must |
| 1350 | # be followed immediately by a '{'. |
| 1351 | qr/\p(?#comment between \p and its property name){Any}/ |
| 1352 | |
| 1353 | # The pattern below generates a syntax error, because the initial |
| 1354 | # '\(' is a literal opening parenthesis, and so there is nothing |
| 1355 | # for the closing ')' to match |
| 1356 | qr/\(?#the backslash means this isn't a comment)p{Any}/ |
| 1357 | |
| 1358 | =item C<(?adlupimnsx-imnsx)> |
| 1359 | |
| 1360 | =item C<(?^alupimnsx)> |
| 1361 | X<(?)> X<(?^)> |
| 1362 | |
| 1363 | One or more embedded pattern-match modifiers, to be turned on (or |
| 1364 | turned off if preceded by C<"-">) for the remainder of the pattern or |
| 1365 | the remainder of the enclosing pattern group (if any). |
| 1366 | |
| 1367 | This is particularly useful for dynamically-generated patterns, |
| 1368 | such as those read in from a |
| 1369 | configuration file, taken from an argument, or specified in a table |
| 1370 | somewhere. Consider the case where some patterns want to be |
| 1371 | case-sensitive and some do not: The case-insensitive ones merely need to |
| 1372 | include C<(?i)> at the front of the pattern. For example: |
| 1373 | |
| 1374 | $pattern = "foobar"; |
| 1375 | if ( /$pattern/i ) { } |
| 1376 | |
| 1377 | # more flexible: |
| 1378 | |
| 1379 | $pattern = "(?i)foobar"; |
| 1380 | if ( /$pattern/ ) { } |
| 1381 | |
| 1382 | These modifiers are restored at the end of the enclosing group. For example, |
| 1383 | |
| 1384 | ( (?i) blah ) \s+ \g1 |
| 1385 | |
| 1386 | will match C<blah> in any case, some spaces, and an exact (I<including the case>!) |
| 1387 | repetition of the previous word, assuming the C</x> modifier, and no C</i> |
| 1388 | modifier outside this group. |
| 1389 | |
| 1390 | These modifiers do not carry over into named subpatterns called in the |
| 1391 | enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not |
| 1392 | change the case-sensitivity of the C<"NAME"> pattern. |
| 1393 | |
| 1394 | A modifier is overridden by later occurrences of this construct in the |
| 1395 | same scope containing the same modifier, so that |
| 1396 | |
| 1397 | /((?im)foo(?-m)bar)/ |
| 1398 | |
| 1399 | matches all of C<foobar> case insensitively, but uses C</m> rules for |
| 1400 | only the C<foo> portion. The C<"a"> flag overrides C<aa> as well; |
| 1401 | likewise C<aa> overrides C<"a">. The same goes for C<"x"> and C<xx>. |
| 1402 | Hence, in |
| 1403 | |
| 1404 | /(?-x)foo/xx |
| 1405 | |
| 1406 | both C</x> and C</xx> are turned off during matching C<foo>. And in |
| 1407 | |
| 1408 | /(?x)foo/x |
| 1409 | |
| 1410 | C</x> but NOT C</xx> is turned on for matching C<foo>. (One might |
| 1411 | mistakenly think that since the inner C<(?x)> is already in the scope of |
| 1412 | C</x>, that the result would effectively be the sum of them, yielding |
| 1413 | C</xx>. It doesn't work that way.) Similarly, doing something like |
| 1414 | C<(?xx-x)foo> turns off all C<"x"> behavior for matching C<foo>, it is not |
| 1415 | that you subtract 1 C<"x"> from 2 to get 1 C<"x"> remaining. |
| 1416 | |
| 1417 | Any of these modifiers can be set to apply globally to all regular |
| 1418 | expressions compiled within the scope of a C<use re>. See |
| 1419 | L<re/"'/flags' mode">. |
| 1420 | |
| 1421 | Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately |
| 1422 | after the C<"?"> is a shorthand equivalent to C<d-imnsx>. Flags (except |
| 1423 | C<"d">) may follow the caret to override it. |
| 1424 | But a minus sign is not legal with it. |
| 1425 | |
| 1426 | Note that the C<"a">, C<"d">, C<"l">, C<"p">, and C<"u"> modifiers are special in |
| 1427 | that they can only be enabled, not disabled, and the C<"a">, C<"d">, C<"l">, and |
| 1428 | C<"u"> modifiers are mutually exclusive: specifying one de-specifies the |
| 1429 | others, and a maximum of one (or two C<"a">'s) may appear in the |
| 1430 | construct. Thus, for |
| 1431 | example, C<(?-p)> will warn when compiled under C<use warnings>; |
| 1432 | C<(?-d:...)> and C<(?dl:...)> are fatal errors. |
| 1433 | |
| 1434 | Note also that the C<"p"> modifier is special in that its presence |
| 1435 | anywhere in a pattern has a global effect. |
| 1436 | |
| 1437 | =item C<(?:pattern)> |
| 1438 | X<(?:)> |
| 1439 | |
| 1440 | =item C<(?adluimnsx-imnsx:pattern)> |
| 1441 | |
| 1442 | =item C<(?^aluimnsx:pattern)> |
| 1443 | X<(?^:)> |
| 1444 | |
| 1445 | This is for clustering, not capturing; it groups subexpressions like |
| 1446 | C<"()">, but doesn't make backreferences as C<"()"> does. So |
| 1447 | |
| 1448 | @fields = split(/\b(?:a|b|c)\b/) |
| 1449 | |
| 1450 | matches the same field delimiters as |
| 1451 | |
| 1452 | @fields = split(/\b(a|b|c)\b/) |
| 1453 | |
| 1454 | but doesn't spit out the delimiters themselves as extra fields (even though |
| 1455 | that's the behaviour of L<perlfunc/split> when its pattern contains capturing |
| 1456 | groups). It's also cheaper not to capture |
| 1457 | characters if you don't need to. |
| 1458 | |
| 1459 | Any letters between C<"?"> and C<":"> act as flags modifiers as with |
| 1460 | C<(?adluimnsx-imnsx)>. For example, |
| 1461 | |
| 1462 | /(?s-i:more.*than).*million/i |
| 1463 | |
| 1464 | is equivalent to the more verbose |
| 1465 | |
| 1466 | /(?:(?s-i)more.*than).*million/i |
| 1467 | |
| 1468 | Note that any C<()> constructs enclosed within this one will still |
| 1469 | capture unless the C</n> modifier is in effect. |
| 1470 | |
| 1471 | Like the L</(?adlupimnsx-imnsx)> construct, C<aa> and C<"a"> override each |
| 1472 | other, as do C<xx> and C<"x">. They are not additive. So, doing |
| 1473 | something like C<(?xx-x:foo)> turns off all C<"x"> behavior for matching |
| 1474 | C<foo>. |
| 1475 | |
| 1476 | Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately |
| 1477 | after the C<"?"> is a shorthand equivalent to C<d-imnsx>. Any positive |
| 1478 | flags (except C<"d">) may follow the caret, so |
| 1479 | |
| 1480 | (?^x:foo) |
| 1481 | |
| 1482 | is equivalent to |
| 1483 | |
| 1484 | (?x-imns:foo) |
| 1485 | |
| 1486 | The caret tells Perl that this cluster doesn't inherit the flags of any |
| 1487 | surrounding pattern, but uses the system defaults (C<d-imnsx>), |
| 1488 | modified by any flags specified. |
| 1489 | |
| 1490 | The caret allows for simpler stringification of compiled regular |
| 1491 | expressions. These look like |
| 1492 | |
| 1493 | (?^:pattern) |
| 1494 | |
| 1495 | with any non-default flags appearing between the caret and the colon. |
| 1496 | A test that looks at such stringification thus doesn't need to have the |
| 1497 | system default flags hard-coded in it, just the caret. If new flags are |
| 1498 | added to Perl, the meaning of the caret's expansion will change to include |
| 1499 | the default for those flags, so the test will still work, unchanged. |
| 1500 | |
| 1501 | Specifying a negative flag after the caret is an error, as the flag is |
| 1502 | redundant. |
| 1503 | |
| 1504 | Mnemonic for C<(?^...)>: A fresh beginning since the usual use of a caret is |
| 1505 | to match at the beginning. |
| 1506 | |
| 1507 | =item C<(?|pattern)> |
| 1508 | X<(?|)> X<Branch reset> |
| 1509 | |
| 1510 | This is the "branch reset" pattern, which has the special property |
| 1511 | that the capture groups are numbered from the same starting point |
| 1512 | in each alternation branch. It is available starting from perl 5.10.0. |
| 1513 | |
| 1514 | Capture groups are numbered from left to right, but inside this |
| 1515 | construct the numbering is restarted for each branch. |
| 1516 | |
| 1517 | The numbering within each branch will be as normal, and any groups |
| 1518 | following this construct will be numbered as though the construct |
| 1519 | contained only one branch, that being the one with the most capture |
| 1520 | groups in it. |
| 1521 | |
| 1522 | This construct is useful when you want to capture one of a |
| 1523 | number of alternative matches. |
| 1524 | |
| 1525 | Consider the following pattern. The numbers underneath show in |
| 1526 | which group the captured content will be stored. |
| 1527 | |
| 1528 | |
| 1529 | # before ---------------branch-reset----------- after |
| 1530 | / ( a ) (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x |
| 1531 | # 1 2 2 3 2 3 4 |
| 1532 | |
| 1533 | Be careful when using the branch reset pattern in combination with |
| 1534 | named captures. Named captures are implemented as being aliases to |
| 1535 | numbered groups holding the captures, and that interferes with the |
| 1536 | implementation of the branch reset pattern. If you are using named |
| 1537 | captures in a branch reset pattern, it's best to use the same names, |
| 1538 | in the same order, in each of the alternations: |
| 1539 | |
| 1540 | /(?| (?<a> x ) (?<b> y ) |
| 1541 | | (?<a> z ) (?<b> w )) /x |
| 1542 | |
| 1543 | Not doing so may lead to surprises: |
| 1544 | |
| 1545 | "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x; |
| 1546 | say $+{a}; # Prints '12' |
| 1547 | say $+{b}; # *Also* prints '12'. |
| 1548 | |
| 1549 | The problem here is that both the group named C<< a >> and the group |
| 1550 | named C<< b >> are aliases for the group belonging to C<< $1 >>. |
| 1551 | |
| 1552 | =item Lookaround Assertions |
| 1553 | X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround> |
| 1554 | |
| 1555 | Lookaround assertions are zero-width patterns which match a specific |
| 1556 | pattern without including it in C<$&>. Positive assertions match when |
| 1557 | their subpattern matches, negative assertions match when their subpattern |
| 1558 | fails. Lookbehind matches text up to the current match position, |
| 1559 | lookahead matches text following the current match position. |
| 1560 | |
| 1561 | =over 4 |
| 1562 | |
| 1563 | =item C<(?=pattern)> |
| 1564 | X<(?=)> X<look-ahead, positive> X<lookahead, positive> |
| 1565 | |
| 1566 | A zero-width positive lookahead assertion. For example, C</\w+(?=\t)/> |
| 1567 | matches a word followed by a tab, without including the tab in C<$&>. |
| 1568 | |
| 1569 | =item C<(?!pattern)> |
| 1570 | X<(?!)> X<look-ahead, negative> X<lookahead, negative> |
| 1571 | |
| 1572 | A zero-width negative lookahead assertion. For example C</foo(?!bar)/> |
| 1573 | matches any occurrence of "foo" that isn't followed by "bar". Note |
| 1574 | however that lookahead and lookbehind are NOT the same thing. You cannot |
| 1575 | use this for lookbehind. |
| 1576 | |
| 1577 | If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/> |
| 1578 | will not do what you want. That's because the C<(?!foo)> is just saying that |
| 1579 | the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will |
| 1580 | match. Use lookbehind instead (see below). |
| 1581 | |
| 1582 | =item C<(?<=pattern)> |
| 1583 | |
| 1584 | =item C<\K> |
| 1585 | X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K> |
| 1586 | |
| 1587 | A zero-width positive lookbehind assertion. For example, C</(?<=\t)\w+/> |
| 1588 | matches a word that follows a tab, without including the tab in C<$&>. |
| 1589 | Works only for fixed-width lookbehind. |
| 1590 | |
| 1591 | There is a special form of this construct, called C<\K> (available since |
| 1592 | Perl 5.10.0), which causes the |
| 1593 | regex engine to "keep" everything it had matched prior to the C<\K> and |
| 1594 | not include it in C<$&>. This effectively provides variable-length |
| 1595 | lookbehind. The use of C<\K> inside of another lookaround assertion |
| 1596 | is allowed, but the behaviour is currently not well defined. |
| 1597 | |
| 1598 | For various reasons C<\K> may be significantly more efficient than the |
| 1599 | equivalent C<< (?<=...) >> construct, and it is especially useful in |
| 1600 | situations where you want to efficiently remove something following |
| 1601 | something else in a string. For instance |
| 1602 | |
| 1603 | s/(foo)bar/$1/g; |
| 1604 | |
| 1605 | can be rewritten as the much more efficient |
| 1606 | |
| 1607 | s/foo\Kbar//g; |
| 1608 | |
| 1609 | =item C<(?<!pattern)> |
| 1610 | X<(?<!)> X<look-behind, negative> X<lookbehind, negative> |
| 1611 | |
| 1612 | A zero-width negative lookbehind assertion. For example C</(?<!bar)foo/> |
| 1613 | matches any occurrence of "foo" that does not follow "bar". Works |
| 1614 | only for fixed-width lookbehind. |
| 1615 | |
| 1616 | =back |
| 1617 | |
| 1618 | =item C<< (?<NAME>pattern) >> |
| 1619 | |
| 1620 | =item C<(?'NAME'pattern)> |
| 1621 | X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture> |
| 1622 | |
| 1623 | A named capture group. Identical in every respect to normal capturing |
| 1624 | parentheses C<()> but for the additional fact that the group |
| 1625 | can be referred to by name in various regular expression |
| 1626 | constructs (like C<\g{NAME}>) and can be accessed by name |
| 1627 | after a successful match via C<%+> or C<%->. See L<perlvar> |
| 1628 | for more details on the C<%+> and C<%-> hashes. |
| 1629 | |
| 1630 | If multiple distinct capture groups have the same name then the |
| 1631 | C<$+{NAME}> will refer to the leftmost defined group in the match. |
| 1632 | |
| 1633 | The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent. |
| 1634 | |
| 1635 | B<NOTE:> While the notation of this construct is the same as the similar |
| 1636 | function in .NET regexes, the behavior is not. In Perl the groups are |
| 1637 | numbered sequentially regardless of being named or not. Thus in the |
| 1638 | pattern |
| 1639 | |
| 1640 | /(x)(?<foo>y)(z)/ |
| 1641 | |
| 1642 | C<$+{I<foo>}> will be the same as C<$2>, and C<$3> will contain 'z' instead of |
| 1643 | the opposite which is what a .NET regex hacker might expect. |
| 1644 | |
| 1645 | Currently I<NAME> is restricted to simple identifiers only. |
| 1646 | In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or |
| 1647 | its Unicode extension (see L<utf8>), |
| 1648 | though it isn't extended by the locale (see L<perllocale>). |
| 1649 | |
| 1650 | B<NOTE:> In order to make things easier for programmers with experience |
| 1651 | with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >> |
| 1652 | may be used instead of C<< (?<NAME>pattern) >>; however this form does not |
| 1653 | support the use of single quotes as a delimiter for the name. |
| 1654 | |
| 1655 | =item C<< \k<NAME> >> |
| 1656 | |
| 1657 | =item C<< \k'NAME' >> |
| 1658 | |
| 1659 | Named backreference. Similar to numeric backreferences, except that |
| 1660 | the group is designated by name and not number. If multiple groups |
| 1661 | have the same name then it refers to the leftmost defined group in |
| 1662 | the current match. |
| 1663 | |
| 1664 | It is an error to refer to a name not defined by a C<< (?<NAME>) >> |
| 1665 | earlier in the pattern. |
| 1666 | |
| 1667 | Both forms are equivalent. |
| 1668 | |
| 1669 | B<NOTE:> In order to make things easier for programmers with experience |
| 1670 | with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >> |
| 1671 | may be used instead of C<< \k<NAME> >>. |
| 1672 | |
| 1673 | =item C<(?{ code })> |
| 1674 | X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in> |
| 1675 | |
| 1676 | B<WARNING>: Using this feature safely requires that you understand its |
| 1677 | limitations. Code executed that has side effects may not perform identically |
| 1678 | from version to version due to the effect of future optimisations in the regex |
| 1679 | engine. For more information on this, see L</Embedded Code Execution |
| 1680 | Frequency>. |
| 1681 | |
| 1682 | This zero-width assertion executes any embedded Perl code. It always |
| 1683 | succeeds, and its return value is set as C<$^R>. |
| 1684 | |
| 1685 | In literal patterns, the code is parsed at the same time as the |
| 1686 | surrounding code. While within the pattern, control is passed temporarily |
| 1687 | back to the perl parser, until the logically-balancing closing brace is |
| 1688 | encountered. This is similar to the way that an array index expression in |
| 1689 | a literal string is handled, for example |
| 1690 | |
| 1691 | "abc$array[ 1 + f('[') + g()]def" |
| 1692 | |
| 1693 | In particular, braces do not need to be balanced: |
| 1694 | |
| 1695 | s/abc(?{ f('{'); })/def/ |
| 1696 | |
| 1697 | Even in a pattern that is interpolated and compiled at run-time, literal |
| 1698 | code blocks will be compiled once, at perl compile time; the following |
| 1699 | prints "ABCD": |
| 1700 | |
| 1701 | print "D"; |
| 1702 | my $qr = qr/(?{ BEGIN { print "A" } })/; |
| 1703 | my $foo = "foo"; |
| 1704 | /$foo$qr(?{ BEGIN { print "B" } })/; |
| 1705 | BEGIN { print "C" } |
| 1706 | |
| 1707 | In patterns where the text of the code is derived from run-time |
| 1708 | information rather than appearing literally in a source code /pattern/, |
| 1709 | the code is compiled at the same time that the pattern is compiled, and |
| 1710 | for reasons of security, C<use re 'eval'> must be in scope. This is to |
| 1711 | stop user-supplied patterns containing code snippets from being |
| 1712 | executable. |
| 1713 | |
| 1714 | In situations where you need to enable this with C<use re 'eval'>, you should |
| 1715 | also have taint checking enabled. Better yet, use the carefully |
| 1716 | constrained evaluation within a Safe compartment. See L<perlsec> for |
| 1717 | details about both these mechanisms. |
| 1718 | |
| 1719 | From the viewpoint of parsing, lexical variable scope and closures, |
| 1720 | |
| 1721 | /AAA(?{ BBB })CCC/ |
| 1722 | |
| 1723 | behaves approximately like |
| 1724 | |
| 1725 | /AAA/ && do { BBB } && /CCC/ |
| 1726 | |
| 1727 | Similarly, |
| 1728 | |
| 1729 | qr/AAA(?{ BBB })CCC/ |
| 1730 | |
| 1731 | behaves approximately like |
| 1732 | |
| 1733 | sub { /AAA/ && do { BBB } && /CCC/ } |
| 1734 | |
| 1735 | In particular: |
| 1736 | |
| 1737 | { my $i = 1; $r = qr/(?{ print $i })/ } |
| 1738 | my $i = 2; |
| 1739 | /$r/; # prints "1" |
| 1740 | |
| 1741 | Inside a C<(?{...})> block, C<$_> refers to the string the regular |
| 1742 | expression is matching against. You can also use C<pos()> to know what is |
| 1743 | the current position of matching within this string. |
| 1744 | |
| 1745 | The code block introduces a new scope from the perspective of lexical |
| 1746 | variable declarations, but B<not> from the perspective of C<local> and |
| 1747 | similar localizing behaviours. So later code blocks within the same |
| 1748 | pattern will still see the values which were localized in earlier blocks. |
| 1749 | These accumulated localizations are undone either at the end of a |
| 1750 | successful match, or if the assertion is backtracked (compare |
| 1751 | L</"Backtracking">). For example, |
| 1752 | |
| 1753 | $_ = 'a' x 8; |
| 1754 | m< |
| 1755 | (?{ $cnt = 0 }) # Initialize $cnt. |
| 1756 | ( |
| 1757 | a |
| 1758 | (?{ |
| 1759 | local $cnt = $cnt + 1; # Update $cnt, |
| 1760 | # backtracking-safe. |
| 1761 | }) |
| 1762 | )* |
| 1763 | aaaa |
| 1764 | (?{ $res = $cnt }) # On success copy to |
| 1765 | # non-localized location. |
| 1766 | >x; |
| 1767 | |
| 1768 | will initially increment C<$cnt> up to 8; then during backtracking, its |
| 1769 | value will be unwound back to 4, which is the value assigned to C<$res>. |
| 1770 | At the end of the regex execution, C<$cnt> will be wound back to its initial |
| 1771 | value of 0. |
| 1772 | |
| 1773 | This assertion may be used as the condition in a |
| 1774 | |
| 1775 | (?(condition)yes-pattern|no-pattern) |
| 1776 | |
| 1777 | switch. If I<not> used in this way, the result of evaluation of C<code> |
| 1778 | is put into the special variable C<$^R>. This happens immediately, so |
| 1779 | C<$^R> can be used from other C<(?{ code })> assertions inside the same |
| 1780 | regular expression. |
| 1781 | |
| 1782 | The assignment to C<$^R> above is properly localized, so the old |
| 1783 | value of C<$^R> is restored if the assertion is backtracked; compare |
| 1784 | L</"Backtracking">. |
| 1785 | |
| 1786 | Note that the special variable C<$^N> is particularly useful with code |
| 1787 | blocks to capture the results of submatches in variables without having to |
| 1788 | keep track of the number of nested parentheses. For example: |
| 1789 | |
| 1790 | $_ = "The brown fox jumps over the lazy dog"; |
| 1791 | /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i; |
| 1792 | print "color = $color, animal = $animal\n"; |
| 1793 | |
| 1794 | |
| 1795 | =item C<(??{ code })> |
| 1796 | X<(??{})> |
| 1797 | X<regex, postponed> X<regexp, postponed> X<regular expression, postponed> |
| 1798 | |
| 1799 | B<WARNING>: Using this feature safely requires that you understand its |
| 1800 | limitations. Code executed that has side effects may not perform |
| 1801 | identically from version to version due to the effect of future |
| 1802 | optimisations in the regex engine. For more information on this, see |
| 1803 | L</Embedded Code Execution Frequency>. |
| 1804 | |
| 1805 | This is a "postponed" regular subexpression. It behaves in I<exactly> the |
| 1806 | same way as a C<(?{ code })> code block as described above, except that |
| 1807 | its return value, rather than being assigned to C<$^R>, is treated as a |
| 1808 | pattern, compiled if it's a string (or used as-is if its a qr// object), |
| 1809 | then matched as if it were inserted instead of this construct. |
| 1810 | |
| 1811 | During the matching of this sub-pattern, it has its own set of |
| 1812 | captures which are valid during the sub-match, but are discarded once |
| 1813 | control returns to the main pattern. For example, the following matches, |
| 1814 | with the inner pattern capturing "B" and matching "BB", while the outer |
| 1815 | pattern captures "A"; |
| 1816 | |
| 1817 | my $inner = '(.)\1'; |
| 1818 | "ABBA" =~ /^(.)(??{ $inner })\1/; |
| 1819 | print $1; # prints "A"; |
| 1820 | |
| 1821 | Note that this means that there is no way for the inner pattern to refer |
| 1822 | to a capture group defined outside. (The code block itself can use C<$1>, |
| 1823 | I<etc>., to refer to the enclosing pattern's capture groups.) Thus, although |
| 1824 | |
| 1825 | ('a' x 100)=~/(??{'(.)' x 100})/ |
| 1826 | |
| 1827 | I<will> match, it will I<not> set C<$1> on exit. |
| 1828 | |
| 1829 | The following pattern matches a parenthesized group: |
| 1830 | |
| 1831 | $re = qr{ |
| 1832 | \( |
| 1833 | (?: |
| 1834 | (?> [^()]+ ) # Non-parens without backtracking |
| 1835 | | |
| 1836 | (??{ $re }) # Group with matching parens |
| 1837 | )* |
| 1838 | \) |
| 1839 | }x; |
| 1840 | |
| 1841 | See also |
| 1842 | L<C<(?I<PARNO>)>|/(?PARNO) (?-PARNO) (?+PARNO) (?R) (?0)> |
| 1843 | for a different, more efficient way to accomplish |
| 1844 | the same task. |
| 1845 | |
| 1846 | Executing a postponed regular expression too many times without |
| 1847 | consuming any input string will also result in a fatal error. The depth |
| 1848 | at which that happens is compiled into perl, so it can be changed with a |
| 1849 | custom build. |
| 1850 | |
| 1851 | =item C<(?I<PARNO>)> C<(?-I<PARNO>)> C<(?+I<PARNO>)> C<(?R)> C<(?0)> |
| 1852 | X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)> |
| 1853 | X<regex, recursive> X<regexp, recursive> X<regular expression, recursive> |
| 1854 | X<regex, relative recursion> X<GOSUB> X<GOSTART> |
| 1855 | |
| 1856 | Recursive subpattern. Treat the contents of a given capture buffer in the |
| 1857 | current pattern as an independent subpattern and attempt to match it at |
| 1858 | the current position in the string. Information about capture state from |
| 1859 | the caller for things like backreferences is available to the subpattern, |
| 1860 | but capture buffers set by the subpattern are not visible to the caller. |
| 1861 | |
| 1862 | Similar to C<(??{ code })> except that it does not involve executing any |
| 1863 | code or potentially compiling a returned pattern string; instead it treats |
| 1864 | the part of the current pattern contained within a specified capture group |
| 1865 | as an independent pattern that must match at the current position. Also |
| 1866 | different is the treatment of capture buffers, unlike C<(??{ code })> |
| 1867 | recursive patterns have access to their caller's match state, so one can |
| 1868 | use backreferences safely. |
| 1869 | |
| 1870 | I<PARNO> is a sequence of digits (not starting with 0) whose value reflects |
| 1871 | the paren-number of the capture group to recurse to. C<(?R)> recurses to |
| 1872 | the beginning of the whole pattern. C<(?0)> is an alternate syntax for |
| 1873 | C<(?R)>. If I<PARNO> is preceded by a plus or minus sign then it is assumed |
| 1874 | to be relative, with negative numbers indicating preceding capture groups |
| 1875 | and positive ones following. Thus C<(?-1)> refers to the most recently |
| 1876 | declared group, and C<(?+1)> indicates the next group to be declared. |
| 1877 | Note that the counting for relative recursion differs from that of |
| 1878 | relative backreferences, in that with recursion unclosed groups B<are> |
| 1879 | included. |
| 1880 | |
| 1881 | The following pattern matches a function C<foo()> which may contain |
| 1882 | balanced parentheses as the argument. |
| 1883 | |
| 1884 | $re = qr{ ( # paren group 1 (full function) |
| 1885 | foo |
| 1886 | ( # paren group 2 (parens) |
| 1887 | \( |
| 1888 | ( # paren group 3 (contents of parens) |
| 1889 | (?: |
| 1890 | (?> [^()]+ ) # Non-parens without backtracking |
| 1891 | | |
| 1892 | (?2) # Recurse to start of paren group 2 |
| 1893 | )* |
| 1894 | ) |
| 1895 | \) |
| 1896 | ) |
| 1897 | ) |
| 1898 | }x; |
| 1899 | |
| 1900 | If the pattern was used as follows |
| 1901 | |
| 1902 | 'foo(bar(baz)+baz(bop))'=~/$re/ |
| 1903 | and print "\$1 = $1\n", |
| 1904 | "\$2 = $2\n", |
| 1905 | "\$3 = $3\n"; |
| 1906 | |
| 1907 | the output produced should be the following: |
| 1908 | |
| 1909 | $1 = foo(bar(baz)+baz(bop)) |
| 1910 | $2 = (bar(baz)+baz(bop)) |
| 1911 | $3 = bar(baz)+baz(bop) |
| 1912 | |
| 1913 | If there is no corresponding capture group defined, then it is a |
| 1914 | fatal error. Recursing deeply without consuming any input string will |
| 1915 | also result in a fatal error. The depth at which that happens is |
| 1916 | compiled into perl, so it can be changed with a custom build. |
| 1917 | |
| 1918 | The following shows how using negative indexing can make it |
| 1919 | easier to embed recursive patterns inside of a C<qr//> construct |
| 1920 | for later use: |
| 1921 | |
| 1922 | my $parens = qr/(\((?:[^()]++|(?-1))*+\))/; |
| 1923 | if (/foo $parens \s+ \+ \s+ bar $parens/x) { |
| 1924 | # do something here... |
| 1925 | } |
| 1926 | |
| 1927 | B<Note> that this pattern does not behave the same way as the equivalent |
| 1928 | PCRE or Python construct of the same form. In Perl you can backtrack into |
| 1929 | a recursed group, in PCRE and Python the recursed into group is treated |
| 1930 | as atomic. Also, modifiers are resolved at compile time, so constructs |
| 1931 | like C<(?i:(?1))> or C<(?:(?i)(?1))> do not affect how the sub-pattern will |
| 1932 | be processed. |
| 1933 | |
| 1934 | =item C<(?&NAME)> |
| 1935 | X<(?&NAME)> |
| 1936 | |
| 1937 | Recurse to a named subpattern. Identical to C<(?I<PARNO>)> except that the |
| 1938 | parenthesis to recurse to is determined by name. If multiple parentheses have |
| 1939 | the same name, then it recurses to the leftmost. |
| 1940 | |
| 1941 | It is an error to refer to a name that is not declared somewhere in the |
| 1942 | pattern. |
| 1943 | |
| 1944 | B<NOTE:> In order to make things easier for programmers with experience |
| 1945 | with the Python or PCRE regex engines the pattern C<< (?P>NAME) >> |
| 1946 | may be used instead of C<< (?&NAME) >>. |
| 1947 | |
| 1948 | =item C<(?(condition)yes-pattern|no-pattern)> |
| 1949 | X<(?()> |
| 1950 | |
| 1951 | =item C<(?(condition)yes-pattern)> |
| 1952 | |
| 1953 | Conditional expression. Matches C<yes-pattern> if C<condition> yields |
| 1954 | a true value, matches C<no-pattern> otherwise. A missing pattern always |
| 1955 | matches. |
| 1956 | |
| 1957 | C<(condition)> should be one of: |
| 1958 | |
| 1959 | =over 4 |
| 1960 | |
| 1961 | =item an integer in parentheses |
| 1962 | |
| 1963 | (which is valid if the corresponding pair of parentheses |
| 1964 | matched); |
| 1965 | |
| 1966 | =item a lookahead/lookbehind/evaluate zero-width assertion; |
| 1967 | |
| 1968 | =item a name in angle brackets or single quotes |
| 1969 | |
| 1970 | (which is valid if a group with the given name matched); |
| 1971 | |
| 1972 | =item the special symbol C<(R)> |
| 1973 | |
| 1974 | (true when evaluated inside of recursion or eval). Additionally the |
| 1975 | C<"R"> may be |
| 1976 | followed by a number, (which will be true when evaluated when recursing |
| 1977 | inside of the appropriate group), or by C<&NAME>, in which case it will |
| 1978 | be true only when evaluated during recursion in the named group. |
| 1979 | |
| 1980 | =back |
| 1981 | |
| 1982 | Here's a summary of the possible predicates: |
| 1983 | |
| 1984 | =over 4 |
| 1985 | |
| 1986 | =item C<(1)> C<(2)> ... |
| 1987 | |
| 1988 | Checks if the numbered capturing group has matched something. |
| 1989 | Full syntax: C<< (?(1)then|else) >> |
| 1990 | |
| 1991 | =item C<(E<lt>I<NAME>E<gt>)> C<('I<NAME>')> |
| 1992 | |
| 1993 | Checks if a group with the given name has matched something. |
| 1994 | Full syntax: C<< (?(<name>)then|else) >> |
| 1995 | |
| 1996 | =item C<(?=...)> C<(?!...)> C<(?<=...)> C<(?<!...)> |
| 1997 | |
| 1998 | Checks whether the pattern matches (or does not match, for the C<"!"> |
| 1999 | variants). |
| 2000 | Full syntax: C<< (?(?=lookahead)then|else) >> |
| 2001 | |
| 2002 | =item C<(?{ I<CODE> })> |
| 2003 | |
| 2004 | Treats the return value of the code block as the condition. |
| 2005 | Full syntax: C<< (?(?{ code })then|else) >> |
| 2006 | |
| 2007 | =item C<(R)> |
| 2008 | |
| 2009 | Checks if the expression has been evaluated inside of recursion. |
| 2010 | Full syntax: C<< (?(R)then|else) >> |
| 2011 | |
| 2012 | =item C<(R1)> C<(R2)> ... |
| 2013 | |
| 2014 | Checks if the expression has been evaluated while executing directly |
| 2015 | inside of the n-th capture group. This check is the regex equivalent of |
| 2016 | |
| 2017 | if ((caller(0))[3] eq 'subname') { ... } |
| 2018 | |
| 2019 | In other words, it does not check the full recursion stack. |
| 2020 | |
| 2021 | Full syntax: C<< (?(R1)then|else) >> |
| 2022 | |
| 2023 | =item C<(R&I<NAME>)> |
| 2024 | |
| 2025 | Similar to C<(R1)>, this predicate checks to see if we're executing |
| 2026 | directly inside of the leftmost group with a given name (this is the same |
| 2027 | logic used by C<(?&I<NAME>)> to disambiguate). It does not check the full |
| 2028 | stack, but only the name of the innermost active recursion. |
| 2029 | Full syntax: C<< (?(R&name)then|else) >> |
| 2030 | |
| 2031 | =item C<(DEFINE)> |
| 2032 | |
| 2033 | In this case, the yes-pattern is never directly executed, and no |
| 2034 | no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient. |
| 2035 | See below for details. |
| 2036 | Full syntax: C<< (?(DEFINE)definitions...) >> |
| 2037 | |
| 2038 | =back |
| 2039 | |
| 2040 | For example: |
| 2041 | |
| 2042 | m{ ( \( )? |
| 2043 | [^()]+ |
| 2044 | (?(1) \) ) |
| 2045 | }x |
| 2046 | |
| 2047 | matches a chunk of non-parentheses, possibly included in parentheses |
| 2048 | themselves. |
| 2049 | |
| 2050 | A special form is the C<(DEFINE)> predicate, which never executes its |
| 2051 | yes-pattern directly, and does not allow a no-pattern. This allows one to |
| 2052 | define subpatterns which will be executed only by the recursion mechanism. |
| 2053 | This way, you can define a set of regular expression rules that can be |
| 2054 | bundled into any pattern you choose. |
| 2055 | |
| 2056 | It is recommended that for this usage you put the DEFINE block at the |
| 2057 | end of the pattern, and that you name any subpatterns defined within it. |
| 2058 | |
| 2059 | Also, it's worth noting that patterns defined this way probably will |
| 2060 | not be as efficient, as the optimizer is not very clever about |
| 2061 | handling them. |
| 2062 | |
| 2063 | An example of how this might be used is as follows: |
| 2064 | |
| 2065 | /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT)) |
| 2066 | (?(DEFINE) |
| 2067 | (?<NAME_PAT>....) |
| 2068 | (?<ADDRESS_PAT>....) |
| 2069 | )/x |
| 2070 | |
| 2071 | Note that capture groups matched inside of recursion are not accessible |
| 2072 | after the recursion returns, so the extra layer of capturing groups is |
| 2073 | necessary. Thus C<$+{NAME_PAT}> would not be defined even though |
| 2074 | C<$+{NAME}> would be. |
| 2075 | |
| 2076 | Finally, keep in mind that subpatterns created inside a DEFINE block |
| 2077 | count towards the absolute and relative number of captures, so this: |
| 2078 | |
| 2079 | my @captures = "a" =~ /(.) # First capture |
| 2080 | (?(DEFINE) |
| 2081 | (?<EXAMPLE> 1 ) # Second capture |
| 2082 | )/x; |
| 2083 | say scalar @captures; |
| 2084 | |
| 2085 | Will output 2, not 1. This is particularly important if you intend to |
| 2086 | compile the definitions with the C<qr//> operator, and later |
| 2087 | interpolate them in another pattern. |
| 2088 | |
| 2089 | =item C<< (?>pattern) >> |
| 2090 | X<backtrack> X<backtracking> X<atomic> X<possessive> |
| 2091 | |
| 2092 | An "independent" subexpression, one which matches the substring |
| 2093 | that a I<standalone> C<pattern> would match if anchored at the given |
| 2094 | position, and it matches I<nothing other than this substring>. This |
| 2095 | construct is useful for optimizations of what would otherwise be |
| 2096 | "eternal" matches, because it will not backtrack (see L</"Backtracking">). |
| 2097 | It may also be useful in places where the "grab all you can, and do not |
| 2098 | give anything back" semantic is desirable. |
| 2099 | |
| 2100 | For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >> |
| 2101 | (anchored at the beginning of string, as above) will match I<all> |
| 2102 | characters C<"a"> at the beginning of string, leaving no C<"a"> for |
| 2103 | C<ab> to match. In contrast, C<a*ab> will match the same as C<a+b>, |
| 2104 | since the match of the subgroup C<a*> is influenced by the following |
| 2105 | group C<ab> (see L</"Backtracking">). In particular, C<a*> inside |
| 2106 | C<a*ab> will match fewer characters than a standalone C<a*>, since |
| 2107 | this makes the tail match. |
| 2108 | |
| 2109 | C<< (?>pattern) >> does not disable backtracking altogether once it has |
| 2110 | matched. It is still possible to backtrack past the construct, but not |
| 2111 | into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar". |
| 2112 | |
| 2113 | An effect similar to C<< (?>pattern) >> may be achieved by writing |
| 2114 | C<(?=(pattern))\g{-1}>. This matches the same substring as a standalone |
| 2115 | C<a+>, and the following C<\g{-1}> eats the matched string; it therefore |
| 2116 | makes a zero-length assertion into an analogue of C<< (?>...) >>. |
| 2117 | (The difference between these two constructs is that the second one |
| 2118 | uses a capturing group, thus shifting ordinals of backreferences |
| 2119 | in the rest of a regular expression.) |
| 2120 | |
| 2121 | Consider this pattern: |
| 2122 | |
| 2123 | m{ \( |
| 2124 | ( |
| 2125 | [^()]+ # x+ |
| 2126 | | |
| 2127 | \( [^()]* \) |
| 2128 | )+ |
| 2129 | \) |
| 2130 | }x |
| 2131 | |
| 2132 | That will efficiently match a nonempty group with matching parentheses |
| 2133 | two levels deep or less. However, if there is no such group, it |
| 2134 | will take virtually forever on a long string. That's because there |
| 2135 | are so many different ways to split a long string into several |
| 2136 | substrings. This is what C<(.+)+> is doing, and C<(.+)+> is similar |
| 2137 | to a subpattern of the above pattern. Consider how the pattern |
| 2138 | above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several |
| 2139 | seconds, but that each extra letter doubles this time. This |
| 2140 | exponential performance will make it appear that your program has |
| 2141 | hung. However, a tiny change to this pattern |
| 2142 | |
| 2143 | m{ \( |
| 2144 | ( |
| 2145 | (?> [^()]+ ) # change x+ above to (?> x+ ) |
| 2146 | | |
| 2147 | \( [^()]* \) |
| 2148 | )+ |
| 2149 | \) |
| 2150 | }x |
| 2151 | |
| 2152 | which uses C<< (?>...) >> matches exactly when the one above does (verifying |
| 2153 | this yourself would be a productive exercise), but finishes in a fourth |
| 2154 | the time when used on a similar string with 1000000 C<"a">s. Be aware, |
| 2155 | however, that, when this construct is followed by a |
| 2156 | quantifier, it currently triggers a warning message under |
| 2157 | the C<use warnings> pragma or B<-w> switch saying it |
| 2158 | C<"matches null string many times in regex">. |
| 2159 | |
| 2160 | On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable |
| 2161 | effect may be achieved by negative lookahead, as in C<[^()]+ (?! [^()] )>. |
| 2162 | This was only 4 times slower on a string with 1000000 C<"a">s. |
| 2163 | |
| 2164 | The "grab all you can, and do not give anything back" semantic is desirable |
| 2165 | in many situations where on the first sight a simple C<()*> looks like |
| 2166 | the correct solution. Suppose we parse text with comments being delimited |
| 2167 | by C<"#"> followed by some optional (horizontal) whitespace. Contrary to |
| 2168 | its appearance, C<#[ \t]*> I<is not> the correct subexpression to match |
| 2169 | the comment delimiter, because it may "give up" some whitespace if |
| 2170 | the remainder of the pattern can be made to match that way. The correct |
| 2171 | answer is either one of these: |
| 2172 | |
| 2173 | (?>#[ \t]*) |
| 2174 | #[ \t]*(?![ \t]) |
| 2175 | |
| 2176 | For example, to grab non-empty comments into C<$1>, one should use either |
| 2177 | one of these: |
| 2178 | |
| 2179 | / (?> \# [ \t]* ) ( .+ ) /x; |
| 2180 | / \# [ \t]* ( [^ \t] .* ) /x; |
| 2181 | |
| 2182 | Which one you pick depends on which of these expressions better reflects |
| 2183 | the above specification of comments. |
| 2184 | |
| 2185 | In some literature this construct is called "atomic matching" or |
| 2186 | "possessive matching". |
| 2187 | |
| 2188 | Possessive quantifiers are equivalent to putting the item they are applied |
| 2189 | to inside of one of these constructs. The following equivalences apply: |
| 2190 | |
| 2191 | Quantifier Form Bracketing Form |
| 2192 | --------------- --------------- |
| 2193 | PAT*+ (?>PAT*) |
| 2194 | PAT++ (?>PAT+) |
| 2195 | PAT?+ (?>PAT?) |
| 2196 | PAT{min,max}+ (?>PAT{min,max}) |
| 2197 | |
| 2198 | =item C<(?[ ])> |
| 2199 | |
| 2200 | See L<perlrecharclass/Extended Bracketed Character Classes>. |
| 2201 | |
| 2202 | Note that this feature is currently L<experimental|perlpolicy/experimental>; |
| 2203 | using it yields a warning in the C<experimental::regex_sets> category. |
| 2204 | |
| 2205 | =back |
| 2206 | |
| 2207 | =head2 Backtracking |
| 2208 | X<backtrack> X<backtracking> |
| 2209 | |
| 2210 | NOTE: This section presents an abstract approximation of regular |
| 2211 | expression behavior. For a more rigorous (and complicated) view of |
| 2212 | the rules involved in selecting a match among possible alternatives, |
| 2213 | see L</Combining RE Pieces>. |
| 2214 | |
| 2215 | A fundamental feature of regular expression matching involves the |
| 2216 | notion called I<backtracking>, which is currently used (when needed) |
| 2217 | by all regular non-possessive expression quantifiers, namely C<"*">, C<*?>, C<"+">, |
| 2218 | C<+?>, C<{n,m}>, and C<{n,m}?>. Backtracking is often optimized |
| 2219 | internally, but the general principle outlined here is valid. |
| 2220 | |
| 2221 | For a regular expression to match, the I<entire> regular expression must |
| 2222 | match, not just part of it. So if the beginning of a pattern containing a |
| 2223 | quantifier succeeds in a way that causes later parts in the pattern to |
| 2224 | fail, the matching engine backs up and recalculates the beginning |
| 2225 | part--that's why it's called backtracking. |
| 2226 | |
| 2227 | Here is an example of backtracking: Let's say you want to find the |
| 2228 | word following "foo" in the string "Food is on the foo table.": |
| 2229 | |
| 2230 | $_ = "Food is on the foo table."; |
| 2231 | if ( /\b(foo)\s+(\w+)/i ) { |
| 2232 | print "$2 follows $1.\n"; |
| 2233 | } |
| 2234 | |
| 2235 | When the match runs, the first part of the regular expression (C<\b(foo)>) |
| 2236 | finds a possible match right at the beginning of the string, and loads up |
| 2237 | C<$1> with "Foo". However, as soon as the matching engine sees that there's |
| 2238 | no whitespace following the "Foo" that it had saved in C<$1>, it realizes its |
| 2239 | mistake and starts over again one character after where it had the |
| 2240 | tentative match. This time it goes all the way until the next occurrence |
| 2241 | of "foo". The complete regular expression matches this time, and you get |
| 2242 | the expected output of "table follows foo." |
| 2243 | |
| 2244 | Sometimes minimal matching can help a lot. Imagine you'd like to match |
| 2245 | everything between "foo" and "bar". Initially, you write something |
| 2246 | like this: |
| 2247 | |
| 2248 | $_ = "The food is under the bar in the barn."; |
| 2249 | if ( /foo(.*)bar/ ) { |
| 2250 | print "got <$1>\n"; |
| 2251 | } |
| 2252 | |
| 2253 | Which perhaps unexpectedly yields: |
| 2254 | |
| 2255 | got <d is under the bar in the > |
| 2256 | |
| 2257 | That's because C<.*> was greedy, so you get everything between the |
| 2258 | I<first> "foo" and the I<last> "bar". Here it's more effective |
| 2259 | to use minimal matching to make sure you get the text between a "foo" |
| 2260 | and the first "bar" thereafter. |
| 2261 | |
| 2262 | if ( /foo(.*?)bar/ ) { print "got <$1>\n" } |
| 2263 | got <d is under the > |
| 2264 | |
| 2265 | Here's another example. Let's say you'd like to match a number at the end |
| 2266 | of a string, and you also want to keep the preceding part of the match. |
| 2267 | So you write this: |
| 2268 | |
| 2269 | $_ = "I have 2 numbers: 53147"; |
| 2270 | if ( /(.*)(\d*)/ ) { # Wrong! |
| 2271 | print "Beginning is <$1>, number is <$2>.\n"; |
| 2272 | } |
| 2273 | |
| 2274 | That won't work at all, because C<.*> was greedy and gobbled up the |
| 2275 | whole string. As C<\d*> can match on an empty string the complete |
| 2276 | regular expression matched successfully. |
| 2277 | |
| 2278 | Beginning is <I have 2 numbers: 53147>, number is <>. |
| 2279 | |
| 2280 | Here are some variants, most of which don't work: |
| 2281 | |
| 2282 | $_ = "I have 2 numbers: 53147"; |
| 2283 | @pats = qw{ |
| 2284 | (.*)(\d*) |
| 2285 | (.*)(\d+) |
| 2286 | (.*?)(\d*) |
| 2287 | (.*?)(\d+) |
| 2288 | (.*)(\d+)$ |
| 2289 | (.*?)(\d+)$ |
| 2290 | (.*)\b(\d+)$ |
| 2291 | (.*\D)(\d+)$ |
| 2292 | }; |
| 2293 | |
| 2294 | for $pat (@pats) { |
| 2295 | printf "%-12s ", $pat; |
| 2296 | if ( /$pat/ ) { |
| 2297 | print "<$1> <$2>\n"; |
| 2298 | } else { |
| 2299 | print "FAIL\n"; |
| 2300 | } |
| 2301 | } |
| 2302 | |
| 2303 | That will print out: |
| 2304 | |
| 2305 | (.*)(\d*) <I have 2 numbers: 53147> <> |
| 2306 | (.*)(\d+) <I have 2 numbers: 5314> <7> |
| 2307 | (.*?)(\d*) <> <> |
| 2308 | (.*?)(\d+) <I have > <2> |
| 2309 | (.*)(\d+)$ <I have 2 numbers: 5314> <7> |
| 2310 | (.*?)(\d+)$ <I have 2 numbers: > <53147> |
| 2311 | (.*)\b(\d+)$ <I have 2 numbers: > <53147> |
| 2312 | (.*\D)(\d+)$ <I have 2 numbers: > <53147> |
| 2313 | |
| 2314 | As you see, this can be a bit tricky. It's important to realize that a |
| 2315 | regular expression is merely a set of assertions that gives a definition |
| 2316 | of success. There may be 0, 1, or several different ways that the |
| 2317 | definition might succeed against a particular string. And if there are |
| 2318 | multiple ways it might succeed, you need to understand backtracking to |
| 2319 | know which variety of success you will achieve. |
| 2320 | |
| 2321 | When using lookahead assertions and negations, this can all get even |
| 2322 | trickier. Imagine you'd like to find a sequence of non-digits not |
| 2323 | followed by "123". You might try to write that as |
| 2324 | |
| 2325 | $_ = "ABC123"; |
| 2326 | if ( /^\D*(?!123)/ ) { # Wrong! |
| 2327 | print "Yup, no 123 in $_\n"; |
| 2328 | } |
| 2329 | |
| 2330 | But that isn't going to match; at least, not the way you're hoping. It |
| 2331 | claims that there is no 123 in the string. Here's a clearer picture of |
| 2332 | why that pattern matches, contrary to popular expectations: |
| 2333 | |
| 2334 | $x = 'ABC123'; |
| 2335 | $y = 'ABC445'; |
| 2336 | |
| 2337 | print "1: got $1\n" if $x =~ /^(ABC)(?!123)/; |
| 2338 | print "2: got $1\n" if $y =~ /^(ABC)(?!123)/; |
| 2339 | |
| 2340 | print "3: got $1\n" if $x =~ /^(\D*)(?!123)/; |
| 2341 | print "4: got $1\n" if $y =~ /^(\D*)(?!123)/; |
| 2342 | |
| 2343 | This prints |
| 2344 | |
| 2345 | 2: got ABC |
| 2346 | 3: got AB |
| 2347 | 4: got ABC |
| 2348 | |
| 2349 | You might have expected test 3 to fail because it seems to a more |
| 2350 | general purpose version of test 1. The important difference between |
| 2351 | them is that test 3 contains a quantifier (C<\D*>) and so can use |
| 2352 | backtracking, whereas test 1 will not. What's happening is |
| 2353 | that you've asked "Is it true that at the start of C<$x>, following 0 or more |
| 2354 | non-digits, you have something that's not 123?" If the pattern matcher had |
| 2355 | let C<\D*> expand to "ABC", this would have caused the whole pattern to |
| 2356 | fail. |
| 2357 | |
| 2358 | The search engine will initially match C<\D*> with "ABC". Then it will |
| 2359 | try to match C<(?!123)> with "123", which fails. But because |
| 2360 | a quantifier (C<\D*>) has been used in the regular expression, the |
| 2361 | search engine can backtrack and retry the match differently |
| 2362 | in the hope of matching the complete regular expression. |
| 2363 | |
| 2364 | The pattern really, I<really> wants to succeed, so it uses the |
| 2365 | standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this |
| 2366 | time. Now there's indeed something following "AB" that is not |
| 2367 | "123". It's "C123", which suffices. |
| 2368 | |
| 2369 | We can deal with this by using both an assertion and a negation. |
| 2370 | We'll say that the first part in C<$1> must be followed both by a digit |
| 2371 | and by something that's not "123". Remember that the lookaheads |
| 2372 | are zero-width expressions--they only look, but don't consume any |
| 2373 | of the string in their match. So rewriting this way produces what |
| 2374 | you'd expect; that is, case 5 will fail, but case 6 succeeds: |
| 2375 | |
| 2376 | print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/; |
| 2377 | print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/; |
| 2378 | |
| 2379 | 6: got ABC |
| 2380 | |
| 2381 | In other words, the two zero-width assertions next to each other work as though |
| 2382 | they're ANDed together, just as you'd use any built-in assertions: C</^$/> |
| 2383 | matches only if you're at the beginning of the line AND the end of the |
| 2384 | line simultaneously. The deeper underlying truth is that juxtaposition in |
| 2385 | regular expressions always means AND, except when you write an explicit OR |
| 2386 | using the vertical bar. C</ab/> means match "a" AND (then) match "b", |
| 2387 | although the attempted matches are made at different positions because "a" |
| 2388 | is not a zero-width assertion, but a one-width assertion. |
| 2389 | |
| 2390 | B<WARNING>: Particularly complicated regular expressions can take |
| 2391 | exponential time to solve because of the immense number of possible |
| 2392 | ways they can use backtracking to try for a match. For example, without |
| 2393 | internal optimizations done by the regular expression engine, this will |
| 2394 | take a painfully long time to run: |
| 2395 | |
| 2396 | 'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/ |
| 2397 | |
| 2398 | And if you used C<"*">'s in the internal groups instead of limiting them |
| 2399 | to 0 through 5 matches, then it would take forever--or until you ran |
| 2400 | out of stack space. Moreover, these internal optimizations are not |
| 2401 | always applicable. For example, if you put C<{0,5}> instead of C<"*"> |
| 2402 | on the external group, no current optimization is applicable, and the |
| 2403 | match takes a long time to finish. |
| 2404 | |
| 2405 | A powerful tool for optimizing such beasts is what is known as an |
| 2406 | "independent group", |
| 2407 | which does not backtrack (see L</C<< (?>pattern) >>>). Note also that |
| 2408 | zero-length lookahead/lookbehind assertions will not backtrack to make |
| 2409 | the tail match, since they are in "logical" context: only |
| 2410 | whether they match is considered relevant. For an example |
| 2411 | where side-effects of lookahead I<might> have influenced the |
| 2412 | following match, see L</C<< (?>pattern) >>>. |
| 2413 | |
| 2414 | =head2 Special Backtracking Control Verbs |
| 2415 | |
| 2416 | These special patterns are generally of the form C<(*I<VERB>:I<ARG>)>. Unless |
| 2417 | otherwise stated the I<ARG> argument is optional; in some cases, it is |
| 2418 | mandatory. |
| 2419 | |
| 2420 | Any pattern containing a special backtracking verb that allows an argument |
| 2421 | has the special behaviour that when executed it sets the current package's |
| 2422 | C<$REGERROR> and C<$REGMARK> variables. When doing so the following |
| 2423 | rules apply: |
| 2424 | |
| 2425 | On failure, the C<$REGERROR> variable will be set to the I<ARG> value of the |
| 2426 | verb pattern, if the verb was involved in the failure of the match. If the |
| 2427 | I<ARG> part of the pattern was omitted, then C<$REGERROR> will be set to the |
| 2428 | name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was |
| 2429 | none. Also, the C<$REGMARK> variable will be set to FALSE. |
| 2430 | |
| 2431 | On a successful match, the C<$REGERROR> variable will be set to FALSE, and |
| 2432 | the C<$REGMARK> variable will be set to the name of the last |
| 2433 | C<(*MARK:NAME)> pattern executed. See the explanation for the |
| 2434 | C<(*MARK:NAME)> verb below for more details. |
| 2435 | |
| 2436 | B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1> |
| 2437 | and most other regex-related variables. They are not local to a scope, nor |
| 2438 | readonly, but instead are volatile package variables similar to C<$AUTOLOAD>. |
| 2439 | They are set in the package containing the code that I<executed> the regex |
| 2440 | (rather than the one that compiled it, where those differ). If necessary, you |
| 2441 | can use C<local> to localize changes to these variables to a specific scope |
| 2442 | before executing a regex. |
| 2443 | |
| 2444 | If a pattern does not contain a special backtracking verb that allows an |
| 2445 | argument, then C<$REGERROR> and C<$REGMARK> are not touched at all. |
| 2446 | |
| 2447 | =over 3 |
| 2448 | |
| 2449 | =item Verbs |
| 2450 | |
| 2451 | =over 4 |
| 2452 | |
| 2453 | =item C<(*PRUNE)> C<(*PRUNE:NAME)> |
| 2454 | X<(*PRUNE)> X<(*PRUNE:NAME)> |
| 2455 | |
| 2456 | This zero-width pattern prunes the backtracking tree at the current point |
| 2457 | when backtracked into on failure. Consider the pattern C</I<A> (*PRUNE) I<B>/>, |
| 2458 | where I<A> and I<B> are complex patterns. Until the C<(*PRUNE)> verb is reached, |
| 2459 | I<A> may backtrack as necessary to match. Once it is reached, matching |
| 2460 | continues in I<B>, which may also backtrack as necessary; however, should B |
| 2461 | not match, then no further backtracking will take place, and the pattern |
| 2462 | will fail outright at the current starting position. |
| 2463 | |
| 2464 | The following example counts all the possible matching strings in a |
| 2465 | pattern (without actually matching any of them). |
| 2466 | |
| 2467 | 'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/; |
| 2468 | print "Count=$count\n"; |
| 2469 | |
| 2470 | which produces: |
| 2471 | |
| 2472 | aaab |
| 2473 | aaa |
| 2474 | aa |
| 2475 | a |
| 2476 | aab |
| 2477 | aa |
| 2478 | a |
| 2479 | ab |
| 2480 | a |
| 2481 | Count=9 |
| 2482 | |
| 2483 | If we add a C<(*PRUNE)> before the count like the following |
| 2484 | |
| 2485 | 'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/; |
| 2486 | print "Count=$count\n"; |
| 2487 | |
| 2488 | we prevent backtracking and find the count of the longest matching string |
| 2489 | at each matching starting point like so: |
| 2490 | |
| 2491 | aaab |
| 2492 | aab |
| 2493 | ab |
| 2494 | Count=3 |
| 2495 | |
| 2496 | Any number of C<(*PRUNE)> assertions may be used in a pattern. |
| 2497 | |
| 2498 | See also C<<< L<< /(?>pattern) >> >>> and possessive quantifiers for |
| 2499 | other ways to |
| 2500 | control backtracking. In some cases, the use of C<(*PRUNE)> can be |
| 2501 | replaced with a C<< (?>pattern) >> with no functional difference; however, |
| 2502 | C<(*PRUNE)> can be used to handle cases that cannot be expressed using a |
| 2503 | C<< (?>pattern) >> alone. |
| 2504 | |
| 2505 | =item C<(*SKIP)> C<(*SKIP:NAME)> |
| 2506 | X<(*SKIP)> |
| 2507 | |
| 2508 | This zero-width pattern is similar to C<(*PRUNE)>, except that on |
| 2509 | failure it also signifies that whatever text that was matched leading up |
| 2510 | to the C<(*SKIP)> pattern being executed cannot be part of I<any> match |
| 2511 | of this pattern. This effectively means that the regex engine "skips" forward |
| 2512 | to this position on failure and tries to match again, (assuming that |
| 2513 | there is sufficient room to match). |
| 2514 | |
| 2515 | The name of the C<(*SKIP:NAME)> pattern has special significance. If a |
| 2516 | C<(*MARK:NAME)> was encountered while matching, then it is that position |
| 2517 | which is used as the "skip point". If no C<(*MARK)> of that name was |
| 2518 | encountered, then the C<(*SKIP)> operator has no effect. When used |
| 2519 | without a name the "skip point" is where the match point was when |
| 2520 | executing the C<(*SKIP)> pattern. |
| 2521 | |
| 2522 | Compare the following to the examples in C<(*PRUNE)>; note the string |
| 2523 | is twice as long: |
| 2524 | |
| 2525 | 'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/; |
| 2526 | print "Count=$count\n"; |
| 2527 | |
| 2528 | outputs |
| 2529 | |
| 2530 | aaab |
| 2531 | aaab |
| 2532 | Count=2 |
| 2533 | |
| 2534 | Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)> |
| 2535 | executed, the next starting point will be where the cursor was when the |
| 2536 | C<(*SKIP)> was executed. |
| 2537 | |
| 2538 | =item C<(*MARK:NAME)> C<(*:NAME)> |
| 2539 | X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)> |
| 2540 | |
| 2541 | This zero-width pattern can be used to mark the point reached in a string |
| 2542 | when a certain part of the pattern has been successfully matched. This |
| 2543 | mark may be given a name. A later C<(*SKIP)> pattern will then skip |
| 2544 | forward to that point if backtracked into on failure. Any number of |
| 2545 | C<(*MARK)> patterns are allowed, and the I<NAME> portion may be duplicated. |
| 2546 | |
| 2547 | In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)> |
| 2548 | can be used to "label" a pattern branch, so that after matching, the |
| 2549 | program can determine which branches of the pattern were involved in the |
| 2550 | match. |
| 2551 | |
| 2552 | When a match is successful, the C<$REGMARK> variable will be set to the |
| 2553 | name of the most recently executed C<(*MARK:NAME)> that was involved |
| 2554 | in the match. |
| 2555 | |
| 2556 | This can be used to determine which branch of a pattern was matched |
| 2557 | without using a separate capture group for each branch, which in turn |
| 2558 | can result in a performance improvement, as perl cannot optimize |
| 2559 | C</(?:(x)|(y)|(z))/> as efficiently as something like |
| 2560 | C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>. |
| 2561 | |
| 2562 | When a match has failed, and unless another verb has been involved in |
| 2563 | failing the match and has provided its own name to use, the C<$REGERROR> |
| 2564 | variable will be set to the name of the most recently executed |
| 2565 | C<(*MARK:NAME)>. |
| 2566 | |
| 2567 | See L</(*SKIP)> for more details. |
| 2568 | |
| 2569 | As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>. |
| 2570 | |
| 2571 | =item C<(*THEN)> C<(*THEN:NAME)> |
| 2572 | |
| 2573 | This is similar to the "cut group" operator C<::> from Perl 6. Like |
| 2574 | C<(*PRUNE)>, this verb always matches, and when backtracked into on |
| 2575 | failure, it causes the regex engine to try the next alternation in the |
| 2576 | innermost enclosing group (capturing or otherwise) that has alternations. |
| 2577 | The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not |
| 2578 | count as an alternation, as far as C<(*THEN)> is concerned. |
| 2579 | |
| 2580 | Its name comes from the observation that this operation combined with the |
| 2581 | alternation operator (C<"|">) can be used to create what is essentially a |
| 2582 | pattern-based if/then/else block: |
| 2583 | |
| 2584 | ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ ) |
| 2585 | |
| 2586 | Note that if this operator is used and NOT inside of an alternation then |
| 2587 | it acts exactly like the C<(*PRUNE)> operator. |
| 2588 | |
| 2589 | / A (*PRUNE) B / |
| 2590 | |
| 2591 | is the same as |
| 2592 | |
| 2593 | / A (*THEN) B / |
| 2594 | |
| 2595 | but |
| 2596 | |
| 2597 | / ( A (*THEN) B | C ) / |
| 2598 | |
| 2599 | is not the same as |
| 2600 | |
| 2601 | / ( A (*PRUNE) B | C ) / |
| 2602 | |
| 2603 | as after matching the I<A> but failing on the I<B> the C<(*THEN)> verb will |
| 2604 | backtrack and try I<C>; but the C<(*PRUNE)> verb will simply fail. |
| 2605 | |
| 2606 | =item C<(*COMMIT)> C<(*COMMIT:args)> |
| 2607 | X<(*COMMIT)> |
| 2608 | |
| 2609 | This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a |
| 2610 | zero-width pattern similar to C<(*SKIP)>, except that when backtracked |
| 2611 | into on failure it causes the match to fail outright. No further attempts |
| 2612 | to find a valid match by advancing the start pointer will occur again. |
| 2613 | For example, |
| 2614 | |
| 2615 | 'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/; |
| 2616 | print "Count=$count\n"; |
| 2617 | |
| 2618 | outputs |
| 2619 | |
| 2620 | aaab |
| 2621 | Count=1 |
| 2622 | |
| 2623 | In other words, once the C<(*COMMIT)> has been entered, and if the pattern |
| 2624 | does not match, the regex engine will not try any further matching on the |
| 2625 | rest of the string. |
| 2626 | |
| 2627 | =item C<(*FAIL)> C<(*F)> C<(*FAIL:arg)> |
| 2628 | X<(*FAIL)> X<(*F)> |
| 2629 | |
| 2630 | This pattern matches nothing and always fails. It can be used to force the |
| 2631 | engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In |
| 2632 | fact, C<(?!)> gets optimised into C<(*FAIL)> internally. You can provide |
| 2633 | an argument so that if the match fails because of this C<FAIL> directive |
| 2634 | the argument can be obtained from C<$REGERROR>. |
| 2635 | |
| 2636 | It is probably useful only when combined with C<(?{})> or C<(??{})>. |
| 2637 | |
| 2638 | =item C<(*ACCEPT)> C<(*ACCEPT:arg)> |
| 2639 | X<(*ACCEPT)> |
| 2640 | |
| 2641 | This pattern matches nothing and causes the end of successful matching at |
| 2642 | the point at which the C<(*ACCEPT)> pattern was encountered, regardless of |
| 2643 | whether there is actually more to match in the string. When inside of a |
| 2644 | nested pattern, such as recursion, or in a subpattern dynamically generated |
| 2645 | via C<(??{})>, only the innermost pattern is ended immediately. |
| 2646 | |
| 2647 | If the C<(*ACCEPT)> is inside of capturing groups then the groups are |
| 2648 | marked as ended at the point at which the C<(*ACCEPT)> was encountered. |
| 2649 | For instance: |
| 2650 | |
| 2651 | 'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x; |
| 2652 | |
| 2653 | will match, and C<$1> will be C<AB> and C<$2> will be C<"B">, C<$3> will not |
| 2654 | be set. If another branch in the inner parentheses was matched, such as in the |
| 2655 | string 'ACDE', then the C<"D"> and C<"E"> would have to be matched as well. |
| 2656 | |
| 2657 | You can provide an argument, which will be available in the var |
| 2658 | C<$REGMARK> after the match completes. |
| 2659 | |
| 2660 | =back |
| 2661 | |
| 2662 | =back |
| 2663 | |
| 2664 | =head2 Warning on C<\1> Instead of C<$1> |
| 2665 | |
| 2666 | Some people get too used to writing things like: |
| 2667 | |
| 2668 | $pattern =~ s/(\W)/\\\1/g; |
| 2669 | |
| 2670 | This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid |
| 2671 | shocking the |
| 2672 | B<sed> addicts, but it's a dirty habit to get into. That's because in |
| 2673 | PerlThink, the righthand side of an C<s///> is a double-quoted string. C<\1> in |
| 2674 | the usual double-quoted string means a control-A. The customary Unix |
| 2675 | meaning of C<\1> is kludged in for C<s///>. However, if you get into the habit |
| 2676 | of doing that, you get yourself into trouble if you then add an C</e> |
| 2677 | modifier. |
| 2678 | |
| 2679 | s/(\d+)/ \1 + 1 /eg; # causes warning under -w |
| 2680 | |
| 2681 | Or if you try to do |
| 2682 | |
| 2683 | s/(\d+)/\1000/; |
| 2684 | |
| 2685 | You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with |
| 2686 | C<${1}000>. The operation of interpolation should not be confused |
| 2687 | with the operation of matching a backreference. Certainly they mean two |
| 2688 | different things on the I<left> side of the C<s///>. |
| 2689 | |
| 2690 | =head2 Repeated Patterns Matching a Zero-length Substring |
| 2691 | |
| 2692 | B<WARNING>: Difficult material (and prose) ahead. This section needs a rewrite. |
| 2693 | |
| 2694 | Regular expressions provide a terse and powerful programming language. As |
| 2695 | with most other power tools, power comes together with the ability |
| 2696 | to wreak havoc. |
| 2697 | |
| 2698 | A common abuse of this power stems from the ability to make infinite |
| 2699 | loops using regular expressions, with something as innocuous as: |
| 2700 | |
| 2701 | 'foo' =~ m{ ( o? )* }x; |
| 2702 | |
| 2703 | The C<o?> matches at the beginning of "C<foo>", and since the position |
| 2704 | in the string is not moved by the match, C<o?> would match again and again |
| 2705 | because of the C<"*"> quantifier. Another common way to create a similar cycle |
| 2706 | is with the looping modifier C</g>: |
| 2707 | |
| 2708 | @matches = ( 'foo' =~ m{ o? }xg ); |
| 2709 | |
| 2710 | or |
| 2711 | |
| 2712 | print "match: <$&>\n" while 'foo' =~ m{ o? }xg; |
| 2713 | |
| 2714 | or the loop implied by C<split()>. |
| 2715 | |
| 2716 | However, long experience has shown that many programming tasks may |
| 2717 | be significantly simplified by using repeated subexpressions that |
| 2718 | may match zero-length substrings. Here's a simple example being: |
| 2719 | |
| 2720 | @chars = split //, $string; # // is not magic in split |
| 2721 | ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// / |
| 2722 | |
| 2723 | Thus Perl allows such constructs, by I<forcefully breaking |
| 2724 | the infinite loop>. The rules for this are different for lower-level |
| 2725 | loops given by the greedy quantifiers C<*+{}>, and for higher-level |
| 2726 | ones like the C</g> modifier or C<split()> operator. |
| 2727 | |
| 2728 | The lower-level loops are I<interrupted> (that is, the loop is |
| 2729 | broken) when Perl detects that a repeated expression matched a |
| 2730 | zero-length substring. Thus |
| 2731 | |
| 2732 | m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x; |
| 2733 | |
| 2734 | is made equivalent to |
| 2735 | |
| 2736 | m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x; |
| 2737 | |
| 2738 | For example, this program |
| 2739 | |
| 2740 | #!perl -l |
| 2741 | "aaaaab" =~ / |
| 2742 | (?: |
| 2743 | a # non-zero |
| 2744 | | # or |
| 2745 | (?{print "hello"}) # print hello whenever this |
| 2746 | # branch is tried |
| 2747 | (?=(b)) # zero-width assertion |
| 2748 | )* # any number of times |
| 2749 | /x; |
| 2750 | print $&; |
| 2751 | print $1; |
| 2752 | |
| 2753 | prints |
| 2754 | |
| 2755 | hello |
| 2756 | aaaaa |
| 2757 | b |
| 2758 | |
| 2759 | Notice that "hello" is only printed once, as when Perl sees that the sixth |
| 2760 | iteration of the outermost C<(?:)*> matches a zero-length string, it stops |
| 2761 | the C<"*">. |
| 2762 | |
| 2763 | The higher-level loops preserve an additional state between iterations: |
| 2764 | whether the last match was zero-length. To break the loop, the following |
| 2765 | match after a zero-length match is prohibited to have a length of zero. |
| 2766 | This prohibition interacts with backtracking (see L</"Backtracking">), |
| 2767 | and so the I<second best> match is chosen if the I<best> match is of |
| 2768 | zero length. |
| 2769 | |
| 2770 | For example: |
| 2771 | |
| 2772 | $_ = 'bar'; |
| 2773 | s/\w??/<$&>/g; |
| 2774 | |
| 2775 | results in C<< <><b><><a><><r><> >>. At each position of the string the best |
| 2776 | match given by non-greedy C<??> is the zero-length match, and the I<second |
| 2777 | best> match is what is matched by C<\w>. Thus zero-length matches |
| 2778 | alternate with one-character-long matches. |
| 2779 | |
| 2780 | Similarly, for repeated C<m/()/g> the second-best match is the match at the |
| 2781 | position one notch further in the string. |
| 2782 | |
| 2783 | The additional state of being I<matched with zero-length> is associated with |
| 2784 | the matched string, and is reset by each assignment to C<pos()>. |
| 2785 | Zero-length matches at the end of the previous match are ignored |
| 2786 | during C<split>. |
| 2787 | |
| 2788 | =head2 Combining RE Pieces |
| 2789 | |
| 2790 | Each of the elementary pieces of regular expressions which were described |
| 2791 | before (such as C<ab> or C<\Z>) could match at most one substring |
| 2792 | at the given position of the input string. However, in a typical regular |
| 2793 | expression these elementary pieces are combined into more complicated |
| 2794 | patterns using combining operators C<ST>, C<S|T>, C<S*> I<etc>. |
| 2795 | (in these examples C<"S"> and C<"T"> are regular subexpressions). |
| 2796 | |
| 2797 | Such combinations can include alternatives, leading to a problem of choice: |
| 2798 | if we match a regular expression C<a|ab> against C<"abc">, will it match |
| 2799 | substring C<"a"> or C<"ab">? One way to describe which substring is |
| 2800 | actually matched is the concept of backtracking (see L</"Backtracking">). |
| 2801 | However, this description is too low-level and makes you think |
| 2802 | in terms of a particular implementation. |
| 2803 | |
| 2804 | Another description starts with notions of "better"/"worse". All the |
| 2805 | substrings which may be matched by the given regular expression can be |
| 2806 | sorted from the "best" match to the "worst" match, and it is the "best" |
| 2807 | match which is chosen. This substitutes the question of "what is chosen?" |
| 2808 | by the question of "which matches are better, and which are worse?". |
| 2809 | |
| 2810 | Again, for elementary pieces there is no such question, since at most |
| 2811 | one match at a given position is possible. This section describes the |
| 2812 | notion of better/worse for combining operators. In the description |
| 2813 | below C<"S"> and C<"T"> are regular subexpressions. |
| 2814 | |
| 2815 | =over 4 |
| 2816 | |
| 2817 | =item C<ST> |
| 2818 | |
| 2819 | Consider two possible matches, C<AB> and C<A'B'>, C<"A"> and C<A'> are |
| 2820 | substrings which can be matched by C<"S">, C<"B"> and C<B'> are substrings |
| 2821 | which can be matched by C<"T">. |
| 2822 | |
| 2823 | If C<"A"> is a better match for C<"S"> than C<A'>, C<AB> is a better |
| 2824 | match than C<A'B'>. |
| 2825 | |
| 2826 | If C<"A"> and C<A'> coincide: C<AB> is a better match than C<AB'> if |
| 2827 | C<"B"> is a better match for C<"T"> than C<B'>. |
| 2828 | |
| 2829 | =item C<S|T> |
| 2830 | |
| 2831 | When C<"S"> can match, it is a better match than when only C<"T"> can match. |
| 2832 | |
| 2833 | Ordering of two matches for C<"S"> is the same as for C<"S">. Similar for |
| 2834 | two matches for C<"T">. |
| 2835 | |
| 2836 | =item C<S{REPEAT_COUNT}> |
| 2837 | |
| 2838 | Matches as C<SSS...S> (repeated as many times as necessary). |
| 2839 | |
| 2840 | =item C<S{min,max}> |
| 2841 | |
| 2842 | Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>. |
| 2843 | |
| 2844 | =item C<S{min,max}?> |
| 2845 | |
| 2846 | Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>. |
| 2847 | |
| 2848 | =item C<S?>, C<S*>, C<S+> |
| 2849 | |
| 2850 | Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively. |
| 2851 | |
| 2852 | =item C<S??>, C<S*?>, C<S+?> |
| 2853 | |
| 2854 | Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively. |
| 2855 | |
| 2856 | =item C<< (?>S) >> |
| 2857 | |
| 2858 | Matches the best match for C<"S"> and only that. |
| 2859 | |
| 2860 | =item C<(?=S)>, C<(?<=S)> |
| 2861 | |
| 2862 | Only the best match for C<"S"> is considered. (This is important only if |
| 2863 | C<"S"> has capturing parentheses, and backreferences are used somewhere |
| 2864 | else in the whole regular expression.) |
| 2865 | |
| 2866 | =item C<(?!S)>, C<(?<!S)> |
| 2867 | |
| 2868 | For this grouping operator there is no need to describe the ordering, since |
| 2869 | only whether or not C<"S"> can match is important. |
| 2870 | |
| 2871 | =item C<(??{ EXPR })>, C<(?I<PARNO>)> |
| 2872 | |
| 2873 | The ordering is the same as for the regular expression which is |
| 2874 | the result of EXPR, or the pattern contained by capture group I<PARNO>. |
| 2875 | |
| 2876 | =item C<(?(condition)yes-pattern|no-pattern)> |
| 2877 | |
| 2878 | Recall that which of C<yes-pattern> or C<no-pattern> actually matches is |
| 2879 | already determined. The ordering of the matches is the same as for the |
| 2880 | chosen subexpression. |
| 2881 | |
| 2882 | =back |
| 2883 | |
| 2884 | The above recipes describe the ordering of matches I<at a given position>. |
| 2885 | One more rule is needed to understand how a match is determined for the |
| 2886 | whole regular expression: a match at an earlier position is always better |
| 2887 | than a match at a later position. |
| 2888 | |
| 2889 | =head2 Creating Custom RE Engines |
| 2890 | |
| 2891 | As of Perl 5.10.0, one can create custom regular expression engines. This |
| 2892 | is not for the faint of heart, as they have to plug in at the C level. See |
| 2893 | L<perlreapi> for more details. |
| 2894 | |
| 2895 | As an alternative, overloaded constants (see L<overload>) provide a simple |
| 2896 | way to extend the functionality of the RE engine, by substituting one |
| 2897 | pattern for another. |
| 2898 | |
| 2899 | Suppose that we want to enable a new RE escape-sequence C<\Y|> which |
| 2900 | matches at a boundary between whitespace characters and non-whitespace |
| 2901 | characters. Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly |
| 2902 | at these positions, so we want to have each C<\Y|> in the place of the |
| 2903 | more complicated version. We can create a module C<customre> to do |
| 2904 | this: |
| 2905 | |
| 2906 | package customre; |
| 2907 | use overload; |
| 2908 | |
| 2909 | sub import { |
| 2910 | shift; |
| 2911 | die "No argument to customre::import allowed" if @_; |
| 2912 | overload::constant 'qr' => \&convert; |
| 2913 | } |
| 2914 | |
| 2915 | sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"} |
| 2916 | |
| 2917 | # We must also take care of not escaping the legitimate \\Y| |
| 2918 | # sequence, hence the presence of '\\' in the conversion rules. |
| 2919 | my %rules = ( '\\' => '\\\\', |
| 2920 | 'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ ); |
| 2921 | sub convert { |
| 2922 | my $re = shift; |
| 2923 | $re =~ s{ |
| 2924 | \\ ( \\ | Y . ) |
| 2925 | } |
| 2926 | { $rules{$1} or invalid($re,$1) }sgex; |
| 2927 | return $re; |
| 2928 | } |
| 2929 | |
| 2930 | Now C<use customre> enables the new escape in constant regular |
| 2931 | expressions, I<i.e.>, those without any runtime variable interpolations. |
| 2932 | As documented in L<overload>, this conversion will work only over |
| 2933 | literal parts of regular expressions. For C<\Y|$re\Y|> the variable |
| 2934 | part of this regular expression needs to be converted explicitly |
| 2935 | (but only if the special meaning of C<\Y|> should be enabled inside C<$re>): |
| 2936 | |
| 2937 | use customre; |
| 2938 | $re = <>; |
| 2939 | chomp $re; |
| 2940 | $re = customre::convert $re; |
| 2941 | /\Y|$re\Y|/; |
| 2942 | |
| 2943 | =head2 Embedded Code Execution Frequency |
| 2944 | |
| 2945 | The exact rules for how often C<(??{})> and C<(?{})> are executed in a pattern |
| 2946 | are unspecified. In the case of a successful match you can assume that |
| 2947 | they DWIM and will be executed in left to right order the appropriate |
| 2948 | number of times in the accepting path of the pattern as would any other |
| 2949 | meta-pattern. How non-accepting pathways and match failures affect the |
| 2950 | number of times a pattern is executed is specifically unspecified and |
| 2951 | may vary depending on what optimizations can be applied to the pattern |
| 2952 | and is likely to change from version to version. |
| 2953 | |
| 2954 | For instance in |
| 2955 | |
| 2956 | "aaabcdeeeee"=~/a(?{print "a"})b(?{print "b"})cde/; |
| 2957 | |
| 2958 | the exact number of times "a" or "b" are printed out is unspecified for |
| 2959 | failure, but you may assume they will be printed at least once during |
| 2960 | a successful match, additionally you may assume that if "b" is printed, |
| 2961 | it will be preceded by at least one "a". |
| 2962 | |
| 2963 | In the case of branching constructs like the following: |
| 2964 | |
| 2965 | /a(b|(?{ print "a" }))c(?{ print "c" })/; |
| 2966 | |
| 2967 | you can assume that the input "ac" will output "ac", and that "abc" |
| 2968 | will output only "c". |
| 2969 | |
| 2970 | When embedded code is quantified, successful matches will call the |
| 2971 | code once for each matched iteration of the quantifier. For |
| 2972 | example: |
| 2973 | |
| 2974 | "good" =~ /g(?:o(?{print "o"}))*d/; |
| 2975 | |
| 2976 | will output "o" twice. |
| 2977 | |
| 2978 | =head2 PCRE/Python Support |
| 2979 | |
| 2980 | As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions |
| 2981 | to the regex syntax. While Perl programmers are encouraged to use the |
| 2982 | Perl-specific syntax, the following are also accepted: |
| 2983 | |
| 2984 | =over 4 |
| 2985 | |
| 2986 | =item C<< (?PE<lt>NAMEE<gt>pattern) >> |
| 2987 | |
| 2988 | Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>. |
| 2989 | |
| 2990 | =item C<< (?P=NAME) >> |
| 2991 | |
| 2992 | Backreference to a named capture group. Equivalent to C<< \g{NAME} >>. |
| 2993 | |
| 2994 | =item C<< (?P>NAME) >> |
| 2995 | |
| 2996 | Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>. |
| 2997 | |
| 2998 | =back |
| 2999 | |
| 3000 | =head1 BUGS |
| 3001 | |
| 3002 | There are a number of issues with regard to case-insensitive matching |
| 3003 | in Unicode rules. See C<"i"> under L</Modifiers> above. |
| 3004 | |
| 3005 | This document varies from difficult to understand to completely |
| 3006 | and utterly opaque. The wandering prose riddled with jargon is |
| 3007 | hard to fathom in several places. |
| 3008 | |
| 3009 | This document needs a rewrite that separates the tutorial content |
| 3010 | from the reference content. |
| 3011 | |
| 3012 | =head1 SEE ALSO |
| 3013 | |
| 3014 | The syntax of patterns used in Perl pattern matching evolved from those |
| 3015 | supplied in the Bell Labs Research Unix 8th Edition (Version 8) regex |
| 3016 | routines. (The code is actually derived (distantly) from Henry |
| 3017 | Spencer's freely redistributable reimplementation of those V8 routines.) |
| 3018 | |
| 3019 | L<perlrequick>. |
| 3020 | |
| 3021 | L<perlretut>. |
| 3022 | |
| 3023 | L<perlop/"Regexp Quote-Like Operators">. |
| 3024 | |
| 3025 | L<perlop/"Gory details of parsing quoted constructs">. |
| 3026 | |
| 3027 | L<perlfaq6>. |
| 3028 | |
| 3029 | L<perlfunc/pos>. |
| 3030 | |
| 3031 | L<perllocale>. |
| 3032 | |
| 3033 | L<perlebcdic>. |
| 3034 | |
| 3035 | I<Mastering Regular Expressions> by Jeffrey Friedl, published |
| 3036 | by O'Reilly and Associates. |