perl 5.003_06: lib/File/Basename.pm
[perl.git] / lib / File / Basename.pm
1 package File::Basename;
2
3 =head1 NAME
4
5 Basename - parse file specifications
6
7 fileparse - split a pathname into pieces
8
9 basename - extract just the filename from a path
10
11 dirname - extract just the directory from a path
12
13 =head1 SYNOPSIS
14
15     use File::Basename;
16
17     ($name,$path,$suffix) = fileparse($fullname,@suffixlist)
18     fileparse_set_fstype($os_string);
19     $basename = basename($fullname,@suffixlist);
20     $dirname = dirname($fullname);
21
22     ($name,$path,$suffix) = fileparse("lib/File/Basename.pm","\.pm");
23     fileparse_set_fstype("VMS");
24     $basename = basename("lib/File/Basename.pm",".pm");
25     $dirname = dirname("lib/File/Basename.pm");
26
27 =head1 DESCRIPTION
28
29 These routines allow you to parse file specifications into useful
30 pieces using the syntax of different operating systems.
31
32 =over 4
33
34 =item fileparse_set_fstype
35
36 You select the syntax via the routine fileparse_set_fstype().
37 If the argument passed to it contains one of the substrings
38 "VMS", "MSDOS", or "MacOS", the file specification syntax of that
39 operating system is used in future calls to fileparse(),
40 basename(), and dirname().  If it contains none of these
41 substrings, UNIX syntax is used.  This pattern matching is
42 case-insensitive.  If you've selected VMS syntax, and the file
43 specification you pass to one of these routines contains a "/",
44 they assume you are using UNIX emulation and apply the UNIX syntax
45 rules instead, for that function call only.
46
47 If you haven't called fileparse_set_fstype(), the syntax is chosen
48 by examining the builtin variable C<$^O> according to these rules.
49
50 =item fileparse
51
52 The fileparse() routine divides a file specification into three
53 parts: a leading B<path>, a file B<name>, and a B<suffix>.  The
54 B<path> contains everything up to and including the last directory
55 separator in the input file specification.  The remainder of the input
56 file specification is then divided into B<name> and B<suffix> based on
57 the optional patterns you specify in C<@suffixlist>.  Each element of
58 this list is interpreted as a regular expression, and is matched
59 against the end of B<name>.  If this succeeds, the matching portion of
60 B<name> is removed and prepended to B<suffix>.  By proper use of
61 C<@suffixlist>, you can remove file types or versions for examination.
62
63 You are guaranteed that if you concatenate B<path>, B<name>, and
64 B<suffix> together in that order, the result will denote the same
65 file as the input file specification.
66
67 =back
68
69 =head1 EXAMPLES
70
71 Using UNIX file syntax:
72
73     ($base,$path,$type) = fileparse('/virgil/aeneid/draft.book7',
74                                     '\.book\d+');
75
76 would yield
77
78     $base eq 'draft'
79     $path eq '/virgil/aeneid/',
80     $type eq '.book7'
81
82 Similarly, using VMS syntax:
83
84     ($name,$dir,$type) = fileparse('Doc_Root:[Help]Rhetoric.Rnh',
85                                    '\..*');
86
87 would yield
88
89     $name eq 'Rhetoric'
90     $dir  eq 'Doc_Root:[Help]'
91     $type eq '.Rnh'
92
93 =item C<basename>
94
95 The basename() routine returns the first element of the list produced
96 by calling fileparse() with the same arguments.  It is provided for
97 compatibility with the UNIX shell command basename(1).
98
99 =item C<dirname>
100
101 The dirname() routine returns the directory portion of the input file
102 specification.  When using VMS or MacOS syntax, this is identical to the
103 second element of the list produced by calling fileparse() with the same
104 input file specification.  (Under VMS, if there is no directory information
105 in the input file specification, then the current default device and
106 directory are returned.)  When using UNIX or MSDOS syntax, the return
107 value conforms to the behavior of the UNIX shell command dirname(1).  This
108 is usually the same as the behavior of fileparse(), but differs in some
109 cases.  For example, for the input file specification F<lib/>, fileparse()
110 considers the directory name to be F<lib/>, while dirname() considers the
111 directory name to be F<.>).
112
113 =cut
114
115 require 5.002;
116 require Exporter;
117 @ISA = qw(Exporter);
118 @EXPORT = qw(fileparse fileparse_set_fstype basename dirname);
119 #use strict;
120 #use vars qw($VERSION $Fileparse_fstype);
121 $VERSION = "2.4";
122
123
124 #   fileparse_set_fstype() - specify OS-based rules used in future
125 #                            calls to routines in this package
126 #
127 #   Currently recognized values: VMS, MSDOS, MacOS
128 #       Any other name uses Unix-style rules
129
130 sub fileparse_set_fstype {
131   my($old) = $Fileparse_fstype;
132   $Fileparse_fstype = $_[0] if $_[0];
133   $old;
134 }
135
136 #   fileparse() - parse file specification
137 #
138 #   Version 2.4  27-Sep-1996  Charles Bailey  bailey@genetics.upenn.edu
139
140
141 sub fileparse {
142   my($fullname,@suffices) = @_;
143   my($fstype) = $Fileparse_fstype;
144   my($dirpath,$tail,$suffix,$basename);
145
146   if ($fstype =~ /^VMS/i) {
147     if ($fullname =~ m#/#) { $fstype = '' }  # We're doing Unix emulation
148     else {
149       ($dirpath,$basename) = ($fullname =~ /^(.*[:>\]])?(.*)/);
150     }
151   }
152   if ($fstype =~ /^MSDOS/i) {
153     ($dirpath,$basename) = ($fullname =~ /^(.*[:\\\/])?(.*)/);
154     $dirpath .= '.\\' unless $dirpath =~ /\\$/;
155   }
156   elsif ($fstype =~ /^MacOS/i) {
157     ($dirpath,$basename) = ($fullname =~ /^(.*:)?(.*)/);
158   }
159   elsif ($fstype !~ /^VMS/i) {  # default to Unix
160     ($dirpath,$basename) = ($fullname =~ m#^(.*/)?(.*)#);
161     $dirpath = './' unless $dirpath;
162   }
163
164   if (@suffices) {
165     $tail = '';
166     foreach $suffix (@suffices) {
167       if ($basename =~ /([\x00-\xff]*?)($suffix)$/) {
168         $tail = $2 . $tail;
169         $basename = $1;
170       }
171     }
172   }
173
174   wantarray ? ($basename,$dirpath,$tail) : $basename;
175
176 }
177
178
179 #   basename() - returns first element of list returned by fileparse()
180
181 sub basename {
182   my($name) = shift;
183   (fileparse($name, map("\Q$_\E",@_)))[0];
184 }
185
186
187 #    dirname() - returns device and directory portion of file specification
188 #        Behavior matches that of Unix dirname(1) exactly for Unix and MSDOS
189 #        filespecs except for names ending with a separator, e.g., "/xx/yy/".
190 #        This differs from the second element of the list returned
191 #        by fileparse() in that the trailing '/' (Unix) or '\' (MSDOS) (and
192 #        the last directory name if the filespec ends in a '/' or '\'), is lost.
193
194 sub dirname {
195     my($basename,$dirname) = fileparse($_[0]);
196     my($fstype) = $Fileparse_fstype;
197
198     if ($fstype =~ /VMS/i) { 
199         if ($_[0] =~ m#/#) { $fstype = '' }
200         else { return $dirname || $ENV{DEFAULT} }
201     }
202     if ($fstype =~ /MacOS/i) { return $dirname }
203     elsif ($fstype =~ /MSDOS/i) { 
204         if ( $dirname =~ /:\\$/) { return $dirname }
205         chop $dirname;
206         $dirname =~ s:[^\\]+$:: unless length($basename);
207         $dirname = '.' unless length($dirname);
208     }
209     else { 
210         if ( $dirname =~ m:^/+$:) { return '/'; }
211         chop $dirname;
212         $dirname =~ s:[^/]+$:: unless length($basename);
213         $dirname =~ s:/+$:: ;
214         $dirname = '.' unless length($dirname);
215     }
216
217     $dirname;
218 }
219
220 $Fileparse_fstype = $^O;
221
222 1;