[perl5.git] / lib / File / Copy.pm

# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
# source code has been placed in the public domain by the author.
# Please be kind and preserve the documentation.
#
# Additions copyright 1996 by Charles Bailey.  Permission is granted
# to distribute the revised code under the same terms as Perl itself.

package File::Copy;

use strict;
use Carp;
use vars qw(@ISA @EXPORT @EXPORT_OK $VERSION $Too_Big
	    &copy &syscopy &cp &mv);

# Note that this module implements only *part* of the API defined by
# the File/Copy.pm module of the File-Tools-2.0 package.  However, that
# package has not yet been updated to work with Perl 5.004, and so it
# would be a Bad Thing for the CPAN module to grab it and replace this
# module.  Therefore, we set this module's version higher than 2.0.
$VERSION = '2.02';

require Exporter;
@ISA = qw(Exporter);
@EXPORT = qw(copy move);
@EXPORT_OK = qw(cp mv);

$Too_Big = 1024 * 1024 * 2;

sub _catname { #  Will be replaced by File::Spec when it arrives
    my($from, $to) = @_;
    if (not defined &basename) {
	require File::Basename;
	import  File::Basename 'basename';
    }
    if ($^O eq 'VMS')  { $to = VMS::Filespec::vmspath($to) . basename($from); }
    elsif ($^O eq 'MacOS') { $to .= ':' . basename($from); }
    elsif ($to =~ m|\\|)   { $to .= '\\' . basename($from); }
    else                   { $to .= '/' . basename($from); }
}

sub copy {
    croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
      unless(@_ == 2 || @_ == 3);

    my $from = shift;
    my $to = shift;

    my $from_a_handle = (ref($from)
			 ? (ref($from) eq 'GLOB'
			    || UNIVERSAL::isa($from, 'GLOB')
                            || UNIVERSAL::isa($from, 'IO::Handle'))
			 : (ref(\$from) eq 'GLOB'));
    my $to_a_handle =   (ref($to)
			 ? (ref($to) eq 'GLOB'
			    || UNIVERSAL::isa($to, 'GLOB')
                            || UNIVERSAL::isa($to, 'IO::Handle'))
			 : (ref(\$to) eq 'GLOB'));

    if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    if (defined &syscopy && \&syscopy != \&copy
	&& !$to_a_handle
	&& !($from_a_handle && $^O eq 'os2' )	# OS/2 cannot handle handles
	&& !($from_a_handle && $^O eq 'mpeix')	# and neither can MPE/iX.
	&& !($from_a_handle && $^O eq 'MSWin32')
       )	
    {
	return syscopy($from, $to);
    }

    my $closefrom = 0;
    my $closeto = 0;
    my ($size, $status, $r, $buf);
    local(*FROM, *TO);
    local($\) = '';

    if ($from_a_handle) {
	*FROM = *$from{FILEHANDLE};
    } else {
	$from = "./$from" if $from =~ /^\s/;
	open(FROM, "< $from\0") or goto fail_open1;
	binmode FROM or die "($!,$^E)";
	$closefrom = 1;
    } 
 
    if ($to_a_handle) {
	*TO = *$to{FILEHANDLE};
    } else {        
	$to = "./$to" if $to =~ /^\s/;
	open(TO,"> $to\0") or goto fail_open2;
	binmode TO or die "($!,$^E)";
	$closeto = 1;
    }  

    if (@_) {
	$size = shift(@_) + 0;
	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
    } else {
	$size = -s FROM;
	$size = 1024 if ($size < 512);
	$size = $Too_Big if ($size > $Too_Big);
    }

    $! = 0;
    for (;;) {
	my ($r, $w, $t);
	defined($r = sysread(FROM, $buf, $size))
	    or goto fail_inner;
	last unless $r;
	for ($w = 0; $w < $r; $w += $t) {
	    $t = syswrite(TO, $buf, $r - $w, $w)
		or goto fail_inner;
	}
    }

    close(TO) || goto fail_open2 if $closeto;
    close(FROM) || goto fail_open1 if $closefrom;

    # Use this idiom to avoid uninitialized value warning.
    return 1;
    
    # All of these contortions try to preserve error messages...
  fail_inner:
    if ($closeto) {
	$status = $!;
	$! = 0;
	close TO;
	$! = $status unless $!;
    }
  fail_open2:
    if ($closefrom) {
	$status = $!;
	$! = 0;
	close FROM;
	$! = $status unless $!;
    }
  fail_open1:
    return 0;
}

