Update podlators to version 4.03
[perl.git] / cpan / podlators / lib / Pod / Text / Color.pm
1 # Pod::Text::Color -- Convert POD data to formatted color ASCII text
2 #
3 # This is just a basic proof of concept.  It should later be modified to make
4 # better use of color, take options changing what colors are used for what
5 # text, and the like.
6 #
7 # Copyright 1999, 2001, 2004, 2006, 2008, 2009, 2014
8 #     Russ Allbery <rra@cpan.org>
9 #
10 # This program is free software; you may redistribute it and/or modify it
11 # under the same terms as Perl itself.
12
13 ##############################################################################
14 # Modules and declarations
15 ##############################################################################
16
17 package Pod::Text::Color;
18
19 use 5.006;
20 use strict;
21 use warnings;
22
23 use Pod::Text ();
24 use Term::ANSIColor qw(colored);
25
26 use vars qw(@ISA $VERSION);
27
28 @ISA = qw(Pod::Text);
29
30 $VERSION = '4.03';
31
32 ##############################################################################
33 # Overrides
34 ##############################################################################
35
36 # Make level one headings bold.
37 sub cmd_head1 {
38     my ($self, $attrs, $text) = @_;
39     $text =~ s/\s+$//;
40     $self->SUPER::cmd_head1 ($attrs, colored ($text, 'bold'));
41 }
42
43 # Make level two headings bold.
44 sub cmd_head2 {
45     my ($self, $attrs, $text) = @_;
46     $text =~ s/\s+$//;
47     $self->SUPER::cmd_head2 ($attrs, colored ($text, 'bold'));
48 }
49
50 # Fix the various formatting codes.
51 sub cmd_b { return colored ($_[2], 'bold')   }
52 sub cmd_f { return colored ($_[2], 'cyan')   }
53 sub cmd_i { return colored ($_[2], 'yellow') }
54
55 # Output any included code in green.
56 sub output_code {
57     my ($self, $code) = @_;
58     $code = colored ($code, 'green');
59     $self->output ($code);
60 }
61
62 # Strip all of the formatting from a provided string, returning the stripped
63 # version.  We will eventually want to use colorstrip() from Term::ANSIColor,
64 # but it's fairly new so avoid the tight dependency.
65 sub strip_format {
66     my ($self, $text) = @_;
67     $text =~ s/\e\[[\d;]*m//g;
68     return $text;
69 }
70
71 # We unfortunately have to override the wrapping code here, since the normal
72 # wrapping code gets really confused by all the escape sequences.
73 sub wrap {
74     my $self = shift;
75     local $_ = shift;
76     my $output = '';
77     my $spaces = ' ' x $$self{MARGIN};
78     my $width = $$self{opt_width} - $$self{MARGIN};
79
80     # We have to do $shortchar and $longchar in variables because the
81     # construct ${char}{0,$width} didn't do the right thing until Perl 5.8.x.
82     my $char = '(?:(?:\e\[[\d;]+m)*[^\n])';
83     my $shortchar = $char . "{0,$width}";
84     my $longchar = $char . "{$width}";
85     while (length > $width) {
86         if (s/^($shortchar)\s+// || s/^($longchar)//) {
87             $output .= $spaces . $1 . "\n";
88         } else {
89             last;
90         }
91     }
92     $output .= $spaces . $_;
93     $output =~ s/\s+$/\n\n/;
94     $output;
95 }
96
97 ##############################################################################
98 # Module return value and documentation
99 ##############################################################################
100
101 1;
102 __END__
103
104 =head1 NAME
105
106 Pod::Text::Color - Convert POD data to formatted color ASCII text
107
108 =for stopwords
109 Allbery
110
111 =head1 SYNOPSIS
112
113     use Pod::Text::Color;
114     my $parser = Pod::Text::Color->new (sentence => 0, width => 78);
115
116     # Read POD from STDIN and write to STDOUT.
117     $parser->parse_from_filehandle;
118
119     # Read POD from file.pod and write to file.txt.
120     $parser->parse_from_file ('file.pod', 'file.txt');
121
122 =head1 DESCRIPTION
123
124 Pod::Text::Color is a simple subclass of Pod::Text that highlights output
125 text using ANSI color escape sequences.  Apart from the color, it in all
126 ways functions like Pod::Text.  See L<Pod::Text> for details and available
127 options.
128
129 Term::ANSIColor is used to get colors and therefore must be installed to use
130 this module.
131
132 =head1 BUGS
133
134 This is just a basic proof of concept.  It should be seriously expanded to
135 support configurable coloration via options passed to the constructor, and
136 B<pod2text> should be taught about those.
137
138 =head1 SEE ALSO
139
140 L<Pod::Text>, L<Pod::Simple>
141
142 The current version of this module is always available from its web site at
143 L<http://www.eyrie.org/~eagle/software/podlators/>.  It is also part of the
144 Perl core distribution as of 5.6.0.
145
146 =head1 AUTHOR
147
148 Russ Allbery <rra@cpan.org>.
149
150 =head1 COPYRIGHT AND LICENSE
151
152 Copyright 1999, 2001, 2004, 2006, 2008, 2009 Russ Allbery <rra@cpan.org>.
153
154 This program is free software; you may redistribute it and/or modify it
155 under the same terms as Perl itself.
156
157 =cut