ExtUtils::ParseXS: Changelog and version bump to 3.14
[perl.git] / dist / ExtUtils-ParseXS / lib / ExtUtils / ParseXS.pm
1 package ExtUtils::ParseXS;
2 use strict;
3
4 use 5.008001;  # We use /??{}/ in regexes
5 use Cwd;
6 use Config;
7 use Exporter;
8 use File::Basename;
9 use File::Spec;
10 use Symbol;
11
12 our $VERSION;
13 BEGIN {
14   $VERSION = '3.14';
15 }
16 use ExtUtils::ParseXS::Constants $VERSION;
17 use ExtUtils::ParseXS::CountLines $VERSION;
18 use ExtUtils::ParseXS::Utilities $VERSION;
19 $VERSION = eval $VERSION if $VERSION =~ /_/;
20
21 use ExtUtils::ParseXS::Utilities qw(
22   standard_typemap_locations
23   trim_whitespace
24   tidy_type
25   C_string
26   valid_proto_string
27   process_typemaps
28   make_targetable
29   map_type
30   standard_XS_defs
31   assign_func_args
32   analyze_preprocessor_statements
33   set_cond
34   Warn
35   current_line_number
36   blurt
37   death
38   check_conditional_preprocessor_statements
39   escape_file_for_line_directive
40   report_typemap_failure
41 );
42
43 our @ISA = qw(Exporter);
44 our @EXPORT_OK = qw(
45   process_file
46   report_error_count
47 );
48
49 # The scalars in the line below remain as 'our' variables because pulling
50 # them into $self led to build problems.  In most cases, strings being
51 # 'eval'-ed contain the variables' names hard-coded.
52 our (
53   $Package, $func_name, $Full_func_name, $pname, $ALIAS,
54 );
55
56 our $self = bless {} => __PACKAGE__;
57
58 sub process_file {
59
60   # Allow for $package->process_file(%hash) in the future
61   my ($pkg, %options) = @_ % 2 ? @_ : (__PACKAGE__, @_);
62
63   $self->{ProtoUsed} = exists $options{prototypes};
64
65   # Set defaults.
66   my %args = (
67     argtypes        => 1,
68     csuffix         => '.c',
69     except          => 0,
70     hiertype        => 0,
71     inout           => 1,
72     linenumbers     => 1,
73     optimize        => 1,
74     output          => \*STDOUT,
75     prototypes      => 0,
76     typemap         => [],
77     versioncheck    => 1,
78     FH              => Symbol::gensym(),
79     %options,
80   );
81   $args{except} = $args{except} ? ' TRY' : '';
82
83   # Global Constants
84
85   my ($Is_VMS, $SymSet);
86   if ($^O eq 'VMS') {
87     $Is_VMS = 1;
88     # Establish set of global symbols with max length 28, since xsubpp
89     # will later add the 'XS_' prefix.
90     require ExtUtils::XSSymSet;
91     $SymSet = ExtUtils::XSSymSet->new(28);
92   }
93   @{ $self->{XSStack} } = ({type => 'none'});
94   $self->{InitFileCode} = [ @ExtUtils::ParseXS::Constants::InitFileCode ];
95   $self->{Overload}     = 0;
96   $self->{errors}       = 0;
97   $self->{Fallback}     = '&PL_sv_undef';
98
99   # Most of the 1500 lines below uses these globals.  We'll have to
100   # clean this up sometime, probably.  For now, we just pull them out
101   # of %args.  -Ken
102
103   $self->{hiertype} = $args{hiertype};
104   $self->{WantPrototypes} = $args{prototypes};
105   $self->{WantVersionChk} = $args{versioncheck};
106   $self->{WantLineNumbers} = $args{linenumbers};
107   $self->{IncludedFiles} = {};
108
109   die "Missing required parameter 'filename'" unless $args{filename};
110   $self->{filepathname} = $args{filename};
111   ($self->{dir}, $self->{filename}) =
112     (dirname($args{filename}), basename($args{filename}));
113   $self->{filepathname} =~ s/\\/\\\\/g;
114   $self->{IncludedFiles}->{$args{filename}}++;
115
116   # Open the output file if given as a string.  If they provide some
117   # other kind of reference, trust them that we can print to it.
118   if (not ref $args{output}) {
119     open my($fh), "> $args{output}" or die "Can't create $args{output}: $!";
120     $args{outfile} = $args{output};
121     $args{output} = $fh;
122   }
123
124   # Really, we shouldn't have to chdir() or select() in the first
125   # place.  For now, just save and restore.
126   my $orig_cwd = cwd();
127   my $orig_fh = select();
128
129   chdir($self->{dir});
130   my $pwd = cwd();
131   my $csuffix = $args{csuffix};
132
133   if ($self->{WantLineNumbers}) {
134     my $cfile;
135     if ( $args{outfile} ) {
136       $cfile = $args{outfile};
137     }
138     else {
139       $cfile = $args{filename};
140       $cfile =~ s/\.xs$/$csuffix/i or $cfile .= $csuffix;
141     }
142     tie(*PSEUDO_STDOUT, 'ExtUtils::ParseXS::CountLines', $cfile, $args{output});
143     select PSEUDO_STDOUT;
144   }
145   else {
146     select $args{output};
147   }
148
149   $self->{typemap} = process_typemaps( $args{typemap}, $pwd );
150
151   my $END = "!End!\n\n";        # "impossible" keyword (multiple newline)
152
153   # Match an XS keyword
154   $self->{BLOCK_re} = '\s*(' .
155     join('|' => @ExtUtils::ParseXS::Constants::XSKeywords) .
156     "|$END)\\s*:";
157
158   our ($C_group_rex, $C_arg);
159   # Group in C (no support for comments or literals)
160   $C_group_rex = qr/ [({\[]
161                (?: (?> [^()\[\]{}]+ ) | (??{ $C_group_rex }) )*
162                [)}\]] /x;
163   # Chunk in C without comma at toplevel (no comments):
164   $C_arg = qr/ (?: (?> [^()\[\]{},"']+ )
165          |   (??{ $C_group_rex })
166          |   " (?: (?> [^\\"]+ )
167            |   \\.
168            )* "        # String literal
169                 |   ' (?: (?> [^\\']+ ) | \\. )* ' # Char literal
170          )* /xs;
171
172   # Since at this point we're ready to begin printing to the output file and
173   # reading from the input file, I want to get as much data as possible into
174   # the proto-object $self.  That means assigning to $self and elements of
175   # %args referenced below this point.
176   # HOWEVER:  This resulted in an error when I tried:
177   #   $args{'s'} ---> $self->{s}.
178   # Use of uninitialized value in quotemeta at
179   #   .../blib/lib/ExtUtils/ParseXS.pm line 733
180
181   foreach my $datum ( qw| argtypes except inout optimize | ) {
182     $self->{$datum} = $args{$datum};
183   }
184
185   # Identify the version of xsubpp used
186   print <<EOM;
187 /*
188  * This file was generated automatically by ExtUtils::ParseXS version $VERSION from the
189  * contents of $self->{filename}. Do not edit this file, edit $self->{filename} instead.
190  *
191  *    ANY CHANGES MADE HERE WILL BE LOST!
192  *
193  */
194
195 EOM
196
197
198   print("#line 1 \"" . escape_file_for_line_directive($self->{filepathname}) . "\"\n")
199     if $self->{WantLineNumbers};
200
201   # Open the input file (using $self->{filename} which
202   # is a basename'd $args{filename} due to chdir above)
203   open($self->{FH}, '<', $self->{filename}) or die "cannot open $self->{filename}: $!\n";
204
205   firstmodule:
206   while (readline($self->{FH})) {
207     if (/^=/) {
208       my $podstartline = $.;
209       do {
210         if (/^=cut\s*$/) {
211           # We can't just write out a /* */ comment, as our embedded
212           # POD might itself be in a comment. We can't put a /**/
213           # comment inside #if 0, as the C standard says that the source
214           # file is decomposed into preprocessing characters in the stage
215           # before preprocessing commands are executed.
216           # I don't want to leave the text as barewords, because the spec
217           # isn't clear whether macros are expanded before or after
218           # preprocessing commands are executed, and someone pathological
219           # may just have defined one of the 3 words as a macro that does
220           # something strange. Multiline strings are illegal in C, so
221           # the "" we write must be a string literal. And they aren't
222           # concatenated until 2 steps later, so we are safe.
223           #     - Nicholas Clark
224           print("#if 0\n  \"Skipped embedded POD.\"\n#endif\n");
225           printf("#line %d \"%s\"\n", $. + 1, escape_file_for_line_directive($self->{filepathname}))
226             if $self->{WantLineNumbers};
227           next firstmodule
228         }
229
230       } while (readline($self->{FH}));
231       # At this point $. is at end of file so die won't state the start
232       # of the problem, and as we haven't yet read any lines &death won't
233       # show the correct line in the message either.
234       die ("Error: Unterminated pod in $self->{filename}, line $podstartline\n")
235         unless $self->{lastline};
236     }
237     last if ($Package, $self->{Prefix}) =
238       /^MODULE\s*=\s*[\w:]+(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/;
239
240     print $_;
241   }
242   unless (defined $_) {
243     warn "Didn't find a 'MODULE ... PACKAGE ... PREFIX' line\n";
244     exit 0; # Not a fatal error for the caller process
245   }
246
247   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
248
249   standard_XS_defs();
250
251   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
252
253   $self->{lastline}    = $_;
254   $self->{lastline_no} = $.;
255
256   my $BootCode_ref = [];
257   my $XSS_work_idx = 0;
258   my $cpp_next_tmp = 'XSubPPtmpAAAA';
259  PARAGRAPH:
260   while ($self->fetch_para()) {
261     my $outlist_ref  = [];
262     # Print initial preprocessor statements and blank lines
263     while (@{ $self->{line} } && $self->{line}->[0] !~ /^[^\#]/) {
264       my $ln = shift(@{ $self->{line} });
265       print $ln, "\n";
266       next unless $ln =~ /^\#\s*((if)(?:n?def)?|elsif|else|endif)\b/;
267       my $statement = $+;
268       ( $self, $XSS_work_idx, $BootCode_ref ) =
269         analyze_preprocessor_statements(
270           $self, $statement, $XSS_work_idx, $BootCode_ref
271         );
272     }
273
274     next PARAGRAPH unless @{ $self->{line} };
275
276     if ($XSS_work_idx && !$self->{XSStack}->[$XSS_work_idx]{varname}) {
277       # We are inside an #if, but have not yet #defined its xsubpp variable.
278       print "#define $cpp_next_tmp 1\n\n";
279       push(@{ $self->{InitFileCode} }, "#if $cpp_next_tmp\n");
280       push(@{ $BootCode_ref },     "#if $cpp_next_tmp");
281       $self->{XSStack}->[$XSS_work_idx]{varname} = $cpp_next_tmp++;
282     }
283
284     $self->death(
285       "Code is not inside a function"
286         ." (maybe last function was ended by a blank line "
287         ." followed by a statement on column one?)")
288       if $self->{line}->[0] =~ /^\s/;
289
290     # initialize info arrays
291     foreach my $member (qw(args_match var_types defaults arg_list
292                            argtype_seen in_out lengthof))
293     {
294       $self->{$member} = {};
295     }
296     $self->{proto_arg} = [];
297     $self->{processing_arg_with_types} = undef;
298     $self->{proto_in_this_xsub}        = undef;
299     $self->{scope_in_this_xsub}        = undef;
300     $self->{interface}                 = undef;
301     $self->{interface_macro}           = 'XSINTERFACE_FUNC';
302     $self->{interface_macro_set}       = 'XSINTERFACE_FUNC_SET';
303     $self->{ProtoThisXSUB}             = $self->{WantPrototypes};
304     $self->{ScopeThisXSUB}             = 0;
305
306     my $xsreturn = 0;
307
308     $_ = shift(@{ $self->{line} });
309     while (my $kwd = $self->check_keyword("REQUIRE|PROTOTYPES|EXPORT_XSUB_SYMBOLS|FALLBACK|VERSIONCHECK|INCLUDE(?:_COMMAND)?|SCOPE")) {
310       my $method = $kwd . "_handler";
311       $self->$method($_);
312       next PARAGRAPH unless @{ $self->{line} };
313       $_ = shift(@{ $self->{line} });
314     }
315
316     if ($self->check_keyword("BOOT")) {
317       check_conditional_preprocessor_statements($self);
318       push (@{ $BootCode_ref }, "#line $self->{line_no}->[@{ $self->{line_no} } - @{ $self->{line} }] \""
319                                 . escape_file_for_line_directive($self->{filepathname}) . "\"")
320         if $self->{WantLineNumbers} && $self->{line}->[0] !~ /^\s*#\s*line\b/;
321       push (@{ $BootCode_ref }, @{ $self->{line} }, "");
322       next PARAGRAPH;
323     }
324
325     # extract return type, function name and arguments
326     ($self->{ret_type}) = tidy_type($_);
327     my $RETVAL_no_return = 1 if $self->{ret_type} =~ s/^NO_OUTPUT\s+//;
328
329     # Allow one-line ANSI-like declaration
330     unshift @{ $self->{line} }, $2
331       if $self->{argtypes}
332         and $self->{ret_type} =~ s/^(.*?\w.*?)\s*\b(\w+\s*\(.*)/$1/s;
333
334     # a function definition needs at least 2 lines
335     $self->blurt("Error: Function definition too short '$self->{ret_type}'"), next PARAGRAPH
336       unless @{ $self->{line} };
337
338     my $externC = 1 if $self->{ret_type} =~ s/^extern "C"\s+//;
339     my $static  = 1 if $self->{ret_type} =~ s/^static\s+//;
340
341     my $func_header = shift(@{ $self->{line} });
342     $self->blurt("Error: Cannot parse function definition from '$func_header'"), next PARAGRAPH
343       unless $func_header =~ /^(?:([\w:]*)::)?(\w+)\s*\(\s*(.*?)\s*\)\s*(const)?\s*(;\s*)?$/s;
344
345     my ($class, $orig_args);
346     ($class, $func_name, $orig_args) =  ($1, $2, $3);
347     $class = "$4 $class" if $4;
348     ($pname = $func_name) =~ s/^($self->{Prefix})?/$self->{Packprefix}/;
349     my $clean_func_name;
350     ($clean_func_name = $func_name) =~ s/^$self->{Prefix}//;
351     $Full_func_name = "$self->{Packid}_$clean_func_name";
352     if ($Is_VMS) {
353       $Full_func_name = $SymSet->addsym($Full_func_name);
354     }
355
356     # Check for duplicate function definition
357     for my $tmp (@{ $self->{XSStack} }) {
358       next unless defined $tmp->{functions}{$Full_func_name};
359       Warn( $self, "Warning: duplicate function definition '$clean_func_name' detected");
360       last;
361     }
362     $self->{XSStack}->[$XSS_work_idx]{functions}{$Full_func_name}++;
363     %{ $self->{XsubAliases} }     = ();
364     %{ $self->{XsubAliasValues} } = ();
365     %{ $self->{Interfaces} }      = ();
366     @{ $self->{Attributes} }      = ();
367     $self->{DoSetMagic} = 1;
368
369     $orig_args =~ s/\\\s*/ /g;    # process line continuations
370     my @args;
371
372     my (@fake_INPUT_pre);    # For length(s) generated variables
373     my (@fake_INPUT);
374     my $only_C_inlist_ref = {};        # Not in the signature of Perl function
375     if ($self->{argtypes} and $orig_args =~ /\S/) {
376       my $args = "$orig_args ,";
377       if ($args =~ /^( (??{ $C_arg }) , )* $ /x) {
378         @args = ($args =~ /\G ( (??{ $C_arg }) ) , /xg);
379         for ( @args ) {
380           s/^\s+//;
381           s/\s+$//;
382           my ($arg, $default) = ($_ =~ m/ ( [^=]* ) ( (?: = .* )? ) /x);
383           my ($pre, $len_name) = ($arg =~ /(.*?) \s*
384                              \b ( \w+ | length\( \s*\w+\s* \) )
385                              \s* $ /x);
386           next unless defined($pre) && length($pre);
387           my $out_type = '';
388           my $inout_var;
389           if ($self->{inout} and s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//) {
390             my $type = $1;
391             $out_type = $type if $type ne 'IN';
392             $arg =~ s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//;
393             $pre =~ s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//;
394           }
395           my $islength;
396           if ($len_name =~ /^length\( \s* (\w+) \s* \)\z/x) {
397             $len_name = "XSauto_length_of_$1";
398             $islength = 1;
399             die "Default value on length() argument: '$_'"
400               if length $default;
401           }
402           if (length $pre or $islength) { # Has a type
403             if ($islength) {
404               push @fake_INPUT_pre, $arg;
405             }
406             else {
407               push @fake_INPUT, $arg;
408             }
409             # warn "pushing '$arg'\n";
410             $self->{argtype_seen}->{$len_name}++;
411             $_ = "$len_name$default"; # Assigns to @args
412           }
413           $only_C_inlist_ref->{$_} = 1 if $out_type eq "OUTLIST" or $islength;
414           push @{ $outlist_ref }, $len_name if $out_type =~ /OUTLIST$/;
415           $self->{in_out}->{$len_name} = $out_type if $out_type;
416         }
417       }
418       else {
419         @args = split(/\s*,\s*/, $orig_args);
420         Warn( $self, "Warning: cannot parse argument list '$orig_args', fallback to split");
421       }
422     }
423     else {
424       @args = split(/\s*,\s*/, $orig_args);
425       for (@args) {
426         if ($self->{inout} and s/^(IN|IN_OUTLIST|OUTLIST|IN_OUT|OUT)\b\s*//) {
427           my $out_type = $1;
428           next if $out_type eq 'IN';
429           $only_C_inlist_ref->{$_} = 1 if $out_type eq "OUTLIST";
430           if ($out_type =~ /OUTLIST$/) {
431               push @{ $outlist_ref }, undef;
432           }
433           $self->{in_out}->{$_} = $out_type;
434         }
435       }
436     }
437     if (defined($class)) {
438       my $arg0 = ((defined($static) or $func_name eq 'new')
439           ? "CLASS" : "THIS");
440       unshift(@args, $arg0);
441     }
442     my $extra_args = 0;
443     my @args_num = ();
444     my $num_args = 0;
445     my $report_args = '';
446     my $ellipsis;
447     foreach my $i (0 .. $#args) {
448       if ($args[$i] =~ s/\.\.\.//) {
449         $ellipsis = 1;
450         if ($args[$i] eq '' && $i == $#args) {
451           $report_args .= ", ...";
452           pop(@args);
453           last;
454         }
455       }
456       if ($only_C_inlist_ref->{$args[$i]}) {
457         push @args_num, undef;
458       }
459       else {
460         push @args_num, ++$num_args;
461           $report_args .= ", $args[$i]";
462       }
463       if ($args[$i] =~ /^([^=]*[^\s=])\s*=\s*(.*)/s) {
464         $extra_args++;
465         $args[$i] = $1;
466         $self->{defaults}->{$args[$i]} = $2;
467         $self->{defaults}->{$args[$i]} =~ s/"/\\"/g;
468       }
469       $self->{proto_arg}->[$i+1] = '$';
470     }
471     my $min_args = $num_args - $extra_args;
472     $report_args =~ s/"/\\"/g;
473     $report_args =~ s/^,\s+//;
474     $self->{func_args} = assign_func_args($self, \@args, $class);
475     @{ $self->{args_match} }{@args} = @args_num;
476
477     my $PPCODE = grep(/^\s*PPCODE\s*:/, @{ $self->{line} });
478     my $CODE = grep(/^\s*CODE\s*:/, @{ $self->{line} });
479     # Detect CODE: blocks which use ST(n)= or XST_m*(n,v)
480     # to set explicit return values.
481     my $EXPLICIT_RETURN = ($CODE &&
482             ("@{ $self->{line} }" =~ /(\bST\s*\([^;]*=) | (\bXST_m\w+\s*\()/x ));
483
484     # The $ALIAS which follows is only explicitly called within the scope of
485     # process_file().  In principle, it ought to be a lexical, i.e., 'my
486     # $ALIAS' like the other nearby variables.  However, implementing that
487     # change produced a slight difference in the resulting .c output in at
488     # least two distributions:  B/BD/BDFOY/Crypt-Rijndael and
489     # G/GF/GFUJI/Hash-FieldHash.  The difference is, arguably, an improvement
490     # in the resulting C code.  Example:
491     # 388c388
492     # <                       GvNAME(CvGV(cv)),
493     # ---
494     # >                       "Crypt::Rijndael::encrypt",
495     # But at this point we're committed to generating the *same* C code that
496     # the current version of ParseXS.pm does.  So we're declaring it as 'our'.
497     $ALIAS  = grep(/^\s*ALIAS\s*:/,  @{ $self->{line} });
498
499     my $INTERFACE  = grep(/^\s*INTERFACE\s*:/,  @{ $self->{line} });
500
501     $xsreturn = 1 if $EXPLICIT_RETURN;
502
503     $externC = $externC ? qq[extern "C"] : "";
504
505     # print function header
506     print Q(<<"EOF");
507 #$externC
508 #XS_EUPXS(XS_${Full_func_name}); /* prototype to pass -Wmissing-prototypes */
509 #XS_EUPXS(XS_${Full_func_name})
510 #[[
511 #    dVAR; dXSARGS;
512 EOF
513     print Q(<<"EOF") if $ALIAS;
514 #    dXSI32;
515 EOF
516     print Q(<<"EOF") if $INTERFACE;
517 #    dXSFUNCTION($self->{ret_type});
518 EOF
519
520     $self->{cond} = set_cond($ellipsis, $min_args, $num_args);
521
522     print Q(<<"EOF") if $self->{except};
523 #    char errbuf[1024];
524 #    *errbuf = '\\0';
525 EOF
526
527     if($self->{cond}) {
528       print Q(<<"EOF");
529 #    if ($self->{cond})
530 #       croak_xs_usage(cv,  "$report_args");
531 EOF
532     }
533     else {
534     # cv likely to be unused
535     print Q(<<"EOF");
536 #    PERL_UNUSED_VAR(cv); /* -W */
537 EOF
538     }
539
540     #gcc -Wall: if an xsub has PPCODE is used
541     #it is possible none of ST, XSRETURN or XSprePUSH macros are used
542     #hence 'ax' (setup by dXSARGS) is unused
543     #XXX: could breakup the dXSARGS; into dSP;dMARK;dITEMS
544     #but such a move could break third-party extensions
545     print Q(<<"EOF") if $PPCODE;
546 #    PERL_UNUSED_VAR(ax); /* -Wall */
547 EOF
548
549     print Q(<<"EOF") if $PPCODE;
550 #    SP -= items;
551 EOF
552
553     # Now do a block of some sort.
554
555     $self->{condnum} = 0;
556     $self->{cond} = '';            # last CASE: conditional
557     push(@{ $self->{line} }, "$END:");
558     push(@{ $self->{line_no} }, $self->{line_no}->[-1]);
559     $_ = '';
560     check_conditional_preprocessor_statements();
561     while (@{ $self->{line} }) {
562
563       $self->CASE_handler($_) if $self->check_keyword("CASE");
564       print Q(<<"EOF");
565 #   $self->{except} [[
566 EOF
567
568       # do initialization of input variables
569       $self->{thisdone} = 0;
570       $self->{retvaldone} = 0;
571       $self->{deferred} = "";
572       %{ $self->{arg_list} } = ();
573       $self->{gotRETVAL} = 0;
574       $self->INPUT_handler($_);
575       $self->process_keyword("INPUT|PREINIT|INTERFACE_MACRO|C_ARGS|ALIAS|ATTRS|PROTOTYPE|SCOPE|OVERLOAD");
576
577       print Q(<<"EOF") if $self->{ScopeThisXSUB};
578 #   ENTER;
579 #   [[
580 EOF
581
582       if (!$self->{thisdone} && defined($class)) {
583         if (defined($static) or $func_name eq 'new') {
584           print "\tchar *";
585           $self->{var_types}->{"CLASS"} = "char *";
586           generate_init( {
587             type          => "char *",
588             num           => 1,
589             var           => "CLASS",
590             printed_name  => undef,
591           } );
592         }
593         else {
594           print "\t$class *";
595           $self->{var_types}->{"THIS"} = "$class *";
596           generate_init( {
597             type          => "$class *",
598             num           => 1,
599             var           => "THIS",
600             printed_name  => undef,
601           } );
602         }
603       }
604
605       # These are set if OUTPUT is found and/or CODE using RETVAL
606       $self->{have_OUTPUT} = $self->{have_CODE_with_RETVAL} = 0;
607
608       my ($wantRETVAL);
609       # do code
610       if (/^\s*NOT_IMPLEMENTED_YET/) {
611         print "\n\tPerl_croak(aTHX_ \"$pname: not implemented yet\");\n";
612         $_ = '';
613       }
614       else {
615         if ($self->{ret_type} ne "void") {
616           print "\t" . map_type($self, $self->{ret_type}, 'RETVAL') . ";\n"
617             if !$self->{retvaldone};
618           $self->{args_match}->{"RETVAL"} = 0;
619           $self->{var_types}->{"RETVAL"} = $self->{ret_type};
620           my $outputmap = $self->{typemap}->get_outputmap( ctype => $self->{ret_type} );
621           print "\tdXSTARG;\n"
622             if $self->{optimize} and $outputmap and $outputmap->targetable;
623         }
624
625         if (@fake_INPUT or @fake_INPUT_pre) {
626           unshift @{ $self->{line} }, @fake_INPUT_pre, @fake_INPUT, $_;
627           $_ = "";
628           $self->{processing_arg_with_types} = 1;
629           $self->INPUT_handler($_);
630         }
631         print $self->{deferred};
632
633         $self->process_keyword("INIT|ALIAS|ATTRS|PROTOTYPE|INTERFACE_MACRO|INTERFACE|C_ARGS|OVERLOAD");
634
635         if ($self->check_keyword("PPCODE")) {
636           $self->print_section();
637           $self->death("PPCODE must be last thing") if @{ $self->{line} };
638           print "\tLEAVE;\n" if $self->{ScopeThisXSUB};
639           print "\tPUTBACK;\n\treturn;\n";
640         }
641         elsif ($self->check_keyword("CODE")) {
642           my $consumed_code = $self->print_section();
643           if ($consumed_code =~ /\bRETVAL\b/) {
644             $self->{have_CODE_with_RETVAL} = 1;
645           }
646         }
647         elsif (defined($class) and $func_name eq "DESTROY") {
648           print "\n\t";
649           print "delete THIS;\n";
650         }
651         else {
652           print "\n\t";
653           if ($self->{ret_type} ne "void") {
654             print "RETVAL = ";
655             $wantRETVAL = 1;
656           }
657           if (defined($static)) {
658             if ($func_name eq 'new') {
659               $func_name = "$class";
660             }
661             else {
662               print "${class}::";
663             }
664           }
665           elsif (defined($class)) {
666             if ($func_name eq 'new') {
667               $func_name .= " $class";
668             }
669             else {
670               print "THIS->";
671             }
672           }
673           $func_name =~ s/^\Q$args{'s'}//
674             if exists $args{'s'};
675           $func_name = 'XSFUNCTION' if $self->{interface};
676           print "$func_name($self->{func_args});\n";
677         }
678       }
679
680       # do output variables
681       $self->{gotRETVAL} = 0;        # 1 if RETVAL seen in OUTPUT section;
682       undef $self->{RETVAL_code} ;    # code to set RETVAL (from OUTPUT section);
683       # $wantRETVAL set if 'RETVAL =' autogenerated
684       ($wantRETVAL, $self->{ret_type}) = (0, 'void') if $RETVAL_no_return;
685       undef %{ $self->{outargs} };
686
687       $self->process_keyword("POSTCALL|OUTPUT|ALIAS|ATTRS|PROTOTYPE|OVERLOAD");
688
689       # A CODE section with RETVAL, but no OUTPUT? FAIL!
690       if ($self->{have_CODE_with_RETVAL} and not $self->{have_OUTPUT} and $self->{ret_type} ne 'void') {
691         $self->Warn("Warning: Found a 'CODE' section which seems to be using 'RETVAL' but no 'OUTPUT' section.");
692       }
693
694       generate_output( {
695         type        => $self->{var_types}->{$_},
696         num         => $self->{args_match}->{$_},
697         var         => $_,
698         do_setmagic => $self->{DoSetMagic},
699         do_push     => undef,
700       } ) for grep $self->{in_out}->{$_} =~ /OUT$/, keys %{ $self->{in_out} };
701
702       my $prepush_done;
703       # all OUTPUT done, so now push the return value on the stack
704       if ($self->{gotRETVAL} && $self->{RETVAL_code}) {
705         print "\t$self->{RETVAL_code}\n";
706       }
707       elsif ($self->{gotRETVAL} || $wantRETVAL) {
708         my $outputmap = $self->{typemap}->get_outputmap( ctype => $self->{ret_type} );
709         my $t = $self->{optimize} && $outputmap && $outputmap->targetable;
710         # Although the '$var' declared in the next line is never explicitly
711         # used within this 'elsif' block, commenting it out leads to
712         # disaster, starting with the first 'eval qq' inside the 'elsif' block
713         # below.
714         # It appears that this is related to the fact that at this point the
715         # value of $t is a reference to an array whose [2] element includes
716         # '$var' as a substring:
717         # <i> <> <(IV)$var>
718         my $var = 'RETVAL';
719         my $type = $self->{ret_type};
720
721         if ($t and not $t->{with_size} and $t->{type} eq 'p') {
722           # PUSHp corresponds to setpvn.  Treat setpv directly
723           my $what = eval qq("$t->{what}");
724           warn $@ if $@;
725
726           print "\tsv_setpv(TARG, $what); XSprePUSH; PUSHTARG;\n";
727           $prepush_done = 1;
728         }
729         elsif ($t) {
730           my $what = eval qq("$t->{what}");
731           warn $@ if $@;
732
733           my $tsize = $t->{what_size};
734           $tsize = '' unless defined $tsize;
735           $tsize = eval qq("$tsize");
736           warn $@ if $@;
737           print "\tXSprePUSH; PUSH$t->{type}($what$tsize);\n";
738           $prepush_done = 1;
739         }
740         else {
741           # RETVAL almost never needs SvSETMAGIC()
742           generate_output( {
743             type        => $self->{ret_type},
744             num         => 0,
745             var         => 'RETVAL',
746             do_setmagic => 0,
747             do_push     => undef,
748           } );
749         }
750       }
751
752       $xsreturn = 1 if $self->{ret_type} ne "void";
753       my $num = $xsreturn;
754       my $c = @{ $outlist_ref };
755       print "\tXSprePUSH;" if $c and not $prepush_done;
756       print "\tEXTEND(SP,$c);\n" if $c;
757       $xsreturn += $c;
758       generate_output( {
759         type        => $self->{var_types}->{$_},
760         num         => $num++,
761         var         => $_,
762         do_setmagic => 0,
763         do_push     => 1,
764       } ) for @{ $outlist_ref };
765
766       # do cleanup
767       $self->process_keyword("CLEANUP|ALIAS|ATTRS|PROTOTYPE|OVERLOAD");
768
769       print Q(<<"EOF") if $self->{ScopeThisXSUB};
770 #   ]]
771 EOF
772       print Q(<<"EOF") if $self->{ScopeThisXSUB} and not $PPCODE;
773 #   LEAVE;
774 EOF
775
776       # print function trailer
777       print Q(<<"EOF");
778 #    ]]
779 EOF
780       print Q(<<"EOF") if $self->{except};
781 #    BEGHANDLERS
782 #    CATCHALL
783 #    sprintf(errbuf, "%s: %s\\tpropagated", Xname, Xreason);
784 #    ENDHANDLERS
785 EOF
786       if ($self->check_keyword("CASE")) {
787         $self->blurt("Error: No 'CASE:' at top of function")
788           unless $self->{condnum};
789         $_ = "CASE: $_";    # Restore CASE: label
790         next;
791       }
792       last if $_ eq "$END:";
793       $self->death(/^$self->{BLOCK_re}/o ? "Misplaced '$1:'" : "Junk at end of function ($_)");
794     }
795
796     print Q(<<"EOF") if $self->{except};
797 #    if (errbuf[0])
798 #    Perl_croak(aTHX_ errbuf);
799 EOF
800
801     if ($xsreturn) {
802       print Q(<<"EOF") unless $PPCODE;
803 #    XSRETURN($xsreturn);
804 EOF
805     }
806     else {
807       print Q(<<"EOF") unless $PPCODE;
808 #    XSRETURN_EMPTY;
809 EOF
810     }
811
812     print Q(<<"EOF");
813 #]]
814 #
815 EOF
816
817     $self->{newXS} = "newXS";
818     $self->{proto} = "";
819
820     # Build the prototype string for the xsub
821     if ($self->{ProtoThisXSUB}) {
822       $self->{newXS} = "newXSproto_portable";
823
824       if ($self->{ProtoThisXSUB} eq 2) {
825         # User has specified empty prototype
826       }
827       elsif ($self->{ProtoThisXSUB} eq 1) {
828         my $s = ';';
829         if ($min_args < $num_args)  {
830           $s = '';
831           $self->{proto_arg}->[$min_args] .= ";";
832         }
833         push @{ $self->{proto_arg} }, "$s\@"
834           if $ellipsis;
835
836         $self->{proto} = join ("", grep defined, @{ $self->{proto_arg} } );
837       }
838       else {
839         # User has specified a prototype
840         $self->{proto} = $self->{ProtoThisXSUB};
841       }
842       $self->{proto} = qq{, "$self->{proto}"};
843     }
844
845     if (%{ $self->{XsubAliases} }) {
846       $self->{XsubAliases}->{$pname} = 0
847         unless defined $self->{XsubAliases}->{$pname};
848       while ( my ($xname, $value) = each %{ $self->{XsubAliases} }) {
849         push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
850 #        cv = $self->{newXS}(\"$xname\", XS_$Full_func_name, file$self->{proto});
851 #        XSANY.any_i32 = $value;
852 EOF
853       }
854     }
855     elsif (@{ $self->{Attributes} }) {
856       push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
857 #        cv = $self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});
858 #        apply_attrs_string("$Package", cv, "@{ $self->{Attributes} }", 0);
859 EOF
860     }
861     elsif ($self->{interface}) {
862       while ( my ($yname, $value) = each %{ $self->{Interfaces} }) {
863         $yname = "$Package\::$yname" unless $yname =~ /::/;
864         push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
865 #        cv = $self->{newXS}(\"$yname\", XS_$Full_func_name, file$self->{proto});
866 #        $self->{interface_macro_set}(cv,$value);
867 EOF
868       }
869     }
870     elsif($self->{newXS} eq 'newXS'){ # work around P5NCI's empty newXS macro
871       push(@{ $self->{InitFileCode} },
872        "        $self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});\n");
873     }
874     else {
875       push(@{ $self->{InitFileCode} },
876        "        (void)$self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});\n");
877     }
878   } # END 'PARAGRAPH' 'while' loop
879
880   if ($self->{Overload}) { # make it findable with fetchmethod
881     print Q(<<"EOF");
882 #XS_EUPXS(XS_$self->{Packid}_nil); /* prototype to pass -Wmissing-prototypes */
883 #XS_EUPXS(XS_$self->{Packid}_nil)
884 #{
885 #   dXSARGS;
886 #   XSRETURN_EMPTY;
887 #}
888 #
889 EOF
890     unshift(@{ $self->{InitFileCode} }, <<"MAKE_FETCHMETHOD_WORK");
891     /* Making a sub named "${Package}::()" allows the package */
892     /* to be findable via fetchmethod(), and causes */
893     /* overload::Overloaded("${Package}") to return true. */
894     (void)$self->{newXS}("${Package}::()", XS_$self->{Packid}_nil, file$self->{proto});
895 MAKE_FETCHMETHOD_WORK
896   }
897
898   # print initialization routine
899
900   print Q(<<"EOF");
901 ##ifdef __cplusplus
902 #extern "C"
903 ##endif
904 EOF
905
906   print Q(<<"EOF");
907 #XS_EXTERNAL(boot_$self->{Module_cname}); /* prototype to pass -Wmissing-prototypes */
908 #XS_EXTERNAL(boot_$self->{Module_cname})
909 EOF
910
911   print Q(<<"EOF");
912 #[[
913 #    dVAR; dXSARGS;
914 EOF
915
916   #Under 5.8.x and lower, newXS is declared in proto.h as expecting a non-const
917   #file name argument. If the wrong qualifier is used, it causes breakage with
918   #C++ compilers and warnings with recent gcc.
919   #-Wall: if there is no $Full_func_name there are no xsubs in this .xs
920   #so 'file' is unused
921   print Q(<<"EOF") if $Full_func_name;
922 ##if (PERL_REVISION == 5 && PERL_VERSION < 9)
923 #    char* file = __FILE__;
924 ##else
925 #    const char* file = __FILE__;
926 ##endif
927 EOF
928
929   print Q("#\n");
930
931   print Q(<<"EOF");
932 #    PERL_UNUSED_VAR(cv); /* -W */
933 #    PERL_UNUSED_VAR(items); /* -W */
934 ##ifdef XS_APIVERSION_BOOTCHECK
935 #    XS_APIVERSION_BOOTCHECK;
936 ##endif
937 EOF
938
939   print Q(<<"EOF") if $self->{WantVersionChk};
940 #    XS_VERSION_BOOTCHECK;
941 #
942 EOF
943
944   print Q(<<"EOF") if defined $self->{xsubaliases} or defined $self->{interfaces};
945 #    {
946 #        CV * cv;
947 #
948 EOF
949
950   print Q(<<"EOF") if ($self->{Overload});
951 #    /* register the overloading (type 'A') magic */
952 #    PL_amagic_generation++;
953 #    /* The magic for overload gets a GV* via gv_fetchmeth as */
954 #    /* mentioned above, and looks in the SV* slot of it for */
955 #    /* the "fallback" status. */
956 #    sv_setsv(
957 #        get_sv( "${Package}::()", TRUE ),
958 #        $self->{Fallback}
959 #    );
960 EOF
961
962   print @{ $self->{InitFileCode} };
963
964   print Q(<<"EOF") if defined $self->{xsubaliases} or defined $self->{interfaces};
965 #    }
966 EOF
967
968   if (@{ $BootCode_ref }) {
969     print "\n    /* Initialisation Section */\n\n";
970     @{ $self->{line} } = @{ $BootCode_ref };
971     $self->print_section();
972     print "\n    /* End of Initialisation Section */\n\n";
973   }
974
975   print Q(<<'EOF');
976 ##if (PERL_REVISION == 5 && PERL_VERSION >= 9)
977 #  if (PL_unitcheckav)
978 #       call_list(PL_scopestack_ix, PL_unitcheckav);
979 ##endif
980 EOF
981
982   print Q(<<"EOF");
983 #    XSRETURN_YES;
984 #]]
985 #
986 EOF
987
988   warn("Please specify prototyping behavior for $self->{filename} (see perlxs manual)\n")
989     unless $self->{ProtoUsed};
990
991   chdir($orig_cwd);
992   select($orig_fh);
993   untie *PSEUDO_STDOUT if tied *PSEUDO_STDOUT;
994   close $self->{FH};
995
996   return 1;
997 }
998
999 sub report_error_count { $self->{errors} }
1000
1001 # Input:  ($self, $_, @{ $self->{line} }) == unparsed input.
1002 # Output: ($_, @{ $self->{line} }) == (rest of line, following lines).
1003 # Return: the matched keyword if found, otherwise 0
1004 sub check_keyword {
1005   my $self = shift;
1006   $_ = shift(@{ $self->{line} }) while !/\S/ && @{ $self->{line} };
1007   s/^(\s*)($_[0])\s*:\s*(?:#.*)?/$1/s && $2;
1008 }
1009
1010 sub print_section {
1011   my $self = shift;
1012
1013   # the "do" is required for right semantics
1014   do { $_ = shift(@{ $self->{line} }) } while !/\S/ && @{ $self->{line} };
1015
1016   my $consumed_code = '';
1017
1018   print("#line ", $self->{line_no}->[@{ $self->{line_no} } - @{ $self->{line} } -1], " \"",
1019         escape_file_for_line_directive($self->{filepathname}), "\"\n")
1020     if $self->{WantLineNumbers} && !/^\s*#\s*line\b/ && !/^#if XSubPPtmp/;
1021   for (;  defined($_) && !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1022     print "$_\n";
1023     $consumed_code .= "$_\n";
1024   }
1025   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
1026
1027   return $consumed_code;
1028 }
1029
1030 sub merge_section {
1031   my $self = shift;
1032   my $in = '';
1033
1034   while (!/\S/ && @{ $self->{line} }) {
1035     $_ = shift(@{ $self->{line} });
1036   }
1037
1038   for (;  defined($_) && !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1039     $in .= "$_\n";
1040   }
1041   chomp $in;
1042   return $in;
1043 }
1044
1045 sub process_keyword {
1046   my($self, $pattern) = @_;
1047
1048   while (my $kwd = $self->check_keyword($pattern)) {
1049     my $method = $kwd . "_handler";
1050     $self->$method($_);
1051   }
1052 }
1053
1054 sub CASE_handler {
1055   my $self = shift;
1056   $_ = shift;
1057   $self->blurt("Error: 'CASE:' after unconditional 'CASE:'")
1058     if $self->{condnum} && $self->{cond} eq '';
1059   $self->{cond} = $_;
1060   trim_whitespace($self->{cond});
1061   print "   ", ($self->{condnum}++ ? " else" : ""), ($self->{cond} ? " if ($self->{cond})\n" : "\n");
1062   $_ = '';
1063 }
1064
1065 sub INPUT_handler {
1066   my $self = shift;
1067   $_ = shift;
1068   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1069     last if /^\s*NOT_IMPLEMENTED_YET/;
1070     next unless /\S/;        # skip blank lines
1071
1072     trim_whitespace($_);
1073     my $ln = $_;
1074
1075     # remove trailing semicolon if no initialisation
1076     s/\s*;$//g unless /[=;+].*\S/;
1077
1078     # Process the length(foo) declarations
1079     if (s/^([^=]*)\blength\(\s*(\w+)\s*\)\s*$/$1 XSauto_length_of_$2=NO_INIT/x) {
1080       print "\tSTRLEN\tSTRLEN_length_of_$2;\n";
1081       $self->{lengthof}->{$2} = undef;
1082       $self->{deferred} .= "\n\tXSauto_length_of_$2 = STRLEN_length_of_$2;\n";
1083     }
1084
1085     # check for optional initialisation code
1086     my $var_init = '';
1087     $var_init = $1 if s/\s*([=;+].*)$//s;
1088     $var_init =~ s/"/\\"/g;
1089     # *sigh* It's valid to supply explicit input typemaps in the argument list...
1090     my $is_overridden_typemap = $var_init =~ /ST\s*\(|\$arg\b/;
1091
1092     s/\s+/ /g;
1093     my ($var_type, $var_addr, $var_name) = /^(.*?[^&\s])\s*(\&?)\s*\b(\w+)$/s
1094       or $self->blurt("Error: invalid argument declaration '$ln'"), next;
1095
1096     # Check for duplicate definitions
1097     $self->blurt("Error: duplicate definition of argument '$var_name' ignored"), next
1098       if $self->{arg_list}->{$var_name}++
1099         or defined $self->{argtype_seen}->{$var_name} and not $self->{processing_arg_with_types};
1100
1101     $self->{thisdone} |= $var_name eq "THIS";
1102     $self->{retvaldone} |= $var_name eq "RETVAL";
1103     $self->{var_types}->{$var_name} = $var_type;
1104     # XXXX This check is a safeguard against the unfinished conversion of
1105     # generate_init().  When generate_init() is fixed,
1106     # one can use 2-args map_type() unconditionally.
1107     my $printed_name;
1108     if ($var_type =~ / \( \s* \* \s* \) /x) {
1109       # Function pointers are not yet supported with output_init()!
1110       print "\t" . map_type($self, $var_type, $var_name);
1111       $printed_name = 1;
1112     }
1113     else {
1114       print "\t" . map_type($self, $var_type, undef);
1115       $printed_name = 0;
1116     }
1117     $self->{var_num} = $self->{args_match}->{$var_name};
1118
1119     if ($self->{var_num}) {
1120       my $typemap = $self->{typemap}->get_typemap(ctype => $var_type);
1121       $self->report_typemap_failure($self->{typemap}, $var_type, "death")
1122         if not $typemap and not $is_overridden_typemap;
1123       $self->{proto_arg}->[$self->{var_num}] = ($typemap && $typemap->proto) || "\$";
1124     }
1125     $self->{func_args} =~ s/\b($var_name)\b/&$1/ if $var_addr;
1126     if ($var_init =~ /^[=;]\s*NO_INIT\s*;?\s*$/
1127       or $self->{in_out}->{$var_name} and $self->{in_out}->{$var_name} =~ /^OUT/
1128       and $var_init !~ /\S/) {
1129       if ($printed_name) {
1130         print ";\n";
1131       }
1132       else {
1133         print "\t$var_name;\n";
1134       }
1135     }
1136     elsif ($var_init =~ /\S/) {
1137       output_init( {
1138         type          => $var_type,
1139         num           => $self->{var_num},
1140         var           => $var_name,
1141         init          => $var_init,
1142         printed_name  => $printed_name,
1143       } );
1144     }
1145     elsif ($self->{var_num}) {
1146       generate_init( {
1147         type          => $var_type,
1148         num           => $self->{var_num},
1149         var           => $var_name,
1150         printed_name  => $printed_name,
1151       } );
1152     }
1153     else {
1154       print ";\n";
1155     }
1156   }
1157 }
1158
1159 sub OUTPUT_handler {
1160   my $self = shift;
1161   $self->{have_OUTPUT} = 1;
1162
1163   $_ = shift;
1164   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1165     next unless /\S/;
1166     if (/^\s*SETMAGIC\s*:\s*(ENABLE|DISABLE)\s*/) {
1167       $self->{DoSetMagic} = ($1 eq "ENABLE" ? 1 : 0);
1168       next;
1169     }
1170     my ($outarg, $outcode) = /^\s*(\S+)\s*(.*?)\s*$/s;
1171     $self->blurt("Error: duplicate OUTPUT argument '$outarg' ignored"), next
1172       if $self->{outargs}->{$outarg}++;
1173     if (!$self->{gotRETVAL} and $outarg eq 'RETVAL') {
1174       # deal with RETVAL last
1175       $self->{RETVAL_code} = $outcode;
1176       $self->{gotRETVAL} = 1;
1177       next;
1178     }
1179     $self->blurt("Error: OUTPUT $outarg not an argument"), next
1180       unless defined($self->{args_match}->{$outarg});
1181     $self->blurt("Error: No input definition for OUTPUT argument '$outarg' - ignored"), next
1182       unless defined $self->{var_types}->{$outarg};
1183     $self->{var_num} = $self->{args_match}->{$outarg};
1184     if ($outcode) {
1185       print "\t$outcode\n";
1186       print "\tSvSETMAGIC(ST(" , $self->{var_num} - 1 , "));\n" if $self->{DoSetMagic};
1187     }
1188     else {
1189       generate_output( {
1190         type        => $self->{var_types}->{$outarg},
1191         num         => $self->{var_num},
1192         var         => $outarg,
1193         do_setmagic => $self->{DoSetMagic},
1194         do_push     => undef,
1195       } );
1196     }
1197     delete $self->{in_out}->{$outarg}     # No need to auto-OUTPUT
1198       if exists $self->{in_out}->{$outarg} and $self->{in_out}->{$outarg} =~ /OUT$/;
1199   }
1200 }
1201
1202 sub C_ARGS_handler {
1203   my $self = shift;
1204   $_ = shift;
1205   my $in = $self->merge_section();
1206
1207   trim_whitespace($in);
1208   $self->{func_args} = $in;
1209 }
1210
1211 sub INTERFACE_MACRO_handler {
1212   my $self = shift;
1213   $_ = shift;
1214   my $in = $self->merge_section();
1215
1216   trim_whitespace($in);
1217   if ($in =~ /\s/) {        # two
1218     ($self->{interface_macro}, $self->{interface_macro_set}) = split ' ', $in;
1219   }
1220   else {
1221     $self->{interface_macro} = $in;
1222     $self->{interface_macro_set} = 'UNKNOWN_CVT'; # catch later
1223   }
1224   $self->{interface} = 1;        # local
1225   $self->{interfaces} = 1;        # global
1226 }
1227
1228 sub INTERFACE_handler {
1229   my $self = shift;
1230   $_ = shift;
1231   my $in = $self->merge_section();
1232
1233   trim_whitespace($in);
1234
1235   foreach (split /[\s,]+/, $in) {
1236     my $iface_name = $_;
1237     $iface_name =~ s/^$self->{Prefix}//;
1238     $self->{Interfaces}->{$iface_name} = $_;
1239   }
1240   print Q(<<"EOF");
1241 #    XSFUNCTION = $self->{interface_macro}($self->{ret_type},cv,XSANY.any_dptr);
1242 EOF
1243   $self->{interface} = 1;        # local
1244   $self->{interfaces} = 1;        # global
1245 }
1246
1247 sub CLEANUP_handler {
1248   my $self = shift;
1249   $self->print_section();
1250 }
1251
1252 sub PREINIT_handler {
1253   my $self = shift;
1254   $self->print_section();
1255 }
1256
1257 sub POSTCALL_handler {
1258   my $self = shift;
1259   $self->print_section();
1260 }
1261
1262 sub INIT_handler {
1263   my $self = shift;
1264   $self->print_section();
1265 }
1266
1267 sub get_aliases {
1268   my $self = shift;
1269   my ($line) = @_;
1270   my ($orig) = $line;
1271
1272   # Parse alias definitions
1273   # format is
1274   #    alias = value alias = value ...
1275
1276   while ($line =~ s/^\s*([\w:]+)\s*=\s*(\w+)\s*//) {
1277     my ($alias, $value) = ($1, $2);
1278     my $orig_alias = $alias;
1279
1280     # check for optional package definition in the alias
1281     $alias = $self->{Packprefix} . $alias if $alias !~ /::/;
1282
1283     # check for duplicate alias name & duplicate value
1284     Warn( $self, "Warning: Ignoring duplicate alias '$orig_alias'")
1285       if defined $self->{XsubAliases}->{$alias};
1286
1287     Warn( $self, "Warning: Aliases '$orig_alias' and '$self->{XsubAliasValues}->{$value}' have identical values")
1288       if $self->{XsubAliasValues}->{$value};
1289
1290     $self->{xsubaliases} = 1;
1291     $self->{XsubAliases}->{$alias} = $value;
1292     $self->{XsubAliasValues}->{$value} = $orig_alias;
1293   }
1294
1295   blurt( $self, "Error: Cannot parse ALIAS definitions from '$orig'")
1296     if $line;
1297 }
1298
1299 sub ATTRS_handler {
1300   my $self = shift;
1301   $_ = shift;
1302
1303   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1304     next unless /\S/;
1305     trim_whitespace($_);
1306     push @{ $self->{Attributes} }, $_;
1307   }
1308 }
1309
1310 sub ALIAS_handler {
1311   my $self = shift;
1312   $_ = shift;
1313
1314   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1315     next unless /\S/;
1316     trim_whitespace($_);
1317     $self->get_aliases($_) if $_;
1318   }
1319 }
1320
1321 sub OVERLOAD_handler {
1322   my $self = shift;
1323   $_ = shift;
1324
1325   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1326     next unless /\S/;
1327     trim_whitespace($_);
1328     while ( s/^\s*([\w:"\\)\+\-\*\/\%\<\>\.\&\|\^\!\~\{\}\=]+)\s*//) {
1329       $self->{Overload} = 1 unless $self->{Overload};
1330       my $overload = "$Package\::(".$1;
1331       push(@{ $self->{InitFileCode} },
1332        "        (void)$self->{newXS}(\"$overload\", XS_$Full_func_name, file$self->{proto});\n");
1333     }
1334   }
1335 }
1336
1337 sub FALLBACK_handler {
1338   my $self = shift;
1339   $_ = shift;
1340
1341   # the rest of the current line should contain either TRUE,
1342   # FALSE or UNDEF
1343
1344   trim_whitespace($_);
1345   my %map = (
1346     TRUE => "&PL_sv_yes", 1 => "&PL_sv_yes",
1347     FALSE => "&PL_sv_no", 0 => "&PL_sv_no",
1348     UNDEF => "&PL_sv_undef",
1349   );
1350
1351   # check for valid FALLBACK value
1352   $self->death("Error: FALLBACK: TRUE/FALSE/UNDEF") unless exists $map{uc $_};
1353
1354   $self->{Fallback} = $map{uc $_};
1355 }
1356
1357
1358 sub REQUIRE_handler {
1359   my $self = shift;
1360   # the rest of the current line should contain a version number
1361   my $Ver = shift;
1362
1363   trim_whitespace($Ver);
1364
1365   $self->death("Error: REQUIRE expects a version number")
1366     unless $Ver;
1367
1368   # check that the version number is of the form n.n
1369   $self->death("Error: REQUIRE: expected a number, got '$Ver'")
1370     unless $Ver =~ /^\d+(\.\d*)?/;
1371
1372   $self->death("Error: xsubpp $Ver (or better) required--this is only $VERSION.")
1373     unless $VERSION >= $Ver;
1374 }
1375
1376 sub VERSIONCHECK_handler {
1377   my $self = shift;
1378   $_ = shift;
1379
1380   # the rest of the current line should contain either ENABLE or
1381   # DISABLE
1382
1383   trim_whitespace($_);
1384
1385   # check for ENABLE/DISABLE
1386   $self->death("Error: VERSIONCHECK: ENABLE/DISABLE")
1387     unless /^(ENABLE|DISABLE)/i;
1388
1389   $self->{WantVersionChk} = 1 if $1 eq 'ENABLE';
1390   $self->{WantVersionChk} = 0 if $1 eq 'DISABLE';
1391
1392 }
1393
1394 sub PROTOTYPE_handler {
1395   my $self = shift;
1396   $_ = shift;
1397
1398   my $specified;
1399
1400   $self->death("Error: Only 1 PROTOTYPE definition allowed per xsub")
1401     if $self->{proto_in_this_xsub}++;
1402
1403   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1404     next unless /\S/;
1405     $specified = 1;
1406     trim_whitespace($_);
1407     if ($_ eq 'DISABLE') {
1408       $self->{ProtoThisXSUB} = 0;
1409     }
1410     elsif ($_ eq 'ENABLE') {
1411       $self->{ProtoThisXSUB} = 1;
1412     }
1413     else {
1414       # remove any whitespace
1415       s/\s+//g;
1416       $self->death("Error: Invalid prototype '$_'")
1417         unless valid_proto_string($_);
1418       $self->{ProtoThisXSUB} = C_string($_);
1419     }
1420   }
1421
1422   # If no prototype specified, then assume empty prototype ""
1423   $self->{ProtoThisXSUB} = 2 unless $specified;
1424
1425   $self->{ProtoUsed} = 1;
1426 }
1427
1428 sub SCOPE_handler {
1429   my $self = shift;
1430   $_ = shift;
1431
1432   $self->death("Error: Only 1 SCOPE declaration allowed per xsub")
1433     if $self->{scope_in_this_xsub}++;
1434
1435   trim_whitespace($_);
1436   $self->death("Error: SCOPE: ENABLE/DISABLE")
1437       unless /^(ENABLE|DISABLE)\b/i;
1438   $self->{ScopeThisXSUB} = ( uc($1) eq 'ENABLE' );
1439 }
1440
1441 sub PROTOTYPES_handler {
1442   my $self = shift;
1443   $_ = shift;
1444
1445   # the rest of the current line should contain either ENABLE or
1446   # DISABLE
1447
1448   trim_whitespace($_);
1449
1450   # check for ENABLE/DISABLE
1451   $self->death("Error: PROTOTYPES: ENABLE/DISABLE")
1452     unless /^(ENABLE|DISABLE)/i;
1453
1454   $self->{WantPrototypes} = 1 if $1 eq 'ENABLE';
1455   $self->{WantPrototypes} = 0 if $1 eq 'DISABLE';
1456   $self->{ProtoUsed} = 1;
1457 }
1458
1459 sub EXPORT_XSUB_SYMBOLS_handler {
1460   my $self = shift;
1461   $_ = shift;
1462
1463   # the rest of the current line should contain either ENABLE or
1464   # DISABLE
1465
1466   trim_whitespace($_);
1467
1468   # check for ENABLE/DISABLE
1469   $self->death("Error: EXPORT_XSUB_SYMBOLS: ENABLE/DISABLE")
1470     unless /^(ENABLE|DISABLE)/i;
1471
1472   my $xs_impl = $1 eq 'ENABLE' ? 'XS_EXTERNAL' : 'XS_INTERNAL';
1473
1474   print Q(<<"EOF");
1475 ##undef XS_EUPXS
1476 ##if defined(PERL_EUPXS_ALWAYS_EXPORT)
1477 ##  define XS_EUPXS(name) XS_EXTERNAL(name)
1478 ##elif defined(PERL_EUPXS_NEVER_EXPORT)
1479 ##  define XS_EUPXS(name) XS_INTERNAL(name)
1480 ##else
1481 ##  define XS_EUPXS(name) $xs_impl(name)
1482 ##endif
1483 EOF
1484 }
1485
1486
1487 sub PushXSStack {
1488   my $self = shift;
1489   my %args = @_;
1490   # Save the current file context.
1491   push(@{ $self->{XSStack} }, {
1492           type            => 'file',
1493           LastLine        => $self->{lastline},
1494           LastLineNo      => $self->{lastline_no},
1495           Line            => $self->{line},
1496           LineNo          => $self->{line_no},
1497           Filename        => $self->{filename},
1498           Filepathname    => $self->{filepathname},
1499           Handle          => $self->{FH},
1500           IsPipe          => scalar($self->{filename} =~ /\|\s*$/),
1501           %args,
1502          });
1503
1504 }
1505
1506 sub INCLUDE_handler {
1507   my $self = shift;
1508   $_ = shift;
1509   # the rest of the current line should contain a valid filename
1510
1511   trim_whitespace($_);
1512
1513   $self->death("INCLUDE: filename missing")
1514     unless $_;
1515
1516   $self->death("INCLUDE: output pipe is illegal")
1517     if /^\s*\|/;
1518
1519   # simple minded recursion detector
1520   $self->death("INCLUDE loop detected")
1521     if $self->{IncludedFiles}->{$_};
1522
1523   ++$self->{IncludedFiles}->{$_} unless /\|\s*$/;
1524
1525   if (/\|\s*$/ && /^\s*perl\s/) {
1526     Warn( $self, "The INCLUDE directive with a command is discouraged." .
1527           " Use INCLUDE_COMMAND instead! In particular using 'perl'" .
1528           " in an 'INCLUDE: ... |' directive is not guaranteed to pick" .
1529           " up the correct perl. The INCLUDE_COMMAND directive allows" .
1530           " the use of \$^X as the currently running perl, see" .
1531           " 'perldoc perlxs' for details.");
1532   }
1533
1534   $self->PushXSStack();
1535
1536   $self->{FH} = Symbol::gensym();
1537
1538   # open the new file
1539   open($self->{FH}, $_) or $self->death("Cannot open '$_': $!");
1540
1541   print Q(<<"EOF");
1542 #
1543 #/* INCLUDE:  Including '$_' from '$self->{filename}' */
1544 #
1545 EOF
1546
1547   $self->{filename} = $_;
1548   $self->{filepathname} = ( $^O =~ /^mswin/i )
1549                           ? qq($self->{dir}/$self->{filename}) # See CPAN RT #61908: gcc doesn't like backslashes on win32?
1550                           : File::Spec->catfile($self->{dir}, $self->{filename});
1551
1552   # Prime the pump by reading the first
1553   # non-blank line
1554
1555   # skip leading blank lines
1556   while (readline($self->{FH})) {
1557     last unless /^\s*$/;
1558   }
1559
1560   $self->{lastline} = $_;
1561   $self->{lastline_no} = $.;
1562 }
1563
1564 sub QuoteArgs {
1565   my $cmd = shift;
1566   my @args = split /\s+/, $cmd;
1567   $cmd = shift @args;
1568   for (@args) {
1569     $_ = q(").$_.q(") if !/^\"/ && length($_) > 0;
1570   }
1571   return join (' ', ($cmd, @args));
1572 }
1573
1574 sub INCLUDE_COMMAND_handler {
1575   my $self = shift;
1576   $_ = shift;
1577   # the rest of the current line should contain a valid command
1578
1579   trim_whitespace($_);
1580
1581   $_ = QuoteArgs($_) if $^O eq 'VMS';
1582
1583   $self->death("INCLUDE_COMMAND: command missing")
1584     unless $_;
1585
1586   $self->death("INCLUDE_COMMAND: pipes are illegal")
1587     if /^\s*\|/ or /\|\s*$/;
1588
1589   $self->PushXSStack( IsPipe => 1 );
1590
1591   $self->{FH} = Symbol::gensym();
1592
1593   # If $^X is used in INCLUDE_COMMAND, we know it's supposed to be
1594   # the same perl interpreter as we're currently running
1595   s/^\s*\$\^X/$^X/;
1596
1597   # open the new file
1598   open ($self->{FH}, "-|", $_)
1599     or $self->death( $self, "Cannot run command '$_' to include its output: $!");
1600
1601   print Q(<<"EOF");
1602 #
1603 #/* INCLUDE_COMMAND:  Including output of '$_' from '$self->{filename}' */
1604 #
1605 EOF
1606
1607   $self->{filename} = $_;
1608   $self->{filepathname} = $self->{filename};
1609   #$self->{filepathname} =~ s/\"/\\"/g; # Fails? See CPAN RT #53938: MinGW Broken after 2.21
1610   $self->{filepathname} =~ s/\\/\\\\/g; # Works according to reporter of #53938
1611
1612   # Prime the pump by reading the first
1613   # non-blank line
1614
1615   # skip leading blank lines
1616   while (readline($self->{FH})) {
1617     last unless /^\s*$/;
1618   }
1619
1620   $self->{lastline} = $_;
1621   $self->{lastline_no} = $.;
1622 }
1623
1624 sub PopFile {
1625   my $self = shift;
1626
1627   return 0 unless $self->{XSStack}->[-1]{type} eq 'file';
1628
1629   my $data     = pop @{ $self->{XSStack} };
1630   my $ThisFile = $self->{filename};
1631   my $isPipe   = $data->{IsPipe};
1632
1633   --$self->{IncludedFiles}->{$self->{filename}}
1634     unless $isPipe;
1635
1636   close $self->{FH};
1637
1638   $self->{FH}         = $data->{Handle};
1639   # $filename is the leafname, which for some reason isused for diagnostic
1640   # messages, whereas $filepathname is the full pathname, and is used for
1641   # #line directives.
1642   $self->{filename}   = $data->{Filename};
1643   $self->{filepathname} = $data->{Filepathname};
1644   $self->{lastline}   = $data->{LastLine};
1645   $self->{lastline_no} = $data->{LastLineNo};
1646   @{ $self->{line} }       = @{ $data->{Line} };
1647   @{ $self->{line_no} }    = @{ $data->{LineNo} };
1648
1649   if ($isPipe and $? ) {
1650     --$self->{lastline_no};
1651     print STDERR "Error reading from pipe '$ThisFile': $! in $self->{filename}, line $self->{lastline_no}\n" ;
1652     exit 1;
1653   }
1654
1655   print Q(<<"EOF");
1656 #
1657 #/* INCLUDE: Returning to '$self->{filename}' from '$ThisFile' */
1658 #
1659 EOF
1660
1661   return 1;
1662 }
1663
1664 sub Q {
1665   my($text) = @_;
1666   $text =~ s/^#//gm;
1667   $text =~ s/\[\[/{/g;
1668   $text =~ s/\]\]/}/g;
1669   $text;
1670 }
1671
1672 # Read next xsub into @{ $self->{line} } from ($lastline, readline($self->{FH})).
1673 sub fetch_para {
1674   my $self = shift;
1675
1676   # parse paragraph
1677   $self->death("Error: Unterminated '#if/#ifdef/#ifndef'")
1678     if !defined $self->{lastline} && $self->{XSStack}->[-1]{type} eq 'if';
1679   @{ $self->{line} } = ();
1680   @{ $self->{line_no} } = ();
1681   return $self->PopFile() if !defined $self->{lastline};
1682
1683   if ($self->{lastline} =~
1684       /^MODULE\s*=\s*([\w:]+)(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/) {
1685     my $Module = $1;
1686     $Package = defined($2) ? $2 : ''; # keep -w happy
1687     $self->{Prefix}  = defined($3) ? $3 : ''; # keep -w happy
1688     $self->{Prefix} = quotemeta $self->{Prefix};
1689     ($self->{Module_cname} = $Module) =~ s/\W/_/g;
1690     ($self->{Packid} = $Package) =~ tr/:/_/;
1691     $self->{Packprefix} = $Package;
1692     $self->{Packprefix} .= "::" if $self->{Packprefix} ne "";
1693     $self->{lastline} = "";
1694   }
1695
1696   for (;;) {
1697     # Skip embedded PODs
1698     while ($self->{lastline} =~ /^=/) {
1699       while ($self->{lastline} = readline($self->{FH})) {
1700         last if ($self->{lastline} =~ /^=cut\s*$/);
1701       }
1702       $self->death("Error: Unterminated pod") unless $self->{lastline};
1703       $self->{lastline} = readline($self->{FH});
1704       chomp $self->{lastline};
1705       $self->{lastline} =~ s/^\s+$//;
1706     }
1707
1708     # This chunk of code strips out (and parses) embedded TYPEMAP blocks
1709     # which support a HEREdoc-alike block syntax.
1710     # This is special cased from the usual paragraph-handler logic
1711     # due to the HEREdoc-ish syntax.
1712     if ($self->{lastline} =~ /^TYPEMAP\s*:\s*<<\s*(?:(["'])(.+?)\1|([^\s'"]+))\s*;?\s*$/) {
1713       my $end_marker = quotemeta(defined($1) ? $2 : $3);
1714       my @tmaplines;
1715       while (1) {
1716         $self->{lastline} = readline($self->{FH});
1717         $self->death("Error: Unterminated typemap") if not defined $self->{lastline};
1718         last if $self->{lastline} =~ /^$end_marker\s*$/;
1719         push @tmaplines, $self->{lastline};
1720       }
1721
1722       my $tmapcode = join "", @tmaplines;
1723       my $tmap = ExtUtils::Typemaps->new(
1724         string => $tmapcode,
1725         lineno_offset => ($self->current_line_number()||0)+1,
1726         fake_filename => $self->{filename},
1727       );
1728       $self->{typemap}->merge(typemap => $tmap, replace => 1);
1729
1730       $self->{lastline} = "";
1731     }
1732
1733     if ($self->{lastline} !~ /^\s*#/ ||
1734     # CPP directives:
1735     #    ANSI:    if ifdef ifndef elif else endif define undef
1736     #        line error pragma
1737     #    gcc:    warning include_next
1738     #   obj-c:    import
1739     #   others:    ident (gcc notes that some cpps have this one)
1740     $self->{lastline} =~ /^#[ \t]*(?:(?:if|ifn?def|elif|else|endif|define|undef|pragma|error|warning|line\s+\d+|ident)\b|(?:include(?:_next)?|import)\s*["<].*[>"])/) {
1741       last if $self->{lastline} =~ /^\S/ && @{ $self->{line} } && $self->{line}->[-1] eq "";
1742       push(@{ $self->{line} }, $self->{lastline});
1743       push(@{ $self->{line_no} }, $self->{lastline_no});
1744     }
1745
1746     # Read next line and continuation lines
1747     last unless defined($self->{lastline} = readline($self->{FH}));
1748     $self->{lastline_no} = $.;
1749     my $tmp_line;
1750     $self->{lastline} .= $tmp_line
1751       while ($self->{lastline} =~ /\\$/ && defined($tmp_line = readline($self->{FH})));
1752
1753     chomp $self->{lastline};
1754     $self->{lastline} =~ s/^\s+$//;
1755   }
1756   pop(@{ $self->{line} }), pop(@{ $self->{line_no} }) while @{ $self->{line} } && $self->{line}->[-1] eq "";
1757   1;
1758 }
1759
1760 sub output_init {
1761   my $argsref = shift;
1762   my ($type, $num, $var, $init, $printed_name) = (
1763     $argsref->{type},
1764     $argsref->{num},
1765     $argsref->{var},
1766     $argsref->{init},
1767     $argsref->{printed_name}
1768   );
1769   my $arg = "ST(" . ($num - 1) . ")";
1770
1771   if (  $init =~ /^=/  ) {
1772     if ($printed_name) {
1773       eval qq/print " $init\\n"/;
1774     }
1775     else {
1776       eval qq/print "\\t$var $init\\n"/;
1777     }
1778     warn $@ if $@;
1779   }
1780   else {
1781     if (  $init =~ s/^\+//  &&  $num  ) {
1782       generate_init( {
1783         type          => $type,
1784         num           => $num,
1785         var           => $var,
1786         printed_name  => $printed_name,
1787       } );
1788     }
1789     elsif ($printed_name) {
1790       print ";\n";
1791       $init =~ s/^;//;
1792     }
1793     else {
1794       eval qq/print "\\t$var;\\n"/;
1795       warn $@ if $@;
1796       $init =~ s/^;//;
1797     }
1798     $self->{deferred} .= eval qq/"\\n\\t$init\\n"/;
1799     warn $@ if $@;
1800   }
1801 }
1802
1803 sub generate_init {
1804   my $argsref = shift;
1805   my ($type, $num, $var, $printed_name) = (
1806     $argsref->{type},
1807     $argsref->{num},
1808     $argsref->{var},
1809     $argsref->{printed_name},
1810   );
1811   my $arg = "ST(" . ($num - 1) . ")";
1812   my ($argoff, $ntype);
1813   $argoff = $num - 1;
1814
1815   my $typemaps = $self->{typemap};
1816
1817   $type = tidy_type($type);
1818   $self->report_typemap_failure($typemaps, $type), return
1819     unless $typemaps->get_typemap(ctype => $type);
1820
1821   ($ntype = $type) =~ s/\s*\*/Ptr/g;
1822   my $subtype;
1823   ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1824   my $typem = $typemaps->get_typemap(ctype => $type);
1825   my $xstype = $typem->xstype;
1826   $xstype =~ s/OBJ$/REF/ if $func_name =~ /DESTROY$/;
1827   if ($xstype eq 'T_PV' and exists $self->{lengthof}->{$var}) {
1828     print "\t$var" unless $printed_name;
1829     print " = ($type)SvPV($arg, STRLEN_length_of_$var);\n";
1830     die "default value not supported with length(NAME) supplied"
1831       if defined $self->{defaults}->{$var};
1832     return;
1833   }
1834   $type =~ tr/:/_/ unless $self->{hiertype};
1835
1836   my $inputmap = $typemaps->get_inputmap(xstype => $xstype);
1837   $self->blurt("Error: No INPUT definition for type '$type', typekind '" . $type->xstype . "' found"), return
1838     unless defined $inputmap;
1839
1840   my $expr = $inputmap->cleaned_code;
1841   # Note: This gruesome bit either needs heavy rethinking or documentation. I vote for the former. --Steffen
1842   if ($expr =~ /DO_ARRAY_ELEM/) {
1843     my $subtypemap  = $typemaps->get_typemap(ctype => $subtype);
1844     $self->report_typemap_failure($typemaps, $subtype), return
1845       if not $subtypemap;
1846     my $subinputmap = $typemaps->get_inputmap(xstype => $subtypemap->xstype);
1847     $self->blurt("Error: No INPUT definition for type '$subtype', typekind '" . $subtypemap->xstype . "' found"), return
1848       unless $subinputmap;
1849     my $subexpr = $subinputmap->cleaned_code;
1850     $subexpr =~ s/\$type/\$subtype/g;
1851     $subexpr =~ s/ntype/subtype/g;
1852     $subexpr =~ s/\$arg/ST(ix_$var)/g;
1853     $subexpr =~ s/\n\t/\n\t\t/g;
1854     $subexpr =~ s/is not of (.*\")/[arg %d] is not of $1, ix_$var + 1/g;
1855     $subexpr =~ s/\$var/${var}[ix_$var - $argoff]/;
1856     $expr =~ s/DO_ARRAY_ELEM/$subexpr/;
1857   }
1858   if ($expr =~ m#/\*.*scope.*\*/#i) {  # "scope" in C comments
1859     $self->{ScopeThisXSUB} = 1;
1860   }
1861   if (defined($self->{defaults}->{$var})) {
1862     $expr =~ s/(\t+)/$1    /g;
1863     $expr =~ s/        /\t/g;
1864     if ($printed_name) {
1865       print ";\n";
1866     }
1867     else {
1868       eval qq/print "\\t$var;\\n"/;
1869       warn $@ if $@;
1870     }
1871     if ($self->{defaults}->{$var} eq 'NO_INIT') {
1872       $self->{deferred} .= eval qq/"\\n\\tif (items >= $num) {\\n$expr;\\n\\t}\\n"/;
1873     }
1874     else {
1875       $self->{deferred} .= eval qq/"\\n\\tif (items < $num)\\n\\t    $var = $self->{defaults}->{$var};\\n\\telse {\\n$expr;\\n\\t}\\n"/;
1876     }
1877     warn $@ if $@;
1878   }
1879   elsif ($self->{ScopeThisXSUB} or $expr !~ /^\s*\$var =/) {
1880     if ($printed_name) {
1881       print ";\n";
1882     }
1883     else {
1884       eval qq/print "\\t$var;\\n"/;
1885       warn $@ if $@;
1886     }
1887     $self->{deferred} .= eval qq/"\\n$expr;\\n"/;
1888     warn $@ if $@;
1889   }
1890   else {
1891     die "panic: do not know how to handle this branch for function pointers"
1892       if $printed_name;
1893     eval qq/print "$expr;\\n"/;
1894     warn $@ if $@;
1895   }
1896 }
1897
1898 sub generate_output {
1899   my $argsref = shift;
1900   my ($type, $num, $var, $do_setmagic, $do_push) = (
1901     $argsref->{type},
1902     $argsref->{num},
1903     $argsref->{var},
1904     $argsref->{do_setmagic},
1905     $argsref->{do_push}
1906   );
1907   my $arg = "ST(" . ($num - ($num != 0)) . ")";
1908   my $ntype;
1909
1910   my $typemaps = $self->{typemap};
1911
1912   $type = tidy_type($type);
1913   if ($type =~ /^array\(([^,]*),(.*)\)/) {
1914     print "\t$arg = sv_newmortal();\n";
1915     print "\tsv_setpvn($arg, (char *)$var, $2 * sizeof($1));\n";
1916     print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1917   }
1918   else {
1919     my $typemap = $typemaps->get_typemap(ctype => $type);
1920     $self->report_typemap_failure($typemaps, $type), return
1921       if not $typemap;
1922     my $outputmap = $typemaps->get_outputmap(xstype => $typemap->xstype);
1923     $self->blurt("Error: No OUTPUT definition for type '$type', typekind '" . $typemap->xstype . "' found"), return
1924       unless $outputmap;
1925     ($ntype = $type) =~ s/\s*\*/Ptr/g;
1926     $ntype =~ s/\(\)//g;
1927     my $subtype;
1928     ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1929
1930     my $expr = $outputmap->cleaned_code;
1931     if ($expr =~ /DO_ARRAY_ELEM/) {
1932       my $subtypemap = $typemaps->get_typemap(ctype => $subtype);
1933       $self->report_typemap_failure($typemaps, $subtype), return
1934         if not $subtypemap;
1935       my $suboutputmap = $typemaps->get_outputmap(xstype => $subtypemap->xstype);
1936       $self->blurt("Error: No OUTPUT definition for type '$subtype', typekind '" . $subtypemap->xstype . "' found"), return
1937         unless $suboutputmap;
1938       my $subexpr = $suboutputmap->cleaned_code;
1939       $subexpr =~ s/ntype/subtype/g;
1940       $subexpr =~ s/\$arg/ST(ix_$var)/g;
1941       $subexpr =~ s/\$var/${var}[ix_$var]/g;
1942       $subexpr =~ s/\n\t/\n\t\t/g;
1943       $expr =~ s/DO_ARRAY_ELEM\n/$subexpr/;
1944       eval "print qq\a$expr\a";
1945       warn $@ if $@;
1946       print "\t\tSvSETMAGIC(ST(ix_$var));\n" if $do_setmagic;
1947     }
1948     elsif ($var eq 'RETVAL') {
1949       if ($expr =~ /^\t\$arg = new/) {
1950         # We expect that $arg has refcnt 1, so we need to
1951         # mortalize it.
1952         eval "print qq\a$expr\a";
1953         warn $@ if $@;
1954         print "\tsv_2mortal(ST($num));\n";
1955         print "\tSvSETMAGIC(ST($num));\n" if $do_setmagic;
1956       }
1957       elsif ($expr =~ /^\s*\$arg\s*=/) {
1958         # We expect that $arg has refcnt >=1, so we need
1959         # to mortalize it!
1960         eval "print qq\a$expr\a";
1961         warn $@ if $@;
1962         print "\tsv_2mortal(ST(0));\n";
1963         print "\tSvSETMAGIC(ST(0));\n" if $do_setmagic;
1964       }
1965       else {
1966         # Just hope that the entry would safely write it
1967         # over an already mortalized value. By
1968         # coincidence, something like $arg = &sv_undef
1969         # works too.
1970         print "\tST(0) = sv_newmortal();\n";
1971         eval "print qq\a$expr\a";
1972         warn $@ if $@;
1973         # new mortals don't have set magic
1974       }
1975     }
1976     elsif ($do_push) {
1977       print "\tPUSHs(sv_newmortal());\n";
1978       $arg = "ST($num)";
1979       eval "print qq\a$expr\a";
1980       warn $@ if $@;
1981       print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1982     }
1983     elsif ($arg =~ /^ST\(\d+\)$/) {
1984       eval "print qq\a$expr\a";
1985       warn $@ if $@;
1986       print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1987     }
1988   }
1989 }
1990
1991 1;
1992
1993 # vim: ts=2 sw=2 et: