[perl5.git] / perly.y

/*    perly.y
 *
 *    Copyright (c) 1991-1997, Larry Wall
 *
 *    You may distribute under the terms of either the GNU General Public
 *    License or the Artistic License, as specified in the README file.
 *
 */

/*
 * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
 * All that is gold does not glitter, not all those who wander are lost.'
 */

%{
#include "EXTERN.h"
#include "perl.h"

static void
dep(void)
{
    deprecate("\"do\" to call subroutines");
}

%}

%start prog

%{
/* I sense a Big Blue pattern here... */
#if !defined(OEMVS) && !defined(__OPEN_VM) && !defined(POSIX_BC)
%}

%union {
    I32	ival;
    char *pval;
    OP *opval;
    GV *gvval;
}

%{
#endif /* !OEMVS && !__OPEN_VM && !POSIX_BC */

#ifdef USE_PURE_BISON
#define YYLEX_PARAM (&yychar)
#endif
%}

%token <ival> '{' ')'

%token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
%token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
%token <pval> LABEL
%token <ival> FORMAT SUB ANONSUB PACKAGE USE
%token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
%token <ival> LOOPEX DOTDOT
%token <ival> FUNC0 FUNC1 FUNC UNIOP LSTOP
%token <ival> RELOP EQOP MULOP ADDOP
%token <ival> DOLSHARP DO HASHBRACK NOAMP
%token LOCAL MY

%type <ival> prog decl local format startsub startanonsub startformsub
%type <ival> remember mremember '&'
%type <opval> block mblock lineseq line loop cond else
%type <opval> expr term scalar ary hsh arylen star amper sideff
%type <opval> argexpr nexpr texpr iexpr mexpr mnexpr mtexpr miexpr
%type <opval> listexpr listexprcom indirob listop method
%type <opval> formname subname proto subbody cont my_scalar
%type <pval> label

%left <ival> OROP
%left ANDOP
%right NOTOP
%nonassoc LSTOP LSTOPSUB
%left ','
%right <ival> ASSIGNOP
%right '?' ':'
%nonassoc DOTDOT
%left OROR
%left ANDAND
%left <ival> BITOROP
%left <ival> BITANDOP
%nonassoc EQOP
%nonassoc RELOP
%nonassoc UNIOP UNIOPSUB
%left <ival> SHIFTOP
%left ADDOP
%left MULOP
%left <ival> MATCHOP
%right '!' '~' UMINUS REFGEN
%right <ival> POWOP
%nonassoc PREINC PREDEC POSTINC POSTDEC
%left ARROW
%left '('

%% /* RULES */

prog	:	/* NULL */
		{
#if defined(YYDEBUG) && defined(DEBUGGING)
		    yydebug = (PL_debug & 1);
#endif
		    PL_expect = XSTATE;
		}
	/*CONTINUED*/	lineseq
			{ newPROG($2); }
	;

block	:	'{' remember lineseq '}'
			{ if (PL_copline > (line_t)$1)
			      PL_copline = $1;
			  $$ = block_end($2, $3); }
	;

remember:	/* NULL */	/* start a full lexical scope */
			{ $$ = block_start(TRUE); }
	;

mblock	:	'{' mremember lineseq '}'
			{ if (PL_copline > (line_t)$1)
			      PL_copline = $1;
			  $$ = block_end($2, $3); }
	;

mremember:	/* NULL */	/* start a partial lexical scope */
			{ $$ = block_start(FALSE); }
	;

lineseq	:	/* NULL */
			{ $$ = Nullop; }
	|	lineseq decl
			{ $$ = $1; }
	|	lineseq line
			{   $$ = append_list(OP_LINESEQ,
				(LISTOP*)$1, (LISTOP*)$2);
			    PL_pad_reset_pending = TRUE;
			    if ($1 && $2) PL_hints |= HINT_BLOCK_SCOPE; }
	;

line	:	label cond
			{ $$ = newSTATEOP(0, $1, $2); }
	|	loop	/* loops add their own labels */
	|	label ';'
			{ if ($1 != Nullch) {
			      $$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
			    }
			    else {
			      $$ = Nullop;
			      PL_copline = NOLINE;
			    }
			    PL_expect = XSTATE; }
	|	label sideff ';'
			{ $$ = newSTATEOP(0, $1, $2);
			  PL_expect = XSTATE; }
	;

sideff	:	error
			{ $$ = Nullop; }
	|	expr
			{ $$ = $1; }
	|	expr IF expr
			{ $$ = newLOGOP(OP_AND, 0, $3, $1); }
	|	expr UNLESS expr
			{ $$ = newLOGOP(OP_OR, 0, $3, $1); }
	|	expr WHILE expr
			{ $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
	|	expr UNTIL iexpr
			{ $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);}
	|	expr FOR expr
			{ $$ = newFOROP(0, Nullch, $2,
					Nullop, $3, $1, Nullop); }
	;

else	:	/* NULL */
			{ $$ = Nullop; }
	|	ELSE mblock
			{ $$ = scope($2); }
	|	ELSIF '(' mexpr ')' mblock else
			{ PL_copline = $1;
			    $$ = newSTATEOP(0, Nullch,
				   newCONDOP(0, $3, scope($5), $6));
			    PL_hints |= HINT_BLOCK_SCOPE; }
	;

cond	:	IF '(' remember mexpr ')' mblock else
			{ PL_copline = $1;
			    $$ = block_end($3,
				   newCONDOP(0, $4, scope($6), $7)); }
	|	UNLESS '(' remember miexpr ')' mblock else
			{ PL_copline = $1;
			    $$ = block_end($3,
				   newCONDOP(0, $4, scope($6), $7)); }
	;

cont	:	/* NULL */
			{ $$ = Nullop; }
	|	CONTINUE block
			{ $$ = scope($2); }
	;