sub move {
    my($from,$to) = @_;
    my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);

    if (-d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    ($tosz1,$tomt1) = (stat($to))[7,9];
    $fromsz = -s $from;
    if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
      # will not rename with overwrite
      unlink $to;
    }
    return 1 if rename $from, $to;

    ($sts,$ossts) = ($! + 0, $^E + 0);
    # Did rename return an error even though it succeeded, because $to
    # is on a remote NFS file system, and NFS lost the server's ack?
    return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
                (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
                ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
                $tosz2 == $fromsz;                         # it's all there
 
    ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
    return 1 if ($copied = copy($from,$to)) && unlink($from);
  
    ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
    unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
    ($!,$^E) = ($sts,$ossts);
    return 0;
}

*cp = \&copy;
*mv = \&move;

# &syscopy is an XSUB under OS/2
unless (defined &syscopy) {
    if ($^O eq 'VMS') {
	*syscopy = \&rmscopy;
    } elsif ($^O eq 'mpeix') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    # Use the MPE cp program in order to
	    # preserve MPE file attributes.
	    return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	};
    } elsif ($^O eq 'MSWin32') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    return Win32::CopyFile(@_, 1);
	};
    } else {
	*syscopy = \&copy;
    }
}

1;

__END__

=head1 NAME

File::Copy - Copy files or filehandles

=head1 SYNOPSIS

  	use File::Copy;

	copy("file1","file2");
  	copy("Copy.pm",\*STDOUT);'
	move("/dev1/fileA","/dev2/fileB");

  	use POSIX;
	use File::Copy cp;

	$n=FileHandle->new("/dev/null","r");
	cp($n,"x");'

=head1 DESCRIPTION

The File::Copy module provides two basic functions, C<copy> and
C<move>, which are useful for getting the contents of a file from
one place to another.

=over 4

=item *

The C<copy> function takes two
parameters: a file to copy from and a file to copy to. Either
argument may be a string, a FileHandle reference or a FileHandle
glob. Obviously, if the first argument is a filehandle of some
sort, it will be read from, and if it is a file I<name> it will
be opened for reading. Likewise, the second argument will be
written to (and created if need be).

B<Note that passing in
files as handles instead of names may lead to loss of information
on some operating systems; it is recommended that you use file
names whenever possible.>  Files are opened in binary mode where
applicable.  To get a consistent behaviour when copying from a
filehandle to a file, use C<binmode> on the filehandle.

An optional third parameter can be used to specify the buffer
size used for copying. This is the number of bytes from the
first file, that wil be held in memory at any given time, before
being written to the second file. The default buffer size depends
upon the file, but will generally be the whole file (up to 2Mb), or
1k for filehandles that do not reference files (eg. sockets).

You may use the syntax C<use File::Copy "cp"> to get at the
"cp" alias for this function. The syntax is I<exactly> the same.

=item *

The C<move> function also takes two parameters: the current name
and the intended name of the file to be moved.  If the destination
already exists and is a directory, and the source is not a
directory, then the source file will be renamed into the directory
specified by the destination.

If possible, move() will simply rename the file.  Otherwise, it copies
the file to the new location and deletes the original.  If an error occurs
during this copy-and-delete process, you may be left with a (possibly partial)
copy of the file under the destination name.

You may use the "mv" alias for this function in the same way that
you may use the "cp" alias for C<copy>.

=back

File::Copy also provides the C<syscopy> routine, which copies the
file specified in the first parameter to the file specified in the
second parameter, preserving OS-specific attributes and file
structure.  For Unix systems, this is equivalent to the simple
C<copy> routine.  For VMS systems, this calls the C<rmscopy>
routine (see below).  For OS/2 systems, this calls the C<syscopy>
XSUB directly. For Win32 systems, this calls C<Win32::CopyFile>.

=head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)

