[perl5.git] / lib / File / Copy.pm

# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
# source code has been placed in the public domain by the author.
# Please be kind and preserve the documentation.
#
# Additions copyright 1996 by Charles Bailey.  Permission is granted
# to distribute the revised code under the same terms as Perl itself.

package File::Copy;

use 5.6.0;
use strict;
use warnings;
use Carp;
use File::Spec;
our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
sub copy;
sub syscopy;
sub cp;
sub mv;

# Note that this module implements only *part* of the API defined by
# the File/Copy.pm module of the File-Tools-2.0 package.  However, that
# package has not yet been updated to work with Perl 5.004, and so it
# would be a Bad Thing for the CPAN module to grab it and replace this
# module.  Therefore, we set this module's version higher than 2.0.
$VERSION = '2.04';

require Exporter;
@ISA = qw(Exporter);
@EXPORT = qw(copy move);
@EXPORT_OK = qw(cp mv);

$Too_Big = 1024 * 1024 * 2;

sub _catname {
    my($from, $to) = @_;
    if (not defined &basename) {
	require File::Basename;
	import  File::Basename 'basename';
    }

    if ($^O eq 'MacOS') {
	# a partial dir name that's valid only in the cwd (e.g. 'tmp')
	$to = ':' . $to if $to !~ /:/;
    }

    return File::Spec->catfile($to, basename($from));
}

sub copy {
    croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
      unless(@_ == 2 || @_ == 3);

    my $from = shift;
    my $to = shift;

    my $from_a_handle = (ref($from)
			 ? (ref($from) eq 'GLOB'
			    || UNIVERSAL::isa($from, 'GLOB')
                            || UNIVERSAL::isa($from, 'IO::Handle'))
			 : (ref(\$from) eq 'GLOB'));
    my $to_a_handle =   (ref($to)
			 ? (ref($to) eq 'GLOB'
			    || UNIVERSAL::isa($to, 'GLOB')
                            || UNIVERSAL::isa($to, 'IO::Handle'))
			 : (ref(\$to) eq 'GLOB'));

    if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    if (defined &syscopy && !$Syscopy_is_copy
	&& !$to_a_handle
	&& !($from_a_handle && $^O eq 'os2' )	# OS/2 cannot handle handles
	&& !($from_a_handle && $^O eq 'mpeix')	# and neither can MPE/iX.
	&& !($from_a_handle && $^O eq 'MSWin32')
	&& !($from_a_handle && $^O eq 'MacOS')
	&& !($from_a_handle && $^O eq 'NetWare')
       )
    {
	return syscopy($from, $to);
    }

    my $closefrom = 0;
    my $closeto = 0;
    my ($size, $status, $r, $buf);
    local(*FROM, *TO);
    local($\) = '';

    if ($from_a_handle) {
	*FROM = *$from{FILEHANDLE};
    } else {
	$from = _protect($from) if $from =~ /^\s/s;
	open(FROM, "< $from\0") or goto fail_open1;
	binmode FROM or die "($!,$^E)";
	$closefrom = 1;
    }

    if ($to_a_handle) {
	*TO = *$to{FILEHANDLE};
    } else {
	$to = _protect($to) if $to =~ /^\s/s;
	open(TO,"> $to\0") or goto fail_open2;
	binmode TO or die "($!,$^E)";
	$closeto = 1;
    }

    if (@_) {
	$size = shift(@_) + 0;
	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
    } else {
	$size = -s FROM;
	$size = 1024 if ($size < 512);
	$size = $Too_Big if ($size > $Too_Big);
    }

    $! = 0;
    for (;;) {
	my ($r, $w, $t);
	defined($r = sysread(FROM, $buf, $size))
	    or goto fail_inner;
	last unless $r;
	for ($w = 0; $w < $r; $w += $t) {
	    $t = syswrite(TO, $buf, $r - $w, $w)
		or goto fail_inner;
	}
    }

    close(TO) || goto fail_open2 if $closeto;
    close(FROM) || goto fail_open1 if $closefrom;

    # Use this idiom to avoid uninitialized value warning.
    return 1;

    # All of these contortions try to preserve error messages...
  fail_inner:
    if ($closeto) {
	$status = $!;
	$! = 0;
	close TO;
	$! = $status unless $!;
    }
  fail_open2:
    if ($closefrom) {
	$status = $!;
	$! = 0;
	close FROM;
	$! = $status unless $!;
    }
  fail_open1:
    return 0;
}