loop	:	label WHILE '(' remember mtexpr ')' mblock cont
			{ PL_copline = $2;
			    $$ = block_end($4,
				   newSTATEOP(0, $1,
				     newWHILEOP(0, 1, (LOOP*)Nullop,
						$2, $5, $7, $8))); }
	|	label UNTIL '(' remember miexpr ')' mblock cont
			{ PL_copline = $2;
			    $$ = block_end($4,
				   newSTATEOP(0, $1,
				     newWHILEOP(0, 1, (LOOP*)Nullop,
						$2, $5, $7, $8))); }
	|	label FOR MY remember my_scalar '(' mexpr ')' mblock cont
			{ $$ = block_end($4,
				 newFOROP(0, $1, $2, $5, $7, $9, $10)); }
	|	label FOR scalar '(' remember mexpr ')' mblock cont
			{ $$ = block_end($5,
				 newFOROP(0, $1, $2, mod($3, OP_ENTERLOOP),
					  $6, $8, $9)); }
	|	label FOR '(' remember mexpr ')' mblock cont
			{ $$ = block_end($4,
				 newFOROP(0, $1, $2, Nullop, $5, $7, $8)); }
	|	label FOR '(' remember mnexpr ';' mtexpr ';' mnexpr ')' mblock
			/* basically fake up an initialize-while lineseq */
			{ OP *forop = append_elem(OP_LINESEQ,
					scalar($5),
					newWHILEOP(0, 1, (LOOP*)Nullop,
						   $2, scalar($7),
						   $11, scalar($9)));
			  PL_copline = $2;
			  $$ = block_end($4, newSTATEOP(0, $1, forop)); }
	|	label block cont  /* a block is a loop that happens once */
			{ $$ = newSTATEOP(0, $1,
				 newWHILEOP(0, 1, (LOOP*)Nullop,
					    NOLINE, Nullop, $2, $3)); }
	;

nexpr	:	/* NULL */
			{ $$ = Nullop; }
	|	sideff
	;

texpr	:	/* NULL means true */
			{ (void)scan_num("1"); $$ = yylval.opval; }
	|	expr
	;

iexpr	:	expr
			{ $$ = invert(scalar($1)); }
	;

mexpr	:	expr
			{ $$ = $1; intro_my(); }
	;

mnexpr	:	nexpr
			{ $$ = $1; intro_my(); }
	;

mtexpr	:	texpr
			{ $$ = $1; intro_my(); }
	;

miexpr	:	iexpr
			{ $$ = $1; intro_my(); }
	;

label	:	/* empty */
			{ $$ = Nullch; }
	|	LABEL
	;

decl	:	format
			{ $$ = 0; }
	|	subrout
			{ $$ = 0; }
	|	package
			{ $$ = 0; }
	|	use
			{ $$ = 0; }
	;

format	:	FORMAT startformsub formname block
			{ newFORM($2, $3, $4); }
	;

formname:	WORD		{ $$ = $1; }
	|	/* NULL */	{ $$ = Nullop; }
	;

subrout	:	SUB startsub subname proto subbody
			{ newSUB($2, $3, $4, $5); }
	;

startsub:	/* NULL */	/* start a regular subroutine scope */
			{ $$ = start_subparse(FALSE, 0); }
	;

startanonsub:	/* NULL */	/* start an anonymous subroutine scope */
			{ $$ = start_subparse(FALSE, CVf_ANON); }
	;

startformsub:	/* NULL */	/* start a format subroutine scope */
			{ $$ = start_subparse(TRUE, 0); }
	;

subname	:	WORD	{ STRLEN n_a; char *name = SvPV(((SVOP*)$1)->op_sv,n_a);
			  if (strEQ(name, "BEGIN") || strEQ(name, "END")
			      || strEQ(name, "INIT"))
			      CvSPECIAL_on(PL_compcv);
			  $$ = $1; }
	;

proto	:	/* NULL */
			{ $$ = Nullop; }
	|	THING
	;

subbody	:	block	{ $$ = $1; }
	|	';'	{ $$ = Nullop; PL_expect = XSTATE; }
	;

package :	PACKAGE WORD ';'
			{ package($2); }
	|	PACKAGE ';'
			{ package(Nullop); }
	;

use	:	USE startsub
			{ CvSPECIAL_on(PL_compcv); /* It's a BEGIN {} */ }
		    WORD WORD listexpr ';'
			{ utilize($1, $2, $4, $5, $6); }
	;

expr	:	expr ANDOP expr
			{ $$ = newLOGOP(OP_AND, 0, $1, $3); }
	|	expr OROP expr
			{ $$ = newLOGOP($2, 0, $1, $3); }
	|	argexpr
	;

argexpr	:	argexpr ','
			{ $$ = $1; }
	|	argexpr ',' term
			{ $$ = append_elem(OP_LIST, $1, $3); }
	|	term
	;

listop	:	LSTOP indirob argexpr
			{ $$ = convert($1, OPf_STACKED,
				prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
	|	FUNC '(' indirob expr ')'
			{ $$ = convert($1, OPf_STACKED,
				prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
	|	term ARROW method '(' listexprcom ')'
			{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
				append_elem(OP_LIST,
				    prepend_elem(OP_LIST, scalar($1), $5),
				    newUNOP(OP_METHOD, 0, $3))); }
	|	term ARROW method
			{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
				append_elem(OP_LIST, scalar($1),
				    newUNOP(OP_METHOD, 0, $3))); }
	|	METHOD indirob listexpr
			{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
				append_elem(OP_LIST,
				    prepend_elem(OP_LIST, $2, $3),
				    newUNOP(OP_METHOD, 0, $1))); }
	|	FUNCMETH indirob '(' listexprcom ')'
			{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
				append_elem(OP_LIST,
				    prepend_elem(OP_LIST, $2, $4),
				    newUNOP(OP_METHOD, 0, $1))); }
	|	LSTOP listexpr
			{ $$ = convert($1, 0, $2); }
	|	FUNC '(' listexprcom ')'
			{ $$ = convert($1, 0, $3); }
	|	LSTOPSUB startanonsub block
			{ $3 = newANONSUB($2, 0, $3); }
		    listexpr		%prec LSTOP
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
				 append_elem(OP_LIST,
				   prepend_elem(OP_LIST, $3, $5), $1)); }
	;

method	:	METHOD
	|	scalar
	;

term	:	term ASSIGNOP term
			{ $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
	|	term POWOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term MULOP term
			{   if ($2 != OP_REPEAT)
				scalar($1);
			    $$ = newBINOP($2, 0, $1, scalar($3)); }
	|	term ADDOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term SHIFTOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term RELOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term EQOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term BITANDOP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term BITOROP term
			{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
	|	term DOTDOT term
			{ $$ = newRANGE($2, scalar($1), scalar($3));}
	|	term ANDAND term
			{ $$ = newLOGOP(OP_AND, 0, $1, $3); }
	|	term OROR term
			{ $$ = newLOGOP(OP_OR, 0, $1, $3); }
	|	term '?' term ':' term
			{ $$ = newCONDOP(0, $1, $3, $5); }
	|	term MATCHOP term
			{ $$ = bind_match($2, $1, $3); }

	|	'-' term %prec UMINUS
			{ $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
	|	'+' term %prec UMINUS
			{ $$ = $2; }
	|	'!' term
			{ $$ = newUNOP(OP_NOT, 0, scalar($2)); }
	|	'~' term
			{ $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
	|	REFGEN term
			{ $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
	|	term POSTINC
			{ $$ = newUNOP(OP_POSTINC, 0,
					mod(scalar($1), OP_POSTINC)); }
	|	term POSTDEC
			{ $$ = newUNOP(OP_POSTDEC, 0,
					mod(scalar($1), OP_POSTDEC)); }
	|	PREINC term
			{ $$ = newUNOP(OP_PREINC, 0,
					mod(scalar($2), OP_PREINC)); }
	|	PREDEC term
			{ $$ = newUNOP(OP_PREDEC, 0,
					mod(scalar($2), OP_PREDEC)); }
	|	local term	%prec UNIOP
			{ $$ = localize($2,$1); }
	|	'(' expr ')'
			{ $$ = sawparens($2); }
	|	'(' ')'
			{ $$ = sawparens(newNULLLIST()); }
	|	'[' expr ']'				%prec '('
			{ $$ = newANONLIST($2); }
	|	'[' ']'					%prec '('
			{ $$ = newANONLIST(Nullop); }
	|	HASHBRACK expr ';' '}'			%prec '('
			{ $$ = newANONHASH($2); }
	|	HASHBRACK ';' '}'				%prec '('
			{ $$ = newANONHASH(Nullop); }
	|	ANONSUB startanonsub proto block		%prec '('
			{ $$ = newANONSUB($2, $3, $4); }
	|	scalar	%prec '('
			{ $$ = $1; }
	|	star '{' expr ';' '}'
			{ $$ = newBINOP(OP_GELEM, 0, $1, scalar($3)); }
	|	star	%prec '('
			{ $$ = $1; }
	|	scalar '[' expr ']'	%prec '('
			{ $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
	|	term ARROW '[' expr ']'	%prec '('
			{ $$ = newBINOP(OP_AELEM, 0,
					ref(newAVREF($1),OP_RV2AV),
					scalar($4));}
	|	term '[' expr ']'	%prec '('
			{ assertref($1); $$ = newBINOP(OP_AELEM, 0,
					ref(newAVREF($1),OP_RV2AV),
					scalar($3));}
	|	hsh 	%prec '('
			{ $$ = $1; }
	|	ary 	%prec '('
			{ $$ = $1; }
	|	arylen 	%prec '('
			{ $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
	|	scalar '{' expr ';' '}'	%prec '('
			{ $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
			    PL_expect = XOPERATOR; }
	|	term ARROW '{' expr ';' '}'	%prec '('
			{ $$ = newBINOP(OP_HELEM, 0,
					ref(newHVREF($1),OP_RV2HV),
					jmaybe($4));
			    PL_expect = XOPERATOR; }
	|	term '{' expr ';' '}'	%prec '('
			{ assertref($1); $$ = newBINOP(OP_HELEM, 0,
					ref(newHVREF($1),OP_RV2HV),
					jmaybe($3));
			    PL_expect = XOPERATOR; }
	|	'(' expr ')' '[' expr ']'	%prec '('
			{ $$ = newSLICEOP(0, $5, $2); }
	|	'(' ')' '[' expr ']'	%prec '('
			{ $$ = newSLICEOP(0, $4, Nullop); }
	|	ary '[' expr ']'	%prec '('
			{ $$ = prepend_elem(OP_ASLICE,
				newOP(OP_PUSHMARK, 0),
				    newLISTOP(OP_ASLICE, 0,
					list($3),
					ref($1, OP_ASLICE))); }
	|	ary '{' expr ';' '}'	%prec '('
			{ $$ = prepend_elem(OP_HSLICE,
				newOP(OP_PUSHMARK, 0),
				    newLISTOP(OP_HSLICE, 0,
					list($3),
					ref(oopsHV($1), OP_HSLICE)));
			    PL_expect = XOPERATOR; }
	|	THING	%prec '('
			{ $$ = $1; }
	|	amper
			{ $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
	|	amper '(' ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
	|	amper '(' expr ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
			    append_elem(OP_LIST, $3, scalar($1))); }
	|	NOAMP WORD listexpr
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
			    append_elem(OP_LIST, $3, scalar($2))); }
	|	DO term	%prec UNIOP
			{ $$ = dofile($2); }
	|	DO block	%prec '('
			{ $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
	|	DO WORD '(' ')'
			{ $$ = newUNOP(OP_ENTERSUB,
			    OPf_SPECIAL|OPf_STACKED,
			    prepend_elem(OP_LIST,
				scalar(newCVREF(
				    (OPpENTERSUB_AMPER<<8),
				    scalar($2)
				)),Nullop)); dep();}
	|	DO WORD '(' expr ')'
			{ $$ = newUNOP(OP_ENTERSUB,
			    OPf_SPECIAL|OPf_STACKED,
			    append_elem(OP_LIST,
				$4,
				scalar(newCVREF(
				    (OPpENTERSUB_AMPER<<8),
				    scalar($2)
				)))); dep();}
	|	DO scalar '(' ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
			    prepend_elem(OP_LIST,
				scalar(newCVREF(0,scalar($2))), Nullop)); dep();}
	|	DO scalar '(' expr ')'
			{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
			    prepend_elem(OP_LIST,
				$4,
				scalar(newCVREF(0,scalar($2))))); dep();}
	|	term ARROW '(' ')'	%prec '('
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
				   newCVREF(0, scalar($1))); }
	|	term ARROW '(' expr ')'	%prec '('
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
				   append_elem(OP_LIST, $4,
				       newCVREF(0, scalar($1)))); }
	|	LOOPEX
			{ $$ = newOP($1, OPf_SPECIAL);
			    PL_hints |= HINT_BLOCK_SCOPE; }
	|	LOOPEX term
			{ $$ = newLOOPEX($1,$2); }
	|	NOTOP argexpr
			{ $$ = newUNOP(OP_NOT, 0, scalar($2)); }
	|	UNIOP
			{ $$ = newOP($1, 0); }
	|	UNIOP block
			{ $$ = newUNOP($1, 0, $2); }
	|	UNIOP term
			{ $$ = newUNOP($1, 0, $2); }
	|	UNIOPSUB term
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
			    append_elem(OP_LIST, $2, scalar($1))); }
	|	FUNC0
			{ $$ = newOP($1, 0); }
	|	FUNC0 '(' ')'
			{ $$ = newOP($1, 0); }
	|	FUNC0SUB
			{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
				scalar($1)); }
	|	FUNC1 '(' ')'
			{ $$ = newOP($1, OPf_SPECIAL); }
	|	FUNC1 '(' expr ')'
			{ $$ = newUNOP($1, 0, $3); }
	|	PMFUNC '(' term ')'
			{ $$ = pmruntime($1, $3, Nullop); }
	|	PMFUNC '(' term ',' term ')'
			{ $$ = pmruntime($1, $3, $5); }
	|	WORD
	|	listop
	;

