Devel-Peek/Peek.pm: update example outputs in pod
[perl.git] / ext / Devel-Peek / Peek.pm
1 # Devel::Peek - A data debugging tool for the XS programmer
2 # The documentation is after the __END__
3
4 package Devel::Peek;
5
6 $VERSION = '1.06';
7 $XS_VERSION = $VERSION;
8 $VERSION = eval $VERSION;
9
10 require Exporter;
11 require XSLoader;
12
13 @ISA = qw(Exporter);
14 @EXPORT = qw(Dump mstat DeadCode DumpArray DumpWithOP DumpProg
15              fill_mstats mstats_fillhash mstats2hash runops_debug debug_flags);
16 @EXPORT_OK = qw(SvREFCNT SvREFCNT_inc SvREFCNT_dec CvGV);
17 %EXPORT_TAGS = ('ALL' => [@EXPORT, @EXPORT_OK]);
18
19 XSLoader::load();
20
21 sub import {
22   my $c = shift;
23   my $ops_rx = qr/^:opd(=[stP]*)?\b/;
24   my @db = grep m/$ops_rx/, @_;
25   @_ = grep !m/$ops_rx/, @_;
26   if (@db) {
27     die "Too many :opd options" if @db > 1;
28     runops_debug(1);
29     my $flags = ($db[0] =~ m/$ops_rx/ and $1);
30     $flags = 'st' unless defined $flags;
31     my $f = 0;
32     $f |= 2  if $flags =~ /s/;
33     $f |= 8  if $flags =~ /t/;
34     $f |= 64 if $flags =~ /P/;
35     $^D |= $f if $f;
36   }
37   unshift @_, $c;
38   goto &Exporter::import;
39 }
40
41 sub DumpWithOP ($;$) {
42    local($Devel::Peek::dump_ops)=1;
43    my $depth = @_ > 1 ? $_[1] : 4 ;
44    Dump($_[0],$depth);
45 }
46
47 $D_flags = 'psltocPmfrxuLHXDSTR';
48
49 sub debug_flags (;$) {
50   my $out = "";
51   for my $i (0 .. length($D_flags)-1) {
52     $out .= substr $D_flags, $i, 1 if $^D & (1<<$i);
53   }
54   my $arg = shift;
55   my $num = $arg;
56   if (defined $arg and $arg =~ /\D/) {
57     die "unknown flags in debug_flags()" if $arg =~ /[^-$D_flags]/;
58     my ($on,$off) = split /-/, "$arg-";
59     $num = $^D;
60     $num |=  (1<<index($D_flags, $_)) for split //, $on;
61     $num &= ~(1<<index($D_flags, $_)) for split //, $off;
62   }
63   $^D = $num if defined $arg;
64   $out
65 }
66
67 1;
68 __END__
69
70 =head1 NAME
71
72 Devel::Peek - A data debugging tool for the XS programmer
73
74 =head1 SYNOPSIS
75
76         use Devel::Peek;
77         Dump( $a );
78         Dump( $a, 5 );
79         DumpArray( 5, $a, $b, ... );
80         mstat "Point 5";
81
82         use Devel::Peek ':opd=st';
83
84 =head1 DESCRIPTION
85
86 Devel::Peek contains functions which allows raw Perl datatypes to be
87 manipulated from a Perl script.  This is used by those who do XS programming
88 to check that the data they are sending from C to Perl looks as they think
89 it should look.  The trick, then, is to know what the raw datatype is
90 supposed to look like when it gets to Perl.  This document offers some tips
91 and hints to describe good and bad raw data.
92
93 It is very possible that this document will fall far short of being useful
94 to the casual reader.  The reader is expected to understand the material in
95 the first few sections of L<perlguts>.
96
97 Devel::Peek supplies a C<Dump()> function which can dump a raw Perl
98 datatype, and C<mstat("marker")> function to report on memory usage
99 (if perl is compiled with corresponding option).  The function
100 DeadCode() provides statistics on the data "frozen" into inactive
101 C<CV>.  Devel::Peek also supplies C<SvREFCNT()>, C<SvREFCNT_inc()>, and
102 C<SvREFCNT_dec()> which can query, increment, and decrement reference
103 counts on SVs.  This document will take a passive, and safe, approach
104 to data debugging and for that it will describe only the C<Dump()>
105 function.
106
107 Function C<DumpArray()> allows dumping of multiple values (useful when you
108 need to analyze returns of functions).
109
110 The global variable $Devel::Peek::pv_limit can be set to limit the
111 number of character printed in various string values.  Setting it to 0
112 means no limit.
113
114 If C<use Devel::Peek> directive has a C<:opd=FLAGS> argument,
115 this switches on debugging of opcode dispatch.  C<FLAGS> should be a
116 combination of C<s>, C<t>, and C<P> (see B<-D> flags in L<perlrun>).
117 C<:opd> is a shortcut for C<:opd=st>.
118
119 =head2 Runtime debugging
120
121 C<CvGV($cv)> return one of the globs associated to a subroutine reference $cv.
122
123 debug_flags() returns a string representation of C<$^D> (similar to
124 what is allowed for B<-D> flag).  When called with a numeric argument,
125 sets $^D to the corresponding value.  When called with an argument of
126 the form C<"flags-flags">, set on/off bits of C<$^D> corresponding to
127 letters before/after C<->.  (The returned value is for C<$^D> before
128 the modification.)
129
130 runops_debug() returns true if the current I<opcode dispatcher> is the
131 debugging one.  When called with an argument, switches to debugging or
132 non-debugging dispatcher depending on the argument (active for
133 newly-entered subs/etc only).  (The returned value is for the dispatcher before the modification.)
134
135 =head2 Memory footprint debugging
136
137 When perl is compiled with support for memory footprint debugging
138 (default with Perl's malloc()), Devel::Peek provides an access to this API.
139
140 Use mstat() function to emit a memory state statistic to the terminal.
141 For more information on the format of output of mstat() see
142 L<perldebguts/Using C<$ENV{PERL_DEBUG_MSTATS}>>.
143
144 Three additional functions allow access to this statistic from Perl.
145 First, use C<mstats_fillhash(%hash)> to get the information contained
146 in the output of mstat() into %hash. The field of this hash are
147
148   minbucket nbuckets sbrk_good sbrk_slack sbrked_remains sbrks start_slack
149   topbucket topbucket_ev topbucket_odd total total_chain total_sbrk totfree
150
151 Two additional fields C<free>, C<used> contain array references which
152 provide per-bucket count of free and used chunks.  Two other fields
153 C<mem_size>, C<available_size> contain array references which provide
154 the information about the allocated size and usable size of chunks in
155 each bucket.  Again, see L<perldebguts/Using C<$ENV{PERL_DEBUG_MSTATS}>>
156 for details.
157
158 Keep in mind that only the first several "odd-numbered" buckets are
159 used, so the information on size of the "odd-numbered" buckets which are
160 not used is probably meaningless.
161
162 The information in
163
164  mem_size available_size minbucket nbuckets
165
166 is the property of a particular build of perl, and does not depend on
167 the current process.  If you do not provide the optional argument to
168 the functions mstats_fillhash(), fill_mstats(), mstats2hash(), then
169 the information in fields C<mem_size>, C<available_size> is not
170 updated.
171
172 C<fill_mstats($buf)> is a much cheaper call (both speedwise and
173 memory-wise) which collects the statistic into $buf in
174 machine-readable form.  At a later moment you may need to call
175 C<mstats2hash($buf, %hash)> to use this information to fill %hash.
176
177 All three APIs C<fill_mstats($buf)>, C<mstats_fillhash(%hash)>, and
178 C<mstats2hash($buf, %hash)> are designed to allocate no memory if used
179 I<the second time> on the same $buf and/or %hash.
180
181 So, if you want to collect memory info in a cycle, you may call
182
183   $#buf = 999;
184   fill_mstats($_) for @buf;
185   mstats_fillhash(%report, 1);          # Static info too
186
187   foreach (@buf) {
188     # Do something...
189     fill_mstats $_;                     # Collect statistic
190   }
191   foreach (@buf) {
192     mstats2hash($_, %report);           # Preserve static info
193     # Do something with %report
194   }
195
196 =head1 EXAMPLES
197
198 The following examples don't attempt to show everything as that would be a
199 monumental task, and, frankly, we don't want this manpage to be an internals
200 document for Perl.  The examples do demonstrate some basics of the raw Perl
201 datatypes, and should suffice to get most determined people on their way.
202 There are no guidewires or safety nets, nor blazed trails, so be prepared to
203 travel alone from this point and on and, if at all possible, don't fall into
204 the quicksand (it's bad for business).
205
206 Oh, one final bit of advice: take L<perlguts> with you.  When you return we
207 expect to see it well-thumbed.
208
209 =head2 A simple scalar string
210
211 Let's begin by looking a simple scalar which is holding a string.
212
213         use Devel::Peek;
214         $a = 42; $a = "hello";
215         Dump $a;
216
217 The output:
218
219         SV = PVIV(0xbc288) at 0xbe9a8
220           REFCNT = 1
221           FLAGS = (POK,pPOK)
222           IV = 42
223           PV = 0xb2048 "hello"\0
224           CUR = 5
225           LEN = 8
226
227 This says C<$a> is an SV, a scalar.  The scalar type is a PVIV, which is
228 capable of holding an integer (IV) and/or a string (PV) value. The scalar's
229 head is allocated at address 0xbe9a8, while the body is at 0xbc288.
230 Its reference count is 1.  It has the C<POK> flag set, meaning its
231 current PV field is valid.  Because POK is set we look at the PV item
232 to see what is in the scalar.  The \0 at the end indicate that this
233 PV is properly NUL-terminated.
234 Note that the IV field still contains its old numeric value, but because
235 FLAGS doesn't have IOK set, we must ignore the IV item.
236 CUR indicates the number of characters in the PV.  LEN indicates the
237 number of bytes allocated for the PV (at least one more than CUR, because
238 LEN includes an extra byte for the end-of-string marker, then usually
239 rounded up to some efficient allocation unit).
240
241 =head2 A simple scalar number
242
243 If the scalar contains a number the raw SV will be leaner.
244
245         use Devel::Peek;
246         $a = 42;
247         Dump $a;
248
249 The output:
250
251         SV = IV(0xbc818) at 0xbe9a8
252           REFCNT = 1
253           FLAGS = (IOK,pIOK)
254           IV = 42
255
256 This says C<$a> is an SV, a scalar.  The scalar is an IV, a number.  Its
257 reference count is 1.  It has the C<IOK> flag set, meaning it is currently
258 being evaluated as a number.  Because IOK is set we look at the IV item to
259 see what is in the scalar.
260
261 =head2 A simple scalar with an extra reference
262
263 If the scalar from the previous example had an extra reference:
264
265         use Devel::Peek;
266         $a = 42;
267         $b = \$a;
268         Dump $a;
269
270 The output:
271
272         SV = IV(0xbe860) at 0xbe9a8
273           REFCNT = 2
274           FLAGS = (IOK,pIOK)
275           IV = 42
276
277 Notice that this example differs from the previous example only in its
278 reference count.  Compare this to the next example, where we dump C<$b>
279 instead of C<$a>.
280
281 =head2 A reference to a simple scalar
282
283 This shows what a reference looks like when it references a simple scalar.
284
285         use Devel::Peek;
286         $a = 42;
287         $b = \$a;
288         Dump $b;
289
290 The output:
291
292         SV = IV(0xf041c) at 0xbe9a0
293           REFCNT = 1
294           FLAGS = (ROK)
295           RV = 0xbab08
296           SV = IV(0xbe860) at 0xbe9a8
297             REFCNT = 2
298             FLAGS = (IOK,pIOK)
299             IV = 42
300
301 Starting from the top, this says C<$b> is an SV.  The scalar is an IV,
302 which is capable of holding an integer or reference value.
303 It has the C<ROK> flag set, meaning it is a reference (rather than an
304 integer or string).  Notice that Dump
305 follows the reference and shows us what C<$b> was referencing.  We see the
306 same C<$a> that we found in the previous example.
307
308 Note that the value of C<RV> coincides with the numbers we see when we
309 stringify $b. The addresses inside IV() are addresses of
310 C<X***> structures which hold the current state of an C<SV>. This
311 address may change during lifetime of an SV.
312
313 =head2 A reference to an array
314
315 This shows what a reference to an array looks like.
316
317         use Devel::Peek;
318         $a = [42];
319         Dump $a;
320
321 The output:
322
323         SV = IV(0xc85998) at 0xc859a8
324           REFCNT = 1
325           FLAGS = (ROK)
326           RV = 0xc70de8
327           SV = PVAV(0xc71e10) at 0xc70de8
328             REFCNT = 1
329             FLAGS = ()
330             ARRAY = 0xc7e820
331             FILL = 0
332             MAX = 0
333             ARYLEN = 0x0
334             FLAGS = (REAL)
335             Elt No. 0
336             SV = IV(0xc70f88) at 0xc70f98
337               REFCNT = 1
338               FLAGS = (IOK,pIOK)
339               IV = 42
340
341 This says C<$a> is a reference (ROK), which points to
342 another SV which is a PVAV, an array.  The array has one element,
343 element zero, which is another SV. The field C<FILL> above indicates
344 the last element in the array, similar to C<$#$a>.
345
346 If C<$a> pointed to an array of two elements then we would see the
347 following.
348
349         use Devel::Peek 'Dump';
350         $a = [42,24];
351         Dump $a;
352
353 The output:
354
355         SV = IV(0x158c998) at 0x158c9a8
356           REFCNT = 1
357           FLAGS = (ROK)
358           RV = 0x1577de8
359           SV = PVAV(0x1578e10) at 0x1577de8
360             REFCNT = 1
361             FLAGS = ()
362             ARRAY = 0x1585820
363             FILL = 1
364             MAX = 1
365             ARYLEN = 0x0
366             FLAGS = (REAL)
367             Elt No. 0
368             SV = IV(0x1577f88) at 0x1577f98
369               REFCNT = 1
370               FLAGS = (IOK,pIOK)
371               IV = 42
372             Elt No. 1
373             SV = IV(0x158be88) at 0x158be98
374               REFCNT = 1
375               FLAGS = (IOK,pIOK)
376               IV = 24
377
378 Note that C<Dump> will not report I<all> the elements in the array,
379 only several first (depending on how deep it already went into the
380 report tree).
381
382 =head2 A reference to a hash
383
384 The following shows the raw form of a reference to a hash.
385
386         use Devel::Peek;
387         $a = {hello=>42};
388         Dump $a;
389
390 The output:
391
392         SV = IV(0x8177858) at 0x816a618
393           REFCNT = 1
394           FLAGS = (ROK)
395           RV = 0x814fc10
396           SV = PVHV(0x8167768) at 0x814fc10
397             REFCNT = 1
398             FLAGS = (SHAREKEYS)
399             ARRAY = 0x816c5b8  (0:7, 1:1)
400             hash quality = 100.0%
401             KEYS = 1
402             FILL = 1
403             MAX = 7
404             RITER = -1
405             EITER = 0x0
406             Elt "hello" HASH = 0xc8fd181b
407             SV = IV(0x816c030) at 0x814fcf4
408               REFCNT = 1
409               FLAGS = (IOK,pIOK)
410               IV = 42
411
412 This shows C<$a> is a reference pointing to an SV.  That SV is a PVHV, a
413 hash. Fields RITER and EITER are used by C<L<each>>.
414
415 The "quality" of a hash is defined as the total number of comparisons needed
416 to access every element once, relative to the expected number needed for a
417 random hash. The value can go over 100%.
418
419 The total number of comparisons is equal to the sum of the squares of the
420 number of entries in each bucket.  For a random hash of C<<n>> keys into
421 C<<k>> buckets, the expected value is:
422
423                 n + n(n-1)/2k
424
425 =head2 Dumping a large array or hash
426
427 The C<Dump()> function, by default, dumps up to 4 elements from a
428 toplevel array or hash.  This number can be increased by supplying a
429 second argument to the function.
430
431         use Devel::Peek;
432         $a = [10,11,12,13,14];
433         Dump $a;
434
435 Notice that C<Dump()> prints only elements 10 through 13 in the above code.
436 The following code will print all of the elements.
437
438         use Devel::Peek 'Dump';
439         $a = [10,11,12,13,14];
440         Dump $a, 5;
441
442 =head2 A reference to an SV which holds a C pointer
443
444 This is what you really need to know as an XS programmer, of course.  When
445 an XSUB returns a pointer to a C structure that pointer is stored in an SV
446 and a reference to that SV is placed on the XSUB stack.  So the output from
447 an XSUB which uses something like the T_PTROBJ map might look something like
448 this:
449
450         SV = IV(0xf381c) at 0xc859a8
451           REFCNT = 1
452           FLAGS = (ROK)
453           RV = 0xb8ad8
454           SV = PVMG(0xbb3c8) at 0xc859a0
455             REFCNT = 1
456             FLAGS = (OBJECT,IOK,pIOK)
457             IV = 729160
458             NV = 0
459             PV = 0
460             STASH = 0xc1d10       "CookBookB::Opaque"
461
462 This shows that we have an SV which is a reference, which points at another
463 SV.  In this case that second SV is a PVMG, a blessed scalar.  Because it is
464 blessed it has the C<OBJECT> flag set.  Note that an SV which holds a C
465 pointer also has the C<IOK> flag set.  The C<STASH> is set to the package
466 name which this SV was blessed into.
467
468 The output from an XSUB which uses something like the T_PTRREF map, which
469 doesn't bless the object, might look something like this:
470
471         SV = IV(0xf381c) at 0xc859a8
472           REFCNT = 1
473           FLAGS = (ROK)
474           RV = 0xb8ad8
475           SV = PVMG(0xbb3c8) at 0xc859a0
476             REFCNT = 1
477             FLAGS = (IOK,pIOK)
478             IV = 729160
479             NV = 0
480             PV = 0
481
482 =head2 A reference to a subroutine
483
484 Looks like this:
485
486         SV = IV(0x24d2dd8) at 0x24d2de8
487           REFCNT = 1
488           FLAGS = (TEMP,ROK)
489           RV = 0x24e79d8
490           SV = PVCV(0x24e5798) at 0x24e79d8
491             REFCNT = 2
492             FLAGS = ()
493             COMP_STASH = 0x22c9c50      "main"
494             START = 0x22eed60 ===> 0
495             ROOT = 0x22ee490
496             GVGV::GV = 0x22de9d8        "MY" :: "top_targets"
497             FILE = "(eval 5)"
498             DEPTH = 0
499             FLAGS = 0x0
500             OUTSIDE_SEQ = 93
501             PADLIST = 0x22e9ed8
502             PADNAME = 0x22e9ec0(0x22eed00) PAD = 0x22e9ea8(0x22eecd0)
503             OUTSIDE = 0x22c9fb0 (MAIN)
504
505
506 This shows that 
507
508 =over 4
509
510 =item *
511
512 the subroutine is not an XSUB (since C<START> and C<ROOT> are
513 non-zero, and C<XSUB> is not listed, and is thus null);
514
515 =item *
516
517 that it was compiled in the package C<main>;
518
519 =item *
520
521 under the name C<MY::top_targets>; 
522
523 =item *
524
525 inside a 5th eval in the program;
526
527 =item *
528
529 it is not currently executed (see C<DEPTH>);
530
531 =item *
532
533 it has no prototype (C<PROTOTYPE> field is missing).
534
535 =back
536
537 =head1 EXPORTS
538
539 C<Dump>, C<mstat>, C<DeadCode>, C<DumpArray>, C<DumpWithOP> and
540 C<DumpProg>, C<fill_mstats>, C<mstats_fillhash>, C<mstats2hash> by
541 default. Additionally available C<SvREFCNT>, C<SvREFCNT_inc> and
542 C<SvREFCNT_dec>.
543
544 =head1 BUGS
545
546 Readers have been known to skip important parts of L<perlguts>, causing much
547 frustration for all.
548
549 =head1 AUTHOR
550
551 Ilya Zakharevich        ilya@math.ohio-state.edu
552
553 Copyright (c) 1995-98 Ilya Zakharevich. All rights reserved.
554 This program is free software; you can redistribute it and/or
555 modify it under the same terms as Perl itself.
556
557 Author of this software makes no claim whatsoever about suitability,
558 reliability, edability, editability or usability of this product, and
559 should not be kept liable for any damage resulting from the use of
560 it. If you can use it, you are in luck, if not, I should not be kept
561 responsible. Keep a handy copy of your backup tape at hand.
562
563 =head1 SEE ALSO
564
565 L<perlguts>, and L<perlguts>, again.
566
567 =cut