sub move {
    my($from,$to) = @_;
    my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);

    if (-d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    ($tosz1,$tomt1) = (stat($to))[7,9];
    $fromsz = -s $from;
    if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
      # will not rename with overwrite
      unlink $to;
    }
    return 1 if rename $from, $to;

    ($sts,$ossts) = ($! + 0, $^E + 0);
    # Did rename return an error even though it succeeded, because $to
    # is on a remote NFS file system, and NFS lost the server's ack?
    return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
                (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
                ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
                $tosz2 == $fromsz;                         # it's all there

    ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
    return 1 if ($copied = copy($from,$to)) && unlink($from);

    ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
    unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
    ($!,$^E) = ($sts,$ossts);
    return 0;
}

*cp = \&copy;
*mv = \&move;


if ($^O eq 'MacOS') {
    *_protect = sub { MacPerl::MakeFSSpec($_[0]) };
} else {
    *_protect = sub { "./$_[0]" };
}

# &syscopy is an XSUB under OS/2
unless (defined &syscopy) {
    if ($^O eq 'VMS') {
	*syscopy = \&rmscopy;
    } elsif ($^O eq 'mpeix') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    # Use the MPE cp program in order to
	    # preserve MPE file attributes.
	    return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	};
    } elsif ($^O eq 'MSWin32') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    return Win32::CopyFile(@_, 1);
	};
    } elsif ($^O eq 'MacOS') {
	require Mac::MoreFiles;
	*syscopy = sub {
	    my($from, $to) = @_;
	    my($dir, $toname);

	    return 0 unless -e $from;

	    if ($to =~ /(.*:)([^:]+):?$/) {
		($dir, $toname) = ($1, $2);
	    } else {
		($dir, $toname) = (":", $to);
	    }

	    unlink($to);
	    Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
	};
    } else {
	$Syscopy_is_copy = 1;
	*syscopy = \&copy;
    }
}

1;

__END__

=head1 NAME

File::Copy - Copy files or filehandles

=head1 SYNOPSIS

  	use File::Copy;

	copy("file1","file2");
  	copy("Copy.pm",\*STDOUT);'
	move("/dev1/fileA","/dev2/fileB");

  	use POSIX;
	use File::Copy cp;

	$n = FileHandle->new("/a/file","r");
	cp($n,"x");'

=head1 DESCRIPTION

The File::Copy module provides two basic functions, C<copy> and
C<move>, which are useful for getting the contents of a file from
one place to another.

=over 4

=item *

The C<copy> function takes two
parameters: a file to copy from and a file to copy to. Either
argument may be a string, a FileHandle reference or a FileHandle
glob. Obviously, if the first argument is a filehandle of some
sort, it will be read from, and if it is a file I<name> it will
be opened for reading. Likewise, the second argument will be
written to (and created if need be).

B<Note that passing in
files as handles instead of names may lead to loss of information
on some operating systems; it is recommended that you use file
names whenever possible.>  Files are opened in binary mode where
applicable.  To get a consistent behaviour when copying from a
filehandle to a file, use C<binmode> on the filehandle.

An optional third parameter can be used to specify the buffer
size used for copying. This is the number of bytes from the
first file, that wil be held in memory at any given time, before
being written to the second file. The default buffer size depends
upon the file, but will generally be the whole file (up to 2Mb), or
1k for filehandles that do not reference files (eg. sockets).

You may use the syntax C<use File::Copy "cp"> to get at the
"cp" alias for this function. The syntax is I<exactly> the same.

=item *

The C<move> function also takes two parameters: the current name
and the intended name of the file to be moved.  If the destination
already exists and is a directory, and the source is not a
directory, then the source file will be renamed into the directory
specified by the destination.

If possible, move() will simply rename the file.  Otherwise, it copies
the file to the new location and deletes the original.  If an error occurs
during this copy-and-delete process, you may be left with a (possibly partial)
copy of the file under the destination name.

