Upgrade to CGI.pm-3.48
[perl.git] / cpan / CGI / lib / CGI / Fast.pm
1 package CGI::Fast;
2 use strict;
3 $^W=1; # A way to say "use warnings" that's compatible with even older perls.
4
5 # See the bottom of this file for the POD documentation.  Search for the
6 # string '=head'.
7
8 # You can run this file through either pod2man or pod2html to produce pretty
9 # documentation in manual or html file format (these utilities are part of the
10 # Perl 5 distribution).
11
12 # Copyright 1995,1996, Lincoln D. Stein.  All rights reserved.
13 # It may be used and modified freely, but I do request that this copyright
14 # notice remain attached to the file.  You may modify this module as you
15 # wish, but if you redistribute a modified version, please attach a note
16 # listing the modifications you have made.
17
18 $CGI::Fast::VERSION='1.07';
19
20 use CGI;
21 use FCGI;
22 # use vars works like "our", but is compatible with older Perls.
23 use vars qw(
24     @ISA
25     $ignore
26 );
27 @ISA = ('CGI');
28
29 # workaround for known bug in libfcgi
30 while (($ignore) = each %ENV) { }
31
32 # override the initialization behavior so that
33 # state is NOT maintained between invocations
34 sub save_request {
35     # no-op
36 }
37
38 # If ENV{FCGI_SOCKET_PATH} is specified, we maintain a FCGI Request handle
39 # in this package variable.
40 use vars qw($Ext_Request);
41 BEGIN {
42    # If ENV{FCGI_SOCKET_PATH} is given, explicitly open the socket,
43    # and keep the request handle around from which to call Accept().
44    if ($ENV{FCGI_SOCKET_PATH}) {
45         my $path    = $ENV{FCGI_SOCKET_PATH};
46         my $backlog = $ENV{FCGI_LISTEN_QUEUE} || 100;
47         my $socket  = FCGI::OpenSocket( $path, $backlog );
48         $Ext_Request = FCGI::Request( \*STDIN, \*STDOUT, \*STDERR,
49                                         \%ENV, $socket, 1 );
50    }
51 }
52
53 # New is slightly different in that it calls FCGI's
54 # accept() method.
55 sub new {
56      my ($self, $initializer, @param) = @_;
57      unless (defined $initializer) {
58         if ($Ext_Request) {
59           return undef unless $Ext_Request->Accept() >= 0;
60         } else {
61          return undef unless FCGI::accept() >= 0;
62      }
63      }
64      CGI->_reset_globals;
65      $self->_setup_symbols(@CGI::SAVED_SYMBOLS) if @CGI::SAVED_SYMBOLS;
66      return $CGI::Q = $self->SUPER::new($initializer, @param);
67 }
68
69 1;
70
71 =head1 NAME
72
73 CGI::Fast - CGI Interface for Fast CGI
74
75 =head1 SYNOPSIS
76
77     use CGI::Fast qw(:standard);
78     $COUNTER = 0;
79     while (new CGI::Fast) {
80         print header;
81         print start_html("Fast CGI Rocks");
82         print
83             h1("Fast CGI Rocks"),
84             "Invocation number ",b($COUNTER++),
85             " PID ",b($$),".",
86             hr;
87         print end_html;
88     }
89
90 =head1 DESCRIPTION
91
92 CGI::Fast is a subclass of the CGI object created by CGI.pm.  It is
93 specialized to work well FCGI module, which greatly speeds up CGI
94 scripts by turning them into persistently running server processes.
95 Scripts that perform time-consuming initialization processes, such as
96 loading large modules or opening persistent database connections, will
97 see large performance improvements.
98
99 =head1 OTHER PIECES OF THE PUZZLE
100
101 In order to use CGI::Fast you'll need the FCGI module.  See
102 http://www.cpan.org/ for details.
103
104 =head1 WRITING FASTCGI PERL SCRIPTS
105
106 FastCGI scripts are persistent: one or more copies of the script
107 are started up when the server initializes, and stay around until
108 the server exits or they die a natural death.  After performing
109 whatever one-time initialization it needs, the script enters a
110 loop waiting for incoming connections, processing the request, and
111 waiting some more.
112
113 A typical FastCGI script will look like this:
114
115     #!/usr/bin/perl
116     use CGI::Fast;
117     &do_some_initialization();
118     while ($q = new CGI::Fast) {
119         &process_request($q);
120     }
121
122 Each time there's a new request, CGI::Fast returns a
123 CGI object to your loop.  The rest of the time your script
124 waits in the call to new().  When the server requests that
125 your script be terminated, new() will return undef.  You can
126 of course exit earlier if you choose.  A new version of the
127 script will be respawned to take its place (this may be
128 necessary in order to avoid Perl memory leaks in long-running
129 scripts).
130
131 CGI.pm's default CGI object mode also works.  Just modify the loop
132 this way:
133
134     while (new CGI::Fast) {
135         &process_request;
136     }
137
138 Calls to header(), start_form(), etc. will all operate on the
139 current request.
140
141 =head1 INSTALLING FASTCGI SCRIPTS
142
143 See the FastCGI developer's kit documentation for full details.  On
144 the Apache server, the following line must be added to srm.conf:
145
146     AddType application/x-httpd-fcgi .fcgi
147
148 FastCGI scripts must end in the extension .fcgi.  For each script you
149 install, you must add something like the following to srm.conf:
150
151     FastCgiServer /usr/etc/httpd/fcgi-bin/file_upload.fcgi -processes 2
152
153 This instructs Apache to launch two copies of file_upload.fcgi at
154 startup time.
155
156 =head1 USING FASTCGI SCRIPTS AS CGI SCRIPTS
157
158 Any script that works correctly as a FastCGI script will also work
159 correctly when installed as a vanilla CGI script.  However it will
160 not see any performance benefit.
161
162 =head1 EXTERNAL FASTCGI SERVER INVOCATION
163
164 FastCGI supports a TCP/IP transport mechanism which allows FastCGI scripts to run
165 external to the webserver, perhaps on a remote machine.  To configure the
166 webserver to connect to an external FastCGI server, you would add the following
167 to your srm.conf:
168
169     FastCgiExternalServer /usr/etc/httpd/fcgi-bin/file_upload.fcgi -host sputnik:8888
170
171 Two environment variables affect how the C<CGI::Fast> object is created,
172 allowing C<CGI::Fast> to be used as an external FastCGI server.  (See C<FCGI>
173 documentation for C<FCGI::OpenSocket> for more information.)
174
175 =over
176
177 =item FCGI_SOCKET_PATH
178
179 The address (TCP/IP) or path (UNIX Domain) of the socket the external FastCGI
180 script to which bind an listen for incoming connections from the web server.
181
182 =item FCGI_LISTEN_QUEUE
183
184 Maximum length of the queue of pending connections.
185
186 =back
187
188 For example:
189
190     #!/usr/local/bin/perl    # must be a FastCGI version of perl!
191     use CGI::Fast;
192     &do_some_initialization();
193     $ENV{FCGI_SOCKET_PATH} = "sputnik:8888";
194     $ENV{FCGI_LISTEN_QUEUE} = 100;
195     while ($q = new CGI::Fast) {
196         &process_request($q);
197     }
198
199 =head1 CAVEATS
200
201 I haven't tested this very much.
202
203 =head1 AUTHOR INFORMATION
204
205 Copyright 1996-1998, Lincoln D. Stein.  All rights reserved.
206
207 This library is free software; you can redistribute it and/or modify
208 it under the same terms as Perl itself.
209
210 Address bug reports and comments to: lstein@cshl.org
211
212 =head1 BUGS
213
214 This section intentionally left blank.
215
216 =head1 SEE ALSO
217
218 L<CGI::Carp>, L<CGI>
219
220 =cut