listexpr:	/* NULL */
			{ $$ = Nullop; }
	|	argexpr
			{ $$ = $1; }
	;

listexprcom:	/* NULL */
			{ $$ = Nullop; }
	|	expr
			{ $$ = $1; }
	|	expr ','
			{ $$ = $1; }
	;

local	:	LOCAL	{ $$ = 0; }
	|	MY	{ $$ = 1; }
	;

my_scalar:	scalar
			{ PL_in_my = 0; $$ = my($1); }
	;

amper	:	'&' indirob
			{ $$ = newCVREF($1,$2); }
	;

scalar	:	'$' indirob
			{ $$ = newSVREF($2); }
	;

ary	:	'@' indirob
			{ $$ = newAVREF($2); }
	;

hsh	:	'%' indirob
			{ $$ = newHVREF($2); }
	;

arylen	:	DOLSHARP indirob
			{ $$ = newAVREF($2); }
	;

star	:	'*' indirob
			{ $$ = newGVREF(0,$2); }
	;

indirob	:	WORD
			{ $$ = scalar($1); }
	|	scalar
			{ $$ = scalar($1);  }
	|	block
			{ $$ = scope($1); }

	|	PRIVATEREF
			{ $$ = $1; }
	;

%% /* PROGRAM */
Commit	Line	Data
a0d0e21e	1	/* perly.y
a687059c	2	*
9607fc9c	3	* Copyright (c) 1991-1997, Larry Wall
a687059c	4	*
9ef589d8 LW	5	* You may distribute under the terms of either the GNU General Public
9ef589d8 LW	6	* License or the Artistic License, as specified in the README file.
8d063cd8	7	*
a0d0e21e LW	8	*/
	9
	10	/*
	11	* 'I see,' laughed Strider. 'I look foul and feel fair. Is that it?
14a38fd5	12	* All that is gold does not glitter, not all those who wander are lost.'
8d063cd8 LW	13	*/
	14
	15	%{
79072805	16	#include "EXTERN.h"
8d063cd8	17	#include "perl.h"
378cc40b	18
a0d0e21e	19	static void
8ac85365	20	dep(void)
a0d0e21e LW	21	{
	22	deprecate("\"do\" to call subroutines");
	23	}
f0fcb552	24
8d063cd8 LW	25	%}
	26
	27	%start prog
	28
9d116dd7	29	%{
a1a0e61e TD	30	/* I sense a Big Blue pattern here... */
a1a0e61e TD	31	#if !defined(OEMVS) && !defined(__OPEN_VM) && !defined(POSIX_BC)
9d116dd7 JH	32	%}
9d116dd7 JH	33
8d063cd8	34	%union {
79072805 LW	35	I32 ival;
	36	char *pval;
	37	OP *opval;
	38	GV *gvval;
8d063cd8 LW	39	}
8d063cd8 LW	40
9d116dd7	41	%{
a1a0e61e TD	42	#endif /* !OEMVS && !__OPEN_VM && !POSIX_BC */
	43
	44	#ifdef USE_PURE_BISON
	45	#define YYLEX_PARAM (&yychar)
	46	#endif
9d116dd7 JH	47	%}
9d116dd7 JH	48
f0fcb552 LW	49	%token <ival> '{' ')'
f0fcb552 LW	50
a0d0e21e	51	%token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
4633a7c4	52	%token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
79072805	53	%token <pval> LABEL
a0d0e21e	54	%token <ival> FORMAT SUB ANONSUB PACKAGE USE
79072805 LW	55	%token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
79072805 LW	56	%token <ival> LOOPEX DOTDOT
36477c24	57	%token <ival> FUNC0 FUNC1 FUNC UNIOP LSTOP
79072805	58	%token <ival> RELOP EQOP MULOP ADDOP
55497cff	59	%token <ival> DOLSHARP DO HASHBRACK NOAMP
55497cff	60	%token LOCAL MY
79072805	61
44a8e56a	62	%type <ival> prog decl local format startsub startanonsub startformsub
28757baa	63	%type <ival> remember mremember '&'
bbce6d69	64	%type <opval> block mblock lineseq line loop cond else
a0d0e21e	65	%type <opval> expr term scalar ary hsh arylen star amper sideff
bbce6d69	66	%type <opval> argexpr nexpr texpr iexpr mexpr mnexpr mtexpr miexpr
44a8e56a	67	%type <opval> listexpr listexprcom indirob listop method
44a8e56a	68	%type <opval> formname subname proto subbody cont my_scalar
79072805	69	%type <pval> label
79072805	70
a0d0e21e	71	%left <ival> OROP
463ee0b2	72	%left ANDOP
c07a80fd	73	%right NOTOP
36477c24	74	%nonassoc LSTOP LSTOPSUB
8d063cd8	75	%left ','
a0d0e21e	76	%right <ival> ASSIGNOP
8d063cd8 LW	77	%right '?' ':'
	78	%nonassoc DOTDOT
	79	%left OROR
	80	%left ANDAND
79072805 LW	81	%left <ival> BITOROP
79072805 LW	82	%left <ival> BITANDOP
a687059c LW	83	%nonassoc EQOP
a687059c LW	84	%nonassoc RELOP
36477c24	85	%nonassoc UNIOP UNIOPSUB
79072805	86	%left <ival> SHIFTOP
a687059c LW	87	%left ADDOP
a687059c LW	88	%left MULOP
8990e307	89	%left <ival> MATCHOP
79072805 LW	90	%right '!' '~' UMINUS REFGEN
	91	%right <ival> POWOP
	92	%nonassoc PREINC PREDEC POSTINC POSTDEC
8990e307	93	%left ARROW
8d063cd8 LW	94	%left '('
	95
	96	%% /* RULES */
	97
ae986130 LW	98	prog : /* NULL */
	99	{
	100	#if defined(YYDEBUG) && defined(DEBUGGING)
3280af22	101	yydebug = (PL_debug & 1);
ae986130	102	#endif
3280af22	103	PL_expect = XSTATE;
ae986130 LW	104	}
ae986130 LW	105	/CONTINUED/ lineseq
a0d0e21e	106	{ newPROG($2); }
8d063cd8 LW	107	;
8d063cd8 LW	108
a687059c	109	block : '{' remember lineseq '}'
3280af22 NIS	110	{ if (PL_copline > (line_t)$1)
3280af22 NIS	111	PL_copline = $1;
36477c24	112	$$ = block_end($2, $3); }
a0d0e21e LW	113	;
a0d0e21e LW	114
55497cff	115	remember: /* NULL / / start a full lexical scope */
	116	{ $$ = block_start(TRUE); }
	117	;
	118
