Make print_section a method
[perl.git] / dist / ExtUtils-ParseXS / lib / ExtUtils / ParseXS.pm
1 package ExtUtils::ParseXS;
2 use strict;
3
4 use 5.006;  # We use /??{}/ in regexes
5 use Cwd;
6 use Config;
7 use Exporter;
8 use File::Basename;
9 use File::Spec;
10 use Symbol;
11 use ExtUtils::ParseXS::Constants ();
12 use ExtUtils::ParseXS::CountLines;
13 use ExtUtils::ParseXS::Utilities qw(
14   standard_typemap_locations
15   trim_whitespace
16   tidy_type
17   C_string
18   valid_proto_string
19   process_typemaps
20   make_targetable
21   map_type
22   standard_XS_defs
23   assign_func_args
24   analyze_preprocessor_statements
25   set_cond
26   Warn
27   blurt
28   death
29   check_conditional_preprocessor_statements
30 );
31
32 our @ISA = qw(Exporter);
33 our @EXPORT_OK = qw(
34   process_file
35   report_error_count
36 );
37 our $VERSION = '3';
38 $VERSION = eval $VERSION if $VERSION =~ /_/;
39
40 # The scalars in the line below remain as 'our' variables because pulling
41 # them into $self led to build problems.  In most cases, strings being
42 # 'eval'-ed contain the variables' names hard-coded.
43 our (
44   $FH, $Package, $func_name, $Full_func_name, $pname, $ALIAS,
45 );
46
47 our $self = bless {} => __PACKAGE__;
48
49 sub process_file {
50
51   # Allow for $package->process_file(%hash) in the future
52   my ($pkg, %options) = @_ % 2 ? @_ : (__PACKAGE__, @_);
53
54   $self->{ProtoUsed} = exists $options{prototypes};
55
56   # Set defaults.
57   my %args = (
58     argtypes        => 1,
59     csuffix         => '.c',
60     except          => 0,
61     hiertype        => 0,
62     inout           => 1,
63     linenumbers     => 1,
64     optimize        => 1,
65     output          => \*STDOUT,
66     prototypes      => 0,
67     typemap         => [],
68     versioncheck    => 1,
69     %options,
70   );
71   $args{except} = $args{except} ? ' TRY' : '';
72
73   # Global Constants
74
75   my ($Is_VMS, $SymSet);
76   if ($^O eq 'VMS') {
77     $Is_VMS = 1;
78     # Establish set of global symbols with max length 28, since xsubpp
79     # will later add the 'XS_' prefix.
80     require ExtUtils::XSSymSet;
81     $SymSet = ExtUtils::XSSymSet->new(28);
82   }
83   @{ $self->{XSStack} } = ({type => 'none'});
84   $self->{InitFileCode} = [ @ExtUtils::ParseXS::Constants::InitFileCode ];
85   $FH                   = $ExtUtils::ParseXS::Constants::FH;
86   $self->{Overload}     = $ExtUtils::ParseXS::Constants::Overload;
87   $self->{errors}       = $ExtUtils::ParseXS::Constants::errors;
88   $self->{Fallback}     = $ExtUtils::ParseXS::Constants::Fallback;
89
90   # Most of the 1500 lines below uses these globals.  We'll have to
91   # clean this up sometime, probably.  For now, we just pull them out
92   # of %args.  -Ken
93
94   $self->{hiertype} = $args{hiertype};
95   $self->{WantPrototypes} = $args{prototypes};
96   $self->{WantVersionChk} = $args{versioncheck};
97   $self->{WantLineNumbers} = $args{linenumbers};
98   $self->{IncludedFiles} = {};
99
100   die "Missing required parameter 'filename'" unless $args{filename};
101   $self->{filepathname} = $args{filename};
102   ($self->{dir}, $self->{filename}) =
103     (dirname($args{filename}), basename($args{filename}));
104   $self->{filepathname} =~ s/\\/\\\\/g;
105   $self->{IncludedFiles}->{$args{filename}}++;
106
107   # Open the output file if given as a string.  If they provide some
108   # other kind of reference, trust them that we can print to it.
109   if (not ref $args{output}) {
110     open my($fh), "> $args{output}" or die "Can't create $args{output}: $!";
111     $args{outfile} = $args{output};
112     $args{output} = $fh;
113   }
114
115   # Really, we shouldn't have to chdir() or select() in the first
116   # place.  For now, just save and restore.
117   my $orig_cwd = cwd();
118   my $orig_fh = select();
119
120   chdir($self->{dir});
121   my $pwd = cwd();
122   my $csuffix = $args{csuffix};
123
124   if ($self->{WantLineNumbers}) {
125     my $cfile;
126     if ( $args{outfile} ) {
127       $cfile = $args{outfile};
128     }
129     else {
130       $cfile = $args{filename};
131       $cfile =~ s/\.xs$/$csuffix/i or $cfile .= $csuffix;
132     }
133     tie(*PSEUDO_STDOUT, 'ExtUtils::ParseXS::CountLines', $cfile, $args{output});
134     select PSEUDO_STDOUT;
135   }
136   else {
137     select $args{output};
138   }
139
140   $self->{typemap} = process_typemaps( $args{typemap}, $pwd );
141
142   my $END = "!End!\n\n";        # "impossible" keyword (multiple newline)
143
144   # Match an XS keyword
145   $self->{BLOCK_re} = '\s*(' .
146     join('|' => @ExtUtils::ParseXS::Constants::XSKeywords) .
147     "|$END)\\s*:";
148
149   our ($C_group_rex, $C_arg);
150   # Group in C (no support for comments or literals)
151   $C_group_rex = qr/ [({\[]
152                (?: (?> [^()\[\]{}]+ ) | (??{ $C_group_rex }) )*
153                [)}\]] /x;
154   # Chunk in C without comma at toplevel (no comments):
155   $C_arg = qr/ (?: (?> [^()\[\]{},"']+ )
156          |   (??{ $C_group_rex })
157          |   " (?: (?> [^\\"]+ )
158            |   \\.
159            )* "        # String literal
160                 |   ' (?: (?> [^\\']+ ) | \\. )* ' # Char literal
161          )* /xs;
162
163   # Since at this point we're ready to begin printing to the output file and
164   # reading from the input file, I want to get as much data as possible into
165   # the proto-object $self.  That means assigning to $self and elements of
166   # %args referenced below this point.
167   # HOWEVER:  This resulted in an error when I tried:
168   #   $args{'s'} ---> $self->{s}.
169   # Use of uninitialized value in quotemeta at
170   #   .../blib/lib/ExtUtils/ParseXS.pm line 733
171
172   foreach my $datum ( qw| argtypes except inout optimize | ) {
173     $self->{$datum} = $args{$datum};
174   }
175
176   # Identify the version of xsubpp used
177   print <<EOM;
178 /*
179  * This file was generated automatically by ExtUtils::ParseXS version $VERSION from the
180  * contents of $self->{filename}. Do not edit this file, edit $self->{filename} instead.
181  *
182  *    ANY CHANGES MADE HERE WILL BE LOST!
183  *
184  */
185
186 EOM
187
188
189   print("#line 1 \"$self->{filepathname}\"\n")
190     if $self->{WantLineNumbers};
191
192   # Open the input file (using $self->{filename} which
193   # is a basename'd $args{filename} due to chdir above)
194   open($FH, $self->{filename}) or die "cannot open $self->{filename}: $!\n";
195
196   firstmodule:
197   while (<$FH>) {
198     if (/^=/) {
199       my $podstartline = $.;
200       do {
201         if (/^=cut\s*$/) {
202           # We can't just write out a /* */ comment, as our embedded
203           # POD might itself be in a comment. We can't put a /**/
204           # comment inside #if 0, as the C standard says that the source
205           # file is decomposed into preprocessing characters in the stage
206           # before preprocessing commands are executed.
207           # I don't want to leave the text as barewords, because the spec
208           # isn't clear whether macros are expanded before or after
209           # preprocessing commands are executed, and someone pathological
210           # may just have defined one of the 3 words as a macro that does
211           # something strange. Multiline strings are illegal in C, so
212           # the "" we write must be a string literal. And they aren't
213           # concatenated until 2 steps later, so we are safe.
214           #     - Nicholas Clark
215           print("#if 0\n  \"Skipped embedded POD.\"\n#endif\n");
216           printf("#line %d \"$self->{filepathname}\"\n", $. + 1)
217             if $self->{WantLineNumbers};
218           next firstmodule
219         }
220
221       } while (<$FH>);
222       # At this point $. is at end of file so die won't state the start
223       # of the problem, and as we haven't yet read any lines &death won't
224       # show the correct line in the message either.
225       die ("Error: Unterminated pod in $self->{filename}, line $podstartline\n")
226         unless $self->{lastline};
227     }
228     last if ($Package, $self->{Prefix}) =
229       /^MODULE\s*=\s*[\w:]+(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/;
230
231     print $_;
232   }
233   unless (defined $_) {
234     warn "Didn't find a 'MODULE ... PACKAGE ... PREFIX' line\n";
235     exit 0; # Not a fatal error for the caller process
236   }
237
238   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
239
240   standard_XS_defs();
241
242   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
243
244   $self->{lastline}    = $_;
245   $self->{lastline_no} = $.;
246
247   my $BootCode_ref = [];
248   my $XSS_work_idx = 0;
249   my $cpp_next_tmp = 'XSubPPtmpAAAA';
250  PARAGRAPH:
251   while ($self->fetch_para()) {
252     my $outlist_ref  = [];
253     # Print initial preprocessor statements and blank lines
254     while (@{ $self->{line} } && $self->{line}->[0] !~ /^[^\#]/) {
255       my $ln = shift(@{ $self->{line} });
256       print $ln, "\n";
257       next unless $ln =~ /^\#\s*((if)(?:n?def)?|elsif|else|endif)\b/;
258       my $statement = $+;
259       ( $self, $XSS_work_idx, $BootCode_ref ) =
260         analyze_preprocessor_statements(
261           $self, $statement, $XSS_work_idx, $BootCode_ref
262         );
263     }
264
265     next PARAGRAPH unless @{ $self->{line} };
266
267     if ($XSS_work_idx && !$self->{XSStack}->[$XSS_work_idx]{varname}) {
268       # We are inside an #if, but have not yet #defined its xsubpp variable.
269       print "#define $cpp_next_tmp 1\n\n";
270       push(@{ $self->{InitFileCode} }, "#if $cpp_next_tmp\n");
271       push(@{ $BootCode_ref },     "#if $cpp_next_tmp");
272       $self->{XSStack}->[$XSS_work_idx]{varname} = $cpp_next_tmp++;
273     }
274
275     death( $self,
276       "Code is not inside a function"
277         ." (maybe last function was ended by a blank line "
278         ." followed by a statement on column one?)")
279       if $self->{line}->[0] =~ /^\s/;
280
281     # initialize info arrays
282     undef(%{ $self->{args_match} });
283     undef(%{ $self->{var_types} });
284     undef(%{ $self->{defaults} });
285     undef(%{ $self->{arg_list} });
286     undef(@{ $self->{proto_arg} });
287     undef($self->{processing_arg_with_types});
288     undef(%{ $self->{argtype_seen} });
289     undef(%{ $self->{in_out} });
290     undef(%{ $self->{lengthof} });
291     undef($self->{proto_in_this_xsub});
292     undef($self->{scope_in_this_xsub});
293     undef($self->{interface});
294     $self->{interface_macro} = 'XSINTERFACE_FUNC';
295     $self->{interface_macro_set} = 'XSINTERFACE_FUNC_SET';
296     $self->{ProtoThisXSUB} = $self->{WantPrototypes};
297     $self->{ScopeThisXSUB} = 0;
298     my $xsreturn = 0;
299
300     $_ = shift(@{ $self->{line} });
301     while (my $kwd = $self->check_keyword("REQUIRE|PROTOTYPES|FALLBACK|VERSIONCHECK|INCLUDE(?:_COMMAND)?|SCOPE")) {
302       my $method = $kwd . "_handler";
303       $self->$method($_);
304       next PARAGRAPH unless @{ $self->{line} };
305       $_ = shift(@{ $self->{line} });
306     }
307
308     if ($self->check_keyword("BOOT")) {
309       check_conditional_preprocessor_statements($self);
310       push (@{ $BootCode_ref }, "#line $self->{line_no}->[@{ $self->{line_no} } - @{ $self->{line} }] \"$self->{filepathname}\"")
311         if $self->{WantLineNumbers} && $self->{line}->[0] !~ /^\s*#\s*line\b/;
312       push (@{ $BootCode_ref }, @{ $self->{line} }, "");
313       next PARAGRAPH;
314     }
315
316     # extract return type, function name and arguments
317     ($self->{ret_type}) = tidy_type($_);
318     my $RETVAL_no_return = 1 if $self->{ret_type} =~ s/^NO_OUTPUT\s+//;
319
320     # Allow one-line ANSI-like declaration
321     unshift @{ $self->{line} }, $2
322       if $self->{argtypes}
323         and $self->{ret_type} =~ s/^(.*?\w.*?)\s*\b(\w+\s*\(.*)/$1/s;
324
325     # a function definition needs at least 2 lines
326     blurt( $self, "Error: Function definition too short '$self->{ret_type}'"), next PARAGRAPH
327       unless @{ $self->{line} };
328
329     my $externC = 1 if $self->{ret_type} =~ s/^extern "C"\s+//;
330     my $static  = 1 if $self->{ret_type} =~ s/^static\s+//;
331
332     my $func_header = shift(@{ $self->{line} });
333     blurt( $self, "Error: Cannot parse function definition from '$func_header'"), next PARAGRAPH
334       unless $func_header =~ /^(?:([\w:]*)::)?(\w+)\s*\(\s*(.*?)\s*\)\s*(const)?\s*(;\s*)?$/s;
335
336     my ($class, $orig_args);
337     ($class, $func_name, $orig_args) =  ($1, $2, $3);
338     $class = "$4 $class" if $4;
339     ($pname = $func_name) =~ s/^($self->{Prefix})?/$self->{Packprefix}/;
340     my $clean_func_name;
341     ($clean_func_name = $func_name) =~ s/^$self->{Prefix}//;
342     $Full_func_name = "$self->{Packid}_$clean_func_name";
343     if ($Is_VMS) {
344       $Full_func_name = $SymSet->addsym($Full_func_name);
345     }
346
347     # Check for duplicate function definition
348     for my $tmp (@{ $self->{XSStack} }) {
349       next unless defined $tmp->{functions}{$Full_func_name};
350       Warn( $self, "Warning: duplicate function definition '$clean_func_name' detected");
351       last;
352     }
353     $self->{XSStack}->[$XSS_work_idx]{functions}{$Full_func_name}++;
354     %{ $self->{XsubAliases} }     = ();
355     %{ $self->{XsubAliasValues} } = ();
356     %{ $self->{Interfaces} }      = ();
357     @{ $self->{Attributes} }      = ();
358     $self->{DoSetMagic} = 1;
359
360     $orig_args =~ s/\\\s*/ /g;    # process line continuations
361     my @args;
362
363     my (@fake_INPUT_pre);    # For length(s) generated variables
364     my (@fake_INPUT);
365     my $only_C_inlist_ref = {};        # Not in the signature of Perl function
366     if ($self->{argtypes} and $orig_args =~ /\S/) {
367       my $args = "$orig_args ,";
368       if ($args =~ /^( (??{ $C_arg }) , )* $ /x) {
369         @args = ($args =~ /\G ( (??{ $C_arg }) ) , /xg);
370         for ( @args ) {
371           s/^\s+//;
372           s/\s+$//;
373           my ($arg, $default) = ($_ =~ m/ ( [^=]* ) ( (?: = .* )? ) /x);
374           my ($pre, $len_name) = ($arg =~ /(.*?) \s*
375                              \b ( \w+ | length\( \s*\w+\s* \) )
376                              \s* $ /x);
377           next unless defined($pre) && length($pre);
378           my $out_type = '';
379           my $inout_var;
380           if ($self->{inout} and s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//) {
381             my $type = $1;
382             $out_type = $type if $type ne 'IN';
383             $arg =~ s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//;
384             $pre =~ s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//;
385           }
386           my $islength;
387           if ($len_name =~ /^length\( \s* (\w+) \s* \)\z/x) {
388             $len_name = "XSauto_length_of_$1";
389             $islength = 1;
390             die "Default value on length() argument: `$_'"
391               if length $default;
392           }
393           if (length $pre or $islength) { # Has a type
394             if ($islength) {
395               push @fake_INPUT_pre, $arg;
396             }
397             else {
398               push @fake_INPUT, $arg;
399             }
400             # warn "pushing '$arg'\n";
401             $self->{argtype_seen}->{$len_name}++;
402             $_ = "$len_name$default"; # Assigns to @args
403           }
404           $only_C_inlist_ref->{$_} = 1 if $out_type eq "OUTLIST" or $islength;
405           push @{ $outlist_ref }, $len_name if $out_type =~ /OUTLIST$/;
406           $self->{in_out}->{$len_name} = $out_type if $out_type;
407         }
408       }
409       else {
410         @args = split(/\s*,\s*/, $orig_args);
411         Warn( $self, "Warning: cannot parse argument list '$orig_args', fallback to split");
412       }
413     }
414     else {
415       @args = split(/\s*,\s*/, $orig_args);
416       for (@args) {
417         if ($self->{inout} and s/^(IN|IN_OUTLIST|OUTLIST|IN_OUT|OUT)\b\s*//) {
418           my $out_type = $1;
419           next if $out_type eq 'IN';
420           $only_C_inlist_ref->{$_} = 1 if $out_type eq "OUTLIST";
421           if ($out_type =~ /OUTLIST$/) {
422               push @{ $outlist_ref }, undef;
423           }
424           $self->{in_out}->{$_} = $out_type;
425         }
426       }
427     }
428     if (defined($class)) {
429       my $arg0 = ((defined($static) or $func_name eq 'new')
430           ? "CLASS" : "THIS");
431       unshift(@args, $arg0);
432     }
433     my $extra_args = 0;
434     my @args_num = ();
435     my $num_args = 0;
436     my $report_args = '';
437     my $ellipsis;
438     foreach my $i (0 .. $#args) {
439       if ($args[$i] =~ s/\.\.\.//) {
440         $ellipsis = 1;
441         if ($args[$i] eq '' && $i == $#args) {
442           $report_args .= ", ...";
443           pop(@args);
444           last;
445         }
446       }
447       if ($only_C_inlist_ref->{$args[$i]}) {
448         push @args_num, undef;
449       }
450       else {
451         push @args_num, ++$num_args;
452           $report_args .= ", $args[$i]";
453       }
454       if ($args[$i] =~ /^([^=]*[^\s=])\s*=\s*(.*)/s) {
455         $extra_args++;
456         $args[$i] = $1;
457         $self->{defaults}->{$args[$i]} = $2;
458         $self->{defaults}->{$args[$i]} =~ s/"/\\"/g;
459       }
460       $self->{proto_arg}->[$i+1] = '$';
461     }
462     my $min_args = $num_args - $extra_args;
463     $report_args =~ s/"/\\"/g;
464     $report_args =~ s/^,\s+//;
465     $self->{func_args} = assign_func_args($self, \@args, $class);
466     @{ $self->{args_match} }{@args} = @args_num;
467
468     my $PPCODE = grep(/^\s*PPCODE\s*:/, @{ $self->{line} });
469     my $CODE = grep(/^\s*CODE\s*:/, @{ $self->{line} });
470     # Detect CODE: blocks which use ST(n)= or XST_m*(n,v)
471     # to set explicit return values.
472     my $EXPLICIT_RETURN = ($CODE &&
473             ("@{ $self->{line} }" =~ /(\bST\s*\([^;]*=) | (\bXST_m\w+\s*\()/x ));
474
475     # The $ALIAS which follows is only explicitly called within the scope of
476     # process_file().  In principle, it ought to be a lexical, i.e., 'my
477     # $ALIAS' like the other nearby variables.  However, implementing that
478     # change produced a slight difference in the resulting .c output in at
479     # least two distributions:  B/BD/BDFOY/Crypt-Rijndael and
480     # G/GF/GFUJI/Hash-FieldHash.  The difference is, arguably, an improvement
481     # in the resulting C code.  Example:
482     # 388c388
483     # <                       GvNAME(CvGV(cv)),
484     # ---
485     # >                       "Crypt::Rijndael::encrypt",
486     # But at this point we're committed to generating the *same* C code that
487     # the current version of ParseXS.pm does.  So we're declaring it as 'our'.
488     $ALIAS  = grep(/^\s*ALIAS\s*:/,  @{ $self->{line} });
489
490     my $INTERFACE  = grep(/^\s*INTERFACE\s*:/,  @{ $self->{line} });
491
492     $xsreturn = 1 if $EXPLICIT_RETURN;
493
494     $externC = $externC ? qq[extern "C"] : "";
495
496     # print function header
497     print Q(<<"EOF");
498 #$externC
499 #XS(XS_${Full_func_name}); /* prototype to pass -Wmissing-prototypes */
500 #XS(XS_${Full_func_name})
501 #[[
502 ##ifdef dVAR
503 #    dVAR; dXSARGS;
504 ##else
505 #    dXSARGS;
506 ##endif
507 EOF
508     print Q(<<"EOF") if $ALIAS;
509 #    dXSI32;
510 EOF
511     print Q(<<"EOF") if $INTERFACE;
512 #    dXSFUNCTION($self->{ret_type});
513 EOF
514
515     $self->{cond} = set_cond($ellipsis, $min_args, $num_args);
516
517     print Q(<<"EOF") if $self->{except};
518 #    char errbuf[1024];
519 #    *errbuf = '\0';
520 EOF
521
522     if($self->{cond}) {
523       print Q(<<"EOF");
524 #    if ($self->{cond})
525 #       croak_xs_usage(cv,  "$report_args");
526 EOF
527     }
528     else {
529     # cv likely to be unused
530     print Q(<<"EOF");
531 #    PERL_UNUSED_VAR(cv); /* -W */
532 EOF
533     }
534
535     #gcc -Wall: if an xsub has PPCODE is used
536     #it is possible none of ST, XSRETURN or XSprePUSH macros are used
537     #hence `ax' (setup by dXSARGS) is unused
538     #XXX: could breakup the dXSARGS; into dSP;dMARK;dITEMS
539     #but such a move could break third-party extensions
540     print Q(<<"EOF") if $PPCODE;
541 #    PERL_UNUSED_VAR(ax); /* -Wall */
542 EOF
543
544     print Q(<<"EOF") if $PPCODE;
545 #    SP -= items;
546 EOF
547
548     # Now do a block of some sort.
549
550     $self->{condnum} = 0;
551     $self->{cond} = '';            # last CASE: conditional
552     push(@{ $self->{line} }, "$END:");
553     push(@{ $self->{line_no} }, $self->{line_no}->[-1]);
554     $_ = '';
555     $self->check_conditional_preprocessor_statements();
556     while (@{ $self->{line} }) {
557       $self->CASE_handler($_) if $self->check_keyword("CASE");
558       print Q(<<"EOF");
559 #   $self->{except} [[
560 EOF
561
562       # do initialization of input variables
563       $self->{thisdone} = 0;
564       $self->{retvaldone} = 0;
565       $self->{deferred} = "";
566       %{ $self->{arg_list} } = ();
567       $self->{gotRETVAL} = 0;
568
569       $self->INPUT_handler($_);
570       $self->process_keyword("INPUT|PREINIT|INTERFACE_MACRO|C_ARGS|ALIAS|ATTRS|PROTOTYPE|SCOPE|OVERLOAD");
571
572       print Q(<<"EOF") if $self->{ScopeThisXSUB};
573 #   ENTER;
574 #   [[
575 EOF
576
577       if (!$self->{thisdone} && defined($class)) {
578         if (defined($static) or $func_name eq 'new') {
579           print "\tchar *";
580           $self->{var_types}->{"CLASS"} = "char *";
581           generate_init( {
582             type          => "char *",
583             num           => 1,
584             var           => "CLASS",
585             printed_name  => undef,
586           } );
587         }
588         else {
589           print "\t$class *";
590           $self->{var_types}->{"THIS"} = "$class *";
591           generate_init( {
592             type          => "$class *",
593             num           => 1,
594             var           => "THIS",
595             printed_name  => undef,
596           } );
597         }
598       }
599
600       my ($wantRETVAL);
601       # do code
602       if (/^\s*NOT_IMPLEMENTED_YET/) {
603         print "\n\tPerl_croak(aTHX_ \"$pname: not implemented yet\");\n";
604         $_ = '';
605       }
606       else {
607         if ($self->{ret_type} ne "void") {
608           print "\t" . map_type($self, $self->{ret_type}, 'RETVAL') . ";\n"
609             if !$self->{retvaldone};
610           $self->{args_match}->{"RETVAL"} = 0;
611           $self->{var_types}->{"RETVAL"} = $self->{ret_type};
612           my $outputmap = $self->{typemap}->get_outputmap( ctype => $self->{ret_type} );
613           print "\tdXSTARG;\n"
614             if $self->{optimize} and $outputmap and $outputmap->targetable;
615         }
616
617         if (@fake_INPUT or @fake_INPUT_pre) {
618           unshift @{ $self->{line} }, @fake_INPUT_pre, @fake_INPUT, $_;
619           $_ = "";
620           $self->{processing_arg_with_types} = 1;
621           $self->INPUT_handler($_);
622         }
623         print $self->{deferred};
624
625         $self->process_keyword("INIT|ALIAS|ATTRS|PROTOTYPE|INTERFACE_MACRO|INTERFACE|C_ARGS|OVERLOAD");
626
627         if ($self->check_keyword("PPCODE")) {
628           $self->print_section();
629           death( $self, "PPCODE must be last thing") if @{ $self->{line} };
630           print "\tLEAVE;\n" if $self->{ScopeThisXSUB};
631           print "\tPUTBACK;\n\treturn;\n";
632         }
633         elsif ($self->check_keyword("CODE")) {
634           $self->print_section();
635         }
636         elsif (defined($class) and $func_name eq "DESTROY") {
637           print "\n\t";
638           print "delete THIS;\n";
639         }
640         else {
641           print "\n\t";
642           if ($self->{ret_type} ne "void") {
643             print "RETVAL = ";
644             $wantRETVAL = 1;
645           }
646           if (defined($static)) {
647             if ($func_name eq 'new') {
648               $func_name = "$class";
649             }
650             else {
651               print "${class}::";
652             }
653           }
654           elsif (defined($class)) {
655             if ($func_name eq 'new') {
656               $func_name .= " $class";
657             }
658             else {
659               print "THIS->";
660             }
661           }
662           $func_name =~ s/^\Q$args{'s'}//
663             if exists $args{'s'};
664           $func_name = 'XSFUNCTION' if $self->{interface};
665           print "$func_name($self->{func_args});\n";
666         }
667       }
668
669       # do output variables
670       $self->{gotRETVAL} = 0;        # 1 if RETVAL seen in OUTPUT section;
671       undef $self->{RETVAL_code} ;    # code to set RETVAL (from OUTPUT section);
672       # $wantRETVAL set if 'RETVAL =' autogenerated
673       ($wantRETVAL, $self->{ret_type}) = (0, 'void') if $RETVAL_no_return;
674       undef %{ $self->{outargs} };
675       $self->process_keyword("POSTCALL|OUTPUT|ALIAS|ATTRS|PROTOTYPE|OVERLOAD");
676
677       generate_output( {
678         type        => $self->{var_types}->{$_},
679         num         => $self->{args_match}->{$_},
680         var         => $_,
681         do_setmagic => $self->{DoSetMagic},
682         do_push     => undef,
683       } ) for grep $self->{in_out}->{$_} =~ /OUT$/, keys %{ $self->{in_out} };
684
685       my $prepush_done;
686       # all OUTPUT done, so now push the return value on the stack
687       if ($self->{gotRETVAL} && $self->{RETVAL_code}) {
688         print "\t$self->{RETVAL_code}\n";
689       }
690       elsif ($self->{gotRETVAL} || $wantRETVAL) {
691         my $outputmap = $self->{typemap}->get_outputmap( ctype => $self->{ret_type} );
692         my $t = $self->{optimize} && $outputmap && $outputmap->targetable;
693         # Although the '$var' declared in the next line is never explicitly
694         # used within this 'elsif' block, commenting it out leads to
695         # disaster, starting with the first 'eval qq' inside the 'elsif' block
696         # below.
697         # It appears that this is related to the fact that at this point the
698         # value of $t is a reference to an array whose [2] element includes
699         # '$var' as a substring:
700         # <i> <> <(IV)$var>
701         my $var = 'RETVAL';
702         my $type = $self->{ret_type};
703
704         if ($t and not $t->{with_size} and $t->{type} eq 'p') {
705           # PUSHp corresponds to setpvn.  Treat setpv directly
706           my $what = eval qq("$t->{what}");
707           warn $@ if $@;
708
709           print "\tsv_setpv(TARG, $what); XSprePUSH; PUSHTARG;\n";
710           $prepush_done = 1;
711         }
712         elsif ($t) {
713           my $what = eval qq("$t->{what}");
714           warn $@ if $@;
715
716           my $tsize = $t->{what_size};
717           $tsize = '' unless defined $tsize;
718           $tsize = eval qq("$tsize");
719           warn $@ if $@;
720           print "\tXSprePUSH; PUSH$t->{type}($what$tsize);\n";
721           $prepush_done = 1;
722         }
723         else {
724           # RETVAL almost never needs SvSETMAGIC()
725           generate_output( {
726             type        => $self->{ret_type},
727             num         => 0,
728             var         => 'RETVAL',
729             do_setmagic => 0,
730             do_push     => undef,
731           } );
732         }
733       }
734
735       $xsreturn = 1 if $self->{ret_type} ne "void";
736       my $num = $xsreturn;
737       my $c = @{ $outlist_ref };
738       print "\tXSprePUSH;" if $c and not $prepush_done;
739       print "\tEXTEND(SP,$c);\n" if $c;
740       $xsreturn += $c;
741       generate_output( {
742         type        => $self->{var_types}->{$_},
743         num         => $num++,
744         var         => $_,
745         do_setmagic => 0,
746         do_push     => 1,
747       } ) for @{ $outlist_ref };
748
749       # do cleanup
750       $self->process_keyword("CLEANUP|ALIAS|ATTRS|PROTOTYPE|OVERLOAD");
751
752       print Q(<<"EOF") if $self->{ScopeThisXSUB};
753 #   ]]
754 EOF
755       print Q(<<"EOF") if $self->{ScopeThisXSUB} and not $PPCODE;
756 #   LEAVE;
757 EOF
758
759       # print function trailer
760       print Q(<<"EOF");
761 #    ]]
762 EOF
763       print Q(<<"EOF") if $self->{except};
764 #    BEGHANDLERS
765 #    CATCHALL
766 #    sprintf(errbuf, "%s: %s\\tpropagated", Xname, Xreason);
767 #    ENDHANDLERS
768 EOF
769       if ($self->check_keyword("CASE")) {
770         blurt( $self, "Error: No `CASE:' at top of function")
771           unless $self->{condnum};
772         $_ = "CASE: $_";    # Restore CASE: label
773         next;
774       }
775       last if $_ eq "$END:";
776       death( $self,
777         /^$self->{BLOCK_re}/o ? "Misplaced `$1:'" : "Junk at end of function ($_)");
778     }
779
780     print Q(<<"EOF") if $self->{except};
781 #    if (errbuf[0])
782 #    Perl_croak(aTHX_ errbuf);
783 EOF
784
785     if ($xsreturn) {
786       print Q(<<"EOF") unless $PPCODE;
787 #    XSRETURN($xsreturn);
788 EOF
789     }
790     else {
791       print Q(<<"EOF") unless $PPCODE;
792 #    XSRETURN_EMPTY;
793 EOF
794     }
795
796     print Q(<<"EOF");
797 #]]
798 #
799 EOF
800
801     $self->{newXS} = "newXS";
802     $self->{proto} = "";
803
804     # Build the prototype string for the xsub
805     if ($self->{ProtoThisXSUB}) {
806       $self->{newXS} = "newXSproto_portable";
807
808       if ($self->{ProtoThisXSUB} eq 2) {
809         # User has specified empty prototype
810       }
811       elsif ($self->{ProtoThisXSUB} eq 1) {
812         my $s = ';';
813         if ($min_args < $num_args)  {
814           $s = '';
815           $self->{proto_arg}->[$min_args] .= ";";
816         }
817         push @{ $self->{proto_arg} }, "$s\@"
818           if $ellipsis;
819
820         $self->{proto} = join ("", grep defined, @{ $self->{proto_arg} } );
821       }
822       else {
823         # User has specified a prototype
824         $self->{proto} = $self->{ProtoThisXSUB};
825       }
826       $self->{proto} = qq{, "$self->{proto}"};
827     }
828
829     if (%{ $self->{XsubAliases} }) {
830       $self->{XsubAliases}->{$pname} = 0
831         unless defined $self->{XsubAliases}->{$pname};
832       while ( my ($xname, $value) = each %{ $self->{XsubAliases} }) {
833         push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
834 #        cv = $self->{newXS}(\"$xname\", XS_$Full_func_name, file$self->{proto});
835 #        XSANY.any_i32 = $value;
836 EOF
837       }
838     }
839     elsif (@{ $self->{Attributes} }) {
840       push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
841 #        cv = $self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});
842 #        apply_attrs_string("$Package", cv, "@{ $self->{Attributes} }", 0);
843 EOF
844     }
845     elsif ($self->{interface}) {
846       while ( my ($yname, $value) = each %{ $self->{Interfaces} }) {
847         $yname = "$Package\::$yname" unless $yname =~ /::/;
848         push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
849 #        cv = $self->{newXS}(\"$yname\", XS_$Full_func_name, file$self->{proto});
850 #        $self->{interface_macro_set}(cv,$value);
851 EOF
852       }
853     }
854     elsif($self->{newXS} eq 'newXS'){ # work around P5NCI's empty newXS macro
855       push(@{ $self->{InitFileCode} },
856        "        $self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});\n");
857     }
858     else {
859       push(@{ $self->{InitFileCode} },
860        "        (void)$self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});\n");
861     }
862   } # END 'PARAGRAPH' 'while' loop
863
864   if ($self->{Overload}) { # make it findable with fetchmethod
865     print Q(<<"EOF");
866 #XS(XS_$self->{Packid}_nil); /* prototype to pass -Wmissing-prototypes */
867 #XS(XS_$self->{Packid}_nil)
868 #{
869 #   dXSARGS;
870 #   XSRETURN_EMPTY;
871 #}
872 #
873 EOF
874     unshift(@{ $self->{InitFileCode} }, <<"MAKE_FETCHMETHOD_WORK");
875     /* Making a sub named "${Package}::()" allows the package */
876     /* to be findable via fetchmethod(), and causes */
877     /* overload::Overloaded("${Package}") to return true. */
878     (void)$self->{newXS}("${Package}::()", XS_$self->{Packid}_nil, file$self->{proto});
879 MAKE_FETCHMETHOD_WORK
880   }
881
882   # print initialization routine
883
884   print Q(<<"EOF");
885 ##ifdef __cplusplus
886 #extern "C"
887 ##endif
888 EOF
889
890   print Q(<<"EOF");
891 #XS(boot_$self->{Module_cname}); /* prototype to pass -Wmissing-prototypes */
892 #XS(boot_$self->{Module_cname})
893 EOF
894
895   print Q(<<"EOF");
896 #[[
897 ##ifdef dVAR
898 #    dVAR; dXSARGS;
899 ##else
900 #    dXSARGS;
901 ##endif
902 EOF
903
904   #Under 5.8.x and lower, newXS is declared in proto.h as expecting a non-const
905   #file name argument. If the wrong qualifier is used, it causes breakage with
906   #C++ compilers and warnings with recent gcc.
907   #-Wall: if there is no $Full_func_name there are no xsubs in this .xs
908   #so `file' is unused
909   print Q(<<"EOF") if $Full_func_name;
910 ##if (PERL_REVISION == 5 && PERL_VERSION < 9)
911 #    char* file = __FILE__;
912 ##else
913 #    const char* file = __FILE__;
914 ##endif
915 EOF
916
917   print Q("#\n");
918
919   print Q(<<"EOF");
920 #    PERL_UNUSED_VAR(cv); /* -W */
921 #    PERL_UNUSED_VAR(items); /* -W */
922 ##ifdef XS_APIVERSION_BOOTCHECK
923 #    XS_APIVERSION_BOOTCHECK;
924 ##endif
925 EOF
926
927   print Q(<<"EOF") if $self->{WantVersionChk};
928 #    XS_VERSION_BOOTCHECK;
929 #
930 EOF
931
932   print Q(<<"EOF") if defined $self->{xsubaliases} or defined $self->{interfaces};
933 #    {
934 #        CV * cv;
935 #
936 EOF
937
938   print Q(<<"EOF") if ($self->{Overload});
939 #    /* register the overloading (type 'A') magic */
940 #    PL_amagic_generation++;
941 #    /* The magic for overload gets a GV* via gv_fetchmeth as */
942 #    /* mentioned above, and looks in the SV* slot of it for */
943 #    /* the "fallback" status. */
944 #    sv_setsv(
945 #        get_sv( "${Package}::()", TRUE ),
946 #        $self->{Fallback}
947 #    );
948 EOF
949
950   print @{ $self->{InitFileCode} };
951
952   print Q(<<"EOF") if defined $self->{xsubaliases} or defined $self->{interfaces};
953 #    }
954 EOF
955
956   if (@{ $BootCode_ref }) {
957     print "\n    /* Initialisation Section */\n\n";
958     @{ $self->{line} } = @{ $BootCode_ref };
959     $self->print_section();
960     print "\n    /* End of Initialisation Section */\n\n";
961   }
962
963   print Q(<<'EOF');
964 ##if (PERL_REVISION == 5 && PERL_VERSION >= 9)
965 #  if (PL_unitcheckav)
966 #       call_list(PL_scopestack_ix, PL_unitcheckav);
967 ##endif
968 EOF
969
970   print Q(<<"EOF");
971 #    XSRETURN_YES;
972 #]]
973 #
974 EOF
975
976   warn("Please specify prototyping behavior for $self->{filename} (see perlxs manual)\n")
977     unless $self->{ProtoUsed};
978
979   chdir($orig_cwd);
980   select($orig_fh);
981   untie *PSEUDO_STDOUT if tied *PSEUDO_STDOUT;
982   close $FH;
983
984   return 1;
985 }
986
987 sub report_error_count { $self->{errors} }
988
989 # Input:  ($self, $_, @{ $self->{line} }) == unparsed input.
990 # Output: ($_, @{ $self->{line} }) == (rest of line, following lines).
991 # Return: the matched keyword if found, otherwise 0
992 sub check_keyword {
993   my $self = shift;
994   $_ = shift(@{ $self->{line} }) while !/\S/ && @{ $self->{line} };
995   s/^(\s*)($_[0])\s*:\s*(?:#.*)?/$1/s && $2;
996 }
997
998 sub print_section {
999   my $self = shift;
1000
1001   # the "do" is required for right semantics
1002   do { $_ = shift(@{ $self->{line} }) } while !/\S/ && @{ $self->{line} };
1003
1004   print("#line ", $self->{line_no}->[@{ $self->{line_no} } - @{ $self->{line} } -1], " \"$self->{filepathname}\"\n")
1005     if $self->{WantLineNumbers} && !/^\s*#\s*line\b/ && !/^#if XSubPPtmp/;
1006   for (;  defined($_) && !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1007     print "$_\n";
1008   }
1009   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
1010 }
1011
1012 sub merge_section {
1013   my $self = shift;
1014   my $in = '';
1015
1016   while (!/\S/ && @{ $self->{line} }) {
1017     $_ = shift(@{ $self->{line} });
1018   }
1019
1020   for (;  defined($_) && !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1021     $in .= "$_\n";
1022   }
1023   chomp $in;
1024   return $in;
1025 }
1026
1027 sub process_keyword {
1028   my($self, $pattern) = @_;
1029
1030   while (my $kwd = $self->check_keyword($pattern)) {
1031     my $method = $kwd . "_handler";
1032     $self->$method($_);
1033   }
1034 }
1035
1036 sub CASE_handler {
1037   my $self = shift;
1038   $_ = shift;
1039   blurt( $self, "Error: `CASE:' after unconditional `CASE:'")
1040     if $self->{condnum} && $self->{cond} eq '';
1041   $self->{cond} = $_;
1042   trim_whitespace($self->{cond});
1043   print "   ", ($self->{condnum}++ ? " else" : ""), ($self->{cond} ? " if ($self->{cond})\n" : "\n");
1044   $_ = '';
1045 }
1046
1047 sub INPUT_handler {
1048   my $self = shift;
1049   $_ = shift;
1050   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1051     last if /^\s*NOT_IMPLEMENTED_YET/;
1052     next unless /\S/;        # skip blank lines
1053
1054     trim_whitespace($_);
1055     my $ln = $_;
1056
1057     # remove trailing semicolon if no initialisation
1058     s/\s*;$//g unless /[=;+].*\S/;
1059
1060     # Process the length(foo) declarations
1061     if (s/^([^=]*)\blength\(\s*(\w+)\s*\)\s*$/$1 XSauto_length_of_$2=NO_INIT/x) {
1062       print "\tSTRLEN\tSTRLEN_length_of_$2;\n";
1063       $self->{lengthof}->{$2} = undef;
1064       $self->{deferred} .= "\n\tXSauto_length_of_$2 = STRLEN_length_of_$2;\n";
1065     }
1066
1067     # check for optional initialisation code
1068     my $var_init = '';
1069     $var_init = $1 if s/\s*([=;+].*)$//s;
1070     $var_init =~ s/"/\\"/g;
1071
1072     s/\s+/ /g;
1073     my ($var_type, $var_addr, $var_name) = /^(.*?[^&\s])\s*(\&?)\s*\b(\w+)$/s
1074       or blurt( $self, "Error: invalid argument declaration '$ln'"), next;
1075
1076     # Check for duplicate definitions
1077     blurt( $self, "Error: duplicate definition of argument '$var_name' ignored"), next
1078       if $self->{arg_list}->{$var_name}++
1079         or defined $self->{argtype_seen}->{$var_name} and not $self->{processing_arg_with_types};
1080
1081     $self->{thisdone} |= $var_name eq "THIS";
1082     $self->{retvaldone} |= $var_name eq "RETVAL";
1083     $self->{var_types}->{$var_name} = $var_type;
1084     # XXXX This check is a safeguard against the unfinished conversion of
1085     # generate_init().  When generate_init() is fixed,
1086     # one can use 2-args map_type() unconditionally.
1087     my $printed_name;
1088     if ($var_type =~ / \( \s* \* \s* \) /x) {
1089       # Function pointers are not yet supported with output_init()!
1090       print "\t" . map_type($self, $var_type, $var_name);
1091       $printed_name = 1;
1092     }
1093     else {
1094       print "\t" . map_type($self, $var_type, undef);
1095       $printed_name = 0;
1096     }
1097     $self->{var_num} = $self->{args_match}->{$var_name};
1098
1099     if ($self->{var_num}) {
1100       my $typemap = $self->{typemap}->get_typemap(ctype => $var_type);
1101       $self->{proto_arg}->[$self->{var_num}] = ($typemap && $typemap->proto) || "\$";
1102     }
1103     $self->{func_args} =~ s/\b($var_name)\b/&$1/ if $var_addr;
1104     if ($var_init =~ /^[=;]\s*NO_INIT\s*;?\s*$/
1105       or $self->{in_out}->{$var_name} and $self->{in_out}->{$var_name} =~ /^OUT/
1106       and $var_init !~ /\S/) {
1107       if ($printed_name) {
1108         print ";\n";
1109       }
1110       else {
1111         print "\t$var_name;\n";
1112       }
1113     }
1114     elsif ($var_init =~ /\S/) {
1115       output_init( {
1116         type          => $var_type,
1117         num           => $self->{var_num},
1118         var           => $var_name,
1119         init          => $var_init,
1120         printed_name  => $printed_name,
1121       } );
1122     }
1123     elsif ($self->{var_num}) {
1124       generate_init( {
1125         type          => $var_type,
1126         num           => $self->{var_num},
1127         var           => $var_name,
1128         printed_name  => $printed_name,
1129       } );
1130     }
1131     else {
1132       print ";\n";
1133     }
1134   }
1135 }
1136
1137 sub OUTPUT_handler {
1138   my $self = shift;
1139   $_ = shift;
1140   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1141     next unless /\S/;
1142     if (/^\s*SETMAGIC\s*:\s*(ENABLE|DISABLE)\s*/) {
1143       $self->{DoSetMagic} = ($1 eq "ENABLE" ? 1 : 0);
1144       next;
1145     }
1146     my ($outarg, $outcode) = /^\s*(\S+)\s*(.*?)\s*$/s;
1147     blurt( $self, "Error: duplicate OUTPUT argument '$outarg' ignored"), next
1148       if $self->{outargs}->{$outarg}++;
1149     if (!$self->{gotRETVAL} and $outarg eq 'RETVAL') {
1150       # deal with RETVAL last
1151       $self->{RETVAL_code} = $outcode;
1152       $self->{gotRETVAL} = 1;
1153       next;
1154     }
1155     blurt( $self, "Error: OUTPUT $outarg not an argument"), next
1156       unless defined($self->{args_match}->{$outarg});
1157     blurt( $self, "Error: No input definition for OUTPUT argument '$outarg' - ignored"), next
1158       unless defined $self->{var_types}->{$outarg};
1159     $self->{var_num} = $self->{args_match}->{$outarg};
1160     if ($outcode) {
1161       print "\t$outcode\n";
1162       print "\tSvSETMAGIC(ST(" , $self->{var_num} - 1 , "));\n" if $self->{DoSetMagic};
1163     }
1164     else {
1165       generate_output( {
1166         type        => $self->{var_types}->{$outarg},
1167         num         => $self->{var_num},
1168         var         => $outarg,
1169         do_setmagic => $self->{DoSetMagic},
1170         do_push     => undef,
1171       } );
1172     }
1173     delete $self->{in_out}->{$outarg}     # No need to auto-OUTPUT
1174       if exists $self->{in_out}->{$outarg} and $self->{in_out}->{$outarg} =~ /OUT$/;
1175   }
1176 }
1177
1178 sub C_ARGS_handler {
1179   my $self = shift;
1180   $_ = shift;
1181   my $in = $self->merge_section();
1182
1183   trim_whitespace($in);
1184   $self->{func_args} = $in;
1185 }
1186
1187 sub INTERFACE_MACRO_handler {
1188   my $self = shift;
1189   $_ = shift;
1190   my $in = $self->merge_section();
1191
1192   trim_whitespace($in);
1193   if ($in =~ /\s/) {        # two
1194     ($self->{interface_macro}, $self->{interface_macro_set}) = split ' ', $in;
1195   }
1196   else {
1197     $self->{interface_macro} = $in;
1198     $self->{interface_macro_set} = 'UNKNOWN_CVT'; # catch later
1199   }
1200   $self->{interface} = 1;        # local
1201   $self->{interfaces} = 1;        # global
1202 }
1203
1204 sub INTERFACE_handler {
1205   my $self = shift;
1206   $_ = shift;
1207   my $in = $self->merge_section();
1208
1209   trim_whitespace($in);
1210
1211   foreach (split /[\s,]+/, $in) {
1212     my $iface_name = $_;
1213     $iface_name =~ s/^$self->{Prefix}//;
1214     $self->{Interfaces}->{$iface_name} = $_;
1215   }
1216   print Q(<<"EOF");
1217 #    XSFUNCTION = $self->{interface_macro}($self->{ret_type},cv,XSANY.any_dptr);
1218 EOF
1219   $self->{interface} = 1;        # local
1220   $self->{interfaces} = 1;        # global
1221 }
1222
1223 sub CLEANUP_handler {
1224   my $self = shift;
1225   $self->print_section();
1226 }
1227
1228 sub PREINIT_handler {
1229   my $self = shift;
1230   $self->print_section();
1231 }
1232
1233 sub POSTCALL_handler {
1234   my $self = shift;
1235   $self->print_section();
1236 }
1237
1238 sub INIT_handler {
1239   my $self = shift;
1240   $self->print_section();
1241 }
1242
1243 sub GetAliases {
1244   my ($line) = @_;
1245   my ($orig) = $line;
1246
1247   # Parse alias definitions
1248   # format is
1249   #    alias = value alias = value ...
1250
1251   while ($line =~ s/^\s*([\w:]+)\s*=\s*(\w+)\s*//) {
1252     my ($alias, $value) = ($1, $2);
1253     my $orig_alias = $alias;
1254
1255     # check for optional package definition in the alias
1256     $alias = $self->{Packprefix} . $alias if $alias !~ /::/;
1257
1258     # check for duplicate alias name & duplicate value
1259     Warn( $self, "Warning: Ignoring duplicate alias '$orig_alias'")
1260       if defined $self->{XsubAliases}->{$alias};
1261
1262     Warn( $self, "Warning: Aliases '$orig_alias' and '$self->{XsubAliasValues}->{$value}' have identical values")
1263       if $self->{XsubAliasValues}->{$value};
1264
1265     $self->{xsubaliases} = 1;
1266     $self->{XsubAliases}->{$alias} = $value;
1267     $self->{XsubAliasValues}->{$value} = $orig_alias;
1268   }
1269
1270   blurt( $self, "Error: Cannot parse ALIAS definitions from '$orig'")
1271     if $line;
1272 }
1273
1274 sub ATTRS_handler {
1275   my $self = shift;
1276   $_ = shift;
1277
1278   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1279     next unless /\S/;
1280     trim_whitespace($_);
1281     push @{ $self->{Attributes} }, $_;
1282   }
1283 }
1284
1285 sub ALIAS_handler {
1286   my $self = shift;
1287   $_ = shift;
1288
1289   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1290     next unless /\S/;
1291     trim_whitespace($_);
1292     GetAliases($_) if $_;
1293   }
1294 }
1295
1296 sub OVERLOAD_handler {
1297   my $self = shift;
1298   $_ = shift;
1299
1300   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1301     next unless /\S/;
1302     trim_whitespace($_);
1303     while ( s/^\s*([\w:"\\)\+\-\*\/\%\<\>\.\&\|\^\!\~\{\}\=]+)\s*//) {
1304       $self->{Overload} = 1 unless $self->{Overload};
1305       my $overload = "$Package\::(".$1;
1306       push(@{ $self->{InitFileCode} },
1307        "        (void)$self->{newXS}(\"$overload\", XS_$Full_func_name, file$self->{proto});\n");
1308     }
1309   }
1310 }
1311
1312 sub FALLBACK_handler {
1313   my $self = shift;
1314   $_ = shift;
1315
1316   # the rest of the current line should contain either TRUE,
1317   # FALSE or UNDEF
1318
1319   trim_whitespace($_);
1320   my %map = (
1321     TRUE => "&PL_sv_yes", 1 => "&PL_sv_yes",
1322     FALSE => "&PL_sv_no", 0 => "&PL_sv_no",
1323     UNDEF => "&PL_sv_undef",
1324   );
1325
1326   # check for valid FALLBACK value
1327   death( $self, "Error: FALLBACK: TRUE/FALSE/UNDEF") unless exists $map{uc $_};
1328
1329   $self->{Fallback} = $map{uc $_};
1330 }
1331
1332
1333 sub REQUIRE_handler {
1334   my $self = shift;
1335   # the rest of the current line should contain a version number
1336   my $Ver = shift;
1337
1338   trim_whitespace($Ver);
1339
1340   death( $self, "Error: REQUIRE expects a version number")
1341     unless $Ver;
1342
1343   # check that the version number is of the form n.n
1344   death( $self, "Error: REQUIRE: expected a number, got '$Ver'")
1345     unless $Ver =~ /^\d+(\.\d*)?/;
1346
1347   death( $self, "Error: xsubpp $Ver (or better) required--this is only $VERSION.")
1348     unless $VERSION >= $Ver;
1349 }
1350
1351 sub VERSIONCHECK_handler {
1352   my $self = shift;
1353   $_ = shift;
1354
1355   # the rest of the current line should contain either ENABLE or
1356   # DISABLE
1357
1358   trim_whitespace($_);
1359
1360   # check for ENABLE/DISABLE
1361   death( $self, "Error: VERSIONCHECK: ENABLE/DISABLE")
1362     unless /^(ENABLE|DISABLE)/i;
1363
1364   $self->{WantVersionChk} = 1 if $1 eq 'ENABLE';
1365   $self->{WantVersionChk} = 0 if $1 eq 'DISABLE';
1366
1367 }
1368
1369 sub PROTOTYPE_handler {
1370   my $self = shift;
1371   $_ = shift;
1372
1373   my $specified;
1374
1375   death( $self, "Error: Only 1 PROTOTYPE definition allowed per xsub")
1376     if $self->{proto_in_this_xsub}++;
1377
1378   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1379     next unless /\S/;
1380     $specified = 1;
1381     trim_whitespace($_);
1382     if ($_ eq 'DISABLE') {
1383       $self->{ProtoThisXSUB} = 0;
1384     }
1385     elsif ($_ eq 'ENABLE') {
1386       $self->{ProtoThisXSUB} = 1;
1387     }
1388     else {
1389       # remove any whitespace
1390       s/\s+//g;
1391       death( $self, "Error: Invalid prototype '$_'")
1392         unless valid_proto_string($_);
1393       $self->{ProtoThisXSUB} = C_string($_);
1394     }
1395   }
1396
1397   # If no prototype specified, then assume empty prototype ""
1398   $self->{ProtoThisXSUB} = 2 unless $specified;
1399
1400   $self->{ProtoUsed} = 1;
1401 }
1402
1403 sub SCOPE_handler {
1404   my $self = shift;
1405   $_ = shift;
1406
1407   death( $self, "Error: Only 1 SCOPE declaration allowed per xsub")
1408     if $self->{scope_in_this_xsub}++;
1409
1410   trim_whitespace($_);
1411   death("Error: SCOPE: ENABLE/DISABLE")
1412       unless /^(ENABLE|DISABLE)\b/i;
1413   $self->{ScopeThisXSUB} = ( uc($1) eq 'ENABLE' );
1414 }
1415
1416 sub PROTOTYPES_handler {
1417   my $self = shift;
1418   $_ = shift;
1419
1420   # the rest of the current line should contain either ENABLE or
1421   # DISABLE
1422
1423   trim_whitespace($_);
1424
1425   # check for ENABLE/DISABLE
1426   death("Error: PROTOTYPES: ENABLE/DISABLE")
1427     unless /^(ENABLE|DISABLE)/i;
1428
1429   $self->{WantPrototypes} = 1 if $1 eq 'ENABLE';
1430   $self->{WantPrototypes} = 0 if $1 eq 'DISABLE';
1431   $self->{ProtoUsed} = 1;
1432 }
1433
1434 sub PushXSStack {
1435   my $self = shift;
1436   my %args = @_;
1437   # Save the current file context.
1438   push(@{ $self->{XSStack} }, {
1439           type            => 'file',
1440           LastLine        => $self->{lastline},
1441           LastLineNo      => $self->{lastline_no},
1442           Line            => $self->{line},
1443           LineNo          => $self->{line_no},
1444           Filename        => $self->{filename},
1445           Filepathname    => $self->{filepathname},
1446           Handle          => $FH,
1447           IsPipe          => scalar($self->{filename} =~ /\|\s*$/),
1448           %args,
1449          });
1450
1451 }
1452
1453 sub INCLUDE_handler {
1454   my $self = shift;
1455   $_ = shift;
1456   # the rest of the current line should contain a valid filename
1457
1458   trim_whitespace($_);
1459
1460   death( $self, "INCLUDE: filename missing")
1461     unless $_;
1462
1463   death( $self, "INCLUDE: output pipe is illegal")
1464     if /^\s*\|/;
1465
1466   # simple minded recursion detector
1467   death( $self, "INCLUDE loop detected")
1468     if $self->{IncludedFiles}->{$_};
1469
1470   ++$self->{IncludedFiles}->{$_} unless /\|\s*$/;
1471
1472   if (/\|\s*$/ && /^\s*perl\s/) {
1473     Warn( $self, "The INCLUDE directive with a command is discouraged." .
1474           " Use INCLUDE_COMMAND instead! In particular using 'perl'" .
1475           " in an 'INCLUDE: ... |' directive is not guaranteed to pick" .
1476           " up the correct perl. The INCLUDE_COMMAND directive allows" .
1477           " the use of \$^X as the currently running perl, see" .
1478           " 'perldoc perlxs' for details.");
1479   }
1480
1481   $self->PushXSStack();
1482
1483   $FH = Symbol::gensym();
1484
1485   # open the new file
1486   open ($FH, "$_") or death( $self, "Cannot open '$_': $!");
1487
1488   print Q(<<"EOF");
1489 #
1490 #/* INCLUDE:  Including '$_' from '$self->{filename}' */
1491 #
1492 EOF
1493
1494   $self->{filename} = $_;
1495   $self->{filepathname} = File::Spec->catfile($self->{dir}, $self->{filename});
1496
1497   # Prime the pump by reading the first
1498   # non-blank line
1499
1500   # skip leading blank lines
1501   while (<$FH>) {
1502     last unless /^\s*$/;
1503   }
1504
1505   $self->{lastline} = $_;
1506   $self->{lastline_no} = $.;
1507 }
1508
1509 sub QuoteArgs {
1510   my $cmd = shift;
1511   my @args = split /\s+/, $cmd;
1512   $cmd = shift @args;
1513   for (@args) {
1514     $_ = q(").$_.q(") if !/^\"/ && length($_) > 0;
1515   }
1516   return join (' ', ($cmd, @args));
1517 }
1518
1519 sub INCLUDE_COMMAND_handler {
1520   my $self = shift;
1521   $_ = shift;
1522   # the rest of the current line should contain a valid command
1523
1524   trim_whitespace($_);
1525
1526   $_ = QuoteArgs($_) if $^O eq 'VMS';
1527
1528   death( $self, "INCLUDE_COMMAND: command missing")
1529     unless $_;
1530
1531   death( $self, "INCLUDE_COMMAND: pipes are illegal")
1532     if /^\s*\|/ or /\|\s*$/;
1533
1534   $self->PushXSStack( IsPipe => 1 );
1535
1536   $FH = Symbol::gensym();
1537
1538   # If $^X is used in INCLUDE_COMMAND, we know it's supposed to be
1539   # the same perl interpreter as we're currently running
1540   s/^\s*\$\^X/$^X/;
1541
1542   # open the new file
1543   open ($FH, "-|", "$_")
1544     or death( $self, "Cannot run command '$_' to include its output: $!");
1545
1546   print Q(<<"EOF");
1547 #
1548 #/* INCLUDE_COMMAND:  Including output of '$_' from '$self->{filename}' */
1549 #
1550 EOF
1551
1552   $self->{filename} = $_;
1553   $self->{filepathname} = $self->{filename};
1554   $self->{filepathname} =~ s/\"/\\"/g;
1555
1556   # Prime the pump by reading the first
1557   # non-blank line
1558
1559   # skip leading blank lines
1560   while (<$FH>) {
1561     last unless /^\s*$/;
1562   }
1563
1564   $self->{lastline} = $_;
1565   $self->{lastline_no} = $.;
1566 }
1567
1568 sub PopFile {
1569   my $self = shift;
1570
1571   return 0 unless $self->{XSStack}->[-1]{type} eq 'file';
1572
1573   my $data     = pop @{ $self->{XSStack} };
1574   my $ThisFile = $self->{filename};
1575   my $isPipe   = $data->{IsPipe};
1576
1577   --$self->{IncludedFiles}->{$self->{filename}}
1578     unless $isPipe;
1579
1580   close $FH;
1581
1582   $FH         = $data->{Handle};
1583   # $filename is the leafname, which for some reason isused for diagnostic
1584   # messages, whereas $filepathname is the full pathname, and is used for
1585   # #line directives.
1586   $self->{filename}   = $data->{Filename};
1587   $self->{filepathname} = $data->{Filepathname};
1588   $self->{lastline}   = $data->{LastLine};
1589   $self->{lastline_no} = $data->{LastLineNo};
1590   @{ $self->{line} }       = @{ $data->{Line} };
1591   @{ $self->{line_no} }    = @{ $data->{LineNo} };
1592
1593   if ($isPipe and $? ) {
1594     --$self->{lastline_no};
1595     print STDERR "Error reading from pipe '$ThisFile': $! in $self->{filename}, line $self->{lastline_no}\n" ;
1596     exit 1;
1597   }
1598
1599   print Q(<<"EOF");
1600 #
1601 #/* INCLUDE: Returning to '$self->{filename}' from '$ThisFile' */
1602 #
1603 EOF
1604
1605   return 1;
1606 }
1607
1608 sub Q {
1609   my($text) = @_;
1610   $text =~ s/^#//gm;
1611   $text =~ s/\[\[/{/g;
1612   $text =~ s/\]\]/}/g;
1613   $text;
1614 }
1615
1616 # Read next xsub into @{ $self->{line} } from ($lastline, <$FH>).
1617 sub fetch_para {
1618   my $self = shift;
1619
1620   # parse paragraph
1621   death("Error: Unterminated `#if/#ifdef/#ifndef'")
1622     if !defined $self->{lastline} && $self->{XSStack}->[-1]{type} eq 'if';
1623   @{ $self->{line} } = ();
1624   @{ $self->{line_no} } = ();
1625   return $self->PopFile() if !defined $self->{lastline};
1626
1627   if ($self->{lastline} =~
1628       /^MODULE\s*=\s*([\w:]+)(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/) {
1629     my $Module = $1;
1630     $Package = defined($2) ? $2 : ''; # keep -w happy
1631     $self->{Prefix}  = defined($3) ? $3 : ''; # keep -w happy
1632     $self->{Prefix} = quotemeta $self->{Prefix};
1633     ($self->{Module_cname} = $Module) =~ s/\W/_/g;
1634     ($self->{Packid} = $Package) =~ tr/:/_/;
1635     $self->{Packprefix} = $Package;
1636     $self->{Packprefix} .= "::" if $self->{Packprefix} ne "";
1637     $self->{lastline} = "";
1638   }
1639
1640   for (;;) {
1641     # Skip embedded PODs
1642     while ($self->{lastline} =~ /^=/) {
1643       while ($self->{lastline} = <$FH>) {
1644         last if ($self->{lastline} =~ /^=cut\s*$/);
1645       }
1646       death("Error: Unterminated pod") unless $self->{lastline};
1647       $self->{lastline} = <$FH>;
1648       chomp $self->{lastline};
1649       $self->{lastline} =~ s/^\s+$//;
1650     }
1651     if ($self->{lastline} !~ /^\s*#/ ||
1652     # CPP directives:
1653     #    ANSI:    if ifdef ifndef elif else endif define undef
1654     #        line error pragma
1655     #    gcc:    warning include_next
1656     #   obj-c:    import
1657     #   others:    ident (gcc notes that some cpps have this one)
1658     $self->{lastline} =~ /^#[ \t]*(?:(?:if|ifn?def|elif|else|endif|define|undef|pragma|error|warning|line\s+\d+|ident)\b|(?:include(?:_next)?|import)\s*["<].*[>"])/) {
1659       last if $self->{lastline} =~ /^\S/ && @{ $self->{line} } && $self->{line}->[-1] eq "";
1660       push(@{ $self->{line} }, $self->{lastline});
1661       push(@{ $self->{line_no} }, $self->{lastline_no});
1662     }
1663
1664     # Read next line and continuation lines
1665     last unless defined($self->{lastline} = <$FH>);
1666     $self->{lastline_no} = $.;
1667     my $tmp_line;
1668     $self->{lastline} .= $tmp_line
1669       while ($self->{lastline} =~ /\\$/ && defined($tmp_line = <$FH>));
1670
1671     chomp $self->{lastline};
1672     $self->{lastline} =~ s/^\s+$//;
1673   }
1674   pop(@{ $self->{line} }), pop(@{ $self->{line_no} }) while @{ $self->{line} } && $self->{line}->[-1] eq "";
1675   1;
1676 }
1677
1678 sub output_init {
1679   my $argsref = shift;
1680   my ($type, $num, $var, $init, $printed_name) = (
1681     $argsref->{type},
1682     $argsref->{num},
1683     $argsref->{var},
1684     $argsref->{init},
1685     $argsref->{printed_name}
1686   );
1687   my $arg = "ST(" . ($num - 1) . ")";
1688
1689   if (  $init =~ /^=/  ) {
1690     if ($printed_name) {
1691       eval qq/print " $init\\n"/;
1692     }
1693     else {
1694       eval qq/print "\\t$var $init\\n"/;
1695     }
1696     warn $@ if $@;
1697   }
1698   else {
1699     if (  $init =~ s/^\+//  &&  $num  ) {
1700       generate_init( {
1701         type          => $type,
1702         num           => $num,
1703         var           => $var,
1704         printed_name  => $printed_name,
1705       } );
1706     }
1707     elsif ($printed_name) {
1708       print ";\n";
1709       $init =~ s/^;//;
1710     }
1711     else {
1712       eval qq/print "\\t$var;\\n"/;
1713       warn $@ if $@;
1714       $init =~ s/^;//;
1715     }
1716     $self->{deferred} .= eval qq/"\\n\\t$init\\n"/;
1717     warn $@ if $@;
1718   }
1719 }
1720
1721 sub generate_init {
1722   my $argsref = shift;
1723   my ($type, $num, $var, $printed_name) = (
1724     $argsref->{type},
1725     $argsref->{num},
1726     $argsref->{var},
1727     $argsref->{printed_name},
1728   );
1729   my $arg = "ST(" . ($num - 1) . ")";
1730   my ($argoff, $ntype);
1731   $argoff = $num - 1;
1732
1733   my $typemaps = $self->{typemap};
1734
1735   $type = tidy_type($type);
1736   blurt( $self, "Error: '$type' not in typemap"), return
1737     unless $typemaps->get_typemap(ctype => $type);
1738
1739   ($ntype = $type) =~ s/\s*\*/Ptr/g;
1740   my $subtype;
1741   ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1742   my $typem = $typemaps->get_typemap(ctype => $type);
1743   my $xstype = $typem->xstype;
1744   $xstype =~ s/OBJ$/REF/ if $func_name =~ /DESTROY$/;
1745   if ($xstype eq 'T_PV' and exists $self->{lengthof}->{$var}) {
1746     print "\t$var" unless $printed_name;
1747     print " = ($type)SvPV($arg, STRLEN_length_of_$var);\n";
1748     die "default value not supported with length(NAME) supplied"
1749       if defined $self->{defaults}->{$var};
1750     return;
1751   }
1752   $type =~ tr/:/_/ unless $self->{hiertype};
1753
1754   my $inputmap = $typemaps->get_inputmap(xstype => $xstype);
1755   blurt( $self, "Error: No INPUT definition for type '$type', typekind '" . $type->xstype . "' found"), return
1756     unless defined $inputmap;
1757
1758   my $expr = $inputmap->cleaned_code;
1759   # Note: This gruesome bit either needs heavy rethinking or documentation. I vote for the former. --Steffen
1760   if ($expr =~ /DO_ARRAY_ELEM/) {
1761     my $subtypemap  = $typemaps->get_typemap(ctype => $subtype);
1762     my $subinputmap = $typemaps->get_inputmap(xstype => $subtypemap->xstype);
1763     blurt( $self, "Error: '$subtype' not in typemap"), return
1764       unless $subtypemap;
1765     blurt( $self, "Error: No INPUT definition for type '$subtype', typekind '" . $subtypemap->xstype . "' found"), return
1766       unless $subinputmap;
1767     my $subexpr = $subinputmap->cleaned_code;
1768     $subexpr =~ s/\$type/\$subtype/g;
1769     $subexpr =~ s/ntype/subtype/g;
1770     $subexpr =~ s/\$arg/ST(ix_$var)/g;
1771     $subexpr =~ s/\n\t/\n\t\t/g;
1772     $subexpr =~ s/is not of (.*\")/[arg %d] is not of $1, ix_$var + 1/g;
1773     $subexpr =~ s/\$var/${var}[ix_$var - $argoff]/;
1774     $expr =~ s/DO_ARRAY_ELEM/$subexpr/;
1775   }
1776   if ($expr =~ m#/\*.*scope.*\*/#i) {  # "scope" in C comments
1777     $self->{ScopeThisXSUB} = 1;
1778   }
1779   if (defined($self->{defaults}->{$var})) {
1780     $expr =~ s/(\t+)/$1    /g;
1781     $expr =~ s/        /\t/g;
1782     if ($printed_name) {
1783       print ";\n";
1784     }
1785     else {
1786       eval qq/print "\\t$var;\\n"/;
1787       warn $@ if $@;
1788     }
1789     if ($self->{defaults}->{$var} eq 'NO_INIT') {
1790       $self->{deferred} .= eval qq/"\\n\\tif (items >= $num) {\\n$expr;\\n\\t}\\n"/;
1791     }
1792     else {
1793       $self->{deferred} .= eval qq/"\\n\\tif (items < $num)\\n\\t    $var = $self->{defaults}->{$var};\\n\\telse {\\n$expr;\\n\\t}\\n"/;
1794     }
1795     warn $@ if $@;
1796   }
1797   elsif ($self->{ScopeThisXSUB} or $expr !~ /^\s*\$var =/) {
1798     if ($printed_name) {
1799       print ";\n";
1800     }
1801     else {
1802       eval qq/print "\\t$var;\\n"/;
1803       warn $@ if $@;
1804     }
1805     $self->{deferred} .= eval qq/"\\n$expr;\\n"/;
1806     warn $@ if $@;
1807   }
1808   else {
1809     die "panic: do not know how to handle this branch for function pointers"
1810       if $printed_name;
1811     eval qq/print "$expr;\\n"/;
1812     warn $@ if $@;
1813   }
1814 }
1815
1816 sub generate_output {
1817   my $argsref = shift;
1818   my ($type, $num, $var, $do_setmagic, $do_push) = (
1819     $argsref->{type},
1820     $argsref->{num},
1821     $argsref->{var},
1822     $argsref->{do_setmagic},
1823     $argsref->{do_push}
1824   );
1825   my $arg = "ST(" . ($num - ($num != 0)) . ")";
1826   my $ntype;
1827
1828   my $typemaps = $self->{typemap};
1829
1830   $type = tidy_type($type);
1831   if ($type =~ /^array\(([^,]*),(.*)\)/) {
1832     print "\t$arg = sv_newmortal();\n";
1833     print "\tsv_setpvn($arg, (char *)$var, $2 * sizeof($1));\n";
1834     print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1835   }
1836   else {
1837     my $typemap   = $typemaps->get_typemap(ctype => $type);
1838     my $outputmap = $typemaps->get_outputmap(xstype => $typemap->xstype);
1839     blurt( $self, "Error: '$type' not in typemap"), return
1840       unless $typemap;
1841     blurt( $self, "Error: No OUTPUT definition for type '$type', typekind '" . $typemap->xstype . "' found"), return
1842       unless $outputmap;
1843     ($ntype = $type) =~ s/\s*\*/Ptr/g;
1844     $ntype =~ s/\(\)//g;
1845     my $subtype;
1846     ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1847
1848     my $expr = $outputmap->cleaned_code;
1849     if ($expr =~ /DO_ARRAY_ELEM/) {
1850       my $subtypemap   = $typemaps->get_typemap(ctype => $subtype);
1851       my $suboutputmap = $typemaps->get_outputmap(xstype => $subtypemap->xstype);
1852       blurt( $self, "Error: '$subtype' not in typemap"), return
1853         unless $subtypemap;
1854       blurt( $self, "Error: No OUTPUT definition for type '$subtype', typekind '" . $subtypemap->xstype . "' found"), return
1855         unless $suboutputmap;
1856       my $subexpr = $suboutputmap->cleaned_code;
1857       $subexpr =~ s/ntype/subtype/g;
1858       $subexpr =~ s/\$arg/ST(ix_$var)/g;
1859       $subexpr =~ s/\$var/${var}[ix_$var]/g;
1860       $subexpr =~ s/\n\t/\n\t\t/g;
1861       $expr =~ s/DO_ARRAY_ELEM\n/$subexpr/;
1862       eval "print qq\a$expr\a";
1863       warn $@ if $@;
1864       print "\t\tSvSETMAGIC(ST(ix_$var));\n" if $do_setmagic;
1865     }
1866     elsif ($var eq 'RETVAL') {
1867       if ($expr =~ /^\t\$arg = new/) {
1868         # We expect that $arg has refcnt 1, so we need to
1869         # mortalize it.
1870         eval "print qq\a$expr\a";
1871         warn $@ if $@;
1872         print "\tsv_2mortal(ST($num));\n";
1873         print "\tSvSETMAGIC(ST($num));\n" if $do_setmagic;
1874       }
1875       elsif ($expr =~ /^\s*\$arg\s*=/) {
1876         # We expect that $arg has refcnt >=1, so we need
1877         # to mortalize it!
1878         eval "print qq\a$expr\a";
1879         warn $@ if $@;
1880         print "\tsv_2mortal(ST(0));\n";
1881         print "\tSvSETMAGIC(ST(0));\n" if $do_setmagic;
1882       }
1883       else {
1884         # Just hope that the entry would safely write it
1885         # over an already mortalized value. By
1886         # coincidence, something like $arg = &sv_undef
1887         # works too.
1888         print "\tST(0) = sv_newmortal();\n";
1889         eval "print qq\a$expr\a";
1890         warn $@ if $@;
1891         # new mortals don't have set magic
1892       }
1893     }
1894     elsif ($do_push) {
1895       print "\tPUSHs(sv_newmortal());\n";
1896       $arg = "ST($num)";
1897       eval "print qq\a$expr\a";
1898       warn $@ if $@;
1899       print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1900     }
1901     elsif ($arg =~ /^ST\(\d+\)$/) {
1902       eval "print qq\a$expr\a";
1903       warn $@ if $@;
1904       print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1905     }
1906   }
1907 }
1908
1909 1;
1910
1911 # vim: ts=2 sw=2 et: