| 1 | =head1 NAME |
| 2 | X<function> |
| 3 | |
| 4 | perlfunc - Perl builtin functions |
| 5 | |
| 6 | =head1 DESCRIPTION |
| 7 | |
| 8 | The functions in this section can serve as terms in an expression. |
| 9 | They fall into two major categories: list operators and named unary |
| 10 | operators. These differ in their precedence relationship with a |
| 11 | following comma. (See the precedence table in L<perlop>.) List |
| 12 | operators take more than one argument, while unary operators can never |
| 13 | take more than one argument. Thus, a comma terminates the argument of |
| 14 | a unary operator, but merely separates the arguments of a list |
| 15 | operator. A unary operator generally provides scalar context to its |
| 16 | argument, while a list operator may provide either scalar or list |
| 17 | contexts for its arguments. If it does both, scalar arguments |
| 18 | come first and list argument follow, and there can only ever |
| 19 | be one such list argument. For instance, splice() has three scalar |
| 20 | arguments followed by a list, whereas gethostbyname() has four scalar |
| 21 | arguments. |
| 22 | |
| 23 | In the syntax descriptions that follow, list operators that expect a |
| 24 | list (and provide list context for elements of the list) are shown |
| 25 | with LIST as an argument. Such a list may consist of any combination |
| 26 | of scalar arguments or list values; the list values will be included |
| 27 | in the list as if each individual element were interpolated at that |
| 28 | point in the list, forming a longer single-dimensional list value. |
| 29 | Commas should separate literal elements of the LIST. |
| 30 | |
| 31 | Any function in the list below may be used either with or without |
| 32 | parentheses around its arguments. (The syntax descriptions omit the |
| 33 | parentheses.) If you use parentheses, the simple but occasionally |
| 34 | surprising rule is this: It I<looks> like a function, therefore it I<is> a |
| 35 | function, and precedence doesn't matter. Otherwise it's a list |
| 36 | operator or unary operator, and precedence does matter. Whitespace |
| 37 | between the function and left parenthesis doesn't count, so sometimes |
| 38 | you need to be careful: |
| 39 | |
| 40 | print 1+2+4; # Prints 7. |
| 41 | print(1+2) + 4; # Prints 3. |
| 42 | print (1+2)+4; # Also prints 3! |
| 43 | print +(1+2)+4; # Prints 7. |
| 44 | print ((1+2)+4); # Prints 7. |
| 45 | |
| 46 | If you run Perl with the B<-w> switch it can warn you about this. For |
| 47 | example, the third line above produces: |
| 48 | |
| 49 | print (...) interpreted as function at - line 1. |
| 50 | Useless use of integer addition in void context at - line 1. |
| 51 | |
| 52 | A few functions take no arguments at all, and therefore work as neither |
| 53 | unary nor list operators. These include such functions as C<time> |
| 54 | and C<endpwent>. For example, C<time+86_400> always means |
| 55 | C<time() + 86_400>. |
| 56 | |
| 57 | For functions that can be used in either a scalar or list context, |
| 58 | nonabortive failure is generally indicated in scalar context by |
| 59 | returning the undefined value, and in list context by returning the |
| 60 | empty list. |
| 61 | |
| 62 | Remember the following important rule: There is B<no rule> that relates |
| 63 | the behavior of an expression in list context to its behavior in scalar |
| 64 | context, or vice versa. It might do two totally different things. |
| 65 | Each operator and function decides which sort of value would be most |
| 66 | appropriate to return in scalar context. Some operators return the |
| 67 | length of the list that would have been returned in list context. Some |
| 68 | operators return the first value in the list. Some operators return the |
| 69 | last value in the list. Some operators return a count of successful |
| 70 | operations. In general, they do what you want, unless you want |
| 71 | consistency. |
| 72 | X<context> |
| 73 | |
| 74 | A named array in scalar context is quite different from what would at |
| 75 | first glance appear to be a list in scalar context. You can't get a list |
| 76 | like C<(1,2,3)> into being in scalar context, because the compiler knows |
| 77 | the context at compile time. It would generate the scalar comma operator |
| 78 | there, not the list construction version of the comma. That means it |
| 79 | was never a list to start with. |
| 80 | |
| 81 | In general, functions in Perl that serve as wrappers for system calls ("syscalls") |
| 82 | of the same name (like chown(2), fork(2), closedir(2), etc.) return |
| 83 | true when they succeed and C<undef> otherwise, as is usually mentioned |
| 84 | in the descriptions below. This is different from the C interfaces, |
| 85 | which return C<-1> on failure. Exceptions to this rule include C<wait>, |
| 86 | C<waitpid>, and C<syscall>. System calls also set the special C<$!> |
| 87 | variable on failure. Other functions do not, except accidentally. |
| 88 | |
| 89 | Extension modules can also hook into the Perl parser to define new |
| 90 | kinds of keyword-headed expression. These may look like functions, but |
| 91 | may also look completely different. The syntax following the keyword |
| 92 | is defined entirely by the extension. If you are an implementor, see |
| 93 | L<perlapi/PL_keyword_plugin> for the mechanism. If you are using such |
| 94 | a module, see the module's documentation for details of the syntax that |
| 95 | it defines. |
| 96 | |
| 97 | =head2 Perl Functions by Category |
| 98 | X<function> |
| 99 | |
| 100 | Here are Perl's functions (including things that look like |
| 101 | functions, like some keywords and named operators) |
| 102 | arranged by category. Some functions appear in more |
| 103 | than one place. |
| 104 | |
| 105 | =over 4 |
| 106 | |
| 107 | =item Functions for SCALARs or strings |
| 108 | X<scalar> X<string> X<character> |
| 109 | |
| 110 | C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>, |
| 111 | C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>, |
| 112 | C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///> |
| 113 | |
| 114 | =item Regular expressions and pattern matching |
| 115 | X<regular expression> X<regex> X<regexp> |
| 116 | |
| 117 | C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//> |
| 118 | |
| 119 | =item Numeric functions |
| 120 | X<numeric> X<number> X<trigonometric> X<trigonometry> |
| 121 | |
| 122 | C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>, |
| 123 | C<sin>, C<sqrt>, C<srand> |
| 124 | |
| 125 | =item Functions for real @ARRAYs |
| 126 | X<array> |
| 127 | |
| 128 | C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values> |
| 129 | |
| 130 | =item Functions for list data |
| 131 | X<list> |
| 132 | |
| 133 | C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack> |
| 134 | |
| 135 | =item Functions for real %HASHes |
| 136 | X<hash> |
| 137 | |
| 138 | C<delete>, C<each>, C<exists>, C<keys>, C<values> |
| 139 | |
| 140 | =item Input and output functions |
| 141 | X<I/O> X<input> X<output> X<dbm> |
| 142 | |
| 143 | C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>, |
| 144 | C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>, |
| 145 | C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>, |
| 146 | C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>, |
| 147 | C<warn>, C<write> |
| 148 | |
| 149 | =item Functions for fixed-length data or records |
| 150 | |
| 151 | C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec> |
| 152 | |
| 153 | =item Functions for filehandles, files, or directories |
| 154 | X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink> |
| 155 | |
| 156 | C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>, |
| 157 | C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>, |
| 158 | C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>, |
| 159 | C<umask>, C<unlink>, C<utime> |
| 160 | |
| 161 | =item Keywords related to the control flow of your Perl program |
| 162 | X<control flow> |
| 163 | |
| 164 | C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>, |
| 165 | C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray> |
| 166 | |
| 167 | =item Keywords related to the switch feature |
| 168 | |
| 169 | C<break>, C<continue>, C<default, >C<given>, C<when> |
| 170 | |
| 171 | These are available only if you enable the C<"switch"> feature. |
| 172 | See L<feature> and L<perlsyn/"Switch statements">. |
| 173 | Alternately, include a C<use v5.10> or later to the current scope. |
| 174 | |
| 175 | =item Keywords related to scoping |
| 176 | |
| 177 | C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use> |
| 178 | |
| 179 | C<state> is available only if the C<"state"> feature is enabled. See |
| 180 | L<feature>. Alternately, include a C<use v5.10> or later to the current scope. |
| 181 | |
| 182 | =item Miscellaneous functions |
| 183 | |
| 184 | C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, |
| 185 | C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray> |
| 186 | |
| 187 | =item Functions for processes and process groups |
| 188 | X<process> X<pid> X<process id> |
| 189 | |
| 190 | C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>, |
| 191 | C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>, |
| 192 | C<times>, C<wait>, C<waitpid> |
| 193 | |
| 194 | =item Keywords related to Perl modules |
| 195 | X<module> |
| 196 | |
| 197 | C<do>, C<import>, C<no>, C<package>, C<require>, C<use> |
| 198 | |
| 199 | =item Keywords related to classes and object-orientation |
| 200 | X<object> X<class> X<package> |
| 201 | |
| 202 | C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>, |
| 203 | C<untie>, C<use> |
| 204 | |
| 205 | =item Low-level socket functions |
| 206 | X<socket> X<sock> |
| 207 | |
| 208 | C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>, |
| 209 | C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>, |
| 210 | C<socket>, C<socketpair> |
| 211 | |
| 212 | =item System V interprocess communication functions |
| 213 | X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message> |
| 214 | |
| 215 | C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>, |
| 216 | C<shmctl>, C<shmget>, C<shmread>, C<shmwrite> |
| 217 | |
| 218 | =item Fetching user and group info |
| 219 | X<user> X<group> X<password> X<uid> X<gid> X<passwd> X</etc/passwd> |
| 220 | |
| 221 | C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>, |
| 222 | C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>, |
| 223 | C<getpwuid>, C<setgrent>, C<setpwent> |
| 224 | |
| 225 | =item Fetching network info |
| 226 | X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service> |
| 227 | |
| 228 | C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>, |
| 229 | C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>, |
| 230 | C<getprotobyname>, C<getprotobynumber>, C<getprotoent>, |
| 231 | C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>, |
| 232 | C<setnetent>, C<setprotoent>, C<setservent> |
| 233 | |
| 234 | =item Time-related functions |
| 235 | X<time> X<date> |
| 236 | |
| 237 | C<gmtime>, C<localtime>, C<time>, C<times> |
| 238 | |
| 239 | =item Functions new in perl5 |
| 240 | X<perl5> |
| 241 | |
| 242 | C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, |
| 243 | C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>, |
| 244 | C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>, |
| 245 | C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>, |
| 246 | C<ucfirst>, C<untie>, C<use>, C<when> |
| 247 | |
| 248 | * C<sub> was a keyword in Perl 4, but in Perl 5 it is an |
| 249 | operator, which can be used in expressions. |
| 250 | |
| 251 | =item Functions obsoleted in perl5 |
| 252 | |
| 253 | C<dbmclose>, C<dbmopen> |
| 254 | |
| 255 | =back |
| 256 | |
| 257 | =head2 Portability |
| 258 | X<portability> X<Unix> X<portable> |
| 259 | |
| 260 | Perl was born in Unix and can therefore access all common Unix |
| 261 | system calls. In non-Unix environments, the functionality of some |
| 262 | Unix system calls may not be available or details of the available |
| 263 | functionality may differ slightly. The Perl functions affected |
| 264 | by this are: |
| 265 | |
| 266 | C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>, |
| 267 | C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>, |
| 268 | C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>, |
| 269 | C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>, |
| 270 | C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>, |
| 271 | C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>, |
| 272 | C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>, |
| 273 | C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>, |
| 274 | C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>, |
| 275 | C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>, |
| 276 | C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>, |
| 277 | C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>, |
| 278 | C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>, |
| 279 | C<shmwrite>, C<socket>, C<socketpair>, |
| 280 | C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>, |
| 281 | C<times>, C<truncate>, C<umask>, C<unlink>, |
| 282 | C<utime>, C<wait>, C<waitpid> |
| 283 | |
| 284 | For more information about the portability of these functions, see |
| 285 | L<perlport> and other available platform-specific documentation. |
| 286 | |
| 287 | =head2 Alphabetical Listing of Perl Functions |
| 288 | |
| 289 | =over |
| 290 | |
| 291 | =item -X FILEHANDLE |
| 292 | X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p> |
| 293 | X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C> |
| 294 | |
| 295 | =item -X EXPR |
| 296 | |
| 297 | =item -X DIRHANDLE |
| 298 | |
| 299 | =item -X |
| 300 | |
| 301 | A file test, where X is one of the letters listed below. This unary |
| 302 | operator takes one argument, either a filename, a filehandle, or a dirhandle, |
| 303 | and tests the associated file to see if something is true about it. If the |
| 304 | argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN. |
| 305 | Unless otherwise documented, it returns C<1> for true and C<''> for false, or |
| 306 | the undefined value if the file doesn't exist. Despite the funny |
| 307 | names, precedence is the same as any other named unary operator. The |
| 308 | operator may be any of: |
| 309 | |
| 310 | -r File is readable by effective uid/gid. |
| 311 | -w File is writable by effective uid/gid. |
| 312 | -x File is executable by effective uid/gid. |
| 313 | -o File is owned by effective uid. |
| 314 | |
| 315 | -R File is readable by real uid/gid. |
| 316 | -W File is writable by real uid/gid. |
| 317 | -X File is executable by real uid/gid. |
| 318 | -O File is owned by real uid. |
| 319 | |
| 320 | -e File exists. |
| 321 | -z File has zero size (is empty). |
| 322 | -s File has nonzero size (returns size in bytes). |
| 323 | |
| 324 | -f File is a plain file. |
| 325 | -d File is a directory. |
| 326 | -l File is a symbolic link. |
| 327 | -p File is a named pipe (FIFO), or Filehandle is a pipe. |
| 328 | -S File is a socket. |
| 329 | -b File is a block special file. |
| 330 | -c File is a character special file. |
| 331 | -t Filehandle is opened to a tty. |
| 332 | |
| 333 | -u File has setuid bit set. |
| 334 | -g File has setgid bit set. |
| 335 | -k File has sticky bit set. |
| 336 | |
| 337 | -T File is an ASCII text file (heuristic guess). |
| 338 | -B File is a "binary" file (opposite of -T). |
| 339 | |
| 340 | -M Script start time minus file modification time, in days. |
| 341 | -A Same for access time. |
| 342 | -C Same for inode change time (Unix, may differ for other platforms) |
| 343 | |
| 344 | Example: |
| 345 | |
| 346 | while (<>) { |
| 347 | chomp; |
| 348 | next unless -f $_; # ignore specials |
| 349 | #... |
| 350 | } |
| 351 | |
| 352 | Note that C<-s/a/b/> does not do a negated substitution. Saying |
| 353 | C<-exp($foo)> still works as expected, however: only single letters |
| 354 | following a minus are interpreted as file tests. |
| 355 | |
| 356 | These operators are exempt from the "looks like a function rule" described |
| 357 | above. That is, an opening parenthesis after the operator does not affect |
| 358 | how much of the following code constitutes the argument. Put the opening |
| 359 | parentheses before the operator to separate it from code that follows (this |
| 360 | applies only to operators with higher precedence than unary operators, of |
| 361 | course): |
| 362 | |
| 363 | -s($file) + 1024 # probably wrong; same as -s($file + 1024) |
| 364 | (-s $file) + 1024 # correct |
| 365 | |
| 366 | The interpretation of the file permission operators C<-r>, C<-R>, |
| 367 | C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode |
| 368 | of the file and the uids and gids of the user. There may be other |
| 369 | reasons you can't actually read, write, or execute the file: for |
| 370 | example network filesystem access controls, ACLs (access control lists), |
| 371 | read-only filesystems, and unrecognized executable formats. Note |
| 372 | that the use of these six specific operators to verify if some operation |
| 373 | is possible is usually a mistake, because it may be open to race |
| 374 | conditions. |
| 375 | |
| 376 | Also note that, for the superuser on the local filesystems, the C<-r>, |
| 377 | C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1 |
| 378 | if any execute bit is set in the mode. Scripts run by the superuser |
| 379 | may thus need to do a stat() to determine the actual mode of the file, |
| 380 | or temporarily set their effective uid to something else. |
| 381 | |
| 382 | If you are using ACLs, there is a pragma called C<filetest> that may |
| 383 | produce more accurate results than the bare stat() mode bits. |
| 384 | When under C<use filetest 'access'> the above-mentioned filetests |
| 385 | test whether the permission can(not) be granted using the |
| 386 | access(2) family of system calls. Also note that the C<-x> and C<-X> may |
| 387 | under this pragma return true even if there are no execute permission |
| 388 | bits set (nor any extra execute permission ACLs). This strangeness is |
| 389 | due to the underlying system calls' definitions. Note also that, due to |
| 390 | the implementation of C<use filetest 'access'>, the C<_> special |
| 391 | filehandle won't cache the results of the file tests when this pragma is |
| 392 | in effect. Read the documentation for the C<filetest> pragma for more |
| 393 | information. |
| 394 | |
| 395 | The C<-T> and C<-B> switches work as follows. The first block or so of the |
| 396 | file is examined for odd characters such as strange control codes or |
| 397 | characters with the high bit set. If too many strange characters (>30%) |
| 398 | are found, it's a C<-B> file; otherwise it's a C<-T> file. Also, any file |
| 399 | containing a zero byte in the first block is considered a binary file. If C<-T> |
| 400 | or C<-B> is used on a filehandle, the current IO buffer is examined |
| 401 | rather than the first block. Both C<-T> and C<-B> return true on an empty |
| 402 | file, or a file at EOF when testing a filehandle. Because you have to |
| 403 | read a file to do the C<-T> test, on most occasions you want to use a C<-f> |
| 404 | against the file first, as in C<next unless -f $file && -T $file>. |
| 405 | |
| 406 | If any of the file tests (or either the C<stat> or C<lstat> operator) is given |
| 407 | the special filehandle consisting of a solitary underline, then the stat |
| 408 | structure of the previous file test (or stat operator) is used, saving |
| 409 | a system call. (This doesn't work with C<-t>, and you need to remember |
| 410 | that lstat() and C<-l> leave values in the stat structure for the |
| 411 | symbolic link, not the real file.) (Also, if the stat buffer was filled by |
| 412 | an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>). |
| 413 | Example: |
| 414 | |
| 415 | print "Can do.\n" if -r $a || -w _ || -x _; |
| 416 | |
| 417 | stat($filename); |
| 418 | print "Readable\n" if -r _; |
| 419 | print "Writable\n" if -w _; |
| 420 | print "Executable\n" if -x _; |
| 421 | print "Setuid\n" if -u _; |
| 422 | print "Setgid\n" if -g _; |
| 423 | print "Sticky\n" if -k _; |
| 424 | print "Text\n" if -T _; |
| 425 | print "Binary\n" if -B _; |
| 426 | |
| 427 | As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file |
| 428 | test operators, in a way that C<-f -w -x $file> is equivalent to |
| 429 | C<-x $file && -w _ && -f _>. (This is only fancy fancy: if you use |
| 430 | the return value of C<-f $file> as an argument to another filetest |
| 431 | operator, no special magic will happen.) |
| 432 | |
| 433 | =item abs VALUE |
| 434 | X<abs> X<absolute> |
| 435 | |
| 436 | =item abs |
| 437 | |
| 438 | Returns the absolute value of its argument. |
| 439 | If VALUE is omitted, uses C<$_>. |
| 440 | |
| 441 | =item accept NEWSOCKET,GENERICSOCKET |
| 442 | X<accept> |
| 443 | |
| 444 | Accepts an incoming socket connect, just as accept(2) |
| 445 | does. Returns the packed address if it succeeded, false otherwise. |
| 446 | See the example in L<perlipc/"Sockets: Client/Server Communication">. |
| 447 | |
| 448 | On systems that support a close-on-exec flag on files, the flag will |
| 449 | be set for the newly opened file descriptor, as determined by the |
| 450 | value of $^F. See L<perlvar/$^F>. |
| 451 | |
| 452 | =item alarm SECONDS |
| 453 | X<alarm> |
| 454 | X<SIGALRM> |
| 455 | X<timer> |
| 456 | |
| 457 | =item alarm |
| 458 | |
| 459 | Arranges to have a SIGALRM delivered to this process after the |
| 460 | specified number of wallclock seconds has elapsed. If SECONDS is not |
| 461 | specified, the value stored in C<$_> is used. (On some machines, |
| 462 | unfortunately, the elapsed time may be up to one second less or more |
| 463 | than you specified because of how seconds are counted, and process |
| 464 | scheduling may delay the delivery of the signal even further.) |
| 465 | |
| 466 | Only one timer may be counting at once. Each call disables the |
| 467 | previous timer, and an argument of C<0> may be supplied to cancel the |
| 468 | previous timer without starting a new one. The returned value is the |
| 469 | amount of time remaining on the previous timer. |
| 470 | |
| 471 | For delays of finer granularity than one second, the Time::HiRes module |
| 472 | (from CPAN, and starting from Perl 5.8 part of the standard |
| 473 | distribution) provides ualarm(). You may also use Perl's four-argument |
| 474 | version of select() leaving the first three arguments undefined, or you |
| 475 | might be able to use the C<syscall> interface to access setitimer(2) if |
| 476 | your system supports it. See L<perlfaq8> for details. |
| 477 | |
| 478 | It is usually a mistake to intermix C<alarm> and C<sleep> calls, because |
| 479 | C<sleep> may be internally implemented on your system with C<alarm>. |
| 480 | |
| 481 | If you want to use C<alarm> to time out a system call you need to use an |
| 482 | C<eval>/C<die> pair. You can't rely on the alarm causing the system call to |
| 483 | fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to |
| 484 | restart system calls on some systems. Using C<eval>/C<die> always works, |
| 485 | modulo the caveats given in L<perlipc/"Signals">. |
| 486 | |
| 487 | eval { |
| 488 | local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required |
| 489 | alarm $timeout; |
| 490 | $nread = sysread SOCKET, $buffer, $size; |
| 491 | alarm 0; |
| 492 | }; |
| 493 | if ($@) { |
| 494 | die unless $@ eq "alarm\n"; # propagate unexpected errors |
| 495 | # timed out |
| 496 | } |
| 497 | else { |
| 498 | # didn't |
| 499 | } |
| 500 | |
| 501 | For more information see L<perlipc>. |
| 502 | |
| 503 | =item atan2 Y,X |
| 504 | X<atan2> X<arctangent> X<tan> X<tangent> |
| 505 | |
| 506 | Returns the arctangent of Y/X in the range -PI to PI. |
| 507 | |
| 508 | For the tangent operation, you may use the C<Math::Trig::tan> |
| 509 | function, or use the familiar relation: |
| 510 | |
| 511 | sub tan { sin($_[0]) / cos($_[0]) } |
| 512 | |
| 513 | The return value for C<atan2(0,0)> is implementation-defined; consult |
| 514 | your atan2(3) manpage for more information. |
| 515 | |
| 516 | =item bind SOCKET,NAME |
| 517 | X<bind> |
| 518 | |
| 519 | Binds a network address to a socket, just as bind(2) |
| 520 | does. Returns true if it succeeded, false otherwise. NAME should be a |
| 521 | packed address of the appropriate type for the socket. See the examples in |
| 522 | L<perlipc/"Sockets: Client/Server Communication">. |
| 523 | |
| 524 | =item binmode FILEHANDLE, LAYER |
| 525 | X<binmode> X<binary> X<text> X<DOS> X<Windows> |
| 526 | |
| 527 | =item binmode FILEHANDLE |
| 528 | |
| 529 | Arranges for FILEHANDLE to be read or written in "binary" or "text" |
| 530 | mode on systems where the run-time libraries distinguish between |
| 531 | binary and text files. If FILEHANDLE is an expression, the value is |
| 532 | taken as the name of the filehandle. Returns true on success, |
| 533 | otherwise it returns C<undef> and sets C<$!> (errno). |
| 534 | |
| 535 | On some systems (in general, DOS- and Windows-based systems) binmode() |
| 536 | is necessary when you're not working with a text file. For the sake |
| 537 | of portability it is a good idea always to use it when appropriate, |
| 538 | and never to use it when it isn't appropriate. Also, people can |
| 539 | set their I/O to be by default UTF8-encoded Unicode, not bytes. |
| 540 | |
| 541 | In other words: regardless of platform, use binmode() on binary data, |
| 542 | like images, for example. |
| 543 | |
| 544 | If LAYER is present it is a single string, but may contain multiple |
| 545 | directives. The directives alter the behaviour of the filehandle. |
| 546 | When LAYER is present, using binmode on a text file makes sense. |
| 547 | |
| 548 | If LAYER is omitted or specified as C<:raw> the filehandle is made |
| 549 | suitable for passing binary data. This includes turning off possible CRLF |
| 550 | translation and marking it as bytes (as opposed to Unicode characters). |
| 551 | Note that, despite what may be implied in I<"Programming Perl"> (the |
| 552 | Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>. |
| 553 | Other layers that would affect the binary nature of the stream are |
| 554 | I<also> disabled. See L<PerlIO>, L<perlrun>, and the discussion about the |
| 555 | PERLIO environment variable. |
| 556 | |
| 557 | The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the |
| 558 | form C<:...>, are called I/O I<layers>. The C<open> pragma can be used to |
| 559 | establish default I/O layers. See L<open>. |
| 560 | |
| 561 | I<The LAYER parameter of the binmode() function is described as "DISCIPLINE" |
| 562 | in "Programming Perl, 3rd Edition". However, since the publishing of this |
| 563 | book, by many known as "Camel III", the consensus of the naming of this |
| 564 | functionality has moved from "discipline" to "layer". All documentation |
| 565 | of this version of Perl therefore refers to "layers" rather than to |
| 566 | "disciplines". Now back to the regularly scheduled documentation...> |
| 567 | |
| 568 | To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>. |
| 569 | C<:utf8> just marks the data as UTF-8 without further checking, |
| 570 | while C<:encoding(UTF-8)> checks the data for actually being valid |
| 571 | UTF-8. More details can be found in L<PerlIO::encoding>. |
| 572 | |
| 573 | In general, binmode() should be called after open() but before any I/O |
| 574 | is done on the filehandle. Calling binmode() normally flushes any |
| 575 | pending buffered output data (and perhaps pending input data) on the |
| 576 | handle. An exception to this is the C<:encoding> layer that |
| 577 | changes the default character encoding of the handle; see L</open>. |
| 578 | The C<:encoding> layer sometimes needs to be called in |
| 579 | mid-stream, and it doesn't flush the stream. The C<:encoding> |
| 580 | also implicitly pushes on top of itself the C<:utf8> layer because |
| 581 | internally Perl operates on UTF8-encoded Unicode characters. |
| 582 | |
| 583 | The operating system, device drivers, C libraries, and Perl run-time |
| 584 | system all conspire to let the programmer treat a single |
| 585 | character (C<\n>) as the line terminator, irrespective of external |
| 586 | representation. On many operating systems, the native text file |
| 587 | representation matches the internal representation, but on some |
| 588 | platforms the external representation of C<\n> is made up of more than |
| 589 | one character. |
| 590 | |
| 591 | All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use |
| 592 | a single character to end each line in the external representation of text |
| 593 | (even though that single character is CARRIAGE RETURN on old, pre-Darwin |
| 594 | flavors of Mac OS, and is LINE FEED on Unix and most VMS files). In other |
| 595 | systems like OS/2, DOS, and the various flavors of MS-Windows, your program |
| 596 | sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the |
| 597 | two characters C<\cM\cJ>. That means that if you don't use binmode() on |
| 598 | these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on |
| 599 | input, and any C<\n> in your program will be converted back to C<\cM\cJ> on |
| 600 | output. This is what you want for text files, but it can be disastrous for |
| 601 | binary files. |
| 602 | |
| 603 | Another consequence of using binmode() (on some systems) is that |
| 604 | special end-of-file markers will be seen as part of the data stream. |
| 605 | For systems from the Microsoft family this means that, if your binary |
| 606 | data contain C<\cZ>, the I/O subsystem will regard it as the end of |
| 607 | the file, unless you use binmode(). |
| 608 | |
| 609 | binmode() is important not only for readline() and print() operations, |
| 610 | but also when using read(), seek(), sysread(), syswrite() and tell() |
| 611 | (see L<perlport> for more details). See the C<$/> and C<$\> variables |
| 612 | in L<perlvar> for how to manually set your input and output |
| 613 | line-termination sequences. |
| 614 | |
| 615 | =item bless REF,CLASSNAME |
| 616 | X<bless> |
| 617 | |
| 618 | =item bless REF |
| 619 | |
| 620 | This function tells the thingy referenced by REF that it is now an object |
| 621 | in the CLASSNAME package. If CLASSNAME is omitted, the current package |
| 622 | is used. Because a C<bless> is often the last thing in a constructor, |
| 623 | it returns the reference for convenience. Always use the two-argument |
| 624 | version if a derived class might inherit the function doing the blessing. |
| 625 | See L<perltoot> and L<perlobj> for more about the blessing (and blessings) |
| 626 | of objects. |
| 627 | |
| 628 | Consider always blessing objects in CLASSNAMEs that are mixed case. |
| 629 | Namespaces with all lowercase names are considered reserved for |
| 630 | Perl pragmata. Builtin types have all uppercase names. To prevent |
| 631 | confusion, you may wish to avoid such package names as well. Make sure |
| 632 | that CLASSNAME is a true value. |
| 633 | |
| 634 | See L<perlmod/"Perl Modules">. |
| 635 | |
| 636 | =item break |
| 637 | |
| 638 | Break out of a C<given()> block. |
| 639 | |
| 640 | This keyword is enabled by the C<"switch"> feature: see |
| 641 | L<feature> for more information. Alternately, include a C<use |
| 642 | v5.10> or later to the current scope. |
| 643 | |
| 644 | =item caller EXPR |
| 645 | X<caller> X<call stack> X<stack> X<stack trace> |
| 646 | |
| 647 | =item caller |
| 648 | |
| 649 | Returns the context of the current subroutine call. In scalar context, |
| 650 | returns the caller's package name if there I<is> a caller (that is, if |
| 651 | we're in a subroutine or C<eval> or C<require>) and the undefined value |
| 652 | otherwise. In list context, returns |
| 653 | |
| 654 | # 0 1 2 |
| 655 | ($package, $filename, $line) = caller; |
| 656 | |
| 657 | With EXPR, it returns some extra information that the debugger uses to |
| 658 | print a stack trace. The value of EXPR indicates how many call frames |
| 659 | to go back before the current one. |
| 660 | |
| 661 | # 0 1 2 3 4 |
| 662 | ($package, $filename, $line, $subroutine, $hasargs, |
| 663 | |
| 664 | # 5 6 7 8 9 10 |
| 665 | $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash) |
| 666 | = caller($i); |
| 667 | |
| 668 | Here $subroutine may be C<(eval)> if the frame is not a subroutine |
| 669 | call, but an C<eval>. In such a case additional elements $evaltext and |
| 670 | C<$is_require> are set: C<$is_require> is true if the frame is created by a |
| 671 | C<require> or C<use> statement, $evaltext contains the text of the |
| 672 | C<eval EXPR> statement. In particular, for an C<eval BLOCK> statement, |
| 673 | $subroutine is C<(eval)>, but $evaltext is undefined. (Note also that |
| 674 | each C<use> statement creates a C<require> frame inside an C<eval EXPR> |
| 675 | frame.) $subroutine may also be C<(unknown)> if this particular |
| 676 | subroutine happens to have been deleted from the symbol table. |
| 677 | C<$hasargs> is true if a new instance of C<@_> was set up for the frame. |
| 678 | C<$hints> and C<$bitmask> contain pragmatic hints that the caller was |
| 679 | compiled with. The C<$hints> and C<$bitmask> values are subject to change |
| 680 | between versions of Perl, and are not meant for external use. |
| 681 | |
| 682 | C<$hinthash> is a reference to a hash containing the value of C<%^H> when the |
| 683 | caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values |
| 684 | of this hash, as they are the actual values stored in the optree. |
| 685 | |
| 686 | Furthermore, when called from within the DB package, caller returns more |
| 687 | detailed information: it sets the list variable C<@DB::args> to be the |
| 688 | arguments with which the subroutine was invoked. |
| 689 | |
| 690 | Be aware that the optimizer might have optimized call frames away before |
| 691 | C<caller> had a chance to get the information. That means that C<caller(N)> |
| 692 | might not return information about the call frame you expect it to, for |
| 693 | C<< N > 1 >>. In particular, C<@DB::args> might have information from the |
| 694 | previous time C<caller> was called. |
| 695 | |
| 696 | Be aware that setting C<@DB::args> is I<best effort>, intended for |
| 697 | debugging or generating backtraces, and should not be relied upon. In |
| 698 | particular, as C<@_> contains aliases to the caller's arguments, Perl does |
| 699 | not take a copy of C<@_>, so C<@DB::args> will contain modifications the |
| 700 | subroutine makes to C<@_> or its contents, not the original values at call |
| 701 | time. C<@DB::args>, like C<@_>, does not hold explicit references to its |
| 702 | elements, so under certain cases its elements may have become freed and |
| 703 | reallocated for other variables or temporary values. Finally, a side effect |
| 704 | of the current implementation is that the effects of C<shift @_> can |
| 705 | I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a |
| 706 | reference to C<@_> has been taken, I<and> subject to the caveat about reallocated |
| 707 | elements), so C<@DB::args> is actually a hybrid of the current state and |
| 708 | initial state of C<@_>. Buyer beware. |
| 709 | |
| 710 | =item chdir EXPR |
| 711 | X<chdir> |
| 712 | X<cd> |
| 713 | X<directory, change> |
| 714 | |
| 715 | =item chdir FILEHANDLE |
| 716 | |
| 717 | =item chdir DIRHANDLE |
| 718 | |
| 719 | =item chdir |
| 720 | |
| 721 | Changes the working directory to EXPR, if possible. If EXPR is omitted, |
| 722 | changes to the directory specified by C<$ENV{HOME}>, if set; if not, |
| 723 | changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the |
| 724 | variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If |
| 725 | neither is set, C<chdir> does nothing. It returns true on success, |
| 726 | false otherwise. See the example under C<die>. |
| 727 | |
| 728 | On systems that support fchdir(2), you may pass a filehandle or |
| 729 | directory handle as the argument. On systems that don't support fchdir(2), |
| 730 | passing handles raises an exception. |
| 731 | |
| 732 | =item chmod LIST |
| 733 | X<chmod> X<permission> X<mode> |
| 734 | |
| 735 | Changes the permissions of a list of files. The first element of the |
| 736 | list must be the numeric mode, which should probably be an octal |
| 737 | number, and which definitely should I<not> be a string of octal digits: |
| 738 | C<0644> is okay, but C<"0644"> is not. Returns the number of files |
| 739 | successfully changed. See also L</oct> if all you have is a string. |
| 740 | |
| 741 | $cnt = chmod 0755, "foo", "bar"; |
| 742 | chmod 0755, @executables; |
| 743 | $mode = "0644"; chmod $mode, "foo"; # !!! sets mode to |
| 744 | # --w----r-T |
| 745 | $mode = "0644"; chmod oct($mode), "foo"; # this is better |
| 746 | $mode = 0644; chmod $mode, "foo"; # this is best |
| 747 | |
| 748 | On systems that support fchmod(2), you may pass filehandles among the |
| 749 | files. On systems that don't support fchmod(2), passing filehandles raises |
| 750 | an exception. Filehandles must be passed as globs or glob references to be |
| 751 | recognized; barewords are considered filenames. |
| 752 | |
| 753 | open(my $fh, "<", "foo"); |
| 754 | my $perm = (stat $fh)[2] & 07777; |
| 755 | chmod($perm | 0600, $fh); |
| 756 | |
| 757 | You can also import the symbolic C<S_I*> constants from the C<Fcntl> |
| 758 | module: |
| 759 | |
| 760 | use Fcntl qw( :mode ); |
| 761 | chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables; |
| 762 | # Identical to the chmod 0755 of the example above. |
| 763 | |
| 764 | =item chomp VARIABLE |
| 765 | X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol> |
| 766 | |
| 767 | =item chomp( LIST ) |
| 768 | |
| 769 | =item chomp |
| 770 | |
| 771 | This safer version of L</chop> removes any trailing string |
| 772 | that corresponds to the current value of C<$/> (also known as |
| 773 | $INPUT_RECORD_SEPARATOR in the C<English> module). It returns the total |
| 774 | number of characters removed from all its arguments. It's often used to |
| 775 | remove the newline from the end of an input record when you're worried |
| 776 | that the final record may be missing its newline. When in paragraph |
| 777 | mode (C<$/ = "">), it removes all trailing newlines from the string. |
| 778 | When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is |
| 779 | a reference to an integer or the like; see L<perlvar>) chomp() won't |
| 780 | remove anything. |
| 781 | If VARIABLE is omitted, it chomps C<$_>. Example: |
| 782 | |
| 783 | while (<>) { |
| 784 | chomp; # avoid \n on last field |
| 785 | @array = split(/:/); |
| 786 | # ... |
| 787 | } |
| 788 | |
| 789 | If VARIABLE is a hash, it chomps the hash's values, but not its keys. |
| 790 | |
| 791 | You can actually chomp anything that's an lvalue, including an assignment: |
| 792 | |
| 793 | chomp($cwd = `pwd`); |
| 794 | chomp($answer = <STDIN>); |
| 795 | |
| 796 | If you chomp a list, each element is chomped, and the total number of |
| 797 | characters removed is returned. |
| 798 | |
| 799 | Note that parentheses are necessary when you're chomping anything |
| 800 | that is not a simple variable. This is because C<chomp $cwd = `pwd`;> |
| 801 | is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as |
| 802 | C<chomp( $cwd = `pwd` )> which you might expect. Similarly, |
| 803 | C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than |
| 804 | as C<chomp($a, $b)>. |
| 805 | |
| 806 | =item chop VARIABLE |
| 807 | X<chop> |
| 808 | |
| 809 | =item chop( LIST ) |
| 810 | |
| 811 | =item chop |
| 812 | |
| 813 | Chops off the last character of a string and returns the character |
| 814 | chopped. It is much more efficient than C<s/.$//s> because it neither |
| 815 | scans nor copies the string. If VARIABLE is omitted, chops C<$_>. |
| 816 | If VARIABLE is a hash, it chops the hash's values, but not its keys. |
| 817 | |
| 818 | You can actually chop anything that's an lvalue, including an assignment. |
| 819 | |
| 820 | If you chop a list, each element is chopped. Only the value of the |
| 821 | last C<chop> is returned. |
| 822 | |
| 823 | Note that C<chop> returns the last character. To return all but the last |
| 824 | character, use C<substr($string, 0, -1)>. |
| 825 | |
| 826 | See also L</chomp>. |
| 827 | |
| 828 | =item chown LIST |
| 829 | X<chown> X<owner> X<user> X<group> |
| 830 | |
| 831 | Changes the owner (and group) of a list of files. The first two |
| 832 | elements of the list must be the I<numeric> uid and gid, in that |
| 833 | order. A value of -1 in either position is interpreted by most |
| 834 | systems to leave that value unchanged. Returns the number of files |
| 835 | successfully changed. |
| 836 | |
| 837 | $cnt = chown $uid, $gid, 'foo', 'bar'; |
| 838 | chown $uid, $gid, @filenames; |
| 839 | |
| 840 | On systems that support fchown(2), you may pass filehandles among the |
| 841 | files. On systems that don't support fchown(2), passing filehandles raises |
| 842 | an exception. Filehandles must be passed as globs or glob references to be |
| 843 | recognized; barewords are considered filenames. |
| 844 | |
| 845 | Here's an example that looks up nonnumeric uids in the passwd file: |
| 846 | |
| 847 | print "User: "; |
| 848 | chomp($user = <STDIN>); |
| 849 | print "Files: "; |
| 850 | chomp($pattern = <STDIN>); |
| 851 | |
| 852 | ($login,$pass,$uid,$gid) = getpwnam($user) |
| 853 | or die "$user not in passwd file"; |
| 854 | |
| 855 | @ary = glob($pattern); # expand filenames |
| 856 | chown $uid, $gid, @ary; |
| 857 | |
| 858 | On most systems, you are not allowed to change the ownership of the |
| 859 | file unless you're the superuser, although you should be able to change |
| 860 | the group to any of your secondary groups. On insecure systems, these |
| 861 | restrictions may be relaxed, but this is not a portable assumption. |
| 862 | On POSIX systems, you can detect this condition this way: |
| 863 | |
| 864 | use POSIX qw(sysconf _PC_CHOWN_RESTRICTED); |
| 865 | $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED); |
| 866 | |
| 867 | =item chr NUMBER |
| 868 | X<chr> X<character> X<ASCII> X<Unicode> |
| 869 | |
| 870 | =item chr |
| 871 | |
| 872 | Returns the character represented by that NUMBER in the character set. |
| 873 | For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and |
| 874 | chr(0x263a) is a Unicode smiley face. |
| 875 | |
| 876 | Negative values give the Unicode replacement character (chr(0xfffd)), |
| 877 | except under the L<bytes> pragma, where the low eight bits of the value |
| 878 | (truncated to an integer) are used. |
| 879 | |
| 880 | If NUMBER is omitted, uses C<$_>. |
| 881 | |
| 882 | For the reverse, use L</ord>. |
| 883 | |
| 884 | Note that characters from 128 to 255 (inclusive) are by default |
| 885 | internally not encoded as UTF-8 for backward compatibility reasons. |
| 886 | |
| 887 | See L<perlunicode> for more about Unicode. |
| 888 | |
| 889 | =item chroot FILENAME |
| 890 | X<chroot> X<root> |
| 891 | |
| 892 | =item chroot |
| 893 | |
| 894 | This function works like the system call by the same name: it makes the |
| 895 | named directory the new root directory for all further pathnames that |
| 896 | begin with a C</> by your process and all its children. (It doesn't |
| 897 | change your current working directory, which is unaffected.) For security |
| 898 | reasons, this call is restricted to the superuser. If FILENAME is |
| 899 | omitted, does a C<chroot> to C<$_>. |
| 900 | |
| 901 | =item close FILEHANDLE |
| 902 | X<close> |
| 903 | |
| 904 | =item close |
| 905 | |
| 906 | Closes the file or pipe associated with the filehandle, flushes the IO |
| 907 | buffers, and closes the system file descriptor. Returns true if those |
| 908 | operations succeed and if no error was reported by any PerlIO |
| 909 | layer. Closes the currently selected filehandle if the argument is |
| 910 | omitted. |
| 911 | |
| 912 | You don't have to close FILEHANDLE if you are immediately going to do |
| 913 | another C<open> on it, because C<open> closes it for you. (See |
| 914 | C<open>.) However, an explicit C<close> on an input file resets the line |
| 915 | counter (C<$.>), while the implicit close done by C<open> does not. |
| 916 | |
| 917 | If the filehandle came from a piped open, C<close> returns false if one of |
| 918 | the other syscalls involved fails or if its program exits with non-zero |
| 919 | status. If the only problem was that the program exited non-zero, C<$!> |
| 920 | will be set to C<0>. Closing a pipe also waits for the process executing |
| 921 | on the pipe to exit--in case you wish to look at the output of the pipe |
| 922 | afterwards--and implicitly puts the exit status value of that command into |
| 923 | C<$?> and C<${^CHILD_ERROR_NATIVE}>. |
| 924 | |
| 925 | If there are multiple threads running, C<close> on a filehandle from a |
| 926 | piped open returns true without waiting for the child process to terminate, |
| 927 | if the filehandle is still open in another thread. |
| 928 | |
| 929 | Closing the read end of a pipe before the process writing to it at the |
| 930 | other end is done writing results in the writer receiving a SIGPIPE. If |
| 931 | the other end can't handle that, be sure to read all the data before |
| 932 | closing the pipe. |
| 933 | |
| 934 | Example: |
| 935 | |
| 936 | open(OUTPUT, '|sort >foo') # pipe to sort |
| 937 | or die "Can't start sort: $!"; |
| 938 | #... # print stuff to output |
| 939 | close OUTPUT # wait for sort to finish |
| 940 | or warn $! ? "Error closing sort pipe: $!" |
| 941 | : "Exit status $? from sort"; |
| 942 | open(INPUT, 'foo') # get sort's results |
| 943 | or die "Can't open 'foo' for input: $!"; |
| 944 | |
| 945 | FILEHANDLE may be an expression whose value can be used as an indirect |
| 946 | filehandle, usually the real filehandle name or an autovivified handle. |
| 947 | |
| 948 | =item closedir DIRHANDLE |
| 949 | X<closedir> |
| 950 | |
| 951 | Closes a directory opened by C<opendir> and returns the success of that |
| 952 | system call. |
| 953 | |
| 954 | =item connect SOCKET,NAME |
| 955 | X<connect> |
| 956 | |
| 957 | Attempts to connect to a remote socket, just like connect(2). |
| 958 | Returns true if it succeeded, false otherwise. NAME should be a |
| 959 | packed address of the appropriate type for the socket. See the examples in |
| 960 | L<perlipc/"Sockets: Client/Server Communication">. |
| 961 | |
| 962 | =item continue BLOCK |
| 963 | X<continue> |
| 964 | |
| 965 | =item continue |
| 966 | |
| 967 | C<continue> is actually a flow control statement rather than a function. If |
| 968 | there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or |
| 969 | C<foreach>), it is always executed just before the conditional is about to |
| 970 | be evaluated again, just like the third part of a C<for> loop in C. Thus |
| 971 | it can be used to increment a loop variable, even when the loop has been |
| 972 | continued via the C<next> statement (which is similar to the C C<continue> |
| 973 | statement). |
| 974 | |
| 975 | C<last>, C<next>, or C<redo> may appear within a C<continue> |
| 976 | block; C<last> and C<redo> behave as if they had been executed within |
| 977 | the main block. So will C<next>, but since it will execute a C<continue> |
| 978 | block, it may be more entertaining. |
| 979 | |
| 980 | while (EXPR) { |
| 981 | ### redo always comes here |
| 982 | do_something; |
| 983 | } continue { |
| 984 | ### next always comes here |
| 985 | do_something_else; |
| 986 | # then back the top to re-check EXPR |
| 987 | } |
| 988 | ### last always comes here |
| 989 | |
| 990 | Omitting the C<continue> section is equivalent to using an |
| 991 | empty one, logically enough, so C<next> goes directly back |
| 992 | to check the condition at the top of the loop. |
| 993 | |
| 994 | If the C<"switch"> feature is enabled, C<continue> is also a function that |
| 995 | falls through the current C<when> or C<default> block instead of iterating |
| 996 | a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>. |
| 997 | See L<feature> and L<perlsyn/"Switch statements"> for more |
| 998 | information. |
| 999 | |
| 1000 | =item cos EXPR |
| 1001 | X<cos> X<cosine> X<acos> X<arccosine> |
| 1002 | |
| 1003 | =item cos |
| 1004 | |
| 1005 | Returns the cosine of EXPR (expressed in radians). If EXPR is omitted, |
| 1006 | takes the cosine of C<$_>. |
| 1007 | |
| 1008 | For the inverse cosine operation, you may use the C<Math::Trig::acos()> |
| 1009 | function, or use this relation: |
| 1010 | |
| 1011 | sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) } |
| 1012 | |
| 1013 | =item crypt PLAINTEXT,SALT |
| 1014 | X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password> |
| 1015 | X<decrypt> X<cryptography> X<passwd> X<encrypt> |
| 1016 | |
| 1017 | Creates a digest string exactly like the crypt(3) function in the C |
| 1018 | library (assuming that you actually have a version there that has not |
| 1019 | been extirpated as a potential munition). |
| 1020 | |
| 1021 | crypt() is a one-way hash function. The PLAINTEXT and SALT are turned |
| 1022 | into a short string, called a digest, which is returned. The same |
| 1023 | PLAINTEXT and SALT will always return the same string, but there is no |
| 1024 | (known) way to get the original PLAINTEXT from the hash. Small |
| 1025 | changes in the PLAINTEXT or SALT will result in large changes in the |
| 1026 | digest. |
| 1027 | |
| 1028 | There is no decrypt function. This function isn't all that useful for |
| 1029 | cryptography (for that, look for F<Crypt> modules on your nearby CPAN |
| 1030 | mirror) and the name "crypt" is a bit of a misnomer. Instead it is |
| 1031 | primarily used to check if two pieces of text are the same without |
| 1032 | having to transmit or store the text itself. An example is checking |
| 1033 | if a correct password is given. The digest of the password is stored, |
| 1034 | not the password itself. The user types in a password that is |
| 1035 | crypt()'d with the same salt as the stored digest. If the two digests |
| 1036 | match, the password is correct. |
| 1037 | |
| 1038 | When verifying an existing digest string you should use the digest as |
| 1039 | the salt (like C<crypt($plain, $digest) eq $digest>). The SALT used |
| 1040 | to create the digest is visible as part of the digest. This ensures |
| 1041 | crypt() will hash the new string with the same salt as the digest. |
| 1042 | This allows your code to work with the standard L<crypt|/crypt> and |
| 1043 | with more exotic implementations. In other words, assume |
| 1044 | nothing about the returned string itself nor about how many bytes |
| 1045 | of SALT may matter. |
| 1046 | |
| 1047 | Traditionally the result is a string of 13 bytes: two first bytes of |
| 1048 | the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only |
| 1049 | the first eight bytes of PLAINTEXT mattered. But alternative |
| 1050 | hashing schemes (like MD5), higher level security schemes (like C2), |
| 1051 | and implementations on non-Unix platforms may produce different |
| 1052 | strings. |
| 1053 | |
| 1054 | When choosing a new salt create a random two character string whose |
| 1055 | characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.', |
| 1056 | '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>). This set of |
| 1057 | characters is just a recommendation; the characters allowed in |
| 1058 | the salt depend solely on your system's crypt library, and Perl can't |
| 1059 | restrict what salts C<crypt()> accepts. |
| 1060 | |
| 1061 | Here's an example that makes sure that whoever runs this program knows |
| 1062 | their password: |
| 1063 | |
| 1064 | $pwd = (getpwuid($<))[1]; |
| 1065 | |
| 1066 | system "stty -echo"; |
| 1067 | print "Password: "; |
| 1068 | chomp($word = <STDIN>); |
| 1069 | print "\n"; |
| 1070 | system "stty echo"; |
| 1071 | |
| 1072 | if (crypt($word, $pwd) ne $pwd) { |
| 1073 | die "Sorry...\n"; |
| 1074 | } else { |
| 1075 | print "ok\n"; |
| 1076 | } |
| 1077 | |
| 1078 | Of course, typing in your own password to whoever asks you |
| 1079 | for it is unwise. |
| 1080 | |
| 1081 | The L<crypt|/crypt> function is unsuitable for hashing large quantities |
| 1082 | of data, not least of all because you can't get the information |
| 1083 | back. Look at the L<Digest> module for more robust algorithms. |
| 1084 | |
| 1085 | If using crypt() on a Unicode string (which I<potentially> has |
| 1086 | characters with codepoints above 255), Perl tries to make sense |
| 1087 | of the situation by trying to downgrade (a copy of) |
| 1088 | the string back to an eight-bit byte string before calling crypt() |
| 1089 | (on that copy). If that works, good. If not, crypt() dies with |
| 1090 | C<Wide character in crypt>. |
| 1091 | |
| 1092 | =item dbmclose HASH |
| 1093 | X<dbmclose> |
| 1094 | |
| 1095 | [This function has been largely superseded by the C<untie> function.] |
| 1096 | |
| 1097 | Breaks the binding between a DBM file and a hash. |
| 1098 | |
| 1099 | =item dbmopen HASH,DBNAME,MASK |
| 1100 | X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm> |
| 1101 | |
| 1102 | [This function has been largely superseded by the C<tie> function.] |
| 1103 | |
| 1104 | This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a |
| 1105 | hash. HASH is the name of the hash. (Unlike normal C<open>, the first |
| 1106 | argument is I<not> a filehandle, even though it looks like one). DBNAME |
| 1107 | is the name of the database (without the F<.dir> or F<.pag> extension if |
| 1108 | any). If the database does not exist, it is created with protection |
| 1109 | specified by MASK (as modified by the C<umask>). If your system supports |
| 1110 | only the older DBM functions, you may make only one C<dbmopen> call in your |
| 1111 | program. In older versions of Perl, if your system had neither DBM nor |
| 1112 | ndbm, calling C<dbmopen> produced a fatal error; it now falls back to |
| 1113 | sdbm(3). |
| 1114 | |
| 1115 | If you don't have write access to the DBM file, you can only read hash |
| 1116 | variables, not set them. If you want to test whether you can write, |
| 1117 | either use file tests or try setting a dummy hash entry inside an C<eval> |
| 1118 | to trap the error. |
| 1119 | |
| 1120 | Note that functions such as C<keys> and C<values> may return huge lists |
| 1121 | when used on large DBM files. You may prefer to use the C<each> |
| 1122 | function to iterate over large DBM files. Example: |
| 1123 | |
| 1124 | # print out history file offsets |
| 1125 | dbmopen(%HIST,'/usr/lib/news/history',0666); |
| 1126 | while (($key,$val) = each %HIST) { |
| 1127 | print $key, ' = ', unpack('L',$val), "\n"; |
| 1128 | } |
| 1129 | dbmclose(%HIST); |
| 1130 | |
| 1131 | See also L<AnyDBM_File> for a more general description of the pros and |
| 1132 | cons of the various dbm approaches, as well as L<DB_File> for a particularly |
| 1133 | rich implementation. |
| 1134 | |
| 1135 | You can control which DBM library you use by loading that library |
| 1136 | before you call dbmopen(): |
| 1137 | |
| 1138 | use DB_File; |
| 1139 | dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db") |
| 1140 | or die "Can't open netscape history file: $!"; |
| 1141 | |
| 1142 | =item default BLOCK |
| 1143 | |
| 1144 | Within a C<foreach> or a C<given>, a C<default> BLOCK acts like a C<when> |
| 1145 | that's always true. Only available after Perl 5.10, and only if the |
| 1146 | C<switch> feature has been requested. See L</when>. |
| 1147 | |
| 1148 | =item defined EXPR |
| 1149 | X<defined> X<undef> X<undefined> |
| 1150 | |
| 1151 | =item defined |
| 1152 | |
| 1153 | Returns a Boolean value telling whether EXPR has a value other than |
| 1154 | the undefined value C<undef>. If EXPR is not present, C<$_> is |
| 1155 | checked. |
| 1156 | |
| 1157 | Many operations return C<undef> to indicate failure, end of file, |
| 1158 | system error, uninitialized variable, and other exceptional |
| 1159 | conditions. This function allows you to distinguish C<undef> from |
| 1160 | other values. (A simple Boolean test will not distinguish among |
| 1161 | C<undef>, zero, the empty string, and C<"0">, which are all equally |
| 1162 | false.) Note that since C<undef> is a valid scalar, its presence |
| 1163 | doesn't I<necessarily> indicate an exceptional condition: C<pop> |
| 1164 | returns C<undef> when its argument is an empty array, I<or> when the |
| 1165 | element to return happens to be C<undef>. |
| 1166 | |
| 1167 | You may also use C<defined(&func)> to check whether subroutine C<&func> |
| 1168 | has ever been defined. The return value is unaffected by any forward |
| 1169 | declarations of C<&func>. A subroutine that is not defined |
| 1170 | may still be callable: its package may have an C<AUTOLOAD> method that |
| 1171 | makes it spring into existence the first time that it is called; see |
| 1172 | L<perlsub>. |
| 1173 | |
| 1174 | Use of C<defined> on aggregates (hashes and arrays) is deprecated. It |
| 1175 | used to report whether memory for that aggregate had ever been |
| 1176 | allocated. This behavior may disappear in future versions of Perl. |
| 1177 | You should instead use a simple test for size: |
| 1178 | |
| 1179 | if (@an_array) { print "has array elements\n" } |
| 1180 | if (%a_hash) { print "has hash members\n" } |
| 1181 | |
| 1182 | When used on a hash element, it tells you whether the value is defined, |
| 1183 | not whether the key exists in the hash. Use L</exists> for the latter |
| 1184 | purpose. |
| 1185 | |
| 1186 | Examples: |
| 1187 | |
| 1188 | print if defined $switch{D}; |
| 1189 | print "$val\n" while defined($val = pop(@ary)); |
| 1190 | die "Can't readlink $sym: $!" |
| 1191 | unless defined($value = readlink $sym); |
| 1192 | sub foo { defined &$bar ? &$bar(@_) : die "No bar"; } |
| 1193 | $debugging = 0 unless defined $debugging; |
| 1194 | |
| 1195 | Note: Many folks tend to overuse C<defined> and are then surprised to |
| 1196 | discover that the number C<0> and C<""> (the zero-length string) are, in fact, |
| 1197 | defined values. For example, if you say |
| 1198 | |
| 1199 | "ab" =~ /a(.*)b/; |
| 1200 | |
| 1201 | The pattern match succeeds and C<$1> is defined, although it |
| 1202 | matched "nothing". It didn't really fail to match anything. Rather, it |
| 1203 | matched something that happened to be zero characters long. This is all |
| 1204 | very above-board and honest. When a function returns an undefined value, |
| 1205 | it's an admission that it couldn't give you an honest answer. So you |
| 1206 | should use C<defined> only when questioning the integrity of what |
| 1207 | you're trying to do. At other times, a simple comparison to C<0> or C<""> is |
| 1208 | what you want. |
| 1209 | |
| 1210 | See also L</undef>, L</exists>, L</ref>. |
| 1211 | |
| 1212 | =item delete EXPR |
| 1213 | X<delete> |
| 1214 | |
| 1215 | Given an expression that specifies an element or slice of a hash, C<delete> |
| 1216 | deletes the specified elements from that hash so that exists() on that element |
| 1217 | no longer returns true. Setting a hash element to the undefined value does |
| 1218 | not remove its key, but deleting it does; see L</exists>. |
| 1219 | |
| 1220 | In list context, returns the value or values deleted, or the last such |
| 1221 | element in scalar context. The return list's length always matches that of |
| 1222 | the argument list: deleting non-existent elements returns the undefined value |
| 1223 | in their corresponding positions. |
| 1224 | |
| 1225 | delete() may also be used on arrays and array slices, but its behavior is less |
| 1226 | straightforward. Although exists() will return false for deleted entries, |
| 1227 | deleting array elements never changes indices of existing values; use shift() |
| 1228 | or splice() for that. However, if all deleted elements fall at the end of an |
| 1229 | array, the array's size shrinks to the position of the highest element that |
| 1230 | still tests true for exists(), or to 0 if none do. |
| 1231 | |
| 1232 | B<WARNING:> Calling delete on array values is deprecated and likely to |
| 1233 | be removed in a future version of Perl. |
| 1234 | |
| 1235 | Deleting from C<%ENV> modifies the environment. Deleting from a hash tied to |
| 1236 | a DBM file deletes the entry from the DBM file. Deleting from a C<tied> hash |
| 1237 | or array may not necessarily return anything; it depends on the implementation |
| 1238 | of the C<tied> package's DELETE method, which may do whatever it pleases. |
| 1239 | |
| 1240 | The C<delete local EXPR> construct localizes the deletion to the current |
| 1241 | block at run time. Until the block exits, elements locally deleted |
| 1242 | temporarily no longer exist. See L<perlsub/"Localized deletion of elements |
| 1243 | of composite types">. |
| 1244 | |
| 1245 | %hash = (foo => 11, bar => 22, baz => 33); |
| 1246 | $scalar = delete $hash{foo}; # $scalar is 11 |
| 1247 | $scalar = delete @hash{qw(foo bar)}; # $scalar is 22 |
| 1248 | @array = delete @hash{qw(foo bar baz)}; # @array is (undef,undef,33) |
| 1249 | |
| 1250 | The following (inefficiently) deletes all the values of %HASH and @ARRAY: |
| 1251 | |
| 1252 | foreach $key (keys %HASH) { |
| 1253 | delete $HASH{$key}; |
| 1254 | } |
| 1255 | |
| 1256 | foreach $index (0 .. $#ARRAY) { |
| 1257 | delete $ARRAY[$index]; |
| 1258 | } |
| 1259 | |
| 1260 | And so do these: |
| 1261 | |
| 1262 | delete @HASH{keys %HASH}; |
| 1263 | |
| 1264 | delete @ARRAY[0 .. $#ARRAY]; |
| 1265 | |
| 1266 | But both are slower than assigning the empty list |
| 1267 | or undefining %HASH or @ARRAY, which is the customary |
| 1268 | way to empty out an aggregate: |
| 1269 | |
| 1270 | %HASH = (); # completely empty %HASH |
| 1271 | undef %HASH; # forget %HASH ever existed |
| 1272 | |
| 1273 | @ARRAY = (); # completely empty @ARRAY |
| 1274 | undef @ARRAY; # forget @ARRAY ever existed |
| 1275 | |
| 1276 | The EXPR can be arbitrarily complicated provided its |
| 1277 | final operation is an element or slice of an aggregate: |
| 1278 | |
| 1279 | delete $ref->[$x][$y]{$key}; |
| 1280 | delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys}; |
| 1281 | |
| 1282 | delete $ref->[$x][$y][$index]; |
| 1283 | delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices]; |
| 1284 | |
| 1285 | =item die LIST |
| 1286 | X<die> X<throw> X<exception> X<raise> X<$@> X<abort> |
| 1287 | |
| 1288 | C<die> raises an exception. Inside an C<eval> the error message is stuffed |
| 1289 | into C<$@> and the C<eval> is terminated with the undefined value. |
| 1290 | If the exception is outside of all enclosing C<eval>s, then the uncaught |
| 1291 | exception prints LIST to C<STDERR> and exits with a non-zero value. If you |
| 1292 | need to exit the process with a specific exit code, see L</exit>. |
| 1293 | |
| 1294 | Equivalent examples: |
| 1295 | |
| 1296 | die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news'; |
| 1297 | chdir '/usr/spool/news' or die "Can't cd to spool: $!\n" |
| 1298 | |
| 1299 | If the last element of LIST does not end in a newline, the current |
| 1300 | script line number and input line number (if any) are also printed, |
| 1301 | and a newline is supplied. Note that the "input line number" (also |
| 1302 | known as "chunk") is subject to whatever notion of "line" happens to |
| 1303 | be currently in effect, and is also available as the special variable |
| 1304 | C<$.>. See L<perlvar/"$/"> and L<perlvar/"$.">. |
| 1305 | |
| 1306 | Hint: sometimes appending C<", stopped"> to your message will cause it |
| 1307 | to make better sense when the string C<"at foo line 123"> is appended. |
| 1308 | Suppose you are running script "canasta". |
| 1309 | |
| 1310 | die "/etc/games is no good"; |
| 1311 | die "/etc/games is no good, stopped"; |
| 1312 | |
| 1313 | produce, respectively |
| 1314 | |
| 1315 | /etc/games is no good at canasta line 123. |
| 1316 | /etc/games is no good, stopped at canasta line 123. |
| 1317 | |
| 1318 | If the output is empty and C<$@> already contains a value (typically from a |
| 1319 | previous eval) that value is reused after appending C<"\t...propagated">. |
| 1320 | This is useful for propagating exceptions: |
| 1321 | |
| 1322 | eval { ... }; |
| 1323 | die unless $@ =~ /Expected exception/; |
| 1324 | |
| 1325 | If the output is empty and C<$@> contains an object reference that has a |
| 1326 | C<PROPAGATE> method, that method will be called with additional file |
| 1327 | and line number parameters. The return value replaces the value in |
| 1328 | C<$@>; i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >> |
| 1329 | were called. |
| 1330 | |
| 1331 | If C<$@> is empty then the string C<"Died"> is used. |
| 1332 | |
| 1333 | If an uncaught exception results in interpreter exit, the exit code is |
| 1334 | determined from the values of C<$!> and C<$?> with this pseudocode: |
| 1335 | |
| 1336 | exit $! if $!; # errno |
| 1337 | exit $? >> 8 if $? >> 8; # child exit status |
| 1338 | exit 255; # last resort |
| 1339 | |
| 1340 | The intent is to squeeze as much possible information about the likely cause |
| 1341 | into the limited space of the system exit code. However, as C<$!> is the value |
| 1342 | of C's C<errno>, which can be set by any system call, this means that the value |
| 1343 | of the exit code used by C<die> can be non-predictable, so should not be relied |
| 1344 | upon, other than to be non-zero. |
| 1345 | |
| 1346 | You can also call C<die> with a reference argument, and if this is trapped |
| 1347 | within an C<eval>, C<$@> contains that reference. This permits more |
| 1348 | elaborate exception handling using objects that maintain arbitrary state |
| 1349 | about the exception. Such a scheme is sometimes preferable to matching |
| 1350 | particular string values of C<$@> with regular expressions. Because C<$@> |
| 1351 | is a global variable and C<eval> may be used within object implementations, |
| 1352 | be careful that analyzing the error object doesn't replace the reference in |
| 1353 | the global variable. It's easiest to make a local copy of the reference |
| 1354 | before any manipulations. Here's an example: |
| 1355 | |
| 1356 | use Scalar::Util "blessed"; |
| 1357 | |
| 1358 | eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) }; |
| 1359 | if (my $ev_err = $@) { |
| 1360 | if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) { |
| 1361 | # handle Some::Module::Exception |
| 1362 | } |
| 1363 | else { |
| 1364 | # handle all other possible exceptions |
| 1365 | } |
| 1366 | } |
| 1367 | |
| 1368 | Because Perl stringifies uncaught exception messages before display, |
| 1369 | you'll probably want to overload stringification operations on |
| 1370 | exception objects. See L<overload> for details about that. |
| 1371 | |
| 1372 | You can arrange for a callback to be run just before the C<die> |
| 1373 | does its deed, by setting the C<$SIG{__DIE__}> hook. The associated |
| 1374 | handler is called with the error text and can change the error |
| 1375 | message, if it sees fit, by calling C<die> again. See |
| 1376 | L<perlvar/%SIG> for details on setting C<%SIG> entries, and |
| 1377 | L<"eval BLOCK"> for some examples. Although this feature was |
| 1378 | to be run only right before your program was to exit, this is not |
| 1379 | currently so: the C<$SIG{__DIE__}> hook is currently called |
| 1380 | even inside eval()ed blocks/strings! If one wants the hook to do |
| 1381 | nothing in such situations, put |
| 1382 | |
| 1383 | die @_ if $^S; |
| 1384 | |
| 1385 | as the first line of the handler (see L<perlvar/$^S>). Because |
| 1386 | this promotes strange action at a distance, this counterintuitive |
| 1387 | behavior may be fixed in a future release. |
| 1388 | |
| 1389 | See also exit(), warn(), and the Carp module. |
| 1390 | |
| 1391 | =item do BLOCK |
| 1392 | X<do> X<block> |
| 1393 | |
| 1394 | Not really a function. Returns the value of the last command in the |
| 1395 | sequence of commands indicated by BLOCK. When modified by the C<while> or |
| 1396 | C<until> loop modifier, executes the BLOCK once before testing the loop |
| 1397 | condition. (On other statements the loop modifiers test the conditional |
| 1398 | first.) |
| 1399 | |
| 1400 | C<do BLOCK> does I<not> count as a loop, so the loop control statements |
| 1401 | C<next>, C<last>, or C<redo> cannot be used to leave or restart the block. |
| 1402 | See L<perlsyn> for alternative strategies. |
| 1403 | |
| 1404 | =item do SUBROUTINE(LIST) |
| 1405 | X<do> |
| 1406 | |
| 1407 | This form of subroutine call is deprecated. SUBROUTINE can be a bareword, |
| 1408 | a scalar variable or a subroutine beginning with C<&>. |
| 1409 | |
| 1410 | =item do EXPR |
| 1411 | X<do> |
| 1412 | |
| 1413 | Uses the value of EXPR as a filename and executes the contents of the |
| 1414 | file as a Perl script. |
| 1415 | |
| 1416 | do 'stat.pl'; |
| 1417 | |
| 1418 | is just like |
| 1419 | |
| 1420 | eval `cat stat.pl`; |
| 1421 | |
| 1422 | except that it's more efficient and concise, keeps track of the current |
| 1423 | filename for error messages, searches the C<@INC> directories, and updates |
| 1424 | C<%INC> if the file is found. See L<perlvar/@INC> and L<perlvar/%INC> for |
| 1425 | these variables. It also differs in that code evaluated with C<do FILENAME> |
| 1426 | cannot see lexicals in the enclosing scope; C<eval STRING> does. It's the |
| 1427 | same, however, in that it does reparse the file every time you call it, |
| 1428 | so you probably don't want to do this inside a loop. |
| 1429 | |
| 1430 | If C<do> can read the file but cannot compile it, it returns C<undef> and sets |
| 1431 | an error message in C<$@>. If C<do> cannot read the file, it returns undef |
| 1432 | and sets C<$!> to the error. Always check C<$@> first, as compilation |
| 1433 | could fail in a way that also sets C<$!>. If the file is successfully |
| 1434 | compiled, C<do> returns the value of the last expression evaluated. |
| 1435 | |
| 1436 | Inclusion of library modules is better done with the |
| 1437 | C<use> and C<require> operators, which also do automatic error checking |
| 1438 | and raise an exception if there's a problem. |
| 1439 | |
| 1440 | You might like to use C<do> to read in a program configuration |
| 1441 | file. Manual error checking can be done this way: |
| 1442 | |
| 1443 | # read in config files: system first, then user |
| 1444 | for $file ("/share/prog/defaults.rc", |
| 1445 | "$ENV{HOME}/.someprogrc") |
| 1446 | { |
| 1447 | unless ($return = do $file) { |
| 1448 | warn "couldn't parse $file: $@" if $@; |
| 1449 | warn "couldn't do $file: $!" unless defined $return; |
| 1450 | warn "couldn't run $file" unless $return; |
| 1451 | } |
| 1452 | } |
| 1453 | |
| 1454 | =item dump LABEL |
| 1455 | X<dump> X<core> X<undump> |
| 1456 | |
| 1457 | =item dump |
| 1458 | |
| 1459 | This function causes an immediate core dump. See also the B<-u> |
| 1460 | command-line switch in L<perlrun>, which does the same thing. |
| 1461 | Primarily this is so that you can use the B<undump> program (not |
| 1462 | supplied) to turn your core dump into an executable binary after |
| 1463 | having initialized all your variables at the beginning of the |
| 1464 | program. When the new binary is executed it will begin by executing |
| 1465 | a C<goto LABEL> (with all the restrictions that C<goto> suffers). |
| 1466 | Think of it as a goto with an intervening core dump and reincarnation. |
| 1467 | If C<LABEL> is omitted, restarts the program from the top. |
| 1468 | |
| 1469 | B<WARNING>: Any files opened at the time of the dump will I<not> |
| 1470 | be open any more when the program is reincarnated, with possible |
| 1471 | resulting confusion by Perl. |
| 1472 | |
| 1473 | This function is now largely obsolete, mostly because it's very hard to |
| 1474 | convert a core file into an executable. That's why you should now invoke |
| 1475 | it as C<CORE::dump()>, if you don't want to be warned against a possible |
| 1476 | typo. |
| 1477 | |
| 1478 | =item each HASH |
| 1479 | X<each> X<hash, iterator> |
| 1480 | |
| 1481 | =item each ARRAY |
| 1482 | X<array, iterator> |
| 1483 | |
| 1484 | =item each EXPR |
| 1485 | |
| 1486 | When called in list context, returns a 2-element list consisting of the key |
| 1487 | and value for the next element of a hash, or the index and value for the |
| 1488 | next element of an array, so that you can iterate over it. When called in |
| 1489 | scalar context, returns only the key (not the value) in a hash, or the index |
| 1490 | in an array. |
| 1491 | |
| 1492 | Hash entries are returned in an apparently random order. The actual random |
| 1493 | order is subject to change in future versions of Perl, but it is |
| 1494 | guaranteed to be in the same order as either the C<keys> or C<values> |
| 1495 | function would produce on the same (unmodified) hash. Since Perl |
| 1496 | 5.8.2 the ordering can be different even between different runs of Perl |
| 1497 | for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">). |
| 1498 | |
| 1499 | After C<each> has returned all entries from the hash or array, the next |
| 1500 | call to C<each> returns the empty list in list context and C<undef> in |
| 1501 | scalar context. The next call following that one restarts iteration. Each |
| 1502 | hash or array has its own internal iterator, accessed by C<each>, C<keys>, |
| 1503 | and C<values>. The iterator is implicitly reset when C<each> has reached |
| 1504 | the end as just described; it can be explicitly reset by calling C<keys> or |
| 1505 | C<values> on the hash or array. If you add or delete a hash's elements |
| 1506 | while iterating over it, entries may be skipped or duplicated--so don't do |
| 1507 | that. Exception: It is always safe to delete the item most recently |
| 1508 | returned by C<each()>, so the following code works properly: |
| 1509 | |
| 1510 | while (($key, $value) = each %hash) { |
| 1511 | print $key, "\n"; |
| 1512 | delete $hash{$key}; # This is safe |
| 1513 | } |
| 1514 | |
| 1515 | This prints out your environment like the printenv(1) program, |
| 1516 | but in a different order: |
| 1517 | |
| 1518 | while (($key,$value) = each %ENV) { |
| 1519 | print "$key=$value\n"; |
| 1520 | } |
| 1521 | |
| 1522 | Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold |
| 1523 | reference to an unblessed hash or array. The argument will be dereferenced |
| 1524 | automatically. This aspect of C<each> is considered highly experimental. |
| 1525 | The exact behaviour may change in a future version of Perl. |
| 1526 | |
| 1527 | while (($key,$value) = each $hashref) { ... } |
| 1528 | |
| 1529 | See also C<keys>, C<values>, and C<sort>. |
| 1530 | |
| 1531 | =item eof FILEHANDLE |
| 1532 | X<eof> |
| 1533 | X<end of file> |
| 1534 | X<end-of-file> |
| 1535 | |
| 1536 | =item eof () |
| 1537 | |
| 1538 | =item eof |
| 1539 | |
| 1540 | Returns 1 if the next read on FILEHANDLE will return end of file I<or> if |
| 1541 | FILEHANDLE is not open. FILEHANDLE may be an expression whose value |
| 1542 | gives the real filehandle. (Note that this function actually |
| 1543 | reads a character and then C<ungetc>s it, so isn't useful in an |
| 1544 | interactive context.) Do not read from a terminal file (or call |
| 1545 | C<eof(FILEHANDLE)> on it) after end-of-file is reached. File types such |
| 1546 | as terminals may lose the end-of-file condition if you do. |
| 1547 | |
| 1548 | An C<eof> without an argument uses the last file read. Using C<eof()> |
| 1549 | with empty parentheses is different. It refers to the pseudo file |
| 1550 | formed from the files listed on the command line and accessed via the |
| 1551 | C<< <> >> operator. Since C<< <> >> isn't explicitly opened, |
| 1552 | as a normal filehandle is, an C<eof()> before C<< <> >> has been |
| 1553 | used will cause C<@ARGV> to be examined to determine if input is |
| 1554 | available. Similarly, an C<eof()> after C<< <> >> has returned |
| 1555 | end-of-file will assume you are processing another C<@ARGV> list, |
| 1556 | and if you haven't set C<@ARGV>, will read input from C<STDIN>; |
| 1557 | see L<perlop/"I/O Operators">. |
| 1558 | |
| 1559 | In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to |
| 1560 | detect the end of each file, whereas C<eof()> will detect the end |
| 1561 | of the very last file only. Examples: |
| 1562 | |
| 1563 | # reset line numbering on each input file |
| 1564 | while (<>) { |
| 1565 | next if /^\s*#/; # skip comments |
| 1566 | print "$.\t$_"; |
| 1567 | } continue { |
| 1568 | close ARGV if eof; # Not eof()! |
| 1569 | } |
| 1570 | |
| 1571 | # insert dashes just before last line of last file |
| 1572 | while (<>) { |
| 1573 | if (eof()) { # check for end of last file |
| 1574 | print "--------------\n"; |
| 1575 | } |
| 1576 | print; |
| 1577 | last if eof(); # needed if we're reading from a terminal |
| 1578 | } |
| 1579 | |
| 1580 | Practical hint: you almost never need to use C<eof> in Perl, because the |
| 1581 | input operators typically return C<undef> when they run out of data or |
| 1582 | encounter an error. |
| 1583 | |
| 1584 | =item eval EXPR |
| 1585 | X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute> |
| 1586 | X<error, handling> X<exception, handling> |
| 1587 | |
| 1588 | =item eval BLOCK |
| 1589 | |
| 1590 | =item eval |
| 1591 | |
| 1592 | In the first form, the return value of EXPR is parsed and executed as if it |
| 1593 | were a little Perl program. The value of the expression (which is itself |
| 1594 | determined within scalar context) is first parsed, and if there were no |
| 1595 | errors, executed as a block within the lexical context of the current Perl |
| 1596 | program. This means, that in particular, any outer lexical variables are |
| 1597 | visible to it, and any package variable settings or subroutine and format |
| 1598 | definitions remain afterwards. |
| 1599 | |
| 1600 | Note that the value is parsed every time the C<eval> executes. |
| 1601 | If EXPR is omitted, evaluates C<$_>. This form is typically used to |
| 1602 | delay parsing and subsequent execution of the text of EXPR until run time. |
| 1603 | |
| 1604 | In the second form, the code within the BLOCK is parsed only once--at the |
| 1605 | same time the code surrounding the C<eval> itself was parsed--and executed |
| 1606 | within the context of the current Perl program. This form is typically |
| 1607 | used to trap exceptions more efficiently than the first (see below), while |
| 1608 | also providing the benefit of checking the code within BLOCK at compile |
| 1609 | time. |
| 1610 | |
| 1611 | The final semicolon, if any, may be omitted from the value of EXPR or within |
| 1612 | the BLOCK. |
| 1613 | |
| 1614 | In both forms, the value returned is the value of the last expression |
| 1615 | evaluated inside the mini-program; a return statement may be also used, just |
| 1616 | as with subroutines. The expression providing the return value is evaluated |
| 1617 | in void, scalar, or list context, depending on the context of the C<eval> |
| 1618 | itself. See L</wantarray> for more on how the evaluation context can be |
| 1619 | determined. |
| 1620 | |
| 1621 | If there is a syntax error or runtime error, or a C<die> statement is |
| 1622 | executed, C<eval> returns C<undef> in scalar context |
| 1623 | or an empty list--or, for syntax errors, a list containing a single |
| 1624 | undefined value--in list context, and C<$@> is set to the error |
| 1625 | message. The discrepancy in the return values in list context is |
| 1626 | considered a bug by some, and will probably be fixed in a future |
| 1627 | release. If there was no error, C<$@> is guaranteed to be the empty |
| 1628 | string. Beware that using C<eval> neither silences Perl from printing |
| 1629 | warnings to STDERR, nor does it stuff the text of warning messages into C<$@>. |
| 1630 | To do either of those, you have to use the C<$SIG{__WARN__}> facility, or |
| 1631 | turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>. |
| 1632 | See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>. |
| 1633 | |
| 1634 | Note that, because C<eval> traps otherwise-fatal errors, it is useful for |
| 1635 | determining whether a particular feature (such as C<socket> or C<symlink>) |
| 1636 | is implemented. It is also Perl's exception-trapping mechanism, where |
| 1637 | the die operator is used to raise exceptions. |
| 1638 | |
| 1639 | If you want to trap errors when loading an XS module, some problems with |
| 1640 | the binary interface (such as Perl version skew) may be fatal even with |
| 1641 | C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set. See L<perlrun>. |
| 1642 | |
| 1643 | If the code to be executed doesn't vary, you may use the eval-BLOCK |
| 1644 | form to trap run-time errors without incurring the penalty of |
| 1645 | recompiling each time. The error, if any, is still returned in C<$@>. |
| 1646 | Examples: |
| 1647 | |
| 1648 | # make divide-by-zero nonfatal |
| 1649 | eval { $answer = $a / $b; }; warn $@ if $@; |
| 1650 | |
| 1651 | # same thing, but less efficient |
| 1652 | eval '$answer = $a / $b'; warn $@ if $@; |
| 1653 | |
| 1654 | # a compile-time error |
| 1655 | eval { $answer = }; # WRONG |
| 1656 | |
| 1657 | # a run-time error |
| 1658 | eval '$answer ='; # sets $@ |
| 1659 | |
| 1660 | Using the C<eval{}> form as an exception trap in libraries does have some |
| 1661 | issues. Due to the current arguably broken state of C<__DIE__> hooks, you |
| 1662 | may wish not to trigger any C<__DIE__> hooks that user code may have installed. |
| 1663 | You can use the C<local $SIG{__DIE__}> construct for this purpose, |
| 1664 | as this example shows: |
| 1665 | |
| 1666 | # a private exception trap for divide-by-zero |
| 1667 | eval { local $SIG{'__DIE__'}; $answer = $a / $b; }; |
| 1668 | warn $@ if $@; |
| 1669 | |
| 1670 | This is especially significant, given that C<__DIE__> hooks can call |
| 1671 | C<die> again, which has the effect of changing their error messages: |
| 1672 | |
| 1673 | # __DIE__ hooks may modify error messages |
| 1674 | { |
| 1675 | local $SIG{'__DIE__'} = |
| 1676 | sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x }; |
| 1677 | eval { die "foo lives here" }; |
| 1678 | print $@ if $@; # prints "bar lives here" |
| 1679 | } |
| 1680 | |
| 1681 | Because this promotes action at a distance, this counterintuitive behavior |
| 1682 | may be fixed in a future release. |
| 1683 | |
| 1684 | With an C<eval>, you should be especially careful to remember what's |
| 1685 | being looked at when: |
| 1686 | |
| 1687 | eval $x; # CASE 1 |
| 1688 | eval "$x"; # CASE 2 |
| 1689 | |
| 1690 | eval '$x'; # CASE 3 |
| 1691 | eval { $x }; # CASE 4 |
| 1692 | |
| 1693 | eval "\$$x++"; # CASE 5 |
| 1694 | $$x++; # CASE 6 |
| 1695 | |
| 1696 | Cases 1 and 2 above behave identically: they run the code contained in |
| 1697 | the variable $x. (Although case 2 has misleading double quotes making |
| 1698 | the reader wonder what else might be happening (nothing is).) Cases 3 |
| 1699 | and 4 likewise behave in the same way: they run the code C<'$x'>, which |
| 1700 | does nothing but return the value of $x. (Case 4 is preferred for |
| 1701 | purely visual reasons, but it also has the advantage of compiling at |
| 1702 | compile-time instead of at run-time.) Case 5 is a place where |
| 1703 | normally you I<would> like to use double quotes, except that in this |
| 1704 | particular situation, you can just use symbolic references instead, as |
| 1705 | in case 6. |
| 1706 | |
| 1707 | Before Perl 5.14, the assignment to C<$@> occurred before restoration |
| 1708 | of localised variables, which means that for your code to run on older |
| 1709 | versions, a temporary is required if you want to mask some but not all |
| 1710 | errors: |
| 1711 | |
| 1712 | # alter $@ on nefarious repugnancy only |
| 1713 | { |
| 1714 | my $e; |
| 1715 | { |
| 1716 | local $@; # protect existing $@ |
| 1717 | eval { test_repugnancy() }; |
| 1718 | # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only |
| 1719 | $@ =~ /nefarious/ and $e = $@; |
| 1720 | } |
| 1721 | die $e if defined $e |
| 1722 | } |
| 1723 | |
| 1724 | C<eval BLOCK> does I<not> count as a loop, so the loop control statements |
| 1725 | C<next>, C<last>, or C<redo> cannot be used to leave or restart the block. |
| 1726 | |
| 1727 | An C<eval ''> executed within the C<DB> package doesn't see the usual |
| 1728 | surrounding lexical scope, but rather the scope of the first non-DB piece |
| 1729 | of code that called it. You don't normally need to worry about this unless |
| 1730 | you are writing a Perl debugger. |
| 1731 | |
| 1732 | =item exec LIST |
| 1733 | X<exec> X<execute> |
| 1734 | |
| 1735 | =item exec PROGRAM LIST |
| 1736 | |
| 1737 | The C<exec> function executes a system command I<and never returns>; |
| 1738 | use C<system> instead of C<exec> if you want it to return. It fails and |
| 1739 | returns false only if the command does not exist I<and> it is executed |
| 1740 | directly instead of via your system's command shell (see below). |
| 1741 | |
| 1742 | Since it's a common mistake to use C<exec> instead of C<system>, Perl |
| 1743 | warns you if there is a following statement that isn't C<die>, C<warn>, |
| 1744 | or C<exit> (if C<-w> is set--but you always do that, right?). If you |
| 1745 | I<really> want to follow an C<exec> with some other statement, you |
| 1746 | can use one of these styles to avoid the warning: |
| 1747 | |
| 1748 | exec ('foo') or print STDERR "couldn't exec foo: $!"; |
| 1749 | { exec ('foo') }; print STDERR "couldn't exec foo: $!"; |
| 1750 | |
| 1751 | If there is more than one argument in LIST, or if LIST is an array |
| 1752 | with more than one value, calls execvp(3) with the arguments in LIST. |
| 1753 | If there is only one scalar argument or an array with one element in it, |
| 1754 | the argument is checked for shell metacharacters, and if there are any, |
| 1755 | the entire argument is passed to the system's command shell for parsing |
| 1756 | (this is C</bin/sh -c> on Unix platforms, but varies on other platforms). |
| 1757 | If there are no shell metacharacters in the argument, it is split into |
| 1758 | words and passed directly to C<execvp>, which is more efficient. |
| 1759 | Examples: |
| 1760 | |
| 1761 | exec '/bin/echo', 'Your arguments are: ', @ARGV; |
| 1762 | exec "sort $outfile | uniq"; |
| 1763 | |
| 1764 | If you don't really want to execute the first argument, but want to lie |
| 1765 | to the program you are executing about its own name, you can specify |
| 1766 | the program you actually want to run as an "indirect object" (without a |
| 1767 | comma) in front of the LIST. (This always forces interpretation of the |
| 1768 | LIST as a multivalued list, even if there is only a single scalar in |
| 1769 | the list.) Example: |
| 1770 | |
| 1771 | $shell = '/bin/csh'; |
| 1772 | exec $shell '-sh'; # pretend it's a login shell |
| 1773 | |
| 1774 | or, more directly, |
| 1775 | |
| 1776 | exec {'/bin/csh'} '-sh'; # pretend it's a login shell |
| 1777 | |
| 1778 | When the arguments get executed via the system shell, results are |
| 1779 | subject to its quirks and capabilities. See L<perlop/"`STRING`"> |
| 1780 | for details. |
| 1781 | |
| 1782 | Using an indirect object with C<exec> or C<system> is also more |
| 1783 | secure. This usage (which also works fine with system()) forces |
| 1784 | interpretation of the arguments as a multivalued list, even if the |
| 1785 | list had just one argument. That way you're safe from the shell |
| 1786 | expanding wildcards or splitting up words with whitespace in them. |
| 1787 | |
| 1788 | @args = ( "echo surprise" ); |
| 1789 | |
| 1790 | exec @args; # subject to shell escapes |
| 1791 | # if @args == 1 |
| 1792 | exec { $args[0] } @args; # safe even with one-arg list |
| 1793 | |
| 1794 | The first version, the one without the indirect object, ran the I<echo> |
| 1795 | program, passing it C<"surprise"> an argument. The second version didn't; |
| 1796 | it tried to run a program named I<"echo surprise">, didn't find it, and set |
| 1797 | C<$?> to a non-zero value indicating failure. |
| 1798 | |
| 1799 | Beginning with v5.6.0, Perl attempts to flush all files opened for |
| 1800 | output before the exec, but this may not be supported on some platforms |
| 1801 | (see L<perlport>). To be safe, you may need to set C<$|> ($AUTOFLUSH |
| 1802 | in English) or call the C<autoflush()> method of C<IO::Handle> on any |
| 1803 | open handles to avoid lost output. |
| 1804 | |
| 1805 | Note that C<exec> will not call your C<END> blocks, nor will it invoke |
| 1806 | C<DESTROY> methods on your objects. |
| 1807 | |
| 1808 | =item exists EXPR |
| 1809 | X<exists> X<autovivification> |
| 1810 | |
| 1811 | Given an expression that specifies an element of a hash, returns true if the |
| 1812 | specified element in the hash has ever been initialized, even if the |
| 1813 | corresponding value is undefined. |
| 1814 | |
| 1815 | print "Exists\n" if exists $hash{$key}; |
| 1816 | print "Defined\n" if defined $hash{$key}; |
| 1817 | print "True\n" if $hash{$key}; |
| 1818 | |
| 1819 | exists may also be called on array elements, but its behavior is much less |
| 1820 | obvious and is strongly tied to the use of L</delete> on arrays. B<Be aware> |
| 1821 | that calling exists on array values is deprecated and likely to be removed in |
| 1822 | a future version of Perl. |
| 1823 | |
| 1824 | print "Exists\n" if exists $array[$index]; |
| 1825 | print "Defined\n" if defined $array[$index]; |
| 1826 | print "True\n" if $array[$index]; |
| 1827 | |
| 1828 | A hash or array element can be true only if it's defined and defined only if |
| 1829 | it exists, but the reverse doesn't necessarily hold true. |
| 1830 | |
| 1831 | Given an expression that specifies the name of a subroutine, |
| 1832 | returns true if the specified subroutine has ever been declared, even |
| 1833 | if it is undefined. Mentioning a subroutine name for exists or defined |
| 1834 | does not count as declaring it. Note that a subroutine that does not |
| 1835 | exist may still be callable: its package may have an C<AUTOLOAD> |
| 1836 | method that makes it spring into existence the first time that it is |
| 1837 | called; see L<perlsub>. |
| 1838 | |
| 1839 | print "Exists\n" if exists &subroutine; |
| 1840 | print "Defined\n" if defined &subroutine; |
| 1841 | |
| 1842 | Note that the EXPR can be arbitrarily complicated as long as the final |
| 1843 | operation is a hash or array key lookup or subroutine name: |
| 1844 | |
| 1845 | if (exists $ref->{A}->{B}->{$key}) { } |
| 1846 | if (exists $hash{A}{B}{$key}) { } |
| 1847 | |
| 1848 | if (exists $ref->{A}->{B}->[$ix]) { } |
| 1849 | if (exists $hash{A}{B}[$ix]) { } |
| 1850 | |
| 1851 | if (exists &{$ref->{A}{B}{$key}}) { } |
| 1852 | |
| 1853 | Although the mostly deeply nested array or hash will not spring into |
| 1854 | existence just because its existence was tested, any intervening ones will. |
| 1855 | Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring |
| 1856 | into existence due to the existence test for the $key element above. |
| 1857 | This happens anywhere the arrow operator is used, including even here: |
| 1858 | |
| 1859 | undef $ref; |
| 1860 | if (exists $ref->{"Some key"}) { } |
| 1861 | print $ref; # prints HASH(0x80d3d5c) |
| 1862 | |
| 1863 | This surprising autovivification in what does not at first--or even |
| 1864 | second--glance appear to be an lvalue context may be fixed in a future |
| 1865 | release. |
| 1866 | |
| 1867 | Use of a subroutine call, rather than a subroutine name, as an argument |
| 1868 | to exists() is an error. |
| 1869 | |
| 1870 | exists ⊂ # OK |
| 1871 | exists &sub(); # Error |
| 1872 | |
| 1873 | =item exit EXPR |
| 1874 | X<exit> X<terminate> X<abort> |
| 1875 | |
| 1876 | =item exit |
| 1877 | |
| 1878 | Evaluates EXPR and exits immediately with that value. Example: |
| 1879 | |
| 1880 | $ans = <STDIN>; |
| 1881 | exit 0 if $ans =~ /^[Xx]/; |
| 1882 | |
| 1883 | See also C<die>. If EXPR is omitted, exits with C<0> status. The only |
| 1884 | universally recognized values for EXPR are C<0> for success and C<1> |
| 1885 | for error; other values are subject to interpretation depending on the |
| 1886 | environment in which the Perl program is running. For example, exiting |
| 1887 | 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause |
| 1888 | the mailer to return the item undelivered, but that's not true everywhere. |
| 1889 | |
| 1890 | Don't use C<exit> to abort a subroutine if there's any chance that |
| 1891 | someone might want to trap whatever error happened. Use C<die> instead, |
| 1892 | which can be trapped by an C<eval>. |
| 1893 | |
| 1894 | The exit() function does not always exit immediately. It calls any |
| 1895 | defined C<END> routines first, but these C<END> routines may not |
| 1896 | themselves abort the exit. Likewise any object destructors that need to |
| 1897 | be called are called before the real exit. C<END> routines and destructors |
| 1898 | can change the exit status by modifying C<$?>. If this is a problem, you |
| 1899 | can call C<POSIX:_exit($status)> to avoid END and destructor processing. |
| 1900 | See L<perlmod> for details. |
| 1901 | |
| 1902 | =item exp EXPR |
| 1903 | X<exp> X<exponential> X<antilog> X<antilogarithm> X<e> |
| 1904 | |
| 1905 | =item exp |
| 1906 | |
| 1907 | Returns I<e> (the natural logarithm base) to the power of EXPR. |
| 1908 | If EXPR is omitted, gives C<exp($_)>. |
| 1909 | |
| 1910 | =item fcntl FILEHANDLE,FUNCTION,SCALAR |
| 1911 | X<fcntl> |
| 1912 | |
| 1913 | Implements the fcntl(2) function. You'll probably have to say |
| 1914 | |
| 1915 | use Fcntl; |
| 1916 | |
| 1917 | first to get the correct constant definitions. Argument processing and |
| 1918 | value returned work just like C<ioctl> below. |
| 1919 | For example: |
| 1920 | |
| 1921 | use Fcntl; |
| 1922 | fcntl($filehandle, F_GETFL, $packed_return_buffer) |
| 1923 | or die "can't fcntl F_GETFL: $!"; |
| 1924 | |
| 1925 | You don't have to check for C<defined> on the return from C<fcntl>. |
| 1926 | Like C<ioctl>, it maps a C<0> return from the system call into |
| 1927 | C<"0 but true"> in Perl. This string is true in boolean context and C<0> |
| 1928 | in numeric context. It is also exempt from the normal B<-w> warnings |
| 1929 | on improper numeric conversions. |
| 1930 | |
| 1931 | Note that C<fcntl> raises an exception if used on a machine that |
| 1932 | doesn't implement fcntl(2). See the Fcntl module or your fcntl(2) |
| 1933 | manpage to learn what functions are available on your system. |
| 1934 | |
| 1935 | Here's an example of setting a filehandle named C<REMOTE> to be |
| 1936 | non-blocking at the system level. You'll have to negotiate C<$|> |
| 1937 | on your own, though. |
| 1938 | |
| 1939 | use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK); |
| 1940 | |
| 1941 | $flags = fcntl(REMOTE, F_GETFL, 0) |
| 1942 | or die "Can't get flags for the socket: $!\n"; |
| 1943 | |
| 1944 | $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK) |
| 1945 | or die "Can't set flags for the socket: $!\n"; |
| 1946 | |
| 1947 | =item fileno FILEHANDLE |
| 1948 | X<fileno> |
| 1949 | |
| 1950 | Returns the file descriptor for a filehandle, or undefined if the |
| 1951 | filehandle is not open. If there is no real file descriptor at the OS |
| 1952 | level, as can happen with filehandles connected to memory objects via |
| 1953 | C<open> with a reference for the third argument, -1 is returned. |
| 1954 | |
| 1955 | This is mainly useful for constructing |
| 1956 | bitmaps for C<select> and low-level POSIX tty-handling operations. |
| 1957 | If FILEHANDLE is an expression, the value is taken as an indirect |
| 1958 | filehandle, generally its name. |
| 1959 | |
| 1960 | You can use this to find out whether two handles refer to the |
| 1961 | same underlying descriptor: |
| 1962 | |
| 1963 | if (fileno(THIS) == fileno(THAT)) { |
| 1964 | print "THIS and THAT are dups\n"; |
| 1965 | } |
| 1966 | |
| 1967 | =item flock FILEHANDLE,OPERATION |
| 1968 | X<flock> X<lock> X<locking> |
| 1969 | |
| 1970 | Calls flock(2), or an emulation of it, on FILEHANDLE. Returns true |
| 1971 | for success, false on failure. Produces a fatal error if used on a |
| 1972 | machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3). |
| 1973 | C<flock> is Perl's portable file-locking interface, although it locks |
| 1974 | entire files only, not records. |
| 1975 | |
| 1976 | Two potentially non-obvious but traditional C<flock> semantics are |
| 1977 | that it waits indefinitely until the lock is granted, and that its locks |
| 1978 | are B<merely advisory>. Such discretionary locks are more flexible, but |
| 1979 | offer fewer guarantees. This means that programs that do not also use |
| 1980 | C<flock> may modify files locked with C<flock>. See L<perlport>, |
| 1981 | your port's specific documentation, and your system-specific local manpages |
| 1982 | for details. It's best to assume traditional behavior if you're writing |
| 1983 | portable programs. (But if you're not, you should as always feel perfectly |
| 1984 | free to write for your own system's idiosyncrasies (sometimes called |
| 1985 | "features"). Slavish adherence to portability concerns shouldn't get |
| 1986 | in the way of your getting your job done.) |
| 1987 | |
| 1988 | OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with |
| 1989 | LOCK_NB. These constants are traditionally valued 1, 2, 8 and 4, but |
| 1990 | you can use the symbolic names if you import them from the L<Fcntl> module, |
| 1991 | either individually, or as a group using the C<:flock> tag. LOCK_SH |
| 1992 | requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN |
| 1993 | releases a previously requested lock. If LOCK_NB is bitwise-or'ed with |
| 1994 | LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking |
| 1995 | waiting for the lock; check the return status to see if you got it. |
| 1996 | |
| 1997 | To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE |
| 1998 | before locking or unlocking it. |
| 1999 | |
| 2000 | Note that the emulation built with lockf(3) doesn't provide shared |
| 2001 | locks, and it requires that FILEHANDLE be open with write intent. These |
| 2002 | are the semantics that lockf(3) implements. Most if not all systems |
| 2003 | implement lockf(3) in terms of fcntl(2) locking, though, so the |
| 2004 | differing semantics shouldn't bite too many people. |
| 2005 | |
| 2006 | Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE |
| 2007 | be open with read intent to use LOCK_SH and requires that it be open |
| 2008 | with write intent to use LOCK_EX. |
| 2009 | |
| 2010 | Note also that some versions of C<flock> cannot lock things over the |
| 2011 | network; you would need to use the more system-specific C<fcntl> for |
| 2012 | that. If you like you can force Perl to ignore your system's flock(2) |
| 2013 | function, and so provide its own fcntl(2)-based emulation, by passing |
| 2014 | the switch C<-Ud_flock> to the F<Configure> program when you configure |
| 2015 | and build a new Perl. |
| 2016 | |
| 2017 | Here's a mailbox appender for BSD systems. |
| 2018 | |
| 2019 | use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants |
| 2020 | |
| 2021 | sub lock { |
| 2022 | my ($fh) = @_; |
| 2023 | flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n"; |
| 2024 | |
| 2025 | # and, in case someone appended while we were waiting... |
| 2026 | seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n"; |
| 2027 | } |
| 2028 | |
| 2029 | sub unlock { |
| 2030 | my ($fh) = @_; |
| 2031 | flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n"; |
| 2032 | } |
| 2033 | |
| 2034 | open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}") |
| 2035 | or die "Can't open mailbox: $!"; |
| 2036 | |
| 2037 | lock($mbox); |
| 2038 | print $mbox $msg,"\n\n"; |
| 2039 | unlock($mbox); |
| 2040 | |
| 2041 | On systems that support a real flock(2), locks are inherited across fork() |
| 2042 | calls, whereas those that must resort to the more capricious fcntl(2) |
| 2043 | function lose their locks, making it seriously harder to write servers. |
| 2044 | |
| 2045 | See also L<DB_File> for other flock() examples. |
| 2046 | |
| 2047 | =item fork |
| 2048 | X<fork> X<child> X<parent> |
| 2049 | |
| 2050 | Does a fork(2) system call to create a new process running the |
| 2051 | same program at the same point. It returns the child pid to the |
| 2052 | parent process, C<0> to the child process, or C<undef> if the fork is |
| 2053 | unsuccessful. File descriptors (and sometimes locks on those descriptors) |
| 2054 | are shared, while everything else is copied. On most systems supporting |
| 2055 | fork(), great care has gone into making it extremely efficient (for |
| 2056 | example, using copy-on-write technology on data pages), making it the |
| 2057 | dominant paradigm for multitasking over the last few decades. |
| 2058 | |
| 2059 | Beginning with v5.6.0, Perl attempts to flush all files opened for |
| 2060 | output before forking the child process, but this may not be supported |
| 2061 | on some platforms (see L<perlport>). To be safe, you may need to set |
| 2062 | C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of |
| 2063 | C<IO::Handle> on any open handles to avoid duplicate output. |
| 2064 | |
| 2065 | If you C<fork> without ever waiting on your children, you will |
| 2066 | accumulate zombies. On some systems, you can avoid this by setting |
| 2067 | C<$SIG{CHLD}> to C<"IGNORE">. See also L<perlipc> for more examples of |
| 2068 | forking and reaping moribund children. |
| 2069 | |
| 2070 | Note that if your forked child inherits system file descriptors like |
| 2071 | STDIN and STDOUT that are actually connected by a pipe or socket, even |
| 2072 | if you exit, then the remote server (such as, say, a CGI script or a |
| 2073 | backgrounded job launched from a remote shell) won't think you're done. |
| 2074 | You should reopen those to F</dev/null> if it's any issue. |
| 2075 | |
| 2076 | =item format |
| 2077 | X<format> |
| 2078 | |
| 2079 | Declare a picture format for use by the C<write> function. For |
| 2080 | example: |
| 2081 | |
| 2082 | format Something = |
| 2083 | Test: @<<<<<<<< @||||| @>>>>> |
| 2084 | $str, $%, '$' . int($num) |
| 2085 | . |
| 2086 | |
| 2087 | $str = "widget"; |
| 2088 | $num = $cost/$quantity; |
| 2089 | $~ = 'Something'; |
| 2090 | write; |
| 2091 | |
| 2092 | See L<perlform> for many details and examples. |
| 2093 | |
| 2094 | =item formline PICTURE,LIST |
| 2095 | X<formline> |
| 2096 | |
| 2097 | This is an internal function used by C<format>s, though you may call it, |
| 2098 | too. It formats (see L<perlform>) a list of values according to the |
| 2099 | contents of PICTURE, placing the output into the format output |
| 2100 | accumulator, C<$^A> (or C<$ACCUMULATOR> in English). |
| 2101 | Eventually, when a C<write> is done, the contents of |
| 2102 | C<$^A> are written to some filehandle. You could also read C<$^A> |
| 2103 | and then set C<$^A> back to C<"">. Note that a format typically |
| 2104 | does one C<formline> per line of form, but the C<formline> function itself |
| 2105 | doesn't care how many newlines are embedded in the PICTURE. This means |
| 2106 | that the C<~> and C<~~> tokens treat the entire PICTURE as a single line. |
| 2107 | You may therefore need to use multiple formlines to implement a single |
| 2108 | record format, just like the C<format> compiler. |
| 2109 | |
| 2110 | Be careful if you put double quotes around the picture, because an C<@> |
| 2111 | character may be taken to mean the beginning of an array name. |
| 2112 | C<formline> always returns true. See L<perlform> for other examples. |
| 2113 | |
| 2114 | If you are trying to use this instead of C<write> to capture the output, |
| 2115 | you may find it easier to open a filehandle to a scalar |
| 2116 | (C<< open $fh, ">", \$output >>) and write to that instead. |
| 2117 | |
| 2118 | =item getc FILEHANDLE |
| 2119 | X<getc> X<getchar> X<character> X<file, read> |
| 2120 | |
| 2121 | =item getc |
| 2122 | |
| 2123 | Returns the next character from the input file attached to FILEHANDLE, |
| 2124 | or the undefined value at end of file or if there was an error (in |
| 2125 | the latter case C<$!> is set). If FILEHANDLE is omitted, reads from |
| 2126 | STDIN. This is not particularly efficient. However, it cannot be |
| 2127 | used by itself to fetch single characters without waiting for the user |
| 2128 | to hit enter. For that, try something more like: |
| 2129 | |
| 2130 | if ($BSD_STYLE) { |
| 2131 | system "stty cbreak </dev/tty >/dev/tty 2>&1"; |
| 2132 | } |
| 2133 | else { |
| 2134 | system "stty", '-icanon', 'eol', "\001"; |
| 2135 | } |
| 2136 | |
| 2137 | $key = getc(STDIN); |
| 2138 | |
| 2139 | if ($BSD_STYLE) { |
| 2140 | system "stty -cbreak </dev/tty >/dev/tty 2>&1"; |
| 2141 | } |
| 2142 | else { |
| 2143 | system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL |
| 2144 | } |
| 2145 | print "\n"; |
| 2146 | |
| 2147 | Determination of whether $BSD_STYLE should be set |
| 2148 | is left as an exercise to the reader. |
| 2149 | |
| 2150 | The C<POSIX::getattr> function can do this more portably on |
| 2151 | systems purporting POSIX compliance. See also the C<Term::ReadKey> |
| 2152 | module from your nearest CPAN site; details on CPAN can be found under |
| 2153 | L<perlmodlib/CPAN>. |
| 2154 | |
| 2155 | =item getlogin |
| 2156 | X<getlogin> X<login> |
| 2157 | |
| 2158 | This implements the C library function of the same name, which on most |
| 2159 | systems returns the current login from F</etc/utmp>, if any. If it |
| 2160 | returns the empty string, use C<getpwuid>. |
| 2161 | |
| 2162 | $login = getlogin || getpwuid($<) || "Kilroy"; |
| 2163 | |
| 2164 | Do not consider C<getlogin> for authentication: it is not as |
| 2165 | secure as C<getpwuid>. |
| 2166 | |
| 2167 | =item getpeername SOCKET |
| 2168 | X<getpeername> X<peer> |
| 2169 | |
| 2170 | Returns the packed sockaddr address of the other end of the SOCKET |
| 2171 | connection. |
| 2172 | |
| 2173 | use Socket; |
| 2174 | $hersockaddr = getpeername(SOCK); |
| 2175 | ($port, $iaddr) = sockaddr_in($hersockaddr); |
| 2176 | $herhostname = gethostbyaddr($iaddr, AF_INET); |
| 2177 | $herstraddr = inet_ntoa($iaddr); |
| 2178 | |
| 2179 | =item getpgrp PID |
| 2180 | X<getpgrp> X<group> |
| 2181 | |
| 2182 | Returns the current process group for the specified PID. Use |
| 2183 | a PID of C<0> to get the current process group for the |
| 2184 | current process. Will raise an exception if used on a machine that |
| 2185 | doesn't implement getpgrp(2). If PID is omitted, returns the process |
| 2186 | group of the current process. Note that the POSIX version of C<getpgrp> |
| 2187 | does not accept a PID argument, so only C<PID==0> is truly portable. |
| 2188 | |
| 2189 | =item getppid |
| 2190 | X<getppid> X<parent> X<pid> |
| 2191 | |
| 2192 | Returns the process id of the parent process. |
| 2193 | |
| 2194 | Note for Linux users: on Linux, the C functions C<getpid()> and |
| 2195 | C<getppid()> return different values from different threads. In order to |
| 2196 | be portable, this behavior is not reflected by the Perl-level function |
| 2197 | C<getppid()>, that returns a consistent value across threads. If you want |
| 2198 | to call the underlying C<getppid()>, you may use the CPAN module |
| 2199 | C<Linux::Pid>. |
| 2200 | |
| 2201 | =item getpriority WHICH,WHO |
| 2202 | X<getpriority> X<priority> X<nice> |
| 2203 | |
| 2204 | Returns the current priority for a process, a process group, or a user. |
| 2205 | (See C<getpriority(2)>.) Will raise a fatal exception if used on a |
| 2206 | machine that doesn't implement getpriority(2). |
| 2207 | |
| 2208 | =item getpwnam NAME |
| 2209 | X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname> |
| 2210 | X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr> |
| 2211 | X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent> |
| 2212 | X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent> |
| 2213 | X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent> |
| 2214 | X<endnetent> X<endprotoent> X<endservent> |
| 2215 | |
| 2216 | =item getgrnam NAME |
| 2217 | |
| 2218 | =item gethostbyname NAME |
| 2219 | |
| 2220 | =item getnetbyname NAME |
| 2221 | |
| 2222 | =item getprotobyname NAME |
| 2223 | |
| 2224 | =item getpwuid UID |
| 2225 | |
| 2226 | =item getgrgid GID |
| 2227 | |
| 2228 | =item getservbyname NAME,PROTO |
| 2229 | |
| 2230 | =item gethostbyaddr ADDR,ADDRTYPE |
| 2231 | |
| 2232 | =item getnetbyaddr ADDR,ADDRTYPE |
| 2233 | |
| 2234 | =item getprotobynumber NUMBER |
| 2235 | |
| 2236 | =item getservbyport PORT,PROTO |
| 2237 | |
| 2238 | =item getpwent |
| 2239 | |
| 2240 | =item getgrent |
| 2241 | |
| 2242 | =item gethostent |
| 2243 | |
| 2244 | =item getnetent |
| 2245 | |
| 2246 | =item getprotoent |
| 2247 | |
| 2248 | =item getservent |
| 2249 | |
| 2250 | =item setpwent |
| 2251 | |
| 2252 | =item setgrent |
| 2253 | |
| 2254 | =item sethostent STAYOPEN |
| 2255 | |
| 2256 | =item setnetent STAYOPEN |
| 2257 | |
| 2258 | =item setprotoent STAYOPEN |
| 2259 | |
| 2260 | =item setservent STAYOPEN |
| 2261 | |
| 2262 | =item endpwent |
| 2263 | |
| 2264 | =item endgrent |
| 2265 | |
| 2266 | =item endhostent |
| 2267 | |
| 2268 | =item endnetent |
| 2269 | |
| 2270 | =item endprotoent |
| 2271 | |
| 2272 | =item endservent |
| 2273 | |
| 2274 | These routines are the same as their counterparts in the |
| 2275 | system C library. In list context, the return values from the |
| 2276 | various get routines are as follows: |
| 2277 | |
| 2278 | ($name,$passwd,$uid,$gid, |
| 2279 | $quota,$comment,$gcos,$dir,$shell,$expire) = getpw* |
| 2280 | ($name,$passwd,$gid,$members) = getgr* |
| 2281 | ($name,$aliases,$addrtype,$length,@addrs) = gethost* |
| 2282 | ($name,$aliases,$addrtype,$net) = getnet* |
| 2283 | ($name,$aliases,$proto) = getproto* |
| 2284 | ($name,$aliases,$port,$proto) = getserv* |
| 2285 | |
| 2286 | (If the entry doesn't exist you get an empty list.) |
| 2287 | |
| 2288 | The exact meaning of the $gcos field varies but it usually contains |
| 2289 | the real name of the user (as opposed to the login name) and other |
| 2290 | information pertaining to the user. Beware, however, that in many |
| 2291 | system users are able to change this information and therefore it |
| 2292 | cannot be trusted and therefore the $gcos is tainted (see |
| 2293 | L<perlsec>). The $passwd and $shell, user's encrypted password and |
| 2294 | login shell, are also tainted, for the same reason. |
| 2295 | |
| 2296 | In scalar context, you get the name, unless the function was a |
| 2297 | lookup by name, in which case you get the other thing, whatever it is. |
| 2298 | (If the entry doesn't exist you get the undefined value.) For example: |
| 2299 | |
| 2300 | $uid = getpwnam($name); |
| 2301 | $name = getpwuid($num); |
| 2302 | $name = getpwent(); |
| 2303 | $gid = getgrnam($name); |
| 2304 | $name = getgrgid($num); |
| 2305 | $name = getgrent(); |
| 2306 | #etc. |
| 2307 | |
| 2308 | In I<getpw*()> the fields $quota, $comment, and $expire are special |
| 2309 | in that they are unsupported on many systems. If the |
| 2310 | $quota is unsupported, it is an empty scalar. If it is supported, it |
| 2311 | usually encodes the disk quota. If the $comment field is unsupported, |
| 2312 | it is an empty scalar. If it is supported it usually encodes some |
| 2313 | administrative comment about the user. In some systems the $quota |
| 2314 | field may be $change or $age, fields that have to do with password |
| 2315 | aging. In some systems the $comment field may be $class. The $expire |
| 2316 | field, if present, encodes the expiration period of the account or the |
| 2317 | password. For the availability and the exact meaning of these fields |
| 2318 | in your system, please consult getpwnam(3) and your system's |
| 2319 | F<pwd.h> file. You can also find out from within Perl what your |
| 2320 | $quota and $comment fields mean and whether you have the $expire field |
| 2321 | by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>, |
| 2322 | C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>. Shadow password |
| 2323 | files are supported only if your vendor has implemented them in the |
| 2324 | intuitive fashion that calling the regular C library routines gets the |
| 2325 | shadow versions if you're running under privilege or if there exists |
| 2326 | the shadow(3) functions as found in System V (this includes Solaris |
| 2327 | and Linux). Those systems that implement a proprietary shadow password |
| 2328 | facility are unlikely to be supported. |
| 2329 | |
| 2330 | The $members value returned by I<getgr*()> is a space-separated list of |
| 2331 | the login names of the members of the group. |
| 2332 | |
| 2333 | For the I<gethost*()> functions, if the C<h_errno> variable is supported in |
| 2334 | C, it will be returned to you via C<$?> if the function call fails. The |
| 2335 | C<@addrs> value returned by a successful call is a list of raw |
| 2336 | addresses returned by the corresponding library call. In the |
| 2337 | Internet domain, each address is four bytes long; you can unpack it |
| 2338 | by saying something like: |
| 2339 | |
| 2340 | ($a,$b,$c,$d) = unpack('W4',$addr[0]); |
| 2341 | |
| 2342 | The Socket library makes this slightly easier: |
| 2343 | |
| 2344 | use Socket; |
| 2345 | $iaddr = inet_aton("127.1"); # or whatever address |
| 2346 | $name = gethostbyaddr($iaddr, AF_INET); |
| 2347 | |
| 2348 | # or going the other way |
| 2349 | $straddr = inet_ntoa($iaddr); |
| 2350 | |
| 2351 | In the opposite way, to resolve a hostname to the IP address |
| 2352 | you can write this: |
| 2353 | |
| 2354 | use Socket; |
| 2355 | $packed_ip = gethostbyname("www.perl.org"); |
| 2356 | if (defined $packed_ip) { |
| 2357 | $ip_address = inet_ntoa($packed_ip); |
| 2358 | } |
| 2359 | |
| 2360 | Make sure <gethostbyname()> is called in SCALAR context and that |
| 2361 | its return value is checked for definedness. |
| 2362 | |
| 2363 | If you get tired of remembering which element of the return list |
| 2364 | contains which return value, by-name interfaces are provided |
| 2365 | in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>, |
| 2366 | C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>, |
| 2367 | and C<User::grent>. These override the normal built-ins, supplying |
| 2368 | versions that return objects with the appropriate names |
| 2369 | for each field. For example: |
| 2370 | |
| 2371 | use File::stat; |
| 2372 | use User::pwent; |
| 2373 | $is_his = (stat($filename)->uid == pwent($whoever)->uid); |
| 2374 | |
| 2375 | Even though it looks as though they're the same method calls (uid), |
| 2376 | they aren't, because a C<File::stat> object is different from |
| 2377 | a C<User::pwent> object. |
| 2378 | |
| 2379 | =item getsockname SOCKET |
| 2380 | X<getsockname> |
| 2381 | |
| 2382 | Returns the packed sockaddr address of this end of the SOCKET connection, |
| 2383 | in case you don't know the address because you have several different |
| 2384 | IPs that the connection might have come in on. |
| 2385 | |
| 2386 | use Socket; |
| 2387 | $mysockaddr = getsockname(SOCK); |
| 2388 | ($port, $myaddr) = sockaddr_in($mysockaddr); |
| 2389 | printf "Connect to %s [%s]\n", |
| 2390 | scalar gethostbyaddr($myaddr, AF_INET), |
| 2391 | inet_ntoa($myaddr); |
| 2392 | |
| 2393 | =item getsockopt SOCKET,LEVEL,OPTNAME |
| 2394 | X<getsockopt> |
| 2395 | |
| 2396 | Queries the option named OPTNAME associated with SOCKET at a given LEVEL. |
| 2397 | Options may exist at multiple protocol levels depending on the socket |
| 2398 | type, but at least the uppermost socket level SOL_SOCKET (defined in the |
| 2399 | C<Socket> module) will exist. To query options at another level the |
| 2400 | protocol number of the appropriate protocol controlling the option |
| 2401 | should be supplied. For example, to indicate that an option is to be |
| 2402 | interpreted by the TCP protocol, LEVEL should be set to the protocol |
| 2403 | number of TCP, which you can get using C<getprotobyname>. |
| 2404 | |
| 2405 | The function returns a packed string representing the requested socket |
| 2406 | option, or C<undef> on error, with the reason for the error placed in |
| 2407 | C<$!>. Just what is in the packed string depends on LEVEL and OPTNAME; |
| 2408 | consult getsockopt(2) for details. A common case is that the option is an |
| 2409 | integer, in which case the result is a packed integer, which you can decode |
| 2410 | using C<unpack> with the C<i> (or C<I>) format. |
| 2411 | |
| 2412 | Here's an example to test whether Nagle's algorithm is enabled on a socket: |
| 2413 | |
| 2414 | use Socket qw(:all); |
| 2415 | |
| 2416 | defined(my $tcp = getprotobyname("tcp")) |
| 2417 | or die "Could not determine the protocol number for tcp"; |
| 2418 | # my $tcp = IPPROTO_TCP; # Alternative |
| 2419 | my $packed = getsockopt($socket, $tcp, TCP_NODELAY) |
| 2420 | or die "getsockopt TCP_NODELAY: $!"; |
| 2421 | my $nodelay = unpack("I", $packed); |
| 2422 | print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n"; |
| 2423 | |
| 2424 | |
| 2425 | =item given EXPR BLOCK |
| 2426 | X<given> |
| 2427 | |
| 2428 | =item given BLOCK |
| 2429 | |
| 2430 | C<given> is analogous to the C<switch> keyword in other languages. C<given> |
| 2431 | and C<when> are used in Perl to implement C<switch>/C<case> like statements. |
| 2432 | Only available after Perl 5.10. For example: |
| 2433 | |
| 2434 | use v5.10; |
| 2435 | given ($fruit) { |
| 2436 | when (/apples?/) { |
| 2437 | print "I like apples." |
| 2438 | } |
| 2439 | when (/oranges?/) { |
| 2440 | print "I don't like oranges." |
| 2441 | } |
| 2442 | default { |
| 2443 | print "I don't like anything" |
| 2444 | } |
| 2445 | } |
| 2446 | |
| 2447 | See L<perlsyn/"Switch statements"> for detailed information. |
| 2448 | |
| 2449 | =item glob EXPR |
| 2450 | X<glob> X<wildcard> X<filename, expansion> X<expand> |
| 2451 | |
| 2452 | =item glob |
| 2453 | |
| 2454 | In list context, returns a (possibly empty) list of filename expansions on |
| 2455 | the value of EXPR such as the standard Unix shell F</bin/csh> would do. In |
| 2456 | scalar context, glob iterates through such filename expansions, returning |
| 2457 | undef when the list is exhausted. This is the internal function |
| 2458 | implementing the C<< <*.c> >> operator, but you can use it directly. If |
| 2459 | EXPR is omitted, C<$_> is used. The C<< <*.c> >> operator is discussed in |
| 2460 | more detail in L<perlop/"I/O Operators">. |
| 2461 | |
| 2462 | Note that C<glob> splits its arguments on whitespace and treats |
| 2463 | each segment as separate pattern. As such, C<glob("*.c *.h")> |
| 2464 | matches all files with a F<.c> or F<.h> extension. The expression |
| 2465 | C<glob(".* *")> matches all files in the current working directory. |
| 2466 | |
| 2467 | If non-empty braces are the only wildcard characters used in the |
| 2468 | C<glob>, no filenames are matched, but potentially many strings |
| 2469 | are returned. For example, this produces nine strings, one for |
| 2470 | each pairing of fruits and colors: |
| 2471 | |
| 2472 | @many = glob "{apple,tomato,cherry}={green,yellow,red}"; |
| 2473 | |
| 2474 | Beginning with v5.6.0, this operator is implemented using the standard |
| 2475 | C<File::Glob> extension. See L<File::Glob> for details, including |
| 2476 | C<bsd_glob> which does not treat whitespace as a pattern separator. |
| 2477 | |
| 2478 | =item gmtime EXPR |
| 2479 | X<gmtime> X<UTC> X<Greenwich> |
| 2480 | |
| 2481 | =item gmtime |
| 2482 | |
| 2483 | Works just like L</localtime> but the returned values are |
| 2484 | localized for the standard Greenwich time zone. |
| 2485 | |
| 2486 | Note: When called in list context, $isdst, the last value |
| 2487 | returned by gmtime, is always C<0>. There is no |
| 2488 | Daylight Saving Time in GMT. |
| 2489 | |
| 2490 | See L<perlport/gmtime> for portability concerns. |
| 2491 | |
| 2492 | =item goto LABEL |
| 2493 | X<goto> X<jump> X<jmp> |
| 2494 | |
| 2495 | =item goto EXPR |
| 2496 | |
| 2497 | =item goto &NAME |
| 2498 | |
| 2499 | The C<goto-LABEL> form finds the statement labeled with LABEL and |
| 2500 | resumes execution there. It can't be used to get out of a block or |
| 2501 | subroutine given to C<sort>. It can be used to go almost anywhere |
| 2502 | else within the dynamic scope, including out of subroutines, but it's |
| 2503 | usually better to use some other construct such as C<last> or C<die>. |
| 2504 | The author of Perl has never felt the need to use this form of C<goto> |
| 2505 | (in Perl, that is; C is another matter). (The difference is that C |
| 2506 | does not offer named loops combined with loop control. Perl does, and |
| 2507 | this replaces most structured uses of C<goto> in other languages.) |
| 2508 | |
| 2509 | The C<goto-EXPR> form expects a label name, whose scope will be resolved |
| 2510 | dynamically. This allows for computed C<goto>s per FORTRAN, but isn't |
| 2511 | necessarily recommended if you're optimizing for maintainability: |
| 2512 | |
| 2513 | goto ("FOO", "BAR", "GLARCH")[$i]; |
| 2514 | |
| 2515 | As shown in this example, C<goto-EXPR> is exempt from the "looks like a |
| 2516 | function" rule. A pair of parentheses following it does not (necessarily) |
| 2517 | delimit its argument. C<goto("NE")."XT"> is equivalent to C<goto NEXT>. |
| 2518 | |
| 2519 | Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is |
| 2520 | deprecated and will issue a warning. Even then, it may not be used to |
| 2521 | go into any construct that requires initialization, such as a |
| 2522 | subroutine or a C<foreach> loop. It also can't be used to go into a |
| 2523 | construct that is optimized away. |
| 2524 | |
| 2525 | The C<goto-&NAME> form is quite different from the other forms of |
| 2526 | C<goto>. In fact, it isn't a goto in the normal sense at all, and |
| 2527 | doesn't have the stigma associated with other gotos. Instead, it |
| 2528 | exits the current subroutine (losing any changes set by local()) and |
| 2529 | immediately calls in its place the named subroutine using the current |
| 2530 | value of @_. This is used by C<AUTOLOAD> subroutines that wish to |
| 2531 | load another subroutine and then pretend that the other subroutine had |
| 2532 | been called in the first place (except that any modifications to C<@_> |
| 2533 | in the current subroutine are propagated to the other subroutine.) |
| 2534 | After the C<goto>, not even C<caller> will be able to tell that this |
| 2535 | routine was called first. |
| 2536 | |
| 2537 | NAME needn't be the name of a subroutine; it can be a scalar variable |
| 2538 | containing a code reference or a block that evaluates to a code |
| 2539 | reference. |
| 2540 | |
| 2541 | =item grep BLOCK LIST |
| 2542 | X<grep> |
| 2543 | |
| 2544 | =item grep EXPR,LIST |
| 2545 | |
| 2546 | This is similar in spirit to, but not the same as, grep(1) and its |
| 2547 | relatives. In particular, it is not limited to using regular expressions. |
| 2548 | |
| 2549 | Evaluates the BLOCK or EXPR for each element of LIST (locally setting |
| 2550 | C<$_> to each element) and returns the list value consisting of those |
| 2551 | elements for which the expression evaluated to true. In scalar |
| 2552 | context, returns the number of times the expression was true. |
| 2553 | |
| 2554 | @foo = grep(!/^#/, @bar); # weed out comments |
| 2555 | |
| 2556 | or equivalently, |
| 2557 | |
| 2558 | @foo = grep {!/^#/} @bar; # weed out comments |
| 2559 | |
| 2560 | Note that C<$_> is an alias to the list value, so it can be used to |
| 2561 | modify the elements of the LIST. While this is useful and supported, |
| 2562 | it can cause bizarre results if the elements of LIST are not variables. |
| 2563 | Similarly, grep returns aliases into the original list, much as a for |
| 2564 | loop's index variable aliases the list elements. That is, modifying an |
| 2565 | element of a list returned by grep (for example, in a C<foreach>, C<map> |
| 2566 | or another C<grep>) actually modifies the element in the original list. |
| 2567 | This is usually something to be avoided when writing clear code. |
| 2568 | |
| 2569 | If C<$_> is lexical in the scope where the C<grep> appears (because it has |
| 2570 | been declared with C<my $_>) then, in addition to being locally aliased to |
| 2571 | the list elements, C<$_> keeps being lexical inside the block; i.e., it |
| 2572 | can't be seen from the outside, avoiding any potential side-effects. |
| 2573 | |
| 2574 | See also L</map> for a list composed of the results of the BLOCK or EXPR. |
| 2575 | |
| 2576 | =item hex EXPR |
| 2577 | X<hex> X<hexadecimal> |
| 2578 | |
| 2579 | =item hex |
| 2580 | |
| 2581 | Interprets EXPR as a hex string and returns the corresponding value. |
| 2582 | (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see |
| 2583 | L</oct>.) If EXPR is omitted, uses C<$_>. |
| 2584 | |
| 2585 | print hex '0xAf'; # prints '175' |
| 2586 | print hex 'aF'; # same |
| 2587 | |
| 2588 | Hex strings may only represent integers. Strings that would cause |
| 2589 | integer overflow trigger a warning. Leading whitespace is not stripped, |
| 2590 | unlike oct(). To present something as hex, look into L</printf>, |
| 2591 | L</sprintf>, and L</unpack>. |
| 2592 | |
| 2593 | =item import LIST |
| 2594 | X<import> |
| 2595 | |
| 2596 | There is no builtin C<import> function. It is just an ordinary |
| 2597 | method (subroutine) defined (or inherited) by modules that wish to export |
| 2598 | names to another module. The C<use> function calls the C<import> method |
| 2599 | for the package used. See also L</use>, L<perlmod>, and L<Exporter>. |
| 2600 | |
| 2601 | =item index STR,SUBSTR,POSITION |
| 2602 | X<index> X<indexOf> X<InStr> |
| 2603 | |
| 2604 | =item index STR,SUBSTR |
| 2605 | |
| 2606 | The index function searches for one string within another, but without |
| 2607 | the wildcard-like behavior of a full regular-expression pattern match. |
| 2608 | It returns the position of the first occurrence of SUBSTR in STR at |
| 2609 | or after POSITION. If POSITION is omitted, starts searching from the |
| 2610 | beginning of the string. POSITION before the beginning of the string |
| 2611 | or after its end is treated as if it were the beginning or the end, |
| 2612 | respectively. POSITION and the return value are based at C<0> (or whatever |
| 2613 | you've set the C<$[> variable to--but don't do that). If the substring |
| 2614 | is not found, C<index> returns one less than the base, ordinarily C<-1>. |
| 2615 | |
| 2616 | =item int EXPR |
| 2617 | X<int> X<integer> X<truncate> X<trunc> X<floor> |
| 2618 | |
| 2619 | =item int |
| 2620 | |
| 2621 | Returns the integer portion of EXPR. If EXPR is omitted, uses C<$_>. |
| 2622 | You should not use this function for rounding: one because it truncates |
| 2623 | towards C<0>, and two because machine representations of floating-point |
| 2624 | numbers can sometimes produce counterintuitive results. For example, |
| 2625 | C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's |
| 2626 | because it's really more like -268.99999999999994315658 instead. Usually, |
| 2627 | the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil> |
| 2628 | functions will serve you better than will int(). |
| 2629 | |
| 2630 | =item ioctl FILEHANDLE,FUNCTION,SCALAR |
| 2631 | X<ioctl> |
| 2632 | |
| 2633 | Implements the ioctl(2) function. You'll probably first have to say |
| 2634 | |
| 2635 | require "sys/ioctl.ph"; # probably in $Config{archlib}/sys/ioctl.ph |
| 2636 | |
| 2637 | to get the correct function definitions. If F<sys/ioctl.ph> doesn't |
| 2638 | exist or doesn't have the correct definitions you'll have to roll your |
| 2639 | own, based on your C header files such as F<< <sys/ioctl.h> >>. |
| 2640 | (There is a Perl script called B<h2ph> that comes with the Perl kit that |
| 2641 | may help you in this, but it's nontrivial.) SCALAR will be read and/or |
| 2642 | written depending on the FUNCTION; a C pointer to the string value of SCALAR |
| 2643 | will be passed as the third argument of the actual C<ioctl> call. (If SCALAR |
| 2644 | has no string value but does have a numeric value, that value will be |
| 2645 | passed rather than a pointer to the string value. To guarantee this to be |
| 2646 | true, add a C<0> to the scalar before using it.) The C<pack> and C<unpack> |
| 2647 | functions may be needed to manipulate the values of structures used by |
| 2648 | C<ioctl>. |
| 2649 | |
| 2650 | The return value of C<ioctl> (and C<fcntl>) is as follows: |
| 2651 | |
| 2652 | if OS returns: then Perl returns: |
| 2653 | -1 undefined value |
| 2654 | 0 string "0 but true" |
| 2655 | anything else that number |
| 2656 | |
| 2657 | Thus Perl returns true on success and false on failure, yet you can |
| 2658 | still easily determine the actual value returned by the operating |
| 2659 | system: |
| 2660 | |
| 2661 | $retval = ioctl(...) || -1; |
| 2662 | printf "System returned %d\n", $retval; |
| 2663 | |
| 2664 | The special string C<"0 but true"> is exempt from B<-w> complaints |
| 2665 | about improper numeric conversions. |
| 2666 | |
| 2667 | =item join EXPR,LIST |
| 2668 | X<join> |
| 2669 | |
| 2670 | Joins the separate strings of LIST into a single string with fields |
| 2671 | separated by the value of EXPR, and returns that new string. Example: |
| 2672 | |
| 2673 | $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell); |
| 2674 | |
| 2675 | Beware that unlike C<split>, C<join> doesn't take a pattern as its |
| 2676 | first argument. Compare L</split>. |
| 2677 | |
| 2678 | =item keys HASH |
| 2679 | X<keys> X<key> |
| 2680 | |
| 2681 | =item keys ARRAY |
| 2682 | |
| 2683 | =item keys EXPR |
| 2684 | |
| 2685 | Returns a list consisting of all the keys of the named hash, or the indices |
| 2686 | of an array. (In scalar context, returns the number of keys or indices.) |
| 2687 | |
| 2688 | The keys of a hash are returned in an apparently random order. The actual |
| 2689 | random order is subject to change in future versions of Perl, but it |
| 2690 | is guaranteed to be the same order as either the C<values> or C<each> |
| 2691 | function produces (given that the hash has not been modified). Since |
| 2692 | Perl 5.8.1 the ordering can be different even between different runs of |
| 2693 | Perl for security reasons (see L<perlsec/"Algorithmic Complexity |
| 2694 | Attacks">). |
| 2695 | |
| 2696 | As a side effect, calling keys() resets the internal interator of the HASH or ARRAY |
| 2697 | (see L</each>). In particular, calling keys() in void context resets |
| 2698 | the iterator with no other overhead. |
| 2699 | |
| 2700 | Here is yet another way to print your environment: |
| 2701 | |
| 2702 | @keys = keys %ENV; |
| 2703 | @values = values %ENV; |
| 2704 | while (@keys) { |
| 2705 | print pop(@keys), '=', pop(@values), "\n"; |
| 2706 | } |
| 2707 | |
| 2708 | or how about sorted by key: |
| 2709 | |
| 2710 | foreach $key (sort(keys %ENV)) { |
| 2711 | print $key, '=', $ENV{$key}, "\n"; |
| 2712 | } |
| 2713 | |
| 2714 | The returned values are copies of the original keys in the hash, so |
| 2715 | modifying them will not affect the original hash. Compare L</values>. |
| 2716 | |
| 2717 | To sort a hash by value, you'll need to use a C<sort> function. |
| 2718 | Here's a descending numeric sort of a hash by its values: |
| 2719 | |
| 2720 | foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) { |
| 2721 | printf "%4d %s\n", $hash{$key}, $key; |
| 2722 | } |
| 2723 | |
| 2724 | Used as an lvalue, C<keys> allows you to increase the number of hash buckets |
| 2725 | allocated for the given hash. This can gain you a measure of efficiency if |
| 2726 | you know the hash is going to get big. (This is similar to pre-extending |
| 2727 | an array by assigning a larger number to $#array.) If you say |
| 2728 | |
| 2729 | keys %hash = 200; |
| 2730 | |
| 2731 | then C<%hash> will have at least 200 buckets allocated for it--256 of them, |
| 2732 | in fact, since it rounds up to the next power of two. These |
| 2733 | buckets will be retained even if you do C<%hash = ()>, use C<undef |
| 2734 | %hash> if you want to free the storage while C<%hash> is still in scope. |
| 2735 | You can't shrink the number of buckets allocated for the hash using |
| 2736 | C<keys> in this way (but you needn't worry about doing this by accident, |
| 2737 | as trying has no effect). C<keys @array> in an lvalue context is a syntax |
| 2738 | error. |
| 2739 | |
| 2740 | Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain |
| 2741 | a reference to an unblessed hash or array. The argument will be |
| 2742 | dereferenced automatically. This aspect of C<keys> is considered highly |
| 2743 | experimental. The exact behaviour may change in a future version of Perl. |
| 2744 | |
| 2745 | for (keys $hashref) { ... } |
| 2746 | for (keys $obj->get_arrayref) { ... } |
| 2747 | |
| 2748 | See also C<each>, C<values>, and C<sort>. |
| 2749 | |
| 2750 | =item kill SIGNAL, LIST |
| 2751 | X<kill> X<signal> |
| 2752 | |
| 2753 | Sends a signal to a list of processes. Returns the number of |
| 2754 | processes successfully signaled (which is not necessarily the |
| 2755 | same as the number actually killed). |
| 2756 | |
| 2757 | $cnt = kill 1, $child1, $child2; |
| 2758 | kill 9, @goners; |
| 2759 | |
| 2760 | If SIGNAL is zero, no signal is sent to the process, but C<kill> |
| 2761 | checks whether it's I<possible> to send a signal to it (that |
| 2762 | means, to be brief, that the process is owned by the same user, or we are |
| 2763 | the super-user). This is useful to check that a child process is still |
| 2764 | alive (even if only as a zombie) and hasn't changed its UID. See |
| 2765 | L<perlport> for notes on the portability of this construct. |
| 2766 | |
| 2767 | Unlike in the shell, if SIGNAL is negative, it kills process groups instead |
| 2768 | of processes. That means you usually want to use positive not negative signals. |
| 2769 | You may also use a signal name in quotes. |
| 2770 | |
| 2771 | The behavior of kill when a I<PROCESS> number is zero or negative depends on |
| 2772 | the operating system. For example, on POSIX-conforming systems, zero will |
| 2773 | signal the current process group and -1 will signal all processes. |
| 2774 | |
| 2775 | See L<perlipc/"Signals"> for more details. |
| 2776 | |
| 2777 | =item last LABEL |
| 2778 | X<last> X<break> |
| 2779 | |
| 2780 | =item last |
| 2781 | |
| 2782 | The C<last> command is like the C<break> statement in C (as used in |
| 2783 | loops); it immediately exits the loop in question. If the LABEL is |
| 2784 | omitted, the command refers to the innermost enclosing loop. The |
| 2785 | C<continue> block, if any, is not executed: |
| 2786 | |
| 2787 | LINE: while (<STDIN>) { |
| 2788 | last LINE if /^$/; # exit when done with header |
| 2789 | #... |
| 2790 | } |
| 2791 | |
| 2792 | C<last> cannot be used to exit a block that returns a value such as |
| 2793 | C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit |
| 2794 | a grep() or map() operation. |
| 2795 | |
| 2796 | Note that a block by itself is semantically identical to a loop |
| 2797 | that executes once. Thus C<last> can be used to effect an early |
| 2798 | exit out of such a block. |
| 2799 | |
| 2800 | See also L</continue> for an illustration of how C<last>, C<next>, and |
| 2801 | C<redo> work. |
| 2802 | |
| 2803 | =item lc EXPR |
| 2804 | X<lc> X<lowercase> |
| 2805 | |
| 2806 | =item lc |
| 2807 | |
| 2808 | Returns a lowercased version of EXPR. This is the internal function |
| 2809 | implementing the C<\L> escape in double-quoted strings. |
| 2810 | |
| 2811 | If EXPR is omitted, uses C<$_>. |
| 2812 | |
| 2813 | What gets returned depends on several factors: |
| 2814 | |
| 2815 | =over |
| 2816 | |
| 2817 | =item If C<use bytes> is in effect: |
| 2818 | |
| 2819 | =over |
| 2820 | |
| 2821 | =item On EBCDIC platforms |
| 2822 | |
| 2823 | The results are what the C language system call C<tolower()> returns. |
| 2824 | |
| 2825 | =item On ASCII platforms |
| 2826 | |
| 2827 | The results follow ASCII semantics. Only characters C<A-Z> change, to C<a-z> |
| 2828 | respectively. |
| 2829 | |
| 2830 | =back |
| 2831 | |
| 2832 | =item Otherwise, If EXPR has the UTF8 flag set |
| 2833 | |
| 2834 | If the current package has a subroutine named C<ToLower>, it will be used to |
| 2835 | change the case |
| 2836 | (See L<perlunicode/"User-Defined Case Mappings (for serious hackers only)">.) |
| 2837 | Otherwise Unicode semantics are used for the case change. |
| 2838 | |
| 2839 | =item Otherwise, if C<use locale> is in effect |
| 2840 | |
| 2841 | Respects current LC_CTYPE locale. See L<perllocale>. |
| 2842 | |
| 2843 | =item Otherwise, if C<use feature 'unicode_strings'> is in effect: |
| 2844 | |
| 2845 | Unicode semantics are used for the case change. Any subroutine named |
| 2846 | C<ToLower> will be ignored. |
| 2847 | |
| 2848 | =item Otherwise: |
| 2849 | |
| 2850 | =over |
| 2851 | |
| 2852 | =item On EBCDIC platforms |
| 2853 | |
| 2854 | The results are what the C language system call C<tolower()> returns. |
| 2855 | |
| 2856 | =item On ASCII platforms |
| 2857 | |
| 2858 | ASCII semantics are used for the case change. The lowercase of any character |
| 2859 | outside the ASCII range is the character itself. |
| 2860 | |
| 2861 | =back |
| 2862 | |
| 2863 | =back |
| 2864 | |
| 2865 | =item lcfirst EXPR |
| 2866 | X<lcfirst> X<lowercase> |
| 2867 | |
| 2868 | =item lcfirst |
| 2869 | |
| 2870 | Returns the value of EXPR with the first character lowercased. This |
| 2871 | is the internal function implementing the C<\l> escape in |
| 2872 | double-quoted strings. |
| 2873 | |
| 2874 | If EXPR is omitted, uses C<$_>. |
| 2875 | |
| 2876 | This function behaves the same way under various pragmata, such as in a locale, |
| 2877 | as L</lc> does. |
| 2878 | |
| 2879 | =item length EXPR |
| 2880 | X<length> X<size> |
| 2881 | |
| 2882 | =item length |
| 2883 | |
| 2884 | Returns the length in I<characters> of the value of EXPR. If EXPR is |
| 2885 | omitted, returns the length of C<$_>. If EXPR is undefined, returns |
| 2886 | C<undef>. |
| 2887 | |
| 2888 | This function cannot be used on an entire array or hash to find out how |
| 2889 | many elements these have. For that, use C<scalar @array> and C<scalar keys |
| 2890 | %hash>, respectively. |
| 2891 | |
| 2892 | Like all Perl character operations, length() normally deals in logical |
| 2893 | characters, not physical bytes. For how many bytes a string encoded as |
| 2894 | UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have |
| 2895 | to C<use Encode> first). See L<Encode> and L<perlunicode>. |
| 2896 | |
| 2897 | =item link OLDFILE,NEWFILE |
| 2898 | X<link> |
| 2899 | |
| 2900 | Creates a new filename linked to the old filename. Returns true for |
| 2901 | success, false otherwise. |
| 2902 | |
| 2903 | =item listen SOCKET,QUEUESIZE |
| 2904 | X<listen> |
| 2905 | |
| 2906 | Does the same thing that the listen(2) system call does. Returns true if |
| 2907 | it succeeded, false otherwise. See the example in |
| 2908 | L<perlipc/"Sockets: Client/Server Communication">. |
| 2909 | |
| 2910 | =item local EXPR |
| 2911 | X<local> |
| 2912 | |
| 2913 | You really probably want to be using C<my> instead, because C<local> isn't |
| 2914 | what most people think of as "local". See |
| 2915 | L<perlsub/"Private Variables via my()"> for details. |
| 2916 | |
| 2917 | A local modifies the listed variables to be local to the enclosing |
| 2918 | block, file, or eval. If more than one value is listed, the list must |
| 2919 | be placed in parentheses. See L<perlsub/"Temporary Values via local()"> |
| 2920 | for details, including issues with tied arrays and hashes. |
| 2921 | |
| 2922 | The C<delete local EXPR> construct can also be used to localize the deletion |
| 2923 | of array/hash elements to the current block. |
| 2924 | See L<perlsub/"Localized deletion of elements of composite types">. |
| 2925 | |
| 2926 | =item localtime EXPR |
| 2927 | X<localtime> X<ctime> |
| 2928 | |
| 2929 | =item localtime |
| 2930 | |
| 2931 | Converts a time as returned by the time function to a 9-element list |
| 2932 | with the time analyzed for the local time zone. Typically used as |
| 2933 | follows: |
| 2934 | |
| 2935 | # 0 1 2 3 4 5 6 7 8 |
| 2936 | ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = |
| 2937 | localtime(time); |
| 2938 | |
| 2939 | All list elements are numeric and come straight out of the C `struct |
| 2940 | tm'. C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours |
| 2941 | of the specified time. |
| 2942 | |
| 2943 | C<$mday> is the day of the month and C<$mon> the month in |
| 2944 | the range C<0..11>, with 0 indicating January and 11 indicating December. |
| 2945 | This makes it easy to get a month name from a list: |
| 2946 | |
| 2947 | my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec ); |
| 2948 | print "$abbr[$mon] $mday"; |
| 2949 | # $mon=9, $mday=18 gives "Oct 18" |
| 2950 | |
| 2951 | C<$year> is the number of years since 1900, B<not> just the last two digits |
| 2952 | of the year. That is, C<$year> is C<123> in year 2023. The proper way |
| 2953 | to get a 4-digit year is simply: |
| 2954 | |
| 2955 | $year += 1900; |
| 2956 | |
| 2957 | Otherwise you create non-Y2K-compliant programs--and you wouldn't want |
| 2958 | to do that, would you? |
| 2959 | |
| 2960 | To get the last two digits of the year (e.g., "01" in 2001) do: |
| 2961 | |
| 2962 | $year = sprintf("%02d", $year % 100); |
| 2963 | |
| 2964 | C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating |
| 2965 | Wednesday. C<$yday> is the day of the year, in the range C<0..364> |
| 2966 | (or C<0..365> in leap years.) |
| 2967 | |
| 2968 | C<$isdst> is true if the specified time occurs during Daylight Saving |
| 2969 | Time, false otherwise. |
| 2970 | |
| 2971 | If EXPR is omitted, C<localtime()> uses the current time (as returned |
| 2972 | by time(3)). |
| 2973 | |
| 2974 | In scalar context, C<localtime()> returns the ctime(3) value: |
| 2975 | |
| 2976 | $now_string = localtime; # e.g., "Thu Oct 13 04:54:34 1994" |
| 2977 | |
| 2978 | This scalar value is B<not> locale-dependent but is a Perl builtin. For GMT |
| 2979 | instead of local time use the L</gmtime> builtin. See also the |
| 2980 | C<Time::Local> module (for converting seconds, minutes, hours, and such back to |
| 2981 | the integer value returned by time()), and the L<POSIX> module's strftime(3) |
| 2982 | and mktime(3) functions. |
| 2983 | |
| 2984 | To get somewhat similar but locale-dependent date strings, set up your |
| 2985 | locale environment variables appropriately (please see L<perllocale>) and |
| 2986 | try for example: |
| 2987 | |
| 2988 | use POSIX qw(strftime); |
| 2989 | $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime; |
| 2990 | # or for GMT formatted appropriately for your locale: |
| 2991 | $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime; |
| 2992 | |
| 2993 | Note that the C<%a> and C<%b>, the short forms of the day of the week |
| 2994 | and the month of the year, may not necessarily be three characters wide. |
| 2995 | |
| 2996 | See L<perlport/localtime> for portability concerns. |
| 2997 | |
| 2998 | The L<Time::gmtime> and L<Time::localtime> modules provide a convenient, |
| 2999 | by-name access mechanism to the gmtime() and localtime() functions, |
| 3000 | respectively. |
| 3001 | |
| 3002 | For a comprehensive date and time representation look at the |
| 3003 | L<DateTime> module on CPAN. |
| 3004 | |
| 3005 | =item lock THING |
| 3006 | X<lock> |
| 3007 | |
| 3008 | This function places an advisory lock on a shared variable or referenced |
| 3009 | object contained in I<THING> until the lock goes out of scope. |
| 3010 | |
| 3011 | lock() is a "weak keyword" : this means that if you've defined a function |
| 3012 | by this name (before any calls to it), that function will be called |
| 3013 | instead. If you are not under C<use threads::shared> this does nothing. |
| 3014 | See L<threads::shared>. |
| 3015 | |
| 3016 | =item log EXPR |
| 3017 | X<log> X<logarithm> X<e> X<ln> X<base> |
| 3018 | |
| 3019 | =item log |
| 3020 | |
| 3021 | Returns the natural logarithm (base I<e>) of EXPR. If EXPR is omitted, |
| 3022 | returns the log of C<$_>. To get the |
| 3023 | log of another base, use basic algebra: |
| 3024 | The base-N log of a number is equal to the natural log of that number |
| 3025 | divided by the natural log of N. For example: |
| 3026 | |
| 3027 | sub log10 { |
| 3028 | my $n = shift; |
| 3029 | return log($n)/log(10); |
| 3030 | } |
| 3031 | |
| 3032 | See also L</exp> for the inverse operation. |
| 3033 | |
| 3034 | =item lstat EXPR |
| 3035 | X<lstat> |
| 3036 | |
| 3037 | =item lstat |
| 3038 | |
| 3039 | Does the same thing as the C<stat> function (including setting the |
| 3040 | special C<_> filehandle) but stats a symbolic link instead of the file |
| 3041 | the symbolic link points to. If symbolic links are unimplemented on |
| 3042 | your system, a normal C<stat> is done. For much more detailed |
| 3043 | information, please see the documentation for C<stat>. |
| 3044 | |
| 3045 | If EXPR is omitted, stats C<$_>. |
| 3046 | |
| 3047 | =item m// |
| 3048 | |
| 3049 | The match operator. See L<perlop/"Regexp Quote-Like Operators">. |
| 3050 | |
| 3051 | =item map BLOCK LIST |
| 3052 | X<map> |
| 3053 | |
| 3054 | =item map EXPR,LIST |
| 3055 | |
| 3056 | Evaluates the BLOCK or EXPR for each element of LIST (locally setting |
| 3057 | C<$_> to each element) and returns the list value composed of the |
| 3058 | results of each such evaluation. In scalar context, returns the |
| 3059 | total number of elements so generated. Evaluates BLOCK or EXPR in |
| 3060 | list context, so each element of LIST may produce zero, one, or |
| 3061 | more elements in the returned value. |
| 3062 | |
| 3063 | @chars = map(chr, @numbers); |
| 3064 | |
| 3065 | translates a list of numbers to the corresponding characters. |
| 3066 | |
| 3067 | my @squares = map { $_ * $_ } @numbers; |
| 3068 | |
| 3069 | translates a list of numbers to their squared values. |
| 3070 | |
| 3071 | my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers; |
| 3072 | |
| 3073 | shows that number of returned elements can differ from the number of |
| 3074 | input elements. To omit an element, return an empty list (). |
| 3075 | This could also be achieved by writing |
| 3076 | |
| 3077 | my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers; |
| 3078 | |
| 3079 | which makes the intention more clear. |
| 3080 | |
| 3081 | Map always returns a list, which can be |
| 3082 | assigned to a hash such that the elements |
| 3083 | become key/value pairs. See L<perldata> for more details. |
| 3084 | |
| 3085 | %hash = map { get_a_key_for($_) => $_ } @array; |
| 3086 | |
| 3087 | is just a funny way to write |
| 3088 | |
| 3089 | %hash = (); |
| 3090 | foreach (@array) { |
| 3091 | $hash{get_a_key_for($_)} = $_; |
| 3092 | } |
| 3093 | |
| 3094 | Note that C<$_> is an alias to the list value, so it can be used to |
| 3095 | modify the elements of the LIST. While this is useful and supported, |
| 3096 | it can cause bizarre results if the elements of LIST are not variables. |
| 3097 | Using a regular C<foreach> loop for this purpose would be clearer in |
| 3098 | most cases. See also L</grep> for an array composed of those items of |
| 3099 | the original list for which the BLOCK or EXPR evaluates to true. |
| 3100 | |
| 3101 | If C<$_> is lexical in the scope where the C<map> appears (because it has |
| 3102 | been declared with C<my $_>), then, in addition to being locally aliased to |
| 3103 | the list elements, C<$_> keeps being lexical inside the block; that is, it |
| 3104 | can't be seen from the outside, avoiding any potential side-effects. |
| 3105 | |
| 3106 | C<{> starts both hash references and blocks, so C<map { ...> could be either |
| 3107 | the start of map BLOCK LIST or map EXPR, LIST. Because Perl doesn't look |
| 3108 | ahead for the closing C<}> it has to take a guess at which it's dealing with |
| 3109 | based on what it finds just after the C<{>. Usually it gets it right, but if it |
| 3110 | doesn't it won't realize something is wrong until it gets to the C<}> and |
| 3111 | encounters the missing (or unexpected) comma. The syntax error will be |
| 3112 | reported close to the C<}>, but you'll need to change something near the C<{> |
| 3113 | such as using a unary C<+> to give Perl some help: |
| 3114 | |
| 3115 | %hash = map { "\L$_" => 1 } @array # perl guesses EXPR. wrong |
| 3116 | %hash = map { +"\L$_" => 1 } @array # perl guesses BLOCK. right |
| 3117 | %hash = map { ("\L$_" => 1) } @array # this also works |
| 3118 | %hash = map { lc($_) => 1 } @array # as does this. |
| 3119 | %hash = map +( lc($_) => 1 ), @array # this is EXPR and works! |
| 3120 | |
| 3121 | %hash = map ( lc($_), 1 ), @array # evaluates to (1, @array) |
| 3122 | |
| 3123 | or to force an anon hash constructor use C<+{>: |
| 3124 | |
| 3125 | @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end |
| 3126 | |
| 3127 | to get a list of anonymous hashes each with only one entry apiece. |
| 3128 | |
| 3129 | =item mkdir FILENAME,MASK |
| 3130 | X<mkdir> X<md> X<directory, create> |
| 3131 | |
| 3132 | =item mkdir FILENAME |
| 3133 | |
| 3134 | =item mkdir |
| 3135 | |
| 3136 | Creates the directory specified by FILENAME, with permissions |
| 3137 | specified by MASK (as modified by C<umask>). If it succeeds it |
| 3138 | returns true; otherwise it returns false and sets C<$!> (errno). |
| 3139 | MASK defaults to 0777 if omitted, and FILENAME defaults |
| 3140 | to C<$_> if omitted. |
| 3141 | |
| 3142 | In general, it is better to create directories with a permissive MASK |
| 3143 | and let the user modify that with their C<umask> than it is to supply |
| 3144 | a restrictive MASK and give the user no way to be more permissive. |
| 3145 | The exceptions to this rule are when the file or directory should be |
| 3146 | kept private (mail files, for instance). The perlfunc(1) entry on |
| 3147 | C<umask> discusses the choice of MASK in more detail. |
| 3148 | |
| 3149 | Note that according to the POSIX 1003.1-1996 the FILENAME may have any |
| 3150 | number of trailing slashes. Some operating and filesystems do not get |
| 3151 | this right, so Perl automatically removes all trailing slashes to keep |
| 3152 | everyone happy. |
| 3153 | |
| 3154 | To recursively create a directory structure, look at |
| 3155 | the C<mkpath> function of the L<File::Path> module. |
| 3156 | |
| 3157 | =item msgctl ID,CMD,ARG |
| 3158 | X<msgctl> |
| 3159 | |
| 3160 | Calls the System V IPC function msgctl(2). You'll probably have to say |
| 3161 | |
| 3162 | use IPC::SysV; |
| 3163 | |
| 3164 | first to get the correct constant definitions. If CMD is C<IPC_STAT>, |
| 3165 | then ARG must be a variable that will hold the returned C<msqid_ds> |
| 3166 | structure. Returns like C<ioctl>: the undefined value for error, |
| 3167 | C<"0 but true"> for zero, or the actual return value otherwise. See also |
| 3168 | L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and |
| 3169 | C<IPC::Semaphore>. |
| 3170 | |
| 3171 | =item msgget KEY,FLAGS |
| 3172 | X<msgget> |
| 3173 | |
| 3174 | Calls the System V IPC function msgget(2). Returns the message queue |
| 3175 | id, or C<undef> on error. See also |
| 3176 | L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and |
| 3177 | C<IPC::Msg>. |
| 3178 | |
| 3179 | =item msgrcv ID,VAR,SIZE,TYPE,FLAGS |
| 3180 | X<msgrcv> |
| 3181 | |
| 3182 | Calls the System V IPC function msgrcv to receive a message from |
| 3183 | message queue ID into variable VAR with a maximum message size of |
| 3184 | SIZE. Note that when a message is received, the message type as a |
| 3185 | native long integer will be the first thing in VAR, followed by the |
| 3186 | actual message. This packing may be opened with C<unpack("l! a*")>. |
| 3187 | Taints the variable. Returns true if successful, false |
| 3188 | on error. See also L<perlipc/"SysV IPC"> and the documentation for |
| 3189 | C<IPC::SysV> and C<IPC::SysV::Msg>. |
| 3190 | |
| 3191 | =item msgsnd ID,MSG,FLAGS |
| 3192 | X<msgsnd> |
| 3193 | |
| 3194 | Calls the System V IPC function msgsnd to send the message MSG to the |
| 3195 | message queue ID. MSG must begin with the native long integer message |
| 3196 | type, be followed by the length of the actual message, and then finally |
| 3197 | the message itself. This kind of packing can be achieved with |
| 3198 | C<pack("l! a*", $type, $message)>. Returns true if successful, |
| 3199 | false on error. See also the C<IPC::SysV> |
| 3200 | and C<IPC::SysV::Msg> documentation. |
| 3201 | |
| 3202 | =item my EXPR |
| 3203 | X<my> |
| 3204 | |
| 3205 | =item my TYPE EXPR |
| 3206 | |
| 3207 | =item my EXPR : ATTRS |
| 3208 | |
| 3209 | =item my TYPE EXPR : ATTRS |
| 3210 | |
| 3211 | A C<my> declares the listed variables to be local (lexically) to the |
| 3212 | enclosing block, file, or C<eval>. If more than one value is listed, |
| 3213 | the list must be placed in parentheses. |
| 3214 | |
| 3215 | The exact semantics and interface of TYPE and ATTRS are still |
| 3216 | evolving. TYPE is currently bound to the use of the C<fields> pragma, |
| 3217 | and attributes are handled using the C<attributes> pragma, or starting |
| 3218 | from Perl 5.8.0 also via the C<Attribute::Handlers> module. See |
| 3219 | L<perlsub/"Private Variables via my()"> for details, and L<fields>, |
| 3220 | L<attributes>, and L<Attribute::Handlers>. |
| 3221 | |
| 3222 | =item next LABEL |
| 3223 | X<next> X<continue> |
| 3224 | |
| 3225 | =item next |
| 3226 | |
| 3227 | The C<next> command is like the C<continue> statement in C; it starts |
| 3228 | the next iteration of the loop: |
| 3229 | |
| 3230 | LINE: while (<STDIN>) { |
| 3231 | next LINE if /^#/; # discard comments |
| 3232 | #... |
| 3233 | } |
| 3234 | |
| 3235 | Note that if there were a C<continue> block on the above, it would get |
| 3236 | executed even on discarded lines. If LABEL is omitted, the command |
| 3237 | refers to the innermost enclosing loop. |
| 3238 | |
| 3239 | C<next> cannot be used to exit a block which returns a value such as |
| 3240 | C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit |
| 3241 | a grep() or map() operation. |
| 3242 | |
| 3243 | Note that a block by itself is semantically identical to a loop |
| 3244 | that executes once. Thus C<next> will exit such a block early. |
| 3245 | |
| 3246 | See also L</continue> for an illustration of how C<last>, C<next>, and |
| 3247 | C<redo> work. |
| 3248 | |
| 3249 | =item no MODULE VERSION LIST |
| 3250 | X<no declarations> |
| 3251 | X<unimporting> |
| 3252 | |
| 3253 | =item no MODULE VERSION |
| 3254 | |
| 3255 | =item no MODULE LIST |
| 3256 | |
| 3257 | =item no MODULE |
| 3258 | |
| 3259 | =item no VERSION |
| 3260 | |
| 3261 | See the C<use> function, of which C<no> is the opposite. |
| 3262 | |
| 3263 | =item oct EXPR |
| 3264 | X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin> |
| 3265 | |
| 3266 | =item oct |
| 3267 | |
| 3268 | Interprets EXPR as an octal string and returns the corresponding |
| 3269 | value. (If EXPR happens to start off with C<0x>, interprets it as a |
| 3270 | hex string. If EXPR starts off with C<0b>, it is interpreted as a |
| 3271 | binary string. Leading whitespace is ignored in all three cases.) |
| 3272 | The following will handle decimal, binary, octal, and hex in standard |
| 3273 | Perl notation: |
| 3274 | |
| 3275 | $val = oct($val) if $val =~ /^0/; |
| 3276 | |
| 3277 | If EXPR is omitted, uses C<$_>. To go the other way (produce a number |
| 3278 | in octal), use sprintf() or printf(): |
| 3279 | |
| 3280 | $dec_perms = (stat("filename"))[2] & 07777; |
| 3281 | $oct_perm_str = sprintf "%o", $perms; |
| 3282 | |
| 3283 | The oct() function is commonly used when a string such as C<644> needs |
| 3284 | to be converted into a file mode, for example. Although Perl |
| 3285 | automatically converts strings into numbers as needed, this automatic |
| 3286 | conversion assumes base 10. |
| 3287 | |
| 3288 | Leading white space is ignored without warning, as too are any trailing |
| 3289 | non-digits, such as a decimal point (C<oct> only handles non-negative |
| 3290 | integers, not negative integers or floating point). |
| 3291 | |
| 3292 | =item open FILEHANDLE,EXPR |
| 3293 | X<open> X<pipe> X<file, open> X<fopen> |
| 3294 | |
| 3295 | =item open FILEHANDLE,MODE,EXPR |
| 3296 | |
| 3297 | =item open FILEHANDLE,MODE,EXPR,LIST |
| 3298 | |
| 3299 | =item open FILEHANDLE,MODE,REFERENCE |
| 3300 | |
| 3301 | =item open FILEHANDLE |
| 3302 | |
| 3303 | Opens the file whose filename is given by EXPR, and associates it with |
| 3304 | FILEHANDLE. |
| 3305 | |
| 3306 | Simple examples to open a file for reading: |
| 3307 | |
| 3308 | open(my $fh, "<", "input.txt") |
| 3309 | or die "cannot open < input.txt: $!"; |
| 3310 | |
| 3311 | and for writing: |
| 3312 | |
| 3313 | open(my $fh, ">", "output.txt") |
| 3314 | or die "cannot open > output.txt: $!"; |
| 3315 | |
| 3316 | (The following is a comprehensive reference to open(): for a gentler |
| 3317 | introduction you may consider L<perlopentut>.) |
| 3318 | |
| 3319 | If FILEHANDLE is an undefined scalar variable (or array or hash element), a |
| 3320 | new filehandle is autovivified, meaning that the variable is assigned a |
| 3321 | reference to a newly allocated anonymous filehandle. Otherwise if |
| 3322 | FILEHANDLE is an expression, its value is the real filehandle. (This is |
| 3323 | considered a symbolic reference, so C<use strict "refs"> should I<not> be |
| 3324 | in effect.) |
| 3325 | |
| 3326 | If EXPR is omitted, the global (package) scalar variable of the same |
| 3327 | name as the FILEHANDLE contains the filename. (Note that lexical |
| 3328 | variables--those declared with C<my> or C<state>--will not work for this |
| 3329 | purpose; so if you're using C<my> or C<state>, specify EXPR in your |
| 3330 | call to open.) |
| 3331 | |
| 3332 | If three (or more) arguments are specified, the open mode (including |
| 3333 | optional encoding) in the second argument are distinct from the filename in |
| 3334 | the third. If MODE is C<< < >> or nothing, the file is opened for input. |
| 3335 | If MODE is C<< > >>, the file is opened for output, with existing files |
| 3336 | first being truncated ("clobbered") and nonexisting files newly created. |
| 3337 | If MODE is C<<< >> >>>, the file is opened for appending, again being |
| 3338 | created if necessary. |
| 3339 | |
| 3340 | You can put a C<+> in front of the C<< > >> or C<< < >> to |
| 3341 | indicate that you want both read and write access to the file; thus |
| 3342 | C<< +< >> is almost always preferred for read/write updates--the |
| 3343 | C<< +> >> mode would clobber the file first. You cant usually use |
| 3344 | either read-write mode for updating textfiles, since they have |
| 3345 | variable-length records. See the B<-i> switch in L<perlrun> for a |
| 3346 | better approach. The file is created with permissions of C<0666> |
| 3347 | modified by the process's C<umask> value. |
| 3348 | |
| 3349 | These various prefixes correspond to the fopen(3) modes of C<r>, |
| 3350 | C<r+>, C<w>, C<w+>, C<a>, and C<a+>. |
| 3351 | |
| 3352 | In the one- and two-argument forms of the call, the mode and filename |
| 3353 | should be concatenated (in that order), preferably separated by white |
| 3354 | space. You can--but shouldn't--omit the mode in these forms when that mode |
| 3355 | is C<< < >>. It is always safe to use the two-argument form of C<open> if |
| 3356 | the filename argument is a known literal. |
| 3357 | |
| 3358 | For three or more arguments if MODE is C<|->, the filename is |
| 3359 | interpreted as a command to which output is to be piped, and if MODE |
| 3360 | is C<-|>, the filename is interpreted as a command that pipes |
| 3361 | output to us. In the two-argument (and one-argument) form, one should |
| 3362 | replace dash (C<->) with the command. |
| 3363 | See L<perlipc/"Using open() for IPC"> for more examples of this. |
| 3364 | (You are not allowed to C<open> to a command that pipes both in I<and> |
| 3365 | out, but see L<IPC::Open2>, L<IPC::Open3>, and |
| 3366 | L<perlipc/"Bidirectional Communication with Another Process"> for |
| 3367 | alternatives.) |
| 3368 | |
| 3369 | In the form of pipe opens taking three or more arguments, if LIST is specified |
| 3370 | (extra arguments after the command name) then LIST becomes arguments |
| 3371 | to the command invoked if the platform supports it. The meaning of |
| 3372 | C<open> with more than three arguments for non-pipe modes is not yet |
| 3373 | defined, but experimental "layers" may give extra LIST arguments |
| 3374 | meaning. |
| 3375 | |
| 3376 | In the two-argument (and one-argument) form, opening C<< <- >> |
| 3377 | or C<-> opens STDIN and opening C<< >- >> opens STDOUT. |
| 3378 | |
| 3379 | You may (and usually should) use the three-argument form of open to specify |
| 3380 | I/O layers (sometimes referred to as "disciplines") to apply to the handle |
| 3381 | that affect how the input and output are processed (see L<open> and |
| 3382 | L<PerlIO> for more details). For example: |
| 3383 | |
| 3384 | open(my $fh, "<:encoding(UTF-8)", "filename") |
| 3385 | || die "can't open UTF-8 encoded filename: $!"; |
| 3386 | |
| 3387 | opens the UTF8-encoded file containing Unicode characters; |
| 3388 | see L<perluniintro>. Note that if layers are specified in the |
| 3389 | three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>; |
| 3390 | usually set by the B<open> pragma or the switch B<-CioD>) are ignored. |
| 3391 | |
| 3392 | Open returns nonzero on success, the undefined value otherwise. If |
| 3393 | the C<open> involved a pipe, the return value happens to be the pid of |
| 3394 | the subprocess. |
| 3395 | |
| 3396 | If you're running Perl on a system that distinguishes between text |
| 3397 | files and binary files, then you should check out L</binmode> for tips |
| 3398 | for dealing with this. The key distinction between systems that need |
| 3399 | C<binmode> and those that don't is their text file formats. Systems |
| 3400 | like Unix, Mac OS, and Plan 9, that end lines with a single |
| 3401 | character and encode that character in C as C<"\n"> do not |
| 3402 | need C<binmode>. The rest need it. |
| 3403 | |
| 3404 | When opening a file, it's seldom a good idea to continue |
| 3405 | if the request failed, so C<open> is frequently used with |
| 3406 | C<die>. Even if C<die> won't do what you want (say, in a CGI script, |
| 3407 | where you want to format a suitable error message (but there are |
| 3408 | modules that can help with that problem)) always check |
| 3409 | the return value from opening a file. |
| 3410 | |
| 3411 | As a special case the three-argument form with a read/write mode and the third |
| 3412 | argument being C<undef>: |
| 3413 | |
| 3414 | open(my $tmp, "+>", undef) or die ... |
| 3415 | |
| 3416 | opens a filehandle to an anonymous temporary file. Also using C<< +< >> |
| 3417 | works for symmetry, but you really should consider writing something |
| 3418 | to the temporary file first. You will need to seek() to do the |
| 3419 | reading. |
| 3420 | |
| 3421 | Since v5.8.0, Perl has built using PerlIO by default. Unless you've |
| 3422 | changed this (such as building Perl with C<Configure -Uuseperlio>), you can |
| 3423 | open filehandles directly to Perl scalars via: |
| 3424 | |
| 3425 | open($fh, ">", \$variable) || .. |
| 3426 | |
| 3427 | To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first: |
| 3428 | |
| 3429 | close STDOUT; |
| 3430 | open(STDOUT, ">", \$variable) |
| 3431 | or die "Can't open STDOUT: $!"; |
| 3432 | |
| 3433 | General examples: |
| 3434 | |
| 3435 | $ARTICLE = 100; |
| 3436 | open(ARTICLE) or die "Can't find article $ARTICLE: $!\n"; |
| 3437 | while (<ARTICLE>) {... |
| 3438 | |
| 3439 | open(LOG, ">>/usr/spool/news/twitlog"); # (log is reserved) |
| 3440 | # if the open fails, output is discarded |
| 3441 | |
| 3442 | open(my $dbase, "+<", "dbase.mine") # open for update |
| 3443 | or die "Can't open 'dbase.mine' for update: $!"; |
| 3444 | |
| 3445 | open(my $dbase, "+<dbase.mine") # ditto |
| 3446 | or die "Can't open 'dbase.mine' for update: $!"; |
| 3447 | |
| 3448 | open(ARTICLE, "-|", "caesar <$article") # decrypt article |
| 3449 | or die "Can't start caesar: $!"; |
| 3450 | |
| 3451 | open(ARTICLE, "caesar <$article |") # ditto |
| 3452 | or die "Can't start caesar: $!"; |
| 3453 | |
| 3454 | open(EXTRACT, "|sort >Tmp$$") # $$ is our process id |
| 3455 | or die "Can't start sort: $!"; |
| 3456 | |
| 3457 | # in-memory files |
| 3458 | open(MEMORY, ">", \$var) |
| 3459 | or die "Can't open memory file: $!"; |
| 3460 | print MEMORY "foo!\n"; # output will appear in $var |
| 3461 | |
| 3462 | # process argument list of files along with any includes |
| 3463 | |
| 3464 | foreach $file (@ARGV) { |
| 3465 | process($file, "fh00"); |
| 3466 | } |
| 3467 | |
| 3468 | sub process { |
| 3469 | my($filename, $input) = @_; |
| 3470 | $input++; # this is a string increment |
| 3471 | unless (open($input, "<", $filename)) { |
| 3472 | print STDERR "Can't open $filename: $!\n"; |
| 3473 | return; |
| 3474 | } |
| 3475 | |
| 3476 | local $_; |
| 3477 | while (<$input>) { # note use of indirection |
| 3478 | if (/^#include "(.*)"/) { |
| 3479 | process($1, $input); |
| 3480 | next; |
| 3481 | } |
| 3482 | #... # whatever |
| 3483 | } |
| 3484 | } |
| 3485 | |
| 3486 | See L<perliol> for detailed info on PerlIO. |
| 3487 | |
| 3488 | You may also, in the Bourne shell tradition, specify an EXPR beginning |
| 3489 | with C<< >& >>, in which case the rest of the string is interpreted |
| 3490 | as the name of a filehandle (or file descriptor, if numeric) to be |
| 3491 | duped (as C<dup(2)>) and opened. You may use C<&> after C<< > >>, |
| 3492 | C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>. |
| 3493 | The mode you specify should match the mode of the original filehandle. |
| 3494 | (Duping a filehandle does not take into account any existing contents |
| 3495 | of IO buffers.) If you use the three-argument form, then you can pass either a |
| 3496 | number, the name of a filehandle, or the normal "reference to a glob". |
| 3497 | |
| 3498 | Here is a script that saves, redirects, and restores C<STDOUT> and |
| 3499 | C<STDERR> using various methods: |
| 3500 | |
| 3501 | #!/usr/bin/perl |
| 3502 | open(my $oldout, ">&STDOUT") or die "Can't dup STDOUT: $!"; |
| 3503 | open(OLDERR, ">&", \*STDERR) or die "Can't dup STDERR: $!"; |
| 3504 | |
| 3505 | open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!"; |
| 3506 | open(STDERR, ">&STDOUT") or die "Can't dup STDOUT: $!"; |
| 3507 | |
| 3508 | select STDERR; $| = 1; # make unbuffered |
| 3509 | select STDOUT; $| = 1; # make unbuffered |
| 3510 | |
| 3511 | print STDOUT "stdout 1\n"; # this works for |
| 3512 | print STDERR "stderr 1\n"; # subprocesses too |
| 3513 | |
| 3514 | open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!"; |
| 3515 | open(STDERR, ">&OLDERR") or die "Can't dup OLDERR: $!"; |
| 3516 | |
| 3517 | print STDOUT "stdout 2\n"; |
| 3518 | print STDERR "stderr 2\n"; |
| 3519 | |
| 3520 | If you specify C<< '<&=X' >>, where C<X> is a file descriptor number |
| 3521 | or a filehandle, then Perl will do an equivalent of C's C<fdopen> of |
| 3522 | that file descriptor (and not call C<dup(2)>); this is more |
| 3523 | parsimonious of file descriptors. For example: |
| 3524 | |
| 3525 | # open for input, reusing the fileno of $fd |
| 3526 | open(FILEHANDLE, "<&=$fd") |
| 3527 | |
| 3528 | or |
| 3529 | |
| 3530 | open(FILEHANDLE, "<&=", $fd) |
| 3531 | |
| 3532 | or |
| 3533 | |
| 3534 | # open for append, using the fileno of OLDFH |
| 3535 | open(FH, ">>&=", OLDFH) |
| 3536 | |
| 3537 | or |
| 3538 | |
| 3539 | open(FH, ">>&=OLDFH") |
| 3540 | |
| 3541 | Being parsimonious on filehandles is also useful (besides being |
| 3542 | parsimonious) for example when something is dependent on file |
| 3543 | descriptors, like for example locking using flock(). If you do just |
| 3544 | C<< open(A, ">>&B") >>, the filehandle A will not have the same file |
| 3545 | descriptor as B, and therefore flock(A) will not flock(B) nor vice |
| 3546 | versa. But with C<< open(A, ">>&=B") >>, the filehandles will share |
| 3547 | the same underlying system file descriptor. |
| 3548 | |
| 3549 | Note that under Perls older than 5.8.0, Perl uses the standard C library's' |
| 3550 | fdopen() to implement the C<=> functionality. On many Unix systems, |
| 3551 | fdopen() fails when file descriptors exceed a certain value, typically 255. |
| 3552 | For Perls 5.8.0 and later, PerlIO is (most often) the default. |
| 3553 | |
| 3554 | You can see whether your Perl was built with PerlIO by running C<perl -V> |
| 3555 | and looking for the C<useperlio=> line. If C<useperlio> is C<define>, you |
| 3556 | have PerlIO; otherwise you don't. |
| 3557 | |
| 3558 | If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|> |
| 3559 | with the one- or two-argument forms of C<open>), |
| 3560 | an implicit C<fork> is done, so C<open> returns twice: in the parent |
| 3561 | process it returns the pid |
| 3562 | of the child process, and in the child process it returns (a defined) C<0>. |
| 3563 | Use C<defined($pid)> or C<//> to determine whether the open was successful. |
| 3564 | |
| 3565 | For example, use either |
| 3566 | |
| 3567 | $child_pid = open(FROM_KID, "-|") // die "can't fork: $!"; |
| 3568 | |
| 3569 | or |
| 3570 | $child_pid = open(TO_KID, "|-") // die "can't fork: $!"; |
| 3571 | |
| 3572 | followed by |
| 3573 | |
| 3574 | if ($child_pid) { |
| 3575 | # am the parent: |
| 3576 | # either write TO_KID or else read FROM_KID |
| 3577 | ... |
| 3578 | wait $child_pid; |
| 3579 | } else { |
| 3580 | # am the child; use STDIN/STDOUT normally |
| 3581 | ... |
| 3582 | exit; |
| 3583 | } |
| 3584 | |
| 3585 | The filehandle behaves normally for the parent, but I/O to that |
| 3586 | filehandle is piped from/to the STDOUT/STDIN of the child process. |
| 3587 | In the child process, the filehandle isn't opened--I/O happens from/to |
| 3588 | the new STDOUT/STDIN. Typically this is used like the normal |
| 3589 | piped open when you want to exercise more control over just how the |
| 3590 | pipe command gets executed, such as when running setuid and |
| 3591 | you don't want to have to scan shell commands for metacharacters. |
| 3592 | |
| 3593 | The following blocks are more or less equivalent: |
| 3594 | |
| 3595 | open(FOO, "|tr '[a-z]' '[A-Z]'"); |
| 3596 | open(FOO, "|-", "tr '[a-z]' '[A-Z]'"); |
| 3597 | open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]'; |
| 3598 | open(FOO, "|-", "tr", '[a-z]', '[A-Z]'); |
| 3599 | |
| 3600 | open(FOO, "cat -n '$file'|"); |
| 3601 | open(FOO, "-|", "cat -n '$file'"); |
| 3602 | open(FOO, "-|") || exec "cat", "-n", $file; |
| 3603 | open(FOO, "-|", "cat", "-n", $file); |
| 3604 | |
| 3605 | The last two examples in each block show the pipe as "list form", which is |
| 3606 | not yet supported on all platforms. A good rule of thumb is that if |
| 3607 | your platform has a real C<fork()> (in other words, if your platform is |
| 3608 | Unix, including Linux and MacOS X), you can use the list form. You would |
| 3609 | want to use the list form of the pipe so you can pass literal arguments |
| 3610 | to the command without risk of the shell interpreting any shell metacharacters |
| 3611 | in them. However, this also bars you from opening pipes to commands |
| 3612 | that intentionally contain shell metacharacters, such as: |
| 3613 | |
| 3614 | open(FOO, "|cat -n | expand -4 | lpr") |
| 3615 | // die "Can't open pipeline to lpr: $!"; |
| 3616 | |
| 3617 | See L<perlipc/"Safe Pipe Opens"> for more examples of this. |
| 3618 | |
| 3619 | Beginning with v5.6.0, Perl will attempt to flush all files opened for |
| 3620 | output before any operation that may do a fork, but this may not be |
| 3621 | supported on some platforms (see L<perlport>). To be safe, you may need |
| 3622 | to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method |
| 3623 | of C<IO::Handle> on any open handles. |
| 3624 | |
| 3625 | On systems that support a close-on-exec flag on files, the flag will |
| 3626 | be set for the newly opened file descriptor as determined by the value |
| 3627 | of C<$^F>. See L<perlvar/$^F>. |
| 3628 | |
| 3629 | Closing any piped filehandle causes the parent process to wait for the |
| 3630 | child to finish, then returns the status value in C<$?> and |
| 3631 | C<${^CHILD_ERROR_NATIVE}>. |
| 3632 | |
| 3633 | The filename passed to the one- and two-argument forms of open() will |
| 3634 | have leading and trailing whitespace deleted and normal |
| 3635 | redirection characters honored. This property, known as "magic open", |
| 3636 | can often be used to good effect. A user could specify a filename of |
| 3637 | F<"rsh cat file |">, or you could change certain filenames as needed: |
| 3638 | |
| 3639 | $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/; |
| 3640 | open(FH, $filename) or die "Can't open $filename: $!"; |
| 3641 | |
| 3642 | Use the three-argument form to open a file with arbitrary weird characters in it, |
| 3643 | |
| 3644 | open(FOO, "<", $file) |
| 3645 | || die "can't open < $file: $!"; |
| 3646 | |
| 3647 | otherwise it's necessary to protect any leading and trailing whitespace: |
| 3648 | |
| 3649 | $file =~ s#^(\s)#./$1#; |
| 3650 | open(FOO, "< $file\0") |
| 3651 | || die "open failed: $!"; |
| 3652 | |
| 3653 | (this may not work on some bizarre filesystems). One should |
| 3654 | conscientiously choose between the I<magic> and I<three-argument> form |
| 3655 | of open(): |
| 3656 | |
| 3657 | open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!"; |
| 3658 | |
| 3659 | will allow the user to specify an argument of the form C<"rsh cat file |">, |
| 3660 | but will not work on a filename that happens to have a trailing space, while |
| 3661 | |
| 3662 | open(IN, "<", $ARGV[0]) |
| 3663 | || die "can't open < $ARGV[0]: $!"; |
| 3664 | |
| 3665 | will have exactly the opposite restrictions. |
| 3666 | |
| 3667 | If you want a "real" C C<open> (see C<open(2)> on your system), then you |
| 3668 | should use the C<sysopen> function, which involves no such magic (but may |
| 3669 | use subtly different filemodes than Perl open(), which is mapped to C |
| 3670 | fopen()). This is another way to protect your filenames from |
| 3671 | interpretation. For example: |
| 3672 | |
| 3673 | use IO::Handle; |
| 3674 | sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL) |
| 3675 | or die "sysopen $path: $!"; |
| 3676 | $oldfh = select(HANDLE); $| = 1; select($oldfh); |
| 3677 | print HANDLE "stuff $$\n"; |
| 3678 | seek(HANDLE, 0, 0); |
| 3679 | print "File contains: ", <HANDLE>; |
| 3680 | |
| 3681 | Using the constructor from the C<IO::Handle> package (or one of its |
| 3682 | subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous |
| 3683 | filehandles that have the scope of the variables used to hold them, then |
| 3684 | automatically (but silently) close once their reference counts become |
| 3685 | zero, typically at scope exit: |
| 3686 | |
| 3687 | use IO::File; |
| 3688 | #... |
| 3689 | sub read_myfile_munged { |
| 3690 | my $ALL = shift; |
| 3691 | # or just leave it undef to autoviv |
| 3692 | my $handle = IO::File->new; |
| 3693 | open($handle, "<", "myfile") or die "myfile: $!"; |
| 3694 | $first = <$handle> |
| 3695 | or return (); # Automatically closed here. |
| 3696 | mung($first) or die "mung failed"; # Or here. |
| 3697 | return (first, <$handle>) if $ALL; # Or here. |
| 3698 | return $first; # Or here. |
| 3699 | } |
| 3700 | |
| 3701 | B<WARNING:> The previous example has a bug because the automatic |
| 3702 | close that happens when the refcount on C<handle> does not |
| 3703 | properly detect and report failures. I<Always> close the handle |
| 3704 | yourself and inspect the return value. |
| 3705 | |
| 3706 | close($handle) |
| 3707 | || warn "close failed: $!"; |
| 3708 | |
| 3709 | See L</seek> for some details about mixing reading and writing. |
| 3710 | |
| 3711 | =item opendir DIRHANDLE,EXPR |
| 3712 | X<opendir> |
| 3713 | |
| 3714 | Opens a directory named EXPR for processing by C<readdir>, C<telldir>, |
| 3715 | C<seekdir>, C<rewinddir>, and C<closedir>. Returns true if successful. |
| 3716 | DIRHANDLE may be an expression whose value can be used as an indirect |
| 3717 | dirhandle, usually the real dirhandle name. If DIRHANDLE is an undefined |
| 3718 | scalar variable (or array or hash element), the variable is assigned a |
| 3719 | reference to a new anonymous dirhandle; that is, it's autovivified. |
| 3720 | DIRHANDLEs have their own namespace separate from FILEHANDLEs. |
| 3721 | |
| 3722 | See the example at C<readdir>. |
| 3723 | |
| 3724 | =item ord EXPR |
| 3725 | X<ord> X<encoding> |
| 3726 | |
| 3727 | =item ord |
| 3728 | |
| 3729 | Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC, |
| 3730 | or Unicode) value of the first character of EXPR. |
| 3731 | If EXPR is an empty string, returns 0. If EXPR is omitted, uses C<$_>. |
| 3732 | (Note I<character>, not byte.) |
| 3733 | |
| 3734 | For the reverse, see L</chr>. |
| 3735 | See L<perlunicode> for more about Unicode. |
| 3736 | |
| 3737 | =item our EXPR |
| 3738 | X<our> X<global> |
| 3739 | |
| 3740 | =item our TYPE EXPR |
| 3741 | |
| 3742 | =item our EXPR : ATTRS |
| 3743 | |
| 3744 | =item our TYPE EXPR : ATTRS |
| 3745 | |
| 3746 | C<our> associates a simple name with a package variable in the current |
| 3747 | package for use within the current scope. When C<use strict 'vars'> is in |
| 3748 | effect, C<our> lets you use declared global variables without qualifying |
| 3749 | them with package names, within the lexical scope of the C<our> declaration. |
| 3750 | In this way C<our> differs from C<use vars>, which is package-scoped. |
| 3751 | |
| 3752 | Unlike C<my> or C<state>, which allocates storage for a variable and |
| 3753 | associates a simple name with that storage for use within the current |
| 3754 | scope, C<our> associates a simple name with a package (read: global) |
| 3755 | variable in the current package, for use within the current lexical scope. |
| 3756 | In other words, C<our> has the same scoping rules as C<my> or C<state>, but |
| 3757 | does not necessarily create a variable. |
| 3758 | |
| 3759 | If more than one value is listed, the list must be placed |
| 3760 | in parentheses. |
| 3761 | |
| 3762 | our $foo; |
| 3763 | our($bar, $baz); |
| 3764 | |
| 3765 | An C<our> declaration declares a global variable that will be visible |
| 3766 | across its entire lexical scope, even across package boundaries. The |
| 3767 | package in which the variable is entered is determined at the point |
| 3768 | of the declaration, not at the point of use. This means the following |
| 3769 | behavior holds: |
| 3770 | |
| 3771 | package Foo; |
| 3772 | our $bar; # declares $Foo::bar for rest of lexical scope |
| 3773 | $bar = 20; |
| 3774 | |
| 3775 | package Bar; |
| 3776 | print $bar; # prints 20, as it refers to $Foo::bar |
| 3777 | |
| 3778 | Multiple C<our> declarations with the same name in the same lexical |
| 3779 | scope are allowed if they are in different packages. If they happen |
| 3780 | to be in the same package, Perl will emit warnings if you have asked |
| 3781 | for them, just like multiple C<my> declarations. Unlike a second |
| 3782 | C<my> declaration, which will bind the name to a fresh variable, a |
| 3783 | second C<our> declaration in the same package, in the same scope, is |
| 3784 | merely redundant. |
| 3785 | |
| 3786 | use warnings; |
| 3787 | package Foo; |
| 3788 | our $bar; # declares $Foo::bar for rest of lexical scope |
| 3789 | $bar = 20; |
| 3790 | |
| 3791 | package Bar; |
| 3792 | our $bar = 30; # declares $Bar::bar for rest of lexical scope |
| 3793 | print $bar; # prints 30 |
| 3794 | |
| 3795 | our $bar; # emits warning but has no other effect |
| 3796 | print $bar; # still prints 30 |
| 3797 | |
| 3798 | An C<our> declaration may also have a list of attributes associated |
| 3799 | with it. |
| 3800 | |
| 3801 | The exact semantics and interface of TYPE and ATTRS are still |
| 3802 | evolving. TYPE is currently bound to the use of C<fields> pragma, |
| 3803 | and attributes are handled using the C<attributes> pragma, or starting |
| 3804 | from Perl 5.8.0 also via the C<Attribute::Handlers> module. See |
| 3805 | L<perlsub/"Private Variables via my()"> for details, and L<fields>, |
| 3806 | L<attributes>, and L<Attribute::Handlers>. |
| 3807 | |
| 3808 | =item pack TEMPLATE,LIST |
| 3809 | X<pack> |
| 3810 | |
| 3811 | Takes a LIST of values and converts it into a string using the rules |
| 3812 | given by the TEMPLATE. The resulting string is the concatenation of |
| 3813 | the converted values. Typically, each converted value looks |
| 3814 | like its machine-level representation. For example, on 32-bit machines |
| 3815 | an integer may be represented by a sequence of 4 bytes, which will in |
| 3816 | Perl be presented as a string that's 4 characters long. |
| 3817 | |
| 3818 | See L<perlpacktut> for an introduction to this function. |
| 3819 | |
| 3820 | The TEMPLATE is a sequence of characters that give the order and type |
| 3821 | of values, as follows: |
| 3822 | |
| 3823 | a A string with arbitrary binary data, will be null padded. |
| 3824 | A A text (ASCII) string, will be space padded. |
| 3825 | Z A null-terminated (ASCIZ) string, will be null padded. |
| 3826 | |
| 3827 | b A bit string (ascending bit order inside each byte, like vec()). |
| 3828 | B A bit string (descending bit order inside each byte). |
| 3829 | h A hex string (low nybble first). |
| 3830 | H A hex string (high nybble first). |
| 3831 | |
| 3832 | c A signed char (8-bit) value. |
| 3833 | C An unsigned char (octet) value. |
| 3834 | W An unsigned char value (can be greater than 255). |
| 3835 | |
| 3836 | s A signed short (16-bit) value. |
| 3837 | S An unsigned short value. |
| 3838 | |
| 3839 | l A signed long (32-bit) value. |
| 3840 | L An unsigned long value. |
| 3841 | |
| 3842 | q A signed quad (64-bit) value. |
| 3843 | Q An unsigned quad value. |
| 3844 | (Quads are available only if your system supports 64-bit |
| 3845 | integer values _and_ if Perl has been compiled to support those. |
| 3846 | Raises an exception otherwise.) |
| 3847 | |
| 3848 | i A signed integer value. |
| 3849 | I A unsigned integer value. |
| 3850 | (This 'integer' is _at_least_ 32 bits wide. Its exact |
| 3851 | size depends on what a local C compiler calls 'int'.) |
| 3852 | |
| 3853 | n An unsigned short (16-bit) in "network" (big-endian) order. |
| 3854 | N An unsigned long (32-bit) in "network" (big-endian) order. |
| 3855 | v An unsigned short (16-bit) in "VAX" (little-endian) order. |
| 3856 | V An unsigned long (32-bit) in "VAX" (little-endian) order. |
| 3857 | |
| 3858 | j A Perl internal signed integer value (IV). |
| 3859 | J A Perl internal unsigned integer value (UV). |
| 3860 | |
| 3861 | f A single-precision float in native format. |
| 3862 | d A double-precision float in native format. |
| 3863 | |
| 3864 | F A Perl internal floating-point value (NV) in native format |
| 3865 | D A float of long-double precision in native format. |
| 3866 | (Long doubles are available only if your system supports long |
| 3867 | double values _and_ if Perl has been compiled to support those. |
| 3868 | Raises an exception otherwise.) |
| 3869 | |
| 3870 | p A pointer to a null-terminated string. |
| 3871 | P A pointer to a structure (fixed-length string). |
| 3872 | |
| 3873 | u A uuencoded string. |
| 3874 | U A Unicode character number. Encodes to a character in character mode |
| 3875 | and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in byte mode. |
| 3876 | |
| 3877 | w A BER compressed integer (not an ASN.1 BER, see perlpacktut for |
| 3878 | details). Its bytes represent an unsigned integer in base 128, |
| 3879 | most significant digit first, with as few digits as possible. Bit |
| 3880 | eight (the high bit) is set on each byte except the last. |
| 3881 | |
| 3882 | x A null byte (a.k.a ASCII NUL, "\000", chr(0)) |
| 3883 | X Back up a byte. |
| 3884 | @ Null-fill or truncate to absolute position, counted from the |
| 3885 | start of the innermost ()-group. |
| 3886 | . Null-fill or truncate to absolute position specified by the value. |
| 3887 | ( Start of a ()-group. |
| 3888 | |
| 3889 | One or more modifiers below may optionally follow certain letters in the |
| 3890 | TEMPLATE (the second column lists letters for which the modifier is valid): |
| 3891 | |
| 3892 | ! sSlLiI Forces native (short, long, int) sizes instead |
| 3893 | of fixed (16-/32-bit) sizes. |
| 3894 | |
| 3895 | xX Make x and X act as alignment commands. |
| 3896 | |
| 3897 | nNvV Treat integers as signed instead of unsigned. |
| 3898 | |
| 3899 | @. Specify position as byte offset in the internal |
| 3900 | representation of the packed string. Efficient but |
| 3901 | dangerous. |
| 3902 | |
| 3903 | > sSiIlLqQ Force big-endian byte-order on the type. |
| 3904 | jJfFdDpP (The "big end" touches the construct.) |
| 3905 | |
| 3906 | < sSiIlLqQ Force little-endian byte-order on the type. |
| 3907 | jJfFdDpP (The "little end" touches the construct.) |
| 3908 | |
| 3909 | The C<< > >> and C<< < >> modifiers can also be used on C<()> groups |
| 3910 | to force a particular byte-order on all components in that group, |
| 3911 | including all its subgroups. |
| 3912 | |
| 3913 | The following rules apply: |
| 3914 | |
| 3915 | =over |
| 3916 | |
| 3917 | =item * |
| 3918 | |
| 3919 | Each letter may optionally be followed by a number indicating the repeat |
| 3920 | count. A numeric repeat count may optionally be enclosed in brackets, as |
| 3921 | in C<pack("C[80]", @arr)>. The repeat count gobbles that many values from |
| 3922 | the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>, |
| 3923 | C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means |
| 3924 | something else, dscribed below. Supplying a C<*> for the repeat count |
| 3925 | instead of a number means to use however many items are left, except for: |
| 3926 | |
| 3927 | =over |
| 3928 | |
| 3929 | =item * |
| 3930 | |
| 3931 | C<@>, C<x>, and C<X>, where it is equivalent to C<0>. |
| 3932 | |
| 3933 | =item * |
| 3934 | |
| 3935 | <.>, where it means relative to the start of the string. |
| 3936 | |
| 3937 | =item * |
| 3938 | |
| 3939 | C<u>, where it is equivalent to 1 (or 45, which here is equivalent). |
| 3940 | |
| 3941 | =back |
| 3942 | |
| 3943 | One can replace a numeric repeat count with a template letter enclosed in |
| 3944 | brackets to use the packed byte length of the bracketed template for the |
| 3945 | repeat count. |
| 3946 | |
| 3947 | For example, the template C<x[L]> skips as many bytes as in a packed long, |
| 3948 | and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when |
| 3949 | variable-expanded) unpacks. If the template in brackets contains alignment |
| 3950 | commands (such as C<x![d]>), its packed length is calculated as if the |
| 3951 | start of the template had the maximal possible alignment. |
| 3952 | |
| 3953 | When used with C<Z>, a C<*> as the repeat count is guaranteed to add a |
| 3954 | trailing null byte, so the resulting string is always one byte longer than |
| 3955 | the byte length of the item itself. |
| 3956 | |
| 3957 | When used with C<@>, the repeat count represents an offset from the start |
| 3958 | of the innermost C<()> group. |
| 3959 | |
| 3960 | When used with C<.>, the repeat count determines the starting position to |
| 3961 | calculate the value offset as follows: |
| 3962 | |
| 3963 | =over |
| 3964 | |
| 3965 | =item * |
| 3966 | |
| 3967 | If the repeat count is C<0>, it's relative to the current position. |
| 3968 | |
| 3969 | =item * |
| 3970 | |
| 3971 | If the repeat count is C<*>, the offset is relative to the start of the |
| 3972 | packed string. |
| 3973 | |
| 3974 | =item * |
| 3975 | |
| 3976 | And if it's an integer I<n>, the offset is relative to the start of the |
| 3977 | I<n>th innermost C<( )> group, or to the start of the string if I<n> is |
| 3978 | bigger then the group level. |
| 3979 | |
| 3980 | =back |
| 3981 | |
| 3982 | The repeat count for C<u> is interpreted as the maximal number of bytes |
| 3983 | to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat |
| 3984 | count should not be more than 65. |
| 3985 | |
| 3986 | =item * |
| 3987 | |
| 3988 | The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a |
| 3989 | string of length count, padding with nulls or spaces as needed. When |
| 3990 | unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything |
| 3991 | after the first null, and C<a> returns data with no stripping at all. |
| 3992 | |
| 3993 | If the value to pack is too long, the result is truncated. If it's too |
| 3994 | long and an explicit count is provided, C<Z> packs only C<$count-1> bytes, |
| 3995 | followed by a null byte. Thus C<Z> always packs a trailing null, except |
| 3996 | when the count is 0. |
| 3997 | |
| 3998 | =item * |
| 3999 | |
| 4000 | Likewise, the C<b> and C<B> formats pack a string that's that many bits long. |
| 4001 | Each such format generates 1 bit of the result. These are typically followed |
| 4002 | by a repeat count like C<B8> or C<B64>. |
| 4003 | |
| 4004 | Each result bit is based on the least-significant bit of the corresponding |
| 4005 | input character, i.e., on C<ord($char)%2>. In particular, characters C<"0"> |
| 4006 | and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">. |
| 4007 | |
| 4008 | Starting from the beginning of the input string, each 8-tuple |
| 4009 | of characters is converted to 1 character of output. With format C<b>, |
| 4010 | the first character of the 8-tuple determines the least-significant bit of a |
| 4011 | character; with format C<B>, it determines the most-significant bit of |
| 4012 | a character. |
| 4013 | |
| 4014 | If the length of the input string is not evenly divisible by 8, the |
| 4015 | remainder is packed as if the input string were padded by null characters |
| 4016 | at the end. Similarly during unpacking, "extra" bits are ignored. |
| 4017 | |
| 4018 | If the input string is longer than needed, remaining characters are ignored. |
| 4019 | |
| 4020 | A C<*> for the repeat count uses all characters of the input field. |
| 4021 | On unpacking, bits are converted to a string of C<0>s and C<1>s. |
| 4022 | |
| 4023 | =item * |
| 4024 | |
| 4025 | The C<h> and C<H> formats pack a string that many nybbles (4-bit groups, |
| 4026 | representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long. |
| 4027 | |
| 4028 | For each such format, pack() generates 4 bits of result. |
| 4029 | With non-alphabetical characters, the result is based on the 4 least-significant |
| 4030 | bits of the input character, i.e., on C<ord($char)%16>. In particular, |
| 4031 | characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes |
| 4032 | C<"\000"> and C<"\001">. For characters C<"a".."f"> and C<"A".."F">, the result |
| 4033 | is compatible with the usual hexadecimal digits, so that C<"a"> and |
| 4034 | C<"A"> both generate the nybble C<0xA==10>. Use only these specific hex |
| 4035 | characters with this format. |
| 4036 | |
| 4037 | Starting from the beginning of the template to pack(), each pair |
| 4038 | of characters is converted to 1 character of output. With format C<h>, the |
| 4039 | first character of the pair determines the least-significant nybble of the |
| 4040 | output character; with format C<H>, it determines the most-significant |
| 4041 | nybble. |
| 4042 | |
| 4043 | If the length of the input string is not even, it behaves as if padded by |
| 4044 | a null character at the end. Similarly, "extra" nybbles are ignored during |
| 4045 | unpacking. |
| 4046 | |
| 4047 | If the input string is longer than needed, extra characters are ignored. |
| 4048 | |
| 4049 | A C<*> for the repeat count uses all characters of the input field. For |
| 4050 | unpack(), nybbles are converted to a string of hexadecimal digits. |
| 4051 | |
| 4052 | =item * |
| 4053 | |
| 4054 | The C<p> format packs a pointer to a null-terminated string. You are |
| 4055 | responsible for ensuring that the string is not a temporary value, as that |
| 4056 | could potentially get deallocated before you got around to using the packed |
| 4057 | result. The C<P> format packs a pointer to a structure of the size indicated |
| 4058 | by the length. A null pointer is created if the corresponding value for |
| 4059 | C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer |
| 4060 | unpacks into C<undef>. |
| 4061 | |
| 4062 | If your system has a strange pointer size--meaning a pointer is neither as |
| 4063 | big as an int nor as big as a long--it may not be possible to pack or |
| 4064 | unpack pointers in big- or little-endian byte order. Attempting to do |
| 4065 | so raises an exception. |
| 4066 | |
| 4067 | =item * |
| 4068 | |
| 4069 | The C</> template character allows packing and unpacking of a sequence of |
| 4070 | items where the packed structure contains a packed item count followed by |
| 4071 | the packed items themselves. This is useful when the structure you're |
| 4072 | unpacking has encoded the sizes or repeat counts for some of its fields |
| 4073 | within the structure itself as separate fields. |
| 4074 | |
| 4075 | For C<pack>, you write I<length-item>C</>I<sequence-item>, and the |
| 4076 | I<length-item> describes how the length value is packed. Formats likely |
| 4077 | to be of most use are integer-packing ones like C<n> for Java strings, |
| 4078 | C<w> for ASN.1 or SNMP, and C<N> for Sun XDR. |
| 4079 | |
| 4080 | For C<pack>, I<sequence-item> may have a repeat count, in which case |
| 4081 | the minimum of that and the number of available items is used as the argument |
| 4082 | for I<length-item>. If it has no repeat count or uses a '*', the number |
| 4083 | of available items is used. |
| 4084 | |
| 4085 | For C<unpack>, an internal stack of integer arguments unpacked so far is |
| 4086 | used. You write C</>I<sequence-item> and the repeat count is obtained by |
| 4087 | popping off the last element from the stack. The I<sequence-item> must not |
| 4088 | have a repeat count. |
| 4089 | |
| 4090 | If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">), |
| 4091 | the I<length-item> is the string length, not the number of strings. With |
| 4092 | an explicit repeat count for pack, the packed string is adjusted to that |
| 4093 | length. For example: |
| 4094 | |
| 4095 | unpack("W/a", "\004Gurusamy") gives ("Guru") |
| 4096 | unpack("a3/A A*", "007 Bond J ") gives (" Bond", "J") |
| 4097 | unpack("a3 x2 /A A*", "007: Bond, J.") gives ("Bond, J", ".") |
| 4098 | |
| 4099 | pack("n/a* w/a","hello,","world") gives "\000\006hello,\005world" |
| 4100 | pack("a/W2", ord("a") .. ord("z")) gives "2ab" |
| 4101 | |
| 4102 | The I<length-item> is not returned explicitly from C<unpack>. |
| 4103 | |
| 4104 | Supplying a count to the I<length-item> format letter is only useful with |
| 4105 | C<A>, C<a>, or C<Z>. Packing with a I<length-item> of C<a> or C<Z> may |
| 4106 | introduce C<"\000"> characters, which Perl does not regard as legal in |
| 4107 | numeric strings. |
| 4108 | |
| 4109 | =item * |
| 4110 | |
| 4111 | The integer types C<s>, C<S>, C<l>, and C<L> may be |
| 4112 | followed by a C<!> modifier to specify native shorts or |
| 4113 | longs. As shown in the example above, a bare C<l> means |
| 4114 | exactly 32 bits, although the native C<long> as seen by the local C compiler |
| 4115 | may be larger. This is mainly an issue on 64-bit platforms. You can |
| 4116 | see whether using C<!> makes any difference this way: |
| 4117 | |
| 4118 | printf "format s is %d, s! is %d\n", |
| 4119 | length pack("s"), length pack("s!"); |
| 4120 | |
| 4121 | printf "format l is %d, l! is %d\n", |
| 4122 | length pack("l"), length pack("l!"); |
| 4123 | |
| 4124 | |
| 4125 | C<i!> and C<I!> are also allowed, but only for completeness' sake: |
| 4126 | they are identical to C<i> and C<I>. |
| 4127 | |
| 4128 | The actual sizes (in bytes) of native shorts, ints, longs, and long |
| 4129 | longs on the platform where Perl was built are also available from |
| 4130 | the command line: |
| 4131 | |
| 4132 | $ perl -V:{short,int,long{,long}}size |
| 4133 | shortsize='2'; |
| 4134 | intsize='4'; |
| 4135 | longsize='4'; |
| 4136 | longlongsize='8'; |
| 4137 | |
| 4138 | or programmatically via the C<Config> module: |
| 4139 | |
| 4140 | use Config; |
| 4141 | print $Config{shortsize}, "\n"; |
| 4142 | print $Config{intsize}, "\n"; |
| 4143 | print $Config{longsize}, "\n"; |
| 4144 | print $Config{longlongsize}, "\n"; |
| 4145 | |
| 4146 | C<$Config{longlongsize}> is undefined on systems without |
| 4147 | long long support. |
| 4148 | |
| 4149 | =item * |
| 4150 | |
| 4151 | The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are |
| 4152 | inherently non-portable between processors and operating systems because |
| 4153 | they obey native byteorder and endianness. For example, a 4-byte integer |
| 4154 | 0x12345678 (305419896 decimal) would be ordered natively (arranged in and |
| 4155 | handled by the CPU registers) into bytes as |
| 4156 | |
| 4157 | 0x12 0x34 0x56 0x78 # big-endian |
| 4158 | 0x78 0x56 0x34 0x12 # little-endian |
| 4159 | |
| 4160 | Basically, Intel and VAX CPUs are little-endian, while everybody else, |
| 4161 | including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are |
| 4162 | big-endian. Alpha and MIPS can be either: Digital/Compaq uses (well, used) |
| 4163 | them in little-endian mode, but SGI/Cray uses them in big-endian mode. |
| 4164 | |
| 4165 | The names I<big-endian> and I<little-endian> are comic references to the |
| 4166 | egg-eating habits of the little-endian Lilliputians and the big-endian |
| 4167 | Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>. |
| 4168 | This entered computer lingo via the paper "On Holy Wars and a Plea for |
| 4169 | Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980. |
| 4170 | |
| 4171 | Some systems may have even weirder byte orders such as |
| 4172 | |
| 4173 | 0x56 0x78 0x12 0x34 |
| 4174 | 0x34 0x12 0x78 0x56 |
| 4175 | |
| 4176 | You can determine your system endianness with this incantation: |
| 4177 | |
| 4178 | printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); |
| 4179 | |
| 4180 | The byteorder on the platform where Perl was built is also available |
| 4181 | via L<Config>: |
| 4182 | |
| 4183 | use Config; |
| 4184 | print "$Config{byteorder}\n"; |
| 4185 | |
| 4186 | or from the command line: |
| 4187 | |
| 4188 | $ perl -V:byteorder |
| 4189 | |
| 4190 | Byteorders C<"1234"> and C<"12345678"> are little-endian; C<"4321"> |
| 4191 | and C<"87654321"> are big-endian. |
| 4192 | |
| 4193 | For portably packed integers, either use the formats C<n>, C<N>, C<v>, |
| 4194 | and C<V> or else use the C<< > >> and C<< < >> modifiers described |
| 4195 | immediately below. See also L<perlport>. |
| 4196 | |
| 4197 | =item * |
| 4198 | |
| 4199 | Starting with Perl 5.9.2, integer and floating-point formats, along with |
| 4200 | the C<p> and C<P> formats and C<()> groups, may all be followed by the |
| 4201 | C<< > >> or C<< < >> endianness modifiers to respectively enforce big- |
| 4202 | or little-endian byte-order. These modifiers are especially useful |
| 4203 | given how C<n>, C<N>, C<v>, and C<V> don't cover signed integers, |
| 4204 | 64-bit integers, or floating-point values. |
| 4205 | |
| 4206 | Here are some concerns to keep in mind when using an endianness modifier: |
| 4207 | |
| 4208 | =over |
| 4209 | |
| 4210 | =item * |
| 4211 | |
| 4212 | Exchanging signed integers between different platforms works only |
| 4213 | when all platforms store them in the same format. Most platforms store |
| 4214 | signed integers in two's-complement notation, so usually this is not an issue. |
| 4215 | |
| 4216 | =item * |
| 4217 | |
| 4218 | The C<< > >> or C<< < >> modifiers can only be used on floating-point |
| 4219 | formats on big- or little-endian machines. Otherwise, attempting to |
| 4220 | use them raises an exception. |
| 4221 | |
| 4222 | =item * |
| 4223 | |
| 4224 | Forcing big- or little-endian byte-order on floating-point values for |
| 4225 | data exchange can work only if all platforms use the same |
| 4226 | binary representation such as IEEE floating-point. Even if all |
| 4227 | platforms are using IEEE, there may still be subtle differences. Being able |
| 4228 | to use C<< > >> or C<< < >> on floating-point values can be useful, |
| 4229 | but also dangerous if you don't know exactly what you're doing. |
| 4230 | It is not a general way to portably store floating-point values. |
| 4231 | |
| 4232 | =item * |
| 4233 | |
| 4234 | When using C<< > >> or C<< < >> on a C<()> group, this affects |
| 4235 | all types inside the group that accept byte-order modifiers, |
| 4236 | including all subgroups. It is silently ignored for all other |
| 4237 | types. You are not allowed to override the byte-order within a group |
| 4238 | that already has a byte-order modifier suffix. |
| 4239 | |
| 4240 | =back |
| 4241 | |
| 4242 | =item * |
| 4243 | |
| 4244 | Real numbers (floats and doubles) are in native machine format only. |
| 4245 | Due to the multiplicity of floating-point formats and the lack of a |
| 4246 | standard "network" representation for them, no facility for interchange has been |
| 4247 | made. This means that packed floating-point data written on one machine |
| 4248 | may not be readable on another, even if both use IEEE floating-point |
| 4249 | arithmetic (because the endianness of the memory representation is not part |
| 4250 | of the IEEE spec). See also L<perlport>. |
| 4251 | |
| 4252 | If you know I<exactly> what you're doing, you can use the C<< > >> or C<< < >> |
| 4253 | modifiers to force big- or little-endian byte-order on floating-point values. |
| 4254 | |
| 4255 | Because Perl uses doubles (or long doubles, if configured) internally for |
| 4256 | all numeric calculation, converting from double into float and thence |
| 4257 | to double again loses precision, so C<unpack("f", pack("f", $foo)>) |
| 4258 | will not in general equal $foo. |
| 4259 | |
| 4260 | =item * |
| 4261 | |
| 4262 | Pack and unpack can operate in two modes: character mode (C<C0> mode) where |
| 4263 | the packed string is processed per character, and UTF-8 mode (C<U0> mode) |
| 4264 | where the packed string is processed in its UTF-8-encoded Unicode form on |
| 4265 | a byte-by-byte basis. Character mode is the default unless the format string |
| 4266 | starts with C<U>. You can always switch mode mid-format with an explicit |
| 4267 | C<C0> or C<U0> in the format. This mode remains in effect until the next |
| 4268 | mode change, or until the end of the C<()> group it (directly) applies to. |
| 4269 | |
| 4270 | Using C<C0> to get Unicode characters while using C<U0> to get I<non>-Unicode |
| 4271 | bytes is not necessarily obvious. Probably only the first of these |
| 4272 | is what you want: |
| 4273 | |
| 4274 | $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | |
| 4275 | perl -CS -ne 'printf "%v04X\n", $_ for unpack("C0A*", $_)' |
| 4276 | 03B1.03C9 |
| 4277 | $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | |
| 4278 | perl -CS -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)' |
| 4279 | CE.B1.CF.89 |
| 4280 | $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | |
| 4281 | perl -C0 -ne 'printf "%v02X\n", $_ for unpack("C0A*", $_)' |
| 4282 | CE.B1.CF.89 |
| 4283 | $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | |
| 4284 | perl -C0 -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)' |
| 4285 | C3.8E.C2.B1.C3.8F.C2.89 |
| 4286 | |
| 4287 | Those examples also illustrate that you should not try to use |
| 4288 | C<pack>/C<unpack> as a substitute for the L<Encode> module. |
| 4289 | |
| 4290 | =item * |
| 4291 | |
| 4292 | You must yourself do any alignment or padding by inserting, for example, |
| 4293 | enough C<"x">es while packing. There is no way for pack() and unpack() |
| 4294 | to know where characters are going to or coming from, so they |
| 4295 | handle their output and input as flat sequences of characters. |
| 4296 | |
| 4297 | =item * |
| 4298 | |
| 4299 | A C<()> group is a sub-TEMPLATE enclosed in parentheses. A group may |
| 4300 | take a repeat count either as postfix, or for unpack(), also via the C</> |
| 4301 | template character. Within each repetition of a group, positioning with |
| 4302 | C<@> starts over at 0. Therefore, the result of |
| 4303 | |
| 4304 | pack("@1A((@2A)@3A)", qw[X Y Z]) |
| 4305 | |
| 4306 | is the string C<"\0X\0\0YZ">. |
| 4307 | |
| 4308 | =item * |
| 4309 | |
| 4310 | C<x> and C<X> accept the C<!> modifier to act as alignment commands: they |
| 4311 | jump forward or back to the closest position aligned at a multiple of C<count> |
| 4312 | characters. For example, to pack() or unpack() a C structure like |
| 4313 | |
| 4314 | struct { |
| 4315 | char c; /* one signed, 8-bit character */ |
| 4316 | double d; |
| 4317 | char cc[2]; |
| 4318 | } |
| 4319 | |
| 4320 | one may need to use the template C<c x![d] d c[2]>. This assumes that |
| 4321 | doubles must be aligned to the size of double. |
| 4322 | |
| 4323 | For alignment commands, a C<count> of 0 is equivalent to a C<count> of 1; |
| 4324 | both are no-ops. |
| 4325 | |
| 4326 | =item * |
| 4327 | |
| 4328 | C<n>, C<N>, C<v> and C<V> accept the C<!> modifier to |
| 4329 | represent signed 16-/32-bit integers in big-/little-endian order. |
| 4330 | This is portable only when all platforms sharing packed data use the |
| 4331 | same binary representation for signed integers; for example, when all |
| 4332 | platforms use two's-complement representation. |
| 4333 | |
| 4334 | =item * |
| 4335 | |
| 4336 | Comments can be embedded in a TEMPLATE using C<#> through the end of line. |
| 4337 | White space can separate pack codes from each other, but modifiers and |
| 4338 | repeat counts must follow immediately. Breaking complex templates into |
| 4339 | individual line-by-line components, suitably annotated, can do as much to |
| 4340 | improve legibility and maintainability of pack/unpack formats as C</x> can |
| 4341 | for complicated pattern matches. |
| 4342 | |
| 4343 | =item * |
| 4344 | |
| 4345 | If TEMPLATE requires more arguments than pack() is given, pack() |
| 4346 | assumes additional C<""> arguments. If TEMPLATE requires fewer arguments |
| 4347 | than given, extra arguments are ignored. |
| 4348 | |
| 4349 | =back |
| 4350 | |
| 4351 | Examples: |
| 4352 | |
| 4353 | $foo = pack("WWWW",65,66,67,68); |
| 4354 | # foo eq "ABCD" |
| 4355 | $foo = pack("W4",65,66,67,68); |
| 4356 | # same thing |
| 4357 | $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9); |
| 4358 | # same thing with Unicode circled letters. |
| 4359 | $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9); |
| 4360 | # same thing with Unicode circled letters. You don't get the UTF-8 |
| 4361 | # bytes because the U at the start of the format caused a switch to |
| 4362 | # U0-mode, so the UTF-8 bytes get joined into characters |
| 4363 | $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9); |
| 4364 | # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9" |
| 4365 | # This is the UTF-8 encoding of the string in the previous example |
| 4366 | |
| 4367 | $foo = pack("ccxxcc",65,66,67,68); |
| 4368 | # foo eq "AB\0\0CD" |
| 4369 | |
| 4370 | # NOTE: The examples above featuring "W" and "c" are true |
| 4371 | # only on ASCII and ASCII-derived systems such as ISO Latin 1 |
| 4372 | # and UTF-8. On EBCDIC systems, the first example would be |
| 4373 | # $foo = pack("WWWW",193,194,195,196); |
| 4374 | |
| 4375 | $foo = pack("s2",1,2); |
| 4376 | # "\001\000\002\000" on little-endian |
| 4377 | # "\000\001\000\002" on big-endian |
| 4378 | |
| 4379 | $foo = pack("a4","abcd","x","y","z"); |
| 4380 | # "abcd" |
| 4381 | |
| 4382 | $foo = pack("aaaa","abcd","x","y","z"); |
| 4383 | # "axyz" |
| 4384 | |
| 4385 | $foo = pack("a14","abcdefg"); |
| 4386 | # "abcdefg\0\0\0\0\0\0\0" |
| 4387 | |
| 4388 | $foo = pack("i9pl", gmtime); |
| 4389 | # a real struct tm (on my system anyway) |
| 4390 | |
| 4391 | $utmp_template = "Z8 Z8 Z16 L"; |
| 4392 | $utmp = pack($utmp_template, @utmp1); |
| 4393 | # a struct utmp (BSDish) |
| 4394 | |
| 4395 | @utmp2 = unpack($utmp_template, $utmp); |
| 4396 | # "@utmp1" eq "@utmp2" |
| 4397 | |
| 4398 | sub bintodec { |
| 4399 | unpack("N", pack("B32", substr("0" x 32 . shift, -32))); |
| 4400 | } |
| 4401 | |
| 4402 | $foo = pack('sx2l', 12, 34); |
| 4403 | # short 12, two zero bytes padding, long 34 |
| 4404 | $bar = pack('s@4l', 12, 34); |
| 4405 | # short 12, zero fill to position 4, long 34 |
| 4406 | # $foo eq $bar |
| 4407 | $baz = pack('s.l', 12, 4, 34); |
| 4408 | # short 12, zero fill to position 4, long 34 |
| 4409 | |
| 4410 | $foo = pack('nN', 42, 4711); |
| 4411 | # pack big-endian 16- and 32-bit unsigned integers |
| 4412 | $foo = pack('S>L>', 42, 4711); |
| 4413 | # exactly the same |
| 4414 | $foo = pack('s<l<', -42, 4711); |
| 4415 | # pack little-endian 16- and 32-bit signed integers |
| 4416 | $foo = pack('(sl)<', -42, 4711); |
| 4417 | # exactly the same |
| 4418 | |
| 4419 | The same template may generally also be used in unpack(). |
| 4420 | |
| 4421 | =item package NAMESPACE |
| 4422 | |
| 4423 | =item package NAMESPACE VERSION |
| 4424 | X<package> X<module> X<namespace> X<version> |
| 4425 | |
| 4426 | =item package NAMESPACE BLOCK |
| 4427 | |
| 4428 | =item package NAMESPACE VERSION BLOCK |
| 4429 | X<package> X<module> X<namespace> X<version> |
| 4430 | |
| 4431 | Declares the BLOCK or the rest of the compilation unit as being in the |
| 4432 | given namespace. The scope of the package declaration is either the |
| 4433 | supplied code BLOCK or, in the absence of a BLOCK, from the declaration |
| 4434 | itself through the end of current scope (the enclosing block, file, or |
| 4435 | C<eval>). That is, the forms without a BLOCK are operative through the end |
| 4436 | of the current scope, just like the C<my>, C<state>, and C<our> operators. |
| 4437 | All unqualified dynamic identifiers in this scope will be in the given |
| 4438 | namespace, except where overridden by another C<package> declaration or |
| 4439 | when they're one of the special identifiers that qualify into C<main::>, |
| 4440 | like C<STDOUT>, C<ARGV>, C<ENV>, and the punctuation variables. |
| 4441 | |
| 4442 | A package statement affects dynamic variables only, including those |
| 4443 | you've used C<local> on, but I<not> lexical variables, which are created |
| 4444 | with C<my>, C<state>, or C<our>. Typically it would be the first |
| 4445 | declaration in a file included by C<require> or C<use>. You can switch into a |
| 4446 | package in more than one place, since this only determines which default |
| 4447 | symbol table the compiler uses for the rest of that block. You can refer to |
| 4448 | identifiers in other packages than the current one by prefixing the identifier |
| 4449 | with the package name and a double colon, as in C<$SomePack::var> |
| 4450 | or C<ThatPack::INPUT_HANDLE>. If package name is omitted, the C<main> |
| 4451 | package as assumed. That is, C<$::sail> is equivalent to |
| 4452 | C<$main::sail> (as well as to C<$main'sail>, still seen in ancient |
| 4453 | code, mostly from Perl 4). |
| 4454 | |
| 4455 | If VERSION is provided, C<package> sets the C<$VERSION> variable in the given |
| 4456 | namespace to a L<version> object with the VERSION provided. VERSION must be a |
| 4457 | "strict" style version number as defined by the L<version> module: a positive |
| 4458 | decimal number (integer or decimal-fraction) without exponentiation or else a |
| 4459 | dotted-decimal v-string with a leading 'v' character and at least three |
| 4460 | components. You should set C<$VERSION> only once per package. |
| 4461 | |
| 4462 | See L<perlmod/"Packages"> for more information about packages, modules, |
| 4463 | and classes. See L<perlsub> for other scoping issues. |
| 4464 | |
| 4465 | =item pipe READHANDLE,WRITEHANDLE |
| 4466 | X<pipe> |
| 4467 | |
| 4468 | Opens a pair of connected pipes like the corresponding system call. |
| 4469 | Note that if you set up a loop of piped processes, deadlock can occur |
| 4470 | unless you are very careful. In addition, note that Perl's pipes use |
| 4471 | IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE |
| 4472 | after each command, depending on the application. |
| 4473 | |
| 4474 | See L<IPC::Open2>, L<IPC::Open3>, and |
| 4475 | L<perlipc/"Bidirectional Communication with Another Process"> |
| 4476 | for examples of such things. |
| 4477 | |
| 4478 | On systems that support a close-on-exec flag on files, that flag is set |
| 4479 | on all newly opened file descriptors whose C<fileno>s are I<higher> than |
| 4480 | the current value of $^F (by default 2 for C<STDERR>). See L<perlvar/$^F>. |
| 4481 | |
| 4482 | =item pop ARRAY |
| 4483 | X<pop> X<stack> |
| 4484 | |
| 4485 | =item pop EXPR |
| 4486 | |
| 4487 | =item pop |
| 4488 | |
| 4489 | Pops and returns the last value of the array, shortening the array by |
| 4490 | one element. |
| 4491 | |
| 4492 | Returns the undefined value if the array is empty, although this may also |
| 4493 | happen at other times. If ARRAY is omitted, pops the C<@ARGV> array in the |
| 4494 | main program, but the C<@_> array in subroutines, just like C<shift>. |
| 4495 | |
| 4496 | Starting with Perl 5.14, C<pop> can take a scalar EXPR, which must hold a |
| 4497 | reference to an unblessed array. The argument will be dereferenced |
| 4498 | automatically. This aspect of C<pop> is considered highly experimental. |
| 4499 | The exact behaviour may change in a future version of Perl. |
| 4500 | |
| 4501 | =item pos SCALAR |
| 4502 | X<pos> X<match, position> |
| 4503 | |
| 4504 | =item pos |
| 4505 | |
| 4506 | Returns the offset of where the last C<m//g> search left off for the |
| 4507 | variable in question (C<$_> is used when the variable is not |
| 4508 | specified). Note that 0 is a valid match offset. C<undef> indicates |
| 4509 | that the search position is reset (usually due to match failure, but |
| 4510 | can also be because no match has yet been run on the scalar). |
| 4511 | |
| 4512 | C<pos> directly accesses the location used by the regexp engine to |
| 4513 | store the offset, so assigning to C<pos> will change that offset, and |
| 4514 | so will also influence the C<\G> zero-width assertion in regular |
| 4515 | expressions. Both of these effects take place for the next match, so |
| 4516 | you can't affect the position with C<pos> during the current match, |
| 4517 | such as in C<(?{pos() = 5})> or C<s//pos() = 5/e>. |
| 4518 | |
| 4519 | Setting C<pos> also resets the I<matched with zero-length> flag, described |
| 4520 | under L<perlre/"Repeated Patterns Matching a Zero-length Substring">. |
| 4521 | |
| 4522 | Because a failed C<m//gc> match doesn't reset the offset, the return |
| 4523 | from C<pos> won't change either in this case. See L<perlre> and |
| 4524 | L<perlop>. |
| 4525 | |
| 4526 | =item print FILEHANDLE LIST |
| 4527 | X<print> |
| 4528 | |
| 4529 | =item print FILEHANDLE |
| 4530 | |
| 4531 | =item print LIST |
| 4532 | |
| 4533 | =item print |
| 4534 | |
| 4535 | Prints a string or a list of strings. Returns true if successful. |
| 4536 | FILEHANDLE may be a scalar variable containing the name of or a reference |
| 4537 | to the filehandle, thus introducing one level of indirection. (NOTE: If |
| 4538 | FILEHANDLE is a variable and the next token is a term, it may be |
| 4539 | misinterpreted as an operator unless you interpose a C<+> or put |
| 4540 | parentheses around the arguments.) If FILEHANDLE is omitted, prints to the |
| 4541 | last selected (see L</select>) output handle. If LIST is omitted, prints |
| 4542 | C<$_> to the currently selected output handle. To use FILEHANDLE alone to |
| 4543 | print the content of C<$_> to it, you must use a real filehandle like |
| 4544 | C<FH>, not an indirect one like C<$fh>. To set the default output handle |
| 4545 | to something other than STDOUT, use the select operation. |
| 4546 | |
| 4547 | The current value of C<$,> (if any) is printed between each LIST item. The |
| 4548 | current value of C<$\> (if any) is printed after the entire LIST has been |
| 4549 | printed. Because print takes a LIST, anything in the LIST is evaluated in |
| 4550 | list context, including any subroutines whose return lists you pass to |
| 4551 | C<print>. Be careful not to follow the print keyword with a left |
| 4552 | parenthesis unless you want the corresponding right parenthesis to |
| 4553 | terminate the arguments to the print; put parentheses around all arguments |
| 4554 | (or interpose a C<+>, but that doesn't look as good). |
| 4555 | |
| 4556 | If you're storing handles in an array or hash, or in general whenever |
| 4557 | you're using any expression more complex than a bareword handle or a plain, |
| 4558 | unsubscripted scalar variable to retrieve it, you will have to use a block |
| 4559 | returning the filehandle value instead, in which case the LIST may not be |
| 4560 | omitted: |
| 4561 | |
| 4562 | print { $files[$i] } "stuff\n"; |
| 4563 | print { $OK ? STDOUT : STDERR } "stuff\n"; |
| 4564 | |
| 4565 | Printing to a closed pipe or socket will generate a SIGPIPE signal. See |
| 4566 | L<perlipc> for more on signal handling. |
| 4567 | |
| 4568 | =item printf FILEHANDLE FORMAT, LIST |
| 4569 | X<printf> |
| 4570 | |
| 4571 | =item printf FILEHANDLE |
| 4572 | |
| 4573 | =item printf FORMAT, LIST |
| 4574 | |
| 4575 | =item printf |
| 4576 | |
| 4577 | Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\> |
| 4578 | (the output record separator) is not appended. The first argument of the |
| 4579 | list will be interpreted as the C<printf> format. See C<sprintf> for an |
| 4580 | explanation of the format argument. If you omit the LIST, C<$_> is used; |
| 4581 | to use FILEHANDLE without a LIST, you must use a real filehandle like |
| 4582 | C<FH>, not an indirect one like C<$fh>. If C<use locale> is in effect and |
| 4583 | POSIX::setlocale() has been called, the character used for the decimal |
| 4584 | separator in formatted floating-point numbers is affected by the LC_NUMERIC |
| 4585 | locale setting. See L<perllocale> and L<POSIX>. |
| 4586 | |
| 4587 | Don't fall into the trap of using a C<printf> when a simple |
| 4588 | C<print> would do. The C<print> is more efficient and less |
| 4589 | error prone. |
| 4590 | |
| 4591 | =item prototype FUNCTION |
| 4592 | X<prototype> |
| 4593 | |
| 4594 | Returns the prototype of a function as a string (or C<undef> if the |
| 4595 | function has no prototype). FUNCTION is a reference to, or the name of, |
| 4596 | the function whose prototype you want to retrieve. |
| 4597 | |
| 4598 | If FUNCTION is a string starting with C<CORE::>, the rest is taken as a |
| 4599 | name for a Perl builtin. If the builtin is not I<overridable> (such as |
| 4600 | C<qw//>) or if its arguments cannot be adequately expressed by a prototype |
| 4601 | (such as C<system>), prototype() returns C<undef>, because the builtin |
| 4602 | does not really behave like a Perl function. Otherwise, the string |
| 4603 | describing the equivalent prototype is returned. |
| 4604 | |
| 4605 | =item push ARRAY,LIST |
| 4606 | X<push> X<stack> |
| 4607 | |
| 4608 | =item push EXPR,LIST |
| 4609 | |
| 4610 | Treats ARRAY as a stack by appending the values of LIST to the end of |
| 4611 | ARRAY. The length of ARRAY increases by the length of LIST. Has the same |
| 4612 | effect as |
| 4613 | |
| 4614 | for $value (LIST) { |
| 4615 | $ARRAY[++$#ARRAY] = $value; |
| 4616 | } |
| 4617 | |
| 4618 | but is more efficient. Returns the number of elements in the array following |
| 4619 | the completed C<push>. |
| 4620 | |
| 4621 | Starting with Perl 5.14, C<push> can take a scalar EXPR, which must hold a |
| 4622 | reference to an unblessed array. The argument will be dereferenced |
| 4623 | automatically. This aspect of C<push> is considered highly experimental. |
| 4624 | The exact behaviour may change in a future version of Perl. |
| 4625 | |
| 4626 | =item q/STRING/ |
| 4627 | |
| 4628 | =item qq/STRING/ |
| 4629 | |
| 4630 | =item qx/STRING/ |
| 4631 | |
| 4632 | =item qw/STRING/ |
| 4633 | |
| 4634 | Generalized quotes. See L<perlop/"Quote-Like Operators">. |
| 4635 | |
| 4636 | =item qr/STRING/ |
| 4637 | |
| 4638 | Regexp-like quote. See L<perlop/"Regexp Quote-Like Operators">. |
| 4639 | |
| 4640 | =item quotemeta EXPR |
| 4641 | X<quotemeta> X<metacharacter> |
| 4642 | |
| 4643 | =item quotemeta |
| 4644 | |
| 4645 | Returns the value of EXPR with all non-"word" |
| 4646 | characters backslashed. (That is, all characters not matching |
| 4647 | C</[A-Za-z_0-9]/> will be preceded by a backslash in the |
| 4648 | returned string, regardless of any locale settings.) |
| 4649 | This is the internal function implementing |
| 4650 | the C<\Q> escape in double-quoted strings. |
| 4651 | |
| 4652 | If EXPR is omitted, uses C<$_>. |
| 4653 | |
| 4654 | quotemeta (and C<\Q> ... C<\E>) are useful when interpolating strings into |
| 4655 | regular expressions, because by default an interpolated variable will be |
| 4656 | considered a mini-regular expression. For example: |
| 4657 | |
| 4658 | my $sentence = 'The quick brown fox jumped over the lazy dog'; |
| 4659 | my $substring = 'quick.*?fox'; |
| 4660 | $sentence =~ s{$substring}{big bad wolf}; |
| 4661 | |
| 4662 | Will cause C<$sentence> to become C<'The big bad wolf jumped over...'>. |
| 4663 | |
| 4664 | On the other hand: |
| 4665 | |
| 4666 | my $sentence = 'The quick brown fox jumped over the lazy dog'; |
| 4667 | my $substring = 'quick.*?fox'; |
| 4668 | $sentence =~ s{\Q$substring\E}{big bad wolf}; |
| 4669 | |
| 4670 | Or: |
| 4671 | |
| 4672 | my $sentence = 'The quick brown fox jumped over the lazy dog'; |
| 4673 | my $substring = 'quick.*?fox'; |
| 4674 | my $quoted_substring = quotemeta($substring); |
| 4675 | $sentence =~ s{$quoted_substring}{big bad wolf}; |
| 4676 | |
| 4677 | Will both leave the sentence as is. Normally, when accepting literal string |
| 4678 | input from the user, quotemeta() or C<\Q> must be used. |
| 4679 | |
| 4680 | In Perl 5.14, all characters whose code points are above 127 are not |
| 4681 | quoted in UTF8-encoded strings, but all are quoted in UTF-8 strings. |
| 4682 | It is planned to change this behavior in 5.16, but the exact rules |
| 4683 | haven't been determined yet. |
| 4684 | |
| 4685 | =item rand EXPR |
| 4686 | X<rand> X<random> |
| 4687 | |
| 4688 | =item rand |
| 4689 | |
| 4690 | Returns a random fractional number greater than or equal to C<0> and less |
| 4691 | than the value of EXPR. (EXPR should be positive.) If EXPR is |
| 4692 | omitted, the value C<1> is used. Currently EXPR with the value C<0> is |
| 4693 | also special-cased as C<1> (this was undocumented before Perl 5.8.0 |
| 4694 | and is subject to change in future versions of Perl). Automatically calls |
| 4695 | C<srand> unless C<srand> has already been called. See also C<srand>. |
| 4696 | |
| 4697 | Apply C<int()> to the value returned by C<rand()> if you want random |
| 4698 | integers instead of random fractional numbers. For example, |
| 4699 | |
| 4700 | int(rand(10)) |
| 4701 | |
| 4702 | returns a random integer between C<0> and C<9>, inclusive. |
| 4703 | |
| 4704 | (Note: If your rand function consistently returns numbers that are too |
| 4705 | large or too small, then your version of Perl was probably compiled |
| 4706 | with the wrong number of RANDBITS.) |
| 4707 | |
| 4708 | B<C<rand()> is not cryptographically secure. You should not rely |
| 4709 | on it in security-sensitive situations.> As of this writing, a |
| 4710 | number of third-party CPAN modules offer random number generators |
| 4711 | intended by their authors to be cryptographically secure, |
| 4712 | including: L<Math::Random::Secure>, L<Math::Random::MT::Perl>, and |
| 4713 | L<Math::TrulyRandom>. |
| 4714 | |
| 4715 | =item read FILEHANDLE,SCALAR,LENGTH,OFFSET |
| 4716 | X<read> X<file, read> |
| 4717 | |
| 4718 | =item read FILEHANDLE,SCALAR,LENGTH |
| 4719 | |
| 4720 | Attempts to read LENGTH I<characters> of data into variable SCALAR |
| 4721 | from the specified FILEHANDLE. Returns the number of characters |
| 4722 | actually read, C<0> at end of file, or undef if there was an error (in |
| 4723 | the latter case C<$!> is also set). SCALAR will be grown or shrunk |
| 4724 | so that the last character actually read is the last character of the |
| 4725 | scalar after the read. |
| 4726 | |
| 4727 | An OFFSET may be specified to place the read data at some place in the |
| 4728 | string other than the beginning. A negative OFFSET specifies |
| 4729 | placement at that many characters counting backwards from the end of |
| 4730 | the string. A positive OFFSET greater than the length of SCALAR |
| 4731 | results in the string being padded to the required size with C<"\0"> |
| 4732 | bytes before the result of the read is appended. |
| 4733 | |
| 4734 | The call is implemented in terms of either Perl's or your system's native |
| 4735 | fread(3) library function. To get a true read(2) system call, see C<sysread>. |
| 4736 | |
| 4737 | Note the I<characters>: depending on the status of the filehandle, |
| 4738 | either (8-bit) bytes or characters are read. By default, all |
| 4739 | filehandles operate on bytes, but for example if the filehandle has |
| 4740 | been opened with the C<:utf8> I/O layer (see L</open>, and the C<open> |
| 4741 | pragma, L<open>), the I/O will operate on UTF8-encoded Unicode |
| 4742 | characters, not bytes. Similarly for the C<:encoding> pragma: |
| 4743 | in that case pretty much any characters can be read. |
| 4744 | |
| 4745 | =item readdir DIRHANDLE |
| 4746 | X<readdir> |
| 4747 | |
| 4748 | Returns the next directory entry for a directory opened by C<opendir>. |
| 4749 | If used in list context, returns all the rest of the entries in the |
| 4750 | directory. If there are no more entries, returns the undefined value in |
| 4751 | scalar context and the empty list in list context. |
| 4752 | |
| 4753 | If you're planning to filetest the return values out of a C<readdir>, you'd |
| 4754 | better prepend the directory in question. Otherwise, because we didn't |
| 4755 | C<chdir> there, it would have been testing the wrong file. |
| 4756 | |
| 4757 | opendir(my $dh, $some_dir) || die "can't opendir $some_dir: $!"; |
| 4758 | @dots = grep { /^\./ && -f "$some_dir/$_" } readdir($dh); |
| 4759 | closedir $dh; |
| 4760 | |
| 4761 | As of Perl 5.11.2 you can use a bare C<readdir> in a C<while> loop, |
| 4762 | which will set C<$_> on every iteration. |
| 4763 | |
| 4764 | opendir(my $dh, $some_dir) || die; |
| 4765 | while(readdir $dh) { |
| 4766 | print "$some_dir/$_\n"; |
| 4767 | } |
| 4768 | closedir $dh; |
| 4769 | |
| 4770 | =item readline EXPR |
| 4771 | |
| 4772 | =item readline |
| 4773 | X<readline> X<gets> X<fgets> |
| 4774 | |
| 4775 | Reads from the filehandle whose typeglob is contained in EXPR (or from |
| 4776 | C<*ARGV> if EXPR is not provided). In scalar context, each call reads and |
| 4777 | returns the next line until end-of-file is reached, whereupon the |
| 4778 | subsequent call returns C<undef>. In list context, reads until end-of-file |
| 4779 | is reached and returns a list of lines. Note that the notion of "line" |
| 4780 | used here is whatever you may have defined with C<$/> or |
| 4781 | C<$INPUT_RECORD_SEPARATOR>). See L<perlvar/"$/">. |
| 4782 | |
| 4783 | When C<$/> is set to C<undef>, when C<readline> is in scalar |
| 4784 | context (i.e., file slurp mode), and when an empty file is read, it |
| 4785 | returns C<''> the first time, followed by C<undef> subsequently. |
| 4786 | |
| 4787 | This is the internal function implementing the C<< <EXPR> >> |
| 4788 | operator, but you can use it directly. The C<< <EXPR> >> |
| 4789 | operator is discussed in more detail in L<perlop/"I/O Operators">. |
| 4790 | |
| 4791 | $line = <STDIN>; |
| 4792 | $line = readline(*STDIN); # same thing |
| 4793 | |
| 4794 | If C<readline> encounters an operating system error, C<$!> will be set |
| 4795 | with the corresponding error message. It can be helpful to check |
| 4796 | C<$!> when you are reading from filehandles you don't trust, such as a |
| 4797 | tty or a socket. The following example uses the operator form of |
| 4798 | C<readline> and dies if the result is not defined. |
| 4799 | |
| 4800 | while ( ! eof($fh) ) { |
| 4801 | defined( $_ = <$fh> ) or die "readline failed: $!"; |
| 4802 | ... |
| 4803 | } |
| 4804 | |
| 4805 | Note that you have can't handle C<readline> errors that way with the |
| 4806 | C<ARGV> filehandle. In that case, you have to open each element of |
| 4807 | C<@ARGV> yourself since C<eof> handles C<ARGV> differently. |
| 4808 | |
| 4809 | foreach my $arg (@ARGV) { |
| 4810 | open(my $fh, $arg) or warn "Can't open $arg: $!"; |
| 4811 | |
| 4812 | while ( ! eof($fh) ) { |
| 4813 | defined( $_ = <$fh> ) |
| 4814 | or die "readline failed for $arg: $!"; |
| 4815 | ... |
| 4816 | } |
| 4817 | } |
| 4818 | |
| 4819 | =item readlink EXPR |
| 4820 | X<readlink> |
| 4821 | |
| 4822 | =item readlink |
| 4823 | |
| 4824 | Returns the value of a symbolic link, if symbolic links are |
| 4825 | implemented. If not, raises an exception. If there is a system |
| 4826 | error, returns the undefined value and sets C<$!> (errno). If EXPR is |
| 4827 | omitted, uses C<$_>. |
| 4828 | |
| 4829 | =item readpipe EXPR |
| 4830 | |
| 4831 | =item readpipe |
| 4832 | X<readpipe> |
| 4833 | |
| 4834 | EXPR is executed as a system command. |
| 4835 | The collected standard output of the command is returned. |
| 4836 | In scalar context, it comes back as a single (potentially |
| 4837 | multi-line) string. In list context, returns a list of lines |
| 4838 | (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>). |
| 4839 | This is the internal function implementing the C<qx/EXPR/> |
| 4840 | operator, but you can use it directly. The C<qx/EXPR/> |
| 4841 | operator is discussed in more detail in L<perlop/"I/O Operators">. |
| 4842 | If EXPR is omitted, uses C<$_>. |
| 4843 | |
| 4844 | =item recv SOCKET,SCALAR,LENGTH,FLAGS |
| 4845 | X<recv> |
| 4846 | |
| 4847 | Receives a message on a socket. Attempts to receive LENGTH characters |
| 4848 | of data into variable SCALAR from the specified SOCKET filehandle. |
| 4849 | SCALAR will be grown or shrunk to the length actually read. Takes the |
| 4850 | same flags as the system call of the same name. Returns the address |
| 4851 | of the sender if SOCKET's protocol supports this; returns an empty |
| 4852 | string otherwise. If there's an error, returns the undefined value. |
| 4853 | This call is actually implemented in terms of recvfrom(2) system call. |
| 4854 | See L<perlipc/"UDP: Message Passing"> for examples. |
| 4855 | |
| 4856 | Note the I<characters>: depending on the status of the socket, either |
| 4857 | (8-bit) bytes or characters are received. By default all sockets |
| 4858 | operate on bytes, but for example if the socket has been changed using |
| 4859 | binmode() to operate with the C<:encoding(utf8)> I/O layer (see the |
| 4860 | C<open> pragma, L<open>), the I/O will operate on UTF8-encoded Unicode |
| 4861 | characters, not bytes. Similarly for the C<:encoding> pragma: in that |
| 4862 | case pretty much any characters can be read. |
| 4863 | |
| 4864 | =item redo LABEL |
| 4865 | X<redo> |
| 4866 | |
| 4867 | =item redo |
| 4868 | |
| 4869 | The C<redo> command restarts the loop block without evaluating the |
| 4870 | conditional again. The C<continue> block, if any, is not executed. If |
| 4871 | the LABEL is omitted, the command refers to the innermost enclosing |
| 4872 | loop. Programs that want to lie to themselves about what was just input |
| 4873 | normally use this command: |
| 4874 | |
| 4875 | # a simpleminded Pascal comment stripper |
| 4876 | # (warning: assumes no { or } in strings) |
| 4877 | LINE: while (<STDIN>) { |
| 4878 | while (s|({.*}.*){.*}|$1 |) {} |
| 4879 | s|{.*}| |; |
| 4880 | if (s|{.*| |) { |
| 4881 | $front = $_; |
| 4882 | while (<STDIN>) { |
| 4883 | if (/}/) { # end of comment? |
| 4884 | s|^|$front\{|; |
| 4885 | redo LINE; |
| 4886 | } |
| 4887 | } |
| 4888 | } |
| 4889 | print; |
| 4890 | } |
| 4891 | |
| 4892 | C<redo> cannot be used to retry a block that returns a value such as |
| 4893 | C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit |
| 4894 | a grep() or map() operation. |
| 4895 | |
| 4896 | Note that a block by itself is semantically identical to a loop |
| 4897 | that executes once. Thus C<redo> inside such a block will effectively |
| 4898 | turn it into a looping construct. |
| 4899 | |
| 4900 | See also L</continue> for an illustration of how C<last>, C<next>, and |
| 4901 | C<redo> work. |
| 4902 | |
| 4903 | =item ref EXPR |
| 4904 | X<ref> X<reference> |
| 4905 | |
| 4906 | =item ref |
| 4907 | |
| 4908 | Returns a non-empty string if EXPR is a reference, the empty |
| 4909 | string otherwise. If EXPR |
| 4910 | is not specified, C<$_> will be used. The value returned depends on the |
| 4911 | type of thing the reference is a reference to. |
| 4912 | Builtin types include: |
| 4913 | |
| 4914 | SCALAR |
| 4915 | ARRAY |
| 4916 | HASH |
| 4917 | CODE |
| 4918 | REF |
| 4919 | GLOB |
| 4920 | LVALUE |
| 4921 | FORMAT |
| 4922 | IO |
| 4923 | VSTRING |
| 4924 | Regexp |
| 4925 | |
| 4926 | If the referenced object has been blessed into a package, then that package |
| 4927 | name is returned instead. You can think of C<ref> as a C<typeof> operator. |
| 4928 | |
| 4929 | if (ref($r) eq "HASH") { |
| 4930 | print "r is a reference to a hash.\n"; |
| 4931 | } |
| 4932 | unless (ref($r)) { |
| 4933 | print "r is not a reference at all.\n"; |
| 4934 | } |
| 4935 | |
| 4936 | The return value C<LVALUE> indicates a reference to an lvalue that is not |
| 4937 | a variable. You get this from taking the reference of function calls like |
| 4938 | C<pos()> or C<substr()>. C<VSTRING> is returned if the reference points |
| 4939 | to a L<version string|perldata/"Version Strings">. |
| 4940 | |
| 4941 | The result C<Regexp> indicates that the argument is a regular expression |
| 4942 | resulting from C<qr//>. |
| 4943 | |
| 4944 | See also L<perlref>. |
| 4945 | |
| 4946 | =item rename OLDNAME,NEWNAME |
| 4947 | X<rename> X<move> X<mv> X<ren> |
| 4948 | |
| 4949 | Changes the name of a file; an existing file NEWNAME will be |
| 4950 | clobbered. Returns true for success, false otherwise. |
| 4951 | |
| 4952 | Behavior of this function varies wildly depending on your system |
| 4953 | implementation. For example, it will usually not work across file system |
| 4954 | boundaries, even though the system I<mv> command sometimes compensates |
| 4955 | for this. Other restrictions include whether it works on directories, |
| 4956 | open files, or pre-existing files. Check L<perlport> and either the |
| 4957 | rename(2) manpage or equivalent system documentation for details. |
| 4958 | |
| 4959 | For a platform independent C<move> function look at the L<File::Copy> |
| 4960 | module. |
| 4961 | |
| 4962 | =item require VERSION |
| 4963 | X<require> |
| 4964 | |
| 4965 | =item require EXPR |
| 4966 | |
| 4967 | =item require |
| 4968 | |
| 4969 | Demands a version of Perl specified by VERSION, or demands some semantics |
| 4970 | specified by EXPR or by C<$_> if EXPR is not supplied. |
| 4971 | |
| 4972 | VERSION may be either a numeric argument such as 5.006, which will be |
| 4973 | compared to C<$]>, or a literal of the form v5.6.1, which will be compared |
| 4974 | to C<$^V> (aka $PERL_VERSION). An exception is raised if |
| 4975 | VERSION is greater than the version of the current Perl interpreter. |
| 4976 | Compare with L</use>, which can do a similar check at compile time. |
| 4977 | |
| 4978 | Specifying VERSION as a literal of the form v5.6.1 should generally be |
| 4979 | avoided, because it leads to misleading error messages under earlier |
| 4980 | versions of Perl that do not support this syntax. The equivalent numeric |
| 4981 | version should be used instead. |
| 4982 | |
| 4983 | require v5.6.1; # run time version check |
| 4984 | require 5.6.1; # ditto |
| 4985 | require 5.006_001; # ditto; preferred for backwards compatibility |
| 4986 | |
| 4987 | Otherwise, C<require> demands that a library file be included if it |
| 4988 | hasn't already been included. The file is included via the do-FILE |
| 4989 | mechanism, which is essentially just a variety of C<eval> with the |
| 4990 | caveat that lexical variables in the invoking script will be invisible |
| 4991 | to the included code. Has semantics similar to the following subroutine: |
| 4992 | |
| 4993 | sub require { |
| 4994 | my ($filename) = @_; |
| 4995 | if (exists $INC{$filename}) { |
| 4996 | return 1 if $INC{$filename}; |
| 4997 | die "Compilation failed in require"; |
| 4998 | } |
| 4999 | my ($realfilename,$result); |
| 5000 | ITER: { |
| 5001 | foreach $prefix (@INC) { |
| 5002 | $realfilename = "$prefix/$filename"; |
| 5003 | if (-f $realfilename) { |
| 5004 | $INC{$filename} = $realfilename; |
| 5005 | $result = do $realfilename; |
| 5006 | last ITER; |
| 5007 | } |
| 5008 | } |
| 5009 | die "Can't find $filename in \@INC"; |
| 5010 | } |
| 5011 | if ($@) { |
| 5012 | $INC{$filename} = undef; |
| 5013 | die $@; |
| 5014 | } elsif (!$result) { |
| 5015 | delete $INC{$filename}; |
| 5016 | die "$filename did not return true value"; |
| 5017 | } else { |
| 5018 | return $result; |
| 5019 | } |
| 5020 | } |
| 5021 | |
| 5022 | Note that the file will not be included twice under the same specified |
| 5023 | name. |
| 5024 | |
| 5025 | The file must return true as the last statement to indicate |
| 5026 | successful execution of any initialization code, so it's customary to |
| 5027 | end such a file with C<1;> unless you're sure it'll return true |
| 5028 | otherwise. But it's better just to put the C<1;>, in case you add more |
| 5029 | statements. |
| 5030 | |
| 5031 | If EXPR is a bareword, the require assumes a "F<.pm>" extension and |
| 5032 | replaces "F<::>" with "F</>" in the filename for you, |
| 5033 | to make it easy to load standard modules. This form of loading of |
| 5034 | modules does not risk altering your namespace. |
| 5035 | |
| 5036 | In other words, if you try this: |
| 5037 | |
| 5038 | require Foo::Bar; # a splendid bareword |
| 5039 | |
| 5040 | The require function will actually look for the "F<Foo/Bar.pm>" file in the |
| 5041 | directories specified in the C<@INC> array. |
| 5042 | |
| 5043 | But if you try this: |
| 5044 | |
| 5045 | $class = 'Foo::Bar'; |
| 5046 | require $class; # $class is not a bareword |
| 5047 | #or |
| 5048 | require "Foo::Bar"; # not a bareword because of the "" |
| 5049 | |
| 5050 | The require function will look for the "F<Foo::Bar>" file in the @INC array and |
| 5051 | will complain about not finding "F<Foo::Bar>" there. In this case you can do: |
| 5052 | |
| 5053 | eval "require $class"; |
| 5054 | |
| 5055 | Now that you understand how C<require> looks for files with a |
| 5056 | bareword argument, there is a little extra functionality going on behind |
| 5057 | the scenes. Before C<require> looks for a "F<.pm>" extension, it will |
| 5058 | first look for a similar filename with a "F<.pmc>" extension. If this file |
| 5059 | is found, it will be loaded in place of any file ending in a "F<.pm>" |
| 5060 | extension. |
| 5061 | |
| 5062 | You can also insert hooks into the import facility by putting Perl code |
| 5063 | directly into the @INC array. There are three forms of hooks: subroutine |
| 5064 | references, array references, and blessed objects. |
| 5065 | |
| 5066 | Subroutine references are the simplest case. When the inclusion system |
| 5067 | walks through @INC and encounters a subroutine, this subroutine gets |
| 5068 | called with two parameters, the first a reference to itself, and the |
| 5069 | second the name of the file to be included (e.g., "F<Foo/Bar.pm>"). The |
| 5070 | subroutine should return either nothing or else a list of up to three |
| 5071 | values in the following order: |
| 5072 | |
| 5073 | =over |
| 5074 | |
| 5075 | =item 1 |
| 5076 | |
| 5077 | A filehandle, from which the file will be read. |
| 5078 | |
| 5079 | =item 2 |
| 5080 | |
| 5081 | A reference to a subroutine. If there is no filehandle (previous item), |
| 5082 | then this subroutine is expected to generate one line of source code per |
| 5083 | call, writing the line into C<$_> and returning 1, then finally at end of |
| 5084 | file returning 0. If there is a filehandle, then the subroutine will be |
| 5085 | called to act as a simple source filter, with the line as read in C<$_>. |
| 5086 | Again, return 1 for each valid line, and 0 after all lines have been |
| 5087 | returned. |
| 5088 | |
| 5089 | =item 3 |
| 5090 | |
| 5091 | Optional state for the subroutine. The state is passed in as C<$_[1]>. A |
| 5092 | reference to the subroutine itself is passed in as C<$_[0]>. |
| 5093 | |
| 5094 | =back |
| 5095 | |
| 5096 | If an empty list, C<undef>, or nothing that matches the first 3 values above |
| 5097 | is returned, then C<require> looks at the remaining elements of @INC. |
| 5098 | Note that this filehandle must be a real filehandle (strictly a typeglob |
| 5099 | or reference to a typeglob, whether blessed or unblessed); tied filehandles |
| 5100 | will be ignored and processing will stop there. |
| 5101 | |
| 5102 | If the hook is an array reference, its first element must be a subroutine |
| 5103 | reference. This subroutine is called as above, but the first parameter is |
| 5104 | the array reference. This lets you indirectly pass arguments to |
| 5105 | the subroutine. |
| 5106 | |
| 5107 | In other words, you can write: |
| 5108 | |
| 5109 | push @INC, \&my_sub; |
| 5110 | sub my_sub { |
| 5111 | my ($coderef, $filename) = @_; # $coderef is \&my_sub |
| 5112 | ... |
| 5113 | } |
| 5114 | |
| 5115 | or: |
| 5116 | |
| 5117 | push @INC, [ \&my_sub, $x, $y, ... ]; |
| 5118 | sub my_sub { |
| 5119 | my ($arrayref, $filename) = @_; |
| 5120 | # Retrieve $x, $y, ... |
| 5121 | my @parameters = @$arrayref[1..$#$arrayref]; |
| 5122 | ... |
| 5123 | } |
| 5124 | |
| 5125 | If the hook is an object, it must provide an INC method that will be |
| 5126 | called as above, the first parameter being the object itself. (Note that |
| 5127 | you must fully qualify the sub's name, as unqualified C<INC> is always forced |
| 5128 | into package C<main>.) Here is a typical code layout: |
| 5129 | |
| 5130 | # In Foo.pm |
| 5131 | package Foo; |
| 5132 | sub new { ... } |
| 5133 | sub Foo::INC { |
| 5134 | my ($self, $filename) = @_; |
| 5135 | ... |
| 5136 | } |
| 5137 | |
| 5138 | # In the main program |
| 5139 | push @INC, Foo->new(...); |
| 5140 | |
| 5141 | These hooks are also permitted to set the %INC entry |
| 5142 | corresponding to the files they have loaded. See L<perlvar/%INC>. |
| 5143 | |
| 5144 | For a yet-more-powerful import facility, see L</use> and L<perlmod>. |
| 5145 | |
| 5146 | =item reset EXPR |
| 5147 | X<reset> |
| 5148 | |
| 5149 | =item reset |
| 5150 | |
| 5151 | Generally used in a C<continue> block at the end of a loop to clear |
| 5152 | variables and reset C<??> searches so that they work again. The |
| 5153 | expression is interpreted as a list of single characters (hyphens |
| 5154 | allowed for ranges). All variables and arrays beginning with one of |
| 5155 | those letters are reset to their pristine state. If the expression is |
| 5156 | omitted, one-match searches (C<?pattern?>) are reset to match again. |
| 5157 | Only resets variables or searches in the current package. Always returns |
| 5158 | 1. Examples: |
| 5159 | |
| 5160 | reset 'X'; # reset all X variables |
| 5161 | reset 'a-z'; # reset lower case variables |
| 5162 | reset; # just reset ?one-time? searches |
| 5163 | |
| 5164 | Resetting C<"A-Z"> is not recommended because you'll wipe out your |
| 5165 | C<@ARGV> and C<@INC> arrays and your C<%ENV> hash. Resets only package |
| 5166 | variables; lexical variables are unaffected, but they clean themselves |
| 5167 | up on scope exit anyway, so you'll probably want to use them instead. |
| 5168 | See L</my>. |
| 5169 | |
| 5170 | =item return EXPR |
| 5171 | X<return> |
| 5172 | |
| 5173 | =item return |
| 5174 | |
| 5175 | Returns from a subroutine, C<eval>, or C<do FILE> with the value |
| 5176 | given in EXPR. Evaluation of EXPR may be in list, scalar, or void |
| 5177 | context, depending on how the return value will be used, and the context |
| 5178 | may vary from one execution to the next (see C<wantarray>). If no EXPR |
| 5179 | is given, returns an empty list in list context, the undefined value in |
| 5180 | scalar context, and (of course) nothing at all in void context. |
| 5181 | |
| 5182 | (In the absence of an explicit C<return>, a subroutine, eval, |
| 5183 | or do FILE automatically returns the value of the last expression |
| 5184 | evaluated.) |
| 5185 | |
| 5186 | =item reverse LIST |
| 5187 | X<reverse> X<rev> X<invert> |
| 5188 | |
| 5189 | In list context, returns a list value consisting of the elements |
| 5190 | of LIST in the opposite order. In scalar context, concatenates the |
| 5191 | elements of LIST and returns a string value with all characters |
| 5192 | in the opposite order. |
| 5193 | |
| 5194 | print join(", ", reverse "world", "Hello"); # Hello, world |
| 5195 | |
| 5196 | print scalar reverse "dlrow ,", "olleH"; # Hello, world |
| 5197 | |
| 5198 | Used without arguments in scalar context, reverse() reverses C<$_>. |
| 5199 | |
| 5200 | $_ = "dlrow ,olleH"; |
| 5201 | print reverse; # No output, list context |
| 5202 | print scalar reverse; # Hello, world |
| 5203 | |
| 5204 | Note that reversing an array to itself (as in C<@a = reverse @a>) will |
| 5205 | preserve non-existent elements whenever possible, i.e., for non magical |
| 5206 | arrays or tied arrays with C<EXISTS> and C<DELETE> methods. |
| 5207 | |
| 5208 | This operator is also handy for inverting a hash, although there are some |
| 5209 | caveats. If a value is duplicated in the original hash, only one of those |
| 5210 | can be represented as a key in the inverted hash. Also, this has to |
| 5211 | unwind one hash and build a whole new one, which may take some time |
| 5212 | on a large hash, such as from a DBM file. |
| 5213 | |
| 5214 | %by_name = reverse %by_address; # Invert the hash |
| 5215 | |
| 5216 | =item rewinddir DIRHANDLE |
| 5217 | X<rewinddir> |
| 5218 | |
| 5219 | Sets the current position to the beginning of the directory for the |
| 5220 | C<readdir> routine on DIRHANDLE. |
| 5221 | |
| 5222 | =item rindex STR,SUBSTR,POSITION |
| 5223 | X<rindex> |
| 5224 | |
| 5225 | =item rindex STR,SUBSTR |
| 5226 | |
| 5227 | Works just like index() except that it returns the position of the I<last> |
| 5228 | occurrence of SUBSTR in STR. If POSITION is specified, returns the |
| 5229 | last occurrence beginning at or before that position. |
| 5230 | |
| 5231 | =item rmdir FILENAME |
| 5232 | X<rmdir> X<rd> X<directory, remove> |
| 5233 | |
| 5234 | =item rmdir |
| 5235 | |
| 5236 | Deletes the directory specified by FILENAME if that directory is |
| 5237 | empty. If it succeeds it returns true; otherwise it returns false and |
| 5238 | sets C<$!> (errno). If FILENAME is omitted, uses C<$_>. |
| 5239 | |
| 5240 | To remove a directory tree recursively (C<rm -rf> on Unix) look at |
| 5241 | the C<rmtree> function of the L<File::Path> module. |
| 5242 | |
| 5243 | =item s/// |
| 5244 | |
| 5245 | The substitution operator. See L<perlop/"Regexp Quote-Like Operators">. |
| 5246 | |
| 5247 | =item say FILEHANDLE LIST |
| 5248 | X<say> |
| 5249 | |
| 5250 | =item say FILEHANDLE |
| 5251 | |
| 5252 | =item say LIST |
| 5253 | |
| 5254 | =item say |
| 5255 | |
| 5256 | Just like C<print>, but implicitly appends a newline. C<say LIST> is |
| 5257 | simply an abbreviation for C<{ local $\ = "\n"; print LIST }>. To use |
| 5258 | FILEHANDLE without a LIST to print the contents of C<$_> to it, you must |
| 5259 | use a real filehandle like C<FH>, not an indirect one like C<$fh>. |
| 5260 | |
| 5261 | This keyword is available only when the C<"say"> feature is enabled; see |
| 5262 | L<feature>. Alternately, include a C<use v5.10> or later to the current |
| 5263 | scope. |
| 5264 | |
| 5265 | =item scalar EXPR |
| 5266 | X<scalar> X<context> |
| 5267 | |
| 5268 | Forces EXPR to be interpreted in scalar context and returns the value |
| 5269 | of EXPR. |
| 5270 | |
| 5271 | @counts = ( scalar @a, scalar @b, scalar @c ); |
| 5272 | |
| 5273 | There is no equivalent operator to force an expression to |
| 5274 | be interpolated in list context because in practice, this is never |
| 5275 | needed. If you really wanted to do so, however, you could use |
| 5276 | the construction C<@{[ (some expression) ]}>, but usually a simple |
| 5277 | C<(some expression)> suffices. |
| 5278 | |
| 5279 | Because C<scalar> is a unary operator, if you accidentally use a |
| 5280 | parenthesized list for the EXPR, this behaves as a scalar comma expression, |
| 5281 | evaluating all but the last element in void context and returning the final |
| 5282 | element evaluated in scalar context. This is seldom what you want. |
| 5283 | |
| 5284 | The following single statement: |
| 5285 | |
| 5286 | print uc(scalar(&foo,$bar)),$baz; |
| 5287 | |
| 5288 | is the moral equivalent of these two: |
| 5289 | |
| 5290 | &foo; |
| 5291 | print(uc($bar),$baz); |
| 5292 | |
| 5293 | See L<perlop> for more details on unary operators and the comma operator. |
| 5294 | |
| 5295 | =item seek FILEHANDLE,POSITION,WHENCE |
| 5296 | X<seek> X<fseek> X<filehandle, position> |
| 5297 | |
| 5298 | Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>. |
| 5299 | FILEHANDLE may be an expression whose value gives the name of the |
| 5300 | filehandle. The values for WHENCE are C<0> to set the new position |
| 5301 | I<in bytes> to POSITION; C<1> to set it to the current position plus |
| 5302 | POSITION; and C<2> to set it to EOF plus POSITION, typically |
| 5303 | negative. For WHENCE you may use the constants C<SEEK_SET>, |
| 5304 | C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end |
| 5305 | of the file) from the L<Fcntl> module. Returns C<1> on success, false |
| 5306 | otherwise. |
| 5307 | |
| 5308 | Note the I<in bytes>: even if the filehandle has been set to |
| 5309 | operate on characters (for example by using the C<:encoding(utf8)> open |
| 5310 | layer), tell() will return byte offsets, not character offsets |
| 5311 | (because implementing that would render seek() and tell() rather slow). |
| 5312 | |
| 5313 | If you want to position the file for C<sysread> or C<syswrite>, don't use |
| 5314 | C<seek>, because buffering makes its effect on the file's read-write position |
| 5315 | unpredictable and non-portable. Use C<sysseek> instead. |
| 5316 | |
| 5317 | Due to the rules and rigors of ANSI C, on some systems you have to do a |
| 5318 | seek whenever you switch between reading and writing. Amongst other |
| 5319 | things, this may have the effect of calling stdio's clearerr(3). |
| 5320 | A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position: |
| 5321 | |
| 5322 | seek(TEST,0,1); |
| 5323 | |
| 5324 | This is also useful for applications emulating C<tail -f>. Once you hit |
| 5325 | EOF on your read and then sleep for a while, you (probably) have to stick in a |
| 5326 | dummy seek() to reset things. The C<seek> doesn't change the position, |
| 5327 | but it I<does> clear the end-of-file condition on the handle, so that the |
| 5328 | next C<< <FILE> >> makes Perl try again to read something. (We hope.) |
| 5329 | |
| 5330 | If that doesn't work (some I/O implementations are particularly |
| 5331 | cantankerous), you might need something like this: |
| 5332 | |
| 5333 | for (;;) { |
| 5334 | for ($curpos = tell(FILE); $_ = <FILE>; |
| 5335 | $curpos = tell(FILE)) { |
| 5336 | # search for some stuff and put it into files |
| 5337 | } |
| 5338 | sleep($for_a_while); |
| 5339 | seek(FILE, $curpos, 0); |
| 5340 | } |
| 5341 | |
| 5342 | =item seekdir DIRHANDLE,POS |
| 5343 | X<seekdir> |
| 5344 | |
| 5345 | Sets the current position for the C<readdir> routine on DIRHANDLE. POS |
| 5346 | must be a value returned by C<telldir>. C<seekdir> also has the same caveats |
| 5347 | about possible directory compaction as the corresponding system library |
| 5348 | routine. |
| 5349 | |
| 5350 | =item select FILEHANDLE |
| 5351 | X<select> X<filehandle, default> |
| 5352 | |
| 5353 | =item select |
| 5354 | |
| 5355 | Returns the currently selected filehandle. If FILEHANDLE is supplied, |
| 5356 | sets the new current default filehandle for output. This has two |
| 5357 | effects: first, a C<write> or a C<print> without a filehandle |
| 5358 | default to this FILEHANDLE. Second, references to variables related to |
| 5359 | output will refer to this output channel. |
| 5360 | |
| 5361 | For example, to set the top-of-form format for more than one |
| 5362 | output channel, you might do the following: |
| 5363 | |
| 5364 | select(REPORT1); |
| 5365 | $^ = 'report1_top'; |
| 5366 | select(REPORT2); |
| 5367 | $^ = 'report2_top'; |
| 5368 | |
| 5369 | FILEHANDLE may be an expression whose value gives the name of the |
| 5370 | actual filehandle. Thus: |
| 5371 | |
| 5372 | $oldfh = select(STDERR); $| = 1; select($oldfh); |
| 5373 | |
| 5374 | Some programmers may prefer to think of filehandles as objects with |
| 5375 | methods, preferring to write the last example as: |
| 5376 | |
| 5377 | use IO::Handle; |
| 5378 | STDERR->autoflush(1); |
| 5379 | |
| 5380 | =item select RBITS,WBITS,EBITS,TIMEOUT |
| 5381 | X<select> |
| 5382 | |
| 5383 | This calls the select(2) syscall with the bit masks specified, which |
| 5384 | can be constructed using C<fileno> and C<vec>, along these lines: |
| 5385 | |
| 5386 | $rin = $win = $ein = ''; |
| 5387 | vec($rin, fileno(STDIN), 1) = 1; |
| 5388 | vec($win, fileno(STDOUT), 1) = 1; |
| 5389 | $ein = $rin | $win; |
| 5390 | |
| 5391 | If you want to select on many filehandles, you may wish to write a |
| 5392 | subroutine like this: |
| 5393 | |
| 5394 | sub fhbits { |
| 5395 | my @fhlist = @_; |
| 5396 | my $bits = ""; |
| 5397 | for my $fh (@fhlist) { |
| 5398 | vec($bits, fileno($fh), 1) = 1; |
| 5399 | } |
| 5400 | return $bits; |
| 5401 | } |
| 5402 | $rin = fhbits(*STDIN, *TTY, *MYSOCK); |
| 5403 | |
| 5404 | The usual idiom is: |
| 5405 | |
| 5406 | ($nfound,$timeleft) = |
| 5407 | select($rout=$rin, $wout=$win, $eout=$ein, $timeout); |
| 5408 | |
| 5409 | or to block until something becomes ready just do this |
| 5410 | |
| 5411 | $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef); |
| 5412 | |
| 5413 | Most systems do not bother to return anything useful in $timeleft, so |
| 5414 | calling select() in scalar context just returns $nfound. |
| 5415 | |
| 5416 | Any of the bit masks can also be undef. The timeout, if specified, is |
| 5417 | in seconds, which may be fractional. Note: not all implementations are |
| 5418 | capable of returning the $timeleft. If not, they always return |
| 5419 | $timeleft equal to the supplied $timeout. |
| 5420 | |
| 5421 | You can effect a sleep of 250 milliseconds this way: |
| 5422 | |
| 5423 | select(undef, undef, undef, 0.25); |
| 5424 | |
| 5425 | Note that whether C<select> gets restarted after signals (say, SIGALRM) |
| 5426 | is implementation-dependent. See also L<perlport> for notes on the |
| 5427 | portability of C<select>. |
| 5428 | |
| 5429 | On error, C<select> behaves just like select(2): it returns |
| 5430 | -1 and sets C<$!>. |
| 5431 | |
| 5432 | On some Unixes, select(2) may report a socket file descriptor as "ready for |
| 5433 | reading" even when no data is available, and thus any subsequent C<read> |
| 5434 | would block. This can be avoided if you always use O_NONBLOCK on the |
| 5435 | socket. See select(2) and fcntl(2) for further details. |
| 5436 | |
| 5437 | The standard C<IO::Select> module provides a user-friendlier interface |
| 5438 | to C<select>, mostly because it does all the bit-mask work for you. |
| 5439 | |
| 5440 | B<WARNING>: One should not attempt to mix buffered I/O (like C<read> |
| 5441 | or <FH>) with C<select>, except as permitted by POSIX, and even |
| 5442 | then only on POSIX systems. You have to use C<sysread> instead. |
| 5443 | |
| 5444 | =item semctl ID,SEMNUM,CMD,ARG |
| 5445 | X<semctl> |
| 5446 | |
| 5447 | Calls the System V IPC function semctl(2). You'll probably have to say |
| 5448 | |
| 5449 | use IPC::SysV; |
| 5450 | |
| 5451 | first to get the correct constant definitions. If CMD is IPC_STAT or |
| 5452 | GETALL, then ARG must be a variable that will hold the returned |
| 5453 | semid_ds structure or semaphore value array. Returns like C<ioctl>: |
| 5454 | the undefined value for error, "C<0 but true>" for zero, or the actual |
| 5455 | return value otherwise. The ARG must consist of a vector of native |
| 5456 | short integers, which may be created with C<pack("s!",(0)x$nsem)>. |
| 5457 | See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore> |
| 5458 | documentation. |
| 5459 | |
| 5460 | =item semget KEY,NSEMS,FLAGS |
| 5461 | X<semget> |
| 5462 | |
| 5463 | Calls the System V IPC function semget(2). Returns the semaphore id, or |
| 5464 | the undefined value on error. See also |
| 5465 | L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore> |
| 5466 | documentation. |
| 5467 | |
| 5468 | =item semop KEY,OPSTRING |
| 5469 | X<semop> |
| 5470 | |
| 5471 | Calls the System V IPC function semop(2) for semaphore operations |
| 5472 | such as signalling and waiting. OPSTRING must be a packed array of |
| 5473 | semop structures. Each semop structure can be generated with |
| 5474 | C<pack("s!3", $semnum, $semop, $semflag)>. The length of OPSTRING |
| 5475 | implies the number of semaphore operations. Returns true if |
| 5476 | successful, false on error. As an example, the |
| 5477 | following code waits on semaphore $semnum of semaphore id $semid: |
| 5478 | |
| 5479 | $semop = pack("s!3", $semnum, -1, 0); |
| 5480 | die "Semaphore trouble: $!\n" unless semop($semid, $semop); |
| 5481 | |
| 5482 | To signal the semaphore, replace C<-1> with C<1>. See also |
| 5483 | L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore> |
| 5484 | documentation. |
| 5485 | |
| 5486 | =item send SOCKET,MSG,FLAGS,TO |
| 5487 | X<send> |
| 5488 | |
| 5489 | =item send SOCKET,MSG,FLAGS |
| 5490 | |
| 5491 | Sends a message on a socket. Attempts to send the scalar MSG to the SOCKET |
| 5492 | filehandle. Takes the same flags as the system call of the same name. On |
| 5493 | unconnected sockets, you must specify a destination to I<send to>, in which |
| 5494 | case it does a sendto(2) syscall. Returns the number of characters sent, |
| 5495 | or the undefined value on error. The sendmsg(2) syscall is currently |
| 5496 | unimplemented. See L<perlipc/"UDP: Message Passing"> for examples. |
| 5497 | |
| 5498 | Note the I<characters>: depending on the status of the socket, either |
| 5499 | (8-bit) bytes or characters are sent. By default all sockets operate |
| 5500 | on bytes, but for example if the socket has been changed using |
| 5501 | binmode() to operate with the C<:encoding(utf8)> I/O layer (see |
| 5502 | L</open>, or the C<open> pragma, L<open>), the I/O will operate on UTF-8 |
| 5503 | encoded Unicode characters, not bytes. Similarly for the C<:encoding> |
| 5504 | pragma: in that case pretty much any characters can be sent. |
| 5505 | |
| 5506 | =item setpgrp PID,PGRP |
| 5507 | X<setpgrp> X<group> |
| 5508 | |
| 5509 | Sets the current process group for the specified PID, C<0> for the current |
| 5510 | process. Raises an exception when used on a machine that doesn't |
| 5511 | implement POSIX setpgid(2) or BSD setpgrp(2). If the arguments are omitted, |
| 5512 | it defaults to C<0,0>. Note that the BSD 4.2 version of C<setpgrp> does not |
| 5513 | accept any arguments, so only C<setpgrp(0,0)> is portable. See also |
| 5514 | C<POSIX::setsid()>. |
| 5515 | |
| 5516 | =item setpriority WHICH,WHO,PRIORITY |
| 5517 | X<setpriority> X<priority> X<nice> X<renice> |
| 5518 | |
| 5519 | Sets the current priority for a process, a process group, or a user. |
| 5520 | (See setpriority(2).) Raises an exception when used on a machine |
| 5521 | that doesn't implement setpriority(2). |
| 5522 | |
| 5523 | =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL |
| 5524 | X<setsockopt> |
| 5525 | |
| 5526 | Sets the socket option requested. Returns C<undef> on error. |
| 5527 | Use integer constants provided by the C<Socket> module for |
| 5528 | LEVEL and OPNAME. Values for LEVEL can also be obtained from |
| 5529 | getprotobyname. OPTVAL might either be a packed string or an integer. |
| 5530 | An integer OPTVAL is shorthand for pack("i", OPTVAL). |
| 5531 | |
| 5532 | An example disabling Nagle's algorithm on a socket: |
| 5533 | |
| 5534 | use Socket qw(IPPROTO_TCP TCP_NODELAY); |
| 5535 | setsockopt($socket, IPPROTO_TCP, TCP_NODELAY, 1); |
| 5536 | |
| 5537 | =item shift ARRAY |
| 5538 | X<shift> |
| 5539 | |
| 5540 | =item shift EXPR |
| 5541 | |
| 5542 | =item shift |
| 5543 | |
| 5544 | Shifts the first value of the array off and returns it, shortening the |
| 5545 | array by 1 and moving everything down. If there are no elements in the |
| 5546 | array, returns the undefined value. If ARRAY is omitted, shifts the |
| 5547 | C<@_> array within the lexical scope of subroutines and formats, and the |
| 5548 | C<@ARGV> array outside a subroutine and also within the lexical scopes |
| 5549 | established by the C<eval STRING>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, |
| 5550 | C<UNITCHECK {}>, and C<END {}> constructs. |
| 5551 | |
| 5552 | Starting with Perl 5.14, C<shift> can take a scalar EXPR, which must hold a |
| 5553 | reference to an unblessed array. The argument will be dereferenced |
| 5554 | automatically. This aspect of C<shift> is considered highly experimental. |
| 5555 | The exact behaviour may change in a future version of Perl. |
| 5556 | |
| 5557 | See also C<unshift>, C<push>, and C<pop>. C<shift> and C<unshift> do the |
| 5558 | same thing to the left end of an array that C<pop> and C<push> do to the |
| 5559 | right end. |
| 5560 | |
| 5561 | =item shmctl ID,CMD,ARG |
| 5562 | X<shmctl> |
| 5563 | |
| 5564 | Calls the System V IPC function shmctl. You'll probably have to say |
| 5565 | |
| 5566 | use IPC::SysV; |
| 5567 | |
| 5568 | first to get the correct constant definitions. If CMD is C<IPC_STAT>, |
| 5569 | then ARG must be a variable that will hold the returned C<shmid_ds> |
| 5570 | structure. Returns like ioctl: C<undef> for error; "C<0> but |
| 5571 | true" for zero; and the actual return value otherwise. |
| 5572 | See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation. |
| 5573 | |
| 5574 | =item shmget KEY,SIZE,FLAGS |
| 5575 | X<shmget> |
| 5576 | |
| 5577 | Calls the System V IPC function shmget. Returns the shared memory |
| 5578 | segment id, or C<undef> on error. |
| 5579 | See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation. |
| 5580 | |
| 5581 | =item shmread ID,VAR,POS,SIZE |
| 5582 | X<shmread> |
| 5583 | X<shmwrite> |
| 5584 | |
| 5585 | =item shmwrite ID,STRING,POS,SIZE |
| 5586 | |
| 5587 | Reads or writes the System V shared memory segment ID starting at |
| 5588 | position POS for size SIZE by attaching to it, copying in/out, and |
| 5589 | detaching from it. When reading, VAR must be a variable that will |
| 5590 | hold the data read. When writing, if STRING is too long, only SIZE |
| 5591 | bytes are used; if STRING is too short, nulls are written to fill out |
| 5592 | SIZE bytes. Return true if successful, false on error. |
| 5593 | shmread() taints the variable. See also L<perlipc/"SysV IPC">, |
| 5594 | C<IPC::SysV>, and the C<IPC::Shareable> module from CPAN. |
| 5595 | |
| 5596 | =item shutdown SOCKET,HOW |
| 5597 | X<shutdown> |
| 5598 | |
| 5599 | Shuts down a socket connection in the manner indicated by HOW, which |
| 5600 | has the same interpretation as in the syscall of the same name. |
| 5601 | |
| 5602 | shutdown(SOCKET, 0); # I/we have stopped reading data |
| 5603 | shutdown(SOCKET, 1); # I/we have stopped writing data |
| 5604 | shutdown(SOCKET, 2); # I/we have stopped using this socket |
| 5605 | |
| 5606 | This is useful with sockets when you want to tell the other |
| 5607 | side you're done writing but not done reading, or vice versa. |
| 5608 | It's also a more insistent form of close because it also |
| 5609 | disables the file descriptor in any forked copies in other |
| 5610 | processes. |
| 5611 | |
| 5612 | Returns C<1> for success; on error, returns C<undef> if |
| 5613 | the first argument is not a valid filehandle, or returns C<0> and sets |
| 5614 | C<$!> for any other failure. |
| 5615 | |
| 5616 | =item sin EXPR |
| 5617 | X<sin> X<sine> X<asin> X<arcsine> |
| 5618 | |
| 5619 | =item sin |
| 5620 | |
| 5621 | Returns the sine of EXPR (expressed in radians). If EXPR is omitted, |
| 5622 | returns sine of C<$_>. |
| 5623 | |
| 5624 | For the inverse sine operation, you may use the C<Math::Trig::asin> |
| 5625 | function, or use this relation: |
| 5626 | |
| 5627 | sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) } |
| 5628 | |
| 5629 | =item sleep EXPR |
| 5630 | X<sleep> X<pause> |
| 5631 | |
| 5632 | =item sleep |
| 5633 | |
| 5634 | Causes the script to sleep for (integer) EXPR seconds, or forever if no |
| 5635 | argument is given. Returns the integer number of seconds actually slept. |
| 5636 | |
| 5637 | May be interrupted if the process receives a signal such as C<SIGALRM>. |
| 5638 | |
| 5639 | eval { |
| 5640 | local $SIG{ALARM} = sub { die "Alarm!\n" }; |
| 5641 | sleep; |
| 5642 | }; |
| 5643 | die $@ unless $@ eq "Alarm!\n"; |
| 5644 | |
| 5645 | You probably cannot mix C<alarm> and C<sleep> calls, because C<sleep> |
| 5646 | is often implemented using C<alarm>. |
| 5647 | |
| 5648 | On some older systems, it may sleep up to a full second less than what |
| 5649 | you requested, depending on how it counts seconds. Most modern systems |
| 5650 | always sleep the full amount. They may appear to sleep longer than that, |
| 5651 | however, because your process might not be scheduled right away in a |
| 5652 | busy multitasking system. |
| 5653 | |
| 5654 | For delays of finer granularity than one second, the Time::HiRes module |
| 5655 | (from CPAN, and starting from Perl 5.8 part of the standard |
| 5656 | distribution) provides usleep(). You may also use Perl's four-argument |
| 5657 | version of select() leaving the first three arguments undefined, or you |
| 5658 | might be able to use the C<syscall> interface to access setitimer(2) if |
| 5659 | your system supports it. See L<perlfaq8> for details. |
| 5660 | |
| 5661 | See also the POSIX module's C<pause> function. |
| 5662 | |
| 5663 | =item socket SOCKET,DOMAIN,TYPE,PROTOCOL |
| 5664 | X<socket> |
| 5665 | |
| 5666 | Opens a socket of the specified kind and attaches it to filehandle |
| 5667 | SOCKET. DOMAIN, TYPE, and PROTOCOL are specified the same as for |
| 5668 | the syscall of the same name. You should C<use Socket> first |
| 5669 | to get the proper definitions imported. See the examples in |
| 5670 | L<perlipc/"Sockets: Client/Server Communication">. |
| 5671 | |
| 5672 | On systems that support a close-on-exec flag on files, the flag will |
| 5673 | be set for the newly opened file descriptor, as determined by the |
| 5674 | value of $^F. See L<perlvar/$^F>. |
| 5675 | |
| 5676 | =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL |
| 5677 | X<socketpair> |
| 5678 | |
| 5679 | Creates an unnamed pair of sockets in the specified domain, of the |
| 5680 | specified type. DOMAIN, TYPE, and PROTOCOL are specified the same as |
| 5681 | for the syscall of the same name. If unimplemented, raises an exception. |
| 5682 | Returns true if successful. |
| 5683 | |
| 5684 | On systems that support a close-on-exec flag on files, the flag will |
| 5685 | be set for the newly opened file descriptors, as determined by the value |
| 5686 | of $^F. See L<perlvar/$^F>. |
| 5687 | |
| 5688 | Some systems defined C<pipe> in terms of C<socketpair>, in which a call |
| 5689 | to C<pipe(Rdr, Wtr)> is essentially: |
| 5690 | |
| 5691 | use Socket; |
| 5692 | socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC); |
| 5693 | shutdown(Rdr, 1); # no more writing for reader |
| 5694 | shutdown(Wtr, 0); # no more reading for writer |
| 5695 | |
| 5696 | See L<perlipc> for an example of socketpair use. Perl 5.8 and later will |
| 5697 | emulate socketpair using IP sockets to localhost if your system implements |
| 5698 | sockets but not socketpair. |
| 5699 | |
| 5700 | =item sort SUBNAME LIST |
| 5701 | X<sort> X<qsort> X<quicksort> X<mergesort> |
| 5702 | |
| 5703 | =item sort BLOCK LIST |
| 5704 | |
| 5705 | =item sort LIST |
| 5706 | |
| 5707 | In list context, this sorts the LIST and returns the sorted list value. |
| 5708 | In scalar context, the behaviour of C<sort()> is undefined. |
| 5709 | |
| 5710 | If SUBNAME or BLOCK is omitted, C<sort>s in standard string comparison |
| 5711 | order. If SUBNAME is specified, it gives the name of a subroutine |
| 5712 | that returns an integer less than, equal to, or greater than C<0>, |
| 5713 | depending on how the elements of the list are to be ordered. (The |
| 5714 | C<< <=> >> and C<cmp> operators are extremely useful in such routines.) |
| 5715 | SUBNAME may be a scalar variable name (unsubscripted), in which case |
| 5716 | the value provides the name of (or a reference to) the actual |
| 5717 | subroutine to use. In place of a SUBNAME, you can provide a BLOCK as |
| 5718 | an anonymous, in-line sort subroutine. |
| 5719 | |
| 5720 | If the subroutine's prototype is C<($$)>, the elements to be compared are |
| 5721 | passed by reference in C<@_>, as for a normal subroutine. This is slower |
| 5722 | than unprototyped subroutines, where the elements to be compared are passed |
| 5723 | into the subroutine as the package global variables $a and $b (see example |
| 5724 | below). Note that in the latter case, it is usually highly counter-productive |
| 5725 | to declare $a and $b as lexicals. |
| 5726 | |
| 5727 | The values to be compared are always passed by reference and should not |
| 5728 | be modified. |
| 5729 | |
| 5730 | You also cannot exit out of the sort block or subroutine using any of the |
| 5731 | loop control operators described in L<perlsyn> or with C<goto>. |
| 5732 | |
| 5733 | When C<use locale> is in effect, C<sort LIST> sorts LIST according to the |
| 5734 | current collation locale. See L<perllocale>. |
| 5735 | |
| 5736 | sort() returns aliases into the original list, much as a for loop's index |
| 5737 | variable aliases the list elements. That is, modifying an element of a |
| 5738 | list returned by sort() (for example, in a C<foreach>, C<map> or C<grep>) |
| 5739 | actually modifies the element in the original list. This is usually |
| 5740 | something to be avoided when writing clear code. |
| 5741 | |
| 5742 | Perl 5.6 and earlier used a quicksort algorithm to implement sort. |
| 5743 | That algorithm was not stable, so I<could> go quadratic. (A I<stable> sort |
| 5744 | preserves the input order of elements that compare equal. Although |
| 5745 | quicksort's run time is O(NlogN) when averaged over all arrays of |
| 5746 | length N, the time can be O(N**2), I<quadratic> behavior, for some |
| 5747 | inputs.) In 5.7, the quicksort implementation was replaced with |
| 5748 | a stable mergesort algorithm whose worst-case behavior is O(NlogN). |
| 5749 | But benchmarks indicated that for some inputs, on some platforms, |
| 5750 | the original quicksort was faster. 5.8 has a sort pragma for |
| 5751 | limited control of the sort. Its rather blunt control of the |
| 5752 | underlying algorithm may not persist into future Perls, but the |
| 5753 | ability to characterize the input or output in implementation |
| 5754 | independent ways quite probably will. See L<the sort pragma|sort>. |
| 5755 | |
| 5756 | Examples: |
| 5757 | |
| 5758 | # sort lexically |
| 5759 | @articles = sort @files; |
| 5760 | |
| 5761 | # same thing, but with explicit sort routine |
| 5762 | @articles = sort {$a cmp $b} @files; |
| 5763 | |
| 5764 | # now case-insensitively |
| 5765 | @articles = sort {uc($a) cmp uc($b)} @files; |
| 5766 | |
| 5767 | # same thing in reversed order |
| 5768 | @articles = sort {$b cmp $a} @files; |
| 5769 | |
| 5770 | # sort numerically ascending |
| 5771 | @articles = sort {$a <=> $b} @files; |
| 5772 | |
| 5773 | # sort numerically descending |
| 5774 | @articles = sort {$b <=> $a} @files; |
| 5775 | |
| 5776 | # this sorts the %age hash by value instead of key |
| 5777 | # using an in-line function |
| 5778 | @eldest = sort { $age{$b} <=> $age{$a} } keys %age; |
| 5779 | |
| 5780 | # sort using explicit subroutine name |
| 5781 | sub byage { |
| 5782 | $age{$a} <=> $age{$b}; # presuming numeric |
| 5783 | } |
| 5784 | @sortedclass = sort byage @class; |
| 5785 | |
| 5786 | sub backwards { $b cmp $a } |
| 5787 | @harry = qw(dog cat x Cain Abel); |
| 5788 | @george = qw(gone chased yz Punished Axed); |
| 5789 | print sort @harry; |
| 5790 | # prints AbelCaincatdogx |
| 5791 | print sort backwards @harry; |
| 5792 | # prints xdogcatCainAbel |
| 5793 | print sort @george, 'to', @harry; |
| 5794 | # prints AbelAxedCainPunishedcatchaseddoggonetoxyz |
| 5795 | |
| 5796 | # inefficiently sort by descending numeric compare using |
| 5797 | # the first integer after the first = sign, or the |
| 5798 | # whole record case-insensitively otherwise |
| 5799 | |
| 5800 | my @new = sort { |
| 5801 | ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0] |
| 5802 | || |
| 5803 | uc($a) cmp uc($b) |
| 5804 | } @old; |
| 5805 | |
| 5806 | # same thing, but much more efficiently; |
| 5807 | # we'll build auxiliary indices instead |
| 5808 | # for speed |
| 5809 | my @nums = @caps = (); |
| 5810 | for (@old) { |
| 5811 | push @nums, ( /=(\d+)/ ? $1 : undef ); |
| 5812 | push @caps, uc($_); |
| 5813 | } |
| 5814 | |
| 5815 | my @new = @old[ sort { |
| 5816 | $nums[$b] <=> $nums[$a] |
| 5817 | || |
| 5818 | $caps[$a] cmp $caps[$b] |
| 5819 | } 0..$#old |
| 5820 | ]; |
| 5821 | |
| 5822 | # same thing, but without any temps |
| 5823 | @new = map { $_->[0] } |
| 5824 | sort { $b->[1] <=> $a->[1] |
| 5825 | || |
| 5826 | $a->[2] cmp $b->[2] |
| 5827 | } map { [$_, /=(\d+)/, uc($_)] } @old; |
| 5828 | |
| 5829 | # using a prototype allows you to use any comparison subroutine |
| 5830 | # as a sort subroutine (including other package's subroutines) |
| 5831 | package other; |
| 5832 | sub backwards ($$) { $_[1] cmp $_[0]; } # $a and $b are not set here |
| 5833 | |
| 5834 | package main; |
| 5835 | @new = sort other::backwards @old; |
| 5836 | |
| 5837 | # guarantee stability, regardless of algorithm |
| 5838 | use sort 'stable'; |
| 5839 | @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old; |
| 5840 | |
| 5841 | # force use of mergesort (not portable outside Perl 5.8) |
| 5842 | use sort '_mergesort'; # note discouraging _ |
| 5843 | @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old; |
| 5844 | |
| 5845 | Warning: syntactical care is required when sorting the list returned from |
| 5846 | a function. If you want to sort the list returned by the function call |
| 5847 | C<find_records(@key)>, you can use: |
| 5848 | |
| 5849 | @contact = sort { $a cmp $b } find_records @key; |
| 5850 | @contact = sort +find_records(@key); |
| 5851 | @contact = sort &find_records(@key); |
| 5852 | @contact = sort(find_records(@key)); |
| 5853 | |
| 5854 | If instead you want to sort the array @key with the comparison routine |
| 5855 | C<find_records()> then you can use: |
| 5856 | |
| 5857 | @contact = sort { find_records() } @key; |
| 5858 | @contact = sort find_records(@key); |
| 5859 | @contact = sort(find_records @key); |
| 5860 | @contact = sort(find_records (@key)); |
| 5861 | |
| 5862 | If you're using strict, you I<must not> declare $a |
| 5863 | and $b as lexicals. They are package globals. That means |
| 5864 | that if you're in the C<main> package and type |
| 5865 | |
| 5866 | @articles = sort {$b <=> $a} @files; |
| 5867 | |
| 5868 | then C<$a> and C<$b> are C<$main::a> and C<$main::b> (or C<$::a> and C<$::b>), |
| 5869 | but if you're in the C<FooPack> package, it's the same as typing |
| 5870 | |
| 5871 | @articles = sort {$FooPack::b <=> $FooPack::a} @files; |
| 5872 | |
| 5873 | The comparison function is required to behave. If it returns |
| 5874 | inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and |
| 5875 | sometimes saying the opposite, for example) the results are not |
| 5876 | well-defined. |
| 5877 | |
| 5878 | Because C<< <=> >> returns C<undef> when either operand is C<NaN> |
| 5879 | (not-a-number), and laso because C<sort> raises an exception unless the |
| 5880 | result of a comparison is defined, be careful when sorting with a |
| 5881 | comparison function like C<< $a <=> $b >> any lists that might contain a |
| 5882 | C<NaN>. The following example takes advantage that C<NaN != NaN> to |
| 5883 | eliminate any C<NaN>s from the input list. |
| 5884 | |
| 5885 | @result = sort { $a <=> $b } grep { $_ == $_ } @input; |
| 5886 | |
| 5887 | =item splice ARRAY or EXPR,OFFSET,LENGTH,LIST |
| 5888 | X<splice> |
| 5889 | |
| 5890 | =item splice ARRAY or EXPR,OFFSET,LENGTH |
| 5891 | |
| 5892 | =item splice ARRAY or EXPR,OFFSET |
| 5893 | |
| 5894 | =item splice ARRAY or EXPR |
| 5895 | |
| 5896 | Removes the elements designated by OFFSET and LENGTH from an array, and |
| 5897 | replaces them with the elements of LIST, if any. In list context, |
| 5898 | returns the elements removed from the array. In scalar context, |
| 5899 | returns the last element removed, or C<undef> if no elements are |
| 5900 | removed. The array grows or shrinks as necessary. |
| 5901 | If OFFSET is negative then it starts that far from the end of the array. |
| 5902 | If LENGTH is omitted, removes everything from OFFSET onward. |
| 5903 | If LENGTH is negative, removes the elements from OFFSET onward |
| 5904 | except for -LENGTH elements at the end of the array. |
| 5905 | If both OFFSET and LENGTH are omitted, removes everything. If OFFSET is |
| 5906 | past the end of the array, Perl issues a warning, and splices at the |
| 5907 | end of the array. |
| 5908 | |
| 5909 | The following equivalences hold (assuming C<< $[ == 0 and $#a >= $i >> ) |
| 5910 | |
| 5911 | push(@a,$x,$y) splice(@a,@a,0,$x,$y) |
| 5912 | pop(@a) splice(@a,-1) |
| 5913 | shift(@a) splice(@a,0,1) |
| 5914 | unshift(@a,$x,$y) splice(@a,0,0,$x,$y) |
| 5915 | $a[$i] = $y splice(@a,$i,1,$y) |
| 5916 | |
| 5917 | Example, assuming array lengths are passed before arrays: |
| 5918 | |
| 5919 | sub aeq { # compare two list values |
| 5920 | my(@a) = splice(@_,0,shift); |
| 5921 | my(@b) = splice(@_,0,shift); |
| 5922 | return 0 unless @a == @b; # same len? |
| 5923 | while (@a) { |
| 5924 | return 0 if pop(@a) ne pop(@b); |
| 5925 | } |
| 5926 | return 1; |
| 5927 | } |
| 5928 | if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... } |
| 5929 | |
| 5930 | Starting with Perl 5.14, C<splice> can take scalar EXPR, which must hold a |
| 5931 | reference to an unblessed array. The argument will be dereferenced |
| 5932 | automatically. This aspect of C<splice> is considered highly experimental. |
| 5933 | The exact behaviour may change in a future version of Perl. |
| 5934 | |
| 5935 | =item split /PATTERN/,EXPR,LIMIT |
| 5936 | X<split> |
| 5937 | |
| 5938 | =item split /PATTERN/,EXPR |
| 5939 | |
| 5940 | =item split /PATTERN/ |
| 5941 | |
| 5942 | =item split |
| 5943 | |
| 5944 | Splits the string EXPR into a list of strings and returns that list. By |
| 5945 | default, empty leading fields are preserved, and empty trailing ones are |
| 5946 | deleted. (If all fields are empty, they are considered to be trailing.) |
| 5947 | |
| 5948 | In scalar context, returns the number of fields found. |
| 5949 | |
| 5950 | If EXPR is omitted, splits the C<$_> string. If PATTERN is also omitted, |
| 5951 | splits on whitespace (after skipping any leading whitespace). Anything |
| 5952 | matching PATTERN is taken to be a delimiter separating the fields. (Note |
| 5953 | that the delimiter may be longer than one character.) |
| 5954 | |
| 5955 | If LIMIT is specified and positive, it represents the maximum number |
| 5956 | of fields the EXPR will be split into, though the actual number of |
| 5957 | fields returned depends on the number of times PATTERN matches within |
| 5958 | EXPR. If LIMIT is unspecified or zero, trailing null fields are |
| 5959 | stripped (which potential users of C<pop> would do well to remember). |
| 5960 | If LIMIT is negative, it is treated as if an arbitrarily large LIMIT |
| 5961 | had been specified. Note that splitting an EXPR that evaluates to the |
| 5962 | empty string always returns the empty list, regardless of the LIMIT |
| 5963 | specified. |
| 5964 | |
| 5965 | A pattern matching the empty string (not to be confused with |
| 5966 | an empty pattern C<//>, which is just one member of the set of patterns |
| 5967 | matching the epmty string), splits EXPR into individual |
| 5968 | characters. For example: |
| 5969 | |
| 5970 | print join(':', split(/ */, 'hi there')), "\n"; |
| 5971 | |
| 5972 | produces the output 'h:i:t:h:e:r:e'. |
| 5973 | |
| 5974 | As a special case for C<split>, the empty pattern C<//> specifically |
| 5975 | matches the empty string; this is not be confused with the normal use |
| 5976 | of an empty pattern to mean the last successful match. So to split |
| 5977 | a string into individual characters, the following: |
| 5978 | |
| 5979 | print join(':', split(//, 'hi there')), "\n"; |
| 5980 | |
| 5981 | produces the output 'h:i: :t:h:e:r:e'. |
| 5982 | |
| 5983 | Empty leading fields are produced when there are positive-width matches at |
| 5984 | the beginning of the string; a zero-width match at the beginning of |
| 5985 | the string does not produce an empty field. For example: |
| 5986 | |
| 5987 | print join(':', split(/(?=\w)/, 'hi there!')); |
| 5988 | |
| 5989 | produces the output 'h:i :t:h:e:r:e!'. Empty trailing fields, on the other |
| 5990 | hand, are produced when there is a match at the end of the string (and |
| 5991 | when LIMIT is given and is not 0), regardless of the length of the match. |
| 5992 | For example: |
| 5993 | |
| 5994 | print join(':', split(//, 'hi there!', -1)), "\n"; |
| 5995 | print join(':', split(/\W/, 'hi there!', -1)), "\n"; |
| 5996 | |
| 5997 | produce the output 'h:i: :t:h:e:r:e:!:' and 'hi:there:', respectively, |
| 5998 | both with an empty trailing field. |
| 5999 | |
| 6000 | The LIMIT parameter can be used to split a line partially |
| 6001 | |
| 6002 | ($login, $passwd, $remainder) = split(/:/, $_, 3); |
| 6003 | |
| 6004 | When assigning to a list, if LIMIT is omitted, or zero, Perl supplies |
| 6005 | a LIMIT one larger than the number of variables in the list, to avoid |
| 6006 | unnecessary work. For the list above LIMIT would have been 4 by |
| 6007 | default. In time critical applications it behooves you not to split |
| 6008 | into more fields than you really need. |
| 6009 | |
| 6010 | If the PATTERN contains parentheses, additional list elements are |
| 6011 | created from each matching substring in the delimiter. |
| 6012 | |
| 6013 | split(/([,-])/, "1-10,20", 3); |
| 6014 | |
| 6015 | produces the list value |
| 6016 | |
| 6017 | (1, '-', 10, ',', 20) |
| 6018 | |
| 6019 | If you had the entire header of a normal Unix email message in $header, |
| 6020 | you could split it up into fields and their values this way: |
| 6021 | |
| 6022 | $header =~ s/\n(?=\s)//g; # fix continuation lines |
| 6023 | %hdrs = (UNIX_FROM => split /^(\S*?):\s*/m, $header); |
| 6024 | |
| 6025 | The pattern C</PATTERN/> may be replaced with an expression to specify |
| 6026 | patterns that vary at runtime. (To do runtime compilation only once, |
| 6027 | use C</$variable/o>.) |
| 6028 | |
| 6029 | As a special case, specifying a PATTERN of space (S<C<' '>>) will split on |
| 6030 | white space just as C<split> with no arguments does. Thus, S<C<split(' ')>> can |
| 6031 | be used to emulate B<awk>'s default behavior, whereas S<C<split(/ /)>> |
| 6032 | will give you as many initial null fields (empty string) as there are leading spaces. |
| 6033 | A C<split> on C</\s+/> is like a S<C<split(' ')>> except that any leading |
| 6034 | whitespace produces a null first field. A C<split> with no arguments |
| 6035 | really does a S<C<split(' ', $_)>> internally. |
| 6036 | |
| 6037 | A PATTERN of C</^/> is treated as if it were C</^/m>, since it isn't |
| 6038 | much use otherwise. |
| 6039 | |
| 6040 | Example: |
| 6041 | |
| 6042 | open(PASSWD, '/etc/passwd'); |
| 6043 | while (<PASSWD>) { |
| 6044 | chomp; |
| 6045 | ($login, $passwd, $uid, $gid, |
| 6046 | $gcos, $home, $shell) = split(/:/); |
| 6047 | #... |
| 6048 | } |
| 6049 | |
| 6050 | As with regular pattern matching, any capturing parentheses that are not |
| 6051 | matched in a C<split()> will be set to C<undef> when returned: |
| 6052 | |
| 6053 | @fields = split /(A)|B/, "1A2B3"; |
| 6054 | # @fields is (1, 'A', 2, undef, 3) |
| 6055 | |
| 6056 | =item sprintf FORMAT, LIST |
| 6057 | X<sprintf> |
| 6058 | |
| 6059 | Returns a string formatted by the usual C<printf> conventions of the C |
| 6060 | library function C<sprintf>. See below for more details |
| 6061 | and see C<sprintf(3)> or C<printf(3)> on your system for an explanation of |
| 6062 | the general principles. |
| 6063 | |
| 6064 | For example: |
| 6065 | |
| 6066 | # Format number with up to 8 leading zeroes |
| 6067 | $result = sprintf("%08d", $number); |
| 6068 | |
| 6069 | # Round number to 3 digits after decimal point |
| 6070 | $rounded = sprintf("%.3f", $number); |
| 6071 | |
| 6072 | Perl does its own C<sprintf> formatting: it emulates the C |
| 6073 | function sprintf(3), but doesn't use it except for floating-point |
| 6074 | numbers, and even then only standard modifiers are allowed. |
| 6075 | Non-standard extensions in your local sprintf(3) are |
| 6076 | therefore unavailable from Perl. |
| 6077 | |
| 6078 | Unlike C<printf>, C<sprintf> does not do what you probably mean when you |
| 6079 | pass it an array as your first argument. The array is given scalar context, |
| 6080 | and instead of using the 0th element of the array as the format, Perl will |
| 6081 | use the count of elements in the array as the format, which is almost never |
| 6082 | useful. |
| 6083 | |
| 6084 | Perl's C<sprintf> permits the following universally-known conversions: |
| 6085 | |
| 6086 | %% a percent sign |
| 6087 | %c a character with the given number |
| 6088 | %s a string |
| 6089 | %d a signed integer, in decimal |
| 6090 | %u an unsigned integer, in decimal |
| 6091 | %o an unsigned integer, in octal |
| 6092 | %x an unsigned integer, in hexadecimal |
| 6093 | %e a floating-point number, in scientific notation |
| 6094 | %f a floating-point number, in fixed decimal notation |
| 6095 | %g a floating-point number, in %e or %f notation |
| 6096 | |
| 6097 | In addition, Perl permits the following widely-supported conversions: |
| 6098 | |
| 6099 | %X like %x, but using upper-case letters |
| 6100 | %E like %e, but using an upper-case "E" |
| 6101 | %G like %g, but with an upper-case "E" (if applicable) |
| 6102 | %b an unsigned integer, in binary |
| 6103 | %B like %b, but using an upper-case "B" with the # flag |
| 6104 | %p a pointer (outputs the Perl value's address in hexadecimal) |
| 6105 | %n special: *stores* the number of characters output so far |
| 6106 | into the next variable in the parameter list |
| 6107 | |
| 6108 | Finally, for backward (and we do mean "backward") compatibility, Perl |
| 6109 | permits these unnecessary but widely-supported conversions: |
| 6110 | |
| 6111 | %i a synonym for %d |
| 6112 | %D a synonym for %ld |
| 6113 | %U a synonym for %lu |
| 6114 | %O a synonym for %lo |
| 6115 | %F a synonym for %f |
| 6116 | |
| 6117 | Note that the number of exponent digits in the scientific notation produced |
| 6118 | by C<%e>, C<%E>, C<%g> and C<%G> for numbers with the modulus of the |
| 6119 | exponent less than 100 is system-dependent: it may be three or less |
| 6120 | (zero-padded as necessary). In other words, 1.23 times ten to the |
| 6121 | 99th may be either "1.23e99" or "1.23e099". |
| 6122 | |
| 6123 | Between the C<%> and the format letter, you may specify several |
| 6124 | additional attributes controlling the interpretation of the format. |
| 6125 | In order, these are: |
| 6126 | |
| 6127 | =over 4 |
| 6128 | |
| 6129 | =item format parameter index |
| 6130 | |
| 6131 | An explicit format parameter index, such as C<2$>. By default sprintf |
| 6132 | will format the next unused argument in the list, but this allows you |
| 6133 | to take the arguments out of order: |
| 6134 | |
| 6135 | printf '%2$d %1$d', 12, 34; # prints "34 12" |
| 6136 | printf '%3$d %d %1$d', 1, 2, 3; # prints "3 1 1" |
| 6137 | |
| 6138 | =item flags |
| 6139 | |
| 6140 | one or more of: |
| 6141 | |
| 6142 | space prefix non-negative number with a space |
| 6143 | + prefix non-negative number with a plus sign |
| 6144 | - left-justify within the field |
| 6145 | 0 use zeros, not spaces, to right-justify |
| 6146 | # ensure the leading "0" for any octal, |
| 6147 | prefix non-zero hexadecimal with "0x" or "0X", |
| 6148 | prefix non-zero binary with "0b" or "0B" |
| 6149 | |
| 6150 | For example: |
| 6151 | |
| 6152 | printf '<% d>', 12; # prints "< 12>" |
| 6153 | printf '<%+d>', 12; # prints "<+12>" |
| 6154 | printf '<%6s>', 12; # prints "< 12>" |
| 6155 | printf '<%-6s>', 12; # prints "<12 >" |
| 6156 | printf '<%06s>', 12; # prints "<000012>" |
| 6157 | printf '<%#o>', 12; # prints "<014>" |
| 6158 | printf '<%#x>', 12; # prints "<0xc>" |
| 6159 | printf '<%#X>', 12; # prints "<0XC>" |
| 6160 | printf '<%#b>', 12; # prints "<0b1100>" |
| 6161 | printf '<%#B>', 12; # prints "<0B1100>" |
| 6162 | |
| 6163 | When a space and a plus sign are given as the flags at once, |
| 6164 | a plus sign is used to prefix a positive number. |
| 6165 | |
| 6166 | printf '<%+ d>', 12; # prints "<+12>" |
| 6167 | printf '<% +d>', 12; # prints "<+12>" |
| 6168 | |
| 6169 | When the # flag and a precision are given in the %o conversion, |
| 6170 | the precision is incremented if it's necessary for the leading "0". |
| 6171 | |
| 6172 | printf '<%#.5o>', 012; # prints "<00012>" |
| 6173 | printf '<%#.5o>', 012345; # prints "<012345>" |
| 6174 | printf '<%#.0o>', 0; # prints "<0>" |
| 6175 | |
| 6176 | =item vector flag |
| 6177 | |
| 6178 | This flag tells Perl to interpret the supplied string as a vector of |
| 6179 | integers, one for each character in the string. Perl applies the format to |
| 6180 | each integer in turn, then joins the resulting strings with a separator (a |
| 6181 | dot C<.> by default). This can be useful for displaying ordinal values of |
| 6182 | characters in arbitrary strings: |
| 6183 | |
| 6184 | printf "%vd", "AB\x{100}"; # prints "65.66.256" |
| 6185 | printf "version is v%vd\n", $^V; # Perl's version |
| 6186 | |
| 6187 | Put an asterisk C<*> before the C<v> to override the string to |
| 6188 | use to separate the numbers: |
| 6189 | |
| 6190 | printf "address is %*vX\n", ":", $addr; # IPv6 address |
| 6191 | printf "bits are %0*v8b\n", " ", $bits; # random bitstring |
| 6192 | |
| 6193 | You can also explicitly specify the argument number to use for |
| 6194 | the join string using something like C<*2$v>; for example: |
| 6195 | |
| 6196 | printf '%*4$vX %*4$vX %*4$vX', @addr[1..3], ":"; # 3 IPv6 addresses |
| 6197 | |
| 6198 | =item (minimum) width |
| 6199 | |
| 6200 | Arguments are usually formatted to be only as wide as required to |
| 6201 | display the given value. You can override the width by putting |
| 6202 | a number here, or get the width from the next argument (with C<*>) |
| 6203 | or from a specified argument (e.g., with C<*2$>): |
| 6204 | |
| 6205 | printf "<%s>", "a"; # prints "<a>" |
| 6206 | printf "<%6s>", "a"; # prints "< a>" |
| 6207 | printf "<%*s>", 6, "a"; # prints "< a>" |
| 6208 | printf "<%*2$s>", "a", 6; # prints "< a>" |
| 6209 | printf "<%2s>", "long"; # prints "<long>" (does not truncate) |
| 6210 | |
| 6211 | If a field width obtained through C<*> is negative, it has the same |
| 6212 | effect as the C<-> flag: left-justification. |
| 6213 | |
| 6214 | =item precision, or maximum width |
| 6215 | X<precision> |
| 6216 | |
| 6217 | You can specify a precision (for numeric conversions) or a maximum |
| 6218 | width (for string conversions) by specifying a C<.> followed by a number. |
| 6219 | For floating-point formats except C<g> and C<G>, this specifies |
| 6220 | how many places right of the decimal point to show (the default being 6). |
| 6221 | For example: |
| 6222 | |
| 6223 | # these examples are subject to system-specific variation |
| 6224 | printf '<%f>', 1; # prints "<1.000000>" |
| 6225 | printf '<%.1f>', 1; # prints "<1.0>" |
| 6226 | printf '<%.0f>', 1; # prints "<1>" |
| 6227 | printf '<%e>', 10; # prints "<1.000000e+01>" |
| 6228 | printf '<%.1e>', 10; # prints "<1.0e+01>" |
| 6229 | |
| 6230 | For "g" and "G", this specifies the maximum number of digits to show, |
| 6231 | including thoe prior to the decimal point and those after it; for |
| 6232 | example: |
| 6233 | |
| 6234 | # These examples are subject to system-specific variation. |
| 6235 | printf '<%g>', 1; # prints "<1>" |
| 6236 | printf '<%.10g>', 1; # prints "<1>" |
| 6237 | printf '<%g>', 100; # prints "<100>" |
| 6238 | printf '<%.1g>', 100; # prints "<1e+02>" |
| 6239 | printf '<%.2g>', 100.01; # prints "<1e+02>" |
| 6240 | printf '<%.5g>', 100.01; # prints "<100.01>" |
| 6241 | printf '<%.4g>', 100.01; # prints "<100>" |
| 6242 | |
| 6243 | For integer conversions, specifying a precision implies that the |
| 6244 | output of the number itself should be zero-padded to this width, |
| 6245 | where the 0 flag is ignored: |
| 6246 | |
| 6247 | printf '<%.6d>', 1; # prints "<000001>" |
| 6248 | printf '<%+.6d>', 1; # prints "<+000001>" |
| 6249 | printf '<%-10.6d>', 1; # prints "<000001 >" |
| 6250 | printf '<%10.6d>', 1; # prints "< 000001>" |
| 6251 | printf '<%010.6d>', 1; # prints "< 000001>" |
| 6252 | printf '<%+10.6d>', 1; # prints "< +000001>" |
| 6253 | |
| 6254 | printf '<%.6x>', 1; # prints "<000001>" |
| 6255 | printf '<%#.6x>', 1; # prints "<0x000001>" |
| 6256 | printf '<%-10.6x>', 1; # prints "<000001 >" |
| 6257 | printf '<%10.6x>', 1; # prints "< 000001>" |
| 6258 | printf '<%010.6x>', 1; # prints "< 000001>" |
| 6259 | printf '<%#10.6x>', 1; # prints "< 0x000001>" |
| 6260 | |
| 6261 | For string conversions, specifying a precision truncates the string |
| 6262 | to fit the specified width: |
| 6263 | |
| 6264 | printf '<%.5s>', "truncated"; # prints "<trunc>" |
| 6265 | printf '<%10.5s>', "truncated"; # prints "< trunc>" |
| 6266 | |
| 6267 | You can also get the precision from the next argument using C<.*>: |
| 6268 | |
| 6269 | printf '<%.6x>', 1; # prints "<000001>" |
| 6270 | printf '<%.*x>', 6, 1; # prints "<000001>" |
| 6271 | |
| 6272 | If a precision obtained through C<*> is negative, it counts |
| 6273 | as having no precision at all. |
| 6274 | |
| 6275 | printf '<%.*s>', 7, "string"; # prints "<string>" |
| 6276 | printf '<%.*s>', 3, "string"; # prints "<str>" |
| 6277 | printf '<%.*s>', 0, "string"; # prints "<>" |
| 6278 | printf '<%.*s>', -1, "string"; # prints "<string>" |
| 6279 | |
| 6280 | printf '<%.*d>', 1, 0; # prints "<0>" |
| 6281 | printf '<%.*d>', 0, 0; # prints "<>" |
| 6282 | printf '<%.*d>', -1, 0; # prints "<0>" |
| 6283 | |
| 6284 | You cannot currently get the precision from a specified number, |
| 6285 | but it is intended that this will be possible in the future, for |
| 6286 | example using C<.*2$>: |
| 6287 | |
| 6288 | printf "<%.*2$x>", 1, 6; # INVALID, but in future will print "<000001>" |
| 6289 | |
| 6290 | =item size |
| 6291 | |
| 6292 | For numeric conversions, you can specify the size to interpret the |
| 6293 | number as using C<l>, C<h>, C<V>, C<q>, C<L>, or C<ll>. For integer |
| 6294 | conversions (C<d u o x X b i D U O>), numbers are usually assumed to be |
| 6295 | whatever the default integer size is on your platform (usually 32 or 64 |
| 6296 | bits), but you can override this to use instead one of the standard C types, |
| 6297 | as supported by the compiler used to build Perl: |
| 6298 | |
| 6299 | hh interpret integer as C type "char" or "unsigned char" |
| 6300 | on Perl 5.14 or later |
| 6301 | h interpret integer as C type "short" or "unsigned short" |
| 6302 | j interpret integer as C type "intmax_t" on Perl 5.14 |
| 6303 | or later, and only with a C99 compiler (unportable) |
| 6304 | l interpret integer as C type "long" or "unsigned long" |
| 6305 | q, L, or ll interpret integer as C type "long long", "unsigned long long", |
| 6306 | or "quad" (typically 64-bit integers) |
| 6307 | t interpret integer as C type "ptrdiff_t" on Perl 5.14 or later |
| 6308 | z interpret integer as C type "size_t" on Perl 5.14 or later |
| 6309 | |
| 6310 | As of 5.14, none of these raises an exception if they are not supported on |
| 6311 | your platform. However, if warnings are enabled, a warning of the |
| 6312 | C<printf> warning class is issued on an unsupported conversion flag. |
| 6313 | Should you instead prefer an exception, do this: |
| 6314 | |
| 6315 | use warnings FATAL => "printf"; |
| 6316 | |
| 6317 | If you would like to know about a version dependency before you |
| 6318 | start running the program, put something like this at its top: |
| 6319 | |
| 6320 | use 5.014; # for hh/j/t/z/ printf modifiers |
| 6321 | |
| 6322 | You can find out whether your Perl supports quads via L<Config>: |
| 6323 | |
| 6324 | use Config; |
| 6325 | if ($Config{use64bitint} eq "define" || $Config{longsize} >= 8) { |
| 6326 | print "Nice quads!\n"; |
| 6327 | } |
| 6328 | |
| 6329 | For floating-point conversions (C<e f g E F G>), numbers are usually assumed |
| 6330 | to be the default floating-point size on your platform (double or long double), |
| 6331 | but you can force "long double" with C<q>, C<L>, or C<ll> if your |
| 6332 | platform supports them. You can find out whether your Perl supports long |
| 6333 | doubles via L<Config>: |
| 6334 | |
| 6335 | use Config; |
| 6336 | print "long doubles\n" if $Config{d_longdbl} eq "define"; |
| 6337 | |
| 6338 | You can find out whether Perl considers "long double" to be the default |
| 6339 | floating-point size to use on your platform via L<Config>: |
| 6340 | |
| 6341 | use Config; |
| 6342 | if ($Config{uselongdouble} eq "define") { |
| 6343 | print "long doubles by default\n"; |
| 6344 | } |
| 6345 | |
| 6346 | It can also be that long doubles and doubles are the same thing: |
| 6347 | |
| 6348 | use Config; |
| 6349 | ($Config{doublesize} == $Config{longdblsize}) && |
| 6350 | print "doubles are long doubles\n"; |
| 6351 | |
| 6352 | The size specifier C<V> has no effect for Perl code, but is supported for |
| 6353 | compatibility with XS code. It means "use the standard size for a Perl |
| 6354 | integer or floating-point number", which is the default. |
| 6355 | |
| 6356 | =item order of arguments |
| 6357 | |
| 6358 | Normally, sprintf() takes the next unused argument as the value to |
| 6359 | format for each format specification. If the format specification |
| 6360 | uses C<*> to require additional arguments, these are consumed from |
| 6361 | the argument list in the order they appear in the format |
| 6362 | specification I<before> the value to format. Where an argument is |
| 6363 | specified by an explicit index, this does not affect the normal |
| 6364 | order for the arguments, even when the explicitly specified index |
| 6365 | would have been the next argument. |
| 6366 | |
| 6367 | So: |
| 6368 | |
| 6369 | printf "<%*.*s>", $a, $b, $c; |
| 6370 | |
| 6371 | uses C<$a> for the width, C<$b> for the precision, and C<$c> |
| 6372 | as the value to format; while: |
| 6373 | |
| 6374 | printf "<%*1$.*s>", $a, $b; |
| 6375 | |
| 6376 | would use C<$a> for the width and precision, and C<$b> as the |
| 6377 | value to format. |
| 6378 | |
| 6379 | Here are some more examples; be aware that when using an explicit |
| 6380 | index, the C<$> may need escaping: |
| 6381 | |
| 6382 | printf "%2\$d %d\n", 12, 34; # will print "34 12\n" |
| 6383 | printf "%2\$d %d %d\n", 12, 34; # will print "34 12 34\n" |
| 6384 | printf "%3\$d %d %d\n", 12, 34, 56; # will print "56 12 34\n" |
| 6385 | printf "%2\$*3\$d %d\n", 12, 34, 3; # will print " 34 12\n" |
| 6386 | |
| 6387 | =back |
| 6388 | |
| 6389 | If C<use locale> is in effect and POSIX::setlocale() has been called, |
| 6390 | the character used for the decimal separator in formatted floating-point |
| 6391 | numbers is affected by the LC_NUMERIC locale. See L<perllocale> |
| 6392 | and L<POSIX>. |
| 6393 | |
| 6394 | =item sqrt EXPR |
| 6395 | X<sqrt> X<root> X<square root> |
| 6396 | |
| 6397 | =item sqrt |
| 6398 | |
| 6399 | Return the positive square root of EXPR. If EXPR is omitted, uses |
| 6400 | C<$_>. Works only for non-negative operands unless you've |
| 6401 | loaded the C<Math::Complex> module. |
| 6402 | |
| 6403 | use Math::Complex; |
| 6404 | print sqrt(-4); # prints 2i |
| 6405 | |
| 6406 | =item srand EXPR |
| 6407 | X<srand> X<seed> X<randseed> |
| 6408 | |
| 6409 | =item srand |
| 6410 | |
| 6411 | Sets and returns the random number seed for the C<rand> operator. |
| 6412 | |
| 6413 | The point of the function is to "seed" the C<rand> function so that |
| 6414 | C<rand> can produce a different sequence each time you run your |
| 6415 | program. When called with a parameter, C<srand> uses that for the seed; |
| 6416 | otherwise it (semi-)randomly chooses a seed. In either case, starting with |
| 6417 | Perl 5.14, it returns the seed. |
| 6418 | |
| 6419 | If C<srand()> is not called explicitly, it is called implicitly without a |
| 6420 | parameter at the first use of the C<rand> operator. However, this was not true |
| 6421 | of versions of Perl before 5.004, so if your script will run under older |
| 6422 | Perl versions, it should call C<srand>; otherwise most programs won't call |
| 6423 | C<srand()> at all. |
| 6424 | |
| 6425 | But there are a few situations in recent Perls where programs are likely to |
| 6426 | want to call C<srand>. One is for generating predictable results generally for |
| 6427 | testing or debugging. There, you use C<srand($seed)>, with the same C<$seed> |
| 6428 | each time. Another other case is where you need a cryptographically-strong |
| 6429 | starting point rather than the generally acceptable default, which is based on |
| 6430 | time of day, process ID, and memory allocation, or the F</dev/urandom> device |
| 6431 | if available. And still another case is that you may want to call C<srand()> |
| 6432 | after a C<fork()> to avoid child processes sharing the same seed value as the |
| 6433 | parent (and consequently each other). |
| 6434 | |
| 6435 | Do B<not> call C<srand()> (i.e., without an argument) more than once per |
| 6436 | process. The internal state of the random number generator should |
| 6437 | contain more entropy than can be provided by any seed, so calling |
| 6438 | C<srand()> again actually I<loses> randomness. |
| 6439 | |
| 6440 | Most implementations of C<srand> take an integer and will silently |
| 6441 | truncate decimal numbers. This means C<srand(42)> will usually |
| 6442 | produce the same results as C<srand(42.1)>. To be safe, always pass |
| 6443 | C<srand> an integer. |
| 6444 | |
| 6445 | In versions of Perl prior to 5.004 the default seed was just the |
| 6446 | current C<time>. This isn't a particularly good seed, so many old |
| 6447 | programs supply their own seed value (often C<time ^ $$> or C<time ^ |
| 6448 | ($$ + ($$ << 15))>), but that isn't necessary any more. |
| 6449 | |
| 6450 | For cryptographic purposes, however, you need something much more random |
| 6451 | than the default seed. Checksumming the compressed output of one or more |
| 6452 | rapidly changing operating system status programs is the usual method. For |
| 6453 | example: |
| 6454 | |
| 6455 | srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip -f`); |
| 6456 | |
| 6457 | If you're particularly concerned with this, search the CPAN for |
| 6458 | random number generator modules instead of rolling out your own. |
| 6459 | |
| 6460 | Frequently called programs (like CGI scripts) that simply use |
| 6461 | |
| 6462 | time ^ $$ |
| 6463 | |
| 6464 | for a seed can fall prey to the mathematical property that |
| 6465 | |
| 6466 | a^b == (a+1)^(b+1) |
| 6467 | |
| 6468 | one-third of the time. So don't do that. |
| 6469 | |
| 6470 | A typical use of the returned seed is for a test program which has too many |
| 6471 | combinations to test comprehensively in the time available to it each run. It |
| 6472 | can test a random subset each time, and should there be a failure, log the seed |
| 6473 | used for that run so that it can later be used to reproduce the same results. |
| 6474 | |
| 6475 | =item stat FILEHANDLE |
| 6476 | X<stat> X<file, status> X<ctime> |
| 6477 | |
| 6478 | =item stat EXPR |
| 6479 | |
| 6480 | =item stat DIRHANDLE |
| 6481 | |
| 6482 | =item stat |
| 6483 | |
| 6484 | Returns a 13-element list giving the status info for a file, either |
| 6485 | the file opened via FILEHANDLE or DIRHANDLE, or named by EXPR. If EXPR is |
| 6486 | omitted, it stats C<$_> (not C<_>!). Returns the empty list if C<stat> fails. Typically |
| 6487 | used as follows: |
| 6488 | |
| 6489 | ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size, |
| 6490 | $atime,$mtime,$ctime,$blksize,$blocks) |
| 6491 | = stat($filename); |
| 6492 | |
| 6493 | Not all fields are supported on all filesystem types. Here are the |
| 6494 | meanings of the fields: |
| 6495 | |
| 6496 | 0 dev device number of filesystem |
| 6497 | 1 ino inode number |
| 6498 | 2 mode file mode (type and permissions) |
| 6499 | 3 nlink number of (hard) links to the file |
| 6500 | 4 uid numeric user ID of file's owner |
| 6501 | 5 gid numeric group ID of file's owner |
| 6502 | 6 rdev the device identifier (special files only) |
| 6503 | 7 size total size of file, in bytes |
| 6504 | 8 atime last access time in seconds since the epoch |
| 6505 | 9 mtime last modify time in seconds since the epoch |
| 6506 | 10 ctime inode change time in seconds since the epoch (*) |
| 6507 | 11 blksize preferred block size for file system I/O |
| 6508 | 12 blocks actual number of blocks allocated |
| 6509 | |
| 6510 | (The epoch was at 00:00 January 1, 1970 GMT.) |
| 6511 | |
| 6512 | (*) Not all fields are supported on all filesystem types. Notably, the |
| 6513 | ctime field is non-portable. In particular, you cannot expect it to be a |
| 6514 | "creation time"; see L<perlport/"Files and Filesystems"> for details. |
| 6515 | |
| 6516 | If C<stat> is passed the special filehandle consisting of an underline, no |
| 6517 | stat is done, but the current contents of the stat structure from the |
| 6518 | last C<stat>, C<lstat>, or filetest are returned. Example: |
| 6519 | |
| 6520 | if (-x $file && (($d) = stat(_)) && $d < 0) { |
| 6521 | print "$file is executable NFS file\n"; |
| 6522 | } |
| 6523 | |
| 6524 | (This works on machines only for which the device number is negative |
| 6525 | under NFS.) |
| 6526 | |
| 6527 | Because the mode contains both the file type and its permissions, you |
| 6528 | should mask off the file type portion and (s)printf using a C<"%o"> |
| 6529 | if you want to see the real permissions. |
| 6530 | |
| 6531 | $mode = (stat($filename))[2]; |
| 6532 | printf "Permissions are %04o\n", $mode & 07777; |
| 6533 | |
| 6534 | In scalar context, C<stat> returns a boolean value indicating success |
| 6535 | or failure, and, if successful, sets the information associated with |
| 6536 | the special filehandle C<_>. |
| 6537 | |
| 6538 | The L<File::stat> module provides a convenient, by-name access mechanism: |
| 6539 | |
| 6540 | use File::stat; |
| 6541 | $sb = stat($filename); |
| 6542 | printf "File is %s, size is %s, perm %04o, mtime %s\n", |
| 6543 | $filename, $sb->size, $sb->mode & 07777, |
| 6544 | scalar localtime $sb->mtime; |
| 6545 | |
| 6546 | You can import symbolic mode constants (C<S_IF*>) and functions |
| 6547 | (C<S_IS*>) from the Fcntl module: |
| 6548 | |
| 6549 | use Fcntl ':mode'; |
| 6550 | |
| 6551 | $mode = (stat($filename))[2]; |
| 6552 | |
| 6553 | $user_rwx = ($mode & S_IRWXU) >> 6; |
| 6554 | $group_read = ($mode & S_IRGRP) >> 3; |
| 6555 | $other_execute = $mode & S_IXOTH; |
| 6556 | |
| 6557 | printf "Permissions are %04o\n", S_IMODE($mode), "\n"; |
| 6558 | |
| 6559 | $is_setuid = $mode & S_ISUID; |
| 6560 | $is_directory = S_ISDIR($mode); |
| 6561 | |
| 6562 | You could write the last two using the C<-u> and C<-d> operators. |
| 6563 | Commonly available C<S_IF*> constants are: |
| 6564 | |
| 6565 | # Permissions: read, write, execute, for user, group, others. |
| 6566 | |
| 6567 | S_IRWXU S_IRUSR S_IWUSR S_IXUSR |
| 6568 | S_IRWXG S_IRGRP S_IWGRP S_IXGRP |
| 6569 | S_IRWXO S_IROTH S_IWOTH S_IXOTH |
| 6570 | |
| 6571 | # Setuid/Setgid/Stickiness/SaveText. |
| 6572 | # Note that the exact meaning of these is system dependent. |
| 6573 | |
| 6574 | S_ISUID S_ISGID S_ISVTX S_ISTXT |
| 6575 | |
| 6576 | # File types. Not necessarily all are available on your system. |
| 6577 | |
| 6578 | S_IFREG S_IFDIR S_IFLNK S_IFBLK S_IFCHR S_IFIFO S_IFSOCK S_IFWHT S_ENFMT |
| 6579 | |
| 6580 | # The following are compatibility aliases for S_IRUSR, S_IWUSR, S_IXUSR. |
| 6581 | |
| 6582 | S_IREAD S_IWRITE S_IEXEC |
| 6583 | |
| 6584 | and the C<S_IF*> functions are |
| 6585 | |
| 6586 | S_IMODE($mode) the part of $mode containing the permission bits |
| 6587 | and the setuid/setgid/sticky bits |
| 6588 | |
| 6589 | S_IFMT($mode) the part of $mode containing the file type |
| 6590 | which can be bit-anded with (for example) S_IFREG |
| 6591 | or with the following functions |
| 6592 | |
| 6593 | # The operators -f, -d, -l, -b, -c, -p, and -S. |
| 6594 | |
| 6595 | S_ISREG($mode) S_ISDIR($mode) S_ISLNK($mode) |
| 6596 | S_ISBLK($mode) S_ISCHR($mode) S_ISFIFO($mode) S_ISSOCK($mode) |
| 6597 | |
| 6598 | # No direct -X operator counterpart, but for the first one |
| 6599 | # the -g operator is often equivalent. The ENFMT stands for |
| 6600 | # record flocking enforcement, a platform-dependent feature. |
| 6601 | |
| 6602 | S_ISENFMT($mode) S_ISWHT($mode) |
| 6603 | |
| 6604 | See your native chmod(2) and stat(2) documentation for more details |
| 6605 | about the C<S_*> constants. To get status info for a symbolic link |
| 6606 | instead of the target file behind the link, use the C<lstat> function. |
| 6607 | |
| 6608 | =item state EXPR |
| 6609 | X<state> |
| 6610 | |
| 6611 | =item state TYPE EXPR |
| 6612 | |
| 6613 | =item state EXPR : ATTRS |
| 6614 | |
| 6615 | =item state TYPE EXPR : ATTRS |
| 6616 | |
| 6617 | C<state> declares a lexically scoped variable, just like C<my> does. |
| 6618 | However, those variables will never be reinitialized, contrary to |
| 6619 | lexical variables that are reinitialized each time their enclosing block |
| 6620 | is entered. |
| 6621 | |
| 6622 | C<state> variables are enabled only when the C<use feature "state"> pragma |
| 6623 | is in effect. See L<feature>. |
| 6624 | |
| 6625 | =item study SCALAR |
| 6626 | X<study> |
| 6627 | |
| 6628 | =item study |
| 6629 | |
| 6630 | Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of |
| 6631 | doing many pattern matches on the string before it is next modified. |
| 6632 | This may or may not save time, depending on the nature and number of |
| 6633 | patterns you are searching and the distribution of character |
| 6634 | frequencies in the string to be searched; you probably want to compare |
| 6635 | run times with and without it to see which is faster. Those loops |
| 6636 | that scan for many short constant strings (including the constant |
| 6637 | parts of more complex patterns) will benefit most. You may have only |
| 6638 | one C<study> active at a time: if you study a different scalar the first |
| 6639 | is "unstudied". (The way C<study> works is this: a linked list of every |
| 6640 | character in the string to be searched is made, so we know, for |
| 6641 | example, where all the C<'k'> characters are. From each search string, |
| 6642 | the rarest character is selected, based on some static frequency tables |
| 6643 | constructed from some C programs and English text. Only those places |
| 6644 | that contain this "rarest" character are examined.) |
| 6645 | |
| 6646 | For example, here is a loop that inserts index producing entries |
| 6647 | before any line containing a certain pattern: |
| 6648 | |
| 6649 | while (<>) { |
| 6650 | study; |
| 6651 | print ".IX foo\n" if /\bfoo\b/; |
| 6652 | print ".IX bar\n" if /\bbar\b/; |
| 6653 | print ".IX blurfl\n" if /\bblurfl\b/; |
| 6654 | # ... |
| 6655 | print; |
| 6656 | } |
| 6657 | |
| 6658 | In searching for C</\bfoo\b/>, only locations in C<$_> that contain C<f> |
| 6659 | will be looked at, because C<f> is rarer than C<o>. In general, this is |
| 6660 | a big win except in pathological cases. The only question is whether |
| 6661 | it saves you more time than it took to build the linked list in the |
| 6662 | first place. |
| 6663 | |
| 6664 | Note that if you have to look for strings that you don't know till |
| 6665 | runtime, you can build an entire loop as a string and C<eval> that to |
| 6666 | avoid recompiling all your patterns all the time. Together with |
| 6667 | undefining C<$/> to input entire files as one record, this can be quite |
| 6668 | fast, often faster than specialized programs like fgrep(1). The following |
| 6669 | scans a list of files (C<@files>) for a list of words (C<@words>), and prints |
| 6670 | out the names of those files that contain a match: |
| 6671 | |
| 6672 | $search = 'while (<>) { study;'; |
| 6673 | foreach $word (@words) { |
| 6674 | $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n"; |
| 6675 | } |
| 6676 | $search .= "}"; |
| 6677 | @ARGV = @files; |
| 6678 | undef $/; |
| 6679 | eval $search; # this screams |
| 6680 | $/ = "\n"; # put back to normal input delimiter |
| 6681 | foreach $file (sort keys(%seen)) { |
| 6682 | print $file, "\n"; |
| 6683 | } |
| 6684 | |
| 6685 | =item sub NAME BLOCK |
| 6686 | X<sub> |
| 6687 | |
| 6688 | =item sub NAME (PROTO) BLOCK |
| 6689 | |
| 6690 | =item sub NAME : ATTRS BLOCK |
| 6691 | |
| 6692 | =item sub NAME (PROTO) : ATTRS BLOCK |
| 6693 | |
| 6694 | This is subroutine definition, not a real function I<per se>. Without a |
| 6695 | BLOCK it's just a forward declaration. Without a NAME, it's an anonymous |
| 6696 | function declaration, so does return a value: the CODE ref of the closure |
| 6697 | just created. |
| 6698 | |
| 6699 | See L<perlsub> and L<perlref> for details about subroutines and |
| 6700 | references; see L<attributes> and L<Attribute::Handlers> for more |
| 6701 | information about attributes. |
| 6702 | |
| 6703 | =item substr EXPR,OFFSET,LENGTH,REPLACEMENT |
| 6704 | X<substr> X<substring> X<mid> X<left> X<right> |
| 6705 | |
| 6706 | =item substr EXPR,OFFSET,LENGTH |
| 6707 | |
| 6708 | =item substr EXPR,OFFSET |
| 6709 | |
| 6710 | Extracts a substring out of EXPR and returns it. First character is at |
| 6711 | offset C<0> (or whatever you've set C<$[> to (but B<<don't do that>)). |
| 6712 | If OFFSET is negative (or more precisely, less than C<$[>), starts |
| 6713 | that far back from the end of the string. If LENGTH is omitted, returns |
| 6714 | everything through the end of the string. If LENGTH is negative, leaves that |
| 6715 | many characters off the end of the string. |
| 6716 | |
| 6717 | my $s = "The black cat climbed the green tree"; |
| 6718 | my $color = substr $s, 4, 5; # black |
| 6719 | my $middle = substr $s, 4, -11; # black cat climbed the |
| 6720 | my $end = substr $s, 14; # climbed the green tree |
| 6721 | my $tail = substr $s, -4; # tree |
| 6722 | my $z = substr $s, -4, 2; # tr |
| 6723 | |
| 6724 | You can use the substr() function as an lvalue, in which case EXPR |
| 6725 | must itself be an lvalue. If you assign something shorter than LENGTH, |
| 6726 | the string will shrink, and if you assign something longer than LENGTH, |
| 6727 | the string will grow to accommodate it. To keep the string the same |
| 6728 | length, you may need to pad or chop your value using C<sprintf>. |
| 6729 | |
| 6730 | If OFFSET and LENGTH specify a substring that is partly outside the |
| 6731 | string, only the part within the string is returned. If the substring |
| 6732 | is beyond either end of the string, substr() returns the undefined |
| 6733 | value and produces a warning. When used as an lvalue, specifying a |
| 6734 | substring that is entirely outside the string raises an exception. |
| 6735 | Here's an example showing the behavior for boundary cases: |
| 6736 | |
| 6737 | my $name = 'fred'; |
| 6738 | substr($name, 4) = 'dy'; # $name is now 'freddy' |
| 6739 | my $null = substr $name, 6, 2; # returns "" (no warning) |
| 6740 | my $oops = substr $name, 7; # returns undef, with warning |
| 6741 | substr($name, 7) = 'gap'; # raises an exception |
| 6742 | |
| 6743 | An alternative to using substr() as an lvalue is to specify the |
| 6744 | replacement string as the 4th argument. This allows you to replace |
| 6745 | parts of the EXPR and return what was there before in one operation, |
| 6746 | just as you can with splice(). |
| 6747 | |
| 6748 | my $s = "The black cat climbed the green tree"; |
| 6749 | my $z = substr $s, 14, 7, "jumped from"; # climbed |
| 6750 | # $s is now "The black cat jumped from the green tree" |
| 6751 | |
| 6752 | Note that the lvalue returned by the three-argument version of substr() acts as |
| 6753 | a 'magic bullet'; each time it is assigned to, it remembers which part |
| 6754 | of the original string is being modified; for example: |
| 6755 | |
| 6756 | $x = '1234'; |
| 6757 | for (substr($x,1,2)) { |
| 6758 | $_ = 'a'; print $x,"\n"; # prints 1a4 |
| 6759 | $_ = 'xyz'; print $x,"\n"; # prints 1xyz4 |
| 6760 | $x = '56789'; |
| 6761 | $_ = 'pq'; print $x,"\n"; # prints 5pq9 |
| 6762 | } |
| 6763 | |
| 6764 | Prior to Perl version 5.9.1, the result of using an lvalue multiple times was |
| 6765 | unspecified. |
| 6766 | |
| 6767 | =item symlink OLDFILE,NEWFILE |
| 6768 | X<symlink> X<link> X<symbolic link> X<link, symbolic> |
| 6769 | |
| 6770 | Creates a new filename symbolically linked to the old filename. |
| 6771 | Returns C<1> for success, C<0> otherwise. On systems that don't support |
| 6772 | symbolic links, raises an exception. To check for that, |
| 6773 | use eval: |
| 6774 | |
| 6775 | $symlink_exists = eval { symlink("",""); 1 }; |
| 6776 | |
| 6777 | =item syscall NUMBER, LIST |
| 6778 | X<syscall> X<system call> |
| 6779 | |
| 6780 | Calls the system call specified as the first element of the list, |
| 6781 | passing the remaining elements as arguments to the system call. If |
| 6782 | unimplemented, raises an exception. The arguments are interpreted |
| 6783 | as follows: if a given argument is numeric, the argument is passed as |
| 6784 | an int. If not, the pointer to the string value is passed. You are |
| 6785 | responsible to make sure a string is pre-extended long enough to |
| 6786 | receive any result that might be written into a string. You can't use a |
| 6787 | string literal (or other read-only string) as an argument to C<syscall> |
| 6788 | because Perl has to assume that any string pointer might be written |
| 6789 | through. If your |
| 6790 | integer arguments are not literals and have never been interpreted in a |
| 6791 | numeric context, you may need to add C<0> to them to force them to look |
| 6792 | like numbers. This emulates the C<syswrite> function (or vice versa): |
| 6793 | |
| 6794 | require 'syscall.ph'; # may need to run h2ph |
| 6795 | $s = "hi there\n"; |
| 6796 | syscall(&SYS_write, fileno(STDOUT), $s, length $s); |
| 6797 | |
| 6798 | Note that Perl supports passing of up to only 14 arguments to your syscall, |
| 6799 | which in practice should (usually) suffice. |
| 6800 | |
| 6801 | Syscall returns whatever value returned by the system call it calls. |
| 6802 | If the system call fails, C<syscall> returns C<-1> and sets C<$!> (errno). |
| 6803 | Note that some system calls I<can> legitimately return C<-1>. The proper |
| 6804 | way to handle such calls is to assign C<$!=0> before the call, then |
| 6805 | check the value of C<$!> if C<syscall> returns C<-1>. |
| 6806 | |
| 6807 | There's a problem with C<syscall(&SYS_pipe)>: it returns the file |
| 6808 | number of the read end of the pipe it creates, but there is no way |
| 6809 | to retrieve the file number of the other end. You can avoid this |
| 6810 | problem by using C<pipe> instead. |
| 6811 | |
| 6812 | =item sysopen FILEHANDLE,FILENAME,MODE |
| 6813 | X<sysopen> |
| 6814 | |
| 6815 | =item sysopen FILEHANDLE,FILENAME,MODE,PERMS |
| 6816 | |
| 6817 | Opens the file whose filename is given by FILENAME, and associates it with |
| 6818 | FILEHANDLE. If FILEHANDLE is an expression, its value is used as the real |
| 6819 | filehandle wanted; an undefined scalar will be suitably autovivified. This |
| 6820 | function calls the underlying operating system's I<open>(2) function with the |
| 6821 | parameters FILENAME, MODE, and PERMS. |
| 6822 | |
| 6823 | The possible values and flag bits of the MODE parameter are |
| 6824 | system-dependent; they are available via the standard module C<Fcntl>. See |
| 6825 | the documentation of your operating system's I<open>(2) syscall to see |
| 6826 | which values and flag bits are available. You may combine several flags |
| 6827 | using the C<|>-operator. |
| 6828 | |
| 6829 | Some of the most common values are C<O_RDONLY> for opening the file in |
| 6830 | read-only mode, C<O_WRONLY> for opening the file in write-only mode, |
| 6831 | and C<O_RDWR> for opening the file in read-write mode. |
| 6832 | X<O_RDONLY> X<O_RDWR> X<O_WRONLY> |
| 6833 | |
| 6834 | For historical reasons, some values work on almost every system |
| 6835 | supported by Perl: 0 means read-only, 1 means write-only, and 2 |
| 6836 | means read/write. We know that these values do I<not> work under |
| 6837 | OS/390 & VM/ESA Unix and on the Macintosh; you probably don't want to |
| 6838 | use them in new code. |
| 6839 | |
| 6840 | If the file named by FILENAME does not exist and the C<open> call creates |
| 6841 | it (typically because MODE includes the C<O_CREAT> flag), then the value of |
| 6842 | PERMS specifies the permissions of the newly created file. If you omit |
| 6843 | the PERMS argument to C<sysopen>, Perl uses the octal value C<0666>. |
| 6844 | These permission values need to be in octal, and are modified by your |
| 6845 | process's current C<umask>. |
| 6846 | X<O_CREAT> |
| 6847 | |
| 6848 | In many systems the C<O_EXCL> flag is available for opening files in |
| 6849 | exclusive mode. This is B<not> locking: exclusiveness means here that |
| 6850 | if the file already exists, sysopen() fails. C<O_EXCL> may not work |
| 6851 | on network filesystems, and has no effect unless the C<O_CREAT> flag |
| 6852 | is set as well. Setting C<O_CREAT|O_EXCL> prevents the file from |
| 6853 | being opened if it is a symbolic link. It does not protect against |
| 6854 | symbolic links in the file's path. |
| 6855 | X<O_EXCL> |
| 6856 | |
| 6857 | Sometimes you may want to truncate an already-existing file. This |
| 6858 | can be done using the C<O_TRUNC> flag. The behavior of |
| 6859 | C<O_TRUNC> with C<O_RDONLY> is undefined. |
| 6860 | X<O_TRUNC> |
| 6861 | |
| 6862 | You should seldom if ever use C<0644> as argument to C<sysopen>, because |
| 6863 | that takes away the user's option to have a more permissive umask. |
| 6864 | Better to omit it. See the perlfunc(1) entry on C<umask> for more |
| 6865 | on this. |
| 6866 | |
| 6867 | Note that C<sysopen> depends on the fdopen() C library function. |
| 6868 | On many Unix systems, fdopen() is known to fail when file descriptors |
| 6869 | exceed a certain value, typically 255. If you need more file |
| 6870 | descriptors than that, consider rebuilding Perl to use the C<sfio> |
| 6871 | library, or perhaps using the POSIX::open() function. |
| 6872 | |
| 6873 | See L<perlopentut> for a kinder, gentler explanation of opening files. |
| 6874 | |
| 6875 | =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET |
| 6876 | X<sysread> |
| 6877 | |
| 6878 | =item sysread FILEHANDLE,SCALAR,LENGTH |
| 6879 | |
| 6880 | Attempts to read LENGTH bytes of data into variable SCALAR from the |
| 6881 | specified FILEHANDLE, using the read(2). It bypasses |
| 6882 | buffered IO, so mixing this with other kinds of reads, C<print>, |
| 6883 | C<write>, C<seek>, C<tell>, or C<eof> can cause confusion because the |
| 6884 | perlio or stdio layers usually buffers data. Returns the number of |
| 6885 | bytes actually read, C<0> at end of file, or undef if there was an |
| 6886 | error (in the latter case C<$!> is also set). SCALAR will be grown or |
| 6887 | shrunk so that the last byte actually read is the last byte of the |
| 6888 | scalar after the read. |
| 6889 | |
| 6890 | An OFFSET may be specified to place the read data at some place in the |
| 6891 | string other than the beginning. A negative OFFSET specifies |
| 6892 | placement at that many characters counting backwards from the end of |
| 6893 | the string. A positive OFFSET greater than the length of SCALAR |
| 6894 | results in the string being padded to the required size with C<"\0"> |
| 6895 | bytes before the result of the read is appended. |
| 6896 | |
| 6897 | There is no syseof() function, which is ok, since eof() doesn't work |
| 6898 | well on device files (like ttys) anyway. Use sysread() and check |
| 6899 | for a return value for 0 to decide whether you're done. |
| 6900 | |
| 6901 | Note that if the filehandle has been marked as C<:utf8> Unicode |
| 6902 | characters are read instead of bytes (the LENGTH, OFFSET, and the |
| 6903 | return value of sysread() are in Unicode characters). |
| 6904 | The C<:encoding(...)> layer implicitly introduces the C<:utf8> layer. |
| 6905 | See L</binmode>, L</open>, and the C<open> pragma, L<open>. |
| 6906 | |
| 6907 | =item sysseek FILEHANDLE,POSITION,WHENCE |
| 6908 | X<sysseek> X<lseek> |
| 6909 | |
| 6910 | Sets FILEHANDLE's system position in bytes using lseek(2). FILEHANDLE may |
| 6911 | be an expression whose value gives the name of the filehandle. The values |
| 6912 | for WHENCE are C<0> to set the new position to POSITION; C<1> to set the it |
| 6913 | to the current position plus POSITION; and C<2> to set it to EOF plus |
| 6914 | POSITION, typically negative. |
| 6915 | |
| 6916 | Note the I<in bytes>: even if the filehandle has been set to operate |
| 6917 | on characters (for example by using the C<:encoding(utf8)> I/O layer), |
| 6918 | tell() will return byte offsets, not character offsets (because |
| 6919 | implementing that would render sysseek() unacceptably slow). |
| 6920 | |
| 6921 | sysseek() bypasses normal buffered IO, so mixing it with reads other |
| 6922 | than C<sysread> (for example C<< <> >> or read()) C<print>, C<write>, |
| 6923 | C<seek>, C<tell>, or C<eof> may cause confusion. |
| 6924 | |
| 6925 | For WHENCE, you may also use the constants C<SEEK_SET>, C<SEEK_CUR>, |
| 6926 | and C<SEEK_END> (start of the file, current position, end of the file) |
| 6927 | from the Fcntl module. Use of the constants is also more portable |
| 6928 | than relying on 0, 1, and 2. For example to define a "systell" function: |
| 6929 | |
| 6930 | use Fcntl 'SEEK_CUR'; |
| 6931 | sub systell { sysseek($_[0], 0, SEEK_CUR) } |
| 6932 | |
| 6933 | Returns the new position, or the undefined value on failure. A position |
| 6934 | of zero is returned as the string C<"0 but true">; thus C<sysseek> returns |
| 6935 | true on success and false on failure, yet you can still easily determine |
| 6936 | the new position. |
| 6937 | |
| 6938 | =item system LIST |
| 6939 | X<system> X<shell> |
| 6940 | |
| 6941 | =item system PROGRAM LIST |
| 6942 | |
| 6943 | Does exactly the same thing as C<exec LIST>, except that a fork is |
| 6944 | done first and the parent process waits for the child process to |
| 6945 | exit. Note that argument processing varies depending on the |
| 6946 | number of arguments. If there is more than one argument in LIST, |
| 6947 | or if LIST is an array with more than one value, starts the program |
| 6948 | given by the first element of the list with arguments given by the |
| 6949 | rest of the list. If there is only one scalar argument, the argument |
| 6950 | is checked for shell metacharacters, and if there are any, the |
| 6951 | entire argument is passed to the system's command shell for parsing |
| 6952 | (this is C</bin/sh -c> on Unix platforms, but varies on other |
| 6953 | platforms). If there are no shell metacharacters in the argument, |
| 6954 | it is split into words and passed directly to C<execvp>, which is |
| 6955 | more efficient. |
| 6956 | |
| 6957 | Beginning with v5.6.0, Perl will attempt to flush all files opened for |
| 6958 | output before any operation that may do a fork, but this may not be |
| 6959 | supported on some platforms (see L<perlport>). To be safe, you may need |
| 6960 | to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method |
| 6961 | of C<IO::Handle> on any open handles. |
| 6962 | |
| 6963 | The return value is the exit status of the program as returned by the |
| 6964 | C<wait> call. To get the actual exit value, shift right by eight (see |
| 6965 | below). See also L</exec>. This is I<not> what you want to use to capture |
| 6966 | the output from a command; for that you should use merely backticks or |
| 6967 | C<qx//>, as described in L<perlop/"`STRING`">. Return value of -1 |
| 6968 | indicates a failure to start the program or an error of the wait(2) system |
| 6969 | call (inspect $! for the reason). |
| 6970 | |
| 6971 | If you'd like to make C<system> (and many other bits of Perl) die on error, |
| 6972 | have a look at the L<autodie> pragma. |
| 6973 | |
| 6974 | Like C<exec>, C<system> allows you to lie to a program about its name if |
| 6975 | you use the C<system PROGRAM LIST> syntax. Again, see L</exec>. |
| 6976 | |
| 6977 | Since C<SIGINT> and C<SIGQUIT> are ignored during the execution of |
| 6978 | C<system>, if you expect your program to terminate on receipt of these |
| 6979 | signals you will need to arrange to do so yourself based on the return |
| 6980 | value. |
| 6981 | |
| 6982 | @args = ("command", "arg1", "arg2"); |
| 6983 | system(@args) == 0 |
| 6984 | or die "system @args failed: $?" |
| 6985 | |
| 6986 | If you'd like to manually inspect C<system>'s failure, you can check all |
| 6987 | possible failure modes by inspecting C<$?> like this: |
| 6988 | |
| 6989 | if ($? == -1) { |
| 6990 | print "failed to execute: $!\n"; |
| 6991 | } |
| 6992 | elsif ($? & 127) { |
| 6993 | printf "child died with signal %d, %s coredump\n", |
| 6994 | ($? & 127), ($? & 128) ? 'with' : 'without'; |
| 6995 | } |
| 6996 | else { |
| 6997 | printf "child exited with value %d\n", $? >> 8; |
| 6998 | } |
| 6999 | |
| 7000 | Alternatively, you may inspect the value of C<${^CHILD_ERROR_NATIVE}> |
| 7001 | with the C<W*()> calls from the POSIX module. |
| 7002 | |
| 7003 | When C<system>'s arguments are executed indirectly by the shell, |
| 7004 | results and return codes are subject to its quirks. |
| 7005 | See L<perlop/"`STRING`"> and L</exec> for details. |
| 7006 | |
| 7007 | Since C<system> does a C<fork> and C<wait> it may affect a C<SIGCHLD> |
| 7008 | handler. See L<perlipc> for details. |
| 7009 | |
| 7010 | =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET |
| 7011 | X<syswrite> |
| 7012 | |
| 7013 | =item syswrite FILEHANDLE,SCALAR,LENGTH |
| 7014 | |
| 7015 | =item syswrite FILEHANDLE,SCALAR |
| 7016 | |
| 7017 | Attempts to write LENGTH bytes of data from variable SCALAR to the |
| 7018 | specified FILEHANDLE, using write(2). If LENGTH is |
| 7019 | not specified, writes whole SCALAR. It bypasses buffered IO, so |
| 7020 | mixing this with reads (other than C<sysread())>, C<print>, C<write>, |
| 7021 | C<seek>, C<tell>, or C<eof> may cause confusion because the perlio and |
| 7022 | stdio layers usually buffer data. Returns the number of bytes |
| 7023 | actually written, or C<undef> if there was an error (in this case the |
| 7024 | errno variable C<$!> is also set). If the LENGTH is greater than the |
| 7025 | data available in the SCALAR after the OFFSET, only as much data as is |
| 7026 | available will be written. |
| 7027 | |
| 7028 | An OFFSET may be specified to write the data from some part of the |
| 7029 | string other than the beginning. A negative OFFSET specifies writing |
| 7030 | that many characters counting backwards from the end of the string. |
| 7031 | If SCALAR is of length zero, you can only use an OFFSET of 0. |
| 7032 | |
| 7033 | B<WARNING>: If the filehandle is marked C<:utf8>, Unicode characters |
| 7034 | encoded in UTF-8 are written instead of bytes, and the LENGTH, OFFSET, and |
| 7035 | return value of syswrite() are in (UTF8-encoded Unicode) characters. |
| 7036 | The C<:encoding(...)> layer implicitly introduces the C<:utf8> layer. |
| 7037 | Alternately, if the handle is not marked with an encoding but you |
| 7038 | attempt to write characters with code points over 255, raises an exception. |
| 7039 | See L</binmode>, L</open>, and the C<open> pragma, L<open>. |
| 7040 | |
| 7041 | =item tell FILEHANDLE |
| 7042 | X<tell> |
| 7043 | |
| 7044 | =item tell |
| 7045 | |
| 7046 | Returns the current position I<in bytes> for FILEHANDLE, or -1 on |
| 7047 | error. FILEHANDLE may be an expression whose value gives the name of |
| 7048 | the actual filehandle. If FILEHANDLE is omitted, assumes the file |
| 7049 | last read. |
| 7050 | |
| 7051 | Note the I<in bytes>: even if the filehandle has been set to |
| 7052 | operate on characters (for example by using the C<:encoding(utf8)> open |
| 7053 | layer), tell() will return byte offsets, not character offsets (because |
| 7054 | that would render seek() and tell() rather slow). |
| 7055 | |
| 7056 | The return value of tell() for the standard streams like the STDIN |
| 7057 | depends on the operating system: it may return -1 or something else. |
| 7058 | tell() on pipes, fifos, and sockets usually returns -1. |
| 7059 | |
| 7060 | There is no C<systell> function. Use C<sysseek(FH, 0, 1)> for that. |
| 7061 | |
| 7062 | Do not use tell() (or other buffered I/O operations) on a filehandle |
| 7063 | that has been manipulated by sysread(), syswrite(), or sysseek(). |
| 7064 | Those functions ignore the buffering, while tell() does not. |
| 7065 | |
| 7066 | =item telldir DIRHANDLE |
| 7067 | X<telldir> |
| 7068 | |
| 7069 | Returns the current position of the C<readdir> routines on DIRHANDLE. |
| 7070 | Value may be given to C<seekdir> to access a particular location in a |
| 7071 | directory. C<telldir> has the same caveats about possible directory |
| 7072 | compaction as the corresponding system library routine. |
| 7073 | |
| 7074 | =item tie VARIABLE,CLASSNAME,LIST |
| 7075 | X<tie> |
| 7076 | |
| 7077 | This function binds a variable to a package class that will provide the |
| 7078 | implementation for the variable. VARIABLE is the name of the variable |
| 7079 | to be enchanted. CLASSNAME is the name of a class implementing objects |
| 7080 | of correct type. Any additional arguments are passed to the C<new> |
| 7081 | method of the class (meaning C<TIESCALAR>, C<TIEHANDLE>, C<TIEARRAY>, |
| 7082 | or C<TIEHASH>). Typically these are arguments such as might be passed |
| 7083 | to the C<dbm_open()> function of C. The object returned by the C<new> |
| 7084 | method is also returned by the C<tie> function, which would be useful |
| 7085 | if you want to access other methods in CLASSNAME. |
| 7086 | |
| 7087 | Note that functions such as C<keys> and C<values> may return huge lists |
| 7088 | when used on large objects, like DBM files. You may prefer to use the |
| 7089 | C<each> function to iterate over such. Example: |
| 7090 | |
| 7091 | # print out history file offsets |
| 7092 | use NDBM_File; |
| 7093 | tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0); |
| 7094 | while (($key,$val) = each %HIST) { |
| 7095 | print $key, ' = ', unpack('L',$val), "\n"; |
| 7096 | } |
| 7097 | untie(%HIST); |
| 7098 | |
| 7099 | A class implementing a hash should have the following methods: |
| 7100 | |
| 7101 | TIEHASH classname, LIST |
| 7102 | FETCH this, key |
| 7103 | STORE this, key, value |
| 7104 | DELETE this, key |
| 7105 | CLEAR this |
| 7106 | EXISTS this, key |
| 7107 | FIRSTKEY this |
| 7108 | NEXTKEY this, lastkey |
| 7109 | SCALAR this |
| 7110 | DESTROY this |
| 7111 | UNTIE this |
| 7112 | |
| 7113 | A class implementing an ordinary array should have the following methods: |
| 7114 | |
| 7115 | TIEARRAY classname, LIST |
| 7116 | FETCH this, key |
| 7117 | STORE this, key, value |
| 7118 | FETCHSIZE this |
| 7119 | STORESIZE this, count |
| 7120 | CLEAR this |
| 7121 | PUSH this, LIST |
| 7122 | POP this |
| 7123 | SHIFT this |
| 7124 | UNSHIFT this, LIST |
| 7125 | SPLICE this, offset, length, LIST |
| 7126 | EXTEND this, count |
| 7127 | DESTROY this |
| 7128 | UNTIE this |
| 7129 | |
| 7130 | A class implementing a filehandle should have the following methods: |
| 7131 | |
| 7132 | TIEHANDLE classname, LIST |
| 7133 | READ this, scalar, length, offset |
| 7134 | READLINE this |
| 7135 | GETC this |
| 7136 | WRITE this, scalar, length, offset |
| 7137 | PRINT this, LIST |
| 7138 | PRINTF this, format, LIST |
| 7139 | BINMODE this |
| 7140 | EOF this |
| 7141 | FILENO this |
| 7142 | SEEK this, position, whence |
| 7143 | TELL this |
| 7144 | OPEN this, mode, LIST |
| 7145 | CLOSE this |
| 7146 | DESTROY this |
| 7147 | UNTIE this |
| 7148 | |
| 7149 | A class implementing a scalar should have the following methods: |
| 7150 | |
| 7151 | TIESCALAR classname, LIST |
| 7152 | FETCH this, |
| 7153 | STORE this, value |
| 7154 | DESTROY this |
| 7155 | UNTIE this |
| 7156 | |
| 7157 | Not all methods indicated above need be implemented. See L<perltie>, |
| 7158 | L<Tie::Hash>, L<Tie::Array>, L<Tie::Scalar>, and L<Tie::Handle>. |
| 7159 | |
| 7160 | Unlike C<dbmopen>, the C<tie> function will not C<use> or C<require> a module |
| 7161 | for you; you need to do that explicitly yourself. See L<DB_File> |
| 7162 | or the F<Config> module for interesting C<tie> implementations. |
| 7163 | |
| 7164 | For further details see L<perltie>, L<"tied VARIABLE">. |
| 7165 | |
| 7166 | =item tied VARIABLE |
| 7167 | X<tied> |
| 7168 | |
| 7169 | Returns a reference to the object underlying VARIABLE (the same value |
| 7170 | that was originally returned by the C<tie> call that bound the variable |
| 7171 | to a package.) Returns the undefined value if VARIABLE isn't tied to a |
| 7172 | package. |
| 7173 | |
| 7174 | =item time |
| 7175 | X<time> X<epoch> |
| 7176 | |
| 7177 | Returns the number of non-leap seconds since whatever time the system |
| 7178 | considers to be the epoch, suitable for feeding to C<gmtime> and |
| 7179 | C<localtime>. On most systems the epoch is 00:00:00 UTC, January 1, 1970; |
| 7180 | a prominent exception being Mac OS Classic which uses 00:00:00, January 1, |
| 7181 | 1904 in the current local time zone for its epoch. |
| 7182 | |
| 7183 | For measuring time in better granularity than one second, use the |
| 7184 | L<Time::HiRes> module from Perl 5.8 onwards (or from CPAN before then), or, |
| 7185 | if you have gettimeofday(2), you may be able to use the C<syscall> |
| 7186 | interface of Perl. See L<perlfaq8> for details. |
| 7187 | |
| 7188 | For date and time processing look at the many related modules on CPAN. |
| 7189 | For a comprehensive date and time representation look at the |
| 7190 | L<DateTime> module. |
| 7191 | |
| 7192 | =item times |
| 7193 | X<times> |
| 7194 | |
| 7195 | Returns a four-element list giving the user and system times in |
| 7196 | seconds for this process and any exited children of this process. |
| 7197 | |
| 7198 | ($user,$system,$cuser,$csystem) = times; |
| 7199 | |
| 7200 | In scalar context, C<times> returns C<$user>. |
| 7201 | |
| 7202 | Children's times are only included for terminated children. |
| 7203 | |
| 7204 | =item tr/// |
| 7205 | |
| 7206 | The transliteration operator. Same as C<y///>. See |
| 7207 | L<perlop/"Quote and Quote-like Operators">. |
| 7208 | |
| 7209 | =item truncate FILEHANDLE,LENGTH |
| 7210 | X<truncate> |
| 7211 | |
| 7212 | =item truncate EXPR,LENGTH |
| 7213 | |
| 7214 | Truncates the file opened on FILEHANDLE, or named by EXPR, to the |
| 7215 | specified length. Raises an exception if truncate isn't implemented |
| 7216 | on your system. Returns true if successful, C<undef> on error. |
| 7217 | |
| 7218 | The behavior is undefined if LENGTH is greater than the length of the |
| 7219 | file. |
| 7220 | |
| 7221 | The position in the file of FILEHANDLE is left unchanged. You may want to |
| 7222 | call L<seek|/"seek FILEHANDLE,POSITION,WHENCE"> before writing to the file. |
| 7223 | |
| 7224 | =item uc EXPR |
| 7225 | X<uc> X<uppercase> X<toupper> |
| 7226 | |
| 7227 | =item uc |
| 7228 | |
| 7229 | Returns an uppercased version of EXPR. This is the internal function |
| 7230 | implementing the C<\U> escape in double-quoted strings. |
| 7231 | It does not attempt to do titlecase mapping on initial letters. See |
| 7232 | L</ucfirst> for that. |
| 7233 | |
| 7234 | If EXPR is omitted, uses C<$_>. |
| 7235 | |
| 7236 | This function behaves the same way under various pragma, such as in a locale, |
| 7237 | as L</lc> does. |
| 7238 | |
| 7239 | =item ucfirst EXPR |
| 7240 | X<ucfirst> X<uppercase> |
| 7241 | |
| 7242 | =item ucfirst |
| 7243 | |
| 7244 | Returns the value of EXPR with the first character in uppercase |
| 7245 | (titlecase in Unicode). This is the internal function implementing |
| 7246 | the C<\u> escape in double-quoted strings. |
| 7247 | |
| 7248 | If EXPR is omitted, uses C<$_>. |
| 7249 | |
| 7250 | This function behaves the same way under various pragma, such as in a locale, |
| 7251 | as L</lc> does. |
| 7252 | |
| 7253 | =item umask EXPR |
| 7254 | X<umask> |
| 7255 | |
| 7256 | =item umask |
| 7257 | |
| 7258 | Sets the umask for the process to EXPR and returns the previous value. |
| 7259 | If EXPR is omitted, merely returns the current umask. |
| 7260 | |
| 7261 | The Unix permission C<rwxr-x---> is represented as three sets of three |
| 7262 | bits, or three octal digits: C<0750> (the leading 0 indicates octal |
| 7263 | and isn't one of the digits). The C<umask> value is such a number |
| 7264 | representing disabled permissions bits. The permission (or "mode") |
| 7265 | values you pass C<mkdir> or C<sysopen> are modified by your umask, so |
| 7266 | even if you tell C<sysopen> to create a file with permissions C<0777>, |
| 7267 | if your umask is C<0022>, then the file will actually be created with |
| 7268 | permissions C<0755>. If your C<umask> were C<0027> (group can't |
| 7269 | write; others can't read, write, or execute), then passing |
| 7270 | C<sysopen> C<0666> would create a file with mode C<0640> (because |
| 7271 | C<0666 &~ 027> is C<0640>). |
| 7272 | |
| 7273 | Here's some advice: supply a creation mode of C<0666> for regular |
| 7274 | files (in C<sysopen>) and one of C<0777> for directories (in |
| 7275 | C<mkdir>) and executable files. This gives users the freedom of |
| 7276 | choice: if they want protected files, they might choose process umasks |
| 7277 | of C<022>, C<027>, or even the particularly antisocial mask of C<077>. |
| 7278 | Programs should rarely if ever make policy decisions better left to |
| 7279 | the user. The exception to this is when writing files that should be |
| 7280 | kept private: mail files, web browser cookies, I<.rhosts> files, and |
| 7281 | so on. |
| 7282 | |
| 7283 | If umask(2) is not implemented on your system and you are trying to |
| 7284 | restrict access for I<yourself> (i.e., C<< (EXPR & 0700) > 0 >>), |
| 7285 | raises an exception. If umask(2) is not implemented and you are |
| 7286 | not trying to restrict access for yourself, returns C<undef>. |
| 7287 | |
| 7288 | Remember that a umask is a number, usually given in octal; it is I<not> a |
| 7289 | string of octal digits. See also L</oct>, if all you have is a string. |
| 7290 | |
| 7291 | =item undef EXPR |
| 7292 | X<undef> X<undefine> |
| 7293 | |
| 7294 | =item undef |
| 7295 | |
| 7296 | Undefines the value of EXPR, which must be an lvalue. Use only on a |
| 7297 | scalar value, an array (using C<@>), a hash (using C<%>), a subroutine |
| 7298 | (using C<&>), or a typeglob (using C<*>). Saying C<undef $hash{$key}> |
| 7299 | will probably not do what you expect on most predefined variables or |
| 7300 | DBM list values, so don't do that; see L</delete>. Always returns the |
| 7301 | undefined value. You can omit the EXPR, in which case nothing is |
| 7302 | undefined, but you still get an undefined value that you could, for |
| 7303 | instance, return from a subroutine, assign to a variable, or pass as a |
| 7304 | parameter. Examples: |
| 7305 | |
| 7306 | undef $foo; |
| 7307 | undef $bar{'blurfl'}; # Compare to: delete $bar{'blurfl'}; |
| 7308 | undef @ary; |
| 7309 | undef %hash; |
| 7310 | undef &mysub; |
| 7311 | undef *xyz; # destroys $xyz, @xyz, %xyz, &xyz, etc. |
| 7312 | return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it; |
| 7313 | select undef, undef, undef, 0.25; |
| 7314 | ($a, $b, undef, $c) = &foo; # Ignore third value returned |
| 7315 | |
| 7316 | Note that this is a unary operator, not a list operator. |
| 7317 | |
| 7318 | =item unlink LIST |
| 7319 | X<unlink> X<delete> X<remove> X<rm> X<del> |
| 7320 | |
| 7321 | =item unlink |
| 7322 | |
| 7323 | Deletes a list of files. On success, it returns the number of files |
| 7324 | it successfully deleted. On failure, it returns false and sets C<$!> |
| 7325 | (errno): |
| 7326 | |
| 7327 | my $unlinked = unlink 'a', 'b', 'c'; |
| 7328 | unlink @goners; |
| 7329 | unlink glob "*.bak"; |
| 7330 | |
| 7331 | On error, C<unlink> will not tell you which files it could not remove. |
| 7332 | If you want to know which files you could not remove, try them one |
| 7333 | at a time: |
| 7334 | |
| 7335 | foreach my $file ( @goners ) { |
| 7336 | unlink $file or warn "Could not unlink $file: $!"; |
| 7337 | } |
| 7338 | |
| 7339 | Note: C<unlink> will not attempt to delete directories unless you are |
| 7340 | superuser and the B<-U> flag is supplied to Perl. Even if these |
| 7341 | conditions are met, be warned that unlinking a directory can inflict |
| 7342 | damage on your filesystem. Finally, using C<unlink> on directories is |
| 7343 | not supported on many operating systems. Use C<rmdir> instead. |
| 7344 | |
| 7345 | If LIST is omitted, C<unlink> uses C<$_>. |
| 7346 | |
| 7347 | =item unpack TEMPLATE,EXPR |
| 7348 | X<unpack> |
| 7349 | |
| 7350 | =item unpack TEMPLATE |
| 7351 | |
| 7352 | C<unpack> does the reverse of C<pack>: it takes a string |
| 7353 | and expands it out into a list of values. |
| 7354 | (In scalar context, it returns merely the first value produced.) |
| 7355 | |
| 7356 | If EXPR is omitted, unpacks the C<$_> string. |
| 7357 | See L<perlpacktut> for an introduction to this function. |
| 7358 | |
| 7359 | The string is broken into chunks described by the TEMPLATE. Each chunk |
| 7360 | is converted separately to a value. Typically, either the string is a result |
| 7361 | of C<pack>, or the characters of the string represent a C structure of some |
| 7362 | kind. |
| 7363 | |
| 7364 | The TEMPLATE has the same format as in the C<pack> function. |
| 7365 | Here's a subroutine that does substring: |
| 7366 | |
| 7367 | sub substr { |
| 7368 | my($what,$where,$howmuch) = @_; |
| 7369 | unpack("x$where a$howmuch", $what); |
| 7370 | } |
| 7371 | |
| 7372 | and then there's |
| 7373 | |
| 7374 | sub ordinal { unpack("W",$_[0]); } # same as ord() |
| 7375 | |
| 7376 | In addition to fields allowed in pack(), you may prefix a field with |
| 7377 | a %<number> to indicate that |
| 7378 | you want a <number>-bit checksum of the items instead of the items |
| 7379 | themselves. Default is a 16-bit checksum. Checksum is calculated by |
| 7380 | summing numeric values of expanded values (for string fields the sum of |
| 7381 | C<ord($char)> is taken; for bit fields the sum of zeroes and ones). |
| 7382 | |
| 7383 | For example, the following |
| 7384 | computes the same number as the System V sum program: |
| 7385 | |
| 7386 | $checksum = do { |
| 7387 | local $/; # slurp! |
| 7388 | unpack("%32W*",<>) % 65535; |
| 7389 | }; |
| 7390 | |
| 7391 | The following efficiently counts the number of set bits in a bit vector: |
| 7392 | |
| 7393 | $setbits = unpack("%32b*", $selectmask); |
| 7394 | |
| 7395 | The C<p> and C<P> formats should be used with care. Since Perl |
| 7396 | has no way of checking whether the value passed to C<unpack()> |
| 7397 | corresponds to a valid memory location, passing a pointer value that's |
| 7398 | not known to be valid is likely to have disastrous consequences. |
| 7399 | |
| 7400 | If there are more pack codes or if the repeat count of a field or a group |
| 7401 | is larger than what the remainder of the input string allows, the result |
| 7402 | is not well defined: the repeat count may be decreased, or |
| 7403 | C<unpack()> may produce empty strings or zeros, or it may raise an exception. |
| 7404 | If the input string is longer than one described by the TEMPLATE, |
| 7405 | the remainder of that input string is ignored. |
| 7406 | |
| 7407 | See L</pack> for more examples and notes. |
| 7408 | |
| 7409 | =item untie VARIABLE |
| 7410 | X<untie> |
| 7411 | |
| 7412 | Breaks the binding between a variable and a package. (See C<tie>.) |
| 7413 | Has no effect if the variable is not tied. |
| 7414 | |
| 7415 | =item unshift ARRAY,LIST |
| 7416 | X<unshift> |
| 7417 | |
| 7418 | =item unshift EXPR,LIST |
| 7419 | |
| 7420 | Does the opposite of a C<shift>. Or the opposite of a C<push>, |
| 7421 | depending on how you look at it. Prepends list to the front of the |
| 7422 | array and returns the new number of elements in the array. |
| 7423 | |
| 7424 | unshift(@ARGV, '-e') unless $ARGV[0] =~ /^-/; |
| 7425 | |
| 7426 | Note the LIST is prepended whole, not one element at a time, so the |
| 7427 | prepended elements stay in the same order. Use C<reverse> to do the |
| 7428 | reverse. |
| 7429 | |
| 7430 | Starting with Perl 5.14, C<unshift> can take a scalar EXPR, which must hold |
| 7431 | a reference to an unblessed array. The argument will be dereferenced |
| 7432 | automatically. This aspect of C<unshift> is considered highly |
| 7433 | experimental. The exact behaviour may change in a future version of Perl. |
| 7434 | |
| 7435 | =item use Module VERSION LIST |
| 7436 | X<use> X<module> X<import> |
| 7437 | |
| 7438 | =item use Module VERSION |
| 7439 | |
| 7440 | =item use Module LIST |
| 7441 | |
| 7442 | =item use Module |
| 7443 | |
| 7444 | =item use VERSION |
| 7445 | |
| 7446 | Imports some semantics into the current package from the named module, |
| 7447 | generally by aliasing certain subroutine or variable names into your |
| 7448 | package. It is exactly equivalent to |
| 7449 | |
| 7450 | BEGIN { require Module; Module->import( LIST ); } |
| 7451 | |
| 7452 | except that Module I<must> be a bareword. |
| 7453 | The importation can be made conditional; see L<if>. |
| 7454 | |
| 7455 | In the peculiar C<use VERSION> form, VERSION may be either a positive |
| 7456 | decimal fraction such as 5.006, which will be compared to C<$]>, or a v-string |
| 7457 | of the form v5.6.1, which will be compared to C<$^V> (aka $PERL_VERSION). An |
| 7458 | exception is raised if VERSION is greater than the version of the |
| 7459 | current Perl interpreter; Perl will not attempt to parse the rest of the |
| 7460 | file. Compare with L</require>, which can do a similar check at run time. |
| 7461 | Symmetrically, C<no VERSION> allows you to specify that you want a version |
| 7462 | of Perl older than the specified one. |
| 7463 | |
| 7464 | Specifying VERSION as a literal of the form v5.6.1 should generally be |
| 7465 | avoided, because it leads to misleading error messages under earlier |
| 7466 | versions of Perl (that is, prior to 5.6.0) that do not support this |
| 7467 | syntax. The equivalent numeric version should be used instead. |
| 7468 | |
| 7469 | use v5.6.1; # compile time version check |
| 7470 | use 5.6.1; # ditto |
| 7471 | use 5.006_001; # ditto; preferred for backwards compatibility |
| 7472 | |
| 7473 | This is often useful if you need to check the current Perl version before |
| 7474 | C<use>ing library modules that won't work with older versions of Perl. |
| 7475 | (We try not to do this more than we have to.) |
| 7476 | |
| 7477 | Also, if the specified Perl version is greater than or equal to 5.9.5, |
| 7478 | C<use VERSION> will also load the C<feature> pragma and enable all |
| 7479 | features available in the requested version. See L<feature>. |
| 7480 | Similarly, if the specified Perl version is greater than or equal to |
| 7481 | 5.11.0, strictures are enabled lexically as with C<use strict> (except |
| 7482 | that the F<strict.pm> file is not actually loaded). |
| 7483 | |
| 7484 | The C<BEGIN> forces the C<require> and C<import> to happen at compile time. The |
| 7485 | C<require> makes sure the module is loaded into memory if it hasn't been |
| 7486 | yet. The C<import> is not a builtin; it's just an ordinary static method |
| 7487 | call into the C<Module> package to tell the module to import the list of |
| 7488 | features back into the current package. The module can implement its |
| 7489 | C<import> method any way it likes, though most modules just choose to |
| 7490 | derive their C<import> method via inheritance from the C<Exporter> class that |
| 7491 | is defined in the C<Exporter> module. See L<Exporter>. If no C<import> |
| 7492 | method can be found then the call is skipped, even if there is an AUTOLOAD |
| 7493 | method. |
| 7494 | |
| 7495 | If you do not want to call the package's C<import> method (for instance, |
| 7496 | to stop your namespace from being altered), explicitly supply the empty list: |
| 7497 | |
| 7498 | use Module (); |
| 7499 | |
| 7500 | That is exactly equivalent to |
| 7501 | |
| 7502 | BEGIN { require Module } |
| 7503 | |
| 7504 | If the VERSION argument is present between Module and LIST, then the |
| 7505 | C<use> will call the VERSION method in class Module with the given |
| 7506 | version as an argument. The default VERSION method, inherited from |
| 7507 | the UNIVERSAL class, croaks if the given version is larger than the |
| 7508 | value of the variable C<$Module::VERSION>. |
| 7509 | |
| 7510 | Again, there is a distinction between omitting LIST (C<import> called |
| 7511 | with no arguments) and an explicit empty LIST C<()> (C<import> not |
| 7512 | called). Note that there is no comma after VERSION! |
| 7513 | |
| 7514 | Because this is a wide-open interface, pragmas (compiler directives) |
| 7515 | are also implemented this way. Currently implemented pragmas are: |
| 7516 | |
| 7517 | use constant; |
| 7518 | use diagnostics; |
| 7519 | use integer; |
| 7520 | use sigtrap qw(SEGV BUS); |
| 7521 | use strict qw(subs vars refs); |
| 7522 | use subs qw(afunc blurfl); |
| 7523 | use warnings qw(all); |
| 7524 | use sort qw(stable _quicksort _mergesort); |
| 7525 | |
| 7526 | Some of these pseudo-modules import semantics into the current |
| 7527 | block scope (like C<strict> or C<integer>, unlike ordinary modules, |
| 7528 | which import symbols into the current package (which are effective |
| 7529 | through the end of the file). |
| 7530 | |
| 7531 | Because C<use> takes effect at compile time, it doesn't respect the |
| 7532 | ordinary flow control of the code being compiled. In particular, putting |
| 7533 | a C<use> inside the false branch of a conditional doesn't prevent it |
| 7534 | from being processed. If a module or pragma only needs to be loaded |
| 7535 | conditionally, this can be done using the L<if> pragma: |
| 7536 | |
| 7537 | use if $] < 5.008, "utf8"; |
| 7538 | use if WANT_WARNINGS, warnings => qw(all); |
| 7539 | |
| 7540 | There's a corresponding C<no> declaration that unimports meanings imported |
| 7541 | by C<use>, i.e., it calls C<unimport Module LIST> instead of C<import>. |
| 7542 | It behaves just as C<import> does with VERSION, an omitted or empty LIST, |
| 7543 | or no unimport method being found. |
| 7544 | |
| 7545 | no integer; |
| 7546 | no strict 'refs'; |
| 7547 | no warnings; |
| 7548 | |
| 7549 | Care should be taken when using the C<no VERSION> form of C<no>. It is |
| 7550 | I<only> meant to be used to assert that the running Perl is of a earlier |
| 7551 | version than its argument and I<not> to undo the feature-enabling side effects |
| 7552 | of C<use VERSION>. |
| 7553 | |
| 7554 | See L<perlmodlib> for a list of standard modules and pragmas. See L<perlrun> |
| 7555 | for the C<-M> and C<-m> command-line options to Perl that give C<use> |
| 7556 | functionality from the command-line. |
| 7557 | |
| 7558 | =item utime LIST |
| 7559 | X<utime> |
| 7560 | |
| 7561 | Changes the access and modification times on each file of a list of |
| 7562 | files. The first two elements of the list must be the NUMERIC access |
| 7563 | and modification times, in that order. Returns the number of files |
| 7564 | successfully changed. The inode change time of each file is set |
| 7565 | to the current time. For example, this code has the same effect as the |
| 7566 | Unix touch(1) command when the files I<already exist> and belong to |
| 7567 | the user running the program: |
| 7568 | |
| 7569 | #!/usr/bin/perl |
| 7570 | $atime = $mtime = time; |
| 7571 | utime $atime, $mtime, @ARGV; |
| 7572 | |
| 7573 | Since Perl 5.7.2, if the first two elements of the list are C<undef>, |
| 7574 | the utime(2) syscall from your C library is called with a null second |
| 7575 | argument. On most systems, this will set the file's access and |
| 7576 | modification times to the current time (i.e., equivalent to the example |
| 7577 | above) and will work even on files you don't own provided you have write |
| 7578 | permission: |
| 7579 | |
| 7580 | for $file (@ARGV) { |
| 7581 | utime(undef, undef, $file) |
| 7582 | || warn "couldn't touch $file: $!"; |
| 7583 | } |
| 7584 | |
| 7585 | Under NFS this will use the time of the NFS server, not the time of |
| 7586 | the local machine. If there is a time synchronization problem, the |
| 7587 | NFS server and local machine will have different times. The Unix |
| 7588 | touch(1) command will in fact normally use this form instead of the |
| 7589 | one shown in the first example. |
| 7590 | |
| 7591 | Passing only one of the first two elements as C<undef> is |
| 7592 | equivalent to passing a 0 and will not have the effect |
| 7593 | described when both are C<undef>. This also triggers an |
| 7594 | uninitialized warning. |
| 7595 | |
| 7596 | On systems that support futimes(2), you may pass filehandles among the |
| 7597 | files. On systems that don't support futimes(2), passing filehandles raises |
| 7598 | an exception. Filehandles must be passed as globs or glob references to be |
| 7599 | recognized; barewords are considered filenames. |
| 7600 | |
| 7601 | =item values HASH |
| 7602 | X<values> |
| 7603 | |
| 7604 | =item values ARRAY |
| 7605 | |
| 7606 | =item values EXPR |
| 7607 | |
| 7608 | Returns a list consisting of all the values of the named hash, or the values |
| 7609 | of an array. (In scalar context, returns the number of values.) |
| 7610 | |
| 7611 | The values are returned in an apparently random order. The actual |
| 7612 | random order is subject to change in future versions of Perl, but it |
| 7613 | is guaranteed to be the same order as either the C<keys> or C<each> |
| 7614 | function would produce on the same (unmodified) hash. Since Perl |
| 7615 | 5.8.1 the ordering is different even between different runs of Perl |
| 7616 | for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">). |
| 7617 | |
| 7618 | As a side effect, calling values() resets the HASH or ARRAY's internal |
| 7619 | iterator; |
| 7620 | see L</each>. (In particular, calling values() in void context resets |
| 7621 | the iterator with no other overhead. Apart from resetting the iterator, |
| 7622 | C<values @array> in list context is the same as plain C<@array>. |
| 7623 | We recommend that you use void context C<keys @array> for this, but reasoned |
| 7624 | that it taking C<values @array> out would require more documentation than |
| 7625 | leaving it in.) |
| 7626 | |
| 7627 | Note that the values are not copied, which means modifying them will |
| 7628 | modify the contents of the hash: |
| 7629 | |
| 7630 | for (values %hash) { s/foo/bar/g } # modifies %hash values |
| 7631 | for (@hash{keys %hash}) { s/foo/bar/g } # same |
| 7632 | |
| 7633 | Starting with Perl 5.14, C<values> can take a scalar EXPR, which must hold |
| 7634 | a reference to an unblessed hash or array. The argument will be |
| 7635 | dereferenced automatically. This aspect of C<values> is considered highly |
| 7636 | experimental. The exact behaviour may change in a future version of Perl. |
| 7637 | |
| 7638 | for (values $hashref) { ... } |
| 7639 | for (values $obj->get_arrayref) { ... } |
| 7640 | |
| 7641 | See also C<keys>, C<each>, and C<sort>. |
| 7642 | |
| 7643 | =item vec EXPR,OFFSET,BITS |
| 7644 | X<vec> X<bit> X<bit vector> |
| 7645 | |
| 7646 | Treats the string in EXPR as a bit vector made up of elements of |
| 7647 | width BITS and returns the value of the element specified by OFFSET |
| 7648 | as an unsigned integer. BITS therefore specifies the number of bits |
| 7649 | that are reserved for each element in the bit vector. This must |
| 7650 | be a power of two from 1 to 32 (or 64, if your platform supports |
| 7651 | that). |
| 7652 | |
| 7653 | If BITS is 8, "elements" coincide with bytes of the input string. |
| 7654 | |
| 7655 | If BITS is 16 or more, bytes of the input string are grouped into chunks |
| 7656 | of size BITS/8, and each group is converted to a number as with |
| 7657 | pack()/unpack() with big-endian formats C<n>/C<N> (and analogously |
| 7658 | for BITS==64). See L<"pack"> for details. |
| 7659 | |
| 7660 | If bits is 4 or less, the string is broken into bytes, then the bits |
| 7661 | of each byte are broken into 8/BITS groups. Bits of a byte are |
| 7662 | numbered in a little-endian-ish way, as in C<0x01>, C<0x02>, |
| 7663 | C<0x04>, C<0x08>, C<0x10>, C<0x20>, C<0x40>, C<0x80>. For example, |
| 7664 | breaking the single input byte C<chr(0x36)> into two groups gives a list |
| 7665 | C<(0x6, 0x3)>; breaking it into 4 groups gives C<(0x2, 0x1, 0x3, 0x0)>. |
| 7666 | |
| 7667 | C<vec> may also be assigned to, in which case parentheses are needed |
| 7668 | to give the expression the correct precedence as in |
| 7669 | |
| 7670 | vec($image, $max_x * $x + $y, 8) = 3; |
| 7671 | |
| 7672 | If the selected element is outside the string, the value 0 is returned. |
| 7673 | If an element off the end of the string is written to, Perl will first |
| 7674 | extend the string with sufficiently many zero bytes. It is an error |
| 7675 | to try to write off the beginning of the string (i.e., negative OFFSET). |
| 7676 | |
| 7677 | If the string happens to be encoded as UTF-8 internally (and thus has |
| 7678 | the UTF8 flag set), this is ignored by C<vec>, and it operates on the |
| 7679 | internal byte string, not the conceptual character string, even if you |
| 7680 | only have characters with values less than 256. |
| 7681 | |
| 7682 | Strings created with C<vec> can also be manipulated with the logical |
| 7683 | operators C<|>, C<&>, C<^>, and C<~>. These operators will assume a bit |
| 7684 | vector operation is desired when both operands are strings. |
| 7685 | See L<perlop/"Bitwise String Operators">. |
| 7686 | |
| 7687 | The following code will build up an ASCII string saying C<'PerlPerlPerl'>. |
| 7688 | The comments show the string after each step. Note that this code works |
| 7689 | in the same way on big-endian or little-endian machines. |
| 7690 | |
| 7691 | my $foo = ''; |
| 7692 | vec($foo, 0, 32) = 0x5065726C; # 'Perl' |
| 7693 | |
| 7694 | # $foo eq "Perl" eq "\x50\x65\x72\x6C", 32 bits |
| 7695 | print vec($foo, 0, 8); # prints 80 == 0x50 == ord('P') |
| 7696 | |
| 7697 | vec($foo, 2, 16) = 0x5065; # 'PerlPe' |
| 7698 | vec($foo, 3, 16) = 0x726C; # 'PerlPerl' |
| 7699 | vec($foo, 8, 8) = 0x50; # 'PerlPerlP' |
| 7700 | vec($foo, 9, 8) = 0x65; # 'PerlPerlPe' |
| 7701 | vec($foo, 20, 4) = 2; # 'PerlPerlPe' . "\x02" |
| 7702 | vec($foo, 21, 4) = 7; # 'PerlPerlPer' |
| 7703 | # 'r' is "\x72" |
| 7704 | vec($foo, 45, 2) = 3; # 'PerlPerlPer' . "\x0c" |
| 7705 | vec($foo, 93, 1) = 1; # 'PerlPerlPer' . "\x2c" |
| 7706 | vec($foo, 94, 1) = 1; # 'PerlPerlPerl' |
| 7707 | # 'l' is "\x6c" |
| 7708 | |
| 7709 | To transform a bit vector into a string or list of 0's and 1's, use these: |
| 7710 | |
| 7711 | $bits = unpack("b*", $vector); |
| 7712 | @bits = split(//, unpack("b*", $vector)); |
| 7713 | |
| 7714 | If you know the exact length in bits, it can be used in place of the C<*>. |
| 7715 | |
| 7716 | Here is an example to illustrate how the bits actually fall in place: |
| 7717 | |
| 7718 | #!/usr/bin/perl -wl |
| 7719 | |
| 7720 | print <<'EOT'; |
| 7721 | 0 1 2 3 |
| 7722 | unpack("V",$_) 01234567890123456789012345678901 |
| 7723 | ------------------------------------------------------------------ |
| 7724 | EOT |
| 7725 | |
| 7726 | for $w (0..3) { |
| 7727 | $width = 2**$w; |
| 7728 | for ($shift=0; $shift < $width; ++$shift) { |
| 7729 | for ($off=0; $off < 32/$width; ++$off) { |
| 7730 | $str = pack("B*", "0"x32); |
| 7731 | $bits = (1<<$shift); |
| 7732 | vec($str, $off, $width) = $bits; |
| 7733 | $res = unpack("b*",$str); |
| 7734 | $val = unpack("V", $str); |
| 7735 | write; |
| 7736 | } |
| 7737 | } |
| 7738 | } |
| 7739 | |
| 7740 | format STDOUT = |
| 7741 | vec($_,@#,@#) = @<< == @######### @>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
| 7742 | $off, $width, $bits, $val, $res |
| 7743 | . |
| 7744 | __END__ |
| 7745 | |
| 7746 | Regardless of the machine architecture on which it runs, the |
| 7747 | example above should print the following table: |
| 7748 | |
| 7749 | 0 1 2 3 |
| 7750 | unpack("V",$_) 01234567890123456789012345678901 |
| 7751 | ------------------------------------------------------------------ |
| 7752 | vec($_, 0, 1) = 1 == 1 10000000000000000000000000000000 |
| 7753 | vec($_, 1, 1) = 1 == 2 01000000000000000000000000000000 |
| 7754 | vec($_, 2, 1) = 1 == 4 00100000000000000000000000000000 |
| 7755 | vec($_, 3, 1) = 1 == 8 00010000000000000000000000000000 |
| 7756 | vec($_, 4, 1) = 1 == 16 00001000000000000000000000000000 |
| 7757 | vec($_, 5, 1) = 1 == 32 00000100000000000000000000000000 |
| 7758 | vec($_, 6, 1) = 1 == 64 00000010000000000000000000000000 |
| 7759 | vec($_, 7, 1) = 1 == 128 00000001000000000000000000000000 |
| 7760 | vec($_, 8, 1) = 1 == 256 00000000100000000000000000000000 |
| 7761 | vec($_, 9, 1) = 1 == 512 00000000010000000000000000000000 |
| 7762 | vec($_,10, 1) = 1 == 1024 00000000001000000000000000000000 |
| 7763 | vec($_,11, 1) = 1 == 2048 00000000000100000000000000000000 |
| 7764 | vec($_,12, 1) = 1 == 4096 00000000000010000000000000000000 |
| 7765 | vec($_,13, 1) = 1 == 8192 00000000000001000000000000000000 |
| 7766 | vec($_,14, 1) = 1 == 16384 00000000000000100000000000000000 |
| 7767 | vec($_,15, 1) = 1 == 32768 00000000000000010000000000000000 |
| 7768 | vec($_,16, 1) = 1 == 65536 00000000000000001000000000000000 |
| 7769 | vec($_,17, 1) = 1 == 131072 00000000000000000100000000000000 |
| 7770 | vec($_,18, 1) = 1 == 262144 00000000000000000010000000000000 |
| 7771 | vec($_,19, 1) = 1 == 524288 00000000000000000001000000000000 |
| 7772 | vec($_,20, 1) = 1 == 1048576 00000000000000000000100000000000 |
| 7773 | vec($_,21, 1) = 1 == 2097152 00000000000000000000010000000000 |
| 7774 | vec($_,22, 1) = 1 == 4194304 00000000000000000000001000000000 |
| 7775 | vec($_,23, 1) = 1 == 8388608 00000000000000000000000100000000 |
| 7776 | vec($_,24, 1) = 1 == 16777216 00000000000000000000000010000000 |
| 7777 | vec($_,25, 1) = 1 == 33554432 00000000000000000000000001000000 |
| 7778 | vec($_,26, 1) = 1 == 67108864 00000000000000000000000000100000 |
| 7779 | vec($_,27, 1) = 1 == 134217728 00000000000000000000000000010000 |
| 7780 | vec($_,28, 1) = 1 == 268435456 00000000000000000000000000001000 |
| 7781 | vec($_,29, 1) = 1 == 536870912 00000000000000000000000000000100 |
| 7782 | vec($_,30, 1) = 1 == 1073741824 00000000000000000000000000000010 |
| 7783 | vec($_,31, 1) = 1 == 2147483648 00000000000000000000000000000001 |
| 7784 | vec($_, 0, 2) = 1 == 1 10000000000000000000000000000000 |
| 7785 | vec($_, 1, 2) = 1 == 4 00100000000000000000000000000000 |
| 7786 | vec($_, 2, 2) = 1 == 16 00001000000000000000000000000000 |
| 7787 | vec($_, 3, 2) = 1 == 64 00000010000000000000000000000000 |
| 7788 | vec($_, 4, 2) = 1 == 256 00000000100000000000000000000000 |
| 7789 | vec($_, 5, 2) = 1 == 1024 00000000001000000000000000000000 |
| 7790 | vec($_, 6, 2) = 1 == 4096 00000000000010000000000000000000 |
| 7791 | vec($_, 7, 2) = 1 == 16384 00000000000000100000000000000000 |
| 7792 | vec($_, 8, 2) = 1 == 65536 00000000000000001000000000000000 |
| 7793 | vec($_, 9, 2) = 1 == 262144 00000000000000000010000000000000 |
| 7794 | vec($_,10, 2) = 1 == 1048576 00000000000000000000100000000000 |
| 7795 | vec($_,11, 2) = 1 == 4194304 00000000000000000000001000000000 |
| 7796 | vec($_,12, 2) = 1 == 16777216 00000000000000000000000010000000 |
| 7797 | vec($_,13, 2) = 1 == 67108864 00000000000000000000000000100000 |
| 7798 | vec($_,14, 2) = 1 == 268435456 00000000000000000000000000001000 |
| 7799 | vec($_,15, 2) = 1 == 1073741824 00000000000000000000000000000010 |
| 7800 | vec($_, 0, 2) = 2 == 2 01000000000000000000000000000000 |
| 7801 | vec($_, 1, 2) = 2 == 8 00010000000000000000000000000000 |
| 7802 | vec($_, 2, 2) = 2 == 32 00000100000000000000000000000000 |
| 7803 | vec($_, 3, 2) = 2 == 128 00000001000000000000000000000000 |
| 7804 | vec($_, 4, 2) = 2 == 512 00000000010000000000000000000000 |
| 7805 | vec($_, 5, 2) = 2 == 2048 00000000000100000000000000000000 |
| 7806 | vec($_, 6, 2) = 2 == 8192 00000000000001000000000000000000 |
| 7807 | vec($_, 7, 2) = 2 == 32768 00000000000000010000000000000000 |
| 7808 | vec($_, 8, 2) = 2 == 131072 00000000000000000100000000000000 |
| 7809 | vec($_, 9, 2) = 2 == 524288 00000000000000000001000000000000 |
| 7810 | vec($_,10, 2) = 2 == 2097152 00000000000000000000010000000000 |
| 7811 | vec($_,11, 2) = 2 == 8388608 00000000000000000000000100000000 |
| 7812 | vec($_,12, 2) = 2 == 33554432 00000000000000000000000001000000 |
| 7813 | vec($_,13, 2) = 2 == 134217728 00000000000000000000000000010000 |
| 7814 | vec($_,14, 2) = 2 == 536870912 00000000000000000000000000000100 |
| 7815 | vec($_,15, 2) = 2 == 2147483648 00000000000000000000000000000001 |
| 7816 | vec($_, 0, 4) = 1 == 1 10000000000000000000000000000000 |
| 7817 | vec($_, 1, 4) = 1 == 16 00001000000000000000000000000000 |
| 7818 | vec($_, 2, 4) = 1 == 256 00000000100000000000000000000000 |
| 7819 | vec($_, 3, 4) = 1 == 4096 00000000000010000000000000000000 |
| 7820 | vec($_, 4, 4) = 1 == 65536 00000000000000001000000000000000 |
| 7821 | vec($_, 5, 4) = 1 == 1048576 00000000000000000000100000000000 |
| 7822 | vec($_, 6, 4) = 1 == 16777216 00000000000000000000000010000000 |
| 7823 | vec($_, 7, 4) = 1 == 268435456 00000000000000000000000000001000 |
| 7824 | vec($_, 0, 4) = 2 == 2 01000000000000000000000000000000 |
| 7825 | vec($_, 1, 4) = 2 == 32 00000100000000000000000000000000 |
| 7826 | vec($_, 2, 4) = 2 == 512 00000000010000000000000000000000 |
| 7827 | vec($_, 3, 4) = 2 == 8192 00000000000001000000000000000000 |
| 7828 | vec($_, 4, 4) = 2 == 131072 00000000000000000100000000000000 |
| 7829 | vec($_, 5, 4) = 2 == 2097152 00000000000000000000010000000000 |
| 7830 | vec($_, 6, 4) = 2 == 33554432 00000000000000000000000001000000 |
| 7831 | vec($_, 7, 4) = 2 == 536870912 00000000000000000000000000000100 |
| 7832 | vec($_, 0, 4) = 4 == 4 00100000000000000000000000000000 |
| 7833 | vec($_, 1, 4) = 4 == 64 00000010000000000000000000000000 |
| 7834 | vec($_, 2, 4) = 4 == 1024 00000000001000000000000000000000 |
| 7835 | vec($_, 3, 4) = 4 == 16384 00000000000000100000000000000000 |
| 7836 | vec($_, 4, 4) = 4 == 262144 00000000000000000010000000000000 |
| 7837 | vec($_, 5, 4) = 4 == 4194304 00000000000000000000001000000000 |
| 7838 | vec($_, 6, 4) = 4 == 67108864 00000000000000000000000000100000 |
| 7839 | vec($_, 7, 4) = 4 == 1073741824 00000000000000000000000000000010 |
| 7840 | vec($_, 0, 4) = 8 == 8 00010000000000000000000000000000 |
| 7841 | vec($_, 1, 4) = 8 == 128 00000001000000000000000000000000 |
| 7842 | vec($_, 2, 4) = 8 == 2048 00000000000100000000000000000000 |
| 7843 | vec($_, 3, 4) = 8 == 32768 00000000000000010000000000000000 |
| 7844 | vec($_, 4, 4) = 8 == 524288 00000000000000000001000000000000 |
| 7845 | vec($_, 5, 4) = 8 == 8388608 00000000000000000000000100000000 |
| 7846 | vec($_, 6, 4) = 8 == 134217728 00000000000000000000000000010000 |
| 7847 | vec($_, 7, 4) = 8 == 2147483648 00000000000000000000000000000001 |
| 7848 | vec($_, 0, 8) = 1 == 1 10000000000000000000000000000000 |
| 7849 | vec($_, 1, 8) = 1 == 256 00000000100000000000000000000000 |
| 7850 | vec($_, 2, 8) = 1 == 65536 00000000000000001000000000000000 |
| 7851 | vec($_, 3, 8) = 1 == 16777216 00000000000000000000000010000000 |
| 7852 | vec($_, 0, 8) = 2 == 2 01000000000000000000000000000000 |
| 7853 | vec($_, 1, 8) = 2 == 512 00000000010000000000000000000000 |
| 7854 | vec($_, 2, 8) = 2 == 131072 00000000000000000100000000000000 |
| 7855 | vec($_, 3, 8) = 2 == 33554432 00000000000000000000000001000000 |
| 7856 | vec($_, 0, 8) = 4 == 4 00100000000000000000000000000000 |
| 7857 | vec($_, 1, 8) = 4 == 1024 00000000001000000000000000000000 |
| 7858 | vec($_, 2, 8) = 4 == 262144 00000000000000000010000000000000 |
| 7859 | vec($_, 3, 8) = 4 == 67108864 00000000000000000000000000100000 |
| 7860 | vec($_, 0, 8) = 8 == 8 00010000000000000000000000000000 |
| 7861 | vec($_, 1, 8) = 8 == 2048 00000000000100000000000000000000 |
| 7862 | vec($_, 2, 8) = 8 == 524288 00000000000000000001000000000000 |
| 7863 | vec($_, 3, 8) = 8 == 134217728 00000000000000000000000000010000 |
| 7864 | vec($_, 0, 8) = 16 == 16 00001000000000000000000000000000 |
| 7865 | vec($_, 1, 8) = 16 == 4096 00000000000010000000000000000000 |
| 7866 | vec($_, 2, 8) = 16 == 1048576 00000000000000000000100000000000 |
| 7867 | vec($_, 3, 8) = 16 == 268435456 00000000000000000000000000001000 |
| 7868 | vec($_, 0, 8) = 32 == 32 00000100000000000000000000000000 |
| 7869 | vec($_, 1, 8) = 32 == 8192 00000000000001000000000000000000 |
| 7870 | vec($_, 2, 8) = 32 == 2097152 00000000000000000000010000000000 |
| 7871 | vec($_, 3, 8) = 32 == 536870912 00000000000000000000000000000100 |
| 7872 | vec($_, 0, 8) = 64 == 64 00000010000000000000000000000000 |
| 7873 | vec($_, 1, 8) = 64 == 16384 00000000000000100000000000000000 |
| 7874 | vec($_, 2, 8) = 64 == 4194304 00000000000000000000001000000000 |
| 7875 | vec($_, 3, 8) = 64 == 1073741824 00000000000000000000000000000010 |
| 7876 | vec($_, 0, 8) = 128 == 128 00000001000000000000000000000000 |
| 7877 | vec($_, 1, 8) = 128 == 32768 00000000000000010000000000000000 |
| 7878 | vec($_, 2, 8) = 128 == 8388608 00000000000000000000000100000000 |
| 7879 | vec($_, 3, 8) = 128 == 2147483648 00000000000000000000000000000001 |
| 7880 | |
| 7881 | =item wait |
| 7882 | X<wait> |
| 7883 | |
| 7884 | Behaves like wait(2) on your system: it waits for a child |
| 7885 | process to terminate and returns the pid of the deceased process, or |
| 7886 | C<-1> if there are no child processes. The status is returned in C<$?> |
| 7887 | and C<${^CHILD_ERROR_NATIVE}>. |
| 7888 | Note that a return value of C<-1> could mean that child processes are |
| 7889 | being automatically reaped, as described in L<perlipc>. |
| 7890 | |
| 7891 | If you use wait in your handler for $SIG{CHLD} it may accidentally for the |
| 7892 | child created by qx() or system(). See L<perlipc> for details. |
| 7893 | |
| 7894 | =item waitpid PID,FLAGS |
| 7895 | X<waitpid> |
| 7896 | |
| 7897 | Waits for a particular child process to terminate and returns the pid of |
| 7898 | the deceased process, or C<-1> if there is no such child process. On some |
| 7899 | systems, a value of 0 indicates that there are processes still running. |
| 7900 | The status is returned in C<$?> and C<${^CHILD_ERROR_NATIVE}>. If you say |
| 7901 | |
| 7902 | use POSIX ":sys_wait_h"; |
| 7903 | #... |
| 7904 | do { |
| 7905 | $kid = waitpid(-1, WNOHANG); |
| 7906 | } while $kid > 0; |
| 7907 | |
| 7908 | then you can do a non-blocking wait for all pending zombie processes. |
| 7909 | Non-blocking wait is available on machines supporting either the |
| 7910 | waitpid(2) or wait4(2) syscalls. However, waiting for a particular |
| 7911 | pid with FLAGS of C<0> is implemented everywhere. (Perl emulates the |
| 7912 | system call by remembering the status values of processes that have |
| 7913 | exited but have not been harvested by the Perl script yet.) |
| 7914 | |
| 7915 | Note that on some systems, a return value of C<-1> could mean that child |
| 7916 | processes are being automatically reaped. See L<perlipc> for details, |
| 7917 | and for other examples. |
| 7918 | |
| 7919 | =item wantarray |
| 7920 | X<wantarray> X<context> |
| 7921 | |
| 7922 | Returns true if the context of the currently executing subroutine or |
| 7923 | C<eval> is looking for a list value. Returns false if the context is |
| 7924 | looking for a scalar. Returns the undefined value if the context is |
| 7925 | looking for no value (void context). |
| 7926 | |
| 7927 | return unless defined wantarray; # don't bother doing more |
| 7928 | my @a = complex_calculation(); |
| 7929 | return wantarray ? @a : "@a"; |
| 7930 | |
| 7931 | C<wantarray()>'s result is unspecified in the top level of a file, |
| 7932 | in a C<BEGIN>, C<UNITCHECK>, C<CHECK>, C<INIT> or C<END> block, or |
| 7933 | in a C<DESTROY> method. |
| 7934 | |
| 7935 | This function should have been named wantlist() instead. |
| 7936 | |
| 7937 | =item warn LIST |
| 7938 | X<warn> X<warning> X<STDERR> |
| 7939 | |
| 7940 | Prints the value of LIST to STDERR. If the last element of LIST does |
| 7941 | not end in a newline, it appends the same file/line number text as C<die> |
| 7942 | does. |
| 7943 | |
| 7944 | If the output is empty and C<$@> already contains a value (typically from a |
| 7945 | previous eval) that value is used after appending C<"\t...caught"> |
| 7946 | to C<$@>. This is useful for staying almost, but not entirely similar to |
| 7947 | C<die>. |
| 7948 | |
| 7949 | If C<$@> is empty then the string C<"Warning: Something's wrong"> is used. |
| 7950 | |
| 7951 | No message is printed if there is a C<$SIG{__WARN__}> handler |
| 7952 | installed. It is the handler's responsibility to deal with the message |
| 7953 | as it sees fit (like, for instance, converting it into a C<die>). Most |
| 7954 | handlers must therefore arrange to actually display the |
| 7955 | warnings that they are not prepared to deal with, by calling C<warn> |
| 7956 | again in the handler. Note that this is quite safe and will not |
| 7957 | produce an endless loop, since C<__WARN__> hooks are not called from |
| 7958 | inside one. |
| 7959 | |
| 7960 | You will find this behavior is slightly different from that of |
| 7961 | C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can |
| 7962 | instead call C<die> again to change it). |
| 7963 | |
| 7964 | Using a C<__WARN__> handler provides a powerful way to silence all |
| 7965 | warnings (even the so-called mandatory ones). An example: |
| 7966 | |
| 7967 | # wipe out *all* compile-time warnings |
| 7968 | BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } } |
| 7969 | my $foo = 10; |
| 7970 | my $foo = 20; # no warning about duplicate my $foo, |
| 7971 | # but hey, you asked for it! |
| 7972 | # no compile-time or run-time warnings before here |
| 7973 | $DOWARN = 1; |
| 7974 | |
| 7975 | # run-time warnings enabled after here |
| 7976 | warn "\$foo is alive and $foo!"; # does show up |
| 7977 | |
| 7978 | See L<perlvar> for details on setting C<%SIG> entries and for more |
| 7979 | examples. See the Carp module for other kinds of warnings using its |
| 7980 | carp() and cluck() functions. |
| 7981 | |
| 7982 | =item when EXPR BLOCK |
| 7983 | X<when> |
| 7984 | |
| 7985 | =item when BLOCK |
| 7986 | |
| 7987 | C<when> is analogous to the C<case> keyword in other languages. Used with a |
| 7988 | C<foreach> loop or the experimental C<given> block, C<when> can be used in |
| 7989 | Perl to implement C<switch>/C<case> like statements. Available as a |
| 7990 | statement after Perl 5.10 and as a statement modifier after 5.14. |
| 7991 | Here are three examples: |
| 7992 | |
| 7993 | use v5.10; |
| 7994 | foreach (@fruits) { |
| 7995 | when (/apples?/) { |
| 7996 | say "I like apples." |
| 7997 | } |
| 7998 | when (/oranges?/) { |
| 7999 | say "I don't like oranges." |
| 8000 | } |
| 8001 | default { |
| 8002 | say "I don't like anything" |
| 8003 | } |
| 8004 | } |
| 8005 | |
| 8006 | # require 5.14 for when as statement modifier |
| 8007 | use v5.14; |
| 8008 | foreach (@fruits) { |
| 8009 | say "I like apples." when /apples?/; |
| 8010 | say "I don't like oranges." when /oranges?; |
| 8011 | default { say "I don't like anything" } |
| 8012 | } |
| 8013 | |
| 8014 | use v5.10; |
| 8015 | given ($fruit) { |
| 8016 | when (/apples?/) { |
| 8017 | say "I like apples." |
| 8018 | } |
| 8019 | when (/oranges?/) { |
| 8020 | say "I don't like oranges." |
| 8021 | } |
| 8022 | default { |
| 8023 | say "I don't like anything" |
| 8024 | } |
| 8025 | } |
| 8026 | |
| 8027 | See L<perlsyn/"Switch statements"> for detailed information. |
| 8028 | |
| 8029 | =item write FILEHANDLE |
| 8030 | X<write> |
| 8031 | |
| 8032 | =item write EXPR |
| 8033 | |
| 8034 | =item write |
| 8035 | |
| 8036 | Writes a formatted record (possibly multi-line) to the specified FILEHANDLE, |
| 8037 | using the format associated with that file. By default the format for |
| 8038 | a file is the one having the same name as the filehandle, but the |
| 8039 | format for the current output channel (see the C<select> function) may be set |
| 8040 | explicitly by assigning the name of the format to the C<$~> variable. |
| 8041 | |
| 8042 | Top of form processing is handled automatically: if there is insufficient |
| 8043 | room on the current page for the formatted record, the page is advanced by |
| 8044 | writing a form feed, a special top-of-page format is used to format the new |
| 8045 | page header before the record is written. By default, the top-of-page |
| 8046 | format is the name of the filehandle with "_TOP" appended. This would be a |
| 8047 | problem with autovivified filehandles, but it may be dynamically set to the |
| 8048 | format of your choice by assigning the name to the C<$^> variable while |
| 8049 | that filehandle is selected. The number of lines remaining on the current |
| 8050 | page is in variable C<$->, which can be set to C<0> to force a new page. |
| 8051 | |
| 8052 | If FILEHANDLE is unspecified, output goes to the current default output |
| 8053 | channel, which starts out as STDOUT but may be changed by the |
| 8054 | C<select> operator. If the FILEHANDLE is an EXPR, then the expression |
| 8055 | is evaluated and the resulting string is used to look up the name of |
| 8056 | the FILEHANDLE at run time. For more on formats, see L<perlform>. |
| 8057 | |
| 8058 | Note that write is I<not> the opposite of C<read>. Unfortunately. |
| 8059 | |
| 8060 | =item y/// |
| 8061 | |
| 8062 | The transliteration operator. Same as C<tr///>. See |
| 8063 | L<perlop/"Quote and Quote-like Operators">. |
| 8064 | |
| 8065 | =back |
| 8066 | |
| 8067 | =cut |