bbce6d69	119	mblock : '{' mremember lineseq '}'
3280af22 NIS	120	{ if (PL_copline > (line_t)$1)
3280af22 NIS	121	PL_copline = $1;
36477c24	122	$$ = block_end($2, $3); }
55497cff	123	;
	124
	125	mremember: /* NULL / / start a partial lexical scope */
	126	{ $$ = block_start(FALSE); }
8d063cd8 LW	127	;
	128
	129	lineseq : /* NULL */
79072805 LW	130	{ $$ = Nullop; }
	131	\| lineseq decl
	132	{ $$ = $1; }
8d063cd8	133	\| lineseq line
463ee0b2	134	{ $$ = append_list(OP_LINESEQ,
a0d0e21e	135	(LISTOP)$1, (LISTOP)$2);
3280af22 NIS	136	PL_pad_reset_pending = TRUE;
3280af22 NIS	137	if ($1 && $2) PL_hints \|= HINT_BLOCK_SCOPE; }
8d063cd8 LW	138	;
8d063cd8 LW	139
79072805 LW	140	line : label cond
79072805 LW	141	{ $$ = newSTATEOP(0, $1, $2); }
8d063cd8 LW	142	\| loop /* loops add their own labels */
	143	\| label ';'
	144	{ if ($1 != Nullch) {
79072805	145	$$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
450a55e4 LW	146	}
450a55e4 LW	147	else {
79072805	148	$$ = Nullop;
3280af22	149	PL_copline = NOLINE;
32c2e4fb	150	}
3280af22	151	PL_expect = XSTATE; }
8d063cd8	152	\| label sideff ';'
79072805	153	{ $$ = newSTATEOP(0, $1, $2);
3280af22	154	PL_expect = XSTATE; }
8d063cd8 LW	155	;
8d063cd8 LW	156
a687059c	157	sideff : error
79072805	158	{ $$ = Nullop; }
a687059c	159	\| expr
79072805	160	{ $$ = $1; }
a687059c	161	\| expr IF expr
79072805	162	{ $$ = newLOGOP(OP_AND, 0, $3, $1); }
a687059c	163	\| expr UNLESS expr
79072805	164	{ $$ = newLOGOP(OP_OR, 0, $3, $1); }
a687059c	165	\| expr WHILE expr
8990e307	166	{ $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
55497cff	167	\| expr UNTIL iexpr
55497cff	168	{ $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);}
ecca16b0 CS	169	\| expr FOR expr
	170	{ $$ = newFOROP(0, Nullch, $2,
	171	Nullop, $3, $1, Nullop); }
79072805 LW	172	;
	173
	174	else : /* NULL */
	175	{ $$ = Nullop; }
55497cff	176	\| ELSE mblock
79072805	177	{ $$ = scope($2); }
55497cff	178	\| ELSIF '(' mexpr ')' mblock else
3280af22	179	{ PL_copline = $1;
bbce6d69	180	$$ = newSTATEOP(0, Nullch,
bbce6d69	181	newCONDOP(0, $3, scope($5), $6));
3280af22	182	PL_hints \|= HINT_BLOCK_SCOPE; }
79072805 LW	183	;
79072805 LW	184
55497cff	185	cond : IF '(' remember mexpr ')' mblock else
3280af22	186	{ PL_copline = $1;
36477c24	187	$$ = block_end($3,
bbce6d69	188	newCONDOP(0, $4, scope($6), $7)); }
55497cff	189	\| UNLESS '(' remember miexpr ')' mblock else
3280af22	190	{ PL_copline = $1;
36477c24	191	$$ = block_end($3,
bbce6d69	192	newCONDOP(0, $4, scope($6), $7)); }
79072805 LW	193	;
	194
	195	cont : /* NULL */
	196	{ $$ = Nullop; }
	197	\| CONTINUE block
	198	{ $$ = scope($2); }
	199	;
	200
55497cff	201	loop : label WHILE '(' remember mtexpr ')' mblock cont
3280af22	202	{ PL_copline = $2;
36477c24	203	$$ = block_end($4,
55497cff	204	newSTATEOP(0, $1,
bbce6d69	205	newWHILEOP(0, 1, (LOOP*)Nullop,
fb73857a	206	$2, $5, $7, $8))); }
55497cff	207	\| label UNTIL '(' remember miexpr ')' mblock cont
3280af22	208	{ PL_copline = $2;
36477c24	209	$$ = block_end($4,
55497cff	210	newSTATEOP(0, $1,
bbce6d69	211	newWHILEOP(0, 1, (LOOP*)Nullop,
fb73857a	212	$2, $5, $7, $8))); }
bbce6d69	213	\| label FOR MY remember my_scalar '(' mexpr ')' mblock cont
36477c24	214	{ $$ = block_end($4,
bbce6d69	215	newFOROP(0, $1, $2, $5, $7, $9, $10)); }
bbce6d69	216	\| label FOR scalar '(' remember mexpr ')' mblock cont
36477c24	217	{ $$ = block_end($5,
bbce6d69	218	newFOROP(0, $1, $2, mod($3, OP_ENTERLOOP),
	219	$6, $8, $9)); }
	220	\| label FOR '(' remember mexpr ')' mblock cont
36477c24	221	{ $$ = block_end($4,
55497cff	222	newFOROP(0, $1, $2, Nullop, $5, $7, $8)); }
bbce6d69	223	\| label FOR '(' remember mnexpr ';' mtexpr ';' mnexpr ')' mblock
8d063cd8	224	/* basically fake up an initialize-while lineseq */
fb73857a	225	{ OP *forop = append_elem(OP_LINESEQ,
	226	scalar($5),
	227	newWHILEOP(0, 1, (LOOP*)Nullop,
	228	$2, scalar($7),
	229	$11, scalar($9)));
3280af22	230	PL_copline = $2;
fb73857a	231	$$ = block_end($4, newSTATEOP(0, $1, forop)); }
79072805	232	\| label block cont /* a block is a loop that happens once */
fb73857a	233	{ $$ = newSTATEOP(0, $1,
	234	newWHILEOP(0, 1, (LOOP*)Nullop,
	235	NOLINE, Nullop, $2, $3)); }
8d063cd8 LW	236	;
	237
	238	nexpr : /* NULL */
79072805	239	{ $$ = Nullop; }
8d063cd8 LW	240	\| sideff
	241	;
	242
	243	texpr : /* NULL means true */
79072805	244	{ (void)scan_num("1"); $$ = yylval.opval; }
8d063cd8 LW	245	\| expr
	246	;
	247
