This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Bump Data::Dumper version
[perl5.git] / regen_perly.pl
... / ...
CommitLineData
1#!/usr/bin/perl
2#
3# regen_perly.pl, DAPM 12-Feb-04
4#
5# Copyright (c) 2004, 2005, 2006, 2009, 2010, 2011 Larry Wall
6#
7# Given an input file perly.y, run bison on it and produce
8# the following output files:
9#
10# perly.h standard bison header file with minor doctoring of
11# #line directives plus adding a #ifdef PERL_CORE
12#
13# perly.tab the parser table C definitions extracted from the bison output
14# plus an extra table generated by this script.
15#
16# perly.act the action case statements extracted from the bison output
17#
18# Note that perly.c is *not* regenerated - this is now a static file which
19# is not dependent on perly.y any more.
20#
21# If a filename of the form foo.y is given on the command line, then
22# this is used instead as the basename for all the files mentioned
23# above.
24#
25# Note that temporary files of the form perlytmp.h and perlytmp.c are
26# created and then deleted during this process
27#
28# Note also that this script is intended to be run on a UNIX system;
29# it may work elsewhere but no specific attempt has been made to make it
30# portable.
31
32use 5.006;
33sub usage { die "usage: $0 [ -b bison_executable ] [ file.y ]\n" }
34
35use warnings;
36use strict;
37
38our $Verbose;
39BEGIN { require './regen/regen_lib.pl'; }
40
41my $bison = 'bison';
42
43if (@ARGV >= 2 and $ARGV[0] eq '-b') {
44 shift;
45 $bison = shift;
46}
47
48my $y_file = shift || 'perly.y';
49
50usage unless @ARGV==0 && $y_file =~ /\.y$/;
51
52(my $h_file = $y_file) =~ s/\.y$/.h/;
53(my $act_file = $y_file) =~ s/\.y$/.act/;
54(my $tab_file = $y_file) =~ s/\.y$/.tab/;
55(my $tmpc_file = $y_file) =~ s/\.y$/tmp.c/;
56(my $tmph_file = $y_file) =~ s/\.y$/tmp.h/;
57
58# the yytranslate[] table generated by bison is ASCII/EBCDIC sensitive
59
60die "$0: must be run on an ASCII system\n" unless ord 'A' == 65;
61
62# check for correct version number. The constraints are:
63# * must be >= 1.24 to avoid licensing issues.
64# * it must generate the yystos[] table. Version 1.28 doesn't generate
65# this; 1.35+ does
66# * Must produce output which is extractable by the regexes below
67# * Must produce the right values.
68# These last two constraints may well be met by earlier versions, but
69# I simply haven't tested them yet. If it works for you, then modify
70# the test below to allow that version too. DAPM Feb 04.
71
72my $version = `$bison -V`;
73unless ($version) { die <<EOF; }
74Could not find a version of bison in your path. Please install bison.
75EOF
76
77# Don't change this to add new bison versions without testing that the generated
78# files actually work :-) Win32 in particular may not like them. :-(
79unless ($version =~ /\b(2\.[567]|3\.[0-7])\b/) { die <<EOF; }
80
81You have the wrong version of bison in your path; currently versions
822.5-2.7 or 3.0-3.7 are known to work. Try installing
83 http://ftp.gnu.org/gnu/bison/bison-3.3.tar.gz
84or similar. Your bison identifies itself as:
85
86$version
87EOF
88
89# bison's version number, not the entire string, is most useful later on.
90$version = $1;
91
92# creates $tmpc_file and $tmph_file
93my_system("$bison -d -o $tmpc_file $y_file");
94
95open my $ctmp_fh, '<', $tmpc_file or die "Can't open $tmpc_file: $!\n";
96my $clines;
97{ local $/; $clines = <$ctmp_fh>; }
98die "failed to read $tmpc_file: length mismatch\n"
99 unless length $clines == -s $tmpc_file;
100close $ctmp_fh;
101
102my ($actlines, $tablines) = extract($clines);
103
104our %tokens;
105$tablines .= make_type_tab($y_file, $tablines);
106
107my ($act_fh, $tab_fh, $h_fh) = map {
108 open_new($_, '>', { by => $0, from => $y_file });
109} $act_file, $tab_file, $h_file;
110
111print $act_fh $actlines;
112
113print $tab_fh $tablines;
114
115unlink $tmpc_file;
116
117# Wrap PERL_CORE round the symbol definitions. Also, the
118# C<#line 30 "perly.y"> confuses the Win32 resource compiler and the
119# C<#line 188 "perlytmp.h"> gets picked up by make depend, so remove them.
120
121open my $tmph_fh, '<', $tmph_file or die "Can't open $tmph_file: $!\n";
122
123# add integer-encoded #def of the bison version
124
125{
126 $version =~ /^(\d+)\.(\d+)/
127 or die "Can't handle bison version format: '$version'";
128 my ($v1,$v2) = ($1,$2);
129 die "Unexpectedly large bison version '$v1'" if $v1 > 99;
130 die "Unexpectedly large bison subversion '$v2'" if $v2 > 9999;
131
132 printf $h_fh "#define PERL_BISON_VERSION %2d%04d\n\n", $v1, $v2;
133}
134
135my $endcore_done = 0;
136my $gather_tokens = 0;
137my $tokens;
138while (<$tmph_fh>) {
139 # bison 2.6 adds header guards, which break things because of where we
140 # insert #ifdef PERL_CORE, so strip them because they aren't important
141 next if /YY_PERLYTMP_H/;
142
143 print $h_fh "#ifdef PERL_CORE\n" if $. == 1;
144 if (!$endcore_done and /YYSTYPE_IS_DECLARED/) {
145 print $h_fh <<h;
146#ifdef PERL_IN_TOKE_C
147static bool
148S_is_opval_token(int type) {
149 switch (type) {
150h
151 print $h_fh <<i for sort grep $tokens{$_} eq 'opval', keys %tokens;
152 case $_:
153i
154 print $h_fh <<j;
155 return 1;
156 }
157 return 0;
158}
159#endif /* PERL_IN_TOKE_C */
160#endif /* PERL_CORE */
161j
162 $endcore_done = 1;
163 }
164 next if /^#line \d+ ".*"/;
165 if (!$gather_tokens) {
166 $gather_tokens = 1 if /^\s* enum \s* yytokentype \s* \{/x;
167 }
168 else {
169 if (/^\# \s* endif/x) { # The #endif just after the end of the token enum
170 $gather_tokens = 0;
171 $_ .= "\n/* Tokens. */\n$tokens";
172 }
173 else {
174 my ($tok, $val) = /(\w+) \s* = \s* (\d+)/x;
175 $tokens .= "#define $tok $val\n" if $tok;
176 }
177 }
178 print $h_fh $_;
179}
180close $tmph_fh;
181unlink $tmph_file;
182
183foreach ($act_fh, $tab_fh, $h_fh) {
184 read_only_bottom_close_and_rename($_, ['regen_perly.pl', $y_file]);
185}
186
187exit 0;
188
189
190# extract the symbol kinds, tables and actions from the generated .c file
191
192sub extract {
193 my $clines = shift;
194 my $tablines;
195 my $actlines;
196
197 # extract the symbol kind table if it exists
198 $clines =~ m@
199 (?:
200 ^/\* \s* Symbol \s+ kind\. \s* \*/\n
201 )?
202 enum \s+ yysymbol_kind_t \s* \{
203 .*?
204 \} \s* ;\n
205 typedef \s+ enum \s+ \w+ \s+ \w+ ; \n+
206 @xms
207 and $tablines .= $&;
208
209 my $last_table = $version >= 3 ? 'yyr2' : 'yystos';
210 $clines =~ m@
211 (?:
212 ^/* YYFINAL[^\n]+\n #optional comment
213 )?
214 \# \s* define \s* YYFINAL # first #define
215 .*? # other defines + most tables
216 $last_table\[\]\s*= # start of last table
217 .*?
218 }\s*; # end of last table
219 @xms
220 or die "Can't extract tables from $tmpc_file\n";
221 $tablines .= $&;
222
223
224 # extract all the cases in the big action switch statement
225
226 $clines =~ m@
227 switch \s* \( \s* yyn \s* \) \s* { \s*
228 ( .*? default: \s* break; \s* )
229 }
230 @xms
231 or die "Can't extract actions from $tmpc_file\n";
232 $actlines = $1;
233
234 # Remove extraneous comments from bison 2.4
235 $actlines =~ s!\s* /\* \s* Line \s* \d+ \s* of \s* yacc\.c \s* \*/!!gx;
236
237 # Remove extraneous comments from bison 3.x
238 $actlines =~ s!\s* /\* \s* yacc\.c : \d+ \s* \*/!!gx;
239
240 # C<#line 188 "perlytmp.c"> gets picked up by make depend, so remove them.
241 $actlines =~ s/^#line \d+ "\Q$tmpc_file\E".*$//gm;
242
243 # convert yyvsp[nnn] into ps[nnn].val
244
245 $actlines =~ s/yyvsp\[(.*?)\]/ps[$1].val/g
246 or die "Can't convert value stack name\n";
247
248 return $actlines. "\n", $tablines. "\n";
249}
250
251# Generate a table, yy_type_tab[], that specifies for each token, what
252# type of value it holds.
253#
254# Read the .y file and extract a list of all the token names and
255# non-terminal names; then scan the string $tablines for the table yytname,
256# which gives the token index of each token/non-terminal; then use this to
257# create yy_type_tab.
258#
259# ie given (in perly.y),
260#
261# %token <opval> A
262# %token <ival> B
263# %type <pval> C
264# %type <opval> D
265#
266# and (in $tablines),
267#
268# yytname[] = { "A" "B", "C", "D", "E" };
269#
270# then return
271#
272# typedef enum { toketype_ival, toketype_opval, toketype_pval } toketypes;
273#
274# static const toketypes yy_type_tab[]
275# = { toketype_opval, toketype_ival, toketype_pval,
276# toketype_opval, toketype_ival }
277#
278# where "E" has the default type. The default type is determined
279# by the __DEFAULT__ comment next to the appropriate union member in
280# perly.y
281
282sub make_type_tab {
283 my ($y_file, $tablines) = @_;
284 my %just_tokens;
285 my %tokens;
286 my %types;
287 my $default_token;
288 open my $fh, '<', $y_file or die "Can't open $y_file: $!\n";
289 while (<$fh>) {
290 if (/(\$\d+)\s*=[^=]/) {
291 warn "$y_file:$.: dangerous assignment to $1: $_";
292 }
293
294 if (/__DEFAULT__/) {
295 m{(\w+) \s* ; \s* /\* \s* __DEFAULT__}x
296 or die "$y_file: can't parse __DEFAULT__ line: $_";
297 die "$y_file: duplicate __DEFAULT__ line: $_"
298 if defined $default_token;
299 $default_token = $1;
300 next;
301 }
302
303 next unless /^%(token|type)/;
304 s/^%((token)|type)\s+<(\w+)>\s+//
305 or die "$y_file: unparseable token/type line: $_";
306 for (split ' ', $_) {
307 $tokens{$_} = $3;
308 if ($2) {
309 $just_tokens{$_} = $3;
310 }
311 }
312 $types{$3} = 1;
313 }
314 *tokens = \%just_tokens; # perly.h needs this
315 die "$y_file: no __DEFAULT__ token defined\n" unless $default_token;
316 $types{$default_token} = 1;
317
318 $tablines =~ /^\Qstatic const char *const yytname[] =\E\n
319 \{\n
320 (.*?)
321 ^};
322 /xsm
323 or die "Can't extract yytname[] from table string\n";
324 my $fields = $1;
325 $fields =~ s{"((?:[^"\\]|\\.)+)"}
326 { "toketype_" .
327 (defined $tokens{$1} ? $tokens{$1} : $default_token)
328 }ge;
329 $fields =~ s/, \s* (?:0|YY_NULL|YY_NULLPTR) \s* $//x
330 or die "make_type_tab: couldn't delete trailing ',0'\n";
331
332 return
333 "\ntypedef enum {\n\t"
334 . join(", ", map "toketype_$_", sort keys %types)
335 . "\n} toketypes;\n\n"
336 . "/* type of each token/terminal */\n"
337 . "static const toketypes yy_type_tab[] =\n{\n"
338 . $fields
339 . "\n};\n";
340}
341
342
343sub my_system {
344 if ($Verbose) {
345 print "executing: @_\n";
346 }
347 system(@_);
348 if ($? == -1) {
349 die "failed to execute command '@_': $!\n";
350 }
351 elsif ($? & 127) {
352 die sprintf "command '@_' died with signal %d\n",
353 ($? & 127);
354 }
355 elsif ($? >> 8) {
356 die sprintf "command '@_' exited with value %d\n", $? >> 8;
357 }
358}