If both arguments to C<copy> are not file handles,
then C<copy> will perform a "system copy" of
the input file to a new output file, in order to preserve file
attributes, indexed file structure, I<etc.>  The buffer size
parameter is ignored.  If either argument to C<copy> is a
handle to an opened file, then data is copied using Perl
operators, and no effort is made to preserve file attributes
or record structure.

The system copy routine may also be called directly under VMS and OS/2
as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
is the routine that does the actual work for syscopy).

=over 4

=item rmscopy($from,$to[,$date_flag])

The first and second arguments may be strings, typeglobs, typeglob
references, or objects inheriting from IO::Handle;
they are used in all cases to obtain the
I<filespec> of the input and output files, respectively.  The
name and type of the input file are used as defaults for the
output file, if necessary.

A new version of the output file is always created, which
inherits the structure and RMS attributes of the input file,
except for owner and protections (and possibly timestamps;
see below).  All data from the input file is copied to the
output file; if either of the first two parameters to C<rmscopy>
is a file handle, its position is unchanged.  (Note that this
means a file handle pointing to the output file will be
associated with an old version of that file after C<rmscopy>
returns, not the newly created version.)

The third parameter is an integer flag, which tells C<rmscopy>
how to handle timestamps.  If it is E<lt> 0, none of the input file's
timestamps are propagated to the output file.  If it is E<gt> 0, then
it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
timestamps other than the revision date are propagated; if bit 1
is set, the revision date is propagated.  If the third parameter
to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
if the name or type of the output file was explicitly specified,
then no timestamps are propagated, but if they were taken implicitly
from the input filespec, then all timestamps other than the
revision date are propagated.  If this parameter is not supplied,
it defaults to 0.

Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
it sets C<$!>, deletes the output file, and returns 0.

=back

=head1 RETURN

All functions return 1 on success, 0 on failure.
$! will be set if an error was encountered.

=head1 AUTHOR

File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.

=cut
Commit	Line	Data
f716a1dd	1	# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
	2	# source code has been placed in the public domain by the author.
	3	# Please be kind and preserve the documentation.
	4	#
71be2cbc	5	# Additions copyright 1996 by Charles Bailey. Permission is granted
71be2cbc	6	# to distribute the revised code under the same terms as Perl itself.
f716a1dd	7
	8	package File::Copy;
	9
71be2cbc	10	use strict;
f716a1dd	11	use Carp;
71be2cbc	12	use vars qw(@ISA @EXPORT @EXPORT_OK $VERSION $Too_Big
	13	&copy &syscopy &cp &mv);
	14
	15	# Note that this module implements only part of the API defined by
	16	# the File/Copy.pm module of the File-Tools-2.0 package. However, that
	17	# package has not yet been updated to work with Perl 5.004, and so it
	18	# would be a Bad Thing for the CPAN module to grab it and replace this
	19	# module. Therefore, we set this module's version higher than 2.0.
e6434134	20	$VERSION = '2.02';
f716a1dd	21
71be2cbc	22	require Exporter;
	23	@ISA = qw(Exporter);
	24	@EXPORT = qw(copy move);
	25	@EXPORT_OK = qw(cp mv);