55497cff	248	iexpr : expr
	249	{ $$ = invert(scalar($1)); }
	250	;
	251
	252	mexpr : expr
bbce6d69	253	{ $$ = $1; intro_my(); }
	254	;
	255
	256	mnexpr : nexpr
	257	{ $$ = $1; intro_my(); }
55497cff	258	;
	259
	260	mtexpr : texpr
bbce6d69	261	{ $$ = $1; intro_my(); }
55497cff	262	;
	263
	264	miexpr : iexpr
bbce6d69	265	{ $$ = $1; intro_my(); }
55497cff	266	;
55497cff	267
8d063cd8 LW	268	label : /* empty */
8d063cd8 LW	269	{ $$ = Nullch; }
32c2e4fb	270	\| LABEL
8d063cd8 LW	271	;
8d063cd8 LW	272
8d063cd8 LW	273	decl : format
	274	{ $$ = 0; }
	275	\| subrout
	276	{ $$ = 0; }
a687059c LW	277	\| package
a687059c LW	278	{ $$ = 0; }
a0d0e21e	279	\| use
85e6fe83	280	{ $$ = 0; }
8d063cd8 LW	281	;
8d063cd8 LW	282
44a8e56a	283	format : FORMAT startformsub formname block
a0d0e21e	284	{ newFORM($2, $3, $4); }
44a8e56a	285	;
	286
	287	formname: WORD { $$ = $1; }
	288	\| /* NULL */ { $$ = Nullop; }
8d063cd8 LW	289	;
8d063cd8 LW	290
28757baa	291	subrout : SUB startsub subname proto subbody
4633a7c4	292	{ newSUB($2, $3, $4, $5); }
28757baa	293	;
28757baa	294
fa83b5b6	295	startsub: /* NULL / / start a regular subroutine scope */
774d564b	296	{ $$ = start_subparse(FALSE, 0); }
28757baa	297	;
	298
	299	startanonsub: /* NULL / / start an anonymous subroutine scope */
774d564b	300	{ $$ = start_subparse(FALSE, CVf_ANON); }
28757baa	301	;
28757baa	302
44a8e56a	303	startformsub: /* NULL / / start a format subroutine scope */
774d564b	304	{ $$ = start_subparse(TRUE, 0); }
44a8e56a	305	;
44a8e56a	306
2d8e6c8d	307	subname : WORD { STRLEN n_a; char name = SvPV(((SVOP)$1)->op_sv,n_a);
e858de61	308	if (strEQ(name, "BEGIN") \|\| strEQ(name, "END")
7d07dbc2	309	\|\| strEQ(name, "INIT"))
1aff0e91	310	CvSPECIAL_on(PL_compcv);
28757baa	311	$$ = $1; }
a0d0e21e LW	312	;
a0d0e21e LW	313
4633a7c4 LW	314	proto : /* NULL */
	315	{ $$ = Nullop; }
	316	\| THING
	317	;
28757baa	318
28757baa	319	subbody : block { $$ = $1; }
3280af22	320	\| ';' { $$ = Nullop; PL_expect = XSTATE; }
8d063cd8 LW	321	;
8d063cd8 LW	322
a687059c	323	package : PACKAGE WORD ';'
79072805	324	{ package($2); }
93a17b20 LW	325	\| PACKAGE ';'
93a17b20 LW	326	{ package(Nullop); }
a687059c LW	327	;
a687059c LW	328
28757baa	329	use : USE startsub
1aff0e91	330	{ CvSPECIAL_on(PL_compcv); /* It's a BEGIN {} */ }
28757baa	331	WORD WORD listexpr ';'
28757baa	332	{ utilize($1, $2, $4, $5, $6); }
85e6fe83 LW	333	;
85e6fe83 LW	334
a0d0e21e LW	335	expr : expr ANDOP expr
	336	{ $$ = newLOGOP(OP_AND, 0, $1, $3); }
	337	\| expr OROP expr
	338	{ $$ = newLOGOP($2, 0, $1, $3); }
a0d0e21e LW	339	\| argexpr
	340	;
	341
	342	argexpr : argexpr ','
	343	{ $$ = $1; }
	344	\| argexpr ',' term
