Update podlators to version 4.03
[perl.git] / cpan / podlators / lib / Pod / Man.pm
1 # Pod::Man -- Convert POD data to formatted *roff input.
2 #
3 # This module translates POD documentation into *roff markup using the man
4 # macro set, and is intended for converting POD documents written as Unix
5 # manual pages to manual pages that can be read by the man(1) command.  It is
6 # a replacement for the pod2man command distributed with versions of Perl
7 # prior to 5.6.
8 #
9 # Perl core hackers, please note that this module is also separately
10 # maintained outside of the Perl core as part of the podlators.  Please send
11 # me any patches at the address above in addition to sending them to the
12 # standard Perl mailing lists.
13 #
14 # Written by Russ Allbery <rra@cpan.org>
15 # Substantial contributions by Sean Burke <sburke@cpan.org>
16 # Copyright 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009,
17 #     2010, 2012, 2013, 2014, 2015 Russ Allbery <rra@cpan.org>
18 #
19 # This program is free software; you may redistribute it and/or modify it
20 # under the same terms as Perl itself.
21
22 ##############################################################################
23 # Modules and declarations
24 ##############################################################################
25
26 package Pod::Man;
27
28 use 5.006;
29 use strict;
30 use warnings;
31
32 use subs qw(makespace);
33 use vars qw(@ISA %ESCAPES $PREAMBLE $VERSION);
34
35 use Carp qw(croak);
36 use Encode qw(encode);
37 use Pod::Simple ();
38
39 @ISA = qw(Pod::Simple);
40
41 $VERSION = '4.03';
42
43 # Set the debugging level.  If someone has inserted a debug function into this
44 # class already, use that.  Otherwise, use any Pod::Simple debug function
45 # that's defined, and failing that, define a debug level of 10.
46 BEGIN {
47     my $parent = defined (&Pod::Simple::DEBUG) ? \&Pod::Simple::DEBUG : undef;
48     unless (defined &DEBUG) {
49         *DEBUG = $parent || sub () { 10 };
50     }
51 }
52
53 # Import the ASCII constant from Pod::Simple.  This is true iff we're in an
54 # ASCII-based universe (including such things as ISO 8859-1 and UTF-8), and is
55 # generally only false for EBCDIC.
56 BEGIN { *ASCII = \&Pod::Simple::ASCII }
57
58 # Pretty-print a data structure.  Only used for debugging.
59 BEGIN { *pretty = \&Pod::Simple::pretty }
60
61 # Formatting instructions for various types of blocks.  cleanup makes hyphens
62 # hard, adds spaces between consecutive underscores, and escapes backslashes.
63 # convert translates characters into escapes.  guesswork means to apply the
64 # transformations done by the guesswork sub.  literal says to protect literal
65 # quotes from being turned into UTF-8 quotes.  By default, all transformations
66 # are on except literal, but some elements override.
67 #
68 # DEFAULT specifies the default settings.  All other elements should list only
69 # those settings that they are overriding.  Data indicates =for roff blocks,
70 # which should be passed along completely verbatim.
71 #
72 # Formatting inherits negatively, in the sense that if the parent has turned
73 # off guesswork, all child elements should leave it off.
74 my %FORMATTING = (
75     DEFAULT  => { cleanup => 1, convert => 1, guesswork => 1, literal => 0 },
76     Data     => { cleanup => 0, convert => 0, guesswork => 0, literal => 0 },
77     Verbatim => {                             guesswork => 0, literal => 1 },
78     C        => {                             guesswork => 0, literal => 1 },
79     X        => { cleanup => 0,               guesswork => 0               },
80 );
81
82 ##############################################################################
83 # Object initialization
84 ##############################################################################
85
86 # Initialize the object and set various Pod::Simple options that we need.
87 # Here, we also process any additional options passed to the constructor or
88 # set up defaults if none were given.  Note that all internal object keys are
89 # in all-caps, reserving all lower-case object keys for Pod::Simple and user
90 # arguments.
91 sub new {
92     my $class = shift;
93     my $self = $class->SUPER::new;
94
95     # Tell Pod::Simple not to handle S<> by automatically inserting &nbsp;.
96     $self->nbsp_for_S (1);
97
98     # Tell Pod::Simple to keep whitespace whenever possible.
99     if (my $preserve_whitespace = $self->can ('preserve_whitespace')) {
100         $self->$preserve_whitespace (1);
101     } else {
102         $self->fullstop_space_harden (1);
103     }
104
105     # The =for and =begin targets that we accept.
106     $self->accept_targets (qw/man MAN roff ROFF/);
107
108     # Ensure that contiguous blocks of code are merged together.  Otherwise,
109     # some of the guesswork heuristics don't work right.
110     $self->merge_text (1);
111
112     # Pod::Simple doesn't do anything useful with our arguments, but we want
113     # to put them in our object as hash keys and values.  This could cause
114     # problems if we ever clash with Pod::Simple's own internal class
115     # variables.
116     %$self = (%$self, @_);
117
118     # Send errors to stderr if requested.
119     if ($$self{stderr} and not $$self{errors}) {
120         $$self{errors} = 'stderr';
121     }
122     delete $$self{stderr};
123
124     # Validate the errors parameter and act on it.
125     if (not defined $$self{errors}) {
126         $$self{errors} = 'pod';
127     }
128     if ($$self{errors} eq 'stderr' || $$self{errors} eq 'die') {
129         $self->no_errata_section (1);
130         $self->complain_stderr (1);
131         if ($$self{errors} eq 'die') {
132             $$self{complain_die} = 1;
133         }
134     } elsif ($$self{errors} eq 'pod') {
135         $self->no_errata_section (0);
136         $self->complain_stderr (0);
137     } elsif ($$self{errors} eq 'none') {
138         $self->no_whining (1);
139     } else {
140         croak (qq(Invalid errors setting: "$$self{errors}"));
141     }
142     delete $$self{errors};
143
144     # Initialize various other internal constants based on our arguments.
145     $self->init_fonts;
146     $self->init_quotes;
147     $self->init_page;
148
149     # For right now, default to turning on all of the magic.
150     $$self{MAGIC_CPP}       = 1;
151     $$self{MAGIC_EMDASH}    = 1;
152     $$self{MAGIC_FUNC}      = 1;
153     $$self{MAGIC_MANREF}    = 1;
154     $$self{MAGIC_SMALLCAPS} = 1;
155     $$self{MAGIC_VARS}      = 1;
156
157     return $self;
158 }
159
160 # Translate a font string into an escape.
161 sub toescape { (length ($_[0]) > 1 ? '\f(' : '\f') . $_[0] }
162
163 # Determine which fonts the user wishes to use and store them in the object.
164 # Regular, italic, bold, and bold-italic are constants, but the fixed width
165 # fonts may be set by the user.  Sets the internal hash key FONTS which is
166 # used to map our internal font escapes to actual *roff sequences later.
167 sub init_fonts {
168     my ($self) = @_;
169
170     # Figure out the fixed-width font.  If user-supplied, make sure that they
171     # are the right length.
172     for (qw/fixed fixedbold fixeditalic fixedbolditalic/) {
173         my $font = $$self{$_};
174         if (defined ($font) && (length ($font) < 1 || length ($font) > 2)) {
175             croak qq(roff font should be 1 or 2 chars, not "$font");
176         }
177     }
178
179     # Set the default fonts.  We can't be sure portably across different
180     # implementations what fixed bold-italic may be called (if it's even
181     # available), so default to just bold.
182     $$self{fixed}           ||= 'CW';
183     $$self{fixedbold}       ||= 'CB';
184     $$self{fixeditalic}     ||= 'CI';
185     $$self{fixedbolditalic} ||= 'CB';
186
187     # Set up a table of font escapes.  First number is fixed-width, second is
188     # bold, third is italic.
189     $$self{FONTS} = { '000' => '\fR', '001' => '\fI',
190                       '010' => '\fB', '011' => '\f(BI',
191                       '100' => toescape ($$self{fixed}),
192                       '101' => toescape ($$self{fixeditalic}),
193                       '110' => toescape ($$self{fixedbold}),
194                       '111' => toescape ($$self{fixedbolditalic}) };
195 }
196
197 # Initialize the quotes that we'll be using for C<> text.  This requires some
198 # special handling, both to parse the user parameter if given and to make sure
199 # that the quotes will be safe against *roff.  Sets the internal hash keys
200 # LQUOTE and RQUOTE.
201 sub init_quotes {
202     my ($self) = (@_);
203
204     $$self{quotes} ||= '"';
205     if ($$self{quotes} eq 'none') {
206         $$self{LQUOTE} = $$self{RQUOTE} = '';
207     } elsif (length ($$self{quotes}) == 1) {
208         $$self{LQUOTE} = $$self{RQUOTE} = $$self{quotes};
209     } elsif (length ($$self{quotes}) % 2 == 0) {
210         my $length = length ($$self{quotes}) / 2;
211         $$self{LQUOTE} = substr ($$self{quotes}, 0, $length);
212         $$self{RQUOTE} = substr ($$self{quotes}, $length);
213     } else {
214         croak(qq(Invalid quote specification "$$self{quotes}"))
215     }
216
217     # Double the first quote; note that this should not be s///g as two double
218     # quotes is represented in *roff as three double quotes, not four.  Weird,
219     # I know.
220     $$self{LQUOTE} =~ s/\"/\"\"/;
221     $$self{RQUOTE} =~ s/\"/\"\"/;
222 }
223
224 # Initialize the page title information and indentation from our arguments.
225 sub init_page {
226     my ($self) = @_;
227
228     # We used to try first to get the version number from a local binary, but
229     # we shouldn't need that any more.  Get the version from the running Perl.
230     # Work a little magic to handle subversions correctly under both the
231     # pre-5.6 and the post-5.6 version numbering schemes.
232     my @version = ($] =~ /^(\d+)\.(\d{3})(\d{0,3})$/);
233     $version[2] ||= 0;
234     $version[2] *= 10 ** (3 - length $version[2]);
235     for (@version) { $_ += 0 }
236     my $version = join ('.', @version);
237
238     # Set the defaults for page titles and indentation if the user didn't
239     # override anything.
240     $$self{center} = 'User Contributed Perl Documentation'
241         unless defined $$self{center};
242     $$self{release} = 'perl v' . $version
243         unless defined $$self{release};
244     $$self{indent} = 4
245         unless defined $$self{indent};
246
247     # Double quotes in things that will be quoted.
248     for (qw/center release/) {
249         $$self{$_} =~ s/\"/\"\"/g if $$self{$_};
250     }
251 }
252
253 ##############################################################################
254 # Core parsing
255 ##############################################################################
256
257 # This is the glue that connects the code below with Pod::Simple itself.  The
258 # goal is to convert the event stream coming from the POD parser into method
259 # calls to handlers once the complete content of a tag has been seen.  Each
260 # paragraph or POD command will have textual content associated with it, and
261 # as soon as all of a paragraph or POD command has been seen, that content
262 # will be passed in to the corresponding method for handling that type of
263 # object.  The exceptions are handlers for lists, which have opening tag
264 # handlers and closing tag handlers that will be called right away.
265 #
266 # The internal hash key PENDING is used to store the contents of a tag until
267 # all of it has been seen.  It holds a stack of open tags, each one
268 # represented by a tuple of the attributes hash for the tag, formatting
269 # options for the tag (which are inherited), and the contents of the tag.
270
271 # Add a block of text to the contents of the current node, formatting it
272 # according to the current formatting instructions as we do.
273 sub _handle_text {
274     my ($self, $text) = @_;
275     DEBUG > 3 and print "== $text\n";
276     my $tag = $$self{PENDING}[-1];
277     $$tag[2] .= $self->format_text ($$tag[1], $text);
278 }
279
280 # Given an element name, get the corresponding method name.
281 sub method_for_element {
282     my ($self, $element) = @_;
283     $element =~ tr/A-Z-/a-z_/;
284     $element =~ tr/_a-z0-9//cd;
285     return $element;
286 }
287
288 # Handle the start of a new element.  If cmd_element is defined, assume that
289 # we need to collect the entire tree for this element before passing it to the
290 # element method, and create a new tree into which we'll collect blocks of
291 # text and nested elements.  Otherwise, if start_element is defined, call it.
292 sub _handle_element_start {
293     my ($self, $element, $attrs) = @_;
294     DEBUG > 3 and print "++ $element (<", join ('> <', %$attrs), ">)\n";
295     my $method = $self->method_for_element ($element);
296
297     # If we have a command handler, we need to accumulate the contents of the
298     # tag before calling it.  Turn off IN_NAME for any command other than
299     # <Para> and the formatting codes so that IN_NAME isn't still set for the
300     # first heading after the NAME heading.
301     if ($self->can ("cmd_$method")) {
302         DEBUG > 2 and print "<$element> starts saving a tag\n";
303         $$self{IN_NAME} = 0 if ($element ne 'Para' && length ($element) > 1);
304
305         # How we're going to format embedded text blocks depends on the tag
306         # and also depends on our parent tags.  Thankfully, inside tags that
307         # turn off guesswork and reformatting, nothing else can turn it back
308         # on, so this can be strictly inherited.
309         my $formatting = {
310             %{ $$self{PENDING}[-1][1] || $FORMATTING{DEFAULT} },
311             %{ $FORMATTING{$element} || {} },
312         };
313         push (@{ $$self{PENDING} }, [ $attrs, $formatting, '' ]);
314         DEBUG > 4 and print "Pending: [", pretty ($$self{PENDING}), "]\n";
315     } elsif (my $start_method = $self->can ("start_$method")) {
316         $self->$start_method ($attrs, '');
317     } else {
318         DEBUG > 2 and print "No $method start method, skipping\n";
319     }
320 }
321
322 # Handle the end of an element.  If we had a cmd_ method for this element,
323 # this is where we pass along the tree that we built.  Otherwise, if we have
324 # an end_ method for the element, call that.
325 sub _handle_element_end {
326     my ($self, $element) = @_;
327     DEBUG > 3 and print "-- $element\n";
328     my $method = $self->method_for_element ($element);
329
330     # If we have a command handler, pull off the pending text and pass it to
331     # the handler along with the saved attribute hash.
332     if (my $cmd_method = $self->can ("cmd_$method")) {
333         DEBUG > 2 and print "</$element> stops saving a tag\n";
334         my $tag = pop @{ $$self{PENDING} };
335         DEBUG > 4 and print "Popped: [", pretty ($tag), "]\n";
336         DEBUG > 4 and print "Pending: [", pretty ($$self{PENDING}), "]\n";
337         my $text = $self->$cmd_method ($$tag[0], $$tag[2]);
338         if (defined $text) {
339             if (@{ $$self{PENDING} } > 1) {
340                 $$self{PENDING}[-1][2] .= $text;
341             } else {
342                 $self->output ($text);
343             }
344         }
345     } elsif (my $end_method = $self->can ("end_$method")) {
346         $self->$end_method ();
347     } else {
348         DEBUG > 2 and print "No $method end method, skipping\n";
349     }
350 }
351
352 ##############################################################################
353 # General formatting
354 ##############################################################################
355
356 # Format a text block.  Takes a hash of formatting options and the text to
357 # format.  Currently, the only formatting options are guesswork, cleanup, and
358 # convert, all of which are boolean.
359 sub format_text {
360     my ($self, $options, $text) = @_;
361     my $guesswork = $$options{guesswork} && !$$self{IN_NAME};
362     my $cleanup = $$options{cleanup};
363     my $convert = $$options{convert};
364     my $literal = $$options{literal};
365
366     # Cleanup just tidies up a few things, telling *roff that the hyphens are
367     # hard, putting a bit of space between consecutive underscores, and
368     # escaping backslashes.  Be careful not to mangle our character
369     # translations by doing this before processing character translation.
370     if ($cleanup) {
371         $text =~ s/\\/\\e/g;
372         $text =~ s/-/\\-/g;
373         $text =~ s/_(?=_)/_\\|/g;
374     }
375
376     # Normally we do character translation, but we won't even do that in
377     # <Data> blocks or if UTF-8 output is desired.
378     if ($convert && !$$self{utf8} && ASCII) {
379         $text =~ s/([^\x00-\x7F])/$ESCAPES{ord ($1)} || "X"/eg;
380     }
381
382     # Ensure that *roff doesn't convert literal quotes to UTF-8 single quotes,
383     # but don't mess up our accept escapes.
384     if ($literal) {
385         $text =~ s/(?<!\\\*)\'/\\*\(Aq/g;
386         $text =~ s/(?<!\\\*)\`/\\\`/g;
387     }
388
389     # If guesswork is asked for, do that.  This involves more substantial
390     # formatting based on various heuristics that may only be appropriate for
391     # particular documents.
392     if ($guesswork) {
393         $text = $self->guesswork ($text);
394     }
395
396     return $text;
397 }
398
399 # Handles C<> text, deciding whether to put \*C` around it or not.  This is a
400 # whole bunch of messy heuristics to try to avoid overquoting, originally from
401 # Barrie Slaymaker.  This largely duplicates similar code in Pod::Text.
402 sub quote_literal {
403     my $self = shift;
404     local $_ = shift;
405
406     # A regex that matches the portion of a variable reference that's the
407     # array or hash index, separated out just because we want to use it in
408     # several places in the following regex.
409     my $index = '(?: \[.*\] | \{.*\} )?';
410
411     # If in NAME section, just return an ASCII quoted string to avoid
412     # confusing tools like whatis.
413     return qq{"$_"} if $$self{IN_NAME};
414
415     # Check for things that we don't want to quote, and if we find any of
416     # them, return the string with just a font change and no quoting.
417     m{
418       ^\s*
419       (?:
420          ( [\'\`\"] ) .* \1                             # already quoted
421        | \\\*\(Aq .* \\\*\(Aq                           # quoted and escaped
422        | \\?\` .* ( \' | \\\*\(Aq )                     # `quoted'
423        | \$+ [\#^]? \S $index                           # special ($^Foo, $")
424        | [\$\@%&*]+ \#? [:\'\w]+ $index                 # plain var or func
425        | [\$\@%&*]* [:\'\w]+ (?: -> )? \(\s*[^\s,]\s*\) # 0/1-arg func call
426        | [-+]? ( \d[\d.]* | \.\d+ ) (?: [eE][-+]?\d+ )? # a number
427        | 0x [a-fA-F\d]+                                 # a hex constant
428       )
429       \s*\z
430      }xso and return '\f(FS' . $_ . '\f(FE';
431
432     # If we didn't return, go ahead and quote the text.
433     return '\f(FS\*(C`' . $_ . "\\*(C'\\f(FE";
434 }
435
436 # Takes a text block to perform guesswork on.  Returns the text block with
437 # formatting codes added.  This is the code that marks up various Perl
438 # constructs and things commonly used in man pages without requiring the user
439 # to add any explicit markup, and is applied to all non-literal text.  We're
440 # guaranteed that the text we're applying guesswork to does not contain any
441 # *roff formatting codes.  Note that the inserted font sequences must be
442 # treated later with mapfonts or textmapfonts.
443 #
444 # This method is very fragile, both in the regular expressions it uses and in
445 # the ordering of those modifications.  Care and testing is required when
446 # modifying it.
447 sub guesswork {
448     my $self = shift;
449     local $_ = shift;
450     DEBUG > 5 and print "   Guesswork called on [$_]\n";
451
452     # By the time we reach this point, all hyphens will be escaped by adding a
453     # backslash.  We want to undo that escaping if they're part of regular
454     # words and there's only a single dash, since that's a real hyphen that
455     # *roff gets to consider a possible break point.  Make sure that a dash
456     # after the first character of a word stays non-breaking, however.
457     #
458     # Note that this is not user-controllable; we pretty much have to do this
459     # transformation or *roff will mangle the output in unacceptable ways.
460     s{
461         ( (?:\G|^|\s) [\(\"]* [a-zA-Z] ) ( \\- )?
462         ( (?: [a-zA-Z\']+ \\-)+ )
463         ( [a-zA-Z\']+ ) (?= [\)\".?!,;:]* (?:\s|\Z|\\\ ) )
464         \b
465     } {
466         my ($prefix, $hyphen, $main, $suffix) = ($1, $2, $3, $4);
467         $hyphen ||= '';
468         $main =~ s/\\-/-/g;
469         $prefix . $hyphen . $main . $suffix;
470     }egx;
471
472     # Translate "--" into a real em-dash if it's used like one.  This means
473     # that it's either surrounded by whitespace, it follows a regular word, or
474     # it occurs between two regular words.
475     if ($$self{MAGIC_EMDASH}) {
476         s{          (\s) \\-\\- (\s)                } { $1 . '\*(--' . $2 }egx;
477         s{ (\b[a-zA-Z]+) \\-\\- (\s|\Z|[a-zA-Z]+\b) } { $1 . '\*(--' . $2 }egx;
478     }
479
480     # Make words in all-caps a little bit smaller; they look better that way.
481     # However, we don't want to change Perl code (like @ARGV), nor do we want
482     # to fix the MIME in MIME-Version since it looks weird with the
483     # full-height V.
484     #
485     # We change only a string of all caps (2) either at the beginning of the
486     # line or following regular punctuation (like quotes) or whitespace (1),
487     # and followed by either similar punctuation, an em-dash, or the end of
488     # the line (3).
489     #
490     # Allow the text we're changing to small caps to include double quotes,
491     # commas, newlines, and periods as long as it doesn't otherwise interrupt
492     # the string of small caps and still fits the criteria.  This lets us turn
493     # entire warranty disclaimers in man page output into small caps.
494     if ($$self{MAGIC_SMALLCAPS}) {
495         s{
496             ( ^ | [\s\(\"\'\`\[\{<>] | \\[ ]  )                     # (1)
497             ( [A-Z] [A-Z] (?: [/A-Z+:\d_\$&] | \\- | [.,\"\s] )* )  # (2)
498             (?= [\s>\}\]\(\)\'\".?!,;] | \\*\(-- | \\[ ] | $ )      # (3)
499         } {
500             $1 . '\s-1' . $2 . '\s0'
501         }egx;
502     }
503
504     # Note that from this point forward, we have to adjust for \s-1 and \s-0
505     # strings inserted around things that we've made small-caps if later
506     # transforms should work on those strings.
507
508     # Italicize functions in the form func(), including functions that are in
509     # all capitals, but don't italize if there's anything between the parens.
510     # The function must start with an alphabetic character or underscore and
511     # then consist of word characters or colons.
512     if ($$self{MAGIC_FUNC}) {
513         s{
514             ( \b | \\s-1 )
515             ( [A-Za-z_] ([:\w] | \\s-?[01])+ \(\) )
516         } {
517             $1 . '\f(IS' . $2 . '\f(IE'
518         }egx;
519     }
520
521     # Change references to manual pages to put the page name in italics but
522     # the number in the regular font, with a thin space between the name and
523     # the number.  Only recognize func(n) where func starts with an alphabetic
524     # character or underscore and contains only word characters, periods (for
525     # configuration file man pages), or colons, and n is a single digit,
526     # optionally followed by some number of lowercase letters.  Note that this
527     # does not recognize man page references like perl(l) or socket(3SOCKET).
528     if ($$self{MAGIC_MANREF}) {
529         s{
530             ( \b | \\s-1 )
531             ( [A-Za-z_] (?:[.:\w] | \\- | \\s-?[01])+ )
532             ( \( \d [a-z]* \) )
533         } {
534             $1 . '\f(IS' . $2 . '\f(IE\|' . $3
535         }egx;
536     }
537
538     # Convert simple Perl variable references to a fixed-width font.  Be
539     # careful not to convert functions, though; there are too many subtleties
540     # with them to want to perform this transformation.
541     if ($$self{MAGIC_VARS}) {
542         s{
543            ( ^ | \s+ )
544            ( [\$\@%] [\w:]+ )
545            (?! \( )
546         } {
547             $1 . '\f(FS' . $2 . '\f(FE'
548         }egx;
549     }
550
551     # Fix up double quotes.  Unfortunately, we miss this transformation if the
552     # quoted text contains any code with formatting codes and there's not much
553     # we can effectively do about that, which makes it somewhat unclear if
554     # this is really a good idea.
555     s{ \" ([^\"]+) \" } { '\*(L"' . $1 . '\*(R"' }egx;
556
557     # Make C++ into \*(C+, which is a squinched version.
558     if ($$self{MAGIC_CPP}) {
559         s{ \b C\+\+ } {\\*\(C+}gx;
560     }
561
562     # Done.
563     DEBUG > 5 and print "   Guesswork returning [$_]\n";
564     return $_;
565 }
566
567 ##############################################################################
568 # Output
569 ##############################################################################
570
571 # When building up the *roff code, we don't use real *roff fonts.  Instead, we
572 # embed font codes of the form \f(<font>[SE] where <font> is one of B, I, or
573 # F, S stands for start, and E stands for end.  This method turns these into
574 # the right start and end codes.
575 #
576 # We add this level of complexity because the old pod2man didn't get code like
577 # B<someI<thing> else> right; after I<> it switched back to normal text rather
578 # than bold.  We take care of this by using variables that state whether bold,
579 # italic, or fixed are turned on as a combined pointer to our current font
580 # sequence, and set each to the number of current nestings of start tags for
581 # that font.
582 #
583 # \fP changes to the previous font, but only one previous font is kept.  We
584 # don't know what the outside level font is; normally it's R, but if we're
585 # inside a heading it could be something else.  So arrange things so that the
586 # outside font is always the "previous" font and end with \fP instead of \fR.
587 # Idea from Zack Weinberg.
588 sub mapfonts {
589     my ($self, $text) = @_;
590     my ($fixed, $bold, $italic) = (0, 0, 0);
591     my %magic = (F => \$fixed, B => \$bold, I => \$italic);
592     my $last = '\fR';
593     $text =~ s<
594         \\f\((.)(.)
595     > <
596         my $sequence = '';
597         my $f;
598         if ($last ne '\fR') { $sequence = '\fP' }
599         ${ $magic{$1} } += ($2 eq 'S') ? 1 : -1;
600         $f = $$self{FONTS}{ ($fixed && 1) . ($bold && 1) . ($italic && 1) };
601         if ($f eq $last) {
602             '';
603         } else {
604             if ($f ne '\fR') { $sequence .= $f }
605             $last = $f;
606             $sequence;
607         }
608     >gxe;
609     return $text;
610 }
611
612 # Unfortunately, there is a bug in Solaris 2.6 nroff (not present in GNU
613 # groff) where the sequence \fB\fP\f(CW\fP leaves the font set to B rather
614 # than R, presumably because \f(CW doesn't actually do a font change.  To work
615 # around this, use a separate textmapfonts for text blocks where the default
616 # font is always R and only use the smart mapfonts for headings.
617 sub textmapfonts {
618     my ($self, $text) = @_;
619     my ($fixed, $bold, $italic) = (0, 0, 0);
620     my %magic = (F => \$fixed, B => \$bold, I => \$italic);
621     $text =~ s<
622         \\f\((.)(.)
623     > <
624         ${ $magic{$1} } += ($2 eq 'S') ? 1 : -1;
625         $$self{FONTS}{ ($fixed && 1) . ($bold && 1) . ($italic && 1) };
626     >gxe;
627     return $text;
628 }
629
630 # Given a command and a single argument that may or may not contain double
631 # quotes, handle double-quote formatting for it.  If there are no double
632 # quotes, just return the command followed by the argument in double quotes.
633 # If there are double quotes, use an if statement to test for nroff, and for
634 # nroff output the command followed by the argument in double quotes with
635 # embedded double quotes doubled.  For other formatters, remap paired double
636 # quotes to LQUOTE and RQUOTE.
637 sub switchquotes {
638     my ($self, $command, $text, $extra) = @_;
639     $text =~ s/\\\*\([LR]\"/\"/g;
640
641     # We also have to deal with \*C` and \*C', which are used to add the
642     # quotes around C<> text, since they may expand to " and if they do this
643     # confuses the .SH macros and the like no end.  Expand them ourselves.
644     # Also separate troff from nroff if there are any fixed-width fonts in use
645     # to work around problems with Solaris nroff.
646     my $c_is_quote = ($$self{LQUOTE} =~ /\"/) || ($$self{RQUOTE} =~ /\"/);
647     my $fixedpat = join '|', @{ $$self{FONTS} }{'100', '101', '110', '111'};
648     $fixedpat =~ s/\\/\\\\/g;
649     $fixedpat =~ s/\(/\\\(/g;
650     if ($text =~ m/\"/ || $text =~ m/$fixedpat/) {
651         $text =~ s/\"/\"\"/g;
652         my $nroff = $text;
653         my $troff = $text;
654         $troff =~ s/\"\"([^\"]*)\"\"/\`\`$1\'\'/g;
655         if ($c_is_quote and $text =~ m/\\\*\(C[\'\`]/) {
656             $nroff =~ s/\\\*\(C\`/$$self{LQUOTE}/g;
657             $nroff =~ s/\\\*\(C\'/$$self{RQUOTE}/g;
658             $troff =~ s/\\\*\(C[\'\`]//g;
659         }
660         $nroff = qq("$nroff") . ($extra ? " $extra" : '');
661         $troff = qq("$troff") . ($extra ? " $extra" : '');
662
663         # Work around the Solaris nroff bug where \f(CW\fP leaves the font set
664         # to Roman rather than the actual previous font when used in headings.
665         # troff output may still be broken, but at least we can fix nroff by
666         # just switching the font changes to the non-fixed versions.
667         $nroff =~ s/\Q$$self{FONTS}{100}\E(.*?)\\f[PR]/$1/g;
668         $nroff =~ s/\Q$$self{FONTS}{101}\E(.*?)\\f([PR])/\\fI$1\\f$2/g;
669         $nroff =~ s/\Q$$self{FONTS}{110}\E(.*?)\\f([PR])/\\fB$1\\f$2/g;
670         $nroff =~ s/\Q$$self{FONTS}{111}\E(.*?)\\f([PR])/\\f\(BI$1\\f$2/g;
671
672         # Now finally output the command.  Bother with .ie only if the nroff
673         # and troff output aren't the same.
674         if ($nroff ne $troff) {
675             return ".ie n $command $nroff\n.el $command $troff\n";
676         } else {
677             return "$command $nroff\n";
678         }
679     } else {
680         $text = qq("$text") . ($extra ? " $extra" : '');
681         return "$command $text\n";
682     }
683 }
684
685 # Protect leading quotes and periods against interpretation as commands.  Also
686 # protect anything starting with a backslash, since it could expand or hide
687 # something that *roff would interpret as a command.  This is overkill, but
688 # it's much simpler than trying to parse *roff here.
689 sub protect {
690     my ($self, $text) = @_;
691     $text =~ s/^([.\'\\])/\\&$1/mg;
692     return $text;
693 }
694
695 # Make vertical whitespace if NEEDSPACE is set, appropriate to the indentation
696 # level the situation.  This function is needed since in *roff one has to
697 # create vertical whitespace after paragraphs and between some things, but
698 # other macros create their own whitespace.  Also close out a sequence of
699 # repeated =items, since calling makespace means we're about to begin the item
700 # body.
701 sub makespace {
702     my ($self) = @_;
703     $self->output (".PD\n") if $$self{ITEMS} > 1;
704     $$self{ITEMS} = 0;
705     $self->output ($$self{INDENT} > 0 ? ".Sp\n" : ".PP\n")
706         if $$self{NEEDSPACE};
707 }
708
709 # Output any pending index entries, and optionally an index entry given as an
710 # argument.  Support multiple index entries in X<> separated by slashes, and
711 # strip special escapes from index entries.
712 sub outindex {
713     my ($self, $section, $index) = @_;
714     my @entries = map { split m%\s*/\s*% } @{ $$self{INDEX} };
715     return unless ($section || @entries);
716
717     # We're about to output all pending entries, so clear our pending queue.
718     $$self{INDEX} = [];
719
720     # Build the output.  Regular index entries are marked Xref, and headings
721     # pass in their own section.  Undo some *roff formatting on headings.
722     my @output;
723     if (@entries) {
724         push @output, [ 'Xref', join (' ', @entries) ];
725     }
726     if ($section) {
727         $index =~ s/\\-/-/g;
728         $index =~ s/\\(?:s-?\d|.\(..|.)//g;
729         push @output, [ $section, $index ];
730     }
731
732     # Print out the .IX commands.
733     for (@output) {
734         my ($type, $entry) = @$_;
735         $entry =~ s/\s+/ /g;
736         $entry =~ s/\"/\"\"/g;
737         $entry =~ s/\\/\\\\/g;
738         $self->output (".IX $type " . '"' . $entry . '"' . "\n");
739     }
740 }
741
742 # Output some text, without any additional changes.
743 sub output {
744     my ($self, @text) = @_;
745     if ($$self{ENCODE}) {
746         print { $$self{output_fh} } encode ('UTF-8', join ('', @text));
747     } else {
748         print { $$self{output_fh} } @text;
749     }
750 }
751
752 ##############################################################################
753 # Document initialization
754 ##############################################################################
755
756 # Handle the start of the document.  Here we handle empty documents, as well
757 # as setting up our basic macros in a preamble and building the page title.
758 sub start_document {
759     my ($self, $attrs) = @_;
760     if ($$attrs{contentless} && !$$self{ALWAYS_EMIT_SOMETHING}) {
761         DEBUG and print "Document is contentless\n";
762         $$self{CONTENTLESS} = 1;
763     } else {
764         delete $$self{CONTENTLESS};
765     }
766
767     # When UTF-8 output is set, check whether our output file handle already
768     # has a PerlIO encoding layer set.  If it does not, we'll need to encode
769     # our output before printing it (handled in the output() sub).  Wrap the
770     # check in an eval to handle versions of Perl without PerlIO.
771     $$self{ENCODE} = 0;
772     if ($$self{utf8}) {
773         $$self{ENCODE} = 1;
774         eval {
775             my @options = (output => 1, details => 1);
776             my $flag = (PerlIO::get_layers ($$self{output_fh}, @options))[-1];
777             if ($flag & PerlIO::F_UTF8 ()) {
778                 $$self{ENCODE} = 0;
779             }
780         }
781     }
782
783     # Determine information for the preamble and then output it unless the
784     # document was content-free.
785     if (!$$self{CONTENTLESS}) {
786         my ($name, $section);
787         if (defined $$self{name}) {
788             $name = $$self{name};
789             $section = $$self{section} || 1;
790         } else {
791             ($name, $section) = $self->devise_title;
792         }
793         my $date = defined($$self{date}) ? $$self{date} : $self->devise_date;
794         $self->preamble ($name, $section, $date)
795             unless $self->bare_output or DEBUG > 9;
796     }
797
798     # Initialize a few per-document variables.
799     $$self{INDENT}    = 0;      # Current indentation level.
800     $$self{INDENTS}   = [];     # Stack of indentations.
801     $$self{INDEX}     = [];     # Index keys waiting to be printed.
802     $$self{IN_NAME}   = 0;      # Whether processing the NAME section.
803     $$self{ITEMS}     = 0;      # The number of consecutive =items.
804     $$self{ITEMTYPES} = [];     # Stack of =item types, one per list.
805     $$self{SHIFTWAIT} = 0;      # Whether there is a shift waiting.
806     $$self{SHIFTS}    = [];     # Stack of .RS shifts.
807     $$self{PENDING}   = [[]];   # Pending output.
808 }
809
810 # Handle the end of the document.  This handles dying on POD errors, since
811 # Pod::Parser currently doesn't.  Otherwise, does nothing but print out a
812 # final comment at the end of the document under debugging.
813 sub end_document {
814     my ($self) = @_;
815     if ($$self{complain_die} && $self->errors_seen) {
816         croak ("POD document had syntax errors");
817     }
818     return if $self->bare_output;
819     return if ($$self{CONTENTLESS} && !$$self{ALWAYS_EMIT_SOMETHING});
820     $self->output (q(.\" [End document]) . "\n") if DEBUG;
821 }
822
823 # Try to figure out the name and section from the file name and return them as
824 # a list, returning an empty name and section 1 if we can't find any better
825 # information.  Uses File::Basename and File::Spec as necessary.
826 sub devise_title {
827     my ($self) = @_;
828     my $name = $self->source_filename || '';
829     my $section = $$self{section} || 1;
830     $section = 3 if (!$$self{section} && $name =~ /\.pm\z/i);
831     $name =~ s/\.p(od|[lm])\z//i;
832
833     # If Pod::Parser gave us an IO::File reference as the source file name,
834     # convert that to the empty string as well.  Then, if we don't have a
835     # valid name, emit a warning and convert it to STDIN.
836     if ($name =~ /^IO::File(?:=\w+)\(0x[\da-f]+\)$/i) {
837         $name = '';
838     }
839     if ($name eq '') {
840         $self->whine (1, 'No name given for document');
841         $name = 'STDIN';
842     }
843
844     # If the section isn't 3, then the name defaults to just the basename of
845     # the file.  Otherwise, assume we're dealing with a module.  We want to
846     # figure out the full module name from the path to the file, but we don't
847     # want to include too much of the path into the module name.  Lose
848     # anything up to the first off:
849     #
850     #     */lib/*perl*/         standard or site_perl module
851     #     */*perl*/lib/         from -Dprefix=/opt/perl
852     #     */*perl*/             random module hierarchy
853     #
854     # which works.  Also strip off a leading site, site_perl, or vendor_perl
855     # component, any OS-specific component, and any version number component,
856     # and strip off an initial component of "lib" or "blib/lib" since that's
857     # what ExtUtils::MakeMaker creates.  splitdir requires at least File::Spec
858     # 0.8.
859     if ($section !~ /^3/) {
860         require File::Basename;
861         $name = uc File::Basename::basename ($name);
862     } else {
863         require File::Spec;
864         my ($volume, $dirs, $file) = File::Spec->splitpath ($name);
865         my @dirs = File::Spec->splitdir ($dirs);
866         my $cut = 0;
867         my $i;
868         for ($i = 0; $i < @dirs; $i++) {
869             if ($dirs[$i] =~ /perl/) {
870                 $cut = $i + 1;
871                 $cut++ if ($dirs[$i + 1] && $dirs[$i + 1] eq 'lib');
872                 last;
873             }
874         }
875         if ($cut > 0) {
876             splice (@dirs, 0, $cut);
877             shift @dirs if ($dirs[0] =~ /^(site|vendor)(_perl)?$/);
878             shift @dirs if ($dirs[0] =~ /^[\d.]+$/);
879             shift @dirs if ($dirs[0] =~ /^(.*-$^O|$^O-.*|$^O)$/);
880         }
881         shift @dirs if $dirs[0] eq 'lib';
882         splice (@dirs, 0, 2) if ($dirs[0] eq 'blib' && $dirs[1] eq 'lib');
883
884         # Remove empty directories when building the module name; they
885         # occur too easily on Unix by doubling slashes.
886         $name = join ('::', (grep { $_ ? $_ : () } @dirs), $file);
887     }
888     return ($name, $section);
889 }
890
891 # Determine the modification date and return that, properly formatted in ISO
892 # format.
893 #
894 # If POD_MAN_DATE is set, that overrides anything else.  This can be used for
895 # reproducible generation of the same file even if the input file timestamps
896 # are unpredictable or the POD coms from standard input.
897 #
898 # Otherwise, if SOURCE_DATE_EPOCH is set and can be parsed as seconds since
899 # the UNIX epoch, base the timestamp on that.  See
900 # <https://reproducible-builds.org/specs/source-date-epoch/>
901 #
902 # Otherwise, use the modification date of the input if we can stat it.  Be
903 # aware that Pod::Simple returns the stringification of the file handle as
904 # source_filename for input from a file handle, so we'll stat some random ref
905 # string in that case.  If that fails, instead use the current time.
906 #
907 # $self - Pod::Man object, used to get the source file
908 #
909 # Returns: YYYY-MM-DD date suitable for the left-hand footer
910 sub devise_date {
911     my ($self) = @_;
912
913     # If POD_MAN_DATE is set, always use it.
914     if (defined($ENV{POD_MAN_DATE})) {
915         return $ENV{POD_MAN_DATE};
916     }
917
918     # If SOURCE_DATE_EPOCH is set and can be parsed, use that.
919     my $time;
920     if (defined($ENV{SOURCE_DATE_EPOCH}) && $ENV{SOURCE_DATE_EPOCH} !~ /\D/) {
921         $time = $ENV{SOURCE_DATE_EPOCH};
922     }
923
924     # Otherwise, get the input filename and try to stat it.  If that fails,
925     # use the current time.
926     if (!defined $time) {
927         my $input = $self->source_filename;
928         if ($input) {
929             $time = (stat($input))[9] || time();
930         } else {
931             $time = time();
932         }
933     }
934
935     # Can't use POSIX::strftime(), which uses Fcntl, because MakeMaker uses
936     # this and it has to work in the core which can't load dynamic libraries.
937     # Use gmtime instead of localtime so that the generated man page does not
938     # depend on the local time zone setting and is more reproducible
939     my ($year, $month, $day) = (gmtime($time))[5,4,3];
940     return sprintf("%04d-%02d-%02d", $year + 1900, $month + 1, $day);
941 }
942
943 # Print out the preamble and the title.  The meaning of the arguments to .TH
944 # unfortunately vary by system; some systems consider the fourth argument to
945 # be a "source" and others use it as a version number.  Generally it's just
946 # presented as the left-side footer, though, so it doesn't matter too much if
947 # a particular system gives it another interpretation.
948 #
949 # The order of date and release used to be reversed in older versions of this
950 # module, but this order is correct for both Solaris and Linux.
951 sub preamble {
952     my ($self, $name, $section, $date) = @_;
953     my $preamble = $self->preamble_template (!$$self{utf8});
954
955     # Build the index line and make sure that it will be syntactically valid.
956     my $index = "$name $section";
957     $index =~ s/\"/\"\"/g;
958
959     # If name or section contain spaces, quote them (section really never
960     # should, but we may as well be cautious).
961     for ($name, $section) {
962         if (/\s/) {
963             s/\"/\"\"/g;
964             $_ = '"' . $_ . '"';
965         }
966     }
967
968     # Double quotes in date, since it will be quoted.
969     $date =~ s/\"/\"\"/g;
970
971     # Substitute into the preamble the configuration options.
972     $preamble =~ s/\@CFONT\@/$$self{fixed}/;
973     $preamble =~ s/\@LQUOTE\@/$$self{LQUOTE}/;
974     $preamble =~ s/\@RQUOTE\@/$$self{RQUOTE}/;
975     chomp $preamble;
976
977     # Get the version information.
978     my $version = $self->version_report;
979
980     # Finally output everything.
981     $self->output (<<"----END OF HEADER----");
982 .\\" Automatically generated by $version
983 .\\"
984 .\\" Standard preamble:
985 .\\" ========================================================================
986 $preamble
987 .\\" ========================================================================
988 .\\"
989 .IX Title "$index"
990 .TH $name $section "$date" "$$self{release}" "$$self{center}"
991 .\\" For nroff, turn off justification.  Always turn off hyphenation; it makes
992 .\\" way too many mistakes in technical documents.
993 .if n .ad l
994 .nh
995 ----END OF HEADER----
996     $self->output (".\\\" [End of preamble]\n") if DEBUG;
997 }
998
999 ##############################################################################
1000 # Text blocks
1001 ##############################################################################
1002
1003 # Handle a basic block of text.  The only tricky part of this is if this is
1004 # the first paragraph of text after an =over, in which case we have to change
1005 # indentations for *roff.
1006 sub cmd_para {
1007     my ($self, $attrs, $text) = @_;
1008     my $line = $$attrs{start_line};
1009
1010     # Output the paragraph.  We also have to handle =over without =item.  If
1011     # there's an =over without =item, SHIFTWAIT will be set, and we need to
1012     # handle creation of the indent here.  Add the shift to SHIFTS so that it
1013     # will be cleaned up on =back.
1014     $self->makespace;
1015     if ($$self{SHIFTWAIT}) {
1016         $self->output (".RS $$self{INDENT}\n");
1017         push (@{ $$self{SHIFTS} }, $$self{INDENT});
1018         $$self{SHIFTWAIT} = 0;
1019     }
1020
1021     # Add the line number for debugging, but not in the NAME section just in
1022     # case the comment would confuse apropos.
1023     $self->output (".\\\" [At source line $line]\n")
1024         if defined ($line) && DEBUG && !$$self{IN_NAME};
1025
1026     # Force exactly one newline at the end and strip unwanted trailing
1027     # whitespace at the end, but leave "\ " backslashed space from an S< > at
1028     # the end of a line.  Reverse the text first, to avoid having to scan the
1029     # entire paragraph.
1030     $text = reverse $text;
1031     $text =~ s/\A\s*?(?= \\|\S|\z)/\n/;
1032     $text = reverse $text;
1033
1034     # Output the paragraph.
1035     $self->output ($self->protect ($self->textmapfonts ($text)));
1036     $self->outindex;
1037     $$self{NEEDSPACE} = 1;
1038     return '';
1039 }
1040
1041 # Handle a verbatim paragraph.  Put a null token at the beginning of each line
1042 # to protect against commands and wrap in .Vb/.Ve (which we define in our
1043 # prelude).
1044 sub cmd_verbatim {
1045     my ($self, $attrs, $text) = @_;
1046
1047     # Ignore an empty verbatim paragraph.
1048     return unless $text =~ /\S/;
1049
1050     # Force exactly one newline at the end and strip unwanted trailing
1051     # whitespace at the end.  Reverse the text first, to avoid having to scan
1052     # the entire paragraph.
1053     $text = reverse $text;
1054     $text =~ s/\A\s*/\n/;
1055     $text = reverse $text;
1056
1057     # Get a count of the number of lines before the first blank line, which
1058     # we'll pass to .Vb as its parameter.  This tells *roff to keep that many
1059     # lines together.  We don't want to tell *roff to keep huge blocks
1060     # together.
1061     my @lines = split (/\n/, $text);
1062     my $unbroken = 0;
1063     for (@lines) {
1064         last if /^\s*$/;
1065         $unbroken++;
1066     }
1067     $unbroken = 10 if ($unbroken > 12 && !$$self{MAGIC_VNOPAGEBREAK_LIMIT});
1068
1069     # Prepend a null token to each line.
1070     $text =~ s/^/\\&/gm;
1071
1072     # Output the results.
1073     $self->makespace;
1074     $self->output (".Vb $unbroken\n$text.Ve\n");
1075     $$self{NEEDSPACE} = 1;
1076     return '';
1077 }
1078
1079 # Handle literal text (produced by =for and similar constructs).  Just output
1080 # it with the minimum of changes.
1081 sub cmd_data {
1082     my ($self, $attrs, $text) = @_;
1083     $text =~ s/^\n+//;
1084     $text =~ s/\n{0,2}$/\n/;
1085     $self->output ($text);
1086     return '';
1087 }
1088
1089 ##############################################################################
1090 # Headings
1091 ##############################################################################
1092
1093 # Common code for all headings.  This is called before the actual heading is
1094 # output.  It returns the cleaned up heading text (putting the heading all on
1095 # one line) and may do other things, like closing bad =item blocks.
1096 sub heading_common {
1097     my ($self, $text, $line) = @_;
1098     $text =~ s/\s+$//;
1099     $text =~ s/\s*\n\s*/ /g;
1100
1101     # This should never happen; it means that we have a heading after =item
1102     # without an intervening =back.  But just in case, handle it anyway.
1103     if ($$self{ITEMS} > 1) {
1104         $$self{ITEMS} = 0;
1105         $self->output (".PD\n");
1106     }
1107
1108     # Output the current source line.
1109     $self->output ( ".\\\" [At source line $line]\n" )
1110         if defined ($line) && DEBUG;
1111     return $text;
1112 }
1113
1114 # First level heading.  We can't output .IX in the NAME section due to a bug
1115 # in some versions of catman, so don't output a .IX for that section.  .SH
1116 # already uses small caps, so remove \s0 and \s-1.  Maintain IN_NAME as
1117 # appropriate.
1118 sub cmd_head1 {
1119     my ($self, $attrs, $text) = @_;
1120     $text =~ s/\\s-?\d//g;
1121     $text = $self->heading_common ($text, $$attrs{start_line});
1122     my $isname = ($text eq 'NAME' || $text =~ /\(NAME\)/);
1123     $self->output ($self->switchquotes ('.SH', $self->mapfonts ($text)));
1124     $self->outindex ('Header', $text) unless $isname;
1125     $$self{NEEDSPACE} = 0;
1126     $$self{IN_NAME} = $isname;
1127     return '';
1128 }
1129
1130 # Second level heading.
1131 sub cmd_head2 {
1132     my ($self, $attrs, $text) = @_;
1133     $text = $self->heading_common ($text, $$attrs{start_line});
1134     $self->output ($self->switchquotes ('.SS', $self->mapfonts ($text)));
1135     $self->outindex ('Subsection', $text);
1136     $$self{NEEDSPACE} = 0;
1137     return '';
1138 }
1139
1140 # Third level heading.  *roff doesn't have this concept, so just put the
1141 # heading in italics as a normal paragraph.
1142 sub cmd_head3 {
1143     my ($self, $attrs, $text) = @_;
1144     $text = $self->heading_common ($text, $$attrs{start_line});
1145     $self->makespace;
1146     $self->output ($self->textmapfonts ('\f(IS' . $text . '\f(IE') . "\n");
1147     $self->outindex ('Subsection', $text);
1148     $$self{NEEDSPACE} = 1;
1149     return '';
1150 }
1151
1152 # Fourth level heading.  *roff doesn't have this concept, so just put the
1153 # heading as a normal paragraph.
1154 sub cmd_head4 {
1155     my ($self, $attrs, $text) = @_;
1156     $text = $self->heading_common ($text, $$attrs{start_line});
1157     $self->makespace;
1158     $self->output ($self->textmapfonts ($text) . "\n");
1159     $self->outindex ('Subsection', $text);
1160     $$self{NEEDSPACE} = 1;
1161     return '';
1162 }
1163
1164 ##############################################################################
1165 # Formatting codes
1166 ##############################################################################
1167
1168 # All of the formatting codes that aren't handled internally by the parser,
1169 # other than L<> and X<>.
1170 sub cmd_b { return $_[0]->{IN_NAME} ? $_[2] : '\f(BS' . $_[2] . '\f(BE' }
1171 sub cmd_i { return $_[0]->{IN_NAME} ? $_[2] : '\f(IS' . $_[2] . '\f(IE' }
1172 sub cmd_f { return $_[0]->{IN_NAME} ? $_[2] : '\f(IS' . $_[2] . '\f(IE' }
1173 sub cmd_c { return $_[0]->quote_literal ($_[2]) }
1174
1175 # Index entries are just added to the pending entries.
1176 sub cmd_x {
1177     my ($self, $attrs, $text) = @_;
1178     push (@{ $$self{INDEX} }, $text);
1179     return '';
1180 }
1181
1182 # Links reduce to the text that we're given, wrapped in angle brackets if it's
1183 # a URL, followed by the URL.  We take an option to suppress the URL if anchor
1184 # text is given.  We need to format the "to" value of the link before
1185 # comparing it to the text since we may escape hyphens.
1186 sub cmd_l {
1187     my ($self, $attrs, $text) = @_;
1188     if ($$attrs{type} eq 'url') {
1189         my $to = $$attrs{to};
1190         if (defined $to) {
1191             my $tag = $$self{PENDING}[-1];
1192             $to = $self->format_text ($$tag[1], $to);
1193         }
1194         if (not defined ($to) or $to eq $text) {
1195             return "<$text>";
1196         } elsif ($$self{nourls}) {
1197             return $text;
1198         } else {
1199             return "$text <$$attrs{to}>";
1200         }
1201     } else {
1202         return $text;
1203     }
1204 }
1205
1206 ##############################################################################
1207 # List handling
1208 ##############################################################################
1209
1210 # Handle the beginning of an =over block.  Takes the type of the block as the
1211 # first argument, and then the attr hash.  This is called by the handlers for
1212 # the four different types of lists (bullet, number, text, and block).
1213 sub over_common_start {
1214     my ($self, $type, $attrs) = @_;
1215     my $line = $$attrs{start_line};
1216     my $indent = $$attrs{indent};
1217     DEBUG > 3 and print " Starting =over $type (line $line, indent ",
1218         ($indent || '?'), "\n";
1219
1220     # Find the indentation level.
1221     unless (defined ($indent) && $indent =~ /^[-+]?\d{1,4}\s*$/) {
1222         $indent = $$self{indent};
1223     }
1224
1225     # If we've gotten multiple indentations in a row, we need to emit the
1226     # pending indentation for the last level that we saw and haven't acted on
1227     # yet.  SHIFTS is the stack of indentations that we've actually emitted
1228     # code for.
1229     if (@{ $$self{SHIFTS} } < @{ $$self{INDENTS} }) {
1230         $self->output (".RS $$self{INDENT}\n");
1231         push (@{ $$self{SHIFTS} }, $$self{INDENT});
1232     }
1233
1234     # Now, do record-keeping.  INDENTS is a stack of indentations that we've
1235     # seen so far, and INDENT is the current level of indentation.  ITEMTYPES
1236     # is a stack of list types that we've seen.
1237     push (@{ $$self{INDENTS} }, $$self{INDENT});
1238     push (@{ $$self{ITEMTYPES} }, $type);
1239     $$self{INDENT} = $indent + 0;
1240     $$self{SHIFTWAIT} = 1;
1241 }
1242
1243 # End an =over block.  Takes no options other than the class pointer.
1244 # Normally, once we close a block and therefore remove something from INDENTS,
1245 # INDENTS will now be longer than SHIFTS, indicating that we also need to emit
1246 # *roff code to close the indent.  This isn't *always* true, depending on the
1247 # circumstance.  If we're still inside an indentation, we need to emit another
1248 # .RE and then a new .RS to unconfuse *roff.
1249 sub over_common_end {
1250     my ($self) = @_;
1251     DEBUG > 3 and print " Ending =over\n";
1252     $$self{INDENT} = pop @{ $$self{INDENTS} };
1253     pop @{ $$self{ITEMTYPES} };
1254
1255     # If we emitted code for that indentation, end it.
1256     if (@{ $$self{SHIFTS} } > @{ $$self{INDENTS} }) {
1257         $self->output (".RE\n");
1258         pop @{ $$self{SHIFTS} };
1259     }
1260
1261     # If we're still in an indentation, *roff will have now lost track of the
1262     # right depth of that indentation, so fix that.
1263     if (@{ $$self{INDENTS} } > 0) {
1264         $self->output (".RE\n");
1265         $self->output (".RS $$self{INDENT}\n");
1266     }
1267     $$self{NEEDSPACE} = 1;
1268     $$self{SHIFTWAIT} = 0;
1269 }
1270
1271 # Dispatch the start and end calls as appropriate.
1272 sub start_over_bullet { my $s = shift; $s->over_common_start ('bullet', @_) }
1273 sub start_over_number { my $s = shift; $s->over_common_start ('number', @_) }
1274 sub start_over_text   { my $s = shift; $s->over_common_start ('text',   @_) }
1275 sub start_over_block  { my $s = shift; $s->over_common_start ('block',  @_) }
1276 sub end_over_bullet { $_[0]->over_common_end }
1277 sub end_over_number { $_[0]->over_common_end }
1278 sub end_over_text   { $_[0]->over_common_end }
1279 sub end_over_block  { $_[0]->over_common_end }
1280
1281 # The common handler for all item commands.  Takes the type of the item, the
1282 # attributes, and then the text of the item.
1283 #
1284 # Emit an index entry for anything that's interesting, but don't emit index
1285 # entries for things like bullets and numbers.  Newlines in an item title are
1286 # turned into spaces since *roff can't handle them embedded.
1287 sub item_common {
1288     my ($self, $type, $attrs, $text) = @_;
1289     my $line = $$attrs{start_line};
1290     DEBUG > 3 and print "  $type item (line $line): $text\n";
1291
1292     # Clean up the text.  We want to end up with two variables, one ($text)
1293     # which contains any body text after taking out the item portion, and
1294     # another ($item) which contains the actual item text.
1295     $text =~ s/\s+$//;
1296     my ($item, $index);
1297     if ($type eq 'bullet') {
1298         $item = "\\\(bu";
1299         $text =~ s/\n*$/\n/;
1300     } elsif ($type eq 'number') {
1301         $item = $$attrs{number} . '.';
1302     } else {
1303         $item = $text;
1304         $item =~ s/\s*\n\s*/ /g;
1305         $text = '';
1306         $index = $item if ($item =~ /\w/);
1307     }
1308
1309     # Take care of the indentation.  If shifts and indents are equal, close
1310     # the top shift, since we're about to create an indentation with .IP.
1311     # Also output .PD 0 to turn off spacing between items if this item is
1312     # directly following another one.  We only have to do that once for a
1313     # whole chain of items so do it for the second item in the change.  Note
1314     # that makespace is what undoes this.
1315     if (@{ $$self{SHIFTS} } == @{ $$self{INDENTS} }) {
1316         $self->output (".RE\n");
1317         pop @{ $$self{SHIFTS} };
1318     }
1319     $self->output (".PD 0\n") if ($$self{ITEMS} == 1);
1320
1321     # Now, output the item tag itself.
1322     $item = $self->textmapfonts ($item);
1323     $self->output ($self->switchquotes ('.IP', $item, $$self{INDENT}));
1324     $$self{NEEDSPACE} = 0;
1325     $$self{ITEMS}++;
1326     $$self{SHIFTWAIT} = 0;
1327
1328     # If body text for this item was included, go ahead and output that now.
1329     if ($text) {
1330         $text =~ s/\s*$/\n/;
1331         $self->makespace;
1332         $self->output ($self->protect ($self->textmapfonts ($text)));
1333         $$self{NEEDSPACE} = 1;
1334     }
1335     $self->outindex ($index ? ('Item', $index) : ());
1336 }
1337
1338 # Dispatch the item commands to the appropriate place.
1339 sub cmd_item_bullet { my $self = shift; $self->item_common ('bullet', @_) }
1340 sub cmd_item_number { my $self = shift; $self->item_common ('number', @_) }
1341 sub cmd_item_text   { my $self = shift; $self->item_common ('text',   @_) }
1342 sub cmd_item_block  { my $self = shift; $self->item_common ('block',  @_) }
1343
1344 ##############################################################################
1345 # Backward compatibility
1346 ##############################################################################
1347
1348 # Reset the underlying Pod::Simple object between calls to parse_from_file so
1349 # that the same object can be reused to convert multiple pages.
1350 sub parse_from_file {
1351     my $self = shift;
1352     $self->reinit;
1353
1354     # Fake the old cutting option to Pod::Parser.  This fiddings with internal
1355     # Pod::Simple state and is quite ugly; we need a better approach.
1356     if (ref ($_[0]) eq 'HASH') {
1357         my $opts = shift @_;
1358         if (defined ($$opts{-cutting}) && !$$opts{-cutting}) {
1359             $$self{in_pod} = 1;
1360             $$self{last_was_blank} = 1;
1361         }
1362     }
1363
1364     # Do the work.
1365     my $retval = $self->SUPER::parse_from_file (@_);
1366
1367     # Flush output, since Pod::Simple doesn't do this.  Ideally we should also
1368     # close the file descriptor if we had to open one, but we can't easily
1369     # figure this out.
1370     my $fh = $self->output_fh ();
1371     my $oldfh = select $fh;
1372     my $oldflush = $|;
1373     $| = 1;
1374     print $fh '';
1375     $| = $oldflush;
1376     select $oldfh;
1377     return $retval;
1378 }
1379
1380 # Pod::Simple failed to provide this backward compatibility function, so
1381 # implement it ourselves.  File handles are one of the inputs that
1382 # parse_from_file supports.
1383 sub parse_from_filehandle {
1384     my $self = shift;
1385     return $self->parse_from_file (@_);
1386 }
1387
1388 # Pod::Simple's parse_file doesn't set output_fh.  Wrap the call and do so
1389 # ourself unless it was already set by the caller, since our documentation has
1390 # always said that this should work.
1391 sub parse_file {
1392     my ($self, $in) = @_;
1393     unless (defined $$self{output_fh}) {
1394         $self->output_fh (\*STDOUT);
1395     }
1396     return $self->SUPER::parse_file ($in);
1397 }
1398
1399 # Do the same for parse_lines, just to be polite.  Pod::Simple's man page
1400 # implies that the caller is responsible for setting this, but I don't see any
1401 # reason not to set a default.
1402 sub parse_lines {
1403     my ($self, @lines) = @_;
1404     unless (defined $$self{output_fh}) {
1405         $self->output_fh (\*STDOUT);
1406     }
1407     return $self->SUPER::parse_lines (@lines);
1408 }
1409
1410 # Likewise for parse_string_document.
1411 sub parse_string_document {
1412     my ($self, $doc) = @_;
1413     unless (defined $$self{output_fh}) {
1414         $self->output_fh (\*STDOUT);
1415     }
1416     return $self->SUPER::parse_string_document ($doc);
1417 }
1418
1419 ##############################################################################
1420 # Translation tables
1421 ##############################################################################
1422
1423 # The following table is adapted from Tom Christiansen's pod2man.  It assumes
1424 # that the standard preamble has already been printed, since that's what
1425 # defines all of the accent marks.  We really want to do something better than
1426 # this when *roff actually supports other character sets itself, since these
1427 # results are pretty poor.
1428 #
1429 # This only works in an ASCII world.  What to do in a non-ASCII world is very
1430 # unclear -- hopefully we can assume UTF-8 and just leave well enough alone.
1431 @ESCAPES{0xA0 .. 0xFF} = (
1432     "\\ ", undef, undef, undef,            undef, undef, undef, undef,
1433     undef, undef, undef, undef,            undef, "\\%", undef, undef,
1434
1435     undef, undef, undef, undef,            undef, undef, undef, undef,
1436     undef, undef, undef, undef,            undef, undef, undef, undef,
1437
1438     "A\\*`",  "A\\*'", "A\\*^", "A\\*~",   "A\\*:", "A\\*o", "\\*(Ae", "C\\*,",
1439     "E\\*`",  "E\\*'", "E\\*^", "E\\*:",   "I\\*`", "I\\*'", "I\\*^",  "I\\*:",
1440
1441     "\\*(D-", "N\\*~", "O\\*`", "O\\*'",   "O\\*^", "O\\*~", "O\\*:",  undef,
1442     "O\\*/",  "U\\*`", "U\\*'", "U\\*^",   "U\\*:", "Y\\*'", "\\*(Th", "\\*8",
1443
1444     "a\\*`",  "a\\*'", "a\\*^", "a\\*~",   "a\\*:", "a\\*o", "\\*(ae", "c\\*,",
1445     "e\\*`",  "e\\*'", "e\\*^", "e\\*:",   "i\\*`", "i\\*'", "i\\*^",  "i\\*:",
1446
1447     "\\*(d-", "n\\*~", "o\\*`", "o\\*'",   "o\\*^", "o\\*~", "o\\*:",  undef,
1448     "o\\*/" , "u\\*`", "u\\*'", "u\\*^",   "u\\*:", "y\\*'", "\\*(th", "y\\*:",
1449 ) if ASCII;
1450
1451 ##############################################################################
1452 # Premable
1453 ##############################################################################
1454
1455 # The following is the static preamble which starts all *roff output we
1456 # generate.  Most is static except for the font to use as a fixed-width font,
1457 # which is designed by @CFONT@, and the left and right quotes to use for C<>
1458 # text, designated by @LQOUTE@ and @RQUOTE@.  However, the second part, which
1459 # defines the accent marks, is only used if $escapes is set to true.
1460 sub preamble_template {
1461     my ($self, $accents) = @_;
1462     my $preamble = <<'----END OF PREAMBLE----';
1463 .de Sp \" Vertical space (when we can't use .PP)
1464 .if t .sp .5v
1465 .if n .sp
1466 ..
1467 .de Vb \" Begin verbatim text
1468 .ft @CFONT@
1469 .nf
1470 .ne \\$1
1471 ..
1472 .de Ve \" End verbatim text
1473 .ft R
1474 .fi
1475 ..
1476 .\" Set up some character translations and predefined strings.  \*(-- will
1477 .\" give an unbreakable dash, \*(PI will give pi, \*(L" will give a left
1478 .\" double quote, and \*(R" will give a right double quote.  \*(C+ will
1479 .\" give a nicer C++.  Capital omega is used to do unbreakable dashes and
1480 .\" therefore won't be available.  \*(C` and \*(C' expand to `' in nroff,
1481 .\" nothing in troff, for use with C<>.
1482 .tr \(*W-
1483 .ds C+ C\v'-.1v'\h'-1p'\s-2+\h'-1p'+\s0\v'.1v'\h'-1p'
1484 .ie n \{\
1485 .    ds -- \(*W-
1486 .    ds PI pi
1487 .    if (\n(.H=4u)&(1m=24u) .ds -- \(*W\h'-12u'\(*W\h'-12u'-\" diablo 10 pitch
1488 .    if (\n(.H=4u)&(1m=20u) .ds -- \(*W\h'-12u'\(*W\h'-8u'-\"  diablo 12 pitch
1489 .    ds L" ""
1490 .    ds R" ""
1491 .    ds C` @LQUOTE@
1492 .    ds C' @RQUOTE@
1493 'br\}
1494 .el\{\
1495 .    ds -- \|\(em\|
1496 .    ds PI \(*p
1497 .    ds L" ``
1498 .    ds R" ''
1499 .    ds C`
1500 .    ds C'
1501 'br\}
1502 .\"
1503 .\" Escape single quotes in literal strings from groff's Unicode transform.
1504 .ie \n(.g .ds Aq \(aq
1505 .el       .ds Aq '
1506 .\"
1507 .\" If the F register is >0, we'll generate index entries on stderr for
1508 .\" titles (.TH), headers (.SH), subsections (.SS), items (.Ip), and index
1509 .\" entries marked with X<> in POD.  Of course, you'll have to process the
1510 .\" output yourself in some meaningful fashion.
1511 .\"
1512 .\" Avoid warning from groff about undefined register 'F'.
1513 .de IX
1514 ..
1515 .if !\nF .nr F 0
1516 .if \nF>0 \{\
1517 .    de IX
1518 .    tm Index:\\$1\t\\n%\t"\\$2"
1519 ..
1520 .    if !\nF==2 \{\
1521 .        nr % 0
1522 .        nr F 2
1523 .    \}
1524 .\}
1525 ----END OF PREAMBLE----
1526 #'# for cperl-mode
1527
1528     if ($accents) {
1529         $preamble .= <<'----END OF PREAMBLE----'
1530 .\"
1531 .\" Accent mark definitions (@(#)ms.acc 1.5 88/02/08 SMI; from UCB 4.2).
1532 .\" Fear.  Run.  Save yourself.  No user-serviceable parts.
1533 .    \" fudge factors for nroff and troff
1534 .if n \{\
1535 .    ds #H 0
1536 .    ds #V .8m
1537 .    ds #F .3m
1538 .    ds #[ \f1
1539 .    ds #] \fP
1540 .\}
1541 .if t \{\
1542 .    ds #H ((1u-(\\\\n(.fu%2u))*.13m)
1543 .    ds #V .6m
1544 .    ds #F 0
1545 .    ds #[ \&
1546 .    ds #] \&
1547 .\}
1548 .    \" simple accents for nroff and troff
1549 .if n \{\
1550 .    ds ' \&
1551 .    ds ` \&
1552 .    ds ^ \&
1553 .    ds , \&
1554 .    ds ~ ~
1555 .    ds /
1556 .\}
1557 .if t \{\
1558 .    ds ' \\k:\h'-(\\n(.wu*8/10-\*(#H)'\'\h"|\\n:u"
1559 .    ds ` \\k:\h'-(\\n(.wu*8/10-\*(#H)'\`\h'|\\n:u'
1560 .    ds ^ \\k:\h'-(\\n(.wu*10/11-\*(#H)'^\h'|\\n:u'
1561 .    ds , \\k:\h'-(\\n(.wu*8/10)',\h'|\\n:u'
1562 .    ds ~ \\k:\h'-(\\n(.wu-\*(#H-.1m)'~\h'|\\n:u'
1563 .    ds / \\k:\h'-(\\n(.wu*8/10-\*(#H)'\z\(sl\h'|\\n:u'
1564 .\}
1565 .    \" troff and (daisy-wheel) nroff accents
1566 .ds : \\k:\h'-(\\n(.wu*8/10-\*(#H+.1m+\*(#F)'\v'-\*(#V'\z.\h'.2m+\*(#F'.\h'|\\n:u'\v'\*(#V'
1567 .ds 8 \h'\*(#H'\(*b\h'-\*(#H'
1568 .ds o \\k:\h'-(\\n(.wu+\w'\(de'u-\*(#H)/2u'\v'-.3n'\*(#[\z\(de\v'.3n'\h'|\\n:u'\*(#]
1569 .ds d- \h'\*(#H'\(pd\h'-\w'~'u'\v'-.25m'\f2\(hy\fP\v'.25m'\h'-\*(#H'
1570 .ds D- D\\k:\h'-\w'D'u'\v'-.11m'\z\(hy\v'.11m'\h'|\\n:u'
1571 .ds th \*(#[\v'.3m'\s+1I\s-1\v'-.3m'\h'-(\w'I'u*2/3)'\s-1o\s+1\*(#]
1572 .ds Th \*(#[\s+2I\s-2\h'-\w'I'u*3/5'\v'-.3m'o\v'.3m'\*(#]
1573 .ds ae a\h'-(\w'a'u*4/10)'e
1574 .ds Ae A\h'-(\w'A'u*4/10)'E
1575 .    \" corrections for vroff
1576 .if v .ds ~ \\k:\h'-(\\n(.wu*9/10-\*(#H)'\s-2\u~\d\s+2\h'|\\n:u'
1577 .if v .ds ^ \\k:\h'-(\\n(.wu*10/11-\*(#H)'\v'-.4m'^\v'.4m'\h'|\\n:u'
1578 .    \" for low resolution devices (crt and lpr)
1579 .if \n(.H>23 .if \n(.V>19 \
1580 \{\
1581 .    ds : e
1582 .    ds 8 ss
1583 .    ds o a
1584 .    ds d- d\h'-1'\(ga
1585 .    ds D- D\h'-1'\(hy
1586 .    ds th \o'bp'
1587 .    ds Th \o'LP'
1588 .    ds ae ae
1589 .    ds Ae AE
1590 .\}
1591 .rm #[ #] #H #V #F C
1592 ----END OF PREAMBLE----
1593 #`# for cperl-mode
1594     }
1595     return $preamble;
1596 }
1597
1598 ##############################################################################
1599 # Module return value and documentation
1600 ##############################################################################
1601
1602 1;
1603 __END__
1604
1605 =for stopwords
1606 en em ALLCAPS teeny fixedbold fixeditalic fixedbolditalic stderr utf8
1607 UTF-8 Allbery Sean Burke Ossanna Solaris formatters troff uppercased
1608 Christiansen nourls parsers Kernighan
1609
1610 =head1 NAME
1611
1612 Pod::Man - Convert POD data to formatted *roff input
1613
1614 =head1 SYNOPSIS
1615
1616     use Pod::Man;
1617     my $parser = Pod::Man->new (release => $VERSION, section => 8);
1618
1619     # Read POD from STDIN and write to STDOUT.
1620     $parser->parse_file (\*STDIN);
1621
1622     # Read POD from file.pod and write to file.1.
1623     $parser->parse_from_file ('file.pod', 'file.1');
1624
1625 =head1 DESCRIPTION
1626
1627 Pod::Man is a module to convert documentation in the POD format (the
1628 preferred language for documenting Perl) into *roff input using the man
1629 macro set.  The resulting *roff code is suitable for display on a terminal
1630 using L<nroff(1)>, normally via L<man(1)>, or printing using L<troff(1)>.
1631 It is conventionally invoked using the driver script B<pod2man>, but it can
1632 also be used directly.
1633
1634 As a derived class from Pod::Simple, Pod::Man supports the same methods and
1635 interfaces.  See L<Pod::Simple> for all the details.
1636
1637 new() can take options, in the form of key/value pairs that control the
1638 behavior of the parser.  See below for details.
1639
1640 If no options are given, Pod::Man uses the name of the input file with any
1641 trailing C<.pod>, C<.pm>, or C<.pl> stripped as the man page title, to
1642 section 1 unless the file ended in C<.pm> in which case it defaults to
1643 section 3, to a centered title of "User Contributed Perl Documentation", to
1644 a centered footer of the Perl version it is run with, and to a left-hand
1645 footer of the modification date of its input (or the current date if given
1646 C<STDIN> for input).
1647
1648 Pod::Man assumes that your *roff formatters have a fixed-width font named
1649 C<CW>.  If yours is called something else (like C<CR>), use the C<fixed>
1650 option to specify it.  This generally only matters for troff output for
1651 printing.  Similarly, you can set the fonts used for bold, italic, and
1652 bold italic fixed-width output.
1653
1654 Besides the obvious pod conversions, Pod::Man also takes care of
1655 formatting func(), func(3), and simple variable references like $foo or
1656 @bar so you don't have to use code escapes for them; complex expressions
1657 like C<$fred{'stuff'}> will still need to be escaped, though.  It also
1658 translates dashes that aren't used as hyphens into en dashes, makes long
1659 dashes--like this--into proper em dashes, fixes "paired quotes," makes C++
1660 look right, puts a little space between double underscores, makes ALLCAPS
1661 a teeny bit smaller in B<troff>, and escapes stuff that *roff treats as
1662 special so that you don't have to.
1663
1664 The recognized options to new() are as follows.  All options take a single
1665 argument.
1666
1667 =over 4
1668
1669 =item center
1670
1671 Sets the centered page header for the C<.TH> macro.  The default, if this
1672 option is not specified, is "User Contributed Perl Documentation".
1673
1674 =item date
1675
1676 Sets the left-hand footer for the C<.TH> macro.  If this option is not set,
1677 the contents of the environment variable POD_MAN_DATE, if set, will be used.
1678 Failing that, the value of SOURCE_DATE_EPOCH, the modification date of the
1679 input file, or the current time if stat() can't find that file (which will be
1680 the case if the input is from C<STDIN>) will be used.  If obtained from the
1681 file modification date or the current time, the date will be formatted as
1682 C<YYYY-MM-DD> and will be based on UTC (so that the output will be
1683 reproducible regardless of local time zone).
1684
1685 =item errors
1686
1687 How to report errors.  C<die> says to throw an exception on any POD
1688 formatting error.  C<stderr> says to report errors on standard error, but
1689 not to throw an exception.  C<pod> says to include a POD ERRORS section
1690 in the resulting documentation summarizing the errors.  C<none> ignores
1691 POD errors entirely, as much as possible.
1692
1693 The default is C<pod>.
1694
1695 =item fixed
1696
1697 The fixed-width font to use for verbatim text and code.  Defaults to
1698 C<CW>.  Some systems may want C<CR> instead.  Only matters for B<troff>
1699 output.
1700
1701 =item fixedbold
1702
1703 Bold version of the fixed-width font.  Defaults to C<CB>.  Only matters
1704 for B<troff> output.
1705
1706 =item fixeditalic
1707
1708 Italic version of the fixed-width font (actually, something of a misnomer,
1709 since most fixed-width fonts only have an oblique version, not an italic
1710 version).  Defaults to C<CI>.  Only matters for B<troff> output.
1711
1712 =item fixedbolditalic
1713
1714 Bold italic (probably actually oblique) version of the fixed-width font.
1715 Pod::Man doesn't assume you have this, and defaults to C<CB>.  Some
1716 systems (such as Solaris) have this font available as C<CX>.  Only matters
1717 for B<troff> output.
1718
1719 =item name
1720
1721 Set the name of the manual page for the C<.TH> macro.  Without this
1722 option, the manual name is set to the uppercased base name of the file
1723 being converted unless the manual section is 3, in which case the path is
1724 parsed to see if it is a Perl module path.  If it is, a path like
1725 C<.../lib/Pod/Man.pm> is converted into a name like C<Pod::Man>.  This
1726 option, if given, overrides any automatic determination of the name.
1727
1728 If generating a manual page from standard input, this option is required,
1729 since there's otherwise no way for Pod::Man to know what to use for the
1730 manual page name.
1731
1732 =item nourls
1733
1734 Normally, LZ<><> formatting codes with a URL but anchor text are formatted
1735 to show both the anchor text and the URL.  In other words:
1736
1737     L<foo|http://example.com/>
1738
1739 is formatted as:
1740
1741     foo <http://example.com/>
1742
1743 This option, if set to a true value, suppresses the URL when anchor text
1744 is given, so this example would be formatted as just C<foo>.  This can
1745 produce less cluttered output in cases where the URLs are not particularly
1746 important.
1747
1748 =item quotes
1749
1750 Sets the quote marks used to surround CE<lt>> text.  If the value is a
1751 single character, it is used as both the left and right quote.  Otherwise,
1752 it is split in half, and the first half of the string is used as the left
1753 quote and the second is used as the right quote.
1754
1755 This may also be set to the special value C<none>, in which case no quote
1756 marks are added around CE<lt>> text (but the font is still changed for troff
1757 output).
1758
1759 =item release
1760
1761 Set the centered footer for the C<.TH> macro.  By default, this is set to
1762 the version of Perl you run Pod::Man under.  Setting this to the empty
1763 string will cause some *roff implementations to use the system default
1764 value.
1765
1766 Note that some system C<an> macro sets assume that the centered footer
1767 will be a modification date and will prepend something like "Last
1768 modified: ".  If this is the case for your target system, you may want to
1769 set C<release> to the last modified date and C<date> to the version
1770 number.
1771
1772 =item section
1773
1774 Set the section for the C<.TH> macro.  The standard section numbering
1775 convention is to use 1 for user commands, 2 for system calls, 3 for
1776 functions, 4 for devices, 5 for file formats, 6 for games, 7 for
1777 miscellaneous information, and 8 for administrator commands.  There is a lot
1778 of variation here, however; some systems (like Solaris) use 4 for file
1779 formats, 5 for miscellaneous information, and 7 for devices.  Still others
1780 use 1m instead of 8, or some mix of both.  About the only section numbers
1781 that are reliably consistent are 1, 2, and 3.
1782
1783 By default, section 1 will be used unless the file ends in C<.pm> in which
1784 case section 3 will be selected.
1785
1786 =item stderr
1787
1788 Send error messages about invalid POD to standard error instead of
1789 appending a POD ERRORS section to the generated *roff output.  This is
1790 equivalent to setting C<errors> to C<stderr> if C<errors> is not already
1791 set.  It is supported for backward compatibility.
1792
1793 =item utf8
1794
1795 By default, Pod::Man produces the most conservative possible *roff output
1796 to try to ensure that it will work with as many different *roff
1797 implementations as possible.  Many *roff implementations cannot handle
1798 non-ASCII characters, so this means all non-ASCII characters are converted
1799 either to a *roff escape sequence that tries to create a properly accented
1800 character (at least for troff output) or to C<X>.
1801
1802 If this option is set, Pod::Man will instead output UTF-8.  If your *roff
1803 implementation can handle it, this is the best output format to use and
1804 avoids corruption of documents containing non-ASCII characters.  However,
1805 be warned that *roff source with literal UTF-8 characters is not supported
1806 by many implementations and may even result in segfaults and other bad
1807 behavior.
1808
1809 Be aware that, when using this option, the input encoding of your POD
1810 source should be properly declared unless it's US-ASCII.  Pod::Simple will
1811 attempt to guess the encoding and may be successful if it's Latin-1 or
1812 UTF-8, but it will produce warnings.  Use the C<=encoding> command to
1813 declare the encoding.  See L<perlpod(1)> for more information.
1814
1815 =back
1816
1817 The standard Pod::Simple method parse_file() takes one argument naming the
1818 POD file to read from.  By default, the output is sent to C<STDOUT>, but
1819 this can be changed with the output_fh() method.
1820
1821 The standard Pod::Simple method parse_from_file() takes up to two
1822 arguments, the first being the input file to read POD from and the second
1823 being the file to write the formatted output to.
1824
1825 You can also call parse_lines() to parse an array of lines or
1826 parse_string_document() to parse a document already in memory.  As with
1827 parse_file(), parse_lines() and parse_string_document() default to sending
1828 their output to C<STDOUT> unless changed with the output_fh() method.
1829
1830 To put the output from any parse method into a string instead of a file
1831 handle, call the output_string() method instead of output_fh().
1832
1833 See L<Pod::Simple> for more specific details on the methods available to
1834 all derived parsers.
1835
1836 =head1 DIAGNOSTICS
1837
1838 =over 4
1839
1840 =item roff font should be 1 or 2 chars, not "%s"
1841
1842 (F) You specified a *roff font (using C<fixed>, C<fixedbold>, etc.) that
1843 wasn't either one or two characters.  Pod::Man doesn't support *roff fonts
1844 longer than two characters, although some *roff extensions do (the
1845 canonical versions of B<nroff> and B<troff> don't either).
1846
1847 =item Invalid errors setting "%s"
1848
1849 (F) The C<errors> parameter to the constructor was set to an unknown value.
1850
1851 =item Invalid quote specification "%s"
1852
1853 (F) The quote specification given (the C<quotes> option to the
1854 constructor) was invalid.  A quote specification must be either one
1855 character long or an even number (greater than one) characters long.
1856
1857 =item POD document had syntax errors
1858
1859 (F) The POD document being formatted had syntax errors and the C<errors>
1860 option was set to C<die>.
1861
1862 =back
1863
1864 =head1 ENVIRONMENT
1865
1866 =over 4
1867
1868 =item POD_MAN_DATE
1869
1870 If set, this will be used as the value of the left-hand footer unless the
1871 C<date> option is explicitly set, overriding the timestamp of the input
1872 file or the current time.  This is primarily useful to ensure reproducible
1873 builds of the same output file given the same source and Pod::Man version,
1874 even when file timestamps may not be consistent.
1875
1876 =item SOURCE_DATE_EPOCH
1877
1878 If set, and POD_MAN_DATE and the C<date> options are not set, this will be
1879 used as the modification time of the source file, overriding the timestamp of
1880 the input file or the current time.  It should be set to the desired time in
1881 seconds since UNIX epoch.  This is primarily useful to ensure reproducible
1882 builds of the same output file given the same source and Pod::Man version,
1883 even when file timestamps may not be consistent.  See
1884 L<https://reproducible-builds.org/specs/source-date-epoch/> for the full
1885 specification.
1886
1887 (Arguably, according to the specification, this variable should be used only
1888 if the timestamp of the input file is not available and Pod::Man uses the
1889 current time.  However, for reproducible builds in Debian, results were more
1890 reliable if this variable overrode the timestamp of the input file.)
1891
1892 =back
1893
1894 =head1 BUGS
1895
1896 Encoding handling assumes that PerlIO is available and does not work
1897 properly if it isn't.  The C<utf8> option is therefore not supported
1898 unless Perl is built with PerlIO support.
1899
1900 There is currently no way to turn off the guesswork that tries to format
1901 unmarked text appropriately, and sometimes it isn't wanted (particularly
1902 when using POD to document something other than Perl).  Most of the work
1903 toward fixing this has now been done, however, and all that's still needed
1904 is a user interface.
1905
1906 The NAME section should be recognized specially and index entries emitted
1907 for everything in that section.  This would have to be deferred until the
1908 next section, since extraneous things in NAME tends to confuse various man
1909 page processors.  Currently, no index entries are emitted for anything in
1910 NAME.
1911
1912 Pod::Man doesn't handle font names longer than two characters.  Neither do
1913 most B<troff> implementations, but GNU troff does as an extension.  It would
1914 be nice to support as an option for those who want to use it.
1915
1916 The preamble added to each output file is rather verbose, and most of it
1917 is only necessary in the presence of non-ASCII characters.  It would
1918 ideally be nice if all of those definitions were only output if needed,
1919 perhaps on the fly as the characters are used.
1920
1921 Pod::Man is excessively slow.
1922
1923 =head1 CAVEATS
1924
1925 If Pod::Man is given the C<utf8> option, the encoding of its output file
1926 handle will be forced to UTF-8 if possible, overriding any existing
1927 encoding.  This will be done even if the file handle is not created by
1928 Pod::Man and was passed in from outside.  This maintains consistency
1929 regardless of PERL_UNICODE and other settings.
1930
1931 The handling of hyphens and em dashes is somewhat fragile, and one may get
1932 the wrong one under some circumstances.  This should only matter for
1933 B<troff> output.
1934
1935 When and whether to use small caps is somewhat tricky, and Pod::Man doesn't
1936 necessarily get it right.
1937
1938 Converting neutral double quotes to properly matched double quotes doesn't
1939 work unless there are no formatting codes between the quote marks.  This
1940 only matters for troff output.
1941
1942 =head1 AUTHOR
1943
1944 Russ Allbery <rra@cpan.org>, based I<very> heavily on the original
1945 B<pod2man> by Tom Christiansen <tchrist@mox.perl.com>.  The modifications to
1946 work with Pod::Simple instead of Pod::Parser were originally contributed by
1947 Sean Burke (but I've since hacked them beyond recognition and all bugs are
1948 mine).
1949
1950 =head1 COPYRIGHT AND LICENSE
1951
1952 Copyright 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
1953 2009, 2010, 2012, 2013, 2014, 2015 Russ Allbery <rra@cpan.org>
1954
1955 This program is free software; you may redistribute it and/or modify it
1956 under the same terms as Perl itself.
1957
1958 =head1 SEE ALSO
1959
1960 L<Pod::Simple>, L<perlpod(1)>, L<pod2man(1)>, L<nroff(1)>, L<troff(1)>,
1961 L<man(1)>, L<man(7)>
1962
1963 Ossanna, Joseph F., and Brian W. Kernighan.  "Troff User's Manual,"
1964 Computing Science Technical Report No. 54, AT&T Bell Laboratories.  This is
1965 the best documentation of standard B<nroff> and B<troff>.  At the time of
1966 this writing, it's available at
1967 L<http://www.cs.bell-labs.com/cm/cs/cstr.html>.
1968
1969 The man page documenting the man macro set may be L<man(5)> instead of
1970 L<man(7)> on your system.  Also, please see L<pod2man(1)> for extensive
1971 documentation on writing manual pages if you've not done it before and
1972 aren't familiar with the conventions.
1973
1974 The current version of this module is always available from its web site at
1975 L<http://www.eyrie.org/~eagle/software/podlators/>.  It is also part of the
1976 Perl core distribution as of 5.6.0.
1977
1978 =cut