RE: Combining UTF-16 output with :crlf is awkward
[perl.git] / lib / SelfLoader.pm
1 package SelfLoader;
2 require Exporter;
3 @ISA = qw(Exporter);
4 @EXPORT = qw(AUTOLOAD);
5 $VERSION = "1.0905";
6 sub Version {$VERSION}
7 $DEBUG = 0;
8
9 my %Cache;      # private cache for all SelfLoader's client packages
10
11 # allow checking for valid ': attrlist' attachments
12 # (we use 'our' rather than 'my' here, due to the rather complex and buggy
13 # behaviour of lexicals with qr// and (??{$lex}) )
14 our $nested;
15 $nested = qr{ \( (?: (?> [^()]+ ) | (??{ $nested }) )* \) }x;
16 our $one_attr = qr{ (?> (?! \d) \w+ (?:$nested)? ) (?:\s*\:\s*|\s+(?!\:)) }x;
17 our $attr_list = qr{ \s* : \s* (?: $one_attr )* }x;
18
19 # in croak and carp, protect $@ from "require Carp;" RT #40216
20
21 sub croak { { local $@; require Carp; } goto &Carp::croak }
22 sub carp { { local $@; require Carp; } goto &Carp::carp }
23
24 AUTOLOAD {
25     print STDERR "SelfLoader::AUTOLOAD for $AUTOLOAD\n" if $DEBUG;
26     my $SL_code = $Cache{$AUTOLOAD};
27     my $save = $@; # evals in both AUTOLOAD and _load_stubs can corrupt $@
28     unless ($SL_code) {
29         # Maybe this pack had stubs before __DATA__, and never initialized.
30         # Or, this maybe an automatic DESTROY method call when none exists.
31         $AUTOLOAD =~ m/^(.*)::/;
32         SelfLoader->_load_stubs($1) unless exists $Cache{"${1}::<DATA"};
33         $SL_code = $Cache{$AUTOLOAD};
34         $SL_code = "sub $AUTOLOAD { }"
35             if (!$SL_code and $AUTOLOAD =~ m/::DESTROY$/);
36         croak "Undefined subroutine $AUTOLOAD" unless $SL_code;
37     }
38     print STDERR "SelfLoader::AUTOLOAD eval: $SL_code\n" if $DEBUG;
39
40     eval $SL_code;
41     if ($@) {
42         $@ =~ s/ at .*\n//;
43         croak $@;
44     }
45     $@ = $save;
46     defined(&$AUTOLOAD) || die "SelfLoader inconsistency error";
47     delete $Cache{$AUTOLOAD};
48     goto &$AUTOLOAD
49 }
50
51 sub load_stubs { shift->_load_stubs((caller)[0]) }
52
53 sub _load_stubs {
54     # $endlines is used by Devel::SelfStubber to capture lines after __END__
55     my($self, $callpack, $endlines) = @_;
56     my $fh = \*{"${callpack}::DATA"};
57     my $currpack = $callpack;
58     my($line,$name,@lines, @stubs, $protoype);
59
60     print STDERR "SelfLoader::load_stubs($callpack)\n" if $DEBUG;
61     croak("$callpack doesn't contain an __DATA__ token")
62         unless fileno($fh);
63     $Cache{"${currpack}::<DATA"} = 1;   # indicate package is cached
64
65     local($/) = "\n";
66     while(defined($line = <$fh>) and $line !~ m/^__END__/) {
67         if ($line =~ m/^sub\s+([\w:]+)\s*((?:\([\\\$\@\%\&\*\;]*\))?(?:$attr_list)?)/) {
68             push(@stubs, $self->_add_to_cache($name, $currpack, \@lines, $protoype));
69             $protoype = $2;
70             @lines = ($line);
71             if (index($1,'::') == -1) {         # simple sub name
72                 $name = "${currpack}::$1";
73             } else {                            # sub name with package
74                 $name = $1;
75                 $name =~ m/^(.*)::/;
76                 if (defined(&{"${1}::AUTOLOAD"})) {
77                     \&{"${1}::AUTOLOAD"} == \&SelfLoader::AUTOLOAD ||
78                         die 'SelfLoader Error: attempt to specify Selfloading',
79                             " sub $name in non-selfloading module $1";
80                 } else {
81                     $self->export($1,'AUTOLOAD');
82                 }
83             }
84         } elsif ($line =~ m/^package\s+([\w:]+)/) { # A package declared
85             push(@stubs, $self->_add_to_cache($name, $currpack, \@lines, $protoype));
86             $self->_package_defined($line);
87             $name = '';
88             @lines = ();
89             $currpack = $1;
90             $Cache{"${currpack}::<DATA"} = 1;   # indicate package is cached
91             if (defined(&{"${1}::AUTOLOAD"})) {
92                 \&{"${1}::AUTOLOAD"} == \&SelfLoader::AUTOLOAD ||
93                     die 'SelfLoader Error: attempt to specify Selfloading',
94                         " package $currpack which already has AUTOLOAD";
95             } else {
96                 $self->export($currpack,'AUTOLOAD');
97             }
98         } else {
99             push(@lines,$line);
100         }
101     }
102     if (defined($line) && $line =~ /^__END__/) { # __END__
103         unless ($line =~ /^__END__\s*DATA/) {
104             if ($endlines) {
105                 # Devel::SelfStubber would like us to capture the lines after
106                 # __END__ so it can write out the entire file
107                 @$endlines = <$fh>;
108             }
109             close($fh);
110         }
111     }
112     push(@stubs, $self->_add_to_cache($name, $currpack, \@lines, $protoype));
113     eval join('', @stubs) if @stubs;
114 }
115
116
117 sub _add_to_cache {
118     my($self,$fullname,$pack,$lines, $protoype) = @_;
119     return () unless $fullname;
120     carp("Redefining sub $fullname")
121       if exists $Cache{$fullname};
122     $Cache{$fullname} = join('', "package $pack; ",@$lines);
123     print STDERR "SelfLoader cached $fullname: $Cache{$fullname}" if $DEBUG;
124     # return stub to be eval'd
125     defined($protoype) ? "sub $fullname $protoype;" : "sub $fullname;"
126 }
127
128 sub _package_defined {}
129
130 1;
131 __END__
132
133 =head1 NAME
134
135 SelfLoader - load functions only on demand
136
137 =head1 SYNOPSIS
138
139     package FOOBAR;
140     use SelfLoader;
141
142     ... (initializing code)
143
144     __DATA__
145     sub {....
146
147
148 =head1 DESCRIPTION
149
150 This module tells its users that functions in the FOOBAR package are to be
151 autoloaded from after the C<__DATA__> token.  See also
152 L<perlsub/"Autoloading">.
153
154 =head2 The __DATA__ token
155
156 The C<__DATA__> token tells the perl compiler that the perl code
157 for compilation is finished. Everything after the C<__DATA__> token
158 is available for reading via the filehandle FOOBAR::DATA,
159 where FOOBAR is the name of the current package when the C<__DATA__>
160 token is reached. This works just the same as C<__END__> does in
161 package 'main', but for other modules data after C<__END__> is not
162 automatically retrievable, whereas data after C<__DATA__> is.
163 The C<__DATA__> token is not recognized in versions of perl prior to
164 5.001m.
165
166 Note that it is possible to have C<__DATA__> tokens in the same package
167 in multiple files, and that the last C<__DATA__> token in a given
168 package that is encountered by the compiler is the one accessible
169 by the filehandle. This also applies to C<__END__> and main, i.e. if
170 the 'main' program has an C<__END__>, but a module 'require'd (_not_ 'use'd)
171 by that program has a 'package main;' declaration followed by an 'C<__DATA__>',
172 then the C<DATA> filehandle is set to access the data after the C<__DATA__>
173 in the module, _not_ the data after the C<__END__> token in the 'main'
174 program, since the compiler encounters the 'require'd file later.
175
176 =head2 SelfLoader autoloading
177
178 The B<SelfLoader> works by the user placing the C<__DATA__>
179 token I<after> perl code which needs to be compiled and
180 run at 'require' time, but I<before> subroutine declarations
181 that can be loaded in later - usually because they may never
182 be called.
183
184 The B<SelfLoader> will read from the FOOBAR::DATA filehandle to
185 load in the data after C<__DATA__>, and load in any subroutine
186 when it is called. The costs are the one-time parsing of the
187 data after C<__DATA__>, and a load delay for the _first_
188 call of any autoloaded function. The benefits (hopefully)
189 are a speeded up compilation phase, with no need to load
190 functions which are never used.
191
192 The B<SelfLoader> will stop reading from C<__DATA__> if
193 it encounters the C<__END__> token - just as you would expect.
194 If the C<__END__> token is present, and is followed by the
195 token DATA, then the B<SelfLoader> leaves the FOOBAR::DATA
196 filehandle open on the line after that token.
197
198 The B<SelfLoader> exports the C<AUTOLOAD> subroutine to the
199 package using the B<SelfLoader>, and this loads the called
200 subroutine when it is first called.
201
202 There is no advantage to putting subroutines which will _always_
203 be called after the C<__DATA__> token.
204
205 =head2 Autoloading and package lexicals
206
207 A 'my $pack_lexical' statement makes the variable $pack_lexical
208 local _only_ to the file up to the C<__DATA__> token. Subroutines
209 declared elsewhere _cannot_ see these types of variables,
210 just as if you declared subroutines in the package but in another
211 file, they cannot see these variables.
212
213 So specifically, autoloaded functions cannot see package
214 lexicals (this applies to both the B<SelfLoader> and the Autoloader).
215 The C<vars> pragma provides an alternative to defining package-level
216 globals that will be visible to autoloaded routines. See the documentation
217 on B<vars> in the pragma section of L<perlmod>.
218
219 =head2 SelfLoader and AutoLoader
220
221 The B<SelfLoader> can replace the AutoLoader - just change 'use AutoLoader'
222 to 'use SelfLoader' (though note that the B<SelfLoader> exports
223 the AUTOLOAD function - but if you have your own AUTOLOAD and
224 are using the AutoLoader too, you probably know what you're doing),
225 and the C<__END__> token to C<__DATA__>. You will need perl version 5.001m
226 or later to use this (version 5.001 with all patches up to patch m).
227
228 There is no need to inherit from the B<SelfLoader>.
229
230 The B<SelfLoader> works similarly to the AutoLoader, but picks up the
231 subs from after the C<__DATA__> instead of in the 'lib/auto' directory.
232 There is a maintenance gain in not needing to run AutoSplit on the module
233 at installation, and a runtime gain in not needing to keep opening and
234 closing files to load subs. There is a runtime loss in needing
235 to parse the code after the C<__DATA__>. Details of the B<AutoLoader> and
236 another view of these distinctions can be found in that module's
237 documentation.
238
239 =head2 __DATA__, __END__, and the FOOBAR::DATA filehandle.
240
241 This section is only relevant if you want to use
242 the C<FOOBAR::DATA> together with the B<SelfLoader>.
243
244 Data after the C<__DATA__> token in a module is read using the
245 FOOBAR::DATA filehandle. C<__END__> can still be used to denote the end
246 of the C<__DATA__> section if followed by the token DATA - this is supported
247 by the B<SelfLoader>. The C<FOOBAR::DATA> filehandle is left open if an
248 C<__END__> followed by a DATA is found, with the filehandle positioned at
249 the start of the line after the C<__END__> token. If no C<__END__> token is
250 present, or an C<__END__> token with no DATA token on the same line, then
251 the filehandle is closed.
252
253 The B<SelfLoader> reads from wherever the current
254 position of the C<FOOBAR::DATA> filehandle is, until the
255 EOF or C<__END__>. This means that if you want to use
256 that filehandle (and ONLY if you want to), you should either
257
258 1. Put all your subroutine declarations immediately after
259 the C<__DATA__> token and put your own data after those
260 declarations, using the C<__END__> token to mark the end
261 of subroutine declarations. You must also ensure that the B<SelfLoader>
262 reads first by  calling 'SelfLoader-E<gt>load_stubs();', or by using a
263 function which is selfloaded;
264
265 or
266
267 2. You should read the C<FOOBAR::DATA> filehandle first, leaving
268 the handle open and positioned at the first line of subroutine
269 declarations.
270
271 You could conceivably do both.
272
273 =head2 Classes and inherited methods.
274
275 For modules which are not classes, this section is not relevant.
276 This section is only relevant if you have methods which could
277 be inherited.
278
279 A subroutine stub (or forward declaration) looks like
280
281   sub stub;
282
283 i.e. it is a subroutine declaration without the body of the
284 subroutine. For modules which are not classes, there is no real
285 need for stubs as far as autoloading is concerned.
286
287 For modules which ARE classes, and need to handle inherited methods,
288 stubs are needed to ensure that the method inheritance mechanism works
289 properly. You can load the stubs into the module at 'require' time, by
290 adding the statement 'SelfLoader-E<gt>load_stubs();' to the module to do
291 this.
292
293 The alternative is to put the stubs in before the C<__DATA__> token BEFORE
294 releasing the module, and for this purpose the C<Devel::SelfStubber>
295 module is available.  However this does require the extra step of ensuring
296 that the stubs are in the module. If this is done I strongly recommend
297 that this is done BEFORE releasing the module - it should NOT be done
298 at install time in general.
299
300 =head1 Multiple packages and fully qualified subroutine names
301
302 Subroutines in multiple packages within the same file are supported - but you
303 should note that this requires exporting the C<SelfLoader::AUTOLOAD> to
304 every package which requires it. This is done automatically by the
305 B<SelfLoader> when it first loads the subs into the cache, but you should
306 really specify it in the initialization before the C<__DATA__> by putting
307 a 'use SelfLoader' statement in each package.
308
309 Fully qualified subroutine names are also supported. For example,
310
311    __DATA__
312    sub foo::bar {23}
313    package baz;
314    sub dob {32}
315
316 will all be loaded correctly by the B<SelfLoader>, and the B<SelfLoader>
317 will ensure that the packages 'foo' and 'baz' correctly have the
318 B<SelfLoader> C<AUTOLOAD> method when the data after C<__DATA__> is first
319 parsed.
320
321 =cut