Updated perlfaq to CPAN version 5.0150040
[perl.git] / Porting / corelist.pl
1 #!perl
2 # Generates info for Module::CoreList from this perl tree
3 # run this from the root of a perl tree
4 #
5 # Data is on STDOUT.
6 #
7 # With an optional arg specifying the root of a CPAN mirror, outputs the
8 # %upstream and %bug_tracker hashes too.
9
10 use autodie;
11 use strict;
12 use warnings;
13 use File::Find;
14 use ExtUtils::MM_Unix;
15 use version;
16 use lib "Porting";
17 use Maintainers qw(%Modules files_to_modules);
18 use File::Spec;
19 use Parse::CPAN::Meta;
20 use IPC::Cmd 'can_run';
21 use HTTP::Tiny;
22 use IO::Uncompress::Gunzip;
23
24 my $corelist_file = 'dist/Module-CoreList/lib/Module/CoreList.pm';
25 my $pod_file = 'dist/Module-CoreList/lib/Module/CoreList.pod';
26
27 my %lines;
28 my %module_to_file;
29 my %modlist;
30
31 die "usage: $0 [ cpan-mirror/ ] [ 5.x.y] \n" unless @ARGV <= 2;
32 my $cpan         = shift;
33 my $raw_version  = shift || $];
34 my $perl_version = version->parse("$raw_version");
35 my $perl_vnum    = $perl_version->numify;
36 my $perl_vstring = $perl_version->normal; # how do we get version.pm to not give us leading v?
37 $perl_vstring =~ s/^v//;
38
39 if ( !-f 'MANIFEST' ) {
40     die "Must be run from the root of a clean perl tree\n";
41 }
42
43 open( my $corelist_fh, '<', $corelist_file );
44 my $corelist = join( '', <$corelist_fh> );
45
46 if ($cpan) {
47     my $modlistfile = File::Spec->catfile( $cpan, 'modules', '02packages.details.txt' );
48     my $content;
49
50     my $fh;
51     if ( -e $modlistfile ) {
52         warn "Reading the module list from $modlistfile";
53         open $fh, '<', $modlistfile;
54     } elsif ( -e $modlistfile . ".gz" ) {
55         my $zcat = can_run('gzcat') || can_run('zcat') or die "Can't find gzcat or zcat";
56         warn "Reading the module list from $modlistfile.gz";
57         open $fh, '-|', "$zcat $modlistfile.gz";
58     } else {
59         warn "About to fetch 02packages from ftp.funet.fi. This may take a few minutes\n";
60         my $gzipped_content = fetch_url('http://ftp.funet.fi/pub/CPAN/modules/02packages.details.txt.gz');
61         unless ($gzipped_content) {
62             die "Unable to read 02packages.details.txt from either your CPAN mirror or ftp.funet.fi";
63         }
64         IO::Uncompress::Gunzip::gunzip(\$gzipped_content, \$content, Transparent => 0)
65             or die "Can't gunzip content: $IO::Uncompress::Gunzip::GunzipError";
66     }
67
68     if ( $fh and !$content ) {
69         local $/ = "\n";
70         $content = join( '', <$fh> );
71     }
72
73     die "Incompatible modlist format"
74         unless $content =~ /^Columns: +package name, version, path/m;
75
76     # Converting the file to a hash is about 5 times faster than a regexp flat
77     # lookup.
78     for ( split( qr/\n/, $content ) ) {
79         next unless /^([A-Za-z_:0-9]+) +[-0-9.undefHASHVERSIONvsetwhenloadingbogus]+ +(\S+)/;
80         $modlist{$1} = $2;
81     }
82 }
83
84 find(
85     sub {
86         /(\.pm|_pm\.PL)$/ or return;
87         /PPPort\.pm$/ and return;
88         my $module = $File::Find::name;
89         $module =~ /\b(demo|t|private)\b/ and return;    # demo or test modules
90         my $version = MM->parse_version($_);
91         defined $version or $version = 'undef';
92         $version =~ /\d/ and $version = "'$version'";
93
94         # some heuristics to figure out the module name from the file name
95         $module =~ s{^(lib|cpan|dist|(?:symbian/)?ext)/}{}
96                         and $1 ne 'lib'
97             and (
98             $module =~ s{\b(\w+)/\1\b}{$1},
99             $module =~ s{^B/O}{O},
100             $module =~ s{^Devel-PPPort}{Devel},
101             $module =~ s{^libnet/}{},
102             $module =~ s{^Encode/encoding}{encoding},
103             $module =~ s{^IPC-SysV/}{IPC/},
104             $module =~ s{^MIME-Base64/QuotedPrint}{MIME/QuotedPrint},
105             $module =~ s{^(?:DynaLoader|Errno|Opcode|XSLoader)/}{},
106             $module =~ s{^Sys-Syslog/win32}{Sys-Syslog},
107             $module =~ s{^Time-Piece/Seconds}{Time/Seconds},
108             );
109         $module =~ s{^vms/ext}{VMS};
110                 $module =~ s{^lib/}{}g;
111         $module =~ s{/}{::}g;
112         $module =~ s{-}{::}g;
113                 $module =~ s{^.*::lib::}{}; # turns Foo/lib/Foo.pm into Foo.pm
114         $module =~ s/(\.pm|_pm\.PL)$//;
115         $lines{$module}          = $version;
116         $module_to_file{$module} = $File::Find::name;
117     },
118     'vms/ext',
119     'symbian/ext',
120     'lib',
121     'ext',
122         'cpan',
123         'dist'
124 );
125
126 -e 'configpm' and $lines{Config} = 'undef';
127
128 if ( open my $ucdv, "<", "lib/unicore/version" ) {
129     chomp( my $ucd = <$ucdv> );
130     $lines{Unicode} = "'$ucd'";
131     close $ucdv;
132 }
133
134 my $versions_in_release = "    " . $perl_vnum . " => {\n";
135 foreach my $key ( sort keys %lines ) {
136     $versions_in_release .= sprintf "\t%-24s=> %s,\n", "'$key'", $lines{$key};
137 }
138 $versions_in_release .= "    },\n";
139
140 $corelist =~ s/^(%version\s*=\s*.*?)(^\);)$/$1$versions_in_release$2/xism;
141
142 exit unless %modlist;
143
144 # We have to go through this two stage lookup, given how Maintainers.pl keys its
145 # data by "Module", which is really a dist.
146 my $file_to_M = files_to_modules( values %module_to_file );
147
148 sub slurp_utf8($) {
149     open my $fh, "<:utf8", "$_[0]"
150         or die "can't open $_[0] for reading: $!";
151     return do { local $/; <$fh> };
152 }
153
154 sub parse_cpan_meta($) {
155     return Parse::CPAN::Meta->${
156         $_[0] =~ /\A\x7b/ ? \"load_json_string" : \"load_yaml_string"
157     }($_[0]);
158 }
159
160 my %module_to_upstream;
161 my %module_to_dist;
162 my %dist_to_meta_YAML;
163 my %module_to_deprecated;
164 while ( my ( $module, $file ) = each %module_to_file ) {
165     my $M = $file_to_M->{$file};
166     next unless $M;
167     next if $Modules{$M}{MAINTAINER} && $Modules{$M}{MAINTAINER} eq 'p5p';
168     $module_to_upstream{$module} = $Modules{$M}{UPSTREAM};
169     $module_to_deprecated{$module} = 1 if $Modules{$M}{DEPRECATED};
170     next
171         if defined $module_to_upstream{$module}
172             && $module_to_upstream{$module} =~ /^(?:blead|first-come)$/;
173     my $dist = $modlist{$module};
174     unless ($dist) {
175         warn "Can't find a distribution for $module\n";
176         next;
177     }
178     $module_to_dist{$module} = $dist;
179
180     next if exists $dist_to_meta_YAML{$dist};
181
182     $dist_to_meta_YAML{$dist} = undef;
183
184     # Like it or lump it, this has to be Unix format.
185     my $meta_YAML_path = "authors/id/$dist";
186     $meta_YAML_path =~ s/(?:tar\.gz|tar\.bz2|zip|tgz)$/meta/ or die "$meta_YAML_path";
187     my $meta_YAML_url = 'http://ftp.funet.fi/pub/CPAN/' . $meta_YAML_path;
188
189     if ( -e "$cpan/$meta_YAML_path" ) {
190         $dist_to_meta_YAML{$dist} = parse_cpan_meta(slurp_utf8( $cpan . "/" . $meta_YAML_path ));
191     } elsif ( my $content = fetch_url($meta_YAML_url) ) {
192         unless ($content) {
193             warn "Failed to fetch $meta_YAML_url\n";
194             next;
195         }
196         eval { $dist_to_meta_YAML{$dist} = parse_cpan_meta($content); };
197         if ( my $err = $@ ) {
198             warn "$meta_YAML_path: ".$err;
199             next;
200         }
201     } else {
202         warn "$meta_YAML_path does not exist for $module\n";
203
204         # I tried code to open the tarballs with Archive::Tar to find and
205         # extract META.yml, but only Text-Tabs+Wrap-2006.1117.tar.gz had one,
206         # so it's not worth including.
207         next;
208     }
209 }
210
211 my $upstream_stanza = "%upstream = (\n";
212 foreach my $module ( sort keys %module_to_upstream ) {
213     my $upstream = defined $module_to_upstream{$module} ? "'$module_to_upstream{$module}'" : 'undef';
214     $upstream_stanza .= sprintf "    %-24s=> %s,\n", "'$module'", $upstream;
215 }
216 $upstream_stanza .= ");";
217
218 $corelist =~ s/^%upstream .*? ;$/$upstream_stanza/ismx;
219
220 # Deprecation generation
221 my $deprecated_stanza = "    " . $perl_vnum . " => {\n";
222 foreach my $module ( sort keys %module_to_deprecated ) {
223     my $deprecated = defined $module_to_deprecated{$module} ? "'$module_to_deprecated{$module}'" : 'undef';
224     $deprecated_stanza .= sprintf "\t%-24s=> %s,\n", "'$module'", $deprecated;
225 }
226 $deprecated_stanza .= "    },\n";
227 $corelist =~ s/^(%deprecated\s*=\s*.*?)(^\);)$/$1$deprecated_stanza$2/xism;
228
229 my $tracker = "%bug_tracker = (\n";
230 foreach my $module ( sort keys %module_to_upstream ) {
231     my $upstream = defined $module_to_upstream{$module};
232     next
233         if defined $upstream
234             and $upstream eq 'blead' || $upstream eq 'first-come';
235
236     my $bug_tracker;
237
238     my $dist = $module_to_dist{$module};
239     $bug_tracker = $dist_to_meta_YAML{$dist}->{resources}{bugtracker}
240         if $dist;
241     $bug_tracker = $bug_tracker->{web} if ref($bug_tracker) eq "HASH";
242
243     $bug_tracker = defined $bug_tracker ? "'$bug_tracker'" : 'undef';
244         next if $bug_tracker eq "'http://rt.perl.org/perlbug/'";
245     $tracker .= sprintf "    %-24s=> %s,\n", "'$module'", $bug_tracker;
246 }
247 $tracker .= ");";
248
249 $corelist =~ s/^%bug_tracker .*? ;/$tracker/eismx;
250
251 unless (
252     $corelist =~ /^%released \s* = \s* \(
253         .*?
254         $perl_vnum => .*?
255         \);/ismx
256     )
257 {
258     warn "Adding $perl_vnum to the list of released perl versions. Please consider adding a release date.\n";
259     $corelist =~ s/^(%released \s* = \s* .*?) ( \) )
260                 /$1  $perl_vnum => '????-??-??',\n  $2/ismx;
261 }
262
263 write_corelist($corelist,$corelist_file);
264
265 open( my $pod_fh, '<', $pod_file );
266 my $pod = join( '', <$pod_fh> );
267
268 unless ( $pod =~ /and $perl_vstring releases of perl/ ) {
269     warn "Adding $perl_vstring to the list of perl versions covered by Module::CoreList\n";
270     $pod =~ s/(currently covers (?:.*?))\s*and (.*?) releases of perl/$1, $2 and $perl_vstring releases of perl/ism;
271 }
272
273 write_corelist($pod,$pod_file);
274
275 warn "All done. Please check over $corelist_file and $pod_file carefully before committing. Thanks!\n";
276
277
278 sub write_corelist {
279     my $content = shift;
280     my $filename = shift;
281     open (my $clfh, ">", $filename);
282     print $clfh $content;
283     close($clfh);
284 }
285
286 sub fetch_url {
287     my $url = shift;
288     my $http = HTTP::Tiny->new;
289     my $response = $http->get($url);
290     if ($response->{success}) {
291         return $response->{content};
292     } else {
293         warn "Error fetching $url: $response->{status} $response->{reason}\n";
294         return;
295     }
296 }