Convert some SvREFCNT_dec's to SvREFCNT_dec_NN's for efficiency
[perl.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 The Syntax of Variable Names
8
9 Variable names in Perl can have several formats.  Usually, they
10 must begin with a letter or underscore, in which case they can be
11 arbitrarily long (up to an internal limit of 251 characters) and
12 may contain letters, digits, underscores, or the special sequence
13 C<::> or C<'>.  In this case, the part before the last C<::> or
14 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
15
16 Perl variable names may also be a sequence of digits or a single
17 punctuation or control character.  These names are all reserved for
18 special uses by Perl; for example, the all-digits names are used
19 to hold data captured by backreferences after a regular expression
20 match.  Perl has a special syntax for the single-control-character
21 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
22 character.  For example, the notation C<$^W> (dollar-sign caret
23 C<W>) is the scalar variable whose name is the single character
24 control-C<W>.  This is better than typing a literal control-C<W>
25 into your program.
26
27 Since Perl v5.6.0, Perl variable names may be alphanumeric
28 strings that begin with control characters (or better yet, a caret).
29 These variables must be written in the form C<${^Foo}>; the braces
30 are not optional.  C<${^Foo}> denotes the scalar variable whose
31 name is a control-C<F> followed by two C<o>'s.  These variables are
32 reserved for future special uses by Perl, except for the ones that
33 begin with C<^_> (control-underscore or caret-underscore).  No
34 control-character name that begins with C<^_> will acquire a special
35 meaning in any future version of Perl; such names may therefore be
36 used safely in programs.  C<$^_> itself, however, I<is> reserved.
37
38 Perl identifiers that begin with digits, control characters, or
39 punctuation characters are exempt from the effects of the C<package>
40 declaration and are always forced to be in package C<main>; they are
41 also exempt from C<strict 'vars'> errors.  A few other names are also
42 exempt in these ways:
43
44     ENV      STDIN
45     INC      STDOUT
46     ARGV     STDERR
47     ARGVOUT
48     SIG
49
50 In particular, the special C<${^_XYZ}> variables are always taken
51 to be in package C<main>, regardless of any C<package> declarations
52 presently in scope.
53
54 =head1 SPECIAL VARIABLES
55
56 The following names have special meaning to Perl.  Most punctuation
57 names have reasonable mnemonics, or analogs in the shells.
58 Nevertheless, if you wish to use long variable names, you need only say:
59
60     use English;
61
62 at the top of your program.  This aliases all the short names to the long
63 names in the current package.  Some even have medium names, generally
64 borrowed from B<awk>.  To avoid a performance hit, if you don't need the
65 C<$PREMATCH>, C<$MATCH>, or C<$POSTMATCH> it's best to use the C<English>
66 module without them:
67
68     use English '-no_match_vars';
69
70 Before you continue, note the sort order for variables.  In general, we
71 first list the variables in case-insensitive, almost-lexigraphical
72 order (ignoring the C<{> or C<^> preceding words, as in C<${^UNICODE}>
73 or C<$^T>), although C<$_> and C<@_> move up to the top of the pile.
74 For variables with the same identifier, we list it in order of scalar,
75 array, hash, and bareword.
76
77 =head2 General Variables
78
79 =over 8
80
81 =item $ARG
82
83 =item $_
84 X<$_> X<$ARG>
85
86 The default input and pattern-searching space.  The following pairs are
87 equivalent:
88
89     while (<>) {...}    # equivalent only in while!
90     while (defined($_ = <>)) {...}
91
92     /^Subject:/
93     $_ =~ /^Subject:/
94
95     tr/a-z/A-Z/
96     $_ =~ tr/a-z/A-Z/
97
98     chomp
99     chomp($_)
100
101 Here are the places where Perl will assume C<$_> even if you don't use it:
102
103 =over 3
104
105 =item *
106
107 The following functions use C<$_> as a default argument:
108
109 abs, alarm, chomp, chop, chr, chroot,
110 cos, defined, eval, evalbytes, exp, fc, glob, hex, int, lc,
111 lcfirst, length, log, lstat, mkdir, oct, ord, pos, print, printf,
112 quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
113 rmdir, say, sin, split (for its second
114 argument), sqrt, stat, study, uc, ucfirst,
115 unlink, unpack.
116
117 =item *
118
119 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
120 See L<perlfunc/-X>
121
122 =item *
123
124 The pattern matching operations C<m//>, C<s///> and C<tr///> (aka C<y///>)
125 when used without an C<=~> operator.
126
127 =item *
128
129 The default iterator variable in a C<foreach> loop if no other
130 variable is supplied.
131
132 =item *
133
134 The implicit iterator variable in the C<grep()> and C<map()> functions.
135
136 =item *
137
138 The implicit variable of C<given()>.
139
140 =item *
141
142 The default place to put the next value or input record
143 when a C<< <FH> >>, C<readline>, C<readdir> or C<each>
144 operation's result is tested by itself as the sole criterion of a C<while>
145 test.  Outside a C<while> test, this will not happen.
146
147 =back
148
149 C<$_> is by default a global variable.  However, as
150 of perl v5.10.0, you can use a lexical version of
151 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
152 declaring C<our $_> restores the global C<$_> in the current scope.  Though
153 this seemed like a good idea at the time it was introduced, lexical C<$_>
154 actually causes more problems than it solves.  If you call a function that
155 expects to be passed information via C<$_>, it may or may not work,
156 depending on how the function is written, there not being any easy way to
157 solve this.  Just avoid lexical C<$_>, unless you are feeling particularly
158 masochistic.  For this reason lexical C<$_> is deprecated and will produce
159 a warning unless warnings have been disabled.
160
161 Mnemonic: underline is understood in certain operations.
162
163 =item @ARG
164
165 =item @_
166 X<@_> X<@ARG>
167
168 Within a subroutine the array C<@_> contains the parameters passed to
169 that subroutine.  Inside a subroutine, C<@_> is the default array for
170 the array operators C<push>, C<pop>, C<shift>, and C<unshift>.
171
172 See L<perlsub>.
173
174 =item $LIST_SEPARATOR
175
176 =item $"
177 X<$"> X<$LIST_SEPARATOR>
178
179 When an array or an array slice is interpolated into a double-quoted
180 string or a similar context such as C</.../>, its elements are
181 separated by this value.  Default is a space.  For example, this:
182
183     print "The array is: @array\n";
184
185 is equivalent to this:
186
187     print "The array is: " . join($", @array) . "\n";
188
189 Mnemonic: works in double-quoted context.
190
191 =item $PROCESS_ID
192
193 =item $PID
194
195 =item $$
196 X<$$> X<$PID> X<$PROCESS_ID>
197
198 The process number of the Perl running this script.  Though you I<can> set
199 this variable, doing so is generally discouraged, although it can be
200 invaluable for some testing purposes.  It will be reset automatically
201 across C<fork()> calls.
202
203 Note for Linux and Debian GNU/kFreeBSD users: Before Perl v5.16.0 perl
204 would emulate POSIX semantics on Linux systems using LinuxThreads, a
205 partial implementation of POSIX Threads that has since been superseded
206 by the Native POSIX Thread Library (NPTL).
207
208 LinuxThreads is now obsolete on Linux, and caching C<getpid()>
209 like this made embedding perl unnecessarily complex (since you'd have
210 to manually update the value of $$), so now C<$$> and C<getppid()>
211 will always return the same values as the underlying C library.
212
213 Debian GNU/kFreeBSD systems also used LinuxThreads up until and
214 including the 6.0 release, but after that moved to FreeBSD thread
215 semantics, which are POSIX-like.
216
217 To see if your system is affected by this discrepancy check if
218 C<getconf GNU_LIBPTHREAD_VERSION | grep -q NPTL> returns a false
219 value. NTPL threads preserve the POSIX semantics.
220
221 Mnemonic: same as shells.
222
223 =item $PROGRAM_NAME
224
225 =item $0
226 X<$0> X<$PROGRAM_NAME>
227
228 Contains the name of the program being executed.
229
230 On some (but not all) operating systems assigning to C<$0> modifies
231 the argument area that the C<ps> program sees.  On some platforms you
232 may have to use special C<ps> options or a different C<ps> to see the
233 changes.  Modifying the C<$0> is more useful as a way of indicating the
234 current program state than it is for hiding the program you're
235 running.
236
237 Note that there are platform-specific limitations on the maximum
238 length of C<$0>.  In the most extreme case it may be limited to the
239 space occupied by the original C<$0>.
240
241 In some platforms there may be arbitrary amount of padding, for
242 example space characters, after the modified name as shown by C<ps>.
243 In some platforms this padding may extend all the way to the original
244 length of the argument area, no matter what you do (this is the case
245 for example with Linux 2.2).
246
247 Note for BSD users: setting C<$0> does not completely remove "perl"
248 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
249 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
250 and the " (perl)" suffix are shown depends on your exact BSD variant
251 and version).  This is an operating system feature, Perl cannot help it.
252
253 In multithreaded scripts Perl coordinates the threads so that any
254 thread may modify its copy of the C<$0> and the change becomes visible
255 to ps(1) (assuming the operating system plays along).  Note that
256 the view of C<$0> the other threads have will not change since they
257 have their own copies of it.
258
259 If the program has been given to perl via the switches C<-e> or C<-E>,
260 C<$0> will contain the string C<"-e">.
261
262 On Linux as of perl v5.14.0 the legacy process name will be set with
263 C<prctl(2)>, in addition to altering the POSIX name via C<argv[0]> as
264 perl has done since version 4.000.  Now system utilities that read the
265 legacy process name such as ps, top and killall will recognize the
266 name you set when assigning to C<$0>.  The string you supply will be
267 cut off at 16 bytes, this is a limitation imposed by Linux.
268
269 Mnemonic: same as B<sh> and B<ksh>.
270
271 =item $REAL_GROUP_ID
272
273 =item $GID
274
275 =item $(
276 X<$(> X<$GID> X<$REAL_GROUP_ID>
277
278 The real gid of this process.  If you are on a machine that supports
279 membership in multiple groups simultaneously, gives a space separated
280 list of groups you are in.  The first number is the one returned by
281 C<getgid()>, and the subsequent ones by C<getgroups()>, one of which may be
282 the same as the first number.
283
284 However, a value assigned to C<$(> must be a single number used to
285 set the real gid.  So the value given by C<$(> should I<not> be assigned
286 back to C<$(> without being forced numeric, such as by adding zero.  Note
287 that this is different to the effective gid (C<$)>) which does take a
288 list.
289
290 You can change both the real gid and the effective gid at the same
291 time by using C<POSIX::setgid()>.  Changes
292 to C<$(> require a check to C<$!>
293 to detect any possible errors after an attempted change.
294
295 Mnemonic: parentheses are used to I<group> things.  The real gid is the
296 group you I<left>, if you're running setgid.
297
298 =item $EFFECTIVE_GROUP_ID
299
300 =item $EGID
301
302 =item $)
303 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
304
305 The effective gid of this process.  If you are on a machine that
306 supports membership in multiple groups simultaneously, gives a space
307 separated list of groups you are in.  The first number is the one
308 returned by C<getegid()>, and the subsequent ones by C<getgroups()>,
309 one of which may be the same as the first number.
310
311 Similarly, a value assigned to C<$)> must also be a space-separated
312 list of numbers.  The first number sets the effective gid, and
313 the rest (if any) are passed to C<setgroups()>.  To get the effect of an
314 empty list for C<setgroups()>, just repeat the new effective gid; that is,
315 to force an effective gid of 5 and an effectively empty C<setgroups()>
316 list, say C< $) = "5 5" >.
317
318 You can change both the effective gid and the real gid at the same
319 time by using C<POSIX::setgid()> (use only a single numeric argument).
320 Changes to C<$)> require a check to C<$!> to detect any possible errors
321 after an attempted change.
322
323 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
324 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
325 and C<$)> can be swapped only on machines supporting C<setregid()>.
326
327 Mnemonic: parentheses are used to I<group> things.  The effective gid
328 is the group that's I<right> for you, if you're running setgid.
329
330 =item $REAL_USER_ID
331
332 =item $UID
333
334 =item $<
335 X<< $< >> X<$UID> X<$REAL_USER_ID>
336
337 The real uid of this process.  You can change both the real uid and the
338 effective uid at the same time by using C<POSIX::setuid()>.  Since
339 changes to C<< $< >> require a system call, check C<$!> after a change
340 attempt to detect any possible errors.
341
342 Mnemonic: it's the uid you came I<from>, if you're running setuid.
343
344 =item $EFFECTIVE_USER_ID
345
346 =item $EUID
347
348 =item $>
349 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
350
351 The effective uid of this process.  For example:
352
353     $< = $>;            # set real to effective uid
354     ($<,$>) = ($>,$<);  # swap real and effective uids
355
356 You can change both the effective uid and the real uid at the same
357 time by using C<POSIX::setuid()>.  Changes to C<< $> >> require a check
358 to C<$!> to detect any possible errors after an attempted change.
359
360 C<< $< >> and C<< $> >> can be swapped only on machines
361 supporting C<setreuid()>.
362
363 Mnemonic: it's the uid you went I<to>, if you're running setuid.
364
365 =item $SUBSCRIPT_SEPARATOR
366
367 =item $SUBSEP
368
369 =item $;
370 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
371
372 The subscript separator for multidimensional array emulation.  If you
373 refer to a hash element as
374
375     $foo{$a,$b,$c}
376
377 it really means
378
379     $foo{join($;, $a, $b, $c)}
380
381 But don't put
382
383     @foo{$a,$b,$c}      # a slice--note the @
384
385 which means
386
387     ($foo{$a},$foo{$b},$foo{$c})
388
389 Default is "\034", the same as SUBSEP in B<awk>.  If your keys contain
390 binary data there might not be any safe value for C<$;>.
391
392 Consider using "real" multidimensional arrays as described
393 in L<perllol>.
394
395 Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.
396
397 =item $a
398
399 =item $b
400 X<$a> X<$b>
401
402 Special package variables when using C<sort()>, see L<perlfunc/sort>.
403 Because of this specialness C<$a> and C<$b> don't need to be declared
404 (using C<use vars>, or C<our()>) even when using the C<strict 'vars'>
405 pragma.  Don't lexicalize them with C<my $a> or C<my $b> if you want to
406 be able to use them in the C<sort()> comparison block or function.
407
408 =item %ENV
409 X<%ENV>
410
411 The hash C<%ENV> contains your current environment.  Setting a
412 value in C<ENV> changes the environment for any child processes
413 you subsequently C<fork()> off.
414
415 =item $SYSTEM_FD_MAX
416
417 =item $^F
418 X<$^F> X<$SYSTEM_FD_MAX>
419
420 The maximum system file descriptor, ordinarily 2.  System file
421 descriptors are passed to C<exec()>ed processes, while higher file
422 descriptors are not.  Also, during an
423 C<open()>, system file descriptors are
424 preserved even if the C<open()> fails (ordinary file descriptors are
425 closed before the C<open()> is attempted).  The close-on-exec
426 status of a file descriptor will be decided according to the value of
427 C<$^F> when the corresponding file, pipe, or socket was opened, not the
428 time of the C<exec()>.
429
430 =item @F
431 X<@F>
432
433 The array C<@F> contains the fields of each line read in when autosplit
434 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
435 is package-specific, and must be declared or given a full package name
436 if not in package main when running under C<strict 'vars'>.
437
438 =item @INC
439 X<@INC>
440
441 The array C<@INC> contains the list of places that the C<do EXPR>,
442 C<require>, or C<use> constructs look for their library files.  It
443 initially consists of the arguments to any B<-I> command-line
444 switches, followed by the default Perl library, probably
445 F</usr/local/lib/perl>, followed by ".", to represent the current
446 directory.  ("." will not be appended if taint checks are enabled,
447 either by C<-T> or by C<-t>.)  If you need to modify this at runtime,
448 you should use the C<use lib> pragma to get the machine-dependent
449 library properly loaded also:
450
451     use lib '/mypath/libdir/';
452     use SomeMod;
453
454 You can also insert hooks into the file inclusion system by putting Perl
455 code directly into C<@INC>.  Those hooks may be subroutine references,
456 array references or blessed objects.  See L<perlfunc/require> for details.
457
458 =item %INC
459 X<%INC>
460
461 The hash C<%INC> contains entries for each filename included via the
462 C<do>, C<require>, or C<use> operators.  The key is the filename
463 you specified (with module names converted to pathnames), and the
464 value is the location of the file found.  The C<require>
465 operator uses this hash to determine whether a particular file has
466 already been included.
467
468 If the file was loaded via a hook (e.g. a subroutine reference, see
469 L<perlfunc/require> for a description of these hooks), this hook is
470 by default inserted into C<%INC> in place of a filename.  Note, however,
471 that the hook may have set the C<%INC> entry by itself to provide some more
472 specific info.
473
474 =item $INPLACE_EDIT
475
476 =item $^I
477 X<$^I> X<$INPLACE_EDIT>
478
479 The current value of the inplace-edit extension.  Use C<undef> to disable
480 inplace editing.
481
482 Mnemonic: value of B<-i> switch.
483
484 =item $^M
485 X<$^M>
486
487 By default, running out of memory is an untrappable, fatal error.
488 However, if suitably built, Perl can use the contents of C<$^M>
489 as an emergency memory pool after C<die()>ing.  Suppose that your Perl
490 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
491 Then
492
493     $^M = 'a' x (1 << 16);
494
495 would allocate a 64K buffer for use in an emergency.  See the
496 F<INSTALL> file in the Perl distribution for information on how to
497 add custom C compilation flags when compiling perl.  To discourage casual
498 use of this advanced feature, there is no L<English|English> long name for
499 this variable.
500
501 This variable was added in Perl 5.004.
502
503 =item $OSNAME
504
505 =item $^O
506 X<$^O> X<$OSNAME>
507
508 The name of the operating system under which this copy of Perl was
509 built, as determined during the configuration process.  For examples
510 see L<perlport/PLATFORMS>.
511
512 The value is identical to C<$Config{'osname'}>.  See also L<Config>
513 and the B<-V> command-line switch documented in L<perlrun>.
514
515 In Windows platforms, C<$^O> is not very helpful: since it is always
516 C<MSWin32>, it doesn't tell the difference between
517 95/98/ME/NT/2000/XP/CE/.NET.  Use C<Win32::GetOSName()> or
518 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
519 between the variants.
520
521 This variable was added in Perl 5.003.
522
523 =item %SIG
524 X<%SIG>
525
526 The hash C<%SIG> contains signal handlers for signals.  For example:
527
528     sub handler {   # 1st argument is signal name
529         my($sig) = @_;
530         print "Caught a SIG$sig--shutting down\n";
531         close(LOG);
532         exit(0);
533         }
534
535     $SIG{'INT'}  = \&handler;
536     $SIG{'QUIT'} = \&handler;
537     ...
538     $SIG{'INT'}  = 'DEFAULT';   # restore default action
539     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
540
541 Using a value of C<'IGNORE'> usually has the effect of ignoring the
542 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
543 this special case.
544
545 Here are some other examples:
546
547     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not
548                                 # recommended)
549     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current
550                                 # Plumber
551     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
552     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber()
553                                 # return??
554
555 Be sure not to use a bareword as the name of a signal handler,
556 lest you inadvertently call it.
557
558 If your system has the C<sigaction()> function then signal handlers
559 are installed using it.  This means you get reliable signal handling.
560
561 The default delivery policy of signals changed in Perl v5.8.0 from
562 immediate (also known as "unsafe") to deferred, also known as "safe
563 signals".  See L<perlipc> for more information.
564
565 Certain internal hooks can be also set using the C<%SIG> hash.  The
566 routine indicated by C<$SIG{__WARN__}> is called when a warning
567 message is about to be printed.  The warning message is passed as the
568 first argument.  The presence of a C<__WARN__> hook causes the
569 ordinary printing of warnings to C<STDERR> to be suppressed.  You can
570 use this to save warnings in a variable, or turn warnings into fatal
571 errors, like this:
572
573     local $SIG{__WARN__} = sub { die $_[0] };
574     eval $proggie;
575
576 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
577 disable warnings using the empty subroutine:
578
579     local $SIG{__WARN__} = sub {};
580
581 The routine indicated by C<$SIG{__DIE__}> is called when a fatal
582 exception is about to be thrown.  The error message is passed as the
583 first argument.  When a C<__DIE__> hook routine returns, the exception
584 processing continues as it would have in the absence of the hook,
585 unless the hook routine itself exits via a C<goto &sub>, a loop exit,
586 or a C<die()>.  The C<__DIE__> handler is explicitly disabled during
587 the call, so that you can die from a C<__DIE__> handler.  Similarly
588 for C<__WARN__>.
589
590 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
591 even inside an C<eval()>.  Do not use this to rewrite a pending
592 exception in C<$@>, or as a bizarre substitute for overriding
593 C<CORE::GLOBAL::die()>.  This strange action at a distance may be fixed
594 in a future release so that C<$SIG{__DIE__}> is only called if your
595 program is about to exit, as was the original intent.  Any other use is
596 deprecated.
597
598 C<__DIE__>/C<__WARN__> handlers are very special in one respect: they
599 may be called to report (probable) errors found by the parser.  In such
600 a case the parser may be in inconsistent state, so any attempt to
601 evaluate Perl code from such a handler will probably result in a
602 segfault.  This means that warnings or errors that result from parsing
603 Perl should be used with extreme caution, like this:
604
605     require Carp if defined $^S;
606     Carp::confess("Something wrong") if defined &Carp::confess;
607     die "Something wrong, but could not load Carp to give "
608       . "backtrace...\n\t"
609       . "To see backtrace try starting Perl with -MCarp switch";
610
611 Here the first line will load C<Carp> I<unless> it is the parser who
612 called the handler.  The second line will print backtrace and die if
613 C<Carp> was available.  The third line will be executed only if C<Carp> was
614 not available.
615
616 Having to even think about the C<$^S> variable in your exception
617 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
618 invites grievous and difficult to track down errors.  Avoid it
619 and use an C<END{}> or CORE::GLOBAL::die override instead.
620
621 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
622 L<warnings> for additional information.
623
624 =item $BASETIME
625
626 =item $^T
627 X<$^T> X<$BASETIME>
628
629 The time at which the program began running, in seconds since the
630 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
631 and B<-C> filetests are based on this value.
632
633 =item $PERL_VERSION
634
635 =item $^V
636 X<$^V> X<$PERL_VERSION>
637
638 The revision, version, and subversion of the Perl interpreter,
639 represented as a C<version> object.
640
641 This variable first appeared in perl v5.6.0; earlier versions of perl
642 will see an undefined value.  Before perl v5.10.0 C<$^V> was represented
643 as a v-string.
644
645 C<$^V> can be used to determine whether the Perl interpreter executing
646 a script is in the right range of versions.  For example:
647
648     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
649
650 To convert C<$^V> into its string representation use C<sprintf()>'s
651 C<"%vd"> conversion:
652
653     printf "version is v%vd\n", $^V;  # Perl's version
654
655 See the documentation of C<use VERSION> and C<require VERSION>
656 for a convenient way to fail if the running Perl interpreter is too old.
657
658 See also C<$]> for an older representation of the Perl version.
659
660 This variable was added in Perl v5.6.0.
661
662 Mnemonic: use ^V for Version Control.
663
664 =item ${^WIN32_SLOPPY_STAT}
665 X<${^WIN32_SLOPPY_STAT}> X<sitecustomize> X<sitecustomize.pl>
666
667 If this variable is set to a true value, then C<stat()> on Windows will
668 not try to open the file.  This means that the link count cannot be
669 determined and file attributes may be out of date if additional
670 hardlinks to the file exist.  On the other hand, not opening the file
671 is considerably faster, especially for files on network drives.
672
673 This variable could be set in the F<sitecustomize.pl> file to
674 configure the local Perl installation to use "sloppy" C<stat()> by
675 default.  See the documentation for B<-f> in
676 L<perlrun|perlrun/"Command Switches"> for more information about site
677 customization.
678
679 This variable was added in Perl v5.10.0.
680
681 =item $EXECUTABLE_NAME
682
683 =item $^X
684 X<$^X> X<$EXECUTABLE_NAME>
685
686 The name used to execute the current copy of Perl, from C's
687 C<argv[0]> or (where supported) F</proc/self/exe>.
688
689 Depending on the host operating system, the value of C<$^X> may be
690 a relative or absolute pathname of the perl program file, or may
691 be the string used to invoke perl but not the pathname of the
692 perl program file.  Also, most operating systems permit invoking
693 programs that are not in the PATH environment variable, so there
694 is no guarantee that the value of C<$^X> is in PATH.  For VMS, the
695 value may or may not include a version number.
696
697 You usually can use the value of C<$^X> to re-invoke an independent
698 copy of the same perl that is currently running, e.g.,
699
700     @first_run = `$^X -le "print int rand 100 for 1..100"`;
701
702 But recall that not all operating systems support forking or
703 capturing of the output of commands, so this complex statement
704 may not be portable.
705
706 It is not safe to use the value of C<$^X> as a path name of a file,
707 as some operating systems that have a mandatory suffix on
708 executable files do not require use of the suffix when invoking
709 a command.  To convert the value of C<$^X> to a path name, use the
710 following statements:
711
712     # Build up a set of file names (not command names).
713     use Config;
714     my $this_perl = $^X;
715     if ($^O ne 'VMS') {
716         $this_perl .= $Config{_exe}
717           unless $this_perl =~ m/$Config{_exe}$/i;
718         }
719
720 Because many operating systems permit anyone with read access to
721 the Perl program file to make a copy of it, patch the copy, and
722 then execute the copy, the security-conscious Perl programmer
723 should take care to invoke the installed copy of perl, not the
724 copy referenced by C<$^X>.  The following statements accomplish
725 this goal, and produce a pathname that can be invoked as a
726 command or referenced as a file.
727
728     use Config;
729     my $secure_perl_path = $Config{perlpath};
730     if ($^O ne 'VMS') {
731         $secure_perl_path .= $Config{_exe}
732             unless $secure_perl_path =~ m/$Config{_exe}$/i;
733         }
734
735 =back
736
737 =head2 Variables related to regular expressions
738
739 Most of the special variables related to regular expressions are side
740 effects.  Perl sets these variables when it has a successful match, so
741 you should check the match result before using them.  For instance:
742
743     if( /P(A)TT(ER)N/ ) {
744         print "I found $1 and $2\n";
745         }
746
747 These variables are read-only and dynamically-scoped, unless we note
748 otherwise.
749
750 The dynamic nature of the regular expression variables means that
751 their value is limited to the block that they are in, as demonstrated
752 by this bit of code:
753
754     my $outer = 'Wallace and Grommit';
755     my $inner = 'Mutt and Jeff';
756
757     my $pattern = qr/(\S+) and (\S+)/;
758
759     sub show_n { print "\$1 is $1; \$2 is $2\n" }
760
761     {
762     OUTER:
763         show_n() if $outer =~ m/$pattern/;
764
765         INNER: {
766             show_n() if $inner =~ m/$pattern/;
767             }
768
769         show_n();
770     }
771
772 The output shows that while in the C<OUTER> block, the values of C<$1>
773 and C<$2> are from the match against C<$outer>.  Inside the C<INNER>
774 block, the values of C<$1> and C<$2> are from the match against
775 C<$inner>, but only until the end of the block (i.e. the dynamic
776 scope).  After the C<INNER> block completes, the values of C<$1> and
777 C<$2> return to the values for the match against C<$outer> even though
778 we have not made another match:
779
780     $1 is Wallace; $2 is Grommit
781     $1 is Mutt; $2 is Jeff
782     $1 is Wallace; $2 is Grommit
783
784 If you are using Perl v5.16 or earlier, note that C<use
785 English> imposes a considerable performance penalty on all regular
786 expression matches in a program because it uses the C<$`>, C<$&>, and
787 C<$'>, regardless of whether they occur in the scope of C<use
788 English>.  For that reason, saying C<use English> in libraries is
789 strongly discouraged unless you import it without the match variables:
790
791     use English '-no_match_vars'
792
793 The C<Devel::NYTProf> and C<Devel::FindAmpersand>
794 modules can help you find uses of these
795 problematic match variables in your code.
796
797 Since Perl v5.10.0, you can use the C</p> match operator flag and the
798 C<${^PREMATCH}>, C<${^MATCH}>, and C<${^POSTMATCH}> variables instead
799 so you only suffer the performance penalties.
800
801 If you are using Perl v5.18.0 or higher, you do not need to worry about
802 this, as the three naughty variables are no longer naughty.
803
804 =over 8
805
806 =item $<I<digits>> ($1, $2, ...)
807 X<$1> X<$2> X<$3>
808
809 Contains the subpattern from the corresponding set of capturing
810 parentheses from the last successful pattern match, not counting patterns
811 matched in nested blocks that have been exited already.
812
813 These variables are read-only and dynamically-scoped.
814
815 Mnemonic: like \digits.
816
817 =item $MATCH
818
819 =item $&
820 X<$&> X<$MATCH>
821
822 The string matched by the last successful pattern match (not counting
823 any matches hidden within a BLOCK or C<eval()> enclosed by the current
824 BLOCK).
825
826 In Perl v5.16 and earlier, the use of this variable
827 anywhere in a program imposes a considerable
828 performance penalty on all regular expression matches.  To avoid this
829 penalty, you can extract the same substring by using L</@->.  Starting
830 with Perl v5.10.0, you can use the C</p> match flag and the C<${^MATCH}>
831 variable to do the same thing for particular match operations.
832
833 This variable is read-only and dynamically-scoped.
834
835 Mnemonic: like C<&> in some editors.
836
837 =item ${^MATCH}
838 X<${^MATCH}>
839
840 This is similar to C<$&> (C<$MATCH>) except that it does not incur the
841 performance penalty associated with that variable.
842 In Perl v5.16 and earlier, it is only guaranteed
843 to return a defined value when the pattern was compiled or executed with
844 the C</p> modifier.  In Perl v5.18, the C</p> modifier does nothing, so
845 C<${^MATCH}> does the same thing as C<$MATCH>.
846
847 This variable was added in Perl v5.10.0.
848
849 This variable is read-only and dynamically-scoped.
850
851 =item $PREMATCH
852
853 =item $`
854 X<$`> X<$PREMATCH> X<${^PREMATCH}>
855
856 The string preceding whatever was matched by the last successful
857 pattern match, not counting any matches hidden within a BLOCK or C<eval>
858 enclosed by the current BLOCK.
859
860 In Perl v5.16 and earlier, the use of this variable
861 anywhere in a program imposes a considerable
862 performance penalty on all regular expression matches.  To avoid this
863 penalty, you can extract the same substring by using L</@->.  Starting
864 with Perl v5.10.0, you can use the C</p> match flag and the
865 C<${^PREMATCH}> variable to do the same thing for particular match
866 operations.
867
868 This variable is read-only and dynamically-scoped.
869
870 Mnemonic: C<`> often precedes a quoted string.
871
872 =item ${^PREMATCH}
873 X<$`> X<${^PREMATCH}>
874
875 This is similar to C<$`> ($PREMATCH) except that it does not incur the
876 performance penalty associated with that variable. 
877 In Perl v5.16 and earlier, it is only guaranteed
878 to return a defined value when the pattern was compiled or executed with
879 the C</p> modifier.  In Perl v5.18, the C</p> modifier does nothing, so
880 C<${^PREMATCH}> does the same thing as C<$PREMATCH>.
881
882 This variable was added in Perl v5.10.0
883
884 This variable is read-only and dynamically-scoped.
885
886 =item $POSTMATCH
887
888 =item $'
889 X<$'> X<$POSTMATCH> X<${^POSTMATCH}> X<@->
890
891 The string following whatever was matched by the last successful
892 pattern match (not counting any matches hidden within a BLOCK or C<eval()>
893 enclosed by the current BLOCK).  Example:
894
895     local $_ = 'abcdefghi';
896     /def/;
897     print "$`:$&:$'\n";         # prints abc:def:ghi
898
899 In Perl v5.16 and earlier, the use of this variable
900 anywhere in a program imposes a considerable
901 performance penalty on all regular expression matches.
902 To avoid this penalty, you can extract the same substring by
903 using L</@->.  Starting with Perl v5.10.0, you can use the C</p> match flag
904 and the C<${^POSTMATCH}> variable to do the same thing for particular
905 match operations.
906
907 This variable is read-only and dynamically-scoped.
908
909 Mnemonic: C<'> often follows a quoted string.
910
911 =item ${^POSTMATCH}
912 X<${^POSTMATCH}> X<$'> X<$POSTMATCH>
913
914 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
915 performance penalty associated with that variable.
916 In Perl v5.16 and earlier, it is only guaranteed
917 to return a defined value when the pattern was compiled or executed with
918 the C</p> modifier.  In Perl v5.18, the C</p> modifier does nothing, so
919 C<${^POSTMATCH}> does the same thing as C<$POSTMATCH>.
920
921 This variable was added in Perl v5.10.0.
922
923 This variable is read-only and dynamically-scoped.
924
925 =item $LAST_PAREN_MATCH
926
927 =item $+
928 X<$+> X<$LAST_PAREN_MATCH>
929
930 The text matched by the last bracket of the last successful search pattern.
931 This is useful if you don't know which one of a set of alternative patterns
932 matched.  For example:
933
934     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
935
936 This variable is read-only and dynamically-scoped.
937
938 Mnemonic: be positive and forward looking.
939
940 =item $LAST_SUBMATCH_RESULT
941
942 =item $^N
943 X<$^N> X<$LAST_SUBMATCH_RESULT>
944
945 The text matched by the used group most-recently closed (i.e. the group
946 with the rightmost closing parenthesis) of the last successful search
947 pattern.
948
949 This is primarily used inside C<(?{...})> blocks for examining text
950 recently matched.  For example, to effectively capture text to a variable
951 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
952
953     (?:(...)(?{ $var = $^N }))
954
955 By setting and then using C<$var> in this way relieves you from having to
956 worry about exactly which numbered set of parentheses they are.
957
958 This variable was added in Perl v5.8.0.
959
960 Mnemonic: the (possibly) Nested parenthesis that most recently closed.
961
962 =item @LAST_MATCH_END
963
964 =item @+
965 X<@+> X<@LAST_MATCH_END>
966
967 This array holds the offsets of the ends of the last successful
968 submatches in the currently active dynamic scope.  C<$+[0]> is
969 the offset into the string of the end of the entire match.  This
970 is the same value as what the C<pos> function returns when called
971 on the variable that was matched against.  The I<n>th element
972 of this array holds the offset of the I<n>th submatch, so
973 C<$+[1]> is the offset past where C<$1> ends, C<$+[2]> the offset
974 past where C<$2> ends, and so on.  You can use C<$#+> to determine
975 how many subgroups were in the last successful match.  See the
976 examples given for the C<@-> variable.
977
978 This variable was added in Perl v5.6.0.
979
980 =item %LAST_PAREN_MATCH
981
982 =item %+
983 X<%+> X<%LAST_PAREN_MATCH>
984
985 Similar to C<@+>, the C<%+> hash allows access to the named capture
986 buffers, should they exist, in the last successful match in the
987 currently active dynamic scope.
988
989 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
990
991     'foo' =~ /(?<foo>foo)/;
992
993 The keys of the C<%+> hash list only the names of buffers that have
994 captured (and that are thus associated to defined values).
995
996 The underlying behaviour of C<%+> is provided by the
997 L<Tie::Hash::NamedCapture> module.
998
999 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1000 associated with the last successful regular expression.  Therefore mixing
1001 iterative access to them via C<each> may have unpredictable results.
1002 Likewise, if the last successful match changes, then the results may be
1003 surprising.
1004
1005 This variable was added in Perl v5.10.0.
1006
1007 This variable is read-only and dynamically-scoped.
1008
1009 =item @LAST_MATCH_START
1010
1011 =item @-
1012 X<@-> X<@LAST_MATCH_START>
1013
1014 C<$-[0]> is the offset of the start of the last successful match.
1015 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
1016 I<n>-th subpattern, or undef if the subpattern did not match.
1017
1018 Thus, after a match against C<$_>, C<$&> coincides with C<substr $_, $-[0],
1019 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
1020 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
1021 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the
1022 last matched subgroup in the last successful match.  Contrast with
1023 C<$#+>, the number of subgroups in the regular expression.  Compare
1024 with C<@+>.
1025
1026 This array holds the offsets of the beginnings of the last
1027 successful submatches in the currently active dynamic scope.
1028 C<$-[0]> is the offset into the string of the beginning of the
1029 entire match.  The I<n>th element of this array holds the offset
1030 of the I<n>th submatch, so C<$-[1]> is the offset where C<$1>
1031 begins, C<$-[2]> the offset where C<$2> begins, and so on.
1032
1033 After a match against some variable C<$var>:
1034
1035 =over 5
1036
1037 =item C<$`> is the same as C<substr($var, 0, $-[0])>
1038
1039 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
1040
1041 =item C<$'> is the same as C<substr($var, $+[0])>
1042
1043 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>
1044
1045 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
1046
1047 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
1048
1049 =back
1050
1051 This variable was added in Perl v5.6.0.
1052
1053 =item %LAST_MATCH_START
1054
1055 =item %-
1056 X<%-> X<%LAST_MATCH_START>
1057
1058 Similar to C<%+>, this variable allows access to the named capture groups
1059 in the last successful match in the currently active dynamic scope.  To
1060 each capture group name found in the regular expression, it associates a
1061 reference to an array containing the list of values captured by all
1062 buffers with that name (should there be several of them), in the order
1063 where they appear.
1064
1065 Here's an example:
1066
1067     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
1068         foreach my $bufname (sort keys %-) {
1069             my $ary = $-{$bufname};
1070             foreach my $idx (0..$#$ary) {
1071                 print "\$-{$bufname}[$idx] : ",
1072                       (defined($ary->[$idx])
1073                           ? "'$ary->[$idx]'"
1074                           : "undef"),
1075                       "\n";
1076             }
1077         }
1078     }
1079
1080 would print out:
1081
1082     $-{A}[0] : '1'
1083     $-{A}[1] : '3'
1084     $-{B}[0] : '2'
1085     $-{B}[1] : '4'
1086
1087 The keys of the C<%-> hash correspond to all buffer names found in
1088 the regular expression.
1089
1090 The behaviour of C<%-> is implemented via the
1091 L<Tie::Hash::NamedCapture> module.
1092
1093 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1094 associated with the last successful regular expression.  Therefore mixing
1095 iterative access to them via C<each> may have unpredictable results.
1096 Likewise, if the last successful match changes, then the results may be
1097 surprising.
1098
1099 This variable was added in Perl v5.10.0.
1100
1101 This variable is read-only and dynamically-scoped.
1102
1103 =item $LAST_REGEXP_CODE_RESULT
1104
1105 =item $^R
1106 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1107
1108 The result of evaluation of the last successful C<(?{ code })>
1109 regular expression assertion (see L<perlre>).  May be written to.
1110
1111 This variable was added in Perl 5.005.
1112
1113 =item ${^RE_DEBUG_FLAGS}
1114 X<${^RE_DEBUG_FLAGS}>
1115
1116 The current value of the regex debugging flags.  Set to 0 for no debug output
1117 even when the C<re 'debug'> module is loaded.  See L<re> for details.
1118
1119 This variable was added in Perl v5.10.0.
1120
1121 =item ${^RE_TRIE_MAXBUF}
1122 X<${^RE_TRIE_MAXBUF}>
1123
1124 Controls how certain regex optimisations are applied and how much memory they
1125 utilize.  This value by default is 65536 which corresponds to a 512kB
1126 temporary cache.  Set this to a higher value to trade
1127 memory for speed when matching large alternations.  Set
1128 it to a lower value if you want the optimisations to
1129 be as conservative of memory as possible but still occur, and set it to a
1130 negative value to prevent the optimisation and conserve the most memory.
1131 Under normal situations this variable should be of no interest to you.
1132
1133 This variable was added in Perl v5.10.0.
1134
1135 =back
1136
1137 =head2 Variables related to filehandles
1138
1139 Variables that depend on the currently selected filehandle may be set
1140 by calling an appropriate object method on the C<IO::Handle> object,
1141 although this is less efficient than using the regular built-in
1142 variables.  (Summary lines below for this contain the word HANDLE.)
1143 First you must say
1144
1145     use IO::Handle;
1146
1147 after which you may use either
1148
1149     method HANDLE EXPR
1150
1151 or more safely,
1152
1153     HANDLE->method(EXPR)
1154
1155 Each method returns the old value of the C<IO::Handle> attribute.  The
1156 methods each take an optional EXPR, which, if supplied, specifies the
1157 new value for the C<IO::Handle> attribute in question.  If not
1158 supplied, most methods do nothing to the current value--except for
1159 C<autoflush()>, which will assume a 1 for you, just to be different.
1160
1161 Because loading in the C<IO::Handle> class is an expensive operation,
1162 you should learn how to use the regular built-in variables.
1163
1164 A few of these variables are considered "read-only".  This means that
1165 if you try to assign to this variable, either directly or indirectly
1166 through a reference, you'll raise a run-time exception.
1167
1168 You should be very careful when modifying the default values of most
1169 special variables described in this document.  In most cases you want
1170 to localize these variables before changing them, since if you don't,
1171 the change may affect other modules which rely on the default values
1172 of the special variables that you have changed.  This is one of the
1173 correct ways to read the whole file at once:
1174
1175     open my $fh, "<", "foo" or die $!;
1176     local $/; # enable localized slurp mode
1177     my $content = <$fh>;
1178     close $fh;
1179
1180 But the following code is quite bad:
1181
1182     open my $fh, "<", "foo" or die $!;
1183     undef $/; # enable slurp mode
1184     my $content = <$fh>;
1185     close $fh;
1186
1187 since some other module, may want to read data from some file in the
1188 default "line mode", so if the code we have just presented has been
1189 executed, the global value of C<$/> is now changed for any other code
1190 running inside the same Perl interpreter.
1191
1192 Usually when a variable is localized you want to make sure that this
1193 change affects the shortest scope possible.  So unless you are already
1194 inside some short C<{}> block, you should create one yourself.  For
1195 example:
1196
1197     my $content = '';
1198     open my $fh, "<", "foo" or die $!;
1199     {
1200         local $/;
1201         $content = <$fh>;
1202     }
1203     close $fh;
1204
1205 Here is an example of how your own code can go broken:
1206
1207     for ( 1..3 ){
1208         $\ = "\r\n";
1209         nasty_break();
1210         print "$_";
1211     }
1212
1213     sub nasty_break {
1214         $\ = "\f";
1215         # do something with $_
1216     }
1217
1218 You probably expect this code to print the equivalent of
1219
1220     "1\r\n2\r\n3\r\n"
1221
1222 but instead you get:
1223
1224     "1\f2\f3\f"
1225
1226 Why? Because C<nasty_break()> modifies C<$\> without localizing it
1227 first.  The value you set in  C<nasty_break()> is still there when you
1228 return.  The fix is to add C<local()> so the value doesn't leak out of
1229 C<nasty_break()>:
1230
1231     local $\ = "\f";
1232
1233 It's easy to notice the problem in such a short example, but in more
1234 complicated code you are looking for trouble if you don't localize
1235 changes to the special variables.
1236
1237 =over 8
1238
1239 =item $ARGV
1240 X<$ARGV>
1241
1242 Contains the name of the current file when reading from C<< <> >>.
1243
1244 =item @ARGV
1245 X<@ARGV>
1246
1247 The array C<@ARGV> contains the command-line arguments intended for
1248 the script.  C<$#ARGV> is generally the number of arguments minus
1249 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1250 command name itself.  See L</$0> for the command name.
1251
1252 =item ARGV
1253 X<ARGV>
1254
1255 The special filehandle that iterates over command-line filenames in
1256 C<@ARGV>.  Usually written as the null filehandle in the angle operator
1257 C<< <> >>.  Note that currently C<ARGV> only has its magical effect
1258 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1259 corresponding to the last file opened by C<< <> >>.  In particular,
1260 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1261 may not cause your function to automatically read the contents of all the
1262 files in C<@ARGV>.
1263
1264 =item ARGVOUT
1265 X<ARGVOUT>
1266
1267 The special filehandle that points to the currently open output file
1268 when doing edit-in-place processing with B<-i>.  Useful when you have
1269 to do a lot of inserting and don't want to keep modifying C<$_>.  See
1270 L<perlrun> for the B<-i> switch.
1271
1272 =item IO::Handle->output_field_separator( EXPR )
1273
1274 =item $OUTPUT_FIELD_SEPARATOR
1275
1276 =item $OFS
1277
1278 =item $,
1279 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
1280
1281 The output field separator for the print operator.  If defined, this
1282 value is printed between each of print's arguments.  Default is C<undef>.
1283
1284 You cannot call C<output_field_separator()> on a handle, only as a
1285 static method.  See L<IO::Handle|IO::Handle>.
1286
1287 Mnemonic: what is printed when there is a "," in your print statement.
1288
1289 =item HANDLE->input_line_number( EXPR )
1290
1291 =item $INPUT_LINE_NUMBER
1292
1293 =item $NR
1294
1295 =item $.
1296 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
1297
1298 Current line number for the last filehandle accessed.
1299
1300 Each filehandle in Perl counts the number of lines that have been read
1301 from it.  (Depending on the value of C<$/>, Perl's idea of what
1302 constitutes a line may not match yours.)  When a line is read from a
1303 filehandle (via C<readline()> or C<< <> >>), or when C<tell()> or
1304 C<seek()> is called on it, C<$.> becomes an alias to the line counter
1305 for that filehandle.
1306
1307 You can adjust the counter by assigning to C<$.>, but this will not
1308 actually move the seek pointer.  I<Localizing C<$.> will not localize
1309 the filehandle's line count>.  Instead, it will localize perl's notion
1310 of which filehandle C<$.> is currently aliased to.
1311
1312 C<$.> is reset when the filehandle is closed, but B<not> when an open
1313 filehandle is reopened without an intervening C<close()>.  For more
1314 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
1315 an explicit close, line numbers increase across C<ARGV> files (but see
1316 examples in L<perlfunc/eof>).
1317
1318 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
1319 line counter for a given filehandle without having to worry about
1320 which handle you last accessed.
1321
1322 Mnemonic: many programs use "." to mean the current line number.
1323
1324 =item IO::Handle->input_record_separator( EXPR )
1325
1326 =item $INPUT_RECORD_SEPARATOR
1327
1328 =item $RS
1329
1330 =item $/
1331 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
1332
1333 The input record separator, newline by default.  This influences Perl's
1334 idea of what a "line" is.  Works like B<awk>'s RS variable, including
1335 treating empty lines as a terminator if set to the null string (an
1336 empty line cannot contain any spaces or tabs).  You may set it to a
1337 multi-character string to match a multi-character terminator, or to
1338 C<undef> to read through the end of file.  Setting it to C<"\n\n">
1339 means something slightly different than setting to C<"">, if the file
1340 contains consecutive empty lines.  Setting to C<""> will treat two or
1341 more consecutive empty lines as a single empty line.  Setting to
1342 C<"\n\n"> will blindly assume that the next input character belongs to
1343 the next paragraph, even if it's a newline.
1344
1345     local $/;           # enable "slurp" mode
1346     local $_ = <FH>;    # whole file now here
1347     s/\n[ \t]+/ /g;
1348
1349 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to
1350 be better for something. :-)
1351
1352 Setting C<$/> to a reference to an integer, scalar containing an
1353 integer, or scalar that's convertible to an integer will attempt to
1354 read records instead of lines, with the maximum record size being the
1355 referenced integer.  So this:
1356
1357     local $/ = \32768; # or \"32768", or \$var_containing_32768
1358     open my $fh, "<", $myfile or die $!;
1359     local $_ = <$fh>;
1360
1361 will read a record of no more than 32768 characters from $fh.  If you're
1362 not reading from a record-oriented file (or your OS doesn't have
1363 record-oriented files), then you'll likely get a full chunk of data
1364 with every read.  If a record is larger than the record size you've
1365 set, you'll get the record back in pieces.  Trying to set the record
1366 size to zero or less will cause reading in the (rest of the) whole file.
1367
1368 On VMS only, record reads bypass PerlIO layers and any associated
1369 buffering,so you must not mix record and non-record reads on the
1370 same filehandle.  Record mode mixes with line mode only when the
1371 same buffering layer is in use for both modes.
1372
1373 You cannot call C<input_record_separator()> on a handle, only as a
1374 static method.  See L<IO::Handle|IO::Handle>.
1375
1376 See also L<perlport/"Newlines">.  Also see L</$.>.
1377
1378 Mnemonic: / delimits line boundaries when quoting poetry.
1379
1380 =item IO::Handle->output_record_separator( EXPR )
1381
1382 =item $OUTPUT_RECORD_SEPARATOR
1383
1384 =item $ORS
1385
1386 =item $\
1387 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
1388
1389 The output record separator for the print operator.  If defined, this
1390 value is printed after the last of print's arguments.  Default is C<undef>.
1391
1392 You cannot call C<output_record_separator()> on a handle, only as a
1393 static method.  See L<IO::Handle|IO::Handle>.
1394
1395 Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
1396 Also, it's just like C<$/>, but it's what you get "back" from Perl.
1397
1398 =item HANDLE->autoflush( EXPR )
1399
1400 =item $OUTPUT_AUTOFLUSH
1401
1402 =item $|
1403 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
1404
1405 If set to nonzero, forces a flush right away and after every write or
1406 print on the currently selected output channel.  Default is 0
1407 (regardless of whether the channel is really buffered by the system or
1408 not; C<$|> tells you only whether you've asked Perl explicitly to
1409 flush after each write).  STDOUT will typically be line buffered if
1410 output is to the terminal and block buffered otherwise.  Setting this
1411 variable is useful primarily when you are outputting to a pipe or
1412 socket, such as when you are running a Perl program under B<rsh> and
1413 want to see the output as it's happening.  This has no effect on input
1414 buffering.  See L<perlfunc/getc> for that.  See L<perlfunc/select> on
1415 how to select the output channel.  See also L<IO::Handle>.
1416
1417 Mnemonic: when you want your pipes to be piping hot.
1418
1419 =item ${^LAST_FH}
1420 X<${^LAST_FH}>
1421
1422 This read-only variable contains a reference to the last-read filehandle.
1423 This is set by C<< <HANDLE> >>, C<readline>, C<tell>, C<eof> and C<seek>.
1424 This is the same handle that C<$.> and C<tell> and C<eof> without arguments
1425 use.  It is also the handle used when Perl appends ", <STDIN> line 1" to
1426 an error or warning message.
1427
1428 This variable was added in Perl v5.18.0.
1429
1430 =back
1431
1432 =head3 Variables related to formats
1433
1434 The special variables for formats are a subset of those for
1435 filehandles.  See L<perlform> for more information about Perl's
1436 formats.
1437
1438 =over 8
1439
1440 =item $ACCUMULATOR
1441
1442 =item $^A
1443 X<$^A> X<$ACCUMULATOR>
1444
1445 The current value of the C<write()> accumulator for C<format()> lines.
1446 A format contains C<formline()> calls that put their result into
1447 C<$^A>.  After calling its format, C<write()> prints out the contents
1448 of C<$^A> and empties.  So you never really see the contents of C<$^A>
1449 unless you call C<formline()> yourself and then look at it.  See
1450 L<perlform> and L<perlfunc/"formline PICTURE,LIST">.
1451
1452 =item IO::Handle->format_formfeed(EXPR)
1453
1454 =item $FORMAT_FORMFEED
1455
1456 =item $^L
1457 X<$^L> X<$FORMAT_FORMFEED>
1458
1459 What formats output as a form feed.  The default is C<\f>.
1460
1461 You cannot call C<format_formfeed()> on a handle, only as a static
1462 method.  See L<IO::Handle|IO::Handle>.
1463
1464 =item HANDLE->format_page_number(EXPR)
1465
1466 =item $FORMAT_PAGE_NUMBER
1467
1468 =item $%
1469 X<$%> X<$FORMAT_PAGE_NUMBER>
1470
1471 The current page number of the currently selected output channel.
1472
1473 Mnemonic: C<%> is page number in B<nroff>.
1474
1475 =item HANDLE->format_lines_left(EXPR)
1476
1477 =item $FORMAT_LINES_LEFT
1478
1479 =item $-
1480 X<$-> X<$FORMAT_LINES_LEFT>
1481
1482 The number of lines left on the page of the currently selected output
1483 channel.
1484
1485 Mnemonic: lines_on_page - lines_printed.
1486
1487 =item IO::Handle->format_line_break_characters EXPR
1488
1489 =item $FORMAT_LINE_BREAK_CHARACTERS
1490
1491 =item $:
1492 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
1493
1494 The current set of characters after which a string may be broken to
1495 fill continuation fields (starting with C<^>) in a format.  The default is
1496 S<" \n-">, to break on a space, newline, or a hyphen.
1497
1498 You cannot call C<format_line_break_characters()> on a handle, only as
1499 a static method.  See L<IO::Handle|IO::Handle>.
1500
1501 Mnemonic: a "colon" in poetry is a part of a line.
1502
1503 =item HANDLE->format_lines_per_page(EXPR)
1504
1505 =item $FORMAT_LINES_PER_PAGE
1506
1507 =item $=
1508 X<$=> X<$FORMAT_LINES_PER_PAGE>
1509
1510 The current page length (printable lines) of the currently selected
1511 output channel.  The default is 60.
1512
1513 Mnemonic: = has horizontal lines.
1514
1515 =item HANDLE->format_top_name(EXPR)
1516
1517 =item $FORMAT_TOP_NAME
1518
1519 =item $^
1520 X<$^> X<$FORMAT_TOP_NAME>
1521
1522 The name of the current top-of-page format for the currently selected
1523 output channel.  The default is the name of the filehandle with C<_TOP>
1524 appended.  For example, the default format top name for the C<STDOUT>
1525 filehandle is C<STDOUT_TOP>.
1526
1527 Mnemonic: points to top of page.
1528
1529 =item HANDLE->format_name(EXPR)
1530
1531 =item $FORMAT_NAME
1532
1533 =item $~
1534 X<$~> X<$FORMAT_NAME>
1535
1536 The name of the current report format for the currently selected
1537 output channel.  The default format name is the same as the filehandle
1538 name.  For example, the default format name for the C<STDOUT>
1539 filehandle is just C<STDOUT>.
1540
1541 Mnemonic: brother to C<$^>.
1542
1543 =back
1544
1545 =head2 Error Variables
1546 X<error> X<exception>
1547
1548 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1549 about different types of error conditions that may appear during
1550 execution of a Perl program.  The variables are shown ordered by
1551 the "distance" between the subsystem which reported the error and
1552 the Perl process.  They correspond to errors detected by the Perl
1553 interpreter, C library, operating system, or an external program,
1554 respectively.
1555
1556 To illustrate the differences between these variables, consider the
1557 following Perl expression, which uses a single-quoted string.  After
1558 execution of this statement, perl may have set all four special error
1559 variables:
1560
1561     eval q{
1562         open my $pipe, "/cdrom/install |" or die $!;
1563         my @res = <$pipe>;
1564         close $pipe or die "bad pipe: $?, $!";
1565     };
1566
1567 When perl executes the C<eval()> expression, it translates the
1568 C<open()>, C<< <PIPE> >>, and C<close> calls in the C run-time library
1569 and thence to the operating system kernel.  perl sets C<$!> to
1570 the C library's C<errno> if one of these calls fails.
1571
1572 C<$@> is set if the string to be C<eval>-ed did not compile (this may
1573 happen if C<open> or C<close> were imported with bad prototypes), or
1574 if Perl code executed during evaluation C<die()>d.  In these cases the
1575 value of C<$@> is the compile error, or the argument to C<die> (which
1576 will interpolate C<$!> and C<$?>).  (See also L<Fatal>, though.)
1577
1578 Under a few operating systems, C<$^E> may contain a more verbose error
1579 indicator, such as in this case, "CDROM tray not closed."  Systems that
1580 do not support extended error messages leave C<$^E> the same as C<$!>.
1581
1582 Finally, C<$?> may be set to non-0 value if the external program
1583 F</cdrom/install> fails.  The upper eight bits reflect specific error
1584 conditions encountered by the program (the program's C<exit()> value).
1585 The lower eight bits reflect mode of failure, like signal death and
1586 core dump information.  See L<wait(2)> for details.  In contrast to
1587 C<$!> and C<$^E>, which are set only if error condition is detected,
1588 the variable C<$?> is set on each C<wait> or pipe C<close>,
1589 overwriting the old value.  This is more like C<$@>, which on every
1590 C<eval()> is always set on failure and cleared on success.
1591
1592 For more details, see the individual descriptions at C<$@>, C<$!>,
1593 C<$^E>, and C<$?>.
1594
1595 =over 8
1596
1597 =item ${^CHILD_ERROR_NATIVE}
1598 X<$^CHILD_ERROR_NATIVE>
1599
1600 The native status returned by the last pipe close, backtick (C<``>)
1601 command, successful call to C<wait()> or C<waitpid()>, or from the
1602 C<system()> operator.  On POSIX-like systems this value can be decoded
1603 with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED,
1604 WSTOPSIG and WIFCONTINUED functions provided by the L<POSIX> module.
1605
1606 Under VMS this reflects the actual VMS exit status; i.e. it is the
1607 same as C<$?> when the pragma C<use vmsish 'status'> is in effect.
1608
1609 This variable was added in Perl v5.10.0.
1610
1611 =item $EXTENDED_OS_ERROR
1612
1613 =item $^E
1614 X<$^E> X<$EXTENDED_OS_ERROR>
1615
1616 Error information specific to the current operating system.  At the
1617 moment, this differs from C<$!> under only VMS, OS/2, and Win32 (and
1618 for MacPerl).  On all other platforms, C<$^E> is always just the same
1619 as C<$!>.
1620
1621 Under VMS, C<$^E> provides the VMS status value from the last system
1622 error.  This is more specific information about the last system error
1623 than that provided by C<$!>.  This is particularly important when C<$!>
1624 is set to B<EVMSERR>.
1625
1626 Under OS/2, C<$^E> is set to the error code of the last call to OS/2
1627 API either via CRT, or directly from perl.
1628
1629 Under Win32, C<$^E> always returns the last error information reported
1630 by the Win32 call C<GetLastError()> which describes the last error
1631 from within the Win32 API.  Most Win32-specific code will report errors
1632 via C<$^E>.  ANSI C and Unix-like calls set C<errno> and so most
1633 portable Perl code will report errors via C<$!>.
1634
1635 Caveats mentioned in the description of C<$!> generally apply to
1636 C<$^E>, also.
1637
1638 This variable was added in Perl 5.003.
1639
1640 Mnemonic: Extra error explanation.
1641
1642 =item $EXCEPTIONS_BEING_CAUGHT
1643
1644 =item $^S
1645 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1646
1647 Current state of the interpreter.
1648
1649         $^S         State
1650         ---------   -------------------------------------
1651         undef       Parsing module, eval, or main program
1652         true (1)    Executing an eval
1653         false (0)   Otherwise
1654
1655 The first state may happen in C<$SIG{__DIE__}> and C<$SIG{__WARN__}>
1656 handlers.
1657
1658 The English name $EXCEPTIONS_BEING_CAUGHT is slightly misleading, because
1659 the C<undef> value does not indicate whether exceptions are being caught,
1660 since compilation of the main program does not catch exceptions.
1661
1662 This variable was added in Perl 5.004.
1663
1664 =item $WARNING
1665
1666 =item $^W
1667 X<$^W> X<$WARNING>
1668
1669 The current value of the warning switch, initially true if B<-w> was
1670 used, false otherwise, but directly modifiable.
1671
1672 See also L<warnings>.
1673
1674 Mnemonic: related to the B<-w> switch.
1675
1676 =item ${^WARNING_BITS}
1677 X<${^WARNING_BITS}>
1678
1679 The current set of warning checks enabled by the C<use warnings> pragma.
1680 It has the same scoping as the C<$^H> and C<%^H> variables.  The exact
1681 values are considered internal to the L<warnings> pragma and may change
1682 between versions of Perl.
1683
1684 This variable was added in Perl v5.6.0.
1685
1686 =item $OS_ERROR
1687
1688 =item $ERRNO
1689
1690 =item $!
1691 X<$!> X<$ERRNO> X<$OS_ERROR>
1692
1693 When referenced, C<$!> retrieves the current value
1694 of the C C<errno> integer variable.
1695 If C<$!> is assigned a numerical value, that value is stored in C<errno>.
1696 When referenced as a string, C<$!> yields the system error string
1697 corresponding to C<errno>.
1698
1699 Many system or library calls set C<errno> if they fail,
1700 to indicate the cause of failure.  They usually do B<not>
1701 set C<errno> to zero if they succeed.  This means C<errno>,
1702 hence C<$!>, is meaningful only I<immediately> after a B<failure>:
1703
1704     if (open my $fh, "<", $filename) {
1705                 # Here $! is meaningless.
1706                 ...
1707     }
1708     else {
1709                 # ONLY here is $! meaningful.
1710                 ...
1711                 # Already here $! might be meaningless.
1712     }
1713     # Since here we might have either success or failure,
1714     # $! is meaningless.
1715
1716 Here, I<meaningless> means that C<$!> may be unrelated to the outcome
1717 of the C<open()> operator.  Assignment to C<$!> is similarly ephemeral.
1718 It can be used immediately before invoking the C<die()> operator,
1719 to set the exit value, or to inspect the system error string
1720 corresponding to error I<n>, or to restore C<$!> to a meaningful state.
1721
1722 Mnemonic: What just went bang?
1723
1724 =item %OS_ERROR
1725
1726 =item %ERRNO
1727
1728 =item %!
1729 X<%!> X<%OS_ERROR> X<%ERRNO>
1730
1731 Each element of C<%!> has a true value only if C<$!> is set to that
1732 value.  For example, C<$!{ENOENT}> is true if and only if the current
1733 value of C<$!> is C<ENOENT>; that is, if the most recent error was "No
1734 such file or directory" (or its moral equivalent: not all operating
1735 systems give that exact error, and certainly not all languages).  To
1736 check if a particular key is meaningful on your system, use C<exists
1737 $!{the_key}>; for a list of legal keys, use C<keys %!>.  See L<Errno>
1738 for more information, and also see L</$!>.
1739
1740 This variable was added in Perl 5.005.
1741
1742 =item $CHILD_ERROR
1743
1744 =item $?
1745 X<$?> X<$CHILD_ERROR>
1746
1747 The status returned by the last pipe close, backtick (C<``>) command,
1748 successful call to C<wait()> or C<waitpid()>, or from the C<system()>
1749 operator.  This is just the 16-bit status word returned by the
1750 traditional Unix C<wait()> system call (or else is made up to look
1751 like it).  Thus, the exit value of the subprocess is really (C<<< $? >>
1752 8 >>>), and C<$? & 127> gives which signal, if any, the process died
1753 from, and C<$? & 128> reports whether there was a core dump.
1754
1755 Additionally, if the C<h_errno> variable is supported in C, its value
1756 is returned via C<$?> if any C<gethost*()> function fails.
1757
1758 If you have installed a signal handler for C<SIGCHLD>, the
1759 value of C<$?> will usually be wrong outside that handler.
1760
1761 Inside an C<END> subroutine C<$?> contains the value that is going to be
1762 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
1763 change the exit status of your program.  For example:
1764
1765     END {
1766         $? = 1 if $? == 255;  # die would make it 255
1767     }
1768
1769 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
1770 actual VMS exit status, instead of the default emulation of POSIX
1771 status; see L<perlvms/$?> for details.
1772
1773 Mnemonic: similar to B<sh> and B<ksh>.
1774
1775 =item $EVAL_ERROR
1776
1777 =item $@
1778 X<$@> X<$EVAL_ERROR>
1779
1780 The Perl syntax error message from the
1781 last C<eval()> operator.  If C<$@> is
1782 the null string, the last C<eval()> parsed and executed correctly
1783 (although the operations you invoked may have failed in the normal
1784 fashion).
1785
1786 Warning messages are not collected in this variable.  You can, however,
1787 set up a routine to process warnings by setting C<$SIG{__WARN__}> as
1788 described in L</%SIG>.
1789
1790 Mnemonic: Where was the syntax error "at"?
1791
1792 =back
1793
1794 =head2 Variables related to the interpreter state
1795
1796 These variables provide information about the current interpreter state.
1797
1798 =over 8
1799
1800 =item $COMPILING
1801
1802 =item $^C
1803 X<$^C> X<$COMPILING>
1804
1805 The current value of the flag associated with the B<-c> switch.
1806 Mainly of use with B<-MO=...> to allow code to alter its behavior
1807 when being compiled, such as for example to C<AUTOLOAD> at compile
1808 time rather than normal, deferred loading.  Setting
1809 C<$^C = 1> is similar to calling C<B::minus_c>.
1810
1811 This variable was added in Perl v5.6.0.
1812
1813 =item $DEBUGGING
1814
1815 =item $^D
1816 X<$^D> X<$DEBUGGING>
1817
1818 The current value of the debugging flags.  May be read or set.  Like its
1819 command-line equivalent, you can use numeric or symbolic values, eg
1820 C<$^D = 10> or C<$^D = "st">.
1821
1822 Mnemonic: value of B<-D> switch.
1823
1824 =item ${^ENCODING}
1825 X<${^ENCODING}>
1826
1827 The I<object reference> to the C<Encode> object that is used to convert
1828 the source code to Unicode.  Thanks to this variable your Perl script
1829 does not have to be written in UTF-8.  Default is I<undef>.  The direct
1830 manipulation of this variable is highly discouraged.
1831
1832 This variable was added in Perl 5.8.2.
1833
1834 =item ${^GLOBAL_PHASE}
1835 X<${^GLOBAL_PHASE}>
1836
1837 The current phase of the perl interpreter.
1838
1839 Possible values are:
1840
1841 =over 8
1842
1843 =item CONSTRUCT
1844
1845 The C<PerlInterpreter*> is being constructed via C<perl_construct>.  This
1846 value is mostly there for completeness and for use via the
1847 underlying C variable C<PL_phase>.  It's not really possible for Perl
1848 code to be executed unless construction of the interpreter is
1849 finished.
1850
1851 =item START
1852
1853 This is the global compile-time.  That includes, basically, every
1854 C<BEGIN> block executed directly or indirectly from during the
1855 compile-time of the top-level program.
1856
1857 This phase is not called "BEGIN" to avoid confusion with
1858 C<BEGIN>-blocks, as those are executed during compile-time of any
1859 compilation unit, not just the top-level program.  A new, localised
1860 compile-time entered at run-time, for example by constructs as
1861 C<eval "use SomeModule"> are not global interpreter phases, and
1862 therefore aren't reflected by C<${^GLOBAL_PHASE}>.
1863
1864 =item CHECK
1865
1866 Execution of any C<CHECK> blocks.
1867
1868 =item INIT
1869
1870 Similar to "CHECK", but for C<INIT>-blocks, not C<CHECK> blocks.
1871
1872 =item RUN
1873
1874 The main run-time, i.e. the execution of C<PL_main_root>.
1875
1876 =item END
1877
1878 Execution of any C<END> blocks.
1879
1880 =item DESTRUCT
1881
1882 Global destruction.
1883
1884 =back
1885
1886 Also note that there's no value for UNITCHECK-blocks.  That's because
1887 those are run for each compilation unit individually, and therefore is
1888 not a global interpreter phase.
1889
1890 Not every program has to go through each of the possible phases, but
1891 transition from one phase to another can only happen in the order
1892 described in the above list.
1893
1894 An example of all of the phases Perl code can see:
1895
1896     BEGIN { print "compile-time: ${^GLOBAL_PHASE}\n" }
1897
1898     INIT  { print "init-time: ${^GLOBAL_PHASE}\n" }
1899
1900     CHECK { print "check-time: ${^GLOBAL_PHASE}\n" }
1901
1902     {
1903         package Print::Phase;
1904
1905         sub new {
1906             my ($class, $time) = @_;
1907             return bless \$time, $class;
1908         }
1909
1910         sub DESTROY {
1911             my $self = shift;
1912             print "$$self: ${^GLOBAL_PHASE}\n";
1913         }
1914     }
1915
1916     print "run-time: ${^GLOBAL_PHASE}\n";
1917
1918     my $runtime = Print::Phase->new(
1919         "lexical variables are garbage collected before END"
1920     );
1921
1922     END   { print "end-time: ${^GLOBAL_PHASE}\n" }
1923
1924     our $destruct = Print::Phase->new(
1925         "package variables are garbage collected after END"
1926     );
1927
1928 This will print out
1929
1930     compile-time: START
1931     check-time: CHECK
1932     init-time: INIT
1933     run-time: RUN
1934     lexical variables are garbage collected before END: RUN
1935     end-time: END
1936     package variables are garbage collected after END: DESTRUCT
1937
1938 This variable was added in Perl 5.14.0.
1939
1940 =item $^H
1941 X<$^H>
1942
1943 WARNING: This variable is strictly for
1944 internal use only.  Its availability,
1945 behavior, and contents are subject to change without notice.
1946
1947 This variable contains compile-time hints for the Perl interpreter.  At the
1948 end of compilation of a BLOCK the value of this variable is restored to the
1949 value when the interpreter started to compile the BLOCK.
1950
1951 When perl begins to parse any block construct that provides a lexical scope
1952 (e.g., eval body, required file, subroutine body, loop body, or conditional
1953 block), the existing value of C<$^H> is saved, but its value is left unchanged.
1954 When the compilation of the block is completed, it regains the saved value.
1955 Between the points where its value is saved and restored, code that
1956 executes within BEGIN blocks is free to change the value of C<$^H>.
1957
1958 This behavior provides the semantic of lexical scoping, and is used in,
1959 for instance, the C<use strict> pragma.
1960
1961 The contents should be an integer; different bits of it are used for
1962 different pragmatic flags.  Here's an example:
1963
1964     sub add_100 { $^H |= 0x100 }
1965
1966     sub foo {
1967         BEGIN { add_100() }
1968         bar->baz($boon);
1969     }
1970
1971 Consider what happens during execution of the BEGIN block.  At this point
1972 the BEGIN block has already been compiled, but the body of C<foo()> is still
1973 being compiled.  The new value of C<$^H>
1974 will therefore be visible only while
1975 the body of C<foo()> is being compiled.
1976
1977 Substitution of C<BEGIN { add_100() }> block with:
1978
1979     BEGIN { require strict; strict->import('vars') }
1980
1981 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
1982 version of the same lexical pragma:
1983
1984     BEGIN {
1985         require strict; strict->import('vars') if $condition
1986     }
1987
1988 This variable was added in Perl 5.003.
1989
1990 =item %^H
1991 X<%^H>
1992
1993 The C<%^H> hash provides the same scoping semantic as C<$^H>.  This makes
1994 it useful for implementation of lexically scoped pragmas.  See
1995 L<perlpragma>.
1996
1997 When putting items into C<%^H>, in order to avoid conflicting with other
1998 users of the hash there is a convention regarding which keys to use.
1999 A module should use only keys that begin with the module's name (the
2000 name of its main package) and a "/" character.  For example, a module
2001 C<Foo::Bar> should use keys such as C<Foo::Bar/baz>.
2002
2003 This variable was added in Perl v5.6.0.
2004
2005 =item ${^OPEN}
2006 X<${^OPEN}>
2007
2008 An internal variable used by PerlIO.  A string in two parts, separated
2009 by a C<\0> byte, the first part describes the input layers, the second
2010 part describes the output layers.
2011
2012 This variable was added in Perl v5.8.0.
2013
2014 =item $PERLDB
2015
2016 =item $^P
2017 X<$^P> X<$PERLDB>
2018
2019 The internal variable for debugging support.  The meanings of the
2020 various bits are subject to change, but currently indicate:
2021
2022 =over 6
2023
2024 =item 0x01
2025
2026 Debug subroutine enter/exit.
2027
2028 =item 0x02
2029
2030 Line-by-line debugging.  Causes C<DB::DB()> subroutine to be called for
2031 each statement executed.  Also causes saving source code lines (like
2032 0x400).
2033
2034 =item 0x04
2035
2036 Switch off optimizations.
2037
2038 =item 0x08
2039
2040 Preserve more data for future interactive inspections.
2041
2042 =item 0x10
2043
2044 Keep info about source lines on which a subroutine is defined.
2045
2046 =item 0x20
2047
2048 Start with single-step on.
2049
2050 =item 0x40
2051
2052 Use subroutine address instead of name when reporting.
2053
2054 =item 0x80
2055
2056 Report C<goto &subroutine> as well.
2057
2058 =item 0x100
2059
2060 Provide informative "file" names for evals based on the place they were compiled.
2061
2062 =item 0x200
2063
2064 Provide informative names to anonymous subroutines based on the place they
2065 were compiled.
2066
2067 =item 0x400
2068
2069 Save source code lines into C<@{"_<$filename"}>.
2070
2071 =back
2072
2073 Some bits may be relevant at compile-time only, some at
2074 run-time only.  This is a new mechanism and the details may change.
2075 See also L<perldebguts>.
2076
2077 =item ${^TAINT}
2078 X<${^TAINT}>
2079
2080 Reflects if taint mode is on or off.  1 for on (the program was run with
2081 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
2082 B<-t> or B<-TU>).
2083
2084 This variable is read-only.
2085
2086 This variable was added in Perl v5.8.0.
2087
2088 =item ${^UNICODE}
2089 X<${^UNICODE}>
2090
2091 Reflects certain Unicode settings of Perl.  See L<perlrun>
2092 documentation for the C<-C> switch for more information about
2093 the possible values.
2094
2095 This variable is set during Perl startup and is thereafter read-only.
2096
2097 This variable was added in Perl v5.8.2.
2098
2099 =item ${^UTF8CACHE}
2100 X<${^UTF8CACHE}>
2101
2102 This variable controls the state of the internal UTF-8 offset caching code.
2103 1 for on (the default), 0 for off, -1 to debug the caching code by checking
2104 all its results against linear scans, and panicking on any discrepancy.
2105
2106 This variable was added in Perl v5.8.9.  It is subject to change or
2107 removal without notice, but is currently used to avoid recalculating the
2108 boundaries of multi-byte UTF-8-encoded characters.
2109
2110 =item ${^UTF8LOCALE}
2111 X<${^UTF8LOCALE}>
2112
2113 This variable indicates whether a UTF-8 locale was detected by perl at
2114 startup.  This information is used by perl when it's in
2115 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
2116 switch); see L<perlrun> for more info on this.
2117
2118 This variable was added in Perl v5.8.8.
2119
2120 =back
2121
2122 =head2 Deprecated and removed variables
2123
2124 Deprecating a variable announces the intent of the perl maintainers to
2125 eventually remove the variable from the language.  It may still be
2126 available despite its status.  Using a deprecated variable triggers
2127 a warning.
2128
2129 Once a variable is removed, its use triggers an error telling you
2130 the variable is unsupported.
2131
2132 See L<perldiag> for details about error messages.
2133
2134 =over 8
2135
2136 =item $OFMT
2137
2138 =item $#
2139 X<$#> X<$OFMT>
2140
2141 C<$#> was a variable that could be used to format printed numbers.
2142 After a deprecation cycle, its magic was removed in Perl v5.10.0 and
2143 using it now triggers a warning: C<$# is no longer supported>.
2144
2145 This is not the sigil you use in front of an array name to get the
2146 last index, like C<$#array>.  That's still how you get the last index
2147 of an array in Perl.  The two have nothing to do with each other.
2148
2149 Deprecated in Perl 5.
2150
2151 Removed in Perl v5.10.0.
2152
2153 =item $*
2154 X<$*>
2155
2156 C<$*> was a variable that you could use to enable multiline matching.
2157 After a deprecation cycle, its magic was removed in Perl v5.10.0.
2158 Using it now triggers a warning: C<$* is no longer supported>.
2159 You should use the C</s> and C</m> regexp modifiers instead.
2160
2161 Deprecated in Perl 5.
2162
2163 Removed in Perl v5.10.0.
2164
2165 =item $ARRAY_BASE
2166
2167 =item $[
2168 X<$[> X<$ARRAY_BASE>
2169
2170 This variable stores the index of the first element in an array, and
2171 of the first character in a substring.  The default is 0, but you could
2172 theoretically set it to 1 to make Perl behave more like B<awk> (or Fortran)
2173 when subscripting and when evaluating the index() and substr() functions.
2174
2175 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
2176 directive, and cannot influence the behavior of any other file.
2177 (That's why you can only assign compile-time constants to it.)
2178 Its use is highly discouraged.
2179
2180 Prior to Perl v5.10.0, assignment to C<$[> could be seen from outer lexical
2181 scopes in the same file, unlike other compile-time directives (such as
2182 L<strict>).  Using local() on it would bind its value strictly to a lexical
2183 block.  Now it is always lexically scoped.
2184
2185 As of Perl v5.16.0, it is implemented by the L<arybase> module.  See
2186 L<arybase> for more details on its behaviour.
2187
2188 Under C<use v5.16>, or C<no feature "array_base">, C<$[> no longer has any
2189 effect, and always contains 0.  Assigning 0 to it is permitted, but any
2190 other value will produce an error.
2191
2192 Mnemonic: [ begins subscripts.
2193
2194 Deprecated in Perl v5.12.0.
2195
2196 =item $OLD_PERL_VERSION
2197
2198 =item $]
2199 X<$]> X<$OLD_PERL_VERSION>
2200
2201 See L</$^V> for a more modern representation of the Perl version that allows
2202 accurate string comparisons.
2203
2204 The version + patchlevel / 1000 of the Perl interpreter.  This variable
2205 can be used to determine whether the Perl interpreter executing a
2206 script is in the right range of versions:
2207
2208     warn "No checksumming!\n" if $] < 3.019;
2209
2210 The floating point representation can sometimes lead to inaccurate
2211 numeric comparisons.
2212
2213 See also the documentation of C<use VERSION> and C<require VERSION>
2214 for a convenient way to fail if the running Perl interpreter is too old.
2215
2216 Mnemonic: Is this version of perl in the right bracket?
2217
2218 =back
2219
2220 =cut