Bump $XS::Typemap::VERSION after previous commit.
[perl.git] / pod / perlrecharclass.pod
1 =head1 NAME
2 X<character class>
3
4 perlrecharclass - Perl Regular Expression Character Classes
5
6 =head1 DESCRIPTION
7
8 The top level documentation about Perl regular expressions
9 is found in L<perlre>.
10
11 This manual page discusses the syntax and use of character
12 classes in Perl regular expressions.
13
14 A character class is a way of denoting a set of characters
15 in such a way that one character of the set is matched.
16 It's important to remember that: matching a character class
17 consumes exactly one character in the source string. (The source
18 string is the string the regular expression is matched against.)
19
20 There are three types of character classes in Perl regular
21 expressions: the dot, backslash sequences, and the form enclosed in square
22 brackets.  Keep in mind, though, that often the term "character class" is used
23 to mean just the bracketed form.  Certainly, most Perl documentation does that.
24
25 =head2 The dot
26
27 The dot (or period), C<.> is probably the most used, and certainly
28 the most well-known character class. By default, a dot matches any
29 character, except for the newline. That default can be changed to
30 add matching the newline by using the I<single line> modifier: either
31 for the entire regular expression with the C</s> modifier, or
32 locally with C<(?s)>.  (The experimental C<\N> backslash sequence, described
33 below, matches any character except newline without regard to the
34 I<single line> modifier.)
35
36 Here are some examples:
37
38  "a"  =~  /./       # Match
39  "."  =~  /./       # Match
40  ""   =~  /./       # No match (dot has to match a character)
41  "\n" =~  /./       # No match (dot does not match a newline)
42  "\n" =~  /./s      # Match (global 'single line' modifier)
43  "\n" =~  /(?s:.)/  # Match (local 'single line' modifier)
44  "ab" =~  /^.$/     # No match (dot matches one character)
45
46 =head2 Backslash sequences
47 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\p> X<\P>
48 X<\N> X<\v> X<\V> X<\h> X<\H>
49 X<word> X<whitespace>
50
51 A backslash sequence is a sequence of characters, the first one of which is a
52 backslash.  Perl ascribes special meaning to many such sequences, and some of
53 these are character classes.  That is, they match a single character each,
54 provided that the character belongs to the specific set of characters defined
55 by the sequence.
56
57 Here's a list of the backslash sequences that are character classes.  They
58 are discussed in more detail below.  (For the backslash sequences that aren't
59 character classes, see L<perlrebackslash>.)
60
61  \d             Match a decimal digit character.
62  \D             Match a non-decimal-digit character.
63  \w             Match a "word" character.
64  \W             Match a non-"word" character.
65  \s             Match a whitespace character.
66  \S             Match a non-whitespace character.
67  \h             Match a horizontal whitespace character.
68  \H             Match a character that isn't horizontal whitespace.
69  \v             Match a vertical whitespace character.
70  \V             Match a character that isn't vertical whitespace.
71  \N             Match a character that isn't a newline.  Experimental.
72  \pP, \p{Prop}  Match a character that has the given Unicode property.
73  \PP, \P{Prop}  Match a character that doesn't have the Unicode property
74
75 =head3 \N
76
77 C<\N> is new in 5.12, and is experimental.  It, like the dot, matches any
78 character that is not a newline. The difference is that C<\N> is not influenced
79 by the I<single line> regular expression modifier (see L</The dot> above).  Note
80 that the form C<\N{...}> may mean something completely different.  When the
81 C<{...}> is a L<quantifier|perlre/Quantifiers>, it means to match a non-newline
82 character that many times.  For example, C<\N{3}> means to match 3
83 non-newlines; C<\N{5,}> means to match 5 or more non-newlines.  But if C<{...}>
84 is not a legal quantifier, it is presumed to be a named character.  See
85 L<charnames> for those.  For example, none of C<\N{COLON}>, C<\N{4F}>, and
86 C<\N{F4}> contain legal quantifiers, so Perl will try to find characters whose
87 names are respectively C<COLON>, C<4F>, and C<F4>.
88
89 =head3 Digits
90
91 C<\d> matches a single character considered to be a decimal I<digit>.
92 If the C</a> regular expression modifier is in effect, it matches [0-9].
93 Otherwise, it
94 matches anything that is matched by C<\p{Digit}>, which includes [0-9].
95 (An unlikely possible exception is that under locale matching rules, the
96 current locale might not have [0-9] matched by C<\d>, and/or might match
97 other characters whose code point is less than 256.  Such a locale
98 definition would be in violation of the C language standard, but Perl
99 doesn't currently assume anything in regard to this.)
100
101 What this means is that unless the C</a> modifier is in effect C<\d> not
102 only matches the digits '0' - '9', but also Arabic, Devanagari, and
103 digits from other languages.  This may cause some confusion, and some
104 security issues.
105
106 Some digits that C<\d> matches look like some of the [0-9] ones, but
107 have different values.  For example, BENGALI DIGIT FOUR (U+09EA) looks
108 very much like an ASCII DIGIT EIGHT (U+0038).  An application that
109 is expecting only the ASCII digits might be misled, or if the match is
110 C<\d+>, the matched string might contain a mixture of digits from
111 different writing systems that look like they signify a number different
112 than they actually do.  L<Unicode::UCD/num()> can
113 be used to safely
114 calculate the value, returning C<undef> if the input string contains
115 such a mixture.
116
117 What C<\p{Digit}> means (and hence C<\d> except under the C</a>
118 modifier) is C<\p{General_Category=Decimal_Number}>, or synonymously,
119 C<\p{General_Category=Digit}>.  Starting with Unicode version 4.1, this
120 is the same set of characters matched by C<\p{Numeric_Type=Decimal}>.
121 But Unicode also has a different property with a similar name,
122 C<\p{Numeric_Type=Digit}>, which matches a completely different set of
123 characters.  These characters are things such as C<CIRCLED DIGIT ONE>
124 or subscripts, or are from writing systems that lack all ten digits.
125
126 The design intent is for C<\d> to exactly match the set of characters
127 that can safely be used with "normal" big-endian positional decimal
128 syntax, where, for example 123 means one 'hundred', plus two 'tens',
129 plus three 'ones'.  This positional notation does not necessarily apply
130 to characters that match the other type of "digit",
131 C<\p{Numeric_Type=Digit}>, and so C<\d> doesn't match them.
132
133 The Tamil digits (U+0BE6 - U+0BEF) can also legally be
134 used in old-style Tamil numbers in which they would appear no more than
135 one in a row, separated by characters that mean "times 10", "times 100",
136 etc.  (See L<http://www.unicode.org/notes/tn21>.)
137
138 Any character not matched by C<\d> is matched by C<\D>.
139
140 =head3 Word characters
141
142 A C<\w> matches a single alphanumeric character (an alphabetic character, or a
143 decimal digit) or a connecting punctuation character, such as an
144 underscore ("_").  It does not match a whole word.  To match a whole
145 word, use C<\w+>.  This isn't the same thing as matching an English word, but
146 in the ASCII range it is the same as a string of Perl-identifier
147 characters.
148
149 =over
150
151 =item If the C</a> modifier is in effect ...
152
153 C<\w> matches the 63 characters [a-zA-Z0-9_].
154
155 =item otherwise ...
156
157 =over
158
159 =item For code points above 255 ...
160
161 C<\w> matches the same as C<\p{Word}> matches in this range.  That is,
162 it matches Thai letters, Greek letters, etc.  This includes connector
163 punctuation (like the underscore) which connect two words together, or
164 diacritics, such as a C<COMBINING TILDE> and the modifier letters, which
165 are generally used to add auxiliary markings to letters.
166
167 =item For code points below 256 ...
168
169 =over
170
171 =item if locale rules are in effect ...
172
173 C<\w> matches the platform's native underscore character plus whatever
174 the locale considers to be alphanumeric.
175
176 =item if Unicode rules are in effect or if on an EBCDIC platform ...
177
178 C<\w> matches exactly what C<\p{Word}> matches.
179
180 =item otherwise ...
181
182 C<\w> matches [a-zA-Z0-9_].
183
184 =back
185
186 =back
187
188 =back
189
190 Which rules apply are determined as described in L<perlre/Which character set modifier is in effect?>.
191
192 There are a number of security issues with the full Unicode list of word
193 characters.  See L<http://unicode.org/reports/tr36>.
194
195 Also, for a somewhat finer-grained set of characters that are in programming
196 language identifiers beyond the ASCII range, you may wish to instead use the
197 more customized L</Unicode Properties>, C<\p{ID_Start}>,
198 C<\p{ID_Continue}>, C<\p{XID_Start}>, and C<\p{XID_Continue}>.  See
199 L<http://unicode.org/reports/tr31>.
200
201 Any character not matched by C<\w> is matched by C<\W>.
202
203 =head3 Whitespace
204
205 C<\s> matches any single character considered whitespace.
206
207 =over
208
209 =item If the C</a> modifier is in effect ...
210
211 C<\s> matches the 5 characters [\t\n\f\r ]; that is, the horizontal tab,
212 the newline, the form feed, the carriage return, and the space.  (Note
213 that it doesn't match the vertical tab, C<\cK> on ASCII platforms.)
214
215 =item otherwise ...
216
217 =over
218
219 =item For code points above 255 ...
220
221 C<\s> matches exactly the code points above 255 shown with an "s" column
222 in the table below.
223
224 =item For code points below 256 ...
225
226 =over
227
228 =item if locale rules are in effect ...
229
230 C<\s> matches whatever the locale considers to be whitespace.  Note that
231 this is likely to include the vertical space, unlike non-locale C<\s>
232 matching.
233
234 =item if Unicode rules are in effect or if on an EBCDIC platform ...
235
236 C<\s> matches exactly the characters shown with an "s" column in the
237 table below.
238
239 =item otherwise ...
240
241 C<\s> matches [\t\n\f\r ].
242 Note that this list doesn't include the non-breaking space.
243
244 =back
245
246 =back
247
248 =back
249
250 Which rules apply are determined as described in L<perlre/Which character set modifier is in effect?>.
251
252 Any character not matched by C<\s> is matched by C<\S>.
253
254 C<\h> matches any character considered horizontal whitespace;
255 this includes the platform's space and tab characters and several others
256 listed in the table below.  C<\H> matches any character
257 not considered horizontal whitespace.  They use the platform's native
258 character set, and do not consider any locale that may otherwise be in
259 use.
260
261 C<\v> matches any character considered vertical whitespace;
262 this includes the platform's carriage return and line feed characters (newline)
263 plus several other characters, all listed in the table below.
264 C<\V> matches any character not considered vertical whitespace.
265 They use the platform's native character set, and do not consider any
266 locale that may otherwise be in use.
267
268 C<\R> matches anything that can be considered a newline under Unicode
269 rules. It's not a character class, as it can match a multi-character
270 sequence. Therefore, it cannot be used inside a bracketed character
271 class; use C<\v> instead (vertical whitespace).  It uses the platform's
272 native character set, and does not consider any locale that may
273 otherwise be in use.
274 Details are discussed in L<perlrebackslash>.
275
276 Note that unlike C<\s> (and C<\d> and C<\w>), C<\h> and C<\v> always match
277 the same characters, without regard to other factors, such as the active
278 locale or whether the source string is in UTF-8 format.
279
280 One might think that C<\s> is equivalent to C<[\h\v]>. This is not true.
281 The difference is that the vertical tab (C<"\x0b">) is not matched by
282 C<\s>; it is however considered vertical whitespace.
283
284 The following table is a complete listing of characters matched by
285 C<\s>, C<\h> and C<\v> as of Unicode 6.0.
286
287 The first column gives the Unicode code point of the character (in hex format),
288 the second column gives the (Unicode) name. The third column indicates
289 by which class(es) the character is matched (assuming no locale or EBCDIC code
290 page is in effect that changes the C<\s> matching).
291
292  0x0009        CHARACTER TABULATION   h s
293  0x000a              LINE FEED (LF)    vs
294  0x000b             LINE TABULATION    v
295  0x000c              FORM FEED (FF)    vs
296  0x000d        CARRIAGE RETURN (CR)    vs
297  0x0020                       SPACE   h s
298  0x0085             NEXT LINE (NEL)    vs  [1]
299  0x00a0              NO-BREAK SPACE   h s  [1]
300  0x1680            OGHAM SPACE MARK   h s
301  0x180e   MONGOLIAN VOWEL SEPARATOR   h s
302  0x2000                     EN QUAD   h s
303  0x2001                     EM QUAD   h s
304  0x2002                    EN SPACE   h s
305  0x2003                    EM SPACE   h s
306  0x2004          THREE-PER-EM SPACE   h s
307  0x2005           FOUR-PER-EM SPACE   h s
308  0x2006            SIX-PER-EM SPACE   h s
309  0x2007                FIGURE SPACE   h s
310  0x2008           PUNCTUATION SPACE   h s
311  0x2009                  THIN SPACE   h s
312  0x200a                  HAIR SPACE   h s
313  0x2028              LINE SEPARATOR    vs
314  0x2029         PARAGRAPH SEPARATOR    vs
315  0x202f       NARROW NO-BREAK SPACE   h s
316  0x205f   MEDIUM MATHEMATICAL SPACE   h s
317  0x3000           IDEOGRAPHIC SPACE   h s
318
319 =over 4
320
321 =item [1]
322
323 NEXT LINE and NO-BREAK SPACE may or may not match C<\s> depending
324 on the rules in effect.  See
325 L<the beginning of this section|/Whitespace>.
326
327 =back
328
329 =head3 Unicode Properties
330
331 C<\pP> and C<\p{Prop}> are character classes to match characters that fit given
332 Unicode properties.  One letter property names can be used in the C<\pP> form,
333 with the property name following the C<\p>, otherwise, braces are required.
334 When using braces, there is a single form, which is just the property name
335 enclosed in the braces, and a compound form which looks like C<\p{name=value}>,
336 which means to match if the property "name" for the character has that particular
337 "value".
338 For instance, a match for a number can be written as C</\pN/> or as
339 C</\p{Number}/>, or as C</\p{Number=True}/>.
340 Lowercase letters are matched by the property I<Lowercase_Letter> which
341 has the short form I<Ll>. They need the braces, so are written as C</\p{Ll}/> or
342 C</\p{Lowercase_Letter}/>, or C</\p{General_Category=Lowercase_Letter}/>
343 (the underscores are optional).
344 C</\pLl/> is valid, but means something different.
345 It matches a two character string: a letter (Unicode property C<\pL>),
346 followed by a lowercase C<l>.
347
348 If locale rules are not in effect, the use of
349 a Unicode property will force the regular expression into using Unicode
350 rules, if it isn't already.
351
352 Note that almost all properties are immune to case-insensitive matching.
353 That is, adding a C</i> regular expression modifier does not change what
354 they match.  There are two sets that are affected.  The first set is
355 C<Uppercase_Letter>,
356 C<Lowercase_Letter>,
357 and C<Titlecase_Letter>,
358 all of which match C<Cased_Letter> under C</i> matching.
359 The second set is
360 C<Uppercase>,
361 C<Lowercase>,
362 and C<Titlecase>,
363 all of which match C<Cased> under C</i> matching.
364 (The difference between these sets is that some things, such as Roman
365 numerals, come in both upper and lower case, so they are C<Cased>, but
366 aren't considered to be letters, so they aren't C<Cased_Letter>s. They're
367 actually C<Letter_Number>s.)
368 This set also includes its subsets C<PosixUpper> and C<PosixLower>, both
369 of which under C</i> match C<PosixAlpha>.
370
371 For more details on Unicode properties, see L<perlunicode/Unicode
372 Character Properties>; for a
373 complete list of possible properties, see
374 L<perluniprops/Properties accessible through \p{} and \P{}>,
375 which notes all forms that have C</i> differences.
376 It is also possible to define your own properties. This is discussed in
377 L<perlunicode/User-Defined Character Properties>.
378
379 Unicode properties are defined (surprise!) only on Unicode code points.
380 A warning is raised and all matches fail on non-Unicode code points
381 (those above the legal Unicode maximum of 0x10FFFF).  This can be
382 somewhat surprising,
383
384  chr(0x110000) =~ \p{ASCII_Hex_Digit=True}      # Fails.
385  chr(0x110000) =~ \p{ASCII_Hex_Digit=False}     # Also fails!
386
387 Even though these two matches might be thought of as complements, they
388 are so only on Unicode code points.
389
390 =head4 Examples
391
392  "a"  =~  /\w/      # Match, "a" is a 'word' character.
393  "7"  =~  /\w/      # Match, "7" is a 'word' character as well.
394  "a"  =~  /\d/      # No match, "a" isn't a digit.
395  "7"  =~  /\d/      # Match, "7" is a digit.
396  " "  =~  /\s/      # Match, a space is whitespace.
397  "a"  =~  /\D/      # Match, "a" is a non-digit.
398  "7"  =~  /\D/      # No match, "7" is not a non-digit.
399  " "  =~  /\S/      # No match, a space is not non-whitespace.
400
401  " "  =~  /\h/      # Match, space is horizontal whitespace.
402  " "  =~  /\v/      # No match, space is not vertical whitespace.
403  "\r" =~  /\v/      # Match, a return is vertical whitespace.
404
405  "a"  =~  /\pL/     # Match, "a" is a letter.
406  "a"  =~  /\p{Lu}/  # No match, /\p{Lu}/ matches upper case letters.
407
408  "\x{0e0b}" =~ /\p{Thai}/  # Match, \x{0e0b} is the character
409                            # 'THAI CHARACTER SO SO', and that's in
410                            # Thai Unicode class.
411  "a"  =~  /\P{Lao}/ # Match, as "a" is not a Laotian character.
412
413 It is worth emphasizing that C<\d>, C<\w>, etc, match single characters, not
414 complete numbers or words. To match a number (that consists of digits),
415 use C<\d+>; to match a word, use C<\w+>.  But be aware of the security
416 considerations in doing so, as mentioned above.
417
418 =head2 Bracketed Character Classes
419
420 The third form of character class you can use in Perl regular expressions
421 is the bracketed character class.  In its simplest form, it lists the characters
422 that may be matched, surrounded by square brackets, like this: C<[aeiou]>.
423 This matches one of C<a>, C<e>, C<i>, C<o> or C<u>.  Like the other
424 character classes, exactly one character is matched.* To match
425 a longer string consisting of characters mentioned in the character
426 class, follow the character class with a L<quantifier|perlre/Quantifiers>.  For
427 instance, C<[aeiou]+> matches one or more lowercase English vowels.
428
429 Repeating a character in a character class has no
430 effect; it's considered to be in the set only once.
431
432 Examples:
433
434  "e"  =~  /[aeiou]/        # Match, as "e" is listed in the class.
435  "p"  =~  /[aeiou]/        # No match, "p" is not listed in the class.
436  "ae" =~  /^[aeiou]$/      # No match, a character class only matches
437                            # a single character.
438  "ae" =~  /^[aeiou]+$/     # Match, due to the quantifier.
439
440  -------
441
442 * There is an exception to a bracketed character class matching a
443 single character only.  When the class is to match caselessly under C</i>
444 matching rules, and a character that is explicitly mentioned inside the
445 class matches a
446 multiple-character sequence caselessly under Unicode rules, the class
447 (when not L<inverted|/Negation>) will also match that sequence.  For
448 example, Unicode says that the letter C<LATIN SMALL LETTER SHARP S>
449 should match the sequence C<ss> under C</i> rules.  Thus,
450
451  'ss' =~ /\A\N{LATIN SMALL LETTER SHARP S}\z/i             # Matches
452  'ss' =~ /\A[aeioust\N{LATIN SMALL LETTER SHARP S}]\z/i    # Matches
453
454 For this to happen, the character must be explicitly specified, and not
455 be part of a multi-character range (not even as one of its endpoints).
456 (L</Character Ranges> will be explained shortly.)  Therefore,
457
458  'ss' =~ /\A[\0-\x{ff}]\z/i        # Doesn't match
459  'ss' =~ /\A[\0-\N{LATIN SMALL LETTER SHARP S}]\z/i    # No match
460  'ss' =~ /\A[\xDF-\xDF]\z/i    # Matches on ASCII platforms, since \XDF
461                                # is LATIN SMALL LETTER SHARP S, and the
462                                # range is just a single element
463
464 Note that it isn't a good idea to specify these types of ranges anyway.
465
466 =head3 Special Characters Inside a Bracketed Character Class
467
468 Most characters that are meta characters in regular expressions (that
469 is, characters that carry a special meaning like C<.>, C<*>, or C<(>) lose
470 their special meaning and can be used inside a character class without
471 the need to escape them. For instance, C<[()]> matches either an opening
472 parenthesis, or a closing parenthesis, and the parens inside the character
473 class don't group or capture.
474
475 Characters that may carry a special meaning inside a character class are:
476 C<\>, C<^>, C<->, C<[> and C<]>, and are discussed below. They can be
477 escaped with a backslash, although this is sometimes not needed, in which
478 case the backslash may be omitted.
479
480 The sequence C<\b> is special inside a bracketed character class. While
481 outside the character class, C<\b> is an assertion indicating a point
482 that does not have either two word characters or two non-word characters
483 on either side, inside a bracketed character class, C<\b> matches a
484 backspace character.
485
486 The sequences
487 C<\a>,
488 C<\c>,
489 C<\e>,
490 C<\f>,
491 C<\n>,
492 C<\N{I<NAME>}>,
493 C<\N{U+I<hex char>}>,
494 C<\r>,
495 C<\t>,
496 and
497 C<\x>
498 are also special and have the same meanings as they do outside a
499 bracketed character class.  (However, inside a bracketed character
500 class, if C<\N{I<NAME>}> expands to a sequence of characters, only the first
501 one in the sequence is used, with a warning.)
502
503 Also, a backslash followed by two or three octal digits is considered an octal
504 number.
505
506 A C<[> is not special inside a character class, unless it's the start of a
507 POSIX character class (see L</POSIX Character Classes> below). It normally does
508 not need escaping.
509
510 A C<]> is normally either the end of a POSIX character class (see
511 L</POSIX Character Classes> below), or it signals the end of the bracketed
512 character class.  If you want to include a C<]> in the set of characters, you
513 must generally escape it.
514
515 However, if the C<]> is the I<first> (or the second if the first
516 character is a caret) character of a bracketed character class, it
517 does not denote the end of the class (as you cannot have an empty class)
518 and is considered part of the set of characters that can be matched without
519 escaping.
520
521 Examples:
522
523  "+"   =~ /[+?*]/     #  Match, "+" in a character class is not special.
524  "\cH" =~ /[\b]/      #  Match, \b inside in a character class
525                       #  is equivalent to a backspace.
526  "]"   =~ /[][]/      #  Match, as the character class contains.
527                       #  both [ and ].
528  "[]"  =~ /[[]]/      #  Match, the pattern contains a character class
529                       #  containing just ], and the character class is
530                       #  followed by a ].
531
532 =head3 Character Ranges
533
534 It is not uncommon to want to match a range of characters. Luckily, instead
535 of listing all characters in the range, one may use the hyphen (C<->).
536 If inside a bracketed character class you have two characters separated
537 by a hyphen, it's treated as if all characters between the two were in
538 the class. For instance, C<[0-9]> matches any ASCII digit, and C<[a-m]>
539 matches any lowercase letter from the first half of the ASCII alphabet.
540
541 Note that the two characters on either side of the hyphen are not
542 necessarily both letters or both digits. Any character is possible,
543 although not advisable.  C<['-?]> contains a range of characters, but
544 most people will not know which characters that means.  Furthermore,
545 such ranges may lead to portability problems if the code has to run on
546 a platform that uses a different character set, such as EBCDIC.
547
548 If a hyphen in a character class cannot syntactically be part of a range, for
549 instance because it is the first or the last character of the character class,
550 or if it immediately follows a range, the hyphen isn't special, and so is
551 considered a character to be matched literally.  If you want a hyphen in
552 your set of characters to be matched and its position in the class is such
553 that it could be considered part of a range, you must escape that hyphen
554 with a backslash.
555
556 Examples:
557
558  [a-z]       #  Matches a character that is a lower case ASCII letter.
559  [a-fz]      #  Matches any letter between 'a' and 'f' (inclusive) or
560              #  the letter 'z'.
561  [-z]        #  Matches either a hyphen ('-') or the letter 'z'.
562  [a-f-m]     #  Matches any letter between 'a' and 'f' (inclusive), the
563              #  hyphen ('-'), or the letter 'm'.
564  ['-?]       #  Matches any of the characters  '()*+,-./0123456789:;<=>?
565              #  (But not on an EBCDIC platform).
566
567
568 =head3 Negation
569
570 It is also possible to instead list the characters you do not want to
571 match. You can do so by using a caret (C<^>) as the first character in the
572 character class. For instance, C<[^a-z]> matches any character that is not a
573 lowercase ASCII letter, which therefore includes more than a million
574 Unicode code points.  The class is said to be "negated" or "inverted".
575
576 This syntax make the caret a special character inside a bracketed character
577 class, but only if it is the first character of the class. So if you want
578 the caret as one of the characters to match, either escape the caret or
579 else don't list it first.
580
581 In inverted bracketed character classes, Perl ignores the Unicode rules
582 that normally say that certain characters should match a sequence of
583 multiple characters under caseless C</i> matching.  Following those
584 rules could lead to highly confusing situations:
585
586  "ss" =~ /^[^\xDF]+$/ui;   # Matches!
587
588 This should match any sequences of characters that aren't C<\xDF> nor
589 what C<\xDF> matches under C</i>.  C<"s"> isn't C<\xDF>, but Unicode
590 says that C<"ss"> is what C<\xDF> matches under C</i>.  So which one
591 "wins"? Do you fail the match because the string has C<ss> or accept it
592 because it has an C<s> followed by another C<s>?  Perl has chosen the
593 latter.
594
595 Examples:
596
597  "e"  =~  /[^aeiou]/   #  No match, the 'e' is listed.
598  "x"  =~  /[^aeiou]/   #  Match, as 'x' isn't a lowercase vowel.
599  "^"  =~  /[^^]/       #  No match, matches anything that isn't a caret.
600  "^"  =~  /[x^]/       #  Match, caret is not special here.
601
602 =head3 Backslash Sequences
603
604 You can put any backslash sequence character class (with the exception of
605 C<\N> and C<\R>) inside a bracketed character class, and it will act just
606 as if you had put all characters matched by the backslash sequence inside the
607 character class. For instance, C<[a-f\d]> matches any decimal digit, or any
608 of the lowercase letters between 'a' and 'f' inclusive.
609
610 C<\N> within a bracketed character class must be of the forms C<\N{I<name>}>
611 or C<\N{U+I<hex char>}>, and NOT be the form that matches non-newlines,
612 for the same reason that a dot C<.> inside a bracketed character class loses
613 its special meaning: it matches nearly anything, which generally isn't what you
614 want to happen.
615
616
617 Examples:
618
619  /[\p{Thai}\d]/     # Matches a character that is either a Thai
620                     # character, or a digit.
621  /[^\p{Arabic}()]/  # Matches a character that is neither an Arabic
622                     # character, nor a parenthesis.
623
624 Backslash sequence character classes cannot form one of the endpoints
625 of a range.  Thus, you can't say:
626
627  /[\p{Thai}-\d]/     # Wrong!
628
629 =head3 POSIX Character Classes
630 X<character class> X<\p> X<\p{}>
631 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
632 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
633
634 POSIX character classes have the form C<[:class:]>, where I<class> is
635 name, and the C<[:> and C<:]> delimiters. POSIX character classes only appear
636 I<inside> bracketed character classes, and are a convenient and descriptive
637 way of listing a group of characters.
638
639 Be careful about the syntax,
640
641  # Correct:
642  $string =~ /[[:alpha:]]/
643
644  # Incorrect (will warn):
645  $string =~ /[:alpha:]/
646
647 The latter pattern would be a character class consisting of a colon,
648 and the letters C<a>, C<l>, C<p> and C<h>.
649 POSIX character classes can be part of a larger bracketed character class.
650 For example,
651
652  [01[:alpha:]%]
653
654 is valid and matches '0', '1', any alphabetic character, and the percent sign.
655
656 Perl recognizes the following POSIX character classes:
657
658  alpha  Any alphabetical character ("[A-Za-z]").
659  alnum  Any alphanumeric character. ("[A-Za-z0-9]")
660  ascii  Any character in the ASCII character set.
661  blank  A GNU extension, equal to a space or a horizontal tab ("\t").
662  cntrl  Any control character.  See Note [2] below.
663  digit  Any decimal digit ("[0-9]"), equivalent to "\d".
664  graph  Any printable character, excluding a space.  See Note [3] below.
665  lower  Any lowercase character ("[a-z]").
666  print  Any printable character, including a space.  See Note [4] below.
667  punct  Any graphical character excluding "word" characters.  Note [5].
668  space  Any whitespace character. "\s" plus the vertical tab ("\cK").
669  upper  Any uppercase character ("[A-Z]").
670  word   A Perl extension ("[A-Za-z0-9_]"), equivalent to "\w".
671  xdigit Any hexadecimal digit ("[0-9a-fA-F]").
672
673 Most POSIX character classes have two Unicode-style C<\p> property
674 counterparts.  (They are not official Unicode properties, but Perl extensions
675 derived from official Unicode properties.)  The table below shows the relation
676 between POSIX character classes and these counterparts.
677
678 One counterpart, in the column labelled "ASCII-range Unicode" in
679 the table, matches only characters in the ASCII character set.
680
681 The other counterpart, in the column labelled "Full-range Unicode", matches any
682 appropriate characters in the full Unicode character set.  For example,
683 C<\p{Alpha}> matches not just the ASCII alphabetic characters, but any
684 character in the entire Unicode character set considered alphabetic.
685 An entry in the column labelled "backslash sequence" is a (short)
686 equivalent.
687
688  [[:...:]]      ASCII-range          Full-range  backslash  Note
689                  Unicode              Unicode     sequence
690  -----------------------------------------------------
691    alpha      \p{PosixAlpha}       \p{XPosixAlpha}
692    alnum      \p{PosixAlnum}       \p{XPosixAlnum}
693    ascii      \p{ASCII}
694    blank      \p{PosixBlank}       \p{XPosixBlank}  \h      [1]
695                                    or \p{HorizSpace}        [1]
696    cntrl      \p{PosixCntrl}       \p{XPosixCntrl}          [2]
697    digit      \p{PosixDigit}       \p{XPosixDigit}  \d
698    graph      \p{PosixGraph}       \p{XPosixGraph}          [3]
699    lower      \p{PosixLower}       \p{XPosixLower}
700    print      \p{PosixPrint}       \p{XPosixPrint}          [4]
701    punct      \p{PosixPunct}       \p{XPosixPunct}          [5]
702               \p{PerlSpace}        \p{XPerlSpace}   \s      [6]
703    space      \p{PosixSpace}       \p{XPosixSpace}          [6]
704    upper      \p{PosixUpper}       \p{XPosixUpper}
705    word       \p{PosixWord}        \p{XPosixWord}   \w
706    xdigit     \p{PosixXDigit}      \p{XPosixXDigit}
707
708 =over 4
709
710 =item [1]
711
712 C<\p{Blank}> and C<\p{HorizSpace}> are synonyms.
713
714 =item [2]
715
716 Control characters don't produce output as such, but instead usually control
717 the terminal somehow: for example, newline and backspace are control characters.
718 In the ASCII range, characters whose code points are between 0 and 31 inclusive,
719 plus 127 (C<DEL>) are control characters.
720
721 On EBCDIC platforms, it is likely that the code page will define C<[[:cntrl:]]>
722 to be the EBCDIC equivalents of the ASCII controls, plus the controls
723 that in Unicode have code points from 128 through 159.
724
725 =item [3]
726
727 Any character that is I<graphical>, that is, visible. This class consists
728 of all alphanumeric characters and all punctuation characters.
729
730 =item [4]
731
732 All printable characters, which is the set of all graphical characters
733 plus those whitespace characters which are not also controls.
734
735 =item [5]
736
737 C<\p{PosixPunct}> and C<[[:punct:]]> in the ASCII range match all
738 non-controls, non-alphanumeric, non-space characters:
739 C<[-!"#$%&'()*+,./:;<=E<gt>?@[\\\]^_`{|}~]> (although if a locale is in effect,
740 it could alter the behavior of C<[[:punct:]]>).
741
742 The similarly named property, C<\p{Punct}>, matches a somewhat different
743 set in the ASCII range, namely
744 C<[-!"#%&'()*,./:;?@[\\\]_{}]>.  That is, it is missing the nine
745 characters C<[$+E<lt>=E<gt>^`|~]>.
746 This is because Unicode splits what POSIX considers to be punctuation into two
747 categories, Punctuation and Symbols.
748
749 C<\p{XPosixPunct}> and (under Unicode rules) C<[[:punct:]]>, match what
750 C<\p{PosixPunct}> matches in the ASCII range, plus what C<\p{Punct}>
751 matches.  This is different than strictly matching according to
752 C<\p{Punct}>.  Another way to say it is that
753 if Unicode rules are in effect, C<[[:punct:]]> matches all characters
754 that Unicode considers punctuation, plus all ASCII-range characters that
755 Unicode considers symbols.
756
757 =item [6]
758
759 C<\p{SpacePerl}> and C<\p{Space}> differ only in that in non-locale
760 matching, C<\p{Space}> additionally
761 matches the vertical tab, C<\cK>.   Same for the two ASCII-only range forms.
762
763 =back
764
765 There are various other synonyms that can be used besides the names
766 listed in the table.  For example, C<\p{PosixAlpha}> can be written as
767 C<\p{Alpha}>.  All are listed in
768 L<perluniprops/Properties accessible through \p{} and \P{}>,
769 plus all characters matched by each ASCII-range property.
770
771 Both the C<\p> counterparts always assume Unicode rules are in effect.
772 On ASCII platforms, this means they assume that the code points from 128
773 to 255 are Latin-1, and that means that using them under locale rules is
774 unwise unless the locale is guaranteed to be Latin-1 or UTF-8.  In contrast, the
775 POSIX character classes are useful under locale rules.  They are
776 affected by the actual rules in effect, as follows:
777
778 =over
779
780 =item If the C</a> modifier, is in effect ...
781
782 Each of the POSIX classes matches exactly the same as their ASCII-range
783 counterparts.
784
785 =item otherwise ...
786
787 =over
788
789 =item For code points above 255 ...
790
791 The POSIX class matches the same as its Full-range counterpart.
792
793 =item For code points below 256 ...
794
795 =over
796
797 =item if locale rules are in effect ...
798
799 The POSIX class matches according to the locale, except that
800 C<word> uses the platform's native underscore character, no matter what
801 the locale is.
802
803 =item if Unicode rules are in effect or if on an EBCDIC platform ...
804
805 The POSIX class matches the same as the Full-range counterpart.
806
807 =item otherwise ...
808
809 The POSIX class matches the same as the ASCII range counterpart.
810
811 =back
812
813 =back
814
815 =back
816
817 Which rules apply are determined as described in
818 L<perlre/Which character set modifier is in effect?>.
819
820 It is proposed to change this behavior in a future release of Perl so that
821 whether or not Unicode rules are in effect would not change the
822 behavior:  Outside of locale or an EBCDIC code page, the POSIX classes
823 would behave like their ASCII-range counterparts.  If you wish to
824 comment on this proposal, send email to C<perl5-porters@perl.org>.
825
826 =head4 Negation of POSIX character classes
827 X<character class, negation>
828
829 A Perl extension to the POSIX character class is the ability to
830 negate it. This is done by prefixing the class name with a caret (C<^>).
831 Some examples:
832
833      POSIX         ASCII-range     Full-range  backslash
834                     Unicode         Unicode    sequence
835  -----------------------------------------------------
836  [[:^digit:]]   \P{PosixDigit}  \P{XPosixDigit}   \D
837  [[:^space:]]   \P{PosixSpace}  \P{XPosixSpace}
838                 \P{PerlSpace}   \P{XPerlSpace}    \S
839  [[:^word:]]    \P{PerlWord}    \P{XPosixWord}    \W
840
841 The backslash sequence can mean either ASCII- or Full-range Unicode,
842 depending on various factors as described in L<perlre/Which character set modifier is in effect?>.
843
844 =head4 [= =] and [. .]
845
846 Perl recognizes the POSIX character classes C<[=class=]> and
847 C<[.class.]>, but does not (yet?) support them.  Any attempt to use
848 either construct raises an exception.
849
850 =head4 Examples
851
852  /[[:digit:]]/            # Matches a character that is a digit.
853  /[01[:lower:]]/          # Matches a character that is either a
854                           # lowercase letter, or '0' or '1'.
855  /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
856                           # except the letters 'a' to 'f' and 'A' to
857                           # 'F'.  This is because the main character
858                           # class is composed of two POSIX character
859                           # classes that are ORed together, one that
860                           # matches any digit, and the other that
861                           # matches anything that isn't a hex digit.
862                           # The OR adds the digits, leaving only the
863                           # letters 'a' to 'f' and 'A' to 'F' excluded.