You may use the "mv" alias for this function in the same way that
you may use the "cp" alias for C<copy>.

=back

File::Copy also provides the C<syscopy> routine, which copies the
file specified in the first parameter to the file specified in the
second parameter, preserving OS-specific attributes and file
structure.  For Unix systems, this is equivalent to the simple
C<copy> routine.  For VMS systems, this calls the C<rmscopy>
routine (see below).  For OS/2 systems, this calls the C<syscopy>
XSUB directly. For Win32 systems, this calls C<Win32::CopyFile>.

=head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)

If both arguments to C<copy> are not file handles,
then C<copy> will perform a "system copy" of
the input file to a new output file, in order to preserve file
attributes, indexed file structure, I<etc.>  The buffer size
parameter is ignored.  If either argument to C<copy> is a
handle to an opened file, then data is copied using Perl
operators, and no effort is made to preserve file attributes
or record structure.

The system copy routine may also be called directly under VMS and OS/2
as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
is the routine that does the actual work for syscopy).

=over 4

=item rmscopy($from,$to[,$date_flag])

The first and second arguments may be strings, typeglobs, typeglob
references, or objects inheriting from IO::Handle;
they are used in all cases to obtain the
I<filespec> of the input and output files, respectively.  The
name and type of the input file are used as defaults for the
output file, if necessary.

A new version of the output file is always created, which
inherits the structure and RMS attributes of the input file,
except for owner and protections (and possibly timestamps;
see below).  All data from the input file is copied to the
output file; if either of the first two parameters to C<rmscopy>
is a file handle, its position is unchanged.  (Note that this
means a file handle pointing to the output file will be
associated with an old version of that file after C<rmscopy>
returns, not the newly created version.)

The third parameter is an integer flag, which tells C<rmscopy>
how to handle timestamps.  If it is E<lt> 0, none of the input file's
timestamps are propagated to the output file.  If it is E<gt> 0, then
it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
timestamps other than the revision date are propagated; if bit 1
is set, the revision date is propagated.  If the third parameter
to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
if the name or type of the output file was explicitly specified,
then no timestamps are propagated, but if they were taken implicitly
from the input filespec, then all timestamps other than the
revision date are propagated.  If this parameter is not supplied,
it defaults to 0.

Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
it sets C<$!>, deletes the output file, and returns 0.

=back

=head1 RETURN

All functions return 1 on success, 0 on failure.
$! will be set if an error was encountered.

=head1 NOTES

=over 4

=item *

On Mac OS (Classic), the path separator is ':', not '/', and the 
current directory is denoted as ':', not '.'. You should be careful 
about specifying relative pathnames. While a full path always begins 
with a volume name, a relative pathname should always begin with a 
':'.  If specifying a volume name only, a trailing ':' is required.

E.g.

  copy("file1", "tmp");        # creates the file 'tmp' in the current directory
  copy("file1", ":tmp:");      # creates :tmp:file1
  copy("file1", ":tmp");       # same as above
  copy("file1", "tmp");        # same as above, if 'tmp' is a directory (but don't do   
                               # that, since it may cause confusion, see example #1)
  copy("file1", "tmp:file1");  # error, since 'tmp:' is not a volume
  copy("file1", ":tmp:file1"); # ok, partial path
  copy("file1", "DataHD:");    # creates DataHD:file1
  
  move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one 
                                             # volume to another

=back

=head1 AUTHOR

File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.

=cut
Commit	Line	Data
f716a1dd	1	# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
	2	# source code has been placed in the public domain by the author.
	3	# Please be kind and preserve the documentation.
	4	#
71be2cbc	5	# Additions copyright 1996 by Charles Bailey. Permission is granted
71be2cbc	6	# to distribute the revised code under the same terms as Perl itself.
f716a1dd	7
	8	package File::Copy;
	9
b395063c	10	use 5.6.0;
71be2cbc	11	use strict;
b395063c	12	use warnings;
f716a1dd	13	use Carp;
6c254d95	14	use File::Spec;
17f410f9 GS	15	our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
	16	sub copy;
	17	sub syscopy;
	18	sub cp;
	19	sub mv;