f716a1dd	26
441496b2	27	$Too_Big = 1024 * 1024 * 2;
f716a1dd	28
71be2cbc	29	sub _catname { # Will be replaced by File::Spec when it arrives
	30	my($from, $to) = @_;
	31	if (not defined &basename) {
	32	require File::Basename;
	33	import File::Basename 'basename';
	34	}
	35	if ($^O eq 'VMS') { $to = VMS::Filespec::vmspath($to) . basename($from); }
	36	elsif ($^O eq 'MacOS') { $to .= ':' . basename($from); }
	37	elsif ($to =~ m\|\\\|) { $to .= '\\' . basename($from); }
	38	else { $to .= '/' . basename($from); }
f716a1dd	39	}
	40
	41	sub copy {
71be2cbc	42	croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
f716a1dd	43	unless(@_ == 2 \|\| @_ == 3);
	44
	45	my $from = shift;
	46	my $to = shift;
71be2cbc	47
	48	my $from_a_handle = (ref($from)
	49	? (ref($from) eq 'GLOB'
d704f39a MG	50	\|\| UNIVERSAL::isa($from, 'GLOB')
d704f39a MG	51	\|\| UNIVERSAL::isa($from, 'IO::Handle'))
71be2cbc	52	: (ref(\$from) eq 'GLOB'));
	53	my $to_a_handle = (ref($to)
	54	? (ref($to) eq 'GLOB'
d704f39a MG	55	\|\| UNIVERSAL::isa($to, 'GLOB')
d704f39a MG	56	\|\| UNIVERSAL::isa($to, 'IO::Handle'))
71be2cbc	57	: (ref(\$to) eq 'GLOB'));
	58
	59	if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	60	$to = _catname($from, $to);
	61	}
	62
	63	if (defined &syscopy && \&syscopy != \&copy
e6434134	64	&& !$to_a_handle
1d84e8df JH	65	&& !($from_a_handle && $^O eq 'os2' ) # OS/2 cannot handle handles
1d84e8df JH	66	&& !($from_a_handle && $^O eq 'mpeix') # and neither can MPE/iX.
7509b657	67	&& !($from_a_handle && $^O eq 'MSWin32')
1d84e8df	68	)
71be2cbc	69	{
	70	return syscopy($from, $to);
	71	}
	72
	73	my $closefrom = 0;
	74	my $closeto = 0;
f716a1dd	75	my ($size, $status, $r, $buf);
f716a1dd	76	local(FROM, TO);
48a5c399	77	local($\) = '';
f716a1dd	78
71be2cbc	79	if ($from_a_handle) {
71be2cbc	80	FROM = $from{FILEHANDLE};
f716a1dd	81	} else {
71be2cbc	82	$from = "./$from" if $from =~ /^\s/;
	83	open(FROM, "< $from\0") or goto fail_open1;
	84	binmode FROM or die "($!,$^E)";
f716a1dd	85	$closefrom = 1;
71be2cbc	86	}
	87
	88	if ($to_a_handle) {
	89	TO = $to{FILEHANDLE};
	90	} else {
	91	$to = "./$to" if $to =~ /^\s/;
	92	open(TO,"> $to\0") or goto fail_open2;
	93	binmode TO or die "($!,$^E)";
	94	$closeto = 1;
	95	}
f716a1dd	96
	97	if (@_) {
	98	$size = shift(@_) + 0;
	99	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
	100	} else {
	101	$size = -s FROM;
	102	$size = 1024 if ($size < 512);
441496b2	103	$size = $Too_Big if ($size > $Too_Big);
f716a1dd	104	}
f716a1dd	105
71be2cbc	106	$! = 0;
	107	for (;;) {
	108	my ($r, $w, $t);
	109	defined($r = sysread(FROM, $buf, $size))
	110	or goto fail_inner;
	111	last unless $r;
	112	for ($w = 0; $w < $r; $w += $t) {
	113	$t = syswrite(TO, $buf, $r - $w, $w)
	114	or goto fail_inner;
f716a1dd	115	}
f716a1dd	116	}
71be2cbc	117
f716a1dd	118	close(TO) \|\| goto fail_open2 if $closeto;
f716a1dd	119	close(FROM) \|\| goto fail_open1 if $closefrom;
71be2cbc	120
48a5c399	121	# Use this idiom to avoid uninitialized value warning.
f716a1dd	122	return 1;
	123
	124	# All of these contortions try to preserve error messages...
	125	fail_inner:
	126	if ($closeto) {
	127	$status = $!;
	128	$! = 0;
	129	close TO;
	130	$! = $status unless $!;
	131	}
	132	fail_open2:
	133	if ($closefrom) {
	134	$status = $!;
	135	$! = 0;
	136	close FROM;
	137	$! = $status unless $!;
	138	}
	139	fail_open1:
f716a1dd	140	return 0;
f716a1dd	141	}
9b957b78	142
441496b2	143	sub move {
71be2cbc	144	my($from,$to) = @_;
71be2cbc	145	my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
441496b2	146
71be2cbc	147	if (-d $to && ! -d $from) {
	148	$to = _catname($from, $to);
	149	}
	150
	151	($tosz1,$tomt1) = (stat($to))[7,9];
	152	$fromsz = -s $from;
e6434134 IZ	153	if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
	154	# will not rename with overwrite
	155	unlink $to;
	156	}
