This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Integrate with Sarathy.
[perl5.git] / lib / Pod / Man.pm
CommitLineData
9741dab0 1# Pod::Man -- Convert POD data to formatted *roff input.
c9abbd5d 2# $Id: Man.pm,v 1.0 2000/03/06 10:16:31 eagle Exp $
9741dab0 3#
c9abbd5d 4# Copyright 1999, 2000 by Russ Allbery <rra@stanford.edu>
9741dab0
GS
5#
6# This program is free software; you can redistribute it and/or modify it
7# under the same terms as Perl itself.
8#
c9abbd5d
GS
9# This module is intended to be a replacement for the pod2man script
10# distributed with versions of Perl prior to 5.6, and attempts to match its
11# output except for some specific circumstances where other decisions seemed
12# to produce better output. It uses Pod::Parser and is designed to be easy
13# to subclass.
14#
15# Perl core hackers, please note that this module is also separately
16# maintained outside of the Perl core as part of the podlators. Please send
17# me any patches at the address above in addition to sending them to the
18# standard Perl mailing lists.
9741dab0
GS
19
20############################################################################
21# Modules and declarations
22############################################################################
23
24package Pod::Man;
25
26require 5.004;
27
28use Carp qw(carp croak);
29use Pod::Parser ();
30
31use strict;
32use subs qw(makespace);
33use vars qw(@ISA %ESCAPES $PREAMBLE $VERSION);
34
35@ISA = qw(Pod::Parser);
36
c9abbd5d
GS
37# Don't use the CVS revision as the version, since this module is also in
38# Perl core and too many things could munge CVS magic revision strings.
39# This number should ideally be the same as the CVS revision in podlators,
40# however.
41$VERSION = 1.00;
9741dab0
GS
42
43
44############################################################################
45# Preamble and *roff output tables
46############################################################################
47
48# The following is the static preamble which starts all *roff output we
49# generate. It's completely static except for the font to use as a
50# fixed-width font, which is designed by @CFONT@. $PREAMBLE should
51# therefore be run through s/\@CFONT\@/<font>/g before output.
52$PREAMBLE = <<'----END OF PREAMBLE----';
53.de Sh \" Subsection heading
54.br
55.if t .Sp
56.ne 5
57.PP
58\fB\\$1\fR
59.PP
60..
61.de Sp \" Vertical space (when we can't use .PP)
62.if t .sp .5v
63.if n .sp
64..
65.de Ip \" List item
66.br
67.ie \\n(.$>=3 .ne \\$3
68.el .ne 3
69.IP "\\$1" \\$2
70..
71.de Vb \" Begin verbatim text
72.ft @CFONT@
73.nf
74.ne \\$1
75..
76.de Ve \" End verbatim text
77.ft R
78
79.fi
80..
81.\" Set up some character translations and predefined strings. \*(-- will
82.\" give an unbreakable dash, \*(PI will give pi, \*(L" will give a left
83.\" double quote, and \*(R" will give a right double quote. | will give a
84.\" real vertical bar. \*(C+ will give a nicer C++. Capital omega is used
85.\" to do unbreakable dashes and therefore won't be available. \*(C` and
86.\" \*(C' expand to `' in nroff, nothing in troff, for use with C<>
87.tr \(*W-|\(bv\*(Tr
88.ds C+ C\v'-.1v'\h'-1p'\s-2+\h'-1p'+\s0\v'.1v'\h'-1p'
89.ie n \{\
90. ds -- \(*W-
91. ds PI pi
92. if (\n(.H=4u)&(1m=24u) .ds -- \(*W\h'-12u'\(*W\h'-12u'-\" diablo 10 pitch
93. if (\n(.H=4u)&(1m=20u) .ds -- \(*W\h'-12u'\(*W\h'-8u'-\" diablo 12 pitch
94. ds L" ""
95. ds R" ""
96. ds C` `
97. ds C' '
98'br\}
99.el\{\
100. ds -- \|\(em\|
101. ds PI \(*p
102. ds L" ``
103. ds R" ''
104'br\}
105.\"
106.\" If the F register is turned on, we'll generate index entries on stderr
107.\" for titles (.TH), headers (.SH), subsections (.Sh), items (.Ip), and
108.\" index entries marked with X<> in POD. Of course, you'll have to process
109.\" the output yourself in some meaningful fashion.
110.if \nF \{\
111. de IX
112. tm Index:\\$1\t\\n%\t"\\$2"
113. .
114. nr % 0
115. rr F
116.\}
117.\"
118.\" For nroff, turn off justification. Always turn off hyphenation; it
119.\" makes way too many mistakes in technical documents.
120.hy 0
121.if n .na
122.\"
123.\" Accent mark definitions (@(#)ms.acc 1.5 88/02/08 SMI; from UCB 4.2).
124.\" Fear. Run. Save yourself. No user-serviceable parts.
125.bd B 3
126. \" fudge factors for nroff and troff
127.if n \{\
128. ds #H 0
129. ds #V .8m
130. ds #F .3m
131. ds #[ \f1
132. ds #] \fP
133.\}
134.if t \{\
135. ds #H ((1u-(\\\\n(.fu%2u))*.13m)
136. ds #V .6m
137. ds #F 0
138. ds #[ \&
139. ds #] \&
140.\}
141. \" simple accents for nroff and troff
142.if n \{\
143. ds ' \&
144. ds ` \&
145. ds ^ \&
146. ds , \&
147. ds ~ ~
148. ds /
149.\}
150.if t \{\
151. ds ' \\k:\h'-(\\n(.wu*8/10-\*(#H)'\'\h"|\\n:u"
152. ds ` \\k:\h'-(\\n(.wu*8/10-\*(#H)'\`\h'|\\n:u'
153. ds ^ \\k:\h'-(\\n(.wu*10/11-\*(#H)'^\h'|\\n:u'
154. ds , \\k:\h'-(\\n(.wu*8/10)',\h'|\\n:u'
155. ds ~ \\k:\h'-(\\n(.wu-\*(#H-.1m)'~\h'|\\n:u'
156. ds / \\k:\h'-(\\n(.wu*8/10-\*(#H)'\z\(sl\h'|\\n:u'
157.\}
158. \" troff and (daisy-wheel) nroff accents
159.ds : \\k:\h'-(\\n(.wu*8/10-\*(#H+.1m+\*(#F)'\v'-\*(#V'\z.\h'.2m+\*(#F'.\h'|\\n:u'\v'\*(#V'
160.ds 8 \h'\*(#H'\(*b\h'-\*(#H'
161.ds o \\k:\h'-(\\n(.wu+\w'\(de'u-\*(#H)/2u'\v'-.3n'\*(#[\z\(de\v'.3n'\h'|\\n:u'\*(#]
162.ds d- \h'\*(#H'\(pd\h'-\w'~'u'\v'-.25m'\f2\(hy\fP\v'.25m'\h'-\*(#H'
163.ds D- D\\k:\h'-\w'D'u'\v'-.11m'\z\(hy\v'.11m'\h'|\\n:u'
164.ds th \*(#[\v'.3m'\s+1I\s-1\v'-.3m'\h'-(\w'I'u*2/3)'\s-1o\s+1\*(#]
165.ds Th \*(#[\s+2I\s-2\h'-\w'I'u*3/5'\v'-.3m'o\v'.3m'\*(#]
166.ds ae a\h'-(\w'a'u*4/10)'e
167.ds Ae A\h'-(\w'A'u*4/10)'E
168. \" corrections for vroff
169.if v .ds ~ \\k:\h'-(\\n(.wu*9/10-\*(#H)'\s-2\u~\d\s+2\h'|\\n:u'
170.if v .ds ^ \\k:\h'-(\\n(.wu*10/11-\*(#H)'\v'-.4m'^\v'.4m'\h'|\\n:u'
171. \" for low resolution devices (crt and lpr)
172.if \n(.H>23 .if \n(.V>19 \
173\{\
174. ds : e
175. ds 8 ss
176. ds o a
177. ds d- d\h'-1'\(ga
178. ds D- D\h'-1'\(hy
179. ds th \o'bp'
180. ds Th \o'LP'
181. ds ae ae
182. ds Ae AE
183.\}
184.rm #[ #] #H #V #F C
185----END OF PREAMBLE----
186
187# This table is taken nearly verbatim from Tom Christiansen's pod2man. It
188# assumes that the standard preamble has already been printed, since that's
189# what defines all of the accent marks. Note that some of these are quoted
190# with double quotes since they contain embedded single quotes, so use \\
191# uniformly for backslash for readability.
192%ESCAPES = (
193 'amp' => '&', # ampersand
194 'lt' => '<', # left chevron, less-than
195 'gt' => '>', # right chevron, greater-than
196 'quot' => '"', # double quote
197
198 'Aacute' => "A\\*'", # capital A, acute accent
199 'aacute' => "a\\*'", # small a, acute accent
200 'Acirc' => 'A\\*^', # capital A, circumflex accent
201 'acirc' => 'a\\*^', # small a, circumflex accent
202 'AElig' => '\*(AE', # capital AE diphthong (ligature)
203 'aelig' => '\*(ae', # small ae diphthong (ligature)
204 'Agrave' => "A\\*`", # capital A, grave accent
205 'agrave' => "A\\*`", # small a, grave accent
206 'Aring' => 'A\\*o', # capital A, ring
207 'aring' => 'a\\*o', # small a, ring
208 'Atilde' => 'A\\*~', # capital A, tilde
209 'atilde' => 'a\\*~', # small a, tilde
210 'Auml' => 'A\\*:', # capital A, dieresis or umlaut mark
211 'auml' => 'a\\*:', # small a, dieresis or umlaut mark
212 'Ccedil' => 'C\\*,', # capital C, cedilla
213 'ccedil' => 'c\\*,', # small c, cedilla
214 'Eacute' => "E\\*'", # capital E, acute accent
215 'eacute' => "e\\*'", # small e, acute accent
216 'Ecirc' => 'E\\*^', # capital E, circumflex accent
217 'ecirc' => 'e\\*^', # small e, circumflex accent
218 'Egrave' => 'E\\*`', # capital E, grave accent
219 'egrave' => 'e\\*`', # small e, grave accent
220 'ETH' => '\\*(D-', # capital Eth, Icelandic
221 'eth' => '\\*(d-', # small eth, Icelandic
222 'Euml' => 'E\\*:', # capital E, dieresis or umlaut mark
223 'euml' => 'e\\*:', # small e, dieresis or umlaut mark
224 'Iacute' => "I\\*'", # capital I, acute accent
225 'iacute' => "i\\*'", # small i, acute accent
226 'Icirc' => 'I\\*^', # capital I, circumflex accent
227 'icirc' => 'i\\*^', # small i, circumflex accent
228 'Igrave' => 'I\\*`', # capital I, grave accent
229 'igrave' => 'i\\*`', # small i, grave accent
230 'Iuml' => 'I\\*:', # capital I, dieresis or umlaut mark
231 'iuml' => 'i\\*:', # small i, dieresis or umlaut mark
232 'Ntilde' => 'N\*~', # capital N, tilde
233 'ntilde' => 'n\*~', # small n, tilde
234 'Oacute' => "O\\*'", # capital O, acute accent
235 'oacute' => "o\\*'", # small o, acute accent
236 'Ocirc' => 'O\\*^', # capital O, circumflex accent
237 'ocirc' => 'o\\*^', # small o, circumflex accent
238 'Ograve' => 'O\\*`', # capital O, grave accent
239 'ograve' => 'o\\*`', # small o, grave accent
240 'Oslash' => 'O\\*/', # capital O, slash
241 'oslash' => 'o\\*/', # small o, slash
242 'Otilde' => 'O\\*~', # capital O, tilde
243 'otilde' => 'o\\*~', # small o, tilde
244 'Ouml' => 'O\\*:', # capital O, dieresis or umlaut mark
245 'ouml' => 'o\\*:', # small o, dieresis or umlaut mark
246 'szlig' => '\*8', # small sharp s, German (sz ligature)
247 'THORN' => '\\*(Th', # capital THORN, Icelandic
248 'thorn' => '\\*(th', # small thorn, Icelandic
249 'Uacute' => "U\\*'", # capital U, acute accent
250 'uacute' => "u\\*'", # small u, acute accent
251 'Ucirc' => 'U\\*^', # capital U, circumflex accent
252 'ucirc' => 'u\\*^', # small u, circumflex accent
253 'Ugrave' => 'U\\*`', # capital U, grave accent
254 'ugrave' => 'u\\*`', # small u, grave accent
255 'Uuml' => 'U\\*:', # capital U, dieresis or umlaut mark
256 'uuml' => 'u\\*:', # small u, dieresis or umlaut mark
257 'Yacute' => "Y\\*'", # capital Y, acute accent
258 'yacute' => "y\\*'", # small y, acute accent
259 'yuml' => 'y\\*:', # small y, dieresis or umlaut mark
260);
261
262
263############################################################################
264# Static helper functions
265############################################################################
266
c9abbd5d
GS
267# Protect leading quotes and periods against interpretation as commands. A
268# leading *roff font escape apparently still leaves a period interpretable
269# as a command by some *roff implementations, so look for a period even
270# after one of those.
271sub protect {
272 local $_ = shift;
273 s{ ^ ( (?: \\f(?:.|\(..) )* [.\'] ) } {\\&$1}xmg;
274 $_;
275}
9741dab0
GS
276
277# Given a command and a single argument that may or may not contain double
278# quotes, handle double-quote formatting for it. If there are no double
279# quotes, just return the command followed by the argument in double quotes.
280# If there are double quotes, use an if statement to test for nroff, and for
281# nroff output the command followed by the argument in double quotes with
282# embedded double quotes doubled. For other formatters, remap paired double
283# quotes to `` and ''.
284sub switchquotes {
285 my $command = shift;
286 local $_ = shift;
287 my $extra = shift;
288 s/\\\*\([LR]\"/\"/g;
289 if (/\"/) {
290 s/\"/\"\"/g;
291 my $troff = $_;
292 $troff =~ s/\"\"([^\"]*)\"\"/\`\`$1\'\'/g;
293 s/\"/\"\"/g if $extra;
294 $troff =~ s/\"/\"\"/g if $extra;
295 $_ = qq("$_") . ($extra ? " $extra" : '');
296 $troff = qq("$troff") . ($extra ? " $extra" : '');
297 return ".if n $command $_\n.el $command $troff\n";
298 } else {
299 $_ = qq("$_") . ($extra ? " $extra" : '');
300 return "$command $_\n";
301 }
302}
303
304# Translate a font string into an escape.
305sub toescape { (length ($_[0]) > 1 ? '\f(' : '\f') . $_[0] }
306
307
308############################################################################
309# Initialization
310############################################################################
311
312# Initialize the object. Here, we also process any additional options
313# passed to the constructor or set up defaults if none were given. center
314# is the centered title, release is the version number, and date is the date
315# for the documentation. Note that we can't know what file name we're
316# processing due to the architecture of Pod::Parser, so that *has* to either
317# be passed to the constructor or set separately with Pod::Man::name().
318sub initialize {
319 my $self = shift;
320
321 # Figure out the fixed-width font. If user-supplied, make sure that
322 # they are the right length.
323 for (qw/fixed fixedbold fixeditalic fixedbolditalic/) {
324 if (defined $$self{$_}) {
325 if (length ($$self{$_}) < 1 || length ($$self{$_}) > 2) {
326 croak "roff font should be 1 or 2 chars, not `$$self{$_}'";
327 }
328 } else {
329 $$self{$_} = '';
330 }
331 }
332
333 # Set the default fonts. We can't be sure what fixed bold-italic is
334 # going to be called, so default to just bold.
335 $$self{fixed} ||= 'CW';
336 $$self{fixedbold} ||= 'CB';
337 $$self{fixeditalic} ||= 'CI';
338 $$self{fixedbolditalic} ||= 'CB';
339
340 # Set up a table of font escapes. First number is fixed-width, second
341 # is bold, third is italic.
342 $$self{FONTS} = { '000' => '\fR', '001' => '\fI',
343 '010' => '\fB', '011' => '\f(BI',
344 '100' => toescape ($$self{fixed}),
345 '101' => toescape ($$self{fixeditalic}),
346 '110' => toescape ($$self{fixedbold}),
347 '111' => toescape ($$self{fixedbolditalic})};
348
349 # Extra stuff for page titles.
350 $$self{center} = 'User Contributed Perl Documentation'
351 unless defined $$self{center};
352 $$self{indent} = 4 unless defined $$self{indent};
353
354 # We used to try first to get the version number from a local binary,
355 # but we shouldn't need that any more. Get the version from the running
c9abbd5d
GS
356 # Perl. Work a little magic to handle subversions correctly under both
357 # the pre-5.6 and the post-5.6 version numbering schemes.
9741dab0 358 if (!defined $$self{release}) {
c9abbd5d
GS
359 my @version = ($] =~ /^(\d+)\.(\d{3})(\d{0,3})$/);
360 $version[2] ||= 0;
361 $version[2] *= 10 ** (3 - length $version[2]);
362 for (@version) { $_ += 0 }
363 $$self{release} = 'perl v' . join ('.', @version);
9741dab0
GS
364 }
365
366 # Double quotes in things that will be quoted.
c9abbd5d
GS
367 for (qw/center date release/) {
368 $$self{$_} =~ s/\"/\"\"/g if $$self{$_};
369 }
9741dab0
GS
370
371 $$self{INDENT} = 0; # Current indentation level.
372 $$self{INDENTS} = []; # Stack of indentations.
373 $$self{INDEX} = []; # Index keys waiting to be printed.
374
375 $self->SUPER::initialize;
376}
377
378# For each document we process, output the preamble first. Note that the
379# fixed width font is a global default; once we interpolate it into the
380# PREAMBLE, it ain't ever changing. Maybe fix this later.
381sub begin_pod {
382 my $self = shift;
383
384 # Try to figure out the name and section from the file name.
385 my $section = $$self{section} || 1;
386 my $name = $$self{name};
387 if (!defined $name) {
388 $name = $self->input_file;
fe6f1558
GS
389 $section = 3 if (!$$self{section} && $name =~ /\.pm\z/i);
390 $name =~ s/\.p(od|[lm])\z//i;
9741dab0
GS
391 if ($section =~ /^1/) {
392 require File::Basename;
393 $name = uc File::Basename::basename ($name);
394 } else {
395 # Lose everything up to the first of
396 # */lib/*perl* standard or site_perl module
397 # */*perl*/lib from -D prefix=/opt/perl
398 # */*perl*/ random module hierarchy
399 # which works. Should be fixed to use File::Spec.
400 for ($name) {
401 s%//+%/%g;
c9abbd5d
GS
402 if ( s%^.*?/lib/[^/]*perl[^/]*/%%si
403 or s%^.*?/[^/]*perl[^/]*/(?:lib/)?%%si) {
404 s%^site(_perl)?/%%s; # site and site_perl
405 s%^(.*-$^O|$^O-.*)/%%so; # arch
406 s%^\d+\.\d+%%s; # version
9741dab0
GS
407 }
408 s%/%::%g;
409 }
410 }
411 }
412
413 # Modification date header. Try to use the modification time of our
414 # input.
415 if (!defined $$self{date}) {
416 my $time = (stat $self->input_file)[9] || time;
417 my ($day, $month, $year) = (localtime $time)[3,4,5];
418 $month++;
419 $year += 1900;
c9abbd5d 420 $$self{date} = sprintf ('%4d-%02d-%02d', $year, $month, $day);
9741dab0
GS
421 }
422
423 # Now, print out the preamble and the title.
424 $PREAMBLE =~ s/\@CFONT\@/$$self{fixed}/;
425 chomp $PREAMBLE;
426 print { $self->output_handle } <<"----END OF HEADER----";
427.\\" Automatically generated by Pod::Man version $VERSION
428.\\" @{[ scalar localtime ]}
429.\\"
430.\\" Standard preamble:
431.\\" ======================================================================
432$PREAMBLE
433.\\" ======================================================================
434.\\"
435.IX Title "$name $section"
436.TH $name $section "$$self{release}" "$$self{date}" "$$self{center}"
437.UC
438----END OF HEADER----
439#"# for cperl-mode
440
441 # Initialize a few per-file variables.
442 $$self{INDENT} = 0;
443 $$self{NEEDSPACE} = 0;
444}
445
446
447############################################################################
448# Core overrides
449############################################################################
450
451# Called for each command paragraph. Gets the command, the associated
452# paragraph, the line number, and a Pod::Paragraph object. Just dispatches
453# the command to a method named the same as the command. =cut is handled
454# internally by Pod::Parser.
455sub command {
456 my $self = shift;
457 my $command = shift;
458 return if $command eq 'pod';
459 return if ($$self{EXCLUDE} && $command ne 'end');
460 $command = 'cmd_' . $command;
461 $self->$command (@_);
462}
463
464# Called for a verbatim paragraph. Gets the paragraph, the line number, and
465# a Pod::Paragraph object. Rofficate backslashes, untabify, put a
466# zero-width character at the beginning of each line to protect against
467# commands, and wrap in .Vb/.Ve.
468sub verbatim {
469 my $self = shift;
470 return if $$self{EXCLUDE};
471 local $_ = shift;
472 return if /^\s+$/;
473 s/\s+$/\n/;
474 my $lines = tr/\n/\n/;
475 1 while s/^(.*?)(\t+)/$1 . ' ' x (length ($2) * 8 - length ($1) % 8)/me;
476 s/\\/\\e/g;
477 s/^(\s*\S)/'\&' . $1/gme;
478 $self->makespace if $$self{NEEDSPACE};
479 $self->output (".Vb $lines\n$_.Ve\n");
480 $$self{NEEDSPACE} = 0;
481}
482
483# Called for a regular text block. Gets the paragraph, the line number, and
484# a Pod::Paragraph object. Perform interpolation and output the results.
485sub textblock {
486 my $self = shift;
487 return if $$self{EXCLUDE};
488 $self->output ($_[0]), return if $$self{VERBATIM};
489
490 # Perform a little magic to collapse multiple L<> references. We'll
491 # just rewrite the whole thing into actual text at this part, bypassing
492 # the whole internal sequence parsing thing.
c9abbd5d
GS
493 my $text = shift;
494 $text =~ s{
9741dab0
GS
495 (L< # A link of the form L</something>.
496 /
497 (
498 [:\w]+ # The item has to be a simple word...
499 (\(\))? # ...or simple function.
500 )
501 >
502 (
503 ,?\s+(and\s+)? # Allow lots of them, conjuncted.
504 L<
505 /
506 ( [:\w]+ ( \(\) )? )
507 >
508 )+
509 )
510 } {
511 local $_ = $1;
c9abbd5d 512 s{ L< / ( [^>]+ ) > } {$1}xg;
9741dab0 513 my @items = split /(?:,?\s+(?:and\s+)?)/;
c9abbd5d 514 my $string = 'the ';
9741dab0
GS
515 my $i;
516 for ($i = 0; $i < @items; $i++) {
517 $string .= $items[$i];
c9abbd5d
GS
518 $string .= ', ' if @items > 2 && $i != $#items;
519 $string .= ' ' if @items == 2 && $i == 2;
520 $string .= 'and ' if ($i == $#items - 1);
9741dab0 521 }
c9abbd5d 522 $string .= ' entries elsewhere in this document';
9741dab0
GS
523 $string;
524 }gex;
525
526 # Parse the tree and output it. collapse knows about references to
527 # scalars as well as scalars and does the right thing with them.
c9abbd5d
GS
528 $text = $self->parse ($text, @_);
529 $text =~ s/\n\s*$/\n/;
9741dab0 530 $self->makespace if $$self{NEEDSPACE};
c9abbd5d 531 $self->output (protect $self->mapfonts ($text));
9741dab0
GS
532 $self->outindex;
533 $$self{NEEDSPACE} = 1;
534}
535
536# Called for an interior sequence. Takes a Pod::InteriorSequence object and
537# returns a reference to a scalar. This scalar is the final formatted text.
538# It's returned as a reference so that other interior sequences above us
539# know that the text has already been processed.
540sub sequence {
541 my ($self, $seq) = @_;
542 my $command = $seq->cmd_name;
543
544 # Zero-width characters.
f5daac4a 545 if ($command eq 'Z') {
c9abbd5d
GS
546 # Workaround to generate a blessable reference, needed by 5.005.
547 my $tmp = '\&';
548 return bless \ "$tmp", 'Pod::Man::String';
f5daac4a 549 }
9741dab0
GS
550
551 # C<>, L<>, X<>, and E<> don't apply guesswork to their contents.
552 local $_ = $self->collapse ($seq->parse_tree, $command =~ /^[CELX]$/);
553
554 # Handle E<> escapes.
555 if ($command eq 'E') {
2e20e14f
GS
556 if (/^\d+$/) {
557 return bless \ chr ($_), 'Pod::Man::String';
558 } elsif (exists $ESCAPES{$_}) {
9741dab0
GS
559 return bless \ "$ESCAPES{$_}", 'Pod::Man::String';
560 } else {
561 carp "Unknown escape E<$1>";
562 return bless \ "E<$_>", 'Pod::Man::String';
563 }
564 }
565
566 # For all the other sequences, empty content produces no output.
567 return '' if $_ eq '';
568
569 # Handle formatting sequences.
570 if ($command eq 'B') {
571 return bless \ ('\f(BS' . $_ . '\f(BE'), 'Pod::Man::String';
572 } elsif ($command eq 'F') {
573 return bless \ ('\f(IS' . $_ . '\f(IE'), 'Pod::Man::String';
574 } elsif ($command eq 'I') {
575 return bless \ ('\f(IS' . $_ . '\f(IE'), 'Pod::Man::String';
576 } elsif ($command eq 'C') {
577 s/-/\\-/g;
578 s/__/_\\|_/g;
579 return bless \ ('\f(FS\*(C`' . $_ . "\\*(C'\\f(FE"),
580 'Pod::Man::String';
581 }
582
583 # Handle links.
584 if ($command eq 'L') {
c9abbd5d
GS
585 # A bug in lvalue subs in 5.6 requires the temporary variable.
586 my $tmp = $self->buildlink ($_);
587 return bless \ "$tmp", 'Pod::Man::String';
9741dab0
GS
588 }
589
590 # Whitespace protection replaces whitespace with "\ ".
591 if ($command eq 'S') {
592 s/\s+/\\ /g;
593 return bless \ "$_", 'Pod::Man::String';
594 }
595
596 # Add an index entry to the list of ones waiting to be output.
597 if ($command eq 'X') { push (@{ $$self{INDEX} }, $_); return '' }
598
599 # Anything else is unknown.
600 carp "Unknown sequence $command<$_>";
601}
602
603
604############################################################################
605# Command paragraphs
606############################################################################
607
608# All command paragraphs take the paragraph and the line number.
609
610# First level heading. We can't output .IX in the NAME section due to a bug
611# in some versions of catman, so don't output a .IX for that section. .SH
612# already uses small caps, so remove any E<> sequences that would cause
613# them.
614sub cmd_head1 {
615 my $self = shift;
616 local $_ = $self->parse (@_);
617 s/\s+$//;
618 s/\\s-?\d//g;
619 $self->output (switchquotes ('.SH', $self->mapfonts ($_)));
620 $self->outindex (($_ eq 'NAME') ? () : ('Header', $_));
621 $$self{NEEDSPACE} = 0;
622}
623
624# Second level heading.
625sub cmd_head2 {
626 my $self = shift;
627 local $_ = $self->parse (@_);
628 s/\s+$//;
629 $self->output (switchquotes ('.Sh', $self->mapfonts ($_)));
630 $self->outindex ('Subsection', $_);
631 $$self{NEEDSPACE} = 0;
632}
633
634# Start a list. For indents after the first, wrap the outside indent in .RS
635# so that hanging paragraph tags will be correct.
636sub cmd_over {
637 my $self = shift;
638 local $_ = shift;
639 unless (/^[-+]?\d+\s+$/) { $_ = $$self{indent} }
640 if (@{ $$self{INDENTS} } > 0) {
641 $self->output (".RS $$self{INDENT}\n");
642 }
643 push (@{ $$self{INDENTS} }, $$self{INDENT});
644 $$self{INDENT} = ($_ + 0);
645}
646
647# End a list. If we've closed an embedded indent, we've mangled the hanging
648# paragraph indent, so temporarily replace it with .RS and set WEIRDINDENT.
649# We'll close that .RS at the next =back or =item.
650sub cmd_back {
651 my $self = shift;
652 $$self{INDENT} = pop @{ $$self{INDENTS} };
653 unless (defined $$self{INDENT}) {
654 carp "Unmatched =back";
655 $$self{INDENT} = 0;
656 }
657 if ($$self{WEIRDINDENT}) {
658 $self->output (".RE\n");
659 $$self{WEIRDINDENT} = 0;
660 }
661 if (@{ $$self{INDENTS} } > 0) {
662 $self->output (".RE\n");
663 $self->output (".RS $$self{INDENT}\n");
664 $$self{WEIRDINDENT} = 1;
665 }
666 $$self{NEEDSPACE} = 1;
667}
668
669# An individual list item. Emit an index entry for anything that's
670# interesting, but don't emit index entries for things like bullets and
671# numbers. rofficate bullets too while we're at it (so for nice output, use
672# * for your lists rather than o or . or - or some other thing).
673sub cmd_item {
674 my $self = shift;
675 local $_ = $self->parse (@_);
676 s/\s+$//;
677 my $index;
678 if (/\w/ && !/^\w[.\)]\s*$/) {
679 $index = $_;
680 $index =~ s/^\s*[-*+o.]?\s*//;
681 }
682 s/^\*(\s|\Z)/\\\(bu$1/;
683 if ($$self{WEIRDINDENT}) {
684 $self->output (".RE\n");
685 $$self{WEIRDINDENT} = 0;
686 }
687 $_ = $self->mapfonts ($_);
688 $self->output (switchquotes ('.Ip', $_, $$self{INDENT}));
689 $self->outindex ($index ? ('Item', $index) : ());
690 $$self{NEEDSPACE} = 0;
691}
692
693# Begin a block for a particular translator. Setting VERBATIM triggers
694# special handling in textblock().
695sub cmd_begin {
696 my $self = shift;
697 local $_ = shift;
698 my ($kind) = /^(\S+)/ or return;
699 if ($kind eq 'man' || $kind eq 'roff') {
700 $$self{VERBATIM} = 1;
701 } else {
702 $$self{EXCLUDE} = 1;
703 }
704}
705
706# End a block for a particular translator. We assume that all =begin/=end
707# pairs are properly closed.
708sub cmd_end {
709 my $self = shift;
710 $$self{EXCLUDE} = 0;
711 $$self{VERBATIM} = 0;
712}
713
714# One paragraph for a particular translator. Ignore it unless it's intended
715# for man or roff, in which case we output it verbatim.
716sub cmd_for {
717 my $self = shift;
718 local $_ = shift;
9741dab0
GS
719 return unless s/^(?:man|roff)\b[ \t]*\n?//;
720 $self->output ($_);
721}
722
723
724############################################################################
725# Link handling
726############################################################################
727
728# Handle links. We can't actually make real hyperlinks, so this is all to
729# figure out what text and formatting we print out.
730sub buildlink {
731 my $self = shift;
732 local $_ = shift;
733
734 # Smash whitespace in case we were split across multiple lines.
735 s/\s+/ /g;
736
737 # If we were given any explicit text, just output it.
738 if (m{ ^ ([^|]+) \| }x) { return $1 }
739
740 # Okay, leading and trailing whitespace isn't important.
741 s/^\s+//;
742 s/\s+$//;
743
744 # Default to using the whole content of the link entry as a section
745 # name. Note that L<manpage/> forces a manpage interpretation, as does
746 # something looking like L<manpage(section)>. Do the same thing to
747 # L<manpage(section)> as we would to manpage(section) without the L<>;
748 # see guesswork(). If we've added italics, don't add the "manpage"
749 # text; markup is sufficient.
750 my ($manpage, $section) = ('', $_);
751 if (/^"\s*(.*?)\s*"$/) {
752 $section = '"' . $1 . '"';
753 } elsif (m{ ^ [-:.\w]+ (?: \( \S+ \) )? $ }x) {
754 ($manpage, $section) = ($_, '');
755 $manpage =~ s/^([^\(]+)\(/'\f(IS' . $1 . '\f(IE\|('/e;
756 } elsif (m%/%) {
757 ($manpage, $section) = split (/\s*\/\s*/, $_, 2);
758 if ($manpage =~ /^[-:.\w]+(?:\(\S+\))?$/) {
759 $manpage =~ s/^([^\(]+)\(/'\f(IS' . $1 . '\f(IE\|'/e;
760 }
761 $section =~ s/^\"\s*//;
762 $section =~ s/\s*\"$//;
763 }
764 if ($manpage && $manpage !~ /\\f\(IS/) {
765 $manpage = "the $manpage manpage";
766 }
767
768 # Now build the actual output text.
769 my $text = '';
770 if (!length ($section) && !length ($manpage)) {
771 carp "Invalid link $_";
772 } elsif (!length ($section)) {
773 $text = $manpage;
774 } elsif ($section =~ /^[:\w]+(?:\(\))?/) {
775 $text .= 'the ' . $section . ' entry';
776 $text .= (length $manpage) ? " in $manpage"
777 : " elsewhere in this document";
778 } else {
2e20e14f
GS
779 if ($section !~ /^".*"$/) { $section = '"' . $section . '"' }
780 $text .= 'the section on ' . $section;
9741dab0
GS
781 $text .= " in $manpage" if length $manpage;
782 }
783 $text;
784}
785
786
787############################################################################
788# Escaping and fontification
789############################################################################
790
791# At this point, we'll have embedded font codes of the form \f(<font>[SE]
792# where <font> is one of B, I, or F. Turn those into the right font start
793# or end codes. B<someI<thing> else> should map to \fBsome\f(BIthing\fB
794# else\fR. The old pod2man didn't get this right; the second \fB was \fR,
795# so nested sequences didn't work right. We take care of this by using
796# variables as a combined pointer to our current font sequence, and set each
797# to the number of current nestings of start tags for that font. Use them
798# as a vector to look up what font sequence to use.
799sub mapfonts {
800 my $self = shift;
801 local $_ = shift;
802
803 my ($fixed, $bold, $italic) = (0, 0, 0);
804 my %magic = (F => \$fixed, B => \$bold, I => \$italic);
805 s { \\f\((.)(.) } {
806 ${ $magic{$1} } += ($2 eq 'S') ? 1 : -1;
807 $$self{FONTS}{($fixed && 1) . ($bold && 1) . ($italic && 1)};
808 }gxe;
809 $_;
810}
811
812
813############################################################################
814# *roff-specific parsing
815############################################################################
816
817# Called instead of parse_text, calls parse_text with the right flags.
818sub parse {
819 my $self = shift;
820 $self->parse_text ({ -expand_seq => 'sequence',
821 -expand_ptree => 'collapse' }, @_);
822}
823
824# Takes a parse tree and a flag saying whether or not to treat it as literal
825# text (not call guesswork on it), and returns the concatenation of all of
826# the text strings in that parse tree. If the literal flag isn't true,
827# guesswork() will be called on all plain scalars in the parse tree.
828# Assumes that everything in the parse tree is either a scalar or a
829# reference to a scalar.
830sub collapse {
831 my ($self, $ptree, $literal) = @_;
832 if ($literal) {
833 return join ('', map {
834 if (ref $_) {
835 $$_;
836 } else {
837 s/\\/\\e/g;
838 $_;
839 }
840 } $ptree->children);
841 } else {
842 return join ('', map {
843 ref ($_) ? $$_ : $self->guesswork ($_)
844 } $ptree->children);
845 }
846}
847
848# Takes a text block to perform guesswork on; this is guaranteed not to
849# contain any interior sequences. Returns the text block with remapping
850# done.
851sub guesswork {
852 my $self = shift;
853 local $_ = shift;
854
855 # rofficate backslashes.
856 s/\\/\\e/g;
857
858 # Ensure double underbars have a tiny space between them.
859 s/__/_\\|_/g;
860
861 # Make all caps a little smaller. Be careful here, since we don't want
862 # to make @ARGV into small caps, nor do we want to fix the MIME in
863 # MIME-Version, since it looks weird with the full-height V.
864 s{
865 ( ^ | [\s\(\"\'\`\[\{<>] )
866 ( [A-Z] [A-Z] [/A-Z+:\d_\$&-]* )
867 (?: (?= [\s>\}\]\)\'\".?!,;:] | -- ) | $ )
c9abbd5d 868 } { $1 . '\s-1' . $2 . '\s0' }egx;
9741dab0
GS
869
870 # Turn PI into a pretty pi.
871 s{ (?: \\s-1 | \b ) PI (?: \\s0 | \b ) } {\\*\(PI}gx;
872
873 # Italize functions in the form func().
874 s{
875 \b
876 (
877 [:\w]+ (?:\\s-1)? \(\)
878 )
879 } { '\f(IS' . $1 . '\f(IE' }egx;
880
881 # func(n) is a reference to a manual page. Make it \fIfunc\fR\|(n).
882 s{
883 \b
884 (\w[-:.\w]+ (?:\\s-1)?)
885 (
886 \( [^\)] \)
887 )
888 } { '\f(IS' . $1 . '\f(IE\|' . $2 }egx;
889
890 # Convert simple Perl variable references to a fixed-width font.
891 s{
892 ( \s+ )
893 ( [\$\@%] [\w:]+ )
894 (?! \( )
895 } { $1 . '\f(FS' . $2 . '\f(FE'}egx;
896
897 # Translate -- into a real em dash if it's used like one and fix up
898 # dashes, but keep hyphens hyphens.
899 s{ (\G|^|.) (-+) (\b|.) } {
900 my ($pre, $dash, $post) = ($1, $2, $3);
901 if (length ($dash) == 1) {
902 ($pre =~ /[a-zA-Z]/) ? "$pre-$post" : "$pre\\-$post";
903 } elsif (length ($dash) == 2
904 && ((!$pre && !$post)
905 || ($pre =~ /\w/ && !$post)
906 || ($pre eq ' ' && $post eq ' ')
907 || ($pre eq '=' && $post ne '=')
908 || ($pre ne '=' && $post eq '='))) {
909 "$pre\\*(--$post";
910 } else {
911 $pre . ('\-' x length $dash) . $post;
912 }
913 }egxs;
914
915 # Fix up double quotes.
916 s{ \" ([^\"]+) \" } { '\*(L"' . $1 . '\*(R"' }egx;
917
918 # Make C++ into \*(C+, which is a squinched version.
919 s{ \b C\+\+ } {\\*\(C+}gx;
920
921 # All done.
922 $_;
923}
924
925
926############################################################################
927# Output formatting
928############################################################################
929
930# Make vertical whitespace.
931sub makespace {
932 my $self = shift;
933 $self->output ($$self{INDENT} > 0 ? ".Sp\n" : ".PP\n");
934}
935
936# Output any pending index entries, and optionally an index entry given as
937# an argument. Support multiple index entries in X<> separated by slashes,
938# and strip special escapes from index entries.
939sub outindex {
940 my ($self, $section, $index) = @_;
941 my @entries = map { split m%\s*/\s*% } @{ $$self{INDEX} };
942 return unless ($section || @entries);
943 $$self{INDEX} = [];
944 my $output;
945 if (@entries) {
946 my $output = '.IX Xref "'
947 . join (' ', map { s/\"/\"\"/; $_ } @entries)
948 . '"' . "\n";
949 }
950 if ($section) {
951 $index =~ s/\"/\"\"/;
952 $index =~ s/\\-/-/g;
953 $index =~ s/\\(?:s-?\d|.\(..|.)//g;
954 $output .= ".IX $section " . '"' . $index . '"' . "\n";
955 }
956 $self->output ($output);
957}
958
959# Output text to the output device.
960sub output { print { $_[0]->output_handle } $_[1] }
961
962__END__
963
964.\" These are some extra bits of roff that I don't want to lose track of
965.\" but that have been removed from the preamble to make it a bit shorter
966.\" since they're not currently being used. They're accents and special
967.\" characters we don't currently have escapes for.
968.if n \{\
969. ds ? ?
970. ds ! !
971. ds q
972.\}
973.if t \{\
974. ds ? \s-2c\h'-\w'c'u*7/10'\u\h'\*(#H'\zi\d\s+2\h'\w'c'u*8/10'
975. ds ! \s-2\(or\s+2\h'-\w'\(or'u'\v'-.8m'.\v'.8m'
976. ds q o\h'-\w'o'u*8/10'\s-4\v'.4m'\z\(*i\v'-.4m'\s+4\h'\w'o'u*8/10'
977.\}
978.ds v \\k:\h'-(\\n(.wu*9/10-\*(#H)'\v'-\*(#V'\*(#[\s-4v\s0\v'\*(#V'\h'|\\n:u'\*(#]
979.ds _ \\k:\h'-(\\n(.wu*9/10-\*(#H+(\*(#F*2/3))'\v'-.4m'\z\(hy\v'.4m'\h'|\\n:u'
980.ds . \\k:\h'-(\\n(.wu*8/10)'\v'\*(#V*4/10'\z.\v'-\*(#V*4/10'\h'|\\n:u'
981.ds 3 \*(#[\v'.2m'\s-2\&3\s0\v'-.2m'\*(#]
982.ds oe o\h'-(\w'o'u*4/10)'e
983.ds Oe O\h'-(\w'O'u*4/10)'E
984.if \n(.H>23 .if \n(.V>19 \
985\{\
986. ds v \h'-1'\o'\(aa\(ga'
987. ds _ \h'-1'^
988. ds . \h'-1'.
989. ds 3 3
990. ds oe oe
991. ds Oe OE
992.\}
993
994############################################################################
995# Documentation
996############################################################################
997
998=head1 NAME
999
1000Pod::Man - Convert POD data to formatted *roff input
1001
1002=head1 SYNOPSIS
1003
1004 use Pod::Man;
1005 my $parser = Pod::Man->new (release => $VERSION, section => 8);
1006
1007 # Read POD from STDIN and write to STDOUT.
1008 $parser->parse_from_filehandle;
1009
1010 # Read POD from file.pod and write to file.1.
1011 $parser->parse_from_file ('file.pod', 'file.1');
1012
1013=head1 DESCRIPTION
1014
1015Pod::Man is a module to convert documentation in the POD format (the
1016preferred language for documenting Perl) into *roff input using the man
1017macro set. The resulting *roff code is suitable for display on a terminal
1018using nroff(1), normally via man(1), or printing using troff(1). It is
9e107c59 1019conventionally invoked using the driver script B<pod2man>, but it can also
9741dab0
GS
1020be used directly.
1021
1022As a derived class from Pod::Parser, Pod::Man supports the same methods and
1023interfaces. See L<Pod::Parser> for all the details; briefly, one creates a
1024new parser with C<Pod::Man-E<gt>new()> and then calls either
1025parse_from_filehandle() or parse_from_file().
1026
1027new() can take options, in the form of key/value pairs that control the
1028behavior of the parser. See below for details.
1029
1030If no options are given, Pod::Man uses the name of the input file with any
1031trailing C<.pod>, C<.pm>, or C<.pl> stripped as the man page title, to
1032section 1 unless the file ended in C<.pm> in which case it defaults to
1033section 3, to a centered title of "User Contributed Perl Documentation", to
1034a centered footer of the Perl version it is run with, and to a left-hand
1035footer of the modification date of its input (or the current date if given
1036STDIN for input).
1037
1038Pod::Man assumes that your *roff formatters have a fixed-width font named
1039CW. If yours is called something else (like CR), use the C<fixed> option to
1040specify it. This generally only matters for troff output for printing.
1041Similarly, you can set the fonts used for bold, italic, and bold italic
1042fixed-width output.
1043
1044Besides the obvious pod conversions, Pod::Man also takes care of formatting
1045func(), func(n), and simple variable references like $foo or @bar so you
1046don't have to use code escapes for them; complex expressions like
1047C<$fred{'stuff'}> will still need to be escaped, though. It also translates
1048dashes that aren't used as hyphens into en dashes, makes long dashes--like
1049this--into proper em dashes, fixes "paired quotes," makes C++ and PI look
1050right, puts a little space between double underbars, makes ALLCAPS a teeny
1051bit smaller in troff(1), and escapes stuff that *roff treats as special so
1052that you don't have to.
1053
1054The recognized options to new() are as follows. All options take a single
1055argument.
1056
1057=over 4
1058
1059=item center
1060
1061Sets the centered page header to use instead of "User Contributed Perl
1062Documentation".
1063
1064=item date
1065
1066Sets the left-hand footer. By default, the modification date of the input
1067file will be used, or the current date if stat() can't find that file (the
1068case if the input is from STDIN), and the date will be formatted as
1069YYYY-MM-DD.
1070
1071=item fixed
1072
1073The fixed-width font to use for vertabim text and code. Defaults to CW.
1074Some systems may want CR instead. Only matters for troff(1) output.
1075
1076=item fixedbold
1077
1078Bold version of the fixed-width font. Defaults to CB. Only matters for
1079troff(1) output.
1080
1081=item fixeditalic
1082
1083Italic version of the fixed-width font (actually, something of a misnomer,
1084since most fixed-width fonts only have an oblique version, not an italic
1085version). Defaults to CI. Only matters for troff(1) output.
1086
1087=item fixedbolditalic
1088
1089Bold italic (probably actually oblique) version of the fixed-width font.
1090Pod::Man doesn't assume you have this, and defaults to CB. Some systems
1091(such as Solaris) have this font available as CX. Only matters for troff(1)
1092output.
1093
1094=item release
1095
1096Set the centered footer. By default, this is the version of Perl you run
1097Pod::Man under. Note that some system an macro sets assume that the
1098centered footer will be a modification date and will prepend something like
1099"Last modified: "; if this is the case, you may want to set C<release> to
1100the last modified date and C<date> to the version number.
1101
1102=item section
1103
1104Set the section for the C<.TH> macro. The standard section numbering
1105convention is to use 1 for user commands, 2 for system calls, 3 for
1106functions, 4 for devices, 5 for file formats, 6 for games, 7 for
1107miscellaneous information, and 8 for administrator commands. There is a lot
1108of variation here, however; some systems (like Solaris) use 4 for file
1109formats, 5 for miscellaneous information, and 7 for devices. Still others
1110use 1m instead of 8, or some mix of both. About the only section numbers
1111that are reliably consistent are 1, 2, and 3.
1112
1113By default, section 1 will be used unless the file ends in .pm in which case
1114section 3 will be selected.
1115
1116=back
1117
1118The standard Pod::Parser method parse_from_filehandle() takes up to two
1119arguments, the first being the file handle to read POD from and the second
1120being the file handle to write the formatted output to. The first defaults
1121to STDIN if not given, and the second defaults to STDOUT. The method
1122parse_from_file() is almost identical, except that its two arguments are the
1123input and output disk files instead. See L<Pod::Parser> for the specific
1124details.
1125
1126=head1 DIAGNOSTICS
1127
1128=over 4
1129
1130=item roff font should be 1 or 2 chars, not `%s'
1131
1132(F) You specified a *roff font (using C<fixed>, C<fixedbold>, etc.) that
1133wasn't either one or two characters. Pod::Man doesn't support *roff fonts
1134longer than two characters, although some *roff extensions do (the canonical
1135versions of nroff(1) and troff(1) don't either).
1136
1137=item Invalid link %s
1138
1139(W) The POD source contained a C<LE<lt>E<gt>> sequence that Pod::Man was
1140unable to parse. You should never see this error message; it probably
1141indicates a bug in Pod::Man.
1142
1143=item Unknown escape EE<lt>%sE<gt>
1144
1145(W) The POD source contained an C<EE<lt>E<gt>> escape that Pod::Man didn't
1146know about. C<EE<lt>%sE<gt>> was printed verbatim in the output.
1147
1148=item Unknown sequence %s
1149
1150(W) The POD source contained a non-standard interior sequence (something of
1151the form C<XE<lt>E<gt>>) that Pod::Man didn't know about. It was ignored.
1152
1153=item Unmatched =back
1154
1155(W) Pod::Man encountered a C<=back> command that didn't correspond to an
1156C<=over> command.
1157
1158=back
1159
1160=head1 BUGS
1161
1162The lint-like features and strict POD format checking done by B<pod2man> are
1163not yet implemented and should be, along with the corresponding C<lax>
1164option.
1165
1166The NAME section should be recognized specially and index entries emitted
1167for everything in that section. This would have to be deferred until the
1168next section, since extraneous things in NAME tends to confuse various man
1169page processors.
1170
1171The handling of hyphens, en dashes, and em dashes is somewhat fragile, and
1172one may get the wrong one under some circumstances. This should only matter
1173for troff(1) output.
1174
1175When and whether to use small caps is somewhat tricky, and Pod::Man doesn't
1176necessarily get it right.
1177
1178Pod::Man doesn't handle font names longer than two characters. Neither do
1179most troff(1) implementations, but GNU troff does as an extension. It would
1180be nice to support as an option for those who want to use it.
1181
1182The preamble added to each output file is rather verbose, and most of it is
1183only necessary in the presence of EE<lt>E<gt> escapes for non-ASCII
1184characters. It would ideally be nice if all of those definitions were only
1185output if needed, perhaps on the fly as the characters are used.
1186
1187Some of the automagic applied to file names assumes Unix directory
1188separators.
1189
1190Pod::Man is excessively slow.
1191
9741dab0
GS
1192=head1 SEE ALSO
1193
9e107c59 1194L<Pod::Parser|Pod::Parser>, perlpod(1), pod2man(1), nroff(1), troff(1),
9741dab0
GS
1195man(1), man(7)
1196
1197Ossanna, Joseph F., and Brian W. Kernighan. "Troff User's Manual,"
1198Computing Science Technical Report No. 54, AT&T Bell Laboratories. This is
1199the best documentation of standard nroff(1) and troff(1). At the time of
1200this writing, it's available at http://www.cs.bell-labs.com/cm/cs/cstr.html.
1201
1202The man page documenting the man macro set may be man(5) instead of man(7)
9e107c59 1203on your system. Also, please see pod2man(1) for extensive documentation on
9741dab0
GS
1204writing manual pages if you've not done it before and aren't familiar with
1205the conventions.
1206
1207=head1 AUTHOR
1208
1209Russ Allbery E<lt>rra@stanford.eduE<gt>, based I<very> heavily on the
1210original B<pod2man> by Tom Christiansen E<lt>tchrist@mox.perl.comE<gt>.
1211
1212=cut