71be2cbc	20
	21	# Note that this module implements only part of the API defined by
	22	# the File/Copy.pm module of the File-Tools-2.0 package. However, that
	23	# package has not yet been updated to work with Perl 5.004, and so it
	24	# would be a Bad Thing for the CPAN module to grab it and replace this
	25	# module. Therefore, we set this module's version higher than 2.0.
6c254d95	26	$VERSION = '2.04';
f716a1dd	27
71be2cbc	28	require Exporter;
	29	@ISA = qw(Exporter);
	30	@EXPORT = qw(copy move);
	31	@EXPORT_OK = qw(cp mv);
f716a1dd	32
441496b2	33	$Too_Big = 1024 * 1024 * 2;
f716a1dd	34
6c254d95	35	sub _catname {
71be2cbc	36	my($from, $to) = @_;
	37	if (not defined &basename) {
	38	require File::Basename;
	39	import File::Basename 'basename';
	40	}
6c254d95 CN	41
	42	if ($^O eq 'MacOS') {
	43	# a partial dir name that's valid only in the cwd (e.g. 'tmp')
	44	$to = ':' . $to if $to !~ /:/;
	45	}
	46
	47	return File::Spec->catfile($to, basename($from));
f716a1dd	48	}
	49
	50	sub copy {
71be2cbc	51	croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
f716a1dd	52	unless(@_ == 2 \|\| @_ == 3);
	53
	54	my $from = shift;
	55	my $to = shift;
71be2cbc	56
	57	my $from_a_handle = (ref($from)
	58	? (ref($from) eq 'GLOB'
d704f39a MG	59	\|\| UNIVERSAL::isa($from, 'GLOB')
d704f39a MG	60	\|\| UNIVERSAL::isa($from, 'IO::Handle'))
71be2cbc	61	: (ref(\$from) eq 'GLOB'));
	62	my $to_a_handle = (ref($to)
	63	? (ref($to) eq 'GLOB'
d704f39a MG	64	\|\| UNIVERSAL::isa($to, 'GLOB')
d704f39a MG	65	\|\| UNIVERSAL::isa($to, 'IO::Handle'))
71be2cbc	66	: (ref(\$to) eq 'GLOB'));
	67
	68	if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	69	$to = _catname($from, $to);
	70	}
	71
1a04d035	72	if (defined &syscopy && !$Syscopy_is_copy
e6434134	73	&& !$to_a_handle
1d84e8df JH	74	&& !($from_a_handle && $^O eq 'os2' ) # OS/2 cannot handle handles
1d84e8df JH	75	&& !($from_a_handle && $^O eq 'mpeix') # and neither can MPE/iX.
7509b657	76	&& !($from_a_handle && $^O eq 'MSWin32')
fa648be5	77	&& !($from_a_handle && $^O eq 'MacOS')
2986a63f	78	&& !($from_a_handle && $^O eq 'NetWare')
1a04d035	79	)
71be2cbc	80	{
	81	return syscopy($from, $to);
	82	}
	83
	84	my $closefrom = 0;
	85	my $closeto = 0;
