ccb8feb1452cbc6ddaf3ba2608834d7634d1bc1a
[perl.git] / regen / regcomp.pl
1 #!/usr/bin/perl -w
2
3 # Regenerate (overwriting only if changed):
4 #
5 #    regnodes.h
6 #
7 # from information stored in
8 #
9 #    regcomp.sym
10 #    regexp.h
11 #
12 # Accepts the standard regen_lib -q and -v args.
13 #
14 # This script is normally invoked from regen.pl.
15
16 BEGIN {
17     # Get function prototypes
18     require 'regen/regen_lib.pl';
19 }
20 use strict;
21
22 open DESC, 'regcomp.sym';
23
24 my $ind = 0;
25 my (@name,@rest,@type,@code,@args,@flags,@longj);
26 my ($desc,$lastregop);
27 while (<DESC>) {
28     s/#.*$//;
29     next if /^\s*$/;
30     chomp; # No \z in 5.004
31     s/\s*$//;
32     if (/^-+\s*$/) {
33         $lastregop= $ind;
34         next;
35     }
36     unless ($lastregop) {
37         ($name[$ind], $desc, $rest[$ind]) = /^(\S+)\s+([^\t]+)\s*;\s*(.*)/;
38         ($type[$ind], $code[$ind], $args[$ind], $flags[$ind], $longj[$ind])
39           = split /[,\s]\s*/, $desc;
40         ++$ind;
41     } else {
42         my ($type,@lists)=split /\s+/, $_;
43         die "No list? $type" if !@lists;
44         foreach my $list (@lists) {
45             my ($names,$special)=split /:/, $list , 2;
46             $special ||= "";
47             foreach my $name (split /,/,$names) {
48                 my $real= $name eq 'resume' 
49                         ? "resume_$type" 
50                         : "${type}_$name";
51                 my @suffix;
52                 if (!$special) {
53                    @suffix=("");
54                 } elsif ($special=~/\d/) {
55                     @suffix=(1..$special);
56                 } elsif ($special eq 'FAIL') {
57                     @suffix=("","_fail");
58                 } else {
59                     die "unknown :type ':$special'";
60                 }
61                 foreach my $suffix (@suffix) {
62                     $name[$ind]="$real$suffix";
63                     $type[$ind]=$type;
64                     $rest[$ind]="state for $type";
65                     ++$ind;
66                 }
67             }
68         }
69         
70     }
71 }
72 # use fixed width to keep the diffs between regcomp.pl recompiles
73 # as small as possible.
74 my ($width,$rwidth,$twidth)=(22,12,9);
75 $lastregop ||= $ind;
76 my $tot = $ind;
77 close DESC;
78 die "Too many regexp/state opcodes! Maximum is 256, but there are $lastregop in file!"
79     if $lastregop>256;
80
81 sub process_flags {
82   my ($flag, $varname, $comment) = @_;
83   $comment = '' unless defined $comment;
84
85   $ind = 0;
86   my @selected;
87   my $bitmap = '';
88   do {
89     my $set = $flags[$ind] && $flags[$ind] eq $flag ? 1 : 0;
90     # Whilst I could do this with vec, I'd prefer to do longhand the arithmetic
91     # ops in the C code.
92     my $current = do {
93       local $^W;
94       ord do {
95         substr $bitmap, ($ind >> 3);
96       }
97     };
98     substr($bitmap, ($ind >> 3), 1) = chr($current | ($set << ($ind & 7)));
99
100     push @selected, $name[$ind] if $set;
101   } while (++$ind < $lastregop);
102   my $out_string = join ', ', @selected, 0;
103   $out_string =~ s/(.{1,70},) /$1\n    /g;
104
105   my $out_mask = join ', ', map {sprintf "0x%02X", ord $_} split '', $bitmap;
106
107   return $comment . <<"EOP";
108 #define REGNODE_\U$varname\E(node) (PL_${varname}_bitmask[(node) >> 3] & (1 << ((node) & 7)))
109
110 #ifndef DOINIT
111 EXTCONST U8 PL_${varname}\[] __attribute__deprecated__;
112 #else
113 EXTCONST U8 PL_${varname}\[] __attribute__deprecated__ = {
114     $out_string
115 };
116 #endif /* DOINIT */
117
118 #ifndef DOINIT
119 EXTCONST U8 PL_${varname}_bitmask[];
120 #else
121 EXTCONST U8 PL_${varname}_bitmask[] = {
122     $out_mask
123 };
124 #endif /* DOINIT */
125
126 EOP
127 }
128
129 my $out = safer_open('regnodes.h-new', 'regnodes.h');
130
131 print $out read_only_top(lang => 'C', by => 'regen/regcomp.pl',
132                          from => 'regcomp.sym');
133 printf $out <<EOP,
134 /* Regops and State definitions */
135
136 #define %*s\t%d
137 #define %*s\t%d
138
139 EOP
140     -$width, REGNODE_MAX        => $lastregop - 1,
141     -$width, REGMATCH_STATE_MAX => $tot - 1
142 ;
143
144
145 for ($ind=0; $ind < $lastregop ; ++$ind) {
146   printf $out "#define\t%*s\t%d\t/* %#04x %s */\n",
147     -$width, $name[$ind], $ind, $ind, $rest[$ind];
148 }
149 print $out "\t/* ------------ States ------------- */\n";
150 for ( ; $ind < $tot ; $ind++) {
151   printf $out "#define\t%*s\t(REGNODE_MAX + %d)\t/* %s */\n",
152     -$width, $name[$ind], $ind - $lastregop + 1, $rest[$ind];
153 }
154
155 print $out <<EOP;
156
157 /* PL_regkind[] What type of regop or state is this. */
158
159 #ifndef DOINIT
160 EXTCONST U8 PL_regkind[];
161 #else
162 EXTCONST U8 PL_regkind[] = {
163 EOP
164
165 $ind = 0;
166 do {
167   printf $out "\t%*s\t/* %*s */\n",
168              -1-$twidth, "$type[$ind],", -$width, $name[$ind];
169   print $out "\t/* ------------ States ------------- */\n"
170     if $ind + 1 == $lastregop and $lastregop != $tot;
171 } while (++$ind < $tot);
172
173 print $out <<EOP;
174 };
175 #endif
176
177 /* regarglen[] - How large is the argument part of the node (in regnodes) */
178
179 #ifdef REG_COMP_C
180 static const U8 regarglen[] = {
181 EOP
182
183 $ind = 0;
184 do {
185   my $size = 0;
186   $size = "EXTRA_SIZE(struct regnode_$args[$ind])" if $args[$ind];
187   
188   printf $out "\t%*s\t/* %*s */\n",
189         -37, "$size,",-$rwidth,$name[$ind];
190 } while (++$ind < $lastregop);
191
192 print $out <<EOP;
193 };
194
195 /* reg_off_by_arg[] - Which argument holds the offset to the next node */
196
197 static const char reg_off_by_arg[] = {
198 EOP
199
200 $ind = 0;
201 do {
202   my $size = $longj[$ind] || 0;
203
204   printf $out "\t%d,\t/* %*s */\n",
205         $size, -$rwidth, $name[$ind]
206 } while (++$ind < $lastregop);
207
208 print $out <<EOP;
209 };
210
211 #endif /* REG_COMP_C */
212
213 /* reg_name[] - Opcode/state names in string form, for debugging */
214
215 #ifndef DOINIT
216 EXTCONST char * PL_reg_name[];
217 #else
218 EXTCONST char * const PL_reg_name[] = {
219 EOP
220
221 $ind = 0;
222 my $ofs = 0;
223 my $sym = "";
224 do {
225   my $size = $longj[$ind] || 0;
226
227   printf $out "\t%*s\t/* $sym%#04x */\n",
228         -3-$width,qq("$name[$ind]",), $ind - $ofs;
229   if ($ind + 1 == $lastregop and $lastregop != $tot) {
230     print $out "\t/* ------------ States ------------- */\n";
231     $ofs = $lastregop - 1;
232     $sym = 'REGNODE_MAX +';
233   }
234     
235 } while (++$ind < $tot);
236
237 print $out <<EOP;
238 };
239 #endif /* DOINIT */
240
241 /* PL_reg_extflags_name[] - Opcode/state names in string form, for debugging */
242
243 #ifndef DOINIT
244 EXTCONST char * PL_reg_extflags_name[];
245 #else
246 EXTCONST char * const PL_reg_extflags_name[] = {
247 EOP
248
249 my %rxfv;
250 my %definitions;    # Remember what the symbol definitions are
251 my $val = 0;
252 my %reverse;
253 foreach my $file ("op_reg_common.h", "regexp.h") {
254     open FH,"<$file" or die "Can't read $file: $!";
255     while (<FH>) {
256
257         # optional leading '_'.  Return symbol in $1, and strip it from
258         # rest of line
259         if (s/ \#define \s+ ( _? RXf_ \w+ ) \s+ //xi) {
260             chomp;
261             my $define = $1;
262             s: / \s* \* .*? \* \s* / : :x;    # Replace comments by a blank
263
264             # Replace any prior defined symbols by their values
265             foreach my $key (keys %definitions) {
266                 s/\b$key\b/$definitions{$key}/g;
267             }
268             my $newval = eval $_;   # Get numeric definition
269
270             $definitions{$define} = $newval;
271
272             next unless $_ =~ /<</; # Bit defines use left shift
273             if($val & $newval) {
274                 die sprintf "Both $define and $reverse{$newval} use %08X", $newval;
275             }
276             $val|=$newval;
277             $rxfv{$define}= $newval;
278             $reverse{$newval} = $define;
279         }
280     }
281 }
282 my %vrxf=reverse %rxfv;
283 printf $out "\t/* Bits in extflags defined: %s */\n", unpack 'B*', pack 'N', $val;
284 for (0..31) {
285     my $power_of_2 = 2**$_;
286     my $n=$vrxf{$power_of_2};
287     if (! $n) {
288
289         # Here, there was no name that matched exactly the bit.  It could be
290         # either that it is unused, or the name matches multiple bits.
291         if (! ($val & $power_of_2)) {
292             $n = "UNUSED_BIT_$_";
293         }
294         else {
295
296             # Here, must be because it matches multiple bits.  Look through
297             # all possibilities until find one that matches this one.  Use
298             # that name, and all the bits it matches
299             foreach my $name (keys %rxfv) {
300                 if ($rxfv{$name} & $power_of_2) {
301                     $n = $name;
302                     $power_of_2 = $rxfv{$name};
303                     last;
304                 }
305             }
306         }
307     }
308     $n=~s/^RXf_(PMf_)?//;
309     printf $out qq(\t%-20s/* 0x%08x */\n), 
310         qq("$n",),$power_of_2;
311 }  
312  
313 print $out <<EOP;
314 };
315 #endif /* DOINIT */
316
317 EOP
318
319 print $out process_flags('V', 'varies', <<'EOC');
320 /* The following have no fixed length. U8 so we can do strchr() on it. */
321 EOC
322
323 print $out process_flags('S', 'simple', <<'EOC');
324 /* The following always have a length of 1. U8 we can do strchr() on it. */
325 /* (Note that length 1 means "one character" under UTF8, not "one octet".) */
326 EOC
327
328 print $out <<EOP;
329 /* ex: set ro: */
330 EOP
331 close_and_rename($out);