79072805	345	{ $$ = append_elem(OP_LIST, $1, $3); }
a0d0e21e	346	\| term
8d063cd8 LW	347	;
8d063cd8 LW	348
a0d0e21e	349	listop : LSTOP indirob argexpr
79072805	350	{ $$ = convert($1, OPf_STACKED,
a0d0e21e LW	351	prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
a0d0e21e LW	352	\| FUNC '(' indirob expr ')'
79072805	353	{ $$ = convert($1, OPf_STACKED,
a0d0e21e LW	354	prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
a0d0e21e LW	355	\| term ARROW method '(' listexprcom ')'
4633a7c4	356	{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
a0d0e21e	357	append_elem(OP_LIST,
55497cff	358	prepend_elem(OP_LIST, scalar($1), $5),
a0d0e21e	359	newUNOP(OP_METHOD, 0, $3))); }
b1524f17 SM	360	\| term ARROW method
	361	{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
	362	append_elem(OP_LIST, scalar($1),
	363	newUNOP(OP_METHOD, 0, $3))); }
79072805	364	\| METHOD indirob listexpr
4633a7c4	365	{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
a0d0e21e	366	append_elem(OP_LIST,
4633a7c4	367	prepend_elem(OP_LIST, $2, $3),
a0d0e21e LW	368	newUNOP(OP_METHOD, 0, $1))); }
a0d0e21e LW	369	\| FUNCMETH indirob '(' listexprcom ')'
4633a7c4	370	{ $$ = convert(OP_ENTERSUB, OPf_STACKED,
a0d0e21e	371	append_elem(OP_LIST,
4633a7c4	372	prepend_elem(OP_LIST, $2, $4),
a0d0e21e	373	newUNOP(OP_METHOD, 0, $1))); }
79072805 LW	374	\| LSTOP listexpr
79072805 LW	375	{ $$ = convert($1, 0, $2); }
a0d0e21e	376	\| FUNC '(' listexprcom ')'
79072805	377	{ $$ = convert($1, 0, $3); }
28757baa	378	\| LSTOPSUB startanonsub block
	379	{ $3 = newANONSUB($2, 0, $3); }
	380	listexpr %prec LSTOP
4633a7c4	381	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
28757baa	382	append_elem(OP_LIST,
28757baa	383	prepend_elem(OP_LIST, $3, $5), $1)); }
a687059c LW	384	;
a687059c LW	385
a0d0e21e LW	386	method : METHOD
	387	\| scalar
	388	;
	389
	390	term : term ASSIGNOP term
	391	{ $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
	392	\| term POWOP term
79072805	393	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	394	\| term MULOP term
79072805 LW	395	{ if ($2 != OP_REPEAT)
	396	scalar($1);
	397	$$ = newBINOP($2, 0, $1, scalar($3)); }
a0d0e21e	398	\| term ADDOP term
79072805	399	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	400	\| term SHIFTOP term
79072805	401	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	402	\| term RELOP term
79072805	403	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	404	\| term EQOP term
79072805	405	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	406	\| term BITANDOP term
79072805	407	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	408	\| term BITOROP term
79072805	409	{ $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
a0d0e21e	410	\| term DOTDOT term
79072805	411	{ $$ = newRANGE($2, scalar($1), scalar($3));}
a0d0e21e	412	\| term ANDAND term
463ee0b2	413	{ $$ = newLOGOP(OP_AND, 0, $1, $3); }
a0d0e21e	414	\| term OROR term
463ee0b2	415	{ $$ = newLOGOP(OP_OR, 0, $1, $3); }
a0d0e21e	416	\| term '?' term ':' term
79072805	417	{ $$ = newCONDOP(0, $1, $3, $5); }
a0d0e21e	418	\| term MATCHOP term
79072805	419	{ $$ = bind_match($2, $1, $3); }
8d063cd8	420
a0d0e21e	421	\| '-' term %prec UMINUS
79072805	422	{ $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
a687059c LW	423	\| '+' term %prec UMINUS
a687059c LW	424	{ $$ = $2; }
8d063cd8	425	\| '!' term
79072805	426	{ $$ = newUNOP(OP_NOT, 0, scalar($2)); }
8d063cd8	427	\| '~' term
79072805 LW	428	{ $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
79072805 LW	429	\| REFGEN term
a0d0e21e	430	{ $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
79072805 LW	431	\| term POSTINC
79072805 LW	432	{ $$ = newUNOP(OP_POSTINC, 0,
463ee0b2	433	mod(scalar($1), OP_POSTINC)); }
79072805 LW	434	\| term POSTDEC
79072805 LW	435	{ $$ = newUNOP(OP_POSTDEC, 0,
463ee0b2	436	mod(scalar($1), OP_POSTDEC)); }
79072805 LW	437	\| PREINC term
79072805 LW	438	{ $$ = newUNOP(OP_PREINC, 0,
463ee0b2	439	mod(scalar($2), OP_PREINC)); }
79072805 LW	440	\| PREDEC term
79072805 LW	441	{ $$ = newUNOP(OP_PREDEC, 0,
463ee0b2	442	mod(scalar($2), OP_PREDEC)); }
55497cff	443	\| local term %prec UNIOP
93a17b20	444	{ $$ = localize($2,$1); }
a0d0e21e	445	\| '(' expr ')'
79072805	446	{ $$ = sawparens($2); }
8d063cd8	447	\| '(' ')'
8990e307	448	{ $$ = sawparens(newNULLLIST()); }
a0d0e21e	449	\| '[' expr ']' %prec '('
79072805 LW	450	{ $$ = newANONLIST($2); }
	451	\| '[' ']' %prec '('
	452	{ $$ = newANONLIST(Nullop); }
a0d0e21e	453	\| HASHBRACK expr ';' '}' %prec '('
79072805 LW	454	{ $$ = newANONHASH($2); }
	455	\| HASHBRACK ';' '}' %prec '('
	456	{ $$ = newANONHASH(Nullop); }
28757baa	457	\| ANONSUB startanonsub proto block %prec '('
4633a7c4	458	{ $$ = newANONSUB($2, $3, $4); }
79072805	459	\| scalar %prec '('
8d063cd8	460	{ $$ = $1; }
c07a80fd	461	\| star '{' expr ';' '}'
640b9ef6	462	{ $$ = newBINOP(OP_GELEM, 0, $1, scalar($3)); }
79072805	463	\| star %prec '('
8d063cd8	464	{ $$ = $1; }
79072805 LW	465	\| scalar '[' expr ']' %prec '('
	466	{ $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
	467	\| term ARROW '[' expr ']' %prec '('
	468	{ $$ = newBINOP(OP_AELEM, 0,
8990e307	469	ref(newAVREF($1),OP_RV2AV),
79072805	470	scalar($4));}
463ee0b2	471	\| term '[' expr ']' %prec '('
a0d0e21e	472	{ assertref($1); $$ = newBINOP(OP_AELEM, 0,
8990e307	473	ref(newAVREF($1),OP_RV2AV),
463ee0b2	474	scalar($3));}
79072805	475	\| hsh %prec '('
8d063cd8	476	{ $$ = $1; }
79072805	477	\| ary %prec '('
8d063cd8	478	{ $$ = $1; }
79072805 LW	479	\| arylen %prec '('
	480	{ $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
	481	\| scalar '{' expr ';' '}' %prec '('
	482	{ $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
3280af22	483	PL_expect = XOPERATOR; }
79072805 LW	484	\| term ARROW '{' expr ';' '}' %prec '('
79072805 LW	485	{ $$ = newBINOP(OP_HELEM, 0,
8990e307	486	ref(newHVREF($1),OP_RV2HV),
79072805	487	jmaybe($4));
3280af22	488	PL_expect = XOPERATOR; }
463ee0b2	489	\| term '{' expr ';' '}' %prec '('
a0d0e21e	490	{ assertref($1); $$ = newBINOP(OP_HELEM, 0,
8990e307	491	ref(newHVREF($1),OP_RV2HV),
463ee0b2	492	jmaybe($3));
3280af22	493	PL_expect = XOPERATOR; }
a0d0e21e	494	\| '(' expr ')' '[' expr ']' %prec '('
79072805 LW	495	{ $$ = newSLICEOP(0, $5, $2); }
	496	\| '(' ')' '[' expr ']' %prec '('
	497	{ $$ = newSLICEOP(0, $4, Nullop); }
	498	\| ary '[' expr ']' %prec '('
	499	{ $$ = prepend_elem(OP_ASLICE,
	500	newOP(OP_PUSHMARK, 0),
79072805 LW	501	newLISTOP(OP_ASLICE, 0,
79072805 LW	502	list($3),
a0d0e21e	503	ref($1, OP_ASLICE))); }
79072805 LW	504	\| ary '{' expr ';' '}' %prec '('
	505	{ $$ = prepend_elem(OP_HSLICE,
	506	newOP(OP_PUSHMARK, 0),
79072805 LW	507	newLISTOP(OP_HSLICE, 0,
79072805 LW	508	list($3),
a0d0e21e	509	ref(oopsHV($1), OP_HSLICE)));
3280af22	510	PL_expect = XOPERATOR; }
79072805 LW	511	\| THING %prec '('
	512	{ $$ = $1; }
	513	\| amper
c07a80fd	514	{ $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
79072805	515	\| amper '(' ')'
a0d0e21e LW	516	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
	517	\| amper '(' expr ')'
	518	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
4633a7c4	519	append_elem(OP_LIST, $3, scalar($1))); }
93a17b20	520	\| NOAMP WORD listexpr
a0d0e21e	521	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
a5f75d66	522	append_elem(OP_LIST, $3, scalar($2))); }
a0d0e21e	523	\| DO term %prec UNIOP
78ca652e	524	{ $$ = dofile($2); }
79072805 LW	525	\| DO block %prec '('
79072805 LW	526	{ $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
8d063cd8	527	\| DO WORD '(' ')'
c07a80fd	528	{ $$ = newUNOP(OP_ENTERSUB,
c07a80fd	529	OPf_SPECIAL\|OPf_STACKED,
4633a7c4	530	prepend_elem(OP_LIST,
c07a80fd	531	scalar(newCVREF(
	532	(OPpENTERSUB_AMPER<<8),
	533	scalar($2)
	534	)),Nullop)); dep();}
a0d0e21e	535	\| DO WORD '(' expr ')'
c07a80fd	536	{ $$ = newUNOP(OP_ENTERSUB,
c07a80fd	537	OPf_SPECIAL\|OPf_STACKED,
4633a7c4	538	append_elem(OP_LIST,
a0d0e21e	539	$4,
c07a80fd	540	scalar(newCVREF(
	541	(OPpENTERSUB_AMPER<<8),
	542	scalar($2)
	543	)))); dep();}
79072805	544	\| DO scalar '(' ')'
a0d0e21e	545	{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL\|OPf_STACKED,
4633a7c4	546	prepend_elem(OP_LIST,
c07a80fd	547	scalar(newCVREF(0,scalar($2))), Nullop)); dep();}
a0d0e21e LW	548	\| DO scalar '(' expr ')'
a0d0e21e LW	549	{ $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL\|OPf_STACKED,
4633a7c4	550	prepend_elem(OP_LIST,
a0d0e21e	551	$4,
c07a80fd	552	scalar(newCVREF(0,scalar($2))))); dep();}
6da72b64 CS	553	\| term ARROW '(' ')' %prec '('
	554	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
	555	newCVREF(0, scalar($1))); }
	556	\| term ARROW '(' expr ')' %prec '('
	557	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
	558	append_elem(OP_LIST, $4,
	559	newCVREF(0, scalar($1)))); }