f716a1dd	86	my ($size, $status, $r, $buf);
f716a1dd	87	local(FROM, TO);
48a5c399	88	local($\) = '';
f716a1dd	89
71be2cbc	90	if ($from_a_handle) {
71be2cbc	91	FROM = $from{FILEHANDLE};
f716a1dd	92	} else {
fa648be5	93	$from = _protect($from) if $from =~ /^\s/s;
71be2cbc	94	open(FROM, "< $from\0") or goto fail_open1;
71be2cbc	95	binmode FROM or die "($!,$^E)";
f716a1dd	96	$closefrom = 1;
1a04d035 A	97	}
1a04d035 A	98
71be2cbc	99	if ($to_a_handle) {
71be2cbc	100	TO = $to{FILEHANDLE};
1a04d035	101	} else {
fa648be5	102	$to = _protect($to) if $to =~ /^\s/s;
71be2cbc	103	open(TO,"> $to\0") or goto fail_open2;
	104	binmode TO or die "($!,$^E)";
	105	$closeto = 1;
1a04d035	106	}
f716a1dd	107
	108	if (@_) {
	109	$size = shift(@_) + 0;
	110	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
	111	} else {
	112	$size = -s FROM;
	113	$size = 1024 if ($size < 512);
441496b2	114	$size = $Too_Big if ($size > $Too_Big);
f716a1dd	115	}
f716a1dd	116
71be2cbc	117	$! = 0;
	118	for (;;) {
	119	my ($r, $w, $t);
	120	defined($r = sysread(FROM, $buf, $size))
	121	or goto fail_inner;
	122	last unless $r;
	123	for ($w = 0; $w < $r; $w += $t) {
	124	$t = syswrite(TO, $buf, $r - $w, $w)
	125	or goto fail_inner;
f716a1dd	126	}
f716a1dd	127	}
71be2cbc	128
f716a1dd	129	close(TO) \|\| goto fail_open2 if $closeto;
f716a1dd	130	close(FROM) \|\| goto fail_open1 if $closefrom;
71be2cbc	131
48a5c399	132	# Use this idiom to avoid uninitialized value warning.
f716a1dd	133	return 1;
1a04d035	134
f716a1dd	135	# All of these contortions try to preserve error messages...
	136	fail_inner:
	137	if ($closeto) {
	138	$status = $!;
	139	$! = 0;
	140	close TO;
	141	$! = $status unless $!;
	142	}
	143	fail_open2:
	144	if ($closefrom) {
	145	$status = $!;
	146	$! = 0;
	147	close FROM;
	148	$! = $status unless $!;
	149	}
	150	fail_open1:
f716a1dd	151	return 0;
f716a1dd	152	}
9b957b78	153
441496b2	154	sub move {
71be2cbc	155	my($from,$to) = @_;
71be2cbc	156	my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
441496b2	157
71be2cbc	158	if (-d $to && ! -d $from) {
	159	$to = _catname($from, $to);
	160	}
	161
	162	($tosz1,$tomt1) = (stat($to))[7,9];
	163	$fromsz = -s $from;
e6434134 IZ	164	if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
	165	# will not rename with overwrite
	166	unlink $to;
	167	}
71be2cbc	168	return 1 if rename $from, $to;
	169
	170	($sts,$ossts) = ($! + 0, $^E + 0);
	171	# Did rename return an error even though it succeeded, because $to
	172	# is on a remote NFS file system, and NFS lost the server's ack?
	173	return 1 if defined($fromsz) && !-e $from && # $from disappeared
	174	(($tosz2,$tomt2) = (stat($to))[7,9]) && # $to's there
	175	($tosz1 != $tosz2 or $tomt1 != $tomt2) && # and changed
	176	$tosz2 == $fromsz; # it's all there
1a04d035	177
71be2cbc	178	($tosz1,$tomt1) = (stat($to))[7,9]; # just in case rename did something
71be2cbc	179	return 1 if ($copied = copy($from,$to)) && unlink($from);
1a04d035	180
71be2cbc	181	($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
	182	unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
	183	($!,$^E) = ($sts,$ossts);
	184	return 0;
441496b2	185	}
9b957b78	186
71be2cbc	187	*cp = \©
	188	*mv = \&move;
	189
fa648be5 CN	190
	191	if ($^O eq 'MacOS') {
	192	*_protect = sub { MacPerl::MakeFSSpec($_[0]) };
	193	} else {
	194	*_protect = sub { "./$_[0]" };
	195	}
	196
9b957b78	197	# &syscopy is an XSUB under OS/2
1d84e8df JH	198	unless (defined &syscopy) {
	199	if ($^O eq 'VMS') {
	200	*syscopy = \&rmscopy;
	201	} elsif ($^O eq 'mpeix') {
	202	*syscopy = sub {
3f5ee302	203	return 0 unless @_ == 2;
1d84e8df JH	204	# Use the MPE cp program in order to
	205	# preserve MPE file attributes.
	206	return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	207	};
7509b657 GS	208	} elsif ($^O eq 'MSWin32') {
	209	*syscopy = sub {
	210	return 0 unless @_ == 2;
	211	return Win32::CopyFile(@_, 1);
	212	};
fa648be5 CN	213	} elsif ($^O eq 'MacOS') {
	214	require Mac::MoreFiles;
	215	*syscopy = sub {
	216	my($from, $to) = @_;
	217	my($dir, $toname);
	218
	219	return 0 unless -e $from;
	220
	221	if ($to =~ /(.*:)([^:]+):?$/) {
	222	($dir, $toname) = ($1, $2);
	223	} else {
	224	($dir, $toname) = (":", $to);
	225	}
	226
	227	unlink($to);
	228	Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
	229	};
1d84e8df	230	} else {
1a04d035	231	$Syscopy_is_copy = 1;
1d84e8df JH	232	*syscopy = \©
	233	}
	234	}
