| 1 | package overload; |
| 2 | |
| 3 | our $VERSION = '1.12'; |
| 4 | |
| 5 | sub nil {} |
| 6 | |
| 7 | sub OVERLOAD { |
| 8 | $package = shift; |
| 9 | my %arg = @_; |
| 10 | my ($sub, $fb); |
| 11 | $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching. |
| 12 | $fb = ${$package . "::()"}; # preserve old fallback value RT#68196 |
| 13 | *{$package . "::()"} = \&nil; # Make it findable via fetchmethod. |
| 14 | for (keys %arg) { |
| 15 | if ($_ eq 'fallback') { |
| 16 | $fb = $arg{$_}; |
| 17 | } else { |
| 18 | $sub = $arg{$_}; |
| 19 | if (not ref $sub and $sub !~ /::/) { |
| 20 | $ {$package . "::(" . $_} = $sub; |
| 21 | $sub = \&nil; |
| 22 | } |
| 23 | #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n"; |
| 24 | *{$package . "::(" . $_} = \&{ $sub }; |
| 25 | } |
| 26 | } |
| 27 | ${$package . "::()"} = $fb; # Make it findable too (fallback only). |
| 28 | } |
| 29 | |
| 30 | sub import { |
| 31 | $package = (caller())[0]; |
| 32 | # *{$package . "::OVERLOAD"} = \&OVERLOAD; |
| 33 | shift; |
| 34 | $package->overload::OVERLOAD(@_); |
| 35 | } |
| 36 | |
| 37 | sub unimport { |
| 38 | $package = (caller())[0]; |
| 39 | ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table |
| 40 | shift; |
| 41 | for (@_) { |
| 42 | if ($_ eq 'fallback') { |
| 43 | undef $ {$package . "::()"}; |
| 44 | } else { |
| 45 | delete $ {$package . "::"}{"(" . $_}; |
| 46 | } |
| 47 | } |
| 48 | } |
| 49 | |
| 50 | sub Overloaded { |
| 51 | my $package = shift; |
| 52 | $package = ref $package if ref $package; |
| 53 | $package->can('()'); |
| 54 | } |
| 55 | |
| 56 | sub ov_method { |
| 57 | my $globref = shift; |
| 58 | return undef unless $globref; |
| 59 | my $sub = \&{*$globref}; |
| 60 | require Scalar::Util; |
| 61 | return $sub |
| 62 | if Scalar::Util::refaddr($sub) != Scalar::Util::refaddr(\&nil); |
| 63 | return shift->can($ {*$globref}); |
| 64 | } |
| 65 | |
| 66 | sub OverloadedStringify { |
| 67 | my $package = shift; |
| 68 | $package = ref $package if ref $package; |
| 69 | #$package->can('(""') |
| 70 | ov_method mycan($package, '(""'), $package |
| 71 | or ov_method mycan($package, '(0+'), $package |
| 72 | or ov_method mycan($package, '(bool'), $package |
| 73 | or ov_method mycan($package, '(nomethod'), $package; |
| 74 | } |
| 75 | |
| 76 | sub Method { |
| 77 | my $package = shift; |
| 78 | if(ref $package) { |
| 79 | local $@; |
| 80 | local $!; |
| 81 | require Scalar::Util; |
| 82 | $package = Scalar::Util::blessed($package); |
| 83 | return undef if !defined $package; |
| 84 | } |
| 85 | #my $meth = $package->can('(' . shift); |
| 86 | ov_method mycan($package, '(' . shift), $package; |
| 87 | #return $meth if $meth ne \&nil; |
| 88 | #return $ {*{$meth}}; |
| 89 | } |
| 90 | |
| 91 | sub AddrRef { |
| 92 | my $package = ref $_[0]; |
| 93 | return "$_[0]" unless $package; |
| 94 | |
| 95 | local $@; |
| 96 | local $!; |
| 97 | require Scalar::Util; |
| 98 | my $class = Scalar::Util::blessed($_[0]); |
| 99 | my $class_prefix = defined($class) ? "$class=" : ""; |
| 100 | my $type = Scalar::Util::reftype($_[0]); |
| 101 | my $addr = Scalar::Util::refaddr($_[0]); |
| 102 | return sprintf("%s%s(0x%x)", $class_prefix, $type, $addr); |
| 103 | } |
| 104 | |
| 105 | *StrVal = *AddrRef; |
| 106 | |
| 107 | sub mycan { # Real can would leave stubs. |
| 108 | my ($package, $meth) = @_; |
| 109 | |
| 110 | local $@; |
| 111 | local $!; |
| 112 | require mro; |
| 113 | |
| 114 | my $mro = mro::get_linear_isa($package); |
| 115 | foreach my $p (@$mro) { |
| 116 | my $fqmeth = $p . q{::} . $meth; |
| 117 | return \*{$fqmeth} if defined &{$fqmeth}; |
| 118 | } |
| 119 | |
| 120 | return undef; |
| 121 | } |
| 122 | |
| 123 | %constants = ( |
| 124 | 'integer' => 0x1000, # HINT_NEW_INTEGER |
| 125 | 'float' => 0x2000, # HINT_NEW_FLOAT |
| 126 | 'binary' => 0x4000, # HINT_NEW_BINARY |
| 127 | 'q' => 0x8000, # HINT_NEW_STRING |
| 128 | 'qr' => 0x10000, # HINT_NEW_RE |
| 129 | ); |
| 130 | |
| 131 | %ops = ( with_assign => "+ - * / % ** << >> x .", |
| 132 | assign => "+= -= *= /= %= **= <<= >>= x= .=", |
| 133 | num_comparison => "< <= > >= == !=", |
| 134 | '3way_comparison'=> "<=> cmp", |
| 135 | str_comparison => "lt le gt ge eq ne", |
| 136 | binary => '& &= | |= ^ ^=', |
| 137 | unary => "neg ! ~", |
| 138 | mutators => '++ --', |
| 139 | func => "atan2 cos sin exp abs log sqrt int", |
| 140 | conversion => 'bool "" 0+ qr', |
| 141 | iterators => '<>', |
| 142 | filetest => "-X", |
| 143 | dereferencing => '${} @{} %{} &{} *{}', |
| 144 | matching => '~~', |
| 145 | special => 'nomethod fallback ='); |
| 146 | |
| 147 | use warnings::register; |
| 148 | sub constant { |
| 149 | # Arguments: what, sub |
| 150 | while (@_) { |
| 151 | if (@_ == 1) { |
| 152 | warnings::warnif ("Odd number of arguments for overload::constant"); |
| 153 | last; |
| 154 | } |
| 155 | elsif (!exists $constants {$_ [0]}) { |
| 156 | warnings::warnif ("`$_[0]' is not an overloadable type"); |
| 157 | } |
| 158 | elsif (!ref $_ [1] || "$_[1]" !~ /(^|=)CODE\(0x[0-9a-f]+\)$/) { |
| 159 | # Can't use C<ref $_[1] eq "CODE"> above as code references can be |
| 160 | # blessed, and C<ref> would return the package the ref is blessed into. |
| 161 | if (warnings::enabled) { |
| 162 | $_ [1] = "undef" unless defined $_ [1]; |
| 163 | warnings::warn ("`$_[1]' is not a code reference"); |
| 164 | } |
| 165 | } |
| 166 | else { |
| 167 | $^H{$_[0]} = $_[1]; |
| 168 | $^H |= $constants{$_[0]}; |
| 169 | } |
| 170 | shift, shift; |
| 171 | } |
| 172 | } |
| 173 | |
| 174 | sub remove_constant { |
| 175 | # Arguments: what, sub |
| 176 | while (@_) { |
| 177 | delete $^H{$_[0]}; |
| 178 | $^H &= ~ $constants{$_[0]}; |
| 179 | shift, shift; |
| 180 | } |
| 181 | } |
| 182 | |
| 183 | 1; |
| 184 | |
| 185 | __END__ |
| 186 | |
| 187 | =head1 NAME |
| 188 | |
| 189 | overload - Package for overloading Perl operations |
| 190 | |
| 191 | =head1 SYNOPSIS |
| 192 | |
| 193 | package SomeThing; |
| 194 | |
| 195 | use overload |
| 196 | '+' => \&myadd, |
| 197 | '-' => \&mysub; |
| 198 | # etc |
| 199 | ... |
| 200 | |
| 201 | package main; |
| 202 | $a = SomeThing->new( 57 ); |
| 203 | $b=5+$a; |
| 204 | ... |
| 205 | if (overload::Overloaded $b) {...} |
| 206 | ... |
| 207 | $strval = overload::StrVal $b; |
| 208 | |
| 209 | =head1 DESCRIPTION |
| 210 | |
| 211 | This pragma allows overloading of Perl's operators for a class. |
| 212 | To overload built-in functions, see L<perlsub/Overriding Built-in Functions> instead. |
| 213 | |
| 214 | =head2 Declaration of overloaded functions |
| 215 | |
| 216 | The compilation directive |
| 217 | |
| 218 | package Number; |
| 219 | use overload |
| 220 | "+" => \&add, |
| 221 | "*=" => "muas"; |
| 222 | |
| 223 | declares function Number::add() for addition, and method muas() in |
| 224 | the "class" C<Number> (or one of its base classes) |
| 225 | for the assignment form C<*=> of multiplication. |
| 226 | |
| 227 | Arguments of this directive come in (key, value) pairs. Legal values |
| 228 | are values legal inside a C<&{ ... }> call, so the name of a |
| 229 | subroutine, a reference to a subroutine, or an anonymous subroutine |
| 230 | will all work. Note that values specified as strings are |
| 231 | interpreted as methods, not subroutines. Legal keys are listed below. |
| 232 | |
| 233 | The subroutine C<add> will be called to execute C<$a+$b> if $a |
| 234 | is a reference to an object blessed into the package C<Number>, or if $a is |
| 235 | not an object from a package with defined mathemagic addition, but $b is a |
| 236 | reference to a C<Number>. It can also be called in other situations, like |
| 237 | C<$a+=7>, or C<$a++>. See L<MAGIC AUTOGENERATION>. (Mathemagical |
| 238 | methods refer to methods triggered by an overloaded mathematical |
| 239 | operator.) |
| 240 | |
| 241 | Since overloading respects inheritance via the @ISA hierarchy, the |
| 242 | above declaration would also trigger overloading of C<+> and C<*=> in |
| 243 | all the packages which inherit from C<Number>. |
| 244 | |
| 245 | =head2 Calling Conventions for Binary Operations |
| 246 | |
| 247 | The functions specified in the C<use overload ...> directive are called |
| 248 | with three (in one particular case with four, see L<Last Resort>) |
| 249 | arguments. If the corresponding operation is binary, then the first |
| 250 | two arguments are the two arguments of the operation. However, due to |
| 251 | general object calling conventions, the first argument should always be |
| 252 | an object in the package, so in the situation of C<7+$a>, the |
| 253 | order of the arguments is interchanged. It probably does not matter |
| 254 | when implementing the addition method, but whether the arguments |
| 255 | are reversed is vital to the subtraction method. The method can |
| 256 | query this information by examining the third argument, which can take |
| 257 | three different values: |
| 258 | |
| 259 | =over 7 |
| 260 | |
| 261 | =item FALSE |
| 262 | |
| 263 | the order of arguments is as in the current operation. |
| 264 | |
| 265 | =item TRUE |
| 266 | |
| 267 | the arguments are reversed. |
| 268 | |
| 269 | =item C<undef> |
| 270 | |
| 271 | the current operation is an assignment variant (as in |
| 272 | C<$a+=7>), but the usual function is called instead. This additional |
| 273 | information can be used to generate some optimizations. Compare |
| 274 | L<Calling Conventions for Mutators>. |
| 275 | |
| 276 | =back |
| 277 | |
| 278 | =head2 Calling Conventions for Unary Operations |
| 279 | |
| 280 | Unary operation are considered binary operations with the second |
| 281 | argument being C<undef>. Thus the functions that overloads C<{"++"}> |
| 282 | is called with arguments C<($a,undef,'')> when $a++ is executed. |
| 283 | |
| 284 | =head2 Calling Conventions for Mutators |
| 285 | |
| 286 | Two types of mutators have different calling conventions: |
| 287 | |
| 288 | =over |
| 289 | |
| 290 | =item C<++> and C<--> |
| 291 | |
| 292 | The routines which implement these operators are expected to actually |
| 293 | I<mutate> their arguments. So, assuming that $obj is a reference to a |
| 294 | number, |
| 295 | |
| 296 | sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n} |
| 297 | |
| 298 | is an appropriate implementation of overloaded C<++>. Note that |
| 299 | |
| 300 | sub incr { ++$ {$_[0]} ; shift } |
| 301 | |
| 302 | is OK if used with preincrement and with postincrement. (In the case |
| 303 | of postincrement a copying will be performed, see L<Copy Constructor>.) |
| 304 | |
| 305 | =item C<x=> and other assignment versions |
| 306 | |
| 307 | There is nothing special about these methods. They may change the |
| 308 | value of their arguments, and may leave it as is. The result is going |
| 309 | to be assigned to the value in the left-hand-side if different from |
| 310 | this value. |
| 311 | |
| 312 | This allows for the same method to be used as overloaded C<+=> and |
| 313 | C<+>. Note that this is I<allowed>, but not recommended, since by the |
| 314 | semantic of L<"Fallback"> Perl will call the method for C<+> anyway, |
| 315 | if C<+=> is not overloaded. |
| 316 | |
| 317 | =back |
| 318 | |
| 319 | B<Warning.> Due to the presence of assignment versions of operations, |
| 320 | routines which may be called in assignment context may create |
| 321 | self-referential structures. Currently Perl will not free self-referential |
| 322 | structures until cycles are C<explicitly> broken. You may get problems |
| 323 | when traversing your structures too. |
| 324 | |
| 325 | Say, |
| 326 | |
| 327 | use overload '+' => sub { bless [ \$_[0], \$_[1] ] }; |
| 328 | |
| 329 | is asking for trouble, since for code C<$obj += $foo> the subroutine |
| 330 | is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj, |
| 331 | \$foo]>. If using such a subroutine is an important optimization, one |
| 332 | can overload C<+=> explicitly by a non-"optimized" version, or switch |
| 333 | to non-optimized version if C<not defined $_[2]> (see |
| 334 | L<Calling Conventions for Binary Operations>). |
| 335 | |
| 336 | Even if no I<explicit> assignment-variants of operators are present in |
| 337 | the script, they may be generated by the optimizer. Say, C<",$obj,"> or |
| 338 | C<',' . $obj . ','> may be both optimized to |
| 339 | |
| 340 | my $tmp = ',' . $obj; $tmp .= ','; |
| 341 | |
| 342 | =head2 Overloadable Operations |
| 343 | |
| 344 | The following symbols can be specified in C<use overload> directive: |
| 345 | |
| 346 | =over 5 |
| 347 | |
| 348 | =item * I<Arithmetic operations> |
| 349 | |
| 350 | "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=", |
| 351 | "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=", |
| 352 | |
| 353 | For these operations a substituted non-assignment variant can be called if |
| 354 | the assignment variant is not available. Methods for operations C<+>, |
| 355 | C<->, C<+=>, and C<-=> can be called to automatically generate |
| 356 | increment and decrement methods. The operation C<-> can be used to |
| 357 | autogenerate missing methods for unary minus or C<abs>. |
| 358 | |
| 359 | See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and |
| 360 | L<"Calling Conventions for Binary Operations">) for details of these |
| 361 | substitutions. |
| 362 | |
| 363 | =item * I<Comparison operations> |
| 364 | |
| 365 | "<", "<=", ">", ">=", "==", "!=", "<=>", |
| 366 | "lt", "le", "gt", "ge", "eq", "ne", "cmp", |
| 367 | |
| 368 | If the corresponding "spaceship" variant is available, it can be |
| 369 | used to substitute for the missing operation. During C<sort>ing |
| 370 | arrays, C<cmp> is used to compare values subject to C<use overload>. |
| 371 | |
| 372 | =item * I<Bit operations> |
| 373 | |
| 374 | "&", "&=", "^", "^=", "|", "|=", "neg", "!", "~", |
| 375 | |
| 376 | C<neg> stands for unary minus. If the method for C<neg> is not |
| 377 | specified, it can be autogenerated using the method for |
| 378 | subtraction. If the method for C<!> is not specified, it can be |
| 379 | autogenerated using the methods for C<bool>, or C<"">, or C<0+>. |
| 380 | |
| 381 | The same remarks in L<"Arithmetic operations"> about |
| 382 | assignment-variants and autogeneration apply for |
| 383 | bit operations C<"&">, C<"^">, and C<"|"> as well. |
| 384 | |
| 385 | =item * I<Increment and decrement> |
| 386 | |
| 387 | "++", "--", |
| 388 | |
| 389 | If undefined, addition and subtraction methods can be |
| 390 | used instead. These operations are called both in prefix and |
| 391 | postfix form. |
| 392 | |
| 393 | =item * I<Transcendental functions> |
| 394 | |
| 395 | "atan2", "cos", "sin", "exp", "abs", "log", "sqrt", "int" |
| 396 | |
| 397 | If C<abs> is unavailable, it can be autogenerated using methods |
| 398 | for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction. |
| 399 | |
| 400 | Note that traditionally the Perl function L<int> rounds to 0, thus for |
| 401 | floating-point-like types one should follow the same semantic. If |
| 402 | C<int> is unavailable, it can be autogenerated using the overloading of |
| 403 | C<0+>. |
| 404 | |
| 405 | =item * I<Boolean, string, numeric and regexp conversions> |
| 406 | |
| 407 | 'bool', '""', '0+', 'qr' |
| 408 | |
| 409 | If one or two of these operations are not overloaded, the remaining ones |
| 410 | can be used instead. C<bool> is used in the flow control operators |
| 411 | (like C<while>) and for the ternary C<?:> operation; C<qr> is used for |
| 412 | the RHS of C<=~> and when an object is interpolated into a regexp. |
| 413 | |
| 414 | C<bool>, C<"">, and C<0+> can return any arbitrary Perl value. If the |
| 415 | corresponding operation for this value is overloaded too, that operation |
| 416 | will be called again with this value. C<qr> must return a compiled |
| 417 | regexp, or a ref to a compiled regexp (such as C<qr//> returns), and any |
| 418 | further overloading on the return value will be ignored. |
| 419 | |
| 420 | As a special case if the overload returns the object itself then it will |
| 421 | be used directly. An overloaded conversion returning the object is |
| 422 | probably a bug, because you're likely to get something that looks like |
| 423 | C<YourPackage=HASH(0x8172b34)>. |
| 424 | |
| 425 | =item * I<Iteration> |
| 426 | |
| 427 | "<>" |
| 428 | |
| 429 | If not overloaded, the argument will be converted to a filehandle or |
| 430 | glob (which may require a stringification). The same overloading |
| 431 | happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and |
| 432 | I<globbing> syntax C<E<lt>${var}E<gt>>. |
| 433 | |
| 434 | B<BUGS> Even in list context, the iterator is currently called only |
| 435 | once and with scalar context. |
| 436 | |
| 437 | =item * I<File tests> |
| 438 | |
| 439 | "-X" |
| 440 | |
| 441 | This overload is used for all the filetest operators (C<-f>, C<-x> and |
| 442 | so on: see L<perlfunc/-X> for the full list). Even though these are |
| 443 | unary operators, the method will be called with a second argument which |
| 444 | is a single letter indicating which test was performed. Note that the |
| 445 | overload key is the literal string C<"-X">: you can't provide separate |
| 446 | overloads for the different tests. |
| 447 | |
| 448 | Calling an overloaded filetest operator does not affect the stat value |
| 449 | associated with the special filehandle C<_>. It still refers to the |
| 450 | result of the last C<stat>, C<lstat> or unoverloaded filetest. |
| 451 | |
| 452 | If not overloaded, these operators will fall back to the default |
| 453 | behaviour even without C<< fallback => 1 >>. This means that if the |
| 454 | object is a blessed glob or blessed IO ref it will be treated as a |
| 455 | filehandle, otherwise string overloading will be invoked and the result |
| 456 | treated as a filename. |
| 457 | |
| 458 | This overload was introduced in perl 5.12. |
| 459 | |
| 460 | =item * I<Matching> |
| 461 | |
| 462 | The key C<"~~"> allows you to override the smart matching logic used by |
| 463 | the C<~~> operator and the switch construct (C<given>/C<when>). See |
| 464 | L<perlsyn/switch> and L<feature>. |
| 465 | |
| 466 | Unusually, overloading of the smart match operator does not automatically |
| 467 | take precedence over normal smart match behaviour. In particular, in the |
| 468 | following code: |
| 469 | |
| 470 | package Foo; |
| 471 | use overload '~~' => 'match'; |
| 472 | |
| 473 | my $obj = Foo->new(); |
| 474 | $obj ~~ [ 1,2,3 ]; |
| 475 | |
| 476 | the smart match does I<not> invoke the method call like this: |
| 477 | |
| 478 | $obj->match([1,2,3],0); |
| 479 | |
| 480 | rather, the smart match distributive rule takes precedence, so $obj is |
| 481 | smart matched against each array element in turn until a match is found, |
| 482 | so you may see between one and three of these calls instead: |
| 483 | |
| 484 | $obj->match(1,0); |
| 485 | $obj->match(2,0); |
| 486 | $obj->match(3,0); |
| 487 | |
| 488 | Consult the match table in L<perlsyn/"Smart matching in detail"> for |
| 489 | details of when overloading is invoked. |
| 490 | |
| 491 | =item * I<Dereferencing> |
| 492 | |
| 493 | '${}', '@{}', '%{}', '&{}', '*{}'. |
| 494 | |
| 495 | If not overloaded, the argument will be dereferenced I<as is>, thus |
| 496 | should be of correct type. These functions should return a reference |
| 497 | of correct type, or another object with overloaded dereferencing. |
| 498 | |
| 499 | As a special case if the overload returns the object itself then it |
| 500 | will be used directly (provided it is the correct type). |
| 501 | |
| 502 | The dereference operators must be specified explicitly they will not be passed to |
| 503 | "nomethod". |
| 504 | |
| 505 | =item * I<Special> |
| 506 | |
| 507 | "nomethod", "fallback", "=". |
| 508 | |
| 509 | see L<SPECIAL SYMBOLS FOR C<use overload>>. |
| 510 | |
| 511 | =back |
| 512 | |
| 513 | See L<"Fallback"> for an explanation of when a missing method can be |
| 514 | autogenerated. |
| 515 | |
| 516 | A computer-readable form of the above table is available in the hash |
| 517 | %overload::ops, with values being space-separated lists of names: |
| 518 | |
| 519 | with_assign => '+ - * / % ** << >> x .', |
| 520 | assign => '+= -= *= /= %= **= <<= >>= x= .=', |
| 521 | num_comparison => '< <= > >= == !=', |
| 522 | '3way_comparison'=> '<=> cmp', |
| 523 | str_comparison => 'lt le gt ge eq ne', |
| 524 | binary => '& &= | |= ^ ^=', |
| 525 | unary => 'neg ! ~', |
| 526 | mutators => '++ --', |
| 527 | func => 'atan2 cos sin exp abs log sqrt', |
| 528 | conversion => 'bool "" 0+ qr', |
| 529 | iterators => '<>', |
| 530 | filetest => '-X', |
| 531 | dereferencing => '${} @{} %{} &{} *{}', |
| 532 | matching => '~~', |
| 533 | special => 'nomethod fallback =' |
| 534 | |
| 535 | =head2 Inheritance and overloading |
| 536 | |
| 537 | Inheritance interacts with overloading in two ways. |
| 538 | |
| 539 | =over |
| 540 | |
| 541 | =item Strings as values of C<use overload> directive |
| 542 | |
| 543 | If C<value> in |
| 544 | |
| 545 | use overload key => value; |
| 546 | |
| 547 | is a string, it is interpreted as a method name. |
| 548 | |
| 549 | =item Overloading of an operation is inherited by derived classes |
| 550 | |
| 551 | Any class derived from an overloaded class is also overloaded. The |
| 552 | set of overloaded methods is the union of overloaded methods of all |
| 553 | the ancestors. If some method is overloaded in several ancestor, then |
| 554 | which description will be used is decided by the usual inheritance |
| 555 | rules: |
| 556 | |
| 557 | If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads |
| 558 | C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">, |
| 559 | then the subroutine C<D::plus_sub> will be called to implement |
| 560 | operation C<+> for an object in package C<A>. |
| 561 | |
| 562 | =back |
| 563 | |
| 564 | Note that since the value of the C<fallback> key is not a subroutine, |
| 565 | its inheritance is not governed by the above rules. In the current |
| 566 | implementation, the value of C<fallback> in the first overloaded |
| 567 | ancestor is used, but this is accidental and subject to change. |
| 568 | |
| 569 | =head1 SPECIAL SYMBOLS FOR C<use overload> |
| 570 | |
| 571 | Three keys are recognized by Perl that are not covered by the above |
| 572 | description. |
| 573 | |
| 574 | =head2 Last Resort |
| 575 | |
| 576 | C<"nomethod"> should be followed by a reference to a function of four |
| 577 | parameters. If defined, it is called when the overloading mechanism |
| 578 | cannot find a method for some operation. The first three arguments of |
| 579 | this function coincide with the arguments for the corresponding method if |
| 580 | it were found, the fourth argument is the symbol |
| 581 | corresponding to the missing method. If several methods are tried, |
| 582 | the last one is used. Say, C<1-$a> can be equivalent to |
| 583 | |
| 584 | &nomethodMethod($a,1,1,"-") |
| 585 | |
| 586 | if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the |
| 587 | C<use overload> directive. |
| 588 | |
| 589 | The C<"nomethod"> mechanism is I<not> used for the dereference operators |
| 590 | ( ${} @{} %{} &{} *{} ). |
| 591 | |
| 592 | |
| 593 | If some operation cannot be resolved, and there is no function |
| 594 | assigned to C<"nomethod">, then an exception will be raised via die()-- |
| 595 | unless C<"fallback"> was specified as a key in C<use overload> directive. |
| 596 | |
| 597 | |
| 598 | =head2 Fallback |
| 599 | |
| 600 | The key C<"fallback"> governs what to do if a method for a particular |
| 601 | operation is not found. Three different cases are possible depending on |
| 602 | the value of C<"fallback">: |
| 603 | |
| 604 | =over 16 |
| 605 | |
| 606 | =item * C<undef> |
| 607 | |
| 608 | Perl tries to use a |
| 609 | substituted method (see L<MAGIC AUTOGENERATION>). If this fails, it |
| 610 | then tries to calls C<"nomethod"> value; if missing, an exception |
| 611 | will be raised. |
| 612 | |
| 613 | =item * TRUE |
| 614 | |
| 615 | The same as for the C<undef> value, but no exception is raised. Instead, |
| 616 | it silently reverts to what it would have done were there no C<use overload> |
| 617 | present. |
| 618 | |
| 619 | =item * defined, but FALSE |
| 620 | |
| 621 | No autogeneration is tried. Perl tries to call |
| 622 | C<"nomethod"> value, and if this is missing, raises an exception. |
| 623 | |
| 624 | =back |
| 625 | |
| 626 | B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone |
| 627 | yet, see L<"Inheritance and overloading">. |
| 628 | |
| 629 | =head2 Copy Constructor |
| 630 | |
| 631 | The value for C<"="> is a reference to a function with three |
| 632 | arguments, i.e., it looks like the other values in C<use |
| 633 | overload>. However, it does not overload the Perl assignment |
| 634 | operator. This would go against Camel hair. |
| 635 | |
| 636 | This operation is called in the situations when a mutator is applied |
| 637 | to a reference that shares its object with some other reference, such |
| 638 | as |
| 639 | |
| 640 | $a=$b; |
| 641 | ++$a; |
| 642 | |
| 643 | To make this change $a and not change $b, a copy of C<$$a> is made, |
| 644 | and $a is assigned a reference to this new object. This operation is |
| 645 | done during execution of the C<++$a>, and not during the assignment, |
| 646 | (so before the increment C<$$a> coincides with C<$$b>). This is only |
| 647 | done if C<++> is expressed via a method for C<'++'> or C<'+='> (or |
| 648 | C<nomethod>). Note that if this operation is expressed via C<'+'> |
| 649 | a nonmutator, i.e., as in |
| 650 | |
| 651 | $a=$b; |
| 652 | $a=$a+1; |
| 653 | |
| 654 | then C<$a> does not reference a new copy of C<$$a>, since $$a does not |
| 655 | appear as lvalue when the above code is executed. |
| 656 | |
| 657 | If the copy constructor is required during the execution of some mutator, |
| 658 | but a method for C<'='> was not specified, it can be autogenerated as a |
| 659 | string copy if the object is a plain scalar or a simple assignment if it |
| 660 | is not. |
| 661 | |
| 662 | =over 5 |
| 663 | |
| 664 | =item B<Example> |
| 665 | |
| 666 | The actually executed code for |
| 667 | |
| 668 | $a=$b; |
| 669 | Something else which does not modify $a or $b.... |
| 670 | ++$a; |
| 671 | |
| 672 | may be |
| 673 | |
| 674 | $a=$b; |
| 675 | Something else which does not modify $a or $b.... |
| 676 | $a = $a->clone(undef,""); |
| 677 | $a->incr(undef,""); |
| 678 | |
| 679 | if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>, |
| 680 | C<'='> was overloaded with C<\&clone>. |
| 681 | |
| 682 | =back |
| 683 | |
| 684 | Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for |
| 685 | C<$b = $a; ++$a>. |
| 686 | |
| 687 | =head1 MAGIC AUTOGENERATION |
| 688 | |
| 689 | If a method for an operation is not found, and the value for C<"fallback"> is |
| 690 | TRUE or undefined, Perl tries to autogenerate a substitute method for |
| 691 | the missing operation based on the defined operations. Autogenerated method |
| 692 | substitutions are possible for the following operations: |
| 693 | |
| 694 | =over 16 |
| 695 | |
| 696 | =item I<Assignment forms of arithmetic operations> |
| 697 | |
| 698 | C<$a+=$b> can use the method for C<"+"> if the method for C<"+="> |
| 699 | is not defined. |
| 700 | |
| 701 | =item I<Conversion operations> |
| 702 | |
| 703 | String, numeric, boolean and regexp conversions are calculated in terms |
| 704 | of one another if not all of them are defined. |
| 705 | |
| 706 | =item I<Increment and decrement> |
| 707 | |
| 708 | The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>, |
| 709 | and C<$a--> in terms of C<$a-=1> and C<$a-1>. |
| 710 | |
| 711 | =item C<abs($a)> |
| 712 | |
| 713 | can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>). |
| 714 | |
| 715 | =item I<Unary minus> |
| 716 | |
| 717 | can be expressed in terms of subtraction. |
| 718 | |
| 719 | =item I<Negation> |
| 720 | |
| 721 | C<!> and C<not> can be expressed in terms of boolean conversion, or |
| 722 | string or numerical conversion. |
| 723 | |
| 724 | =item I<Concatenation> |
| 725 | |
| 726 | can be expressed in terms of string conversion. |
| 727 | |
| 728 | =item I<Comparison operations> |
| 729 | |
| 730 | can be expressed in terms of its "spaceship" counterpart: either |
| 731 | C<E<lt>=E<gt>> or C<cmp>: |
| 732 | |
| 733 | <, >, <=, >=, ==, != in terms of <=> |
| 734 | lt, gt, le, ge, eq, ne in terms of cmp |
| 735 | |
| 736 | =item I<Iterator> |
| 737 | |
| 738 | <> in terms of builtin operations |
| 739 | |
| 740 | =item I<Dereferencing> |
| 741 | |
| 742 | ${} @{} %{} &{} *{} in terms of builtin operations |
| 743 | |
| 744 | =item I<Copy operator> |
| 745 | |
| 746 | can be expressed in terms of an assignment to the dereferenced value, if this |
| 747 | value is a scalar and not a reference, or simply a reference assignment |
| 748 | otherwise. |
| 749 | |
| 750 | =back |
| 751 | |
| 752 | =head1 Minimal set of overloaded operations |
| 753 | |
| 754 | Since some operations can be automatically generated from others, there is |
| 755 | a minimal set of operations that need to be overloaded in order to have |
| 756 | the complete set of overloaded operations at one's disposal. |
| 757 | Of course, the autogenerated operations may not do exactly what the user |
| 758 | expects. See L<MAGIC AUTOGENERATION> above. The minimal set is: |
| 759 | |
| 760 | + - * / % ** << >> x |
| 761 | <=> cmp |
| 762 | & | ^ ~ |
| 763 | atan2 cos sin exp log sqrt int |
| 764 | |
| 765 | Additionally, you need to define at least one of string, boolean or |
| 766 | numeric conversions because any one can be used to emulate the others. |
| 767 | The string conversion can also be used to emulate concatenation. |
| 768 | |
| 769 | =head1 Losing overloading |
| 770 | |
| 771 | The restriction for the comparison operation is that even if, for example, |
| 772 | `C<cmp>' should return a blessed reference, the autogenerated `C<lt>' |
| 773 | function will produce only a standard logical value based on the |
| 774 | numerical value of the result of `C<cmp>'. In particular, a working |
| 775 | numeric conversion is needed in this case (possibly expressed in terms of |
| 776 | other conversions). |
| 777 | |
| 778 | Similarly, C<.=> and C<x=> operators lose their mathemagical properties |
| 779 | if the string conversion substitution is applied. |
| 780 | |
| 781 | When you chop() a mathemagical object it is promoted to a string and its |
| 782 | mathemagical properties are lost. The same can happen with other |
| 783 | operations as well. |
| 784 | |
| 785 | =head1 Run-time Overloading |
| 786 | |
| 787 | Since all C<use> directives are executed at compile-time, the only way to |
| 788 | change overloading during run-time is to |
| 789 | |
| 790 | eval 'use overload "+" => \&addmethod'; |
| 791 | |
| 792 | You can also use |
| 793 | |
| 794 | eval 'no overload "+", "--", "<="'; |
| 795 | |
| 796 | though the use of these constructs during run-time is questionable. |
| 797 | |
| 798 | =head1 Public functions |
| 799 | |
| 800 | Package C<overload.pm> provides the following public functions: |
| 801 | |
| 802 | =over 5 |
| 803 | |
| 804 | =item overload::StrVal(arg) |
| 805 | |
| 806 | Gives string value of C<arg> as in absence of stringify overloading. If you |
| 807 | are using this to get the address of a reference (useful for checking if two |
| 808 | references point to the same thing) then you may be better off using |
| 809 | C<Scalar::Util::refaddr()>, which is faster. |
| 810 | |
| 811 | =item overload::Overloaded(arg) |
| 812 | |
| 813 | Returns true if C<arg> is subject to overloading of some operations. |
| 814 | |
| 815 | =item overload::Method(obj,op) |
| 816 | |
| 817 | Returns C<undef> or a reference to the method that implements C<op>. |
| 818 | |
| 819 | =back |
| 820 | |
| 821 | =head1 Overloading constants |
| 822 | |
| 823 | For some applications, the Perl parser mangles constants too much. |
| 824 | It is possible to hook into this process via C<overload::constant()> |
| 825 | and C<overload::remove_constant()> functions. |
| 826 | |
| 827 | These functions take a hash as an argument. The recognized keys of this hash |
| 828 | are: |
| 829 | |
| 830 | =over 8 |
| 831 | |
| 832 | =item integer |
| 833 | |
| 834 | to overload integer constants, |
| 835 | |
| 836 | =item float |
| 837 | |
| 838 | to overload floating point constants, |
| 839 | |
| 840 | =item binary |
| 841 | |
| 842 | to overload octal and hexadecimal constants, |
| 843 | |
| 844 | =item q |
| 845 | |
| 846 | to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted |
| 847 | strings and here-documents, |
| 848 | |
| 849 | =item qr |
| 850 | |
| 851 | to overload constant pieces of regular expressions. |
| 852 | |
| 853 | =back |
| 854 | |
| 855 | The corresponding values are references to functions which take three arguments: |
| 856 | the first one is the I<initial> string form of the constant, the second one |
| 857 | is how Perl interprets this constant, the third one is how the constant is used. |
| 858 | Note that the initial string form does not |
| 859 | contain string delimiters, and has backslashes in backslash-delimiter |
| 860 | combinations stripped (thus the value of delimiter is not relevant for |
| 861 | processing of this string). The return value of this function is how this |
| 862 | constant is going to be interpreted by Perl. The third argument is undefined |
| 863 | unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote |
| 864 | context (comes from strings, regular expressions, and single-quote HERE |
| 865 | documents), it is C<tr> for arguments of C<tr>/C<y> operators, |
| 866 | it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise. |
| 867 | |
| 868 | Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>, |
| 869 | it is expected that overloaded constant strings are equipped with reasonable |
| 870 | overloaded catenation operator, otherwise absurd results will result. |
| 871 | Similarly, negative numbers are considered as negations of positive constants. |
| 872 | |
| 873 | Note that it is probably meaningless to call the functions overload::constant() |
| 874 | and overload::remove_constant() from anywhere but import() and unimport() methods. |
| 875 | From these methods they may be called as |
| 876 | |
| 877 | sub import { |
| 878 | shift; |
| 879 | return unless @_; |
| 880 | die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant'; |
| 881 | overload::constant integer => sub {Math::BigInt->new(shift)}; |
| 882 | } |
| 883 | |
| 884 | =head1 IMPLEMENTATION |
| 885 | |
| 886 | What follows is subject to change RSN. |
| 887 | |
| 888 | The table of methods for all operations is cached in magic for the |
| 889 | symbol table hash for the package. The cache is invalidated during |
| 890 | processing of C<use overload>, C<no overload>, new function |
| 891 | definitions, and changes in @ISA. However, this invalidation remains |
| 892 | unprocessed until the next C<bless>ing into the package. Hence if you |
| 893 | want to change overloading structure dynamically, you'll need an |
| 894 | additional (fake) C<bless>ing to update the table. |
| 895 | |
| 896 | (Every SVish thing has a magic queue, and magic is an entry in that |
| 897 | queue. This is how a single variable may participate in multiple |
| 898 | forms of magic simultaneously. For instance, environment variables |
| 899 | regularly have two forms at once: their %ENV magic and their taint |
| 900 | magic. However, the magic which implements overloading is applied to |
| 901 | the stashes, which are rarely used directly, thus should not slow down |
| 902 | Perl.) |
| 903 | |
| 904 | If an object belongs to a package using overload, it carries a special |
| 905 | flag. Thus the only speed penalty during arithmetic operations without |
| 906 | overloading is the checking of this flag. |
| 907 | |
| 908 | In fact, if C<use overload> is not present, there is almost no overhead |
| 909 | for overloadable operations, so most programs should not suffer |
| 910 | measurable performance penalties. A considerable effort was made to |
| 911 | minimize the overhead when overload is used in some package, but the |
| 912 | arguments in question do not belong to packages using overload. When |
| 913 | in doubt, test your speed with C<use overload> and without it. So far |
| 914 | there have been no reports of substantial speed degradation if Perl is |
| 915 | compiled with optimization turned on. |
| 916 | |
| 917 | There is no size penalty for data if overload is not used. The only |
| 918 | size penalty if overload is used in some package is that I<all> the |
| 919 | packages acquire a magic during the next C<bless>ing into the |
| 920 | package. This magic is three-words-long for packages without |
| 921 | overloading, and carries the cache table if the package is overloaded. |
| 922 | |
| 923 | Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is |
| 924 | carried out before any operation that can imply an assignment to the |
| 925 | object $a (or $b) refers to, like C<$a++>. You can override this |
| 926 | behavior by defining your own copy constructor (see L<"Copy Constructor">). |
| 927 | |
| 928 | It is expected that arguments to methods that are not explicitly supposed |
| 929 | to be changed are constant (but this is not enforced). |
| 930 | |
| 931 | =head1 Metaphor clash |
| 932 | |
| 933 | One may wonder why the semantic of overloaded C<=> is so counter intuitive. |
| 934 | If it I<looks> counter intuitive to you, you are subject to a metaphor |
| 935 | clash. |
| 936 | |
| 937 | Here is a Perl object metaphor: |
| 938 | |
| 939 | I< object is a reference to blessed data> |
| 940 | |
| 941 | and an arithmetic metaphor: |
| 942 | |
| 943 | I< object is a thing by itself>. |
| 944 | |
| 945 | The I<main> problem of overloading C<=> is the fact that these metaphors |
| 946 | imply different actions on the assignment C<$a = $b> if $a and $b are |
| 947 | objects. Perl-think implies that $a becomes a reference to whatever |
| 948 | $b was referencing. Arithmetic-think implies that the value of "object" |
| 949 | $a is changed to become the value of the object $b, preserving the fact |
| 950 | that $a and $b are separate entities. |
| 951 | |
| 952 | The difference is not relevant in the absence of mutators. After |
| 953 | a Perl-way assignment an operation which mutates the data referenced by $a |
| 954 | would change the data referenced by $b too. Effectively, after |
| 955 | C<$a = $b> values of $a and $b become I<indistinguishable>. |
| 956 | |
| 957 | On the other hand, anyone who has used algebraic notation knows the |
| 958 | expressive power of the arithmetic metaphor. Overloading works hard |
| 959 | to enable this metaphor while preserving the Perlian way as far as |
| 960 | possible. Since it is not possible to freely mix two contradicting |
| 961 | metaphors, overloading allows the arithmetic way to write things I<as |
| 962 | far as all the mutators are called via overloaded access only>. The |
| 963 | way it is done is described in L<Copy Constructor>. |
| 964 | |
| 965 | If some mutator methods are directly applied to the overloaded values, |
| 966 | one may need to I<explicitly unlink> other values which references the |
| 967 | same value: |
| 968 | |
| 969 | $a = Data->new(23); |
| 970 | ... |
| 971 | $b = $a; # $b is "linked" to $a |
| 972 | ... |
| 973 | $a = $a->clone; # Unlink $b from $a |
| 974 | $a->increment_by(4); |
| 975 | |
| 976 | Note that overloaded access makes this transparent: |
| 977 | |
| 978 | $a = Data->new(23); |
| 979 | $b = $a; # $b is "linked" to $a |
| 980 | $a += 4; # would unlink $b automagically |
| 981 | |
| 982 | However, it would not make |
| 983 | |
| 984 | $a = Data->new(23); |
| 985 | $a = 4; # Now $a is a plain 4, not 'Data' |
| 986 | |
| 987 | preserve "objectness" of $a. But Perl I<has> a way to make assignments |
| 988 | to an object do whatever you want. It is just not the overload, but |
| 989 | tie()ing interface (see L<perlfunc/tie>). Adding a FETCH() method |
| 990 | which returns the object itself, and STORE() method which changes the |
| 991 | value of the object, one can reproduce the arithmetic metaphor in its |
| 992 | completeness, at least for variables which were tie()d from the start. |
| 993 | |
| 994 | (Note that a workaround for a bug may be needed, see L<"BUGS">.) |
| 995 | |
| 996 | =head1 Cookbook |
| 997 | |
| 998 | Please add examples to what follows! |
| 999 | |
| 1000 | =head2 Two-face scalars |
| 1001 | |
| 1002 | Put this in F<two_face.pm> in your Perl library directory: |
| 1003 | |
| 1004 | package two_face; # Scalars with separate string and |
| 1005 | # numeric values. |
| 1006 | sub new { my $p = shift; bless [@_], $p } |
| 1007 | use overload '""' => \&str, '0+' => \&num, fallback => 1; |
| 1008 | sub num {shift->[1]} |
| 1009 | sub str {shift->[0]} |
| 1010 | |
| 1011 | Use it as follows: |
| 1012 | |
| 1013 | require two_face; |
| 1014 | my $seven = two_face->new("vii", 7); |
| 1015 | printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1; |
| 1016 | print "seven contains `i'\n" if $seven =~ /i/; |
| 1017 | |
| 1018 | (The second line creates a scalar which has both a string value, and a |
| 1019 | numeric value.) This prints: |
| 1020 | |
| 1021 | seven=vii, seven=7, eight=8 |
| 1022 | seven contains `i' |
| 1023 | |
| 1024 | =head2 Two-face references |
| 1025 | |
| 1026 | Suppose you want to create an object which is accessible as both an |
| 1027 | array reference and a hash reference. |
| 1028 | |
| 1029 | package two_refs; |
| 1030 | use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} }; |
| 1031 | sub new { |
| 1032 | my $p = shift; |
| 1033 | bless \ [@_], $p; |
| 1034 | } |
| 1035 | sub gethash { |
| 1036 | my %h; |
| 1037 | my $self = shift; |
| 1038 | tie %h, ref $self, $self; |
| 1039 | \%h; |
| 1040 | } |
| 1041 | |
| 1042 | sub TIEHASH { my $p = shift; bless \ shift, $p } |
| 1043 | my %fields; |
| 1044 | my $i = 0; |
| 1045 | $fields{$_} = $i++ foreach qw{zero one two three}; |
| 1046 | sub STORE { |
| 1047 | my $self = ${shift()}; |
| 1048 | my $key = $fields{shift()}; |
| 1049 | defined $key or die "Out of band access"; |
| 1050 | $$self->[$key] = shift; |
| 1051 | } |
| 1052 | sub FETCH { |
| 1053 | my $self = ${shift()}; |
| 1054 | my $key = $fields{shift()}; |
| 1055 | defined $key or die "Out of band access"; |
| 1056 | $$self->[$key]; |
| 1057 | } |
| 1058 | |
| 1059 | Now one can access an object using both the array and hash syntax: |
| 1060 | |
| 1061 | my $bar = two_refs->new(3,4,5,6); |
| 1062 | $bar->[2] = 11; |
| 1063 | $bar->{two} == 11 or die 'bad hash fetch'; |
| 1064 | |
| 1065 | Note several important features of this example. First of all, the |
| 1066 | I<actual> type of $bar is a scalar reference, and we do not overload |
| 1067 | the scalar dereference. Thus we can get the I<actual> non-overloaded |
| 1068 | contents of $bar by just using C<$$bar> (what we do in functions which |
| 1069 | overload dereference). Similarly, the object returned by the |
| 1070 | TIEHASH() method is a scalar reference. |
| 1071 | |
| 1072 | Second, we create a new tied hash each time the hash syntax is used. |
| 1073 | This allows us not to worry about a possibility of a reference loop, |
| 1074 | which would lead to a memory leak. |
| 1075 | |
| 1076 | Both these problems can be cured. Say, if we want to overload hash |
| 1077 | dereference on a reference to an object which is I<implemented> as a |
| 1078 | hash itself, the only problem one has to circumvent is how to access |
| 1079 | this I<actual> hash (as opposed to the I<virtual> hash exhibited by the |
| 1080 | overloaded dereference operator). Here is one possible fetching routine: |
| 1081 | |
| 1082 | sub access_hash { |
| 1083 | my ($self, $key) = (shift, shift); |
| 1084 | my $class = ref $self; |
| 1085 | bless $self, 'overload::dummy'; # Disable overloading of %{} |
| 1086 | my $out = $self->{$key}; |
| 1087 | bless $self, $class; # Restore overloading |
| 1088 | $out; |
| 1089 | } |
| 1090 | |
| 1091 | To remove creation of the tied hash on each access, one may an extra |
| 1092 | level of indirection which allows a non-circular structure of references: |
| 1093 | |
| 1094 | package two_refs1; |
| 1095 | use overload '%{}' => sub { ${shift()}->[1] }, |
| 1096 | '@{}' => sub { ${shift()}->[0] }; |
| 1097 | sub new { |
| 1098 | my $p = shift; |
| 1099 | my $a = [@_]; |
| 1100 | my %h; |
| 1101 | tie %h, $p, $a; |
| 1102 | bless \ [$a, \%h], $p; |
| 1103 | } |
| 1104 | sub gethash { |
| 1105 | my %h; |
| 1106 | my $self = shift; |
| 1107 | tie %h, ref $self, $self; |
| 1108 | \%h; |
| 1109 | } |
| 1110 | |
| 1111 | sub TIEHASH { my $p = shift; bless \ shift, $p } |
| 1112 | my %fields; |
| 1113 | my $i = 0; |
| 1114 | $fields{$_} = $i++ foreach qw{zero one two three}; |
| 1115 | sub STORE { |
| 1116 | my $a = ${shift()}; |
| 1117 | my $key = $fields{shift()}; |
| 1118 | defined $key or die "Out of band access"; |
| 1119 | $a->[$key] = shift; |
| 1120 | } |
| 1121 | sub FETCH { |
| 1122 | my $a = ${shift()}; |
| 1123 | my $key = $fields{shift()}; |
| 1124 | defined $key or die "Out of band access"; |
| 1125 | $a->[$key]; |
| 1126 | } |
| 1127 | |
| 1128 | Now if $baz is overloaded like this, then C<$baz> is a reference to a |
| 1129 | reference to the intermediate array, which keeps a reference to an |
| 1130 | actual array, and the access hash. The tie()ing object for the access |
| 1131 | hash is a reference to a reference to the actual array, so |
| 1132 | |
| 1133 | =over |
| 1134 | |
| 1135 | =item * |
| 1136 | |
| 1137 | There are no loops of references. |
| 1138 | |
| 1139 | =item * |
| 1140 | |
| 1141 | Both "objects" which are blessed into the class C<two_refs1> are |
| 1142 | references to a reference to an array, thus references to a I<scalar>. |
| 1143 | Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no |
| 1144 | overloaded operations. |
| 1145 | |
| 1146 | =back |
| 1147 | |
| 1148 | =head2 Symbolic calculator |
| 1149 | |
| 1150 | Put this in F<symbolic.pm> in your Perl library directory: |
| 1151 | |
| 1152 | package symbolic; # Primitive symbolic calculator |
| 1153 | use overload nomethod => \&wrap; |
| 1154 | |
| 1155 | sub new { shift; bless ['n', @_] } |
| 1156 | sub wrap { |
| 1157 | my ($obj, $other, $inv, $meth) = @_; |
| 1158 | ($obj, $other) = ($other, $obj) if $inv; |
| 1159 | bless [$meth, $obj, $other]; |
| 1160 | } |
| 1161 | |
| 1162 | This module is very unusual as overloaded modules go: it does not |
| 1163 | provide any usual overloaded operators, instead it provides the L<Last |
| 1164 | Resort> operator C<nomethod>. In this example the corresponding |
| 1165 | subroutine returns an object which encapsulates operations done over |
| 1166 | the objects: C<< symbolic->new(3) >> contains C<['n', 3]>, C<< 2 + |
| 1167 | symbolic->new(3) >> contains C<['+', 2, ['n', 3]]>. |
| 1168 | |
| 1169 | Here is an example of the script which "calculates" the side of |
| 1170 | circumscribed octagon using the above package: |
| 1171 | |
| 1172 | require symbolic; |
| 1173 | my $iter = 1; # 2**($iter+2) = 8 |
| 1174 | my $side = symbolic->new(1); |
| 1175 | my $cnt = $iter; |
| 1176 | |
| 1177 | while ($cnt--) { |
| 1178 | $side = (sqrt(1 + $side**2) - 1)/$side; |
| 1179 | } |
| 1180 | print "OK\n"; |
| 1181 | |
| 1182 | The value of $side is |
| 1183 | |
| 1184 | ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]], |
| 1185 | undef], 1], ['n', 1]] |
| 1186 | |
| 1187 | Note that while we obtained this value using a nice little script, |
| 1188 | there is no simple way to I<use> this value. In fact this value may |
| 1189 | be inspected in debugger (see L<perldebug>), but only if |
| 1190 | C<bareStringify> B<O>ption is set, and not via C<p> command. |
| 1191 | |
| 1192 | If one attempts to print this value, then the overloaded operator |
| 1193 | C<""> will be called, which will call C<nomethod> operator. The |
| 1194 | result of this operator will be stringified again, but this result is |
| 1195 | again of type C<symbolic>, which will lead to an infinite loop. |
| 1196 | |
| 1197 | Add a pretty-printer method to the module F<symbolic.pm>: |
| 1198 | |
| 1199 | sub pretty { |
| 1200 | my ($meth, $a, $b) = @{+shift}; |
| 1201 | $a = 'u' unless defined $a; |
| 1202 | $b = 'u' unless defined $b; |
| 1203 | $a = $a->pretty if ref $a; |
| 1204 | $b = $b->pretty if ref $b; |
| 1205 | "[$meth $a $b]"; |
| 1206 | } |
| 1207 | |
| 1208 | Now one can finish the script by |
| 1209 | |
| 1210 | print "side = ", $side->pretty, "\n"; |
| 1211 | |
| 1212 | The method C<pretty> is doing object-to-string conversion, so it |
| 1213 | is natural to overload the operator C<""> using this method. However, |
| 1214 | inside such a method it is not necessary to pretty-print the |
| 1215 | I<components> $a and $b of an object. In the above subroutine |
| 1216 | C<"[$meth $a $b]"> is a catenation of some strings and components $a |
| 1217 | and $b. If these components use overloading, the catenation operator |
| 1218 | will look for an overloaded operator C<.>; if not present, it will |
| 1219 | look for an overloaded operator C<"">. Thus it is enough to use |
| 1220 | |
| 1221 | use overload nomethod => \&wrap, '""' => \&str; |
| 1222 | sub str { |
| 1223 | my ($meth, $a, $b) = @{+shift}; |
| 1224 | $a = 'u' unless defined $a; |
| 1225 | $b = 'u' unless defined $b; |
| 1226 | "[$meth $a $b]"; |
| 1227 | } |
| 1228 | |
| 1229 | Now one can change the last line of the script to |
| 1230 | |
| 1231 | print "side = $side\n"; |
| 1232 | |
| 1233 | which outputs |
| 1234 | |
| 1235 | side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]] |
| 1236 | |
| 1237 | and one can inspect the value in debugger using all the possible |
| 1238 | methods. |
| 1239 | |
| 1240 | Something is still amiss: consider the loop variable $cnt of the |
| 1241 | script. It was a number, not an object. We cannot make this value of |
| 1242 | type C<symbolic>, since then the loop will not terminate. |
| 1243 | |
| 1244 | Indeed, to terminate the cycle, the $cnt should become false. |
| 1245 | However, the operator C<bool> for checking falsity is overloaded (this |
| 1246 | time via overloaded C<"">), and returns a long string, thus any object |
| 1247 | of type C<symbolic> is true. To overcome this, we need a way to |
| 1248 | compare an object to 0. In fact, it is easier to write a numeric |
| 1249 | conversion routine. |
| 1250 | |
| 1251 | Here is the text of F<symbolic.pm> with such a routine added (and |
| 1252 | slightly modified str()): |
| 1253 | |
| 1254 | package symbolic; # Primitive symbolic calculator |
| 1255 | use overload |
| 1256 | nomethod => \&wrap, '""' => \&str, '0+' => \# |
| 1257 | |
| 1258 | sub new { shift; bless ['n', @_] } |
| 1259 | sub wrap { |
| 1260 | my ($obj, $other, $inv, $meth) = @_; |
| 1261 | ($obj, $other) = ($other, $obj) if $inv; |
| 1262 | bless [$meth, $obj, $other]; |
| 1263 | } |
| 1264 | sub str { |
| 1265 | my ($meth, $a, $b) = @{+shift}; |
| 1266 | $a = 'u' unless defined $a; |
| 1267 | if (defined $b) { |
| 1268 | "[$meth $a $b]"; |
| 1269 | } else { |
| 1270 | "[$meth $a]"; |
| 1271 | } |
| 1272 | } |
| 1273 | my %subr = ( n => sub {$_[0]}, |
| 1274 | sqrt => sub {sqrt $_[0]}, |
| 1275 | '-' => sub {shift() - shift()}, |
| 1276 | '+' => sub {shift() + shift()}, |
| 1277 | '/' => sub {shift() / shift()}, |
| 1278 | '*' => sub {shift() * shift()}, |
| 1279 | '**' => sub {shift() ** shift()}, |
| 1280 | ); |
| 1281 | sub num { |
| 1282 | my ($meth, $a, $b) = @{+shift}; |
| 1283 | my $subr = $subr{$meth} |
| 1284 | or die "Do not know how to ($meth) in symbolic"; |
| 1285 | $a = $a->num if ref $a eq __PACKAGE__; |
| 1286 | $b = $b->num if ref $b eq __PACKAGE__; |
| 1287 | $subr->($a,$b); |
| 1288 | } |
| 1289 | |
| 1290 | All the work of numeric conversion is done in %subr and num(). Of |
| 1291 | course, %subr is not complete, it contains only operators used in the |
| 1292 | example below. Here is the extra-credit question: why do we need an |
| 1293 | explicit recursion in num()? (Answer is at the end of this section.) |
| 1294 | |
| 1295 | Use this module like this: |
| 1296 | |
| 1297 | require symbolic; |
| 1298 | my $iter = symbolic->new(2); # 16-gon |
| 1299 | my $side = symbolic->new(1); |
| 1300 | my $cnt = $iter; |
| 1301 | |
| 1302 | while ($cnt) { |
| 1303 | $cnt = $cnt - 1; # Mutator `--' not implemented |
| 1304 | $side = (sqrt(1 + $side**2) - 1)/$side; |
| 1305 | } |
| 1306 | printf "%s=%f\n", $side, $side; |
| 1307 | printf "pi=%f\n", $side*(2**($iter+2)); |
| 1308 | |
| 1309 | It prints (without so many line breaks) |
| 1310 | |
| 1311 | [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] |
| 1312 | [n 1]] 2]]] 1] |
| 1313 | [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912 |
| 1314 | pi=3.182598 |
| 1315 | |
| 1316 | The above module is very primitive. It does not implement |
| 1317 | mutator methods (C<++>, C<-=> and so on), does not do deep copying |
| 1318 | (not required without mutators!), and implements only those arithmetic |
| 1319 | operations which are used in the example. |
| 1320 | |
| 1321 | To implement most arithmetic operations is easy; one should just use |
| 1322 | the tables of operations, and change the code which fills %subr to |
| 1323 | |
| 1324 | my %subr = ( 'n' => sub {$_[0]} ); |
| 1325 | foreach my $op (split " ", $overload::ops{with_assign}) { |
| 1326 | $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}"; |
| 1327 | } |
| 1328 | my @bins = qw(binary 3way_comparison num_comparison str_comparison); |
| 1329 | foreach my $op (split " ", "@overload::ops{ @bins }") { |
| 1330 | $subr{$op} = eval "sub {shift() $op shift()}"; |
| 1331 | } |
| 1332 | foreach my $op (split " ", "@overload::ops{qw(unary func)}") { |
| 1333 | print "defining `$op'\n"; |
| 1334 | $subr{$op} = eval "sub {$op shift()}"; |
| 1335 | } |
| 1336 | |
| 1337 | Due to L<Calling Conventions for Mutators>, we do not need anything |
| 1338 | special to make C<+=> and friends work, except filling C<+=> entry of |
| 1339 | %subr, and defining a copy constructor (needed since Perl has no |
| 1340 | way to know that the implementation of C<'+='> does not mutate |
| 1341 | the argument, compare L<Copy Constructor>). |
| 1342 | |
| 1343 | To implement a copy constructor, add C<< '=' => \&cpy >> to C<use overload> |
| 1344 | line, and code (this code assumes that mutators change things one level |
| 1345 | deep only, so recursive copying is not needed): |
| 1346 | |
| 1347 | sub cpy { |
| 1348 | my $self = shift; |
| 1349 | bless [@$self], ref $self; |
| 1350 | } |
| 1351 | |
| 1352 | To make C<++> and C<--> work, we need to implement actual mutators, |
| 1353 | either directly, or in C<nomethod>. We continue to do things inside |
| 1354 | C<nomethod>, thus add |
| 1355 | |
| 1356 | if ($meth eq '++' or $meth eq '--') { |
| 1357 | @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference |
| 1358 | return $obj; |
| 1359 | } |
| 1360 | |
| 1361 | after the first line of wrap(). This is not a most effective |
| 1362 | implementation, one may consider |
| 1363 | |
| 1364 | sub inc { $_[0] = bless ['++', shift, 1]; } |
| 1365 | |
| 1366 | instead. |
| 1367 | |
| 1368 | As a final remark, note that one can fill %subr by |
| 1369 | |
| 1370 | my %subr = ( 'n' => sub {$_[0]} ); |
| 1371 | foreach my $op (split " ", $overload::ops{with_assign}) { |
| 1372 | $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}"; |
| 1373 | } |
| 1374 | my @bins = qw(binary 3way_comparison num_comparison str_comparison); |
| 1375 | foreach my $op (split " ", "@overload::ops{ @bins }") { |
| 1376 | $subr{$op} = eval "sub {shift() $op shift()}"; |
| 1377 | } |
| 1378 | foreach my $op (split " ", "@overload::ops{qw(unary func)}") { |
| 1379 | $subr{$op} = eval "sub {$op shift()}"; |
| 1380 | } |
| 1381 | $subr{'++'} = $subr{'+'}; |
| 1382 | $subr{'--'} = $subr{'-'}; |
| 1383 | |
| 1384 | This finishes implementation of a primitive symbolic calculator in |
| 1385 | 50 lines of Perl code. Since the numeric values of subexpressions |
| 1386 | are not cached, the calculator is very slow. |
| 1387 | |
| 1388 | Here is the answer for the exercise: In the case of str(), we need no |
| 1389 | explicit recursion since the overloaded C<.>-operator will fall back |
| 1390 | to an existing overloaded operator C<"">. Overloaded arithmetic |
| 1391 | operators I<do not> fall back to numeric conversion if C<fallback> is |
| 1392 | not explicitly requested. Thus without an explicit recursion num() |
| 1393 | would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild |
| 1394 | the argument of num(). |
| 1395 | |
| 1396 | If you wonder why defaults for conversion are different for str() and |
| 1397 | num(), note how easy it was to write the symbolic calculator. This |
| 1398 | simplicity is due to an appropriate choice of defaults. One extra |
| 1399 | note: due to the explicit recursion num() is more fragile than sym(): |
| 1400 | we need to explicitly check for the type of $a and $b. If components |
| 1401 | $a and $b happen to be of some related type, this may lead to problems. |
| 1402 | |
| 1403 | =head2 I<Really> symbolic calculator |
| 1404 | |
| 1405 | One may wonder why we call the above calculator symbolic. The reason |
| 1406 | is that the actual calculation of the value of expression is postponed |
| 1407 | until the value is I<used>. |
| 1408 | |
| 1409 | To see it in action, add a method |
| 1410 | |
| 1411 | sub STORE { |
| 1412 | my $obj = shift; |
| 1413 | $#$obj = 1; |
| 1414 | @$obj->[0,1] = ('=', shift); |
| 1415 | } |
| 1416 | |
| 1417 | to the package C<symbolic>. After this change one can do |
| 1418 | |
| 1419 | my $a = symbolic->new(3); |
| 1420 | my $b = symbolic->new(4); |
| 1421 | my $c = sqrt($a**2 + $b**2); |
| 1422 | |
| 1423 | and the numeric value of $c becomes 5. However, after calling |
| 1424 | |
| 1425 | $a->STORE(12); $b->STORE(5); |
| 1426 | |
| 1427 | the numeric value of $c becomes 13. There is no doubt now that the module |
| 1428 | symbolic provides a I<symbolic> calculator indeed. |
| 1429 | |
| 1430 | To hide the rough edges under the hood, provide a tie()d interface to the |
| 1431 | package C<symbolic> (compare with L<Metaphor clash>). Add methods |
| 1432 | |
| 1433 | sub TIESCALAR { my $pack = shift; $pack->new(@_) } |
| 1434 | sub FETCH { shift } |
| 1435 | sub nop { } # Around a bug |
| 1436 | |
| 1437 | (the bug is described in L<"BUGS">). One can use this new interface as |
| 1438 | |
| 1439 | tie $a, 'symbolic', 3; |
| 1440 | tie $b, 'symbolic', 4; |
| 1441 | $a->nop; $b->nop; # Around a bug |
| 1442 | |
| 1443 | my $c = sqrt($a**2 + $b**2); |
| 1444 | |
| 1445 | Now numeric value of $c is 5. After C<$a = 12; $b = 5> the numeric value |
| 1446 | of $c becomes 13. To insulate the user of the module add a method |
| 1447 | |
| 1448 | sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; } |
| 1449 | |
| 1450 | Now |
| 1451 | |
| 1452 | my ($a, $b); |
| 1453 | symbolic->vars($a, $b); |
| 1454 | my $c = sqrt($a**2 + $b**2); |
| 1455 | |
| 1456 | $a = 3; $b = 4; |
| 1457 | printf "c5 %s=%f\n", $c, $c; |
| 1458 | |
| 1459 | $a = 12; $b = 5; |
| 1460 | printf "c13 %s=%f\n", $c, $c; |
| 1461 | |
| 1462 | shows that the numeric value of $c follows changes to the values of $a |
| 1463 | and $b. |
| 1464 | |
| 1465 | =head1 AUTHOR |
| 1466 | |
| 1467 | Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>. |
| 1468 | |
| 1469 | =head1 SEE ALSO |
| 1470 | |
| 1471 | The L<overloading> pragma can be used to enable or disable overloaded |
| 1472 | operations within a lexical scope. |
| 1473 | |
| 1474 | =head1 DIAGNOSTICS |
| 1475 | |
| 1476 | When Perl is run with the B<-Do> switch or its equivalent, overloading |
| 1477 | induces diagnostic messages. |
| 1478 | |
| 1479 | Using the C<m> command of Perl debugger (see L<perldebug>) one can |
| 1480 | deduce which operations are overloaded (and which ancestor triggers |
| 1481 | this overloading). Say, if C<eq> is overloaded, then the method C<(eq> |
| 1482 | is shown by debugger. The method C<()> corresponds to the C<fallback> |
| 1483 | key (in fact a presence of this method shows that this package has |
| 1484 | overloading enabled, and it is what is used by the C<Overloaded> |
| 1485 | function of module C<overload>). |
| 1486 | |
| 1487 | The module might issue the following warnings: |
| 1488 | |
| 1489 | =over 4 |
| 1490 | |
| 1491 | =item Odd number of arguments for overload::constant |
| 1492 | |
| 1493 | (W) The call to overload::constant contained an odd number of arguments. |
| 1494 | The arguments should come in pairs. |
| 1495 | |
| 1496 | =item `%s' is not an overloadable type |
| 1497 | |
| 1498 | (W) You tried to overload a constant type the overload package is unaware of. |
| 1499 | |
| 1500 | =item `%s' is not a code reference |
| 1501 | |
| 1502 | (W) The second (fourth, sixth, ...) argument of overload::constant needs |
| 1503 | to be a code reference. Either an anonymous subroutine, or a reference |
| 1504 | to a subroutine. |
| 1505 | |
| 1506 | =back |
| 1507 | |
| 1508 | =head1 BUGS |
| 1509 | |
| 1510 | Because it is used for overloading, the per-package hash %OVERLOAD now |
| 1511 | has a special meaning in Perl. The symbol table is filled with names |
| 1512 | looking like line-noise. |
| 1513 | |
| 1514 | For the purpose of inheritance every overloaded package behaves as if |
| 1515 | C<fallback> is present (possibly undefined). This may create |
| 1516 | interesting effects if some package is not overloaded, but inherits |
| 1517 | from two overloaded packages. |
| 1518 | |
| 1519 | Relation between overloading and tie()ing is broken. Overloading is |
| 1520 | triggered or not basing on the I<previous> class of tie()d value. |
| 1521 | |
| 1522 | This happens because the presence of overloading is checked too early, |
| 1523 | before any tie()d access is attempted. If the FETCH()ed class of the |
| 1524 | tie()d value does not change, a simple workaround is to access the value |
| 1525 | immediately after tie()ing, so that after this call the I<previous> class |
| 1526 | coincides with the current one. |
| 1527 | |
| 1528 | B<Needed:> a way to fix this without a speed penalty. |
| 1529 | |
| 1530 | Barewords are not covered by overloaded string constants. |
| 1531 | |
| 1532 | This document is confusing. There are grammos and misleading language |
| 1533 | used in places. It would seem a total rewrite is needed. |
| 1534 | |
| 1535 | =cut |
| 1536 | |