c46be839c3192529fa2c749c8dc2bbc224e9d52c
[perl.git] / lib / overload.pm
1 package overload;
2
3 sub nil {}
4
5 sub OVERLOAD {
6   $package = shift;
7   my %arg = @_;
8   my ($sub, $fb);
9   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
10   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
11   for (keys %arg) {
12     if ($_ eq 'fallback') {
13       $fb = $arg{$_};
14     } else {
15       $sub = $arg{$_};
16       if (not ref $sub and $sub !~ /::/) {
17         $ {$package . "::(" . $_} = $sub;
18         $sub = \&nil;
19       }
20       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
21       *{$package . "::(" . $_} = \&{ $sub };
22     }
23   }
24   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
25 }
26
27 sub import {
28   $package = (caller())[0];
29   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
30   shift;
31   $package->overload::OVERLOAD(@_);
32 }
33
34 sub unimport {
35   $package = (caller())[0];
36   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
37   shift;
38   for (@_) {
39     if ($_ eq 'fallback') {
40       undef $ {$package . "::()"};
41     } else {
42       delete $ {$package . "::"}{"(" . $_};
43     }
44   }
45 }
46
47 sub Overloaded {
48   my $package = shift;
49   $package = ref $package if ref $package;
50   $package->can('()');
51 }
52
53 sub ov_method {
54   my $globref = shift;
55   return undef unless $globref;
56   my $sub = \&{*$globref};
57   return $sub if $sub ne \&nil;
58   return shift->can($ {*$globref});
59 }
60
61 sub OverloadedStringify {
62   my $package = shift;
63   $package = ref $package if ref $package;
64   #$package->can('(""')
65   ov_method mycan($package, '(""'), $package
66     or ov_method mycan($package, '(0+'), $package
67     or ov_method mycan($package, '(bool'), $package
68     or ov_method mycan($package, '(nomethod'), $package;
69 }
70
71 sub Method {
72   my $package = shift;
73   $package = ref $package if ref $package;
74   #my $meth = $package->can('(' . shift);
75   ov_method mycan($package, '(' . shift), $package;
76   #return $meth if $meth ne \&nil;
77   #return $ {*{$meth}};
78 }
79
80 sub AddrRef {
81   my $package = ref $_[0];
82   return "$_[0]" unless $package;
83   bless $_[0], overload::Fake;  # Non-overloaded package
84   my $str = "$_[0]";
85   bless $_[0], $package;        # Back
86   $package . substr $str, index $str, '=';
87 }
88
89 sub StrVal {
90   (OverloadedStringify($_[0]) or ref($_[0]) eq 'Regexp') ?
91     (AddrRef(shift)) :
92     "$_[0]";
93 }
94
95 sub mycan {                             # Real can would leave stubs.
96   my ($package, $meth) = @_;
97   return \*{$package . "::$meth"} if defined &{$package . "::$meth"};
98   my $p;
99   foreach $p (@{$package . "::ISA"}) {
100     my $out = mycan($p, $meth);
101     return $out if $out;
102   }
103   return undef;
104 }
105
106 %constants = (
107               'integer'   =>  0x1000, 
108               'float'     =>  0x2000,
109               'binary'    =>  0x4000,
110               'q'         =>  0x8000,
111               'qr'        => 0x10000,
112              );
113
114 %ops = ( with_assign      => "+ - * / % ** << >> x .",
115          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
116          str_comparison   => "< <= >  >= == !=",
117          '3way_comparison'=> "<=> cmp",
118          num_comparison   => "lt le gt ge eq ne",
119          binary           => "& | ^",
120          unary            => "neg ! ~",
121          mutators         => '++ --',
122          func             => "atan2 cos sin exp abs log sqrt",
123          conversion       => 'bool "" 0+',
124          iterators        => '<>',
125          dereferencing    => '${} @{} %{} &{} *{}',
126          special          => 'nomethod fallback =');
127
128 sub constant {
129   # Arguments: what, sub
130   while (@_) {
131     $^H{$_[0]} = $_[1];
132     $^H |= $constants{$_[0]} | 0x20000;
133     shift, shift;
134   }
135 }
136
137 sub remove_constant {
138   # Arguments: what, sub
139   while (@_) {
140     delete $^H{$_[0]};
141     $^H &= ~ $constants{$_[0]};
142     shift, shift;
143   }
144 }
145
146 1;
147
148 __END__
149
150 =head1 NAME 
151
152 overload - Package for overloading perl operations
153
154 =head1 SYNOPSIS
155
156     package SomeThing;
157
158     use overload 
159         '+' => \&myadd,
160         '-' => \&mysub;
161         # etc
162     ...
163
164     package main;
165     $a = new SomeThing 57;
166     $b=5+$a;
167     ...
168     if (overload::Overloaded $b) {...}
169     ...
170     $strval = overload::StrVal $b;
171
172 =head1 DESCRIPTION
173
174 =head2 Declaration of overloaded functions
175
176 The compilation directive
177
178     package Number;
179     use overload
180         "+" => \&add, 
181         "*=" => "muas";
182
183 declares function Number::add() for addition, and method muas() in
184 the "class" C<Number> (or one of its base classes)
185 for the assignment form C<*=> of multiplication.  
186
187 Arguments of this directive come in (key, value) pairs.  Legal values
188 are values legal inside a C<&{ ... }> call, so the name of a
189 subroutine, a reference to a subroutine, or an anonymous subroutine
190 will all work.  Note that values specified as strings are
191 interpreted as methods, not subroutines.  Legal keys are listed below.
192
193 The subroutine C<add> will be called to execute C<$a+$b> if $a
194 is a reference to an object blessed into the package C<Number>, or if $a is
195 not an object from a package with defined mathemagic addition, but $b is a
196 reference to a C<Number>.  It can also be called in other situations, like
197 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
198 methods refer to methods triggered by an overloaded mathematical
199 operator.)
200
201 Since overloading respects inheritance via the @ISA hierarchy, the
202 above declaration would also trigger overloading of C<+> and C<*=> in
203 all the packages which inherit from C<Number>.
204
205 =head2 Calling Conventions for Binary Operations
206
207 The functions specified in the C<use overload ...> directive are called
208 with three (in one particular case with four, see L<Last Resort>)
209 arguments.  If the corresponding operation is binary, then the first
210 two arguments are the two arguments of the operation.  However, due to
211 general object calling conventions, the first argument should always be
212 an object in the package, so in the situation of C<7+$a>, the
213 order of the arguments is interchanged.  It probably does not matter
214 when implementing the addition method, but whether the arguments
215 are reversed is vital to the subtraction method.  The method can
216 query this information by examining the third argument, which can take
217 three different values:
218
219 =over 7
220
221 =item FALSE
222
223 the order of arguments is as in the current operation.
224
225 =item TRUE
226
227 the arguments are reversed.
228
229 =item C<undef>
230
231 the current operation is an assignment variant (as in
232 C<$a+=7>), but the usual function is called instead.  This additional
233 information can be used to generate some optimizations.  Compare
234 L<Calling Conventions for Mutators>.
235
236 =back
237
238 =head2 Calling Conventions for Unary Operations
239
240 Unary operation are considered binary operations with the second
241 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
242 is called with arguments C<($a,undef,'')> when $a++ is executed.
243
244 =head2 Calling Conventions for Mutators
245
246 Two types of mutators have different calling conventions:
247
248 =over
249
250 =item C<++> and C<-->
251
252 The routines which implement these operators are expected to actually
253 I<mutate> their arguments.  So, assuming that $obj is a reference to a
254 number,
255
256   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
257
258 is an appropriate implementation of overloaded C<++>.  Note that
259
260   sub incr { ++$ {$_[0]} ; shift }
261
262 is OK if used with preincrement and with postincrement. (In the case
263 of postincrement a copying will be performed, see L<Copy Constructor>.)
264
265 =item C<x=> and other assignment versions
266
267 There is nothing special about these methods.  They may change the
268 value of their arguments, and may leave it as is.  The result is going
269 to be assigned to the value in the left-hand-side if different from
270 this value.
271
272 This allows for the same method to be used as overloaded C<+=> and
273 C<+>.  Note that this is I<allowed>, but not recommended, since by the
274 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
275 if C<+=> is not overloaded.
276
277 =back
278
279 B<Warning.>  Due to the presense of assignment versions of operations,
280 routines which may be called in assignment context may create 
281 self-referential structures.  Currently Perl will not free self-referential 
282 structures until cycles are C<explicitly> broken.  You may get problems
283 when traversing your structures too.
284
285 Say, 
286
287   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
288
289 is asking for trouble, since for code C<$obj += $foo> the subroutine
290 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj, 
291 \$foo]>.  If using such a subroutine is an important optimization, one
292 can overload C<+=> explicitly by a non-"optimized" version, or switch
293 to non-optimized version if C<not defined $_[2]> (see 
294 L<Calling Conventions for Binary Operations>).
295
296 Even if no I<explicit> assignment-variants of operators are present in
297 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
298 C<',' . $obj . ','> may be both optimized to
299
300   my $tmp = ',' . $obj;    $tmp .= ',';
301
302 =head2 Overloadable Operations
303
304 The following symbols can be specified in C<use overload> directive:
305
306 =over 5
307
308 =item * I<Arithmetic operations>
309
310     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
311     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
312
313 For these operations a substituted non-assignment variant can be called if
314 the assignment variant is not available.  Methods for operations "C<+>",
315 "C<->", "C<+=>", and "C<-=>" can be called to automatically generate
316 increment and decrement methods.  The operation "C<->" can be used to
317 autogenerate missing methods for unary minus or C<abs>.
318
319 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
320 L<"Calling Conventions for Binary Operations">) for details of these
321 substitutions.
322
323 =item * I<Comparison operations>
324
325     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
326     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
327
328 If the corresponding "spaceship" variant is available, it can be
329 used to substitute for the missing operation.  During C<sort>ing
330 arrays, C<cmp> is used to compare values subject to C<use overload>.
331
332 =item * I<Bit operations>
333
334     "&", "^", "|", "neg", "!", "~",
335
336 "C<neg>" stands for unary minus.  If the method for C<neg> is not
337 specified, it can be autogenerated using the method for
338 subtraction. If the method for "C<!>" is not specified, it can be
339 autogenerated using the methods for "C<bool>", or "C<\"\">", or "C<0+>".
340
341 =item * I<Increment and decrement>
342
343     "++", "--",
344
345 If undefined, addition and subtraction methods can be
346 used instead.  These operations are called both in prefix and
347 postfix form.
348
349 =item * I<Transcendental functions>
350
351     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt",
352
353 If C<abs> is unavailable, it can be autogenerated using methods
354 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
355
356 =item * I<Boolean, string and numeric conversion>
357
358     "bool", "\"\"", "0+",
359
360 If one or two of these operations are not overloaded, the remaining ones can
361 be used instead.  C<bool> is used in the flow control operators
362 (like C<while>) and for the ternary "C<?:>" operation.  These functions can
363 return any arbitrary Perl value.  If the corresponding operation for this value
364 is overloaded too, that operation will be called again with this value.
365
366 =item * I<Iteration>
367
368     "<>"
369
370 If not overloaded, the argument will be converted to a filehandle or
371 glob (which may require a stringification).  The same overloading
372 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
373 I<globbing> syntax C<E<lt>${var}E<gt>>.
374
375 =item * I<Dereferencing>
376
377     '${}', '@{}', '%{}', '&{}', '*{}'.
378
379 If not overloaded, the argument will be dereferenced I<as is>, thus
380 should be of correct type.  These functions should return a reference
381 of correct type, or another object with overloaded dereferencing.
382
383 =item * I<Special>
384
385     "nomethod", "fallback", "=",
386
387 see L<SPECIAL SYMBOLS FOR C<use overload>>.
388
389 =back
390
391 See L<"Fallback"> for an explanation of when a missing method can be
392 autogenerated.
393
394 A computer-readable form of the above table is available in the hash
395 %overload::ops, with values being space-separated lists of names:
396
397  with_assign      => '+ - * / % ** << >> x .',
398  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
399  str_comparison   => '< <= > >= == !=',
400  '3way_comparison'=> '<=> cmp',
401  num_comparison   => 'lt le gt ge eq ne',
402  binary           => '& | ^',
403  unary            => 'neg ! ~',
404  mutators         => '++ --',
405  func             => 'atan2 cos sin exp abs log sqrt',
406  conversion       => 'bool "" 0+',
407  iterators        => '<>',
408  dereferencing    => '${} @{} %{} &{} *{}',
409  special          => 'nomethod fallback ='
410
411 =head2 Inheritance and overloading
412
413 Inheritance interacts with overloading in two ways.
414
415 =over
416
417 =item Strings as values of C<use overload> directive
418
419 If C<value> in
420
421   use overload key => value;
422
423 is a string, it is interpreted as a method name.
424
425 =item Overloading of an operation is inherited by derived classes
426
427 Any class derived from an overloaded class is also overloaded.  The
428 set of overloaded methods is the union of overloaded methods of all
429 the ancestors. If some method is overloaded in several ancestor, then
430 which description will be used is decided by the usual inheritance
431 rules:
432
433 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
434 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
435 then the subroutine C<D::plus_sub> will be called to implement
436 operation C<+> for an object in package C<A>.
437
438 =back
439
440 Note that since the value of the C<fallback> key is not a subroutine,
441 its inheritance is not governed by the above rules.  In the current
442 implementation, the value of C<fallback> in the first overloaded
443 ancestor is used, but this is accidental and subject to change.
444
445 =head1 SPECIAL SYMBOLS FOR C<use overload>
446
447 Three keys are recognized by Perl that are not covered by the above
448 description.
449
450 =head2 Last Resort
451
452 C<"nomethod"> should be followed by a reference to a function of four
453 parameters.  If defined, it is called when the overloading mechanism
454 cannot find a method for some operation.  The first three arguments of
455 this function coincide with the arguments for the corresponding method if
456 it were found, the fourth argument is the symbol
457 corresponding to the missing method.  If several methods are tried,
458 the last one is used.  Say, C<1-$a> can be equivalent to
459
460         &nomethodMethod($a,1,1,"-")
461
462 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
463 C<use overload> directive.
464
465 If some operation cannot be resolved, and there is no function
466 assigned to C<"nomethod">, then an exception will be raised via die()--
467 unless C<"fallback"> was specified as a key in C<use overload> directive.
468
469 =head2 Fallback 
470
471 The key C<"fallback"> governs what to do if a method for a particular
472 operation is not found.  Three different cases are possible depending on
473 the value of C<"fallback">:
474
475 =over 16
476
477 =item * C<undef>
478
479 Perl tries to use a
480 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
481 then tries to calls C<"nomethod"> value; if missing, an exception
482 will be raised.
483
484 =item * TRUE
485
486 The same as for the C<undef> value, but no exception is raised.  Instead,
487 it silently reverts to what it would have done were there no C<use overload>
488 present.
489
490 =item * defined, but FALSE
491
492 No autogeneration is tried.  Perl tries to call
493 C<"nomethod"> value, and if this is missing, raises an exception. 
494
495 =back
496
497 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
498 yet, see L<"Inheritance and overloading">.
499
500 =head2 Copy Constructor
501
502 The value for C<"="> is a reference to a function with three
503 arguments, i.e., it looks like the other values in C<use
504 overload>. However, it does not overload the Perl assignment
505 operator. This would go against Camel hair.
506
507 This operation is called in the situations when a mutator is applied
508 to a reference that shares its object with some other reference, such
509 as
510
511         $a=$b; 
512         ++$a;
513
514 To make this change $a and not change $b, a copy of C<$$a> is made,
515 and $a is assigned a reference to this new object.  This operation is
516 done during execution of the C<++$a>, and not during the assignment,
517 (so before the increment C<$$a> coincides with C<$$b>).  This is only
518 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
519 C<nomethod>).  Note that if this operation is expressed via C<'+'>
520 a nonmutator, i.e., as in
521
522         $a=$b; 
523         $a=$a+1;
524
525 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
526 appear as lvalue when the above code is executed.
527
528 If the copy constructor is required during the execution of some mutator,
529 but a method for C<'='> was not specified, it can be autogenerated as a
530 string copy if the object is a plain scalar.
531
532 =over 5
533
534 =item B<Example>
535
536 The actually executed code for 
537
538         $a=$b; 
539         Something else which does not modify $a or $b....
540         ++$a;
541
542 may be
543
544         $a=$b; 
545         Something else which does not modify $a or $b....
546         $a = $a->clone(undef,"");
547         $a->incr(undef,"");
548
549 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
550 C<'='> was overloaded with C<\&clone>.
551
552 =back
553
554 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
555 C<$b = $a; ++$a>.
556
557 =head1 MAGIC AUTOGENERATION
558
559 If a method for an operation is not found, and the value for  C<"fallback"> is
560 TRUE or undefined, Perl tries to autogenerate a substitute method for
561 the missing operation based on the defined operations.  Autogenerated method
562 substitutions are possible for the following operations:
563
564 =over 16
565
566 =item I<Assignment forms of arithmetic operations>
567
568 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
569 is not defined.
570
571 =item I<Conversion operations> 
572
573 String, numeric, and boolean conversion are calculated in terms of one
574 another if not all of them are defined.
575
576 =item I<Increment and decrement>
577
578 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
579 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
580
581 =item C<abs($a)>
582
583 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
584
585 =item I<Unary minus>
586
587 can be expressed in terms of subtraction.
588
589 =item I<Negation>
590
591 C<!> and C<not> can be expressed in terms of boolean conversion, or
592 string or numerical conversion.
593
594 =item I<Concatenation>
595
596 can be expressed in terms of string conversion.
597
598 =item I<Comparison operations> 
599
600 can be expressed in terms of its "spaceship" counterpart: either
601 C<E<lt>=E<gt>> or C<cmp>:
602
603     <, >, <=, >=, ==, !=        in terms of <=>
604     lt, gt, le, ge, eq, ne      in terms of cmp
605
606 =item I<Iterator>
607
608     <>                          in terms of builtin operations
609
610 =item I<Dereferencing>
611
612     ${} @{} %{} &{} *{}         in terms of builtin operations
613
614 =item I<Copy operator>
615
616 can be expressed in terms of an assignment to the dereferenced value, if this
617 value is a scalar and not a reference.
618
619 =back
620
621 =head1 Losing overloading
622
623 The restriction for the comparison operation is that even if, for example,
624 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
625 function will produce only a standard logical value based on the
626 numerical value of the result of `C<cmp>'.  In particular, a working
627 numeric conversion is needed in this case (possibly expressed in terms of
628 other conversions).
629
630 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
631 if the string conversion substitution is applied.
632
633 When you chop() a mathemagical object it is promoted to a string and its
634 mathemagical properties are lost.  The same can happen with other
635 operations as well.
636
637 =head1 Run-time Overloading
638
639 Since all C<use> directives are executed at compile-time, the only way to
640 change overloading during run-time is to
641
642     eval 'use overload "+" => \&addmethod';
643
644 You can also use
645
646     eval 'no overload "+", "--", "<="';
647
648 though the use of these constructs during run-time is questionable.
649
650 =head1 Public functions
651
652 Package C<overload.pm> provides the following public functions:
653
654 =over 5
655
656 =item overload::StrVal(arg)
657
658 Gives string value of C<arg> as in absence of stringify overloading.
659
660 =item overload::Overloaded(arg)
661
662 Returns true if C<arg> is subject to overloading of some operations.
663
664 =item overload::Method(obj,op)
665
666 Returns C<undef> or a reference to the method that implements C<op>.
667
668 =back
669
670 =head1 Overloading constants
671
672 For some application Perl parser mangles constants too much.  It is possible
673 to hook into this process via overload::constant() and overload::remove_constant()
674 functions.
675
676 These functions take a hash as an argument.  The recognized keys of this hash
677 are
678
679 =over 8
680
681 =item integer
682
683 to overload integer constants,
684
685 =item float
686
687 to overload floating point constants,
688
689 =item binary
690
691 to overload octal and hexadecimal constants,
692
693 =item q
694
695 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
696 strings and here-documents,
697
698 =item qr
699
700 to overload constant pieces of regular expressions.
701
702 =back
703
704 The corresponding values are references to functions which take three arguments:
705 the first one is the I<initial> string form of the constant, the second one
706 is how Perl interprets this constant, the third one is how the constant is used.  
707 Note that the initial string form does not
708 contain string delimiters, and has backslashes in backslash-delimiter 
709 combinations stripped (thus the value of delimiter is not relevant for
710 processing of this string).  The return value of this function is how this 
711 constant is going to be interpreted by Perl.  The third argument is undefined
712 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
713 context (comes from strings, regular expressions, and single-quote HERE
714 documents), it is C<tr> for arguments of C<tr>/C<y> operators, 
715 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
716
717 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
718 it is expected that overloaded constant strings are equipped with reasonable
719 overloaded catenation operator, otherwise absurd results will result.  
720 Similarly, negative numbers are considered as negations of positive constants.
721
722 Note that it is probably meaningless to call the functions overload::constant()
723 and overload::remove_constant() from anywhere but import() and unimport() methods.
724 From these methods they may be called as
725
726         sub import {
727           shift;
728           return unless @_;
729           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
730           overload::constant integer => sub {Math::BigInt->new(shift)};
731         }
732
733 B<BUGS> Currently overloaded-ness of constants does not propagate 
734 into C<eval '...'>.
735
736 =head1 IMPLEMENTATION
737
738 What follows is subject to change RSN.
739
740 The table of methods for all operations is cached in magic for the
741 symbol table hash for the package.  The cache is invalidated during
742 processing of C<use overload>, C<no overload>, new function
743 definitions, and changes in @ISA. However, this invalidation remains
744 unprocessed until the next C<bless>ing into the package. Hence if you
745 want to change overloading structure dynamically, you'll need an
746 additional (fake) C<bless>ing to update the table.
747
748 (Every SVish thing has a magic queue, and magic is an entry in that
749 queue.  This is how a single variable may participate in multiple
750 forms of magic simultaneously.  For instance, environment variables
751 regularly have two forms at once: their %ENV magic and their taint
752 magic. However, the magic which implements overloading is applied to
753 the stashes, which are rarely used directly, thus should not slow down
754 Perl.)
755
756 If an object belongs to a package using overload, it carries a special
757 flag.  Thus the only speed penalty during arithmetic operations without
758 overloading is the checking of this flag.
759
760 In fact, if C<use overload> is not present, there is almost no overhead
761 for overloadable operations, so most programs should not suffer
762 measurable performance penalties.  A considerable effort was made to
763 minimize the overhead when overload is used in some package, but the
764 arguments in question do not belong to packages using overload.  When
765 in doubt, test your speed with C<use overload> and without it.  So far
766 there have been no reports of substantial speed degradation if Perl is
767 compiled with optimization turned on.
768
769 There is no size penalty for data if overload is not used. The only
770 size penalty if overload is used in some package is that I<all> the
771 packages acquire a magic during the next C<bless>ing into the
772 package. This magic is three-words-long for packages without
773 overloading, and carries the cache table if the package is overloaded.
774
775 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is 
776 carried out before any operation that can imply an assignment to the
777 object $a (or $b) refers to, like C<$a++>.  You can override this
778 behavior by defining your own copy constructor (see L<"Copy Constructor">).
779
780 It is expected that arguments to methods that are not explicitly supposed
781 to be changed are constant (but this is not enforced).
782
783 =head1 Metaphor clash
784
785 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
786 If it I<looks> counter intuitive to you, you are subject to a metaphor 
787 clash.  
788
789 Here is a Perl object metaphor:
790
791 I<  object is a reference to blessed data>
792
793 and an arithmetic metaphor:
794
795 I<  object is a thing by itself>.
796
797 The I<main> problem of overloading C<=> is the fact that these metaphors
798 imply different actions on the assignment C<$a = $b> if $a and $b are
799 objects.  Perl-think implies that $a becomes a reference to whatever
800 $b was referencing.  Arithmetic-think implies that the value of "object"
801 $a is changed to become the value of the object $b, preserving the fact
802 that $a and $b are separate entities.
803
804 The difference is not relevant in the absence of mutators.  After
805 a Perl-way assignment an operation which mutates the data referenced by $a
806 would change the data referenced by $b too.  Effectively, after 
807 C<$a = $b> values of $a and $b become I<indistinguishable>.
808
809 On the other hand, anyone who has used algebraic notation knows the 
810 expressive power of the arithmetic metaphor.  Overloading works hard
811 to enable this metaphor while preserving the Perlian way as far as
812 possible.  Since it is not not possible to freely mix two contradicting
813 metaphors, overloading allows the arithmetic way to write things I<as
814 far as all the mutators are called via overloaded access only>.  The
815 way it is done is described in L<Copy Constructor>.
816
817 If some mutator methods are directly applied to the overloaded values,
818 one may need to I<explicitly unlink> other values which references the 
819 same value:
820
821     $a = new Data 23;
822     ...
823     $b = $a;            # $b is "linked" to $a
824     ...
825     $a = $a->clone;     # Unlink $b from $a
826     $a->increment_by(4);
827
828 Note that overloaded access makes this transparent:
829
830     $a = new Data 23;
831     $b = $a;            # $b is "linked" to $a
832     $a += 4;            # would unlink $b automagically
833
834 However, it would not make
835
836     $a = new Data 23;
837     $a = 4;             # Now $a is a plain 4, not 'Data'
838
839 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
840 to an object do whatever you want.  It is just not the overload, but
841 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
842 which returns the object itself, and STORE() method which changes the 
843 value of the object, one can reproduce the arithmetic metaphor in its
844 completeness, at least for variables which were tie()d from the start.
845
846 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
847
848 =head1 Cookbook
849
850 Please add examples to what follows!
851
852 =head2 Two-face scalars
853
854 Put this in F<two_face.pm> in your Perl library directory:
855
856   package two_face;             # Scalars with separate string and
857                                 # numeric values.
858   sub new { my $p = shift; bless [@_], $p }
859   use overload '""' => \&str, '0+' => \&num, fallback => 1;
860   sub num {shift->[1]}
861   sub str {shift->[0]}
862
863 Use it as follows:
864
865   require two_face;
866   my $seven = new two_face ("vii", 7);
867   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
868   print "seven contains `i'\n" if $seven =~ /i/;
869
870 (The second line creates a scalar which has both a string value, and a
871 numeric value.)  This prints:
872
873   seven=vii, seven=7, eight=8
874   seven contains `i'
875
876 =head2 Two-face references
877
878 Suppose you want to create an object which is accessible as both an
879 array reference, and a hash reference, similar to the builtin
880 L<array-accessible-as-a-hash|perlref/"Pseudo-hashes: Using an array as
881 a hash"> builtin Perl type.  Let us make it better than the builtin
882 type, there will be no restriction that you cannot use the index 0 of
883 your array.
884
885   package two_refs;
886   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
887   sub new { 
888     my $p = shift; 
889     bless \ [@_], $p;
890   }
891   sub gethash {
892     my %h;
893     my $self = shift;
894     tie %h, ref $self, $self;
895     \%h;
896   }
897
898   sub TIEHASH { my $p = shift; bless \ shift, $p }
899   my %fields;
900   my $i = 0;
901   $fields{$_} = $i++ foreach qw{zero one two three};
902   sub STORE { 
903     my $self = ${shift()};
904     my $key = $fields{shift()};
905     defined $key or die "Out of band access";
906     $$self->[$key] = shift;
907   }
908   sub FETCH { 
909     my $self = ${shift()};
910     my $key = $fields{shift()};
911     defined $key or die "Out of band access";
912     $$self->[$key];
913   }
914
915 Now one can access an object using both the array and hash syntax:
916
917   my $bar = new two_refs 3,4,5,6;
918   $bar->[2] = 11;
919   $bar->{two} == 11 or die 'bad hash fetch';
920
921 Note several important features of this example.  First of all, the
922 I<actual> type of $bar is a scalar reference, and we do not overload
923 the scalar dereference.  Thus we can get the I<actual> non-overloaded
924 contents of $bar by just using C<$$bar> (what we do in functions which
925 overload dereference).  Similarly, the object returned by the
926 TIEHASH() method is a scalar reference.
927
928 Second, we create a new tied hash each time the hash syntax is used.
929 This allows us not to worry about a possibility of a reference loop,
930 would would lead to a memory leak.
931
932 Both these problems can be cured.  Say, if we want to overload hash
933 dereference on a reference to an object which is I<implemented> as a
934 hash itself, the only problem one has to circumvent is how to access
935 this I<actual> hash (as opposed to the I<virtual> exhibited by
936 overloaded dereference operator).  Here is one possible fetching routine:
937
938   sub access_hash {
939     my ($self, $key) = (shift, shift);
940     my $class = ref $self;
941     bless $self, 'overload::dummy'; # Disable overloading of %{} 
942     my $out = $self->{$key};
943     bless $self, $class;        # Restore overloading
944     $out;
945   }
946
947 To move creation of the tied hash on each access, one may an extra
948 level of indirection which allows a non-circular structure of references:
949
950   package two_refs1;
951   use overload '%{}' => sub { ${shift()}->[1] },
952                '@{}' => sub { ${shift()}->[0] };
953   sub new { 
954     my $p = shift; 
955     my $a = [@_];
956     my %h;
957     tie %h, $p, $a;
958     bless \ [$a, \%h], $p;
959   }
960   sub gethash {
961     my %h;
962     my $self = shift;
963     tie %h, ref $self, $self;
964     \%h;
965   }
966
967   sub TIEHASH { my $p = shift; bless \ shift, $p }
968   my %fields;
969   my $i = 0;
970   $fields{$_} = $i++ foreach qw{zero one two three};
971   sub STORE { 
972     my $a = ${shift()};
973     my $key = $fields{shift()};
974     defined $key or die "Out of band access";
975     $a->[$key] = shift;
976   }
977   sub FETCH { 
978     my $a = ${shift()};
979     my $key = $fields{shift()};
980     defined $key or die "Out of band access";
981     $a->[$key];
982   }
983
984 Now if $baz is overloaded like this, then C<$bar> is a reference to a
985 reference to the intermediate array, which keeps a reference to an
986 actual array, and the access hash.  The tie()ing object for the access
987 hash is also a reference to a reference to the actual array, so 
988
989 =over
990
991 =item *
992
993 There are no loops of references.
994
995 =item *
996
997 Both "objects" which are blessed into the class C<two_refs1> are
998 references to a reference to an array, thus references to a I<scalar>.
999 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1000 overloaded operations.
1001
1002 =back
1003
1004 =head2 Symbolic calculator
1005
1006 Put this in F<symbolic.pm> in your Perl library directory:
1007
1008   package symbolic;             # Primitive symbolic calculator
1009   use overload nomethod => \&wrap;
1010
1011   sub new { shift; bless ['n', @_] }
1012   sub wrap {
1013     my ($obj, $other, $inv, $meth) = @_;
1014     ($obj, $other) = ($other, $obj) if $inv;
1015     bless [$meth, $obj, $other];
1016   }
1017
1018 This module is very unusual as overloaded modules go: it does not
1019 provide any usual overloaded operators, instead it provides the L<Last
1020 Resort> operator C<nomethod>.  In this example the corresponding
1021 subroutine returns an object which encapsulates operations done over
1022 the objects: C<new symbolic 3> contains C<['n', 3]>, C<2 + new
1023 symbolic 3> contains C<['+', 2, ['n', 3]]>.
1024
1025 Here is an example of the script which "calculates" the side of
1026 circumscribed octagon using the above package:
1027
1028   require symbolic;
1029   my $iter = 1;                 # 2**($iter+2) = 8
1030   my $side = new symbolic 1;
1031   my $cnt = $iter;
1032   
1033   while ($cnt--) {
1034     $side = (sqrt(1 + $side**2) - 1)/$side;
1035   }
1036   print "OK\n";
1037
1038 The value of $side is
1039
1040   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1041                        undef], 1], ['n', 1]]
1042
1043 Note that while we obtained this value using a nice little script,
1044 there is no simple way to I<use> this value.  In fact this value may
1045 be inspected in debugger (see L<perldebug>), but ony if
1046 C<bareStringify> B<O>ption is set, and not via C<p> command.
1047
1048 If one attempts to print this value, then the overloaded operator
1049 C<""> will be called, which will call C<nomethod> operator.  The
1050 result of this operator will be stringified again, but this result is
1051 again of type C<symbolic>, which will lead to an infinite loop.
1052
1053 Add a pretty-printer method to the module F<symbolic.pm>:
1054
1055   sub pretty {
1056     my ($meth, $a, $b) = @{+shift};
1057     $a = 'u' unless defined $a;
1058     $b = 'u' unless defined $b;
1059     $a = $a->pretty if ref $a;
1060     $b = $b->pretty if ref $b;
1061     "[$meth $a $b]";
1062   } 
1063
1064 Now one can finish the script by
1065
1066   print "side = ", $side->pretty, "\n";
1067
1068 The method C<pretty> is doing object-to-string conversion, so it
1069 is natural to overload the operator C<""> using this method.  However,
1070 inside such a method it is not necessary to pretty-print the
1071 I<components> $a and $b of an object.  In the above subroutine
1072 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1073 and $b.  If these components use overloading, the catenation operator
1074 will look for an overloaded operator C<.>, if not present, it will
1075 look for an overloaded operator C<"">.  Thus it is enough to use
1076
1077   use overload nomethod => \&wrap, '""' => \&str;
1078   sub str {
1079     my ($meth, $a, $b) = @{+shift};
1080     $a = 'u' unless defined $a;
1081     $b = 'u' unless defined $b;
1082     "[$meth $a $b]";
1083   } 
1084
1085 Now one can change the last line of the script to
1086
1087   print "side = $side\n";
1088
1089 which outputs
1090
1091   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1092
1093 and one can inspect the value in debugger using all the possible
1094 methods.  
1095
1096 Something is is still amiss: consider the loop variable $cnt of the
1097 script.  It was a number, not an object.  We cannot make this value of
1098 type C<symbolic>, since then the loop will not terminate.
1099
1100 Indeed, to terminate the cycle, the $cnt should become false.
1101 However, the operator C<bool> for checking falsity is overloaded (this
1102 time via overloaded C<"">), and returns a long string, thus any object
1103 of type C<symbolic> is true.  To overcome this, we need a way to
1104 compare an object to 0.  In fact, it is easier to write a numeric
1105 conversion routine.
1106
1107 Here is the text of F<symbolic.pm> with such a routine added (and
1108 slightly modified str()):
1109
1110   package symbolic;             # Primitive symbolic calculator
1111   use overload
1112     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1113
1114   sub new { shift; bless ['n', @_] }
1115   sub wrap {
1116     my ($obj, $other, $inv, $meth) = @_;
1117     ($obj, $other) = ($other, $obj) if $inv;
1118     bless [$meth, $obj, $other];
1119   }
1120   sub str {
1121     my ($meth, $a, $b) = @{+shift};
1122     $a = 'u' unless defined $a;
1123     if (defined $b) {
1124       "[$meth $a $b]";
1125     } else {
1126       "[$meth $a]";
1127     }
1128   } 
1129   my %subr = ( n => sub {$_[0]}, 
1130                sqrt => sub {sqrt $_[0]}, 
1131                '-' => sub {shift() - shift()},
1132                '+' => sub {shift() + shift()},
1133                '/' => sub {shift() / shift()},
1134                '*' => sub {shift() * shift()},
1135                '**' => sub {shift() ** shift()},
1136              );
1137   sub num {
1138     my ($meth, $a, $b) = @{+shift};
1139     my $subr = $subr{$meth} 
1140       or die "Do not know how to ($meth) in symbolic";
1141     $a = $a->num if ref $a eq __PACKAGE__;
1142     $b = $b->num if ref $b eq __PACKAGE__;
1143     $subr->($a,$b);
1144   }
1145
1146 All the work of numeric conversion is done in %subr and num().  Of
1147 course, %subr is not complete, it contains only operators used in the
1148 example below.  Here is the extra-credit question: why do we need an
1149 explicit recursion in num()?  (Answer is at the end of this section.)
1150
1151 Use this module like this:
1152
1153   require symbolic;
1154   my $iter = new symbolic 2;    # 16-gon
1155   my $side = new symbolic 1;
1156   my $cnt = $iter;
1157   
1158   while ($cnt) {
1159     $cnt = $cnt - 1;            # Mutator `--' not implemented
1160     $side = (sqrt(1 + $side**2) - 1)/$side;
1161   }
1162   printf "%s=%f\n", $side, $side;
1163   printf "pi=%f\n", $side*(2**($iter+2));
1164
1165 It prints (without so many line breaks)
1166
1167   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1168                           [n 1]] 2]]] 1]
1169      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1170   pi=3.182598
1171
1172 The above module is very primitive.  It does not implement
1173 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1174 (not required without mutators!), and implements only those arithmetic
1175 operations which are used in the example.
1176
1177 To implement most arithmetic operations is easy, one should just use
1178 the tables of operations, and change the code which fills %subr to
1179
1180   my %subr = ( 'n' => sub {$_[0]} );
1181   foreach my $op (split " ", $overload::ops{with_assign}) {
1182     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1183   }
1184   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1185   foreach my $op (split " ", "@overload::ops{ @bins }") {
1186     $subr{$op} = eval "sub {shift() $op shift()}";
1187   }
1188   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1189     print "defining `$op'\n";
1190     $subr{$op} = eval "sub {$op shift()}";
1191   }
1192
1193 Due to L<Calling Conventions for Mutators>, we do not need anything
1194 special to make C<+=> and friends work, except filling C<+=> entry of
1195 %subr, and defining a copy constructor (needed since Perl has no
1196 way to know that the implementation of C<'+='> does not mutate
1197 the argument, compare L<Copy Constructor>).
1198
1199 To implement a copy constructor, add C<'=' => \&cpy> to C<use overload>
1200 line, and code (this code assumes that mutators change things one level
1201 deep only, so recursive copying is not needed):
1202
1203   sub cpy {
1204     my $self = shift;
1205     bless [@$self], ref $self;
1206   }
1207
1208 To make C<++> and C<--> work, we need to implement actual mutators, 
1209 either directly, or in C<nomethod>.  We continue to do things inside
1210 C<nomethod>, thus add
1211
1212     if ($meth eq '++' or $meth eq '--') {
1213       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1214       return $obj;
1215     }
1216
1217 after the first line of wrap().  This is not a most effective 
1218 implementation, one may consider
1219
1220   sub inc { $_[0] = bless ['++', shift, 1]; }
1221
1222 instead.
1223
1224 As a final remark, note that one can fill %subr by
1225
1226   my %subr = ( 'n' => sub {$_[0]} );
1227   foreach my $op (split " ", $overload::ops{with_assign}) {
1228     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1229   }
1230   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1231   foreach my $op (split " ", "@overload::ops{ @bins }") {
1232     $subr{$op} = eval "sub {shift() $op shift()}";
1233   }
1234   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1235     $subr{$op} = eval "sub {$op shift()}";
1236   }
1237   $subr{'++'} = $subr{'+'};
1238   $subr{'--'} = $subr{'-'};
1239
1240 This finishes implementation of a primitive symbolic calculator in 
1241 50 lines of Perl code.  Since the numeric values of subexpressions 
1242 are not cached, the calculator is very slow.
1243
1244 Here is the answer for the exercise: In the case of str(), we need no
1245 explicit recursion since the overloaded C<.>-operator will fall back
1246 to an existing overloaded operator C<"">.  Overloaded arithmetic
1247 operators I<do not> fall back to numeric conversion if C<fallback> is
1248 not explicitly requested.  Thus without an explicit recursion num()
1249 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1250 the argument of num().
1251
1252 If you wonder why defaults for conversion are different for str() and
1253 num(), note how easy it was to write the symbolic calculator.  This
1254 simplicity is due to an appropriate choice of defaults.  One extra
1255 note: due to the explicit recursion num() is more fragile than sym():
1256 we need to explicitly check for the type of $a and $b.  If components
1257 $a and $b happen to be of some related type, this may lead to problems.
1258
1259 =head2 I<Really> symbolic calculator
1260
1261 One may wonder why we call the above calculator symbolic.  The reason
1262 is that the actual calculation of the value of expression is postponed
1263 until the value is I<used>.
1264
1265 To see it in action, add a method
1266
1267   sub STORE { 
1268     my $obj = shift; 
1269     $#$obj = 1; 
1270     @$obj->[0,1] = ('=', shift);
1271   }
1272
1273 to the package C<symbolic>.  After this change one can do
1274
1275   my $a = new symbolic 3;
1276   my $b = new symbolic 4;
1277   my $c = sqrt($a**2 + $b**2);
1278
1279 and the numeric value of $c becomes 5.  However, after calling
1280
1281   $a->STORE(12);  $b->STORE(5);
1282
1283 the numeric value of $c becomes 13.  There is no doubt now that the module
1284 symbolic provides a I<symbolic> calculator indeed.
1285
1286 To hide the rough edges under the hood, provide a tie()d interface to the
1287 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1288
1289   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1290   sub FETCH { shift }
1291   sub nop {  }          # Around a bug
1292
1293 (the bug is described in L<"BUGS">).  One can use this new interface as
1294
1295   tie $a, 'symbolic', 3;
1296   tie $b, 'symbolic', 4;
1297   $a->nop;  $b->nop;    # Around a bug
1298
1299   my $c = sqrt($a**2 + $b**2);
1300
1301 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1302 of $c becomes 13.  To insulate the user of the module add a method
1303
1304   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1305
1306 Now
1307
1308   my ($a, $b);
1309   symbolic->vars($a, $b);
1310   my $c = sqrt($a**2 + $b**2);
1311
1312   $a = 3; $b = 4;
1313   printf "c5  %s=%f\n", $c, $c;
1314
1315   $a = 12; $b = 5;
1316   printf "c13  %s=%f\n", $c, $c;
1317
1318 shows that the numeric value of $c follows changes to the values of $a
1319 and $b.
1320
1321 =head1 AUTHOR
1322
1323 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1324
1325 =head1 DIAGNOSTICS
1326
1327 When Perl is run with the B<-Do> switch or its equivalent, overloading
1328 induces diagnostic messages.
1329
1330 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1331 deduce which operations are overloaded (and which ancestor triggers
1332 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1333 is shown by debugger. The method C<()> corresponds to the C<fallback>
1334 key (in fact a presence of this method shows that this package has
1335 overloading enabled, and it is what is used by the C<Overloaded>
1336 function of module C<overload>).
1337
1338 =head1 BUGS
1339
1340 Because it is used for overloading, the per-package hash %OVERLOAD now
1341 has a special meaning in Perl. The symbol table is filled with names
1342 looking like line-noise.
1343
1344 For the purpose of inheritance every overloaded package behaves as if
1345 C<fallback> is present (possibly undefined). This may create
1346 interesting effects if some package is not overloaded, but inherits
1347 from two overloaded packages.
1348
1349 Relation between overloading and tie()ing is broken.  Overloading is 
1350 triggered or not basing on the I<previous> class of tie()d value.
1351
1352 This happens because the presence of overloading is checked too early, 
1353 before any tie()d access is attempted.  If the FETCH()ed class of the
1354 tie()d value does not change, a simple workaround is to access the value 
1355 immediately after tie()ing, so that after this call the I<previous> class
1356 coincides with the current one.
1357
1358 B<Needed:> a way to fix this without a speed penalty.
1359
1360 Barewords are not covered by overloaded string constants.
1361
1362 This document is confusing.  There are grammos and misleading language
1363 used in places.  It would seem a total rewrite is needed.
1364
1365 =cut
1366