This is a live mirror of the Perl 5 development currently hosted at
doubled words in pods (from Simon Cozens
[perl5.git] / pod / perlopentut.pod
1=head1 NAME
3perlopentut - tutorial on opening things in Perl
7Perl has two simple, built-in ways to open files: the shell way for
8convenience, and the C way for precision. The choice is yours.
10=head1 Open E<agrave> la shell
12Perl's C<open> function was designed to mimic the way command-line
13redirection in the shell works. Here are some basic examples
14from the shell:
16 $ myprogram file1 file2 file3
17 $ myprogram < inputfile
18 $ myprogram > outputfile
19 $ myprogram >> outputfile
20 $ myprogram | otherprogram
21 $ otherprogram | myprogram
23And here are some more advanced examples:
25 $ otherprogram | myprogram f1 - f2
26 $ otherprogram 2>&1 | myprogram -
27 $ myprogram <&3
28 $ myprogram >&4
30Programmers accustomed to constructs like those above can take comfort
31in learning that Perl directly supports these familiar constructs using
32virtually the same syntax as the shell.
34=head2 Simple Opens
36The C<open> function takes two arguments: the first is a filehandle,
37and the second is a single string comprising both what to open and how
38to open it. C<open> returns true when it works, and when it fails,
39returns a false value and sets the special variable $! to reflect
40the system error. If the filehandle was previously opened, it will
41be implicitly closed first.
43For example:
45 open(INFO, "datafile") || die("can't open datafile: $!");
46 open(INFO, "< datafile") || die("can't open datafile: $!");
47 open(RESULTS,"> runstats") || die("can't open runstats: $!");
48 open(LOG, ">> logfile ") || die("can't open logfile: $!");
50If you prefer the low-punctuation version, you could write that this way:
52 open INFO, "< datafile" or die "can't open datafile: $!";
53 open RESULTS,"> runstats" or die "can't open runstats: $!";
54 open LOG, ">> logfile " or die "can't open logfile: $!";
56A few things to notice. First, the leading less-than is optional.
57If omitted, Perl assumes that you want to open the file for reading.
59The other important thing to notice is that, just as in the shell,
60any white space before or after the filename is ignored. This is good,
61because you wouldn't want these to do different things:
63 open INFO, "<datafile"
64 open INFO, "< datafile"
65 open INFO, "< datafile"
67Ignoring surround whitespace also helps for when you read a filename in
68from a different file, and forget to trim it before opening:
70 $filename = <INFO>; # oops, \n still there
71 open(EXTRA, "< $filename") || die "can't open $filename: $!";
73This is not a bug, but a feature. Because C<open> mimics the shell in
74its style of using redirection arrows to specify how to open the file, it
75also does so with respect to extra white space around the filename itself
19799a22 76as well. For accessing files with naughty names, see L<"Dispelling
77the Dweomer">.
79=head2 Pipe Opens
81In C, when you want to open a file using the standard I/O library,
82you use the C<fopen> function, but when opening a pipe, you use the
83C<popen> function. But in the shell, you just use a different redirection
84character. That's also the case for Perl. The C<open> call
85remains the same--just its argument differs.
f5daac4a 87If the leading character is a pipe symbol, C<open> starts up a new
88command and open a write-only filehandle leading into that command.
89This lets you write into that handle and have what you write show up on
90that command's standard input. For example:
92 open(PRINTER, "| lpr -Plp1") || die "cannot fork: $!";
93 print PRINTER "stuff\n";
94 close(PRINTER) || die "can't close lpr: $!";
96If the trailing character is a pipe, you start up a new command and open a
97read-only filehandle leading out of that command. This lets whatever that
98command writes to its standard output show up on your handle for reading.
99For example:
101 open(NET, "netstat -i -n |") || die "cannot fork: $!";
102 while (<NET>) { } # do something with input
103 close(NET) || die "can't close netstat: $!";
105What happens if you try to open a pipe to or from a non-existent command?
106In most systems, such an C<open> will not return an error. That's
107because in the traditional C<fork>/C<exec> model, running the other
108program happens only in the forked child process, which means that
109the failed C<exec> can't be reflected in the return value of C<open>.
110Only a failed C<fork> shows up there. See L<perlfaq8/"Why doesn't open()
111return an error when a pipe open fails?"> to see how to cope with this.
112There's also an explanation in L<perlipc>.
114If you would like to open a bidirectional pipe, the IPC::Open2
115library will handle this for you. Check out L<perlipc/"Bidirectional
116Communication with Another Process">
118=head2 The Minus File
120Again following the lead of the standard shell utilities, Perl's
121C<open> function treats a file whose name is a single minus, "-", in a
122special way. If you open minus for reading, it really means to access
123the standard input. If you open minus for writing, it really means to
124access the standard output.
40b7eeef 126If minus can be used as the default input or default output, what happens
f8284313 127if you open a pipe into or out of minus? What's the default command it
40b7eeef 128would run? The same script as you're currently running! This is actually
129a stealth C<fork> hidden inside an C<open> call. See L<perlipc/"Safe Pipe
130Opens"> for details.
132=head2 Mixing Reads and Writes
134It is possible to specify both read and write access. All you do is
135add a "+" symbol in front of the redirection. But as in the shell,
136using a less-than on a file never creates a new file; it only opens an
137existing one. On the other hand, using a greater-than always clobbers
138(truncates to zero length) an existing file, or creates a brand-new one
139if there isn't an old one. Adding a "+" for read-write doesn't affect
140whether it only works on existing files or always clobbers existing ones.
142 open(WTMP, "+< /usr/adm/wtmp")
143 || die "can't open /usr/adm/wtmp: $!";
145 open(SCREEN, "+> /tmp/lkscreen")
146 || die "can't open /tmp/lkscreen: $!";
148 open(LOGFILE, "+>> /tmp/applog"
149 || die "can't open /tmp/applog: $!";
151The first one won't create a new file, and the second one will always
152clobber an old one. The third one will create a new file if necessary
153and not clobber an old one, and it will allow you to read at any point
154in the file, but all writes will always go to the end. In short,
155the first case is substantially more common than the second and third
156cases, which are almost always wrong. (If you know C, the plus in
157Perl's C<open> is historically derived from the one in C's fopen(3S),
158which it ultimately calls.)
160In fact, when it comes to updating a file, unless you're working on
161a binary file as in the WTMP case above, you probably don't want to
162use this approach for updating. Instead, Perl's B<-i> flag comes to
163the rescue. The following command takes all the C, C++, or yacc source
164or header files and changes all their foo's to bar's, leaving
165the old version in the original file name with a ".orig" tacked
166on the end:
168 $ perl -i.orig -pe 's/\bfoo\b/bar/g' *.[Cchy]
170This is a short cut for some renaming games that are really
171the best way to update textfiles. See the second question in
172L<perlfaq5> for more details.
174=head2 Filters
176One of the most common uses for C<open> is one you never
177even notice. When you process the ARGV filehandle using
c47ff5f1 178C<< <ARGV> >>, Perl actually does an implicit open
179on each file in @ARGV. Thus a program called like this:
181 $ myprogram file1 file2 file3
183Can have all its files opened and processed one at a time
184using a construct no more complex than:
186 while (<>) {
187 # do something with $_
188 }
190If @ARGV is empty when the loop first begins, Perl pretends you've opened
191up minus, that is, the standard input. In fact, $ARGV, the currently
c47ff5f1 192open file during C<< <ARGV> >> processing, is even set to "-"
193in these circumstances.
195You are welcome to pre-process your @ARGV before starting the loop to
196make sure it's to your liking. One reason to do this might be to remove
197command options beginning with a minus. While you can always roll the
198simple ones by hand, the Getopts modules are good for this.
200 use Getopt::Std;
202 # -v, -D, -o ARG, sets $opt_v, $opt_D, $opt_o
203 getopts("vDo:");
205 # -v, -D, -o ARG, sets $args{v}, $args{D}, $args{o}
206 getopts("vDo:", \%args);
208Or the standard Getopt::Long module to permit named arguments:
210 use Getopt::Long;
211 GetOptions( "verbose" => \$verbose, # --verbose
212 "Debug" => \$debug, # --Debug
213 "output=s" => \$output );
214 # --output=somestring or --output somestring
216Another reason for preprocessing arguments is to make an empty
217argument list default to all files:
219 @ARGV = glob("*") unless @ARGV;
221You could even filter out all but plain, text files. This is a bit
222silent, of course, and you might prefer to mention them on the way.
224 @ARGV = grep { -f && -T } @ARGV;
226If you're using the B<-n> or B<-p> command-line options, you
227should put changes to @ARGV in a C<BEGIN{}> block.
229Remember that a normal C<open> has special properties, in that it might
230call fopen(3S) or it might called popen(3S), depending on what its
231argument looks like; that's why it's sometimes called "magic open".
232Here's an example:
234 $pwdinfo = `domainname` =~ /^(\(none\))?$/
235 ? '< /etc/passwd'
236 : 'ypcat passwd |';
238 open(PWD, $pwdinfo)
239 or die "can't open $pwdinfo: $!";
241This sort of thing also comes into play in filter processing. Because
c47ff5f1 242C<< <ARGV> >> processing employs the normal, shell-style Perl C<open>,
243it respects all the special things we've already seen:
245 $ myprogram f1 "cmd1|" - f2 "cmd2|" f3 < tmpfile
247That program will read from the file F<f1>, the process F<cmd1>, standard
248input (F<tmpfile> in this case), the F<f2> file, the F<cmd2> command,
249and finally the F<f3> file.
251Yes, this also means that if you have a file named "-" (and so on) in
252your directory, that they won't be processed as literal files by C<open>.
253You'll need to pass them as "./-" much as you would for the I<rm> program.
254Or you could use C<sysopen> as described below.
256One of the more interesting applications is to change files of a certain
257name into pipes. For example, to autoprocess gzipped or compressed
258files by decompressing them with I<gzip>:
260 @ARGV = map { /^\.(gz|Z)$/ ? "gzip -dc $_ |" : $_ } @ARGV;
262Or, if you have the I<GET> program installed from LWP,
263you can fetch URLs before processing them:
265 @ARGV = map { m#^\w+://# ? "GET $_ |" : $_ } @ARGV;
c47ff5f1 267It's not for nothing that this is called magic C<< <ARGV> >>.
268Pretty nifty, eh?
270=head1 Open E<agrave> la C
272If you want the convenience of the shell, then Perl's C<open> is
273definitely the way to go. On the other hand, if you want finer precision
274than C's simplistic fopen(3S) provides, then you should look to Perl's
275C<sysopen>, which is a direct hook into the open(2) system call.
276That does mean it's a bit more involved, but that's the price of
279C<sysopen> takes 3 (or 4) arguments.
281 sysopen HANDLE, PATH, FLAGS, [MASK]
283The HANDLE argument is a filehandle just as with C<open>. The PATH is
284a literal path, one that doesn't pay attention to any greater-thans or
285less-thans or pipes or minuses, nor ignore white space. If it's there,
286it's part of the path. The FLAGS argument contains one or more values
287derived from the Fcntl module that have been or'd together using the
288bitwise "|" operator. The final argument, the MASK, is optional; if
289present, it is combined with the user's current umask for the creation
290mode of the file. You should usually omit this.
292Although the traditional values of read-only, write-only, and read-write
293are 0, 1, and 2 respectively, this is known not to hold true on some
294systems. Instead, it's best to load in the appropriate constants first
295from the Fcntl module, which supplies the following standard flags:
297 O_RDONLY Read only
298 O_WRONLY Write only
299 O_RDWR Read and write
300 O_CREAT Create the file if it doesn't exist
301 O_EXCL Fail if the file already exists
302 O_APPEND Append to the file
303 O_TRUNC Truncate the file
304 O_NONBLOCK Non-blocking access
306Less common flags that are sometimes available on some operating
307systems include C<O_BINARY>, C<O_TEXT>, C<O_SHLOCK>, C<O_EXLOCK>,
309C<O_NOCTTY>, C<O_NDELAY> and C<O_LARGEFILE>. Consult your open(2)
310manpage or its local equivalent for details. (Note: starting from
311Perl release 5.6 the O_LARGEFILE flag, if available, is automatically
106325ad 312added to the sysopen() flags because large files are the default.)
314Here's how to use C<sysopen> to emulate the simple C<open> calls we had
315before. We'll omit the C<|| die $!> checks for clarity, but make sure
316you always check the return values in real code. These aren't quite
317the same, since C<open> will trim leading and trailing white space,
318but you'll get the idea:
320To open a file for reading:
322 open(FH, "< $path");
323 sysopen(FH, $path, O_RDONLY);
325To open a file for writing, creating a new file if needed or else truncating
326an old file:
328 open(FH, "> $path");
329 sysopen(FH, $path, O_WRONLY | O_TRUNC | O_CREAT);
331To open a file for appending, creating one if necessary:
333 open(FH, ">> $path");
334 sysopen(FH, $path, O_WRONLY | O_APPEND | O_CREAT);
336To open a file for update, where the file must already exist:
338 open(FH, "+< $path");
339 sysopen(FH, $path, O_RDWR);
341And here are things you can do with C<sysopen> that you cannot do with
342a regular C<open>. As you see, it's just a matter of controlling the
343flags in the third argument.
345To open a file for writing, creating a new file which must not previously
348 sysopen(FH, $path, O_WRONLY | O_EXCL | O_CREAT);
350To open a file for appending, where that file must already exist:
352 sysopen(FH, $path, O_WRONLY | O_APPEND);
354To open a file for update, creating a new file if necessary:
356 sysopen(FH, $path, O_RDWR | O_CREAT);
358To open a file for update, where that file must not already exist:
360 sysopen(FH, $path, O_RDWR | O_EXCL | O_CREAT);
362To open a file without blocking, creating one if necessary:
364 sysopen(FH, $path, O_WRONLY | O_NONBLOCK | O_CREAT);
366=head2 Permissions E<agrave> la mode
368If you omit the MASK argument to C<sysopen>, Perl uses the octal value
3690666. The normal MASK to use for executables and directories should
370be 0777, and for anything else, 0666.
372Why so permissive? Well, it isn't really. The MASK will be modified
373by your process's current C<umask>. A umask is a number representing
374I<disabled> permissions bits; that is, bits that will not be turned on
375in the created files' permissions field.
377For example, if your C<umask> were 027, then the 020 part would
378disable the group from writing, and the 007 part would disable others
379from reading, writing, or executing. Under these conditions, passing
380C<sysopen> 0666 would create a file with mode 0640, since C<0666 &~ 027>
381is 0640.
383You should seldom use the MASK argument to C<sysopen()>. That takes
384away the user's freedom to choose what permission new files will have.
385Denying choice is almost always a bad thing. One exception would be for
386cases where sensitive or private data is being stored, such as with mail
387folders, cookie files, and internal temporary files.
389=head1 Obscure Open Tricks
391=head2 Re-Opening Files (dups)
393Sometimes you already have a filehandle open, and want to make another
394handle that's a duplicate of the first one. In the shell, we place an
395ampersand in front of a file descriptor number when doing redirections.
c47ff5f1 396For example, C<< 2>&1 >> makes descriptor 2 (that's STDERR in Perl)
397be redirected into descriptor 1 (which is usually Perl's STDOUT).
398The same is essentially true in Perl: a filename that begins with an
399ampersand is treated instead as a file descriptor if a number, or as a
400filehandle if a string.
402 open(SAVEOUT, ">&SAVEERR") || die "couldn't dup SAVEERR: $!";
403 open(MHCONTEXT, "<&4") || die "couldn't dup fd4: $!";
405That means that if a function is expecting a filename, but you don't
406want to give it a filename because you already have the file open, you
407can just pass the filehandle with a leading ampersand. It's best to
408use a fully qualified handle though, just in case the function happens
409to be in a different package:
411 somefunction("&main::LOGFILE");
413This way if somefunction() is planning on opening its argument, it can
414just use the already opened handle. This differs from passing a handle,
415because with a handle, you don't open the file. Here you have something
416you can pass to open.
418If you have one of those tricky, newfangled I/O objects that the C++
419folks are raving about, then this doesn't work because those aren't a
420proper filehandle in the native Perl sense. You'll have to use fileno()
421to pull out the proper descriptor number, assuming you can:
423 use IO::Socket;
424 $handle = IO::Socket::INET->new("");
425 $fd = $handle->fileno;
426 somefunction("&$fd"); # not an indirect function call
428It can be easier (and certainly will be faster) just to use real
429filehandles though:
431 use IO::Socket;
432 local *REMOTE = IO::Socket::INET->new("");
433 die "can't connect" unless defined(fileno(REMOTE));
434 somefunction("&main::REMOTE");
436If the filehandle or descriptor number is preceded not just with a simple
437"&" but rather with a "&=" combination, then Perl will not create a
438completely new descriptor opened to the same place using the dup(2)
439system call. Instead, it will just make something of an alias to the
440existing one using the fdopen(3S) library call This is slightly more
441parsimonious of systems resources, although this is less a concern
442these days. Here's an example of that:
444 $fd = $ENV{"MHCONTEXTFD"};
445 open(MHCONTEXT, "<&=$fd") or die "couldn't fdopen $fd: $!";
447If you're using magic C<< <ARGV> >>, you could even pass in as a
448command line argument in @ARGV something like C<"<&=$MHCONTEXTFD">,
449but we've never seen anyone actually do this.
451=head2 Dispelling the Dweomer
453Perl is more of a DWIMmer language than something like Java--where DWIM
454is an acronym for "do what I mean". But this principle sometimes leads
455to more hidden magic than one knows what to do with. In this way, Perl
456is also filled with I<dweomer>, an obscure word meaning an enchantment.
457Sometimes, Perl's DWIMmer is just too much like dweomer for comfort.
459If magic C<open> is a bit too magical for you, you don't have to turn
460to C<sysopen>. To open a file with arbitrary weird characters in
461it, it's necessary to protect any leading and trailing whitespace.
462Leading whitespace is protected by inserting a C<"./"> in front of a
463filename that starts with whitespace. Trailing whitespace is protected
464by appending an ASCII NUL byte (C<"\0">) at the end off the string.
466 $file =~ s#^(\s)#./$1#;
467 open(FH, "< $file\0") || die "can't open $file: $!";
469This assumes, of course, that your system considers dot the current
470working directory, slash the directory separator, and disallows ASCII
471NULs within a valid filename. Most systems follow these conventions,
472including all POSIX systems as well as proprietary Microsoft systems.
473The only vaguely popular system that doesn't work this way is the
474proprietary Macintosh system, which uses a colon where the rest of us
475use a slash. Maybe C<sysopen> isn't such a bad idea after all.
c47ff5f1 477If you want to use C<< <ARGV> >> processing in a totally boring
478and non-magical way, you could do this first:
480 # "Sam sat on the ground and put his head in his hands.
481 # 'I wish I had never come here, and I don't want to see
482 # no more magic,' he said, and fell silent."
483 for (@ARGV) {
484 s#^([^./])#./$1#;
485 $_ .= "\0";
486 }
487 while (<>) {
488 # now process $_
489 }
491But be warned that users will not appreciate being unable to use "-"
492to mean standard input, per the standard convention.
494=head2 Paths as Opens
496You've probably noticed how Perl's C<warn> and C<die> functions can
497produce messages like:
1761cee5 499 Some warning at scriptname line 29, <FH> line 7.
501That's because you opened a filehandle FH, and had read in seven records
502from it. But what was the name of the file, not the handle?
504If you aren't running with C<strict refs>, or if you've turn them off
505temporarily, then all you have to do is this:
507 open($path, "< $path") || die "can't open $path: $!";
508 while (<$path>) {
509 # whatever
510 }
512Since you're using the pathname of the file as its handle,
513you'll get warnings more like
1761cee5 515 Some warning at scriptname line 29, </etc/motd> line 7.
517=head2 Single Argument Open
519Remember how we said that Perl's open took two arguments? That was a
520passive prevarication. You see, it can also take just one argument.
521If and only if the variable is a global variable, not a lexical, you
522can pass C<open> just one argument, the filehandle, and it will
523get the path from the global scalar variable of the same name.
525 $FILE = "/etc/motd";
526 open FILE or die "can't open $FILE: $!";
527 while (<FILE>) {
528 # whatever
529 }
531Why is this here? Someone has to cater to the hysterical porpoises.
532It's something that's been in Perl since the very beginning, if not
535=head2 Playing with STDIN and STDOUT
537One clever move with STDOUT is to explicitly close it when you're done
538with the program.
540 END { close(STDOUT) || die "can't close stdout: $!" }
542If you don't do this, and your program fills up the disk partition due
543to a command line redirection, it won't report the error exit with a
544failure status.
546You don't have to accept the STDIN and STDOUT you were given. You are
547welcome to reopen them if you'd like.
549 open(STDIN, "< datafile")
550 || die "can't open datafile: $!";
552 open(STDOUT, "> output")
553 || die "can't open output: $!";
555And then these can be read directly or passed on to subprocesses.
556This makes it look as though the program were initially invoked
557with those redirections from the command line.
559It's probably more interesting to connect these to pipes. For example:
561 $pager = $ENV{PAGER} || "(less || more)";
562 open(STDOUT, "| $pager")
563 || die "can't fork a pager: $!";
565This makes it appear as though your program were called with its stdout
566already piped into your pager. You can also use this kind of thing
567in conjunction with an implicit fork to yourself. You might do this
568if you would rather handle the post processing in your own program,
569just in a different process:
571 head(100);
572 while (<>) {
573 print;
574 }
576 sub head {
577 my $lines = shift || 20;
578 return unless $pid = open(STDOUT, "|-");
579 die "cannot fork: $!" unless defined $pid;
580 while (<STDIN>) {
581 print;
582 last if --$lines < 0;
583 }
584 exit;
585 }
587This technique can be applied to repeatedly push as many filters on your
588output stream as you wish.
590=head1 Other I/O Issues
592These topics aren't really arguments related to C<open> or C<sysopen>,
593but they do affect what you do with your open files.
595=head2 Opening Non-File Files
597When is a file not a file? Well, you could say when it exists but
598isn't a plain file. We'll check whether it's a symbolic link first,
599just in case.
601 if (-l $file || ! -f _) {
602 print "$file is not a plain file\n";
603 }
605What other kinds of files are there than, well, files? Directories,
606symbolic links, named pipes, Unix-domain sockets, and block and character
607devices. Those are all files, too--just not I<plain> files. This isn't
608the same issue as being a text file. Not all text files are plain files.
609Not all plain files are textfiles. That's why there are separate C<-f>
610and C<-T> file tests.
612To open a directory, you should use the C<opendir> function, then
613process it with C<readdir>, carefully restoring the directory
614name if necessary:
616 opendir(DIR, $dirname) or die "can't opendir $dirname: $!";
617 while (defined($file = readdir(DIR))) {
618 # do something with "$dirname/$file"
619 }
620 closedir(DIR);
622If you want to process directories recursively, it's better to use the
623File::Find module. For example, this prints out all files recursively,
624add adds a slash to their names if the file is a directory.
626 @ARGV = qw(.) unless @ARGV;
627 use File::Find;
628 find sub { print $File::Find::name, -d && '/', "\n" }, @ARGV;
630This finds all bogus symbolic links beneath a particular directory:
632 find sub { print "$File::Find::name\n" if -l && !-e }, $dir;
634As you see, with symbolic links, you can just pretend that it is
635what it points to. Or, if you want to know I<what> it points to, then
636C<readlink> is called for:
638 if (-l $file) {
639 if (defined($whither = readlink($file))) {
640 print "$file points to $whither\n";
641 } else {
642 print "$file points nowhere: $!\n";
643 }
644 }
646Named pipes are a different matter. You pretend they're regular files,
647but their opens will normally block until there is both a reader and
648a writer. You can read more about them in L<perlipc/"Named Pipes">.
649Unix-domain sockets are rather different beasts as well; they're
650described in L<perlipc/"Unix-Domain TCP Clients and Servers">.
652When it comes to opening devices, it can be easy and it can tricky.
653We'll assume that if you're opening up a block device, you know what
654you're doing. The character devices are more interesting. These are
655typically used for modems, mice, and some kinds of printers. This is
656described in L<perlfaq8/"How do I read and write the serial port?">
657It's often enough to open them carefully:
659 sysopen(TTYIN, "/dev/ttyS1", O_RDWR | O_NDELAY | O_NOCTTY)
660 # (O_NOCTTY no longer needed on POSIX systems)
661 or die "can't open /dev/ttyS1: $!";
662 open(TTYOUT, "+>&TTYIN")
663 or die "can't dup TTYIN: $!";
665 $ofh = select(TTYOUT); $| = 1; select($ofh);
667 print TTYOUT "+++at\015";
668 $answer = <TTYIN>;
670With descriptors that you haven't opened using C<sysopen>, such as a
671socket, you can set them to be non-blocking using C<fcntl>:
673 use Fcntl;
674 fcntl(Connection, F_SETFL, O_NONBLOCK)
675 or die "can't set non blocking: $!";
677Rather than losing yourself in a morass of twisting, turning C<ioctl>s,
678all dissimilar, if you're going to manipulate ttys, it's best to
679make calls out to the stty(1) program if you have it, or else use the
680portable POSIX interface. To figure this all out, you'll need to read the
681termios(3) manpage, which describes the POSIX interface to tty devices,
682and then L<POSIX>, which describes Perl's interface to POSIX. There are
683also some high-level modules on CPAN that can help you with these games.
684Check out Term::ReadKey and Term::ReadLine.
686What else can you open? To open a connection using sockets, you won't use
687one of Perl's two open functions. See L<perlipc/"Sockets: Client/Server
688Communication"> for that. Here's an example. Once you have it,
689you can use FH as a bidirectional filehandle.
691 use IO::Socket;
692 local *FH = IO::Socket::INET->new("");
694For opening up a URL, the LWP modules from CPAN are just what
695the doctor ordered. There's no filehandle interface, but
696it's still easy to get the contents of a document:
698 use LWP::Simple;
6cecdcac 699 $doc = get('');
701=head2 Binary Files
703On certain legacy systems with what could charitably be called terminally
704convoluted (some would say broken) I/O models, a file isn't a file--at
705least, not with respect to the C standard I/O library. On these old
706systems whose libraries (but not kernels) distinguish between text and
707binary streams, to get files to behave properly you'll have to bend over
708backwards to avoid nasty problems. On such infelicitous systems, sockets
709and pipes are already opened in binary mode, and there is currently no
710way to turn that off. With files, you have more options.
712Another option is to use the C<binmode> function on the appropriate
713handles before doing regular I/O on them:
715 binmode(STDIN);
716 binmode(STDOUT);
717 while (<STDIN>) { print }
719Passing C<sysopen> a non-standard flag option will also open the file in
720binary mode on those systems that support it. This is the equivalent of
721opening the file normally, then calling C<binmode>ing on the handle.
723 sysopen(BINDAT, "", O_RDWR | O_BINARY)
724 || die "can't open $!";
726Now you can use C<read> and C<print> on that handle without worrying
727about the system non-standard I/O library breaking your data. It's not
728a pretty picture, but then, legacy systems seldom are. CP/M will be
729with us until the end of days, and after.
731On systems with exotic I/O systems, it turns out that, astonishingly
732enough, even unbuffered I/O using C<sysread> and C<syswrite> might do
733sneaky data mutilation behind your back.
735 while (sysread(WHENCE, $buf, 1024)) {
736 syswrite(WHITHER, $buf, length($buf));
737 }
739Depending on the vicissitudes of your runtime system, even these calls
740may need C<binmode> or C<O_BINARY> first. Systems known to be free of
741such difficulties include Unix, the Mac OS, Plan9, and Inferno.
743=head2 File Locking
745In a multitasking environment, you may need to be careful not to collide
746with other processes who want to do I/O on the same files as others
747are working on. You'll often need shared or exclusive locks
748on files for reading and writing respectively. You might just
749pretend that only exclusive locks exist.
751Never use the existence of a file C<-e $file> as a locking indication,
752because there is a race condition between the test for the existence of
753the file and its creation. Atomicity is critical.
755Perl's most portable locking interface is via the C<flock> function,
756whose simplicity is emulated on systems that don't directly support it,
757such as SysV or WindowsNT. The underlying semantics may affect how
758it all works, so you should learn how C<flock> is implemented on your
759system's port of Perl.
761File locking I<does not> lock out another process that would like to
762do I/O. A file lock only locks out others trying to get a lock, not
763processes trying to do I/O. Because locks are advisory, if one process
764uses locking and another doesn't, all bets are off.
766By default, the C<flock> call will block until a lock is granted.
767A request for a shared lock will be granted as soon as there is no
768exclusive locker. A request for a exclusive lock will be granted as
769soon as there is no locker of any kind. Locks are on file descriptors,
770not file names. You can't lock a file until you open it, and you can't
771hold on to a lock once the file has been closed.
773Here's how to get a blocking shared lock on a file, typically used
774for reading:
776 use 5.004;
777 use Fcntl qw(:DEFAULT :flock);
778 open(FH, "< filename") or die "can't open filename: $!";
779 flock(FH, LOCK_SH) or die "can't lock filename: $!";
780 # now read from FH
782You can get a non-blocking lock by using C<LOCK_NB>.
784 flock(FH, LOCK_SH | LOCK_NB)
785 or die "can't lock filename: $!";
787This can be useful for producing more user-friendly behaviour by warning
788if you're going to be blocking:
790 use 5.004;
791 use Fcntl qw(:DEFAULT :flock);
792 open(FH, "< filename") or die "can't open filename: $!";
793 unless (flock(FH, LOCK_SH | LOCK_NB)) {
794 $| = 1;
795 print "Waiting for lock...";
796 flock(FH, LOCK_SH) or die "can't lock filename: $!";
797 print "got it.\n"
798 }
799 # now read from FH
801To get an exclusive lock, typically used for writing, you have to be
802careful. We C<sysopen> the file so it can be locked before it gets
803emptied. You can get a nonblocking version using C<LOCK_EX | LOCK_NB>.
805 use 5.004;
806 use Fcntl qw(:DEFAULT :flock);
807 sysopen(FH, "filename", O_WRONLY | O_CREAT)
808 or die "can't open filename: $!";
809 flock(FH, LOCK_EX)
810 or die "can't lock filename: $!";
811 truncate(FH, 0)
812 or die "can't truncate filename: $!";
813 # now write to FH
815Finally, due to the uncounted millions who cannot be dissuaded from
816wasting cycles on useless vanity devices called hit counters, here's
817how to increment a number in a file safely:
819 use Fcntl qw(:DEFAULT :flock);
821 sysopen(FH, "numfile", O_RDWR | O_CREAT)
822 or die "can't open numfile: $!";
823 # autoflush FH
824 $ofh = select(FH); $| = 1; select ($ofh);
825 flock(FH, LOCK_EX)
826 or die "can't write-lock numfile: $!";
828 $num = <FH> || 0;
829 seek(FH, 0, 0)
830 or die "can't rewind numfile : $!";
831 print FH $num+1, "\n"
832 or die "can't write numfile: $!";
834 truncate(FH, tell(FH))
835 or die "can't truncate numfile: $!";
836 close(FH)
837 or die "can't close numfile: $!";
839=head1 SEE ALSO
841The C<open> and C<sysopen> function in perlfunc(1);
842the standard open(2), dup(2), fopen(3), and fdopen(3) manpages;
843the POSIX documentation.
845=head1 AUTHOR and COPYRIGHT
847Copyright 1998 Tom Christiansen.
849When included as part of the Standard Version of Perl, or as part of
850its complete documentation whether printed or otherwise, this work may
851be distributed only under the terms of Perl's Artistic License. Any
852distribution of this file or derivatives thereof outside of that
853package require that special arrangements be made with copyright
856Irrespective of its distribution, all code examples in these files are
857hereby placed into the public domain. You are permitted and
858encouraged to use this code in your own programs for fun or for profit
859as you see fit. A simple comment in the code giving credit would be
860courteous but is not required.
862=head1 HISTORY
864First release: Sat Jan 9 08:09:11 MST 1999