perl5.002beta3
[perl.git] / lib / ExtUtils / Mksymlists.pm
1 package ExtUtils::Mksymlists;
2 use strict qw[ subs refs ];
3 # no strict 'vars';  # until filehandles are exempted
4
5 use Carp;
6 use Config;
7 use Exporter;
8 # mention vars twice to prevent single-use warnings
9 @ExtUtils::Mksymlists::ISA = @ExtUtils::Mksymlists::ISA = 'Exporter';
10 @ExtUtils::Mksymlists::EXPORT = @ExtUtils::Mksymlists::EXPORT = '&Mksymlists';
11 $ExtUtils::Mksymlists::VERSION = $ExtUtils::Mksymlists::VERSION = '1.00';
12
13 sub Mksymlists {
14     my(%spec) = @_;
15     my($osname) = $Config{'osname'};
16
17     croak("Insufficient information specified to Mksymlists")
18         unless ( $spec{NAME} or
19                  ($spec{FILE} and ($spec{DL_FUNCS} or $spec{FUNCLIST})) );
20
21     $spec{DL_VARS} = [] unless $spec{DL_VARS};
22     ($spec{FILE} = $spec{NAME}) =~ s/.*::// unless $spec{FILE};
23     $spec{DL_FUNCS} = { $spec{NAME} => [] }
24         unless ( ($spec{DL_FUNCS} and keys %{$spec{DL_FUNCS}}) or
25                  $spec{FUNCLIST});
26     $spec{FUNCLIST} = [] unless $spec{FUNCLIST};
27     if (defined $spec{DL_FUNCS}) {
28         my($package);
29         foreach $package (keys %{$spec{DL_FUNCS}}) {
30             my($packprefix,$sym,$bootseen);
31             ($packprefix = $package) =~ s/\W/_/g;
32             foreach $sym (@{$spec{DL_FUNCS}->{$package}}) {
33                 if ($sym =~ /^boot_/) {
34                     push(@{$spec{FUNCLIST}},$sym);
35                     $bootseen++;
36                 }
37                 else { push(@{$spec{FUNCLIST}},"XS_${packprefix}_$sym"); }
38             }
39             push(@{$spec{FUNCLIST}},"boot_$packprefix") unless $bootseen;
40         }
41     }
42
43 #    We'll need this if we ever add any OS which uses mod2fname
44 #    require DynaLoader;
45 #    if (defined &DynaLoader::mod2fname and not $spec{DLBASE}) {
46 #        $spec{DLBASE} = DynaLoader::mod2fname([ split(/::/,$spec{NAME}) ]);
47 #    }
48
49     if    ($osname eq 'aix') { _write_aix(\%spec); }
50     elsif ($osname eq 'VMS') { _write_vms(\%spec) }
51     elsif ($osname eq 'OS2') { _write_os2(\%spec) }
52     else { croak("Don't know how to create linker option file for $osname\n"); }
53 }
54
55
56 sub _write_aix {
57     my($data) = @_;
58
59     rename "$data->{FILE}.exp", "$data->{FILE}.exp_old";
60
61     open(EXP,">$data->{FILE}.exp")
62         or croak("Can't create $data->{FILE}.exp: $!\n");
63     print EXP join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
64     print EXP join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
65     close EXP;
66 }
67
68
69 sub _write_os2 {
70     my($data) = @_;
71
72     if (not $data->{DLBASE}) {
73         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
74         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
75     }
76     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
77
78     open(DEF,">$data->{FILE}.def")
79         or croak("Can't create $data->{FILE}.def: $!\n");
80     print DEF "LIBRARY '$data->{DLBASE}' INITINSTANCE TERMINSTANCE\n";
81     print DEF "CODE LOADONCALL\n";
82     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
83     print DEF "EXPORTS\n";
84     print DEF join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
85     print DEF join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
86     close DEF;
87 }
88
89
90 sub _write_vms {
91     my($data) = @_;
92     my($isvax) = $Config{'arch'} =~ /VAX/i;
93     my($sym);
94
95     rename "$data->{FILE}.opt", "$data->{FILE}.opt_old";
96
97     open(OPT,">$data->{FILE}.opt")
98         or croak("Can't create $data->{FILE}.opt: $!\n");
99
100     # Options file declaring universal symbols
101     # Used when linking shareable image for dynamic extension,
102     # or when linking PerlShr into which we've added this package
103     # as a static extension
104     # We don't do anything to preserve order, so we won't relax
105     # the GSMATCH criteria for a dynamic extension
106
107     foreach $sym (@{$data->{FUNCLIST}}) {
108         if ($isvax) { print OPT "UNIVERSAL=$sym\n" }
109         else        { print OPT "SYMBOL_VECTOR=($sym=PROCEDURE)\n"; }
110     }
111     foreach $sym (@{$data->{DL_VARS}}) {
112         print OPT "PSECT_ATTR=${sym},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
113         if ($isvax) { print OPT "UNIVERSAL=$sym\n" }
114         else        { print OPT "SYMBOL_VECTOR=($sym=DATA)\n"; }
115     }
116     close OPT;
117
118     # Options file specifying RTLs to which this extension must be linked.
119     # Eventually, the list of libraries will be supplied by a working
120     # extliblist routine.
121     open OPT,'>rtls.opt';
122     print OPT "PerlShr/Share\n";
123     foreach $rtl (split(/\s+/,$Config{'libs'})) { print OPT "$rtl\n"; }
124     close OPT;
125 }
126
127 1;
128
129 __END__
130
131 =head1 NAME
132
133 ExtUtils::Mksymlists - write linker options files for dynamic extension
134
135 =head1 SYNOPSIS
136
137     use ExtUtils::Mksymlists;
138     Mksymlists({ NAME     => $name ,
139                  DL_VARS  => [ $var1, $var2, $var3 ],
140                  DL_FUNCS => { $pkg1 => [ $func1, $func2 ],
141                                $pkg2 => [ $func3 ] });
142
143 =head1 DESCRIPTION
144
145 C<ExtUtils::Mksymlists> produces files used by the linker under some OSs
146 during the creation of shared libraries for synamic extensions.  It is
147 normally called from a MakeMaker-generated Makefile when the extension
148 is built.  The linker option file is generated by calling the function
149 C<Mksymlists>, which is exported by default from C<ExtUtils::Mksymlists>.
150 It takes one argument, a list of key-value pairs, in which the following
151 keys are recognized:
152
153 =item NAME
154
155 This gives the name of the extension (I<e.g.> Tk::Canvas) for which
156 the linker option file will be produced.
157
158 =item DL_FUNCS
159
160 This is identical to the DL_FUNCS attribute available via MakeMaker,
161 from which it is usually taken.  Its value is a reference to an
162 associative array, in which each key is the name of a package, and
163 each value is an a reference to an array of function names which
164 should be exported by the extension.  For instance, one might say
165 C<DL_FUNCS =E<gt> { Homer::Iliad =E<gt> [ qw(trojans greeks) ],
166 Homer::Odyssey =E<gt> [ qw(travellers family suitors) ] }>.  The
167 function names should be identical to those in the XSUB code;
168 C<Mksymlists> will alter the names written to the linker option
169 file to match the changes made by F<xsubpp>.  In addition, if
170 none of the functions in a list begin with the string B<boot_>,
171 C<Mksymlists> will add a bootstrap function for that package,
172 just as xsubpp does.  (If a B<boot_E<lt>pkgE<gt>> function is
173 present in the list, it is passed through unchanged.)  If
174 DL_FUNCS is not specified, it defaults to the bootstrap
175 function for the extension specified in NAME.
176
177 =item DL_VARS
178
179 This is identical to the DL_VARS attribute available via MakeMaker,
180 and, like DL_FUNCS, it is usually specified via MakeMaker.  Its
181 value is a reference to an array of variable names which should
182 be exported by the extension.
183
184 =item FILE
185
186 This key can be used to specify the name of the linker option file
187 (minus the OS-specific extension), if for some reason you do not
188 want to use the default value, which is the last word of the NAME
189 attribute (I<e.g.> for Tk::Canvas, FILE defaults to 'Canvas').
190
191 =item FUNCLIST
192
193 This provides an alternate means to specify function names to be
194 exported from the extension.  Its value is a reference to an
195 array of function names to be exported by the extension.  These
196 names are passed through unaltered to the linker options file.
197
198 =item DLBASE
199
200 This item specifies the name by which the linker knows the
201 extension, which may be different from the name of the
202 extension itself (for instance, some linkers add an '_' to the
203 name of the extension).  If it is not specified, it is derived
204 from the NAME attribute.  It is presently used only by OS2.
205
206 When calling C<Mksymlists>, one should always specify the NAME
207 attribute.  In most cases, this is all that's necessary.  In
208 the case of unusual extensions, however, the other attributes
209 can be used to provide additional information to the linker.
210
211 =head1 AUTHOR
212
213 Charles Bailey I<E<lt>bailey@genetics.upenn.eduE<gt>>
214
215 =head1 REVISION
216
217 Last revised 14-Jan-1996, for Perl 5.002.