Update podlators to version 4.03
[perl.git] / cpan / podlators / bin / pod2text
1 #!perl
2
3 # pod2text -- Convert POD data to formatted ASCII text.
4 #
5 # Copyright 1999, 2000, 2001, 2004, 2006, 2008, 2010, 2012, 2013, 2014, 2015
6 #     Russ Allbery <rra@cpan.org>
7 #
8 # This program is free software; you may redistribute it and/or modify it
9 # under the same terms as Perl itself.
10 #
11 # The driver script for Pod::Text, Pod::Text::Termcap, and Pod::Text::Color,
12 # invoked by perldoc -t among other things.
13
14 use 5.006;
15 use strict;
16 use warnings;
17
18 use Getopt::Long qw(GetOptions);
19 use Pod::Text ();
20 use Pod::Usage qw(pod2usage);
21
22 # Clean up $0 for error reporting.
23 $0 =~ s%.*/%%;
24
25 # Take an initial pass through our options, looking for one of the form
26 # -<number>.  We turn that into -w <number> for compatibility with the
27 # original pod2text script.
28 for (my $i = 0; $i < @ARGV; $i++) {
29     last if $ARGV[$i] =~ /^--$/;
30     if ($ARGV[$i] =~ /^-(\d+)$/) {
31         splice (@ARGV, $i++, 1, '-w', $1);
32     }
33 }
34
35 # Insert -- into @ARGV before any single dash argument to hide it from
36 # Getopt::Long; we want to interpret it as meaning stdin (which Pod::Simple
37 # does correctly).
38 my $stdin;
39 @ARGV = map { $_ eq '-' && !$stdin++ ? ('--', $_) : $_ } @ARGV;
40
41 # Parse our options.  Use the same names as Pod::Text for simplicity, and
42 # default to sentence boundaries turned off for compatibility.
43 my %options;
44 $options{sentence} = 0;
45 Getopt::Long::config ('bundling');
46 GetOptions (\%options, 'alt|a', 'code', 'color|c', 'errors=s', 'help|h',
47             'indent|i=i', 'loose|l', 'margin|left-margin|m=i', 'nourls',
48             'overstrike|o', 'quotes|q=s', 'sentence|s', 'stderr', 'termcap|t',
49             'utf8|u', 'width|w=i')
50     or exit 1;
51 pod2usage (1) if $options{help};
52
53 # Figure out what formatter we're going to use.  -c overrides -t.
54 my $formatter = 'Pod::Text';
55 if ($options{color}) {
56     $formatter = 'Pod::Text::Color';
57     eval { require Term::ANSIColor };
58     if ($@) { die "-c (--color) requires Term::ANSIColor be installed\n" }
59     require Pod::Text::Color;
60 } elsif ($options{termcap}) {
61     $formatter = 'Pod::Text::Termcap';
62     require Pod::Text::Termcap;
63 } elsif ($options{overstrike}) {
64     $formatter = 'Pod::Text::Overstrike';
65     require Pod::Text::Overstrike;
66 }
67 delete @options{'color', 'termcap', 'overstrike'};
68
69 # If neither stderr nor errors is set, default to errors = die.
70 if (!defined $options{stderr} && !defined $options{errors}) {
71     $options{errors} = 'die';
72 }
73
74 # Initialize and run the formatter.
75 my $parser = $formatter->new (%options);
76 my $status = 0;
77 do {
78     my ($input, $output) = splice (@ARGV, 0, 2);
79     $parser->parse_from_file ($input, $output);
80     if ($parser->{CONTENTLESS}) {
81         $status = 1;
82         warn "$0: unable to format $input\n";
83         if (defined ($output) and $output ne '-') {
84             unlink $output unless (-s $output);
85         }
86     }
87 } while (@ARGV);
88 exit $status;
89
90 __END__
91
92 =for stopwords
93 -aclostu --alt --stderr Allbery --overstrike overstrike --termcap --utf8
94 UTF-8 subclasses --nourls
95
96 =head1 NAME
97
98 pod2text - Convert POD data to formatted ASCII text
99
100 =head1 SYNOPSIS
101
102 pod2text [B<-aclostu>] [B<--code>] [B<--errors>=I<style>] [B<-i> I<indent>]
103     S<[B<-q> I<quotes>]> [B<--nourls>] [B<--stderr>] S<[B<-w> I<width>]>
104     [I<input> [I<output> ...]]
105
106 pod2text B<-h>
107
108 =head1 DESCRIPTION
109
110 B<pod2text> is a front-end for Pod::Text and its subclasses.  It uses them
111 to generate formatted ASCII text from POD source.  It can optionally use
112 either termcap sequences or ANSI color escape sequences to format the text.
113
114 I<input> is the file to read for POD source (the POD can be embedded in
115 code).  If I<input> isn't given, it defaults to C<STDIN>.  I<output>, if
116 given, is the file to which to write the formatted output.  If I<output>
117 isn't given, the formatted output is written to C<STDOUT>.  Several POD
118 files can be processed in the same B<pod2text> invocation (saving module
119 load and compile times) by providing multiple pairs of I<input> and
120 I<output> files on the command line.
121
122 =head1 OPTIONS
123
124 =over 4
125
126 =item B<-a>, B<--alt>
127
128 Use an alternate output format that, among other things, uses a different
129 heading style and marks C<=item> entries with a colon in the left margin.
130
131 =item B<--code>
132
133 Include any non-POD text from the input file in the output as well.  Useful
134 for viewing code documented with POD blocks with the POD rendered and the
135 code left intact.
136
137 =item B<-c>, B<--color>
138
139 Format the output with ANSI color escape sequences.  Using this option
140 requires that Term::ANSIColor be installed on your system.
141
142 =item B<--errors>=I<style>
143
144 Set the error handling style.  C<die> says to throw an exception on any
145 POD formatting error.  C<stderr> says to report errors on standard error,
146 but not to throw an exception.  C<pod> says to include a POD ERRORS
147 section in the resulting documentation summarizing the errors.  C<none>
148 ignores POD errors entirely, as much as possible.
149
150 The default is C<die>.
151
152 =item B<-i> I<indent>, B<--indent=>I<indent>
153
154 Set the number of spaces to indent regular text, and the default indentation
155 for C<=over> blocks.  Defaults to 4 spaces if this option isn't given.
156
157 =item B<-h>, B<--help>
158
159 Print out usage information and exit.
160
161 =item B<-l>, B<--loose>
162
163 Print a blank line after a C<=head1> heading.  Normally, no blank line is
164 printed after C<=head1>, although one is still printed after C<=head2>,
165 because this is the expected formatting for manual pages; if you're
166 formatting arbitrary text documents, using this option is recommended.
167
168 =item B<-m> I<width>, B<--left-margin>=I<width>, B<--margin>=I<width>
169
170 The width of the left margin in spaces.  Defaults to 0.  This is the margin
171 for all text, including headings, not the amount by which regular text is
172 indented; for the latter, see B<-i> option.
173
174 =item B<--nourls>
175
176 Normally, LZ<><> formatting codes with a URL but anchor text are formatted
177 to show both the anchor text and the URL.  In other words:
178
179     L<foo|http://example.com/>
180
181 is formatted as:
182
183     foo <http://example.com/>
184
185 This flag, if given, suppresses the URL when anchor text is given, so this
186 example would be formatted as just C<foo>.  This can produce less
187 cluttered output in cases where the URLs are not particularly important.
188
189 =item B<-o>, B<--overstrike>
190
191 Format the output with overstrike printing.  Bold text is rendered as
192 character, backspace, character.  Italics and file names are rendered as
193 underscore, backspace, character.  Many pagers, such as B<less>, know how
194 to convert this to bold or underlined text.
195
196 =item B<-q> I<quotes>, B<--quotes>=I<quotes>
197
198 Sets the quote marks used to surround CE<lt>> text to I<quotes>.  If
199 I<quotes> is a single character, it is used as both the left and right
200 quote.  Otherwise, it is split in half, and the first half of the string
201 is used as the left quote and the second is used as the right quote.
202
203 I<quotes> may also be set to the special value C<none>, in which case no
204 quote marks are added around CE<lt>> text.
205
206 =item B<-s>, B<--sentence>
207
208 Assume each sentence ends with two spaces and try to preserve that spacing.
209 Without this option, all consecutive whitespace in non-verbatim paragraphs
210 is compressed into a single space.
211
212 =item B<--stderr>
213
214 By default, B<pod2text> dies if any errors are detected in the POD input.
215 If B<--stderr> is given and no B<--errors> flag is present, errors are
216 sent to standard error, but B<pod2text> does not abort.  This is
217 equivalent to C<--errors=stderr> and is supported for backward
218 compatibility.
219
220 =item B<-t>, B<--termcap>
221
222 Try to determine the width of the screen and the bold and underline
223 sequences for the terminal from termcap, and use that information in
224 formatting the output.  Output will be wrapped at two columns less than the
225 width of your terminal device.  Using this option requires that your system
226 have a termcap file somewhere where Term::Cap can find it and requires that
227 your system support termios.  With this option, the output of B<pod2text>
228 will contain terminal control sequences for your current terminal type.
229
230 =item B<-u>, B<--utf8>
231
232 By default, B<pod2text> tries to use the same output encoding as its input
233 encoding (to be backward-compatible with older versions).  This option
234 says to instead force the output encoding to UTF-8.
235
236 Be aware that, when using this option, the input encoding of your POD
237 source should be properly declared unless it's US-ASCII.  Pod::Simple
238 will attempt to guess the encoding and may be successful if it's
239 Latin-1 or UTF-8, but it will warn, which by default results in a
240 B<pod2text> failure.  Use the C<=encoding> command to declare the
241 encoding.  See L<perlpod(1)> for more information.
242
243 =item B<-w>, B<--width=>I<width>, B<->I<width>
244
245 The column at which to wrap text on the right-hand side.  Defaults to 76,
246 unless B<-t> is given, in which case it's two columns less than the width of
247 your terminal device.
248
249 =back
250
251 =head1 EXIT STATUS
252
253 As long as all documents processed result in some output, even if that
254 output includes errata (a C<POD ERRORS> section generated with
255 C<--errors=pod>), B<pod2text> will exit with status 0.  If any of the
256 documents being processed do not result in an output document, B<pod2text>
257 will exit with status 1.  If there are syntax errors in a POD document
258 being processed and the error handling style is set to the default of
259 C<die>, B<pod2text> will abort immediately with exit status 255.
260
261 =head1 DIAGNOSTICS
262
263 If B<pod2text> fails with errors, see L<Pod::Text> and L<Pod::Simple> for
264 information about what those errors might mean.  Internally, it can also
265 produce the following diagnostics:
266
267 =over 4
268
269 =item -c (--color) requires Term::ANSIColor be installed
270
271 (F) B<-c> or B<--color> were given, but Term::ANSIColor could not be
272 loaded.
273
274 =item Unknown option: %s
275
276 (F) An unknown command line option was given.
277
278 =back
279
280 In addition, other L<Getopt::Long> error messages may result from invalid
281 command-line options.
282
283 =head1 ENVIRONMENT
284
285 =over 4
286
287 =item COLUMNS
288
289 If B<-t> is given, B<pod2text> will take the current width of your screen
290 from this environment variable, if available.  It overrides terminal width
291 information in TERMCAP.
292
293 =item TERMCAP
294
295 If B<-t> is given, B<pod2text> will use the contents of this environment
296 variable if available to determine the correct formatting sequences for your
297 current terminal device.
298
299 =back
300
301 =head1 SEE ALSO
302
303 L<Pod::Text>, L<Pod::Text::Color>, L<Pod::Text::Overstrike>,
304 L<Pod::Text::Termcap>, L<Pod::Simple>, L<perlpod(1)>
305
306 The current version of this script is always available from its web site at
307 L<http://www.eyrie.org/~eagle/software/podlators/>.  It is also part of the
308 Perl core distribution as of 5.6.0.
309
310 =head1 AUTHOR
311
312 Russ Allbery <rra@cpan.org>.
313
314 =head1 COPYRIGHT AND LICENSE
315
316 Copyright 1999, 2000, 2001, 2004, 2006, 2008, 2010, 2012, 2013, 2014, 2015
317 Russ Allbery <rra@cpan.org>
318
319 This program is free software; you may redistribute it and/or modify it
320 under the same terms as Perl itself.
321
322 =cut