Deparse -l: set correct line num at end of sub
[perl.git] / lib / B / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD OPf_PARENS
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpKVSLICE
16          OPpCONST_BARE
17          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
18          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER OPpREPEAT_DOLIST
19          OPpSORT_REVERSE OPpMULTIDEREF_EXISTS OPpMULTIDEREF_DELETE
20          OPpSPLIT_ASSIGN OPpSPLIT_LEX
21          OPpPADHV_ISKEYS OPpRV2HV_ISKEYS
22          OPpCONCAT_NESTED
23          OPpMULTICONCAT_APPEND OPpMULTICONCAT_STRINGIFY OPpMULTICONCAT_FAKE
24          OPpTRUEBOOL OPpINDEX_BOOLNEG
25          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
26          SVs_PADTMP SVpad_TYPED
27          CVf_METHOD CVf_LVALUE
28          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
29          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED PMf_EXTENDED_MORE
30          PADNAMEt_OUTER
31         MDEREF_reload
32         MDEREF_AV_pop_rv2av_aelem
33         MDEREF_AV_gvsv_vivify_rv2av_aelem
34         MDEREF_AV_padsv_vivify_rv2av_aelem
35         MDEREF_AV_vivify_rv2av_aelem
36         MDEREF_AV_padav_aelem
37         MDEREF_AV_gvav_aelem
38         MDEREF_HV_pop_rv2hv_helem
39         MDEREF_HV_gvsv_vivify_rv2hv_helem
40         MDEREF_HV_padsv_vivify_rv2hv_helem
41         MDEREF_HV_vivify_rv2hv_helem
42         MDEREF_HV_padhv_helem
43         MDEREF_HV_gvhv_helem
44         MDEREF_ACTION_MASK
45         MDEREF_INDEX_none
46         MDEREF_INDEX_const
47         MDEREF_INDEX_padsv
48         MDEREF_INDEX_gvsv
49         MDEREF_INDEX_MASK
50         MDEREF_FLAG_last
51         MDEREF_MASK
52         MDEREF_SHIFT
53     );
54
55 $VERSION = '1.47';
56 use strict;
57 our $AUTOLOAD;
58 use warnings ();
59 require feature;
60
61 use Config;
62
63 BEGIN {
64     # List version-specific constants here.
65     # Easiest way to keep this code portable between version looks to
66     # be to fake up a dummy constant that will never actually be true.
67     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
68                 OPpPAD_STATE PMf_SKIPWHITE RXf_SKIPWHITE
69                 PMf_CHARSET PMf_KEEPCOPY PMf_NOCAPTURE CVf_ANONCONST
70                 CVf_LOCKED OPpREVERSE_INPLACE OPpSUBSTR_REPL_FIRST
71                 PMf_NONDESTRUCT OPpCONST_ARYBASE OPpEVAL_BYTES
72                 OPpLVREF_TYPE OPpLVREF_SV OPpLVREF_AV OPpLVREF_HV
73                 OPpLVREF_CV OPpLVREF_ELEM SVpad_STATE)) {
74         eval { B->import($_) };
75         no strict 'refs';
76         *{$_} = sub () {0} unless *{$_}{CODE};
77     }
78 }
79
80 # Todo:
81 #  (See also BUGS section at the end of this file)
82 #
83 # - finish tr/// changes
84 # - add option for even more parens (generalize \&foo change)
85 # - left/right context
86 # - copy comments (look at real text with $^P?)
87 # - avoid semis in one-statement blocks
88 # - associativity of &&=, ||=, ?:
89 # - ',' => '=>' (auto-unquote?)
90 # - break long lines ("\r" as discretionary break?)
91 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
92 # - more style options: brace style, hex vs. octal, quotes, ...
93 # - print big ints as hex/octal instead of decimal (heuristic?)
94 # - handle 'my $x if 0'?
95 # - version using op_next instead of op_first/sibling?
96 # - avoid string copies (pass arrays, one big join?)
97 # - here-docs?
98
99 # Current test.deparse failures
100 # comp/hints 6 - location of BEGIN blocks wrt. block openings
101 # run/switchI 1 - missing -I switches entirely
102 #    perl -Ifoo -e 'print @INC'
103 # op/caller 2 - warning mask propagates backwards before warnings::register
104 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
105 # op/getpid 2 - can't assign to shared my() declaration (threads only)
106 #    'my $x : shared = 5'
107 # op/override 7 - parens on overridden require change v-string interpretation
108 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
109 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
110 # op/pat 774 - losing Unicode-ness of Latin1-only strings
111 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
112 # op/recurse 12 - missing parens on recursive call makes it look like method
113 #    'sub f { f($x) }'
114 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
115 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
116 # op/tiehandle compile - "use strict" deparsed in the wrong place
117 # uni/tr_ several
118 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
119 # ext/Data/Dumper/t/dumper compile
120 # ext/DB_file/several
121 # ext/Encode/several
122 # ext/Ernno/Errno warnings
123 # ext/IO/lib/IO/t/io_sel 23
124 # ext/PerlIO/t/encoding compile
125 # ext/POSIX/t/posix 6
126 # ext/Socket/Socket 8
127 # ext/Storable/t/croak compile
128 # lib/Attribute/Handlers/t/multi compile
129 # lib/bignum/ several
130 # lib/charnames 35
131 # lib/constant 32
132 # lib/English 40
133 # lib/ExtUtils/t/bytes 4
134 # lib/File/DosGlob compile
135 # lib/Filter/Simple/t/data 1
136 # lib/Math/BigInt/t/constant 1
137 # lib/Net/t/config Deparse-warning
138 # lib/overload compile
139 # lib/Switch/ several
140 # lib/Symbol 4
141 # lib/Test/Simple several
142 # lib/Term/Complete
143 # lib/Tie/File/t/29_downcopy 5
144 # lib/vars 22
145
146 # Object fields:
147 #
148 # in_coderef2text:
149 # True when deparsing via $deparse->coderef2text; false when deparsing the
150 # main program.
151 #
152 # avoid_local:
153 # (local($a), local($b)) and local($a, $b) have the same internal
154 # representation but the short form looks better. We notice we can
155 # use a large-scale local when checking the list, but need to prevent
156 # individual locals too. This hash holds the addresses of OPs that
157 # have already had their local-ness accounted for. The same thing
158 # is done with my().
159 #
160 # curcv:
161 # CV for current sub (or main program) being deparsed
162 #
163 # curcvlex:
164 # Cached hash of lexical variables for curcv: keys are
165 # names prefixed with "m" or "o" (representing my/our), and
166 # each value is an array with two elements indicating the cop_seq
167 # of scopes in which a var of that name is valid and a third ele-
168 # ment referencing the pad name.
169 #
170 # curcop:
171 # COP for statement being deparsed
172 #
173 # curstash:
174 # name of the current package for deparsed code
175 #
176 # subs_todo:
177 # array of [cop_seq, CV, is_format?, name] for subs and formats we still
178 # want to deparse.  The fourth element is a pad name thingy for lexical
179 # subs or a string for special blocks.  For other subs, it is undef.  For
180 # lexical subs, CV may be undef, indicating a stub declaration.
181 #
182 # protos_todo:
183 # as above, but [name, prototype] for subs that never got a GV
184 #
185 # subs_done, forms_done:
186 # keys are addresses of GVs for subs and formats we've already
187 # deparsed (or at least put into subs_todo)
188 #
189 # subs_declared
190 # keys are names of subs for which we've printed declarations.
191 # That means we can omit parentheses from the arguments. It also means we
192 # need to put CORE:: on core functions of the same name.
193 #
194 # in_subst_repl
195 # True when deparsing the replacement part of a substitution.
196 #
197 # in_refgen
198 # True when deparsing the argument to \.
199 #
200 # parens: -p
201 # linenums: -l
202 # unquote: -q
203 # cuddle: ' ' or '\n', depending on -sC
204 # indent_size: -si
205 # use_tabs: -sT
206 # ex_const: -sv
207
208 # A little explanation of how precedence contexts and associativity
209 # work:
210 #
211 # deparse() calls each per-op subroutine with an argument $cx (short
212 # for context, but not the same as the cx* in the perl core), which is
213 # a number describing the op's parents in terms of precedence, whether
214 # they're inside an expression or at statement level, etc.  (see
215 # chart below). When ops with children call deparse on them, they pass
216 # along their precedence. Fractional values are used to implement
217 # associativity ('($x + $y) + $z' => '$x + $y + $y') and related
218 # parentheses hacks. The major disadvantage of this scheme is that
219 # it doesn't know about right sides and left sides, so say if you
220 # assign a listop to a variable, it can't tell it's allowed to leave
221 # the parens off the listop.
222
223 # Precedences:
224 # 26             [TODO] inside interpolation context ("")
225 # 25 left        terms and list operators (leftward)
226 # 24 left        ->
227 # 23 nonassoc    ++ --
228 # 22 right       **
229 # 21 right       ! ~ \ and unary + and -
230 # 20 left        =~ !~
231 # 19 left        * / % x
232 # 18 left        + - .
233 # 17 left        << >>
234 # 16 nonassoc    named unary operators
235 # 15 nonassoc    < > <= >= lt gt le ge
236 # 14 nonassoc    == != <=> eq ne cmp
237 # 13 left        &
238 # 12 left        | ^
239 # 11 left        &&
240 # 10 left        ||
241 #  9 nonassoc    ..  ...
242 #  8 right       ?:
243 #  7 right       = += -= *= etc.
244 #  6 left        , =>
245 #  5 nonassoc    list operators (rightward)
246 #  4 right       not
247 #  3 left        and
248 #  2 left        or xor
249 #  1             statement modifiers
250 #  0.5           statements, but still print scopes as do { ... }
251 #  0             statement level
252 # -1             format body
253
254 # Nonprinting characters with special meaning:
255 # \cS - steal parens (see maybe_parens_unop)
256 # \n - newline and indent
257 # \t - increase indent
258 # \b - decrease indent ('outdent')
259 # \f - flush left (no indent)
260 # \cK - kill following semicolon, if any
261
262 # Semicolon handling:
263 #  - Individual statements are not deparsed with trailing semicolons.
264 #    (If necessary, \cK is tacked on to the end.)
265 #  - Whatever code joins statements together or emits them (lineseq,
266 #    scopeop, deparse_root) is responsible for adding semicolons where
267 #    necessary.
268 #  - use statements are deparsed with trailing semicolons because they are
269 #    immediately concatenated with the following statement.
270 #  - indent() removes semicolons wherever it sees \cK.
271
272
273 BEGIN { for (qw[ const stringify rv2sv list glob pushmark null aelem
274                  kvaslice kvhslice padsv
275                  nextstate dbstate rv2av rv2hv helem custom ]) {
276     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
277 }}
278
279 # _pessimise_walk(): recursively walk the optree of a sub,
280 # possibly undoing optimisations along the way.
281
282 sub _pessimise_walk {
283     my ($self, $startop) = @_;
284
285     return unless $$startop;
286     my ($op, $prevop);
287     for ($op = $startop; $$op; $prevop = $op, $op = $op->sibling) {
288         my $ppname = $op->name;
289
290         # pessimisations start here
291
292         if ($ppname eq "padrange") {
293             # remove PADRANGE:
294             # the original optimisation either (1) changed this:
295             #    pushmark -> (various pad and list and null ops) -> the_rest
296             # or (2), for the = @_ case, changed this:
297             #    pushmark -> gv[_] -> rv2av -> (pad stuff)       -> the_rest
298             # into this:
299             #    padrange ----------------------------------------> the_rest
300             # so we just need to convert the padrange back into a
301             # pushmark, and in case (1), set its op_next to op_sibling,
302             # which is the head of the original chain of optimised-away
303             # pad ops, or for (2), set it to sibling->first, which is
304             # the original gv[_].
305
306             $B::overlay->{$$op} = {
307                     type => OP_PUSHMARK,
308                     name => 'pushmark',
309                     private => ($op->private & OPpLVAL_INTRO),
310             };
311         }
312
313         # pessimisations end here
314
315         if (class($op) eq 'PMOP') {
316             if (ref($op->pmreplroot)
317                 && ${$op->pmreplroot}
318                 && $op->pmreplroot->isa( 'B::OP' ))
319             {
320                 $self-> _pessimise_walk($op->pmreplroot);
321             }
322
323             # pessimise any /(?{...})/ code blocks
324             my ($re, $cv);
325             my $code_list = $op->code_list;
326             if ($$code_list) {
327                 $self->_pessimise_walk($code_list);
328             }
329             elsif (${$re = $op->pmregexp} && ${$cv = $re->qr_anoncv}) {
330                 $code_list = $cv->ROOT      # leavesub
331                                ->first      #   qr
332                                ->code_list; #     list
333                 $self->_pessimise_walk($code_list);
334             }
335         }
336
337         if ($op->flags & OPf_KIDS) {
338             $self-> _pessimise_walk($op->first);
339         }
340
341     }
342 }
343
344
345 # _pessimise_walk_exe(): recursively walk the op_next chain of a sub,
346 # possibly undoing optimisations along the way.
347
348 sub _pessimise_walk_exe {
349     my ($self, $startop, $visited) = @_;
350
351     no warnings 'recursion';
352
353     return unless $$startop;
354     return if $visited->{$$startop};
355     my ($op, $prevop);
356     for ($op = $startop; $$op; $prevop = $op, $op = $op->next) {
357         last if $visited->{$$op};
358         $visited->{$$op} = 1;
359         my $ppname = $op->name;
360         if ($ppname =~
361             /^((and|d?or)(assign)?|(map|grep)while|range|cond_expr|once)$/
362             # entertry is also a logop, but its op_other invariably points
363             # into the same chain as the main execution path, so we skip it
364         ) {
365             $self->_pessimise_walk_exe($op->other, $visited);
366         }
367         elsif ($ppname eq "subst") {
368             $self->_pessimise_walk_exe($op->pmreplstart, $visited);
369         }
370         elsif ($ppname =~ /^(enter(loop|iter))$/) {
371             # redoop and nextop will already be covered by the main block
372             # of the loop
373             $self->_pessimise_walk_exe($op->lastop, $visited);
374         }
375
376         # pessimisations start here
377     }
378 }
379
380 # Go through an optree and "remove" some optimisations by using an
381 # overlay to selectively modify or un-null some ops. Deparsing in the
382 # absence of those optimisations is then easier.
383 #
384 # Note that older optimisations are not removed, as Deparse was already
385 # written to recognise them before the pessimise/overlay system was added.
386
387 sub pessimise {
388     my ($self, $root, $start) = @_;
389
390     no warnings 'recursion';
391     # walk tree in root-to-branch order
392     $self->_pessimise_walk($root);
393
394     my %visited;
395     # walk tree in execution order
396     $self->_pessimise_walk_exe($start, \%visited);
397 }
398
399
400 sub null {
401     my $op = shift;
402     return class($op) eq "NULL";
403 }
404
405
406 # Add a CV to the list of subs that still need deparsing.
407
408 sub todo {
409     my $self = shift;
410     my($cv, $is_form, $name) = @_;
411     my $cvfile = $cv->FILE//'';
412     return unless ($cvfile eq $0 || exists $self->{files}{$cvfile});
413     my $seq;
414     if ($cv->OUTSIDE_SEQ) {
415         $seq = $cv->OUTSIDE_SEQ;
416     } elsif (!null($cv->START) and is_state($cv->START)) {
417         $seq = $cv->START->cop_seq;
418     } else {
419         $seq = 0;
420     }
421     my $stash = $cv->STASH;
422     if (class($stash) eq 'HV') {
423         $self->{packs}{$stash->NAME}++;
424     }
425     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form, $name];
426 }
427
428
429 # Pop the next sub from the todo list and deparse it
430
431 sub next_todo {
432     my $self = shift;
433     my $ent = shift @{$self->{'subs_todo'}};
434     my ($seq, $cv, $is_form, $name) = @$ent;
435
436     # any 'use strict; package foo' that should come before the sub
437     # declaration to sync with the first COP of the sub
438     my $pragmata = '';
439     if ($cv and !null($cv->START) and is_state($cv->START))  {
440         $pragmata = $self->pragmata($cv->START);
441     }
442
443     if (ref $name) { # lexical sub
444         # emit the sub.
445         my @text;
446         my $flags = $name->FLAGS;
447         push @text,
448             !$cv || $seq <= $name->COP_SEQ_RANGE_LOW
449                 ? $self->keyword($flags & SVpad_OUR
450                                     ? "our"
451                                     : $flags & SVpad_STATE
452                                         ? "state"
453                                         : "my") . " "
454                 : "";
455         # XXX We would do $self->keyword("sub"), but ‘my CORE::sub’
456         #     doesn’t work and ‘my sub’ ignores a &sub in scope.  I.e.,
457         #     we have a core bug here.
458         push @text, "sub " . substr $name->PVX, 1;
459         if ($cv) {
460             # my sub foo { }
461             push @text,  " " . $self->deparse_sub($cv);
462             $text[-1] =~ s/ ;$/;/;
463         }
464         else {
465             # my sub foo;
466             push @text, ";\n";
467         }
468         return $pragmata . join "", @text;
469     }
470
471     my $gv = $cv->GV;
472     $name //= $self->gv_name($gv);
473     if ($is_form) {
474         return $pragmata . $self->keyword("format") . " $name =\n"
475             . $self->deparse_format($cv). "\n";
476     } else {
477         my $use_dec;
478         if ($name eq "BEGIN") {
479             $use_dec = $self->begin_is_use($cv);
480             if (defined ($use_dec) and $self->{'expand'} < 5) {
481                 return $pragmata if 0 == length($use_dec);
482
483                 #  XXX bit of a hack: Test::More's use_ok() method
484                 #  builds a fake use statement which deparses as, e.g.
485                 #      use Net::Ping (@{$args[0];});
486                 #  As well as being superfluous (the use_ok() is deparsed
487                 #  too) and ugly, it fails under use strict and otherwise
488                 #  makes use of a lexical var that's not in scope.
489                 #  So strip it out.
490                 return $pragmata
491                         if $use_dec =~
492                             m/
493                                 \A
494                                 use \s \S+ \s \(\@\{
495                                 (
496                                     \s*\#line\ \d+\ \".*"\s*
497                                 )?
498                                 \$args\[0\];\}\);
499                                 \n
500                                 \Z
501                             /x;
502
503                 $use_dec =~ s/^(use|no)\b/$self->keyword($1)/e;
504             }
505         }
506         my $l = '';
507         if ($self->{'linenums'}) {
508             my $line = $gv->LINE;
509             my $file = $gv->FILE;
510             $l = "\n\f#line $line \"$file\"\n";
511         }
512         my $p = '';
513         my $stash;
514         if (class($cv->STASH) ne "SPECIAL") {
515             $stash = $cv->STASH->NAME;
516             if ($stash ne $self->{'curstash'}) {
517                 $p = $self->keyword("package") . " $stash;\n";
518                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
519                 $self->{'curstash'} = $stash;
520             }
521         }
522         if ($use_dec) {
523             return "$pragmata$p$l$use_dec";
524         }
525         if ( $name !~ /::/ and $self->lex_in_scope("&$name")
526                             || $self->lex_in_scope("&$name", 1) )
527         {
528             $name = "$self->{'curstash'}::$name";
529         } elsif (defined $stash) {
530             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
531         }
532         my $ret = "$pragmata${p}${l}" . $self->keyword("sub") . " $name "
533               . $self->deparse_sub($cv);
534         $self->{'subs_declared'}{$name} = 1;
535         return $ret;
536     }
537 }
538
539
540 # Return a "use" declaration for this BEGIN block, if appropriate
541 sub begin_is_use {
542     my ($self, $cv) = @_;
543     my $root = $cv->ROOT;
544     local @$self{qw'curcv curcvlex'} = ($cv);
545     local $B::overlay = {};
546     $self->pessimise($root, $cv->START);
547 #require B::Debug;
548 #B::walkoptree($cv->ROOT, "debug");
549     my $lineseq = $root->first;
550     return if $lineseq->name ne "lineseq";
551
552     my $req_op = $lineseq->first->sibling;
553     return if $req_op->name ne "require";
554
555     # maybe it's C<require expr> rather than C<require 'foo'>
556     return if ($req_op->first->name ne 'const');
557
558     my $module;
559     if ($req_op->first->private & OPpCONST_BARE) {
560         # Actually it should always be a bareword
561         $module = $self->const_sv($req_op->first)->PV;
562         $module =~ s[/][::]g;
563         $module =~ s/.pm$//;
564     }
565     else {
566         $module = $self->const($self->const_sv($req_op->first), 6);
567     }
568
569     my $version;
570     my $version_op = $req_op->sibling;
571     return if class($version_op) eq "NULL";
572     if ($version_op->name eq "lineseq") {
573         # We have a version parameter; skip nextstate & pushmark
574         my $constop = $version_op->first->next->next;
575
576         return unless $self->const_sv($constop)->PV eq $module;
577         $constop = $constop->sibling;
578         $version = $self->const_sv($constop);
579         if (class($version) eq "IV") {
580             $version = $version->int_value;
581         } elsif (class($version) eq "NV") {
582             $version = $version->NV;
583         } elsif (class($version) ne "PVMG") {
584             # Includes PVIV and PVNV
585             $version = $version->PV;
586         } else {
587             # version specified as a v-string
588             $version = 'v'.join '.', map ord, split //, $version->PV;
589         }
590         $constop = $constop->sibling;
591         return if $constop->name ne "method_named";
592         return if $self->meth_sv($constop)->PV ne "VERSION";
593     }
594
595     $lineseq = $version_op->sibling;
596     return if $lineseq->name ne "lineseq";
597     my $entersub = $lineseq->first->sibling;
598     if ($entersub->name eq "stub") {
599         return "use $module $version ();\n" if defined $version;
600         return "use $module ();\n";
601     }
602     return if $entersub->name ne "entersub";
603
604     # See if there are import arguments
605     my $args = '';
606
607     my $svop = $entersub->first->sibling; # Skip over pushmark
608     return unless $self->const_sv($svop)->PV eq $module;
609
610     # Pull out the arguments
611     for ($svop=$svop->sibling; index($svop->name, "method_") != 0;
612                 $svop = $svop->sibling) {
613         $args .= ", " if length($args);
614         $args .= $self->deparse($svop, 6);
615     }
616
617     my $use = 'use';
618     my $method_named = $svop;
619     return if $method_named->name ne "method_named";
620     my $method_name = $self->meth_sv($method_named)->PV;
621
622     if ($method_name eq "unimport") {
623         $use = 'no';
624     }
625
626     # Certain pragmas are dealt with using hint bits,
627     # so we ignore them here
628     if ($module eq 'strict' || $module eq 'integer'
629         || $module eq 'bytes' || $module eq 'warnings'
630         || $module eq 'feature') {
631         return "";
632     }
633
634     if (defined $version && length $args) {
635         return "$use $module $version ($args);\n";
636     } elsif (defined $version) {
637         return "$use $module $version;\n";
638     } elsif (length $args) {
639         return "$use $module ($args);\n";
640     } else {
641         return "$use $module;\n";
642     }
643 }
644
645 sub stash_subs {
646     my ($self, $pack, $seen) = @_;
647     my (@ret, $stash);
648     if (!defined $pack) {
649         $pack = '';
650         $stash = \%::;
651     }
652     else {
653         $pack =~ s/(::)?$/::/;
654         no strict 'refs';
655         $stash = \%{"main::$pack"};
656     }
657     return
658         if ($seen ||= {})->{
659             $INC{"overload.pm"} ? overload::StrVal($stash) : $stash
660            }++;
661     my $stashobj = svref_2object($stash);
662     my %stash = $stashobj->ARRAY;
663     while (my ($key, $val) = each %stash) {
664         my $flags = $val->FLAGS;
665         if ($flags & SVf_ROK) {
666             # A reference.  Dump this if it is a reference to a CV.  If it
667             # is a constant acting as a proxy for a full subroutine, then
668             # we may or may not have to dump it.  If some form of perl-
669             # space visible code must have created it, be it a use
670             # statement, or some direct symbol-table manipulation code that
671             # we will deparse, then we don’t want to dump it.  If it is the
672             # result of a declaration like sub f () { 42 } then we *do*
673             # want to dump it.  The only way to distinguish these seems
674             # to be the SVs_PADTMP flag on the constant, which is admit-
675             # tedly a hack.
676             my $class = class(my $referent = $val->RV);
677             if ($class eq "CV") {
678                 $self->todo($referent, 0);
679             } elsif (
680                 $class !~ /^(AV|HV|CV|FM|IO|SPECIAL)\z/
681                 # A more robust way to write that would be this, but B does
682                 # not provide the SVt_ constants:
683                 # ($referent->FLAGS & B::SVTYPEMASK) < B::SVt_PVAV
684                 and $referent->FLAGS & SVs_PADTMP
685             ) {
686                 push @{$self->{'protos_todo'}}, [$pack . $key, $val];
687             }
688         } elsif ($flags & (SVf_POK|SVf_IOK)) {
689             # Just a prototype. As an ugly but fairly effective way
690             # to find out if it belongs here is to see if the AUTOLOAD
691             # (if any) for the stash was defined in one of our files.
692             my $A = $stash{"AUTOLOAD"};
693             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
694                 && class($A->CV) eq "CV") {
695                 my $AF = $A->FILE;
696                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
697             }
698             push @{$self->{'protos_todo'}},
699                  [$pack . $key, $flags & SVf_POK ? $val->PV: undef];
700         } elsif (class($val) eq "GV") {
701             if (class(my $cv = $val->CV) ne "SPECIAL") {
702                 next if $self->{'subs_done'}{$$val}++;
703
704                 # Ignore imposters (aliases etc)
705                 my $name = $cv->NAME_HEK;
706                 if(defined $name) {
707                     # avoid using $cv->GV here because if the $val GV is
708                     # an alias, CvGV() could upgrade the real stash entry
709                     # from an RV to a GV
710                     next unless $name eq $key;
711                     next unless $$stashobj == ${$cv->STASH};
712                 }
713                 else {
714                    next if $$val != ${$cv->GV};
715                 }
716
717                 $self->todo($cv, 0);
718             }
719             if (class(my $cv = $val->FORM) ne "SPECIAL") {
720                 next if $self->{'forms_done'}{$$val}++;
721                 next if $$val != ${$cv->GV};   # Ignore imposters
722                 $self->todo($cv, 1);
723             }
724             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
725                 $self->stash_subs($pack . $key, $seen);
726             }
727         }
728     }
729 }
730
731 sub print_protos {
732     my $self = shift;
733     my $ar;
734     my @ret;
735     foreach $ar (@{$self->{'protos_todo'}}) {
736         if (ref $ar->[1]) {
737             # Only print a constant if it occurs in the same package as a
738             # dumped sub.  This is not perfect, but a heuristic that will
739             # hopefully work most of the time.  Ideally we would use
740             # CvFILE, but a constant stub has no CvFILE.
741             my $pack = ($ar->[0] =~ /(.*)::/)[0];
742             next if $pack and !$self->{packs}{$pack}
743         }
744         my $body = defined $ar->[1]
745                 ? ref $ar->[1]
746                     ? " () {\n    " . $self->const($ar->[1]->RV,0) . ";\n}"
747                     : " (". $ar->[1] . ");"
748                 : ";";
749         push @ret, "sub " . $ar->[0] .  "$body\n";
750     }
751     delete $self->{'protos_todo'};
752     return @ret;
753 }
754
755 sub style_opts {
756     my $self = shift;
757     my $opts = shift;
758     my $opt;
759     while (length($opt = substr($opts, 0, 1))) {
760         if ($opt eq "C") {
761             $self->{'cuddle'} = " ";
762             $opts = substr($opts, 1);
763         } elsif ($opt eq "i") {
764             $opts =~ s/^i(\d+)//;
765             $self->{'indent_size'} = $1;
766         } elsif ($opt eq "T") {
767             $self->{'use_tabs'} = 1;
768             $opts = substr($opts, 1);
769         } elsif ($opt eq "v") {
770             $opts =~ s/^v([^.]*)(.|$)//;
771             $self->{'ex_const'} = $1;
772         }
773     }
774 }
775
776 sub new {
777     my $class = shift;
778     my $self = bless {}, $class;
779     $self->{'cuddle'} = "\n";
780     $self->{'curcop'} = undef;
781     $self->{'curstash'} = "main";
782     $self->{'ex_const'} = "'???'";
783     $self->{'expand'} = 0;
784     $self->{'files'} = {};
785     $self->{'packs'} = {};
786     $self->{'indent_size'} = 4;
787     $self->{'linenums'} = 0;
788     $self->{'parens'} = 0;
789     $self->{'subs_todo'} = [];
790     $self->{'unquote'} = 0;
791     $self->{'use_dumper'} = 0;
792     $self->{'use_tabs'} = 0;
793
794     $self->{'ambient_arybase'} = 0;
795     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
796     $self->{'ambient_hints'} = 0;
797     $self->{'ambient_hinthash'} = undef;
798     $self->init();
799
800     while (my $arg = shift @_) {
801         if ($arg eq "-d") {
802             $self->{'use_dumper'} = 1;
803             require Data::Dumper;
804         } elsif ($arg =~ /^-f(.*)/) {
805             $self->{'files'}{$1} = 1;
806         } elsif ($arg eq "-l") {
807             $self->{'linenums'} = 1;
808         } elsif ($arg eq "-p") {
809             $self->{'parens'} = 1;
810         } elsif ($arg eq "-P") {
811             $self->{'noproto'} = 1;
812         } elsif ($arg eq "-q") {
813             $self->{'unquote'} = 1;
814         } elsif (substr($arg, 0, 2) eq "-s") {
815             $self->style_opts(substr $arg, 2);
816         } elsif ($arg =~ /^-x(\d)$/) {
817             $self->{'expand'} = $1;
818         }
819     }
820     return $self;
821 }
822
823 {
824     # Mask out the bits that L<warnings::register> uses
825     my $WARN_MASK;
826     BEGIN {
827         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
828     }
829     sub WARN_MASK () {
830         return $WARN_MASK;
831     }
832 }
833
834 # Initialise the contextual information, either from
835 # defaults provided with the ambient_pragmas method,
836 # or from perl's own defaults otherwise.
837 sub init {
838     my $self = shift;
839
840     $self->{'arybase'}  = $self->{'ambient_arybase'};
841     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
842                                 ? $self->{'ambient_warnings'} & WARN_MASK
843                                 : undef;
844     $self->{'hints'}    = $self->{'ambient_hints'};
845     $self->{'hinthash'} = $self->{'ambient_hinthash'};
846
847     # also a convenient place to clear out subs_declared
848     delete $self->{'subs_declared'};
849 }
850
851 sub compile {
852     my(@args) = @_;
853     return sub {
854         my $self = B::Deparse->new(@args);
855         # First deparse command-line args
856         if (defined $^I) { # deparse -i
857             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
858         }
859         if ($^W) { # deparse -w
860             print qq(BEGIN { \$^W = $^W; }\n);
861         }
862         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
863             my $fs = perlstring($/) || 'undef';
864             my $bs = perlstring($O::savebackslash) || 'undef';
865             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
866         }
867         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
868         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
869             ? B::unitcheck_av->ARRAY
870             : ();
871         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
872         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
873         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
874         my @names = qw(BEGIN UNITCHECK CHECK INIT END);
875         my @blocks = \(@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs);
876         while (@names) {
877             my ($name, $blocks) = (shift @names, shift @blocks);
878             for my $block (@$blocks) {
879                 $self->todo($block, 0, $name);
880             }
881         }
882         $self->stash_subs();
883         local($SIG{"__DIE__"}) =
884           sub {
885               if ($self->{'curcop'}) {
886                   my $cop = $self->{'curcop'};
887                   my($line, $file) = ($cop->line, $cop->file);
888                   print STDERR "While deparsing $file near line $line,\n";
889               }
890             };
891         $self->{'curcv'} = main_cv;
892         $self->{'curcvlex'} = undef;
893         print $self->print_protos;
894         @{$self->{'subs_todo'}} =
895           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
896         my $root = main_root;
897         local $B::overlay = {};
898         unless (null $root) {
899             $self->pad_subs($self->{'curcv'});
900             # Check for a stub-followed-by-ex-cop, resulting from a program
901             # consisting solely of sub declarations.  For backward-compati-
902             # bility (and sane output) we don’t want to emit the stub.
903             #   leave
904             #     enter
905             #     stub
906             #     ex-nextstate (or ex-dbstate)
907             my $kid;
908             if ( $root->name eq 'leave'
909              and ($kid = $root->first)->name eq 'enter'
910              and !null($kid = $kid->sibling) and $kid->name eq 'stub'
911              and !null($kid = $kid->sibling) and $kid->name eq 'null'
912              and class($kid) eq 'COP' and null $kid->sibling )
913             {
914                 # ignore
915             } else {
916                 $self->pessimise($root, main_start);
917                 print $self->indent($self->deparse_root($root)), "\n";
918             }
919         }
920         my @text;
921         while (scalar(@{$self->{'subs_todo'}})) {
922             push @text, $self->next_todo;
923         }
924         print $self->indent(join("", @text)), "\n" if @text;
925
926         # Print __DATA__ section, if necessary
927         no strict 'refs';
928         my $laststash = defined $self->{'curcop'}
929             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
930         if (defined *{$laststash."::DATA"}{IO}) {
931             print $self->keyword("package") . " $laststash;\n"
932                 unless $laststash eq $self->{'curstash'};
933             print $self->keyword("__DATA__") . "\n";
934             print readline(*{$laststash."::DATA"});
935         }
936     }
937 }
938
939 sub coderef2text {
940     my $self = shift;
941     my $sub = shift;
942     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
943
944     $self->init();
945     local $self->{in_coderef2text} = 1;
946     return $self->indent($self->deparse_sub(svref_2object($sub)));
947 }
948
949 my %strict_bits = do {
950     local $^H;
951     map +($_ => strict::bits($_)), qw/refs subs vars/
952 };
953
954 sub ambient_pragmas {
955     my $self = shift;
956     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
957
958     while (@_ > 1) {
959         my $name = shift();
960         my $val  = shift();
961
962         if ($name eq 'strict') {
963             require strict;
964
965             if ($val eq 'none') {
966                 $hint_bits &= $strict_bits{$_} for qw/refs subs vars/;
967                 next();
968             }
969
970             my @names;
971             if ($val eq "all") {
972                 @names = qw/refs subs vars/;
973             }
974             elsif (ref $val) {
975                 @names = @$val;
976             }
977             else {
978                 @names = split' ', $val;
979             }
980             $hint_bits |= $strict_bits{$_} for @names;
981         }
982
983         elsif ($name eq '$[') {
984             if (OPpCONST_ARYBASE) {
985                 $arybase = $val;
986             } else {
987                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
988             }
989         }
990
991         elsif ($name eq 'integer'
992             || $name eq 'bytes'
993             || $name eq 'utf8') {
994             require "$name.pm";
995             if ($val) {
996                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
997             }
998             else {
999                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
1000             }
1001         }
1002
1003         elsif ($name eq 're') {
1004             require re;
1005             if ($val eq 'none') {
1006                 $hint_bits &= ~re::bits(qw/taint eval/);
1007                 next();
1008             }
1009
1010             my @names;
1011             if ($val eq 'all') {
1012                 @names = qw/taint eval/;
1013             }
1014             elsif (ref $val) {
1015                 @names = @$val;
1016             }
1017             else {
1018                 @names = split' ',$val;
1019             }
1020             $hint_bits |= re::bits(@names);
1021         }
1022
1023         elsif ($name eq 'warnings') {
1024             if ($val eq 'none') {
1025                 $warning_bits = $warnings::NONE;
1026                 next();
1027             }
1028
1029             my @names;
1030             if (ref $val) {
1031                 @names = @$val;
1032             }
1033             else {
1034                 @names = split/\s+/, $val;
1035             }
1036
1037             $warning_bits = $warnings::NONE if !defined ($warning_bits);
1038             $warning_bits |= warnings::bits(@names);
1039         }
1040
1041         elsif ($name eq 'warning_bits') {
1042             $warning_bits = $val;
1043         }
1044
1045         elsif ($name eq 'hint_bits') {
1046             $hint_bits = $val;
1047         }
1048
1049         elsif ($name eq '%^H') {
1050             $hinthash = $val;
1051         }
1052
1053         else {
1054             croak "Unknown pragma type: $name";
1055         }
1056     }
1057     if (@_) {
1058         croak "The ambient_pragmas method expects an even number of args";
1059     }
1060
1061     $self->{'ambient_arybase'} = $arybase;
1062     $self->{'ambient_warnings'} = $warning_bits;
1063     $self->{'ambient_hints'} = $hint_bits;
1064     $self->{'ambient_hinthash'} = $hinthash;
1065 }
1066
1067 # This method is the inner loop, so try to keep it simple
1068 sub deparse {
1069     my $self = shift;
1070     my($op, $cx) = @_;
1071
1072     Carp::confess("Null op in deparse") if !defined($op)
1073                                         || class($op) eq "NULL";
1074     my $meth = "pp_" . $op->name;
1075     return $self->$meth($op, $cx);
1076 }
1077
1078 sub indent {
1079     my $self = shift;
1080     my $txt = shift;
1081     # \cK also swallows a preceding line break when followed by a
1082     # semicolon.
1083     $txt =~ s/\n\cK;//g;
1084     my @lines = split(/\n/, $txt);
1085     my $leader = "";
1086     my $level = 0;
1087     my $line;
1088     for $line (@lines) {
1089         my $cmd = substr($line, 0, 1);
1090         if ($cmd eq "\t" or $cmd eq "\b") {
1091             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
1092             if ($self->{'use_tabs'}) {
1093                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
1094             } else {
1095                 $leader = " " x $level;
1096             }
1097             $line = substr($line, 1);
1098         }
1099         if (index($line, "\f") > 0) {
1100                 $line =~ s/\f/\n/;
1101         }
1102         if (substr($line, 0, 1) eq "\f") {
1103             $line = substr($line, 1); # no indent
1104         } else {
1105             $line = $leader . $line;
1106         }
1107         $line =~ s/\cK;?//g;
1108     }
1109     return join("\n", @lines);
1110 }
1111
1112 sub pad_subs {
1113     my ($self, $cv) = @_;
1114     my $padlist = $cv->PADLIST;
1115     my @names = $padlist->ARRAYelt(0)->ARRAY;
1116     my @values = $padlist->ARRAYelt(1)->ARRAY;
1117     my @todo;
1118   PADENTRY:
1119     for my $ix (0.. $#names) { for $_ ($names[$ix]) {
1120         next if class($_) eq "SPECIAL";
1121         my $name = $_->PVX;
1122         if (defined $name && $name =~ /^&./) {
1123             my $low = $_->COP_SEQ_RANGE_LOW;
1124             my $flags = $_->FLAGS;
1125             my $outer = $flags & PADNAMEt_OUTER;
1126             if ($flags & SVpad_OUR) {
1127                 push @todo, [$low, undef, 0, $_]
1128                           # [seq, no cv, not format, padname]
1129                     unless $outer;
1130                 next;
1131             }
1132             my $protocv = $flags & SVpad_STATE
1133                 ? $values[$ix]
1134                 : $_->PROTOCV;
1135             if (class ($protocv) ne 'CV') {
1136                 my $flags = $flags;
1137                 my $cv = $cv;
1138                 my $name = $_;
1139                 while ($flags & PADNAMEt_OUTER && class ($protocv) ne 'CV')
1140                 {
1141                     $cv = $cv->OUTSIDE;
1142                     next PADENTRY if class($cv) eq 'SPECIAL'; # XXX freed?
1143                     my $padlist = $cv->PADLIST;
1144                     my $ix = $name->PARENT_PAD_INDEX;
1145                     $name = $padlist->NAMES->ARRAYelt($ix);
1146                     $flags = $name->FLAGS;
1147                     $protocv = $flags & SVpad_STATE
1148                         ? $padlist->ARRAYelt(1)->ARRAYelt($ix)
1149                         : $name->PROTOCV;
1150                 }
1151             }
1152             my $defined_in_this_sub = ${$protocv->OUTSIDE} == $$cv || do {
1153                 my $other = $protocv->PADLIST;
1154                 $$other && $other->outid == $padlist->id;
1155             };
1156             if ($flags & PADNAMEt_OUTER) {
1157                 next unless $defined_in_this_sub;
1158                 push @todo, [$protocv->OUTSIDE_SEQ, $protocv, 0, $_];
1159                 next;
1160             }
1161             my $outseq = $protocv->OUTSIDE_SEQ;
1162             if ($outseq <= $low) {
1163                 # defined before its name is visible, so it’s gotta be
1164                 # declared and defined at once: my sub foo { ... }
1165                 push @todo, [$low, $protocv, 0, $_];
1166             }
1167             else {
1168                 # declared and defined separately: my sub f; sub f { ... }
1169                 push @todo, [$low, undef, 0, $_];
1170                 push @todo, [$outseq, $protocv, 0, $_]
1171                     if $defined_in_this_sub;
1172             }
1173         }
1174     }}
1175     @{$self->{'subs_todo'}} =
1176         sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}}, @todo
1177 }
1178
1179
1180 # deparse_argops(): deparse, if possible, a sequence of argcheck + argelem
1181 # ops into a subroutine signature. If successful, return the first op
1182 # following the signature ops plus the signature string; else return the
1183 # empty list.
1184 #
1185 # Normally a bunch of argelem ops will have been generated by the
1186 # signature parsing, but it's possible that ops have been added manually
1187 # or altered. In this case we return "()" and fall back to general
1188 # deparsing of the individual sigelems as 'my $x = $_[N]' etc.
1189 #
1190 # We're only called if the first two ops are nextstate and argcheck.
1191
1192 sub deparse_argops {
1193     my ($self, $firstop, $cv) = @_;
1194
1195     my @sig;
1196     my $o = $firstop;
1197     return if $o->label; #first nextstate;
1198
1199     # OP_ARGCHECK
1200
1201     $o = $o->sibling;
1202     my ($params, $opt_params, $slurpy) = $o->aux_list($cv);
1203     my $mandatory = $params - $opt_params;
1204     my $seen_slurpy = 0;
1205     my $last_ix = -1;
1206
1207     # keep looking for valid nextstate + argelem pairs
1208
1209     while (1) {
1210         # OP_NEXTSTATE
1211         $o = $o->sibling;
1212         last unless $$o;
1213         last unless $o->name =~ /^(next|db)state$/;
1214         last if $o->label;
1215
1216         # OP_ARGELEM
1217         my $o2 = $o->sibling;
1218         last unless $$o2;
1219
1220         if ($o2->name eq 'argelem') {
1221             my $ix  = $o2->string($cv);
1222             while (++$last_ix < $ix) {
1223                 push @sig, $last_ix <  $mandatory ? '$' : '$=';
1224             }
1225             my $var = $self->padname($o2->targ);
1226             if ($var =~ /^[@%]/) {
1227                 return if $seen_slurpy;
1228                 $seen_slurpy = 1;
1229                 return if $ix != $params or !$slurpy
1230                             or substr($var,0,1) ne $slurpy;
1231             }
1232             else {
1233                 return if $ix >= $params;
1234             }
1235             if ($o2->flags & OPf_KIDS) {
1236                 my $kid = $o2->first;
1237                 return unless $$kid and $kid->name eq 'argdefelem';
1238                 my $def = $self->deparse($kid->first, 7);
1239                 $def = "($def)" if $kid->first->flags & OPf_PARENS;
1240                 $var .= " = $def";
1241             }
1242             push @sig, $var;
1243         }
1244         elsif ($o2->name eq 'null'
1245                and ($o2->flags & OPf_KIDS)
1246                and $o2->first->name eq 'argdefelem')
1247         {
1248             # special case - a void context default expression: $ = expr
1249
1250             my $defop = $o2->first;
1251             my $ix = $defop->targ;
1252             while (++$last_ix < $ix) {
1253                 push @sig, $last_ix <  $mandatory ? '$' : '$=';
1254             }
1255             return if $last_ix >= $params
1256                     or $last_ix < $mandatory;
1257             my $def = $self->deparse($defop->first, 7);
1258             $def = "($def)" if $defop->first->flags & OPf_PARENS;
1259             push @sig, '$ = ' . $def;
1260         }
1261         else {
1262             last;
1263         }
1264
1265         $o = $o2;
1266     }
1267
1268     while (++$last_ix < $params) {
1269         push @sig, $last_ix <  $mandatory ? '$' : '$=';
1270     }
1271     push @sig, $slurpy if $slurpy and !$seen_slurpy;
1272
1273     return ($o, join(', ', @sig));
1274 }
1275
1276 # Deparse a sub. Returns everything except the 'sub foo',
1277 # e.g.  ($$) : method { ...; }
1278 # or    : prototype($$) lvalue ($a, $b) { ...; };
1279
1280 sub deparse_sub {
1281     my $self = shift;
1282     my $cv = shift;
1283     my @attrs;
1284     my $proto;
1285     my $sig;
1286
1287 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
1288 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
1289     local $self->{'curcop'} = $self->{'curcop'};
1290
1291     my $has_sig = $self->{hinthash}{feature_signatures};
1292     if ($cv->FLAGS & SVf_POK) {
1293         my $myproto = $cv->PV;
1294         if ($has_sig) {
1295             push @attrs, "prototype($myproto)";
1296         }
1297         else {
1298             $proto = $myproto;
1299         }
1300     }
1301     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE|CVf_ANONCONST)) {
1302         push @attrs, "lvalue" if $cv->CvFLAGS & CVf_LVALUE;
1303         push @attrs, "method" if $cv->CvFLAGS & CVf_METHOD;
1304         push @attrs, "const"  if $cv->CvFLAGS & CVf_ANONCONST;
1305     }
1306
1307     local($self->{'curcv'}) = $cv;
1308     local($self->{'curcvlex'});
1309     local(@$self{qw'curstash warnings hints hinthash'})
1310                 = @$self{qw'curstash warnings hints hinthash'};
1311     my $body;
1312     my $root = $cv->ROOT;
1313     local $B::overlay = {};
1314     if (not null $root) {
1315         $self->pad_subs($cv);
1316         $self->pessimise($root, $cv->START);
1317         my $lineseq = $root->first;
1318         if ($lineseq->name eq "lineseq") {
1319             my $firstop = $lineseq->first;
1320
1321             if ($has_sig) {
1322                 my $o2;
1323                 # try to deparse first few ops as a signature if possible
1324                 if (     $$firstop
1325                      and $firstop->name =~  /^(next|db)state$/
1326                      and (($o2 = $firstop->sibling))
1327                      and $$o2)
1328                 {
1329                     if ($o2->name eq 'argcheck') {
1330                         my ($nexto, $mysig) = $self->deparse_argops($firstop, $cv);
1331                         if (defined $nexto) {
1332                             $firstop = $nexto;
1333                             $sig = $mysig;
1334                         }
1335                     }
1336                 }
1337             }
1338
1339             my @ops;
1340             for (my $o = $firstop; $$o; $o=$o->sibling) {
1341                 push @ops, $o;
1342             }
1343             $body = $self->lineseq(undef, 0, @ops).";";
1344             if (!$has_sig and $ops[-1]->name =~ /^(next|db)state$/) {
1345                 # this handles void context in
1346                 #   use feature signatures; sub ($=1) {}
1347                 $body .= "\n()";
1348             }
1349             my $scope_en = $self->find_scope_en($lineseq);
1350             if (defined $scope_en) {
1351                 my $subs = join"", $self->seq_subs($scope_en);
1352                 $body .= ";\n$subs" if length($subs);
1353             }
1354         }
1355         else {
1356             $body = $self->deparse($root->first, 0);
1357         }
1358
1359         my $l = '';
1360         if ($self->{'linenums'}) {
1361             # a glob's gp_line is set from the line containing a
1362             # sub's closing '}' if the CV is the first use of the GV.
1363             # So make sure the linenum is set correctly for '}'
1364             my $gv = $cv->GV;
1365             my $line = $gv->LINE;
1366             my $file = $gv->FILE;
1367             $l = "\f#line $line \"$file\"\n";
1368         }
1369         $body = "{\n\t$body\n$l\b}";
1370     }
1371     else {
1372         my $sv = $cv->const_sv;
1373         if ($$sv) {
1374             # uh-oh. inlinable sub... format it differently
1375             $body = "{ " . $self->const($sv, 0) . " }\n";
1376         } else { # XSUB? (or just a declaration)
1377             $body = ';'
1378         }
1379     }
1380     $proto = defined $proto ? "($proto) " : "";
1381     $sig   = defined $sig   ? "($sig) "   : "";
1382     my $attrs = '';
1383     $attrs = ': ' . join('', map "$_ ", @attrs) if @attrs;
1384     return "$proto$attrs$sig$body\n";
1385 }
1386
1387 sub deparse_format {
1388     my $self = shift;
1389     my $form = shift;
1390     my @text;
1391     local($self->{'curcv'}) = $form;
1392     local($self->{'curcvlex'});
1393     local($self->{'in_format'}) = 1;
1394     local(@$self{qw'curstash warnings hints hinthash'})
1395                 = @$self{qw'curstash warnings hints hinthash'};
1396     my $op = $form->ROOT;
1397     local $B::overlay = {};
1398     $self->pessimise($op, $form->START);
1399     my $kid;
1400     return "\f." if $op->first->name eq 'stub'
1401                 || $op->first->name eq 'nextstate';
1402     $op = $op->first->first; # skip leavewrite, lineseq
1403     while (not null $op) {
1404         $op = $op->sibling; # skip nextstate
1405         my @exprs;
1406         $kid = $op->first->sibling; # skip pushmark
1407         push @text, "\f".$self->const_sv($kid)->PV;
1408         $kid = $kid->sibling;
1409         for (; not null $kid; $kid = $kid->sibling) {
1410             push @exprs, $self->deparse($kid, -1);
1411             $exprs[-1] =~ s/;\z//;
1412         }
1413         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
1414         $op = $op->sibling;
1415     }
1416     return join("", @text) . "\f.";
1417 }
1418
1419 sub is_scope {
1420     my $op = shift;
1421     return $op->name eq "leave" || $op->name eq "scope"
1422       || $op->name eq "lineseq"
1423         || ($op->name eq "null" && class($op) eq "UNOP"
1424             && (is_scope($op->first) || $op->first->name eq "enter"));
1425 }
1426
1427 sub is_state {
1428     my $name = $_[0]->name;
1429     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
1430 }
1431
1432 sub is_miniwhile { # check for one-line loop ('foo() while $y--')
1433     my $op = shift;
1434     return (!null($op) and null($op->sibling)
1435             and $op->name eq "null" and class($op) eq "UNOP"
1436             and (($op->first->name =~ /^(and|or)$/
1437                   and $op->first->first->sibling->name eq "lineseq")
1438                  or ($op->first->name eq "lineseq"
1439                      and not null $op->first->first->sibling
1440                      and $op->first->first->sibling->name eq "unstack")
1441                  ));
1442 }
1443
1444 # Check if the op and its sibling are the initialization and the rest of a
1445 # for (..;..;..) { ... } loop
1446 sub is_for_loop {
1447     my $op = shift;
1448     # This OP might be almost anything, though it won't be a
1449     # nextstate. (It's the initialization, so in the canonical case it
1450     # will be an sassign.) The sibling is (old style) a lineseq whose
1451     # first child is a nextstate and whose second is a leaveloop, or
1452     # (new style) an unstack whose sibling is a leaveloop.
1453     my $lseq = $op->sibling;
1454     return 0 unless !is_state($op) and !null($lseq);
1455     if ($lseq->name eq "lineseq") {
1456         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
1457             && (my $sib = $lseq->first->sibling)) {
1458             return (!null($sib) && $sib->name eq "leaveloop");
1459         }
1460     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
1461         my $sib = $lseq->sibling;
1462         return $sib && !null($sib) && $sib->name eq "leaveloop";
1463     }
1464     return 0;
1465 }
1466
1467 sub is_scalar {
1468     my $op = shift;
1469     return ($op->name eq "rv2sv" or
1470             $op->name eq "padsv" or
1471             $op->name eq "gv" or # only in array/hash constructs
1472             $op->flags & OPf_KIDS && !null($op->first)
1473               && $op->first->name eq "gvsv");
1474 }
1475
1476 sub maybe_parens {
1477     my $self = shift;
1478     my($text, $cx, $prec) = @_;
1479     if ($prec < $cx              # unary ops nest just fine
1480         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1481         or $self->{'parens'})
1482     {
1483         $text = "($text)";
1484         # In a unop, let parent reuse our parens; see maybe_parens_unop
1485         $text = "\cS" . $text if $cx == 16;
1486         return $text;
1487     } else {
1488         return $text;
1489     }
1490 }
1491
1492 # same as above, but get around the 'if it looks like a function' rule
1493 sub maybe_parens_unop {
1494     my $self = shift;
1495     my($name, $kid, $cx) = @_;
1496     if ($cx > 16 or $self->{'parens'}) {
1497         $kid =  $self->deparse($kid, 1);
1498         if ($name eq "umask" && $kid =~ /^\d+$/) {
1499             $kid = sprintf("%#o", $kid);
1500         }
1501         return $self->keyword($name) . "($kid)";
1502     } else {
1503         $kid = $self->deparse($kid, 16);
1504         if ($name eq "umask" && $kid =~ /^\d+$/) {
1505             $kid = sprintf("%#o", $kid);
1506         }
1507         $name = $self->keyword($name);
1508         if (substr($kid, 0, 1) eq "\cS") {
1509             # use kid's parens
1510             return $name . substr($kid, 1);
1511         } elsif (substr($kid, 0, 1) eq "(") {
1512             # avoid looks-like-a-function trap with extra parens
1513             # ('+' can lead to ambiguities)
1514             return "$name(" . $kid  . ")";
1515         } else {
1516             return "$name $kid";
1517         }
1518     }
1519 }
1520
1521 sub maybe_parens_func {
1522     my $self = shift;
1523     my($func, $text, $cx, $prec) = @_;
1524     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1525         return "$func($text)";
1526     } else {
1527         return "$func $text";
1528     }
1529 }
1530
1531 sub find_our_type {
1532     my ($self, $name) = @_;
1533     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1534     my $seq = $self->{'curcop'} ? $self->{'curcop'}->cop_seq : 0;
1535     for my $a (@{$self->{'curcvlex'}{"o$name"}}) {
1536         my ($st, undef, $padname) = @$a;
1537         if ($st >= $seq && $padname->FLAGS & SVpad_TYPED) {
1538             return $padname->SvSTASH->NAME;
1539         }
1540     }
1541     return '';
1542 }
1543
1544 sub maybe_local {
1545     my $self = shift;
1546     my($op, $cx, $text) = @_;
1547     my $name = $op->name;
1548     my $our_intro = ($name =~ /^(?:(?:gv|rv2)[ash]v|split|refassign
1549                                   |lv(?:av)?ref)$/x)
1550                         ? OPpOUR_INTRO
1551                         : 0;
1552     my $lval_intro = $name eq 'split' ? 0 : OPpLVAL_INTRO;
1553     # The @a in \(@a) isn't in ref context, but only when the
1554     # parens are there.
1555     my $need_parens = $self->{'in_refgen'} && $name =~ /[ah]v\z/
1556                    && ($op->flags & (OPf_PARENS|OPf_REF)) == OPf_PARENS;
1557     if ((my $priv = $op->private) & ($lval_intro|$our_intro)) {
1558         my @our_local;
1559         push @our_local, "local" if $priv & $lval_intro;
1560         push @our_local, "our"   if $priv & $our_intro;
1561         my $our_local = join " ", map $self->keyword($_), @our_local;
1562         if( $our_local[-1] eq 'our' ) {
1563             if ( $text !~ /^\W(\w+::)*\w+\z/
1564              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1565             ) {
1566                 die "Unexpected our($text)\n";
1567             }
1568             $text =~ s/(\w+::)+//;
1569
1570             if (my $type = $self->find_our_type($text)) {
1571                 $our_local .= ' ' . $type;
1572             }
1573         }
1574         return $need_parens ? "($text)" : $text
1575             if $self->{'avoid_local'}{$$op};
1576         if ($need_parens) {
1577             return "$our_local($text)";
1578         } elsif (want_scalar($op)) {
1579             return "$our_local $text";
1580         } else {
1581             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1582         }
1583     } else {
1584         return $need_parens ? "($text)" : $text;
1585     }
1586 }
1587
1588 sub maybe_targmy {
1589     my $self = shift;
1590     my($op, $cx, $func, @args) = @_;
1591     if ($op->private & OPpTARGET_MY) {
1592         my $var = $self->padname($op->targ);
1593         my $val = $func->($self, $op, 7, @args);
1594         return $self->maybe_parens("$var = $val", $cx, 7);
1595     } else {
1596         return $func->($self, $op, $cx, @args);
1597     }
1598 }
1599
1600 sub padname_sv {
1601     my $self = shift;
1602     my $targ = shift;
1603     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1604 }
1605
1606 sub maybe_my {
1607     my $self = shift;
1608     my($op, $cx, $text, $padname, $forbid_parens) = @_;
1609     # The @a in \(@a) isn't in ref context, but only when the
1610     # parens are there.
1611     my $need_parens = !$forbid_parens && $self->{'in_refgen'}
1612                    && $op->name =~ /[ah]v\z/
1613                    && ($op->flags & (OPf_PARENS|OPf_REF)) == OPf_PARENS;
1614     # The @a in \my @a must not have parens.
1615     if (!$need_parens && $self->{'in_refgen'}) {
1616         $forbid_parens = 1;
1617     }
1618     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1619         # Check $padname->FLAGS for statehood, rather than $op->private,
1620         # because enteriter ops do not carry the flag.
1621         my $my =
1622             $self->keyword($padname->FLAGS & SVpad_STATE ? "state" : "my");
1623         if ($padname->FLAGS & SVpad_TYPED) {
1624             $my .= ' ' . $padname->SvSTASH->NAME;
1625         }
1626         if ($need_parens) {
1627             return "$my($text)";
1628         } elsif ($forbid_parens || want_scalar($op)) {
1629             return "$my $text";
1630         } else {
1631             return $self->maybe_parens_func($my, $text, $cx, 16);
1632         }
1633     } else {
1634         return $need_parens ? "($text)" : $text;
1635     }
1636 }
1637
1638 # The following OPs don't have functions:
1639
1640 # pp_padany -- does not exist after parsing
1641
1642 sub AUTOLOAD {
1643     if ($AUTOLOAD =~ s/^.*::pp_//) {
1644         warn "unexpected OP_".
1645           ($_[1]->type == OP_CUSTOM ? "CUSTOM ($AUTOLOAD)" : uc $AUTOLOAD);
1646         return "XXX";
1647     } else {
1648         die "Undefined subroutine $AUTOLOAD called";
1649     }
1650 }
1651
1652 sub DESTROY {}  #       Do not AUTOLOAD
1653
1654 # $root should be the op which represents the root of whatever
1655 # we're sequencing here. If it's undefined, then we don't append
1656 # any subroutine declarations to the deparsed ops, otherwise we
1657 # append appropriate declarations.
1658 sub lineseq {
1659     my($self, $root, $cx, @ops) = @_;
1660     my($expr, @exprs);
1661
1662     my $out_cop = $self->{'curcop'};
1663     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1664     my $limit_seq;
1665     if (defined $root) {
1666         $limit_seq = $out_seq;
1667         my $nseq;
1668         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1669         $limit_seq = $nseq if !defined($limit_seq)
1670                            or defined($nseq) && $nseq < $limit_seq;
1671     }
1672     $limit_seq = $self->{'limit_seq'}
1673         if defined($self->{'limit_seq'})
1674         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1675     local $self->{'limit_seq'} = $limit_seq;
1676
1677     $self->walk_lineseq($root, \@ops,
1678                        sub { push @exprs, $_[0]} );
1679
1680     my $sep = $cx ? '; ' : ";\n";
1681     my $body = join($sep, grep {length} @exprs);
1682     my $subs = "";
1683     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1684         $subs = join "\n", $self->seq_subs($limit_seq);
1685     }
1686     return join($sep, grep {length} $body, $subs);
1687 }
1688
1689 sub scopeop {
1690     my($real_block, $self, $op, $cx) = @_;
1691     my $kid;
1692     my @kids;
1693
1694     local(@$self{qw'curstash warnings hints hinthash'})
1695                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1696     if ($real_block) {
1697         $kid = $op->first->sibling; # skip enter
1698         if (is_miniwhile($kid)) {
1699             my $top = $kid->first;
1700             my $name = $top->name;
1701             if ($name eq "and") {
1702                 $name = $self->keyword("while");
1703             } elsif ($name eq "or") {
1704                 $name = $self->keyword("until");
1705             } else { # no conditional -> while 1 or until 0
1706                 return $self->deparse($top->first, 1) . " "
1707                      . $self->keyword("while") . " 1";
1708             }
1709             my $cond = $top->first;
1710             my $body = $cond->sibling->first; # skip lineseq
1711             $cond = $self->deparse($cond, 1);
1712             $body = $self->deparse($body, 1);
1713             return "$body $name $cond";
1714         }
1715     } else {
1716         $kid = $op->first;
1717     }
1718     for (; !null($kid); $kid = $kid->sibling) {
1719         push @kids, $kid;
1720     }
1721     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1722         my $body = $self->lineseq($op, 0, @kids);
1723         return is_lexical_subs(@kids)
1724                 ? $body
1725                 : ($self->lex_in_scope("&do") ? "CORE::do" : "do")
1726                  . " {\n\t$body\n\b}";
1727     } else {
1728         my $lineseq = $self->lineseq($op, $cx, @kids);
1729         return (length ($lineseq) ? "$lineseq;" : "");
1730     }
1731 }
1732
1733 sub pp_scope { scopeop(0, @_); }
1734 sub pp_lineseq { scopeop(0, @_); }
1735 sub pp_leave { scopeop(1, @_); }
1736
1737 # This is a special case of scopeop and lineseq, for the case of the
1738 # main_root. The difference is that we print the output statements as
1739 # soon as we get them, for the sake of impatient users.
1740 sub deparse_root {
1741     my $self = shift;
1742     my($op) = @_;
1743     local(@$self{qw'curstash warnings hints hinthash'})
1744       = @$self{qw'curstash warnings hints hinthash'};
1745     my @kids;
1746     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1747     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1748         push @kids, $kid;
1749     }
1750     $self->walk_lineseq($op, \@kids,
1751                         sub { return unless length $_[0];
1752                               print $self->indent($_[0].';');
1753                               print "\n"
1754                                 unless $_[1] == $#kids;
1755                           });
1756 }
1757
1758 sub walk_lineseq {
1759     my ($self, $op, $kids, $callback) = @_;
1760     my @kids = @$kids;
1761     for (my $i = 0; $i < @kids; $i++) {
1762         my $expr = "";
1763         if (is_state $kids[$i]) {
1764             $expr = $self->deparse($kids[$i++], 0);
1765             if ($i > $#kids) {
1766                 $callback->($expr, $i);
1767                 last;
1768             }
1769         }
1770         if (is_for_loop($kids[$i])) {
1771             $callback->($expr . $self->for_loop($kids[$i], 0),
1772                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1773             next;
1774         }
1775         my $expr2 = $self->deparse($kids[$i], (@kids != 1)/2);
1776         $expr2 =~ s/^sub :(?!:)/+sub :/; # statement label otherwise
1777         $expr .= $expr2;
1778         $callback->($expr, $i);
1779     }
1780 }
1781
1782 # The BEGIN {} is used here because otherwise this code isn't executed
1783 # when you run B::Deparse on itself.
1784 my %globalnames;
1785 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1786             "ENV", "ARGV", "ARGVOUT", "_"); }
1787
1788 sub gv_name {
1789     my $self = shift;
1790     my $gv = shift;
1791     my $raw = shift;
1792 #Carp::confess() unless ref($gv) eq "B::GV";
1793     my $cv = $gv->FLAGS & SVf_ROK ? $gv->RV : 0;
1794     my $stash = ($cv || $gv)->STASH->NAME;
1795     my $name = $raw
1796         ? $cv ? $cv->NAME_HEK || $cv->GV->NAME : $gv->NAME
1797         : $cv
1798             ? B::safename($cv->NAME_HEK || $cv->GV->NAME)
1799             : $gv->SAFENAME;
1800     if ($stash eq 'main' && $name =~ /^::/) {
1801         $stash = '::';
1802     }
1803     elsif (($stash eq 'main'
1804             && ($globalnames{$name} || $name =~ /^[^A-Za-z_:]/))
1805         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1806             && ($stash eq 'main' || $name !~ /::/))
1807           )
1808     {
1809         $stash = "";
1810     } else {
1811         $stash = $stash . "::";
1812     }
1813     if (!$raw and $name =~ /^(\^..|{)/) {
1814         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1815     }
1816     return $stash . $name;
1817 }
1818
1819 # Return the name to use for a stash variable.
1820 # If a lexical with the same name is in scope, or
1821 # if strictures are enabled, it may need to be
1822 # fully-qualified.
1823 sub stash_variable {
1824     my ($self, $prefix, $name, $cx) = @_;
1825
1826     return $prefix.$self->maybe_qualify($prefix, $name) if $name =~ /::/;
1827
1828     unless ($prefix eq '$' || $prefix eq '@' || $prefix eq '&' || #'
1829             $prefix eq '%' || $prefix eq '$#') {
1830         return "$prefix$name";
1831     }
1832
1833     if ($name =~ /^[^[:alpha:]_+-]$/) {
1834       if (defined $cx && $cx == 26) {
1835         if ($prefix eq '@') {
1836             return "$prefix\{$name}";
1837         }
1838         elsif ($name eq '#') { return '${#}' } #  "${#}a" vs "$#a"
1839       }
1840       if ($prefix eq '$#') {
1841         return "\$#{$name}";
1842       }
1843     }
1844
1845     return $prefix . $self->maybe_qualify($prefix, $name);
1846 }
1847
1848 my %unctrl = # portable to EBCDIC
1849     (
1850      "\c@" => '@',      # unused
1851      "\cA" => 'A',
1852      "\cB" => 'B',
1853      "\cC" => 'C',
1854      "\cD" => 'D',
1855      "\cE" => 'E',
1856      "\cF" => 'F',
1857      "\cG" => 'G',
1858      "\cH" => 'H',
1859      "\cI" => 'I',
1860      "\cJ" => 'J',
1861      "\cK" => 'K',
1862      "\cL" => 'L',
1863      "\cM" => 'M',
1864      "\cN" => 'N',
1865      "\cO" => 'O',
1866      "\cP" => 'P',
1867      "\cQ" => 'Q',
1868      "\cR" => 'R',
1869      "\cS" => 'S',
1870      "\cT" => 'T',
1871      "\cU" => 'U',
1872      "\cV" => 'V',
1873      "\cW" => 'W',
1874      "\cX" => 'X',
1875      "\cY" => 'Y',
1876      "\cZ" => 'Z',
1877      "\c[" => '[',      # unused
1878      "\c\\" => '\\',    # unused
1879      "\c]" => ']',      # unused
1880      "\c_" => '_',      # unused
1881     );
1882
1883 # Return just the name, without the prefix.  It may be returned as a quoted
1884 # string.  The second return value is a boolean indicating that.
1885 sub stash_variable_name {
1886     my($self, $prefix, $gv) = @_;
1887     my $name = $self->gv_name($gv, 1);
1888     $name = $self->maybe_qualify($prefix,$name);
1889     if ($name =~ /^(?:\S|(?!\d)[\ca-\cz]?(?:\w|::)*|\d+)\z/) {
1890         $name =~ s/^([\ca-\cz])/'^' . $unctrl{$1}/e;
1891         $name =~ /^(\^..|{)/ and $name = "{$name}";
1892         return $name, 0; # not quoted
1893     }
1894     else {
1895         single_delim("q", "'", $name, $self), 1;
1896     }
1897 }
1898
1899 sub maybe_qualify {
1900     my ($self,$prefix,$name) = @_;
1901     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1902     if ($prefix eq "") {
1903         $name .= "::" if $name =~ /(?:\ACORE::[^:]*|::)\z/;
1904         return $name;
1905     }
1906     return $name if $name =~ /::/;
1907     return $self->{'curstash'}.'::'. $name
1908         if
1909             $name =~ /^(?!\d)\w/         # alphabetic
1910          && $v    !~ /^\$[ab]\z/         # not $a or $b
1911          && $v =~ /\A[\$\@\%\&]/         # scalar, array, hash, or sub
1912          && !$globalnames{$name}         # not a global name
1913          && $self->{hints} & $strict_bits{vars}  # strict vars
1914          && !$self->lex_in_scope($v,1)   # no "our"
1915       or $self->lex_in_scope($v);        # conflicts with "my" variable
1916     return $name;
1917 }
1918
1919 sub lex_in_scope {
1920     my ($self, $name, $our) = @_;
1921     substr $name, 0, 0, = $our ? 'o' : 'm'; # our/my
1922     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1923
1924     return 0 if !defined($self->{'curcop'});
1925     my $seq = $self->{'curcop'}->cop_seq;
1926     return 0 if !exists $self->{'curcvlex'}{$name};
1927     for my $a (@{$self->{'curcvlex'}{$name}}) {
1928         my ($st, $en) = @$a;
1929         return 1 if $seq > $st && $seq <= $en;
1930     }
1931     return 0;
1932 }
1933
1934 sub populate_curcvlex {
1935     my $self = shift;
1936     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1937         my $padlist = $cv->PADLIST;
1938         # an undef CV still in lexical chain
1939         next if class($padlist) eq "SPECIAL";
1940         my @padlist = $padlist->ARRAY;
1941         my @ns = $padlist[0]->ARRAY;
1942
1943         for (my $i=0; $i<@ns; ++$i) {
1944             next if class($ns[$i]) eq "SPECIAL";
1945             if (class($ns[$i]) eq "PV") {
1946                 # Probably that pesky lexical @_
1947                 next;
1948             }
1949             my $name = $ns[$i]->PVX;
1950             next unless defined $name;
1951             my ($seq_st, $seq_en) =
1952                 ($ns[$i]->FLAGS & SVf_FAKE)
1953                     ? (0, 999999)
1954                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1955
1956             push @{$self->{'curcvlex'}{
1957                         ($ns[$i]->FLAGS & SVpad_OUR ? 'o' : 'm') . $name
1958                   }}, [$seq_st, $seq_en, $ns[$i]];
1959         }
1960     }
1961 }
1962
1963 sub find_scope_st { ((find_scope(@_))[0]); }
1964 sub find_scope_en { ((find_scope(@_))[1]); }
1965
1966 # Recurses down the tree, looking for pad variable introductions and COPs
1967 sub find_scope {
1968     my ($self, $op, $scope_st, $scope_en) = @_;
1969     carp("Undefined op in find_scope") if !defined $op;
1970     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1971
1972     my @queue = ($op);
1973     while(my $op = shift @queue ) {
1974         for (my $o=$op->first; $$o; $o=$o->sibling) {
1975             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1976                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1977                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1978                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1979                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1980                 return ($scope_st, $scope_en);
1981             }
1982             elsif (is_state($o)) {
1983                 my $c = $o->cop_seq;
1984                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1985                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1986                 return ($scope_st, $scope_en);
1987             }
1988             elsif ($o->flags & OPf_KIDS) {
1989                 unshift (@queue, $o);
1990             }
1991         }
1992     }
1993
1994     return ($scope_st, $scope_en);
1995 }
1996
1997 # Returns a list of subs which should be inserted before the COP
1998 sub cop_subs {
1999     my ($self, $op, $out_seq) = @_;
2000     my $seq = $op->cop_seq;
2001     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
2002     return $self->seq_subs($seq);
2003 }
2004
2005 sub seq_subs {
2006     my ($self, $seq) = @_;
2007     my @text;
2008 #push @text, "# ($seq)\n";
2009
2010     return "" if !defined $seq;
2011     my @pending;
2012     while (scalar(@{$self->{'subs_todo'}})
2013            and $seq > $self->{'subs_todo'}[0][0]) {
2014         my $cv = $self->{'subs_todo'}[0][1];
2015         # Skip the OUTSIDE check for lexical subs.  We may be deparsing a
2016         # cloned anon sub with lexical subs declared in it, in which case
2017         # the OUTSIDE pointer points to the anon protosub.
2018         my $lexical = ref $self->{'subs_todo'}[0][3];
2019         my $outside = !$lexical && $cv && $cv->OUTSIDE;
2020         if (!$lexical and $cv
2021          and ${$cv->OUTSIDE || \0} != ${$self->{'curcv'}})
2022         {
2023             push @pending, shift @{$self->{'subs_todo'}};
2024             next;
2025         }
2026         push @text, $self->next_todo;
2027     }
2028     unshift @{$self->{'subs_todo'}}, @pending;
2029     return @text;
2030 }
2031
2032 sub _features_from_bundle {
2033     my ($hints, $hh) = @_;
2034     foreach (@{$feature::feature_bundle{@feature::hint_bundles[$hints >> $feature::hint_shift]}}) {
2035         $hh->{$feature::feature{$_}} = 1;
2036     }
2037     return $hh;
2038 }
2039
2040 # generate any pragmas, 'package foo' etc needed to synchronise
2041 # with the given cop
2042
2043 sub pragmata {
2044     my $self = shift;
2045     my($op) = @_;
2046
2047     my @text;
2048
2049     my $stash = $op->stashpv;
2050     if ($stash ne $self->{'curstash'}) {
2051         push @text, $self->keyword("package") . " $stash;\n";
2052         $self->{'curstash'} = $stash;
2053     }
2054
2055     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
2056         push @text, '$[ = '. $op->arybase .";\n";
2057         $self->{'arybase'} = $op->arybase;
2058     }
2059
2060     my $warnings = $op->warnings;
2061     my $warning_bits;
2062     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
2063         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
2064     }
2065     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
2066         $warning_bits = $warnings::NONE;
2067     }
2068     elsif ($warnings->isa("B::SPECIAL")) {
2069         $warning_bits = undef;
2070     }
2071     else {
2072         $warning_bits = $warnings->PV & WARN_MASK;
2073     }
2074
2075     if (defined ($warning_bits) and
2076        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
2077         push @text,
2078             $self->declare_warnings($self->{'warnings'}, $warning_bits);
2079         $self->{'warnings'} = $warning_bits;
2080     }
2081
2082     my $hints = $op->hints;
2083     my $old_hints = $self->{'hints'};
2084     if ($self->{'hints'} != $hints) {
2085         push @text, $self->declare_hints($self->{'hints'}, $hints);
2086         $self->{'hints'} = $hints;
2087     }
2088
2089     my $newhh;
2090     $newhh = $op->hints_hash->HASH;
2091
2092     {
2093         # feature bundle hints
2094         my $from = $old_hints & $feature::hint_mask;
2095         my $to   = $    hints & $feature::hint_mask;
2096         if ($from != $to) {
2097             if ($to == $feature::hint_mask) {
2098                 if ($self->{'hinthash'}) {
2099                     delete $self->{'hinthash'}{$_}
2100                         for grep /^feature_/, keys %{$self->{'hinthash'}};
2101                 }
2102                 else { $self->{'hinthash'} = {} }
2103                 $self->{'hinthash'}
2104                     = _features_from_bundle($from, $self->{'hinthash'});
2105             }
2106             else {
2107                 my $bundle =
2108                     $feature::hint_bundles[$to >> $feature::hint_shift];
2109                 $bundle =~ s/(\d[13579])\z/$1+1/e; # 5.11 => 5.12
2110                 push @text,
2111                     $self->keyword("no") . " feature ':all';\n",
2112                     $self->keyword("use") . " feature ':$bundle';\n";
2113             }
2114         }
2115     }
2116
2117     {
2118         push @text, $self->declare_hinthash(
2119             $self->{'hinthash'}, $newhh,
2120             $self->{indent_size}, $self->{hints},
2121         );
2122         $self->{'hinthash'} = $newhh;
2123     }
2124
2125     return join("", @text);
2126 }
2127
2128
2129 # Notice how subs and formats are inserted between statements here;
2130 # also $[ assignments and pragmas.
2131 sub pp_nextstate {
2132     my $self = shift;
2133     my($op, $cx) = @_;
2134     $self->{'curcop'} = $op;
2135
2136     my @text;
2137
2138     my @subs = $self->cop_subs($op);
2139     if (@subs) {
2140         # Special marker to swallow up the semicolon
2141         push @subs, "\cK";
2142     }
2143     push @text, @subs;
2144
2145     push @text, $self->pragmata($op);
2146
2147
2148     # This should go after of any branches that add statements, to
2149     # increase the chances that it refers to the same line it did in
2150     # the original program.
2151     if ($self->{'linenums'} && $cx != .5) { # $cx == .5 means in a format
2152         push @text, "\f#line " . $op->line .
2153           ' "' . $op->file, qq'"\n';
2154     }
2155
2156     push @text, $op->label . ": " if $op->label;
2157
2158     return join("", @text);
2159 }
2160
2161 sub declare_warnings {
2162     my ($self, $from, $to) = @_;
2163     $from //= '';
2164     my $all = (warnings::bits("all") & WARN_MASK);
2165     unless ((($from & WARN_MASK) & ~$all) =~ /[^\0]/) {
2166         # no FATAL bits need turning off
2167         if (   ($to & WARN_MASK) eq $all) {
2168             return $self->keyword("use") . " warnings;\n";
2169         }
2170         elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
2171             return $self->keyword("no") . " warnings;\n";
2172         }
2173     }
2174
2175     return "BEGIN {\${^WARNING_BITS} = \""
2176            . join("", map { sprintf("\\x%02x", ord $_) } split "", $to)
2177            . "\"}\n\cK";
2178 }
2179
2180 sub declare_hints {
2181     my ($self, $from, $to) = @_;
2182     my $use = $to   & ~$from;
2183     my $no  = $from & ~$to;
2184     my $decls = "";
2185     for my $pragma (hint_pragmas($use)) {
2186         $decls .= $self->keyword("use") . " $pragma;\n";
2187     }
2188     for my $pragma (hint_pragmas($no)) {
2189         $decls .= $self->keyword("no") . " $pragma;\n";
2190     }
2191     return $decls;
2192 }
2193
2194 # Internal implementation hints that the core sets automatically, so don't need
2195 # (or want) to be passed back to the user
2196 my %ignored_hints = (
2197     'open<' => 1,
2198     'open>' => 1,
2199     ':'     => 1,
2200     'strict/refs' => 1,
2201     'strict/subs' => 1,
2202     'strict/vars' => 1,
2203 );
2204
2205 my %rev_feature;
2206
2207 sub declare_hinthash {
2208     my ($self, $from, $to, $indent, $hints) = @_;
2209     my $doing_features =
2210         ($hints & $feature::hint_mask) == $feature::hint_mask;
2211     my @decls;
2212     my @features;
2213     my @unfeatures; # bugs?
2214     for my $key (sort keys %$to) {
2215         next if $ignored_hints{$key};
2216         my $is_feature = $key =~ /^feature_/;
2217         next if $is_feature and not $doing_features;
2218         if (!exists $from->{$key} or $from->{$key} ne $to->{$key}) {
2219             push(@features, $key), next if $is_feature;
2220             push @decls,
2221                 qq(\$^H{) . single_delim("q", "'", $key, $self) . qq(} = )
2222               . (
2223                    defined $to->{$key}
2224                         ? single_delim("q", "'", $to->{$key}, $self)
2225                         : 'undef'
2226                 )
2227               . qq(;);
2228         }
2229     }
2230     for my $key (sort keys %$from) {
2231         next if $ignored_hints{$key};
2232         my $is_feature = $key =~ /^feature_/;
2233         next if $is_feature and not $doing_features;
2234         if (!exists $to->{$key}) {
2235             push(@unfeatures, $key), next if $is_feature;
2236             push @decls, qq(delete \$^H{'$key'};);
2237         }
2238     }
2239     my @ret;
2240     if (@features || @unfeatures) {
2241         if (!%rev_feature) { %rev_feature = reverse %feature::feature }
2242     }
2243     if (@features) {
2244         push @ret, $self->keyword("use") . " feature "
2245                  . join(", ", map "'$rev_feature{$_}'", @features) . ";\n";
2246     }
2247     if (@unfeatures) {
2248         push @ret, $self->keyword("no") . " feature "
2249                  . join(", ", map "'$rev_feature{$_}'", @unfeatures)
2250                  . ";\n";
2251     }
2252     @decls and
2253         push @ret,
2254              join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n\cK";
2255     return @ret;
2256 }
2257
2258 sub hint_pragmas {
2259     my ($bits) = @_;
2260     my (@pragmas, @strict);
2261     push @pragmas, "integer" if $bits & 0x1;
2262     for (sort keys %strict_bits) {
2263         push @strict, "'$_'" if $bits & $strict_bits{$_};
2264     }
2265     if (@strict == keys %strict_bits) {
2266         push @pragmas, "strict";
2267     }
2268     elsif (@strict) {
2269         push @pragmas, "strict " . join ', ', @strict;
2270     }
2271     push @pragmas, "bytes" if $bits & 0x8;
2272     return @pragmas;
2273 }
2274
2275 sub pp_dbstate { pp_nextstate(@_) }
2276 sub pp_setstate { pp_nextstate(@_) }
2277
2278 sub pp_unstack { return "" } # see also leaveloop
2279
2280 my %feature_keywords = (
2281   # keyword => 'feature',
2282     state   => 'state',
2283     say     => 'say',
2284     given   => 'switch',
2285     when    => 'switch',
2286     default => 'switch',
2287     break   => 'switch',
2288     evalbytes=>'evalbytes',
2289     __SUB__ => '__SUB__',
2290    fc       => 'fc',
2291 );
2292
2293 # keywords that are strong and also have a prototype
2294 #
2295 my %strong_proto_keywords = map { $_ => 1 } qw(
2296     pos
2297     prototype
2298     scalar
2299     study
2300     undef
2301 );
2302
2303 sub feature_enabled {
2304         my($self,$name) = @_;
2305         my $hh;
2306         my $hints = $self->{hints} & $feature::hint_mask;
2307         if ($hints && $hints != $feature::hint_mask) {
2308             $hh = _features_from_bundle($hints);
2309         }
2310         elsif ($hints) { $hh = $self->{'hinthash'} }
2311         return $hh && $hh->{"feature_$feature_keywords{$name}"}
2312 }
2313
2314 sub keyword {
2315     my $self = shift;
2316     my $name = shift;
2317     return $name if $name =~ /^CORE::/; # just in case
2318     if (exists $feature_keywords{$name}) {
2319         return "CORE::$name" if not $self->feature_enabled($name);
2320     }
2321     # This sub may be called for a program that has no nextstate ops.  In
2322     # that case we may have a lexical sub named no/use/sub in scope but
2323     # but $self->lex_in_scope will return false because it depends on the
2324     # current nextstate op.  So we need this alternate method if there is
2325     # no current cop.
2326     if (!$self->{'curcop'}) {
2327         $self->populate_curcvlex() if !defined $self->{'curcvlex'};
2328         return "CORE::$name" if exists $self->{'curcvlex'}{"m&$name"}
2329                              || exists $self->{'curcvlex'}{"o&$name"};
2330     } elsif ($self->lex_in_scope("&$name")
2331           || $self->lex_in_scope("&$name", 1)) {
2332         return "CORE::$name";
2333     }
2334     if ($strong_proto_keywords{$name}
2335         || ($name !~ /^(?:chom?p|do|exec|glob|s(?:elect|ystem))\z/
2336             && !defined eval{prototype "CORE::$name"})
2337     ) { return $name }
2338     if (
2339         exists $self->{subs_declared}{$name}
2340          or
2341         exists &{"$self->{curstash}::$name"}
2342     ) {
2343         return "CORE::$name"
2344     }
2345     return $name;
2346 }
2347
2348 sub baseop {
2349     my $self = shift;
2350     my($op, $cx, $name) = @_;
2351     return $self->keyword($name);
2352 }
2353
2354 sub pp_stub { "()" }
2355 sub pp_wantarray { baseop(@_, "wantarray") }
2356 sub pp_fork { baseop(@_, "fork") }
2357 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
2358 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
2359 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
2360 sub pp_tms { baseop(@_, "times") }
2361 sub pp_ghostent { baseop(@_, "gethostent") }
2362 sub pp_gnetent { baseop(@_, "getnetent") }
2363 sub pp_gprotoent { baseop(@_, "getprotoent") }
2364 sub pp_gservent { baseop(@_, "getservent") }
2365 sub pp_ehostent { baseop(@_, "endhostent") }
2366 sub pp_enetent { baseop(@_, "endnetent") }
2367 sub pp_eprotoent { baseop(@_, "endprotoent") }
2368 sub pp_eservent { baseop(@_, "endservent") }
2369 sub pp_gpwent { baseop(@_, "getpwent") }
2370 sub pp_spwent { baseop(@_, "setpwent") }
2371 sub pp_epwent { baseop(@_, "endpwent") }
2372 sub pp_ggrent { baseop(@_, "getgrent") }
2373 sub pp_sgrent { baseop(@_, "setgrent") }
2374 sub pp_egrent { baseop(@_, "endgrent") }
2375 sub pp_getlogin { baseop(@_, "getlogin") }
2376
2377 sub POSTFIX () { 1 }
2378
2379 # I couldn't think of a good short name, but this is the category of
2380 # symbolic unary operators with interesting precedence
2381
2382 sub pfixop {
2383     my $self = shift;
2384     my($op, $cx, $name, $prec, $flags) = (@_, 0);
2385     my $kid = $op->first;
2386     $kid = $self->deparse($kid, $prec);
2387     return $self->maybe_parens(($flags & POSTFIX)
2388                                  ? "$kid$name"
2389                                    # avoid confusion with filetests
2390                                  : $name eq '-'
2391                                    && $kid =~ /^[a-zA-Z](?!\w)/
2392                                         ? "$name($kid)"
2393                                         : "$name$kid",
2394                                $cx, $prec);
2395 }
2396
2397 sub pp_preinc { pfixop(@_, "++", 23) }
2398 sub pp_predec { pfixop(@_, "--", 23) }
2399 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
2400 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
2401 sub pp_i_preinc { pfixop(@_, "++", 23) }
2402 sub pp_i_predec { pfixop(@_, "--", 23) }
2403 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
2404 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
2405 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
2406 *pp_ncomplement = *pp_complement;
2407 sub pp_scomplement { maybe_targmy(@_, \&pfixop, "~.", 21) }
2408
2409 sub pp_negate { maybe_targmy(@_, \&real_negate) }
2410 sub real_negate {
2411     my $self = shift;
2412     my($op, $cx) = @_;
2413     if ($op->first->name =~ /^(i_)?negate$/) {
2414         # avoid --$x
2415         $self->pfixop($op, $cx, "-", 21.5);
2416     } else {
2417         $self->pfixop($op, $cx, "-", 21);       
2418     }
2419 }
2420 sub pp_i_negate { pp_negate(@_) }
2421
2422 sub pp_not {
2423     my $self = shift;
2424     my($op, $cx) = @_;
2425     if ($cx <= 4) {
2426         $self->listop($op, $cx, "not", $op->first);
2427     } else {
2428         $self->pfixop($op, $cx, "!", 21);       
2429     }
2430 }
2431
2432 sub unop {
2433     my $self = shift;
2434     my($op, $cx, $name, $nollafr) = @_;
2435     my $kid;
2436     if ($op->flags & OPf_KIDS) {
2437         $kid = $op->first;
2438         if (not $name) {
2439             # this deals with 'boolkeys' right now
2440             return $self->deparse($kid,$cx);
2441         }
2442         my $builtinname = $name;
2443         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
2444         if (defined prototype($builtinname)
2445            && $builtinname ne 'CORE::readline'
2446            && prototype($builtinname) =~ /^;?\*/
2447            && $kid->name eq "rv2gv") {
2448             $kid = $kid->first;
2449         }
2450
2451         if ($nollafr) {
2452             if (($kid = $self->deparse($kid, 16)) !~ s/^\cS//) {
2453                 # require foo() is a syntax error.
2454                 $kid =~ /^(?!\d)\w/ and $kid = "($kid)";
2455             }
2456             return $self->maybe_parens(
2457                         $self->keyword($name) . " $kid", $cx, 16
2458                    );
2459         }   
2460         return $self->maybe_parens_unop($name, $kid, $cx);
2461     } else {
2462         return $self->maybe_parens(
2463             $self->keyword($name) . ($op->flags & OPf_SPECIAL ? "()" : ""),
2464             $cx, 16,
2465         );
2466     }
2467 }
2468
2469 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
2470 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
2471 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
2472 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
2473 sub pp_defined { unop(@_, "defined") }
2474 sub pp_undef { unop(@_, "undef") }
2475 sub pp_study { unop(@_, "study") }
2476 sub pp_ref { unop(@_, "ref") }
2477 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
2478
2479 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
2480 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
2481 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
2482 sub pp_srand { unop(@_, "srand") }
2483 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
2484 sub pp_log { maybe_targmy(@_, \&unop, "log") }
2485 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
2486 sub pp_int { maybe_targmy(@_, \&unop, "int") }
2487 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
2488 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
2489 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
2490
2491 sub pp_length { maybe_targmy(@_, \&unop, "length") }
2492 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
2493 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
2494
2495 sub pp_each { unop(@_, "each") }
2496 sub pp_values { unop(@_, "values") }
2497 sub pp_keys { unop(@_, "keys") }
2498 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
2499 sub pp_boolkeys { 
2500     # no name because its an optimisation op that has no keyword
2501     unop(@_,"");
2502 }
2503 sub pp_aeach { unop(@_, "each") }
2504 sub pp_avalues { unop(@_, "values") }
2505 sub pp_akeys { unop(@_, "keys") }
2506 sub pp_pop { unop(@_, "pop") }
2507 sub pp_shift { unop(@_, "shift") }
2508
2509 sub pp_caller { unop(@_, "caller") }
2510 sub pp_reset { unop(@_, "reset") }
2511 sub pp_exit { unop(@_, "exit") }
2512 sub pp_prototype { unop(@_, "prototype") }
2513
2514 sub pp_close { unop(@_, "close") }
2515 sub pp_fileno { unop(@_, "fileno") }
2516 sub pp_umask { unop(@_, "umask") }
2517 sub pp_untie { unop(@_, "untie") }
2518 sub pp_tied { unop(@_, "tied") }
2519 sub pp_dbmclose { unop(@_, "dbmclose") }
2520 sub pp_getc { unop(@_, "getc") }
2521 sub pp_eof { unop(@_, "eof") }
2522 sub pp_tell { unop(@_, "tell") }
2523 sub pp_getsockname { unop(@_, "getsockname") }
2524 sub pp_getpeername { unop(@_, "getpeername") }
2525
2526 sub pp_chdir {
2527     my ($self, $op, $cx) = @_;
2528     if (($op->flags & (OPf_SPECIAL|OPf_KIDS)) == (OPf_SPECIAL|OPf_KIDS)) {
2529         my $kw = $self->keyword("chdir");
2530         my $kid = $self->const_sv($op->first)->PV;
2531         my $code = $kw
2532                  . ($cx >= 16 || $self->{'parens'} ? "($kid)" : " $kid");
2533         maybe_targmy(@_, sub { $_[3] }, $code);
2534     } else {
2535         maybe_targmy(@_, \&unop, "chdir")
2536     }
2537 }
2538
2539 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
2540 sub pp_readlink { unop(@_, "readlink") }
2541 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
2542 sub pp_readdir { unop(@_, "readdir") }
2543 sub pp_telldir { unop(@_, "telldir") }
2544 sub pp_rewinddir { unop(@_, "rewinddir") }
2545 sub pp_closedir { unop(@_, "closedir") }
2546 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
2547 sub pp_localtime { unop(@_, "localtime") }
2548 sub pp_gmtime { unop(@_, "gmtime") }
2549 sub pp_alarm { unop(@_, "alarm") }
2550 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
2551
2552 sub pp_dofile {
2553     my $code = unop(@_, "do", 1); # llafr does not apply
2554     if ($code =~ s/^((?:CORE::)?do) \{/$1({/) { $code .= ')' }
2555     $code;
2556 }
2557 sub pp_entereval {
2558     unop(
2559       @_,
2560       $_[1]->private & OPpEVAL_BYTES ? 'evalbytes' : "eval"
2561     )
2562 }
2563
2564 sub pp_ghbyname { unop(@_, "gethostbyname") }
2565 sub pp_gnbyname { unop(@_, "getnetbyname") }
2566 sub pp_gpbyname { unop(@_, "getprotobyname") }
2567 sub pp_shostent { unop(@_, "sethostent") }
2568 sub pp_snetent { unop(@_, "setnetent") }
2569 sub pp_sprotoent { unop(@_, "setprotoent") }
2570 sub pp_sservent { unop(@_, "setservent") }
2571 sub pp_gpwnam { unop(@_, "getpwnam") }
2572 sub pp_gpwuid { unop(@_, "getpwuid") }
2573 sub pp_ggrnam { unop(@_, "getgrnam") }
2574 sub pp_ggrgid { unop(@_, "getgrgid") }
2575
2576 sub pp_lock { unop(@_, "lock") }
2577
2578 sub pp_continue { unop(@_, "continue"); }
2579 sub pp_break { unop(@_, "break"); }
2580
2581 sub givwhen {
2582     my $self = shift;
2583     my($op, $cx, $givwhen) = @_;
2584
2585     my $enterop = $op->first;
2586     my ($head, $block);
2587     if ($enterop->flags & OPf_SPECIAL) {
2588         $head = $self->keyword("default");
2589         $block = $self->deparse($enterop->first, 0);
2590     }
2591     else {
2592         my $cond = $enterop->first;
2593         my $cond_str = $self->deparse($cond, 1);
2594         $head = "$givwhen ($cond_str)";
2595         $block = $self->deparse($cond->sibling, 0);
2596     }
2597
2598     return "$head {\n".
2599         "\t$block\n".
2600         "\b}\cK";
2601 }
2602
2603 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
2604 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
2605
2606 sub pp_exists {
2607     my $self = shift;
2608     my($op, $cx) = @_;
2609     my $arg;
2610     my $name = $self->keyword("exists");
2611     if ($op->private & OPpEXISTS_SUB) {
2612         # Checking for the existence of a subroutine
2613         return $self->maybe_parens_func($name,
2614                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
2615     }
2616     if ($op->flags & OPf_SPECIAL) {
2617         # Array element, not hash element
2618         return $self->maybe_parens_func($name,
2619                                 $self->pp_aelem($op->first, 16), $cx, 16);
2620     }
2621     return $self->maybe_parens_func($name, $self->pp_helem($op->first, 16),
2622                                     $cx, 16);
2623 }
2624
2625 sub pp_delete {
2626     my $self = shift;
2627     my($op, $cx) = @_;
2628     my $arg;
2629     my $name = $self->keyword("delete");
2630     if ($op->private & (OPpSLICE|OPpKVSLICE)) {
2631         if ($op->flags & OPf_SPECIAL) {
2632             # Deleting from an array, not a hash
2633             return $self->maybe_parens_func($name,
2634                                         $self->pp_aslice($op->first, 16),
2635                                         $cx, 16);
2636         }
2637         return $self->maybe_parens_func($name,
2638                                         $self->pp_hslice($op->first, 16),
2639                                         $cx, 16);
2640     } else {
2641         if ($op->flags & OPf_SPECIAL) {
2642             # Deleting from an array, not a hash
2643             return $self->maybe_parens_func($name,
2644                                         $self->pp_aelem($op->first, 16),
2645                                         $cx, 16);
2646         }
2647         return $self->maybe_parens_func($name,
2648                                         $self->pp_helem($op->first, 16),
2649                                         $cx, 16);
2650     }
2651 }
2652
2653 sub pp_require {
2654     my $self = shift;
2655     my($op, $cx) = @_;
2656     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
2657     my $kid = $op->first;
2658     if ($kid->name eq 'const') {
2659         my $priv = $kid->private;
2660         my $sv = $self->const_sv($kid);
2661         my $arg;
2662         if ($priv & OPpCONST_BARE) {
2663             $arg = $sv->PV;
2664             $arg =~ s[/][::]g;
2665             $arg =~ s/\.pm//g;
2666         } elsif ($priv & OPpCONST_NOVER) {
2667             $opname = $self->keyword('no');
2668             $arg = $self->const($sv, 16);
2669         } elsif ((my $tmp = $self->const($sv, 16)) =~ /^v/) {
2670             $arg = $tmp;
2671         }
2672         if ($arg) {
2673             return $self->maybe_parens("$opname $arg", $cx, 16);
2674         }
2675     }
2676     $self->unop(
2677             $op, $cx,
2678             $opname,
2679             1, # llafr does not apply
2680     );
2681 }
2682
2683 sub pp_scalar {
2684     my $self = shift;
2685     my($op, $cx) = @_;
2686     my $kid = $op->first;
2687     if (not null $kid->sibling) {
2688         # XXX Was a here-doc
2689         return $self->dquote($op);
2690     }
2691     $self->unop(@_, "scalar");
2692 }
2693
2694
2695 sub padval {
2696     my $self = shift;
2697     my $targ = shift;
2698     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
2699 }
2700
2701 sub anon_hash_or_list {
2702     my $self = shift;
2703     my($op, $cx) = @_;
2704
2705     my($pre, $post) = @{{"anonlist" => ["[","]"],
2706                          "anonhash" => ["{","}"]}->{$op->name}};
2707     my($expr, @exprs);
2708     $op = $op->first->sibling; # skip pushmark
2709     for (; !null($op); $op = $op->sibling) {
2710         $expr = $self->deparse($op, 6);
2711         push @exprs, $expr;
2712     }
2713     if ($pre eq "{" and $cx < 1) {
2714         # Disambiguate that it's not a block
2715         $pre = "+{";
2716     }
2717     return $pre . join(", ", @exprs) . $post;
2718 }
2719
2720 sub pp_anonlist {
2721     my $self = shift;
2722     my ($op, $cx) = @_;
2723     if ($op->flags & OPf_SPECIAL) {
2724         return $self->anon_hash_or_list($op, $cx);
2725     }
2726     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
2727     return 'XXX';
2728 }
2729
2730 *pp_anonhash = \&pp_anonlist;
2731
2732 sub pp_refgen {
2733     my $self = shift;   
2734     my($op, $cx) = @_;
2735     my $kid = $op->first;
2736     if ($kid->name eq "null") {
2737         my $anoncode = $kid = $kid->first;
2738         if ($anoncode->name eq "anonconst") {
2739             $anoncode = $anoncode->first->first->sibling;
2740         }
2741         if ($anoncode->name eq "anoncode"
2742          or !null($anoncode = $kid->sibling) and
2743                  $anoncode->name eq "anoncode") {
2744             return $self->e_anoncode({ code => $self->padval($anoncode->targ) });
2745         } elsif ($kid->name eq "pushmark") {
2746             my $sib_name = $kid->sibling->name;
2747             if ($sib_name eq 'entersub') {
2748                 my $text = $self->deparse($kid->sibling, 1);
2749                 # Always show parens for \(&func()), but only with -p otherwise
2750                 $text = "($text)" if $self->{'parens'}
2751                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
2752                 return "\\$text";
2753             }
2754         }
2755     }
2756     local $self->{'in_refgen'} = 1;
2757     $self->pfixop($op, $cx, "\\", 20);
2758 }
2759
2760 sub e_anoncode {
2761     my ($self, $info) = @_;
2762     my $text = $self->deparse_sub($info->{code});
2763     return $self->keyword("sub") . " $text";
2764 }
2765
2766 sub pp_srefgen { pp_refgen(@_) }
2767
2768 sub pp_readline {
2769     my $self = shift;
2770     my($op, $cx) = @_;
2771     my $kid = $op->first;
2772     if (is_scalar($kid)
2773         and $op->flags & OPf_SPECIAL
2774         and $self->deparse($kid, 1) eq 'ARGV')
2775     {
2776         return '<<>>';
2777     }
2778     return $self->unop($op, $cx, "readline");
2779 }
2780
2781 sub pp_rcatline {
2782     my $self = shift;
2783     my($op) = @_;
2784     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
2785 }
2786
2787 # Unary operators that can occur as pseudo-listops inside double quotes
2788 sub dq_unop {
2789     my $self = shift;
2790     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
2791     my $kid;
2792     if ($op->flags & OPf_KIDS) {
2793        $kid = $op->first;
2794        # If there's more than one kid, the first is an ex-pushmark.
2795        $kid = $kid->sibling if not null $kid->sibling;
2796        return $self->maybe_parens_unop($name, $kid, $cx);
2797     } else {
2798        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
2799     }
2800 }
2801
2802 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
2803 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
2804 sub pp_uc { dq_unop(@_, "uc") }
2805 sub pp_lc { dq_unop(@_, "lc") }
2806 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
2807 sub pp_fc { dq_unop(@_, "fc") }
2808
2809 sub loopex {
2810     my $self = shift;
2811     my ($op, $cx, $name) = @_;
2812     if (class($op) eq "PVOP") {
2813         $name .= " " . $op->pv;
2814     } elsif (class($op) eq "OP") {
2815         # no-op
2816     } elsif (class($op) eq "UNOP") {
2817         (my $kid = $self->deparse($op->first, 7)) =~ s/^\cS//;
2818         # last foo() is a syntax error.
2819         $kid =~ /^(?!\d)\w/ and $kid = "($kid)";
2820         $name .= " $kid";
2821     }
2822     return $self->maybe_parens($name, $cx, 7);
2823 }
2824
2825 sub pp_last { loopex(@_, "last") }
2826 sub pp_next { loopex(@_, "next") }
2827 sub pp_redo { loopex(@_, "redo") }
2828 sub pp_goto { loopex(@_, "goto") }
2829 sub pp_dump { loopex(@_, "CORE::dump") }
2830
2831 sub ftst {
2832     my $self = shift;
2833     my($op, $cx, $name) = @_;
2834     if (class($op) eq "UNOP") {
2835         # Genuine '-X' filetests are exempt from the LLAFR, but not
2836         # l?stat()
2837         if ($name =~ /^-/) {
2838             (my $kid = $self->deparse($op->first, 16)) =~ s/^\cS//;
2839             return $self->maybe_parens("$name $kid", $cx, 16);
2840         }
2841         return $self->maybe_parens_unop($name, $op->first, $cx);
2842     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2843         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2844     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2845         return $name;
2846     }
2847 }
2848
2849 sub pp_lstat    { ftst(@_, "lstat") }
2850 sub pp_stat     { ftst(@_, "stat") }
2851 sub pp_ftrread  { ftst(@_, "-R") }
2852 sub pp_ftrwrite { ftst(@_, "-W") }
2853 sub pp_ftrexec  { ftst(@_, "-X") }
2854 sub pp_fteread  { ftst(@_, "-r") }
2855 sub pp_ftewrite { ftst(@_, "-w") }
2856 sub pp_fteexec  { ftst(@_, "-x") }
2857 sub pp_ftis     { ftst(@_, "-e") }
2858 sub pp_fteowned { ftst(@_, "-O") }
2859 sub pp_ftrowned { ftst(@_, "-o") }
2860 sub pp_ftzero   { ftst(@_, "-z") }
2861 sub pp_ftsize   { ftst(@_, "-s") }
2862 sub pp_ftmtime  { ftst(@_, "-M") }
2863 sub pp_ftatime  { ftst(@_, "-A") }
2864 sub pp_ftctime  { ftst(@_, "-C") }
2865 sub pp_ftsock   { ftst(@_, "-S") }
2866 sub pp_ftchr    { ftst(@_, "-c") }
2867 sub pp_ftblk    { ftst(@_, "-b") }
2868 sub pp_ftfile   { ftst(@_, "-f") }
2869 sub pp_ftdir    { ftst(@_, "-d") }
2870 sub pp_ftpipe   { ftst(@_, "-p") }
2871 sub pp_ftlink   { ftst(@_, "-l") }
2872 sub pp_ftsuid   { ftst(@_, "-u") }
2873 sub pp_ftsgid   { ftst(@_, "-g") }
2874 sub pp_ftsvtx   { ftst(@_, "-k") }
2875 sub pp_fttty    { ftst(@_, "-t") }
2876 sub pp_fttext   { ftst(@_, "-T") }
2877 sub pp_ftbinary { ftst(@_, "-B") }
2878
2879 sub SWAP_CHILDREN () { 1 }
2880 sub ASSIGN () { 2 } # has OP= variant
2881 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2882
2883 my(%left, %right);
2884
2885 sub assoc_class {
2886     my $op = shift;
2887     my $name = $op->name;
2888     if ($name eq "concat" and $op->first->name eq "concat") {
2889         # avoid spurious '=' -- see comment in pp_concat
2890         return "concat";
2891     }
2892     if ($name eq "null" and class($op) eq "UNOP"
2893         and $op->first->name =~ /^(and|x?or)$/
2894         and null $op->first->sibling)
2895     {
2896         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2897         # with a null that's used as the common end point of the two
2898         # flows of control. For precedence purposes, ignore it.
2899         # (COND_EXPRs have these too, but we don't bother with
2900         # their associativity).
2901         return assoc_class($op->first);
2902     }
2903     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2904 }
2905
2906 # Left associative operators, like '+', for which
2907 # $a + $b + $c is equivalent to ($a + $b) + $c
2908
2909 BEGIN {
2910     %left = ('multiply' => 19, 'i_multiply' => 19,
2911              'divide' => 19, 'i_divide' => 19,
2912              'modulo' => 19, 'i_modulo' => 19,
2913              'repeat' => 19,
2914              'add' => 18, 'i_add' => 18,
2915              'subtract' => 18, 'i_subtract' => 18,
2916              'concat' => 18,
2917              'left_shift' => 17, 'right_shift' => 17,
2918              'bit_and' => 13, 'nbit_and' => 13, 'sbit_and' => 13,
2919              'bit_or' => 12, 'bit_xor' => 12,
2920              'sbit_or' => 12, 'sbit_xor' => 12,
2921              'nbit_or' => 12, 'nbit_xor' => 12,
2922              'and' => 3,
2923              'or' => 2, 'xor' => 2,
2924             );
2925 }
2926
2927 sub deparse_binop_left {
2928     my $self = shift;
2929     my($op, $left, $prec) = @_;
2930     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2931         and $left{assoc_class($op)} == $left{assoc_class($left)})
2932     {
2933         return $self->deparse($left, $prec - .00001);
2934     } else {
2935         return $self->deparse($left, $prec);    
2936     }
2937 }
2938
2939 # Right associative operators, like '=', for which
2940 # $a = $b = $c is equivalent to $a = ($b = $c)
2941
2942 BEGIN {
2943     %right = ('pow' => 22,
2944               'sassign=' => 7, 'aassign=' => 7,
2945               'multiply=' => 7, 'i_multiply=' => 7,
2946               'divide=' => 7, 'i_divide=' => 7,
2947               'modulo=' => 7, 'i_modulo=' => 7,
2948               'repeat=' => 7, 'refassign' => 7, 'refassign=' => 7,
2949               'add=' => 7, 'i_add=' => 7,
2950               'subtract=' => 7, 'i_subtract=' => 7,
2951               'concat=' => 7,
2952               'left_shift=' => 7, 'right_shift=' => 7,
2953               'bit_and=' => 7, 'sbit_and=' => 7, 'nbit_and=' => 7,
2954               'nbit_or=' => 7, 'nbit_xor=' => 7,
2955               'sbit_or=' => 7, 'sbit_xor=' => 7,
2956               'andassign' => 7,
2957               'orassign' => 7,
2958              );
2959 }
2960
2961 sub deparse_binop_right {
2962     my $self = shift;
2963     my($op, $right, $prec) = @_;
2964     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2965         and $right{assoc_class($op)} == $right{assoc_class($right)})
2966     {
2967         return $self->deparse($right, $prec - .00001);
2968     } else {
2969         return $self->deparse($right, $prec);   
2970     }
2971 }
2972
2973 sub binop {
2974     my $self = shift;
2975     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2976     my $left = $op->first;
2977     my $right = $op->last;
2978     my $eq = "";
2979     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2980         $eq = "=";
2981         $prec = 7;
2982     }
2983     if ($flags & SWAP_CHILDREN) {
2984         ($left, $right) = ($right, $left);
2985     }
2986     my $leftop = $left;
2987     $left = $self->deparse_binop_left($op, $left, $prec);
2988     $left = "($left)" if $flags & LIST_CONTEXT
2989                      and    $left !~ /^(my|our|local|state|)\s*[\@%\(]/
2990                          || do {
2991                                 # Parenthesize if the left argument is a
2992                                 # lone repeat op.
2993                                 my $left = $leftop->first->sibling;
2994                                 $left->name eq 'repeat'
2995                                     && null($left->sibling);
2996                             };
2997     $right = $self->deparse_binop_right($op, $right, $prec);
2998     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2999 }
3000
3001 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
3002 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
3003 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
3004 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
3005 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
3006 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
3007 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
3008 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
3009 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
3010 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
3011 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
3012
3013 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
3014 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
3015 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
3016 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
3017 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
3018 *pp_nbit_and = *pp_bit_and;
3019 *pp_nbit_or  = *pp_bit_or;
3020 *pp_nbit_xor = *pp_bit_xor;
3021 sub pp_sbit_and { maybe_targmy(@_, \&binop, "&.", 13, ASSIGN) }
3022 sub pp_sbit_or { maybe_targmy(@_, \&binop, "|.", 12, ASSIGN) }
3023 sub pp_sbit_xor { maybe_targmy(@_, \&binop, "^.", 12, ASSIGN) }
3024
3025 sub pp_eq { binop(@_, "==", 14) }
3026 sub pp_ne { binop(@_, "!=", 14) }
3027 sub pp_lt { binop(@_, "<", 15) }
3028 sub pp_gt { binop(@_, ">", 15) }
3029 sub pp_ge { binop(@_, ">=", 15) }
3030 sub pp_le { binop(@_, "<=", 15) }
3031 sub pp_ncmp { binop(@_, "<=>", 14) }
3032 sub pp_i_eq { binop(@_, "==", 14) }
3033 sub pp_i_ne { binop(@_, "!=", 14) }
3034 sub pp_i_lt { binop(@_, "<", 15) }
3035 sub pp_i_gt { binop(@_, ">", 15) }
3036 sub pp_i_ge { binop(@_, ">=", 15) }
3037 sub pp_i_le { binop(@_, "<=", 15) }
3038 sub pp_i_ncmp { maybe_targmy(@_, \&binop, "<=>", 14) }
3039
3040 sub pp_seq { binop(@_, "eq", 14) }
3041 sub pp_sne { binop(@_, "ne", 14) }
3042 sub pp_slt { binop(@_, "lt", 15) }
3043 sub pp_sgt { binop(@_, "gt", 15) }
3044 sub pp_sge { binop(@_, "ge", 15) }
3045 sub pp_sle { binop(@_, "le", 15) }
3046 sub pp_scmp { maybe_targmy(@_, \&binop, "cmp", 14) }
3047
3048 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
3049 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
3050
3051 sub pp_smartmatch {
3052     my ($self, $op, $cx) = @_;
3053     if (($op->flags & OPf_SPECIAL) && $self->{expand} < 2) {
3054         return $self->deparse($op->last, $cx);
3055     }
3056     else {
3057         binop(@_, "~~", 14);
3058     }
3059 }
3060
3061 # '.' is special because concats-of-concats are optimized to save copying
3062 # by making all but the first concat stacked. The effect is as if the
3063 # programmer had written '($a . $b) .= $c', except legal.
3064 sub pp_concat { maybe_targmy(@_, \&real_concat) }
3065 sub real_concat {
3066     my $self = shift;
3067     my($op, $cx) = @_;
3068     my $left = $op->first;
3069     my $right = $op->last;
3070     my $eq = "";
3071     my $prec = 18;
3072     if (($op->flags & OPf_STACKED) and !($op->private & OPpCONCAT_NESTED)) {
3073         # '.=' rather than optimised '.'
3074         $eq = "=";
3075         $prec = 7;
3076     }
3077     $left = $self->deparse_binop_left($op, $left, $prec);
3078     $right = $self->deparse_binop_right($op, $right, $prec);
3079     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
3080 }
3081
3082 sub pp_repeat { maybe_targmy(@_, \&repeat) }
3083
3084 # 'x' is weird when the left arg is a list
3085 sub repeat {
3086     my $self = shift;
3087     my($op, $cx) = @_;
3088     my $left = $op->first;
3089     my $right = $op->last;
3090     my $eq = "";
3091     my $prec = 19;
3092     if ($op->flags & OPf_STACKED) {
3093         $eq = "=";
3094         $prec = 7;
3095     }
3096     if (null($right)) { # list repeat; count is inside left-side ex-list
3097                         # in 5.21.5 and earlier
3098         my $kid = $left->first->sibling; # skip pushmark
3099         my @exprs;
3100         for (; !null($kid->sibling); $kid = $kid->sibling) {
3101             push @exprs, $self->deparse($kid, 6);
3102         }
3103         $right = $kid;
3104         $left = "(" . join(", ", @exprs). ")";
3105     } else {
3106         my $dolist = $op->private & OPpREPEAT_DOLIST;
3107         $left = $self->deparse_binop_left($op, $left, $dolist ? 1 : $prec);
3108         if ($dolist) {
3109             $left = "($left)";
3110         }
3111     }
3112     $right = $self->deparse_binop_right($op, $right, $prec);
3113     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
3114 }
3115
3116 sub range {
3117     my $self = shift;
3118     my ($op, $cx, $type) = @_;
3119     my $left = $op->first;
3120     my $right = $left->sibling;
3121     $left = $self->deparse($left, 9);
3122     $right = $self->deparse($right, 9);
3123     return $self->maybe_parens("$left $type $right", $cx, 9);
3124 }
3125
3126 sub pp_flop {
3127     my $self = shift;
3128     my($op, $cx) = @_;
3129     my $flip = $op->first;
3130     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
3131     return $self->range($flip->first, $cx, $type);
3132 }
3133
3134 # one-line while/until is handled in pp_leave
3135
3136 sub logop {
3137     my $self = shift;
3138     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
3139     my $left = $op->first;
3140     my $right = $op->first->sibling;
3141     $blockname &&= $self->keyword($blockname);
3142     if ($cx < 1 and is_scope($right) and $blockname
3143         and $self->{'expand'} < 7)
3144     { # if ($a) {$b}
3145         $left = $self->deparse($left, 1);
3146         $right = $self->deparse($right, 0);
3147         return "$blockname ($left) {\n\t$right\n\b}\cK";
3148     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
3149              and $self->{'expand'} < 7) { # $b if $a
3150         $right = $self->deparse($right, 1);
3151         $left = $self->deparse($left, 1);
3152         return "$right $blockname $left";
3153     } elsif ($cx > $lowprec and $highop) { # $a && $b
3154         $left = $self->deparse_binop_left($op, $left, $highprec);
3155         $right = $self->deparse_binop_right($op, $right, $highprec);
3156         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
3157     } else { # $a and $b
3158         $left = $self->deparse_binop_left($op, $left, $lowprec);
3159         $right = $self->deparse_binop_right($op, $right, $lowprec);
3160         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
3161     }
3162 }
3163
3164 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
3165 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
3166 sub pp_dor { logop(@_, "//", 10) }
3167
3168 # xor is syntactically a logop, but it's really a binop (contrary to
3169 # old versions of opcode.pl). Syntax is what matters here.
3170 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
3171
3172 sub logassignop {
3173     my $self = shift;
3174     my ($op, $cx, $opname) = @_;
3175     my $left = $op->first;
3176     my $right = $op->first->sibling->first; # skip sassign
3177     $left = $self->deparse($left, 7);
3178     $right = $self->deparse($right, 7);
3179     return $self->maybe_parens("$left $opname $right", $cx, 7);
3180 }
3181
3182 sub pp_andassign { logassignop(@_, "&&=") }
3183 sub pp_orassign  { logassignop(@_, "||=") }
3184 sub pp_dorassign { logassignop(@_, "//=") }
3185
3186 sub rv2gv_or_string {
3187     my($self,$op) = @_;
3188     if ($op->name eq "gv") { # could be open("open") or open("###")
3189         my($name,$quoted) =
3190             $self->stash_variable_name("", $self->gv_or_padgv($op));
3191         $quoted ? $name : "*$name";
3192     }
3193     else {
3194         $self->deparse($op, 6);
3195     }
3196 }
3197
3198 sub listop {
3199     my $self = shift;
3200     my($op, $cx, $name, $kid, $nollafr) = @_;
3201     my(@exprs);
3202     my $parens = ($cx >= 5) || $self->{'parens'};
3203     $kid ||= $op->first->sibling;
3204     # If there are no arguments, add final parentheses (or parenthesize the
3205     # whole thing if the llafr does not apply) to account for cases like
3206     # (return)+1 or setpgrp()+1.  When the llafr does not apply, we use a
3207     # precedence of 6 (< comma), as "return, 1" does not need parentheses.
3208     if (null $kid) {
3209         return $nollafr
3210                 ? $self->maybe_parens($self->keyword($name), $cx, 7)
3211                 : $self->keyword($name) . '()' x (7 < $cx);
3212     }
3213     my $first;
3214     my $fullname = $self->keyword($name);
3215     my $proto = prototype("CORE::$name");
3216     if (
3217          (     (defined $proto && $proto =~ /^;?\*/)
3218             || $name eq 'select' # select(F) doesn't have a proto
3219          )
3220          && $kid->name eq "rv2gv"
3221          && !($kid->private & OPpLVAL_INTRO)
3222     ) {
3223         $first = $self->rv2gv_or_string($kid->first);
3224     }
3225     else {
3226         $first = $self->deparse($kid, 6);
3227     }
3228     if ($name eq "chmod" && $first =~ /^\d+$/) {
3229         $first = sprintf("%#o", $first);
3230     }
3231     $first = "+$first"
3232         if not $parens and not $nollafr and substr($first, 0, 1) eq "(";
3233     push @exprs, $first;
3234     $kid = $kid->sibling;
3235     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv"
3236          && !($kid->private & OPpLVAL_INTRO)) {
3237         push @exprs, $first = $self->rv2gv_or_string($kid->first);
3238         $kid = $kid->sibling;
3239     }
3240     for (; !null($kid); $kid = $kid->sibling) {
3241         push @exprs, $self->deparse($kid, 6);
3242     }
3243     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
3244         return "$exprs[0] = $fullname"
3245                  . ($parens ? "($exprs[0])" : " $exprs[0]");
3246     }
3247
3248     if ($parens && $nollafr) {
3249         return "($fullname " . join(", ", @exprs) . ")";
3250     } elsif ($parens) {
3251         return "$fullname(" . join(", ", @exprs) . ")";
3252     } else {
3253         return "$fullname " . join(", ", @exprs);
3254     }
3255 }
3256
3257 sub pp_bless { listop(@_, "bless") }
3258 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
3259 sub pp_substr {
3260     my ($self,$op,$cx) = @_;
3261     if ($op->private & OPpSUBSTR_REPL_FIRST) {
3262         return
3263            listop($self, $op, 7, "substr", $op->first->sibling->sibling)
3264          . " = "
3265          . $self->deparse($op->first->sibling, 7);
3266     }
3267     maybe_local(@_, listop(@_, "substr"))
3268 }
3269
3270 sub pp_index {
3271     # Also handles pp_rindex.
3272     #
3273     # The body of this function includes an unrolled maybe_targmy(),
3274     # since the two parts of that sub's actions need to have have the
3275     # '== -1' bit in between
3276
3277     my($self, $op, $cx) = @_;
3278
3279     my $lex  = ($op->private & OPpTARGET_MY);
3280     my $bool = ($op->private & OPpTRUEBOOL);
3281
3282     my $val = $self->listop($op, ($bool ? 14 : $lex ? 7 : $cx), $op->name);
3283
3284     # (index() == -1) has op_eq and op_const optimised away
3285     if ($bool) {
3286         $val .= ($op->private & OPpINDEX_BOOLNEG) ? " == -1" : " != -1";
3287         $val = "($val)" if ($op->flags & OPf_PARENS);
3288     }
3289     if ($lex) {
3290         my $var = $self->padname($op->targ);
3291         $val = $self->maybe_parens("$var = $val", $cx, 7);
3292     }
3293     $val;
3294 }
3295
3296 sub pp_rindex { pp_index(@_); }
3297 sub pp_vec { maybe_targmy(@_, \&maybe_local, listop(@_, "vec")) }
3298 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
3299 sub pp_formline { listop(@_, "formline") } # see also deparse_format
3300 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
3301 sub pp_unpack { listop(@_, "unpack") }
3302 sub pp_pack { listop(@_, "pack") }
3303 sub pp_join { maybe_targmy(@_, \&listop, "join") }
3304 sub pp_splice { listop(@_, "splice") }
3305 sub pp_push { maybe_targmy(@_, \&listop, "push") }
3306 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
3307 sub pp_reverse { listop(@_, "reverse") }
3308 sub pp_warn { listop(@_, "warn") }
3309 sub pp_die { listop(@_, "die") }
3310 sub pp_return { listop(@_, "return", undef, 1) } # llafr does not apply
3311 sub pp_open { listop(@_, "open") }
3312 sub pp_pipe_op { listop(@_, "pipe") }
3313 sub pp_tie { listop(@_, "tie") }
3314 sub pp_binmode { listop(@_, "binmode") }
3315 sub pp_dbmopen { listop(@_, "dbmopen") }
3316 sub pp_sselect { listop(@_, "select") }
3317 sub pp_select { listop(@_, "select") }
3318 sub pp_read { listop(@_, "read") }
3319 sub pp_sysopen { listop(@_, "sysopen") }
3320 sub pp_sysseek { listop(@_, "sysseek") }
3321 sub pp_sysread { listop(@_, "sysread") }
3322 sub pp_syswrite { listop(@_, "syswrite") }
3323 sub pp_send { listop(@_, "send") }
3324 sub pp_recv { listop(@_, "recv") }
3325 sub pp_seek { listop(@_, "seek") }
3326 sub pp_fcntl { listop(@_, "fcntl") }
3327 sub pp_ioctl { listop(@_, "ioctl") }
3328 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
3329 sub pp_socket { listop(@_, "socket") }
3330 sub pp_sockpair { listop(@_, "socketpair") }
3331 sub pp_bind { listop(@_, "bind") }
3332 sub pp_connect { listop(@_, "connect") }
3333 sub pp_listen { listop(@_, "listen") }
3334 sub pp_accept { listop(@_, "accept") }
3335 sub pp_shutdown { listop(@_, "shutdown") }
3336 sub pp_gsockopt { listop(@_, "getsockopt") }
3337 sub pp_ssockopt { listop(@_, "setsockopt") }
3338 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
3339 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
3340 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
3341 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
3342 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
3343 sub pp_link { maybe_targmy(@_, \&listop, "link") }
3344 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
3345 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
3346 sub pp_open_dir { listop(@_, "opendir") }
3347 sub pp_seekdir { listop(@_, "seekdir") }
3348 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
3349 sub pp_system { maybe_targmy(@_, \&indirop, "system") }
3350 sub pp_exec { maybe_targmy(@_, \&indirop, "exec") }
3351 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
3352 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
3353 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
3354 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
3355 sub pp_shmget { listop(@_, "shmget") }
3356 sub pp_shmctl { listop(@_, "shmctl") }
3357 sub pp_shmread { listop(@_, "shmread") }
3358 sub pp_shmwrite { listop(@_, "shmwrite") }
3359 sub pp_msgget { listop(@_, "msgget") }
3360 sub pp_msgctl { listop(@_, "msgctl") }
3361 sub pp_msgsnd { listop(@_, "msgsnd") }
3362 sub pp_msgrcv { listop(@_, "msgrcv") }
3363 sub pp_semget { listop(@_, "semget") }
3364 sub pp_semctl { listop(@_, "semctl") }
3365 sub pp_semop { listop(@_, "semop") }
3366 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
3367 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
3368 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
3369 sub pp_gsbyname { listop(@_, "getservbyname") }
3370 sub pp_gsbyport { listop(@_, "getservbyport") }
3371 sub pp_syscall { listop(@_, "syscall") }
3372
3373 sub pp_glob {
3374     my $self = shift;
3375     my($op, $cx) = @_;
3376     my $kid = $op->first->sibling;  # skip pushmark
3377     my $keyword =
3378         $op->flags & OPf_SPECIAL ? 'glob' : $self->keyword('glob');
3379     my $text = $self->deparse($kid);
3380     return $cx >= 5 || $self->{'parens'}
3381         ? "$keyword($text)"
3382         : "$keyword $text";
3383 }
3384
3385 # Truncate is special because OPf_SPECIAL makes a bareword first arg
3386 # be a filehandle. This could probably be better fixed in the core
3387 # by moving the GV lookup into ck_truc.
3388
3389 sub pp_truncate {
3390     my $self = shift;
3391     my($op, $cx) = @_;
3392     my(@exprs);
3393     my $parens = ($cx >= 5) || $self->{'parens'};
3394     my $kid = $op->first->sibling;
3395     my $fh;
3396     if ($op->flags & OPf_SPECIAL) {
3397         # $kid is an OP_CONST
3398         $fh = $self->const_sv($kid)->PV;
3399     } else {
3400         $fh = $self->deparse($kid, 6);
3401         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
3402     }
3403     my $len = $self->deparse($kid->sibling, 6);
3404     my $name = $self->keyword('truncate');
3405     if ($parens) {
3406         return "$name($fh, $len)";
3407     } else {
3408         return "$name $fh, $len";
3409     }
3410 }
3411
3412 sub indirop {
3413     my $self = shift;
3414     my($op, $cx, $name) = @_;
3415     my($expr, @exprs);
3416     my $firstkid = my $kid = $op->first->sibling;
3417     my $indir = "";
3418     if ($op->flags & OPf_STACKED) {
3419         $indir = $kid;
3420         $indir = $indir->first; # skip rv2gv
3421         if (is_scope($indir)) {
3422             $indir = "{" . $self->deparse($indir, 0) . "}";
3423             $indir = "{;}" if $indir eq "{}";
3424         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
3425             $indir = $self->const_sv($indir)->PV;
3426         } else {
3427             $indir = $self->deparse($indir, 24);
3428         }
3429         $indir = $indir . " ";
3430         $kid = $kid->sibling;
3431     }
3432     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
3433         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
3434                                                   : '{$a <=> $b} ';
3435     }
3436     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
3437         $indir = '{$b cmp $a} ';
3438     }
3439     for (; !null($kid); $kid = $kid->sibling) {
3440         $expr = $self->deparse($kid, !$indir && $kid == $firstkid && $name eq "sort" && $firstkid->name eq "entersub" ? 16 : 6);
3441         push @exprs, $expr;
3442     }
3443     my $name2;
3444     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
3445         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
3446     }
3447     else { $name2 = $self->keyword($name) }
3448     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
3449         return "$exprs[0] = $name2 $indir $exprs[0]";
3450     }
3451
3452     my $args = $indir . join(", ", @exprs);
3453     if ($indir ne "" && $name eq "sort") {
3454         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
3455         # give bareword warnings in that case. Therefore if context
3456         # requires, we'll put parens around the outside "(sort f 1, 2,
3457         # 3)". Unfortunately, we'll currently think the parens are
3458         # necessary more often that they really are, because we don't
3459         # distinguish which side of an assignment we're on.
3460         if ($cx >= 5) {
3461             return "($name2 $args)";
3462         } else {
3463             return "$name2 $args";
3464         }
3465     } elsif (
3466         !$indir && $name eq "sort"
3467       && !null($op->first->sibling)
3468       && $op->first->sibling->name eq 'entersub'
3469     ) {
3470         # We cannot say sort foo(bar), as foo will be interpreted as a
3471         # comparison routine.  We have to say sort(...) in that case.
3472         return "$name2($args)";
3473     } else {
3474         return length $args
3475                 ? $self->maybe_parens_func($name2, $args, $cx, 5)
3476                 : $name2 . '()' x (7 < $cx);
3477     }
3478
3479 }
3480
3481 sub pp_prtf { indirop(@_, "printf") }
3482 sub pp_print { indirop(@_, "print") }
3483 sub pp_say  { indirop(@_, "say") }
3484 sub pp_sort { indirop(@_, "sort") }
3485
3486 sub mapop {
3487     my $self = shift;
3488     my($op, $cx, $name) = @_;
3489     my($expr, @exprs);
3490     my $kid = $op->first; # this is the (map|grep)start
3491     $kid = $kid->first->sibling; # skip a pushmark
3492     my $code = $kid->first; # skip a null
3493     if (is_scope $code) {
3494         $code = "{" . $self->deparse($code, 0) . "} ";
3495     } else {
3496         $code = $self->deparse($code, 24);
3497         $code .= ", " if !null($kid->sibling);
3498     }
3499     $kid = $kid->sibling;
3500     for (; !null($kid); $kid = $kid->sibling) {
3501         $expr = $self->deparse($kid, 6);
3502         push @exprs, $expr if defined $expr;
3503     }
3504     return $self->maybe_parens_func($self->keyword($name),
3505                                     $code . join(", ", @exprs), $cx, 5);
3506 }
3507
3508 sub pp_mapwhile { mapop(@_, "map") }
3509 sub pp_grepwhile { mapop(@_, "grep") }
3510 sub pp_mapstart { baseop(@_, "map") }
3511 sub pp_grepstart { baseop(@_, "grep") }
3512
3513 my %uses_intro;
3514 BEGIN {
3515     @uses_intro{
3516         eval { require B::Op_private }
3517           ? @{$B::Op_private::ops_using{OPpLVAL_INTRO}}
3518           : qw(gvsv rv2sv rv2hv rv2gv rv2av aelem helem aslice
3519                hslice delete padsv padav padhv enteriter entersub padrange
3520                pushmark cond_expr refassign list)
3521     } = ();
3522     delete @uses_intro{qw( lvref lvrefslice lvavref entersub )};
3523 }
3524
3525
3526 # Look for a my/state attribute declaration in a list or ex-list.
3527 # Returns undef if not found, 'my($x, @a) :Foo(bar)' etc otherwise.
3528 #
3529 # There are three basic tree structs that are expected:
3530 #
3531 # my $x :foo;
3532 #      <1> ex-list vK/LVINTRO ->c
3533 #         <0> ex-pushmark v ->3
3534 #         <1> entersub[t2] vKRS*/TARG ->b
3535 #                ....
3536 #         <0> padsv[$x:64,65] vM/LVINTRO ->c
3537 #
3538 # my @a :foo;
3539 # my %h :foo;
3540 #
3541 #      <1> ex-list vK ->c
3542 #         <0> ex-pushmark v ->3
3543 #         <0> padav[@a:64,65] vM/LVINTRO ->4
3544 #         <1> entersub[t2] vKRS*/TARG ->c
3545 #            ....
3546 #
3547 # my ($x,@a,%h) :foo;
3548 #
3549 #      <;> nextstate(main 64 -e:1) v:{ ->3
3550 #      <@> list vKP ->w
3551 #         <0> pushmark vM/LVINTRO ->4
3552 #         <0> padsv[$x:64,65] vM/LVINTRO ->5
3553 #         <0> padav[@a:64,65] vM/LVINTRO ->6
3554 #         <0> padhv[%h:64,65] vM/LVINTRO ->7
3555 #         <1> entersub[t4] vKRS*/TARG ->f
3556 #            ....
3557 #         <1> entersub[t5] vKRS*/TARG ->n
3558 #            ....
3559 #         <1> entersub[t6] vKRS*/TARG ->v
3560 #           ....
3561 # where the entersub in all cases looks like
3562 #        <1> entersub[t2] vKRS*/TARG ->c
3563 #           <0> pushmark s ->5
3564 #           <$> const[PV "attributes"] sM ->6
3565 #           <$> const[PV "main"] sM ->7
3566 #           <1> srefgen sKM/1 ->9
3567 #              <1> ex-list lKRM ->8
3568 #                 <0> padsv[@a:64,65] sRM ->8
3569 #           <$> const[PV "foo"] sM ->a
3570 #           <.> method_named[PV "import"] ->b
3571
3572 sub maybe_var_attr {
3573     my ($self, $op, $cx) = @_;
3574
3575     my $kid = $op->first->sibling; # skip pushmark
3576     return if class($kid) eq 'NULL';
3577
3578     my $lop;
3579     my $type;
3580
3581     # Extract out all the pad ops and entersub ops into
3582     # @padops and @entersubops. Return if anything else seen.
3583     # Also determine what class (if any) all the pad vars belong to
3584     my $class;
3585     my $decl; # 'my' or 'state'
3586     my (@padops, @entersubops);
3587     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
3588         my $lopname = $lop->name;
3589         my $loppriv = $lop->private;
3590         if ($lopname =~ /^pad[sah]v$/) {
3591             return unless $loppriv & OPpLVAL_INTRO;
3592
3593             my $padname = $self->padname_sv($lop->targ);
3594             my $thisclass = ($padname->FLAGS & SVpad_TYPED)
3595                                 ? $padname->SvSTASH->NAME : 'main';
3596
3597             # all pad vars must be in the same class
3598             $class //= $thisclass;
3599             return unless $thisclass eq $class;
3600
3601             # all pad vars must be the same sort of declaration
3602             # (all my, all state, etc)
3603             my $this = ($loppriv & OPpPAD_STATE) ? 'state' : 'my';
3604             if (defined $decl) {
3605                 return unless $this eq $decl;
3606             }
3607             $decl = $this;
3608
3609             push @padops, $lop;
3610         }
3611         elsif ($lopname eq 'entersub') {
3612             push @entersubops, $lop;
3613         }
3614         else {
3615             return;
3616         }
3617     }
3618
3619     return unless @padops && @padops == @entersubops;
3620
3621     # there should be a balance: each padop has a corresponding
3622     # 'attributes'->import() method call, in the same order.
3623
3624     my @varnames;
3625     my $attr_text;
3626
3627     for my $i (0..$#padops) {
3628         my $padop = $padops[$i];
3629         my $esop  = $entersubops[$i];
3630
3631         push @varnames, $self->padname($padop->targ);
3632
3633         return unless ($esop->flags & OPf_KIDS);
3634
3635         my $kid = $esop->first;
3636         return unless $kid->type == OP_PUSHMARK;
3637
3638         $kid = $kid->sibling;
3639         return unless $$kid && $kid->type == OP_CONST;
3640         return unless $self->const_sv($kid)->PV eq 'attributes';
3641
3642         $kid = $kid->sibling;
3643         return unless $$kid && $kid->type == OP_CONST; # __PACKAGE__
3644
3645         $kid = $kid->sibling;
3646         return unless  $$kid
3647                     && $kid->name eq "srefgen"
3648                     && ($kid->flags & OPf_KIDS)
3649                     && ($kid->first->flags & OPf_KIDS)
3650                     && $kid->first->first->name =~ /^pad[sah]v$/
3651                     && $kid->first->first->targ == $padop->targ;
3652
3653         $kid = $kid->sibling;
3654         my @attr;
3655         while ($$kid) {
3656             last if ($kid->type != OP_CONST);
3657             push @attr, $self->const_sv($kid)->PV;
3658             $kid = $kid->sibling;
3659         }
3660         return unless @attr;
3661         my $thisattr = ":" . join(' ', @attr);
3662         $attr_text //= $thisattr;
3663         # all import calls must have the same list of attributes
3664         return unless $attr_text eq $thisattr;
3665
3666         return unless $kid->name eq 'method_named';
3667         return unless $self->meth_sv($kid)->PV eq 'import';
3668
3669         $kid = $kid->sibling;
3670         return if $$kid;
3671     }
3672
3673     my $res = $decl;
3674     $res .= " $class " if $class ne 'main';
3675     $res .=
3676             (@varnames > 1)
3677             ? "(" . join(', ', @varnames) . ')'
3678             : " $varnames[0]";
3679
3680     return "$res $attr_text";
3681 }
3682
3683
3684 sub pp_list {
3685     my $self = shift;
3686     my($op, $cx) = @_;
3687
3688     {
3689         # might be my ($s,@a,%h) :Foo(bar);
3690         my $my_attr = maybe_var_attr($self, $op, $cx);
3691         return $my_attr if defined $my_attr;
3692     }
3693
3694     my($expr, @exprs);
3695     my $kid = $op->first->sibling; # skip pushmark
3696     return '' if class($kid) eq 'NULL';
3697     my $lop;
3698     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
3699     my $type;
3700     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
3701         my $lopname = $lop->name;
3702         my $loppriv = $lop->private;
3703         my $newtype;
3704         if ($lopname =~ /^pad[ash]v$/ && $loppriv & OPpLVAL_INTRO) {
3705             if ($loppriv & OPpPAD_STATE) { # state()
3706                 ($local = "", last) if $local !~ /^(?:either|state)$/;
3707                 $local = "state";
3708             } else { # my()
3709                 ($local = "", last) if $local !~ /^(?:either|my)$/;
3710                 $local = "my";
3711             }
3712             my $padname = $self->padname_sv($lop->targ);
3713             if ($padname->FLAGS & SVpad_TYPED) {
3714                 $newtype = $padname->SvSTASH->NAME;
3715             }
3716         } elsif ($lopname =~ /^(?:gv|rv2)([ash])v$/
3717                         && $loppriv & OPpOUR_INTRO
3718                 or $lopname eq "null" && class($lop) eq 'UNOP'
3719                         && $lop->first->name eq "gvsv"
3720                         && $lop->first->private & OPpOUR_INTRO) { # our()
3721             my $newlocal = "local " x !!($loppriv & OPpLVAL_INTRO) . "our";
3722             ($local = "", last)
3723                 if $local ne 'either' && $local ne $newlocal;
3724             $local = $newlocal;
3725             my $funny = !$1 || $1 eq 's' ? '$' : $1 eq 'a' ? '@' : '%';
3726             if (my $t = $self->find_our_type(
3727                     $funny . $self->gv_or_padgv($lop->first)->NAME
3728                )) {
3729                 $newtype = $t;
3730             }
3731         } elsif ($lopname ne 'undef'
3732            and    !($loppriv & OPpLVAL_INTRO)
3733                || !exists $uses_intro{$lopname eq 'null'
3734                                         ? substr B::ppname($lop->targ), 3
3735                                         : $lopname})
3736         {
3737             $local = ""; # or not
3738             last;
3739         } elsif ($lopname ne "undef")
3740         {
3741             # local()
3742             ($local = "", last) if $local !~ /^(?:either|local)$/;
3743             $local = "local";
3744         }
3745         if (defined $type && defined $newtype && $newtype ne $type) {
3746             $local = '';
3747             last;
3748         }
3749         $type = $newtype;
3750     }
3751     $local = "" if $local eq "either"; # no point if it's all undefs
3752     $local &&= join ' ', map $self->keyword($_), split / /, $local;
3753     $local .= " $type " if $local && length $type;
3754     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
3755     for (; !null($kid); $kid = $kid->sibling) {
3756         if ($local) {
3757             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
3758                 $lop = $kid->first;
3759             } else {
3760                 $lop = $kid;
3761             }
3762             $self->{'avoid_local'}{$$lop}++;
3763             $expr = $self->deparse($kid, 6);
3764             delete $self->{'avoid_local'}{$$lop};
3765         } else {
3766             $expr = $self->deparse($kid, 6);
3767         }
3768         push @exprs, $expr;
3769     }
3770     if ($local) {
3771         if (@exprs == 1 && ($local eq 'state' || $local eq 'CORE::state')) {
3772             # 'state @a = ...' is legal, while 'state(@a) = ...' currently isn't
3773             return "$local $exprs[0]";
3774         }
3775         return "$local(" . join(", ", @exprs) . ")";
3776     } else {
3777         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
3778     }
3779 }
3780
3781 sub is_ifelse_cont {
3782     my $op = shift;
3783     return ($op->name eq "null" and class($op) eq "UNOP"
3784             and $op->first->name =~ /^(and|cond_expr)$/
3785             and is_scope($op->first->first->sibling));
3786 }
3787
3788 sub pp_cond_expr {
3789     my $self = shift;
3790     my($op, $cx) = @_;
3791     my $cond = $op->first;
3792     my $true = $cond->sibling;
3793     my $false = $true->sibling;
3794     my $cuddle = $self->{'cuddle'};
3795     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
3796             (is_scope($false) || is_ifelse_cont($false))
3797             and $self->{'expand'} < 7) {
3798         $cond = $self->deparse($cond, 8);
3799         $true = $self->deparse($true, 6);
3800         $false = $self->deparse($false, 8);
3801         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
3802     }
3803
3804     $cond = $self->deparse($cond, 1);
3805     $true = $self->deparse($true, 0);
3806     my $head = $self->keyword("if") . " ($cond) {\n\t$true\n\b}";
3807     my @elsifs;
3808     my $elsif;
3809     while (!null($false) and is_ifelse_cont($false)) {
3810         my $newop = $false->first;
3811         my $newcond = $newop->first;
3812         my $newtrue = $newcond->sibling;
3813         $false = $newtrue->sibling; # last in chain is OP_AND => no else
3814         if ($newcond->name eq "lineseq")
3815         {
3816             # lineseq to ensure correct line numbers in elsif()
3817             # Bug #37302 fixed by change #33710.
3818             $newcond = $newcond->first->sibling;
3819         }
3820         $newcond = $self->deparse($newcond, 1);
3821         $newtrue = $self->deparse($newtrue, 0);
3822         $elsif ||= $self->keyword("elsif");
3823         push @elsifs, "$elsif ($newcond) {\n\t$newtrue\n\b}";
3824     }
3825     if (!null($false)) {
3826         $false = $cuddle . $self->keyword("else") . " {\n\t" .
3827           $self->deparse($false, 0) . "\n\b}\cK";
3828     } else {
3829         $false = "\cK";
3830     }
3831     return $head . join($cuddle, "", @elsifs) . $false;
3832 }
3833
3834 sub pp_once {
3835     my ($self, $op, $cx) = @_;
3836     my $cond = $op->first;
3837     my $true = $cond->sibling;
3838
3839     my $ret = $self->deparse($true, $cx);
3840     $ret =~ s/^(\(?)\$/$1 . $self->keyword("state") . ' $'/e;
3841     $ret;
3842 }
3843
3844 sub loop_common {
3845     my $self = shift;
3846     my($op, $cx, $init) = @_;
3847     my $enter = $op->first;
3848     my $kid = $enter->sibling;
3849     local(@$self{qw'curstash warnings hints hinthash'})
3850                 = @$self{qw'curstash warnings hints hinthash'};
3851     my $head = "";
3852     my $bare = 0;
3853     my $body;
3854     my $cond = undef;
3855     my $name;
3856     if ($kid->name eq "lineseq") { # bare or infinite loop
3857         if ($kid->last->name eq "unstack") { # infinite
3858             $head = "while (1) "; # Can't use for(;;) if there's a continue
3859             $cond = "";
3860         } else {
3861             $bare = 1;
3862         }
3863         $body = $kid;
3864     } elsif ($enter->name eq "enteriter") { # foreach
3865         my $ary = $enter->first->sibling; # first was pushmark
3866         my $var = $ary->sibling;
3867         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
3868             # "reverse" was optimised away
3869             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
3870         } elsif ($enter->flags & OPf_STACKED
3871             and not null $ary->first->sibling->sibling)
3872         {
3873             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
3874               $self->deparse($ary->first->sibling->sibling, 9);
3875         } else {
3876             $ary = $self->deparse($ary, 1);
3877         }
3878         if (null $var) {
3879             $var = $self->pp_padsv($enter, 1, 1);
3880         } elsif ($var->name eq "rv2gv") {
3881             $var = $self->pp_rv2sv($var, 1);
3882             if ($enter->private & OPpOUR_INTRO) {
3883                 # our declarations don't have package names
3884                 $var =~ s/^(.).*::/$1/;
3885                 $var = "our $var";
3886             }
3887         } elsif ($var->name eq "gv") {
3888             $var = "\$" . $self->deparse($var, 1);
3889         } else {
3890             $var = $self->deparse($var, 1);
3891         }
3892         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
3893         if (!is_state $body->first and $body->first->name !~ /^(?:stub|leave|scope)$/) {
3894             confess unless $var eq '$_';
3895             $body = $body->first;
3896             return $self->deparse($body, 2) . " "
3897                  . $self->keyword("foreach") . " ($ary)";
3898         }
3899         $head = "foreach $var ($ary) ";
3900     } elsif ($kid->name eq "null") { # while/until
3901         $kid = $kid->first;
3902         $name = {"and" => "while", "or" => "until"}->{$kid->name};
3903         $cond = $kid->first;
3904         $body = $kid->first->sibling;
3905     } elsif ($kid->name eq "stub") { # bare and empty
3906         return "{;}"; # {} could be a hashref
3907     }
3908     # If there isn't a continue block, then the next pointer for the loop
3909     # will point to the unstack, which is kid's last child, except
3910     # in a bare loop, when it will point to the leaveloop. When neither of
3911     # these conditions hold, then the second-to-last child is the continue
3912     # block (or the last in a bare loop).
3913     my $cont_start = $enter->nextop;
3914     my $cont;
3915     my $precond;
3916     my $postcond;
3917     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
3918         if ($bare) {
3919             $cont = $body->last;
3920         } else {
3921             $cont = $body->first;
3922             while (!null($cont->sibling->sibling)) {
3923                 $cont = $cont->sibling;
3924             }
3925         }
3926         my $state = $body->first;
3927         my $cuddle = $self->{'cuddle'};
3928         my @states;
3929         for (; $$state != $$cont; $state = $state->sibling) {
3930             push @states, $state;
3931         }
3932         $body = $self->lineseq(undef, 0, @states);
3933         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
3934             $precond = "for ($init; ";
3935             $postcond = "; " . $self->deparse($cont, 1) .") ";
3936             $cont = "\cK";
3937         } else {
3938             $cont = $cuddle . "continue {\n\t" .
3939               $self->deparse($cont, 0) . "\n\b}\cK";
3940         }
3941     } else {
3942         return "" if !defined $body;
3943         if (length $init) {
3944             $precond = "for ($init; ";
3945             $postcond = ";) ";
3946         }
3947         $cont = "\cK";
3948         $body = $self->deparse($body, 0);
3949     }
3950     if ($precond) { # for(;;)
3951         $cond &&= $name eq 'until'
3952                     ? listop($self, undef, 1, "not", $cond->first)
3953                     : $self->deparse($cond, 1);
3954         $head = "$precond$cond$postcond";
3955     }
3956     if ($name && !$head) {
3957         ref $cond and $cond = $self->deparse($cond, 1);
3958         $head = "$name ($cond) ";
3959     }
3960     $head =~ s/^(for(?:each)?|while|until)/$self->keyword($1)/e;
3961     $body =~ s/;?$/;\n/;
3962
3963     return $head . "{\n\t" . $body . "\b}" . $cont;
3964 }
3965
3966 sub pp_leaveloop { shift->loop_common(@_, "") }
3967
3968 sub for_loop {
3969     my $self = shift;
3970     my($op, $cx) = @_;
3971     my $init = $self->deparse($op, 1);
3972     my $s = $op->sibling;
3973     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
3974     return $self->loop_common($ll, $cx, $init);
3975 }
3976
3977 sub pp_leavetry {
3978     my $self = shift;
3979     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
3980 }
3981
3982 sub _op_is_or_was {
3983   my ($op, $expect_type) = @_;
3984   my $type = $op->type;
3985   return($type == $expect_type
3986          || ($type == OP_NULL && $op->targ == $expect_type));
3987 }
3988
3989 sub pp_null {
3990     my($self, $op, $cx) = @_;
3991
3992     # might be 'my $s :Foo(bar);'
3993     if ($op->targ == OP_LIST) {
3994         my $my_attr = maybe_var_attr($self, $op, $cx);
3995         return $my_attr if defined $my_attr;
3996     }
3997
3998     if (class($op) eq "OP") {
3999         # old value is lost
4000         return $self->{'ex_const'} if $op->targ == OP_CONST;
4001     } elsif (class ($op) eq "COP") {
4002             return &pp_nextstate;
4003     } elsif ($op->first->name eq 'pushmark'
4004              or $op->first->name eq 'null'
4005                 && $op->first->targ == OP_PUSHMARK
4006                 && _op_is_or_was($op, OP_LIST)) {
4007         return $self->pp_list($op, $cx);
4008     } elsif ($op->first->name eq "enter") {
4009         return $self->pp_leave($op, $cx);
4010     } elsif ($op->first->name eq "leave") {
4011         return $self->pp_leave($op->first, $cx);
4012     } elsif ($op->first->name eq "scope") {
4013         return $self->pp_scope($op->first, $cx);
4014     } elsif ($op->targ == OP_STRINGIFY) {
4015         return $self->dquote($op, $cx);
4016     } elsif ($op->targ == OP_GLOB) {
4017         return $self->pp_glob(
4018                  $op->first    # entersub
4019                     ->first    # ex-list
4020                     ->first    # pushmark
4021                     ->sibling, # glob
4022                  $cx
4023                );
4024     } elsif (!null($op->first->sibling) and
4025              $op->first->sibling->name eq "readline" and
4026              $op->first->sibling->flags & OPf_STACKED) {
4027         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
4028                                    . $self->deparse($op->first->sibling, 7),
4029                                    $cx, 7);
4030     } elsif (!null($op->first->sibling) and
4031              $op->first->sibling->name =~ /^transr?\z/ and
4032              $op->first->sibling->flags & OPf_STACKED) {
4033         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
4034                                    . $self->deparse($op->first->sibling, 20),
4035                                    $cx, 20);
4036     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
4037         return ($self->lex_in_scope("&do") ? "CORE::do" : "do")
4038              . " {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
4039     } elsif (!null($op->first->sibling) and
4040              $op->first->sibling->name eq "null" and
4041              class($op->first->sibling) eq "UNOP" and
4042              $op->first->sibling->first->flags & OPf_STACKED and
4043              $op->first->sibling->first->name eq "rcatline") {
4044         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
4045                                    . $self->deparse($op->first->sibling, 18),
4046                                    $cx, 18);
4047     } else {
4048         return $self->deparse($op->first, $cx);
4049     }
4050 }
4051
4052 sub padname {
4053     my $self = shift;
4054     my $targ = shift;
4055     return $self->padname_sv($targ)->PVX;
4056 }
4057
4058 sub padany {
4059     my $self = shift;
4060     my $op = shift;
4061     return substr($self->padname($op->targ), 1); # skip $/@/%
4062 }
4063
4064 sub pp_padsv {
4065     my $self = shift;
4066     my($op, $cx, $forbid_parens) = @_;
4067     my $targ = $op->targ;
4068     return $self->maybe_my($op, $cx, $self->padname($targ),
4069                            $self->padname_sv($targ),
4070                            $forbid_parens);
4071 }
4072
4073 sub pp_padav { pp_padsv(@_) }
4074
4075 # prepend 'keys' where its been optimised away, with suitable handling
4076 # of CORE:: and parens
4077
4078 sub add_keys_keyword {
4079     my ($self, $str, $cx) = @_;
4080     $str = $self->maybe_parens($str, $cx, 16);
4081     # 'keys %h' versus 'keys(%h)'
4082     $str = " $str" unless $str =~ /^\(/;
4083     return $self->keyword("keys") . $str;
4084 }
4085
4086 sub pp_padhv {
4087     my ($self, $op, $cx) = @_;
4088     my $str =  pp_padsv(@_);
4089     # with OPpPADHV_ISKEYS the keys op is optimised away, except
4090     # in scalar context the old op is kept (but not executed) so its targ
4091     # can be used.
4092     if (     ($op->private & OPpPADHV_ISKEYS)
4093         && !(($op->flags & OPf_WANT) == OPf_WANT_SCALAR))
4094     {
4095         $str = $self->add_keys_keyword($str, $cx);
4096     }
4097     $str;
4098 }
4099
4100 sub gv_or_padgv {
4101     my $self = shift;
4102     my $op = shift;
4103     if (class($op) eq "PADOP") {
4104         return $self->padval($op->padix);
4105     } else { # class($op) eq "SVOP"
4106         return $op->gv;
4107     }
4108 }
4109
4110 sub pp_gvsv {
4111     my $self = shift;
4112     my($op, $cx) = @_;
4113     my $gv = $self->gv_or_padgv($op);
4114     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
4115                                  $self->gv_name($gv), $cx));
4116 }
4117
4118 sub pp_gv {
4119     my $self = shift;
4120     my($op, $cx) = @_;
4121     my $gv = $self->gv_or_padgv($op);
4122     return $self->maybe_qualify("", $self->gv_name($gv));
4123 }
4124
4125 sub pp_aelemfast_lex {
4126     my $self = shift;
4127     my($op, $cx) = @_;
4128     my $name = $self->padname($op->targ);
4129     $name =~ s/^@/\$/;
4130     my $i = $op->private;
4131     $i -= 256 if $i > 127;
4132     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
4133 }
4134
4135 sub pp_aelemfast {
4136     my $self = shift;
4137     my($op, $cx) = @_;
4138     # optimised PADAV, pre 5.15
4139     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
4140
4141     my $gv = $self->gv_or_padgv($op);
4142     my($name,$quoted) = $self->stash_variable_name('@',$gv);
4143     $name = $quoted ? "$name->" : '$' . $name;
4144     my $i = $op->private;
4145     $i -= 256 if $i > 127;
4146     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
4147 }
4148
4149 sub rv2x {
4150     my $self = shift;
4151     my($op, $cx, $type) = @_;
4152
4153     if (class($op) eq 'NULL' || !$op->can("first")) {
4154         carp("Unexpected op in pp_rv2x");
4155         return 'XXX';
4156     }
4157     my $kid = $op->first;
4158     if ($kid->name eq "gv") {
4159         return $self->stash_variable($type,
4160                     $self->gv_name($self->gv_or_padgv($kid)), $cx);
4161     } elsif (is_scalar $kid) {
4162         my $str = $self->deparse($kid, 0);
4163         if ($str =~ /^\$([^\w\d])\z/) {
4164             # "$$+" isn't a legal way to write the scalar dereference
4165             # of $+, since the lexer can't tell you aren't trying to
4166             # do something like "$$ + 1" to get one more than your
4167             # PID. Either "${$+}" or "$${+}" are workable
4168             # disambiguations, but if the programmer did the former,
4169             # they'd be in the "else" clause below rather than here.
4170             # It's not clear if this should somehow be unified with
4171             # the code in dq and re_dq that also adds lexer
4172             # disambiguation braces.
4173             $str = '$' . "{$1}"; #'
4174         }
4175         return $type . $str;
4176     } else {
4177         return $type . "{" . $self->deparse($kid, 0) . "}";
4178     }
4179 }
4180
4181 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
4182 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
4183
4184 sub pp_rv2hv {
4185     my ($self, $op, $cx) = @_;
4186     my $str = rv2x(@_, "%");
4187     if ($op->private & OPpRV2HV_ISKEYS) {
4188         $str = $self->add_keys_keyword($str, $cx);
4189     }
4190     return maybe_local(@_, $str);
4191 }
4192
4193 # skip rv2av
4194 sub pp_av2arylen {
4195     my $self = shift;
4196     my($op, $cx) = @_;
4197     if ($op->first->name eq "padav") {
4198         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
4199     } else {
4200         return $self->maybe_local($op, $cx,
4201                                   $self->rv2x($op->first, $cx, '$#'));
4202     }
4203 }
4204
4205 # skip down to the old, ex-rv2cv
4206 sub pp_rv2cv {
4207     my ($self, $op, $cx) = @_;
4208     if (!null($op->first) && $op->first->name eq 'null' &&
4209         $op->first->targ == OP_LIST)
4210     {
4211         return $self->rv2x($op->first->first->sibling, $cx, "&")
4212     }
4213     else {
4214         return $self->rv2x($op, $cx, "")
4215     }
4216 }
4217
4218 sub list_const {
4219     my $self = shift;
4220     my($cx, @list) = @_;
4221     my @a = map $self->const($_, 6), @list;
4222     if (@a == 0) {
4223         return "()";
4224     } elsif (@a == 1) {
4225         return $a[0];
4226     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
4227         # collapse (-1,0,1,2) into (-1..2)
4228         my ($s, $e) = @a[0,-1];
4229         my $i = $s;
4230         return $self->maybe_parens("$s..$e", $cx, 9)
4231           unless grep $i++ != $_, @a;
4232     }
4233     return $self->maybe_parens(join(", ", @a), $cx, 6);
4234 }
4235
4236 sub pp_rv2av {
4237     my $self = shift;
4238     my($op, $cx) = @_;
4239     my $kid = $op->first;
4240     if ($kid->name eq "const") { # constant list
4241         my $av = $self->const_sv($kid);
4242         return $self->list_const($cx, $av->ARRAY);
4243     } else {
4244         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
4245     }
4246  }
4247
4248 sub is_subscriptable {
4249     my $op = shift;
4250     if ($op->name =~ /^([ahg]elem|multideref$)/) {
4251         return 1;
4252     } elsif ($op->name eq "entersub") {
4253         my $kid = $op->first;
4254         return 0 unless null $kid->sibling;
4255         $kid = $kid->first;
4256         $kid = $kid->sibling until null $kid->sibling;
4257         return 0 if is_scope($kid);
4258         $kid = $kid->first;
4259         return 0 if $kid->name eq "gv" || $kid->name eq "padcv";
4260         return 0 if is_scalar($kid);
4261         return is_subscriptable($kid);  
4262     } else {
4263         return 0;
4264     }
4265 }
4266
4267 sub elem_or_slice_array_name
4268 {
4269     my $self = shift;
4270     my ($array, $left, $padname, $allow_arrow) = @_;
4271
4272     if ($array->name eq $padname) {
4273         return $self->padany($array);
4274     } elsif (is_scope($array)) { # ${expr}[0]
4275         return "{" . $self->deparse($array, 0) . "}";
4276     } elsif ($array->name eq "gv") {
4277         ($array, my $quoted) =
4278             $self->stash_variable_name(
4279                 $left eq '[' ? '@' : '%', $self->gv_or_padgv($array)
4280             );
4281         if (!$allow_arrow && $quoted) {
4282             # This cannot happen.
4283             die "Invalid variable name $array for slice";
4284         }
4285         return $quoted ? "$array->" : $array;
4286     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
4287         return $self->deparse($array, 24);
4288     } else {
4289         return undef;
4290     }
4291 }
4292
4293 sub elem_or_slice_single_index
4294 {
4295     my $self = shift;
4296     my ($idx) = @_;
4297
4298     $idx = $self->deparse($idx, 1);
4299
4300     # Outer parens in an array index will confuse perl
4301     # if we're interpolating in a regular expression, i.e.
4302     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
4303     #
4304     # If $self->{parens}, then an initial '(' will
4305     # definitely be paired with a final ')'. If
4306     # !$self->{parens}, the misleading parens won't
4307     # have been added in the first place.
4308     #
4309     # [You might think that we could get "(...)...(...)"
4310     # where the initial and final parens do not match
4311     # each other. But we can't, because the above would
4312     # only happen if there's an infix binop between the
4313     # two pairs of parens, and *that* means that the whole
4314     # expression would be parenthesized as well.]
4315     #
4316     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
4317
4318     # Hash-element braces will autoquote a bareword inside themselves.
4319     # We need to make sure that C<$hash{warn()}> doesn't come out as
4320     # C<$hash{warn}>, which has a quite different meaning. Currently
4321     # B::Deparse will always quote strings, even if the string was a
4322     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
4323     # for constant strings.) So we can cheat slightly here - if we see
4324     # a bareword, we know that it is supposed to be a function call.
4325     #
4326     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
4327
4328     return $idx;
4329 }
4330
4331 sub elem {
4332     my $self = shift;
4333     my ($op, $cx, $left, $right, $padname) = @_;
4334     my($array, $idx) = ($op->first, $op->first->sibling);
4335
4336     $idx = $self->elem_or_slice_single_index($idx);
4337
4338     unless ($array->name eq $padname) { # Maybe this has been fixed     
4339         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
4340     }
4341     if (my $array_name=$self->elem_or_slice_array_name
4342             ($array, $left, $padname, 1)) {
4343         return ($array_name =~ /->\z/
4344                     ? $array_name
4345                     : $array_name eq '#' ? '${#}' : "\$" . $array_name)
4346               . $left . $idx . $right;
4347     } else {
4348         # $x[20][3]{hi} or expr->[20]
4349         my $arrow = is_subscriptable($array) ? "" : "->";
4350         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
4351     }
4352
4353 }
4354
4355 # a simplified version of elem_or_slice_array_name()
4356 # for the use of pp_multideref
4357
4358 sub multideref_var_name {
4359     my $self = shift;
4360     my ($gv, $is_hash) = @_;
4361
4362     my ($name, $quoted) =
4363         $self->stash_variable_name( $is_hash  ? '%' : '@', $gv);
4364     return $quoted ? "$name->"
4365                    : $name eq '#'
4366                         ? '${#}'       # avoid ${#}[1] => $#[1]
4367                         : '$' . $name;
4368 }
4369
4370
4371 # deparse an OP_MULTICONCAT. If $in_dq is 1, we're within
4372 # a double-quoted string, so for example.
4373 #     "abc\Qdef$x\Ebar"
4374 # might get compiled as
4375 #    multiconcat("abc", metaquote(multiconcat("def", $x)), "bar")
4376 # and the inner multiconcat should be deparsed as C<def$x> rather than
4377 # the normal C<def . $x>
4378 # Ditto if  $in_dq is 2, handle qr/...\Qdef$x\E.../.
4379
4380 sub do_multiconcat {
4381     my $self = shift;
4382     my($op, $cx, $in_dq) = @_;
4383
4384     my $kid;
4385     my @kids;
4386     my $assign;
4387     my $append;
4388     my $lhs = "";
4389
4390     for ($kid = $op->first; !null $kid; $kid = $kid->sibling) {
4391         # skip the consts and/or padsv we've optimised away
4392         push @kids, $kid
4393             unless $kid->type == OP_NULL
4394               && (   $kid->targ == OP_PADSV
4395                   || $kid->targ == OP_CONST
4396                   || $kid->targ == OP_PUSHMARK);
4397     }
4398
4399     $append = ($op->private & OPpMULTICONCAT_APPEND);
4400
4401     if ($op->private & OPpTARGET_MY) {
4402         # '$lex  = ...' or '$lex .= ....' or 'my $lex = '
4403         $lhs = $self->padname($op->targ);
4404         $lhs = "my $lhs" if ($op->private & OPpLVAL_INTRO);
4405         $assign = 1;
4406     }
4407     elsif ($op->flags & OPf_STACKED) {
4408         # 'expr  = ...' or 'expr .= ....'
4409         my $expr = $append ? shift(@kids) : pop(@kids);
4410         $lhs = $self->deparse($expr, 7);
4411         $assign = 1;
4412     }
4413
4414     if ($assign) {
4415         $lhs .=  $append ? ' .= ' : ' = ';
4416     }
4417
4418     my ($nargs, $const_str, @const_lens) = $op->aux_list($self->{curcv});
4419
4420     my @consts;
4421     my $i = 0;
4422     for (@const_lens) {
4423         if ($_ == -1) {
4424             push @consts, undef;
4425         }
4426         else {
4427             push @consts, substr($const_str, $i, $_);
4428         my @args;
4429             $i += $_;
4430         }
4431     }
4432
4433     my $rhs = "";
4434
4435     if (   $in_dq
4436         || (($op->private & OPpMULTICONCAT_STRINGIFY) && !$self->{'unquote'}))
4437     {
4438         # "foo=$foo bar=$bar "
4439         my $not_first;
4440         while (@consts) {
4441             if ($not_first) {
4442                 my $s = $self->dq(shift(@kids), 18);
4443                 # don't deparse "a${$}b" as "a$$b"
4444                 $s = '${$}' if $s eq '$$';
4445                 $rhs = dq_disambiguate($rhs, $s);
4446             }
4447             $not_first = 1;
4448             my $c = shift @consts;
4449             if (defined $c) {
4450                 if ($in_dq == 2) {
4451                     # in pattern: don't convert newline to '\n' etc etc
4452                     my $s = re_uninterp(escape_re(re_unback($c)));
4453                     $rhs = re_dq_disambiguate($rhs, $s)
4454                 }
4455                 else {
4456                     my $s = uninterp(escape_str(unback($c)));
4457                     $rhs = dq_disambiguate($rhs, $s)
4458                 }
4459             }
4460         }
4461         return $rhs if $in_dq;
4462         $rhs = single_delim("qq", '"', $rhs, $self);
4463     }
4464     elsif ($op->private & OPpMULTICONCAT_FAKE) {
4465         # sprintf("foo=%s bar=%s ", $foo, $bar)
4466
4467         my @all;
4468         @consts = map { $_ //= ''; s/%/%%/g; $_ } @consts;
4469         my $fmt = join '%s', @consts;
4470         push @all, $self->quoted_const_str($fmt);
4471
4472         # the following is a stripped down copy of sub listop {}
4473         my $parens = $assign || ($cx >= 5) || $self->{'parens'};
4474         my $fullname = $self->keyword('sprintf');
4475         push @all, map $self->deparse($_, 6), @kids;
4476
4477         $rhs = $parens
4478                 ? "$fullname(" . join(", ", @all) . ")"
4479                 : "$fullname " . join(", ", @all);
4480     }
4481     else {
4482         # "foo=" . $foo . " bar=" . $bar
4483         my @all;
4484         my $not_first;
4485         while (@consts) {
4486             push @all, $self->deparse(shift(@kids), 18) if $not_first;
4487             $not_first = 1;
4488             my $c = shift @consts;
4489             if (defined $c) {
4490                 push @all, $self->quoted_const_str($c);
4491             }
4492         }
4493         $rhs .= join ' . ', @all;
4494     }
4495
4496     my $text = $lhs . $rhs;