Use two colons for lexsub warning
[perl.git] / pod / perlsub.pod
1 =head1 NAME
2 X<subroutine> X<function>
3
4 perlsub - Perl subroutines
5
6 =head1 SYNOPSIS
7
8 To declare subroutines:
9 X<subroutine, declaration> X<sub>
10
11     sub NAME;                     # A "forward" declaration.
12     sub NAME(PROTO);              #  ditto, but with prototypes
13     sub NAME : ATTRS;             #  with attributes
14     sub NAME(PROTO) : ATTRS;      #  with attributes and prototypes
15
16     sub NAME BLOCK                # A declaration and a definition.
17     sub NAME(PROTO) BLOCK         #  ditto, but with prototypes
18     sub NAME : ATTRS BLOCK        #  with attributes
19     sub NAME(PROTO) : ATTRS BLOCK #  with prototypes and attributes
20
21 To define an anonymous subroutine at runtime:
22 X<subroutine, anonymous>
23
24     $subref = sub BLOCK;                 # no proto
25     $subref = sub (PROTO) BLOCK;         # with proto
26     $subref = sub : ATTRS BLOCK;         # with attributes
27     $subref = sub (PROTO) : ATTRS BLOCK; # with proto and attributes
28
29 To import subroutines:
30 X<import>
31
32     use MODULE qw(NAME1 NAME2 NAME3);
33
34 To call subroutines:
35 X<subroutine, call> X<call>
36
37     NAME(LIST);    # & is optional with parentheses.
38     NAME LIST;     # Parentheses optional if predeclared/imported.
39     &NAME(LIST);   # Circumvent prototypes.
40     &NAME;         # Makes current @_ visible to called subroutine.
41
42 =head1 DESCRIPTION
43
44 Like many languages, Perl provides for user-defined subroutines.
45 These may be located anywhere in the main program, loaded in from
46 other files via the C<do>, C<require>, or C<use> keywords, or
47 generated on the fly using C<eval> or anonymous subroutines.
48 You can even call a function indirectly using a variable containing
49 its name or a CODE reference.
50
51 The Perl model for function call and return values is simple: all
52 functions are passed as parameters one single flat list of scalars, and
53 all functions likewise return to their caller one single flat list of
54 scalars.  Any arrays or hashes in these call and return lists will
55 collapse, losing their identities--but you may always use
56 pass-by-reference instead to avoid this.  Both call and return lists may
57 contain as many or as few scalar elements as you'd like.  (Often a
58 function without an explicit return statement is called a subroutine, but
59 there's really no difference from Perl's perspective.)
60 X<subroutine, parameter> X<parameter>
61
62 Any arguments passed in show up in the array C<@_>.  Therefore, if
63 you called a function with two arguments, those would be stored in
64 C<$_[0]> and C<$_[1]>.  The array C<@_> is a local array, but its
65 elements are aliases for the actual scalar parameters.  In particular,
66 if an element C<$_[0]> is updated, the corresponding argument is
67 updated (or an error occurs if it is not updatable).  If an argument
68 is an array or hash element which did not exist when the function
69 was called, that element is created only when (and if) it is modified
70 or a reference to it is taken.  (Some earlier versions of Perl
71 created the element whether or not the element was assigned to.)
72 Assigning to the whole array C<@_> removes that aliasing, and does
73 not update any arguments.
74 X<subroutine, argument> X<argument> X<@_>
75
76 A C<return> statement may be used to exit a subroutine, optionally
77 specifying the returned value, which will be evaluated in the
78 appropriate context (list, scalar, or void) depending on the context of
79 the subroutine call.  If you specify no return value, the subroutine
80 returns an empty list in list context, the undefined value in scalar
81 context, or nothing in void context.  If you return one or more
82 aggregates (arrays and hashes), these will be flattened together into
83 one large indistinguishable list.
84
85 If no C<return> is found and if the last statement is an expression, its
86 value is returned. If the last statement is a loop control structure
87 like a C<foreach> or a C<while>, the returned value is unspecified. The
88 empty sub returns the empty list.
89 X<subroutine, return value> X<return value> X<return>
90
91 Perl does not have named formal parameters.  In practice all you
92 do is assign to a C<my()> list of these.  Variables that aren't
93 declared to be private are global variables.  For gory details
94 on creating private variables, see L<"Private Variables via my()">
95 and L<"Temporary Values via local()">.  To create protected
96 environments for a set of functions in a separate package (and
97 probably a separate file), see L<perlmod/"Packages">.
98 X<formal parameter> X<parameter, formal>
99
100 Example:
101
102     sub max {
103         my $max = shift(@_);
104         foreach $foo (@_) {
105             $max = $foo if $max < $foo;
106         }
107         return $max;
108     }
109     $bestday = max($mon,$tue,$wed,$thu,$fri);
110
111 Example:
112
113     # get a line, combining continuation lines
114     #  that start with whitespace
115
116     sub get_line {
117         $thisline = $lookahead;  # global variables!
118         LINE: while (defined($lookahead = <STDIN>)) {
119             if ($lookahead =~ /^[ \t]/) {
120                 $thisline .= $lookahead;
121             }
122             else {
123                 last LINE;
124             }
125         }
126         return $thisline;
127     }
128
129     $lookahead = <STDIN>;       # get first line
130     while (defined($line = get_line())) {
131         ...
132     }
133
134 Assigning to a list of private variables to name your arguments:
135
136     sub maybeset {
137         my($key, $value) = @_;
138         $Foo{$key} = $value unless $Foo{$key};
139     }
140
141 Because the assignment copies the values, this also has the effect
142 of turning call-by-reference into call-by-value.  Otherwise a
143 function is free to do in-place modifications of C<@_> and change
144 its caller's values.
145 X<call-by-reference> X<call-by-value>
146
147     upcase_in($v1, $v2);  # this changes $v1 and $v2
148     sub upcase_in {
149         for (@_) { tr/a-z/A-Z/ }
150     }
151
152 You aren't allowed to modify constants in this way, of course.  If an
153 argument were actually literal and you tried to change it, you'd take a
154 (presumably fatal) exception.   For example, this won't work:
155 X<call-by-reference> X<call-by-value>
156
157     upcase_in("frederick");
158
159 It would be much safer if the C<upcase_in()> function
160 were written to return a copy of its parameters instead
161 of changing them in place:
162
163     ($v3, $v4) = upcase($v1, $v2);  # this doesn't change $v1 and $v2
164     sub upcase {
165         return unless defined wantarray;  # void context, do nothing
166         my @parms = @_;
167         for (@parms) { tr/a-z/A-Z/ }
168         return wantarray ? @parms : $parms[0];
169     }
170
171 Notice how this (unprototyped) function doesn't care whether it was
172 passed real scalars or arrays.  Perl sees all arguments as one big,
173 long, flat parameter list in C<@_>.  This is one area where
174 Perl's simple argument-passing style shines.  The C<upcase()>
175 function would work perfectly well without changing the C<upcase()>
176 definition even if we fed it things like this:
177
178     @newlist   = upcase(@list1, @list2);
179     @newlist   = upcase( split /:/, $var );
180
181 Do not, however, be tempted to do this:
182
183     (@a, @b)   = upcase(@list1, @list2);
184
185 Like the flattened incoming parameter list, the return list is also
186 flattened on return.  So all you have managed to do here is stored
187 everything in C<@a> and made C<@b> empty.  See 
188 L<Pass by Reference> for alternatives.
189
190 A subroutine may be called using an explicit C<&> prefix.  The
191 C<&> is optional in modern Perl, as are parentheses if the
192 subroutine has been predeclared.  The C<&> is I<not> optional
193 when just naming the subroutine, such as when it's used as
194 an argument to defined() or undef().  Nor is it optional when you
195 want to do an indirect subroutine call with a subroutine name or
196 reference using the C<&$subref()> or C<&{$subref}()> constructs,
197 although the C<< $subref->() >> notation solves that problem.
198 See L<perlref> for more about all that.
199 X<&>
200
201 Subroutines may be called recursively.  If a subroutine is called
202 using the C<&> form, the argument list is optional, and if omitted,
203 no C<@_> array is set up for the subroutine: the C<@_> array at the
204 time of the call is visible to subroutine instead.  This is an
205 efficiency mechanism that new users may wish to avoid.
206 X<recursion>
207
208     &foo(1,2,3);        # pass three arguments
209     foo(1,2,3);         # the same
210
211     foo();              # pass a null list
212     &foo();             # the same
213
214     &foo;               # foo() get current args, like foo(@_) !!
215     foo;                # like foo() IFF sub foo predeclared, else "foo"
216
217 Not only does the C<&> form make the argument list optional, it also
218 disables any prototype checking on arguments you do provide.  This
219 is partly for historical reasons, and partly for having a convenient way
220 to cheat if you know what you're doing.  See L</Prototypes> below.
221 X<&>
222
223 Since Perl 5.16.0, the C<__SUB__> token is available under C<use feature
224 'current_sub'> and C<use 5.16.0>.  It will evaluate to a reference to the
225 currently-running sub, which allows for recursive calls without knowing
226 your subroutine's name.
227
228     use 5.16.0;
229     my $factorial = sub {
230       my ($x) = @_;
231       return 1 if $x == 1;
232       return($x * __SUB__->( $x - 1 ) );
233     };
234
235 Subroutines whose names are in all upper case are reserved to the Perl
236 core, as are modules whose names are in all lower case.  A subroutine in
237 all capitals is a loosely-held convention meaning it will be called
238 indirectly by the run-time system itself, usually due to a triggered event.
239 Subroutines that do special, pre-defined things include C<AUTOLOAD>, C<CLONE>,
240 C<DESTROY> plus all functions mentioned in L<perltie> and L<PerlIO::via>.
241
242 The C<BEGIN>, C<UNITCHECK>, C<CHECK>, C<INIT> and C<END> subroutines
243 are not so much subroutines as named special code blocks, of which you
244 can have more than one in a package, and which you can B<not> call
245 explicitly.  See L<perlmod/"BEGIN, UNITCHECK, CHECK, INIT and END">
246
247 =head2 Private Variables via my()
248 X<my> X<variable, lexical> X<lexical> X<lexical variable> X<scope, lexical>
249 X<lexical scope> X<attributes, my>
250
251 Synopsis:
252
253     my $foo;            # declare $foo lexically local
254     my (@wid, %get);    # declare list of variables local
255     my $foo = "flurp";  # declare $foo lexical, and init it
256     my @oof = @bar;     # declare @oof lexical, and init it
257     my $x : Foo = $y;   # similar, with an attribute applied
258
259 B<WARNING>: The use of attribute lists on C<my> declarations is still
260 evolving.  The current semantics and interface are subject to change.
261 See L<attributes> and L<Attribute::Handlers>.
262
263 The C<my> operator declares the listed variables to be lexically
264 confined to the enclosing block, conditional (C<if/unless/elsif/else>),
265 loop (C<for/foreach/while/until/continue>), subroutine, C<eval>,
266 or C<do/require/use>'d file.  If more than one value is listed, the
267 list must be placed in parentheses.  All listed elements must be
268 legal lvalues.  Only alphanumeric identifiers may be lexically
269 scoped--magical built-ins like C<$/> must currently be C<local>ized
270 with C<local> instead.
271
272 Unlike dynamic variables created by the C<local> operator, lexical
273 variables declared with C<my> are totally hidden from the outside
274 world, including any called subroutines.  This is true if it's the
275 same subroutine called from itself or elsewhere--every call gets
276 its own copy.
277 X<local>
278
279 This doesn't mean that a C<my> variable declared in a statically
280 enclosing lexical scope would be invisible.  Only dynamic scopes
281 are cut off.   For example, the C<bumpx()> function below has access
282 to the lexical $x variable because both the C<my> and the C<sub>
283 occurred at the same scope, presumably file scope.
284
285     my $x = 10;
286     sub bumpx { $x++ } 
287
288 An C<eval()>, however, can see lexical variables of the scope it is
289 being evaluated in, so long as the names aren't hidden by declarations within
290 the C<eval()> itself.  See L<perlref>.
291 X<eval, scope of>
292
293 The parameter list to my() may be assigned to if desired, which allows you
294 to initialize your variables.  (If no initializer is given for a
295 particular variable, it is created with the undefined value.)  Commonly
296 this is used to name input parameters to a subroutine.  Examples:
297
298     $arg = "fred";        # "global" variable
299     $n = cube_root(27);
300     print "$arg thinks the root is $n\n";
301  fred thinks the root is 3
302
303     sub cube_root {
304         my $arg = shift;  # name doesn't matter
305         $arg **= 1/3;
306         return $arg;
307     }
308
309 The C<my> is simply a modifier on something you might assign to.  So when
310 you do assign to variables in its argument list, C<my> doesn't
311 change whether those variables are viewed as a scalar or an array.  So
312
313     my ($foo) = <STDIN>;                # WRONG?
314     my @FOO = <STDIN>;
315
316 both supply a list context to the right-hand side, while
317
318     my $foo = <STDIN>;
319
320 supplies a scalar context.  But the following declares only one variable:
321
322     my $foo, $bar = 1;                  # WRONG
323
324 That has the same effect as
325
326     my $foo;
327     $bar = 1;
328
329 The declared variable is not introduced (is not visible) until after
330 the current statement.  Thus,
331
332     my $x = $x;
333
334 can be used to initialize a new $x with the value of the old $x, and
335 the expression
336
337     my $x = 123 and $x == 123
338
339 is false unless the old $x happened to have the value C<123>.
340
341 Lexical scopes of control structures are not bounded precisely by the
342 braces that delimit their controlled blocks; control expressions are
343 part of that scope, too.  Thus in the loop
344
345     while (my $line = <>) {
346         $line = lc $line;
347     } continue {
348         print $line;
349     }
350
351 the scope of $line extends from its declaration throughout the rest of
352 the loop construct (including the C<continue> clause), but not beyond
353 it.  Similarly, in the conditional
354
355     if ((my $answer = <STDIN>) =~ /^yes$/i) {
356         user_agrees();
357     } elsif ($answer =~ /^no$/i) {
358         user_disagrees();
359     } else {
360         chomp $answer;
361         die "'$answer' is neither 'yes' nor 'no'";
362     }
363
364 the scope of $answer extends from its declaration through the rest
365 of that conditional, including any C<elsif> and C<else> clauses, 
366 but not beyond it.  See L<perlsyn/"Simple Statements"> for information
367 on the scope of variables in statements with modifiers.
368
369 The C<foreach> loop defaults to scoping its index variable dynamically
370 in the manner of C<local>.  However, if the index variable is
371 prefixed with the keyword C<my>, or if there is already a lexical
372 by that name in scope, then a new lexical is created instead.  Thus
373 in the loop
374 X<foreach> X<for>
375
376     for my $i (1, 2, 3) {
377         some_function();
378     }
379
380 the scope of $i extends to the end of the loop, but not beyond it,
381 rendering the value of $i inaccessible within C<some_function()>.
382 X<foreach> X<for>
383
384 Some users may wish to encourage the use of lexically scoped variables.
385 As an aid to catching implicit uses to package variables,
386 which are always global, if you say
387
388     use strict 'vars';
389
390 then any variable mentioned from there to the end of the enclosing
391 block must either refer to a lexical variable, be predeclared via
392 C<our> or C<use vars>, or else must be fully qualified with the package name.
393 A compilation error results otherwise.  An inner block may countermand
394 this with C<no strict 'vars'>.
395
396 A C<my> has both a compile-time and a run-time effect.  At compile
397 time, the compiler takes notice of it.  The principal usefulness
398 of this is to quiet C<use strict 'vars'>, but it is also essential
399 for generation of closures as detailed in L<perlref>.  Actual
400 initialization is delayed until run time, though, so it gets executed
401 at the appropriate time, such as each time through a loop, for
402 example.
403
404 Variables declared with C<my> are not part of any package and are therefore
405 never fully qualified with the package name.  In particular, you're not
406 allowed to try to make a package variable (or other global) lexical:
407
408     my $pack::var;      # ERROR!  Illegal syntax
409
410 In fact, a dynamic variable (also known as package or global variables)
411 are still accessible using the fully qualified C<::> notation even while a
412 lexical of the same name is also visible:
413
414     package main;
415     local $x = 10;
416     my    $x = 20;
417     print "$x and $::x\n";
418
419 That will print out C<20> and C<10>.
420
421 You may declare C<my> variables at the outermost scope of a file
422 to hide any such identifiers from the world outside that file.  This
423 is similar in spirit to C's static variables when they are used at
424 the file level.  To do this with a subroutine requires the use of
425 a closure (an anonymous function that accesses enclosing lexicals).
426 If you want to create a private subroutine that cannot be called
427 from outside that block, it can declare a lexical variable containing
428 an anonymous sub reference:
429
430     my $secret_version = '1.001-beta';
431     my $secret_sub = sub { print $secret_version };
432     &$secret_sub();
433
434 As long as the reference is never returned by any function within the
435 module, no outside module can see the subroutine, because its name is not in
436 any package's symbol table.  Remember that it's not I<REALLY> called
437 C<$some_pack::secret_version> or anything; it's just $secret_version,
438 unqualified and unqualifiable.
439
440 This does not work with object methods, however; all object methods
441 have to be in the symbol table of some package to be found.  See
442 L<perlref/"Function Templates"> for something of a work-around to
443 this.
444
445 =head2 Persistent Private Variables
446 X<state> X<state variable> X<static> X<variable, persistent> X<variable, static> X<closure>
447
448 There are two ways to build persistent private variables in Perl 5.10.
449 First, you can simply use the C<state> feature. Or, you can use closures,
450 if you want to stay compatible with releases older than 5.10.
451
452 =head3 Persistent variables via state()
453
454 Beginning with Perl 5.10.0, you can declare variables with the C<state>
455 keyword in place of C<my>.  For that to work, though, you must have
456 enabled that feature beforehand, either by using the C<feature> pragma, or
457 by using C<-E> on one-liners (see L<feature>).  Beginning with Perl 5.16,
458 the C<CORE::state> form does not require the
459 C<feature> pragma.
460
461 The C<state> keyword creates a lexical variable (following the same scoping
462 rules as C<my>) that persists from one subroutine call to the next.  If a
463 state variable resides inside an anonymous subroutine, then each copy of
464 the subroutine has its own copy of the state variable.  However, the value
465 of the state variable will still persist between calls to the same copy of
466 the anonymous subroutine.  (Don't forget that C<sub { ... }> creates a new
467 subroutine each time it is executed.)
468
469 For example, the following code maintains a private counter, incremented
470 each time the gimme_another() function is called:
471
472     use feature 'state';
473     sub gimme_another { state $x; return ++$x }
474
475 And this example uses anonymous subroutines to create separate counters:
476
477     use feature 'state';
478     sub create_counter {
479         return sub { state $x; return ++$x }
480     }
481
482 Also, since C<$x> is lexical, it can't be reached or modified by any Perl
483 code outside.
484
485 When combined with variable declaration, simple scalar assignment to C<state>
486 variables (as in C<state $x = 42>) is executed only the first time.  When such
487 statements are evaluated subsequent times, the assignment is ignored.  The
488 behavior of this sort of assignment to non-scalar variables is undefined.
489
490 =head3 Persistent variables with closures
491
492 Just because a lexical variable is lexically (also called statically)
493 scoped to its enclosing block, C<eval>, or C<do> FILE, this doesn't mean that
494 within a function it works like a C static.  It normally works more
495 like a C auto, but with implicit garbage collection.  
496
497 Unlike local variables in C or C++, Perl's lexical variables don't
498 necessarily get recycled just because their scope has exited.
499 If something more permanent is still aware of the lexical, it will
500 stick around.  So long as something else references a lexical, that
501 lexical won't be freed--which is as it should be.  You wouldn't want
502 memory being free until you were done using it, or kept around once you
503 were done.  Automatic garbage collection takes care of this for you.
504
505 This means that you can pass back or save away references to lexical
506 variables, whereas to return a pointer to a C auto is a grave error.
507 It also gives us a way to simulate C's function statics.  Here's a
508 mechanism for giving a function private variables with both lexical
509 scoping and a static lifetime.  If you do want to create something like
510 C's static variables, just enclose the whole function in an extra block,
511 and put the static variable outside the function but in the block.
512
513     {
514         my $secret_val = 0;
515         sub gimme_another {
516             return ++$secret_val;
517         }
518     }
519     # $secret_val now becomes unreachable by the outside
520     # world, but retains its value between calls to gimme_another
521
522 If this function is being sourced in from a separate file
523 via C<require> or C<use>, then this is probably just fine.  If it's
524 all in the main program, you'll need to arrange for the C<my>
525 to be executed early, either by putting the whole block above
526 your main program, or more likely, placing merely a C<BEGIN>
527 code block around it to make sure it gets executed before your program
528 starts to run:
529
530     BEGIN {
531         my $secret_val = 0;
532         sub gimme_another {
533             return ++$secret_val;
534         }
535     }
536
537 See L<perlmod/"BEGIN, UNITCHECK, CHECK, INIT and END"> about the
538 special triggered code blocks, C<BEGIN>, C<UNITCHECK>, C<CHECK>,
539 C<INIT> and C<END>.
540
541 If declared at the outermost scope (the file scope), then lexicals
542 work somewhat like C's file statics.  They are available to all
543 functions in that same file declared below them, but are inaccessible
544 from outside that file.  This strategy is sometimes used in modules
545 to create private variables that the whole module can see.
546
547 =head2 Temporary Values via local()
548 X<local> X<scope, dynamic> X<dynamic scope> X<variable, local>
549 X<variable, temporary>
550
551 B<WARNING>: In general, you should be using C<my> instead of C<local>, because
552 it's faster and safer.  Exceptions to this include the global punctuation
553 variables, global filehandles and formats, and direct manipulation of the
554 Perl symbol table itself.  C<local> is mostly used when the current value
555 of a variable must be visible to called subroutines.
556
557 Synopsis:
558
559     # localization of values
560
561     local $foo;                 # make $foo dynamically local
562     local (@wid, %get);         # make list of variables local
563     local $foo = "flurp";       # make $foo dynamic, and init it
564     local @oof = @bar;          # make @oof dynamic, and init it
565
566     local $hash{key} = "val";   # sets a local value for this hash entry
567     delete local $hash{key};    # delete this entry for the current block
568     local ($cond ? $v1 : $v2);  # several types of lvalues support
569                                 # localization
570
571     # localization of symbols
572
573     local *FH;                  # localize $FH, @FH, %FH, &FH  ...
574     local *merlyn = *randal;    # now $merlyn is really $randal, plus
575                                 #     @merlyn is really @randal, etc
576     local *merlyn = 'randal';   # SAME THING: promote 'randal' to *randal
577     local *merlyn = \$randal;   # just alias $merlyn, not @merlyn etc
578
579 A C<local> modifies its listed variables to be "local" to the
580 enclosing block, C<eval>, or C<do FILE>--and to I<any subroutine
581 called from within that block>.  A C<local> just gives temporary
582 values to global (meaning package) variables.  It does I<not> create
583 a local variable.  This is known as dynamic scoping.  Lexical scoping
584 is done with C<my>, which works more like C's auto declarations.
585
586 Some types of lvalues can be localized as well: hash and array elements
587 and slices, conditionals (provided that their result is always
588 localizable), and symbolic references.  As for simple variables, this
589 creates new, dynamically scoped values.
590
591 If more than one variable or expression is given to C<local>, they must be
592 placed in parentheses.  This operator works
593 by saving the current values of those variables in its argument list on a
594 hidden stack and restoring them upon exiting the block, subroutine, or
595 eval.  This means that called subroutines can also reference the local
596 variable, but not the global one.  The argument list may be assigned to if
597 desired, which allows you to initialize your local variables.  (If no
598 initializer is given for a particular variable, it is created with an
599 undefined value.)
600
601 Because C<local> is a run-time operator, it gets executed each time
602 through a loop.  Consequently, it's more efficient to localize your
603 variables outside the loop.
604
605 =head3 Grammatical note on local()
606 X<local, context>
607
608 A C<local> is simply a modifier on an lvalue expression.  When you assign to
609 a C<local>ized variable, the C<local> doesn't change whether its list is viewed
610 as a scalar or an array.  So
611
612     local($foo) = <STDIN>;
613     local @FOO = <STDIN>;
614
615 both supply a list context to the right-hand side, while
616
617     local $foo = <STDIN>;
618
619 supplies a scalar context.
620
621 =head3 Localization of special variables
622 X<local, special variable>
623
624 If you localize a special variable, you'll be giving a new value to it,
625 but its magic won't go away.  That means that all side-effects related
626 to this magic still work with the localized value.
627
628 This feature allows code like this to work :
629
630     # Read the whole contents of FILE in $slurp
631     { local $/ = undef; $slurp = <FILE>; }
632
633 Note, however, that this restricts localization of some values ; for
634 example, the following statement dies, as of perl 5.10.0, with an error
635 I<Modification of a read-only value attempted>, because the $1 variable is
636 magical and read-only :
637
638     local $1 = 2;
639
640 One exception is the default scalar variable: starting with perl 5.14
641 C<local($_)> will always strip all magic from $_, to make it possible
642 to safely reuse $_ in a subroutine.
643
644 B<WARNING>: Localization of tied arrays and hashes does not currently
645 work as described.
646 This will be fixed in a future release of Perl; in the meantime, avoid
647 code that relies on any particular behaviour of localising tied arrays
648 or hashes (localising individual elements is still okay).
649 See L<perl58delta/"Localising Tied Arrays and Hashes Is Broken"> for more
650 details.
651 X<local, tie>
652
653 =head3 Localization of globs
654 X<local, glob> X<glob>
655
656 The construct
657
658     local *name;
659
660 creates a whole new symbol table entry for the glob C<name> in the
661 current package.  That means that all variables in its glob slot ($name,
662 @name, %name, &name, and the C<name> filehandle) are dynamically reset.
663
664 This implies, among other things, that any magic eventually carried by
665 those variables is locally lost.  In other words, saying C<local */>
666 will not have any effect on the internal value of the input record
667 separator.
668
669 =head3 Localization of elements of composite types
670 X<local, composite type element> X<local, array element> X<local, hash element>
671
672 It's also worth taking a moment to explain what happens when you
673 C<local>ize a member of a composite type (i.e. an array or hash element).
674 In this case, the element is C<local>ized I<by name>. This means that
675 when the scope of the C<local()> ends, the saved value will be
676 restored to the hash element whose key was named in the C<local()>, or
677 the array element whose index was named in the C<local()>.  If that
678 element was deleted while the C<local()> was in effect (e.g. by a
679 C<delete()> from a hash or a C<shift()> of an array), it will spring
680 back into existence, possibly extending an array and filling in the
681 skipped elements with C<undef>.  For instance, if you say
682
683     %hash = ( 'This' => 'is', 'a' => 'test' );
684     @ary  = ( 0..5 );
685     {
686          local($ary[5]) = 6;
687          local($hash{'a'}) = 'drill';
688          while (my $e = pop(@ary)) {
689              print "$e . . .\n";
690              last unless $e > 3;
691          }
692          if (@ary) {
693              $hash{'only a'} = 'test';
694              delete $hash{'a'};
695          }
696     }
697     print join(' ', map { "$_ $hash{$_}" } sort keys %hash),".\n";
698     print "The array has ",scalar(@ary)," elements: ",
699           join(', ', map { defined $_ ? $_ : 'undef' } @ary),"\n";
700
701 Perl will print
702
703     6 . . .
704     4 . . .
705     3 . . .
706     This is a test only a test.
707     The array has 6 elements: 0, 1, 2, undef, undef, 5
708
709 The behavior of local() on non-existent members of composite
710 types is subject to change in future.
711
712 =head3 Localized deletion of elements of composite types
713 X<delete> X<local, composite type element> X<local, array element> X<local, hash element>
714
715 You can use the C<delete local $array[$idx]> and C<delete local $hash{key}>
716 constructs to delete a composite type entry for the current block and restore
717 it when it ends. They return the array/hash value before the localization,
718 which means that they are respectively equivalent to
719
720     do {
721         my $val = $array[$idx];
722         local  $array[$idx];
723         delete $array[$idx];
724         $val
725     }
726
727 and
728
729     do {
730         my $val = $hash{key};
731         local  $hash{key};
732         delete $hash{key};
733         $val
734     }
735
736 except that for those the C<local> is scoped to the C<do> block. Slices are
737 also accepted.
738
739     my %hash = (
740      a => [ 7, 8, 9 ],
741      b => 1,
742     )
743
744     {
745      my $a = delete local $hash{a};
746      # $a is [ 7, 8, 9 ]
747      # %hash is (b => 1)
748
749      {
750       my @nums = delete local @$a[0, 2]
751       # @nums is (7, 9)
752       # $a is [ undef, 8 ]
753
754       $a[0] = 999; # will be erased when the scope ends
755      }
756      # $a is back to [ 7, 8, 9 ]
757
758     }
759     # %hash is back to its original state
760
761 =head2 Lvalue subroutines
762 X<lvalue> X<subroutine, lvalue>
763
764 B<WARNING>: Lvalue subroutines are still experimental and the
765 implementation may change in future versions of Perl.
766
767 It is possible to return a modifiable value from a subroutine.
768 To do this, you have to declare the subroutine to return an lvalue.
769
770     my $val;
771     sub canmod : lvalue {
772         $val;  # or:  return $val;
773     }
774     sub nomod {
775         $val;
776     }
777
778     canmod() = 5;   # assigns to $val
779     nomod()  = 5;   # ERROR
780
781 The scalar/list context for the subroutine and for the right-hand
782 side of assignment is determined as if the subroutine call is replaced
783 by a scalar. For example, consider:
784
785     data(2,3) = get_data(3,4);
786
787 Both subroutines here are called in a scalar context, while in:
788
789     (data(2,3)) = get_data(3,4);
790
791 and in:
792
793     (data(2),data(3)) = get_data(3,4);
794
795 all the subroutines are called in a list context.
796
797 =over 4
798
799 =item Lvalue subroutines are EXPERIMENTAL
800
801 They appear to be convenient, but there is at least one reason to be
802 circumspect.
803
804 They violate encapsulation.  A normal mutator can check the supplied
805 argument before setting the attribute it is protecting, an lvalue
806 subroutine never gets that chance.  Consider;
807
808     my $some_array_ref = [];    # protected by mutators ??
809
810     sub set_arr {               # normal mutator
811         my $val = shift;
812         die("expected array, you supplied ", ref $val)
813            unless ref $val eq 'ARRAY';
814         $some_array_ref = $val;
815     }
816     sub set_arr_lv : lvalue {   # lvalue mutator
817         $some_array_ref;
818     }
819
820     # set_arr_lv cannot stop this !
821     set_arr_lv() = { a => 1 };
822
823 =back
824
825 =head2 Lexical Subroutines
826 X<my sub> X<state sub> X<our sub> X<subroutine, lexical>
827
828 B<WARNING>: Lexical subroutines are still experimental.  The feature may be
829 modified or removed in future versions of Perl.
830
831 Lexical subroutines are only available under the C<use feature
832 'lexical_subs'> pragma, which produces a warning unless the
833 "experimental::lexical_subs" warnings category is disabled.
834
835 Beginning with Perl 5.18, you can declare a private subroutine with C<my>
836 or C<state>.  As with state variables, the C<state> keyword is only
837 available under C<use feature 'state'> or C<use 5.010> or higher.
838
839 These subroutines are only visible within the block in which they are
840 declared, and only after that declaration:
841
842     no warnings "experimental::lexical_subs";
843     use feature 'lexical_subs';
844
845     foo();              # calls the package/global subroutine
846     state sub foo {
847         foo();          # also calls the package subroutine
848     }
849     foo();              # calls "state" sub
850     my $ref = \&foo;    # take a reference to "state" sub
851
852     my sub bar { ... }
853     bar();              # calls "my" sub
854
855 To use a lexical subroutine from inside the subroutine itself, you must
856 predeclare it.  The C<sub foo {...}> subroutine definition syntax respects
857 any previous C<my sub;> or C<state sub;> declaration.
858
859     my sub baz;         # predeclaration
860     sub baz {           # define the "my" sub
861         baz();          # recursive call
862     }
863
864 =head3 C<state sub> vs C<my sub>
865
866 What is the difference between "state" subs and "my" subs?  Each time that
867 execution enters a block when "my" subs are declared, a new copy of each
868 sub is created.  "State" subroutines persist from one execution of the
869 containing block to the next.
870
871 So, in general, "state" subroutines are faster.  But "my" subs are
872 necessary if you want to create closures:
873
874     no warnings "experimental::lexical_subs";
875     use feature 'lexical_subs';
876
877     sub whatever {
878         my $x = shift;
879         my sub inner {
880             ... do something with $x ...
881         }
882         inner();
883     }
884
885 In this example, a new C<$x> is created when C<whatever> is called, and
886 also a new C<inner>, which can see the new C<$x>.  A "state" sub will only
887 see the C<$x> from the first call to C<whatever>.
888
889 =head3 C<our> subroutines
890
891 Like C<our $variable>, C<our sub> creates a lexical alias to the package
892 subroutine of the same name.
893
894 The two main uses for this are to switch back to using the package sub
895 inside an inner scope:
896
897     no warnings "experimental::lexical_subs";
898     use feature 'lexical_subs';
899
900     sub foo { ... }
901
902     sub bar {
903         my sub foo { ... }
904         {
905             # need to use the outer foo here
906             our sub foo;
907             foo();
908         }
909     }
910
911 and to make a subroutine visible to other packages in the same scope:
912
913     package MySneakyModule;
914
915     no warnings "experimental::lexical_subs";
916     use feature 'lexical_subs';
917
918     our sub do_something { ... }
919
920     sub do_something_with_caller {
921         package DB;
922         () = caller 1;          # sets @DB::args
923         do_something(@args);    # uses MySneakyModule::do_something
924     }
925
926 =head2 Passing Symbol Table Entries (typeglobs)
927 X<typeglob> X<*>
928
929 B<WARNING>: The mechanism described in this section was originally
930 the only way to simulate pass-by-reference in older versions of
931 Perl.  While it still works fine in modern versions, the new reference
932 mechanism is generally easier to work with.  See below.
933
934 Sometimes you don't want to pass the value of an array to a subroutine
935 but rather the name of it, so that the subroutine can modify the global
936 copy of it rather than working with a local copy.  In perl you can
937 refer to all objects of a particular name by prefixing the name
938 with a star: C<*foo>.  This is often known as a "typeglob", because the
939 star on the front can be thought of as a wildcard match for all the
940 funny prefix characters on variables and subroutines and such.
941
942 When evaluated, the typeglob produces a scalar value that represents
943 all the objects of that name, including any filehandle, format, or
944 subroutine.  When assigned to, it causes the name mentioned to refer to
945 whatever C<*> value was assigned to it.  Example:
946
947     sub doubleary {
948         local(*someary) = @_;
949         foreach $elem (@someary) {
950             $elem *= 2;
951         }
952     }
953     doubleary(*foo);
954     doubleary(*bar);
955
956 Scalars are already passed by reference, so you can modify
957 scalar arguments without using this mechanism by referring explicitly
958 to C<$_[0]> etc.  You can modify all the elements of an array by passing
959 all the elements as scalars, but you have to use the C<*> mechanism (or
960 the equivalent reference mechanism) to C<push>, C<pop>, or change the size of
961 an array.  It will certainly be faster to pass the typeglob (or reference).
962
963 Even if you don't want to modify an array, this mechanism is useful for
964 passing multiple arrays in a single LIST, because normally the LIST
965 mechanism will merge all the array values so that you can't extract out
966 the individual arrays.  For more on typeglobs, see
967 L<perldata/"Typeglobs and Filehandles">.
968
969 =head2 When to Still Use local()
970 X<local> X<variable, local>
971
972 Despite the existence of C<my>, there are still three places where the
973 C<local> operator still shines.  In fact, in these three places, you
974 I<must> use C<local> instead of C<my>.
975
976 =over 4
977
978 =item 1.
979
980 You need to give a global variable a temporary value, especially $_.
981
982 The global variables, like C<@ARGV> or the punctuation variables, must be 
983 C<local>ized with C<local()>.  This block reads in F</etc/motd>, and splits
984 it up into chunks separated by lines of equal signs, which are placed
985 in C<@Fields>.
986
987     {
988         local @ARGV = ("/etc/motd");
989         local $/ = undef;
990         local $_ = <>;  
991         @Fields = split /^\s*=+\s*$/;
992     } 
993
994 It particular, it's important to C<local>ize $_ in any routine that assigns
995 to it.  Look out for implicit assignments in C<while> conditionals.
996
997 =item 2.
998
999 You need to create a local file or directory handle or a local function.
1000
1001 A function that needs a filehandle of its own must use
1002 C<local()> on a complete typeglob.   This can be used to create new symbol
1003 table entries:
1004
1005     sub ioqueue {
1006         local  (*READER, *WRITER);    # not my!
1007         pipe    (READER,  WRITER)     or die "pipe: $!";
1008         return (*READER, *WRITER);
1009     }
1010     ($head, $tail) = ioqueue();
1011
1012 See the Symbol module for a way to create anonymous symbol table
1013 entries.
1014
1015 Because assignment of a reference to a typeglob creates an alias, this
1016 can be used to create what is effectively a local function, or at least,
1017 a local alias.
1018
1019     {
1020         local *grow = \&shrink; # only until this block exits
1021         grow();                 # really calls shrink()
1022         move();                 # if move() grow()s, it shrink()s too
1023     }
1024     grow();                     # get the real grow() again
1025
1026 See L<perlref/"Function Templates"> for more about manipulating
1027 functions by name in this way.
1028
1029 =item 3.
1030
1031 You want to temporarily change just one element of an array or hash.
1032
1033 You can C<local>ize just one element of an aggregate.  Usually this
1034 is done on dynamics:
1035
1036     {
1037         local $SIG{INT} = 'IGNORE';
1038         funct();                            # uninterruptible
1039     } 
1040     # interruptibility automatically restored here
1041
1042 But it also works on lexically declared aggregates.
1043
1044 =back
1045
1046 =head2 Pass by Reference
1047 X<pass by reference> X<pass-by-reference> X<reference>
1048
1049 If you want to pass more than one array or hash into a function--or
1050 return them from it--and have them maintain their integrity, then
1051 you're going to have to use an explicit pass-by-reference.  Before you
1052 do that, you need to understand references as detailed in L<perlref>.
1053 This section may not make much sense to you otherwise.
1054
1055 Here are a few simple examples.  First, let's pass in several arrays
1056 to a function and have it C<pop> all of then, returning a new list
1057 of all their former last elements:
1058
1059     @tailings = popmany ( \@a, \@b, \@c, \@d );
1060
1061     sub popmany {
1062         my $aref;
1063         my @retlist = ();
1064         foreach $aref ( @_ ) {
1065             push @retlist, pop @$aref;
1066         }
1067         return @retlist;
1068     }
1069
1070 Here's how you might write a function that returns a
1071 list of keys occurring in all the hashes passed to it:
1072
1073     @common = inter( \%foo, \%bar, \%joe );
1074     sub inter {
1075         my ($k, $href, %seen); # locals
1076         foreach $href (@_) {
1077             while ( $k = each %$href ) {
1078                 $seen{$k}++;
1079             }
1080         }
1081         return grep { $seen{$_} == @_ } keys %seen;
1082     }
1083
1084 So far, we're using just the normal list return mechanism.
1085 What happens if you want to pass or return a hash?  Well,
1086 if you're using only one of them, or you don't mind them
1087 concatenating, then the normal calling convention is ok, although
1088 a little expensive.
1089
1090 Where people get into trouble is here:
1091
1092     (@a, @b) = func(@c, @d);
1093 or
1094     (%a, %b) = func(%c, %d);
1095
1096 That syntax simply won't work.  It sets just C<@a> or C<%a> and
1097 clears the C<@b> or C<%b>.  Plus the function didn't get passed
1098 into two separate arrays or hashes: it got one long list in C<@_>,
1099 as always.
1100
1101 If you can arrange for everyone to deal with this through references, it's
1102 cleaner code, although not so nice to look at.  Here's a function that
1103 takes two array references as arguments, returning the two array elements
1104 in order of how many elements they have in them:
1105
1106     ($aref, $bref) = func(\@c, \@d);
1107     print "@$aref has more than @$bref\n";
1108     sub func {
1109         my ($cref, $dref) = @_;
1110         if (@$cref > @$dref) {
1111             return ($cref, $dref);
1112         } else {
1113             return ($dref, $cref);
1114         }
1115     }
1116
1117 It turns out that you can actually do this also:
1118
1119     (*a, *b) = func(\@c, \@d);
1120     print "@a has more than @b\n";
1121     sub func {
1122         local (*c, *d) = @_;
1123         if (@c > @d) {
1124             return (\@c, \@d);
1125         } else {
1126             return (\@d, \@c);
1127         }
1128     }
1129
1130 Here we're using the typeglobs to do symbol table aliasing.  It's
1131 a tad subtle, though, and also won't work if you're using C<my>
1132 variables, because only globals (even in disguise as C<local>s)
1133 are in the symbol table.
1134
1135 If you're passing around filehandles, you could usually just use the bare
1136 typeglob, like C<*STDOUT>, but typeglobs references work, too.
1137 For example:
1138
1139     splutter(\*STDOUT);
1140     sub splutter {
1141         my $fh = shift;
1142         print $fh "her um well a hmmm\n";
1143     }
1144
1145     $rec = get_rec(\*STDIN);
1146     sub get_rec {
1147         my $fh = shift;
1148         return scalar <$fh>;
1149     }
1150
1151 If you're planning on generating new filehandles, you could do this.
1152 Notice to pass back just the bare *FH, not its reference.
1153
1154     sub openit {
1155         my $path = shift;
1156         local *FH;
1157         return open (FH, $path) ? *FH : undef;
1158     }
1159
1160 =head2 Prototypes
1161 X<prototype> X<subroutine, prototype>
1162
1163 Perl supports a very limited kind of compile-time argument checking
1164 using function prototyping.  If you declare
1165
1166     sub mypush (+@)
1167
1168 then C<mypush()> takes arguments exactly like C<push()> does.  The
1169 function declaration must be visible at compile time.  The prototype
1170 affects only interpretation of new-style calls to the function,
1171 where new-style is defined as not using the C<&> character.  In
1172 other words, if you call it like a built-in function, then it behaves
1173 like a built-in function.  If you call it like an old-fashioned
1174 subroutine, then it behaves like an old-fashioned subroutine.  It
1175 naturally falls out from this rule that prototypes have no influence
1176 on subroutine references like C<\&foo> or on indirect subroutine
1177 calls like C<&{$subref}> or C<< $subref->() >>.
1178
1179 Method calls are not influenced by prototypes either, because the
1180 function to be called is indeterminate at compile time, since
1181 the exact code called depends on inheritance.
1182
1183 Because the intent of this feature is primarily to let you define
1184 subroutines that work like built-in functions, here are prototypes
1185 for some other functions that parse almost exactly like the
1186 corresponding built-in.
1187
1188     Declared as                 Called as
1189
1190     sub mylink ($$)          mylink $old, $new
1191     sub myvec ($$$)          myvec $var, $offset, 1
1192     sub myindex ($$;$)       myindex &getstring, "substr"
1193     sub mysyswrite ($$$;$)   mysyswrite $buf, 0, length($buf) - $off, $off
1194     sub myreverse (@)        myreverse $a, $b, $c
1195     sub myjoin ($@)          myjoin ":", $a, $b, $c
1196     sub mypop (+)            mypop @array
1197     sub mysplice (+$$@)      mysplice @array, 0, 2, @pushme
1198     sub mykeys (+)           mykeys %{$hashref}
1199     sub myopen (*;$)         myopen HANDLE, $name
1200     sub mypipe (**)          mypipe READHANDLE, WRITEHANDLE
1201     sub mygrep (&@)          mygrep { /foo/ } $a, $b, $c
1202     sub myrand (;$)          myrand 42
1203     sub mytime ()            mytime
1204
1205 Any backslashed prototype character represents an actual argument
1206 that must start with that character (optionally preceded by C<my>,
1207 C<our> or C<local>), with the exception of C<$>, which will
1208 accept any scalar lvalue expression, such as C<$foo = 7> or
1209 C<< my_function()->[0] >>. The value passed as part of C<@_> will be a
1210 reference to the actual argument given in the subroutine call,
1211 obtained by applying C<\> to that argument.
1212
1213 You can use the C<\[]> backslash group notation to specify more than one
1214 allowed argument type. For example:
1215
1216     sub myref (\[$@%&*])
1217
1218 will allow calling myref() as
1219
1220     myref $var
1221     myref @array
1222     myref %hash
1223     myref &sub
1224     myref *glob
1225
1226 and the first argument of myref() will be a reference to
1227 a scalar, an array, a hash, a code, or a glob.
1228
1229 Unbackslashed prototype characters have special meanings.  Any
1230 unbackslashed C<@> or C<%> eats all remaining arguments, and forces
1231 list context.  An argument represented by C<$> forces scalar context.  An
1232 C<&> requires an anonymous subroutine, which, if passed as the first
1233 argument, does not require the C<sub> keyword or a subsequent comma.
1234
1235 A C<*> allows the subroutine to accept a bareword, constant, scalar expression,
1236 typeglob, or a reference to a typeglob in that slot.  The value will be
1237 available to the subroutine either as a simple scalar, or (in the latter
1238 two cases) as a reference to the typeglob.  If you wish to always convert
1239 such arguments to a typeglob reference, use Symbol::qualify_to_ref() as
1240 follows:
1241
1242     use Symbol 'qualify_to_ref';
1243
1244     sub foo (*) {
1245         my $fh = qualify_to_ref(shift, caller);
1246         ...
1247     }
1248
1249 The C<+> prototype is a special alternative to C<$> that will act like
1250 C<\[@%]> when given a literal array or hash variable, but will otherwise
1251 force scalar context on the argument.  This is useful for functions which
1252 should accept either a literal array or an array reference as the argument:
1253
1254     sub mypush (+@) {
1255         my $aref = shift;
1256         die "Not an array or arrayref" unless ref $aref eq 'ARRAY';
1257         push @$aref, @_;
1258     }
1259
1260 When using the C<+> prototype, your function must check that the argument
1261 is of an acceptable type.
1262
1263 A semicolon (C<;>) separates mandatory arguments from optional arguments.
1264 It is redundant before C<@> or C<%>, which gobble up everything else.
1265
1266 As the last character of a prototype, or just before a semicolon, a C<@>
1267 or a C<%>, you can use C<_> in place of C<$>: if this argument is not
1268 provided, C<$_> will be used instead.
1269
1270 Note how the last three examples in the table above are treated
1271 specially by the parser.  C<mygrep()> is parsed as a true list
1272 operator, C<myrand()> is parsed as a true unary operator with unary
1273 precedence the same as C<rand()>, and C<mytime()> is truly without
1274 arguments, just like C<time()>.  That is, if you say
1275
1276     mytime +2;
1277
1278 you'll get C<mytime() + 2>, not C<mytime(2)>, which is how it would be parsed
1279 without a prototype.  If you want to force a unary function to have the
1280 same precedence as a list operator, add C<;> to the end of the prototype:
1281
1282     sub mygetprotobynumber($;);
1283     mygetprotobynumber $a > $b; # parsed as mygetprotobynumber($a > $b)
1284
1285 The interesting thing about C<&> is that you can generate new syntax with it,
1286 provided it's in the initial position:
1287 X<&>
1288
1289     sub try (&@) {
1290         my($try,$catch) = @_;
1291         eval { &$try };
1292         if ($@) {
1293             local $_ = $@;
1294             &$catch;
1295         }
1296     }
1297     sub catch (&) { $_[0] }
1298
1299     try {
1300         die "phooey";
1301     } catch {
1302         /phooey/ and print "unphooey\n";
1303     };
1304
1305 That prints C<"unphooey">.  (Yes, there are still unresolved
1306 issues having to do with visibility of C<@_>.  I'm ignoring that
1307 question for the moment.  (But note that if we make C<@_> lexically
1308 scoped, those anonymous subroutines can act like closures... (Gee,
1309 is this sounding a little Lispish?  (Never mind.))))
1310
1311 And here's a reimplementation of the Perl C<grep> operator:
1312 X<grep>
1313
1314     sub mygrep (&@) {
1315         my $code = shift;
1316         my @result;
1317         foreach $_ (@_) {
1318             push(@result, $_) if &$code;
1319         }
1320         @result;
1321     }
1322
1323 Some folks would prefer full alphanumeric prototypes.  Alphanumerics have
1324 been intentionally left out of prototypes for the express purpose of
1325 someday in the future adding named, formal parameters.  The current
1326 mechanism's main goal is to let module writers provide better diagnostics
1327 for module users.  Larry feels the notation quite understandable to Perl
1328 programmers, and that it will not intrude greatly upon the meat of the
1329 module, nor make it harder to read.  The line noise is visually
1330 encapsulated into a small pill that's easy to swallow.
1331
1332 If you try to use an alphanumeric sequence in a prototype you will
1333 generate an optional warning - "Illegal character in prototype...".
1334 Unfortunately earlier versions of Perl allowed the prototype to be
1335 used as long as its prefix was a valid prototype.  The warning may be
1336 upgraded to a fatal error in a future version of Perl once the
1337 majority of offending code is fixed.
1338
1339 It's probably best to prototype new functions, not retrofit prototyping
1340 into older ones.  That's because you must be especially careful about
1341 silent impositions of differing list versus scalar contexts.  For example,
1342 if you decide that a function should take just one parameter, like this:
1343
1344     sub func ($) {
1345         my $n = shift;
1346         print "you gave me $n\n";
1347     }
1348
1349 and someone has been calling it with an array or expression
1350 returning a list:
1351
1352     func(@foo);
1353     func( split /:/ );
1354
1355 Then you've just supplied an automatic C<scalar> in front of their
1356 argument, which can be more than a bit surprising.  The old C<@foo>
1357 which used to hold one thing doesn't get passed in.  Instead,
1358 C<func()> now gets passed in a C<1>; that is, the number of elements
1359 in C<@foo>.  And the C<split> gets called in scalar context so it
1360 starts scribbling on your C<@_> parameter list.  Ouch!
1361
1362 This is all very powerful, of course, and should be used only in moderation
1363 to make the world a better place.
1364
1365 =head2 Constant Functions
1366 X<constant>
1367
1368 Functions with a prototype of C<()> are potential candidates for
1369 inlining.  If the result after optimization and constant folding
1370 is either a constant or a lexically-scoped scalar which has no other
1371 references, then it will be used in place of function calls made
1372 without C<&>.  Calls made using C<&> are never inlined.  (See
1373 F<constant.pm> for an easy way to declare most constants.)
1374
1375 The following functions would all be inlined:
1376
1377     sub pi ()           { 3.14159 }             # Not exact, but close.
1378     sub PI ()           { 4 * atan2 1, 1 }      # As good as it gets,
1379                                                 # and it's inlined, too!
1380     sub ST_DEV ()       { 0 }
1381     sub ST_INO ()       { 1 }
1382
1383     sub FLAG_FOO ()     { 1 << 8 }
1384     sub FLAG_BAR ()     { 1 << 9 }
1385     sub FLAG_MASK ()    { FLAG_FOO | FLAG_BAR }
1386
1387     sub OPT_BAZ ()      { not (0x1B58 & FLAG_MASK) }
1388
1389     sub N () { int(OPT_BAZ) / 3 }
1390
1391     sub FOO_SET () { 1 if FLAG_MASK & FLAG_FOO }
1392
1393 Be aware that these will not be inlined; as they contain inner scopes,
1394 the constant folding doesn't reduce them to a single constant:
1395
1396     sub foo_set () { if (FLAG_MASK & FLAG_FOO) { 1 } }
1397
1398     sub baz_val () {
1399         if (OPT_BAZ) {
1400             return 23;
1401         }
1402         else {
1403             return 42;
1404         }
1405     }
1406
1407 If you redefine a subroutine that was eligible for inlining, you'll get
1408 a warning by default.  (You can use this warning to tell whether or not a
1409 particular subroutine is considered constant.)  The warning is
1410 considered severe enough not to be affected by the B<-w>
1411 switch (or its absence) because previously compiled
1412 invocations of the function will still be using the old value of the
1413 function.  If you need to be able to redefine the subroutine, you need to
1414 ensure that it isn't inlined, either by dropping the C<()> prototype
1415 (which changes calling semantics, so beware) or by thwarting the
1416 inlining mechanism in some other way, such as
1417
1418     sub not_inlined () {
1419         23 if $];
1420     }
1421
1422 =head2 Overriding Built-in Functions
1423 X<built-in> X<override> X<CORE> X<CORE::GLOBAL>
1424
1425 Many built-in functions may be overridden, though this should be tried
1426 only occasionally and for good reason.  Typically this might be
1427 done by a package attempting to emulate missing built-in functionality
1428 on a non-Unix system.
1429
1430 Overriding may be done only by importing the name from a module at
1431 compile time--ordinary predeclaration isn't good enough.  However, the
1432 C<use subs> pragma lets you, in effect, predeclare subs
1433 via the import syntax, and these names may then override built-in ones:
1434
1435     use subs 'chdir', 'chroot', 'chmod', 'chown';
1436     chdir $somewhere;
1437     sub chdir { ... }
1438
1439 To unambiguously refer to the built-in form, precede the
1440 built-in name with the special package qualifier C<CORE::>.  For example,
1441 saying C<CORE::open()> always refers to the built-in C<open()>, even
1442 if the current package has imported some other subroutine called
1443 C<&open()> from elsewhere.  Even though it looks like a regular
1444 function call, it isn't: the CORE:: prefix in that case is part of Perl's
1445 syntax, and works for any keyword, regardless of what is in the CORE
1446 package.  Taking a reference to it, that is, C<\&CORE::open>, only works
1447 for some keywords.  See L<CORE>.
1448
1449 Library modules should not in general export built-in names like C<open>
1450 or C<chdir> as part of their default C<@EXPORT> list, because these may
1451 sneak into someone else's namespace and change the semantics unexpectedly.
1452 Instead, if the module adds that name to C<@EXPORT_OK>, then it's
1453 possible for a user to import the name explicitly, but not implicitly.
1454 That is, they could say
1455
1456     use Module 'open';
1457
1458 and it would import the C<open> override.  But if they said
1459
1460     use Module;
1461
1462 they would get the default imports without overrides.
1463
1464 The foregoing mechanism for overriding built-in is restricted, quite
1465 deliberately, to the package that requests the import.  There is a second
1466 method that is sometimes applicable when you wish to override a built-in
1467 everywhere, without regard to namespace boundaries.  This is achieved by
1468 importing a sub into the special namespace C<CORE::GLOBAL::>.  Here is an
1469 example that quite brazenly replaces the C<glob> operator with something
1470 that understands regular expressions.
1471
1472     package REGlob;
1473     require Exporter;
1474     @ISA = 'Exporter';
1475     @EXPORT_OK = 'glob';
1476
1477     sub import {
1478         my $pkg = shift;
1479         return unless @_;
1480         my $sym = shift;
1481         my $where = ($sym =~ s/^GLOBAL_// ? 'CORE::GLOBAL' : caller(0));
1482         $pkg->export($where, $sym, @_);
1483     }
1484
1485     sub glob {
1486         my $pat = shift;
1487         my @got;
1488         if (opendir my $d, '.') { 
1489             @got = grep /$pat/, readdir $d; 
1490             closedir $d;   
1491         }
1492         return @got;
1493     }
1494     1;
1495
1496 And here's how it could be (ab)used:
1497
1498     #use REGlob 'GLOBAL_glob';      # override glob() in ALL namespaces
1499     package Foo;
1500     use REGlob 'glob';              # override glob() in Foo:: only
1501     print for <^[a-z_]+\.pm\$>;     # show all pragmatic modules
1502
1503 The initial comment shows a contrived, even dangerous example.
1504 By overriding C<glob> globally, you would be forcing the new (and
1505 subversive) behavior for the C<glob> operator for I<every> namespace,
1506 without the complete cognizance or cooperation of the modules that own
1507 those namespaces.  Naturally, this should be done with extreme caution--if
1508 it must be done at all.
1509
1510 The C<REGlob> example above does not implement all the support needed to
1511 cleanly override perl's C<glob> operator.  The built-in C<glob> has
1512 different behaviors depending on whether it appears in a scalar or list
1513 context, but our C<REGlob> doesn't.  Indeed, many perl built-in have such
1514 context sensitive behaviors, and these must be adequately supported by
1515 a properly written override.  For a fully functional example of overriding
1516 C<glob>, study the implementation of C<File::DosGlob> in the standard
1517 library.
1518
1519 When you override a built-in, your replacement should be consistent (if
1520 possible) with the built-in native syntax.  You can achieve this by using
1521 a suitable prototype.  To get the prototype of an overridable built-in,
1522 use the C<prototype> function with an argument of C<"CORE::builtin_name">
1523 (see L<perlfunc/prototype>).
1524
1525 Note however that some built-ins can't have their syntax expressed by a
1526 prototype (such as C<system> or C<chomp>).  If you override them you won't
1527 be able to fully mimic their original syntax.
1528
1529 The built-ins C<do>, C<require> and C<glob> can also be overridden, but due
1530 to special magic, their original syntax is preserved, and you don't have
1531 to define a prototype for their replacements.  (You can't override the
1532 C<do BLOCK> syntax, though).
1533
1534 C<require> has special additional dark magic: if you invoke your
1535 C<require> replacement as C<require Foo::Bar>, it will actually receive
1536 the argument C<"Foo/Bar.pm"> in @_.  See L<perlfunc/require>.
1537
1538 And, as you'll have noticed from the previous example, if you override
1539 C<glob>, the C<< <*> >> glob operator is overridden as well.
1540
1541 In a similar fashion, overriding the C<readline> function also overrides
1542 the equivalent I/O operator C<< <FILEHANDLE> >>. Also, overriding
1543 C<readpipe> also overrides the operators C<``> and C<qx//>.
1544
1545 Finally, some built-ins (e.g. C<exists> or C<grep>) can't be overridden.
1546
1547 =head2 Autoloading
1548 X<autoloading> X<AUTOLOAD>
1549
1550 If you call a subroutine that is undefined, you would ordinarily
1551 get an immediate, fatal error complaining that the subroutine doesn't
1552 exist.  (Likewise for subroutines being used as methods, when the
1553 method doesn't exist in any base class of the class's package.)
1554 However, if an C<AUTOLOAD> subroutine is defined in the package or
1555 packages used to locate the original subroutine, then that
1556 C<AUTOLOAD> subroutine is called with the arguments that would have
1557 been passed to the original subroutine.  The fully qualified name
1558 of the original subroutine magically appears in the global $AUTOLOAD
1559 variable of the same package as the C<AUTOLOAD> routine.  The name
1560 is not passed as an ordinary argument because, er, well, just
1561 because, that's why.  (As an exception, a method call to a nonexistent
1562 C<import> or C<unimport> method is just skipped instead.  Also, if
1563 the AUTOLOAD subroutine is an XSUB, there are other ways to retrieve the
1564 subroutine name.  See L<perlguts/Autoloading with XSUBs> for details.)
1565
1566
1567 Many C<AUTOLOAD> routines load in a definition for the requested
1568 subroutine using eval(), then execute that subroutine using a special
1569 form of goto() that erases the stack frame of the C<AUTOLOAD> routine
1570 without a trace.  (See the source to the standard module documented
1571 in L<AutoLoader>, for example.)  But an C<AUTOLOAD> routine can
1572 also just emulate the routine and never define it.   For example,
1573 let's pretend that a function that wasn't defined should just invoke
1574 C<system> with those arguments.  All you'd do is:
1575
1576     sub AUTOLOAD {
1577         my $program = $AUTOLOAD;
1578         $program =~ s/.*:://;
1579         system($program, @_);
1580     }
1581     date();
1582     who('am', 'i');
1583     ls('-l');
1584
1585 In fact, if you predeclare functions you want to call that way, you don't
1586 even need parentheses:
1587
1588     use subs qw(date who ls);
1589     date;
1590     who "am", "i";
1591     ls '-l';
1592
1593 A more complete example of this is the Shell module on CPAN, which
1594 can treat undefined subroutine calls as calls to external programs.
1595
1596 Mechanisms are available to help modules writers split their modules
1597 into autoloadable files.  See the standard AutoLoader module
1598 described in L<AutoLoader> and in L<AutoSplit>, the standard
1599 SelfLoader modules in L<SelfLoader>, and the document on adding C
1600 functions to Perl code in L<perlxs>.
1601
1602 =head2 Subroutine Attributes
1603 X<attribute> X<subroutine, attribute> X<attrs>
1604
1605 A subroutine declaration or definition may have a list of attributes
1606 associated with it.  If such an attribute list is present, it is
1607 broken up at space or colon boundaries and treated as though a
1608 C<use attributes> had been seen.  See L<attributes> for details
1609 about what attributes are currently supported.
1610 Unlike the limitation with the obsolescent C<use attrs>, the
1611 C<sub : ATTRLIST> syntax works to associate the attributes with
1612 a pre-declaration, and not just with a subroutine definition.
1613
1614 The attributes must be valid as simple identifier names (without any
1615 punctuation other than the '_' character).  They may have a parameter
1616 list appended, which is only checked for whether its parentheses ('(',')')
1617 nest properly.
1618
1619 Examples of valid syntax (even though the attributes are unknown):
1620
1621     sub fnord (&\%) : switch(10,foo(7,3))  :  expensive;
1622     sub plugh () : Ugly('\(") :Bad;
1623     sub xyzzy : _5x5 { ... }
1624
1625 Examples of invalid syntax:
1626
1627     sub fnord : switch(10,foo(); # ()-string not balanced
1628     sub snoid : Ugly('(');        # ()-string not balanced
1629     sub xyzzy : 5x5;              # "5x5" not a valid identifier
1630     sub plugh : Y2::north;        # "Y2::north" not a simple identifier
1631     sub snurt : foo + bar;        # "+" not a colon or space
1632
1633 The attribute list is passed as a list of constant strings to the code
1634 which associates them with the subroutine.  In particular, the second example
1635 of valid syntax above currently looks like this in terms of how it's
1636 parsed and invoked:
1637
1638     use attributes __PACKAGE__, \&plugh, q[Ugly('\(")], 'Bad';
1639
1640 For further details on attribute lists and their manipulation,
1641 see L<attributes> and L<Attribute::Handlers>.
1642
1643 =head1 SEE ALSO
1644
1645 See L<perlref/"Function Templates"> for more about references and closures.
1646 See L<perlxs> if you'd like to learn about calling C subroutines from Perl.  
1647 See L<perlembed> if you'd like to learn about calling Perl subroutines from C.  
1648 See L<perlmod> to learn about bundling up your functions in separate files.
1649 See L<perlmodlib> to learn what library modules come standard on your system.
1650 See L<perlootut> to learn how to make object method calls.