8d063cd8	560	\| LOOPEX
85e6fe83	561	{ $$ = newOP($1, OPf_SPECIAL);
3280af22	562	PL_hints \|= HINT_BLOCK_SCOPE; }
a0d0e21e	563	\| LOOPEX term
8990e307	564	{ $$ = newLOOPEX($1,$2); }
c07a80fd	565	\| NOTOP argexpr
c07a80fd	566	{ $$ = newUNOP(OP_NOT, 0, scalar($2)); }
8d063cd8	567	\| UNIOP
79072805	568	{ $$ = newOP($1, 0); }
f0fcb552	569	\| UNIOP block
79072805	570	{ $$ = newUNOP($1, 0, $2); }
a0d0e21e	571	\| UNIOP term
79072805	572	{ $$ = newUNOP($1, 0, $2); }
4633a7c4 LW	573	\| UNIOPSUB term
	574	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
	575	append_elem(OP_LIST, $2, scalar($1))); }
8d063cd8	576	\| FUNC0
79072805	577	{ $$ = newOP($1, 0); }
ae986130	578	\| FUNC0 '(' ')'
79072805	579	{ $$ = newOP($1, 0); }
4633a7c4	580	\| FUNC0SUB
28757baa	581	{ $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
4633a7c4	582	scalar($1)); }
03a14243	583	\| FUNC1 '(' ')'
79072805	584	{ $$ = newOP($1, OPf_SPECIAL); }
8d063cd8	585	\| FUNC1 '(' expr ')'
79072805	586	{ $$ = newUNOP($1, 0, $3); }
a0d0e21e	587	\| PMFUNC '(' term ')'
79072805	588	{ $$ = pmruntime($1, $3, Nullop); }
a0d0e21e	589	\| PMFUNC '(' term ',' term ')'
79072805 LW	590	{ $$ = pmruntime($1, $3, $5); }
79072805 LW	591	\| WORD
378cc40b	592	\| listop
8d063cd8 LW	593	;
8d063cd8 LW	594
79072805	595	listexpr: /* NULL */
8990e307	596	{ $$ = Nullop; }
a0d0e21e LW	597	\| argexpr
	598	{ $$ = $1; }
	599	;
	600
	601	listexprcom: /* NULL */
	602	{ $$ = Nullop; }
79072805 LW	603	\| expr
79072805 LW	604	{ $$ = $1; }
a0d0e21e LW	605	\| expr ','
a0d0e21e LW	606	{ $$ = $1; }
79072805 LW	607	;
79072805 LW	608
55497cff	609	local : LOCAL { $$ = 0; }
	610	\| MY { $$ = 1; }
	611	;
	612
	613	my_scalar: scalar
3280af22	614	{ PL_in_my = 0; $$ = my($1); }
55497cff	615	;
55497cff	616
79072805	617	amper : '&' indirob
c07a80fd	618	{ $$ = newCVREF($1,$2); }
a687059c LW	619	;
a687059c LW	620
79072805 LW	621	scalar : '$' indirob
79072805 LW	622	{ $$ = newSVREF($2); }
a687059c LW	623	;
a687059c LW	624
79072805 LW	625	ary : '@' indirob
	626	{ $$ = newAVREF($2); }
	627	;
	628
	629	hsh : '%' indirob
	630	{ $$ = newHVREF($2); }
	631	;
	632
	633	arylen : DOLSHARP indirob
	634	{ $$ = newAVREF($2); }
	635	;
	636
	637	star : '*' indirob
a0d0e21e	638	{ $$ = newGVREF(0,$2); }
79072805 LW	639	;
	640
	641	indirob : WORD
	642	{ $$ = scalar($1); }
	643	\| scalar
463ee0b2	644	{ $$ = scalar($1); }
79072805	645	\| block
a0d0e21e	646	{ $$ = scope($1); }
79072805	647
93a17b20 LW	648	\| PRIVATEREF
93a17b20 LW	649	{ $$ = $1; }
8d063cd8 LW	650	;
	651
	652	%% /* PROGRAM */