[perl #64772] allow for sync on read only handles
[perl.git] / lib / overload.pm
1 package overload;
2
3 our $VERSION = '1.19';
4
5 %ops = (
6     with_assign         => "+ - * / % ** << >> x .",
7     assign              => "+= -= *= /= %= **= <<= >>= x= .=",
8     num_comparison      => "< <= >  >= == !=",
9     '3way_comparison'   => "<=> cmp",
10     str_comparison      => "lt le gt ge eq ne",
11     binary              => '& &= | |= ^ ^=',
12     unary               => "neg ! ~",
13     mutators            => '++ --',
14     func                => "atan2 cos sin exp abs log sqrt int",
15     conversion          => 'bool "" 0+ qr',
16     iterators           => '<>',
17     filetest            => "-X",
18     dereferencing       => '${} @{} %{} &{} *{}',
19     matching            => '~~',
20     special             => 'nomethod fallback =',
21 );
22
23 my %ops_seen;
24 for $category (keys %ops) {
25     $ops_seen{$_}++ for (split /\s+/, $ops{$category});
26 }
27
28 sub nil {}
29
30 sub OVERLOAD {
31   $package = shift;
32   my %arg = @_;
33   my ($sub, $fb);
34   *{$package . "::(("} = \&nil; # Make it findable via fetchmethod.
35   for (keys %arg) {
36     if ($_ eq 'fallback') {
37       for my $sym (*{$package . "::()"}) {
38         *$sym = \&nil; # Make it findable via fetchmethod.
39         $$sym = $arg{$_};
40       }
41     } else {
42       warnings::warnif("overload arg '$_' is invalid")
43         unless $ops_seen{$_};
44       $sub = $arg{$_};
45       if (not ref $sub) {
46         $ {$package . "::(" . $_} = $sub;
47         $sub = \&nil;
48       }
49       #print STDERR "Setting '$ {'package'}::\cO$_' to \\&'$sub'.\n";
50       *{$package . "::(" . $_} = \&{ $sub };
51     }
52   }
53 }
54
55 sub import {
56   $package = (caller())[0];
57   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
58   shift;
59   $package->overload::OVERLOAD(@_);
60 }
61
62 sub unimport {
63   $package = (caller())[0];
64   shift;
65   *{$package . "::(("} = \&nil;
66   for (@_) {
67       warnings::warnif("overload arg '$_' is invalid")
68         unless $ops_seen{$_};
69       delete $ {$package . "::"}{$_ eq 'fallback' ? '()' : "(" .$_};
70   }
71 }
72
73 sub Overloaded {
74   my $package = shift;
75   $package = ref $package if ref $package;
76   mycan ($package, '()') || mycan ($package, '((');
77 }
78
79 sub ov_method {
80   my $globref = shift;
81   return undef unless $globref;
82   my $sub = \&{*$globref};
83   no overloading;
84   return $sub if !ref $sub or $sub != \&nil;
85   return shift->can($ {*$globref});
86 }
87
88 sub OverloadedStringify {
89   my $package = shift;
90   $package = ref $package if ref $package;
91   #$package->can('(""')
92   ov_method mycan($package, '(""'), $package
93     or ov_method mycan($package, '(0+'), $package
94     or ov_method mycan($package, '(bool'), $package
95     or ov_method mycan($package, '(nomethod'), $package;
96 }
97
98 sub Method {
99   my $package = shift;
100   if(ref $package) {
101     local $@;
102     local $!;
103     require Scalar::Util;
104     $package = Scalar::Util::blessed($package);
105     return undef if !defined $package;
106   }
107   #my $meth = $package->can('(' . shift);
108   ov_method mycan($package, '(' . shift), $package;
109   #return $meth if $meth ne \&nil;
110   #return $ {*{$meth}};
111 }
112
113 sub AddrRef {
114   no overloading;
115   "$_[0]";
116 }
117
118 *StrVal = *AddrRef;
119
120 sub mycan {                             # Real can would leave stubs.
121   my ($package, $meth) = @_;
122
123   local $@;
124   local $!;
125   require mro;
126
127   my $mro = mro::get_linear_isa($package);
128   foreach my $p (@$mro) {
129     my $fqmeth = $p . q{::} . $meth;
130     return \*{$fqmeth} if defined &{$fqmeth};
131   }
132
133   return undef;
134 }
135
136 %constants = (
137               'integer'   =>  0x1000, # HINT_NEW_INTEGER
138               'float'     =>  0x2000, # HINT_NEW_FLOAT
139               'binary'    =>  0x4000, # HINT_NEW_BINARY
140               'q'         =>  0x8000, # HINT_NEW_STRING
141               'qr'        => 0x10000, # HINT_NEW_RE
142              );
143
144 use warnings::register;
145 sub constant {
146   # Arguments: what, sub
147   while (@_) {
148     if (@_ == 1) {
149         warnings::warnif ("Odd number of arguments for overload::constant");
150         last;
151     }
152     elsif (!exists $constants {$_ [0]}) {
153         warnings::warnif ("'$_[0]' is not an overloadable type");
154     }
155     elsif (!ref $_ [1] || "$_[1]" !~ /(^|=)CODE\(0x[0-9a-f]+\)$/) {
156         # Can't use C<ref $_[1] eq "CODE"> above as code references can be
157         # blessed, and C<ref> would return the package the ref is blessed into.
158         if (warnings::enabled) {
159             $_ [1] = "undef" unless defined $_ [1];
160             warnings::warn ("'$_[1]' is not a code reference");
161         }
162     }
163     else {
164         $^H{$_[0]} = $_[1];
165         $^H |= $constants{$_[0]};
166     }
167     shift, shift;
168   }
169 }
170
171 sub remove_constant {
172   # Arguments: what, sub
173   while (@_) {
174     delete $^H{$_[0]};
175     $^H &= ~ $constants{$_[0]};
176     shift, shift;
177   }
178 }
179
180 1;
181
182 __END__
183
184 =head1 NAME
185
186 overload - Package for overloading Perl operations
187
188 =head1 SYNOPSIS
189
190     package SomeThing;
191
192     use overload
193         '+' => \&myadd,
194         '-' => \&mysub;
195         # etc
196     ...
197
198     package main;
199     $a = SomeThing->new( 57 );
200     $b = 5 + $a;
201     ...
202     if (overload::Overloaded $b) {...}
203     ...
204     $strval = overload::StrVal $b;
205
206 =head1 DESCRIPTION
207
208 This pragma allows overloading of Perl's operators for a class.
209 To overload built-in functions, see L<perlsub/Overriding Built-in Functions> instead.
210
211 =head2 Fundamentals
212
213 =head3 Declaration
214
215 Arguments of the C<use overload> directive are (key, value) pairs.
216 For the full set of legal keys, see L<Overloadable Operations> below.
217
218 Operator implementations (the values) can be subroutines,
219 references to subroutines, or anonymous subroutines
220 - in other words, anything legal inside a C<&{ ... }> call.
221 Values specified as strings are interpreted as method names.
222 Thus
223
224     package Number;
225     use overload
226         "-" => "minus",
227         "*=" => \&muas,
228         '""' => sub { ...; };
229
230 declares that subtraction is to be implemented by method C<minus()>
231 in the class C<Number> (or one of its base classes),
232 and that the function C<Number::muas()> is to be used for the
233 assignment form of multiplication, C<*=>.
234 It also defines an anonymous subroutine to implement stringification:
235 this is called whenever an object blessed into the package C<Number>
236 is used in a string context (this subroutine might, for example,
237 return the number as a Roman numeral).
238
239 =head3 Calling Conventions and Magic Autogeneration
240
241 The following sample implementation of C<minus()> (which assumes
242 that C<Number> objects are simply blessed references to scalars)
243 illustrates the calling conventions:
244
245     package Number;
246     sub minus {
247         my ($self, $other, $swap) = @_;
248         my $result = $$self - $other;         # *
249         $result = -$result if $swap;
250         ref $result ? $result : bless \$result;
251     }
252     # * may recurse once - see table below
253
254 Three arguments are passed to all subroutines specified in the
255 C<use overload> directive (with one exception - see L</nomethod>).
256 The first of these is the operand providing the overloaded
257 operator implementation -
258 in this case, the object whose C<minus()> method is being called.
259
260 The second argument is the other operand, or C<undef> in the
261 case of a unary operator.
262
263 The third argument is set to TRUE if (and only if) the two
264 operands have been swapped.  Perl may do this to ensure that the
265 first argument (C<$self>) is an object implementing the overloaded
266 operation, in line with general object calling conventions.
267 For example, if C<$x> and C<$y> are C<Number>s:
268
269     operation   |   generates a call to
270     ============|======================
271     $x - $y     |   minus($x, $y, '')
272     $x - 7      |   minus($x, 7, '')
273     7 - $x      |   minus($x, 7, 1)
274
275 Perl may also use C<minus()> to implement other operators which
276 have not been specified in the C<use overload> directive,
277 according to the rules for L<Magic Autogeneration> described later.
278 For example, the C<use overload> above declared no subroutine
279 for any of the operators C<-->, C<neg> (the overload key for
280 unary minus), or C<-=>.  Thus
281
282     operation   |   generates a call to
283     ============|======================
284     -$x         |   minus($x, 0, 1)
285     $x--        |   minus($x, 1, undef)
286     $x -= 3     |   minus($x, 3, undef)
287
288 Note the C<undef>s:
289 where autogeneration results in the method for a standard
290 operator which does not change either of its operands, such
291 as C<->, being used to implement an operator which changes
292 the operand ("mutators": here, C<--> and C<-=>),
293 Perl passes undef as the third argument.
294 This still evaluates as FALSE, consistent with the fact that
295 the operands have not been swapped, but gives the subroutine
296 a chance to alter its behaviour in these cases.
297
298 In all the above examples, C<minus()> is required
299 only to return the result of the subtraction:
300 Perl takes care of the assignment to $x.
301 In fact, such methods should I<not> modify their operands,
302 even if C<undef> is passed as the third argument
303 (see L<Overloadable Operations>).
304
305 The same is not true of implementations of C<++> and C<-->:
306 these are expected to modify their operand.
307 An appropriate implementation of C<--> might look like
308
309     use overload '--' => "decr",
310         # ...
311     sub decr { --${$_[0]}; }
312
313 =head3 Mathemagic, Mutators, and Copy Constructors
314
315 The term 'mathemagic' describes the overloaded implementation
316 of mathematical operators.
317 Mathemagical operations raise an issue.
318 Consider the code:
319
320     $a = $b;
321     --$a;
322
323 If C<$a> and C<$b> are scalars then after these statements
324
325     $a == $b - 1
326
327 An object, however, is a reference to blessed data, so if
328 C<$a> and C<$b> are objects then the assignment C<$a = $b>
329 copies only the reference, leaving C<$a> and C<$b> referring
330 to the same object data.
331 One might therefore expect the operation C<--$a> to decrement
332 C<$b> as well as C<$a>.
333 However, this would not be consistent with how we expect the
334 mathematical operators to work.
335
336 Perl resolves this dilemma by transparently calling a copy
337 constructor before calling a method defined to implement
338 a mutator (C<-->, C<+=>, and so on.).
339 In the above example, when Perl reaches the decrement
340 statement, it makes a copy of the object data in C<$a> and
341 assigns to C<$a> a reference to the copied data.
342 Only then does it call C<decr()>, which alters the copied
343 data, leaving C<$b> unchanged.
344 Thus the object metaphor is preserved as far as possible,
345 while mathemagical operations still work according to the
346 arithmetic metaphor.
347
348 Note: the preceding paragraph describes what happens when
349 Perl autogenerates the copy constructor for an object based
350 on a scalar.
351 For other cases, see L<Copy Constructor>.
352
353 =head2 Overloadable Operations
354
355 The complete list of keys that can be specified in the C<use overload>
356 directive are given, separated by spaces, in the values of the
357 hash C<%overload::ops>:
358
359  with_assign      => '+ - * / % ** << >> x .',
360  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
361  num_comparison   => '< <= > >= == !=',
362  '3way_comparison'=> '<=> cmp',
363  str_comparison   => 'lt le gt ge eq ne',
364  binary           => '& &= | |= ^ ^=',
365  unary            => 'neg ! ~',
366  mutators         => '++ --',
367  func             => 'atan2 cos sin exp abs log sqrt int',
368  conversion       => 'bool "" 0+ qr',
369  iterators        => '<>',
370  filetest         => '-X',
371  dereferencing    => '${} @{} %{} &{} *{}',
372  matching         => '~~',
373  special          => 'nomethod fallback ='
374
375 Most of the overloadable operators map one-to-one to these keys.
376 Exceptions, including additional overloadable operations not
377 apparent from this hash, are included in the notes which follow.
378
379 A warning is issued if an attempt is made to register an operator not found
380 above.
381
382 =over 5
383
384 =item * C<not>
385
386 The operator C<not> is not a valid key for C<use overload>.
387 However, if the operator C<!> is overloaded then the same
388 implementation will be used for C<not>
389 (since the two operators differ only in precedence).
390
391 =item * C<neg>
392
393 The key C<neg> is used for unary minus to disambiguate it from
394 binary C<->.
395
396 =item * C<++>, C<-->
397
398 Assuming they are to behave analogously to Perl's C<++> and C<-->,
399 overloaded implementations of these operators are required to
400 mutate their operands.
401
402 No distinction is made between prefix and postfix forms of the
403 increment and decrement operators: these differ only in the
404 point at which Perl calls the associated subroutine when
405 evaluating an expression.
406
407 =item * I<Assignments>
408
409     +=  -=  *=  /=  %=  **=  <<=  >>=  x=  .=
410     &=  |=  ^=
411
412 Simple assignment is not overloadable (the C<'='> key is used
413 for the L<Copy Constructor>).
414 Perl does have a way to make assignments to an object do whatever
415 you want, but this involves using tie(), not overload -
416 see L<perlfunc/tie> and the L</COOKBOOK> examples below.
417
418 The subroutine for the assignment variant of an operator is
419 required only to return the result of the operation.
420 It is permitted to change the value of its operand
421 (this is safe because Perl calls the copy constructor first),
422 but this is optional since Perl assigns the returned value to
423 the left-hand operand anyway.
424
425 An object that overloads an assignment operator does so only in
426 respect of assignments to that object.
427 In other words, Perl never calls the corresponding methods with
428 the third argument (the "swap" argument) set to TRUE.
429 For example, the operation
430
431     $a *= $b
432
433 cannot lead to C<$b>'s implementation of C<*=> being called,
434 even if C<$a> is a scalar.
435 (It can, however, generate a call to C<$b>'s method for C<*>).
436
437 =item * I<Non-mutators with a mutator variant>
438
439      +  -  *  /  %  **  <<  >>  x  .
440      &  |  ^
441
442 As described L<above|"Calling Conventions and Magic Autogeneration">,
443 Perl may call methods for operators like C<+> and C<&> in the course
444 of implementing missing operations like C<++>, C<+=>, and C<&=>.
445 While these methods may detect this usage by testing the definedness
446 of the third argument, they should in all cases avoid changing their
447 operands.
448 This is because Perl does not call the copy constructor before
449 invoking these methods.
450
451 =item * C<int>
452
453 Traditionally, the Perl function C<int> rounds to 0
454 (see L<perlfunc/int>), and so for floating-point-like types one
455 should follow the same semantic.
456
457 =item * I<String, numeric, boolean, and regexp conversions>
458
459     ""  0+  bool
460
461 These conversions are invoked according to context as necessary.
462 For example, the subroutine for C<'""'> (stringify) may be used
463 where the overloaded object is passed as an argument to C<print>,
464 and that for C<'bool'> where it is tested in the condition of a flow
465 control statement (like C<while>) or the ternary C<?:> operation.
466
467 Of course, in contexts like, for example, C<$obj + 1>, Perl will
468 invoke C<$obj>'s implementation of C<+> rather than (in this
469 example) converting C<$obj> to a number using the numify method
470 C<'0+'> (an exception to this is when no method has been provided
471 for C<'+'> and L</fallback> is set to TRUE).
472
473 The subroutines for C<'""'>, C<'0+'>, and C<'bool'> can return
474 any arbitrary Perl value.
475 If the corresponding operation for this value is overloaded too,
476 the operation will be called again with this value.
477
478 As a special case if the overload returns the object itself then it will
479 be used directly.  An overloaded conversion returning the object is
480 probably a bug, because you're likely to get something that looks like
481 C<YourPackage=HASH(0x8172b34)>.
482
483     qr
484
485 The subroutine for C<'qr'> is used wherever the object is
486 interpolated into or used as a regexp, including when it
487 appears on the RHS of a C<=~> or C<!~> operator.
488
489 C<qr> must return a compiled regexp, or a ref to a compiled regexp
490 (such as C<qr//> returns), and any further overloading on the return
491 value will be ignored.
492
493 =item * I<Iteration>
494
495 If C<E<lt>E<gt>> is overloaded then the same implementation is used
496 for both the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
497 I<globbing> syntax C<E<lt>${var}E<gt>>.
498
499 B<BUGS> Even in list context, the iterator is currently called only
500 once and with scalar context.
501
502 =item * I<File tests>
503
504 The key C<'-X'> is used to specify a subroutine to handle all the
505 filetest operators (C<-f>, C<-x>, and so on: see L<perlfunc/-X> for
506 the full list);
507 it is not possible to overload any filetest operator individually.
508 To distinguish them, the letter following the '-' is passed as the
509 second argument (that is, in the slot that for binary operators
510 is used to pass the second operand).
511
512 Calling an overloaded filetest operator does not affect the stat value
513 associated with the special filehandle C<_>.  It still refers to the
514 result of the last C<stat>, C<lstat> or unoverloaded filetest.
515
516 This overload was introduced in Perl 5.12.
517
518 =item * I<Matching>
519
520 The key C<"~~"> allows you to override the smart matching logic used by
521 the C<~~> operator and the switch construct (C<given>/C<when>).  See
522 L<perlsyn/Switch Statements> and L<feature>.
523
524 Unusually, the overloaded implementation of the smart match operator
525 does not get full control of the smart match behaviour.
526 In particular, in the following code:
527
528     package Foo;
529     use overload '~~' => 'match';
530
531     my $obj =  Foo->new();
532     $obj ~~ [ 1,2,3 ];
533
534 the smart match does I<not> invoke the method call like this:
535
536     $obj->match([1,2,3],0);
537
538 rather, the smart match distributive rule takes precedence, so $obj is
539 smart matched against each array element in turn until a match is found,
540 so you may see between one and three of these calls instead:
541
542     $obj->match(1,0);
543     $obj->match(2,0);
544     $obj->match(3,0);
545
546 Consult the match table in  L<perlop/"Smartmatch Operator"> for
547 details of when overloading is invoked.
548
549 =item * I<Dereferencing>
550
551     ${}  @{}  %{}  &{}  *{}
552
553 If these operators are not explicitly overloaded then they
554 work in the normal way, yielding the underlying scalar,
555 array, or whatever stores the object data (or the appropriate
556 error message if the dereference operator doesn't match it).
557 Defining a catch-all C<'nomethod'> (see L<below|/nomethod>)
558 makes no difference to this as the catch-all function will
559 not be called to implement a missing dereference operator.
560
561 If a dereference operator is overloaded then it must return a
562 I<reference> of the appropriate type (for example, the
563 subroutine for key C<'${}'> should return a reference to a
564 scalar, not a scalar), or another object which overloads the
565 operator: that is, the subroutine only determines what is
566 dereferenced and the actual dereferencing is left to Perl.
567 As a special case, if the subroutine returns the object itself
568 then it will not be called again - avoiding infinite recursion.
569
570 =item * I<Special>
571
572     nomethod  fallback  =
573
574 See L<Special Keys for C<use overload>>.
575
576 =back
577
578 =head2 Magic Autogeneration
579
580 If a method for an operation is not found then Perl tries to
581 autogenerate a substitute implementation from the operations
582 that have been defined.
583
584 Note: the behaviour described in this section can be disabled
585 by setting C<fallback> to FALSE (see L</fallback>).
586
587 In the following tables, numbers indicate priority.
588 For example, the table below states that,
589 if no implementation for C<'!'> has been defined then Perl will
590 implement it using C<'bool'> (that is, by inverting the value
591 returned by the method for C<'bool'>);
592 if boolean conversion is also unimplemented then Perl will
593 use C<'0+'> or, failing that, C<'""'>.
594
595     operator | can be autogenerated from
596              |
597              | 0+   ""   bool   .   x
598     =========|==========================
599        0+    |       1     2
600        ""    |  1          2
601        bool  |  1    2
602        int   |  1    2     3
603        !     |  2    3     1
604        qr    |  2    1     3
605        .     |  2    1     3
606        x     |  2    1     3
607        .=    |  3    2     4    1
608        x=    |  3    2     4        1
609        <>    |  2    1     3
610        -X    |  2    1     3
611
612 Note: The iterator (C<'E<lt>E<gt>'>) and file test (C<'-X'>)
613 operators work as normal: if the operand is not a blessed glob or
614 IO reference then it is converted to a string (using the method
615 for C<'""'>, C<'0+'>, or C<'bool'>) to be interpreted as a glob
616 or filename.
617
618     operator | can be autogenerated from
619              |
620              |  <   <=>   neg   -=    -
621     =========|==========================
622        neg   |                        1
623        -=    |                        1
624        --    |                   1    2
625        abs   | a1    a2    b1        b2    [*]
626        <     |        1
627        <=    |        1
628        >     |        1
629        >=    |        1
630        ==    |        1
631        !=    |        1
632
633     * one from [a1, a2] and one from [b1, b2]
634
635 Just as numeric comparisons can be autogenerated from the method
636 for C<< '<=>' >>, string comparisons can be autogenerated from
637 that for C<'cmp'>:
638
639      operators          |  can be autogenerated from
640     ====================|===========================
641      lt gt le ge eq ne  |  cmp
642
643 Similarly, autogeneration for keys C<'+='> and C<'++'> is analogous
644 to C<'-='> and C<'--'> above:
645
646     operator | can be autogenerated from
647              |
648              |  +=    +
649     =========|==========================
650         +=   |        1
651         ++   |   1    2
652
653 And other assignment variations are analogous to
654 C<'+='> and C<'-='> (and similar to C<'.='> and C<'x='> above):
655
656               operator ||  *= /= %= **= <<= >>= &= ^= |=
657     -------------------||--------------------------------
658     autogenerated from ||  *  /  %  **  <<  >>  &  ^  |
659
660 Note also that the copy constructor (key C<'='>) may be
661 autogenerated, but only for objects based on scalars.
662 See L<Copy Constructor>.
663
664 =head3 Minimal Set of Overloaded Operations
665
666 Since some operations can be automatically generated from others, there is
667 a minimal set of operations that need to be overloaded in order to have
668 the complete set of overloaded operations at one's disposal.
669 Of course, the autogenerated operations may not do exactly what the user
670 expects.  The minimal set is:
671
672     + - * / % ** << >> x
673     <=> cmp
674     & | ^ ~
675     atan2 cos sin exp log sqrt int
676     "" 0+ bool
677     ~~
678
679 Of the conversions, only one of string, boolean or numeric is
680 needed because each can be generated from either of the other two.
681
682 =head2 Special Keys for C<use overload>
683
684 =head3 C<nomethod>
685
686 The C<'nomethod'> key is used to specify a catch-all function to
687 be called for any operator that is not individually overloaded.
688 The specified function will be passed four parameters.
689 The first three arguments coincide with those that would have been
690 passed to the corresponding method if it had been defined.
691 The fourth argument is the C<use overload> key for that missing
692 method.
693
694 For example, if C<$a> is an object blessed into a package declaring
695
696     use overload 'nomethod' => 'catch_all', # ...
697
698 then the operation
699
700     3 + $a
701
702 could (unless a method is specifically declared for the key
703 C<'+'>) result in a call
704
705     catch_all($a, 3, 1, '+')
706
707 See L<How Perl Chooses an Operator Implementation>.
708
709 =head3 C<fallback>
710
711 The value assigned to the key C<'fallback'> tells Perl how hard
712 it should try to find an alternative way to implement a missing
713 operator.
714
715 =over
716
717 =item * defined, but FALSE
718
719     use overload "fallback" => 0, # ... ;
720
721 This disables L<Magic Autogeneration>.
722
723 =item * C<undef>
724
725 In the default case where no value is explicitly assigned to
726 C<fallback>, magic autogeneration is enabled.
727
728 =item * TRUE
729
730 The same as for C<undef>, but if a missing operator cannot be
731 autogenerated then, instead of issuing an error message, Perl
732 is allowed to revert to what it would have done for that
733 operator if there had been no C<use overload> directive.
734
735 Note: in most cases, particularly the L<Copy Constructor>,
736 this is unlikely to be appropriate behaviour.
737
738 =back
739
740 See L<How Perl Chooses an Operator Implementation>.
741
742 =head3 Copy Constructor
743
744 As mentioned L<above|"Mathemagic, Mutators, and Copy Constructors">,
745 this operation is called when a mutator is applied to a reference
746 that shares its object with some other reference.
747 For example, if C<$b> is mathemagical, and C<'++'> is overloaded
748 with C<'incr'>, and C<'='> is overloaded with C<'clone'>, then the
749 code
750
751     $a = $b;
752     # ... (other code which does not modify $a or $b) ...
753     ++$b;
754
755 would be executed in a manner equivalent to
756
757     $a = $b;
758     # ...
759     $b = $b->clone(undef, "");
760     $b->incr(undef, "");
761
762 Note:
763
764 =over
765
766 =item *
767
768 The subroutine for C<'='> does not overload the Perl assignment
769 operator: it is used only to allow mutators to work as described
770 here.  (See L</Assignments> above.)
771
772 =item *
773
774 As for other operations, the subroutine implementing '=' is passed
775 three arguments, though the last two are always C<undef> and C<''>.
776
777 =item *
778
779 The copy constructor is called only before a call to a function
780 declared to implement a mutator, for example, if C<++$b;> in the
781 code above is effected via a method declared for key C<'++'>
782 (or 'nomethod', passed C<'++'> as the fourth argument) or, by
783 autogeneration, C<'+='>.
784 It is not called if the increment operation is effected by a call
785 to the method for C<'+'> since, in the equivalent code,
786
787     $a = $b;
788     $b = $b + 1;
789
790 the data referred to by C<$a> is unchanged by the assignment to
791 C<$b> of a reference to new object data.
792
793 =item *
794
795 The copy constructor is not called if Perl determines that it is
796 unnecessary because there is no other reference to the data being
797 modified.
798
799 =item *
800
801 If C<'fallback'> is undefined or TRUE then a copy constructor
802 can be autogenerated, but only for objects based on scalars.
803 In other cases it needs to be defined explicitly.
804 Where an object's data is stored as, for example, an array of
805 scalars, the following might be appropriate:
806
807     use overload '=' => sub { bless [ @{$_[0]} ] },  # ...
808
809 =item *
810
811 If C<'fallback'> is TRUE and no copy constructor is defined then,
812 for objects not based on scalars, Perl may silently fall back on
813 simple assignment - that is, assignment of the object reference.
814 In effect, this disables the copy constructor mechanism since
815 no new copy of the object data is created.
816 This is almost certainly not what you want.
817 (It is, however, consistent: for example, Perl's fallback for the
818 C<++> operator is to increment the reference itself.)
819
820 =back
821
822 =head2 How Perl Chooses an Operator Implementation
823
824 Which is checked first, C<nomethod> or C<fallback>?
825 If the two operands of an operator are of different types and
826 both overload the operator, which implementation is used?
827 The following are the precedence rules:
828
829 =over
830
831 =item 1.
832
833 If the first operand has declared a subroutine to overload the
834 operator then use that implementation.
835
836 =item 2.
837
838 Otherwise, if fallback is TRUE or undefined for the
839 first operand then see if the
840 L<rules for autogeneration|"Magic Autogeneration">
841 allows another of its operators to be used instead.
842
843 =item 3.
844
845 Unless the operator is an assignment (C<+=>, C<-=>, etc.),
846 repeat step (1) in respect of the second operand.
847
848 =item 4.
849
850 Repeat Step (2) in respect of the second operand.
851
852 =item 5.
853
854 If the first operand has a "nomethod" method then use that.
855
856 =item 6.
857
858 If the second operand has a "nomethod" method then use that.
859
860 =item 7.
861
862 If C<fallback> is TRUE for both operands
863 then perform the usual operation for the operator,
864 treating the operands as numbers, strings, or booleans
865 as appropriate for the operator (see note).
866
867 =item 8.
868
869 Nothing worked - die.
870
871 =back
872
873 Where there is only one operand (or only one operand with
874 overloading) the checks in respect of the other operand above are
875 skipped.
876
877 There are exceptions to the above rules for dereference operations
878 (which, if Step 1 fails, always fall back to the normal, built-in
879 implementations - see Dereferencing), and for C<~~> (which has its
880 own set of rules - see C<Matching> under L</Overloadable Operations>
881 above).
882
883 Note on Step 7: some operators have a different semantic depending
884 on the type of their operands.
885 As there is no way to instruct Perl to treat the operands as, e.g.,
886 numbers instead of strings, the result here may not be what you
887 expect.
888 See L<BUGS AND PITFALLS>.
889
890 =head2 Losing Overloading
891
892 The restriction for the comparison operation is that even if, for example,
893 C<cmp> should return a blessed reference, the autogenerated C<lt>
894 function will produce only a standard logical value based on the
895 numerical value of the result of C<cmp>.  In particular, a working
896 numeric conversion is needed in this case (possibly expressed in terms of
897 other conversions).
898
899 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
900 if the string conversion substitution is applied.
901
902 When you chop() a mathemagical object it is promoted to a string and its
903 mathemagical properties are lost.  The same can happen with other
904 operations as well.
905
906 =head2 Inheritance and Overloading
907
908 Overloading respects inheritance via the @ISA hierarchy.
909 Inheritance interacts with overloading in two ways.
910
911 =over
912
913 =item Method names in the C<use overload> directive
914
915 If C<value> in
916
917   use overload key => value;
918
919 is a string, it is interpreted as a method name - which may
920 (in the usual way) be inherited from another class.
921
922 =item Overloading of an operation is inherited by derived classes
923
924 Any class derived from an overloaded class is also overloaded
925 and inherits its operator implementations.
926 If the same operator is overloaded in more than one ancestor
927 then the implementation is determined by the usual inheritance
928 rules.
929
930 For example, if C<A> inherits from C<B> and C<C> (in that order),
931 C<B> overloads C<+> with C<\&D::plus_sub>, and C<C> overloads
932 C<+> by C<"plus_meth">, then the subroutine C<D::plus_sub> will
933 be called to implement operation C<+> for an object in package C<A>.
934
935 =back
936
937 Note that in Perl version prior to 5.18 inheritance of the C<fallback> key
938 was not governed by the above rules.  The value of C<fallback> in the first 
939 overloaded ancestor was used.  This was fixed in 5.18 to follow the usual
940 rules of inheritance.
941
942 =head2 Run-time Overloading
943
944 Since all C<use> directives are executed at compile-time, the only way to
945 change overloading during run-time is to
946
947     eval 'use overload "+" => \&addmethod';
948
949 You can also use
950
951     eval 'no overload "+", "--", "<="';
952
953 though the use of these constructs during run-time is questionable.
954
955 =head2 Public Functions
956
957 Package C<overload.pm> provides the following public functions:
958
959 =over 5
960
961 =item overload::StrVal(arg)
962
963 Gives the string value of C<arg> as in the
964 absence of stringify overloading.  If you
965 are using this to get the address of a reference (useful for checking if two
966 references point to the same thing) then you may be better off using
967 C<Scalar::Util::refaddr()>, which is faster.
968
969 =item overload::Overloaded(arg)
970
971 Returns true if C<arg> is subject to overloading of some operations.
972
973 =item overload::Method(obj,op)
974
975 Returns C<undef> or a reference to the method that implements C<op>.
976
977 =back
978
979 =head2 Overloading Constants
980
981 For some applications, the Perl parser mangles constants too much.
982 It is possible to hook into this process via C<overload::constant()>
983 and C<overload::remove_constant()> functions.
984
985 These functions take a hash as an argument.  The recognized keys of this hash
986 are:
987
988 =over 8
989
990 =item integer
991
992 to overload integer constants,
993
994 =item float
995
996 to overload floating point constants,
997
998 =item binary
999
1000 to overload octal and hexadecimal constants,
1001
1002 =item q
1003
1004 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
1005 strings and here-documents,
1006
1007 =item qr
1008
1009 to overload constant pieces of regular expressions.
1010
1011 =back
1012
1013 The corresponding values are references to functions which take three arguments:
1014 the first one is the I<initial> string form of the constant, the second one
1015 is how Perl interprets this constant, the third one is how the constant is used.
1016 Note that the initial string form does not
1017 contain string delimiters, and has backslashes in backslash-delimiter
1018 combinations stripped (thus the value of delimiter is not relevant for
1019 processing of this string).  The return value of this function is how this
1020 constant is going to be interpreted by Perl.  The third argument is undefined
1021 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
1022 context (comes from strings, regular expressions, and single-quote HERE
1023 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
1024 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
1025
1026 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
1027 it is expected that overloaded constant strings are equipped with reasonable
1028 overloaded catenation operator, otherwise absurd results will result.
1029 Similarly, negative numbers are considered as negations of positive constants.
1030
1031 Note that it is probably meaningless to call the functions overload::constant()
1032 and overload::remove_constant() from anywhere but import() and unimport() methods.
1033 From these methods they may be called as
1034
1035     sub import {
1036        shift;
1037        return unless @_;
1038        die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
1039        overload::constant integer => sub {Math::BigInt->new(shift)};
1040     }
1041
1042 =head1 IMPLEMENTATION
1043
1044 What follows is subject to change RSN.
1045
1046 The table of methods for all operations is cached in magic for the
1047 symbol table hash for the package.  The cache is invalidated during
1048 processing of C<use overload>, C<no overload>, new function
1049 definitions, and changes in @ISA.
1050
1051 (Every SVish thing has a magic queue, and magic is an entry in that
1052 queue.  This is how a single variable may participate in multiple
1053 forms of magic simultaneously.  For instance, environment variables
1054 regularly have two forms at once: their %ENV magic and their taint
1055 magic.  However, the magic which implements overloading is applied to
1056 the stashes, which are rarely used directly, thus should not slow down
1057 Perl.)
1058
1059 If a package uses overload, it carries a special flag.  This flag is also
1060 set when new function are defined or @ISA is modified.  There will be a
1061 slight speed penalty on the very first operation thereafter that supports
1062 overloading, while the overload tables are updated.  If there is no
1063 overloading present, the flag is turned off.  Thus the only speed penalty
1064 thereafter is the checking of this flag.
1065
1066 It is expected that arguments to methods that are not explicitly supposed
1067 to be changed are constant (but this is not enforced).
1068
1069 =head1 COOKBOOK
1070
1071 Please add examples to what follows!
1072
1073 =head2 Two-face Scalars
1074
1075 Put this in F<two_face.pm> in your Perl library directory:
1076
1077   package two_face;             # Scalars with separate string and
1078                                 # numeric values.
1079   sub new { my $p = shift; bless [@_], $p }
1080   use overload '""' => \&str, '0+' => \&num, fallback => 1;
1081   sub num {shift->[1]}
1082   sub str {shift->[0]}
1083
1084 Use it as follows:
1085
1086   require two_face;
1087   my $seven = two_face->new("vii", 7);
1088   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
1089   print "seven contains 'i'\n" if $seven =~ /i/;
1090
1091 (The second line creates a scalar which has both a string value, and a
1092 numeric value.)  This prints:
1093
1094   seven=vii, seven=7, eight=8
1095   seven contains 'i'
1096
1097 =head2 Two-face References
1098
1099 Suppose you want to create an object which is accessible as both an
1100 array reference and a hash reference.
1101
1102   package two_refs;
1103   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
1104   sub new {
1105     my $p = shift;
1106     bless \ [@_], $p;
1107   }
1108   sub gethash {
1109     my %h;
1110     my $self = shift;
1111     tie %h, ref $self, $self;
1112     \%h;
1113   }
1114
1115   sub TIEHASH { my $p = shift; bless \ shift, $p }
1116   my %fields;
1117   my $i = 0;
1118   $fields{$_} = $i++ foreach qw{zero one two three};
1119   sub STORE {
1120     my $self = ${shift()};
1121     my $key = $fields{shift()};
1122     defined $key or die "Out of band access";
1123     $$self->[$key] = shift;
1124   }
1125   sub FETCH {
1126     my $self = ${shift()};
1127     my $key = $fields{shift()};
1128     defined $key or die "Out of band access";
1129     $$self->[$key];
1130   }
1131
1132 Now one can access an object using both the array and hash syntax:
1133
1134   my $bar = two_refs->new(3,4,5,6);
1135   $bar->[2] = 11;
1136   $bar->{two} == 11 or die 'bad hash fetch';
1137
1138 Note several important features of this example.  First of all, the
1139 I<actual> type of $bar is a scalar reference, and we do not overload
1140 the scalar dereference.  Thus we can get the I<actual> non-overloaded
1141 contents of $bar by just using C<$$bar> (what we do in functions which
1142 overload dereference).  Similarly, the object returned by the
1143 TIEHASH() method is a scalar reference.
1144
1145 Second, we create a new tied hash each time the hash syntax is used.
1146 This allows us not to worry about a possibility of a reference loop,
1147 which would lead to a memory leak.
1148
1149 Both these problems can be cured.  Say, if we want to overload hash
1150 dereference on a reference to an object which is I<implemented> as a
1151 hash itself, the only problem one has to circumvent is how to access
1152 this I<actual> hash (as opposed to the I<virtual> hash exhibited by the
1153 overloaded dereference operator).  Here is one possible fetching routine:
1154
1155   sub access_hash {
1156     my ($self, $key) = (shift, shift);
1157     my $class = ref $self;
1158     bless $self, 'overload::dummy'; # Disable overloading of %{}
1159     my $out = $self->{$key};
1160     bless $self, $class;        # Restore overloading
1161     $out;
1162   }
1163
1164 To remove creation of the tied hash on each access, one may an extra
1165 level of indirection which allows a non-circular structure of references:
1166
1167   package two_refs1;
1168   use overload '%{}' => sub { ${shift()}->[1] },
1169                '@{}' => sub { ${shift()}->[0] };
1170   sub new {
1171     my $p = shift;
1172     my $a = [@_];
1173     my %h;
1174     tie %h, $p, $a;
1175     bless \ [$a, \%h], $p;
1176   }
1177   sub gethash {
1178     my %h;
1179     my $self = shift;
1180     tie %h, ref $self, $self;
1181     \%h;
1182   }
1183
1184   sub TIEHASH { my $p = shift; bless \ shift, $p }
1185   my %fields;
1186   my $i = 0;
1187   $fields{$_} = $i++ foreach qw{zero one two three};
1188   sub STORE {
1189     my $a = ${shift()};
1190     my $key = $fields{shift()};
1191     defined $key or die "Out of band access";
1192     $a->[$key] = shift;
1193   }
1194   sub FETCH {
1195     my $a = ${shift()};
1196     my $key = $fields{shift()};
1197     defined $key or die "Out of band access";
1198     $a->[$key];
1199   }
1200
1201 Now if $baz is overloaded like this, then C<$baz> is a reference to a
1202 reference to the intermediate array, which keeps a reference to an
1203 actual array, and the access hash.  The tie()ing object for the access
1204 hash is a reference to a reference to the actual array, so
1205
1206 =over
1207
1208 =item *
1209
1210 There are no loops of references.
1211
1212 =item *
1213
1214 Both "objects" which are blessed into the class C<two_refs1> are
1215 references to a reference to an array, thus references to a I<scalar>.
1216 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1217 overloaded operations.
1218
1219 =back
1220
1221 =head2 Symbolic Calculator
1222
1223 Put this in F<symbolic.pm> in your Perl library directory:
1224
1225   package symbolic;             # Primitive symbolic calculator
1226   use overload nomethod => \&wrap;
1227
1228   sub new { shift; bless ['n', @_] }
1229   sub wrap {
1230     my ($obj, $other, $inv, $meth) = @_;
1231     ($obj, $other) = ($other, $obj) if $inv;
1232     bless [$meth, $obj, $other];
1233   }
1234
1235 This module is very unusual as overloaded modules go: it does not
1236 provide any usual overloaded operators, instead it provides an
1237 implementation for L<C<nomethod>>.  In this example the C<nomethod>
1238 subroutine returns an object which encapsulates operations done over
1239 the objects: C<< symbolic->new(3) >> contains C<['n', 3]>, C<< 2 +
1240 symbolic->new(3) >> contains C<['+', 2, ['n', 3]]>.
1241
1242 Here is an example of the script which "calculates" the side of
1243 circumscribed octagon using the above package:
1244
1245   require symbolic;
1246   my $iter = 1;                 # 2**($iter+2) = 8
1247   my $side = symbolic->new(1);
1248   my $cnt = $iter;
1249
1250   while ($cnt--) {
1251     $side = (sqrt(1 + $side**2) - 1)/$side;
1252   }
1253   print "OK\n";
1254
1255 The value of $side is
1256
1257   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1258                        undef], 1], ['n', 1]]
1259
1260 Note that while we obtained this value using a nice little script,
1261 there is no simple way to I<use> this value.  In fact this value may
1262 be inspected in debugger (see L<perldebug>), but only if
1263 C<bareStringify> B<O>ption is set, and not via C<p> command.
1264
1265 If one attempts to print this value, then the overloaded operator
1266 C<""> will be called, which will call C<nomethod> operator.  The
1267 result of this operator will be stringified again, but this result is
1268 again of type C<symbolic>, which will lead to an infinite loop.
1269
1270 Add a pretty-printer method to the module F<symbolic.pm>:
1271
1272   sub pretty {
1273     my ($meth, $a, $b) = @{+shift};
1274     $a = 'u' unless defined $a;
1275     $b = 'u' unless defined $b;
1276     $a = $a->pretty if ref $a;
1277     $b = $b->pretty if ref $b;
1278     "[$meth $a $b]";
1279   }
1280
1281 Now one can finish the script by
1282
1283   print "side = ", $side->pretty, "\n";
1284
1285 The method C<pretty> is doing object-to-string conversion, so it
1286 is natural to overload the operator C<""> using this method.  However,
1287 inside such a method it is not necessary to pretty-print the
1288 I<components> $a and $b of an object.  In the above subroutine
1289 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1290 and $b.  If these components use overloading, the catenation operator
1291 will look for an overloaded operator C<.>; if not present, it will
1292 look for an overloaded operator C<"">.  Thus it is enough to use
1293
1294   use overload nomethod => \&wrap, '""' => \&str;
1295   sub str {
1296     my ($meth, $a, $b) = @{+shift};
1297     $a = 'u' unless defined $a;
1298     $b = 'u' unless defined $b;
1299     "[$meth $a $b]";
1300   }
1301
1302 Now one can change the last line of the script to
1303
1304   print "side = $side\n";
1305
1306 which outputs
1307
1308   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1309
1310 and one can inspect the value in debugger using all the possible
1311 methods.
1312
1313 Something is still amiss: consider the loop variable $cnt of the
1314 script.  It was a number, not an object.  We cannot make this value of
1315 type C<symbolic>, since then the loop will not terminate.
1316
1317 Indeed, to terminate the cycle, the $cnt should become false.
1318 However, the operator C<bool> for checking falsity is overloaded (this
1319 time via overloaded C<"">), and returns a long string, thus any object
1320 of type C<symbolic> is true.  To overcome this, we need a way to
1321 compare an object to 0.  In fact, it is easier to write a numeric
1322 conversion routine.
1323
1324 Here is the text of F<symbolic.pm> with such a routine added (and
1325 slightly modified str()):
1326
1327   package symbolic;             # Primitive symbolic calculator
1328   use overload
1329     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1330
1331   sub new { shift; bless ['n', @_] }
1332   sub wrap {
1333     my ($obj, $other, $inv, $meth) = @_;
1334     ($obj, $other) = ($other, $obj) if $inv;
1335     bless [$meth, $obj, $other];
1336   }
1337   sub str {
1338     my ($meth, $a, $b) = @{+shift};
1339     $a = 'u' unless defined $a;
1340     if (defined $b) {
1341       "[$meth $a $b]";
1342     } else {
1343       "[$meth $a]";
1344     }
1345   }
1346   my %subr = ( n => sub {$_[0]},
1347                sqrt => sub {sqrt $_[0]},
1348                '-' => sub {shift() - shift()},
1349                '+' => sub {shift() + shift()},
1350                '/' => sub {shift() / shift()},
1351                '*' => sub {shift() * shift()},
1352                '**' => sub {shift() ** shift()},
1353              );
1354   sub num {
1355     my ($meth, $a, $b) = @{+shift};
1356     my $subr = $subr{$meth}
1357       or die "Do not know how to ($meth) in symbolic";
1358     $a = $a->num if ref $a eq __PACKAGE__;
1359     $b = $b->num if ref $b eq __PACKAGE__;
1360     $subr->($a,$b);
1361   }
1362
1363 All the work of numeric conversion is done in %subr and num().  Of
1364 course, %subr is not complete, it contains only operators used in the
1365 example below.  Here is the extra-credit question: why do we need an
1366 explicit recursion in num()?  (Answer is at the end of this section.)
1367
1368 Use this module like this:
1369
1370   require symbolic;
1371   my $iter = symbolic->new(2);  # 16-gon
1372   my $side = symbolic->new(1);
1373   my $cnt = $iter;
1374
1375   while ($cnt) {
1376     $cnt = $cnt - 1;            # Mutator '--' not implemented
1377     $side = (sqrt(1 + $side**2) - 1)/$side;
1378   }
1379   printf "%s=%f\n", $side, $side;
1380   printf "pi=%f\n", $side*(2**($iter+2));
1381
1382 It prints (without so many line breaks)
1383
1384   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1385                           [n 1]] 2]]] 1]
1386      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1387   pi=3.182598
1388
1389 The above module is very primitive.  It does not implement
1390 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1391 (not required without mutators!), and implements only those arithmetic
1392 operations which are used in the example.
1393
1394 To implement most arithmetic operations is easy; one should just use
1395 the tables of operations, and change the code which fills %subr to
1396
1397   my %subr = ( 'n' => sub {$_[0]} );
1398   foreach my $op (split " ", $overload::ops{with_assign}) {
1399     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1400   }
1401   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1402   foreach my $op (split " ", "@overload::ops{ @bins }") {
1403     $subr{$op} = eval "sub {shift() $op shift()}";
1404   }
1405   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1406     print "defining '$op'\n";
1407     $subr{$op} = eval "sub {$op shift()}";
1408   }
1409
1410 Since subroutines implementing assignment operators are not required
1411 to modify their operands (see L<Overloadable Operations> above),
1412 we do not need anything special to make C<+=> and friends work,
1413 besides adding these operators to %subr and defining a copy
1414 constructor (needed since Perl has no way to know that the
1415 implementation of C<'+='> does not mutate the argument -
1416 see L<Copy Constructor>).
1417
1418 To implement a copy constructor, add C<< '=' => \&cpy >> to C<use overload>
1419 line, and code (this code assumes that mutators change things one level
1420 deep only, so recursive copying is not needed):
1421
1422   sub cpy {
1423     my $self = shift;
1424     bless [@$self], ref $self;
1425   }
1426
1427 To make C<++> and C<--> work, we need to implement actual mutators,
1428 either directly, or in C<nomethod>.  We continue to do things inside
1429 C<nomethod>, thus add
1430
1431     if ($meth eq '++' or $meth eq '--') {
1432       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1433       return $obj;
1434     }
1435
1436 after the first line of wrap().  This is not a most effective
1437 implementation, one may consider
1438
1439   sub inc { $_[0] = bless ['++', shift, 1]; }
1440
1441 instead.
1442
1443 As a final remark, note that one can fill %subr by
1444
1445   my %subr = ( 'n' => sub {$_[0]} );
1446   foreach my $op (split " ", $overload::ops{with_assign}) {
1447     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1448   }
1449   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1450   foreach my $op (split " ", "@overload::ops{ @bins }") {
1451     $subr{$op} = eval "sub {shift() $op shift()}";
1452   }
1453   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1454     $subr{$op} = eval "sub {$op shift()}";
1455   }
1456   $subr{'++'} = $subr{'+'};
1457   $subr{'--'} = $subr{'-'};
1458
1459 This finishes implementation of a primitive symbolic calculator in
1460 50 lines of Perl code.  Since the numeric values of subexpressions
1461 are not cached, the calculator is very slow.
1462
1463 Here is the answer for the exercise: In the case of str(), we need no
1464 explicit recursion since the overloaded C<.>-operator will fall back
1465 to an existing overloaded operator C<"">.  Overloaded arithmetic
1466 operators I<do not> fall back to numeric conversion if C<fallback> is
1467 not explicitly requested.  Thus without an explicit recursion num()
1468 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1469 the argument of num().
1470
1471 If you wonder why defaults for conversion are different for str() and
1472 num(), note how easy it was to write the symbolic calculator.  This
1473 simplicity is due to an appropriate choice of defaults.  One extra
1474 note: due to the explicit recursion num() is more fragile than sym():
1475 we need to explicitly check for the type of $a and $b.  If components
1476 $a and $b happen to be of some related type, this may lead to problems.
1477
1478 =head2 I<Really> Symbolic Calculator
1479
1480 One may wonder why we call the above calculator symbolic.  The reason
1481 is that the actual calculation of the value of expression is postponed
1482 until the value is I<used>.
1483
1484 To see it in action, add a method
1485
1486   sub STORE {
1487     my $obj = shift;
1488     $#$obj = 1;
1489     @$obj->[0,1] = ('=', shift);
1490   }
1491
1492 to the package C<symbolic>.  After this change one can do
1493
1494   my $a = symbolic->new(3);
1495   my $b = symbolic->new(4);
1496   my $c = sqrt($a**2 + $b**2);
1497
1498 and the numeric value of $c becomes 5.  However, after calling
1499
1500   $a->STORE(12);  $b->STORE(5);
1501
1502 the numeric value of $c becomes 13.  There is no doubt now that the module
1503 symbolic provides a I<symbolic> calculator indeed.
1504
1505 To hide the rough edges under the hood, provide a tie()d interface to the
1506 package C<symbolic>.  Add methods
1507
1508   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1509   sub FETCH { shift }
1510   sub nop {  }          # Around a bug
1511
1512 (the bug, fixed in Perl 5.14, is described in L<"BUGS">).  One can use this
1513 new interface as
1514
1515   tie $a, 'symbolic', 3;
1516   tie $b, 'symbolic', 4;
1517   $a->nop;  $b->nop;    # Around a bug
1518
1519   my $c = sqrt($a**2 + $b**2);
1520
1521 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1522 of $c becomes 13.  To insulate the user of the module add a method
1523
1524   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1525
1526 Now
1527
1528   my ($a, $b);
1529   symbolic->vars($a, $b);
1530   my $c = sqrt($a**2 + $b**2);
1531
1532   $a = 3; $b = 4;
1533   printf "c5  %s=%f\n", $c, $c;
1534
1535   $a = 12; $b = 5;
1536   printf "c13  %s=%f\n", $c, $c;
1537
1538 shows that the numeric value of $c follows changes to the values of $a
1539 and $b.
1540
1541 =head1 AUTHOR
1542
1543 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1544
1545 =head1 SEE ALSO
1546
1547 The C<overloading> pragma can be used to enable or disable overloaded
1548 operations within a lexical scope - see L<overloading>.
1549
1550 =head1 DIAGNOSTICS
1551
1552 When Perl is run with the B<-Do> switch or its equivalent, overloading
1553 induces diagnostic messages.
1554
1555 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1556 deduce which operations are overloaded (and which ancestor triggers
1557 this overloading).  Say, if C<eq> is overloaded, then the method C<(eq>
1558 is shown by debugger.  The method C<()> corresponds to the C<fallback>
1559 key (in fact a presence of this method shows that this package has
1560 overloading enabled, and it is what is used by the C<Overloaded>
1561 function of module C<overload>).
1562
1563 The module might issue the following warnings:
1564
1565 =over 4
1566
1567 =item Odd number of arguments for overload::constant
1568
1569 (W) The call to overload::constant contained an odd number of arguments.
1570 The arguments should come in pairs.
1571
1572 =item '%s' is not an overloadable type
1573
1574 (W) You tried to overload a constant type the overload package is unaware of.
1575
1576 =item '%s' is not a code reference
1577
1578 (W) The second (fourth, sixth, ...) argument of overload::constant needs
1579 to be a code reference.  Either an anonymous subroutine, or a reference
1580 to a subroutine.
1581
1582 =item overload arg '%s' is invalid
1583
1584 (W) C<use overload> was passed an argument it did not
1585 recognize.  Did you mistype an operator?
1586
1587 =back
1588
1589 =head1 BUGS AND PITFALLS
1590
1591 =over
1592
1593 =item *
1594
1595 A pitfall when fallback is TRUE and Perl resorts to a built-in
1596 implementation of an operator is that some operators have more
1597 than one semantic, for example C<|>:
1598
1599         use overload '0+' => sub { $_[0]->{n}; },
1600             fallback => 1;
1601         my $x = bless { n => 4 }, "main";
1602         my $y = bless { n => 8 }, "main";
1603         print $x | $y, "\n";
1604
1605 You might expect this to output "12".
1606 In fact, it prints "<": the ASCII result of treating "|"
1607 as a bitwise string operator - that is, the result of treating
1608 the operands as the strings "4" and "8" rather than numbers.
1609 The fact that numify (C<0+>) is implemented but stringify
1610 (C<"">) isn't makes no difference since the latter is simply
1611 autogenerated from the former.
1612
1613 The only way to change this is to provide your own subroutine
1614 for C<'|'>.
1615
1616 =item *
1617
1618 Magic autogeneration increases the potential for inadvertently
1619 creating self-referential structures.
1620 Currently Perl will not free self-referential
1621 structures until cycles are explicitly broken.
1622 For example,
1623
1624     use overload '+' => 'add';
1625     sub add { bless [ \$_[0], \$_[1] ] };
1626
1627 is asking for trouble, since
1628
1629     $obj += $y;
1630
1631 will effectively become
1632
1633     $obj = add($obj, $y, undef);
1634
1635 with the same result as
1636
1637     $obj = [\$obj, \$foo];
1638
1639 Even if no I<explicit> assignment-variants of operators are present in
1640 the script, they may be generated by the optimizer.
1641 For example,
1642
1643     "obj = $obj\n"
1644
1645 may be optimized to
1646
1647     my $tmp = 'obj = ' . $obj;  $tmp .= "\n";
1648
1649 =item *
1650
1651 The symbol table is filled with names looking like line-noise.
1652
1653 =item *
1654
1655 This bug was fixed in Perl 5.18, but may still trip you up if you are using
1656 older versions:
1657
1658 For the purpose of inheritance every overloaded package behaves as if
1659 C<fallback> is present (possibly undefined).  This may create
1660 interesting effects if some package is not overloaded, but inherits
1661 from two overloaded packages.
1662
1663 =item *
1664
1665 Before Perl 5.14, the relation between overloading and tie()ing was broken.
1666 Overloading was triggered or not based on the I<previous> class of the
1667 tie()d variable.
1668
1669 This happened because the presence of overloading was checked
1670 too early, before any tie()d access was attempted.  If the
1671 class of the value FETCH()ed from the tied variable does not
1672 change, a simple workaround for code that is to run on older Perl
1673 versions is to access the value (via C<() = $foo> or some such)
1674 immediately after tie()ing, so that after this call the I<previous> class
1675 coincides with the current one.
1676
1677 =item *
1678
1679 Barewords are not covered by overloaded string constants.
1680
1681 =back
1682
1683 =cut
1684