Update IPC-Cmd to CPAN version 0.76
[perl.git] / Porting / corelist.pl
1 #!perl
2 # Generates info for Module::CoreList from this perl tree
3 # run this from the root of a perl tree
4 #
5 # Data is on STDOUT.
6 #
7 # With an optional arg specifying the root of a CPAN mirror, outputs the
8 # %upstream and %bug_tracker hashes too.
9
10 use autodie;
11 use strict;
12 use warnings;
13 use File::Find;
14 use ExtUtils::MM_Unix;
15 use version;
16 use lib "Porting";
17 use Maintainers qw(%Modules files_to_modules);
18 use File::Spec;
19 use Parse::CPAN::Meta;
20 use IPC::Cmd 'can_run';
21 use HTTP::Tiny;
22 use IO::Uncompress::Gunzip;
23
24 my $corelist_file = 'dist/Module-CoreList/lib/Module/CoreList.pm';
25
26 my %lines;
27 my %module_to_file;
28 my %modlist;
29
30 die "usage: $0 [ cpan-mirror/ ] [ 5.x.y] \n" unless @ARGV <= 2;
31 my $cpan         = shift;
32 my $raw_version  = shift || $];
33 my $perl_version = version->parse("$raw_version");
34 my $perl_vnum    = $perl_version->numify;
35 my $perl_vstring = $perl_version->normal; # how do we get version.pm to not give us leading v?
36 $perl_vstring =~ s/^v//;
37
38 if ( !-f 'MANIFEST' ) {
39     die "Must be run from the root of a clean perl tree\n";
40 }
41
42 open( my $corelist_fh, '<', $corelist_file );
43 my $corelist = join( '', <$corelist_fh> );
44
45 if ($cpan) {
46     my $modlistfile = File::Spec->catfile( $cpan, 'modules', '02packages.details.txt' );
47     my $content;
48
49     my $fh;
50     if ( -e $modlistfile ) {
51         warn "Reading the module list from $modlistfile";
52         open $fh, '<', $modlistfile;
53     } elsif ( -e $modlistfile . ".gz" ) {
54         my $zcat = can_run('gzcat') || can_run('zcat') or die "Can't find gzcat or zcat";
55         warn "Reading the module list from $modlistfile.gz";
56         open $fh, '-|', "$zcat $modlistfile.gz";
57     } else {
58         warn "About to fetch 02packages from ftp.funet.fi. This may take a few minutes\n";
59         my $gzipped_content = fetch_url('http://ftp.funet.fi/pub/CPAN/modules/02packages.details.txt.gz');
60         unless ($gzipped_content) {
61             die "Unable to read 02packages.details.txt from either your CPAN mirror or ftp.funet.fi";
62         }
63         IO::Uncompress::Gunzip::gunzip(\$gzipped_content, \$content, Transparent => 0)
64             or die "Can't gunzip content: $IO::Uncompress::Gunzip::GunzipError";
65     }
66
67     if ( $fh and !$content ) {
68         local $/ = "\n";
69         $content = join( '', <$fh> );
70     }
71
72     die "Incompatible modlist format"
73         unless $content =~ /^Columns: +package name, version, path/m;
74
75     # Converting the file to a hash is about 5 times faster than a regexp flat
76     # lookup.
77     for ( split( qr/\n/, $content ) ) {
78         next unless /^([A-Za-z_:0-9]+) +[-0-9.undefHASHVERSIONvsetwhenloadingbogus]+ +(\S+)/;
79         $modlist{$1} = $2;
80     }
81 }
82
83 find(
84     sub {
85         /(\.pm|_pm\.PL)$/ or return;
86         /PPPort\.pm$/ and return;
87         my $module = $File::Find::name;
88         $module =~ /\b(demo|t|private)\b/ and return;    # demo or test modules
89         my $version = MM->parse_version($_);
90         defined $version or $version = 'undef';
91         $version =~ /\d/ and $version = "'$version'";
92
93         # some heuristics to figure out the module name from the file name
94         $module =~ s{^(lib|cpan|dist|(?:symbian/)?ext)/}{}
95                         and $1 ne 'lib'
96             and (
97             $module =~ s{\b(\w+)/\1\b}{$1},
98             $module =~ s{^B/O}{O},
99             $module =~ s{^Devel-PPPort}{Devel},
100             $module =~ s{^libnet/}{},
101             $module =~ s{^Encode/encoding}{encoding},
102             $module =~ s{^IPC-SysV/}{IPC/},
103             $module =~ s{^MIME-Base64/QuotedPrint}{MIME/QuotedPrint},
104             $module =~ s{^(?:DynaLoader|Errno|Opcode|XSLoader)/}{},
105             $module =~ s{^Sys-Syslog/win32}{Sys-Syslog},
106             $module =~ s{^Time-Piece/Seconds}{Time/Seconds},
107             );
108         $module =~ s{^vms/ext}{VMS};
109                 $module =~ s{^lib/}{}g;
110         $module =~ s{/}{::}g;
111         $module =~ s{-}{::}g;
112                 $module =~ s{^.*::lib::}{}; # turns Foo/lib/Foo.pm into Foo.pm
113         $module =~ s/(\.pm|_pm\.PL)$//;
114         $lines{$module}          = $version;
115         $module_to_file{$module} = $File::Find::name;
116     },
117     'vms/ext',
118     'symbian/ext',
119     'lib',
120     'ext',
121         'cpan',
122         'dist'
123 );
124
125 -e 'configpm' and $lines{Config} = 'undef';
126
127 if ( open my $ucdv, "<", "lib/unicore/version" ) {
128     chomp( my $ucd = <$ucdv> );
129     $lines{Unicode} = "'$ucd'";
130     close $ucdv;
131 }
132
133 my $versions_in_release = "    " . $perl_vnum . " => {\n";
134 foreach my $key ( sort keys %lines ) {
135     $versions_in_release .= sprintf "\t%-24s=> %s,\n", "'$key'", $lines{$key};
136 }
137 $versions_in_release .= "    },\n";
138
139 $corelist =~ s/^(%version\s*=\s*.*?)(^\);)$/$1$versions_in_release$2/xism;
140
141 exit unless %modlist;
142
143 # We have to go through this two stage lookup, given how Maintainers.pl keys its
144 # data by "Module", which is really a dist.
145 my $file_to_M = files_to_modules( values %module_to_file );
146
147 my %module_to_upstream;
148 my %module_to_dist;
149 my %dist_to_meta_YAML;
150 my %module_to_deprecated;
151 while ( my ( $module, $file ) = each %module_to_file ) {
152     my $M = $file_to_M->{$file};
153     next unless $M;
154     next if $Modules{$M}{MAINTAINER} eq 'p5p';
155     $module_to_upstream{$module} = $Modules{$M}{UPSTREAM};
156     $module_to_deprecated{$module} = 1 if $Modules{$M}{DEPRECATED};
157     next
158         if defined $module_to_upstream{$module}
159             && $module_to_upstream{$module} =~ /^(?:blead|first-come)$/;
160     my $dist = $modlist{$module};
161     unless ($dist) {
162         warn "Can't find a distribution for $module\n";
163         next;
164     }
165     $module_to_dist{$module} = $dist;
166
167     next if exists $dist_to_meta_YAML{$dist};
168
169     $dist_to_meta_YAML{$dist} = undef;
170
171     # Like it or lump it, this has to be Unix format.
172     my $meta_YAML_path = "authors/id/$dist";
173     $meta_YAML_path =~ s/(?:tar\.gz|tar\.bz2|zip)$/meta/ or die "$meta_YAML_path";
174     my $meta_YAML_url = 'http://ftp.funet.fi/pub/CPAN/' . $meta_YAML_path;
175
176     if ( -e "$cpan/$meta_YAML_path" ) {
177         $dist_to_meta_YAML{$dist} = Parse::CPAN::Meta::LoadFile( $cpan . "/" . $meta_YAML_path );
178     } elsif ( my $content = fetch_url($meta_YAML_url) ) {
179         unless ($content) {
180             warn "Failed to fetch $meta_YAML_url\n";
181             next;
182         }
183         eval { $dist_to_meta_YAML{$dist} = Parse::CPAN::Meta::Load($content); };
184         if ( my $err = $@ ) {
185             warn "$meta_YAML_path: ".$err;
186             next;
187         }
188     } else {
189         warn "$meta_YAML_path does not exist for $module\n";
190
191         # I tried code to open the tarballs with Archive::Tar to find and
192         # extract META.yml, but only Text-Tabs+Wrap-2006.1117.tar.gz had one,
193         # so it's not worth including.
194         next;
195     }
196 }
197
198 my $upstream_stanza = "%upstream = (\n";
199 foreach my $module ( sort keys %module_to_upstream ) {
200     my $upstream = defined $module_to_upstream{$module} ? "'$module_to_upstream{$module}'" : 'undef';
201     $upstream_stanza .= sprintf "    %-24s=> %s,\n", "'$module'", $upstream;
202 }
203 $upstream_stanza .= ");";
204
205 $corelist =~ s/^%upstream .*? ;$/$upstream_stanza/ismx;
206
207 # Deprecation generation
208 my $deprecated_stanza = "    " . $perl_vnum . " => {\n";
209 foreach my $module ( sort keys %module_to_deprecated ) {
210     my $deprecated = defined $module_to_deprecated{$module} ? "'$module_to_deprecated{$module}'" : 'undef';
211     $deprecated_stanza .= sprintf "\t%-24s=> %s,\n", "'$module'", $deprecated;
212 }
213 $deprecated_stanza .= "    },\n";
214 $corelist =~ s/^(%deprecated\s*=\s*.*?)(^\);)$/$1$deprecated_stanza$2/xism;
215
216 my $tracker = "%bug_tracker = (\n";
217 foreach my $module ( sort keys %module_to_upstream ) {
218     my $upstream = defined $module_to_upstream{$module};
219     next
220         if defined $upstream
221             and $upstream eq 'blead' || $upstream eq 'first-come';
222
223     my $bug_tracker;
224
225     my $dist = $module_to_dist{$module};
226     $bug_tracker = $dist_to_meta_YAML{$dist}->{resources}{bugtracker}
227         if $dist;
228
229     $bug_tracker = defined $bug_tracker ? "'$bug_tracker'" : 'undef';
230         next if $bug_tracker eq "'http://rt.perl.org/perlbug/'";
231     $tracker .= sprintf "    %-24s=> %s,\n", "'$module'", $bug_tracker;
232 }
233 $tracker .= ");";
234
235 $corelist =~ s/^%bug_tracker .*? ;/$tracker/eismx;
236
237 unless ( $corelist =~ /and $perl_vstring releases of perl/ ) {
238     warn "Adding $perl_vstring to the list of perl versions covered by Module::CoreList\n";
239     $corelist =~ s/(currently covers (?:.*?))\s*and (.*?) releases of perl/$1, $2 and $perl_vstring releases of perl/ism;
240 }
241
242 unless (
243     $corelist =~ /^%released \s* = \s* \(
244         .*?
245         $perl_vnum => .*?
246         \);/ismx
247     )
248 {
249     warn "Adding $perl_vnum to the list of released perl versions. Please consider adding a release date.\n";
250     $corelist =~ s/^(%released \s* = \s* .*?) ( \) )
251                 /$1  $perl_vnum => '????-??-??',\n  $2/ismx;
252 }
253
254 write_corelist($corelist);
255
256 warn "All done. Please check over $corelist_file carefully before committing. Thanks!\n";
257
258
259 sub write_corelist {
260     my $content = shift;
261     open (my $clfh, ">", $corelist_file);
262     print $clfh $content;
263     close($clfh);
264 }
265
266 sub fetch_url {
267     my $url = shift;
268     my $http = HTTP::Tiny->new;
269     my $response = $http->get($url);
270     if ($response->{success}) {
271         return $response->{content};
272     } else {
273         warn "Error fetching $url: $response->{status} $response->{reason}\n";
274         return;
275     }
276 }