Bump ExtUtils::ParseXS version for doc references
[perl.git] / dist / ExtUtils-ParseXS / lib / ExtUtils / ParseXS.pm
1 package ExtUtils::ParseXS;
2 use strict;
3
4 use 5.008001;  # We use /??{}/ in regexes
5 use Cwd;
6 use Config;
7 use Exporter;
8 use File::Basename;
9 use File::Spec;
10 use Symbol;
11
12 our $VERSION;
13 BEGIN {
14   $VERSION = '3.12';
15 }
16 use ExtUtils::ParseXS::Constants $VERSION;
17 use ExtUtils::ParseXS::CountLines $VERSION;
18 use ExtUtils::ParseXS::Utilities $VERSION;
19 $VERSION = eval $VERSION if $VERSION =~ /_/;
20
21 use ExtUtils::ParseXS::Utilities qw(
22   standard_typemap_locations
23   trim_whitespace
24   tidy_type
25   C_string
26   valid_proto_string
27   process_typemaps
28   make_targetable
29   map_type
30   standard_XS_defs
31   assign_func_args
32   analyze_preprocessor_statements
33   set_cond
34   Warn
35   current_line_number
36   blurt
37   death
38   check_conditional_preprocessor_statements
39   escape_file_for_line_directive
40 );
41
42 our @ISA = qw(Exporter);
43 our @EXPORT_OK = qw(
44   process_file
45   report_error_count
46 );
47
48 # The scalars in the line below remain as 'our' variables because pulling
49 # them into $self led to build problems.  In most cases, strings being
50 # 'eval'-ed contain the variables' names hard-coded.
51 our (
52   $Package, $func_name, $Full_func_name, $pname, $ALIAS,
53 );
54
55 our $self = bless {} => __PACKAGE__;
56
57 sub process_file {
58
59   # Allow for $package->process_file(%hash) in the future
60   my ($pkg, %options) = @_ % 2 ? @_ : (__PACKAGE__, @_);
61
62   $self->{ProtoUsed} = exists $options{prototypes};
63
64   # Set defaults.
65   my %args = (
66     argtypes        => 1,
67     csuffix         => '.c',
68     except          => 0,
69     hiertype        => 0,
70     inout           => 1,
71     linenumbers     => 1,
72     optimize        => 1,
73     output          => \*STDOUT,
74     prototypes      => 0,
75     typemap         => [],
76     versioncheck    => 1,
77     FH              => Symbol::gensym(),
78     %options,
79   );
80   $args{except} = $args{except} ? ' TRY' : '';
81
82   # Global Constants
83
84   my ($Is_VMS, $SymSet);
85   if ($^O eq 'VMS') {
86     $Is_VMS = 1;
87     # Establish set of global symbols with max length 28, since xsubpp
88     # will later add the 'XS_' prefix.
89     require ExtUtils::XSSymSet;
90     $SymSet = ExtUtils::XSSymSet->new(28);
91   }
92   @{ $self->{XSStack} } = ({type => 'none'});
93   $self->{InitFileCode} = [ @ExtUtils::ParseXS::Constants::InitFileCode ];
94   $self->{Overload}     = 0;
95   $self->{errors}       = 0;
96   $self->{Fallback}     = '&PL_sv_undef';
97
98   # Most of the 1500 lines below uses these globals.  We'll have to
99   # clean this up sometime, probably.  For now, we just pull them out
100   # of %args.  -Ken
101
102   $self->{hiertype} = $args{hiertype};
103   $self->{WantPrototypes} = $args{prototypes};
104   $self->{WantVersionChk} = $args{versioncheck};
105   $self->{WantLineNumbers} = $args{linenumbers};
106   $self->{IncludedFiles} = {};
107
108   die "Missing required parameter 'filename'" unless $args{filename};
109   $self->{filepathname} = $args{filename};
110   ($self->{dir}, $self->{filename}) =
111     (dirname($args{filename}), basename($args{filename}));
112   $self->{filepathname} =~ s/\\/\\\\/g;
113   $self->{IncludedFiles}->{$args{filename}}++;
114
115   # Open the output file if given as a string.  If they provide some
116   # other kind of reference, trust them that we can print to it.
117   if (not ref $args{output}) {
118     open my($fh), "> $args{output}" or die "Can't create $args{output}: $!";
119     $args{outfile} = $args{output};
120     $args{output} = $fh;
121   }
122
123   # Really, we shouldn't have to chdir() or select() in the first
124   # place.  For now, just save and restore.
125   my $orig_cwd = cwd();
126   my $orig_fh = select();
127
128   chdir($self->{dir});
129   my $pwd = cwd();
130   my $csuffix = $args{csuffix};
131
132   if ($self->{WantLineNumbers}) {
133     my $cfile;
134     if ( $args{outfile} ) {
135       $cfile = $args{outfile};
136     }
137     else {
138       $cfile = $args{filename};
139       $cfile =~ s/\.xs$/$csuffix/i or $cfile .= $csuffix;
140     }
141     tie(*PSEUDO_STDOUT, 'ExtUtils::ParseXS::CountLines', $cfile, $args{output});
142     select PSEUDO_STDOUT;
143   }
144   else {
145     select $args{output};
146   }
147
148   $self->{typemap} = process_typemaps( $args{typemap}, $pwd );
149
150   my $END = "!End!\n\n";        # "impossible" keyword (multiple newline)
151
152   # Match an XS keyword
153   $self->{BLOCK_re} = '\s*(' .
154     join('|' => @ExtUtils::ParseXS::Constants::XSKeywords) .
155     "|$END)\\s*:";
156
157   our ($C_group_rex, $C_arg);
158   # Group in C (no support for comments or literals)
159   $C_group_rex = qr/ [({\[]
160                (?: (?> [^()\[\]{}]+ ) | (??{ $C_group_rex }) )*
161                [)}\]] /x;
162   # Chunk in C without comma at toplevel (no comments):
163   $C_arg = qr/ (?: (?> [^()\[\]{},"']+ )
164          |   (??{ $C_group_rex })
165          |   " (?: (?> [^\\"]+ )
166            |   \\.
167            )* "        # String literal
168                 |   ' (?: (?> [^\\']+ ) | \\. )* ' # Char literal
169          )* /xs;
170
171   # Since at this point we're ready to begin printing to the output file and
172   # reading from the input file, I want to get as much data as possible into
173   # the proto-object $self.  That means assigning to $self and elements of
174   # %args referenced below this point.
175   # HOWEVER:  This resulted in an error when I tried:
176   #   $args{'s'} ---> $self->{s}.
177   # Use of uninitialized value in quotemeta at
178   #   .../blib/lib/ExtUtils/ParseXS.pm line 733
179
180   foreach my $datum ( qw| argtypes except inout optimize | ) {
181     $self->{$datum} = $args{$datum};
182   }
183
184   # Identify the version of xsubpp used
185   print <<EOM;
186 /*
187  * This file was generated automatically by ExtUtils::ParseXS version $VERSION from the
188  * contents of $self->{filename}. Do not edit this file, edit $self->{filename} instead.
189  *
190  *    ANY CHANGES MADE HERE WILL BE LOST!
191  *
192  */
193
194 EOM
195
196
197   print("#line 1 \"" . escape_file_for_line_directive($self->{filepathname}) . "\"\n")
198     if $self->{WantLineNumbers};
199
200   # Open the input file (using $self->{filename} which
201   # is a basename'd $args{filename} due to chdir above)
202   open($self->{FH}, '<', $self->{filename}) or die "cannot open $self->{filename}: $!\n";
203
204   firstmodule:
205   while (readline($self->{FH})) {
206     if (/^=/) {
207       my $podstartline = $.;
208       do {
209         if (/^=cut\s*$/) {
210           # We can't just write out a /* */ comment, as our embedded
211           # POD might itself be in a comment. We can't put a /**/
212           # comment inside #if 0, as the C standard says that the source
213           # file is decomposed into preprocessing characters in the stage
214           # before preprocessing commands are executed.
215           # I don't want to leave the text as barewords, because the spec
216           # isn't clear whether macros are expanded before or after
217           # preprocessing commands are executed, and someone pathological
218           # may just have defined one of the 3 words as a macro that does
219           # something strange. Multiline strings are illegal in C, so
220           # the "" we write must be a string literal. And they aren't
221           # concatenated until 2 steps later, so we are safe.
222           #     - Nicholas Clark
223           print("#if 0\n  \"Skipped embedded POD.\"\n#endif\n");
224           printf("#line %d \"%s\"\n", $. + 1, escape_file_for_line_directive($self->{filepathname}))
225             if $self->{WantLineNumbers};
226           next firstmodule
227         }
228
229       } while (readline($self->{FH}));
230       # At this point $. is at end of file so die won't state the start
231       # of the problem, and as we haven't yet read any lines &death won't
232       # show the correct line in the message either.
233       die ("Error: Unterminated pod in $self->{filename}, line $podstartline\n")
234         unless $self->{lastline};
235     }
236     last if ($Package, $self->{Prefix}) =
237       /^MODULE\s*=\s*[\w:]+(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/;
238
239     print $_;
240   }
241   unless (defined $_) {
242     warn "Didn't find a 'MODULE ... PACKAGE ... PREFIX' line\n";
243     exit 0; # Not a fatal error for the caller process
244   }
245
246   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
247
248   standard_XS_defs();
249
250   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
251
252   $self->{lastline}    = $_;
253   $self->{lastline_no} = $.;
254
255   my $BootCode_ref = [];
256   my $XSS_work_idx = 0;
257   my $cpp_next_tmp = 'XSubPPtmpAAAA';
258  PARAGRAPH:
259   while ($self->fetch_para()) {
260     my $outlist_ref  = [];
261     # Print initial preprocessor statements and blank lines
262     while (@{ $self->{line} } && $self->{line}->[0] !~ /^[^\#]/) {
263       my $ln = shift(@{ $self->{line} });
264       print $ln, "\n";
265       next unless $ln =~ /^\#\s*((if)(?:n?def)?|elsif|else|endif)\b/;
266       my $statement = $+;
267       ( $self, $XSS_work_idx, $BootCode_ref ) =
268         analyze_preprocessor_statements(
269           $self, $statement, $XSS_work_idx, $BootCode_ref
270         );
271     }
272
273     next PARAGRAPH unless @{ $self->{line} };
274
275     if ($XSS_work_idx && !$self->{XSStack}->[$XSS_work_idx]{varname}) {
276       # We are inside an #if, but have not yet #defined its xsubpp variable.
277       print "#define $cpp_next_tmp 1\n\n";
278       push(@{ $self->{InitFileCode} }, "#if $cpp_next_tmp\n");
279       push(@{ $BootCode_ref },     "#if $cpp_next_tmp");
280       $self->{XSStack}->[$XSS_work_idx]{varname} = $cpp_next_tmp++;
281     }
282
283     $self->death(
284       "Code is not inside a function"
285         ." (maybe last function was ended by a blank line "
286         ." followed by a statement on column one?)")
287       if $self->{line}->[0] =~ /^\s/;
288
289     # initialize info arrays
290     foreach my $member (qw(args_match var_types defaults arg_list
291                            argtype_seen in_out lengthof))
292     {
293       $self->{$member} = {};
294     }
295     $self->{proto_arg} = [];
296     $self->{processing_arg_with_types} = undef;
297     $self->{proto_in_this_xsub}        = undef;
298     $self->{scope_in_this_xsub}        = undef;
299     $self->{interface}                 = undef;
300     $self->{interface_macro}           = 'XSINTERFACE_FUNC';
301     $self->{interface_macro_set}       = 'XSINTERFACE_FUNC_SET';
302     $self->{ProtoThisXSUB}             = $self->{WantPrototypes};
303     $self->{ScopeThisXSUB}             = 0;
304
305     my $xsreturn = 0;
306
307     $_ = shift(@{ $self->{line} });
308     while (my $kwd = $self->check_keyword("REQUIRE|PROTOTYPES|EXPORT_XSUB_SYMBOLS|FALLBACK|VERSIONCHECK|INCLUDE(?:_COMMAND)?|SCOPE")) {
309       my $method = $kwd . "_handler";
310       $self->$method($_);
311       next PARAGRAPH unless @{ $self->{line} };
312       $_ = shift(@{ $self->{line} });
313     }
314
315     if ($self->check_keyword("BOOT")) {
316       check_conditional_preprocessor_statements($self);
317       push (@{ $BootCode_ref }, "#line $self->{line_no}->[@{ $self->{line_no} } - @{ $self->{line} }] \""
318                                 . escape_file_for_line_directive($self->{filepathname}) . "\"")
319         if $self->{WantLineNumbers} && $self->{line}->[0] !~ /^\s*#\s*line\b/;
320       push (@{ $BootCode_ref }, @{ $self->{line} }, "");
321       next PARAGRAPH;
322     }
323
324     # extract return type, function name and arguments
325     ($self->{ret_type}) = tidy_type($_);
326     my $RETVAL_no_return = 1 if $self->{ret_type} =~ s/^NO_OUTPUT\s+//;
327
328     # Allow one-line ANSI-like declaration
329     unshift @{ $self->{line} }, $2
330       if $self->{argtypes}
331         and $self->{ret_type} =~ s/^(.*?\w.*?)\s*\b(\w+\s*\(.*)/$1/s;
332
333     # a function definition needs at least 2 lines
334     $self->blurt("Error: Function definition too short '$self->{ret_type}'"), next PARAGRAPH
335       unless @{ $self->{line} };
336
337     my $externC = 1 if $self->{ret_type} =~ s/^extern "C"\s+//;
338     my $static  = 1 if $self->{ret_type} =~ s/^static\s+//;
339
340     my $func_header = shift(@{ $self->{line} });
341     $self->blurt("Error: Cannot parse function definition from '$func_header'"), next PARAGRAPH
342       unless $func_header =~ /^(?:([\w:]*)::)?(\w+)\s*\(\s*(.*?)\s*\)\s*(const)?\s*(;\s*)?$/s;
343
344     my ($class, $orig_args);
345     ($class, $func_name, $orig_args) =  ($1, $2, $3);
346     $class = "$4 $class" if $4;
347     ($pname = $func_name) =~ s/^($self->{Prefix})?/$self->{Packprefix}/;
348     my $clean_func_name;
349     ($clean_func_name = $func_name) =~ s/^$self->{Prefix}//;
350     $Full_func_name = "$self->{Packid}_$clean_func_name";
351     if ($Is_VMS) {
352       $Full_func_name = $SymSet->addsym($Full_func_name);
353     }
354
355     # Check for duplicate function definition
356     for my $tmp (@{ $self->{XSStack} }) {
357       next unless defined $tmp->{functions}{$Full_func_name};
358       Warn( $self, "Warning: duplicate function definition '$clean_func_name' detected");
359       last;
360     }
361     $self->{XSStack}->[$XSS_work_idx]{functions}{$Full_func_name}++;
362     %{ $self->{XsubAliases} }     = ();
363     %{ $self->{XsubAliasValues} } = ();
364     %{ $self->{Interfaces} }      = ();
365     @{ $self->{Attributes} }      = ();
366     $self->{DoSetMagic} = 1;
367
368     $orig_args =~ s/\\\s*/ /g;    # process line continuations
369     my @args;
370
371     my (@fake_INPUT_pre);    # For length(s) generated variables
372     my (@fake_INPUT);
373     my $only_C_inlist_ref = {};        # Not in the signature of Perl function
374     if ($self->{argtypes} and $orig_args =~ /\S/) {
375       my $args = "$orig_args ,";
376       if ($args =~ /^( (??{ $C_arg }) , )* $ /x) {
377         @args = ($args =~ /\G ( (??{ $C_arg }) ) , /xg);
378         for ( @args ) {
379           s/^\s+//;
380           s/\s+$//;
381           my ($arg, $default) = ($_ =~ m/ ( [^=]* ) ( (?: = .* )? ) /x);
382           my ($pre, $len_name) = ($arg =~ /(.*?) \s*
383                              \b ( \w+ | length\( \s*\w+\s* \) )
384                              \s* $ /x);
385           next unless defined($pre) && length($pre);
386           my $out_type = '';
387           my $inout_var;
388           if ($self->{inout} and s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//) {
389             my $type = $1;
390             $out_type = $type if $type ne 'IN';
391             $arg =~ s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//;
392             $pre =~ s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//;
393           }
394           my $islength;
395           if ($len_name =~ /^length\( \s* (\w+) \s* \)\z/x) {
396             $len_name = "XSauto_length_of_$1";
397             $islength = 1;
398             die "Default value on length() argument: '$_'"
399               if length $default;
400           }
401           if (length $pre or $islength) { # Has a type
402             if ($islength) {
403               push @fake_INPUT_pre, $arg;
404             }
405             else {
406               push @fake_INPUT, $arg;
407             }
408             # warn "pushing '$arg'\n";
409             $self->{argtype_seen}->{$len_name}++;
410             $_ = "$len_name$default"; # Assigns to @args
411           }
412           $only_C_inlist_ref->{$_} = 1 if $out_type eq "OUTLIST" or $islength;
413           push @{ $outlist_ref }, $len_name if $out_type =~ /OUTLIST$/;
414           $self->{in_out}->{$len_name} = $out_type if $out_type;
415         }
416       }
417       else {
418         @args = split(/\s*,\s*/, $orig_args);
419         Warn( $self, "Warning: cannot parse argument list '$orig_args', fallback to split");
420       }
421     }
422     else {
423       @args = split(/\s*,\s*/, $orig_args);
424       for (@args) {
425         if ($self->{inout} and s/^(IN|IN_OUTLIST|OUTLIST|IN_OUT|OUT)\b\s*//) {
426           my $out_type = $1;
427           next if $out_type eq 'IN';
428           $only_C_inlist_ref->{$_} = 1 if $out_type eq "OUTLIST";
429           if ($out_type =~ /OUTLIST$/) {
430               push @{ $outlist_ref }, undef;
431           }
432           $self->{in_out}->{$_} = $out_type;
433         }
434       }
435     }
436     if (defined($class)) {
437       my $arg0 = ((defined($static) or $func_name eq 'new')
438           ? "CLASS" : "THIS");
439       unshift(@args, $arg0);
440     }
441     my $extra_args = 0;
442     my @args_num = ();
443     my $num_args = 0;
444     my $report_args = '';
445     my $ellipsis;
446     foreach my $i (0 .. $#args) {
447       if ($args[$i] =~ s/\.\.\.//) {
448         $ellipsis = 1;
449         if ($args[$i] eq '' && $i == $#args) {
450           $report_args .= ", ...";
451           pop(@args);
452           last;
453         }
454       }
455       if ($only_C_inlist_ref->{$args[$i]}) {
456         push @args_num, undef;
457       }
458       else {
459         push @args_num, ++$num_args;
460           $report_args .= ", $args[$i]";
461       }
462       if ($args[$i] =~ /^([^=]*[^\s=])\s*=\s*(.*)/s) {
463         $extra_args++;
464         $args[$i] = $1;
465         $self->{defaults}->{$args[$i]} = $2;
466         $self->{defaults}->{$args[$i]} =~ s/"/\\"/g;
467       }
468       $self->{proto_arg}->[$i+1] = '$';
469     }
470     my $min_args = $num_args - $extra_args;
471     $report_args =~ s/"/\\"/g;
472     $report_args =~ s/^,\s+//;
473     $self->{func_args} = assign_func_args($self, \@args, $class);
474     @{ $self->{args_match} }{@args} = @args_num;
475
476     my $PPCODE = grep(/^\s*PPCODE\s*:/, @{ $self->{line} });
477     my $CODE = grep(/^\s*CODE\s*:/, @{ $self->{line} });
478     # Detect CODE: blocks which use ST(n)= or XST_m*(n,v)
479     # to set explicit return values.
480     my $EXPLICIT_RETURN = ($CODE &&
481             ("@{ $self->{line} }" =~ /(\bST\s*\([^;]*=) | (\bXST_m\w+\s*\()/x ));
482
483     # The $ALIAS which follows is only explicitly called within the scope of
484     # process_file().  In principle, it ought to be a lexical, i.e., 'my
485     # $ALIAS' like the other nearby variables.  However, implementing that
486     # change produced a slight difference in the resulting .c output in at
487     # least two distributions:  B/BD/BDFOY/Crypt-Rijndael and
488     # G/GF/GFUJI/Hash-FieldHash.  The difference is, arguably, an improvement
489     # in the resulting C code.  Example:
490     # 388c388
491     # <                       GvNAME(CvGV(cv)),
492     # ---
493     # >                       "Crypt::Rijndael::encrypt",
494     # But at this point we're committed to generating the *same* C code that
495     # the current version of ParseXS.pm does.  So we're declaring it as 'our'.
496     $ALIAS  = grep(/^\s*ALIAS\s*:/,  @{ $self->{line} });
497
498     my $INTERFACE  = grep(/^\s*INTERFACE\s*:/,  @{ $self->{line} });
499
500     $xsreturn = 1 if $EXPLICIT_RETURN;
501
502     $externC = $externC ? qq[extern "C"] : "";
503
504     # print function header
505     print Q(<<"EOF");
506 #$externC
507 #XS_EUPXS(XS_${Full_func_name}); /* prototype to pass -Wmissing-prototypes */
508 #XS_EUPXS(XS_${Full_func_name})
509 #[[
510 #    dVAR; dXSARGS;
511 EOF
512     print Q(<<"EOF") if $ALIAS;
513 #    dXSI32;
514 EOF
515     print Q(<<"EOF") if $INTERFACE;
516 #    dXSFUNCTION($self->{ret_type});
517 EOF
518
519     $self->{cond} = set_cond($ellipsis, $min_args, $num_args);
520
521     print Q(<<"EOF") if $self->{except};
522 #    char errbuf[1024];
523 #    *errbuf = '\\0';
524 EOF
525
526     if($self->{cond}) {
527       print Q(<<"EOF");
528 #    if ($self->{cond})
529 #       croak_xs_usage(cv,  "$report_args");
530 EOF
531     }
532     else {
533     # cv likely to be unused
534     print Q(<<"EOF");
535 #    PERL_UNUSED_VAR(cv); /* -W */
536 EOF
537     }
538
539     #gcc -Wall: if an xsub has PPCODE is used
540     #it is possible none of ST, XSRETURN or XSprePUSH macros are used
541     #hence 'ax' (setup by dXSARGS) is unused
542     #XXX: could breakup the dXSARGS; into dSP;dMARK;dITEMS
543     #but such a move could break third-party extensions
544     print Q(<<"EOF") if $PPCODE;
545 #    PERL_UNUSED_VAR(ax); /* -Wall */
546 EOF
547
548     print Q(<<"EOF") if $PPCODE;
549 #    SP -= items;
550 EOF
551
552     # Now do a block of some sort.
553
554     $self->{condnum} = 0;
555     $self->{cond} = '';            # last CASE: conditional
556     push(@{ $self->{line} }, "$END:");
557     push(@{ $self->{line_no} }, $self->{line_no}->[-1]);
558     $_ = '';
559     check_conditional_preprocessor_statements();
560     while (@{ $self->{line} }) {
561
562       $self->CASE_handler($_) if $self->check_keyword("CASE");
563       print Q(<<"EOF");
564 #   $self->{except} [[
565 EOF
566
567       # do initialization of input variables
568       $self->{thisdone} = 0;
569       $self->{retvaldone} = 0;
570       $self->{deferred} = "";
571       %{ $self->{arg_list} } = ();
572       $self->{gotRETVAL} = 0;
573       $self->INPUT_handler($_);
574       $self->process_keyword("INPUT|PREINIT|INTERFACE_MACRO|C_ARGS|ALIAS|ATTRS|PROTOTYPE|SCOPE|OVERLOAD");
575
576       print Q(<<"EOF") if $self->{ScopeThisXSUB};
577 #   ENTER;
578 #   [[
579 EOF
580
581       if (!$self->{thisdone} && defined($class)) {
582         if (defined($static) or $func_name eq 'new') {
583           print "\tchar *";
584           $self->{var_types}->{"CLASS"} = "char *";
585           generate_init( {
586             type          => "char *",
587             num           => 1,
588             var           => "CLASS",
589             printed_name  => undef,
590           } );
591         }
592         else {
593           print "\t$class *";
594           $self->{var_types}->{"THIS"} = "$class *";
595           generate_init( {
596             type          => "$class *",
597             num           => 1,
598             var           => "THIS",
599             printed_name  => undef,
600           } );
601         }
602       }
603
604       # These are set if OUTPUT is found and/or CODE using RETVAL
605       $self->{have_OUTPUT} = $self->{have_CODE_with_RETVAL} = 0;
606
607       my ($wantRETVAL);
608       # do code
609       if (/^\s*NOT_IMPLEMENTED_YET/) {
610         print "\n\tPerl_croak(aTHX_ \"$pname: not implemented yet\");\n";
611         $_ = '';
612       }
613       else {
614         if ($self->{ret_type} ne "void") {
615           print "\t" . map_type($self, $self->{ret_type}, 'RETVAL') . ";\n"
616             if !$self->{retvaldone};
617           $self->{args_match}->{"RETVAL"} = 0;
618           $self->{var_types}->{"RETVAL"} = $self->{ret_type};
619           my $outputmap = $self->{typemap}->get_outputmap( ctype => $self->{ret_type} );
620           print "\tdXSTARG;\n"
621             if $self->{optimize} and $outputmap and $outputmap->targetable;
622         }
623
624         if (@fake_INPUT or @fake_INPUT_pre) {
625           unshift @{ $self->{line} }, @fake_INPUT_pre, @fake_INPUT, $_;
626           $_ = "";
627           $self->{processing_arg_with_types} = 1;
628           $self->INPUT_handler($_);
629         }
630         print $self->{deferred};
631
632         $self->process_keyword("INIT|ALIAS|ATTRS|PROTOTYPE|INTERFACE_MACRO|INTERFACE|C_ARGS|OVERLOAD");
633
634         if ($self->check_keyword("PPCODE")) {
635           $self->print_section();
636           $self->death("PPCODE must be last thing") if @{ $self->{line} };
637           print "\tLEAVE;\n" if $self->{ScopeThisXSUB};
638           print "\tPUTBACK;\n\treturn;\n";
639         }
640         elsif ($self->check_keyword("CODE")) {
641           my $consumed_code = $self->print_section();
642           if ($consumed_code =~ /\bRETVAL\b/) {
643             $self->{have_CODE_with_RETVAL} = 1;
644           }
645         }
646         elsif (defined($class) and $func_name eq "DESTROY") {
647           print "\n\t";
648           print "delete THIS;\n";
649         }
650         else {
651           print "\n\t";
652           if ($self->{ret_type} ne "void") {
653             print "RETVAL = ";
654             $wantRETVAL = 1;
655           }
656           if (defined($static)) {
657             if ($func_name eq 'new') {
658               $func_name = "$class";
659             }
660             else {
661               print "${class}::";
662             }
663           }
664           elsif (defined($class)) {
665             if ($func_name eq 'new') {
666               $func_name .= " $class";
667             }
668             else {
669               print "THIS->";
670             }
671           }
672           $func_name =~ s/^\Q$args{'s'}//
673             if exists $args{'s'};
674           $func_name = 'XSFUNCTION' if $self->{interface};
675           print "$func_name($self->{func_args});\n";
676         }
677       }
678
679       # do output variables
680       $self->{gotRETVAL} = 0;        # 1 if RETVAL seen in OUTPUT section;
681       undef $self->{RETVAL_code} ;    # code to set RETVAL (from OUTPUT section);
682       # $wantRETVAL set if 'RETVAL =' autogenerated
683       ($wantRETVAL, $self->{ret_type}) = (0, 'void') if $RETVAL_no_return;
684       undef %{ $self->{outargs} };
685
686       $self->process_keyword("POSTCALL|OUTPUT|ALIAS|ATTRS|PROTOTYPE|OVERLOAD");
687
688       # A CODE section with RETVAL, but no OUTPUT? FAIL!
689       if ($self->{have_CODE_with_RETVAL} and not $self->{have_OUTPUT} and $self->{ret_type} ne 'void') {
690         $self->Warn("Warning: Found a 'CODE' section which seems to be using 'RETVAL' but no 'OUTPUT' section.");
691       }
692
693       generate_output( {
694         type        => $self->{var_types}->{$_},
695         num         => $self->{args_match}->{$_},
696         var         => $_,
697         do_setmagic => $self->{DoSetMagic},
698         do_push     => undef,
699       } ) for grep $self->{in_out}->{$_} =~ /OUT$/, keys %{ $self->{in_out} };
700
701       my $prepush_done;
702       # all OUTPUT done, so now push the return value on the stack
703       if ($self->{gotRETVAL} && $self->{RETVAL_code}) {
704         print "\t$self->{RETVAL_code}\n";
705       }
706       elsif ($self->{gotRETVAL} || $wantRETVAL) {
707         my $outputmap = $self->{typemap}->get_outputmap( ctype => $self->{ret_type} );
708         my $t = $self->{optimize} && $outputmap && $outputmap->targetable;
709         # Although the '$var' declared in the next line is never explicitly
710         # used within this 'elsif' block, commenting it out leads to
711         # disaster, starting with the first 'eval qq' inside the 'elsif' block
712         # below.
713         # It appears that this is related to the fact that at this point the
714         # value of $t is a reference to an array whose [2] element includes
715         # '$var' as a substring:
716         # <i> <> <(IV)$var>
717         my $var = 'RETVAL';
718         my $type = $self->{ret_type};
719
720         if ($t and not $t->{with_size} and $t->{type} eq 'p') {
721           # PUSHp corresponds to setpvn.  Treat setpv directly
722           my $what = eval qq("$t->{what}");
723           warn $@ if $@;
724
725           print "\tsv_setpv(TARG, $what); XSprePUSH; PUSHTARG;\n";
726           $prepush_done = 1;
727         }
728         elsif ($t) {
729           my $what = eval qq("$t->{what}");
730           warn $@ if $@;
731
732           my $tsize = $t->{what_size};
733           $tsize = '' unless defined $tsize;
734           $tsize = eval qq("$tsize");
735           warn $@ if $@;
736           print "\tXSprePUSH; PUSH$t->{type}($what$tsize);\n";
737           $prepush_done = 1;
738         }
739         else {
740           # RETVAL almost never needs SvSETMAGIC()
741           generate_output( {
742             type        => $self->{ret_type},
743             num         => 0,
744             var         => 'RETVAL',
745             do_setmagic => 0,
746             do_push     => undef,
747           } );
748         }
749       }
750
751       $xsreturn = 1 if $self->{ret_type} ne "void";
752       my $num = $xsreturn;
753       my $c = @{ $outlist_ref };
754       print "\tXSprePUSH;" if $c and not $prepush_done;
755       print "\tEXTEND(SP,$c);\n" if $c;
756       $xsreturn += $c;
757       generate_output( {
758         type        => $self->{var_types}->{$_},
759         num         => $num++,
760         var         => $_,
761         do_setmagic => 0,
762         do_push     => 1,
763       } ) for @{ $outlist_ref };
764
765       # do cleanup
766       $self->process_keyword("CLEANUP|ALIAS|ATTRS|PROTOTYPE|OVERLOAD");
767
768       print Q(<<"EOF") if $self->{ScopeThisXSUB};
769 #   ]]
770 EOF
771       print Q(<<"EOF") if $self->{ScopeThisXSUB} and not $PPCODE;
772 #   LEAVE;
773 EOF
774
775       # print function trailer
776       print Q(<<"EOF");
777 #    ]]
778 EOF
779       print Q(<<"EOF") if $self->{except};
780 #    BEGHANDLERS
781 #    CATCHALL
782 #    sprintf(errbuf, "%s: %s\\tpropagated", Xname, Xreason);
783 #    ENDHANDLERS
784 EOF
785       if ($self->check_keyword("CASE")) {
786         $self->blurt("Error: No 'CASE:' at top of function")
787           unless $self->{condnum};
788         $_ = "CASE: $_";    # Restore CASE: label
789         next;
790       }
791       last if $_ eq "$END:";
792       $self->death(/^$self->{BLOCK_re}/o ? "Misplaced '$1:'" : "Junk at end of function ($_)");
793     }
794
795     print Q(<<"EOF") if $self->{except};
796 #    if (errbuf[0])
797 #    Perl_croak(aTHX_ errbuf);
798 EOF
799
800     if ($xsreturn) {
801       print Q(<<"EOF") unless $PPCODE;
802 #    XSRETURN($xsreturn);
803 EOF
804     }
805     else {
806       print Q(<<"EOF") unless $PPCODE;
807 #    XSRETURN_EMPTY;
808 EOF
809     }
810
811     print Q(<<"EOF");
812 #]]
813 #
814 EOF
815
816     $self->{newXS} = "newXS";
817     $self->{proto} = "";
818
819     # Build the prototype string for the xsub
820     if ($self->{ProtoThisXSUB}) {
821       $self->{newXS} = "newXSproto_portable";
822
823       if ($self->{ProtoThisXSUB} eq 2) {
824         # User has specified empty prototype
825       }
826       elsif ($self->{ProtoThisXSUB} eq 1) {
827         my $s = ';';
828         if ($min_args < $num_args)  {
829           $s = '';
830           $self->{proto_arg}->[$min_args] .= ";";
831         }
832         push @{ $self->{proto_arg} }, "$s\@"
833           if $ellipsis;
834
835         $self->{proto} = join ("", grep defined, @{ $self->{proto_arg} } );
836       }
837       else {
838         # User has specified a prototype
839         $self->{proto} = $self->{ProtoThisXSUB};
840       }
841       $self->{proto} = qq{, "$self->{proto}"};
842     }
843
844     if (%{ $self->{XsubAliases} }) {
845       $self->{XsubAliases}->{$pname} = 0
846         unless defined $self->{XsubAliases}->{$pname};
847       while ( my ($xname, $value) = each %{ $self->{XsubAliases} }) {
848         push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
849 #        cv = $self->{newXS}(\"$xname\", XS_$Full_func_name, file$self->{proto});
850 #        XSANY.any_i32 = $value;
851 EOF
852       }
853     }
854     elsif (@{ $self->{Attributes} }) {
855       push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
856 #        cv = $self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});
857 #        apply_attrs_string("$Package", cv, "@{ $self->{Attributes} }", 0);
858 EOF
859     }
860     elsif ($self->{interface}) {
861       while ( my ($yname, $value) = each %{ $self->{Interfaces} }) {
862         $yname = "$Package\::$yname" unless $yname =~ /::/;
863         push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
864 #        cv = $self->{newXS}(\"$yname\", XS_$Full_func_name, file$self->{proto});
865 #        $self->{interface_macro_set}(cv,$value);
866 EOF
867       }
868     }
869     elsif($self->{newXS} eq 'newXS'){ # work around P5NCI's empty newXS macro
870       push(@{ $self->{InitFileCode} },
871        "        $self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});\n");
872     }
873     else {
874       push(@{ $self->{InitFileCode} },
875        "        (void)$self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});\n");
876     }
877   } # END 'PARAGRAPH' 'while' loop
878
879   if ($self->{Overload}) { # make it findable with fetchmethod
880     print Q(<<"EOF");
881 #XS_EUPXS(XS_$self->{Packid}_nil); /* prototype to pass -Wmissing-prototypes */
882 #XS_EUPXS(XS_$self->{Packid}_nil)
883 #{
884 #   dXSARGS;
885 #   XSRETURN_EMPTY;
886 #}
887 #
888 EOF
889     unshift(@{ $self->{InitFileCode} }, <<"MAKE_FETCHMETHOD_WORK");
890     /* Making a sub named "${Package}::()" allows the package */
891     /* to be findable via fetchmethod(), and causes */
892     /* overload::Overloaded("${Package}") to return true. */
893     (void)$self->{newXS}("${Package}::()", XS_$self->{Packid}_nil, file$self->{proto});
894 MAKE_FETCHMETHOD_WORK
895   }
896
897   # print initialization routine
898
899   print Q(<<"EOF");
900 ##ifdef __cplusplus
901 #extern "C"
902 ##endif
903 EOF
904
905   print Q(<<"EOF");
906 #XS_EXTERNAL(boot_$self->{Module_cname}); /* prototype to pass -Wmissing-prototypes */
907 #XS_EXTERNAL(boot_$self->{Module_cname})
908 EOF
909
910   print Q(<<"EOF");
911 #[[
912 #    dVAR; dXSARGS;
913 EOF
914
915   #Under 5.8.x and lower, newXS is declared in proto.h as expecting a non-const
916   #file name argument. If the wrong qualifier is used, it causes breakage with
917   #C++ compilers and warnings with recent gcc.
918   #-Wall: if there is no $Full_func_name there are no xsubs in this .xs
919   #so 'file' is unused
920   print Q(<<"EOF") if $Full_func_name;
921 ##if (PERL_REVISION == 5 && PERL_VERSION < 9)
922 #    char* file = __FILE__;
923 ##else
924 #    const char* file = __FILE__;
925 ##endif
926 EOF
927
928   print Q("#\n");
929
930   print Q(<<"EOF");
931 #    PERL_UNUSED_VAR(cv); /* -W */
932 #    PERL_UNUSED_VAR(items); /* -W */
933 ##ifdef XS_APIVERSION_BOOTCHECK
934 #    XS_APIVERSION_BOOTCHECK;
935 ##endif
936 EOF
937
938   print Q(<<"EOF") if $self->{WantVersionChk};
939 #    XS_VERSION_BOOTCHECK;
940 #
941 EOF
942
943   print Q(<<"EOF") if defined $self->{xsubaliases} or defined $self->{interfaces};
944 #    {
945 #        CV * cv;
946 #
947 EOF
948
949   print Q(<<"EOF") if ($self->{Overload});
950 #    /* register the overloading (type 'A') magic */
951 #    PL_amagic_generation++;
952 #    /* The magic for overload gets a GV* via gv_fetchmeth as */
953 #    /* mentioned above, and looks in the SV* slot of it for */
954 #    /* the "fallback" status. */
955 #    sv_setsv(
956 #        get_sv( "${Package}::()", TRUE ),
957 #        $self->{Fallback}
958 #    );
959 EOF
960
961   print @{ $self->{InitFileCode} };
962
963   print Q(<<"EOF") if defined $self->{xsubaliases} or defined $self->{interfaces};
964 #    }
965 EOF
966
967   if (@{ $BootCode_ref }) {
968     print "\n    /* Initialisation Section */\n\n";
969     @{ $self->{line} } = @{ $BootCode_ref };
970     $self->print_section();
971     print "\n    /* End of Initialisation Section */\n\n";
972   }
973
974   print Q(<<'EOF');
975 ##if (PERL_REVISION == 5 && PERL_VERSION >= 9)
976 #  if (PL_unitcheckav)
977 #       call_list(PL_scopestack_ix, PL_unitcheckav);
978 ##endif
979 EOF
980
981   print Q(<<"EOF");
982 #    XSRETURN_YES;
983 #]]
984 #
985 EOF
986
987   warn("Please specify prototyping behavior for $self->{filename} (see perlxs manual)\n")
988     unless $self->{ProtoUsed};
989
990   chdir($orig_cwd);
991   select($orig_fh);
992   untie *PSEUDO_STDOUT if tied *PSEUDO_STDOUT;
993   close $self->{FH};
994
995   return 1;
996 }
997
998 sub report_error_count { $self->{errors} }
999
1000 # Input:  ($self, $_, @{ $self->{line} }) == unparsed input.
1001 # Output: ($_, @{ $self->{line} }) == (rest of line, following lines).
1002 # Return: the matched keyword if found, otherwise 0
1003 sub check_keyword {
1004   my $self = shift;
1005   $_ = shift(@{ $self->{line} }) while !/\S/ && @{ $self->{line} };
1006   s/^(\s*)($_[0])\s*:\s*(?:#.*)?/$1/s && $2;
1007 }
1008
1009 sub print_section {
1010   my $self = shift;
1011
1012   # the "do" is required for right semantics
1013   do { $_ = shift(@{ $self->{line} }) } while !/\S/ && @{ $self->{line} };
1014
1015   my $consumed_code = '';
1016
1017   print("#line ", $self->{line_no}->[@{ $self->{line_no} } - @{ $self->{line} } -1], " \"",
1018         escape_file_for_line_directive($self->{filepathname}), "\"\n")
1019     if $self->{WantLineNumbers} && !/^\s*#\s*line\b/ && !/^#if XSubPPtmp/;
1020   for (;  defined($_) && !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1021     print "$_\n";
1022     $consumed_code .= "$_\n";
1023   }
1024   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
1025
1026   return $consumed_code;
1027 }
1028
1029 sub merge_section {
1030   my $self = shift;
1031   my $in = '';
1032
1033   while (!/\S/ && @{ $self->{line} }) {
1034     $_ = shift(@{ $self->{line} });
1035   }
1036
1037   for (;  defined($_) && !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1038     $in .= "$_\n";
1039   }
1040   chomp $in;
1041   return $in;
1042 }
1043
1044 sub process_keyword {
1045   my($self, $pattern) = @_;
1046
1047   while (my $kwd = $self->check_keyword($pattern)) {
1048     my $method = $kwd . "_handler";
1049     $self->$method($_);
1050   }
1051 }
1052
1053 sub CASE_handler {
1054   my $self = shift;
1055   $_ = shift;
1056   $self->blurt("Error: 'CASE:' after unconditional 'CASE:'")
1057     if $self->{condnum} && $self->{cond} eq '';
1058   $self->{cond} = $_;
1059   trim_whitespace($self->{cond});
1060   print "   ", ($self->{condnum}++ ? " else" : ""), ($self->{cond} ? " if ($self->{cond})\n" : "\n");
1061   $_ = '';
1062 }
1063
1064 sub INPUT_handler {
1065   my $self = shift;
1066   $_ = shift;
1067   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1068     last if /^\s*NOT_IMPLEMENTED_YET/;
1069     next unless /\S/;        # skip blank lines
1070
1071     trim_whitespace($_);
1072     my $ln = $_;
1073
1074     # remove trailing semicolon if no initialisation
1075     s/\s*;$//g unless /[=;+].*\S/;
1076
1077     # Process the length(foo) declarations
1078     if (s/^([^=]*)\blength\(\s*(\w+)\s*\)\s*$/$1 XSauto_length_of_$2=NO_INIT/x) {
1079       print "\tSTRLEN\tSTRLEN_length_of_$2;\n";
1080       $self->{lengthof}->{$2} = undef;
1081       $self->{deferred} .= "\n\tXSauto_length_of_$2 = STRLEN_length_of_$2;\n";
1082     }
1083
1084     # check for optional initialisation code
1085     my $var_init = '';
1086     $var_init = $1 if s/\s*([=;+].*)$//s;
1087     $var_init =~ s/"/\\"/g;
1088     # *sigh* It's valid to supply explicit input typemaps in the argument list...
1089     my $is_overridden_typemap = $var_init =~ /ST\s*\(|\$arg\b/;
1090
1091     s/\s+/ /g;
1092     my ($var_type, $var_addr, $var_name) = /^(.*?[^&\s])\s*(\&?)\s*\b(\w+)$/s
1093       or $self->blurt("Error: invalid argument declaration '$ln'"), next;
1094
1095     # Check for duplicate definitions
1096     $self->blurt("Error: duplicate definition of argument '$var_name' ignored"), next
1097       if $self->{arg_list}->{$var_name}++
1098         or defined $self->{argtype_seen}->{$var_name} and not $self->{processing_arg_with_types};
1099
1100     $self->{thisdone} |= $var_name eq "THIS";
1101     $self->{retvaldone} |= $var_name eq "RETVAL";
1102     $self->{var_types}->{$var_name} = $var_type;
1103     # XXXX This check is a safeguard against the unfinished conversion of
1104     # generate_init().  When generate_init() is fixed,
1105     # one can use 2-args map_type() unconditionally.
1106     my $printed_name;
1107     if ($var_type =~ / \( \s* \* \s* \) /x) {
1108       # Function pointers are not yet supported with output_init()!
1109       print "\t" . map_type($self, $var_type, $var_name);
1110       $printed_name = 1;
1111     }
1112     else {
1113       print "\t" . map_type($self, $var_type, undef);
1114       $printed_name = 0;
1115     }
1116     $self->{var_num} = $self->{args_match}->{$var_name};
1117
1118     if ($self->{var_num}) {
1119       my $typemap = $self->{typemap}->get_typemap(ctype => $var_type);
1120       $self->death("Could not find a typemap for C type '$var_type'")
1121         if not $typemap and not $is_overridden_typemap;
1122       $self->{proto_arg}->[$self->{var_num}] = ($typemap && $typemap->proto) || "\$";
1123     }
1124     $self->{func_args} =~ s/\b($var_name)\b/&$1/ if $var_addr;
1125     if ($var_init =~ /^[=;]\s*NO_INIT\s*;?\s*$/
1126       or $self->{in_out}->{$var_name} and $self->{in_out}->{$var_name} =~ /^OUT/
1127       and $var_init !~ /\S/) {
1128       if ($printed_name) {
1129         print ";\n";
1130       }
1131       else {
1132         print "\t$var_name;\n";
1133       }
1134     }
1135     elsif ($var_init =~ /\S/) {
1136       output_init( {
1137         type          => $var_type,
1138         num           => $self->{var_num},
1139         var           => $var_name,
1140         init          => $var_init,
1141         printed_name  => $printed_name,
1142       } );
1143     }
1144     elsif ($self->{var_num}) {
1145       generate_init( {
1146         type          => $var_type,
1147         num           => $self->{var_num},
1148         var           => $var_name,
1149         printed_name  => $printed_name,
1150       } );
1151     }
1152     else {
1153       print ";\n";
1154     }
1155   }
1156 }
1157
1158 sub OUTPUT_handler {
1159   my $self = shift;
1160   $self->{have_OUTPUT} = 1;
1161
1162   $_ = shift;
1163   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1164     next unless /\S/;
1165     if (/^\s*SETMAGIC\s*:\s*(ENABLE|DISABLE)\s*/) {
1166       $self->{DoSetMagic} = ($1 eq "ENABLE" ? 1 : 0);
1167       next;
1168     }
1169     my ($outarg, $outcode) = /^\s*(\S+)\s*(.*?)\s*$/s;
1170     $self->blurt("Error: duplicate OUTPUT argument '$outarg' ignored"), next
1171       if $self->{outargs}->{$outarg}++;
1172     if (!$self->{gotRETVAL} and $outarg eq 'RETVAL') {
1173       # deal with RETVAL last
1174       $self->{RETVAL_code} = $outcode;
1175       $self->{gotRETVAL} = 1;
1176       next;
1177     }
1178     $self->blurt("Error: OUTPUT $outarg not an argument"), next
1179       unless defined($self->{args_match}->{$outarg});
1180     $self->blurt("Error: No input definition for OUTPUT argument '$outarg' - ignored"), next
1181       unless defined $self->{var_types}->{$outarg};
1182     $self->{var_num} = $self->{args_match}->{$outarg};
1183     if ($outcode) {
1184       print "\t$outcode\n";
1185       print "\tSvSETMAGIC(ST(" , $self->{var_num} - 1 , "));\n" if $self->{DoSetMagic};
1186     }
1187     else {
1188       generate_output( {
1189         type        => $self->{var_types}->{$outarg},
1190         num         => $self->{var_num},
1191         var         => $outarg,
1192         do_setmagic => $self->{DoSetMagic},
1193         do_push     => undef,
1194       } );
1195     }
1196     delete $self->{in_out}->{$outarg}     # No need to auto-OUTPUT
1197       if exists $self->{in_out}->{$outarg} and $self->{in_out}->{$outarg} =~ /OUT$/;
1198   }
1199 }
1200
1201 sub C_ARGS_handler {
1202   my $self = shift;
1203   $_ = shift;
1204   my $in = $self->merge_section();
1205
1206   trim_whitespace($in);
1207   $self->{func_args} = $in;
1208 }
1209
1210 sub INTERFACE_MACRO_handler {
1211   my $self = shift;
1212   $_ = shift;
1213   my $in = $self->merge_section();
1214
1215   trim_whitespace($in);
1216   if ($in =~ /\s/) {        # two
1217     ($self->{interface_macro}, $self->{interface_macro_set}) = split ' ', $in;
1218   }
1219   else {
1220     $self->{interface_macro} = $in;
1221     $self->{interface_macro_set} = 'UNKNOWN_CVT'; # catch later
1222   }
1223   $self->{interface} = 1;        # local
1224   $self->{interfaces} = 1;        # global
1225 }
1226
1227 sub INTERFACE_handler {
1228   my $self = shift;
1229   $_ = shift;
1230   my $in = $self->merge_section();
1231
1232   trim_whitespace($in);
1233
1234   foreach (split /[\s,]+/, $in) {
1235     my $iface_name = $_;
1236     $iface_name =~ s/^$self->{Prefix}//;
1237     $self->{Interfaces}->{$iface_name} = $_;
1238   }
1239   print Q(<<"EOF");
1240 #    XSFUNCTION = $self->{interface_macro}($self->{ret_type},cv,XSANY.any_dptr);
1241 EOF
1242   $self->{interface} = 1;        # local
1243   $self->{interfaces} = 1;        # global
1244 }
1245
1246 sub CLEANUP_handler {
1247   my $self = shift;
1248   $self->print_section();
1249 }
1250
1251 sub PREINIT_handler {
1252   my $self = shift;
1253   $self->print_section();
1254 }
1255
1256 sub POSTCALL_handler {
1257   my $self = shift;
1258   $self->print_section();
1259 }
1260
1261 sub INIT_handler {
1262   my $self = shift;
1263   $self->print_section();
1264 }
1265
1266 sub get_aliases {
1267   my $self = shift;
1268   my ($line) = @_;
1269   my ($orig) = $line;
1270
1271   # Parse alias definitions
1272   # format is
1273   #    alias = value alias = value ...
1274
1275   while ($line =~ s/^\s*([\w:]+)\s*=\s*(\w+)\s*//) {
1276     my ($alias, $value) = ($1, $2);
1277     my $orig_alias = $alias;
1278
1279     # check for optional package definition in the alias
1280     $alias = $self->{Packprefix} . $alias if $alias !~ /::/;
1281
1282     # check for duplicate alias name & duplicate value
1283     Warn( $self, "Warning: Ignoring duplicate alias '$orig_alias'")
1284       if defined $self->{XsubAliases}->{$alias};
1285
1286     Warn( $self, "Warning: Aliases '$orig_alias' and '$self->{XsubAliasValues}->{$value}' have identical values")
1287       if $self->{XsubAliasValues}->{$value};
1288
1289     $self->{xsubaliases} = 1;
1290     $self->{XsubAliases}->{$alias} = $value;
1291     $self->{XsubAliasValues}->{$value} = $orig_alias;
1292   }
1293
1294   blurt( $self, "Error: Cannot parse ALIAS definitions from '$orig'")
1295     if $line;
1296 }
1297
1298 sub ATTRS_handler {
1299   my $self = shift;
1300   $_ = shift;
1301
1302   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1303     next unless /\S/;
1304     trim_whitespace($_);
1305     push @{ $self->{Attributes} }, $_;
1306   }
1307 }
1308
1309 sub ALIAS_handler {
1310   my $self = shift;
1311   $_ = shift;
1312
1313   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1314     next unless /\S/;
1315     trim_whitespace($_);
1316     $self->get_aliases($_) if $_;
1317   }
1318 }
1319
1320 sub OVERLOAD_handler {
1321   my $self = shift;
1322   $_ = shift;
1323
1324   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1325     next unless /\S/;
1326     trim_whitespace($_);
1327     while ( s/^\s*([\w:"\\)\+\-\*\/\%\<\>\.\&\|\^\!\~\{\}\=]+)\s*//) {
1328       $self->{Overload} = 1 unless $self->{Overload};
1329       my $overload = "$Package\::(".$1;
1330       push(@{ $self->{InitFileCode} },
1331        "        (void)$self->{newXS}(\"$overload\", XS_$Full_func_name, file$self->{proto});\n");
1332     }
1333   }
1334 }
1335
1336 sub FALLBACK_handler {
1337   my $self = shift;
1338   $_ = shift;
1339
1340   # the rest of the current line should contain either TRUE,
1341   # FALSE or UNDEF
1342
1343   trim_whitespace($_);
1344   my %map = (
1345     TRUE => "&PL_sv_yes", 1 => "&PL_sv_yes",
1346     FALSE => "&PL_sv_no", 0 => "&PL_sv_no",
1347     UNDEF => "&PL_sv_undef",
1348   );
1349
1350   # check for valid FALLBACK value
1351   $self->death("Error: FALLBACK: TRUE/FALSE/UNDEF") unless exists $map{uc $_};
1352
1353   $self->{Fallback} = $map{uc $_};
1354 }
1355
1356
1357 sub REQUIRE_handler {
1358   my $self = shift;
1359   # the rest of the current line should contain a version number
1360   my $Ver = shift;
1361
1362   trim_whitespace($Ver);
1363
1364   $self->death("Error: REQUIRE expects a version number")
1365     unless $Ver;
1366
1367   # check that the version number is of the form n.n
1368   $self->death("Error: REQUIRE: expected a number, got '$Ver'")
1369     unless $Ver =~ /^\d+(\.\d*)?/;
1370
1371   $self->death("Error: xsubpp $Ver (or better) required--this is only $VERSION.")
1372     unless $VERSION >= $Ver;
1373 }
1374
1375 sub VERSIONCHECK_handler {
1376   my $self = shift;
1377   $_ = shift;
1378
1379   # the rest of the current line should contain either ENABLE or
1380   # DISABLE
1381
1382   trim_whitespace($_);
1383
1384   # check for ENABLE/DISABLE
1385   $self->death("Error: VERSIONCHECK: ENABLE/DISABLE")
1386     unless /^(ENABLE|DISABLE)/i;
1387
1388   $self->{WantVersionChk} = 1 if $1 eq 'ENABLE';
1389   $self->{WantVersionChk} = 0 if $1 eq 'DISABLE';
1390
1391 }
1392
1393 sub PROTOTYPE_handler {
1394   my $self = shift;
1395   $_ = shift;
1396
1397   my $specified;
1398
1399   $self->death("Error: Only 1 PROTOTYPE definition allowed per xsub")
1400     if $self->{proto_in_this_xsub}++;
1401
1402   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1403     next unless /\S/;
1404     $specified = 1;
1405     trim_whitespace($_);
1406     if ($_ eq 'DISABLE') {
1407       $self->{ProtoThisXSUB} = 0;
1408     }
1409     elsif ($_ eq 'ENABLE') {
1410       $self->{ProtoThisXSUB} = 1;
1411     }
1412     else {
1413       # remove any whitespace
1414       s/\s+//g;
1415       $self->death("Error: Invalid prototype '$_'")
1416         unless valid_proto_string($_);
1417       $self->{ProtoThisXSUB} = C_string($_);
1418     }
1419   }
1420
1421   # If no prototype specified, then assume empty prototype ""
1422   $self->{ProtoThisXSUB} = 2 unless $specified;
1423
1424   $self->{ProtoUsed} = 1;
1425 }
1426
1427 sub SCOPE_handler {
1428   my $self = shift;
1429   $_ = shift;
1430
1431   $self->death("Error: Only 1 SCOPE declaration allowed per xsub")
1432     if $self->{scope_in_this_xsub}++;
1433
1434   trim_whitespace($_);
1435   $self->death("Error: SCOPE: ENABLE/DISABLE")
1436       unless /^(ENABLE|DISABLE)\b/i;
1437   $self->{ScopeThisXSUB} = ( uc($1) eq 'ENABLE' );
1438 }
1439
1440 sub PROTOTYPES_handler {
1441   my $self = shift;
1442   $_ = shift;
1443
1444   # the rest of the current line should contain either ENABLE or
1445   # DISABLE
1446
1447   trim_whitespace($_);
1448
1449   # check for ENABLE/DISABLE
1450   $self->death("Error: PROTOTYPES: ENABLE/DISABLE")
1451     unless /^(ENABLE|DISABLE)/i;
1452
1453   $self->{WantPrototypes} = 1 if $1 eq 'ENABLE';
1454   $self->{WantPrototypes} = 0 if $1 eq 'DISABLE';
1455   $self->{ProtoUsed} = 1;
1456 }
1457
1458 sub EXPORT_XSUB_SYMBOLS_handler {
1459   my $self = shift;
1460   $_ = shift;
1461
1462   # the rest of the current line should contain either ENABLE or
1463   # DISABLE
1464
1465   trim_whitespace($_);
1466
1467   # check for ENABLE/DISABLE
1468   $self->death("Error: EXPORT_XSUB_SYMBOLS: ENABLE/DISABLE")
1469     unless /^(ENABLE|DISABLE)/i;
1470
1471   my $xs_impl = $1 eq 'ENABLE' ? 'XS_EXTERNAL' : 'XS_INTERNAL';
1472
1473   print Q(<<"EOF");
1474 ##undef XS_EUPXS
1475 ##if defined(PERL_EUPXS_ALWAYS_EXPORT)
1476 ##  define XS_EUPXS(name) XS_EXTERNAL(name)
1477 ##elif defined(PERL_EUPXS_NEVER_EXPORT)
1478 ##  define XS_EUPXS(name) XS_INTERNAL(name)
1479 ##else
1480 ##  define XS_EUPXS(name) $xs_impl(name)
1481 ##endif
1482 EOF
1483 }
1484
1485
1486 sub PushXSStack {
1487   my $self = shift;
1488   my %args = @_;
1489   # Save the current file context.
1490   push(@{ $self->{XSStack} }, {
1491           type            => 'file',
1492           LastLine        => $self->{lastline},
1493           LastLineNo      => $self->{lastline_no},
1494           Line            => $self->{line},
1495           LineNo          => $self->{line_no},
1496           Filename        => $self->{filename},
1497           Filepathname    => $self->{filepathname},
1498           Handle          => $self->{FH},
1499           IsPipe          => scalar($self->{filename} =~ /\|\s*$/),
1500           %args,
1501          });
1502
1503 }
1504
1505 sub INCLUDE_handler {
1506   my $self = shift;
1507   $_ = shift;
1508   # the rest of the current line should contain a valid filename
1509
1510   trim_whitespace($_);
1511
1512   $self->death("INCLUDE: filename missing")
1513     unless $_;
1514
1515   $self->death("INCLUDE: output pipe is illegal")
1516     if /^\s*\|/;
1517
1518   # simple minded recursion detector
1519   $self->death("INCLUDE loop detected")
1520     if $self->{IncludedFiles}->{$_};
1521
1522   ++$self->{IncludedFiles}->{$_} unless /\|\s*$/;
1523
1524   if (/\|\s*$/ && /^\s*perl\s/) {
1525     Warn( $self, "The INCLUDE directive with a command is discouraged." .
1526           " Use INCLUDE_COMMAND instead! In particular using 'perl'" .
1527           " in an 'INCLUDE: ... |' directive is not guaranteed to pick" .
1528           " up the correct perl. The INCLUDE_COMMAND directive allows" .
1529           " the use of \$^X as the currently running perl, see" .
1530           " 'perldoc perlxs' for details.");
1531   }
1532
1533   $self->PushXSStack();
1534
1535   $self->{FH} = Symbol::gensym();
1536
1537   # open the new file
1538   open($self->{FH}, $_) or $self->death("Cannot open '$_': $!");
1539
1540   print Q(<<"EOF");
1541 #
1542 #/* INCLUDE:  Including '$_' from '$self->{filename}' */
1543 #
1544 EOF
1545
1546   $self->{filename} = $_;
1547   $self->{filepathname} = ( $^O =~ /^mswin/i )
1548                           ? qq($self->{dir}/$self->{filename}) # See CPAN RT #61908: gcc doesn't like backslashes on win32?
1549                           : File::Spec->catfile($self->{dir}, $self->{filename});
1550
1551   # Prime the pump by reading the first
1552   # non-blank line
1553
1554   # skip leading blank lines
1555   while (readline($self->{FH})) {
1556     last unless /^\s*$/;
1557   }
1558
1559   $self->{lastline} = $_;
1560   $self->{lastline_no} = $.;
1561 }
1562
1563 sub QuoteArgs {
1564   my $cmd = shift;
1565   my @args = split /\s+/, $cmd;
1566   $cmd = shift @args;
1567   for (@args) {
1568     $_ = q(").$_.q(") if !/^\"/ && length($_) > 0;
1569   }
1570   return join (' ', ($cmd, @args));
1571 }
1572
1573 sub INCLUDE_COMMAND_handler {
1574   my $self = shift;
1575   $_ = shift;
1576   # the rest of the current line should contain a valid command
1577
1578   trim_whitespace($_);
1579
1580   $_ = QuoteArgs($_) if $^O eq 'VMS';
1581
1582   $self->death("INCLUDE_COMMAND: command missing")
1583     unless $_;
1584
1585   $self->death("INCLUDE_COMMAND: pipes are illegal")
1586     if /^\s*\|/ or /\|\s*$/;
1587
1588   $self->PushXSStack( IsPipe => 1 );
1589
1590   $self->{FH} = Symbol::gensym();
1591
1592   # If $^X is used in INCLUDE_COMMAND, we know it's supposed to be
1593   # the same perl interpreter as we're currently running
1594   s/^\s*\$\^X/$^X/;
1595
1596   # open the new file
1597   open ($self->{FH}, "-|", $_)
1598     or $self->death( $self, "Cannot run command '$_' to include its output: $!");
1599
1600   print Q(<<"EOF");
1601 #
1602 #/* INCLUDE_COMMAND:  Including output of '$_' from '$self->{filename}' */
1603 #
1604 EOF
1605
1606   $self->{filename} = $_;
1607   $self->{filepathname} = $self->{filename};
1608   #$self->{filepathname} =~ s/\"/\\"/g; # Fails? See CPAN RT #53938: MinGW Broken after 2.21
1609   $self->{filepathname} =~ s/\\/\\\\/g; # Works according to reporter of #53938
1610
1611   # Prime the pump by reading the first
1612   # non-blank line
1613
1614   # skip leading blank lines
1615   while (readline($self->{FH})) {
1616     last unless /^\s*$/;
1617   }
1618
1619   $self->{lastline} = $_;
1620   $self->{lastline_no} = $.;
1621 }
1622
1623 sub PopFile {
1624   my $self = shift;
1625
1626   return 0 unless $self->{XSStack}->[-1]{type} eq 'file';
1627
1628   my $data     = pop @{ $self->{XSStack} };
1629   my $ThisFile = $self->{filename};
1630   my $isPipe   = $data->{IsPipe};
1631
1632   --$self->{IncludedFiles}->{$self->{filename}}
1633     unless $isPipe;
1634
1635   close $self->{FH};
1636
1637   $self->{FH}         = $data->{Handle};
1638   # $filename is the leafname, which for some reason isused for diagnostic
1639   # messages, whereas $filepathname is the full pathname, and is used for
1640   # #line directives.
1641   $self->{filename}   = $data->{Filename};
1642   $self->{filepathname} = $data->{Filepathname};
1643   $self->{lastline}   = $data->{LastLine};
1644   $self->{lastline_no} = $data->{LastLineNo};
1645   @{ $self->{line} }       = @{ $data->{Line} };
1646   @{ $self->{line_no} }    = @{ $data->{LineNo} };
1647
1648   if ($isPipe and $? ) {
1649     --$self->{lastline_no};
1650     print STDERR "Error reading from pipe '$ThisFile': $! in $self->{filename}, line $self->{lastline_no}\n" ;
1651     exit 1;
1652   }
1653
1654   print Q(<<"EOF");
1655 #
1656 #/* INCLUDE: Returning to '$self->{filename}' from '$ThisFile' */
1657 #
1658 EOF
1659
1660   return 1;
1661 }
1662
1663 sub Q {
1664   my($text) = @_;
1665   $text =~ s/^#//gm;
1666   $text =~ s/\[\[/{/g;
1667   $text =~ s/\]\]/}/g;
1668   $text;
1669 }
1670
1671 # Read next xsub into @{ $self->{line} } from ($lastline, readline($self->{FH})).
1672 sub fetch_para {
1673   my $self = shift;
1674
1675   # parse paragraph
1676   $self->death("Error: Unterminated '#if/#ifdef/#ifndef'")
1677     if !defined $self->{lastline} && $self->{XSStack}->[-1]{type} eq 'if';
1678   @{ $self->{line} } = ();
1679   @{ $self->{line_no} } = ();
1680   return $self->PopFile() if !defined $self->{lastline};
1681
1682   if ($self->{lastline} =~
1683       /^MODULE\s*=\s*([\w:]+)(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/) {
1684     my $Module = $1;
1685     $Package = defined($2) ? $2 : ''; # keep -w happy
1686     $self->{Prefix}  = defined($3) ? $3 : ''; # keep -w happy
1687     $self->{Prefix} = quotemeta $self->{Prefix};
1688     ($self->{Module_cname} = $Module) =~ s/\W/_/g;
1689     ($self->{Packid} = $Package) =~ tr/:/_/;
1690     $self->{Packprefix} = $Package;
1691     $self->{Packprefix} .= "::" if $self->{Packprefix} ne "";
1692     $self->{lastline} = "";
1693   }
1694
1695   for (;;) {
1696     # Skip embedded PODs
1697     while ($self->{lastline} =~ /^=/) {
1698       while ($self->{lastline} = readline($self->{FH})) {
1699         last if ($self->{lastline} =~ /^=cut\s*$/);
1700       }
1701       $self->death("Error: Unterminated pod") unless $self->{lastline};
1702       $self->{lastline} = readline($self->{FH});
1703       chomp $self->{lastline};
1704       $self->{lastline} =~ s/^\s+$//;
1705     }
1706
1707     # This chunk of code strips out (and parses) embedded TYPEMAP blocks
1708     # which support a HEREdoc-alike block syntax.
1709     # This is special cased from the usual paragraph-handler logic
1710     # due to the HEREdoc-ish syntax.
1711     if ($self->{lastline} =~ /^TYPEMAP\s*:\s*<<\s*(?:(["'])(.+?)\1|([^\s'"]+))\s*;?\s*$/) {
1712       my $end_marker = quotemeta(defined($1) ? $2 : $3);
1713       my @tmaplines;
1714       while (1) {
1715         $self->{lastline} = readline($self->{FH});
1716         $self->death("Error: Unterminated typemap") if not defined $self->{lastline};
1717         last if $self->{lastline} =~ /^$end_marker\s*$/;
1718         push @tmaplines, $self->{lastline};
1719       }
1720
1721       my $tmapcode = join "", @tmaplines;
1722       my $tmap = ExtUtils::Typemaps->new(
1723         string => $tmapcode,
1724         lineno_offset => ($self->current_line_number()||0)+1,
1725         fake_filename => $self->{filename},
1726       );
1727       $self->{typemap}->merge(typemap => $tmap, replace => 1);
1728
1729       last unless defined($self->{lastline} = readline($self->{FH}));
1730       next;
1731     }
1732
1733     if ($self->{lastline} !~ /^\s*#/ ||
1734     # CPP directives:
1735     #    ANSI:    if ifdef ifndef elif else endif define undef
1736     #        line error pragma
1737     #    gcc:    warning include_next
1738     #   obj-c:    import
1739     #   others:    ident (gcc notes that some cpps have this one)
1740     $self->{lastline} =~ /^#[ \t]*(?:(?:if|ifn?def|elif|else|endif|define|undef|pragma|error|warning|line\s+\d+|ident)\b|(?:include(?:_next)?|import)\s*["<].*[>"])/) {
1741       last if $self->{lastline} =~ /^\S/ && @{ $self->{line} } && $self->{line}->[-1] eq "";
1742       push(@{ $self->{line} }, $self->{lastline});
1743       push(@{ $self->{line_no} }, $self->{lastline_no});
1744     }
1745
1746     # Read next line and continuation lines
1747     last unless defined($self->{lastline} = readline($self->{FH}));
1748     $self->{lastline_no} = $.;
1749     my $tmp_line;
1750     $self->{lastline} .= $tmp_line
1751       while ($self->{lastline} =~ /\\$/ && defined($tmp_line = readline($self->{FH})));
1752
1753     chomp $self->{lastline};
1754     $self->{lastline} =~ s/^\s+$//;
1755   }
1756   pop(@{ $self->{line} }), pop(@{ $self->{line_no} }) while @{ $self->{line} } && $self->{line}->[-1] eq "";
1757   1;
1758 }
1759
1760 sub output_init {
1761   my $argsref = shift;
1762   my ($type, $num, $var, $init, $printed_name) = (
1763     $argsref->{type},
1764     $argsref->{num},
1765     $argsref->{var},
1766     $argsref->{init},
1767     $argsref->{printed_name}
1768   );
1769   my $arg = "ST(" . ($num - 1) . ")";
1770
1771   if (  $init =~ /^=/  ) {
1772     if ($printed_name) {
1773       eval qq/print " $init\\n"/;
1774     }
1775     else {
1776       eval qq/print "\\t$var $init\\n"/;
1777     }
1778     warn $@ if $@;
1779   }
1780   else {
1781     if (  $init =~ s/^\+//  &&  $num  ) {
1782       generate_init( {
1783         type          => $type,
1784         num           => $num,
1785         var           => $var,
1786         printed_name  => $printed_name,
1787       } );
1788     }
1789     elsif ($printed_name) {
1790       print ";\n";
1791       $init =~ s/^;//;
1792     }
1793     else {
1794       eval qq/print "\\t$var;\\n"/;
1795       warn $@ if $@;
1796       $init =~ s/^;//;
1797     }
1798     $self->{deferred} .= eval qq/"\\n\\t$init\\n"/;
1799     warn $@ if $@;
1800   }
1801 }
1802
1803 sub generate_init {
1804   my $argsref = shift;
1805   my ($type, $num, $var, $printed_name) = (
1806     $argsref->{type},
1807     $argsref->{num},
1808     $argsref->{var},
1809     $argsref->{printed_name},
1810   );
1811   my $arg = "ST(" . ($num - 1) . ")";
1812   my ($argoff, $ntype);
1813   $argoff = $num - 1;
1814
1815   my $typemaps = $self->{typemap};
1816
1817   $type = tidy_type($type);
1818   $self->blurt("Error: '$type' not in typemap"), return
1819     unless $typemaps->get_typemap(ctype => $type);
1820
1821   ($ntype = $type) =~ s/\s*\*/Ptr/g;
1822   my $subtype;
1823   ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1824   my $typem = $typemaps->get_typemap(ctype => $type);
1825   my $xstype = $typem->xstype;
1826   $xstype =~ s/OBJ$/REF/ if $func_name =~ /DESTROY$/;
1827   if ($xstype eq 'T_PV' and exists $self->{lengthof}->{$var}) {
1828     print "\t$var" unless $printed_name;
1829     print " = ($type)SvPV($arg, STRLEN_length_of_$var);\n";
1830     die "default value not supported with length(NAME) supplied"
1831       if defined $self->{defaults}->{$var};
1832     return;
1833   }
1834   $type =~ tr/:/_/ unless $self->{hiertype};
1835
1836   my $inputmap = $typemaps->get_inputmap(xstype => $xstype);
1837   $self->blurt("Error: No INPUT definition for type '$type', typekind '" . $type->xstype . "' found"), return
1838     unless defined $inputmap;
1839
1840   my $expr = $inputmap->cleaned_code;
1841   # Note: This gruesome bit either needs heavy rethinking or documentation. I vote for the former. --Steffen
1842   if ($expr =~ /DO_ARRAY_ELEM/) {
1843     my $subtypemap  = $typemaps->get_typemap(ctype => $subtype);
1844     $self->blurt("Error: C type '$subtype' not in typemap"), return
1845       if not $subtypemap;
1846     my $subinputmap = $typemaps->get_inputmap(xstype => $subtypemap->xstype);
1847     $self->blurt("Error: No INPUT definition for type '$subtype', typekind '" . $subtypemap->xstype . "' found"), return
1848       unless $subinputmap;
1849     my $subexpr = $subinputmap->cleaned_code;
1850     $subexpr =~ s/\$type/\$subtype/g;
1851     $subexpr =~ s/ntype/subtype/g;
1852     $subexpr =~ s/\$arg/ST(ix_$var)/g;
1853     $subexpr =~ s/\n\t/\n\t\t/g;
1854     $subexpr =~ s/is not of (.*\")/[arg %d] is not of $1, ix_$var + 1/g;
1855     $subexpr =~ s/\$var/${var}[ix_$var - $argoff]/;
1856     $expr =~ s/DO_ARRAY_ELEM/$subexpr/;
1857   }
1858   if ($expr =~ m#/\*.*scope.*\*/#i) {  # "scope" in C comments
1859     $self->{ScopeThisXSUB} = 1;
1860   }
1861   if (defined($self->{defaults}->{$var})) {
1862     $expr =~ s/(\t+)/$1    /g;
1863     $expr =~ s/        /\t/g;
1864     if ($printed_name) {
1865       print ";\n";
1866     }
1867     else {
1868       eval qq/print "\\t$var;\\n"/;
1869       warn $@ if $@;
1870     }
1871     if ($self->{defaults}->{$var} eq 'NO_INIT') {
1872       $self->{deferred} .= eval qq/"\\n\\tif (items >= $num) {\\n$expr;\\n\\t}\\n"/;
1873     }
1874     else {
1875       $self->{deferred} .= eval qq/"\\n\\tif (items < $num)\\n\\t    $var = $self->{defaults}->{$var};\\n\\telse {\\n$expr;\\n\\t}\\n"/;
1876     }
1877     warn $@ if $@;
1878   }
1879   elsif ($self->{ScopeThisXSUB} or $expr !~ /^\s*\$var =/) {
1880     if ($printed_name) {
1881       print ";\n";
1882     }
1883     else {
1884       eval qq/print "\\t$var;\\n"/;
1885       warn $@ if $@;
1886     }
1887     $self->{deferred} .= eval qq/"\\n$expr;\\n"/;
1888     warn $@ if $@;
1889   }
1890   else {
1891     die "panic: do not know how to handle this branch for function pointers"
1892       if $printed_name;
1893     eval qq/print "$expr;\\n"/;
1894     warn $@ if $@;
1895   }
1896 }
1897
1898 sub generate_output {
1899   my $argsref = shift;
1900   my ($type, $num, $var, $do_setmagic, $do_push) = (
1901     $argsref->{type},
1902     $argsref->{num},
1903     $argsref->{var},
1904     $argsref->{do_setmagic},
1905     $argsref->{do_push}
1906   );
1907   my $arg = "ST(" . ($num - ($num != 0)) . ")";
1908   my $ntype;
1909
1910   my $typemaps = $self->{typemap};
1911
1912   $type = tidy_type($type);
1913   if ($type =~ /^array\(([^,]*),(.*)\)/) {
1914     print "\t$arg = sv_newmortal();\n";
1915     print "\tsv_setpvn($arg, (char *)$var, $2 * sizeof($1));\n";
1916     print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1917   }
1918   else {
1919     my $typemap   = $typemaps->get_typemap(ctype => $type);
1920     $self->blurt("Could not find a typemap for C type '$type'"), return
1921       if not $typemap;
1922     my $outputmap = $typemaps->get_outputmap(xstype => $typemap->xstype);
1923     $self->blurt("Error: No OUTPUT definition for type '$type', typekind '" . $typemap->xstype . "' found"), return
1924       unless $outputmap;
1925     ($ntype = $type) =~ s/\s*\*/Ptr/g;
1926     $ntype =~ s/\(\)//g;
1927     my $subtype;
1928     ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1929
1930     my $expr = $outputmap->cleaned_code;
1931     if ($expr =~ /DO_ARRAY_ELEM/) {
1932       my $subtypemap   = $typemaps->get_typemap(ctype => $subtype);
1933       $self->blurt("Could not find a typemap for C type '$subtype'"), return
1934         if not $subtypemap;
1935       my $suboutputmap = $typemaps->get_outputmap(xstype => $subtypemap->xstype);
1936       $self->blurt("Error: No OUTPUT definition for type '$subtype', typekind '" . $subtypemap->xstype . "' found"), return
1937         unless $suboutputmap;
1938       my $subexpr = $suboutputmap->cleaned_code;
1939       $subexpr =~ s/ntype/subtype/g;
1940       $subexpr =~ s/\$arg/ST(ix_$var)/g;
1941       $subexpr =~ s/\$var/${var}[ix_$var]/g;
1942       $subexpr =~ s/\n\t/\n\t\t/g;
1943       $expr =~ s/DO_ARRAY_ELEM\n/$subexpr/;
1944       eval "print qq\a$expr\a";
1945       warn $@ if $@;
1946       print "\t\tSvSETMAGIC(ST(ix_$var));\n" if $do_setmagic;
1947     }
1948     elsif ($var eq 'RETVAL') {
1949       if ($expr =~ /^\t\$arg = new/) {
1950         # We expect that $arg has refcnt 1, so we need to
1951         # mortalize it.
1952         eval "print qq\a$expr\a";
1953         warn $@ if $@;
1954         print "\tsv_2mortal(ST($num));\n";
1955         print "\tSvSETMAGIC(ST($num));\n" if $do_setmagic;
1956       }
1957       elsif ($expr =~ /^\s*\$arg\s*=/) {
1958         # We expect that $arg has refcnt >=1, so we need
1959         # to mortalize it!
1960         eval "print qq\a$expr\a";
1961         warn $@ if $@;
1962         print "\tsv_2mortal(ST(0));\n";
1963         print "\tSvSETMAGIC(ST(0));\n" if $do_setmagic;
1964       }
1965       else {
1966         # Just hope that the entry would safely write it
1967         # over an already mortalized value. By
1968         # coincidence, something like $arg = &sv_undef
1969         # works too.
1970         print "\tST(0) = sv_newmortal();\n";
1971         eval "print qq\a$expr\a";
1972         warn $@ if $@;
1973         # new mortals don't have set magic
1974       }
1975     }
1976     elsif ($do_push) {
1977       print "\tPUSHs(sv_newmortal());\n";
1978       $arg = "ST($num)";
1979       eval "print qq\a$expr\a";
1980       warn $@ if $@;
1981       print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1982     }
1983     elsif ($arg =~ /^ST\(\d+\)$/) {
1984       eval "print qq\a$expr\a";
1985       warn $@ if $@;
1986       print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1987     }
1988   }
1989 }
1990
1991 1;
1992
1993 # vim: ts=2 sw=2 et: