Remove old perltodo
[perl.git] / make_ext.pl
1 #!./miniperl
2 use strict;
3 use warnings;
4 use Config;
5 BEGIN {
6     if ($^O eq 'MSWin32') {
7         unshift @INC, '../dist/Cwd';
8         require FindExt;
9     } else {
10         unshift @INC, 'dist/Cwd';
11     }
12 }
13 use Cwd;
14
15 my $is_Win32 = $^O eq 'MSWin32';
16 my $is_VMS = $^O eq 'VMS';
17 my $is_Unix = !$is_Win32 && !$is_VMS;
18
19 my @ext_dirs = qw(cpan dist ext);
20 my $ext_dirs_re = '(?:' . join('|', @ext_dirs) . ')';
21
22 # This script acts as a simple interface for building extensions.
23
24 # It's actually a cut and shut of the Unix version ext/utils/makeext and the
25 # Windows version win32/build_ext.pl hence the two invocation styles.
26
27 # On Unix, it primarily used by the perl Makefile one extension at a time:
28 #
29 # d_dummy $(dynamic_ext): miniperl preplibrary FORCE
30 #       @$(RUN) ./miniperl make_ext.pl --target=dynamic $@ MAKE=$(MAKE) LIBPERL_A=$(LIBPERL)
31 #
32 # On Windows or VMS,
33 # If '--static' is specified, static extensions will be built.
34 # If '--dynamic' is specified, dynamic extensions will be built.
35 # If '--nonxs' is specified, nonxs extensions will be built.
36 # If '--dynaloader' is specified, DynaLoader will be built.
37 # If '--all' is specified, all extensions will be built.
38 #
39 #    make_ext.pl "MAKE=make [-make_opts]" --dir=directory [--target=target] [--static|--dynamic|--all] +ext2 !ext1
40 #
41 # E.g.
42
43 #     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext
44
45 #     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext --target=clean
46
47 #     make_ext.pl MAKE=dmake --dir=..\ext
48
49 #     make_ext.pl MAKE=dmake --dir=..\ext --target=clean
50
51 # Will skip building extensions which are marked with an '!' char.
52 # Mostly because they still not ported to specified platform.
53
54 # If any extensions are listed with a '+' char then only those
55 # extensions will be built, but only if they arent countermanded
56 # by an '!ext' and are appropriate to the type of building being done.
57
58 # It may be deleted in a later release of perl so try to
59 # avoid using it for other purposes.
60
61 my (%excl, %incl, %opts, @extspec, @pass_through);
62
63 foreach (@ARGV) {
64     if (/^!(.*)$/) {
65         $excl{$1} = 1;
66     } elsif (/^\+(.*)$/) {
67         $incl{$1} = 1;
68     } elsif (/^--([\w\-]+)$/) {
69         $opts{$1} = 1;
70     } elsif (/^--([\w\-]+)=(.*)$/) {
71         push @{$opts{$1}}, $2;
72     } elsif (/=/) {
73         push @pass_through, $_;
74     } elsif (length) {
75         push @extspec, $_;
76     }
77 }
78
79 my $static = $opts{static} || $opts{all};
80 my $dynamic = $opts{dynamic} || $opts{all};
81 my $nonxs = $opts{nonxs} || $opts{all};
82 my $dynaloader = $opts{dynaloader} || $opts{all};
83
84 # The Perl Makefile.SH will expand all extensions to
85 #       lib/auto/X/X.a  (or lib/auto/X/Y/Y.a if nested)
86 # A user wishing to run make_ext might use
87 #       X (or X/Y or X::Y if nested)
88
89 # canonise into X/Y form (pname)
90
91 foreach (@extspec) {
92     if (s{^lib/auto/}{}) {
93         # Remove lib/auto prefix and /*.* suffix
94         s{/[^/]+\.[^/]+$}{};
95     } elsif (s{^$ext_dirs_re/}{}) {
96         # Remove ext/ prefix and /pm_to_blib suffix
97         s{/pm_to_blib$}{};
98         # Targets are given as files on disk, but the extension spec is still
99         # written using /s for each ::
100         tr!-!/!;
101     } elsif (s{::}{\/}g) {
102         # Convert :: to /
103     } else {
104         s/\..*o//;
105     }
106 }
107
108 my $makecmd  = shift @pass_through; # Should be something like MAKE=make
109 unshift @pass_through, 'PERL_CORE=1';
110
111 my @dirs  = @{$opts{dir} || \@ext_dirs};
112 my $target   = $opts{target}[0];
113 $target = 'all' unless defined $target;
114
115 # Previously, $make was taken from config.sh.  However, the user might
116 # instead be running a possibly incompatible make.  This might happen if
117 # the user types "gmake" instead of a plain "make", for example.  The
118 # correct current value of MAKE will come through from the main perl
119 # makefile as MAKE=/whatever/make in $makecmd.  We'll be cautious in
120 # case third party users of this script (are there any?) don't have the
121 # MAKE=$(MAKE) argument, which was added after 5.004_03.
122 unless(defined $makecmd and $makecmd =~ /^MAKE=(.*)$/) {
123     die "$0:  WARNING:  Please include MAKE=\$(MAKE) in \@ARGV\n";
124 }
125
126 # This isn't going to cope with anything fancy, such as spaces inside command
127 # names, but neither did what it replaced. Once there is a use case that needs
128 # it, please supply patches. Until then, I'm sticking to KISS
129 my @make = split ' ', $1 || $Config{make} || $ENV{MAKE};
130 # Using an array of 0 or 1 elements makes the subsequent code simpler.
131 my @run = $Config{run};
132 @run = () if not defined $run[0] or $run[0] eq '';
133
134
135 if ($target eq '') {
136     die "make_ext: no make target specified (eg all or clean)\n";
137 } elsif ($target !~ /(?:^all|clean)$/) {
138     # for the time being we are strict about what make_ext is used for
139     die "$0: unknown make target '$target'\n";
140 }
141
142 if (!@extspec and !$static and !$dynamic and !$nonxs and !$dynaloader)  {
143     die "$0: no extension specified\n";
144 }
145
146 my $perl;
147 my %extra_passthrough;
148
149 if ($is_Win32) {
150     my $build = getcwd();
151     $perl = $^X;
152     if ($perl =~ m#^\.\.#) {
153         my $here = $build;
154         $here =~ s{/}{\\}g;
155         $perl = "$here\\$perl";
156     }
157     (my $topdir = $perl) =~ s/\\[^\\]+$//;
158     # miniperl needs to find perlglob and pl2bat
159     $ENV{PATH} = "$topdir;$topdir\\win32\\bin;$ENV{PATH}";
160     my $pl2bat = "$topdir\\win32\\bin\\pl2bat";
161     unless (-f "$pl2bat.bat") {
162         my @args = ($perl, "-I$topdir\\lib", ("$pl2bat.pl") x 2);
163         print "@args\n";
164         system(@args) unless defined $::Cross::platform;
165     }
166
167     print "In $build";
168     foreach my $dir (@dirs) {
169         chdir($dir) or die "Cannot cd to $dir: $!\n";
170         (my $ext = getcwd()) =~ s{/}{\\}g;
171         FindExt::scan_ext($ext);
172         FindExt::set_static_extensions(split ' ', $Config{static_ext});
173         chdir $build
174             or die "Couldn't chdir to '$build': $!"; # restore our start directory
175     }
176
177     my @ext;
178     push @ext, FindExt::static_ext() if $static;
179     push @ext, FindExt::dynamic_ext() if $dynamic;
180     push @ext, FindExt::nonxs_ext() if $nonxs;
181     push @ext, 'DynaLoader' if $dynaloader;
182
183     foreach (sort @ext) {
184         if (%incl and !exists $incl{$_}) {
185             #warn "Skipping extension $_, not in inclusion list\n";
186             next;
187         }
188         if (exists $excl{$_}) {
189             warn "Skipping extension $_, not ported to current platform";
190             next;
191         }
192         push @extspec, $_;
193         if($_ eq 'DynaLoader' and $target !~ /clean$/) {
194             # No, we don't know why nmake can't work out the dependency chain
195             push @{$extra_passthrough{$_}}, 'DynaLoader.c';
196         } elsif(FindExt::is_static($_)) {
197             push @{$extra_passthrough{$_}}, 'LINKTYPE=static';
198         }
199     }
200
201     chdir '..'
202         or die "Couldn't chdir to build directory: $!"; # now in the Perl build
203 }
204 elsif ($is_VMS) {
205     $perl = $^X;
206     push @extspec, (split ' ', $Config{static_ext}) if $static;
207     push @extspec, (split ' ', $Config{dynamic_ext}) if $dynamic;
208     push @extspec, (split ' ', $Config{nonxs_ext}) if $nonxs;
209     push @extspec, 'DynaLoader' if $dynaloader;
210 }
211
212 {
213     # Cwd needs to be built before Encode recurses into subdirectories.
214     # This seems to be the simplest way to ensure this ordering:
215     my (@first, @other);
216     foreach (@extspec) {
217         if ($_ eq 'Cwd') {
218             push @first, $_;
219         } else {
220             push @other, $_;
221         }
222     }
223     @extspec = (@first, @other);
224 }
225
226 if ($Config{osname} eq 'catamount' and @extspec) {
227     # Snowball's chance of building extensions.
228     die "This is $Config{osname}, not building $extspec[0], sorry.\n";
229 }
230
231 foreach my $spec (@extspec)  {
232     my $mname = $spec;
233     $mname =~ s!/!::!g;
234     my $ext_pathname;
235
236     # Try new style ext/Data-Dumper/ first
237     my $copy = $spec;
238     $copy =~ tr!/!-!;
239     foreach my $dir (@ext_dirs) {
240         if (-d "$dir/$copy") {
241             $ext_pathname = "$dir/$copy";
242             last;
243         }
244     }
245
246     if (!defined $ext_pathname) {
247         if (-d "ext/$spec") {
248             # Old style ext/Data/Dumper/
249             $ext_pathname = "ext/$spec";
250         } else {
251             warn "Can't find extension $spec in any of @ext_dirs";
252             next;
253         }
254     }
255
256     print "\tMaking $mname ($target)\n";
257
258     build_extension($ext_pathname, $perl, $mname,
259                     [@pass_through, @{$extra_passthrough{$spec} || []}]);
260 }
261
262 sub build_extension {
263     my ($ext_dir, $perl, $mname, $pass_through) = @_;
264
265     unless (chdir "$ext_dir") {
266         warn "Cannot cd to $ext_dir: $!";
267         return;
268     }
269
270     my $up = $ext_dir;
271     $up =~ s![^/]+!..!g;
272
273     $perl ||= "$up/miniperl";
274     my $return_dir = $up;
275     my $lib_dir = "$up/lib";
276     $ENV{PERL_CORE} = 1;
277
278     my $makefile;
279     if ($is_VMS) {
280         $makefile = 'descrip.mms';
281         if ($target =~ /clean$/
282             && !-f $makefile
283             && -f "${makefile}_old") {
284             $makefile = "${makefile}_old";
285         }
286     } else {
287         $makefile = 'Makefile';
288     }
289     
290     if (!-f $makefile) {
291         if (!-f 'Makefile.PL') {
292             print "\nCreating Makefile.PL in $ext_dir for $mname\n";
293             my ($fromname, $key, $value);
294             if ($mname eq 'podlators') {
295                 # We need to special case this somewhere, and this is fewer
296                 # lines of code than a core-only Makefile.PL, and no more
297                 # complex
298                 $fromname = 'VERSION';
299                 $key = 'DISTNAME';
300                 $value = 'podlators';
301                 $mname = 'Pod';
302             } else {
303                 $key = 'ABSTRACT_FROM';
304                 # We need to cope well with various possible layouts
305                 my @dirs = split /::/, $mname;
306                 my $leaf = pop @dirs;
307                 my $leafname = "$leaf.pm";
308                 my $pathname = join '/', @dirs, $leafname;
309                 my @locations = ($leafname, $pathname, "lib/$pathname");
310                 foreach (@locations) {
311                     if (-f $_) {
312                         $fromname = $_;
313                         last;
314                     }
315                 }
316
317                 unless ($fromname) {
318                     die "For $mname tried @locations in in $ext_dir but can't find source";
319                 }
320                 ($value = $fromname) =~ s/\.pm\z/.pod/;
321                 $value = $fromname unless -e $value;
322             }
323             open my $fh, '>', 'Makefile.PL'
324                 or die "Can't open Makefile.PL for writing: $!";
325             printf $fh <<'EOM', $0, $mname, $fromname, $key, $value;
326 #-*- buffer-read-only: t -*-
327
328 # This Makefile.PL was written by %s.
329 # It will be deleted automatically by make realclean
330
331 use strict;
332 use ExtUtils::MakeMaker;
333
334 # This is what the .PL extracts to. Not the ultimate file that is installed.
335 # (ie Win32 runs pl2bat after this)
336
337 # Doing this here avoids all sort of quoting issues that would come from
338 # attempting to write out perl source with literals to generate the arrays and
339 # hash.
340 my @temps = 'Makefile.PL';
341 foreach (glob('scripts/pod*.PL')) {
342     # The various pod*.PL extractors change directory. Doing that with relative
343     # paths in @INC breaks. It seems the lesser of two evils to copy (to avoid)
344     # the chdir doing anything, than to attempt to convert lib paths to
345     # absolute, and potentially run into problems with quoting special
346     # characters in the path to our build dir (such as spaces)
347     require File::Copy;
348
349     my $temp = $_;
350     $temp =~ s!scripts/!!;
351     File::Copy::copy($_, $temp) or die "Can't copy $temp to $_: $!";
352     push @temps, $temp;
353 }
354
355 my $script_ext = $^O eq 'VMS' ? '.com' : '';
356 my %%pod_scripts;
357 foreach (glob('pod*.PL')) {
358     my $script = $_;
359     s/.PL$/$script_ext/i;
360     $pod_scripts{$script} = $_;
361 }
362 my @exe_files = values %%pod_scripts;
363
364 WriteMakefile(
365     NAME          => '%s',
366     VERSION_FROM  => '%s',
367     %-13s => '%s',
368     realclean     => { FILES => "@temps" },
369     (%%pod_scripts ? (
370         PL_FILES  => \%%pod_scripts,
371         EXE_FILES => \@exe_files,
372         clean     => { FILES => "@exe_files" },
373     ) : ()),
374 );
375
376 # ex: set ro:
377 EOM
378             close $fh or die "Can't close Makefile.PL: $!";
379         }
380   eval {
381     my $ftime = time - 4;
382     utime $ftime, $ftime, 'Makefile.PL';
383   };
384         print "\nRunning Makefile.PL in $ext_dir\n";
385
386         # Presumably this can be simplified
387         my @cross;
388         if (defined $::Cross::platform) {
389             # Inherited from win32/buildext.pl
390             @cross = "-MCross=$::Cross::platform";
391         } elsif ($opts{cross}) {
392             # Inherited from make_ext.pl
393             @cross = '-MCross';
394         }
395
396         my @args = ("-I$lib_dir", @cross, 'Makefile.PL');
397         if ($is_VMS) {
398             my $libd = VMS::Filespec::vmspath($lib_dir);
399             push @args, "INST_LIB=$libd", "INST_ARCHLIB=$libd";
400         } else {
401             push @args, 'INSTALLDIRS=perl', 'INSTALLMAN1DIR=none',
402                 'INSTALLMAN3DIR=none';
403         }
404         push @args, @$pass_through;
405         _quote_args(\@args) if $is_VMS;
406         print join(' ', @run, $perl, @args), "\n";
407         my $code = system @run, $perl, @args;
408         warn "$code from $ext_dir\'s Makefile.PL" if $code;
409
410         # Right. The reason for this little hack is that we're sitting inside
411         # a program run by ./miniperl, but there are tasks we need to perform
412         # when the 'realclean', 'distclean' or 'veryclean' targets are run.
413         # Unfortunately, they can be run *after* 'clean', which deletes
414         # ./miniperl
415         # So we do our best to leave a set of instructions identical to what
416         # we would do if we are run directly as 'realclean' etc
417         # Whilst we're perfect, unfortunately the targets we call are not, as
418         # some of them rely on a $(PERL) for their own distclean targets.
419         # But this always used to be a problem with the old /bin/sh version of
420         # this.
421         if ($is_Unix) {
422             my $suffix = '.sh';
423             foreach my $clean_target ('realclean', 'veryclean') {
424                 my $file = "$return_dir/$clean_target$suffix";
425                 open my $fh, '>>', $file or die "open $file: $!";
426                 # Quite possible that we're being run in parallel here.
427                 # Can't use Fcntl this early to get the LOCK_EX
428                 flock $fh, 2 or warn "flock $file: $!";
429                 print $fh <<"EOS";
430 cd $ext_dir
431 if test ! -f Makefile -a -f Makefile.old; then
432     echo "Note: Using Makefile.old"
433     make -f Makefile.old $clean_target MAKE='@make' @pass_through
434 else
435     if test ! -f Makefile ; then
436         echo "Warning: No Makefile!"
437     fi
438     make $clean_target MAKE='@make' @pass_through
439 fi
440 cd $return_dir
441 EOS
442                 close $fh or die "close $file: $!";
443             }
444         }
445     }
446
447     if (not -f $makefile) {
448         print "Warning: No Makefile!\n";
449     }
450
451     if ($is_VMS) {
452         _macroify_passthrough($pass_through);
453         unshift @$pass_through, "/DESCRIPTION=$makefile";
454     }
455
456     if (!$target or $target !~ /clean$/) {
457         # Give makefile an opportunity to rewrite itself.
458         # reassure users that life goes on...
459         my @args = ('config', @$pass_through);
460         system(@run, @make, @args) and print "@run @make @args failed, continuing anyway...\n";
461     }
462     my @targ = ($target, @$pass_through);
463     print "Making $target in $ext_dir\n@run @make @targ\n";
464     my $code = system(@run, @make, @targ);
465     die "Unsuccessful make($ext_dir): code=$code" if $code != 0;
466
467     chdir $return_dir || die "Cannot cd to $return_dir: $!";
468 }
469
470 sub _quote_args {
471     my $args = shift; # must be array reference
472
473     # Do not quote qualifiers that begin with '/'.
474     map { if (!/^\//) {
475           $_ =~ s/\"/""/g;     # escape C<"> by doubling
476           $_ = q(").$_.q(");
477         }
478     } @{$args}
479     ;
480 }
481
482 sub _macroify_passthrough {
483     my $passthrough = shift;
484     _quote_args($passthrough);
485     my $macro = '/MACRO=(' . join(',',@$passthrough) . ')';
486     @$passthrough = ();
487     @$passthrough[0] = $macro;  
488 }