Bump $XS::Typemap::VERSION after previous commit.
[perl.git] / pod / perlipc.pod
1 =head1 NAME
2
3 perlipc - Perl interprocess communication (signals, fifos, pipes, safe subprocesses, sockets, and semaphores)
4
5 =head1 DESCRIPTION
6
7 The basic IPC facilities of Perl are built out of the good old Unix
8 signals, named pipes, pipe opens, the Berkeley socket routines, and SysV
9 IPC calls.  Each is used in slightly different situations.
10
11 =head1 Signals
12
13 Perl uses a simple signal handling model: the %SIG hash contains names
14 or references of user-installed signal handlers.  These handlers will
15 be called with an argument which is the name of the signal that
16 triggered it.  A signal may be generated intentionally from a
17 particular keyboard sequence like control-C or control-Z, sent to you
18 from another process, or triggered automatically by the kernel when
19 special events transpire, like a child process exiting, your own process
20 running out of stack space, or hitting a process file-size limit.
21
22 For example, to trap an interrupt signal, set up a handler like this:
23
24     our $shucks;
25
26     sub catch_zap {
27         my $signame = shift;
28         $shucks++;
29         die "Somebody sent me a SIG$signame";
30     }
31     $SIG{INT} = __PACKAGE__ . "::catch_zap";  
32     $SIG{INT} = \&catch_zap;  # best strategy
33
34 Prior to Perl 5.8.0 it was necessary to do as little as you possibly
35 could in your handler; notice how all we do is set a global variable
36 and then raise an exception.  That's because on most systems,
37 libraries are not re-entrant; particularly, memory allocation and I/O
38 routines are not.  That meant that doing nearly I<anything> in your
39 handler could in theory trigger a memory fault and subsequent core
40 dump - see L</Deferred Signals (Safe Signals)> below.
41
42 The names of the signals are the ones listed out by C<kill -l> on your
43 system, or you can retrieve them using the CPAN module L<IPC::Signal>.
44
45 You may also choose to assign the strings C<"IGNORE"> or C<"DEFAULT"> as
46 the handler, in which case Perl will try to discard the signal or do the
47 default thing.
48
49 On most Unix platforms, the C<CHLD> (sometimes also known as C<CLD>) signal
50 has special behavior with respect to a value of C<"IGNORE">.
51 Setting C<$SIG{CHLD}> to C<"IGNORE"> on such a platform has the effect of
52 not creating zombie processes when the parent process fails to C<wait()>
53 on its child processes (i.e., child processes are automatically reaped).
54 Calling C<wait()> with C<$SIG{CHLD}> set to C<"IGNORE"> usually returns
55 C<-1> on such platforms.
56
57 Some signals can be neither trapped nor ignored, such as the KILL and STOP
58 (but not the TSTP) signals. Note that ignoring signals makes them disappear.
59 If you only want them blocked temporarily without them getting lost you'll
60 have to use POSIX' sigprocmask.
61
62 Sending a signal to a negative process ID means that you send the signal
63 to the entire Unix process group.  This code sends a hang-up signal to all
64 processes in the current process group, and also sets $SIG{HUP} to C<"IGNORE"> 
65 so it doesn't kill itself:
66
67     # block scope for local
68     {
69         local $SIG{HUP} = "IGNORE";
70         kill HUP => -$$;
71         # snazzy writing of: kill("HUP", -$$)
72     }
73
74 Another interesting signal to send is signal number zero.  This doesn't
75 actually affect a child process, but instead checks whether it's alive
76 or has changed its UIDs.
77
78     unless (kill 0 => $kid_pid) {
79         warn "something wicked happened to $kid_pid";
80     }
81
82 Signal number zero may fail because you lack permission to send the
83 signal when directed at a process whose real or saved UID is not
84 identical to the real or effective UID of the sending process, even
85 though the process is alive.  You may be able to determine the cause of
86 failure using C<$!> or C<%!>.
87
88     unless (kill(0 => $pid) || $!{EPERM}) {
89         warn "$pid looks dead";
90     }
91
92 You might also want to employ anonymous functions for simple signal
93 handlers:
94
95     $SIG{INT} = sub { die "\nOutta here!\n" };
96
97 SIGCHLD handlers require some special care.  If a second child dies
98 while in the signal handler caused by the first death, we won't get
99 another signal. So must loop here else we will leave the unreaped child
100 as a zombie. And the next time two children die we get another zombie.
101 And so on.
102
103     use POSIX ":sys_wait_h";
104     $SIG{CHLD} = sub {
105         while ((my $child = waitpid(-1, WNOHANG)) > 0) {
106             $Kid_Status{$child} = $?;
107         }
108     };
109     # do something that forks...
110
111 Be careful: qx(), system(), and some modules for calling external commands
112 do a fork(), then wait() for the result. Thus, your signal handler
113 will be called. Because wait() was already called by system() or qx(),
114 the wait() in the signal handler will see no more zombies and will
115 therefore block.
116
117 The best way to prevent this issue is to use waitpid(), as in the following
118 example:
119
120     use POSIX ":sys_wait_h"; # for nonblocking read
121
122     my %children;
123
124     $SIG{CHLD} = sub {
125         # don't change $! and $? outside handler
126         local ($!, $?);
127         my $pid = waitpid(-1, WNOHANG);
128         return if $pid == -1;
129         return unless defined $children{$pid};
130         delete $children{$pid};
131         cleanup_child($pid, $?);
132     };
133
134     while (1) {
135         my $pid = fork();
136         die "cannot fork" unless defined $pid;
137         if ($pid == 0) {
138             # ...
139             exit 0;
140         } else {
141             $children{$pid}=1;
142             # ...
143             system($command);
144             # ...
145        }
146     }
147
148 Signal handling is also used for timeouts in Unix.  While safely
149 protected within an C<eval{}> block, you set a signal handler to trap
150 alarm signals and then schedule to have one delivered to you in some
151 number of seconds.  Then try your blocking operation, clearing the alarm
152 when it's done but not before you've exited your C<eval{}> block.  If it
153 goes off, you'll use die() to jump out of the block.
154
155 Here's an example:
156
157     my $ALARM_EXCEPTION = "alarm clock restart";
158     eval {
159         local $SIG{ALRM} = sub { die $ALARM_EXCEPTION };
160         alarm 10;
161         flock(FH, 2)    # blocking write lock
162                         || die "cannot flock: $!";
163         alarm 0;
164     };
165     if ($@ && $@ !~ quotemeta($ALARM_EXCEPTION)) { die }
166
167 If the operation being timed out is system() or qx(), this technique
168 is liable to generate zombies.    If this matters to you, you'll
169 need to do your own fork() and exec(), and kill the errant child process.
170
171 For more complex signal handling, you might see the standard POSIX
172 module.  Lamentably, this is almost entirely undocumented, but
173 the F<t/lib/posix.t> file from the Perl source distribution has some
174 examples in it.
175
176 =head2 Handling the SIGHUP Signal in Daemons
177
178 A process that usually starts when the system boots and shuts down
179 when the system is shut down is called a daemon (Disk And Execution
180 MONitor). If a daemon process has a configuration file which is
181 modified after the process has been started, there should be a way to
182 tell that process to reread its configuration file without stopping
183 the process. Many daemons provide this mechanism using a C<SIGHUP>
184 signal handler. When you want to tell the daemon to reread the file,
185 simply send it the C<SIGHUP> signal.
186
187 The following example implements a simple daemon, which restarts
188 itself every time the C<SIGHUP> signal is received. The actual code is
189 located in the subroutine C<code()>, which just prints some debugging
190 info to show that it works; it should be replaced with the real code.
191
192   #!/usr/bin/perl -w
193
194   use POSIX ();
195   use FindBin ();
196   use File::Basename ();
197   use File::Spec::Functions;
198
199   $| = 1;
200
201   # make the daemon cross-platform, so exec always calls the script
202   # itself with the right path, no matter how the script was invoked.
203   my $script = File::Basename::basename($0);
204   my $SELF  = catfile($FindBin::Bin, $script);
205
206   # POSIX unmasks the sigprocmask properly
207   $SIG{HUP} = sub {
208       print "got SIGHUP\n";
209       exec($SELF, @ARGV)        || die "$0: couldn't restart: $!";
210   };
211
212   code();
213
214   sub code {
215       print "PID: $$\n";
216       print "ARGV: @ARGV\n";
217       my $count = 0;
218       while (++$count) {
219           sleep 2;
220           print "$count\n";
221       }
222   }
223
224
225 =head2 Deferred Signals (Safe Signals)
226
227 Before Perl 5.8.0, installing Perl code to deal with signals exposed you to
228 danger from two things.  First, few system library functions are
229 re-entrant.  If the signal interrupts while Perl is executing one function
230 (like malloc(3) or printf(3)), and your signal handler then calls the same
231 function again, you could get unpredictable behavior--often, a core dump.
232 Second, Perl isn't itself re-entrant at the lowest levels.  If the signal
233 interrupts Perl while Perl is changing its own internal data structures,
234 similarly unpredictable behavior may result.
235
236 There were two things you could do, knowing this: be paranoid or be
237 pragmatic.  The paranoid approach was to do as little as possible in your
238 signal handler.  Set an existing integer variable that already has a
239 value, and return.  This doesn't help you if you're in a slow system call,
240 which will just restart.  That means you have to C<die> to longjmp(3) out
241 of the handler.  Even this is a little cavalier for the true paranoiac,
242 who avoids C<die> in a handler because the system I<is> out to get you.
243 The pragmatic approach was to say "I know the risks, but prefer the
244 convenience", and to do anything you wanted in your signal handler,
245 and be prepared to clean up core dumps now and again.
246
247 Perl 5.8.0 and later avoid these problems by "deferring" signals.  That is,
248 when the signal is delivered to the process by the system (to the C code
249 that implements Perl) a flag is set, and the handler returns immediately.
250 Then at strategic "safe" points in the Perl interpreter (e.g. when it is
251 about to execute a new opcode) the flags are checked and the Perl level
252 handler from %SIG is executed. The "deferred" scheme allows much more
253 flexibility in the coding of signal handlers as we know the Perl
254 interpreter is in a safe state, and that we are not in a system library
255 function when the handler is called.  However the implementation does
256 differ from previous Perls in the following ways:
257
258 =over 4
259
260 =item Long-running opcodes
261
262 As the Perl interpreter looks at signal flags only when it is about
263 to execute a new opcode, a signal that arrives during a long-running
264 opcode (e.g. a regular expression operation on a very large string) will
265 not be seen until the current opcode completes.
266
267 If a signal of any given type fires multiple times during an opcode 
268 (such as from a fine-grained timer), the handler for that signal will
269 be called only once, after the opcode completes; all other
270 instances will be discarded.  Furthermore, if your system's signal queue
271 gets flooded to the point that there are signals that have been raised
272 but not yet caught (and thus not deferred) at the time an opcode
273 completes, those signals may well be caught and deferred during
274 subsequent opcodes, with sometimes surprising results.  For example, you
275 may see alarms delivered even after calling C<alarm(0)> as the latter
276 stops the raising of alarms but does not cancel the delivery of alarms
277 raised but not yet caught.  Do not depend on the behaviors described in
278 this paragraph as they are side effects of the current implementation and
279 may change in future versions of Perl.
280
281 =item Interrupting IO
282
283 When a signal is delivered (e.g., SIGINT from a control-C) the operating
284 system breaks into IO operations like I<read>(2), which is used to
285 implement Perl's readline() function, the C<< <> >> operator. On older
286 Perls the handler was called immediately (and as C<read> is not "unsafe",
287 this worked well). With the "deferred" scheme the handler is I<not> called
288 immediately, and if Perl is using the system's C<stdio> library that
289 library may restart the C<read> without returning to Perl to give it a
290 chance to call the %SIG handler. If this happens on your system the
291 solution is to use the C<:perlio> layer to do IO--at least on those handles
292 that you want to be able to break into with signals. (The C<:perlio> layer
293 checks the signal flags and calls %SIG handlers before resuming IO
294 operation.)
295
296 The default in Perl 5.8.0 and later is to automatically use
297 the C<:perlio> layer.
298
299 Note that it is not advisable to access a file handle within a signal
300 handler where that signal has interrupted an I/O operation on that same
301 handle. While perl will at least try hard not to crash, there are no
302 guarantees of data integrity; for example, some data might get dropped or
303 written twice.
304
305 Some networking library functions like gethostbyname() are known to have
306 their own implementations of timeouts which may conflict with your
307 timeouts.  If you have problems with such functions, try using the POSIX
308 sigaction() function, which bypasses Perl safe signals.  Be warned that
309 this does subject you to possible memory corruption, as described above.
310
311 Instead of setting C<$SIG{ALRM}>:
312
313    local $SIG{ALRM} = sub { die "alarm" };
314
315 try something like the following:
316
317   use POSIX qw(SIGALRM);
318   POSIX::sigaction(SIGALRM, POSIX::SigAction->new(sub { die "alarm" }))
319           || die "Error setting SIGALRM handler: $!\n";
320
321 Another way to disable the safe signal behavior locally is to use
322 the C<Perl::Unsafe::Signals> module from CPAN, which affects
323 all signals.
324
325 =item Restartable system calls
326
327 On systems that supported it, older versions of Perl used the
328 SA_RESTART flag when installing %SIG handlers.  This meant that
329 restartable system calls would continue rather than returning when
330 a signal arrived.  In order to deliver deferred signals promptly,
331 Perl 5.8.0 and later do I<not> use SA_RESTART.  Consequently, 
332 restartable system calls can fail (with $! set to C<EINTR>) in places
333 where they previously would have succeeded.
334
335 The default C<:perlio> layer retries C<read>, C<write>
336 and C<close> as described above; interrupted C<wait> and 
337 C<waitpid> calls will always be retried.
338
339 =item Signals as "faults"
340
341 Certain signals like SEGV, ILL, and BUS are generated by virtual memory
342 addressing errors and similar "faults". These are normally fatal: there is
343 little a Perl-level handler can do with them.  So Perl delivers them
344 immediately rather than attempting to defer them.
345
346 =item Signals triggered by operating system state
347
348 On some operating systems certain signal handlers are supposed to "do
349 something" before returning. One example can be CHLD or CLD, which
350 indicates a child process has completed. On some operating systems the
351 signal handler is expected to C<wait> for the completed child
352 process. On such systems the deferred signal scheme will not work for
353 those signals: it does not do the C<wait>. Again the failure will
354 look like a loop as the operating system will reissue the signal because
355 there are completed child processes that have not yet been C<wait>ed for.
356
357 =back
358
359 If you want the old signal behavior back despite possible
360 memory corruption, set the environment variable C<PERL_SIGNALS> to
361 C<"unsafe">.  This feature first appeared in Perl 5.8.1.
362
363 =head1 Named Pipes
364
365 A named pipe (often referred to as a FIFO) is an old Unix IPC
366 mechanism for processes communicating on the same machine.  It works
367 just like regular anonymous pipes, except that the
368 processes rendezvous using a filename and need not be related.
369
370 To create a named pipe, use the C<POSIX::mkfifo()> function.
371
372     use POSIX qw(mkfifo);
373     mkfifo($path, 0700)     ||  die "mkfifo $path failed: $!";
374
375 You can also use the Unix command mknod(1), or on some
376 systems, mkfifo(1).  These may not be in your normal path, though.
377
378     # system return val is backwards, so && not ||
379     #
380     $ENV{PATH} .= ":/etc:/usr/etc";
381     if  (      system("mknod",  $path, "p")
382             && system("mkfifo", $path) )
383     {
384         die "mk{nod,fifo} $path failed";
385     }
386
387
388 A fifo is convenient when you want to connect a process to an unrelated
389 one.  When you open a fifo, the program will block until there's something
390 on the other end.
391
392 For example, let's say you'd like to have your F<.signature> file be a
393 named pipe that has a Perl program on the other end.  Now every time any
394 program (like a mailer, news reader, finger program, etc.) tries to read
395 from that file, the reading program will read the new signature from your
396 program.  We'll use the pipe-checking file-test operator, B<-p>, to find
397 out whether anyone (or anything) has accidentally removed our fifo.
398
399     chdir();    # go home
400     my $FIFO = ".signature";
401
402     while (1) {
403         unless (-p $FIFO) {
404             unlink $FIFO;   # discard any failure, will catch later
405             require POSIX;  # delayed loading of heavy module
406             POSIX::mkfifo($FIFO, 0700)
407                                 || die "can't mkfifo $FIFO: $!";
408         }
409
410         # next line blocks till there's a reader
411         open (FIFO, "> $FIFO")  || die "can't open $FIFO: $!";
412         print FIFO "John Smith (smith\@host.org)\n", `fortune -s`;
413         close(FIFO)             || die "can't close $FIFO: $!";
414         sleep 2;                # to avoid dup signals
415     }
416
417 =head1 Using open() for IPC
418
419 Perl's basic open() statement can also be used for unidirectional
420 interprocess communication by either appending or prepending a pipe
421 symbol to the second argument to open().  Here's how to start
422 something up in a child process you intend to write to:
423
424     open(SPOOLER, "| cat -v | lpr -h 2>/dev/null")
425                         || die "can't fork: $!";
426     local $SIG{PIPE} = sub { die "spooler pipe broke" };
427     print SPOOLER "stuff\n";
428     close SPOOLER       || die "bad spool: $! $?";
429
430 And here's how to start up a child process you intend to read from:
431
432     open(STATUS, "netstat -an 2>&1 |")
433                         || die "can't fork: $!";
434     while (<STATUS>) {
435         next if /^(tcp|udp)/;
436         print;
437     }
438     close STATUS        || die "bad netstat: $! $?";
439
440 If one can be sure that a particular program is a Perl script expecting
441 filenames in @ARGV, the clever programmer can write something like this:
442
443     % program f1 "cmd1|" - f2 "cmd2|" f3 < tmpfile
444
445 and no matter which sort of shell it's called from, the Perl program will
446 read from the file F<f1>, the process F<cmd1>, standard input (F<tmpfile>
447 in this case), the F<f2> file, the F<cmd2> command, and finally the F<f3>
448 file.  Pretty nifty, eh?
449
450 You might notice that you could use backticks for much the
451 same effect as opening a pipe for reading:
452
453     print grep { !/^(tcp|udp)/ } `netstat -an 2>&1`;
454     die "bad netstatus ($?)" if $?;
455
456 While this is true on the surface, it's much more efficient to process the
457 file one line or record at a time because then you don't have to read the
458 whole thing into memory at once.  It also gives you finer control of the
459 whole process, letting you kill off the child process early if you'd like.
460
461 Be careful to check the return values from both open() and close().  If
462 you're I<writing> to a pipe, you should also trap SIGPIPE.  Otherwise,
463 think of what happens when you start up a pipe to a command that doesn't
464 exist: the open() will in all likelihood succeed (it only reflects the
465 fork()'s success), but then your output will fail--spectacularly.  Perl
466 can't know whether the command worked, because your command is actually
467 running in a separate process whose exec() might have failed.  Therefore,
468 while readers of bogus commands return just a quick EOF, writers
469 to bogus commands will get hit with a signal, which they'd best be prepared
470 to handle.  Consider:
471
472     open(FH, "|bogus")      || die "can't fork: $!";
473     print FH "bang\n";      #  neither necessary nor sufficient 
474                             #  to check print retval!
475     close(FH)               || die "can't close: $!";
476
477 The reason for not checking the return value from print() is because of
478 pipe buffering; physical writes are delayed.  That won't blow up until the
479 close, and it will blow up with a SIGPIPE.  To catch it, you could use
480 this:
481
482     $SIG{PIPE} = "IGNORE";
483     open(FH, "|bogus")  || die "can't fork: $!";
484     print FH "bang\n";
485     close(FH)           || die "can't close: status=$?";
486
487 =head2 Filehandles
488
489 Both the main process and any child processes it forks share the same
490 STDIN, STDOUT, and STDERR filehandles.  If both processes try to access
491 them at once, strange things can happen.  You may also want to close
492 or reopen the filehandles for the child.  You can get around this by
493 opening your pipe with open(), but on some systems this means that the
494 child process cannot outlive the parent.
495
496 =head2 Background Processes
497
498 You can run a command in the background with:
499
500     system("cmd &");
501
502 The command's STDOUT and STDERR (and possibly STDIN, depending on your
503 shell) will be the same as the parent's.  You won't need to catch
504 SIGCHLD because of the double-fork taking place; see below for details.
505
506 =head2 Complete Dissociation of Child from Parent
507
508 In some cases (starting server processes, for instance) you'll want to
509 completely dissociate the child process from the parent.  This is
510 often called daemonization.  A well-behaved daemon will also chdir()
511 to the root directory so it doesn't prevent unmounting the filesystem
512 containing the directory from which it was launched, and redirect its
513 standard file descriptors from and to F</dev/null> so that random
514 output doesn't wind up on the user's terminal.
515
516     use POSIX "setsid";
517
518     sub daemonize {
519         chdir("/")                      || die "can't chdir to /: $!";
520         open(STDIN,  "< /dev/null")     || die "can't read /dev/null: $!";
521         open(STDOUT, "> /dev/null")     || die "can't write to /dev/null: $!";
522         defined(my $pid = fork())       || die "can't fork: $!";
523         exit if $pid;                   # non-zero now means I am the parent
524         (setsid() != -1)                || die "Can't start a new session: $!" 
525         open(STDERR, ">&STDOUT")        || die "can't dup stdout: $!";
526     }
527
528 The fork() has to come before the setsid() to ensure you aren't a
529 process group leader; the setsid() will fail if you are.  If your
530 system doesn't have the setsid() function, open F</dev/tty> and use the
531 C<TIOCNOTTY> ioctl() on it instead.  See tty(4) for details.
532
533 Non-Unix users should check their C<< I<Your_OS>::Process >> module for 
534 other possible solutions.
535
536 =head2 Safe Pipe Opens
537
538 Another interesting approach to IPC is making your single program go
539 multiprocess and communicate between--or even amongst--yourselves.  The
540 open() function will accept a file argument of either C<"-|"> or C<"|-">
541 to do a very interesting thing: it forks a child connected to the
542 filehandle you've opened.  The child is running the same program as the
543 parent.  This is useful for safely opening a file when running under an
544 assumed UID or GID, for example.  If you open a pipe I<to> minus, you can
545 write to the filehandle you opened and your kid will find it in I<his>
546 STDIN.  If you open a pipe I<from> minus, you can read from the filehandle
547 you opened whatever your kid writes to I<his> STDOUT.
548
549     use English qw[ -no_match_vars ];
550     my $PRECIOUS = "/path/to/some/safe/file";
551     my $sleep_count;
552     my $pid;
553
554     do {
555         $pid = open(KID_TO_WRITE, "|-");
556         unless (defined $pid) {
557             warn "cannot fork: $!";
558             die "bailing out" if $sleep_count++ > 6;
559             sleep 10;
560         }
561     } until defined $pid;
562
563     if ($pid) {                 # I am the parent 
564         print KID_TO_WRITE @some_data;
565         close(KID_TO_WRITE)     || warn "kid exited $?";
566     } else {                    # I am the child
567         # drop permissions in setuid and/or setgid programs:
568         ($EUID, $EGID) = ($UID, $GID);  
569         open (OUTFILE, "> $PRECIOUS") 
570                                 || die "can't open $PRECIOUS: $!";
571         while (<STDIN>) {
572             print OUTFILE;      # child's STDIN is parent's KID_TO_WRITE
573         }
574         close(OUTFILE)          || die "can't close $PRECIOUS: $!";
575         exit(0);                # don't forget this!!
576     }
577
578 Another common use for this construct is when you need to execute
579 something without the shell's interference.  With system(), it's
580 straightforward, but you can't use a pipe open or backticks safely.
581 That's because there's no way to stop the shell from getting its hands on
582 your arguments.   Instead, use lower-level control to call exec() directly.
583
584 Here's a safe backtick or pipe open for read:
585
586     my $pid = open(KID_TO_READ, "-|");
587     defined($pid)           || die "can't fork: $!";
588
589     if ($pid) {             # parent
590         while (<KID_TO_READ>) {
591                             # do something interesting
592         }
593         close(KID_TO_READ)  || warn "kid exited $?";
594
595     } else {                # child
596         ($EUID, $EGID) = ($UID, $GID); # suid only
597         exec($program, @options, @args)
598                             || die "can't exec program: $!";
599         # NOTREACHED
600     }
601
602 And here's a safe pipe open for writing:
603
604     my $pid = open(KID_TO_WRITE, "|-");
605     defined($pid)           || die "can't fork: $!";
606
607     $SIG{PIPE} = sub { die "whoops, $program pipe broke" };
608
609     if ($pid) {             # parent
610         print KID_TO_WRITE @data;
611         close(KID_TO_WRITE) || warn "kid exited $?";
612
613     } else {                # child
614         ($EUID, $EGID) = ($UID, $GID);
615         exec($program, @options, @args)
616                             || die "can't exec program: $!";
617         # NOTREACHED
618     }
619
620 It is very easy to dead-lock a process using this form of open(), or
621 indeed with any use of pipe() with multiple subprocesses.  The 
622 example above is "safe" because it is simple and calls exec().  See
623 L</"Avoiding Pipe Deadlocks"> for general safety principles, but there
624 are extra gotchas with Safe Pipe Opens.
625
626 In particular, if you opened the pipe using C<open FH, "|-">, then you
627 cannot simply use close() in the parent process to close an unwanted
628 writer.  Consider this code:
629
630     my $pid = open(WRITER, "|-");        # fork open a kid
631     defined($pid)               || die "first fork failed: $!";
632     if ($pid) {
633         if (my $sub_pid = fork()) {
634             defined($sub_pid)   || die "second fork failed: $!";
635             close(WRITER)       || die "couldn't close WRITER: $!";
636             # now do something else...
637         }
638         else {
639             # first write to WRITER
640             # ...
641             # then when finished
642             close(WRITER)       || die "couldn't close WRITER: $!";
643             exit(0);
644         }
645     }
646     else {
647         # first do something with STDIN, then
648         exit(0);
649     }
650
651 In the example above, the true parent does not want to write to the WRITER
652 filehandle, so it closes it.  However, because WRITER was opened using
653 C<open FH, "|-">, it has a special behavior: closing it calls
654 waitpid() (see L<perlfunc/waitpid>), which waits for the subprocess
655 to exit.  If the child process ends up waiting for something happening
656 in the section marked "do something else", you have deadlock.
657
658 This can also be a problem with intermediate subprocesses in more
659 complicated code, which will call waitpid() on all open filehandles
660 during global destruction--in no predictable order.
661
662 To solve this, you must manually use pipe(), fork(), and the form of
663 open() which sets one file descriptor to another, as shown below:
664
665     pipe(READER, WRITER)        || die "pipe failed: $!";
666     $pid = fork();
667     defined($pid)               || die "first fork failed: $!";
668     if ($pid) {
669         close READER;
670         if (my $sub_pid = fork()) {
671             defined($sub_pid)   || die "first fork failed: $!";
672             close(WRITER)       || die "can't close WRITER: $!";
673         }
674         else {
675             # write to WRITER...
676             # ...
677             # then  when finished
678             close(WRITER)       || die "can't close WRITER: $!";
679             exit(0);
680         }
681         # write to WRITER...
682     }
683     else {
684         open(STDIN, "<&READER") || die "can't reopen STDIN: $!";
685         close(WRITER)           || die "can't close WRITER: $!";
686         # do something...
687         exit(0);
688     }
689
690 Since Perl 5.8.0, you can also use the list form of C<open> for pipes.
691 This is preferred when you wish to avoid having the shell interpret
692 metacharacters that may be in your command string.
693
694 So for example, instead of using:
695
696     open(PS_PIPE, "ps aux|")    || die "can't open ps pipe: $!";
697
698 One would use either of these:
699
700     open(PS_PIPE, "-|", "ps", "aux") 
701                                 || die "can't open ps pipe: $!";
702
703     @ps_args = qw[ ps aux ];
704     open(PS_PIPE, "-|", @ps_args)
705                                 || die "can't open @ps_args|: $!";
706
707 Because there are more than three arguments to open(), forks the ps(1)
708 command I<without> spawning a shell, and reads its standard output via the
709 C<PS_PIPE> filehandle.  The corresponding syntax to I<write> to command
710 pipes is to use C<"|-"> in place of C<"-|">.  
711
712 This was admittedly a rather silly example, because you're using string
713 literals whose content is perfectly safe.  There is therefore no cause to
714 resort to the harder-to-read, multi-argument form of pipe open().  However,
715 whenever you cannot be assured that the program arguments are free of shell
716 metacharacters, the fancier form of open() should be used.  For example:
717
718     @grep_args = ("egrep", "-i", $some_pattern, @many_files);
719     open(GREP_PIPE, "-|", @grep_args)
720                         || die "can't open @grep_args|: $!";
721
722 Here the multi-argument form of pipe open() is preferred because the
723 pattern and indeed even the filenames themselves might hold metacharacters.
724
725 Be aware that these operations are full Unix forks, which means they may
726 not be correctly implemented on all alien systems.  Additionally, these are
727 not true multithreading.  To learn more about threading, see the F<modules>
728 file mentioned below in the SEE ALSO section.
729
730 =head2 Avoiding Pipe Deadlocks
731
732 Whenever you have more than one subprocess, you must be careful that each
733 closes whichever half of any pipes created for interprocess communication
734 it is not using.  This is because any child process reading from the pipe
735 and expecting an EOF will never receive it, and therefore never exit. A
736 single process closing a pipe is not enough to close it; the last process
737 with the pipe open must close it for it to read EOF.
738
739 Certain built-in Unix features help prevent this most of the time.  For
740 instance, filehandles have a "close on exec" flag, which is set I<en masse>
741 under control of the C<$^F> variable.  This is so any filehandles you
742 didn't explicitly route to the STDIN, STDOUT or STDERR of a child
743 I<program> will be automatically closed.
744
745 Always explicitly and immediately call close() on the writable end of any
746 pipe, unless that process is actually writing to it.  Even if you don't
747 explicitly call close(), Perl will still close() all filehandles during
748 global destruction.  As previously discussed, if those filehandles have
749 been opened with Safe Pipe Open, this will result in calling waitpid(),
750 which may again deadlock.
751
752 =head2 Bidirectional Communication with Another Process
753
754 While this works reasonably well for unidirectional communication, what
755 about bidirectional communication?  The most obvious approach doesn't work:
756
757     # THIS DOES NOT WORK!!
758     open(PROG_FOR_READING_AND_WRITING, "| some program |")
759
760 If you forget to C<use warnings>, you'll miss out entirely on the
761 helpful diagnostic message:
762
763     Can't do bidirectional pipe at -e line 1.
764
765 If you really want to, you can use the standard open2() from the
766 C<IPC::Open2> module to catch both ends.  There's also an open3() in
767 C<IPC::Open3> for tridirectional I/O so you can also catch your child's
768 STDERR, but doing so would then require an awkward select() loop and
769 wouldn't allow you to use normal Perl input operations.
770
771 If you look at its source, you'll see that open2() uses low-level
772 primitives like the pipe() and exec() syscalls to create all the
773 connections.  Although it might have been more efficient by using
774 socketpair(), this would have been even less portable than it already
775 is. The open2() and open3() functions are unlikely to work anywhere
776 except on a Unix system, or at least one purporting POSIX compliance.
777
778 =for TODO
779 Hold on, is this even true?  First it says that socketpair() is avoided
780 for portability, but then it says it probably won't work except on 
781 Unixy systems anyway.  Which one of those is true?
782
783 Here's an example of using open2():
784
785     use FileHandle;
786     use IPC::Open2;
787     $pid = open2(*Reader, *Writer, "cat -un");
788     print Writer "stuff\n";
789     $got = <Reader>;
790
791 The problem with this is that buffering is really going to ruin your
792 day.  Even though your C<Writer> filehandle is auto-flushed so the process
793 on the other end gets your data in a timely manner, you can't usually do
794 anything to force that process to give its data to you in a similarly quick
795 fashion.  In this special case, we could actually so, because we gave
796 I<cat> a B<-u> flag to make it unbuffered.  But very few commands are
797 designed to operate over pipes, so this seldom works unless you yourself
798 wrote the program on the other end of the double-ended pipe.
799
800 A solution to this is to use a library which uses pseudottys to make your
801 program behave more reasonably.  This way you don't have to have control
802 over the source code of the program you're using.  The C<Expect> module
803 from CPAN also addresses this kind of thing.  This module requires two
804 other modules from CPAN, C<IO::Pty> and C<IO::Stty>.  It sets up a pseudo
805 terminal to interact with programs that insist on talking to the terminal
806 device driver.  If your system is supported, this may be your best bet.
807
808 =head2 Bidirectional Communication with Yourself
809
810 If you want, you may make low-level pipe() and fork() syscalls to stitch
811 this together by hand.  This example only talks to itself, but you could
812 reopen the appropriate handles to STDIN and STDOUT and call other processes.
813 (The following example lacks proper error checking.)
814
815     #!/usr/bin/perl -w
816     # pipe1 - bidirectional communication using two pipe pairs
817     #         designed for the socketpair-challenged
818     use IO::Handle;               # thousands of lines just for autoflush :-(
819     pipe(PARENT_RDR, CHILD_WTR);  # XXX: check failure?
820     pipe(CHILD_RDR,  PARENT_WTR); # XXX: check failure?
821     CHILD_WTR->autoflush(1);
822     PARENT_WTR->autoflush(1);
823
824     if ($pid = fork()) {
825         close PARENT_RDR; 
826         close PARENT_WTR;
827         print CHILD_WTR "Parent Pid $$ is sending this\n";
828         chomp($line = <CHILD_RDR>);
829         print "Parent Pid $$ just read this: '$line'\n";
830         close CHILD_RDR; close CHILD_WTR;
831         waitpid($pid, 0);
832     } else {
833         die "cannot fork: $!" unless defined $pid;
834         close CHILD_RDR; 
835         close CHILD_WTR;
836         chomp($line = <PARENT_RDR>);
837         print "Child Pid $$ just read this: '$line'\n";
838         print PARENT_WTR "Child Pid $$ is sending this\n";
839         close PARENT_RDR; 
840         close PARENT_WTR;
841         exit(0);
842     }
843
844 But you don't actually have to make two pipe calls.  If you
845 have the socketpair() system call, it will do this all for you.
846
847     #!/usr/bin/perl -w
848     # pipe2 - bidirectional communication using socketpair
849     #   "the best ones always go both ways"
850
851     use Socket;
852     use IO::Handle;  # thousands of lines just for autoflush :-(
853
854     # We say AF_UNIX because although *_LOCAL is the
855     # POSIX 1003.1g form of the constant, many machines
856     # still don't have it.
857     socketpair(CHILD, PARENT, AF_UNIX, SOCK_STREAM, PF_UNSPEC)
858                                 ||  die "socketpair: $!";
859
860     CHILD->autoflush(1);
861     PARENT->autoflush(1);
862
863     if ($pid = fork()) {
864         close PARENT;
865         print CHILD "Parent Pid $$ is sending this\n";
866         chomp($line = <CHILD>);
867         print "Parent Pid $$ just read this: '$line'\n";
868         close CHILD;
869         waitpid($pid, 0);
870     } else {
871         die "cannot fork: $!" unless defined $pid;
872         close CHILD;
873         chomp($line = <PARENT>);
874         print "Child Pid $$ just read this: '$line'\n";
875         print PARENT "Child Pid $$ is sending this\n";
876         close PARENT;
877         exit(0);
878     }
879
880 =head1 Sockets: Client/Server Communication
881
882 While not entirely limited to Unix-derived operating systems (e.g., WinSock
883 on PCs provides socket support, as do some VMS libraries), you might not have
884 sockets on your system, in which case this section probably isn't going to
885 do you much good.  With sockets, you can do both virtual circuits like TCP
886 streams and datagrams like UDP packets.  You may be able to do even more
887 depending on your system.
888
889 The Perl functions for dealing with sockets have the same names as
890 the corresponding system calls in C, but their arguments tend to differ
891 for two reasons.  First, Perl filehandles work differently than C file
892 descriptors.  Second, Perl already knows the length of its strings, so you
893 don't need to pass that information.
894
895 One of the major problems with ancient, antemillennial socket code in Perl
896 was that it used hard-coded values for some of the constants, which
897 severely hurt portability.  If you ever see code that does anything like
898 explicitly setting C<$AF_INET = 2>, you know you're in for big trouble.  
899 An immeasurably superior approach is to use the C<Socket> module, which more
900 reliably grants access to the various constants and functions you'll need.
901
902 If you're not writing a server/client for an existing protocol like
903 NNTP or SMTP, you should give some thought to how your server will
904 know when the client has finished talking, and vice-versa.  Most
905 protocols are based on one-line messages and responses (so one party
906 knows the other has finished when a "\n" is received) or multi-line
907 messages and responses that end with a period on an empty line
908 ("\n.\n" terminates a message/response).
909
910 =head2 Internet Line Terminators
911
912 The Internet line terminator is "\015\012".  Under ASCII variants of
913 Unix, that could usually be written as "\r\n", but under other systems,
914 "\r\n" might at times be "\015\015\012", "\012\012\015", or something
915 completely different.  The standards specify writing "\015\012" to be
916 conformant (be strict in what you provide), but they also recommend
917 accepting a lone "\012" on input (be lenient in what you require).
918 We haven't always been very good about that in the code in this manpage,
919 but unless you're on a Mac from way back in its pre-Unix dark ages, you'll 
920 probably be ok.
921
922 =head2 Internet TCP Clients and Servers
923
924 Use Internet-domain sockets when you want to do client-server
925 communication that might extend to machines outside of your own system.
926
927 Here's a sample TCP client using Internet-domain sockets:
928
929     #!/usr/bin/perl -w
930     use strict;
931     use Socket;
932     my ($remote, $port, $iaddr, $paddr, $proto, $line);
933
934     $remote  = shift || "localhost";
935     $port    = shift || 2345;  # random port
936     if ($port =~ /\D/) { $port = getservbyname($port, "tcp") }
937     die "No port" unless $port;
938     $iaddr   = inet_aton($remote)       || die "no host: $remote";
939     $paddr   = sockaddr_in($port, $iaddr);
940
941     $proto   = getprotobyname("tcp");
942     socket(SOCK, PF_INET, SOCK_STREAM, $proto)  || die "socket: $!";
943     connect(SOCK, $paddr)               || die "connect: $!";
944     while ($line = <SOCK>) {
945         print $line;
946     }
947
948     close (SOCK)                        || die "close: $!";
949     exit(0);
950
951 And here's a corresponding server to go along with it.  We'll
952 leave the address as C<INADDR_ANY> so that the kernel can choose
953 the appropriate interface on multihomed hosts.  If you want sit
954 on a particular interface (like the external side of a gateway
955 or firewall machine), fill this in with your real address instead.
956
957     #!/usr/bin/perl -Tw
958     use strict;
959     BEGIN { $ENV{PATH} = "/usr/bin:/bin" }
960     use Socket;
961     use Carp;
962     my $EOL = "\015\012";
963
964     sub logmsg { print "$0 $$: @_ at ", scalar localtime(), "\n" }
965
966     my $port  = shift || 2345;
967     die "invalid port" unless if $port =~ /^ \d+ $/x;
968
969     my $proto = getprotobyname("tcp");
970
971     socket(Server, PF_INET, SOCK_STREAM, $proto)    || die "socket: $!";
972     setsockopt(Server, SOL_SOCKET, SO_REUSEADDR, pack("l", 1))    
973                                                     || die "setsockopt: $!";
974     bind(Server, sockaddr_in($port, INADDR_ANY))    || die "bind: $!";
975     listen(Server, SOMAXCONN)                       || die "listen: $!";
976
977     logmsg "server started on port $port";
978
979     my $paddr;
980
981     $SIG{CHLD} = \&REAPER;
982
983     for ( ; $paddr = accept(Client, Server); close Client) {
984         my($port, $iaddr) = sockaddr_in($paddr);
985         my $name = gethostbyaddr($iaddr, AF_INET);
986
987         logmsg "connection from $name [",
988                 inet_ntoa($iaddr), "]
989                 at port $port";
990
991         print Client "Hello there, $name, it's now ",
992                         scalar localtime(), $EOL;
993     }
994
995 And here's a multithreaded version.  It's multithreaded in that
996 like most typical servers, it spawns (fork()s) a slave server to
997 handle the client request so that the master server can quickly
998 go back to service a new client.
999
1000     #!/usr/bin/perl -Tw
1001     use strict;
1002     BEGIN { $ENV{PATH} = "/usr/bin:/bin" }
1003     use Socket;
1004     use Carp;
1005     my $EOL = "\015\012";
1006
1007     sub spawn;  # forward declaration
1008     sub logmsg { print "$0 $$: @_ at ", scalar localtime(), "\n" }
1009
1010     my $port  = shift || 2345;
1011     die "invalid port" unless if $port =~ /^ \d+ $/x;
1012
1013     my $proto = getprotobyname("tcp");
1014
1015     socket(Server, PF_INET, SOCK_STREAM, $proto)    || die "socket: $!";
1016     setsockopt(Server, SOL_SOCKET, SO_REUSEADDR, pack("l", 1))         
1017                                                     || die "setsockopt: $!";
1018     bind(Server, sockaddr_in($port, INADDR_ANY))    || die "bind: $!";
1019     listen(Server, SOMAXCONN)                       || die "listen: $!";
1020
1021     logmsg "server started on port $port";
1022
1023     my $waitedpid = 0;
1024     my $paddr;
1025
1026     use POSIX ":sys_wait_h";
1027     use Errno;
1028
1029     sub REAPER {
1030         local $!;   # don't let waitpid() overwrite current error
1031         while ((my $pid = waitpid(-1, WNOHANG)) > 0 && WIFEXITED($?)) {
1032             logmsg "reaped $waitedpid" . ($? ? " with exit $?" : "");
1033         }
1034         $SIG{CHLD} = \&REAPER;  # loathe SysV
1035     }
1036
1037     $SIG{CHLD} = \&REAPER;
1038
1039     while (1) {
1040         $paddr = accept(Client, Server) || do {
1041             # try again if accept() returned because got a signal
1042             next if $!{EINTR};
1043             die "accept: $!";
1044         };
1045         my ($port, $iaddr) = sockaddr_in($paddr);
1046         my $name = gethostbyaddr($iaddr, AF_INET);
1047
1048         logmsg "connection from $name [",
1049                inet_ntoa($iaddr),
1050                "] at port $port";
1051
1052         spawn sub {
1053             $| = 1;
1054             print "Hello there, $name, it's now ", scalar localtime(), $EOL;
1055             exec "/usr/games/fortune"       # XXX: "wrong" line terminators
1056                 or confess "can't exec fortune: $!";
1057         };
1058         close Client;
1059     }
1060
1061     sub spawn {
1062         my $coderef = shift;
1063
1064         unless (@_ == 0 && $coderef && ref($coderef) eq "CODE") {
1065             confess "usage: spawn CODEREF";
1066         }
1067
1068         my $pid;
1069         unless (defined($pid = fork())) {
1070             logmsg "cannot fork: $!";
1071             return;
1072         } 
1073         elsif ($pid) {
1074             logmsg "begat $pid";
1075             return; # I'm the parent
1076         }
1077         # else I'm the child -- go spawn
1078
1079         open(STDIN,  "<&Client")    || die "can't dup client to stdin";
1080         open(STDOUT, ">&Client")    || die "can't dup client to stdout";
1081         ## open(STDERR, ">&STDOUT") || die "can't dup stdout to stderr";
1082         exit($coderef->());
1083     }
1084
1085 This server takes the trouble to clone off a child version via fork()
1086 for each incoming request.  That way it can handle many requests at
1087 once, which you might not always want.  Even if you don't fork(), the
1088 listen() will allow that many pending connections.  Forking servers
1089 have to be particularly careful about cleaning up their dead children
1090 (called "zombies" in Unix parlance), because otherwise you'll quickly
1091 fill up your process table.  The REAPER subroutine is used here to
1092 call waitpid() for any child processes that have finished, thereby
1093 ensuring that they terminate cleanly and don't join the ranks of the
1094 living dead.
1095
1096 Within the while loop we call accept() and check to see if it returns
1097 a false value.  This would normally indicate a system error needs
1098 to be reported.  However, the introduction of safe signals (see
1099 L</Deferred Signals (Safe Signals)> above) in Perl 5.8.0 means that
1100 accept() might also be interrupted when the process receives a signal.
1101 This typically happens when one of the forked subprocesses exits and
1102 notifies the parent process with a CHLD signal.  
1103
1104 If accept() is interrupted by a signal, $! will be set to EINTR.
1105 If this happens, we can safely continue to the next iteration of
1106 the loop and another call to accept().  It is important that your
1107 signal handling code not modify the value of $!, or else this test 
1108 will likely fail.  In the REAPER subroutine we create a local version
1109 of $! before calling waitpid().  When waitpid() sets $! to ECHILD as
1110 it inevitably does when it has no more children waiting, it 
1111 updates the local copy and leaves the original unchanged.
1112
1113 You should use the B<-T> flag to enable taint checking (see L<perlsec>)
1114 even if we aren't running setuid or setgid.  This is always a good idea
1115 for servers or any program run on behalf of someone else (like CGI
1116 scripts), because it lessens the chances that people from the outside will
1117 be able to compromise your system.
1118
1119 Let's look at another TCP client.  This one connects to the TCP "time"
1120 service on a number of different machines and shows how far their clocks
1121 differ from the system on which it's being run:
1122
1123     #!/usr/bin/perl  -w
1124     use strict;
1125     use Socket;
1126
1127     my $SECS_OF_70_YEARS = 2208988800;
1128     sub ctime { scalar localtime(shift() || time()) }
1129
1130     my $iaddr = gethostbyname("localhost");
1131     my $proto = getprotobyname("tcp");
1132     my $port = getservbyname("time", "tcp");
1133     my $paddr = sockaddr_in(0, $iaddr);
1134     my($host);
1135
1136     $| = 1;
1137     printf "%-24s %8s %s\n", "localhost", 0, ctime();
1138
1139     foreach $host (@ARGV) {
1140         printf "%-24s ", $host;
1141         my $hisiaddr = inet_aton($host)     || die "unknown host";
1142         my $hispaddr = sockaddr_in($port, $hisiaddr);
1143         socket(SOCKET, PF_INET, SOCK_STREAM, $proto)   
1144                                             || die "socket: $!";
1145         connect(SOCKET, $hispaddr)          || die "connect: $!";
1146         my $rtime = pack("C4", ());
1147         read(SOCKET, $rtime, 4);
1148         close(SOCKET);
1149         my $histime = unpack("N", $rtime) - $SECS_OF_70_YEARS;
1150         printf "%8d %s\n", $histime - time(), ctime($histime);
1151     }
1152
1153 =head2 Unix-Domain TCP Clients and Servers
1154
1155 That's fine for Internet-domain clients and servers, but what about local
1156 communications?  While you can use the same setup, sometimes you don't
1157 want to.  Unix-domain sockets are local to the current host, and are often
1158 used internally to implement pipes.  Unlike Internet domain sockets, Unix
1159 domain sockets can show up in the file system with an ls(1) listing.
1160
1161     % ls -l /dev/log
1162     srw-rw-rw-  1 root            0 Oct 31 07:23 /dev/log
1163
1164 You can test for these with Perl's B<-S> file test:
1165
1166     unless (-S "/dev/log") {
1167         die "something's wicked with the log system";
1168     }
1169
1170 Here's a sample Unix-domain client:
1171
1172     #!/usr/bin/perl -w
1173     use Socket;
1174     use strict;
1175     my ($rendezvous, $line);
1176
1177     $rendezvous = shift || "catsock";
1178     socket(SOCK, PF_UNIX, SOCK_STREAM, 0)     || die "socket: $!";
1179     connect(SOCK, sockaddr_un($rendezvous))   || die "connect: $!";
1180     while (defined($line = <SOCK>)) {
1181         print $line;
1182     }
1183     exit(0);
1184
1185 And here's a corresponding server.  You don't have to worry about silly
1186 network terminators here because Unix domain sockets are guaranteed
1187 to be on the localhost, and thus everything works right.
1188
1189     #!/usr/bin/perl -Tw
1190     use strict;
1191     use Socket;
1192     use Carp;
1193
1194     BEGIN { $ENV{PATH} = "/usr/bin:/bin" }
1195     sub spawn;  # forward declaration
1196     sub logmsg { print "$0 $$: @_ at ", scalar localtime(), "\n" }
1197
1198     my $NAME = "catsock";
1199     my $uaddr = sockaddr_un($NAME);
1200     my $proto = getprotobyname("tcp");
1201
1202     socket(Server, PF_UNIX, SOCK_STREAM, 0) || die "socket: $!";
1203     unlink($NAME);
1204     bind  (Server, $uaddr)                  || die "bind: $!";
1205     listen(Server, SOMAXCONN)               || die "listen: $!";
1206
1207     logmsg "server started on $NAME";
1208
1209     my $waitedpid;
1210
1211     use POSIX ":sys_wait_h";
1212     sub REAPER {
1213         my $child;
1214         while (($waitedpid = waitpid(-1, WNOHANG)) > 0) {
1215             logmsg "reaped $waitedpid" . ($? ? " with exit $?" : "");
1216         }
1217         $SIG{CHLD} = \&REAPER;  # loathe SysV
1218     }
1219
1220     $SIG{CHLD} = \&REAPER;
1221
1222
1223     for ( $waitedpid = 0;
1224           accept(Client, Server) || $waitedpid;
1225           $waitedpid = 0, close Client)
1226     {
1227         next if $waitedpid;
1228         logmsg "connection on $NAME";
1229         spawn sub {
1230             print "Hello there, it's now ", scalar localtime(), "\n";
1231             exec("/usr/games/fortune")  || die "can't exec fortune: $!";
1232         };
1233     }
1234
1235     sub spawn {
1236         my $coderef = shift();
1237
1238         unless (@_ == 0 && $coderef && ref($coderef) eq "CODE") {
1239             confess "usage: spawn CODEREF";
1240         }
1241
1242         my $pid;
1243         unless (defined($pid = fork())) {
1244             logmsg "cannot fork: $!";
1245             return;
1246         } 
1247         elsif ($pid) {
1248             logmsg "begat $pid";
1249             return; # I'm the parent
1250         } 
1251         else {
1252             # I'm the child -- go spawn
1253         }
1254
1255         open(STDIN,  "<&Client")    || die "can't dup client to stdin";
1256         open(STDOUT, ">&Client")    || die "can't dup client to stdout";
1257         ## open(STDERR, ">&STDOUT") || die "can't dup stdout to stderr";
1258         exit($coderef->());
1259     }
1260
1261 As you see, it's remarkably similar to the Internet domain TCP server, so
1262 much so, in fact, that we've omitted several duplicate functions--spawn(),
1263 logmsg(), ctime(), and REAPER()--which are the same as in the other server.
1264
1265 So why would you ever want to use a Unix domain socket instead of a
1266 simpler named pipe?  Because a named pipe doesn't give you sessions.  You
1267 can't tell one process's data from another's.  With socket programming,
1268 you get a separate session for each client; that's why accept() takes two
1269 arguments.
1270
1271 For example, let's say that you have a long-running database server daemon
1272 that you want folks to be able to access from the Web, but only
1273 if they go through a CGI interface.  You'd have a small, simple CGI
1274 program that does whatever checks and logging you feel like, and then acts
1275 as a Unix-domain client and connects to your private server.
1276
1277 =head1 TCP Clients with IO::Socket
1278
1279 For those preferring a higher-level interface to socket programming, the
1280 IO::Socket module provides an object-oriented approach.  If for some reason
1281 you lack this module, you can just fetch IO::Socket from CPAN, where you'll also
1282 find modules providing easy interfaces to the following systems: DNS, FTP,
1283 Ident (RFC 931), NIS and NISPlus, NNTP, Ping, POP3, SMTP, SNMP, SSLeay,
1284 Telnet, and Time--to name just a few.
1285
1286 =head2 A Simple Client
1287
1288 Here's a client that creates a TCP connection to the "daytime"
1289 service at port 13 of the host name "localhost" and prints out everything
1290 that the server there cares to provide.
1291
1292     #!/usr/bin/perl -w
1293     use IO::Socket;
1294     $remote = IO::Socket::INET->new(
1295                         Proto    => "tcp",
1296                         PeerAddr => "localhost",
1297                         PeerPort => "daytime(13)",
1298                     )
1299                   || die "can't connect to daytime service on localhost";
1300     while (<$remote>) { print }
1301
1302 When you run this program, you should get something back that
1303 looks like this:
1304
1305     Wed May 14 08:40:46 MDT 1997
1306
1307 Here are what those parameters to the new() constructor mean:
1308
1309 =over 4
1310
1311 =item C<Proto>
1312
1313 This is which protocol to use.  In this case, the socket handle returned
1314 will be connected to a TCP socket, because we want a stream-oriented
1315 connection, that is, one that acts pretty much like a plain old file.
1316 Not all sockets are this of this type.  For example, the UDP protocol
1317 can be used to make a datagram socket, used for message-passing.
1318
1319 =item C<PeerAddr>
1320
1321 This is the name or Internet address of the remote host the server is
1322 running on.  We could have specified a longer name like C<"www.perl.com">,
1323 or an address like C<"207.171.7.72">.  For demonstration purposes, we've
1324 used the special hostname C<"localhost">, which should always mean the
1325 current machine you're running on.  The corresponding Internet address
1326 for localhost is C<"127.0.0.1">, if you'd rather use that.
1327
1328 =item C<PeerPort>
1329
1330 This is the service name or port number we'd like to connect to.
1331 We could have gotten away with using just C<"daytime"> on systems with a
1332 well-configured system services file,[FOOTNOTE: The system services file
1333 is found in I</etc/services> under Unixy systems.] but here we've specified the
1334 port number (13) in parentheses.  Using just the number would have also
1335 worked, but numeric literals make careful programmers nervous.
1336
1337 =back
1338
1339 Notice how the return value from the C<new> constructor is used as
1340 a filehandle in the C<while> loop?  That's what's called an I<indirect
1341 filehandle>, a scalar variable containing a filehandle.  You can use
1342 it the same way you would a normal filehandle.  For example, you
1343 can read one line from it this way:
1344
1345     $line = <$handle>;
1346
1347 all remaining lines from is this way:
1348
1349     @lines = <$handle>;
1350
1351 and send a line of data to it this way:
1352
1353     print $handle "some data\n";
1354
1355 =head2 A Webget Client
1356
1357 Here's a simple client that takes a remote host to fetch a document
1358 from, and then a list of files to get from that host.  This is a
1359 more interesting client than the previous one because it first sends
1360 something to the server before fetching the server's response.
1361
1362     #!/usr/bin/perl -w
1363     use IO::Socket;
1364     unless (@ARGV > 1) { die "usage: $0 host url ..." }
1365     $host = shift(@ARGV);
1366     $EOL = "\015\012";
1367     $BLANK = $EOL x 2;
1368     for my $document (@ARGV) {
1369         $remote = IO::Socket::INET->new( Proto     => "tcp",
1370                                          PeerAddr  => $host,
1371                                          PeerPort  => "http(80)",
1372                   )     || die "cannot connect to httpd on $host";
1373         $remote->autoflush(1);
1374         print $remote "GET $document HTTP/1.0" . $BLANK;
1375         while ( <$remote> ) { print }
1376         close $remote;
1377     }
1378
1379 The web server handling the HTTP service is assumed to be at
1380 its standard port, number 80.  If the server you're trying to
1381 connect to is at a different port, like 1080 or 8080, you should specify it
1382 as the named-parameter pair, C<< PeerPort => 8080 >>.  The C<autoflush>
1383 method is used on the socket because otherwise the system would buffer
1384 up the output we sent it.  (If you're on a prehistoric Mac, you'll also
1385 need to change every C<"\n"> in your code that sends data over the network
1386 to be a C<"\015\012"> instead.)
1387
1388 Connecting to the server is only the first part of the process: once you
1389 have the connection, you have to use the server's language.  Each server
1390 on the network has its own little command language that it expects as
1391 input.  The string that we send to the server starting with "GET" is in
1392 HTTP syntax.  In this case, we simply request each specified document.
1393 Yes, we really are making a new connection for each document, even though
1394 it's the same host.  That's the way you always used to have to speak HTTP.
1395 Recent versions of web browsers may request that the remote server leave
1396 the connection open a little while, but the server doesn't have to honor
1397 such a request.
1398
1399 Here's an example of running that program, which we'll call I<webget>:
1400
1401     % webget www.perl.com /guanaco.html
1402     HTTP/1.1 404 File Not Found
1403     Date: Thu, 08 May 1997 18:02:32 GMT
1404     Server: Apache/1.2b6
1405     Connection: close
1406     Content-type: text/html
1407
1408     <HEAD><TITLE>404 File Not Found</TITLE></HEAD>
1409     <BODY><H1>File Not Found</H1>
1410     The requested URL /guanaco.html was not found on this server.<P>
1411     </BODY>
1412
1413 Ok, so that's not very interesting, because it didn't find that
1414 particular document.  But a long response wouldn't have fit on this page.
1415
1416 For a more featureful version of this program, you should look to
1417 the I<lwp-request> program included with the LWP modules from CPAN.
1418
1419 =head2 Interactive Client with IO::Socket
1420
1421 Well, that's all fine if you want to send one command and get one answer,
1422 but what about setting up something fully interactive, somewhat like
1423 the way I<telnet> works?  That way you can type a line, get the answer,
1424 type a line, get the answer, etc.
1425
1426 This client is more complicated than the two we've done so far, but if
1427 you're on a system that supports the powerful C<fork> call, the solution
1428 isn't that rough.  Once you've made the connection to whatever service
1429 you'd like to chat with, call C<fork> to clone your process.  Each of
1430 these two identical process has a very simple job to do: the parent
1431 copies everything from the socket to standard output, while the child
1432 simultaneously copies everything from standard input to the socket.
1433 To accomplish the same thing using just one process would be I<much>
1434 harder, because it's easier to code two processes to do one thing than it
1435 is to code one process to do two things.  (This keep-it-simple principle
1436 a cornerstones of the Unix philosophy, and good software engineering as
1437 well, which is probably why it's spread to other systems.)
1438
1439 Here's the code:
1440
1441     #!/usr/bin/perl -w
1442     use strict;
1443     use IO::Socket;
1444     my ($host, $port, $kidpid, $handle, $line);
1445
1446     unless (@ARGV == 2) { die "usage: $0 host port" }
1447     ($host, $port) = @ARGV;
1448
1449     # create a tcp connection to the specified host and port
1450     $handle = IO::Socket::INET->new(Proto     => "tcp",
1451                                     PeerAddr  => $host,
1452                                     PeerPort  => $port)
1453                || die "can't connect to port $port on $host: $!";
1454
1455     $handle->autoflush(1);       # so output gets there right away
1456     print STDERR "[Connected to $host:$port]\n";
1457
1458     # split the program into two processes, identical twins
1459     die "can't fork: $!" unless defined($kidpid = fork());
1460
1461     # the if{} block runs only in the parent process
1462     if ($kidpid) {
1463         # copy the socket to standard output
1464         while (defined ($line = <$handle>)) {
1465             print STDOUT $line;
1466         }
1467         kill("TERM", $kidpid);   # send SIGTERM to child
1468     }
1469     # the else{} block runs only in the child process
1470     else {
1471         # copy standard input to the socket
1472         while (defined ($line = <STDIN>)) {
1473             print $handle $line;
1474         }
1475         exit(0);                # just in case
1476     }
1477
1478 The C<kill> function in the parent's C<if> block is there to send a
1479 signal to our child process, currently running in the C<else> block,
1480 as soon as the remote server has closed its end of the connection.
1481
1482 If the remote server sends data a byte at time, and you need that
1483 data immediately without waiting for a newline (which might not happen),
1484 you may wish to replace the C<while> loop in the parent with the
1485 following:
1486
1487     my $byte;
1488     while (sysread($handle, $byte, 1) == 1) {
1489         print STDOUT $byte;
1490     }
1491
1492 Making a system call for each byte you want to read is not very efficient
1493 (to put it mildly) but is the simplest to explain and works reasonably
1494 well.
1495
1496 =head1 TCP Servers with IO::Socket
1497
1498 As always, setting up a server is little bit more involved than running a client.
1499 The model is that the server creates a special kind of socket that
1500 does nothing but listen on a particular port for incoming connections.
1501 It does this by calling the C<< IO::Socket::INET->new() >> method with
1502 slightly different arguments than the client did.
1503
1504 =over 4
1505
1506 =item Proto
1507
1508 This is which protocol to use.  Like our clients, we'll
1509 still specify C<"tcp"> here.
1510
1511 =item LocalPort
1512
1513 We specify a local
1514 port in the C<LocalPort> argument, which we didn't do for the client.
1515 This is service name or port number for which you want to be the
1516 server. (Under Unix, ports under 1024 are restricted to the
1517 superuser.)  In our sample, we'll use port 9000, but you can use
1518 any port that's not currently in use on your system.  If you try
1519 to use one already in used, you'll get an "Address already in use"
1520 message.  Under Unix, the C<netstat -a> command will show
1521 which services current have servers.
1522
1523 =item Listen
1524
1525 The C<Listen> parameter is set to the maximum number of
1526 pending connections we can accept until we turn away incoming clients.
1527 Think of it as a call-waiting queue for your telephone.
1528 The low-level Socket module has a special symbol for the system maximum, which
1529 is SOMAXCONN.
1530
1531 =item Reuse
1532
1533 The C<Reuse> parameter is needed so that we restart our server
1534 manually without waiting a few minutes to allow system buffers to
1535 clear out.
1536
1537 =back
1538
1539 Once the generic server socket has been created using the parameters
1540 listed above, the server then waits for a new client to connect
1541 to it.  The server blocks in the C<accept> method, which eventually accepts a
1542 bidirectional connection from the remote client.  (Make sure to autoflush
1543 this handle to circumvent buffering.)
1544
1545 To add to user-friendliness, our server prompts the user for commands.
1546 Most servers don't do this.  Because of the prompt without a newline,
1547 you'll have to use the C<sysread> variant of the interactive client above.
1548
1549 This server accepts one of five different commands, sending output back to
1550 the client.  Unlike most network servers, this one handles only one
1551 incoming client at a time.  Multithreaded servers are covered in 
1552 Chapter 16 of the Camel.
1553
1554 Here's the code.  We'll
1555
1556  #!/usr/bin/perl -w
1557  use IO::Socket;
1558  use Net::hostent;      # for OOish version of gethostbyaddr
1559
1560  $PORT = 9000;          # pick something not in use
1561
1562  $server = IO::Socket::INET->new( Proto     => "tcp",
1563                                   LocalPort => $PORT,
1564                                   Listen    => SOMAXCONN,
1565                                   Reuse     => 1);
1566
1567  die "can't setup server" unless $server;
1568  print "[Server $0 accepting clients]\n";
1569
1570  while ($client = $server->accept()) {
1571    $client->autoflush(1);
1572    print $client "Welcome to $0; type help for command list.\n";
1573    $hostinfo = gethostbyaddr($client->peeraddr);
1574    printf "[Connect from %s]\n", $hostinfo ? $hostinfo->name : $client->peerhost;
1575    print $client "Command? ";
1576    while ( <$client>) {
1577      next unless /\S/;       # blank line
1578      if    (/quit|exit/i)    { last                                      }
1579      elsif (/date|time/i)    { printf $client "%s\n", scalar localtime() }
1580      elsif (/who/i )         { print  $client `who 2>&1`                 }
1581      elsif (/cookie/i )      { print  $client `/usr/games/fortune 2>&1`  }
1582      elsif (/motd/i )        { print  $client `cat /etc/motd 2>&1`       }
1583      else {
1584        print $client "Commands: quit date who cookie motd\n";
1585      }
1586    } continue {
1587       print $client "Command? ";
1588    }
1589    close $client;
1590  }
1591
1592 =head1 UDP: Message Passing
1593
1594 Another kind of client-server setup is one that uses not connections, but
1595 messages.  UDP communications involve much lower overhead but also provide
1596 less reliability, as there are no promises that messages will arrive at
1597 all, let alone in order and unmangled.  Still, UDP offers some advantages
1598 over TCP, including being able to "broadcast" or "multicast" to a whole
1599 bunch of destination hosts at once (usually on your local subnet).  If you
1600 find yourself overly concerned about reliability and start building checks
1601 into your message system, then you probably should use just TCP to start
1602 with.
1603
1604 UDP datagrams are I<not> a bytestream and should not be treated as such.
1605 This makes using I/O mechanisms with internal buffering like stdio (i.e.
1606 print() and friends) especially cumbersome. Use syswrite(), or better
1607 send(), like in the example below.
1608
1609 Here's a UDP program similar to the sample Internet TCP client given
1610 earlier.  However, instead of checking one host at a time, the UDP version
1611 will check many of them asynchronously by simulating a multicast and then
1612 using select() to do a timed-out wait for I/O.  To do something similar
1613 with TCP, you'd have to use a different socket handle for each host.
1614
1615     #!/usr/bin/perl -w
1616     use strict;
1617     use Socket;
1618     use Sys::Hostname;
1619
1620     my ( $count, $hisiaddr, $hispaddr, $histime,
1621          $host, $iaddr, $paddr, $port, $proto,
1622          $rin, $rout, $rtime, $SECS_OF_70_YEARS);
1623
1624     $SECS_OF_70_YEARS = 2_208_988_800;
1625
1626     $iaddr = gethostbyname(hostname());
1627     $proto = getprotobyname("udp");
1628     $port = getservbyname("time", "udp");
1629     $paddr = sockaddr_in(0, $iaddr); # 0 means let kernel pick
1630
1631     socket(SOCKET, PF_INET, SOCK_DGRAM, $proto)   || die "socket: $!";
1632     bind(SOCKET, $paddr)                          || die "bind: $!";
1633
1634     $| = 1;
1635     printf "%-12s %8s %s\n",  "localhost", 0, scalar localtime();
1636     $count = 0;
1637     for $host (@ARGV) {
1638         $count++;
1639         $hisiaddr = inet_aton($host)              || die "unknown host";
1640         $hispaddr = sockaddr_in($port, $hisiaddr);
1641         defined(send(SOCKET, 0, 0, $hispaddr))    || die "send $host: $!";
1642     }
1643
1644     $rin = "";
1645     vec($rin, fileno(SOCKET), 1) = 1;
1646
1647     # timeout after 10.0 seconds
1648     while ($count && select($rout = $rin, undef, undef, 10.0)) {
1649         $rtime = "";
1650         $hispaddr = recv(SOCKET, $rtime, 4, 0)    || die "recv: $!";
1651         ($port, $hisiaddr) = sockaddr_in($hispaddr);
1652         $host = gethostbyaddr($hisiaddr, AF_INET);
1653         $histime = unpack("N", $rtime) - $SECS_OF_70_YEARS;
1654         printf "%-12s ", $host;
1655         printf "%8d %s\n", $histime - time(), scalar localtime($histime);
1656         $count--;
1657     }
1658
1659 This example does not include any retries and may consequently fail to
1660 contact a reachable host. The most prominent reason for this is congestion
1661 of the queues on the sending host if the number of hosts to contact is
1662 sufficiently large.
1663
1664 =head1 SysV IPC
1665
1666 While System V IPC isn't so widely used as sockets, it still has some
1667 interesting uses.  However, you cannot use SysV IPC or Berkeley mmap() to
1668 have a variable shared amongst several processes.  That's because Perl
1669 would reallocate your string when you weren't wanting it to.  You might
1670 look into the C<IPC::Shareable> or C<threads::shared> modules for that.
1671
1672 Here's a small example showing shared memory usage.
1673
1674     use IPC::SysV qw(IPC_PRIVATE IPC_RMID S_IRUSR S_IWUSR);
1675
1676     $size = 2000;
1677     $id = shmget(IPC_PRIVATE, $size, S_IRUSR | S_IWUSR);
1678     defined($id)                    || die "shmget: $!";
1679     print "shm key $id\n";
1680
1681     $message = "Message #1";
1682     shmwrite($id, $message, 0, 60)  || die "shmwrite: $!";
1683     print "wrote: '$message'\n";
1684     shmread($id, $buff, 0, 60)      || die "shmread: $!";
1685     print "read : '$buff'\n";
1686
1687     # the buffer of shmread is zero-character end-padded.
1688     substr($buff, index($buff, "\0")) = "";
1689     print "un" unless $buff eq $message;
1690     print "swell\n";
1691
1692     print "deleting shm $id\n";
1693     shmctl($id, IPC_RMID, 0)        || die "shmctl: $!";
1694
1695 Here's an example of a semaphore:
1696
1697     use IPC::SysV qw(IPC_CREAT);
1698
1699     $IPC_KEY = 1234;
1700     $id = semget($IPC_KEY, 10, 0666 | IPC_CREAT);
1701     defined($id)                    || die "semget: $!";
1702     print "sem id $id\n";
1703
1704 Put this code in a separate file to be run in more than one process.
1705 Call the file F<take>:
1706
1707     # create a semaphore
1708
1709     $IPC_KEY = 1234;
1710     $id = semget($IPC_KEY, 0, 0);
1711     defined($id)                    || die "semget: $!";
1712
1713     $semnum  = 0;
1714     $semflag = 0;
1715
1716     # "take" semaphore
1717     # wait for semaphore to be zero
1718     $semop = 0;
1719     $opstring1 = pack("s!s!s!", $semnum, $semop, $semflag);
1720
1721     # Increment the semaphore count
1722     $semop = 1;
1723     $opstring2 = pack("s!s!s!", $semnum, $semop,  $semflag);
1724     $opstring  = $opstring1 . $opstring2;
1725
1726     semop($id, $opstring)   || die "semop: $!";
1727
1728 Put this code in a separate file to be run in more than one process.
1729 Call this file F<give>:
1730
1731     # "give" the semaphore
1732     # run this in the original process and you will see
1733     # that the second process continues
1734
1735     $IPC_KEY = 1234;
1736     $id = semget($IPC_KEY, 0, 0);
1737     die unless defined($id);
1738
1739     $semnum  = 0;
1740     $semflag = 0;
1741
1742     # Decrement the semaphore count
1743     $semop = -1;
1744     $opstring = pack("s!s!s!", $semnum, $semop, $semflag);
1745
1746     semop($id, $opstring)   || die "semop: $!";
1747
1748 The SysV IPC code above was written long ago, and it's definitely
1749 clunky looking.  For a more modern look, see the IPC::SysV module.
1750
1751 A small example demonstrating SysV message queues:
1752
1753     use IPC::SysV qw(IPC_PRIVATE IPC_RMID IPC_CREAT S_IRUSR S_IWUSR);
1754
1755     my $id = msgget(IPC_PRIVATE, IPC_CREAT | S_IRUSR | S_IWUSR);
1756     defined($id)                || die "msgget failed: $!";
1757
1758     my $sent      = "message";
1759     my $type_sent = 1234;
1760
1761     msgsnd($id, pack("l! a*", $type_sent, $sent), 0)
1762                                 || die "msgsnd failed: $!";
1763
1764     msgrcv($id, my $rcvd_buf, 60, 0, 0)
1765                                 || die "msgrcv failed: $!";
1766
1767     my($type_rcvd, $rcvd) = unpack("l! a*", $rcvd_buf);
1768
1769     if ($rcvd eq $sent) {
1770         print "okay\n";
1771     } else {
1772         print "not okay\n";
1773     }
1774
1775     msgctl($id, IPC_RMID, 0)    || die "msgctl failed: $!\n";
1776
1777 =head1 NOTES
1778
1779 Most of these routines quietly but politely return C<undef> when they
1780 fail instead of causing your program to die right then and there due to
1781 an uncaught exception.  (Actually, some of the new I<Socket> conversion
1782 functions do croak() on bad arguments.)  It is therefore essential to
1783 check return values from these functions.  Always begin your socket
1784 programs this way for optimal success, and don't forget to add the B<-T>
1785 taint-checking flag to the C<#!> line for servers:
1786
1787     #!/usr/bin/perl -Tw
1788     use strict;
1789     use sigtrap;
1790     use Socket;
1791
1792 =head1 BUGS
1793
1794 These routines all create system-specific portability problems.  As noted
1795 elsewhere, Perl is at the mercy of your C libraries for much of its system
1796 behavior.  It's probably safest to assume broken SysV semantics for
1797 signals and to stick with simple TCP and UDP socket operations; e.g., don't
1798 try to pass open file descriptors over a local UDP datagram socket if you
1799 want your code to stand a chance of being portable.
1800
1801 =head1 AUTHOR
1802
1803 Tom Christiansen, with occasional vestiges of Larry Wall's original
1804 version and suggestions from the Perl Porters.
1805
1806 =head1 SEE ALSO
1807
1808 There's a lot more to networking than this, but this should get you
1809 started.
1810
1811 For intrepid programmers, the indispensable textbook is I<Unix Network
1812 Programming, 2nd Edition, Volume 1> by W. Richard Stevens (published by
1813 Prentice-Hall).  Most books on networking address the subject from the
1814 perspective of a C programmer; translation to Perl is left as an exercise
1815 for the reader.
1816
1817 The IO::Socket(3) manpage describes the object library, and the Socket(3)
1818 manpage describes the low-level interface to sockets.  Besides the obvious
1819 functions in L<perlfunc>, you should also check out the F<modules> file at
1820 your nearest CPAN site, especially
1821 L<http://www.cpan.org/modules/00modlist.long.html#ID5_Networking_>.  
1822 See L<perlmodlib> or best yet, the F<Perl FAQ> for a description
1823 of what CPAN is and where to get it if the previous link doesn't work 
1824 for you.
1825
1826 Section 5 of CPAN's F<modules> file is devoted to "Networking, Device
1827 Control (modems), and Interprocess Communication", and contains numerous
1828 unbundled modules numerous networking modules, Chat and Expect operations,
1829 CGI programming, DCE, FTP, IPC, NNTP, Proxy, Ptty, RPC, SNMP, SMTP, Telnet,
1830 Threads, and ToolTalk--to name just a few.