71be2cbc	157	return 1 if rename $from, $to;
	158
	159	($sts,$ossts) = ($! + 0, $^E + 0);
	160	# Did rename return an error even though it succeeded, because $to
	161	# is on a remote NFS file system, and NFS lost the server's ack?
	162	return 1 if defined($fromsz) && !-e $from && # $from disappeared
	163	(($tosz2,$tomt2) = (stat($to))[7,9]) && # $to's there
	164	($tosz1 != $tosz2 or $tomt1 != $tomt2) && # and changed
	165	$tosz2 == $fromsz; # it's all there
441496b2	166
71be2cbc	167	($tosz1,$tomt1) = (stat($to))[7,9]; # just in case rename did something
71be2cbc	168	return 1 if ($copied = copy($from,$to)) && unlink($from);
441496b2	169
71be2cbc	170	($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
	171	unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
	172	($!,$^E) = ($sts,$ossts);
	173	return 0;
441496b2	174	}
9b957b78	175
71be2cbc	176	*cp = \©
	177	*mv = \&move;
	178
9b957b78	179	# &syscopy is an XSUB under OS/2
1d84e8df JH	180	unless (defined &syscopy) {
	181	if ($^O eq 'VMS') {
	182	*syscopy = \&rmscopy;
	183	} elsif ($^O eq 'mpeix') {
	184	*syscopy = sub {
3f5ee302	185	return 0 unless @_ == 2;
1d84e8df JH	186	# Use the MPE cp program in order to
	187	# preserve MPE file attributes.
	188	return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	189	};
7509b657 GS	190	} elsif ($^O eq 'MSWin32') {
	191	*syscopy = sub {
	192	return 0 unless @_ == 2;
	193	return Win32::CopyFile(@_, 1);
	194	};
1d84e8df JH	195	} else {
	196	*syscopy = \©
	197	}
	198	}
f716a1dd	199
	200	1;
	201
	202	__END__
a5f75d66	203
f716a1dd	204	=head1 NAME
	205
	206	File::Copy - Copy files or filehandles
	207
a5f75d66	208	=head1 SYNOPSIS
f716a1dd	209
	210	use File::Copy;
	211
	212	copy("file1","file2");
	213	copy("Copy.pm",\*STDOUT);'
441496b2	214	move("/dev1/fileA","/dev2/fileB");
f716a1dd	215
	216	use POSIX;
	217	use File::Copy cp;
	218
	219	$n=FileHandle->new("/dev/null","r");
	220	cp($n,"x");'
	221
	222	=head1 DESCRIPTION
	223
441496b2 CB	224	The File::Copy module provides two basic functions, C<copy> and
	225	C<move>, which are useful for getting the contents of a file from
	226	one place to another.
	227
	228	=over 4
	229
	230	=item *
	231
	232	The C<copy> function takes two
f716a1dd	233	parameters: a file to copy from and a file to copy to. Either
	234	argument may be a string, a FileHandle reference or a FileHandle
	235	glob. Obviously, if the first argument is a filehandle of some
	236	sort, it will be read from, and if it is a file I<name> it will
	237	be opened for reading. Likewise, the second argument will be
e6434134	238	written to (and created if need be).
71be2cbc	239
71be2cbc	240	B<Note that passing in
9b957b78	241	files as handles instead of names may lead to loss of information
9b957b78	242	on some operating systems; it is recommended that you use file
e6434134	243	names whenever possible.> Files are opened in binary mode where
8dcee03e	244	applicable. To get a consistent behaviour when copying from a
e6434134	245	filehandle to a file, use C<binmode> on the filehandle.
f716a1dd	246
	247	An optional third parameter can be used to specify the buffer
	248	size used for copying. This is the number of bytes from the
	249	first file, that wil be held in memory at any given time, before
	250	being written to the second file. The default buffer size depends
	251	upon the file, but will generally be the whole file (up to 2Mb), or
	252	1k for filehandles that do not reference files (eg. sockets).
	253
	254	You may use the syntax C<use File::Copy "cp"> to get at the
	255	"cp" alias for this function. The syntax is I<exactly> the same.
	256
