This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perldata: Fix too long verbatim lines
[perl5.git] / pod / perldata.pod
CommitLineData
a0d0e21e
LW
1=head1 NAME
2
cb1a09d0 3perldata - Perl data types
a0d0e21e
LW
4
5=head1 DESCRIPTION
6
7=head2 Variable names
d74e8afc 8X<variable, name> X<variable name> X<data type> X<type>
a0d0e21e 9
d55a8828 10Perl has three built-in data types: scalars, arrays of scalars, and
692ef166
SF
11associative arrays of scalars, known as "hashes". A scalar is a
12single string (of any size, limited only by the available memory),
13number, or a reference to something (which will be discussed
14in L<perlref>). Normal arrays are ordered lists of scalars indexed
15by number, starting with 0. Hashes are unordered collections of scalar
16values indexed by their associated string key.
a0d0e21e 17
d55a8828 18Values are usually referred to by name, or through a named reference.
b88cefa9
PP
19The first character of the name tells you to what sort of data
20structure it refers. The rest of the name tells you the particular
d55a8828
TC
21value to which it refers. Usually this name is a single I<identifier>,
22that is, a string beginning with a letter or underscore, and
23containing letters, underscores, and digits. In some cases, it may
24be a chain of identifiers, separated by C<::> (or by the slightly
25archaic C<'>); all but the last are interpreted as names of packages,
26to locate the namespace in which to look up the final identifier
32833930
BF
27(see L<perlmod/Packages> for details). For a more in-depth discussion
28on identifiers, see L<Identifier parsing>. It's possible to
29substitute for a simple identifier, an expression that produces a reference
d55a8828
TC
30to the value at runtime. This is described in more detail below
31and in L<perlref>.
d74e8afc 32X<identifier>
d55a8828
TC
33
34Perl also has its own built-in variables whose names don't follow
35these rules. They have strange names so they don't accidentally
36collide with one of your normal variables. Strings that match
37parenthesized parts of a regular expression are saved under names
38containing only digits after the C<$> (see L<perlop> and L<perlre>).
39In addition, several special variables that provide windows into
40the inner working of Perl have names containing punctuation characters
41and control characters. These are documented in L<perlvar>.
d74e8afc 42X<variable, built-in>
d55a8828
TC
43
44Scalar values are always named with '$', even when referring to a
45scalar that is part of an array or a hash. The '$' symbol works
46semantically like the English word "the" in that it indicates a
47single value is expected.
d74e8afc 48X<scalar>
a0d0e21e
LW
49
50 $days # the simple scalar value "days"
51 $days[28] # the 29th element of array @days
52 $days{'Feb'} # the 'Feb' value from hash %days
53 $#days # the last index of array @days
54
d55a8828 55Entire arrays (and slices of arrays and hashes) are denoted by '@',
3921068c 56which works much as the word "these" or "those" does in English,
d55a8828 57in that it indicates multiple values are expected.
d74e8afc 58X<array>
a0d0e21e
LW
59
60 @days # ($days[0], $days[1],... $days[n])
d55a8828 61 @days[3,4,5] # same as ($days[3],$days[4],$days[5])
a0d0e21e
LW
62 @days{'a','c'} # same as ($days{'a'},$days{'c'})
63
d55a8828 64Entire hashes are denoted by '%':
d74e8afc 65X<hash>
a0d0e21e
LW
66
67 %days # (key1, val1, key2, val2 ...)
68
d55a8828
TC
69In addition, subroutines are named with an initial '&', though this
70is optional when unambiguous, just as the word "do" is often redundant
71in English. Symbol table entries can be named with an initial '*',
72but you don't really care about that yet (if ever :-).
73
74Every variable type has its own namespace, as do several
75non-variable identifiers. This means that you can, without fear
76of conflict, use the same name for a scalar variable, an array, or
77a hash--or, for that matter, for a filehandle, a directory handle, a
78subroutine name, a format name, or a label. This means that $foo
79and @foo are two different variables. It also means that C<$foo[1]>
80is a part of @foo, not a part of $foo. This may seem a bit weird,
81but that's okay, because it is weird.
d74e8afc 82X<namespace>
d55a8828
TC
83
84Because variable references always start with '$', '@', or '%', the
85"reserved" words aren't in fact reserved with respect to variable
86names. They I<are> reserved with respect to labels and filehandles,
87however, which don't have an initial special character. You can't
88have a filehandle named "log", for instance. Hint: you could say
89C<open(LOG,'logfile')> rather than C<open(log,'logfile')>. Using
90uppercase filehandles also improves readability and protects you
91from conflict with future reserved words. Case I<is> significant--"FOO",
92"Foo", and "foo" are all different names. Names that start with a
93letter or underscore may also contain digits and underscores.
d74e8afc
ITB
94X<identifier, case sensitivity>
95X<case>
a0d0e21e
LW
96
97It is possible to replace such an alphanumeric name with an expression
d55a8828 98that returns a reference to the appropriate type. For a description
a0d0e21e
LW
99of this, see L<perlref>.
100
5f05dabc 101Names that start with a digit may contain only more digits. Names
9539f610
RGS
102that do not start with a letter, underscore, digit or a caret (i.e.
103a control character) are limited to one character, e.g., C<$%> or
104C<$$>. (Most of these one character names have a predefined
105significance to Perl. For instance, C<$$> is the current process
106id.)
a0d0e21e 107
32833930
BF
108=head2 Identifier parsing
109X<identifiers>
110
111Up until Perl 5.18, the actual rules of what a valid identifier
112was were a bit fuzzy. However, in general, anything defined here should
113work on previous versions of Perl, while the opposite -- edge cases
114that work in previous versions, but aren't defined here -- probably
115won't work on newer versions.
116As an important side note, please note that the following only applies
117to bareword identifiers as found in Perl source code, not identifiers
118introduced through symbolic references, which have much fewer
119restrictions.
120If working under the effect of the C<use utf8;> pragma, the following
121rules apply:
122
9c1129c7
KW
123 / (?[ ( \p{Word} & \p{XID_Start} ) + [_] ])
124 (?[ ( \p{Word} & \p{XID_Continue} ) ]) * /x
125
126That is, a "start" character followed by any number of "continue"
127characters. Perl requires every character in an identifier to also
128match C<\w> (this prevents some problematic cases); and Perl
129additionally accepts identfier names beginning with an underscore.
32833930
BF
130
131If not under C<use utf8>, the source is treated as ASCII + 128 extra
132controls, and identifiers should match
133
134 / (?aa) (?!\d) \w+ /x
135
136That is, any word character in the ASCII range, as long as the first
137character is not a digit.
138
139There are two package separators in Perl: A double colon (C<::>) and a single
140quote (C<'>). Normal identifiers can start or end with a double colon, and
141can contain several parts delimited by double colons.
142Single quotes have similar rules, but with the exception that they are not
143legal at the end of an identifier: That is, C<$'foo> and C<$foo'bar> are
1d268002 144legal, but C<$foo'bar'> is not.
32833930 145
1d268002 146Additionally, if the identifier is preceded by a sigil --
32833930
BF
147that is, if the identifier is part of a variable name -- it
148may optionally be enclosed in braces.
149
150While you can mix double colons with singles quotes, the quotes must come
151after the colons: C<$::::'foo> and C<$foo::'bar> are legal, but C<$::'::foo>
152and C<$foo'::bar> are not.
153
154Put together, a grammar to match a basic identifier becomes
155
156 /
157 (?(DEFINE)
158 (?<variable>
159 (?&sigil)
160 (?:
161 (?&normal_identifier)
162 | \{ \s* (?&normal_identifier) \s* \}
163 )
164 )
165 (?<normal_identifier>
166 (?: :: )* '?
167 (?&basic_identifier)
168 (?: (?= (?: :: )+ '? | (?: :: )* ' ) (?&normal_identifier) )?
169 (?: :: )*
170 )
171 (?<basic_identifier>
172 # is use utf8 on?
173 (?(?{ (caller(0))[8] & $utf8::hint_bits })
4c106081 174 (?&Perl_XIDS) (?&Perl_XIDC)*
32833930
BF
175 | (?aa) (?!\d) \w+
176 )
177 )
178 (?<sigil> [&*\$\@\%])
179 (?<Perl_XIDS> (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) )
4c106081 180 (?<Perl_XIDC> (?[ \p{Word} & \p{XID_Continue} ]) )
32833930
BF
181 )
182 /x
183
184Meanwhile, special identifiers don't follow the above rules; For the most
185part, all of the identifiers in this category have a special meaning given
186by Perl. Because they have special parsing rules, these generally can't be
187fully-qualified. They come in four forms:
188
189=over
190
191=item A sigil, followed solely by digits matching \p{POSIX_Digit}, like C<$0>,
192C<$1>, or C<$10000>.
193
194=item A sigil, followed by either a caret and a single POSIX uppercase letter,
195like C<$^V> or C<$^W>, or a sigil followed by a literal control character
b4e2e1dd
FC
196matching the C<\p{POSIX_Cntrl}> property.
197Due to a historical oddity, if not
32833930 198running under C<use utf8>, the 128 extra controls in the C<[0x80-0xff]> range
b50f77aa
RS
199may also be used in length one variables. The use of a literal control
200character is deprecated. Support for this form will be removed in a future
201version of perl.
32833930
BF
202
203=item Similar to the above, a sigil, followed by bareword text in brackets,
204where the first character is either a caret followed by an uppercase letter,
b50f77aa
RS
205or a literal control, like C<${^GLOBAL_PHASE}> or C<${\7LOBAL_PHASE}>. The use
206of a literal control character is deprecated. Support for this form will be
207removed in a future version of perl.
32833930
BF
208
209=item A sigil followed by a single character matching the C<\p{POSIX_Punct}>
210property, like C<$!> or C<%+>.
211
212=back
213
b29f65fc
BF
214Note that as of Perl 5.20, literal control characters in variable names
215are deprecated.
216
a0d0e21e 217=head2 Context
d74e8afc 218X<context> X<scalar context> X<list context>
a0d0e21e
LW
219
220The interpretation of operations and values in Perl sometimes depends
221on the requirements of the context around the operation or value.
d55a8828 222There are two major contexts: list and scalar. Certain operations
a0d0e21e 223return list values in contexts wanting a list, and scalar values
d55a8828
TC
224otherwise. If this is true of an operation it will be mentioned in
225the documentation for that operation. In other words, Perl overloads
a0d0e21e 226certain operations based on whether the expected return value is
d55a8828
TC
227singular or plural. Some words in English work this way, like "fish"
228and "sheep".
a0d0e21e
LW
229
230In a reciprocal fashion, an operation provides either a scalar or a
231list context to each of its arguments. For example, if you say
232
233 int( <STDIN> )
234
c47ff5f1 235the integer operation provides scalar context for the <>
a0d0e21e
LW
236operator, which responds by reading one line from STDIN and passing it
237back to the integer operation, which will then find the integer value
238of that line and return that. If, on the other hand, you say
239
240 sort( <STDIN> )
241
c47ff5f1 242then the sort operation provides list context for <>, which
a0d0e21e
LW
243will proceed to read every line available up to the end of file, and
244pass that list of lines back to the sort routine, which will then
245sort those lines and return them as a list to whatever the context
246of the sort was.
247
d55a8828
TC
248Assignment is a little bit special in that it uses its left argument
249to determine the context for the right argument. Assignment to a
250scalar evaluates the right-hand side in scalar context, while
251assignment to an array or hash evaluates the righthand side in list
252context. Assignment to a list (or slice, which is just a list
3921068c 253anyway) also evaluates the right-hand side in list context.
d55a8828 254
9f1b1f2d
GS
255When you use the C<use warnings> pragma or Perl's B<-w> command-line
256option, you may see warnings
d55a8828
TC
257about useless uses of constants or functions in "void context".
258Void context just means the value has been discarded, such as a
259statement containing only C<"fred";> or C<getpwuid(0);>. It still
260counts as scalar context for functions that care whether or not
261they're being called in list context.
262
263User-defined subroutines may choose to care whether they are being
264called in a void, scalar, or list context. Most subroutines do not
265need to bother, though. That's because both scalars and lists are
266automatically interpolated into lists. See L<perlfunc/wantarray>
267for how you would dynamically discern your function's calling
268context.
a0d0e21e
LW
269
270=head2 Scalar values
d74e8afc 271X<scalar> X<number> X<string> X<reference>
a0d0e21e 272
d55a8828
TC
273All data in Perl is a scalar, an array of scalars, or a hash of
274scalars. A scalar may contain one single value in any of three
275different flavors: a number, a string, or a reference. In general,
276conversion from one form to another is transparent. Although a
277scalar may not directly hold multiple values, it may contain a
278reference to an array or hash which in turn contains multiple values.
279
280Scalars aren't necessarily one thing or another. There's no place
281to declare a scalar variable to be of type "string", type "number",
282type "reference", or anything else. Because of the automatic
283conversion of scalars, operations that return scalars don't need
284to care (and in fact, cannot care) whether their caller is looking
285for a string, a number, or a reference. Perl is a contextually
286polymorphic language whose scalars can be strings, numbers, or
287references (which includes objects). Although strings and numbers
288are considered pretty much the same thing for nearly all purposes,
289references are strongly-typed, uncastable pointers with builtin
290reference-counting and destructor invocation.
a0d0e21e 291
32860eee
FC
292A scalar value is interpreted as FALSE in the Boolean sense
293if it is undefined, the null string or the number 0 (or its
294string equivalent, "0"), and TRUE if it is anything else. The
d55a8828
TC
295Boolean context is just a special kind of scalar context where no
296conversion to a string or a number is ever performed.
d74e8afc 297X<boolean> X<bool> X<true> X<false> X<truth>
d55a8828
TC
298
299There are actually two varieties of null strings (sometimes referred
300to as "empty" strings), a defined one and an undefined one. The
301defined version is just a string of length zero, such as C<"">.
302The undefined version is the value that indicates that there is
303no real value for something, such as when there was an error, or
304at end of file, or when you refer to an uninitialized variable or
305element of an array or hash. Although in early versions of Perl,
306an undefined scalar could become defined when first used in a
307place expecting a defined value, this no longer happens except for
308rare cases of autovivification as explained in L<perlref>. You can
309use the defined() operator to determine whether a scalar value is
310defined (this has no meaning on arrays or hashes), and the undef()
311operator to produce an undefined value.
d74e8afc 312X<defined> X<undefined> X<undef> X<null> X<string, null>
d55a8828
TC
313
314To find out whether a given string is a valid non-zero number, it's
315sometimes enough to test it against both numeric 0 and also lexical
692ef166
SF
316"0" (although this will cause noises if warnings are on). That's
317because strings that aren't numbers count as 0, just as they do in B<awk>:
4633a7c4
LW
318
319 if ($str == 0 && $str ne "0") {
320 warn "That doesn't look like a number";
54310121 321 }
4633a7c4 322
d55a8828
TC
323That method may be best because otherwise you won't treat IEEE
324notations like C<NaN> or C<Infinity> properly. At other times, you
325might prefer to determine whether string data can be used numerically
326by calling the POSIX::strtod() function or by inspecting your string
327with a regular expression (as documented in L<perlre>).
cb1a09d0
AD
328
329 warn "has nondigits" if /\D/;
5a964f20
TC
330 warn "not a natural number" unless /^\d+$/; # rejects -3
331 warn "not an integer" unless /^-?\d+$/; # rejects +3
332 warn "not an integer" unless /^[+-]?\d+$/;
333 warn "not a decimal number" unless /^-?\d+\.?\d*$/; # rejects .2
334 warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
54310121 335 warn "not a C float"
cb1a09d0
AD
336 unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
337
d55a8828 338The length of an array is a scalar value. You may find the length
fc518ee5 339of array @days by evaluating C<$#days>, as in B<csh>. However, this
340isn't the length of the array; it's the subscript of the last element,
341which is a different value since there is ordinarily a 0th element.
d55a8828
TC
342Assigning to C<$#days> actually changes the length of the array.
343Shortening an array this way destroys intervening values. Lengthening
344an array that was previously shortened does not recover values
0568eccd 345that were in those elements.
d74e8afc 346X<$#> X<array, length>
d55a8828 347
210b36aa 348You can also gain some minuscule measure of efficiency by pre-extending
d55a8828
TC
349an array that is going to get big. You can also extend an array
350by assigning to an element that is off the end of the array. You
19799a22 351can truncate an array down to nothing by assigning the null list
d55a8828 352() to it. The following are equivalent:
a0d0e21e 353
84f709e7 354 @whatever = ();
3e3baf6d 355 $#whatever = -1;
a0d0e21e 356
d55a8828
TC
357If you evaluate an array in scalar context, it returns the length
358of the array. (Note that this is not true of lists, which return
359the last value, like the C comma operator, nor of built-in functions,
360which return whatever they feel like returning.) The following is
361always true:
d74e8afc 362X<array, length>
a0d0e21e 363
a0d0e21e
LW
364 scalar(@whatever) == $#whatever + 1;
365
d55a8828
TC
366Some programmers choose to use an explicit conversion so as to
367leave nothing to doubt:
4633a7c4
LW
368
369 $element_count = scalar(@whatever);
370
d55a8828
TC
371If you evaluate a hash in scalar context, it returns false if the
372hash is empty. If there are any key/value pairs, it returns true;
373more precisely, the value returned is a string consisting of the
374number of used buckets and the number of allocated buckets, separated
375by a slash. This is pretty much useful only to find out whether
376Perl's internal hashing algorithm is performing poorly on your data
377set. For example, you stick 10,000 things in a hash, but evaluating
378%HASH in scalar context reveals C<"1/16">, which means only one out
379of sixteen buckets has been touched, and presumably contains all
126c71c8 38010,000 of your items. This isn't supposed to happen. If a tied hash
6e4c4703
DM
381is evaluated in scalar context, the C<SCALAR> method is called (with a
382fallback to C<FIRSTKEY>).
d74e8afc 383X<hash, scalar context> X<hash, bucket> X<bucket>
a0d0e21e 384
5a964f20 385You can preallocate space for a hash by assigning to the keys() function.
65841adf 386This rounds up the allocated buckets to the next power of two:
5a964f20
TC
387
388 keys(%users) = 1000; # allocate 1024 buckets
389
a0d0e21e 390=head2 Scalar value constructors
d74e8afc 391X<scalar, literal> X<scalar, constant>
a0d0e21e 392
d55a8828 393Numeric literals are specified in any of the following floating point or
a0d0e21e
LW
394integer formats:
395
a94ee3a1
KW
396 12345
397 12345.67
398 .23E-10 # a very small number
399 3.14_15_92 # a very important number
400 4_294_967_296 # underscore for legibility
401 0xff # hex
402 0xdead_beef # more hex
403 0377 # octal (only numbers, begins with 0)
404 0b011011 # binary
405 0x1.999ap-4 # hexadecimal floating point (the 'p' is required)
a0d0e21e 406
d4ced10d 407You are allowed to use underscores (underbars) in numeric literals
d823de2e
KW
408between digits for legibility (but not multiple underscores in a row:
409C<23__500> is not legal; C<23_500> is).
410You could, for example, group binary
d4ced10d
JH
411digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
412or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
d74e8afc 413X<number, literal>
1d277562 414
55497cff 415String literals are usually delimited by either single or double
d55a8828
TC
416quotes. They work much like quotes in the standard Unix shells:
417double-quoted string literals are subject to backslash and variable
19799a22
GS
418substitution; single-quoted strings are not (except for C<\'> and
419C<\\>). The usual C-style backslash rules apply for making
d55a8828 420characters such as newline, tab, etc., as well as some more exotic
4a4eefd0 421forms. See L<perlop/"Quote and Quote-like Operators"> for a list.
d74e8afc 422X<string, literal>
d55a8828
TC
423
424Hexadecimal, octal, or binary, representations in string literals
425(e.g. '0xff') are not automatically converted to their integer
426representation. The hex() and oct() functions make these conversions
427for you. See L<perlfunc/hex> and L<perlfunc/oct> for more details.
68dc0745 428
61e61fbc
JH
429Hexadecimal floating point can start just like a hexadecimal literal,
430and it can be followed by an optional fractional hexadecimal part,
431but it must be followed by C<p>, an optional sign, and a power of two.
432The format is useful for accurately presenting floating point values,
433avoiding conversions to or from decimal floating point, and therefore
434avoiding possible loss in precision. Notice that while most current
435platforms use the 64-bit IEEE 754 floating point, not all do.
436
5f05dabc 437You can also embed newlines directly in your strings, i.e., they can end
a0d0e21e
LW
438on a different line than they begin. This is nice, but if you forget
439your trailing quote, the error will not be reported until Perl finds
440another line containing the quote character, which may be much further
441on in the script. Variable substitution inside strings is limited to
d55a8828 442scalar variables, arrays, and array or hash slices. (In other words,
b88cefa9 443names beginning with $ or @, followed by an optional bracketed
a0d0e21e 444expression as a subscript.) The following code segment prints out "The
184e9718 445price is $Z<>100."
d74e8afc 446X<interpolation>
a0d0e21e 447
692ef166
SF
448 $Price = '$100'; # not interpolated
449 print "The price is $Price.\n"; # interpolated
450
451There is no double interpolation in Perl, so the C<$100> is left as is.
a0d0e21e 452
7e4353e9
RGS
453By default floating point numbers substituted inside strings use the
454dot (".") as the decimal separator. If C<use locale> is in effect,
455and POSIX::setlocale() has been called, the character used for the
456decimal separator is affected by the LC_NUMERIC locale.
457See L<perllocale> and L<POSIX>.
458
d55a8828 459As in some shells, you can enclose the variable name in braces to
f1cbbd6e
GS
460disambiguate it from following alphanumerics (and underscores).
461You must also do
d55a8828
TC
462this when interpolating a variable into a string to separate the
463variable name from a following double-colon or an apostrophe, since
464these would be otherwise treated as a package separator:
d74e8afc 465X<interpolation>
d55a8828 466
84f709e7 467 $who = "Larry";
d55a8828
TC
468 print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
469 print "We use ${who}speak when ${who}'s here.\n";
470
471Without the braces, Perl would have looked for a $whospeak, a
472C<$who::0>, and a C<$who's> variable. The last two would be the
473$0 and the $s variables in the (presumably) non-existent package
474C<who>.
475
34a2706e 476In fact, a simple identifier within such curlies is forced to be
b4e2e1dd 477a string, and likewise within a hash subscript. Neither need
d55a8828
TC
478quoting. Our earlier example, C<$days{'Feb'}> can be written as
479C<$days{Feb}> and the quotes will be assumed automatically. But
719b43e8
RGS
480anything more complicated in the subscript will be interpreted as an
481expression. This means for example that C<$version{2.0}++> is
482equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>.
d55a8828 483
692ef166 484=head3 Version Strings
d74e8afc 485X<version string> X<vstring> X<v-string>
692ef166 486
191d61a7 487A literal of the form C<v1.20.300.4000> is parsed as a string composed
6b2463a0
JH
488of characters with the specified ordinals. This form, known as
489v-strings, provides an alternative, more readable way to construct
490strings, rather than use the somewhat less readable interpolation form
491C<"\x{1}\x{14}\x{12c}\x{fa0}">. This is useful for representing
492Unicode strings, and for comparing version "numbers" using the string
493comparison operators, C<cmp>, C<gt>, C<lt> etc. If there are two or
494more dots in the literal, the leading C<v> may be omitted.
b9c62f5b 495
2575c402 496 print v9786; # prints SMILEY, "\x{263a}"
b9c62f5b
GS
497 print v102.111.111; # prints "foo"
498 print 102.111.111; # same
499
500Such literals are accepted by both C<require> and C<use> for
a32521b7
JD
501doing a version check. Note that using the v-strings for IPv4
502addresses is not portable unless you also use the
503inet_aton()/inet_ntoa() routines of the Socket package.
191d61a7 504
d32a65d2 505Note that since Perl 5.8.1 the single-number v-strings (like C<v65>)
8fa72689 506are not v-strings before the C<< => >> operator (which is usually used
3921068c 507to separate a hash key from a hash value); instead they are interpreted
15ecd4ae
JH
508as literal strings ('v65'). They were v-strings from Perl 5.6.0 to
509Perl 5.8.0, but that caused more confusion and breakage than good.
510Multi-number v-strings like C<v65.66> and C<65.66.67> continue to
511be v-strings always.
d32a65d2 512
692ef166 513=head3 Special Literals
d74e8afc
ITB
514X<special literal> X<__END__> X<__DATA__> X<END> X<DATA>
515X<end> X<data> X<^D> X<^Z>
692ef166 516
d55a8828 517The special literals __FILE__, __LINE__, and __PACKAGE__
68dc0745 518represent the current filename, line number, and package name at that
84ed0108
FC
519point in your program. __SUB__ gives a reference to the current
520subroutine. They may be used only as separate tokens; they
68dc0745 521will not be interpolated into strings. If there is no current package
3e92a254 522(due to an empty C<package;> directive), __PACKAGE__ is the undefined
8fdd8881 523value. (But the empty C<package;> is no longer supported, as of version
84ed0108
FC
5245.10.) Outside of a subroutine, __SUB__ is the undefined value. __SUB__
525is only available in 5.16 or higher, and only with a C<use v5.16> or
526C<use feature "current_sub"> declaration.
527X<__FILE__> X<__LINE__> X<__PACKAGE__> X<__SUB__>
528X<line> X<file> X<package>
3e92a254
GS
529
530The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
531may be used to indicate the logical end of the script before the actual
532end of file. Any following text is ignored.
533
1bab44f9 534Text after __DATA__ may be read via the filehandle C<PACKNAME::DATA>,
3e92a254
GS
535where C<PACKNAME> is the package that was current when the __DATA__
536token was encountered. The filehandle is left open pointing to the
4d383607 537line after __DATA__. The program should C<close DATA> when it is done
9c205800
FC
538reading from it. (Leaving it open leaks filehandles if the module is
539reloaded for any reason, so it's a safer practice to close it.) For
4d383607
JK
540compatibility with older scripts written before __DATA__ was
541introduced, __END__ behaves like __DATA__ in the top level script (but
542not in files loaded with C<require> or C<do>) and leaves the remaining
543contents of the file accessible via C<main::DATA>.
3e92a254
GS
544
545See L<SelfLoader> for more description of __DATA__, and
d55a8828
TC
546an example of its use. Note that you cannot read from the DATA
547filehandle in a BEGIN block: the BEGIN block is executed as soon
548as it is seen (during compilation), at which point the corresponding
a00c1fe5 549__DATA__ (or __END__) token has not yet been seen.
a0d0e21e 550
692ef166 551=head3 Barewords
d74e8afc 552X<bareword>
692ef166 553
748a9306 554A word that has no other interpretation in the grammar will
a0d0e21e
LW
555be treated as if it were a quoted string. These are known as
556"barewords". As with filehandles and labels, a bareword that consists
557entirely of lowercase letters risks conflict with future reserved
9f1b1f2d 558words, and if you use the C<use warnings> pragma or the B<-w> switch,
05b4f1ec
FW
559Perl will warn you about any such words. Perl limits barewords (like
560identifiers) to about 250 characters. Future versions of Perl are likely
561to eliminate these arbitrary limitations.
562
563Some people may wish to outlaw barewords entirely. If you
a0d0e21e
LW
564say
565
566 use strict 'subs';
567
568then any bareword that would NOT be interpreted as a subroutine call
569produces a compile-time error instead. The restriction lasts to the
54310121 570end of the enclosing block. An inner block may countermand this
a0d0e21e
LW
571by saying C<no strict 'subs'>.
572
e2b457c0 573=head3 Array Interpolation
d74e8afc 574X<array, interpolation> X<interpolation, array> X<$">
692ef166 575
d55a8828
TC
576Arrays and slices are interpolated into double-quoted strings
577by joining the elements with the delimiter specified in the C<$">
692ef166
SF
578variable (C<$LIST_SEPARATOR> if "use English;" is specified),
579space by default. The following are equivalent:
a0d0e21e 580
84f709e7 581 $temp = join($", @ARGV);
a0d0e21e
LW
582 system "echo $temp";
583
584 system "echo @ARGV";
585
586Within search patterns (which also undergo double-quotish substitution)
d55a8828 587there is an unfortunate ambiguity: Is C</$foo[bar]/> to be interpreted as
a0d0e21e
LW
588C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
589expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
590@foo)? If @foo doesn't otherwise exist, then it's obviously a
591character class. If @foo exists, Perl takes a good guess about C<[bar]>,
592and is almost always right. If it does guess wrong, or if you're just
593plain paranoid, you can force the correct interpretation with curly
d55a8828 594braces as above.
a0d0e21e 595
7e3b091d 596If you're looking for the information on how to use here-documents,
210b36aa
AMS
597which used to be here, that's been moved to
598L<perlop/Quote and Quote-like Operators>.
be16fac9 599
a0d0e21e 600=head2 List value constructors
d74e8afc 601X<list>
a0d0e21e
LW
602
603List values are denoted by separating individual values by commas
604(and enclosing the list in parentheses where precedence requires it):
605
606 (LIST)
607
d55a8828
TC
608In a context not requiring a list value, the value of what appears
609to be a list literal is simply the value of the final element, as
610with the C comma operator. For example,
a0d0e21e 611
84f709e7 612 @foo = ('cc', '-E', $bar);
a0d0e21e 613
d55a8828 614assigns the entire list value to array @foo, but
a0d0e21e 615
84f709e7 616 $foo = ('cc', '-E', $bar);
a0d0e21e 617
d55a8828
TC
618assigns the value of variable $bar to the scalar variable $foo.
619Note that the value of an actual array in scalar context is the
620length of the array; the following assigns the value 3 to $foo:
a0d0e21e 621
84f709e7 622 @foo = ('cc', '-E', $bar);
7e3b091d 623 $foo = @foo; # $foo gets 3
a0d0e21e 624
54310121 625You may have an optional comma before the closing parenthesis of a
a0d0e21e
LW
626list literal, so that you can say:
627
84f709e7 628 @foo = (
7e3b091d
DA
629 1,
630 2,
631 3,
a0d0e21e
LW
632 );
633
d55a8828
TC
634To use a here-document to assign an array, one line per element,
635you might use an approach like this:
636
84f709e7 637 @sauces = <<End_Lines =~ m/(\S.*\S)/g;
7e3b091d
DA
638 normal tomato
639 spicy tomato
640 green chile
641 pesto
642 white wine
d55a8828
TC
643 End_Lines
644
a0d0e21e 645LISTs do automatic interpolation of sublists. That is, when a LIST is
d55a8828 646evaluated, each element of the list is evaluated in list context, and
a0d0e21e 647the resulting list value is interpolated into LIST just as if each
5a964f20 648individual element were a member of LIST. Thus arrays and hashes lose their
a0d0e21e
LW
649identity in a LIST--the list
650
5a964f20 651 (@foo,@bar,&SomeSub,%glarch)
a0d0e21e
LW
652
653contains all the elements of @foo followed by all the elements of @bar,
5a964f20 654followed by all the elements returned by the subroutine named SomeSub
d55a8828 655called in list context, followed by the key/value pairs of %glarch.
a0d0e21e
LW
656To make a list reference that does I<NOT> interpolate, see L<perlref>.
657
19799a22 658The null list is represented by (). Interpolating it in a list
a0d0e21e
LW
659has no effect. Thus ((),(),()) is equivalent to (). Similarly,
660interpolating an array with no elements is the same as if no
661array had been interpolated at that point.
662
c2689353 663This interpolation combines with the facts that the opening
ab1f959b 664and closing parentheses are optional (except when necessary for
c2689353 665precedence) and lists may end with an optional comma to mean that
8fdd8881 666multiple commas within lists are legal syntax. The list C<1,,3> is a
c2689353
NC
667concatenation of two lists, C<1,> and C<3>, the first of which ends
668with that optional comma. C<1,,3> is C<(1,),(3)> is C<1,3> (And
669similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.) Not that
670we'd advise you to use this obfuscation.
671
a0d0e21e 672A list value may also be subscripted like a normal array. You must
54310121 673put the list in parentheses to avoid ambiguity. For example:
a0d0e21e
LW
674
675 # Stat returns list value.
84f709e7 676 $time = (stat($file))[8];
a0d0e21e 677
4633a7c4 678 # SYNTAX ERROR HERE.
84f709e7 679 $time = stat($file)[8]; # OOPS, FORGOT PARENTHESES
4633a7c4 680
a0d0e21e 681 # Find a hex digit.
84f709e7 682 $hexdigit = ('a','b','c','d','e','f')[$digit-10];
a0d0e21e
LW
683
684 # A "reverse comma operator".
685 return (pop(@foo),pop(@foo))[0];
686
d55a8828
TC
687Lists may be assigned to only when each element of the list
688is itself legal to assign to:
a0d0e21e 689
84f709e7 690 ($a, $b, $c) = (1, 2, 3);
a0d0e21e 691
84f709e7 692 ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
a0d0e21e 693
d55a8828
TC
694An exception to this is that you may assign to C<undef> in a list.
695This is useful for throwing away some of the return values of a
696function:
697
84f709e7 698 ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
d55a8828
TC
699
700List assignment in scalar context returns the number of elements
4633a7c4
LW
701produced by the expression on the right side of the assignment:
702
7e3b091d
DA
703 $x = (($foo,$bar) = (3,2,1)); # set $x to 3, not 2
704 $x = (($foo,$bar) = f()); # set $x to f()'s return count
4633a7c4 705
d55a8828 706This is handy when you want to do a list assignment in a Boolean
19799a22 707context, because most list functions return a null list when finished,
4633a7c4
LW
708which when assigned produces a 0, which is interpreted as FALSE.
709
ab1f959b
PN
710It's also the source of a useful idiom for executing a function or
711performing an operation in list context and then counting the number of
712return values, by assigning to an empty list and then using that
8fdd8881 713assignment in scalar context. For example, this code:
ab1f959b 714
84f709e7 715 $count = () = $string =~ /\d+/g;
ab1f959b
PN
716
717will place into $count the number of digit groups found in $string.
718This happens because the pattern match is in list context (since it
719is being assigned to the empty list), and will therefore return a list
8fdd8881 720of all matching parts of the string. The list assignment in scalar
ab1f959b 721context will translate that into the number of elements (here, the
8fdd8881 722number of times the pattern matched) and assign that to $count. Note
ab1f959b
PN
723that simply using
724
84f709e7 725 $count = $string =~ /\d+/g;
ab1f959b
PN
726
727would not have worked, since a pattern match in scalar context will
728only return true or false, rather than a count of matches.
729
730The final element of a list assignment may be an array or a hash:
a0d0e21e 731
84f709e7 732 ($a, $b, @rest) = split;
5a964f20 733 my($a, $b, %rest) = @_;
a0d0e21e 734
4633a7c4 735You can actually put an array or hash anywhere in the list, but the first one
d55a8828
TC
736in the list will soak up all the values, and anything after it will become
737undefined. This may be useful in a my() or local().
a0d0e21e 738
d55a8828
TC
739A hash can be initialized using a literal list holding pairs of
740items to be interpreted as a key and a value:
a0d0e21e
LW
741
742 # same as map assignment above
84f709e7 743 %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
a0d0e21e 744
d55a8828 745While literal lists and named arrays are often interchangeable, that's
4633a7c4
LW
746not the case for hashes. Just because you can subscript a list value like
747a normal array does not mean that you can subscript a list value as a
748hash. Likewise, hashes included as parts of other lists (including
749parameters lists and return lists from functions) always flatten out into
750key/value pairs. That's why it's good to use references sometimes.
a0d0e21e 751
c47ff5f1
GS
752It is often more readable to use the C<< => >> operator between key/value
753pairs. The C<< => >> operator is mostly just a more visually distinctive
b88cefa9 754synonym for a comma, but it also arranges for its left-hand operand to be
ac036724 755interpreted as a string if it's a bareword that would be a legal simple
8fdd8881
FC
756identifier. C<< => >> doesn't quote compound identifiers, that contain
757double colons. This makes it nice for initializing hashes:
a0d0e21e 758
84f709e7 759 %map = (
7e3b091d
DA
760 red => 0x00f,
761 blue => 0x0f0,
762 green => 0xf00,
4633a7c4
LW
763 );
764
765or for initializing hash references to be used as records:
766
84f709e7 767 $rec = {
7e3b091d
DA
768 witch => 'Mable the Merciless',
769 cat => 'Fluffy the Ferocious',
770 date => '10/31/1776',
4633a7c4
LW
771 };
772
773or for using call-by-named-parameter to complicated functions:
774
84f709e7 775 $field = $query->radio_group(
7e3b091d 776 name => 'group_name',
4633a7c4
LW
777 values => ['eenie','meenie','minie'],
778 default => 'meenie',
779 linebreak => 'true',
84f709e7 780 labels => \%labels
4633a7c4 781 );
cb1a09d0
AD
782
783Note that just because a hash is initialized in that order doesn't
784mean that it comes out in that order. See L<perlfunc/sort> for examples
785of how to arrange for an output ordering.
786
c9e3649f
LM
787If a key appears more than once in the initializer list of a hash, the last
788occurrence wins:
789
790 %circle = (
791 center => [5, 10],
792 center => [27, 9],
793 radius => 100,
794 color => [0xDF, 0xFF, 0x00],
795 radius => 54,
796 );
797
798 # same as
799 %circle = (
800 center => [27, 9],
801 color => [0xDF, 0xFF, 0x00],
802 radius => 54,
803 );
804
805This can be used to provide overridable configuration defaults:
806
807 # values in %args take priority over %config_defaults
808 %config = (%config_defaults, %args);
809
692ef166
SF
810=head2 Subscripts
811
aa80e1dc
FC
812An array can be accessed one scalar at a
813time by specifying a dollar sign (C<$>), then the
692ef166
SF
814name of the array (without the leading C<@>), then the subscript inside
815square brackets. For example:
816
817 @myarray = (5, 50, 500, 5000);
2adc35dd 818 print "The Third Element is", $myarray[2], "\n";
692ef166 819
8fdd8881 820The array indices start with 0. A negative subscript retrieves its
692ef166
SF
821value from the end. In our example, C<$myarray[-1]> would have been
8225000, and C<$myarray[-2]> would have been 500.
823
824Hash subscripts are similar, only instead of square brackets curly brackets
8fdd8881 825are used. For example:
692ef166
SF
826
827 %scientists =
828 (
829 "Newton" => "Isaac",
830 "Einstein" => "Albert",
831 "Darwin" => "Charles",
832 "Feynman" => "Richard",
833 );
834
835 print "Darwin's First Name is ", $scientists{"Darwin"}, "\n";
836
aa80e1dc 837You can also subscript a list to get a single element from it:
d55a8828 838
aa80e1dc 839 $dir = (getpwnam("daemon"))[7];
d55a8828 840
9ed2a148
IG
841=head2 Multi-dimensional array emulation
842
843Multidimensional arrays may be emulated by subscripting a hash with a
8fdd8881 844list. The elements of the list are joined with the subscript separator
b8db74f2 845(see L<perlvar/$;>).
9ed2a148
IG
846
847 $foo{$a,$b,$c}
848
849is equivalent to
850
851 $foo{join($;, $a, $b, $c)}
852
853The default subscript separator is "\034", the same as SUBSEP in B<awk>.
854
aa80e1dc
FC
855=head2 Slices
856X<slice> X<array, slice> X<hash, slice>
d55a8828
TC
857
858A slice accesses several elements of a list, an array, or a hash
56d7751a
GS
859simultaneously using a list of subscripts. It's more convenient
860than writing out the individual elements as a list of separate
d55a8828
TC
861scalar values.
862
7e3b091d
DA
863 ($him, $her) = @folks[0,-1]; # array slice
864 @them = @folks[0 .. 3]; # array slice
865 ($who, $home) = @ENV{"USER", "HOME"}; # hash slice
866 ($uid, $dir) = (getpwnam("daemon"))[2,7]; # list slice
d55a8828
TC
867
868Since you can assign to a list of variables, you can also assign to
869an array or hash slice.
870
84f709e7 871 @days[3..5] = qw/Wed Thu Fri/;
d55a8828 872 @colors{'red','blue','green'}
7e3b091d 873 = (0xff0000, 0x0000ff, 0x00ff00);
d55a8828
TC
874 @folks[0, -1] = @folks[-1, 0];
875
876The previous assignments are exactly equivalent to
877
84f709e7
JH
878 ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
879 ($colors{'red'}, $colors{'blue'}, $colors{'green'})
7e3b091d 880 = (0xff0000, 0x0000ff, 0x00ff00);
88fd19e3 881 ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
d55a8828
TC
882
883Since changing a slice changes the original array or hash that it's
56d7751a
GS
884slicing, a C<foreach> construct will alter some--or even all--of the
885values of the array or hash.
d55a8828
TC
886
887 foreach (@array[ 4 .. 10 ]) { s/peter/paul/ }
888
00cb5da1 889 foreach (@hash{qw[key1 key2]}) {
7e3b091d
DA
890 s/^\s+//; # trim leading whitespace
891 s/\s+$//; # trim trailing whitespace
892 s/(\w+)/\u\L$1/g; # "titlecase" words
d55a8828
TC
893 }
894
08cd8952
GS
895A slice of an empty list is still an empty list. Thus:
896
84f709e7
JH
897 @a = ()[1,0]; # @a has no elements
898 @b = (@a)[0,1]; # @b has no elements
56d7751a
GS
899
900But:
901
84f709e7
JH
902 @a = (1)[1,0]; # @a has two elements
903 @b = (1,undef)[1,0,2]; # @b has three elements
08cd8952 904
f51152ef
AP
905More generally, a slice yields the empty list if it indexes only
906beyond the end of a list:
907
908 @a = (1)[ 1,2]; # @a has no elements
909 @b = (1)[0,1,2]; # @b has three elements
910
19799a22
GS
911This makes it easy to write loops that terminate when a null list
912is returned:
d55a8828 913
84f709e7 914 while ( ($home, $user) = (getpwent)[7,0]) {
7e3b091d 915 printf "%-8s %s\n", $user, $home;
d55a8828
TC
916 }
917
918As noted earlier in this document, the scalar sense of list assignment
919is the number of elements on the right-hand side of the assignment.
19799a22 920The null list contains no elements, so when the password file is
d55a8828
TC
921exhausted, the result is 0, not 2.
922
ad1de9c6
ML
923Slices in scalar context return the last item of the slice.
924
925 @a = qw/first second third/;
926 %h = (first => 'A', second => 'B');
927 $t = @a[0, 1]; # $t is now 'second'
0de10106 928 $u = @h{'first', 'second'}; # $u is now 'B'
ad1de9c6 929
d55a8828
TC
930If you're confused about why you use an '@' there on a hash slice
931instead of a '%', think of it like this. The type of bracket (square
932or curly) governs whether it's an array or a hash being looked at.
933On the other hand, the leading symbol ('$' or '@') on the array or
934hash indicates whether you are getting back a singular value (a
935scalar) or a plural one (a list).
936
8a7ab7dc 937=head3 Key/Value Hash Slices
23a22365 938
c44d7536
FC
939Starting in Perl 5.20, a hash slice operation
940with the % symbol is a variant of slice operation
190c3990 941returning a list of key/value pairs rather than just values:
23a22365 942
190c3990
FC
943 %h = (blonk => 2, foo => 3, squink => 5, bar => 8);
944 %subset = %h{'foo', 'bar'}; # key/value hash slice
945 # %subset is now (foo => 3, bar => 8)
23a22365 946
190c3990
FC
947However, the result of such a slice cannot be localized, deleted or used
948in assignment. These are otherwise very much consistent with hash slices
949using the @ symbol.
23a22365 950
8a7ab7dc 951=head3 Index/Value Array Slices
23a22365 952
c44d7536
FC
953Similar to key/value hash slices (and also introduced
954in Perl 5.20), the % array slice syntax returns a list
190c3990 955of index/value pairs:
23a22365 956
190c3990
FC
957 @a = "a".."z";
958 @list = %a[3,4,6];
959 # @list is now (3, "d", 4, "e", 6, "g")
23a22365 960
5f05dabc 961=head2 Typeglobs and Filehandles
d74e8afc 962X<typeglob> X<filehandle> X<*>
cb1a09d0
AD
963
964Perl uses an internal type called a I<typeglob> to hold an entire
965symbol table entry. The type prefix of a typeglob is a C<*>, because
54310121 966it represents all types. This used to be the preferred way to
cb1a09d0 967pass arrays and hashes by reference into a function, but now that
5a964f20
TC
968we have real references, this is seldom needed.
969
970The main use of typeglobs in modern Perl is create symbol table aliases.
971This assignment:
972
973 *this = *that;
974
975makes $this an alias for $that, @this an alias for @that, %this an alias
976for %that, &this an alias for &that, etc. Much safer is to use a reference.
977This:
5f05dabc 978
5a964f20
TC
979 local *Here::blue = \$There::green;
980
981temporarily makes $Here::blue an alias for $There::green, but doesn't
982make @Here::blue an alias for @There::green, or %Here::blue an alias for
983%There::green, etc. See L<perlmod/"Symbol Tables"> for more examples
984of this. Strange though this may seem, this is the basis for the whole
84f709e7 985module import/export system.
5a964f20 986
d55a8828 987Another use for typeglobs is to pass filehandles into a function or
5a964f20
TC
988to create new filehandles. If you need to use a typeglob to save away
989a filehandle, do it this way:
5f05dabc 990
84f709e7 991 $fh = *STDOUT;
5f05dabc
PP
992
993or perhaps as a real reference, like this:
994
84f709e7 995 $fh = \*STDOUT;
5f05dabc 996
5a964f20
TC
997See L<perlsub> for examples of using these as indirect filehandles
998in functions.
999
1000Typeglobs are also a way to create a local filehandle using the local()
1001operator. These last until their block is exited, but may be passed back.
1002For example:
5f05dabc
PP
1003
1004 sub newopen {
7e3b091d
DA
1005 my $path = shift;
1006 local *FH; # not my!
1007 open (FH, $path) or return undef;
1008 return *FH;
5f05dabc 1009 }
84f709e7 1010 $fh = newopen('/etc/passwd');
5f05dabc 1011
d55a8828 1012Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
5a964f20 1013for filehandle manipulations, although they're still needed to pass brand
8fdd8881 1014new file and directory handles into or out of functions. That's because
d55a8828
TC
1015C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
1016In other words, C<*FH> must be used to create new symbol table entries;
1017C<*foo{THING}> cannot. When in doubt, use C<*FH>.
1018
36392fcf
GS
1019All functions that are capable of creating filehandles (open(),
1020opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
1021automatically create an anonymous filehandle if the handle passed to
8fdd8881 1022them is an uninitialized scalar variable. This allows the constructs
36392fcf
GS
1023such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
1024create filehandles that will conveniently be closed automatically when
8fdd8881 1025the scope ends, provided there are no other references to them. This
36392fcf
GS
1026largely eliminates the need for typeglobs when opening filehandles
1027that must be passed around, as in the following example:
1028
1029 sub myopen {
84f709e7 1030 open my $fh, "@_"
7e3b091d
DA
1031 or die "Can't open '@_': $!";
1032 return $fh;
36392fcf
GS
1033 }
1034
1035 {
1036 my $f = myopen("</etc/motd");
7e3b091d
DA
1037 print <$f>;
1038 # $f implicitly closed here
36392fcf
GS
1039 }
1040
b92795fe
AMS
1041Note that if an initialized scalar variable is used instead the
1042result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent
1043to C<open( *{'zzz'}, ...)>.
d83fe814
AT
1044C<use strict 'refs'> forbids such practice.
1045
d55a8828
TC
1046Another way to create anonymous filehandles is with the Symbol
1047module or with the IO::Handle module and its ilk. These modules
1048have the advantage of not hiding different types of the same name
66b6e4ad
KW
1049during the local(). See the bottom of L<perlfunc/open> for an
1050example.
d55a8828
TC
1051
1052=head1 SEE ALSO
1053
1054See L<perlvar> for a description of Perl's built-in variables and
1055a discussion of legal variable names. See L<perlref>, L<perlsub>,
1056and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
1057the C<*foo{THING}> syntax.