bump version number of Encode to _02
[perl.git] / cpan / Encode / Encode.pm
1 #
2 # $Id: Encode.pm,v 2.42 2010/12/31 22:48:10 dankogai Exp $
3 #
4 package Encode;
5 use strict;
6 use warnings;
7 our $VERSION = sprintf "%d.%02d_02", q$Revision: 2.42 $ =~ /(\d+)/g;
8 sub DEBUG () { 0 }
9 use XSLoader ();
10 XSLoader::load( __PACKAGE__, $VERSION );
11
12 require Exporter;
13 use base qw/Exporter/;
14
15 # Public, encouraged API is exported by default
16
17 our @EXPORT = qw(
18   decode  decode_utf8  encode  encode_utf8 str2bytes bytes2str
19   encodings  find_encoding clone_encoding
20 );
21 our @FB_FLAGS = qw(
22   DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
23   PERLQQ HTMLCREF XMLCREF STOP_AT_PARTIAL
24 );
25 our @FB_CONSTS = qw(
26   FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
27   FB_PERLQQ FB_HTMLCREF FB_XMLCREF
28 );
29 our @EXPORT_OK = (
30     qw(
31       _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
32       is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
33       ),
34     @FB_FLAGS, @FB_CONSTS,
35 );
36
37 our %EXPORT_TAGS = (
38     all          => [ @EXPORT,    @EXPORT_OK ],
39     default      => [ @EXPORT ],
40     fallbacks    => [ @FB_CONSTS ],
41     fallback_all => [ @FB_CONSTS, @FB_FLAGS ],
42 );
43
44 # Documentation moved after __END__ for speed - NI-S
45
46 our $ON_EBCDIC = ( ord("A") == 193 );
47
48 use Encode::Alias;
49
50 # Make a %Encoding package variable to allow a certain amount of cheating
51 our %Encoding;
52 our %ExtModule;
53 require Encode::Config;
54 #  See
55 #  https://bugzilla.redhat.com/show_bug.cgi?id=435505#c2
56 #  to find why sig handers inside eval{} are disabled.
57 eval {
58     local $SIG{__DIE__};
59     local $SIG{__WARN__};
60     require Encode::ConfigLocal;
61 };
62
63 sub encodings {
64     my $class = shift;
65     my %enc;
66     if ( @_ and $_[0] eq ":all" ) {
67         %enc = ( %Encoding, %ExtModule );
68     }
69     else {
70         %enc = %Encoding;
71         for my $mod ( map { m/::/o ? $_ : "Encode::$_" } @_ ) {
72             DEBUG and warn $mod;
73             for my $enc ( keys %ExtModule ) {
74                 $ExtModule{$enc} eq $mod and $enc{$enc} = $mod;
75             }
76         }
77     }
78     return sort { lc $a cmp lc $b }
79       grep      { !/^(?:Internal|Unicode|Guess)$/o } keys %enc;
80 }
81
82 sub perlio_ok {
83     my $obj = ref( $_[0] ) ? $_[0] : find_encoding( $_[0] );
84     $obj->can("perlio_ok") and return $obj->perlio_ok();
85     return 0;    # safety net
86 }
87
88 sub define_encoding {
89     my $obj  = shift;
90     my $name = shift;
91     $Encoding{$name} = $obj;
92     my $lc = lc($name);
93     define_alias( $lc => $obj ) unless $lc eq $name;
94     while (@_) {
95         my $alias = shift;
96         define_alias( $alias, $obj );
97     }
98     return $obj;
99 }
100
101 sub getEncoding {
102     my ( $class, $name, $skip_external ) = @_;
103
104     ref($name) && $name->can('renew') and return $name;
105     exists $Encoding{$name} and return $Encoding{$name};
106     my $lc = lc $name;
107     exists $Encoding{$lc} and return $Encoding{$lc};
108
109     my $oc = $class->find_alias($name);
110     defined($oc) and return $oc;
111     $lc ne $name and $oc = $class->find_alias($lc);
112     defined($oc) and return $oc;
113
114     unless ($skip_external) {
115         if ( my $mod = $ExtModule{$name} || $ExtModule{$lc} ) {
116             $mod =~ s,::,/,g;
117             $mod .= '.pm';
118             eval { require $mod; };
119             exists $Encoding{$name} and return $Encoding{$name};
120         }
121     }
122     return;
123 }
124
125 sub find_encoding($;$) {
126     my ( $name, $skip_external ) = @_;
127     return __PACKAGE__->getEncoding( $name, $skip_external );
128 }
129
130 sub resolve_alias($) {
131     my $obj = find_encoding(shift);
132     defined $obj and return $obj->name;
133     return;
134 }
135
136 sub clone_encoding($) {
137     my $obj = find_encoding(shift);
138     ref $obj or return;
139     eval { require Storable };
140     $@ and return;
141     return Storable::dclone($obj);
142 }
143
144 sub encode($$;$) {
145     my ( $name, $string, $check ) = @_;
146     return undef unless defined $string;
147     $string .= '' if ref $string;    # stringify;
148     $check ||= 0;
149     unless ( defined $name ) {
150         require Carp;
151         Carp::croak("Encoding name should not be undef");
152     }
153     my $enc = find_encoding($name);
154     unless ( defined $enc ) {
155         require Carp;
156         Carp::croak("Unknown encoding '$name'");
157     }
158     my $octets = $enc->encode( $string, $check );
159     $_[1] = $string if $check and !ref $check and !( $check & LEAVE_SRC() );
160     return $octets;
161 }
162 *str2bytes = \&encode;
163
164 sub decode($$;$) {
165     my ( $name, $octets, $check ) = @_;
166     return undef unless defined $octets;
167     $octets .= '' if ref $octets;
168     $check ||= 0;
169     my $enc = find_encoding($name);
170     unless ( defined $enc ) {
171         require Carp;
172         Carp::croak("Unknown encoding '$name'");
173     }
174     my $string = $enc->decode( $octets, $check );
175     $_[1] = $octets if $check and !ref $check and !( $check & LEAVE_SRC() );
176     return $string;
177 }
178 *bytes2str = \&decode;
179
180 sub from_to($$$;$) {
181     my ( $string, $from, $to, $check ) = @_;
182     return undef unless defined $string;
183     $check ||= 0;
184     my $f = find_encoding($from);
185     unless ( defined $f ) {
186         require Carp;
187         Carp::croak("Unknown encoding '$from'");
188     }
189     my $t = find_encoding($to);
190     unless ( defined $t ) {
191         require Carp;
192         Carp::croak("Unknown encoding '$to'");
193     }
194     my $uni = $f->decode($string);
195     $_[0] = $string = $t->encode( $uni, $check );
196     return undef if ( $check && length($uni) );
197     return defined( $_[0] ) ? length($string) : undef;
198 }
199
200 sub encode_utf8($) {
201     my ($str) = @_;
202     utf8::encode($str);
203     return $str;
204 }
205
206 my $utf8enc;
207
208 sub decode_utf8($;$) {
209     my ( $octets, $check ) = @_;
210     return $octets if is_utf8($octets);
211     return undef unless defined $octets;
212     $octets .= '' if ref $octets;
213     $check   ||= 0;
214     $utf8enc ||= find_encoding('utf8');
215     my $string = $utf8enc->decode( $octets, $check );
216     $_[0] = $octets if $check and !ref $check and !( $check & LEAVE_SRC() );
217     return $string;
218 }
219
220 # sub decode_utf8($;$) {
221 #     my ( $str, $check ) = @_;
222 #     return $str if is_utf8($str);
223 #     if ($check) {
224 #         return decode( "utf8", $str, $check );
225 #     }
226 #     else {
227 #         return decode( "utf8", $str );
228 #         return $str;
229 #     }
230 # }
231
232 predefine_encodings(1);
233
234 #
235 # This is to restore %Encoding if really needed;
236 #
237
238 sub predefine_encodings {
239     require Encode::Encoding;
240     no warnings 'redefine';
241     my $use_xs = shift;
242     if ($ON_EBCDIC) {
243
244         # was in Encode::UTF_EBCDIC
245         package Encode::UTF_EBCDIC;
246         push @Encode::UTF_EBCDIC::ISA, 'Encode::Encoding';
247         *decode = sub {
248             my ( $obj, $str, $chk ) = @_;
249             my $res = '';
250             for ( my $i = 0 ; $i < length($str) ; $i++ ) {
251                 $res .=
252                   chr(
253                     utf8::unicode_to_native( ord( substr( $str, $i, 1 ) ) )
254                   );
255             }
256             $_[1] = '' if $chk;
257             return $res;
258         };
259         *encode = sub {
260             my ( $obj, $str, $chk ) = @_;
261             my $res = '';
262             for ( my $i = 0 ; $i < length($str) ; $i++ ) {
263                 $res .=
264                   chr(
265                     utf8::native_to_unicode( ord( substr( $str, $i, 1 ) ) )
266                   );
267             }
268             $_[1] = '' if $chk;
269             return $res;
270         };
271         $Encode::Encoding{Unicode} =
272           bless { Name => "UTF_EBCDIC" } => "Encode::UTF_EBCDIC";
273     }
274     else {
275
276         package Encode::Internal;
277         push @Encode::Internal::ISA, 'Encode::Encoding';
278         *decode = sub {
279             my ( $obj, $str, $chk ) = @_;
280             utf8::upgrade($str);
281             $_[1] = '' if $chk;
282             return $str;
283         };
284         *encode = \&decode;
285         $Encode::Encoding{Unicode} =
286           bless { Name => "Internal" } => "Encode::Internal";
287     }
288
289     {
290
291         # was in Encode::utf8
292         package Encode::utf8;
293         push @Encode::utf8::ISA, 'Encode::Encoding';
294
295         #
296         if ($use_xs) {
297             Encode::DEBUG and warn __PACKAGE__, " XS on";
298             *decode = \&decode_xs;
299             *encode = \&encode_xs;
300         }
301         else {
302             Encode::DEBUG and warn __PACKAGE__, " XS off";
303             *decode = sub {
304                 my ( $obj, $octets, $chk ) = @_;
305                 my $str = Encode::decode_utf8($octets);
306                 if ( defined $str ) {
307                     $_[1] = '' if $chk;
308                     return $str;
309                 }
310                 return undef;
311             };
312             *encode = sub {
313                 my ( $obj, $string, $chk ) = @_;
314                 my $octets = Encode::encode_utf8($string);
315                 $_[1] = '' if $chk;
316                 return $octets;
317             };
318         }
319         *cat_decode = sub {    # ($obj, $dst, $src, $pos, $trm, $chk)
320                                # currently ignores $chk
321             my ( $obj, undef, undef, $pos, $trm ) = @_;
322             my ( $rdst, $rsrc, $rpos ) = \@_[ 1, 2, 3 ];
323             use bytes;
324             if ( ( my $npos = index( $$rsrc, $trm, $pos ) ) >= 0 ) {
325                 $$rdst .=
326                   substr( $$rsrc, $pos, $npos - $pos + length($trm) );
327                 $$rpos = $npos + length($trm);
328                 return 1;
329             }
330             $$rdst .= substr( $$rsrc, $pos );
331             $$rpos = length($$rsrc);
332             return '';
333         };
334         $Encode::Encoding{utf8} =
335           bless { Name => "utf8" } => "Encode::utf8";
336         $Encode::Encoding{"utf-8-strict"} =
337           bless { Name => "utf-8-strict", strict_utf8 => 1 } =>
338           "Encode::utf8";
339     }
340 }
341
342 1;
343
344 __END__
345
346 =head1 NAME
347
348 Encode - character encodings
349
350 =head1 SYNOPSIS
351
352     use Encode;
353
354 =head2 Table of Contents
355
356 Encode consists of a collection of modules whose details are too big
357 to fit in one document.  This POD itself explains the top-level APIs
358 and general topics at a glance.  For other topics and more details,
359 see the PODs below:
360
361   Name                          Description
362   --------------------------------------------------------
363   Encode::Alias         Alias definitions to encodings
364   Encode::Encoding      Encode Implementation Base Class
365   Encode::Supported     List of Supported Encodings
366   Encode::CN            Simplified Chinese Encodings
367   Encode::JP            Japanese Encodings
368   Encode::KR            Korean Encodings
369   Encode::TW            Traditional Chinese Encodings
370   --------------------------------------------------------
371
372 =head1 DESCRIPTION
373
374 The C<Encode> module provides the interfaces between Perl's strings
375 and the rest of the system.  Perl strings are sequences of
376 B<characters>.
377
378 The repertoire of characters that Perl can represent is at least that
379 defined by the Unicode Consortium. On most platforms the ordinal
380 values of the characters (as returned by C<ord(ch)>) is the "Unicode
381 codepoint" for the character (the exceptions are those platforms where
382 the legacy encoding is some variant of EBCDIC rather than a super-set
383 of ASCII - see L<perlebcdic>).
384
385 Traditionally, computer data has been moved around in 8-bit chunks
386 often called "bytes". These chunks are also known as "octets" in
387 networking standards. Perl is widely used to manipulate data of many
388 types - not only strings of characters representing human or computer
389 languages but also "binary" data being the machine's representation of
390 numbers, pixels in an image - or just about anything.
391
392 When Perl is processing "binary data", the programmer wants Perl to
393 process "sequences of bytes". This is not a problem for Perl - as a
394 byte has 256 possible values, it easily fits in Perl's much larger
395 "logical character".
396
397 =head2 TERMINOLOGY
398
399 =over 2
400
401 =item *
402
403 I<character>: a character in the range 0..(2**32-1) (or more).
404 (What Perl's strings are made of.)
405
406 =item *
407
408 I<byte>: a character in the range 0..255
409 (A special case of a Perl character.)
410
411 =item *
412
413 I<octet>: 8 bits of data, with ordinal values 0..255
414 (Term for bytes passed to or from a non-Perl context, e.g. a disk file.)
415
416 =back
417
418 =head1 PERL ENCODING API
419
420 =over 2
421
422 =item $octets  = encode(ENCODING, $string [, CHECK])
423
424 Encodes a string from Perl's internal form into I<ENCODING> and returns
425 a sequence of octets.  ENCODING can be either a canonical name or
426 an alias.  For encoding names and aliases, see L</"Defining Aliases">.
427 For CHECK, see L</"Handling Malformed Data">.
428
429 For example, to convert a string from Perl's internal format to
430 iso-8859-1 (also known as Latin1),
431
432   $octets = encode("iso-8859-1", $string);
433
434 B<CAVEAT>: When you run C<$octets = encode("utf8", $string)>, then
435 $octets B<may not be equal to> $string.  Though they both contain the
436 same data, the UTF8 flag for $octets is B<always> off.  When you
437 encode anything, UTF8 flag of the result is always off, even when it
438 contains completely valid utf8 string. See L</"The UTF8 flag"> below.
439
440 If the $string is C<undef> then C<undef> is returned.
441
442 =item $string = decode(ENCODING, $octets [, CHECK])
443
444 Decodes a sequence of octets assumed to be in I<ENCODING> into Perl's
445 internal form and returns the resulting string.  As in encode(),
446 ENCODING can be either a canonical name or an alias. For encoding names
447 and aliases, see L</"Defining Aliases">.  For CHECK, see
448 L</"Handling Malformed Data">.
449
450 For example, to convert ISO-8859-1 data to a string in Perl's internal format:
451
452   $string = decode("iso-8859-1", $octets);
453
454 B<CAVEAT>: When you run C<$string = decode("utf8", $octets)>, then $string
455 B<may not be equal to> $octets.  Though they both contain the same data,
456 the UTF8 flag for $string is on unless $octets entirely consists of
457 ASCII data (or EBCDIC on EBCDIC machines).  See L</"The UTF8 flag">
458 below.
459
460 If the $string is C<undef> then C<undef> is returned.
461
462 =item [$obj =] find_encoding(ENCODING)
463
464 Returns the I<encoding object> corresponding to ENCODING.  Returns
465 undef if no matching ENCODING is find.
466
467 This object is what actually does the actual (en|de)coding.
468
469   $utf8 = decode($name, $bytes);
470
471 is in fact
472
473   $utf8 = do{
474     $obj = find_encoding($name);
475     croak qq(encoding "$name" not found) unless ref $obj;
476     $obj->decode($bytes)
477   };
478
479 with more error checking.
480
481 Therefore you can save time by reusing this object as follows;
482
483   my $enc = find_encoding("iso-8859-1");
484   while(<>){
485      my $utf8 = $enc->decode($_);
486      # and do someting with $utf8;
487   }
488
489 Besides C<< ->decode >> and C<< ->encode >>, other methods are
490 available as well.  For instance, C<< -> name >> returns the canonical
491 name of the encoding object.
492
493   find_encoding("latin1")->name; # iso-8859-1
494
495 See L<Encode::Encoding> for details.
496
497 =item [$length =] from_to($octets, FROM_ENC, TO_ENC [, CHECK])
498
499 Converts B<in-place> data between two encodings. The data in $octets
500 must be encoded as octets and not as characters in Perl's internal
501 format. For example, to convert ISO-8859-1 data to Microsoft's CP1250
502 encoding:
503
504   from_to($octets, "iso-8859-1", "cp1250");
505
506 and to convert it back:
507
508   from_to($octets, "cp1250", "iso-8859-1");
509
510 Note that because the conversion happens in place, the data to be
511 converted cannot be a string constant; it must be a scalar variable.
512
513 from_to() returns the length of the converted string in octets on
514 success, I<undef> on error.
515
516 B<CAVEAT>: The following operations look the same but are not quite so;
517
518   from_to($data, "iso-8859-1", "utf8"); #1
519   $data = decode("iso-8859-1", $data);  #2
520
521 Both #1 and #2 make $data consist of a completely valid UTF-8 string
522 but only #2 turns UTF8 flag on.  #1 is equivalent to
523
524   $data = encode("utf8", decode("iso-8859-1", $data));
525
526 See L</"The UTF8 flag"> below.
527
528 Also note that
529
530   from_to($octets, $from, $to, $check);
531
532 is equivalent to
533
534   $octets = encode($to, decode($from, $octets), $check);
535
536 Yes, it does not respect the $check during decoding.  It is
537 deliberately done that way.  If you need minute control, C<decode>
538 then C<encode> as follows;
539
540   $octets = encode($to, decode($from, $octets, $check_from), $check_to);
541
542 =item $octets = encode_utf8($string);
543
544 Equivalent to C<$octets = encode("utf8", $string);> The characters
545 that comprise $string are encoded in Perl's internal format and the
546 result is returned as a sequence of octets. All possible
547 characters have a UTF-8 representation so this function cannot fail.
548
549
550 =item $string = decode_utf8($octets [, CHECK]);
551
552 equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
553 The sequence of octets represented by
554 $octets is decoded from UTF-8 into a sequence of logical
555 characters. Not all sequences of octets form valid UTF-8 encodings, so
556 it is possible for this call to fail.  For CHECK, see
557 L</"Handling Malformed Data">.
558
559 =back
560
561 =head2 Listing available encodings
562
563   use Encode;
564   @list = Encode->encodings();
565
566 Returns a list of the canonical names of the available encodings that
567 are loaded.  To get a list of all available encodings including the
568 ones that are not loaded yet, say
569
570   @all_encodings = Encode->encodings(":all");
571
572 Or you can give the name of a specific module.
573
574   @with_jp = Encode->encodings("Encode::JP");
575
576 When "::" is not in the name, "Encode::" is assumed.
577
578   @ebcdic = Encode->encodings("EBCDIC");
579
580 To find out in detail which encodings are supported by this package,
581 see L<Encode::Supported>.
582
583 =head2 Defining Aliases
584
585 To add a new alias to a given encoding, use:
586
587   use Encode;
588   use Encode::Alias;
589   define_alias(newName => ENCODING);
590
591 After that, newName can be used as an alias for ENCODING.
592 ENCODING may be either the name of an encoding or an
593 I<encoding object>
594
595 But before you do so, make sure the alias is nonexistent with
596 C<resolve_alias()>, which returns the canonical name thereof.
597 i.e.
598
599   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
600   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
601   Encode::resolve_alias($name) eq $name  # true if $name is canonical
602
603 resolve_alias() does not need C<use Encode::Alias>; it can be
604 exported via C<use Encode qw(resolve_alias)>.
605
606 See L<Encode::Alias> for details.
607
608 =head2 Finding IANA Character Set Registry names
609
610 The canonical name of a given encoding does not necessarily agree with
611 IANA IANA Character Set Registry, commonly seen as C<< Content-Type:
612 text/plain; charset=I<whatever> >>.  For most cases canonical names
613 work but sometimes it does not (notably 'utf-8-strict').
614
615 Therefore as of Encode version 2.21, a new method C<mime_name()> is added.
616
617   use Encode;
618   my $enc = find_encoding('UTF-8');
619   warn $enc->name;      # utf-8-strict
620   warn $enc->mime_name; # UTF-8
621
622 See also:  L<Encode::Encoding>
623
624 =head1 Encoding via PerlIO
625
626 If your perl supports I<PerlIO> (which is the default), you can use a
627 PerlIO layer to decode and encode directly via a filehandle.  The
628 following two examples are totally identical in their functionality.
629
630   # via PerlIO
631   open my $in,  "<:encoding(shiftjis)", $infile  or die;
632   open my $out, ">:encoding(euc-jp)",   $outfile or die;
633   while(<$in>){ print $out $_; }
634
635   # via from_to
636   open my $in,  "<", $infile  or die;
637   open my $out, ">", $outfile or die;
638   while(<$in>){
639     from_to($_, "shiftjis", "euc-jp", 1);
640     print $out $_;
641   }
642
643 Unfortunately, it may be that encodings are PerlIO-savvy.  You can check
644 if your encoding is supported by PerlIO by calling the C<perlio_ok>
645 method.
646
647   Encode::perlio_ok("hz");             # False
648   find_encoding("euc-cn")->perlio_ok;  # True where PerlIO is available
649
650   use Encode qw(perlio_ok);            # exported upon request
651   perlio_ok("euc-jp")
652
653 Fortunately, all encodings that come with Encode core are PerlIO-savvy
654 except for hz and ISO-2022-kr.  For gory details, see
655 L<Encode::Encoding> and L<Encode::PerlIO>.
656
657 =head1 Handling Malformed Data
658
659 The optional I<CHECK> argument tells Encode what to do when it
660 encounters malformed data.  Without CHECK, Encode::FB_DEFAULT ( == 0 )
661 is assumed.
662
663 As of version 2.12 Encode supports coderef values for CHECK.  See below.
664
665 =over 2
666
667 =item B<NOTE:> Not all encoding support this feature
668
669 Some encodings ignore I<CHECK> argument.  For example,
670 L<Encode::Unicode> ignores I<CHECK> and it always croaks on error.
671
672 =back
673
674 Now here is the list of I<CHECK> values available
675
676 =over 2
677
678 =item I<CHECK> = Encode::FB_DEFAULT ( == 0)
679
680 If I<CHECK> is 0, (en|de)code will put a I<substitution character> in
681 place of a malformed character.  When you encode, E<lt>subcharE<gt>
682 will be used.  When you decode the code point C<0xFFFD> is used.  If
683 the data is supposed to be UTF-8, an optional lexical warning
684 (category utf8) is given.
685
686 =item I<CHECK> = Encode::FB_CROAK ( == 1)
687
688 If I<CHECK> is 1, methods will die on error immediately with an error
689 message.  Therefore, when I<CHECK> is set to 1,  you should trap the
690 error with eval{} unless you really want to let it die.
691
692 =item I<CHECK> = Encode::FB_QUIET
693
694 If I<CHECK> is set to Encode::FB_QUIET, (en|de)code will immediately
695 return the portion of the data that has been processed so far when an
696 error occurs. The data argument will be overwritten with everything
697 after that point (that is, the unprocessed part of data).  This is
698 handy when you have to call decode repeatedly in the case where your
699 source data may contain partial multi-byte character sequences,
700 (i.e. you are reading with a fixed-width buffer). Here is a sample
701 code that does exactly this:
702
703   my $buffer = ''; my $string = '';
704   while(read $fh, $buffer, 256, length($buffer)){
705     $string .= decode($encoding, $buffer, Encode::FB_QUIET);
706     # $buffer now contains the unprocessed partial character
707   }
708
709 =item I<CHECK> = Encode::FB_WARN
710
711 This is the same as above, except that it warns on error.  Handy when
712 you are debugging the mode above.
713
714 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
715
716 =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
717
718 =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
719
720 For encodings that are implemented by Encode::XS, CHECK ==
721 Encode::FB_PERLQQ turns (en|de)code into C<perlqq> fallback mode.
722
723 When you decode, C<\xI<HH>> will be inserted for a malformed character,
724 where I<HH> is the hex representation of the octet  that could not be
725 decoded to utf8.  And when you encode, C<\x{I<HHHH>}> will be inserted,
726 where I<HHHH> is the Unicode ID of the character that cannot be found
727 in the character repertoire of the encoding.
728
729 HTML/XML character reference modes are about the same, in place of
730 C<\x{I<HHHH>}>, HTML uses C<&#I<NNN>;> where I<NNN> is a decimal number and
731 XML uses C<&#xI<HHHH>;> where I<HHHH> is the hexadecimal number.
732
733 In Encode 2.10 or later, C<LEAVE_SRC> is also implied.
734
735 =item The bitmask
736
737 These modes are actually set via a bitmask.  Here is how the FB_XX
738 constants are laid out.  You can import the FB_XX constants via
739 C<use Encode qw(:fallbacks)>; you can import the generic bitmask
740 constants via C<use Encode qw(:fallback_all)>.
741
742                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
743  DIE_ON_ERR    0x0001             X
744  WARN_ON_ERR   0x0002                               X
745  RETURN_ON_ERR 0x0004                      X        X
746  LEAVE_SRC     0x0008                                        X
747  PERLQQ        0x0100                                        X
748  HTMLCREF      0x0200
749  XMLCREF       0x0400
750
751 =back
752
753 =over 2
754
755 =item Encode::LEAVE_SRC
756
757 If the C<Encode::LEAVE_SRC> bit is not set, but I<CHECK> is, then the second
758 argument to C<encode()> or C<decode()> may be assigned to by the functions. If
759 you're not interested in this, then bitwise-or the bitmask with it.
760
761 =back
762
763 =head2 coderef for CHECK
764
765 As of Encode 2.12 CHECK can also be a code reference which takes the
766 ord value of unmapped caharacter as an argument and returns a string
767 that represents the fallback character.  For instance,
768
769   $ascii = encode("ascii", $utf8, sub{ sprintf "<U+%04X>", shift });
770
771 Acts like FB_PERLQQ but E<lt>U+I<XXXX>E<gt> is used instead of
772 \x{I<XXXX>}.
773
774 =head1 Defining Encodings
775
776 To define a new encoding, use:
777
778     use Encode qw(define_encoding);
779     define_encoding($object, 'canonicalName' [, alias...]);
780
781 I<canonicalName> will be associated with I<$object>.  The object
782 should provide the interface described in L<Encode::Encoding>.
783 If more than two arguments are provided then additional
784 arguments are taken as aliases for I<$object>.
785
786 See L<Encode::Encoding> for more details.
787
788 =head1 The UTF8 flag
789
790 Before the introduction of Unicode support in perl, The C<eq> operator
791 just compared the strings represented by two scalars. Beginning with
792 perl 5.8, C<eq> compares two strings with simultaneous consideration of
793 I<the UTF8 flag>. To explain why we made it so, I will quote page 402 of
794 C<Programming Perl, 3rd ed.>
795
796 =over 2
797
798 =item Goal #1:
799
800 Old byte-oriented programs should not spontaneously break on the old
801 byte-oriented data they used to work on.
802
803 =item Goal #2:
804
805 Old byte-oriented programs should magically start working on the new
806 character-oriented data when appropriate.
807
808 =item Goal #3:
809
810 Programs should run just as fast in the new character-oriented mode
811 as in the old byte-oriented mode.
812
813 =item Goal #4:
814
815 Perl should remain one language, rather than forking into a
816 byte-oriented Perl and a character-oriented Perl.
817
818 =back
819
820 Back when C<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0
821 was born and many features documented in the book remained
822 unimplemented for a long time.  Perl 5.8 corrected this and the introduction
823 of the UTF8 flag is one of them.  You can think of this perl notion as of a
824 byte-oriented mode (UTF8 flag off) and a character-oriented mode (UTF8
825 flag on).
826
827 Here is how Encode takes care of the UTF8 flag.
828
829 =over 2
830
831 =item *
832
833 When you encode, the resulting UTF8 flag is always off.
834
835 =item *
836
837 When you decode, the resulting UTF8 flag is on unless you can
838 unambiguously represent data.  Here is the definition of
839 dis-ambiguity.
840
841 After C<$utf8 = decode('foo', $octet);>,
842
843   When $octet is...   The UTF8 flag in $utf8 is
844   ---------------------------------------------
845   In ASCII only (or EBCDIC only)            OFF
846   In ISO-8859-1                              ON
847   In any other Encoding                      ON
848   ---------------------------------------------
849
850 As you see, there is one exception, In ASCII.  That way you can assume
851 Goal #1.  And with Encode Goal #2 is assumed but you still have to be
852 careful in such cases mentioned in B<CAVEAT> paragraphs.
853
854 This UTF8 flag is not visible in perl scripts, exactly for the same
855 reason you cannot (or you I<don't have to>) see if a scalar contains a
856 string, integer, or floating point number.   But you can still peek
857 and poke these if you will.  See the section below.
858
859 =back
860
861 =head2 Messing with Perl's Internals
862
863 The following API uses parts of Perl's internals in the current
864 implementation.  As such, they are efficient but may change.
865
866 =over 2
867
868 =item is_utf8(STRING [, CHECK])
869
870 [INTERNAL] Tests whether the UTF8 flag is turned on in the STRING.
871 If CHECK is true, also checks the data in STRING for being well-formed
872 UTF-8.  Returns true if successful, false otherwise.
873
874 As of perl 5.8.1, L<utf8> also has utf8::is_utf8().
875
876 =item _utf8_on(STRING)
877
878 [INTERNAL] Turns on the UTF8 flag in STRING.  The data in STRING is
879 B<not> checked for being well-formed UTF-8.  Do not use unless you
880 B<know> that the STRING is well-formed UTF-8.  Returns the previous
881 state of the UTF8 flag (so please don't treat the return value as
882 indicating success or failure), or C<undef> if STRING is not a string.
883
884 This function does not work on tainted values.
885
886 =item _utf8_off(STRING)
887
888 [INTERNAL] Turns off the UTF8 flag in STRING.  Do not use frivolously.
889 Returns the previous state of the UTF8 flag (so please don't treat the
890 return value as indicating success or failure), or C<undef> if STRING is
891 not a string.
892
893 This function does not work on tainted values.
894
895 =back
896
897 =head1 UTF-8 vs. utf8 vs. UTF8
898
899   ....We now view strings not as sequences of bytes, but as sequences
900   of numbers in the range 0 .. 2**32-1 (or in the case of 64-bit
901   computers, 0 .. 2**64-1) -- Programming Perl, 3rd ed.
902
903 That has been the perl's notion of UTF-8 but official UTF-8 is more
904 strict; Its ranges is much narrower (0 .. 10FFFF), some sequences are
905 not allowed (i.e. Those used in the surrogate pair, 0xFFFE, et al).
906
907 Now that is overruled by Larry Wall himself.
908
909   From: Larry Wall <larry@wall.org>
910   Date: December 04, 2004 11:51:58 JST
911   To: perl-unicode@perl.org
912   Subject: Re: Make Encode.pm support the real UTF-8
913   Message-Id: <20041204025158.GA28754@wall.org>
914   
915   On Fri, Dec 03, 2004 at 10:12:12PM +0000, Tim Bunce wrote:
916   : I've no problem with 'utf8' being perl's unrestricted uft8 encoding,
917   : but "UTF-8" is the name of the standard and should give the
918   : corresponding behaviour.
919   
920   For what it's worth, that's how I've always kept them straight in my
921   head.
922   
923   Also for what it's worth, Perl 6 will mostly default to strict but
924   make it easy to switch back to lax.
925   
926   Larry
927
928 Do you copy?  As of Perl 5.8.7, B<UTF-8> means strict, official UTF-8
929 while B<utf8> means liberal, lax, version thereof.  And Encode version
930 2.10 or later thus groks the difference between C<UTF-8> and C"utf8".
931
932   encode("utf8",  "\x{FFFF_FFFF}", 1); # okay
933   encode("UTF-8", "\x{FFFF_FFFF}", 1); # croaks
934
935 C<UTF-8> in Encode is actually a canonical name for C<utf-8-strict>.
936 Yes, the hyphen between "UTF" and "8" is important.  Without it Encode
937 goes "liberal"
938
939   find_encoding("UTF-8")->name # is 'utf-8-strict'
940   find_encoding("utf-8")->name # ditto. names are case insensitive
941   find_encoding("utf_8")->name  # ditto. "_" are treated as "-"
942   find_encoding("UTF8")->name  # is 'utf8'.
943
944 The UTF8 flag is internally called UTF8, without a hyphen. It indicates
945 whether a string is internally encoded as utf8, also without a hypen.
946
947 =head1 SEE ALSO
948
949 L<Encode::Encoding>,
950 L<Encode::Supported>,
951 L<Encode::PerlIO>,
952 L<encoding>,
953 L<perlebcdic>,
954 L<perlfunc/open>,
955 L<perlunicode>, L<perluniintro>, L<perlunifaq>, L<perlunitut>
956 L<utf8>,
957 the Perl Unicode Mailing List E<lt>perl-unicode@perl.orgE<gt>
958
959 =head1 MAINTAINER
960
961 This project was originated by Nick Ing-Simmons and later maintained
962 by Dan Kogai E<lt>dankogai@dan.co.jpE<gt>.  See AUTHORS for a full
963 list of people involved.  For any questions, use
964 E<lt>perl-unicode@perl.orgE<gt> so we can all share.
965
966 While Dan Kogai retains the copyright as a maintainer, the credit
967 should go to all those involoved.  See AUTHORS for those submitted
968 codes.
969
970 =head1 COPYRIGHT
971
972 Copyright 2002-2006 Dan Kogai E<lt>dankogai@dan.co.jpE<gt>
973
974 This library is free software; you can redistribute it and/or modify
975 it under the same terms as Perl itself.
976
977 =cut