441496b2 CB	257	=item *
	258
	259	The C<move> function also takes two parameters: the current name
71be2cbc	260	and the intended name of the file to be moved. If the destination
	261	already exists and is a directory, and the source is not a
	262	directory, then the source file will be renamed into the directory
	263	specified by the destination.
	264
	265	If possible, move() will simply rename the file. Otherwise, it copies
	266	the file to the new location and deletes the original. If an error occurs
	267	during this copy-and-delete process, you may be left with a (possibly partial)
441496b2 CB	268	copy of the file under the destination name.
	269
	270	You may use the "mv" alias for this function in the same way that
	271	you may use the "cp" alias for C<copy>.
	272
	273	=back
	274
9b957b78	275	File::Copy also provides the C<syscopy> routine, which copies the
	276	file specified in the first parameter to the file specified in the
	277	second parameter, preserving OS-specific attributes and file
	278	structure. For Unix systems, this is equivalent to the simple
	279	C<copy> routine. For VMS systems, this calls the C<rmscopy>
	280	routine (see below). For OS/2 systems, this calls the C<syscopy>
7509b657	281	XSUB directly. For Win32 systems, this calls C<Win32::CopyFile>.
9b957b78	282
7509b657	283	=head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)
9b957b78	284
71be2cbc	285	If both arguments to C<copy> are not file handles,
71be2cbc	286	then C<copy> will perform a "system copy" of
9b957b78	287	the input file to a new output file, in order to preserve file
9b957b78	288	attributes, indexed file structure, I<etc.> The buffer size
71be2cbc	289	parameter is ignored. If either argument to C<copy> is a
71be2cbc	290	handle to an opened file, then data is copied using Perl
9b957b78	291	operators, and no effort is made to preserve file attributes
	292	or record structure.
	293
55497cff	294	The system copy routine may also be called directly under VMS and OS/2
55497cff	295	as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
71be2cbc	296	is the routine that does the actual work for syscopy).
9b957b78	297
441496b2	298	=over 4
55497cff	299
9b957b78	300	=item rmscopy($from,$to[,$date_flag])
9b957b78	301
71be2cbc	302	The first and second arguments may be strings, typeglobs, typeglob
	303	references, or objects inheriting from IO::Handle;
	304	they are used in all cases to obtain the
9b957b78	305	I<filespec> of the input and output files, respectively. The
	306	name and type of the input file are used as defaults for the
	307	output file, if necessary.
	308
	309	A new version of the output file is always created, which
	310	inherits the structure and RMS attributes of the input file,
	311	except for owner and protections (and possibly timestamps;
	312	see below). All data from the input file is copied to the
	313	output file; if either of the first two parameters to C<rmscopy>
	314	is a file handle, its position is unchanged. (Note that this
	315	means a file handle pointing to the output file will be
	316	associated with an old version of that file after C<rmscopy>
	317	returns, not the newly created version.)
	318
	319	The third parameter is an integer flag, which tells C<rmscopy>
1fef88e7 JM	320	how to handle timestamps. If it is E<lt> 0, none of the input file's
1fef88e7 JM	321	timestamps are propagated to the output file. If it is E<gt> 0, then
9b957b78	322	it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
	323	timestamps other than the revision date are propagated; if bit 1
	324	is set, the revision date is propagated. If the third parameter
	325	to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
	326	if the name or type of the output file was explicitly specified,
	327	then no timestamps are propagated, but if they were taken implicitly
	328	from the input filespec, then all timestamps other than the
	329	revision date are propagated. If this parameter is not supplied,
	330	it defaults to 0.
	331
	332	Like C<copy>, C<rmscopy> returns 1 on success. If an error occurs,
	333	it sets C<$!>, deletes the output file, and returns 0.
	334
55497cff	335	=back
55497cff	336
f716a1dd	337	=head1 RETURN
f716a1dd	338
441496b2 CB	339	All functions return 1 on success, 0 on failure.
441496b2 CB	340	$! will be set if an error was encountered.
f716a1dd	341
	342	=head1 AUTHOR
	343
441496b2	344	File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
bd3fa61c	345	and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
f716a1dd	346
f716a1dd	347	=cut
441496b2	348