Correct the inconsistencies in the entry for Locale::Maketext::Simple
[perl.git] / ext / Locale-Maketext / t / 40_super.t
1 #!/usr/bin/perl -Tw
2
3 use strict;
4 use Test::More tests=>19;
5
6 BEGIN {
7     use_ok( 'Locale::Maketext' );
8 }
9
10 print "#\n# Testing non-tight insertion of super-ordinate language tags...\n#\n";
11
12 my @in = grep m/\S/, split /[\n\r]/, q{
13  NIX => NIX
14   sv => sv
15   en => en
16  hai => hai
17
18           pt-br => pt-br pt
19        pt-br fr => pt-br fr pt
20     pt-br fr pt => pt-br fr pt
21  pt-br fr pt de => pt-br fr pt de
22  de pt-br fr pt => de pt-br fr pt
23     de pt-br fr => de pt-br fr pt
24    hai pt-br fr => hai pt-br fr  pt
25
26 # Now test multi-part complicateds:
27    pt-br-janeiro fr => pt-br-janeiro fr pt-br pt 
28 pt-br-janeiro de fr => pt-br-janeiro de fr pt-br pt
29 pt-br-janeiro de pt fr => pt-br-janeiro de pt fr pt-br
30
31 ja    pt-br-janeiro fr => ja pt-br-janeiro fr pt-br pt 
32 ja pt-br-janeiro de fr => ja pt-br-janeiro de fr pt-br pt
33 ja pt-br-janeiro de pt fr => ja pt-br-janeiro de pt fr pt-br
34
35 pt-br-janeiro de pt-br fr => pt-br-janeiro de pt-br fr pt
36  # an odd case, since we don't filter for uniqueness in this sub
37  
38 };
39
40 $Locale::Maketext::MATCH_SUPERS_TIGHTLY = 0;
41
42 foreach my $in ( @in ) {
43     $in =~ s/^\s+//s;
44     $in =~ s/\s+$//s;
45     $in =~ s/#.+//s;
46     next unless $in =~ m/\S/;
47
48     die "What kind of line is <$in>?!"
49         unless $in =~ m/^(.+)=>(.+)$/s;
50
51     my ($i,$s) = ($1, $2);
52     my @in     = ($i =~ m/(\S+)/g);
53     my @should = ($s =~ m/(\S+)/g);
54
55     my @out = Locale::Maketext->_add_supers(
56         ("@in" eq 'NIX') ? () : @in
57     );
58     @out = 'NIX' unless @out;
59
60     is_deeply( \@out, \@should, "Happily got [@out] from $in" );
61 }