RE: [PATCH] use 5.010 is ugly; use 5.10.0 warns
[perl.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, the scalar arguments will
18 be first, and the list argument will follow.  (Note that there can ever
19 be only one such list argument.)  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for the elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use the parentheses, the simple (but occasionally
34 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  And whitespace
37 between the function and left parenthesis doesn't count--so you need to
38 be careful sometimes:
39
40     print 1+2+4;        # Prints 7.
41     print(1+2) + 4;     # Prints 3.
42     print (1+2)+4;      # Also prints 3!
43     print +(1+2)+4;     # Prints 7.
44     print ((1+2)+4);    # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in a scalar context by
59 returning the undefined value, and in a list context by returning the
60 null list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value it would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls
82 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 =head2 Perl Functions by Category
90 X<function>
91
92 Here are Perl's functions (including things that look like
93 functions, like some keywords and named operators)
94 arranged by category.  Some functions appear in more
95 than one place.
96
97 =over 4
98
99 =item Functions for SCALARs or strings
100 X<scalar> X<string> X<character>
101
102 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
103 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
104 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
105
106 =item Regular expressions and pattern matching
107 X<regular expression> X<regex> X<regexp>
108
109 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
110
111 =item Numeric functions
112 X<numeric> X<number> X<trigonometric> X<trigonometry>
113
114 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
115 C<sin>, C<sqrt>, C<srand>
116
117 =item Functions for real @ARRAYs
118 X<array>
119
120 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
121
122 =item Functions for list data
123 X<list>
124
125 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
126
127 =item Functions for real %HASHes
128 X<hash>
129
130 C<delete>, C<each>, C<exists>, C<keys>, C<values>
131
132 =item Input and output functions
133 X<I/O> X<input> X<output> X<dbm>
134
135 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
136 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
137 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
138 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
139 C<warn>, C<write>
140
141 =item Functions for fixed length data or records
142
143 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
144
145 =item Functions for filehandles, files, or directories
146 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
147
148 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
149 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
150 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
151 C<umask>, C<unlink>, C<utime>
152
153 =item Keywords related to the control flow of your Perl program
154 X<control flow>
155
156 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
157 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
158
159 =item Keywords related to switch
160
161 C<break>, C<continue>, C<given>, C<when>, C<default>
162
163 (These are only available if you enable the "switch" feature.
164 See L<feature> and L<perlsyn/"Switch statements">.)
165
166 =item Keywords related to scoping
167
168 C<caller>, C<import>, C<local>, C<my>, C<our>, C<state>, C<package>,
169 C<use>
170
171 (C<state> is only available if the "state" feature is enabled. See
172 L<feature>.)
173
174 =item Miscellaneous functions
175
176 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
177 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
178
179 =item Functions for processes and process groups
180 X<process> X<pid> X<process id>
181
182 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
183 C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
184 C<times>, C<wait>, C<waitpid>
185
186 =item Keywords related to perl modules
187 X<module>
188
189 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
190
191 =item Keywords related to classes and object-orientedness
192 X<object> X<class> X<package>
193
194 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
195 C<untie>, C<use>
196
197 =item Low-level socket functions
198 X<socket> X<sock>
199
200 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
201 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
202 C<socket>, C<socketpair>
203
204 =item System V interprocess communication functions
205 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
206
207 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
208 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
209
210 =item Fetching user and group info
211 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
212
213 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
214 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
215 C<getpwuid>, C<setgrent>, C<setpwent>
216
217 =item Fetching network info
218 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
219
220 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
221 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
222 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
223 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
224 C<setnetent>, C<setprotoent>, C<setservent>
225
226 =item Time-related functions
227 X<time> X<date>
228
229 C<gmtime>, C<localtime>, C<time>, C<times>
230
231 =item Functions new in perl5
232 X<perl5>
233
234 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
235 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
236 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
237 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
238 C<ucfirst>, C<untie>, C<use>, C<when>
239
240 * - C<sub> was a keyword in perl4, but in perl5 it is an
241 operator, which can be used in expressions.
242
243 =item Functions obsoleted in perl5
244
245 C<dbmclose>, C<dbmopen>
246
247 =back
248
249 =head2 Portability
250 X<portability> X<Unix> X<portable>
251
252 Perl was born in Unix and can therefore access all common Unix
253 system calls.  In non-Unix environments, the functionality of some
254 Unix system calls may not be available, or details of the available
255 functionality may differ slightly.  The Perl functions affected
256 by this are:
257
258 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
259 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
260 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
261 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
262 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
263 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
264 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
265 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
266 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
267 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
268 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
269 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
270 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
271 C<shmwrite>, C<socket>, C<socketpair>,
272 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
273 C<times>, C<truncate>, C<umask>, C<unlink>,
274 C<utime>, C<wait>, C<waitpid>
275
276 For more information about the portability of these functions, see
277 L<perlport> and other available platform-specific documentation.
278
279 =head2 Alphabetical Listing of Perl Functions
280
281 =over 8
282
283 =item -X FILEHANDLE
284 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
285 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
286
287 =item -X EXPR
288
289 =item -X DIRHANDLE
290
291 =item -X
292
293 A file test, where X is one of the letters listed below.  This unary
294 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
295 and tests the associated file to see if something is true about it.  If the
296 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
297 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
298 the undefined value if the file doesn't exist.  Despite the funny
299 names, precedence is the same as any other named unary operator.  The
300 operator may be any of:
301
302     -r  File is readable by effective uid/gid.
303     -w  File is writable by effective uid/gid.
304     -x  File is executable by effective uid/gid.
305     -o  File is owned by effective uid.
306
307     -R  File is readable by real uid/gid.
308     -W  File is writable by real uid/gid.
309     -X  File is executable by real uid/gid.
310     -O  File is owned by real uid.
311
312     -e  File exists.
313     -z  File has zero size (is empty).
314     -s  File has nonzero size (returns size in bytes).
315
316     -f  File is a plain file.
317     -d  File is a directory.
318     -l  File is a symbolic link.
319     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
320     -S  File is a socket.
321     -b  File is a block special file.
322     -c  File is a character special file.
323     -t  Filehandle is opened to a tty.
324
325     -u  File has setuid bit set.
326     -g  File has setgid bit set.
327     -k  File has sticky bit set.
328
329     -T  File is an ASCII text file (heuristic guess).
330     -B  File is a "binary" file (opposite of -T).
331
332     -M  Script start time minus file modification time, in days.
333     -A  Same for access time.
334     -C  Same for inode change time (Unix, may differ for other platforms)
335
336 Example:
337
338     while (<>) {
339         chomp;
340         next unless -f $_;      # ignore specials
341         #...
342     }
343
344 The interpretation of the file permission operators C<-r>, C<-R>,
345 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
346 of the file and the uids and gids of the user.  There may be other
347 reasons you can't actually read, write, or execute the file.  Such
348 reasons may be for example network filesystem access controls, ACLs
349 (access control lists), read-only filesystems, and unrecognized
350 executable formats.
351
352 Also note that, for the superuser on the local filesystems, the C<-r>,
353 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
354 if any execute bit is set in the mode.  Scripts run by the superuser
355 may thus need to do a stat() to determine the actual mode of the file,
356 or temporarily set their effective uid to something else.
357
358 If you are using ACLs, there is a pragma called C<filetest> that may
359 produce more accurate results than the bare stat() mode bits.
360 When under the C<use filetest 'access'> the above-mentioned filetests
361 will test whether the permission can (not) be granted using the
362 access() family of system calls.  Also note that the C<-x> and C<-X> may
363 under this pragma return true even if there are no execute permission
364 bits set (nor any extra execute permission ACLs).  This strangeness is
365 due to the underlying system calls' definitions.  Read the
366 documentation for the C<filetest> pragma for more information.
367
368 Note that C<-s/a/b/> does not do a negated substitution.  Saying
369 C<-exp($foo)> still works as expected, however--only single letters
370 following a minus are interpreted as file tests.
371
372 The C<-T> and C<-B> switches work as follows.  The first block or so of the
373 file is examined for odd characters such as strange control codes or
374 characters with the high bit set.  If too many strange characters (>30%)
375 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
376 containing null in the first block is considered a binary file.  If C<-T>
377 or C<-B> is used on a filehandle, the current IO buffer is examined
378 rather than the first block.  Both C<-T> and C<-B> return true on a null
379 file, or a file at EOF when testing a filehandle.  Because you have to
380 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
381 against the file first, as in C<next unless -f $file && -T $file>.
382
383 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
384 the special filehandle consisting of a solitary underline, then the stat
385 structure of the previous file test (or stat operator) is used, saving
386 a system call.  (This doesn't work with C<-t>, and you need to remember
387 that lstat() and C<-l> will leave values in the stat structure for the
388 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
389 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
390 Example:
391
392     print "Can do.\n" if -r $a || -w _ || -x _;
393
394     stat($filename);
395     print "Readable\n" if -r _;
396     print "Writable\n" if -w _;
397     print "Executable\n" if -x _;
398     print "Setuid\n" if -u _;
399     print "Setgid\n" if -g _;
400     print "Sticky\n" if -k _;
401     print "Text\n" if -T _;
402     print "Binary\n" if -B _;
403
404 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
405 test operators, in a way that C<-f -w -x $file> is equivalent to
406 C<-x $file && -w _ && -f _>. (This is only syntax fancy: if you use
407 the return value of C<-f $file> as an argument to another filetest
408 operator, no special magic will happen.)
409
410 =item abs VALUE
411 X<abs> X<absolute>
412
413 =item abs
414
415 Returns the absolute value of its argument.
416 If VALUE is omitted, uses C<$_>.
417
418 =item accept NEWSOCKET,GENERICSOCKET
419 X<accept>
420
421 Accepts an incoming socket connect, just as the accept(2) system call
422 does.  Returns the packed address if it succeeded, false otherwise.
423 See the example in L<perlipc/"Sockets: Client/Server Communication">.
424
425 On systems that support a close-on-exec flag on files, the flag will
426 be set for the newly opened file descriptor, as determined by the
427 value of $^F.  See L<perlvar/$^F>.
428
429 =item alarm SECONDS
430 X<alarm>
431 X<SIGALRM>
432 X<timer>
433
434 =item alarm
435
436 Arranges to have a SIGALRM delivered to this process after the
437 specified number of wallclock seconds has elapsed.  If SECONDS is not
438 specified, the value stored in C<$_> is used. (On some machines,
439 unfortunately, the elapsed time may be up to one second less or more
440 than you specified because of how seconds are counted, and process
441 scheduling may delay the delivery of the signal even further.)
442
443 Only one timer may be counting at once.  Each call disables the
444 previous timer, and an argument of C<0> may be supplied to cancel the
445 previous timer without starting a new one.  The returned value is the
446 amount of time remaining on the previous timer.
447
448 For delays of finer granularity than one second, the Time::HiRes module
449 (from CPAN, and starting from Perl 5.8 part of the standard
450 distribution) provides ualarm().  You may also use Perl's four-argument
451 version of select() leaving the first three arguments undefined, or you
452 might be able to use the C<syscall> interface to access setitimer(2) if
453 your system supports it. See L<perlfaq8> for details.
454
455 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
456 (C<sleep> may be internally implemented in your system with C<alarm>)
457
458 If you want to use C<alarm> to time out a system call you need to use an
459 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
460 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
461 restart system calls on some systems.  Using C<eval>/C<die> always works,
462 modulo the caveats given in L<perlipc/"Signals">.
463
464     eval {
465         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
466         alarm $timeout;
467         $nread = sysread SOCKET, $buffer, $size;
468         alarm 0;
469     };
470     if ($@) {
471         die unless $@ eq "alarm\n";   # propagate unexpected errors
472         # timed out
473     }
474     else {
475         # didn't
476     }
477
478 For more information see L<perlipc>.
479
480 =item atan2 Y,X
481 X<atan2> X<arctangent> X<tan> X<tangent>
482
483 Returns the arctangent of Y/X in the range -PI to PI.
484
485 For the tangent operation, you may use the C<Math::Trig::tan>
486 function, or use the familiar relation:
487
488     sub tan { sin($_[0]) / cos($_[0])  }
489
490 Note that atan2(0, 0) is not well-defined.
491
492 =item bind SOCKET,NAME
493 X<bind>
494
495 Binds a network address to a socket, just as the bind system call
496 does.  Returns true if it succeeded, false otherwise.  NAME should be a
497 packed address of the appropriate type for the socket.  See the examples in
498 L<perlipc/"Sockets: Client/Server Communication">.
499
500 =item binmode FILEHANDLE, LAYER
501 X<binmode> X<binary> X<text> X<DOS> X<Windows>
502
503 =item binmode FILEHANDLE
504
505 Arranges for FILEHANDLE to be read or written in "binary" or "text"
506 mode on systems where the run-time libraries distinguish between
507 binary and text files.  If FILEHANDLE is an expression, the value is
508 taken as the name of the filehandle.  Returns true on success,
509 otherwise it returns C<undef> and sets C<$!> (errno).
510
511 On some systems (in general, DOS and Windows-based systems) binmode()
512 is necessary when you're not working with a text file.  For the sake
513 of portability it is a good idea to always use it when appropriate,
514 and to never use it when it isn't appropriate.  Also, people can
515 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
516
517 In other words: regardless of platform, use binmode() on binary data,
518 like for example images.
519
520 If LAYER is present it is a single string, but may contain multiple
521 directives. The directives alter the behaviour of the file handle.
522 When LAYER is present using binmode on text file makes sense.
523
524 If LAYER is omitted or specified as C<:raw> the filehandle is made
525 suitable for passing binary data. This includes turning off possible CRLF
526 translation and marking it as bytes (as opposed to Unicode characters).
527 Note that, despite what may be implied in I<"Programming Perl"> (the
528 Camel) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>
529 -- other layers which would affect the binary nature of the stream are
530 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
531 PERLIO environment variable.
532
533 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
534 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
535 establish default I/O layers.  See L<open>.
536
537 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
538 in "Programming Perl, 3rd Edition".  However, since the publishing of this
539 book, by many known as "Camel III", the consensus of the naming of this
540 functionality has moved from "discipline" to "layer".  All documentation
541 of this version of Perl therefore refers to "layers" rather than to
542 "disciplines".  Now back to the regularly scheduled documentation...>
543
544 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(utf8)>.
545 C<:utf8> just marks the data as UTF-8 without further checking,
546 while C<:encoding(utf8)> checks the data for actually being valid
547 UTF-8. More details can be found in L<PerlIO::encoding>.
548
549 In general, binmode() should be called after open() but before any I/O
550 is done on the filehandle.  Calling binmode() will normally flush any
551 pending buffered output data (and perhaps pending input data) on the
552 handle.  An exception to this is the C<:encoding> layer that
553 changes the default character encoding of the handle, see L<open>.
554 The C<:encoding> layer sometimes needs to be called in
555 mid-stream, and it doesn't flush the stream.  The C<:encoding>
556 also implicitly pushes on top of itself the C<:utf8> layer because
557 internally Perl will operate on UTF-8 encoded Unicode characters.
558
559 The operating system, device drivers, C libraries, and Perl run-time
560 system all work together to let the programmer treat a single
561 character (C<\n>) as the line terminator, irrespective of the external
562 representation.  On many operating systems, the native text file
563 representation matches the internal representation, but on some
564 platforms the external representation of C<\n> is made up of more than
565 one character.
566
567 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
568 character to end each line in the external representation of text (even
569 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
570 on Unix and most VMS files). In other systems like OS/2, DOS and the
571 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
572 but what's stored in text files are the two characters C<\cM\cJ>.  That
573 means that, if you don't use binmode() on these systems, C<\cM\cJ>
574 sequences on disk will be converted to C<\n> on input, and any C<\n> in
575 your program will be converted back to C<\cM\cJ> on output.  This is what
576 you want for text files, but it can be disastrous for binary files.
577
578 Another consequence of using binmode() (on some systems) is that
579 special end-of-file markers will be seen as part of the data stream.
580 For systems from the Microsoft family this means that if your binary
581 data contains C<\cZ>, the I/O subsystem will regard it as the end of
582 the file, unless you use binmode().
583
584 binmode() is not only important for readline() and print() operations,
585 but also when using read(), seek(), sysread(), syswrite() and tell()
586 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
587 in L<perlvar> for how to manually set your input and output
588 line-termination sequences.
589
590 =item bless REF,CLASSNAME
591 X<bless>
592
593 =item bless REF
594
595 This function tells the thingy referenced by REF that it is now an object
596 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
597 is used.  Because a C<bless> is often the last thing in a constructor,
598 it returns the reference for convenience.  Always use the two-argument
599 version if a derived class might inherit the function doing the blessing.
600 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
601 of objects.
602
603 Consider always blessing objects in CLASSNAMEs that are mixed case.
604 Namespaces with all lowercase names are considered reserved for
605 Perl pragmata.  Builtin types have all uppercase names. To prevent
606 confusion, you may wish to avoid such package names as well.  Make sure
607 that CLASSNAME is a true value.
608
609 See L<perlmod/"Perl Modules">.
610
611 =item break
612
613 Break out of a C<given()> block.
614
615 This keyword is enabled by the "switch" feature: see L<feature>
616 for more information.
617
618 =item caller EXPR
619 X<caller> X<call stack> X<stack> X<stack trace>
620
621 =item caller
622
623 Returns the context of the current subroutine call.  In scalar context,
624 returns the caller's package name if there is a caller, that is, if
625 we're in a subroutine or C<eval> or C<require>, and the undefined value
626 otherwise.  In list context, returns
627
628     # 0         1          2
629     ($package, $filename, $line) = caller;
630
631 With EXPR, it returns some extra information that the debugger uses to
632 print a stack trace.  The value of EXPR indicates how many call frames
633 to go back before the current one.
634
635     #  0         1          2      3            4
636     ($package, $filename, $line, $subroutine, $hasargs,
637
638     #  5          6          7            8       9         10
639     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
640      = caller($i);
641
642 Here $subroutine may be C<(eval)> if the frame is not a subroutine
643 call, but an C<eval>.  In such a case additional elements $evaltext and
644 C<$is_require> are set: C<$is_require> is true if the frame is created by a
645 C<require> or C<use> statement, $evaltext contains the text of the
646 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
647 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
648 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
649 frame.)  $subroutine may also be C<(unknown)> if this particular
650 subroutine happens to have been deleted from the symbol table.
651 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
652 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
653 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
654 between versions of Perl, and are not meant for external use.
655
656 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
657 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
658 of this hash, as they are the actual values stored in the optree.
659
660 Furthermore, when called from within the DB package, caller returns more
661 detailed information: it sets the list variable C<@DB::args> to be the
662 arguments with which the subroutine was invoked.
663
664 Be aware that the optimizer might have optimized call frames away before
665 C<caller> had a chance to get the information.  That means that C<caller(N)>
666 might not return information about the call frame you expect it do, for
667 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
668 previous time C<caller> was called.
669
670 =item chdir EXPR
671 X<chdir>
672 X<cd>
673 X<directory, change>
674
675 =item chdir FILEHANDLE
676
677 =item chdir DIRHANDLE
678
679 =item chdir
680
681 Changes the working directory to EXPR, if possible. If EXPR is omitted,
682 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
683 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
684 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
685 neither is set, C<chdir> does nothing. It returns true upon success,
686 false otherwise. See the example under C<die>.
687
688 On systems that support fchdir, you might pass a file handle or
689 directory handle as argument.  On systems that don't support fchdir,
690 passing handles produces a fatal error at run time.
691
692 =item chmod LIST
693 X<chmod> X<permission> X<mode>
694
695 Changes the permissions of a list of files.  The first element of the
696 list must be the numerical mode, which should probably be an octal
697 number, and which definitely should I<not> be a string of octal digits:
698 C<0644> is okay, C<'0644'> is not.  Returns the number of files
699 successfully changed.  See also L</oct>, if all you have is a string.
700
701     $cnt = chmod 0755, 'foo', 'bar';
702     chmod 0755, @executables;
703     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
704                                              # --w----r-T
705     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
706     $mode = 0644;   chmod $mode, 'foo';      # this is best
707
708 On systems that support fchmod, you might pass file handles among the
709 files.  On systems that don't support fchmod, passing file handles
710 produces a fatal error at run time.   The file handles must be passed
711 as globs or references to be recognized.  Barewords are considered
712 file names.
713
714     open(my $fh, "<", "foo");
715     my $perm = (stat $fh)[2] & 07777;
716     chmod($perm | 0600, $fh);
717
718 You can also import the symbolic C<S_I*> constants from the Fcntl
719 module:
720
721     use Fcntl ':mode';
722
723     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
724     # This is identical to the chmod 0755 of the above example.
725
726 =item chomp VARIABLE
727 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
728
729 =item chomp( LIST )
730
731 =item chomp
732
733 This safer version of L</chop> removes any trailing string
734 that corresponds to the current value of C<$/> (also known as
735 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
736 number of characters removed from all its arguments.  It's often used to
737 remove the newline from the end of an input record when you're worried
738 that the final record may be missing its newline.  When in paragraph
739 mode (C<$/ = "">), it removes all trailing newlines from the string.
740 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
741 a reference to an integer or the like, see L<perlvar>) chomp() won't
742 remove anything.
743 If VARIABLE is omitted, it chomps C<$_>.  Example:
744
745     while (<>) {
746         chomp;  # avoid \n on last field
747         @array = split(/:/);
748         # ...
749     }
750
751 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
752
753 You can actually chomp anything that's an lvalue, including an assignment:
754
755     chomp($cwd = `pwd`);
756     chomp($answer = <STDIN>);
757
758 If you chomp a list, each element is chomped, and the total number of
759 characters removed is returned.
760
761 Note that parentheses are necessary when you're chomping anything
762 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
763 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
764 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
765 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
766 as C<chomp($a, $b)>.
767
768 =item chop VARIABLE
769 X<chop>
770
771 =item chop( LIST )
772
773 =item chop
774
775 Chops off the last character of a string and returns the character
776 chopped.  It is much more efficient than C<s/.$//s> because it neither
777 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
778 If VARIABLE is a hash, it chops the hash's values, but not its keys.
779
780 You can actually chop anything that's an lvalue, including an assignment.
781
782 If you chop a list, each element is chopped.  Only the value of the
783 last C<chop> is returned.
784
785 Note that C<chop> returns the last character.  To return all but the last
786 character, use C<substr($string, 0, -1)>.
787
788 See also L</chomp>.
789
790 =item chown LIST
791 X<chown> X<owner> X<user> X<group>
792
793 Changes the owner (and group) of a list of files.  The first two
794 elements of the list must be the I<numeric> uid and gid, in that
795 order.  A value of -1 in either position is interpreted by most
796 systems to leave that value unchanged.  Returns the number of files
797 successfully changed.
798
799     $cnt = chown $uid, $gid, 'foo', 'bar';
800     chown $uid, $gid, @filenames;
801
802 On systems that support fchown, you might pass file handles among the
803 files.  On systems that don't support fchown, passing file handles
804 produces a fatal error at run time.  The file handles must be passed
805 as globs or references to be recognized.  Barewords are considered
806 file names.
807
808 Here's an example that looks up nonnumeric uids in the passwd file:
809
810     print "User: ";
811     chomp($user = <STDIN>);
812     print "Files: ";
813     chomp($pattern = <STDIN>);
814
815     ($login,$pass,$uid,$gid) = getpwnam($user)
816         or die "$user not in passwd file";
817
818     @ary = glob($pattern);      # expand filenames
819     chown $uid, $gid, @ary;
820
821 On most systems, you are not allowed to change the ownership of the
822 file unless you're the superuser, although you should be able to change
823 the group to any of your secondary groups.  On insecure systems, these
824 restrictions may be relaxed, but this is not a portable assumption.
825 On POSIX systems, you can detect this condition this way:
826
827     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
828     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
829
830 =item chr NUMBER
831 X<chr> X<character> X<ASCII> X<Unicode>
832
833 =item chr
834
835 Returns the character represented by that NUMBER in the character set.
836 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
837 chr(0x263a) is a Unicode smiley face.  
838
839 Negative values give the Unicode replacement character (chr(0xfffd)),
840 except under the L<bytes> pragma, where low eight bits of the value
841 (truncated to an integer) are used.
842
843 If NUMBER is omitted, uses C<$_>.
844
845 For the reverse, use L</ord>.
846
847 Note that characters from 128 to 255 (inclusive) are by default
848 internally not encoded as UTF-8 for backward compatibility reasons.
849
850 See L<perlunicode> for more about Unicode.
851
852 =item chroot FILENAME
853 X<chroot> X<root>
854
855 =item chroot
856
857 This function works like the system call by the same name: it makes the
858 named directory the new root directory for all further pathnames that
859 begin with a C</> by your process and all its children.  (It doesn't
860 change your current working directory, which is unaffected.)  For security
861 reasons, this call is restricted to the superuser.  If FILENAME is
862 omitted, does a C<chroot> to C<$_>.
863
864 =item close FILEHANDLE
865 X<close>
866
867 =item close
868
869 Closes the file or pipe associated with the file handle, flushes the IO
870 buffers, and closes the system file descriptor.  Returns true if those
871 operations have succeeded and if no error was reported by any PerlIO
872 layer.  Closes the currently selected filehandle if the argument is
873 omitted.
874
875 You don't have to close FILEHANDLE if you are immediately going to do
876 another C<open> on it, because C<open> will close it for you.  (See
877 C<open>.)  However, an explicit C<close> on an input file resets the line
878 counter (C<$.>), while the implicit close done by C<open> does not.
879
880 If the file handle came from a piped open, C<close> will additionally
881 return false if one of the other system calls involved fails, or if the
882 program exits with non-zero status.  (If the only problem was that the
883 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
884 also waits for the process executing on the pipe to complete, in case you
885 want to look at the output of the pipe afterwards, and
886 implicitly puts the exit status value of that command into C<$?> and
887 C<${^CHILD_ERROR_NATIVE}>.
888
889 Prematurely closing the read end of a pipe (i.e. before the process
890 writing to it at the other end has closed it) will result in a
891 SIGPIPE being delivered to the writer.  If the other end can't
892 handle that, be sure to read all the data before closing the pipe.
893
894 Example:
895
896     open(OUTPUT, '|sort >foo')  # pipe to sort
897         or die "Can't start sort: $!";
898     #...                        # print stuff to output
899     close OUTPUT                # wait for sort to finish
900         or warn $! ? "Error closing sort pipe: $!"
901                    : "Exit status $? from sort";
902     open(INPUT, 'foo')          # get sort's results
903         or die "Can't open 'foo' for input: $!";
904
905 FILEHANDLE may be an expression whose value can be used as an indirect
906 filehandle, usually the real filehandle name.
907
908 =item closedir DIRHANDLE
909 X<closedir>
910
911 Closes a directory opened by C<opendir> and returns the success of that
912 system call.
913
914 =item connect SOCKET,NAME
915 X<connect>
916
917 Attempts to connect to a remote socket, just as the connect system call
918 does.  Returns true if it succeeded, false otherwise.  NAME should be a
919 packed address of the appropriate type for the socket.  See the examples in
920 L<perlipc/"Sockets: Client/Server Communication">.
921
922 =item continue BLOCK
923 X<continue>
924
925 =item continue
926
927 C<continue> is actually a flow control statement rather than a function.  If
928 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
929 C<foreach>), it is always executed just before the conditional is about to
930 be evaluated again, just like the third part of a C<for> loop in C.  Thus
931 it can be used to increment a loop variable, even when the loop has been
932 continued via the C<next> statement (which is similar to the C C<continue>
933 statement).
934
935 C<last>, C<next>, or C<redo> may appear within a C<continue>
936 block.  C<last> and C<redo> will behave as if they had been executed within
937 the main block.  So will C<next>, but since it will execute a C<continue>
938 block, it may be more entertaining.
939
940     while (EXPR) {
941         ### redo always comes here
942         do_something;
943     } continue {
944         ### next always comes here
945         do_something_else;
946         # then back the top to re-check EXPR
947     }
948     ### last always comes here
949
950 Omitting the C<continue> section is semantically equivalent to using an
951 empty one, logically enough.  In that case, C<next> goes directly back
952 to check the condition at the top of the loop.
953
954 If the "switch" feature is enabled, C<continue> is also a
955 function that will break out of the current C<when> or C<default>
956 block, and fall through to the next case. See L<feature> and
957 L<perlsyn/"Switch statements"> for more information.
958
959
960 =item cos EXPR
961 X<cos> X<cosine> X<acos> X<arccosine>
962
963 =item cos
964
965 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
966 takes cosine of C<$_>.
967
968 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
969 function, or use this relation:
970
971     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
972
973 =item crypt PLAINTEXT,SALT
974 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
975 X<decrypt> X<cryptography> X<passwd> X<encrypt>
976
977 Creates a digest string exactly like the crypt(3) function in the C
978 library (assuming that you actually have a version there that has not
979 been extirpated as a potential munitions).
980
981 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
982 into a short string, called a digest, which is returned.  The same
983 PLAINTEXT and SALT will always return the same string, but there is no
984 (known) way to get the original PLAINTEXT from the hash.  Small
985 changes in the PLAINTEXT or SALT will result in large changes in the
986 digest.
987
988 There is no decrypt function.  This function isn't all that useful for
989 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
990 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
991 primarily used to check if two pieces of text are the same without
992 having to transmit or store the text itself.  An example is checking
993 if a correct password is given.  The digest of the password is stored,
994 not the password itself.  The user types in a password that is
995 crypt()'d with the same salt as the stored digest.  If the two digests
996 match the password is correct.
997
998 When verifying an existing digest string you should use the digest as
999 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1000 to create the digest is visible as part of the digest.  This ensures
1001 crypt() will hash the new string with the same salt as the digest.
1002 This allows your code to work with the standard L<crypt|/crypt> and
1003 with more exotic implementations.  In other words, do not assume
1004 anything about the returned string itself, or how many bytes in the
1005 digest matter.
1006
1007 Traditionally the result is a string of 13 bytes: two first bytes of
1008 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1009 the first eight bytes of the digest string mattered, but alternative
1010 hashing schemes (like MD5), higher level security schemes (like C2),
1011 and implementations on non-UNIX platforms may produce different
1012 strings.
1013
1014 When choosing a new salt create a random two character string whose
1015 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1016 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1017 characters is just a recommendation; the characters allowed in
1018 the salt depend solely on your system's crypt library, and Perl can't
1019 restrict what salts C<crypt()> accepts.
1020
1021 Here's an example that makes sure that whoever runs this program knows
1022 their password:
1023
1024     $pwd = (getpwuid($<))[1];
1025
1026     system "stty -echo";
1027     print "Password: ";
1028     chomp($word = <STDIN>);
1029     print "\n";
1030     system "stty echo";
1031
1032     if (crypt($word, $pwd) ne $pwd) {
1033         die "Sorry...\n";
1034     } else {
1035         print "ok\n";
1036     }
1037
1038 Of course, typing in your own password to whoever asks you
1039 for it is unwise.
1040
1041 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1042 of data, not least of all because you can't get the information
1043 back.  Look at the L<Digest> module for more robust algorithms.
1044
1045 If using crypt() on a Unicode string (which I<potentially> has
1046 characters with codepoints above 255), Perl tries to make sense
1047 of the situation by trying to downgrade (a copy of the string)
1048 the string back to an eight-bit byte string before calling crypt()
1049 (on that copy).  If that works, good.  If not, crypt() dies with
1050 C<Wide character in crypt>.
1051
1052 =item dbmclose HASH
1053 X<dbmclose>
1054
1055 [This function has been largely superseded by the C<untie> function.]
1056
1057 Breaks the binding between a DBM file and a hash.
1058
1059 =item dbmopen HASH,DBNAME,MASK
1060 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1061
1062 [This function has been largely superseded by the C<tie> function.]
1063
1064 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1065 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1066 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1067 is the name of the database (without the F<.dir> or F<.pag> extension if
1068 any).  If the database does not exist, it is created with protection
1069 specified by MASK (as modified by the C<umask>).  If your system supports
1070 only the older DBM functions, you may perform only one C<dbmopen> in your
1071 program.  In older versions of Perl, if your system had neither DBM nor
1072 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1073 sdbm(3).
1074
1075 If you don't have write access to the DBM file, you can only read hash
1076 variables, not set them.  If you want to test whether you can write,
1077 either use file tests or try setting a dummy hash entry inside an C<eval>,
1078 which will trap the error.
1079
1080 Note that functions such as C<keys> and C<values> may return huge lists
1081 when used on large DBM files.  You may prefer to use the C<each>
1082 function to iterate over large DBM files.  Example:
1083
1084     # print out history file offsets
1085     dbmopen(%HIST,'/usr/lib/news/history',0666);
1086     while (($key,$val) = each %HIST) {
1087         print $key, ' = ', unpack('L',$val), "\n";
1088     }
1089     dbmclose(%HIST);
1090
1091 See also L<AnyDBM_File> for a more general description of the pros and
1092 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1093 rich implementation.
1094
1095 You can control which DBM library you use by loading that library
1096 before you call dbmopen():
1097
1098     use DB_File;
1099     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1100         or die "Can't open netscape history file: $!";
1101
1102 =item defined EXPR
1103 X<defined> X<undef> X<undefined>
1104
1105 =item defined
1106
1107 Returns a Boolean value telling whether EXPR has a value other than
1108 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
1109 checked.
1110
1111 Many operations return C<undef> to indicate failure, end of file,
1112 system error, uninitialized variable, and other exceptional
1113 conditions.  This function allows you to distinguish C<undef> from
1114 other values.  (A simple Boolean test will not distinguish among
1115 C<undef>, zero, the empty string, and C<"0">, which are all equally
1116 false.)  Note that since C<undef> is a valid scalar, its presence
1117 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1118 returns C<undef> when its argument is an empty array, I<or> when the
1119 element to return happens to be C<undef>.
1120
1121 You may also use C<defined(&func)> to check whether subroutine C<&func>
1122 has ever been defined.  The return value is unaffected by any forward
1123 declarations of C<&func>.  Note that a subroutine which is not defined
1124 may still be callable: its package may have an C<AUTOLOAD> method that
1125 makes it spring into existence the first time that it is called -- see
1126 L<perlsub>.
1127
1128 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1129 used to report whether memory for that aggregate has ever been
1130 allocated.  This behavior may disappear in future versions of Perl.
1131 You should instead use a simple test for size:
1132
1133     if (@an_array) { print "has array elements\n" }
1134     if (%a_hash)   { print "has hash members\n"   }
1135
1136 When used on a hash element, it tells you whether the value is defined,
1137 not whether the key exists in the hash.  Use L</exists> for the latter
1138 purpose.
1139
1140 Examples:
1141
1142     print if defined $switch{'D'};
1143     print "$val\n" while defined($val = pop(@ary));
1144     die "Can't readlink $sym: $!"
1145         unless defined($value = readlink $sym);
1146     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1147     $debugging = 0 unless defined $debugging;
1148
1149 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1150 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1151 defined values.  For example, if you say
1152
1153     "ab" =~ /a(.*)b/;
1154
1155 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1156 matched "nothing".  It didn't really fail to match anything.  Rather, it
1157 matched something that happened to be zero characters long.  This is all
1158 very above-board and honest.  When a function returns an undefined value,
1159 it's an admission that it couldn't give you an honest answer.  So you
1160 should use C<defined> only when you're questioning the integrity of what
1161 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1162 what you want.
1163
1164 See also L</undef>, L</exists>, L</ref>.
1165
1166 =item delete EXPR
1167 X<delete>
1168
1169 Given an expression that specifies a hash element, array element, hash slice,
1170 or array slice, deletes the specified element(s) from the hash or array.
1171 In the case of an array, if the array elements happen to be at the end,
1172 the size of the array will shrink to the highest element that tests
1173 true for exists() (or 0 if no such element exists).
1174
1175 Returns a list with the same number of elements as the number of elements
1176 for which deletion was attempted.  Each element of that list consists of
1177 either the value of the element deleted, or the undefined value.  In scalar
1178 context, this means that you get the value of the last element deleted (or
1179 the undefined value if that element did not exist).
1180
1181     %hash = (foo => 11, bar => 22, baz => 33);
1182     $scalar = delete $hash{foo};             # $scalar is 11
1183     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1184     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1185
1186 Deleting from C<%ENV> modifies the environment.  Deleting from
1187 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1188 from a C<tie>d hash or array may not necessarily return anything.
1189
1190 Deleting an array element effectively returns that position of the array
1191 to its initial, uninitialized state.  Subsequently testing for the same
1192 element with exists() will return false.  Also, deleting array elements
1193 in the middle of an array will not shift the index of the elements
1194 after them down.  Use splice() for that.  See L</exists>.
1195
1196 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1197
1198     foreach $key (keys %HASH) {
1199         delete $HASH{$key};
1200     }
1201
1202     foreach $index (0 .. $#ARRAY) {
1203         delete $ARRAY[$index];
1204     }
1205
1206 And so do these:
1207
1208     delete @HASH{keys %HASH};
1209
1210     delete @ARRAY[0 .. $#ARRAY];
1211
1212 But both of these are slower than just assigning the empty list
1213 or undefining %HASH or @ARRAY:
1214
1215     %HASH = ();         # completely empty %HASH
1216     undef %HASH;        # forget %HASH ever existed
1217
1218     @ARRAY = ();        # completely empty @ARRAY
1219     undef @ARRAY;       # forget @ARRAY ever existed
1220
1221 Note that the EXPR can be arbitrarily complicated as long as the final
1222 operation is a hash element, array element,  hash slice, or array slice
1223 lookup:
1224
1225     delete $ref->[$x][$y]{$key};
1226     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1227
1228     delete $ref->[$x][$y][$index];
1229     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1230
1231 =item die LIST
1232 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1233
1234 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1235 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1236 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1237 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1238 an C<eval(),> the error message is stuffed into C<$@> and the
1239 C<eval> is terminated with the undefined value.  This makes
1240 C<die> the way to raise an exception.
1241
1242 Equivalent examples:
1243
1244     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1245     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1246
1247 If the last element of LIST does not end in a newline, the current
1248 script line number and input line number (if any) are also printed,
1249 and a newline is supplied.  Note that the "input line number" (also
1250 known as "chunk") is subject to whatever notion of "line" happens to
1251 be currently in effect, and is also available as the special variable
1252 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1253
1254 Hint: sometimes appending C<", stopped"> to your message will cause it
1255 to make better sense when the string C<"at foo line 123"> is appended.
1256 Suppose you are running script "canasta".
1257
1258     die "/etc/games is no good";
1259     die "/etc/games is no good, stopped";
1260
1261 produce, respectively
1262
1263     /etc/games is no good at canasta line 123.
1264     /etc/games is no good, stopped at canasta line 123.
1265
1266 See also exit(), warn(), and the Carp module.
1267
1268 If LIST is empty and C<$@> already contains a value (typically from a
1269 previous eval) that value is reused after appending C<"\t...propagated">.
1270 This is useful for propagating exceptions:
1271
1272     eval { ... };
1273     die unless $@ =~ /Expected exception/;
1274
1275 If LIST is empty and C<$@> contains an object reference that has a
1276 C<PROPAGATE> method, that method will be called with additional file
1277 and line number parameters.  The return value replaces the value in
1278 C<$@>.  i.e. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1279 were called.
1280
1281 If C<$@> is empty then the string C<"Died"> is used.
1282
1283 die() can also be called with a reference argument.  If this happens to be
1284 trapped within an eval(), $@ contains the reference.  This behavior permits
1285 a more elaborate exception handling implementation using objects that
1286 maintain arbitrary state about the nature of the exception.  Such a scheme
1287 is sometimes preferable to matching particular string values of $@ using
1288 regular expressions.  Because $@ is a global variable, and eval() may be
1289 used within object implementations, care must be taken that analyzing the
1290 error object doesn't replace the reference in the global variable.  The
1291 easiest solution is to make a local copy of the reference before doing
1292 other manipulations.  Here's an example:
1293
1294     use Scalar::Util 'blessed';
1295
1296     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1297     if (my $ev_err = $@) {
1298         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1299             # handle Some::Module::Exception
1300         }
1301         else {
1302             # handle all other possible exceptions
1303         }
1304     }
1305
1306 Because perl will stringify uncaught exception messages before displaying
1307 them, you may want to overload stringification operations on such custom
1308 exception objects.  See L<overload> for details about that.
1309
1310 You can arrange for a callback to be run just before the C<die>
1311 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1312 handler will be called with the error text and can change the error
1313 message, if it sees fit, by calling C<die> again.  See
1314 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1315 L<"eval BLOCK"> for some examples.  Although this feature was 
1316 to be run only right before your program was to exit, this is not
1317 currently the case--the C<$SIG{__DIE__}> hook is currently called
1318 even inside eval()ed blocks/strings!  If one wants the hook to do
1319 nothing in such situations, put
1320
1321         die @_ if $^S;
1322
1323 as the first line of the handler (see L<perlvar/$^S>).  Because
1324 this promotes strange action at a distance, this counterintuitive
1325 behavior may be fixed in a future release.
1326
1327 =item do BLOCK
1328 X<do> X<block>
1329
1330 Not really a function.  Returns the value of the last command in the
1331 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1332 C<until> loop modifier, executes the BLOCK once before testing the loop
1333 condition. (On other statements the loop modifiers test the conditional
1334 first.)
1335
1336 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1337 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1338 See L<perlsyn> for alternative strategies.
1339
1340 =item do SUBROUTINE(LIST)
1341 X<do>
1342
1343 This form of subroutine call is deprecated.  See L<perlsub>.
1344
1345 =item do EXPR
1346 X<do>
1347
1348 Uses the value of EXPR as a filename and executes the contents of the
1349 file as a Perl script.
1350
1351     do 'stat.pl';
1352
1353 is just like
1354
1355     eval `cat stat.pl`;
1356
1357 except that it's more efficient and concise, keeps track of the current
1358 filename for error messages, searches the @INC directories, and updates
1359 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1360 variables.  It also differs in that code evaluated with C<do FILENAME>
1361 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1362 same, however, in that it does reparse the file every time you call it,
1363 so you probably don't want to do this inside a loop.
1364
1365 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1366 error.  If C<do> can read the file but cannot compile it, it
1367 returns undef and sets an error message in C<$@>.   If the file is
1368 successfully compiled, C<do> returns the value of the last expression
1369 evaluated.
1370
1371 Note that inclusion of library modules is better done with the
1372 C<use> and C<require> operators, which also do automatic error checking
1373 and raise an exception if there's a problem.
1374
1375 You might like to use C<do> to read in a program configuration
1376 file.  Manual error checking can be done this way:
1377
1378     # read in config files: system first, then user
1379     for $file ("/share/prog/defaults.rc",
1380                "$ENV{HOME}/.someprogrc")
1381    {
1382         unless ($return = do $file) {
1383             warn "couldn't parse $file: $@" if $@;
1384             warn "couldn't do $file: $!"    unless defined $return;
1385             warn "couldn't run $file"       unless $return;
1386         }
1387     }
1388
1389 =item dump LABEL
1390 X<dump> X<core> X<undump>
1391
1392 =item dump
1393
1394 This function causes an immediate core dump.  See also the B<-u>
1395 command-line switch in L<perlrun>, which does the same thing.
1396 Primarily this is so that you can use the B<undump> program (not
1397 supplied) to turn your core dump into an executable binary after
1398 having initialized all your variables at the beginning of the
1399 program.  When the new binary is executed it will begin by executing
1400 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1401 Think of it as a goto with an intervening core dump and reincarnation.
1402 If C<LABEL> is omitted, restarts the program from the top.
1403
1404 B<WARNING>: Any files opened at the time of the dump will I<not>
1405 be open any more when the program is reincarnated, with possible
1406 resulting confusion on the part of Perl.
1407
1408 This function is now largely obsolete, mostly because it's very hard to
1409 convert a core file into an executable. That's why you should now invoke
1410 it as C<CORE::dump()>, if you don't want to be warned against a possible
1411 typo.
1412
1413 =item each HASH
1414 X<each> X<hash, iterator>
1415
1416 When called in list context, returns a 2-element list consisting of the
1417 key and value for the next element of a hash, so that you can iterate over
1418 it.  When called in scalar context, returns only the key for the next
1419 element in the hash.
1420
1421 Entries are returned in an apparently random order.  The actual random
1422 order is subject to change in future versions of perl, but it is
1423 guaranteed to be in the same order as either the C<keys> or C<values>
1424 function would produce on the same (unmodified) hash.  Since Perl
1425 5.8.1 the ordering is different even between different runs of Perl
1426 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1427
1428 When the hash is entirely read, a null array is returned in list context
1429 (which when assigned produces a false (C<0>) value), and C<undef> in
1430 scalar context.  The next call to C<each> after that will start iterating
1431 again.  There is a single iterator for each hash, shared by all C<each>,
1432 C<keys>, and C<values> function calls in the program; it can be reset by
1433 reading all the elements from the hash, or by evaluating C<keys HASH> or
1434 C<values HASH>.  If you add or delete elements of a hash while you're
1435 iterating over it, you may get entries skipped or duplicated, so
1436 don't.  Exception: It is always safe to delete the item most recently
1437 returned by C<each()>, which means that the following code will work:
1438
1439         while (($key, $value) = each %hash) {
1440           print $key, "\n";
1441           delete $hash{$key};   # This is safe
1442         }
1443
1444 The following prints out your environment like the printenv(1) program,
1445 only in a different order:
1446
1447     while (($key,$value) = each %ENV) {
1448         print "$key=$value\n";
1449     }
1450
1451 See also C<keys>, C<values> and C<sort>.
1452
1453 =item eof FILEHANDLE
1454 X<eof>
1455 X<end of file>
1456 X<end-of-file>
1457
1458 =item eof ()
1459
1460 =item eof
1461
1462 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1463 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1464 gives the real filehandle.  (Note that this function actually
1465 reads a character and then C<ungetc>s it, so isn't very useful in an
1466 interactive context.)  Do not read from a terminal file (or call
1467 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1468 as terminals may lose the end-of-file condition if you do.
1469
1470 An C<eof> without an argument uses the last file read.  Using C<eof()>
1471 with empty parentheses is very different.  It refers to the pseudo file
1472 formed from the files listed on the command line and accessed via the
1473 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1474 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1475 used will cause C<@ARGV> to be examined to determine if input is
1476 available.   Similarly, an C<eof()> after C<< <> >> has returned
1477 end-of-file will assume you are processing another C<@ARGV> list,
1478 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1479 see L<perlop/"I/O Operators">.
1480
1481 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1482 detect the end of each file, C<eof()> will only detect the end of the
1483 last file.  Examples:
1484
1485     # reset line numbering on each input file
1486     while (<>) {
1487         next if /^\s*#/;        # skip comments
1488         print "$.\t$_";
1489     } continue {
1490         close ARGV  if eof;     # Not eof()!
1491     }
1492
1493     # insert dashes just before last line of last file
1494     while (<>) {
1495         if (eof()) {            # check for end of last file
1496             print "--------------\n";
1497         }
1498         print;
1499         last if eof();          # needed if we're reading from a terminal
1500     }
1501
1502 Practical hint: you almost never need to use C<eof> in Perl, because the
1503 input operators typically return C<undef> when they run out of data, or if
1504 there was an error.
1505
1506 =item eval EXPR
1507 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1508 X<error, handling> X<exception, handling>
1509
1510 =item eval BLOCK
1511
1512 =item eval
1513
1514 In the first form, the return value of EXPR is parsed and executed as if it
1515 were a little Perl program.  The value of the expression (which is itself
1516 determined within scalar context) is first parsed, and if there weren't any
1517 errors, executed in the lexical context of the current Perl program, so
1518 that any variable settings or subroutine and format definitions remain
1519 afterwards.  Note that the value is parsed every time the C<eval> executes.
1520 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1521 delay parsing and subsequent execution of the text of EXPR until run time.
1522
1523 In the second form, the code within the BLOCK is parsed only once--at the
1524 same time the code surrounding the C<eval> itself was parsed--and executed
1525 within the context of the current Perl program.  This form is typically
1526 used to trap exceptions more efficiently than the first (see below), while
1527 also providing the benefit of checking the code within BLOCK at compile
1528 time.
1529
1530 The final semicolon, if any, may be omitted from the value of EXPR or within
1531 the BLOCK.
1532
1533 In both forms, the value returned is the value of the last expression
1534 evaluated inside the mini-program; a return statement may be also used, just
1535 as with subroutines.  The expression providing the return value is evaluated
1536 in void, scalar, or list context, depending on the context of the C<eval> 
1537 itself.  See L</wantarray> for more on how the evaluation context can be 
1538 determined.
1539
1540 If there is a syntax error or runtime error, or a C<die> statement is
1541 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1542 error message.  If there was no error, C<$@> is guaranteed to be a null
1543 string.  Beware that using C<eval> neither silences perl from printing
1544 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1545 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1546 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1547 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1548
1549 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1550 determining whether a particular feature (such as C<socket> or C<symlink>)
1551 is implemented.  It is also Perl's exception trapping mechanism, where
1552 the die operator is used to raise exceptions.
1553
1554 If the code to be executed doesn't vary, you may use the eval-BLOCK
1555 form to trap run-time errors without incurring the penalty of
1556 recompiling each time.  The error, if any, is still returned in C<$@>.
1557 Examples:
1558
1559     # make divide-by-zero nonfatal
1560     eval { $answer = $a / $b; }; warn $@ if $@;
1561
1562     # same thing, but less efficient
1563     eval '$answer = $a / $b'; warn $@ if $@;
1564
1565     # a compile-time error
1566     eval { $answer = };                 # WRONG
1567
1568     # a run-time error
1569     eval '$answer =';   # sets $@
1570
1571 Using the C<eval{}> form as an exception trap in libraries does have some
1572 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1573 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1574 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1575 as shown in this example:
1576
1577     # a very private exception trap for divide-by-zero
1578     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1579     warn $@ if $@;
1580
1581 This is especially significant, given that C<__DIE__> hooks can call
1582 C<die> again, which has the effect of changing their error messages:
1583
1584     # __DIE__ hooks may modify error messages
1585     {
1586        local $SIG{'__DIE__'} =
1587               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1588        eval { die "foo lives here" };
1589        print $@ if $@;                # prints "bar lives here"
1590     }
1591
1592 Because this promotes action at a distance, this counterintuitive behavior
1593 may be fixed in a future release.
1594
1595 With an C<eval>, you should be especially careful to remember what's
1596 being looked at when:
1597
1598     eval $x;            # CASE 1
1599     eval "$x";          # CASE 2
1600
1601     eval '$x';          # CASE 3
1602     eval { $x };        # CASE 4
1603
1604     eval "\$$x++";      # CASE 5
1605     $$x++;              # CASE 6
1606
1607 Cases 1 and 2 above behave identically: they run the code contained in
1608 the variable $x.  (Although case 2 has misleading double quotes making
1609 the reader wonder what else might be happening (nothing is).)  Cases 3
1610 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1611 does nothing but return the value of $x.  (Case 4 is preferred for
1612 purely visual reasons, but it also has the advantage of compiling at
1613 compile-time instead of at run-time.)  Case 5 is a place where
1614 normally you I<would> like to use double quotes, except that in this
1615 particular situation, you can just use symbolic references instead, as
1616 in case 6.
1617
1618 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1619 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1620
1621 Note that as a very special case, an C<eval ''> executed within the C<DB>
1622 package doesn't see the usual surrounding lexical scope, but rather the
1623 scope of the first non-DB piece of code that called it. You don't normally
1624 need to worry about this unless you are writing a Perl debugger.
1625
1626 =item exec LIST
1627 X<exec> X<execute>
1628
1629 =item exec PROGRAM LIST
1630
1631 The C<exec> function executes a system command I<and never returns>--
1632 use C<system> instead of C<exec> if you want it to return.  It fails and
1633 returns false only if the command does not exist I<and> it is executed
1634 directly instead of via your system's command shell (see below).
1635
1636 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1637 warns you if there is a following statement which isn't C<die>, C<warn>,
1638 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1639 I<really> want to follow an C<exec> with some other statement, you
1640 can use one of these styles to avoid the warning:
1641
1642     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1643     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1644
1645 If there is more than one argument in LIST, or if LIST is an array
1646 with more than one value, calls execvp(3) with the arguments in LIST.
1647 If there is only one scalar argument or an array with one element in it,
1648 the argument is checked for shell metacharacters, and if there are any,
1649 the entire argument is passed to the system's command shell for parsing
1650 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1651 If there are no shell metacharacters in the argument, it is split into
1652 words and passed directly to C<execvp>, which is more efficient.
1653 Examples:
1654
1655     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1656     exec "sort $outfile | uniq";
1657
1658 If you don't really want to execute the first argument, but want to lie
1659 to the program you are executing about its own name, you can specify
1660 the program you actually want to run as an "indirect object" (without a
1661 comma) in front of the LIST.  (This always forces interpretation of the
1662 LIST as a multivalued list, even if there is only a single scalar in
1663 the list.)  Example:
1664
1665     $shell = '/bin/csh';
1666     exec $shell '-sh';          # pretend it's a login shell
1667
1668 or, more directly,
1669
1670     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1671
1672 When the arguments get executed via the system shell, results will
1673 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1674 for details.
1675
1676 Using an indirect object with C<exec> or C<system> is also more
1677 secure.  This usage (which also works fine with system()) forces
1678 interpretation of the arguments as a multivalued list, even if the
1679 list had just one argument.  That way you're safe from the shell
1680 expanding wildcards or splitting up words with whitespace in them.
1681
1682     @args = ( "echo surprise" );
1683
1684     exec @args;               # subject to shell escapes
1685                                 # if @args == 1
1686     exec { $args[0] } @args;  # safe even with one-arg list
1687
1688 The first version, the one without the indirect object, ran the I<echo>
1689 program, passing it C<"surprise"> an argument.  The second version
1690 didn't--it tried to run a program literally called I<"echo surprise">,
1691 didn't find it, and set C<$?> to a non-zero value indicating failure.
1692
1693 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1694 output before the exec, but this may not be supported on some platforms
1695 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1696 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1697 open handles in order to avoid lost output.
1698
1699 Note that C<exec> will not call your C<END> blocks, nor will it call
1700 any C<DESTROY> methods in your objects.
1701
1702 =item exists EXPR
1703 X<exists> X<autovivification>
1704
1705 Given an expression that specifies a hash element or array element,
1706 returns true if the specified element in the hash or array has ever
1707 been initialized, even if the corresponding value is undefined.  The
1708 element is not autovivified if it doesn't exist.
1709
1710     print "Exists\n"    if exists $hash{$key};
1711     print "Defined\n"   if defined $hash{$key};
1712     print "True\n"      if $hash{$key};
1713
1714     print "Exists\n"    if exists $array[$index];
1715     print "Defined\n"   if defined $array[$index];
1716     print "True\n"      if $array[$index];
1717
1718 A hash or array element can be true only if it's defined, and defined if
1719 it exists, but the reverse doesn't necessarily hold true.
1720
1721 Given an expression that specifies the name of a subroutine,
1722 returns true if the specified subroutine has ever been declared, even
1723 if it is undefined.  Mentioning a subroutine name for exists or defined
1724 does not count as declaring it.  Note that a subroutine which does not
1725 exist may still be callable: its package may have an C<AUTOLOAD>
1726 method that makes it spring into existence the first time that it is
1727 called -- see L<perlsub>.
1728
1729     print "Exists\n"    if exists &subroutine;
1730     print "Defined\n"   if defined &subroutine;
1731
1732 Note that the EXPR can be arbitrarily complicated as long as the final
1733 operation is a hash or array key lookup or subroutine name:
1734
1735     if (exists $ref->{A}->{B}->{$key})  { }
1736     if (exists $hash{A}{B}{$key})       { }
1737
1738     if (exists $ref->{A}->{B}->[$ix])   { }
1739     if (exists $hash{A}{B}[$ix])        { }
1740
1741     if (exists &{$ref->{A}{B}{$key}})   { }
1742
1743 Although the deepest nested array or hash will not spring into existence
1744 just because its existence was tested, any intervening ones will.
1745 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1746 into existence due to the existence test for the $key element above.
1747 This happens anywhere the arrow operator is used, including even:
1748
1749     undef $ref;
1750     if (exists $ref->{"Some key"})      { }
1751     print $ref;             # prints HASH(0x80d3d5c)
1752
1753 This surprising autovivification in what does not at first--or even
1754 second--glance appear to be an lvalue context may be fixed in a future
1755 release.
1756
1757 Use of a subroutine call, rather than a subroutine name, as an argument
1758 to exists() is an error.
1759
1760     exists &sub;        # OK
1761     exists &sub();      # Error
1762
1763 =item exit EXPR
1764 X<exit> X<terminate> X<abort>
1765
1766 =item exit
1767
1768 Evaluates EXPR and exits immediately with that value.    Example:
1769
1770     $ans = <STDIN>;
1771     exit 0 if $ans =~ /^[Xx]/;
1772
1773 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1774 universally recognized values for EXPR are C<0> for success and C<1>
1775 for error; other values are subject to interpretation depending on the
1776 environment in which the Perl program is running.  For example, exiting
1777 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1778 the mailer to return the item undelivered, but that's not true everywhere.
1779
1780 Don't use C<exit> to abort a subroutine if there's any chance that
1781 someone might want to trap whatever error happened.  Use C<die> instead,
1782 which can be trapped by an C<eval>.
1783
1784 The exit() function does not always exit immediately.  It calls any
1785 defined C<END> routines first, but these C<END> routines may not
1786 themselves abort the exit.  Likewise any object destructors that need to
1787 be called are called before the real exit.  If this is a problem, you
1788 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1789 See L<perlmod> for details.
1790
1791 =item exp EXPR
1792 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1793
1794 =item exp
1795
1796 Returns I<e> (the natural logarithm base) to the power of EXPR.
1797 If EXPR is omitted, gives C<exp($_)>.
1798
1799 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1800 X<fcntl>
1801
1802 Implements the fcntl(2) function.  You'll probably have to say
1803
1804     use Fcntl;
1805
1806 first to get the correct constant definitions.  Argument processing and
1807 value return works just like C<ioctl> below.
1808 For example:
1809
1810     use Fcntl;
1811     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1812         or die "can't fcntl F_GETFL: $!";
1813
1814 You don't have to check for C<defined> on the return from C<fcntl>.
1815 Like C<ioctl>, it maps a C<0> return from the system call into
1816 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1817 in numeric context.  It is also exempt from the normal B<-w> warnings
1818 on improper numeric conversions.
1819
1820 Note that C<fcntl> will produce a fatal error if used on a machine that
1821 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1822 manpage to learn what functions are available on your system.
1823
1824 Here's an example of setting a filehandle named C<REMOTE> to be
1825 non-blocking at the system level.  You'll have to negotiate C<$|>
1826 on your own, though.
1827
1828     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1829
1830     $flags = fcntl(REMOTE, F_GETFL, 0)
1831                 or die "Can't get flags for the socket: $!\n";
1832
1833     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1834                 or die "Can't set flags for the socket: $!\n";
1835
1836 =item fileno FILEHANDLE
1837 X<fileno>
1838
1839 Returns the file descriptor for a filehandle, or undefined if the
1840 filehandle is not open.  This is mainly useful for constructing
1841 bitmaps for C<select> and low-level POSIX tty-handling operations.
1842 If FILEHANDLE is an expression, the value is taken as an indirect
1843 filehandle, generally its name.
1844
1845 You can use this to find out whether two handles refer to the
1846 same underlying descriptor:
1847
1848     if (fileno(THIS) == fileno(THAT)) {
1849         print "THIS and THAT are dups\n";
1850     }
1851
1852 (Filehandles connected to memory objects via new features of C<open> may
1853 return undefined even though they are open.)
1854
1855
1856 =item flock FILEHANDLE,OPERATION
1857 X<flock> X<lock> X<locking>
1858
1859 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1860 for success, false on failure.  Produces a fatal error if used on a
1861 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1862 C<flock> is Perl's portable file locking interface, although it locks
1863 only entire files, not records.
1864
1865 Two potentially non-obvious but traditional C<flock> semantics are
1866 that it waits indefinitely until the lock is granted, and that its locks
1867 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1868 fewer guarantees.  This means that programs that do not also use C<flock>
1869 may modify files locked with C<flock>.  See L<perlport>, 
1870 your port's specific documentation, or your system-specific local manpages
1871 for details.  It's best to assume traditional behavior if you're writing
1872 portable programs.  (But if you're not, you should as always feel perfectly
1873 free to write for your own system's idiosyncrasies (sometimes called
1874 "features").  Slavish adherence to portability concerns shouldn't get
1875 in the way of your getting your job done.)
1876
1877 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1878 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1879 you can use the symbolic names if you import them from the Fcntl module,
1880 either individually, or as a group using the ':flock' tag.  LOCK_SH
1881 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1882 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1883 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1884 waiting for the lock (check the return status to see if you got it).
1885
1886 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1887 before locking or unlocking it.
1888
1889 Note that the emulation built with lockf(3) doesn't provide shared
1890 locks, and it requires that FILEHANDLE be open with write intent.  These
1891 are the semantics that lockf(3) implements.  Most if not all systems
1892 implement lockf(3) in terms of fcntl(2) locking, though, so the
1893 differing semantics shouldn't bite too many people.
1894
1895 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1896 be open with read intent to use LOCK_SH and requires that it be open
1897 with write intent to use LOCK_EX.
1898
1899 Note also that some versions of C<flock> cannot lock things over the
1900 network; you would need to use the more system-specific C<fcntl> for
1901 that.  If you like you can force Perl to ignore your system's flock(2)
1902 function, and so provide its own fcntl(2)-based emulation, by passing
1903 the switch C<-Ud_flock> to the F<Configure> program when you configure
1904 perl.
1905
1906 Here's a mailbox appender for BSD systems.
1907
1908     use Fcntl ':flock'; # import LOCK_* constants
1909
1910     sub lock {
1911         flock(MBOX,LOCK_EX);
1912         # and, in case someone appended
1913         # while we were waiting...
1914         seek(MBOX, 0, 2);
1915     }
1916
1917     sub unlock {
1918         flock(MBOX,LOCK_UN);
1919     }
1920
1921     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1922             or die "Can't open mailbox: $!";
1923
1924     lock();
1925     print MBOX $msg,"\n\n";
1926     unlock();
1927
1928 On systems that support a real flock(), locks are inherited across fork()
1929 calls, whereas those that must resort to the more capricious fcntl()
1930 function lose the locks, making it harder to write servers.
1931
1932 See also L<DB_File> for other flock() examples.
1933
1934 =item fork
1935 X<fork> X<child> X<parent>
1936
1937 Does a fork(2) system call to create a new process running the
1938 same program at the same point.  It returns the child pid to the
1939 parent process, C<0> to the child process, or C<undef> if the fork is
1940 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1941 are shared, while everything else is copied.  On most systems supporting
1942 fork(), great care has gone into making it extremely efficient (for
1943 example, using copy-on-write technology on data pages), making it the
1944 dominant paradigm for multitasking over the last few decades.
1945
1946 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1947 output before forking the child process, but this may not be supported
1948 on some platforms (see L<perlport>).  To be safe, you may need to set
1949 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1950 C<IO::Handle> on any open handles in order to avoid duplicate output.
1951
1952 If you C<fork> without ever waiting on your children, you will
1953 accumulate zombies.  On some systems, you can avoid this by setting
1954 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1955 forking and reaping moribund children.
1956
1957 Note that if your forked child inherits system file descriptors like
1958 STDIN and STDOUT that are actually connected by a pipe or socket, even
1959 if you exit, then the remote server (such as, say, a CGI script or a
1960 backgrounded job launched from a remote shell) won't think you're done.
1961 You should reopen those to F</dev/null> if it's any issue.
1962
1963 =item format
1964 X<format>
1965
1966 Declare a picture format for use by the C<write> function.  For
1967 example:
1968
1969     format Something =
1970         Test: @<<<<<<<< @||||| @>>>>>
1971               $str,     $%,    '$' . int($num)
1972     .
1973
1974     $str = "widget";
1975     $num = $cost/$quantity;
1976     $~ = 'Something';
1977     write;
1978
1979 See L<perlform> for many details and examples.
1980
1981 =item formline PICTURE,LIST
1982 X<formline>
1983
1984 This is an internal function used by C<format>s, though you may call it,
1985 too.  It formats (see L<perlform>) a list of values according to the
1986 contents of PICTURE, placing the output into the format output
1987 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1988 Eventually, when a C<write> is done, the contents of
1989 C<$^A> are written to some filehandle.  You could also read C<$^A>
1990 and then set C<$^A> back to C<"">.  Note that a format typically
1991 does one C<formline> per line of form, but the C<formline> function itself
1992 doesn't care how many newlines are embedded in the PICTURE.  This means
1993 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1994 You may therefore need to use multiple formlines to implement a single
1995 record format, just like the format compiler.
1996
1997 Be careful if you put double quotes around the picture, because an C<@>
1998 character may be taken to mean the beginning of an array name.
1999 C<formline> always returns true.  See L<perlform> for other examples.
2000
2001 =item getc FILEHANDLE
2002 X<getc> X<getchar> X<character> X<file, read>
2003
2004 =item getc
2005
2006 Returns the next character from the input file attached to FILEHANDLE,
2007 or the undefined value at end of file, or if there was an error (in
2008 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2009 STDIN.  This is not particularly efficient.  However, it cannot be
2010 used by itself to fetch single characters without waiting for the user
2011 to hit enter.  For that, try something more like:
2012
2013     if ($BSD_STYLE) {
2014         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2015     }
2016     else {
2017         system "stty", '-icanon', 'eol', "\001";
2018     }
2019
2020     $key = getc(STDIN);
2021
2022     if ($BSD_STYLE) {
2023         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2024     }
2025     else {
2026         system "stty", 'icanon', 'eol', '^@'; # ASCII null
2027     }
2028     print "\n";
2029
2030 Determination of whether $BSD_STYLE should be set
2031 is left as an exercise to the reader.
2032
2033 The C<POSIX::getattr> function can do this more portably on
2034 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2035 module from your nearest CPAN site; details on CPAN can be found on
2036 L<perlmodlib/CPAN>.
2037
2038 =item getlogin
2039 X<getlogin> X<login>
2040
2041 This implements the C library function of the same name, which on most
2042 systems returns the current login from F</etc/utmp>, if any.  If null,
2043 use C<getpwuid>.
2044
2045     $login = getlogin || getpwuid($<) || "Kilroy";
2046
2047 Do not consider C<getlogin> for authentication: it is not as
2048 secure as C<getpwuid>.
2049
2050 =item getpeername SOCKET
2051 X<getpeername> X<peer>
2052
2053 Returns the packed sockaddr address of other end of the SOCKET connection.
2054
2055     use Socket;
2056     $hersockaddr    = getpeername(SOCK);
2057     ($port, $iaddr) = sockaddr_in($hersockaddr);
2058     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2059     $herstraddr     = inet_ntoa($iaddr);
2060
2061 =item getpgrp PID
2062 X<getpgrp> X<group>
2063
2064 Returns the current process group for the specified PID.  Use
2065 a PID of C<0> to get the current process group for the
2066 current process.  Will raise an exception if used on a machine that
2067 doesn't implement getpgrp(2).  If PID is omitted, returns process
2068 group of current process.  Note that the POSIX version of C<getpgrp>
2069 does not accept a PID argument, so only C<PID==0> is truly portable.
2070
2071 =item getppid
2072 X<getppid> X<parent> X<pid>
2073
2074 Returns the process id of the parent process.
2075
2076 Note for Linux users: on Linux, the C functions C<getpid()> and
2077 C<getppid()> return different values from different threads. In order to
2078 be portable, this behavior is not reflected by the perl-level function
2079 C<getppid()>, that returns a consistent value across threads. If you want
2080 to call the underlying C<getppid()>, you may use the CPAN module
2081 C<Linux::Pid>.
2082
2083 =item getpriority WHICH,WHO
2084 X<getpriority> X<priority> X<nice>
2085
2086 Returns the current priority for a process, a process group, or a user.
2087 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2088 machine that doesn't implement getpriority(2).
2089
2090 =item getpwnam NAME
2091 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2092 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2093 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2094 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2095 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2096 X<endnetent> X<endprotoent> X<endservent> 
2097
2098 =item getgrnam NAME
2099
2100 =item gethostbyname NAME
2101
2102 =item getnetbyname NAME
2103
2104 =item getprotobyname NAME
2105
2106 =item getpwuid UID
2107
2108 =item getgrgid GID
2109
2110 =item getservbyname NAME,PROTO
2111
2112 =item gethostbyaddr ADDR,ADDRTYPE
2113
2114 =item getnetbyaddr ADDR,ADDRTYPE
2115
2116 =item getprotobynumber NUMBER
2117
2118 =item getservbyport PORT,PROTO
2119
2120 =item getpwent
2121
2122 =item getgrent
2123
2124 =item gethostent
2125
2126 =item getnetent
2127
2128 =item getprotoent
2129
2130 =item getservent
2131
2132 =item setpwent
2133
2134 =item setgrent
2135
2136 =item sethostent STAYOPEN
2137
2138 =item setnetent STAYOPEN
2139
2140 =item setprotoent STAYOPEN
2141
2142 =item setservent STAYOPEN
2143
2144 =item endpwent
2145
2146 =item endgrent
2147
2148 =item endhostent
2149
2150 =item endnetent
2151
2152 =item endprotoent
2153
2154 =item endservent
2155
2156 These routines perform the same functions as their counterparts in the
2157 system library.  In list context, the return values from the
2158 various get routines are as follows:
2159
2160     ($name,$passwd,$uid,$gid,
2161        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2162     ($name,$passwd,$gid,$members) = getgr*
2163     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2164     ($name,$aliases,$addrtype,$net) = getnet*
2165     ($name,$aliases,$proto) = getproto*
2166     ($name,$aliases,$port,$proto) = getserv*
2167
2168 (If the entry doesn't exist you get a null list.)
2169
2170 The exact meaning of the $gcos field varies but it usually contains
2171 the real name of the user (as opposed to the login name) and other
2172 information pertaining to the user.  Beware, however, that in many
2173 system users are able to change this information and therefore it
2174 cannot be trusted and therefore the $gcos is tainted (see
2175 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2176 login shell, are also tainted, because of the same reason.
2177
2178 In scalar context, you get the name, unless the function was a
2179 lookup by name, in which case you get the other thing, whatever it is.
2180 (If the entry doesn't exist you get the undefined value.)  For example:
2181
2182     $uid   = getpwnam($name);
2183     $name  = getpwuid($num);
2184     $name  = getpwent();
2185     $gid   = getgrnam($name);
2186     $name  = getgrgid($num);
2187     $name  = getgrent();
2188     #etc.
2189
2190 In I<getpw*()> the fields $quota, $comment, and $expire are special
2191 cases in the sense that in many systems they are unsupported.  If the
2192 $quota is unsupported, it is an empty scalar.  If it is supported, it
2193 usually encodes the disk quota.  If the $comment field is unsupported,
2194 it is an empty scalar.  If it is supported it usually encodes some
2195 administrative comment about the user.  In some systems the $quota
2196 field may be $change or $age, fields that have to do with password
2197 aging.  In some systems the $comment field may be $class.  The $expire
2198 field, if present, encodes the expiration period of the account or the
2199 password.  For the availability and the exact meaning of these fields
2200 in your system, please consult your getpwnam(3) documentation and your
2201 F<pwd.h> file.  You can also find out from within Perl what your
2202 $quota and $comment fields mean and whether you have the $expire field
2203 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2204 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2205 files are only supported if your vendor has implemented them in the
2206 intuitive fashion that calling the regular C library routines gets the
2207 shadow versions if you're running under privilege or if there exists
2208 the shadow(3) functions as found in System V (this includes Solaris
2209 and Linux.)  Those systems that implement a proprietary shadow password
2210 facility are unlikely to be supported.
2211
2212 The $members value returned by I<getgr*()> is a space separated list of
2213 the login names of the members of the group.
2214
2215 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2216 C, it will be returned to you via C<$?> if the function call fails.  The
2217 C<@addrs> value returned by a successful call is a list of the raw
2218 addresses returned by the corresponding system library call.  In the
2219 Internet domain, each address is four bytes long and you can unpack it
2220 by saying something like:
2221
2222     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2223
2224 The Socket library makes this slightly easier:
2225
2226     use Socket;
2227     $iaddr = inet_aton("127.1"); # or whatever address
2228     $name  = gethostbyaddr($iaddr, AF_INET);
2229
2230     # or going the other way
2231     $straddr = inet_ntoa($iaddr);
2232
2233 In the opposite way, to resolve a hostname to the IP address
2234 you can write this:
2235
2236     use Socket;
2237     $packed_ip = gethostbyname("www.perl.org");
2238     if (defined $packed_ip) {
2239         $ip_address = inet_ntoa($packed_ip);
2240     }
2241
2242 Make sure <gethostbyname()> is called in SCALAR context and that
2243 its return value is checked for definedness.
2244
2245 If you get tired of remembering which element of the return list
2246 contains which return value, by-name interfaces are provided
2247 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2248 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2249 and C<User::grent>.  These override the normal built-ins, supplying
2250 versions that return objects with the appropriate names
2251 for each field.  For example:
2252
2253    use File::stat;
2254    use User::pwent;
2255    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2256
2257 Even though it looks like they're the same method calls (uid),
2258 they aren't, because a C<File::stat> object is different from
2259 a C<User::pwent> object.
2260
2261 =item getsockname SOCKET
2262 X<getsockname>
2263
2264 Returns the packed sockaddr address of this end of the SOCKET connection,
2265 in case you don't know the address because you have several different
2266 IPs that the connection might have come in on.
2267
2268     use Socket;
2269     $mysockaddr = getsockname(SOCK);
2270     ($port, $myaddr) = sockaddr_in($mysockaddr);
2271     printf "Connect to %s [%s]\n",
2272        scalar gethostbyaddr($myaddr, AF_INET),
2273        inet_ntoa($myaddr);
2274
2275 =item getsockopt SOCKET,LEVEL,OPTNAME
2276 X<getsockopt>
2277
2278 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2279 Options may exist at multiple protocol levels depending on the socket
2280 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2281 C<Socket> module) will exist. To query options at another level the
2282 protocol number of the appropriate protocol controlling the option
2283 should be supplied. For example, to indicate that an option is to be
2284 interpreted by the TCP protocol, LEVEL should be set to the protocol
2285 number of TCP, which you can get using getprotobyname.
2286
2287 The call returns a packed string representing the requested socket option,
2288 or C<undef> if there is an error (the error reason will be in $!). What
2289 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2290 your system documentation for details. A very common case however is that
2291 the option is an integer, in which case the result will be a packed
2292 integer which you can decode using unpack with the C<i> (or C<I>) format.
2293
2294 An example testing if Nagle's algorithm is turned on on a socket:
2295
2296     use Socket qw(:all);
2297
2298     defined(my $tcp = getprotobyname("tcp"))
2299         or die "Could not determine the protocol number for tcp";
2300     # my $tcp = IPPROTO_TCP; # Alternative
2301     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2302         or die "Could not query TCP_NODELAY socket option: $!";
2303     my $nodelay = unpack("I", $packed);
2304     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2305
2306
2307 =item glob EXPR
2308 X<glob> X<wildcard> X<filename, expansion> X<expand>
2309
2310 =item glob
2311
2312 In list context, returns a (possibly empty) list of filename expansions on
2313 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2314 scalar context, glob iterates through such filename expansions, returning
2315 undef when the list is exhausted. This is the internal function
2316 implementing the C<< <*.c> >> operator, but you can use it directly. If
2317 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2318 more detail in L<perlop/"I/O Operators">.
2319
2320 Beginning with v5.6.0, this operator is implemented using the standard
2321 C<File::Glob> extension.  See L<File::Glob> for details.
2322
2323 =item gmtime EXPR
2324 X<gmtime> X<UTC> X<Greenwich>
2325
2326 =item gmtime
2327
2328 Works just like L<localtime> but the returned values are
2329 localized for the standard Greenwich time zone.
2330
2331 Note: when called in list context, $isdst, the last value
2332 returned by gmtime is always C<0>.  There is no
2333 Daylight Saving Time in GMT.
2334
2335 See L<perlport/gmtime> for portability concerns.
2336
2337 =item goto LABEL
2338 X<goto> X<jump> X<jmp>
2339
2340 =item goto EXPR
2341
2342 =item goto &NAME
2343
2344 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2345 execution there.  It may not be used to go into any construct that
2346 requires initialization, such as a subroutine or a C<foreach> loop.  It
2347 also can't be used to go into a construct that is optimized away,
2348 or to get out of a block or subroutine given to C<sort>.
2349 It can be used to go almost anywhere else within the dynamic scope,
2350 including out of subroutines, but it's usually better to use some other
2351 construct such as C<last> or C<die>.  The author of Perl has never felt the
2352 need to use this form of C<goto> (in Perl, that is--C is another matter).
2353 (The difference being that C does not offer named loops combined with
2354 loop control.  Perl does, and this replaces most structured uses of C<goto>
2355 in other languages.)
2356
2357 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2358 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2359 necessarily recommended if you're optimizing for maintainability:
2360
2361     goto ("FOO", "BAR", "GLARCH")[$i];
2362
2363 The C<goto-&NAME> form is quite different from the other forms of
2364 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2365 doesn't have the stigma associated with other gotos.  Instead, it
2366 exits the current subroutine (losing any changes set by local()) and
2367 immediately calls in its place the named subroutine using the current
2368 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2369 load another subroutine and then pretend that the other subroutine had
2370 been called in the first place (except that any modifications to C<@_>
2371 in the current subroutine are propagated to the other subroutine.)
2372 After the C<goto>, not even C<caller> will be able to tell that this
2373 routine was called first.
2374
2375 NAME needn't be the name of a subroutine; it can be a scalar variable
2376 containing a code reference, or a block that evaluates to a code
2377 reference.
2378
2379 =item grep BLOCK LIST
2380 X<grep>
2381
2382 =item grep EXPR,LIST
2383
2384 This is similar in spirit to, but not the same as, grep(1) and its
2385 relatives.  In particular, it is not limited to using regular expressions.
2386
2387 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2388 C<$_> to each element) and returns the list value consisting of those
2389 elements for which the expression evaluated to true.  In scalar
2390 context, returns the number of times the expression was true.
2391
2392     @foo = grep(!/^#/, @bar);    # weed out comments
2393
2394 or equivalently,
2395
2396     @foo = grep {!/^#/} @bar;    # weed out comments
2397
2398 Note that C<$_> is an alias to the list value, so it can be used to
2399 modify the elements of the LIST.  While this is useful and supported,
2400 it can cause bizarre results if the elements of LIST are not variables.
2401 Similarly, grep returns aliases into the original list, much as a for
2402 loop's index variable aliases the list elements.  That is, modifying an
2403 element of a list returned by grep (for example, in a C<foreach>, C<map>
2404 or another C<grep>) actually modifies the element in the original list.
2405 This is usually something to be avoided when writing clear code.
2406
2407 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2408 been declared with C<my $_>) then, in addition to being locally aliased to
2409 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2410 can't be seen from the outside, avoiding any potential side-effects.
2411
2412 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2413
2414 =item hex EXPR
2415 X<hex> X<hexadecimal>
2416
2417 =item hex
2418
2419 Interprets EXPR as a hex string and returns the corresponding value.
2420 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2421 L</oct>.)  If EXPR is omitted, uses C<$_>.
2422
2423     print hex '0xAf'; # prints '175'
2424     print hex 'aF';   # same
2425
2426 Hex strings may only represent integers.  Strings that would cause
2427 integer overflow trigger a warning.  Leading whitespace is not stripped,
2428 unlike oct(). To present something as hex, look into L</printf>,
2429 L</sprintf>, or L</unpack>.
2430
2431 =item import LIST
2432 X<import>
2433
2434 There is no builtin C<import> function.  It is just an ordinary
2435 method (subroutine) defined (or inherited) by modules that wish to export
2436 names to another module.  The C<use> function calls the C<import> method
2437 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2438
2439 =item index STR,SUBSTR,POSITION
2440 X<index> X<indexOf> X<InStr>
2441
2442 =item index STR,SUBSTR
2443
2444 The index function searches for one string within another, but without
2445 the wildcard-like behavior of a full regular-expression pattern match.
2446 It returns the position of the first occurrence of SUBSTR in STR at
2447 or after POSITION.  If POSITION is omitted, starts searching from the
2448 beginning of the string.  POSITION before the beginning of the string
2449 or after its end is treated as if it were the beginning or the end,
2450 respectively.  POSITION and the return value are based at C<0> (or whatever
2451 you've set the C<$[> variable to--but don't do that).  If the substring
2452 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2453
2454 =item int EXPR
2455 X<int> X<integer> X<truncate> X<trunc> X<floor>
2456
2457 =item int
2458
2459 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2460 You should not use this function for rounding: one because it truncates
2461 towards C<0>, and two because machine representations of floating point
2462 numbers can sometimes produce counterintuitive results.  For example,
2463 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2464 because it's really more like -268.99999999999994315658 instead.  Usually,
2465 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2466 functions will serve you better than will int().
2467
2468 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2469 X<ioctl>
2470
2471 Implements the ioctl(2) function.  You'll probably first have to say
2472
2473     require "sys/ioctl.ph";     # probably in $Config{archlib}/sys/ioctl.ph
2474
2475 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2476 exist or doesn't have the correct definitions you'll have to roll your
2477 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2478 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2479 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2480 written depending on the FUNCTION--a pointer to the string value of SCALAR
2481 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2482 has no string value but does have a numeric value, that value will be
2483 passed rather than a pointer to the string value.  To guarantee this to be
2484 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2485 functions may be needed to manipulate the values of structures used by
2486 C<ioctl>.
2487
2488 The return value of C<ioctl> (and C<fcntl>) is as follows:
2489
2490         if OS returns:          then Perl returns:
2491             -1                    undefined value
2492              0                  string "0 but true"
2493         anything else               that number
2494
2495 Thus Perl returns true on success and false on failure, yet you can
2496 still easily determine the actual value returned by the operating
2497 system:
2498
2499     $retval = ioctl(...) || -1;
2500     printf "System returned %d\n", $retval;
2501
2502 The special string C<"0 but true"> is exempt from B<-w> complaints
2503 about improper numeric conversions.
2504
2505 =item join EXPR,LIST
2506 X<join>
2507
2508 Joins the separate strings of LIST into a single string with fields
2509 separated by the value of EXPR, and returns that new string.  Example:
2510
2511     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2512
2513 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2514 first argument.  Compare L</split>.
2515
2516 =item keys HASH
2517 X<keys> X<key>
2518
2519 Returns a list consisting of all the keys of the named hash.
2520 (In scalar context, returns the number of keys.)
2521
2522 The keys are returned in an apparently random order.  The actual
2523 random order is subject to change in future versions of perl, but it
2524 is guaranteed to be the same order as either the C<values> or C<each>
2525 function produces (given that the hash has not been modified).  Since
2526 Perl 5.8.1 the ordering is different even between different runs of
2527 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2528 Attacks">).
2529
2530 As a side effect, calling keys() resets the HASH's internal iterator
2531 (see L</each>).  In particular, calling keys() in void context resets
2532 the iterator with no other overhead.
2533
2534 Here is yet another way to print your environment:
2535
2536     @keys = keys %ENV;
2537     @values = values %ENV;
2538     while (@keys) {
2539         print pop(@keys), '=', pop(@values), "\n";
2540     }
2541
2542 or how about sorted by key:
2543
2544     foreach $key (sort(keys %ENV)) {
2545         print $key, '=', $ENV{$key}, "\n";
2546     }
2547
2548 The returned values are copies of the original keys in the hash, so
2549 modifying them will not affect the original hash.  Compare L</values>.
2550
2551 To sort a hash by value, you'll need to use a C<sort> function.
2552 Here's a descending numeric sort of a hash by its values:
2553
2554     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2555         printf "%4d %s\n", $hash{$key}, $key;
2556     }
2557
2558 As an lvalue C<keys> allows you to increase the number of hash buckets
2559 allocated for the given hash.  This can gain you a measure of efficiency if
2560 you know the hash is going to get big.  (This is similar to pre-extending
2561 an array by assigning a larger number to $#array.)  If you say
2562
2563     keys %hash = 200;
2564
2565 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2566 in fact, since it rounds up to the next power of two.  These
2567 buckets will be retained even if you do C<%hash = ()>, use C<undef
2568 %hash> if you want to free the storage while C<%hash> is still in scope.
2569 You can't shrink the number of buckets allocated for the hash using
2570 C<keys> in this way (but you needn't worry about doing this by accident,
2571 as trying has no effect).
2572
2573 See also C<each>, C<values> and C<sort>.
2574
2575 =item kill SIGNAL, LIST
2576 X<kill> X<signal>
2577
2578 Sends a signal to a list of processes.  Returns the number of
2579 processes successfully signaled (which is not necessarily the
2580 same as the number actually killed).
2581
2582     $cnt = kill 1, $child1, $child2;
2583     kill 9, @goners;
2584
2585 If SIGNAL is zero, no signal is sent to the process, but the kill(2)
2586 system call will check whether it's possible to send a signal to it (that
2587 means, to be brief, that the process is owned by the same user, or we are
2588 the super-user).  This is a useful way to check that a child process is
2589 alive (even if only as a zombie) and hasn't changed its UID.  See
2590 L<perlport> for notes on the portability of this construct.
2591
2592 Unlike in the shell, if SIGNAL is negative, it kills
2593 process groups instead of processes.  (On System V, a negative I<PROCESS>
2594 number will also kill process groups, but that's not portable.)  That
2595 means you usually want to use positive not negative signals.  You may also
2596 use a signal name in quotes.
2597
2598 See L<perlipc/"Signals"> for more details.
2599
2600 =item last LABEL
2601 X<last> X<break>
2602
2603 =item last
2604
2605 The C<last> command is like the C<break> statement in C (as used in
2606 loops); it immediately exits the loop in question.  If the LABEL is
2607 omitted, the command refers to the innermost enclosing loop.  The
2608 C<continue> block, if any, is not executed:
2609
2610     LINE: while (<STDIN>) {
2611         last LINE if /^$/;      # exit when done with header
2612         #...
2613     }
2614
2615 C<last> cannot be used to exit a block which returns a value such as
2616 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2617 a grep() or map() operation.
2618
2619 Note that a block by itself is semantically identical to a loop
2620 that executes once.  Thus C<last> can be used to effect an early
2621 exit out of such a block.
2622
2623 See also L</continue> for an illustration of how C<last>, C<next>, and
2624 C<redo> work.
2625
2626 =item lc EXPR
2627 X<lc> X<lowercase>
2628
2629 =item lc
2630
2631 Returns a lowercased version of EXPR.  This is the internal function
2632 implementing the C<\L> escape in double-quoted strings.  Respects
2633 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2634 and L<perlunicode> for more details about locale and Unicode support.
2635
2636 If EXPR is omitted, uses C<$_>.
2637
2638 =item lcfirst EXPR
2639 X<lcfirst> X<lowercase>
2640
2641 =item lcfirst
2642
2643 Returns the value of EXPR with the first character lowercased.  This
2644 is the internal function implementing the C<\l> escape in
2645 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2646 locale> in force.  See L<perllocale> and L<perlunicode> for more
2647 details about locale and Unicode support.
2648
2649 If EXPR is omitted, uses C<$_>.
2650
2651 =item length EXPR
2652 X<length> X<size>
2653
2654 =item length
2655
2656 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2657 omitted, returns length of C<$_>.  Note that this cannot be used on
2658 an entire array or hash to find out how many elements these have.
2659 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2660
2661 Note the I<characters>: if the EXPR is in Unicode, you will get the
2662 number of characters, not the number of bytes.  To get the length
2663 of the internal string in bytes, use C<bytes::length(EXPR)>, see
2664 L<bytes>.  Note that the internal encoding is variable, and the number
2665 of bytes usually meaningless.  To get the number of bytes that the
2666 string would have when encoded as UTF-8, use
2667 C<length(Encoding::encode_utf8(EXPR))>.
2668
2669 =item link OLDFILE,NEWFILE
2670 X<link>
2671
2672 Creates a new filename linked to the old filename.  Returns true for
2673 success, false otherwise.
2674
2675 =item listen SOCKET,QUEUESIZE
2676 X<listen>
2677
2678 Does the same thing that the listen system call does.  Returns true if
2679 it succeeded, false otherwise.  See the example in
2680 L<perlipc/"Sockets: Client/Server Communication">.
2681
2682 =item local EXPR
2683 X<local>
2684
2685 You really probably want to be using C<my> instead, because C<local> isn't
2686 what most people think of as "local".  See
2687 L<perlsub/"Private Variables via my()"> for details.
2688
2689 A local modifies the listed variables to be local to the enclosing
2690 block, file, or eval.  If more than one value is listed, the list must
2691 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2692 for details, including issues with tied arrays and hashes.
2693
2694 =item localtime EXPR
2695 X<localtime> X<ctime>
2696
2697 =item localtime
2698
2699 Converts a time as returned by the time function to a 9-element list
2700 with the time analyzed for the local time zone.  Typically used as
2701 follows:
2702
2703     #  0    1    2     3     4    5     6     7     8
2704     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2705                                                 localtime(time);
2706
2707 All list elements are numeric, and come straight out of the C `struct
2708 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2709 of the specified time.
2710
2711 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2712 the range C<0..11> with 0 indicating January and 11 indicating December.
2713 This makes it easy to get a month name from a list:
2714
2715     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2716     print "$abbr[$mon] $mday";
2717     # $mon=9, $mday=18 gives "Oct 18"
2718
2719 C<$year> is the number of years since 1900, not just the last two digits
2720 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2721 to get a complete 4-digit year is simply:
2722
2723     $year += 1900;
2724
2725 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
2726 to do that, would you?
2727
2728 To get the last two digits of the year (e.g., '01' in 2001) do:
2729
2730     $year = sprintf("%02d", $year % 100);
2731
2732 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2733 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2734 (or C<0..365> in leap years.)
2735
2736 C<$isdst> is true if the specified time occurs during Daylight Saving
2737 Time, false otherwise.
2738
2739 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2740
2741 In scalar context, C<localtime()> returns the ctime(3) value:
2742
2743     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2744
2745 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2746 instead of local time use the L</gmtime> builtin. See also the
2747 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2748 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2749 and mktime(3) functions.
2750
2751 To get somewhat similar but locale dependent date strings, set up your
2752 locale environment variables appropriately (please see L<perllocale>) and
2753 try for example:
2754
2755     use POSIX qw(strftime);
2756     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2757     # or for GMT formatted appropriately for your locale:
2758     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2759
2760 Note that the C<%a> and C<%b>, the short forms of the day of the week
2761 and the month of the year, may not necessarily be three characters wide.
2762
2763 See L<perlport/localtime> for portability concerns.
2764
2765 The L<Time::gmtime> and L<Time::localtime> modules provides a convenient,
2766 by-name access mechanism to the gmtime() and localtime() functions,
2767 respectively.
2768
2769 For a comprehensive date and time representation look at the
2770 L<DateTime> module on CPAN.
2771
2772 =item lock THING
2773 X<lock>
2774
2775 This function places an advisory lock on a shared variable, or referenced
2776 object contained in I<THING> until the lock goes out of scope.
2777
2778 lock() is a "weak keyword" : this means that if you've defined a function
2779 by this name (before any calls to it), that function will be called
2780 instead. (However, if you've said C<use threads>, lock() is always a
2781 keyword.) See L<threads>.
2782
2783 =item log EXPR
2784 X<log> X<logarithm> X<e> X<ln> X<base>
2785
2786 =item log
2787
2788 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2789 returns log of C<$_>.  To get the log of another base, use basic algebra:
2790 The base-N log of a number is equal to the natural log of that number
2791 divided by the natural log of N.  For example:
2792
2793     sub log10 {
2794         my $n = shift;
2795         return log($n)/log(10);
2796     }
2797
2798 See also L</exp> for the inverse operation.
2799
2800 =item lstat EXPR
2801 X<lstat>
2802
2803 =item lstat
2804
2805 Does the same thing as the C<stat> function (including setting the
2806 special C<_> filehandle) but stats a symbolic link instead of the file
2807 the symbolic link points to.  If symbolic links are unimplemented on
2808 your system, a normal C<stat> is done.  For much more detailed
2809 information, please see the documentation for C<stat>.
2810
2811 If EXPR is omitted, stats C<$_>.
2812
2813 =item m//
2814
2815 The match operator.  See L<perlop>.
2816
2817 =item map BLOCK LIST
2818 X<map>
2819
2820 =item map EXPR,LIST
2821
2822 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2823 C<$_> to each element) and returns the list value composed of the
2824 results of each such evaluation.  In scalar context, returns the
2825 total number of elements so generated.  Evaluates BLOCK or EXPR in
2826 list context, so each element of LIST may produce zero, one, or
2827 more elements in the returned value.
2828
2829     @chars = map(chr, @nums);
2830
2831 translates a list of numbers to the corresponding characters.  And
2832
2833     %hash = map { get_a_key_for($_) => $_ } @array;
2834
2835 is just a funny way to write
2836
2837     %hash = ();
2838     foreach (@array) {
2839         $hash{get_a_key_for($_)} = $_;
2840     }
2841
2842 Note that C<$_> is an alias to the list value, so it can be used to
2843 modify the elements of the LIST.  While this is useful and supported,
2844 it can cause bizarre results if the elements of LIST are not variables.
2845 Using a regular C<foreach> loop for this purpose would be clearer in
2846 most cases.  See also L</grep> for an array composed of those items of
2847 the original list for which the BLOCK or EXPR evaluates to true.
2848
2849 If C<$_> is lexical in the scope where the C<map> appears (because it has
2850 been declared with C<my $_>), then, in addition to being locally aliased to
2851 the list elements, C<$_> keeps being lexical inside the block; that is, it
2852 can't be seen from the outside, avoiding any potential side-effects.
2853
2854 C<{> starts both hash references and blocks, so C<map { ...> could be either
2855 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2856 ahead for the closing C<}> it has to take a guess at which its dealing with
2857 based what it finds just after the C<{>. Usually it gets it right, but if it
2858 doesn't it won't realize something is wrong until it gets to the C<}> and
2859 encounters the missing (or unexpected) comma. The syntax error will be
2860 reported close to the C<}> but you'll need to change something near the C<{>
2861 such as using a unary C<+> to give perl some help:
2862
2863     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2864     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2865     %hash = map { ("\L$_", 1) } @array  # this also works
2866     %hash = map {  lc($_), 1  } @array  # as does this.
2867     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2868
2869     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2870
2871 or to force an anon hash constructor use C<+{>:
2872
2873    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2874
2875 and you get list of anonymous hashes each with only 1 entry.
2876
2877 =item mkdir FILENAME,MASK
2878 X<mkdir> X<md> X<directory, create>
2879
2880 =item mkdir FILENAME
2881
2882 =item mkdir
2883
2884 Creates the directory specified by FILENAME, with permissions
2885 specified by MASK (as modified by C<umask>).  If it succeeds it
2886 returns true, otherwise it returns false and sets C<$!> (errno).
2887 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2888 to C<$_>.
2889
2890 In general, it is better to create directories with permissive MASK,
2891 and let the user modify that with their C<umask>, than it is to supply
2892 a restrictive MASK and give the user no way to be more permissive.
2893 The exceptions to this rule are when the file or directory should be
2894 kept private (mail files, for instance).  The perlfunc(1) entry on
2895 C<umask> discusses the choice of MASK in more detail.
2896
2897 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2898 number of trailing slashes.  Some operating and filesystems do not get
2899 this right, so Perl automatically removes all trailing slashes to keep
2900 everyone happy.
2901
2902 In order to recursively create a directory structure look at
2903 the C<mkpath> function of the L<File::Path> module.
2904
2905 =item msgctl ID,CMD,ARG
2906 X<msgctl>
2907
2908 Calls the System V IPC function msgctl(2).  You'll probably have to say
2909
2910     use IPC::SysV;
2911
2912 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2913 then ARG must be a variable that will hold the returned C<msqid_ds>
2914 structure.  Returns like C<ioctl>: the undefined value for error,
2915 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2916 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2917
2918 =item msgget KEY,FLAGS
2919 X<msgget>
2920
2921 Calls the System V IPC function msgget(2).  Returns the message queue
2922 id, or the undefined value if there is an error.  See also
2923 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2924
2925 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2926 X<msgrcv>
2927
2928 Calls the System V IPC function msgrcv to receive a message from
2929 message queue ID into variable VAR with a maximum message size of
2930 SIZE.  Note that when a message is received, the message type as a
2931 native long integer will be the first thing in VAR, followed by the
2932 actual message.  This packing may be opened with C<unpack("l! a*")>.
2933 Taints the variable.  Returns true if successful, or false if there is
2934 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2935 C<IPC::SysV::Msg> documentation.
2936
2937 =item msgsnd ID,MSG,FLAGS
2938 X<msgsnd>
2939
2940 Calls the System V IPC function msgsnd to send the message MSG to the
2941 message queue ID.  MSG must begin with the native long integer message
2942 type, and be followed by the length of the actual message, and finally
2943 the message itself.  This kind of packing can be achieved with
2944 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2945 or false if there is an error.  See also C<IPC::SysV>
2946 and C<IPC::SysV::Msg> documentation.
2947
2948 =item my EXPR
2949 X<my>
2950
2951 =item my TYPE EXPR
2952
2953 =item my EXPR : ATTRS
2954
2955 =item my TYPE EXPR : ATTRS
2956
2957 A C<my> declares the listed variables to be local (lexically) to the
2958 enclosing block, file, or C<eval>.  If more than one value is listed,
2959 the list must be placed in parentheses.
2960
2961 The exact semantics and interface of TYPE and ATTRS are still
2962 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2963 and attributes are handled using the C<attributes> pragma, or starting
2964 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2965 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2966 L<attributes>, and L<Attribute::Handlers>.
2967
2968 =item next LABEL
2969 X<next> X<continue>
2970
2971 =item next
2972
2973 The C<next> command is like the C<continue> statement in C; it starts
2974 the next iteration of the loop:
2975
2976     LINE: while (<STDIN>) {
2977         next LINE if /^#/;      # discard comments
2978         #...
2979     }
2980
2981 Note that if there were a C<continue> block on the above, it would get
2982 executed even on discarded lines.  If the LABEL is omitted, the command
2983 refers to the innermost enclosing loop.
2984
2985 C<next> cannot be used to exit a block which returns a value such as
2986 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2987 a grep() or map() operation.
2988
2989 Note that a block by itself is semantically identical to a loop
2990 that executes once.  Thus C<next> will exit such a block early.
2991
2992 See also L</continue> for an illustration of how C<last>, C<next>, and
2993 C<redo> work.
2994
2995 =item no Module VERSION LIST
2996 X<no>
2997
2998 =item no Module VERSION
2999
3000 =item no Module LIST
3001
3002 =item no Module
3003
3004 =item no VERSION
3005
3006 See the C<use> function, of which C<no> is the opposite.
3007
3008 =item oct EXPR
3009 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3010
3011 =item oct
3012
3013 Interprets EXPR as an octal string and returns the corresponding
3014 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3015 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3016 binary string.  Leading whitespace is ignored in all three cases.)
3017 The following will handle decimal, binary, octal, and hex in the standard
3018 Perl or C notation:
3019
3020     $val = oct($val) if $val =~ /^0/;
3021
3022 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3023 in octal), use sprintf() or printf():
3024
3025     $perms = (stat("filename"))[2] & 07777;
3026     $oct_perms = sprintf "%lo", $perms;
3027
3028 The oct() function is commonly used when a string such as C<644> needs
3029 to be converted into a file mode, for example. (Although perl will
3030 automatically convert strings into numbers as needed, this automatic
3031 conversion assumes base 10.)
3032
3033 =item open FILEHANDLE,EXPR
3034 X<open> X<pipe> X<file, open> X<fopen>
3035
3036 =item open FILEHANDLE,MODE,EXPR
3037
3038 =item open FILEHANDLE,MODE,EXPR,LIST
3039
3040 =item open FILEHANDLE,MODE,REFERENCE
3041
3042 =item open FILEHANDLE
3043
3044 Opens the file whose filename is given by EXPR, and associates it with
3045 FILEHANDLE.
3046
3047 (The following is a comprehensive reference to open(): for a gentler
3048 introduction you may consider L<perlopentut>.)
3049
3050 If FILEHANDLE is an undefined scalar variable (or array or hash element)
3051 the variable is assigned a reference to a new anonymous filehandle,
3052 otherwise if FILEHANDLE is an expression, its value is used as the name of
3053 the real filehandle wanted.  (This is considered a symbolic reference, so
3054 C<use strict 'refs'> should I<not> be in effect.)
3055
3056 If EXPR is omitted, the scalar variable of the same name as the
3057 FILEHANDLE contains the filename.  (Note that lexical variables--those
3058 declared with C<my>--will not work for this purpose; so if you're
3059 using C<my>, specify EXPR in your call to open.)
3060
3061 If three or more arguments are specified then the mode of opening and
3062 the file name are separate. If MODE is C<< '<' >> or nothing, the file
3063 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
3064 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
3065 the file is opened for appending, again being created if necessary.
3066
3067 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
3068 indicate that you want both read and write access to the file; thus
3069 C<< '+<' >> is almost always preferred for read/write updates--the C<<
3070 '+>' >> mode would clobber the file first.  You can't usually use
3071 either read-write mode for updating textfiles, since they have
3072 variable length records.  See the B<-i> switch in L<perlrun> for a
3073 better approach.  The file is created with permissions of C<0666>
3074 modified by the process' C<umask> value.
3075
3076 These various prefixes correspond to the fopen(3) modes of C<'r'>,
3077 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
3078
3079 In the 2-arguments (and 1-argument) form of the call the mode and
3080 filename should be concatenated (in this order), possibly separated by
3081 spaces.  It is possible to omit the mode in these forms if the mode is
3082 C<< '<' >>.
3083
3084 If the filename begins with C<'|'>, the filename is interpreted as a
3085 command to which output is to be piped, and if the filename ends with a
3086 C<'|'>, the filename is interpreted as a command which pipes output to
3087 us.  See L<perlipc/"Using open() for IPC">
3088 for more examples of this.  (You are not allowed to C<open> to a command
3089 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
3090 and L<perlipc/"Bidirectional Communication with Another Process">
3091 for alternatives.)
3092
3093 For three or more arguments if MODE is C<'|-'>, the filename is
3094 interpreted as a command to which output is to be piped, and if MODE
3095 is C<'-|'>, the filename is interpreted as a command which pipes
3096 output to us.  In the 2-arguments (and 1-argument) form one should
3097 replace dash (C<'-'>) with the command.
3098 See L<perlipc/"Using open() for IPC"> for more examples of this.
3099 (You are not allowed to C<open> to a command that pipes both in I<and>
3100 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3101 L<perlipc/"Bidirectional Communication"> for alternatives.)
3102
3103 In the three-or-more argument form of pipe opens, if LIST is specified
3104 (extra arguments after the command name) then LIST becomes arguments
3105 to the command invoked if the platform supports it.  The meaning of
3106 C<open> with more than three arguments for non-pipe modes is not yet
3107 specified. Experimental "layers" may give extra LIST arguments
3108 meaning.
3109
3110 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
3111 and opening C<< '>-' >> opens STDOUT.
3112
3113 You may use the three-argument form of open to specify IO "layers"
3114 (sometimes also referred to as "disciplines") to be applied to the handle
3115 that affect how the input and output are processed (see L<open> and
3116 L<PerlIO> for more details). For example
3117
3118   open(FH, "<:encoding(UTF-8)", "file")
3119
3120 will open the UTF-8 encoded file containing Unicode characters,
3121 see L<perluniintro>. Note that if layers are specified in the
3122 three-arg form then default layers stored in ${^OPEN} (see L<perlvar>;
3123 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3124
3125 Open returns nonzero upon success, the undefined value otherwise.  If
3126 the C<open> involved a pipe, the return value happens to be the pid of
3127 the subprocess.
3128
3129 If you're running Perl on a system that distinguishes between text
3130 files and binary files, then you should check out L</binmode> for tips
3131 for dealing with this.  The key distinction between systems that need
3132 C<binmode> and those that don't is their text file formats.  Systems
3133 like Unix, Mac OS, and Plan 9, which delimit lines with a single
3134 character, and which encode that character in C as C<"\n">, do not
3135 need C<binmode>.  The rest need it.
3136
3137 When opening a file, it's usually a bad idea to continue normal execution
3138 if the request failed, so C<open> is frequently used in connection with
3139 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3140 where you want to make a nicely formatted error message (but there are
3141 modules that can help with that problem)) you should always check
3142 the return value from opening a file.  The infrequent exception is when
3143 working with an unopened filehandle is actually what you want to do.
3144
3145 As a special case the 3-arg form with a read/write mode and the third
3146 argument being C<undef>:
3147
3148     open(TMP, "+>", undef) or die ...
3149
3150 opens a filehandle to an anonymous temporary file.  Also using "+<"
3151 works for symmetry, but you really should consider writing something
3152 to the temporary file first.  You will need to seek() to do the
3153 reading.
3154
3155 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
3156 changed this (i.e. Configure -Uuseperlio), you can open file handles to
3157 "in memory" files held in Perl scalars via:
3158
3159     open($fh, '>', \$variable) || ..
3160
3161 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
3162 file, you have to close it first:
3163
3164     close STDOUT;
3165     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3166
3167 Examples:
3168
3169     $ARTICLE = 100;
3170     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3171     while (<ARTICLE>) {...
3172
3173     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
3174     # if the open fails, output is discarded
3175
3176     open(DBASE, '+<', 'dbase.mine')             # open for update
3177         or die "Can't open 'dbase.mine' for update: $!";
3178
3179     open(DBASE, '+<dbase.mine')                 # ditto
3180         or die "Can't open 'dbase.mine' for update: $!";
3181
3182     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
3183         or die "Can't start caesar: $!";
3184
3185     open(ARTICLE, "caesar <$article |")         # ditto
3186         or die "Can't start caesar: $!";
3187
3188     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
3189         or die "Can't start sort: $!";
3190
3191     # in memory files
3192     open(MEMORY,'>', \$var)
3193         or die "Can't open memory file: $!";
3194     print MEMORY "foo!\n";                      # output will end up in $var
3195
3196     # process argument list of files along with any includes
3197
3198     foreach $file (@ARGV) {
3199         process($file, 'fh00');
3200     }
3201
3202     sub process {
3203         my($filename, $input) = @_;
3204         $input++;               # this is a string increment
3205         unless (open($input, $filename)) {
3206             print STDERR "Can't open $filename: $!\n";
3207             return;
3208         }
3209
3210         local $_;
3211         while (<$input>) {              # note use of indirection
3212             if (/^#include "(.*)"/) {
3213                 process($1, $input);
3214                 next;
3215             }
3216             #...                # whatever
3217         }
3218     }
3219
3220 See L<perliol> for detailed info on PerlIO.
3221
3222 You may also, in the Bourne shell tradition, specify an EXPR beginning
3223 with C<< '>&' >>, in which case the rest of the string is interpreted
3224 as the name of a filehandle (or file descriptor, if numeric) to be
3225 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3226 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3227 The mode you specify should match the mode of the original filehandle.
3228 (Duping a filehandle does not take into account any existing contents
3229 of IO buffers.) If you use the 3-arg form then you can pass either a
3230 number, the name of a filehandle or the normal "reference to a glob".
3231
3232 Here is a script that saves, redirects, and restores C<STDOUT> and
3233 C<STDERR> using various methods:
3234
3235     #!/usr/bin/perl
3236     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3237     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3238
3239     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3240     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3241
3242     select STDERR; $| = 1;      # make unbuffered
3243     select STDOUT; $| = 1;      # make unbuffered
3244
3245     print STDOUT "stdout 1\n";  # this works for
3246     print STDERR "stderr 1\n";  # subprocesses too
3247
3248     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3249     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3250
3251     print STDOUT "stdout 2\n";
3252     print STDERR "stderr 2\n";
3253
3254 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3255 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3256 that file descriptor (and not call L<dup(2)>); this is more
3257 parsimonious of file descriptors.  For example:
3258
3259     # open for input, reusing the fileno of $fd
3260     open(FILEHANDLE, "<&=$fd")
3261
3262 or
3263
3264     open(FILEHANDLE, "<&=", $fd)
3265
3266 or
3267
3268     # open for append, using the fileno of OLDFH
3269     open(FH, ">>&=", OLDFH)
3270
3271 or
3272
3273     open(FH, ">>&=OLDFH")
3274
3275 Being parsimonious on filehandles is also useful (besides being
3276 parsimonious) for example when something is dependent on file
3277 descriptors, like for example locking using flock().  If you do just
3278 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3279 descriptor as B, and therefore flock(A) will not flock(B), and vice
3280 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3281 the same file descriptor.
3282
3283 Note that if you are using Perls older than 5.8.0, Perl will be using
3284 the standard C libraries' fdopen() to implement the "=" functionality.
3285 On many UNIX systems fdopen() fails when file descriptors exceed a
3286 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3287 most often the default.
3288
3289 You can see whether Perl has been compiled with PerlIO or not by
3290 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3291 is C<define>, you have PerlIO, otherwise you don't.
3292
3293 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3294 with 2-arguments (or 1-argument) form of open(), then
3295 there is an implicit fork done, and the return value of open is the pid
3296 of the child within the parent process, and C<0> within the child
3297 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3298 The filehandle behaves normally for the parent, but i/o to that
3299 filehandle is piped from/to the STDOUT/STDIN of the child process.
3300 In the child process the filehandle isn't opened--i/o happens from/to
3301 the new STDOUT or STDIN.  Typically this is used like the normal
3302 piped open when you want to exercise more control over just how the
3303 pipe command gets executed, such as when you are running setuid, and
3304 don't want to have to scan shell commands for metacharacters.
3305 The following triples are more or less equivalent:
3306
3307     open(FOO, "|tr '[a-z]' '[A-Z]'");
3308     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3309     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3310     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3311
3312     open(FOO, "cat -n '$file'|");
3313     open(FOO, '-|', "cat -n '$file'");
3314     open(FOO, '-|') || exec 'cat', '-n', $file;
3315     open(FOO, '-|', "cat", '-n', $file);
3316
3317 The last example in each block shows the pipe as "list form", which is
3318 not yet supported on all platforms.  A good rule of thumb is that if
3319 your platform has true C<fork()> (in other words, if your platform is
3320 UNIX) you can use the list form.
3321
3322 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3323
3324 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3325 output before any operation that may do a fork, but this may not be
3326 supported on some platforms (see L<perlport>).  To be safe, you may need
3327 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3328 of C<IO::Handle> on any open handles.
3329
3330 On systems that support a close-on-exec flag on files, the flag will
3331 be set for the newly opened file descriptor as determined by the value
3332 of $^F.  See L<perlvar/$^F>.
3333
3334 Closing any piped filehandle causes the parent process to wait for the
3335 child to finish, and returns the status value in C<$?> and
3336 C<${^CHILD_ERROR_NATIVE}>.
3337
3338 The filename passed to 2-argument (or 1-argument) form of open() will
3339 have leading and trailing whitespace deleted, and the normal
3340 redirection characters honored.  This property, known as "magic open",
3341 can often be used to good effect.  A user could specify a filename of
3342 F<"rsh cat file |">, or you could change certain filenames as needed:
3343
3344     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3345     open(FH, $filename) or die "Can't open $filename: $!";
3346
3347 Use 3-argument form to open a file with arbitrary weird characters in it,
3348
3349     open(FOO, '<', $file);
3350
3351 otherwise it's necessary to protect any leading and trailing whitespace:
3352
3353     $file =~ s#^(\s)#./$1#;
3354     open(FOO, "< $file\0");
3355
3356 (this may not work on some bizarre filesystems).  One should
3357 conscientiously choose between the I<magic> and 3-arguments form
3358 of open():
3359
3360     open IN, $ARGV[0];
3361
3362 will allow the user to specify an argument of the form C<"rsh cat file |">,
3363 but will not work on a filename which happens to have a trailing space, while
3364
3365     open IN, '<', $ARGV[0];
3366
3367 will have exactly the opposite restrictions.
3368
3369 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3370 should use the C<sysopen> function, which involves no such magic (but
3371 may use subtly different filemodes than Perl open(), which is mapped
3372 to C fopen()).  This is
3373 another way to protect your filenames from interpretation.  For example:
3374
3375     use IO::Handle;
3376     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3377         or die "sysopen $path: $!";
3378     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3379     print HANDLE "stuff $$\n";
3380     seek(HANDLE, 0, 0);
3381     print "File contains: ", <HANDLE>;
3382
3383 Using the constructor from the C<IO::Handle> package (or one of its
3384 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3385 filehandles that have the scope of whatever variables hold references to
3386 them, and automatically close whenever and however you leave that scope:
3387
3388     use IO::File;
3389     #...
3390     sub read_myfile_munged {
3391         my $ALL = shift;
3392         my $handle = new IO::File;
3393         open($handle, "myfile") or die "myfile: $!";
3394         $first = <$handle>
3395             or return ();     # Automatically closed here.
3396         mung $first or die "mung failed";       # Or here.
3397         return $first, <$handle> if $ALL;       # Or here.
3398         $first;                                 # Or here.
3399     }
3400
3401 See L</seek> for some details about mixing reading and writing.
3402
3403 =item opendir DIRHANDLE,EXPR
3404 X<opendir>
3405
3406 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3407 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3408 DIRHANDLE may be an expression whose value can be used as an indirect
3409 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3410 scalar variable (or array or hash element), the variable is assigned a
3411 reference to a new anonymous dirhandle.
3412 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3413
3414 =item ord EXPR
3415 X<ord> X<encoding>
3416
3417 =item ord
3418
3419 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3420 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3421 uses C<$_>.
3422
3423 For the reverse, see L</chr>.
3424 See L<perlunicode> for more about Unicode.
3425
3426 =item our EXPR
3427 X<our> X<global>
3428
3429 =item our TYPE EXPR
3430
3431 =item our EXPR : ATTRS
3432
3433 =item our TYPE EXPR : ATTRS
3434
3435 C<our> associates a simple name with a package variable in the current
3436 package for use within the current scope.  When C<use strict 'vars'> is in
3437 effect, C<our> lets you use declared global variables without qualifying
3438 them with package names, within the lexical scope of the C<our> declaration.
3439 In this way C<our> differs from C<use vars>, which is package scoped.
3440
3441 Unlike C<my>, which both allocates storage for a variable and associates
3442 a simple name with that storage for use within the current scope, C<our>
3443 associates a simple name with a package variable in the current package,
3444 for use within the current scope.  In other words, C<our> has the same
3445 scoping rules as C<my>, but does not necessarily create a
3446 variable.
3447
3448 If more than one value is listed, the list must be placed
3449 in parentheses.
3450
3451     our $foo;
3452     our($bar, $baz);
3453
3454 An C<our> declaration declares a global variable that will be visible
3455 across its entire lexical scope, even across package boundaries.  The
3456 package in which the variable is entered is determined at the point
3457 of the declaration, not at the point of use.  This means the following
3458 behavior holds:
3459
3460     package Foo;
3461     our $bar;           # declares $Foo::bar for rest of lexical scope
3462     $bar = 20;
3463
3464     package Bar;
3465     print $bar;         # prints 20, as it refers to $Foo::bar
3466
3467 Multiple C<our> declarations with the same name in the same lexical
3468 scope are allowed if they are in different packages.  If they happen
3469 to be in the same package, Perl will emit warnings if you have asked
3470 for them, just like multiple C<my> declarations.  Unlike a second
3471 C<my> declaration, which will bind the name to a fresh variable, a
3472 second C<our> declaration in the same package, in the same scope, is
3473 merely redundant.
3474
3475     use warnings;
3476     package Foo;
3477     our $bar;           # declares $Foo::bar for rest of lexical scope
3478     $bar = 20;
3479
3480     package Bar;
3481     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3482     print $bar;         # prints 30
3483
3484     our $bar;           # emits warning but has no other effect
3485     print $bar;         # still prints 30
3486
3487 An C<our> declaration may also have a list of attributes associated
3488 with it.
3489
3490 The exact semantics and interface of TYPE and ATTRS are still
3491 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3492 and attributes are handled using the C<attributes> pragma, or starting
3493 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3494 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3495 L<attributes>, and L<Attribute::Handlers>.
3496
3497 =item pack TEMPLATE,LIST
3498 X<pack>
3499
3500 Takes a LIST of values and converts it into a string using the rules
3501 given by the TEMPLATE.  The resulting string is the concatenation of
3502 the converted values.  Typically, each converted value looks
3503 like its machine-level representation.  For example, on 32-bit machines
3504 an integer may be represented by a sequence of 4 bytes that will be 
3505 converted to a sequence of 4 characters.
3506
3507 The TEMPLATE is a sequence of characters that give the order and type
3508 of values, as follows:
3509
3510     a   A string with arbitrary binary data, will be null padded.
3511     A   A text (ASCII) string, will be space padded.
3512     Z   A null terminated (ASCIZ) string, will be null padded.
3513
3514     b   A bit string (ascending bit order inside each byte, like vec()).
3515     B   A bit string (descending bit order inside each byte).
3516     h   A hex string (low nybble first).
3517     H   A hex string (high nybble first).
3518
3519     c   A signed char (8-bit) value.
3520     C   An unsigned char (octet) value.
3521     W   An unsigned char value (can be greater than 255).
3522
3523     s   A signed short (16-bit) value.
3524     S   An unsigned short value.
3525
3526     l   A signed long (32-bit) value.
3527     L   An unsigned long value.
3528
3529     q   A signed quad (64-bit) value.
3530     Q   An unsigned quad value.
3531           (Quads are available only if your system supports 64-bit
3532            integer values _and_ if Perl has been compiled to support those.
3533            Causes a fatal error otherwise.)
3534
3535     i   A signed integer value.
3536     I   A unsigned integer value.
3537           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3538            size depends on what a local C compiler calls 'int'.)
3539
3540     n   An unsigned short (16-bit) in "network" (big-endian) order.
3541     N   An unsigned long (32-bit) in "network" (big-endian) order.
3542     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3543     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3544
3545     j   A Perl internal signed integer value (IV).
3546     J   A Perl internal unsigned integer value (UV).
3547
3548     f   A single-precision float in the native format.
3549     d   A double-precision float in the native format.
3550
3551     F   A Perl internal floating point value (NV) in the native format
3552     D   A long double-precision float in the native format.
3553           (Long doubles are available only if your system supports long
3554            double values _and_ if Perl has been compiled to support those.
3555            Causes a fatal error otherwise.)
3556
3557     p   A pointer to a null-terminated string.
3558     P   A pointer to a structure (fixed-length string).
3559
3560     u   A uuencoded string.
3561     U   A Unicode character number.  Encodes to a character in character mode
3562         and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in byte mode.
3563
3564     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3565         details).  Its bytes represent an unsigned integer in base 128,
3566         most significant digit first, with as few digits as possible.  Bit
3567         eight (the high bit) is set on each byte except the last.
3568
3569     x   A null byte.
3570     X   Back up a byte.
3571     @   Null fill or truncate to absolute position, counted from the
3572         start of the innermost ()-group.
3573     .   Null fill or truncate to absolute position specified by value.
3574     (   Start of a ()-group.
3575
3576 One or more of the modifiers below may optionally follow some letters in the
3577 TEMPLATE (the second column lists the letters for which the modifier is
3578 valid):
3579
3580     !   sSlLiI     Forces native (short, long, int) sizes instead
3581                    of fixed (16-/32-bit) sizes.
3582
3583         xX         Make x and X act as alignment commands.
3584
3585         nNvV       Treat integers as signed instead of unsigned.
3586
3587         @.         Specify position as byte offset in the internal
3588                    representation of the packed string. Efficient but
3589                    dangerous.
3590
3591     >   sSiIlLqQ   Force big-endian byte-order on the type.
3592         jJfFdDpP   (The "big end" touches the construct.)
3593
3594     <   sSiIlLqQ   Force little-endian byte-order on the type.
3595         jJfFdDpP   (The "little end" touches the construct.)
3596
3597 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3598 in which case they force a certain byte-order on all components of
3599 that group, including subgroups.
3600
3601 The following rules apply:
3602
3603 =over 8
3604
3605 =item *
3606
3607 Each letter may optionally be followed by a number giving a repeat
3608 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3609 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3610 that many values from the LIST.  A C<*> for the repeat count means to
3611 use however many items are left, except for C<@>, C<x>, C<X>, where it
3612 is equivalent to C<0>, for <.> where it means relative to string start
3613 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3614 A numeric repeat count may optionally be enclosed in brackets, as in
3615 C<pack 'C[80]', @arr>.
3616
3617 One can replace the numeric repeat count by a template enclosed in brackets;
3618 then the packed length of this template in bytes is used as a count.
3619 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3620 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3621 If the template in brackets contains alignment commands (such as C<x![d]>),
3622 its packed length is calculated as if the start of the template has the maximal
3623 possible alignment.
3624
3625 When used with C<Z>, C<*> results in the addition of a trailing null
3626 byte (so the packed result will be one longer than the byte C<length>
3627 of the item).
3628
3629 When used with C<@>, the repeat count represents an offset from the start
3630 of the innermost () group.
3631
3632 When used with C<.>, the repeat count is used to determine the starting
3633 position from where the value offset is calculated. If the repeat count
3634 is 0, it's relative to the current position. If the repeat count is C<*>,
3635 the offset is relative to the start of the packed string. And if its an
3636 integer C<n> the offset is relative to the start of the n-th innermost
3637 () group (or the start of the string if C<n> is bigger then the group
3638 level).
3639
3640 The repeat count for C<u> is interpreted as the maximal number of bytes
3641 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3642 count should not be more than 65.
3643
3644 =item *
3645
3646 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3647 string of length count, padding with nulls or spaces as necessary.  When
3648 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3649 after the first null, and C<a> returns data verbatim.
3650
3651 If the value-to-pack is too long, it is truncated.  If too long and an
3652 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3653 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3654 count is 0).
3655
3656 =item *
3657
3658 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3659 Each character of the input field of pack() generates 1 bit of the result.
3660 Each result bit is based on the least-significant bit of the corresponding
3661 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3662 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3663
3664 Starting from the beginning of the input string of pack(), each 8-tuple
3665 of characters is converted to 1 character of output.  With format C<b>
3666 the first character of the 8-tuple determines the least-significant bit of a
3667 character, and with format C<B> it determines the most-significant bit of
3668 a character.
3669
3670 If the length of the input string is not exactly divisible by 8, the
3671 remainder is packed as if the input string were padded by null characters
3672 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3673
3674 If the input string of pack() is longer than needed, extra characters are 
3675 ignored. A C<*> for the repeat count of pack() means to use all the 
3676 characters of the input field.  On unpack()ing the bits are converted to a 
3677 string of C<"0">s and C<"1">s.
3678
3679 =item *
3680
3681 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3682 representable as hexadecimal digits, 0-9a-f) long.
3683
3684 Each character of the input field of pack() generates 4 bits of the result.
3685 For non-alphabetical characters the result is based on the 4 least-significant
3686 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3687 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3688 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3689 is compatible with the usual hexadecimal digits, so that C<"a"> and
3690 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3691 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3692
3693 Starting from the beginning of the input string of pack(), each pair
3694 of characters is converted to 1 character of output.  With format C<h> the
3695 first character of the pair determines the least-significant nybble of the
3696 output character, and with format C<H> it determines the most-significant
3697 nybble.
3698
3699 If the length of the input string is not even, it behaves as if padded
3700 by a null character at the end.  Similarly, during unpack()ing the "extra"
3701 nybbles are ignored.
3702
3703 If the input string of pack() is longer than needed, extra characters are
3704 ignored.
3705 A C<*> for the repeat count of pack() means to use all the characters of
3706 the input field.  On unpack()ing the nybbles are converted to a string
3707 of hexadecimal digits.
3708
3709 =item *
3710
3711 The C<p> type packs a pointer to a null-terminated string.  You are
3712 responsible for ensuring the string is not a temporary value (which can
3713 potentially get deallocated before you get around to using the packed result).
3714 The C<P> type packs a pointer to a structure of the size indicated by the
3715 length.  A NULL pointer is created if the corresponding value for C<p> or
3716 C<P> is C<undef>, similarly for unpack().
3717
3718 If your system has a strange pointer size (i.e. a pointer is neither as
3719 big as an int nor as big as a long), it may not be possible to pack or
3720 unpack pointers in big- or little-endian byte order.  Attempting to do
3721 so will result in a fatal error.
3722
3723 =item *
3724
3725 The C</> template character allows packing and unpacking of a sequence of
3726 items where the packed structure contains a packed item count followed by 
3727 the packed items themselves.
3728
3729 For C<pack> you write I<length-item>C</>I<sequence-item> and the
3730 I<length-item> describes how the length value is packed. The ones likely
3731 to be of most use are integer-packing ones like C<n> (for Java strings),
3732 C<w> (for ASN.1 or SNMP) and C<N> (for Sun XDR).
3733
3734 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3735 the minimum of that and the number of available items is used as argument
3736 for the I<length-item>. If it has no repeat count or uses a '*', the number
3737 of available items is used.
3738
3739 For C<unpack> an internal stack of integer arguments unpacked so far is
3740 used. You write C</>I<sequence-item> and the repeat count is obtained by
3741 popping off the last element from the stack. The I<sequence-item> must not
3742 have a repeat count.
3743
3744 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3745 the I<length-item> is a string length, not a number of strings. If there is
3746 an explicit repeat count for pack, the packed string will be adjusted to that
3747 given length.
3748
3749     unpack 'W/a', "\04Gurusamy";            gives ('Guru')
3750     unpack 'a3/A A*', '007 Bond  J ';       gives (' Bond', 'J')
3751     unpack 'a3 x2 /A A*', '007: Bond, J.';  gives ('Bond, J', '.')
3752     pack 'n/a* w/a','hello,','world';       gives "\000\006hello,\005world"
3753     pack 'a/W2', ord('a') .. ord('z');      gives '2ab'
3754
3755 The I<length-item> is not returned explicitly from C<unpack>.
3756
3757 Adding a count to the I<length-item> letter is unlikely to do anything
3758 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3759 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3760 which Perl does not regard as legal in numeric strings.
3761
3762 =item *
3763
3764 The integer types C<s>, C<S>, C<l>, and C<L> may be
3765 followed by a C<!> modifier to signify native shorts or
3766 longs--as you can see from above for example a bare C<l> does mean
3767 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3768 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3769 see whether using C<!> makes any difference by
3770
3771         print length(pack("s")), " ", length(pack("s!")), "\n";
3772         print length(pack("l")), " ", length(pack("l!")), "\n";
3773
3774 C<i!> and C<I!> also work but only because of completeness;
3775 they are identical to C<i> and C<I>.
3776
3777 The actual sizes (in bytes) of native shorts, ints, longs, and long
3778 longs on the platform where Perl was built are also available via
3779 L<Config>:
3780
3781        use Config;
3782        print $Config{shortsize},    "\n";
3783        print $Config{intsize},      "\n";
3784        print $Config{longsize},     "\n";
3785        print $Config{longlongsize}, "\n";
3786
3787 (The C<$Config{longlongsize}> will be undefined if your system does
3788 not support long longs.)
3789
3790 =item *
3791
3792 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3793 are inherently non-portable between processors and operating systems
3794 because they obey the native byteorder and endianness.  For example a
3795 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3796 (arranged in and handled by the CPU registers) into bytes as
3797
3798         0x12 0x34 0x56 0x78     # big-endian
3799         0x78 0x56 0x34 0x12     # little-endian
3800
3801 Basically, the Intel and VAX CPUs are little-endian, while everybody
3802 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3803 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3804 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3805 mode.
3806
3807 The names `big-endian' and `little-endian' are comic references to
3808 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3809 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3810 the egg-eating habits of the Lilliputians.
3811
3812 Some systems may have even weirder byte orders such as
3813
3814         0x56 0x78 0x12 0x34
3815         0x34 0x12 0x78 0x56
3816
3817 You can see your system's preference with
3818
3819         print join(" ", map { sprintf "%#02x", $_ }
3820                             unpack("W*",pack("L",0x12345678))), "\n";
3821
3822 The byteorder on the platform where Perl was built is also available
3823 via L<Config>:
3824
3825         use Config;
3826         print $Config{byteorder}, "\n";
3827
3828 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3829 and C<'87654321'> are big-endian.
3830
3831 If you want portable packed integers you can either use the formats
3832 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3833 modifiers.  These modifiers are only available as of perl 5.9.2.
3834 See also L<perlport>.
3835
3836 =item *
3837
3838 All integer and floating point formats as well as C<p> and C<P> and
3839 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3840 to force big- or little- endian byte-order, respectively.
3841 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3842 signed integers, 64-bit integers and floating point values.  However,
3843 there are some things to keep in mind.
3844
3845 Exchanging signed integers between different platforms only works
3846 if all platforms store them in the same format.  Most platforms store
3847 signed integers in two's complement, so usually this is not an issue.
3848
3849 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3850 formats on big- or little-endian machines.  Otherwise, attempting to
3851 do so will result in a fatal error.
3852
3853 Forcing big- or little-endian byte-order on floating point values for
3854 data exchange can only work if all platforms are using the same
3855 binary representation (e.g. IEEE floating point format).  Even if all
3856 platforms are using IEEE, there may be subtle differences.  Being able
3857 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3858 but also very dangerous if you don't know exactly what you're doing.
3859 It is definitely not a general way to portably store floating point
3860 values.
3861
3862 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3863 all types inside the group that accept the byte-order modifiers,
3864 including all subgroups.  It will silently be ignored for all other
3865 types.  You are not allowed to override the byte-order within a group
3866 that already has a byte-order modifier suffix.
3867
3868 =item *
3869
3870 Real numbers (floats and doubles) are in the native machine format only;
3871 due to the multiplicity of floating formats around, and the lack of a
3872 standard "network" representation, no facility for interchange has been
3873 made.  This means that packed floating point data written on one machine
3874 may not be readable on another - even if both use IEEE floating point
3875 arithmetic (as the endian-ness of the memory representation is not part
3876 of the IEEE spec).  See also L<perlport>.
3877
3878 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3879 modifiers to force big- or little-endian byte-order on floating point values.
3880
3881 Note that Perl uses doubles (or long doubles, if configured) internally for
3882 all numeric calculation, and converting from double into float and thence back
3883 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3884 will not in general equal $foo).
3885
3886 =item *
3887
3888 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3889 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3890 where the packed string is processed in its UTF-8-encoded Unicode form on
3891 a byte by byte basis. Character mode is the default unless the format string 
3892 starts with an C<U>. You can switch mode at any moment with an explicit 
3893 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3894 or until the end of the ()-group in which it was entered.
3895
3896 =item *
3897
3898 You must yourself do any alignment or padding by inserting for example
3899 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3900 could know where the characters are going to or coming from.  Therefore
3901 C<pack> (and C<unpack>) handle their output and input as flat
3902 sequences of characters.
3903
3904 =item *
3905
3906 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3907 take a repeat count, both as postfix, and for unpack() also via the C</>
3908 template character. Within each repetition of a group, positioning with
3909 C<@> starts again at 0. Therefore, the result of
3910
3911     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3912
3913 is the string "\0a\0\0bc".
3914
3915 =item *
3916
3917 C<x> and C<X> accept C<!> modifier.  In this case they act as
3918 alignment commands: they jump forward/back to the closest position
3919 aligned at a multiple of C<count> characters. For example, to pack() or
3920 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3921 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3922 aligned on the double's size.
3923
3924 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3925 both result in no-ops.
3926
3927 =item *
3928
3929 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3930 will represent signed 16-/32-bit integers in big-/little-endian order.
3931 This is only portable if all platforms sharing the packed data use the
3932 same binary representation for signed integers (e.g. all platforms are
3933 using two's complement representation).
3934
3935 =item *
3936
3937 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3938 White space may be used to separate pack codes from each other, but
3939 modifiers and a repeat count must follow immediately.
3940
3941 =item *
3942
3943 If TEMPLATE requires more arguments to pack() than actually given, pack()
3944 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
3945 to pack() than actually given, extra arguments are ignored.
3946
3947 =back
3948
3949 Examples:
3950
3951     $foo = pack("WWWW",65,66,67,68);
3952     # foo eq "ABCD"
3953     $foo = pack("W4",65,66,67,68);
3954     # same thing
3955     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
3956     # same thing with Unicode circled letters.
3957     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3958     # same thing with Unicode circled letters. You don't get the UTF-8
3959     # bytes because the U at the start of the format caused a switch to
3960     # U0-mode, so the UTF-8 bytes get joined into characters
3961     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
3962     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
3963     # This is the UTF-8 encoding of the string in the previous example
3964
3965     $foo = pack("ccxxcc",65,66,67,68);
3966     # foo eq "AB\0\0CD"
3967
3968     # note: the above examples featuring "W" and "c" are true
3969     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3970     # and UTF-8.  In EBCDIC the first example would be
3971     # $foo = pack("WWWW",193,194,195,196);
3972
3973     $foo = pack("s2",1,2);
3974     # "\1\0\2\0" on little-endian
3975     # "\0\1\0\2" on big-endian
3976
3977     $foo = pack("a4","abcd","x","y","z");
3978     # "abcd"
3979
3980     $foo = pack("aaaa","abcd","x","y","z");
3981     # "axyz"
3982
3983     $foo = pack("a14","abcdefg");
3984     # "abcdefg\0\0\0\0\0\0\0"
3985
3986     $foo = pack("i9pl", gmtime);
3987     # a real struct tm (on my system anyway)
3988
3989     $utmp_template = "Z8 Z8 Z16 L";
3990     $utmp = pack($utmp_template, @utmp1);
3991     # a struct utmp (BSDish)
3992
3993     @utmp2 = unpack($utmp_template, $utmp);
3994     # "@utmp1" eq "@utmp2"
3995
3996     sub bintodec {
3997         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3998     }
3999
4000     $foo = pack('sx2l', 12, 34);
4001     # short 12, two zero bytes padding, long 34
4002     $bar = pack('s@4l', 12, 34);
4003     # short 12, zero fill to position 4, long 34
4004     # $foo eq $bar
4005     $baz = pack('s.l', 12, 4, 34);
4006     # short 12, zero fill to position 4, long 34
4007
4008     $foo = pack('nN', 42, 4711);
4009     # pack big-endian 16- and 32-bit unsigned integers
4010     $foo = pack('S>L>', 42, 4711);
4011     # exactly the same
4012     $foo = pack('s<l<', -42, 4711);
4013     # pack little-endian 16- and 32-bit signed integers
4014     $foo = pack('(sl)<', -42, 4711);
4015     # exactly the same
4016
4017 The same template may generally also be used in unpack().
4018
4019 =item package NAMESPACE
4020 X<package> X<module> X<namespace>
4021
4022 =item package
4023
4024 Declares the compilation unit as being in the given namespace.  The scope
4025 of the package declaration is from the declaration itself through the end
4026 of the enclosing block, file, or eval (the same as the C<my> operator).
4027 All further unqualified dynamic identifiers will be in this namespace.
4028 A package statement affects only dynamic variables--including those
4029 you've used C<local> on--but I<not> lexical variables, which are created
4030 with C<my>.  Typically it would be the first declaration in a file to
4031 be included by the C<require> or C<use> operator.  You can switch into a
4032 package in more than one place; it merely influences which symbol table
4033 is used by the compiler for the rest of that block.  You can refer to
4034 variables and filehandles in other packages by prefixing the identifier
4035 with the package name and a double colon:  C<$Package::Variable>.
4036 If the package name is null, the C<main> package as assumed.  That is,
4037 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
4038 still seen in older code).
4039
4040 If NAMESPACE is omitted, then there is no current package, and all
4041 identifiers must be fully qualified or lexicals.  However, you are
4042 strongly advised not to make use of this feature. Its use can cause
4043 unexpected behaviour, even crashing some versions of Perl. It is
4044 deprecated, and will be removed from a future release.
4045
4046 See L<perlmod/"Packages"> for more information about packages, modules,
4047 and classes.  See L<perlsub> for other scoping issues.
4048
4049 =item pipe READHANDLE,WRITEHANDLE
4050 X<pipe>
4051
4052 Opens a pair of connected pipes like the corresponding system call.
4053 Note that if you set up a loop of piped processes, deadlock can occur
4054 unless you are very careful.  In addition, note that Perl's pipes use
4055 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4056 after each command, depending on the application.
4057
4058 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
4059 for examples of such things.
4060
4061 On systems that support a close-on-exec flag on files, the flag will be set
4062 for the newly opened file descriptors as determined by the value of $^F.
4063 See L<perlvar/$^F>.
4064
4065 =item pop ARRAY
4066 X<pop> X<stack>
4067
4068 =item pop
4069
4070 Pops and returns the last value of the array, shortening the array by
4071 one element.
4072
4073 If there are no elements in the array, returns the undefined value
4074 (although this may happen at other times as well).  If ARRAY is
4075 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
4076 array in subroutines, just like C<shift>.
4077
4078 =item pos SCALAR
4079 X<pos> X<match, position>
4080
4081 =item pos
4082
4083 Returns the offset of where the last C<m//g> search left off for the variable
4084 in question (C<$_> is used when the variable is not specified).  Note that
4085 0 is a valid match offset.  C<undef> indicates that the search position
4086 is reset (usually due to match failure, but can also be because no match has
4087 yet been performed on the scalar). C<pos> directly accesses the location used
4088 by the regexp engine to store the offset, so assigning to C<pos> will change
4089 that offset, and so will also influence the C<\G> zero-width assertion in
4090 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
4091 the return from C<pos> won't change either in this case.  See L<perlre> and
4092 L<perlop>.
4093
4094 =item print FILEHANDLE LIST
4095 X<print>
4096
4097 =item print LIST
4098
4099 =item print
4100
4101 Prints a string or a list of strings.  Returns true if successful.
4102 FILEHANDLE may be a scalar variable name, in which case the variable
4103 contains the name of or a reference to the filehandle, thus introducing
4104 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
4105 the next token is a term, it may be misinterpreted as an operator
4106 unless you interpose a C<+> or put parentheses around the arguments.)
4107 If FILEHANDLE is omitted, prints by default to standard output (or
4108 to the last selected output channel--see L</select>).  If LIST is
4109 also omitted, prints C<$_> to the currently selected output channel.
4110 To set the default output channel to something other than STDOUT
4111 use the select operation.  The current value of C<$,> (if any) is
4112 printed between each LIST item.  The current value of C<$\> (if
4113 any) is printed after the entire LIST has been printed.  Because
4114 print takes a LIST, anything in the LIST is evaluated in list
4115 context, and any subroutine that you call will have one or more of
4116 its expressions evaluated in list context.  Also be careful not to
4117 follow the print keyword with a left parenthesis unless you want
4118 the corresponding right parenthesis to terminate the arguments to
4119 the print--interpose a C<+> or put parentheses around all the
4120 arguments.
4121
4122 Note that if you're storing FILEHANDLEs in an array, or if you're using
4123 any other expression more complex than a scalar variable to retrieve it,
4124 you will have to use a block returning the filehandle value instead:
4125
4126     print { $files[$i] } "stuff\n";
4127     print { $OK ? STDOUT : STDERR } "stuff\n";
4128
4129 =item printf FILEHANDLE FORMAT, LIST
4130 X<printf>
4131
4132 =item printf FORMAT, LIST
4133
4134 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4135 (the output record separator) is not appended.  The first argument
4136 of the list will be interpreted as the C<printf> format. See C<sprintf>
4137 for an explanation of the format argument.  If C<use locale> is in effect,
4138 and POSIX::setlocale() has been called, the character used for the decimal
4139 separator in formatted floating point numbers is affected by the LC_NUMERIC
4140 locale.  See L<perllocale> and L<POSIX>.
4141
4142 Don't fall into the trap of using a C<printf> when a simple
4143 C<print> would do.  The C<print> is more efficient and less
4144 error prone.
4145
4146 =item prototype FUNCTION
4147 X<prototype>
4148
4149 Returns the prototype of a function as a string (or C<undef> if the
4150 function has no prototype).  FUNCTION is a reference to, or the name of,
4151 the function whose prototype you want to retrieve.
4152
4153 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4154 name for Perl builtin.  If the builtin is not I<overridable> (such as
4155 C<qw//>) or if its arguments cannot be adequately expressed by a prototype
4156 (such as C<system>), prototype() returns C<undef>, because the builtin
4157 does not really behave like a Perl function.  Otherwise, the string
4158 describing the equivalent prototype is returned.
4159
4160 =item push ARRAY,LIST
4161 X<push> X<stack>
4162
4163 Treats ARRAY as a stack, and pushes the values of LIST
4164 onto the end of ARRAY.  The length of ARRAY increases by the length of
4165 LIST.  Has the same effect as
4166
4167     for $value (LIST) {
4168         $ARRAY[++$#ARRAY] = $value;
4169     }
4170
4171 but is more efficient.  Returns the number of elements in the array following
4172 the completed C<push>.
4173
4174 =item q/STRING/
4175
4176 =item qq/STRING/
4177
4178 =item qr/STRING/
4179
4180 =item qx/STRING/
4181
4182 =item qw/STRING/
4183
4184 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
4185
4186 =item quotemeta EXPR
4187 X<quotemeta> X<metacharacter>
4188
4189 =item quotemeta
4190
4191 Returns the value of EXPR with all non-"word"
4192 characters backslashed.  (That is, all characters not matching
4193 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4194 returned string, regardless of any locale settings.)
4195 This is the internal function implementing
4196 the C<\Q> escape in double-quoted strings.
4197
4198 If EXPR is omitted, uses C<$_>.
4199
4200 =item rand EXPR
4201 X<rand> X<random>
4202
4203 =item rand
4204
4205 Returns a random fractional number greater than or equal to C<0> and less
4206 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4207 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4208 also special-cased as C<1> - this has not been documented before perl 5.8.0
4209 and is subject to change in future versions of perl.  Automatically calls
4210 C<srand> unless C<srand> has already been called.  See also C<srand>.
4211
4212 Apply C<int()> to the value returned by C<rand()> if you want random
4213 integers instead of random fractional numbers.  For example,
4214
4215     int(rand(10))
4216
4217 returns a random integer between C<0> and C<9>, inclusive.
4218
4219 (Note: If your rand function consistently returns numbers that are too
4220 large or too small, then your version of Perl was probably compiled
4221 with the wrong number of RANDBITS.)
4222
4223 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4224 X<read> X<file, read>
4225
4226 =item read FILEHANDLE,SCALAR,LENGTH
4227
4228 Attempts to read LENGTH I<characters> of data into variable SCALAR
4229 from the specified FILEHANDLE.  Returns the number of characters
4230 actually read, C<0> at end of file, or undef if there was an error (in
4231 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4232 so that the last character actually read is the last character of the
4233 scalar after the read.
4234
4235 An OFFSET may be specified to place the read data at some place in the
4236 string other than the beginning.  A negative OFFSET specifies
4237 placement at that many characters counting backwards from the end of
4238 the string.  A positive OFFSET greater than the length of SCALAR
4239 results in the string being padded to the required size with C<"\0">
4240 bytes before the result of the read is appended.
4241
4242 The call is actually implemented in terms of either Perl's or system's
4243 fread() call.  To get a true read(2) system call, see C<sysread>.
4244
4245 Note the I<characters>: depending on the status of the filehandle,
4246 either (8-bit) bytes or characters are read.  By default all
4247 filehandles operate on bytes, but for example if the filehandle has
4248 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4249 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4250 characters, not bytes.  Similarly for the C<:encoding> pragma:
4251 in that case pretty much any characters can be read.
4252
4253 =item readdir DIRHANDLE
4254 X<readdir>
4255
4256 Returns the next directory entry for a directory opened by C<opendir>.
4257 If used in list context, returns all the rest of the entries in the
4258 directory.  If there are no more entries, returns an undefined value in
4259 scalar context or a null list in list context.
4260
4261 If you're planning to filetest the return values out of a C<readdir>, you'd
4262 better prepend the directory in question.  Otherwise, because we didn't
4263 C<chdir> there, it would have been testing the wrong file.
4264
4265     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4266     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4267     closedir DIR;
4268
4269 =item readline EXPR
4270
4271 =item readline
4272 X<readline> X<gets> X<fgets>
4273
4274 Reads from the filehandle whose typeglob is contained in EXPR (or from
4275 *ARGV if EXPR is not provided).  In scalar context, each call reads and
4276 returns the next line, until end-of-file is reached, whereupon the
4277 subsequent call returns undef.  In list context, reads until end-of-file
4278 is reached and returns a list of lines.  Note that the notion of "line"
4279 used here is however you may have defined it with C<$/> or
4280 C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4281
4282 When C<$/> is set to C<undef>, when readline() is in scalar
4283 context (i.e. file slurp mode), and when an empty file is read, it
4284 returns C<''> the first time, followed by C<undef> subsequently.
4285
4286 This is the internal function implementing the C<< <EXPR> >>
4287 operator, but you can use it directly.  The C<< <EXPR> >>
4288 operator is discussed in more detail in L<perlop/"I/O Operators">.
4289
4290     $line = <STDIN>;
4291     $line = readline(*STDIN);           # same thing
4292
4293 If readline encounters an operating system error, C<$!> will be set with the
4294 corresponding error message.  It can be helpful to check C<$!> when you are
4295 reading from filehandles you don't trust, such as a tty or a socket.  The
4296 following example uses the operator form of C<readline>, and takes the necessary
4297 steps to ensure that C<readline> was successful.
4298
4299     for (;;) {
4300         undef $!;
4301         unless (defined( $line = <> )) {
4302             die $! if $!;
4303             last; # reached EOF
4304         }
4305         # ...
4306     }
4307
4308 =item readlink EXPR
4309 X<readlink>
4310
4311 =item readlink
4312
4313 Returns the value of a symbolic link, if symbolic links are
4314 implemented.  If not, gives a fatal error.  If there is some system
4315 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4316 omitted, uses C<$_>.
4317
4318 =item readpipe EXPR
4319
4320 =item readpipe
4321 X<readpipe>
4322
4323 EXPR is executed as a system command.
4324 The collected standard output of the command is returned.
4325 In scalar context, it comes back as a single (potentially
4326 multi-line) string.  In list context, returns a list of lines
4327 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4328 This is the internal function implementing the C<qx/EXPR/>
4329 operator, but you can use it directly.  The C<qx/EXPR/>
4330 operator is discussed in more detail in L<perlop/"I/O Operators">.
4331 If EXPR is omitted, uses C<$_>.
4332
4333 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4334 X<recv>
4335
4336 Receives a message on a socket.  Attempts to receive LENGTH characters
4337 of data into variable SCALAR from the specified SOCKET filehandle.
4338 SCALAR will be grown or shrunk to the length actually read.  Takes the
4339 same flags as the system call of the same name.  Returns the address
4340 of the sender if SOCKET's protocol supports this; returns an empty
4341 string otherwise.  If there's an error, returns the undefined value.
4342 This call is actually implemented in terms of recvfrom(2) system call.
4343 See L<perlipc/"UDP: Message Passing"> for examples.
4344
4345 Note the I<characters>: depending on the status of the socket, either
4346 (8-bit) bytes or characters are received.  By default all sockets
4347 operate on bytes, but for example if the socket has been changed using
4348 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4349 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4350 characters, not bytes.  Similarly for the C<:encoding> pragma:
4351 in that case pretty much any characters can be read.
4352
4353 =item redo LABEL
4354 X<redo>
4355
4356 =item redo
4357
4358 The C<redo> command restarts the loop block without evaluating the
4359 conditional again.  The C<continue> block, if any, is not executed.  If
4360 the LABEL is omitted, the command refers to the innermost enclosing
4361 loop.  Programs that want to lie to themselves about what was just input 
4362 normally use this command:
4363
4364     # a simpleminded Pascal comment stripper
4365     # (warning: assumes no { or } in strings)
4366     LINE: while (<STDIN>) {
4367         while (s|({.*}.*){.*}|$1 |) {}
4368         s|{.*}| |;
4369         if (s|{.*| |) {
4370             $front = $_;
4371             while (<STDIN>) {
4372                 if (/}/) {      # end of comment?
4373                     s|^|$front\{|;
4374                     redo LINE;
4375                 }
4376             }
4377         }
4378         print;
4379     }
4380
4381 C<redo> cannot be used to retry a block which returns a value such as
4382 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4383 a grep() or map() operation.
4384
4385 Note that a block by itself is semantically identical to a loop
4386 that executes once.  Thus C<redo> inside such a block will effectively
4387 turn it into a looping construct.
4388
4389 See also L</continue> for an illustration of how C<last>, C<next>, and
4390 C<redo> work.
4391
4392 =item ref EXPR
4393 X<ref> X<reference>
4394
4395 =item ref
4396
4397 Returns a non-empty string if EXPR is a reference, the empty
4398 string otherwise. If EXPR
4399 is not specified, C<$_> will be used.  The value returned depends on the
4400 type of thing the reference is a reference to.
4401 Builtin types include:
4402
4403     SCALAR
4404     ARRAY
4405     HASH
4406     CODE
4407     REF
4408     GLOB
4409     LVALUE
4410     FORMAT
4411     IO
4412     VSTRING
4413     Regexp
4414
4415 If the referenced object has been blessed into a package, then that package
4416 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4417
4418     if (ref($r) eq "HASH") {
4419         print "r is a reference to a hash.\n";
4420     }
4421     unless (ref($r)) {
4422         print "r is not a reference at all.\n";
4423     }
4424
4425 The return value C<LVALUE> indicates a reference to an lvalue that is not
4426 a variable. You get this from taking the reference of function calls like
4427 C<pos()> or C<substr()>. C<VSTRING> is returned if the reference points
4428 to a L<version string|perldata/"Version Strings">.
4429
4430 The result C<Regexp> indicates that the argument is a regular expression
4431 resulting from C<qr//>.
4432
4433 See also L<perlref>.
4434
4435 =item rename OLDNAME,NEWNAME
4436 X<rename> X<move> X<mv> X<ren>
4437
4438 Changes the name of a file; an existing file NEWNAME will be
4439 clobbered.  Returns true for success, false otherwise.
4440
4441 Behavior of this function varies wildly depending on your system
4442 implementation.  For example, it will usually not work across file system
4443 boundaries, even though the system I<mv> command sometimes compensates
4444 for this.  Other restrictions include whether it works on directories,
4445 open files, or pre-existing files.  Check L<perlport> and either the
4446 rename(2) manpage or equivalent system documentation for details.
4447
4448 For a platform independent C<move> function look at the L<File::Copy>
4449 module.
4450
4451 =item require VERSION
4452 X<require>
4453
4454 =item require EXPR
4455
4456 =item require
4457
4458 Demands a version of Perl specified by VERSION, or demands some semantics
4459 specified by EXPR or by C<$_> if EXPR is not supplied.
4460
4461 VERSION may be either a numeric argument such as 5.006, which will be
4462 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4463 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4464 VERSION is greater than the version of the current Perl interpreter.
4465 Compare with L</use>, which can do a similar check at compile time.
4466
4467 Specifying VERSION as a literal of the form v5.6.1 should generally be
4468 avoided, because it leads to misleading error messages under earlier
4469 versions of Perl that do not support this syntax.  The equivalent numeric
4470 version should be used instead.
4471
4472     require v5.6.1;     # run time version check
4473     require 5.6.1;      # ditto
4474     require 5.006_001;  # ditto; preferred for backwards compatibility
4475
4476 Otherwise, C<require> demands that a library file be included if it
4477 hasn't already been included.  The file is included via the do-FILE
4478 mechanism, which is essentially just a variety of C<eval> with the
4479 caveat that lexical variables in the invoking script will be invisible
4480 to the included code.  Has semantics similar to the following subroutine:
4481
4482     sub require {
4483        my ($filename) = @_;
4484        if (exists $INC{$filename}) {
4485            return 1 if $INC{$filename};
4486            die "Compilation failed in require";
4487        }
4488        my ($realfilename,$result);
4489        ITER: {
4490            foreach $prefix (@INC) {
4491                $realfilename = "$prefix/$filename";
4492                if (-f $realfilename) {
4493                    $INC{$filename} = $realfilename;
4494                    $result = do $realfilename;
4495                    last ITER;
4496                }
4497            }
4498            die "Can't find $filename in \@INC";
4499        }
4500        if ($@) {
4501            $INC{$filename} = undef;
4502            die $@;
4503        } elsif (!$result) {
4504            delete $INC{$filename};
4505            die "$filename did not return true value";
4506        } else {
4507            return $result;
4508        }
4509     }
4510
4511 Note that the file will not be included twice under the same specified
4512 name.
4513
4514 The file must return true as the last statement to indicate
4515 successful execution of any initialization code, so it's customary to
4516 end such a file with C<1;> unless you're sure it'll return true
4517 otherwise.  But it's better just to put the C<1;>, in case you add more
4518 statements.
4519
4520 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4521 replaces "F<::>" with "F</>" in the filename for you,
4522 to make it easy to load standard modules.  This form of loading of
4523 modules does not risk altering your namespace.
4524
4525 In other words, if you try this:
4526
4527         require Foo::Bar;    # a splendid bareword
4528
4529 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4530 directories specified in the C<@INC> array.
4531
4532 But if you try this:
4533
4534         $class = 'Foo::Bar';
4535         require $class;      # $class is not a bareword
4536     #or
4537         require "Foo::Bar";  # not a bareword because of the ""
4538
4539 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4540 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4541
4542         eval "require $class";
4543
4544 Now that you understand how C<require> looks for files in the case of a
4545 bareword argument, there is a little extra functionality going on behind
4546 the scenes.  Before C<require> looks for a "F<.pm>" extension, it will
4547 first look for a similar filename with a "F<.pmc>" extension. If this file
4548 is found, it will be loaded in place of any file ending in a "F<.pm>"
4549 extension.
4550
4551 You can also insert hooks into the import facility, by putting directly
4552 Perl code into the @INC array.  There are three forms of hooks: subroutine
4553 references, array references and blessed objects.
4554
4555 Subroutine references are the simplest case.  When the inclusion system
4556 walks through @INC and encounters a subroutine, this subroutine gets
4557 called with two parameters, the first being a reference to itself, and the
4558 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4559 subroutine should return nothing, or a list of up to three values in the
4560 following order:
4561
4562 =over
4563
4564 =item 1
4565
4566 A filehandle, from which the file will be read.  
4567
4568 =item 2
4569
4570 A reference to a subroutine. If there is no filehandle (previous item),
4571 then this subroutine is expected to generate one line of source code per
4572 call, writing the line into C<$_> and returning 1, then returning 0 at
4573 "end of file". If there is a filehandle, then the subroutine will be
4574 called to act a simple source filter, with the line as read in C<$_>.
4575 Again, return 1 for each valid line, and 0 after all lines have been
4576 returned.
4577
4578 =item 3
4579
4580 Optional state for the subroutine. The state is passed in as C<$_[1]>. A
4581 reference to the subroutine itself is passed in as C<$_[0]>.
4582
4583 =back
4584
4585 If an empty list, C<undef>, or nothing that matches the first 3 values above
4586 is returned then C<require> will look at the remaining elements of @INC.
4587 Note that this file handle must be a real file handle (strictly a typeglob,
4588 or reference to a typeglob, blessed or unblessed) - tied file handles will be
4589 ignored and return value processing will stop there.
4590
4591 If the hook is an array reference, its first element must be a subroutine
4592 reference.  This subroutine is called as above, but the first parameter is
4593 the array reference.  This enables to pass indirectly some arguments to
4594 the subroutine.
4595
4596 In other words, you can write:
4597
4598     push @INC, \&my_sub;
4599     sub my_sub {
4600         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4601         ...
4602     }
4603
4604 or:
4605
4606     push @INC, [ \&my_sub, $x, $y, ... ];
4607     sub my_sub {
4608         my ($arrayref, $filename) = @_;
4609         # Retrieve $x, $y, ...
4610         my @parameters = @$arrayref[1..$#$arrayref];
4611         ...
4612     }
4613
4614 If the hook is an object, it must provide an INC method that will be
4615 called as above, the first parameter being the object itself.  (Note that
4616 you must fully qualify the sub's name, as unqualified C<INC> is always forced
4617 into package C<main>.)  Here is a typical code layout:
4618
4619     # In Foo.pm
4620     package Foo;
4621     sub new { ... }
4622     sub Foo::INC {
4623         my ($self, $filename) = @_;
4624         ...
4625     }
4626
4627     # In the main program
4628     push @INC, new Foo(...);
4629
4630 Note that these hooks are also permitted to set the %INC entry
4631 corresponding to the files they have loaded. See L<perlvar/%INC>.
4632
4633 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4634
4635 =item reset EXPR
4636 X<reset>
4637
4638 =item reset
4639
4640 Generally used in a C<continue> block at the end of a loop to clear
4641 variables and reset C<??> searches so that they work again.  The
4642 expression is interpreted as a list of single characters (hyphens
4643 allowed for ranges).  All variables and arrays beginning with one of
4644 those letters are reset to their pristine state.  If the expression is
4645 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4646 only variables or searches in the current package.  Always returns
4647 1.  Examples:
4648
4649     reset 'X';          # reset all X variables
4650     reset 'a-z';        # reset lower case variables
4651     reset;              # just reset ?one-time? searches
4652
4653 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4654 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4655 variables--lexical variables are unaffected, but they clean themselves
4656 up on scope exit anyway, so you'll probably want to use them instead.
4657 See L</my>.
4658
4659 =item return EXPR
4660 X<return>
4661
4662 =item return
4663