f716a1dd	235
	236	1;
	237
	238	__END__
a5f75d66	239
f716a1dd	240	=head1 NAME
	241
	242	File::Copy - Copy files or filehandles
	243
a5f75d66	244	=head1 SYNOPSIS
f716a1dd	245
	246	use File::Copy;
	247
	248	copy("file1","file2");
	249	copy("Copy.pm",\*STDOUT);'
441496b2	250	move("/dev1/fileA","/dev2/fileB");
f716a1dd	251
	252	use POSIX;
	253	use File::Copy cp;
	254
23f3aea0	255	$n = FileHandle->new("/a/file","r");
f716a1dd	256	cp($n,"x");'
	257
	258	=head1 DESCRIPTION
	259
441496b2 CB	260	The File::Copy module provides two basic functions, C<copy> and
	261	C<move>, which are useful for getting the contents of a file from
	262	one place to another.
	263
	264	=over 4
	265
	266	=item *
	267
	268	The C<copy> function takes two
f716a1dd	269	parameters: a file to copy from and a file to copy to. Either
	270	argument may be a string, a FileHandle reference or a FileHandle
	271	glob. Obviously, if the first argument is a filehandle of some
	272	sort, it will be read from, and if it is a file I<name> it will
	273	be opened for reading. Likewise, the second argument will be
e6434134	274	written to (and created if need be).
71be2cbc	275
71be2cbc	276	B<Note that passing in
9b957b78	277	files as handles instead of names may lead to loss of information
9b957b78	278	on some operating systems; it is recommended that you use file
e6434134	279	names whenever possible.> Files are opened in binary mode where
8dcee03e	280	applicable. To get a consistent behaviour when copying from a
e6434134	281	filehandle to a file, use C<binmode> on the filehandle.
f716a1dd	282
	283	An optional third parameter can be used to specify the buffer
	284	size used for copying. This is the number of bytes from the
	285	first file, that wil be held in memory at any given time, before
	286	being written to the second file. The default buffer size depends
	287	upon the file, but will generally be the whole file (up to 2Mb), or
	288	1k for filehandles that do not reference files (eg. sockets).
	289
	290	You may use the syntax C<use File::Copy "cp"> to get at the
	291	"cp" alias for this function. The syntax is I<exactly> the same.
	292
441496b2 CB	293	=item *
	294
	295	The C<move> function also takes two parameters: the current name
71be2cbc	296	and the intended name of the file to be moved. If the destination
	297	already exists and is a directory, and the source is not a
	298	directory, then the source file will be renamed into the directory
	299	specified by the destination.
	300
	301	If possible, move() will simply rename the file. Otherwise, it copies
	302	the file to the new location and deletes the original. If an error occurs
	303	during this copy-and-delete process, you may be left with a (possibly partial)
441496b2 CB	304	copy of the file under the destination name.
	305
	306	You may use the "mv" alias for this function in the same way that
	307	you may use the "cp" alias for C<copy>.
	308
	309	=back
	310
9b957b78	311	File::Copy also provides the C<syscopy> routine, which copies the
	312	file specified in the first parameter to the file specified in the
	313	second parameter, preserving OS-specific attributes and file
	314	structure. For Unix systems, this is equivalent to the simple
	315	C<copy> routine. For VMS systems, this calls the C<rmscopy>
	316	routine (see below). For OS/2 systems, this calls the C<syscopy>
7509b657	317	XSUB directly. For Win32 systems, this calls C<Win32::CopyFile>.
9b957b78	318
7509b657	319	=head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)
9b957b78	320
71be2cbc	321	If both arguments to C<copy> are not file handles,
71be2cbc	322	then C<copy> will perform a "system copy" of
9b957b78	323	the input file to a new output file, in order to preserve file
9b957b78	324	attributes, indexed file structure, I<etc.> The buffer size
71be2cbc	325	parameter is ignored. If either argument to C<copy> is a
71be2cbc	326	handle to an opened file, then data is copied using Perl
9b957b78	327	operators, and no effort is made to preserve file attributes
	328	or record structure.
	329
55497cff	330	The system copy routine may also be called directly under VMS and OS/2
55497cff	331	as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
71be2cbc	332	is the routine that does the actual work for syscopy).
9b957b78	333
441496b2	334	=over 4
55497cff	335
9b957b78	336	=item rmscopy($from,$to[,$date_flag])
9b957b78	337
71be2cbc	338	The first and second arguments may be strings, typeglobs, typeglob
	339	references, or objects inheriting from IO::Handle;
	340	they are used in all cases to obtain the
9b957b78	341	I<filespec> of the input and output files, respectively. The
	342	name and type of the input file are used as defaults for the
	343	output file, if necessary.
	344
	345	A new version of the output file is always created, which
	346	inherits the structure and RMS attributes of the input file,
	347	except for owner and protections (and possibly timestamps;
	348	see below). All data from the input file is copied to the
	349	output file; if either of the first two parameters to C<rmscopy>
	350	is a file handle, its position is unchanged. (Note that this
	351	means a file handle pointing to the output file will be
	352	associated with an old version of that file after C<rmscopy>
	353	returns, not the newly created version.)
	354
	355	The third parameter is an integer flag, which tells C<rmscopy>
1fef88e7 JM	356	how to handle timestamps. If it is E<lt> 0, none of the input file's
1fef88e7 JM	357	timestamps are propagated to the output file. If it is E<gt> 0, then
9b957b78	358	it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
	359	timestamps other than the revision date are propagated; if bit 1
	360	is set, the revision date is propagated. If the third parameter
	361	to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
	362	if the name or type of the output file was explicitly specified,
	363	then no timestamps are propagated, but if they were taken implicitly
	364	from the input filespec, then all timestamps other than the
	365	revision date are propagated. If this parameter is not supplied,
	366	it defaults to 0.
	367
	368	Like C<copy>, C<rmscopy> returns 1 on success. If an error occurs,
	369	it sets C<$!>, deletes the output file, and returns 0.
	370
55497cff	371	=back
55497cff	372
f716a1dd	373	=head1 RETURN
f716a1dd	374
441496b2 CB	375	All functions return 1 on success, 0 on failure.
441496b2 CB	376	$! will be set if an error was encountered.
f716a1dd	377
6c254d95 CN	378	=head1 NOTES
	379
	380	=over 4
	381
	382	=item *
	383
	384	On Mac OS (Classic), the path separator is ':', not '/', and the
	385	current directory is denoted as ':', not '.'. You should be careful
	386	about specifying relative pathnames. While a full path always begins
	387	with a volume name, a relative pathname should always begin with a
	388	':'. If specifying a volume name only, a trailing ':' is required.
	389
	390	E.g.
	391
	392	copy("file1", "tmp"); # creates the file 'tmp' in the current directory
	393	copy("file1", ":tmp:"); # creates :tmp:file1
	394	copy("file1", ":tmp"); # same as above
	395	copy("file1", "tmp"); # same as above, if 'tmp' is a directory (but don't do
	396	# that, since it may cause confusion, see example #1)
	397	copy("file1", "tmp:file1"); # error, since 'tmp:' is not a volume
	398	copy("file1", ":tmp:file1"); # ok, partial path
	399	copy("file1", "DataHD:"); # creates DataHD:file1
	400
	401	move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one
	402	# volume to another
	403
	404	=back
	405
f716a1dd	406	=head1 AUTHOR
f716a1dd	407
441496b2	408	File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
bd3fa61c	409	and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
f716a1dd	410
f716a1dd	411	=cut
441496b2	412